automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994-2012 Free Software Foundation, Inc.
  10
  11 # This program is free software; you can redistribute it and/or modify
  12 # it under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 2, or (at your option)
  14 # any later version.
  15
  16 # This program is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 # GNU General Public License for more details.
  20
  21 # You should have received a copy of the GNU General Public License
  22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  25 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  26 # Alexandre Duret-Lutz <adl@gnu.org>.
  27
  28 package Language;
  29
  30 BEGIN
  31 {
  32   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  33   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  34
  35   # Override SHELL.  This is required on DJGPP so that system() uses
  36   # bash, not COMMAND.COM which doesn't quote arguments properly.
  37   # Other systems aren't expected to use $SHELL when Automake
  38   # runs, but it should be safe to drop the "if DJGPP" guard if
  39   # it turns up other systems need the same thing.  After all,
  40   # if SHELL is used, ./configure's SHELL is always better than
  41   # the user's SHELL (which may be something like tcsh).
  42   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJDIR'};
  43 }
  44
  45 use Class::Struct ();
  46 Class::Struct::struct (
  47         # Short name of the language (c, f77...).
  48         'name' => "\$",
  49         # Nice name of the language (C, Fortran 77...).
  50         'Name' => "\$",
  51
  52         # List of configure variables which must be defined.
  53         'config_vars' => '@',
  54
  55         # 'pure' is '1' or ''.  A 'pure' language is one where, if
  56         # all the files in a directory are of that language, then we
  57         # do not require the C compiler or any code to call it.
  58         'pure'   => "\$",
  59
  60         'autodep' => "\$",
  61
  62         # Name of the compiling variable (COMPILE).
  63         'compiler'  => "\$",
  64         # Content of the compiling variable.
  65         'compile'  => "\$",
  66         # Flag to require compilation without linking (-c).
  67         'compile_flag' => "\$",
  68         'extensions' => '@',
  69         # A subroutine to compute a list of possible extensions of
  70         # the product given the input extensions.
  71         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  72         'output_extensions' => "\$",
  73         # A list of flag variables used in 'compile'.
  74         # (defaults to [])
  75         'flags' => "@",
  76
  77         # Any tag to pass to libtool while compiling.
  78         'libtool_tag' => "\$",
  79
  80         # The file to use when generating rules for this language.
  81         # The default is 'depend2'.
  82         'rule_file' => "\$",
  83
  84         # Name of the linking variable (LINK).
  85         'linker' => "\$",
  86         # Content of the linking variable.
  87         'link' => "\$",
  88
  89         # Name of the compiler variable (CC).
  90         'ccer' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} (@_);
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 BEGIN
 134 {
 135   if ($perl_threads)
 136     {
 137       require threads;
 138       import threads;
 139       require Thread::Queue;
 140       import Thread::Queue;
 141     }
 142 }
 143 use Automake::General;
 144 use Automake::XFile;
 145 use Automake::Channels;
 146 use Automake::ChannelDefs;
 147 use Automake::Configure_ac;
 148 use Automake::FileUtils;
 149 use Automake::Location;
 150 use Automake::Condition qw/TRUE FALSE/;
 151 use Automake::DisjConditions;
 152 use Automake::Options;
 153 use Automake::Variable;
 154 use Automake::VarDef;
 155 use Automake::Rule;
 156 use Automake::RuleDef;
 157 use Automake::Wrap 'makefile_wrap';
 158 use File::Basename;
 159 use File::Spec;
 160 use Carp;
 161
 162 ## ----------- ##
 163 ## Constants.  ##
 164 ## ----------- ##
 165
 166 # Some regular expressions.  One reason to put them here is that it
 167 # makes indentation work better in Emacs.
 168
 169 # Writing singled-quoted-$-terminated regexes is a pain because
 170 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 171 # by a closing quote.  Letting perl-mode think the quote is not closed
 172 # leads to all sort of misindentations.  On the other hand, defining
 173 # regexes as double-quoted strings is far less readable.  So usually
 174 # we will write:
 175 #
 176 #  $REGEX = '^regex_value' . "\$";
 177
 178 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 179 my $WHITE_PATTERN = '^\s*' . "\$";
 180 my $COMMENT_PATTERN = '^#';
 181 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 182 # A rule has three parts: a list of targets, a list of dependencies,
 183 # and optionally actions.
 184 my $RULE_PATTERN =
 185   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 186
 187 # Only recognize leading spaces, not leading tabs.  If we recognize
 188 # leading tabs here then we need to make the reader smarter, because
 189 # otherwise it will think rules like 'foo=bar; \' are errors.
 190 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 191 # This pattern recognizes a Gnits version id and sets $1 if the
 192 # release is an alpha release.  We also allow a suffix which can be
 193 # used to extend the version number with a "fork" identifier.
 194 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 195
 196 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 197 my $ELSE_PATTERN =
 198   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 199 my $ENDIF_PATTERN =
 200   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 201 my $PATH_PATTERN = '(\w|[+/.-])+';
 202 # This will pass through anything not of the prescribed form.
 203 my $INCLUDE_PATTERN = ('^include\s+'
 204                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 205                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 206                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 207
 208 # Directories installed during 'install-exec' phase.
 209 my $EXEC_DIR_PATTERN =
 210   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 211
 212 # Values for AC_CANONICAL_*
 213 use constant AC_CANONICAL_BUILD  => 1;
 214 use constant AC_CANONICAL_HOST   => 2;
 215 use constant AC_CANONICAL_TARGET => 3;
 216
 217 # Values indicating when something should be cleaned.
 218 use constant MOSTLY_CLEAN     => 0;
 219 use constant CLEAN            => 1;
 220 use constant DIST_CLEAN       => 2;
 221 use constant MAINTAINER_CLEAN => 3;
 222
 223 # Libtool files.
 224 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 225 # ltconfig appears here for compatibility with old versions of libtool.
 226 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 227
 228 # Commonly found files we look for and automatically include in
 229 # DISTFILES.
 230 my @common_files =
 231     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 232         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 233         ar-lib compile config.guess config.rpath
 234         config.sub depcomp elisp-comp install-sh libversion.in mdate-sh
 235         missing mkinstalldirs py-compile texinfo.tex ylwrap),
 236      @libtool_files, @libtool_sometimes);
 237
 238 # Commonly used files we auto-include, but only sometimes.  This list
 239 # is used for the --help output only.
 240 my @common_sometimes =
 241   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 242      configure.ac configure.in stamp-vti);
 243
 244 # Standard directories from the GNU Coding Standards, and additional
 245 # pkg* directories from Automake.  Stored in a hash for fast member check.
 246 my %standard_prefix =
 247     map { $_ => 1 } (qw(bin data dataroot doc dvi exec html include info
 248                         lib libexec lisp locale localstate man man1 man2
 249                         man3 man4 man5 man6 man7 man8 man9 oldinclude pdf
 250                         pkgdata pkginclude pkglib pkglibexec ps sbin
 251                         sharedstate sysconf));
 252
 253 # Copyright on generated Makefile.ins.
 254 my $gen_copyright = "\
 255 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
 256 # 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software
 257 # Foundation, Inc.
 258 # This Makefile.in is free software; the Free Software Foundation
 259 # gives unlimited permission to copy and/or distribute it,
 260 # with or without modifications, as long as this notice is preserved.
 261
 262 # This program is distributed in the hope that it will be useful,
 263 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 264 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 265 # PARTICULAR PURPOSE.
 266 ";
 267
 268 # These constants are returned by the lang_*_rewrite functions.
 269 # LANG_SUBDIR means that the resulting object file should be in a
 270 # subdir if the source file is.  In this case the file name cannot
 271 # have '..' components.
 272 use constant LANG_IGNORE  => 0;
 273 use constant LANG_PROCESS => 1;
 274 use constant LANG_SUBDIR  => 2;
 275
 276 # These are used when keeping track of whether an object can be built
 277 # by two different paths.
 278 use constant COMPILE_LIBTOOL  => 1;
 279 use constant COMPILE_ORDINARY => 2;
 280
 281 # We can't always associate a location to a variable or a rule,
 282 # when it's defined by Automake.  We use INTERNAL in this case.
 283 use constant INTERNAL => new Automake::Location;
 284
 285 # Serialization keys for message queues.
 286 use constant QUEUE_MESSAGE   => "msg";
 287 use constant QUEUE_CONF_FILE => "conf file";
 288 use constant QUEUE_LOCATION  => "location";
 289 use constant QUEUE_STRING    => "string";
 290
 291 ## ---------------------------------- ##
 292 ## Variables related to the options.  ##
 293 ## ---------------------------------- ##
 294
 295 # TRUE if we should always generate Makefile.in.
 296 my $force_generation = 1;
 297
 298 # From the Perl manual.
 299 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 300
 301 # TRUE if missing standard files should be installed.
 302 my $add_missing = 0;
 303
 304 # TRUE if we should copy missing files; otherwise symlink if possible.
 305 my $copy_missing = 0;
 306
 307 # TRUE if we should always update files that we know about.
 308 my $force_missing = 0;
 309
 310
 311 ## ---------------------------------------- ##
 312 ## Variables filled during files scanning.  ##
 313 ## ---------------------------------------- ##
 314
 315 # Name of the configure.ac file.
 316 my $configure_ac;
 317
 318 # Files found by scanning configure.ac for LIBOBJS.
 319 my %libsources = ();
 320
 321 # Names used in AC_CONFIG_HEADER call.
 322 my @config_headers = ();
 323
 324 # Names used in AC_CONFIG_LINKS call.
 325 my @config_links = ();
 326
 327 # List of Makefile.am's to process, and their corresponding outputs.
 328 my @input_files = ();
 329 my %output_files = ();
 330
 331 # Complete list of Makefile.am's that exist.
 332 my @configure_input_files = ();
 333
 334 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 335 # and their outputs.
 336 my @other_input_files = ();
 337 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 338 # The keys are the files created by these macros.
 339 my %ac_config_files_location = ();
 340 # The condition under which AC_CONFIG_FOOS appears.
 341 my %ac_config_files_condition = ();
 342
 343 # Directory to search for configure-required files.  This
 344 # will be computed by &locate_aux_dir and can be set using
 345 # AC_CONFIG_AUX_DIR in configure.ac.
 346 # $CONFIG_AUX_DIR is the 'raw' directory, valid only in the source-tree.
 347 my $config_aux_dir = '';
 348 my $config_aux_dir_set_in_configure_ac = 0;
 349 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 350 # in Makefiles.
 351 my $am_config_aux_dir = '';
 352
 353 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 354 # in configure.ac.
 355 my $config_libobj_dir = '';
 356
 357 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 358 my $seen_gettext = 0;
 359 # Whether AM_GNU_GETTEXT([external]) is used.
 360 my $seen_gettext_external = 0;
 361 # Where AM_GNU_GETTEXT appears.
 362 my $ac_gettext_location;
 363 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 364 my $seen_gettext_intl = 0;
 365
 366 # Lists of tags supported by Libtool.
 367 my %libtool_tags = ();
 368 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 369 # uses AC_REQUIRE_AUX_FILE.
 370 my $libtool_new_api = 0;
 371
 372 # Most important AC_CANONICAL_* macro seen so far.
 373 my $seen_canonical = 0;
 374 # Location of that macro.
 375 my $canonical_location;
 376
 377 # Where AM_MAINTAINER_MODE appears.
 378 my $seen_maint_mode;
 379
 380 # Actual version we've seen.
 381 my $package_version = '';
 382
 383 # Where version is defined.
 384 my $package_version_location;
 385
 386 # TRUE if we've seen AM_PROG_AR
 387 my $seen_ar = 0;
 388
 389 # TRUE if we've seen AM_PROG_CC_C_O
 390 my $seen_cc_c_o = 0;
 391
 392 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 393 my %required_aux_file = ();
 394
 395 # Where AM_INIT_AUTOMAKE is called;
 396 my $seen_init_automake = 0;
 397
 398 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 399 my $seen_automake_version = 0;
 400
 401 # Hash table of discovered configure substitutions.  Keys are names,
 402 # values are 'FILE:LINE' strings which are used by error message
 403 # generation.
 404 my %configure_vars = ();
 405
 406 # Ignored configure substitutions (i.e., variables not to be output in
 407 # Makefile.in)
 408 my %ignored_configure_vars = ();
 409
 410 # Files included by $configure_ac.
 411 my @configure_deps = ();
 412
 413 # Greatest timestamp of configure's dependencies.
 414 my $configure_deps_greatest_timestamp = 0;
 415
 416 # Hash table of AM_CONDITIONAL variables seen in configure.
 417 my %configure_cond = ();
 418
 419 # This maps extensions onto language names.
 420 my %extension_map = ();
 421
 422 # List of the DIST_COMMON files we discovered while reading
 423 # configure.ac.
 424 my $configure_dist_common = '';
 425
 426 # This maps languages names onto objects.
 427 my %languages = ();
 428 # Maps each linker variable onto a language object.
 429 my %link_languages = ();
 430
 431 # maps extensions to needed source flags.
 432 my %sourceflags = ();
 433
 434 # List of targets we must always output.
 435 # FIXME: Complete, and remove falsely required targets.
 436 my %required_targets =
 437   (
 438    'all'          => 1,
 439    'dvi'          => 1,
 440    'pdf'          => 1,
 441    'ps'           => 1,
 442    'info'         => 1,
 443    'install-info' => 1,
 444    'install'      => 1,
 445    'install-data' => 1,
 446    'install-exec' => 1,
 447    'uninstall'    => 1,
 448
 449    # FIXME: Not required, temporary hacks.
 450    # Well, actually they are sort of required: the -recursive
 451    # targets will run them anyway...
 452    'html-am'         => 1,
 453    'dvi-am'          => 1,
 454    'pdf-am'          => 1,
 455    'ps-am'           => 1,
 456    'info-am'         => 1,
 457    'install-data-am' => 1,
 458    'install-exec-am' => 1,
 459    'install-html-am' => 1,
 460    'install-dvi-am'  => 1,
 461    'install-pdf-am'  => 1,
 462    'install-ps-am'   => 1,
 463    'install-info-am' => 1,
 464    'installcheck-am' => 1,
 465    'uninstall-am' => 1,
 466
 467    'install-man' => 1,
 468   );
 469
 470 # Queue to push require_conf_file requirements to.
 471 my $required_conf_file_queue;
 472
 473 # The name of the Makefile currently being processed.
 474 my $am_file = 'BUG';
 475
 476 ################################################################
 477
 478 ## ------------------------------------------ ##
 479 ## Variables reset by &initialize_per_input.  ##
 480 ## ------------------------------------------ ##
 481
 482 # Basename and relative dir of the input file.
 483 my $am_file_name;
 484 my $am_relative_dir;
 485
 486 # Same but wrt Makefile.in.
 487 my $in_file_name;
 488 my $relative_dir;
 489
 490 # Relative path to the top directory.
 491 my $topsrcdir;
 492
 493 # Greatest timestamp of the output's dependencies (excluding
 494 # configure's dependencies).
 495 my $output_deps_greatest_timestamp;
 496
 497 # These variables are used when generating each Makefile.in.
 498 # They hold the Makefile.in until it is ready to be printed.
 499 my $output_vars;
 500 my $output_all;
 501 my $output_header;
 502 my $output_rules;
 503 my $output_trailer;
 504
 505 # This is the conditional stack, updated on if/else/endif, and
 506 # used to build Condition objects.
 507 my @cond_stack;
 508
 509 # This holds the set of included files.
 510 my @include_stack;
 511
 512 # List of dependencies for the obvious targets.
 513 my @all;
 514 my @check;
 515 my @check_tests;
 516
 517 # Keys in this hash table are files to delete.  The associated
 518 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 519 my %clean_files;
 520
 521 # Keys in this hash table are object files or other files in
 522 # subdirectories which need to be removed.  This only holds files
 523 # which are created by compilations.  The value in the hash indicates
 524 # when the file should be removed.
 525 my %compile_clean_files;
 526
 527 # Keys in this hash table are directories where we expect to build a
 528 # libtool object.  We use this information to decide what directories
 529 # to delete.
 530 my %libtool_clean_directories;
 531
 532 # Value of $(SOURCES), used by tags.am.
 533 my @sources;
 534 # Sources which go in the distribution.
 535 my @dist_sources;
 536
 537 # This hash maps object file names onto their corresponding source
 538 # file names.  This is used to ensure that each object is created
 539 # by a single source file.
 540 my %object_map;
 541
 542 # This hash maps object file names onto an integer value representing
 543 # whether this object has been built via ordinary compilation or
 544 # libtool compilation (the COMPILE_* constants).
 545 my %object_compilation_map;
 546
 547
 548 # This keeps track of the directories for which we've already
 549 # created dirstamp code.  Keys are directories, values are stamp files.
 550 # Several keys can share the same stamp files if they are equivalent
 551 # (as are './/foo' and 'foo').
 552 my %directory_map;
 553
 554 # All .P files.
 555 my %dep_files;
 556
 557 # This is a list of all targets to run during "make dist".
 558 my @dist_targets;
 559
 560 # Keep track of all programs declared in this Makefile, without
 561 # $(EXEEXT).  @substitutions@ are not listed.
 562 my %known_programs;
 563 my %known_libraries;
 564
 565 # This keeps track of which extensions we've seen (that we care
 566 # about).
 567 my %extension_seen;
 568
 569 # This is random scratch space for the language finish functions.
 570 # Don't randomly overwrite it; examine other uses of keys first.
 571 my %language_scratch;
 572
 573 # We keep track of which objects need special (per-executable)
 574 # handling on a per-language basis.
 575 my %lang_specific_files;
 576
 577 # This is set when 'handle_dist' has finished.  Once this happens,
 578 # we should no longer push on dist_common.
 579 my $handle_dist_run;
 580
 581 # Used to store a set of linkers needed to generate the sources currently
 582 # under consideration.
 583 my %linkers_used;
 584
 585 # True if we need 'LINK' defined.  This is a hack.
 586 my $need_link;
 587
 588 # Does the generated Makefile have to build some compiled object
 589 # (for binary programs, or plain or libtool libraries)?
 590 my $must_handle_compiled_objects;
 591
 592 # Record each file processed by make_paragraphs.
 593 my %transformed_files;
 594
 595 ################################################################
 596
 597 ## ---------------------------------------------- ##
 598 ## Variables not reset by &initialize_per_input.  ##
 599 ## ---------------------------------------------- ##
 600
 601 # Cache each file processed by make_paragraphs.
 602 # (This is different from %transformed_files because
 603 # %transformed_files is reset for each file while %am_file_cache
 604 # it global to the run.)
 605 my %am_file_cache;
 606
 607 ################################################################
 608
 609 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 610 # ------------------------------------
 611 # This is called by Automake::Variable::define() when SUFFIXES
 612 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 613 # The work here needs to be performed as a side-effect of the
 614 # macro_define() call because SUFFIXES definitions impact
 615 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 616 # the input am file.
 617 sub var_SUFFIXES_trigger ($$)
 618 {
 619     my ($type, $value) = @_;
 620     accept_extensions (split (' ', $value));
 621 }
 622 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 623
 624 ################################################################
 625
 626 ## --------------------------------- ##
 627 ## Forward subroutine declarations.  ##
 628 ## --------------------------------- ##
 629 sub register_language (%);
 630 sub file_contents_internal ($$$%);
 631 sub define_files_variable ($\@$$);
 632
 633
 634 # &initialize_per_input ()
 635 # ------------------------
 636 # (Re)-Initialize per-Makefile.am variables.
 637 sub initialize_per_input ()
 638 {
 639     reset_local_duplicates ();
 640
 641     $am_file_name = undef;
 642     $am_relative_dir = undef;
 643
 644     $in_file_name = undef;
 645     $relative_dir = undef;
 646     $topsrcdir = undef;
 647
 648     $output_deps_greatest_timestamp = 0;
 649
 650     $output_vars = '';
 651     $output_all = '';
 652     $output_header = '';
 653     $output_rules = '';
 654     $output_trailer = '';
 655
 656     Automake::Options::reset;
 657     Automake::Variable::reset;
 658     Automake::Rule::reset;
 659
 660     @cond_stack = ();
 661
 662     @include_stack = ();
 663
 664     @all = ();
 665     @check = ();
 666     @check_tests = ();
 667
 668     %clean_files = ();
 669     %compile_clean_files = ();
 670
 671     # We always include '.'.  This isn't strictly correct.
 672     %libtool_clean_directories = ('.' => 1);
 673
 674     @sources = ();
 675     @dist_sources = ();
 676
 677     %object_map = ();
 678     %object_compilation_map = ();
 679
 680     %directory_map = ();
 681
 682     %dep_files = ();
 683
 684     @dist_targets = ();
 685
 686     %known_programs = ();
 687     %known_libraries= ();
 688
 689     %extension_seen = ();
 690
 691     %language_scratch = ();
 692
 693     %lang_specific_files = ();
 694
 695     $handle_dist_run = 0;
 696
 697     $need_link = 0;
 698
 699     $must_handle_compiled_objects = 0;
 700
 701     %transformed_files = ();
 702 }
 703
 704
 705 ################################################################
 706
 707 # Initialize our list of languages that are internally supported.
 708
 709 # C.
 710 register_language ('name' => 'c',
 711                    'Name' => 'C',
 712                    'config_vars' => ['CC'],
 713                    'autodep' => '',
 714                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 715                    'ccer' => 'CC',
 716                    'compiler' => 'COMPILE',
 717                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 718                    'lder' => 'CCLD',
 719                    'ld' => '$(CC)',
 720                    'linker' => 'LINK',
 721                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 722                    'compile_flag' => '-c',
 723                    'libtool_tag' => 'CC',
 724                    'extensions' => ['.c']);
 725
 726 # C++.
 727 register_language ('name' => 'cxx',
 728                    'Name' => 'C++',
 729                    'config_vars' => ['CXX'],
 730                    'linker' => 'CXXLINK',
 731                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 732                    'autodep' => 'CXX',
 733                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 734                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 735                    'ccer' => 'CXX',
 736                    'compiler' => 'CXXCOMPILE',
 737                    'compile_flag' => '-c',
 738                    'output_flag' => '-o',
 739                    'libtool_tag' => 'CXX',
 740                    'lder' => 'CXXLD',
 741                    'ld' => '$(CXX)',
 742                    'pure' => 1,
 743                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 744
 745 # Objective C.
 746 register_language ('name' => 'objc',
 747                    'Name' => 'Objective C',
 748                    'config_vars' => ['OBJC'],
 749                    'linker' => 'OBJCLINK',
 750                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 751                    'autodep' => 'OBJC',
 752                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 753                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 754                    'ccer' => 'OBJC',
 755                    'compiler' => 'OBJCCOMPILE',
 756                    'compile_flag' => '-c',
 757                    'output_flag' => '-o',
 758                    'lder' => 'OBJCLD',
 759                    'ld' => '$(OBJC)',
 760                    'pure' => 1,
 761                    'extensions' => ['.m']);
 762
 763 # Unified Parallel C.
 764 register_language ('name' => 'upc',
 765                    'Name' => 'Unified Parallel C',
 766                    'config_vars' => ['UPC'],
 767                    'linker' => 'UPCLINK',
 768                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 769                    'autodep' => 'UPC',
 770                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 771                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 772                    'ccer' => 'UPC',
 773                    'compiler' => 'UPCCOMPILE',
 774                    'compile_flag' => '-c',
 775                    'output_flag' => '-o',
 776                    'lder' => 'UPCLD',
 777                    'ld' => '$(UPC)',
 778                    'pure' => 1,
 779                    'extensions' => ['.upc']);
 780
 781 # Headers.
 782 register_language ('name' => 'header',
 783                    'Name' => 'Header',
 784                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 785                                     '.hpp', '.inc'],
 786                    # No output.
 787                    'output_extensions' => sub { return () },
 788                    # Nothing to do.
 789                    '_finish' => sub { });
 790
 791 # Vala
 792 register_language ('name' => 'vala',
 793                    'Name' => 'Vala',
 794                    'config_vars' => ['VALAC'],
 795                    'flags' => [],
 796                    'compile' => '$(VALAC) $(AM_VALAFLAGS) $(VALAFLAGS)',
 797                    'ccer' => 'VALAC',
 798                    'compiler' => 'VALACOMPILE',
 799                    'extensions' => ['.vala'],
 800                    'output_extensions' => sub { (my $ext = $_[0]) =~ s/vala$/c/;
 801                                                 return ($ext,) },
 802                    'rule_file' => 'vala',
 803                    '_finish' => \&lang_vala_finish,
 804                    '_target_hook' => \&lang_vala_target_hook,
 805                    'nodist_specific' => 1);
 806
 807 # Yacc (C & C++).
 808 register_language ('name' => 'yacc',
 809                    'Name' => 'Yacc',
 810                    'config_vars' => ['YACC'],
 811                    'flags' => ['YFLAGS'],
 812                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 813                    'ccer' => 'YACC',
 814                    'compiler' => 'YACCCOMPILE',
 815                    'extensions' => ['.y'],
 816                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 817                                                 return ($ext,) },
 818                    'rule_file' => 'yacc',
 819                    '_finish' => \&lang_yacc_finish,
 820                    '_target_hook' => \&lang_yacc_target_hook,
 821                    'nodist_specific' => 1);
 822 register_language ('name' => 'yaccxx',
 823                    'Name' => 'Yacc (C++)',
 824                    'config_vars' => ['YACC'],
 825                    'rule_file' => 'yacc',
 826                    'flags' => ['YFLAGS'],
 827                    'ccer' => 'YACC',
 828                    'compiler' => 'YACCCOMPILE',
 829                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 830                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 831                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 832                                                 return ($ext,) },
 833                    '_finish' => \&lang_yacc_finish,
 834                    '_target_hook' => \&lang_yacc_target_hook,
 835                    'nodist_specific' => 1);
 836
 837 # Lex (C & C++).
 838 register_language ('name' => 'lex',
 839                    'Name' => 'Lex',
 840                    'config_vars' => ['LEX'],
 841                    'rule_file' => 'lex',
 842                    'flags' => ['LFLAGS'],
 843                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 844                    'ccer' => 'LEX',
 845                    'compiler' => 'LEXCOMPILE',
 846                    'extensions' => ['.l'],
 847                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 848                                                 return ($ext,) },
 849                    '_finish' => \&lang_lex_finish,
 850                    '_target_hook' => \&lang_lex_target_hook,
 851                    'nodist_specific' => 1);
 852 register_language ('name' => 'lexxx',
 853                    'Name' => 'Lex (C++)',
 854                    'config_vars' => ['LEX'],
 855                    'rule_file' => 'lex',
 856                    'flags' => ['LFLAGS'],
 857                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 858                    'ccer' => 'LEX',
 859                    'compiler' => 'LEXCOMPILE',
 860                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 861                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 862                                                 return ($ext,) },
 863                    '_finish' => \&lang_lex_finish,
 864                    '_target_hook' => \&lang_lex_target_hook,
 865                    'nodist_specific' => 1);
 866
 867 # Assembler.
 868 register_language ('name' => 'asm',
 869                    'Name' => 'Assembler',
 870                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 871
 872                    'flags' => ['CCASFLAGS'],
 873                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 874                    # or anything else required.  They can also set CCAS.
 875                    # Or simply use Preprocessed Assembler.
 876                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 877                    'ccer' => 'CCAS',
 878                    'compiler' => 'CCASCOMPILE',
 879                    'compile_flag' => '-c',
 880                    'output_flag' => '-o',
 881                    'extensions' => ['.s']);
 882
 883 # Preprocessed Assembler.
 884 register_language ('name' => 'cppasm',
 885                    'Name' => 'Preprocessed Assembler',
 886                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 887
 888                    'autodep' => 'CCAS',
 889                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 890                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 891                    'ccer' => 'CPPAS',
 892                    'compiler' => 'CPPASCOMPILE',
 893                    'compile_flag' => '-c',
 894                    'output_flag' => '-o',
 895                    'extensions' => ['.S', '.sx']);
 896
 897 # Fortran 77
 898 register_language ('name' => 'f77',
 899                    'Name' => 'Fortran 77',
 900                    'config_vars' => ['F77'],
 901                    'linker' => 'F77LINK',
 902                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 903                    'flags' => ['FFLAGS'],
 904                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 905                    'ccer' => 'F77',
 906                    'compiler' => 'F77COMPILE',
 907                    'compile_flag' => '-c',
 908                    'output_flag' => '-o',
 909                    'libtool_tag' => 'F77',
 910                    'lder' => 'F77LD',
 911                    'ld' => '$(F77)',
 912                    'pure' => 1,
 913                    'extensions' => ['.f', '.for']);
 914
 915 # Fortran
 916 register_language ('name' => 'fc',
 917                    'Name' => 'Fortran',
 918                    'config_vars' => ['FC'],
 919                    'linker' => 'FCLINK',
 920                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 921                    'flags' => ['FCFLAGS'],
 922                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 923                    'ccer' => 'FC',
 924                    'compiler' => 'FCCOMPILE',
 925                    'compile_flag' => '-c',
 926                    'output_flag' => '-o',
 927                    'libtool_tag' => 'FC',
 928                    'lder' => 'FCLD',
 929                    'ld' => '$(FC)',
 930                    'pure' => 1,
 931                    'extensions' => ['.f90', '.f95', '.f03', '.f08']);
 932
 933 # Preprocessed Fortran
 934 register_language ('name' => 'ppfc',
 935                    'Name' => 'Preprocessed Fortran',
 936                    'config_vars' => ['FC'],
 937                    'linker' => 'FCLINK',
 938                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 939                    'lder' => 'FCLD',
 940                    'ld' => '$(FC)',
 941                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 942                    'ccer' => 'PPFC',
 943                    'compiler' => 'PPFCCOMPILE',
 944                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 945                    'compile_flag' => '-c',
 946                    'output_flag' => '-o',
 947                    'libtool_tag' => 'FC',
 948                    'pure' => 1,
 949                    'extensions' => ['.F90','.F95', '.F03', '.F08']);
 950
 951 # Preprocessed Fortran 77
 952 #
 953 # The current support for preprocessing Fortran 77 just involves
 954 # passing "$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 955 # $(CPPFLAGS)" as additional flags to the Fortran 77 compiler, since
 956 # this is how GNU Make does it; see the "GNU Make Manual, Edition 0.51
 957 # for `make' Version 3.76 Beta" (specifically, from info file
 958 # for `make' Version 3.76 Beta" (specifically, from info file
 959 # '(make)Catalogue of Rules').
 960 #
 961 # A better approach would be to write an Autoconf test
 962 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 963 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 964 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 965 # preprocessing capabilities, and then fall back on cpp (if cpp were
 966 # available).
 967 register_language ('name' => 'ppf77',
 968                    'Name' => 'Preprocessed Fortran 77',
 969                    'config_vars' => ['F77'],
 970                    'linker' => 'F77LINK',
 971                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 972                    'lder' => 'F77LD',
 973                    'ld' => '$(F77)',
 974                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 975                    'ccer' => 'PPF77',
 976                    'compiler' => 'PPF77COMPILE',
 977                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 978                    'compile_flag' => '-c',
 979                    'output_flag' => '-o',
 980                    'libtool_tag' => 'F77',
 981                    'pure' => 1,
 982                    'extensions' => ['.F']);
 983
 984 # Ratfor.
 985 register_language ('name' => 'ratfor',
 986                    'Name' => 'Ratfor',
 987                    'config_vars' => ['F77'],
 988                    'linker' => 'F77LINK',
 989                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 990                    'lder' => 'F77LD',
 991                    'ld' => '$(F77)',
 992                    'flags' => ['RFLAGS', 'FFLAGS'],
 993                    # FIXME also FFLAGS.
 994                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
 995                    'ccer' => 'F77',
 996                    'compiler' => 'RCOMPILE',
 997                    'compile_flag' => '-c',
 998                    'output_flag' => '-o',
 999                    'libtool_tag' => 'F77',
1000                    'pure' => 1,
1001                    'extensions' => ['.r']);
1002
1003 # Java via gcj.
1004 register_language ('name' => 'java',
1005                    'Name' => 'Java',
1006                    'config_vars' => ['GCJ'],
1007                    'linker' => 'GCJLINK',
1008                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1009                    'autodep' => 'GCJ',
1010                    'flags' => ['GCJFLAGS'],
1011                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
1012                    'ccer' => 'GCJ',
1013                    'compiler' => 'GCJCOMPILE',
1014                    'compile_flag' => '-c',
1015                    'output_flag' => '-o',
1016                    'libtool_tag' => 'GCJ',
1017                    'lder' => 'GCJLD',
1018                    'ld' => '$(GCJ)',
1019                    'pure' => 1,
1020                    'extensions' => ['.java', '.class', '.zip', '.jar']);
1021
1022 ################################################################
1023
1024 # Error reporting functions.
1025
1026 # err_am ($MESSAGE, [%OPTIONS])
1027 # -----------------------------
1028 # Uncategorized errors about the current Makefile.am.
1029 sub err_am ($;%)
1030 {
1031   msg_am ('error', @_);
1032 }
1033
1034 # err_ac ($MESSAGE, [%OPTIONS])
1035 # -----------------------------
1036 # Uncategorized errors about configure.ac.
1037 sub err_ac ($;%)
1038 {
1039   msg_ac ('error', @_);
1040 }
1041
1042 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1043 # ---------------------------------------
1044 # Messages about about the current Makefile.am.
1045 sub msg_am ($$;%)
1046 {
1047   my ($channel, $msg, %opts) = @_;
1048   msg $channel, "${am_file}.am", $msg, %opts;
1049 }
1050
1051 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1052 # ---------------------------------------
1053 # Messages about about configure.ac.
1054 sub msg_ac ($$;%)
1055 {
1056   my ($channel, $msg, %opts) = @_;
1057   msg $channel, $configure_ac, $msg, %opts;
1058 }
1059
1060 ################################################################
1061
1062 # subst ($TEXT)
1063 # -------------
1064 # Return a configure-style substitution using the indicated text.
1065 # We do this to avoid having the substitutions directly in automake.in;
1066 # when we do that they are sometimes removed and this causes confusion
1067 # and bugs.
1068 sub subst ($)
1069 {
1070     my ($text) = @_;
1071     return '@' . $text . '@';
1072 }
1073
1074 ################################################################
1075
1076
1077 # $BACKPATH
1078 # &backname ($RELDIR)
1079 # --------------------
1080 # If I "cd $RELDIR", then to come back, I should "cd $BACKPATH".
1081 # For instance 'src/foo' => '../..'.
1082 # Works with non strictly increasing paths, i.e., 'src/../lib' => '..'.
1083 sub backname ($)
1084 {
1085     my ($file) = @_;
1086     my @res;
1087     foreach (split (/\//, $file))
1088     {
1089         next if $_ eq '.' || $_ eq '';
1090         if ($_ eq '..')
1091         {
1092             pop @res
1093               or prog_error ("trying to reverse path '$file' pointing outside tree");
1094         }
1095         else
1096         {
1097             push (@res, '..');
1098         }
1099     }
1100     return join ('/', @res) || '.';
1101 }
1102
1103 ################################################################
1104
1105 # 'silent-rules' mode handling functions.
1106
1107 # verbose_var (NAME)
1108 # ------------------
1109 # The public variable stem used to implement 'silent-rules'.
1110 sub verbose_var ($)
1111 {
1112     my ($name) = @_;
1113     return 'AM_V_' . $name;
1114 }
1115
1116 # verbose_private_var (NAME)
1117 # --------------------------
1118 # The naming policy for the private variables for 'silent-rules'.
1119 sub verbose_private_var ($)
1120 {
1121     my ($name) = @_;
1122     return 'am__v_' . $name;
1123 }
1124
1125 # define_verbose_var (NAME, VAL)
1126 # ------------------------------
1127 # For 'silent-rules' mode, setup VAR and dispatcher, to expand to VAL if silent.
1128 sub define_verbose_var ($$)
1129 {
1130     my ($name, $val) = @_;
1131     my $var = verbose_var ($name);
1132     my $pvar = verbose_private_var ($name);
1133     my $silent_var = $pvar . '_0';
1134     if (option 'silent-rules')
1135       {
1136         # For typical 'make's, 'configure' replaces AM_V (inside @@) with $(V)
1137         # and AM_DEFAULT_V (inside @@) with $(AM_DEFAULT_VERBOSITY).
1138         # For strict POSIX 2008 'make's, it replaces them with 0 or 1 instead.
1139         # See AM_SILENT_RULES in m4/silent.m4.
1140         define_variable ($var, '$(' . $pvar . '_@'.'AM_V'.'@)', INTERNAL);
1141         define_variable ($pvar . '_', '$(' . $pvar . '_@'.'AM_DEFAULT_V'.'@)', INTERNAL);
1142         Automake::Variable::define ($silent_var, VAR_AUTOMAKE, '', TRUE, $val,
1143                                     '', INTERNAL, VAR_ASIS)
1144           if (! vardef ($silent_var, TRUE));
1145       }
1146 }
1147
1148 # Above should not be needed in the general automake code.
1149
1150 # verbose_flag (NAME)
1151 # -------------------
1152 # Contents of %VERBOSE%: variable to expand before rule command.
1153 sub verbose_flag ($)
1154 {
1155     my ($name) = @_;
1156     return '$(' . verbose_var ($name) . ')'
1157       if (option 'silent-rules');
1158     return '';
1159 }
1160
1161 sub verbose_nodep_flag ($)
1162 {
1163     my ($name) = @_;
1164     return '$(' . verbose_var ($name) . subst ('am__nodep') . ')'
1165       if (option 'silent-rules');
1166     return '';
1167 }
1168
1169 # silent_flag
1170 # -----------
1171 # Contents of %SILENT%: variable to expand to '@' when silent.
1172 sub silent_flag ()
1173 {
1174     return verbose_flag ('at');
1175 }
1176
1177 # define_verbose_tagvar (NAME)
1178 # ----------------------------
1179 # Engage the needed 'silent-rules' machinery for tag NAME.
1180 sub define_verbose_tagvar ($)
1181 {
1182     my ($name) = @_;
1183     if (option 'silent-rules')
1184       {
1185         define_verbose_var ($name, '@echo "  '. $name . ' ' x (8 - length ($name)) . '" $@;');
1186         define_verbose_var ('at', '@');
1187       }
1188 }
1189
1190 # define_verbose_texinfo
1191 # ----------------------
1192 # Engage the needed 'silent-rules' machinery for assorted texinfo commands.
1193 sub define_verbose_texinfo ()
1194 {
1195   my @tagvars = ('DVIPS', 'MAKEINFO', 'INFOHTML', 'TEXI2DVI', 'TEXI2PDF');
1196   foreach my $tag (@tagvars)
1197     {
1198       define_verbose_tagvar($tag);
1199     }
1200   define_verbose_var('texinfo', '-q');
1201   define_verbose_var('texidevnull', '> /dev/null');
1202 }
1203
1204 # define_verbose_libtool
1205 # ----------------------
1206 # Engage the needed 'silent-rules' machinery for 'libtool --silent'.
1207 sub define_verbose_libtool ()
1208 {
1209     define_verbose_var ('lt', '--silent');
1210     return verbose_flag ('lt');
1211 }
1212
1213
1214 ################################################################
1215
1216
1217 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1218 sub handle_options
1219 {
1220   my $var = var ('AUTOMAKE_OPTIONS');
1221   if ($var)
1222     {
1223       if ($var->has_conditional_contents)
1224         {
1225           msg_var ('unsupported', $var,
1226                    "'AUTOMAKE_OPTIONS' cannot have conditional contents");
1227         }
1228       my @options = map { { option => $_->[1], where => $_->[0] } }
1229                         $var->value_as_list_recursive (cond_filter => TRUE,
1230                                                        location => 1);
1231       return 1 if process_option_list (@options);
1232     }
1233
1234   # Override portability-recursive warning.
1235   switch_warning ('no-portability-recursive')
1236     if option 'silent-rules';
1237
1238   if ($strictness == GNITS)
1239     {
1240       set_option ('readme-alpha', INTERNAL);
1241       set_option ('std-options', INTERNAL);
1242       set_option ('check-news', INTERNAL);
1243     }
1244
1245   return 0;
1246 }
1247
1248 # shadow_unconditionally ($varname, $where)
1249 # -----------------------------------------
1250 # Return a $(variable) that contains all possible values
1251 # $varname can take.
1252 # If the VAR wasn't defined conditionally, return $(VAR).
1253 # Otherwise we create an am__VAR_DIST variable which contains
1254 # all possible values, and return $(am__VAR_DIST).
1255 sub shadow_unconditionally ($$)
1256 {
1257   my ($varname, $where) = @_;
1258   my $var = var $varname;
1259   if ($var->has_conditional_contents)
1260     {
1261       $varname = "am__${varname}_DIST";
1262       my @files = uniq ($var->value_as_list_recursive);
1263       define_pretty_variable ($varname, TRUE, $where, @files);
1264     }
1265   return "\$($varname)"
1266 }
1267
1268 # check_user_variables (@LIST)
1269 # ----------------------------
1270 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1271 # otherwise.
1272 sub check_user_variables (@)
1273 {
1274   my @dont_override = @_;
1275   foreach my $flag (@dont_override)
1276     {
1277       my $var = var $flag;
1278       if ($var)
1279         {
1280           for my $cond ($var->conditions->conds)
1281             {
1282               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1283                 {
1284                   msg_cond_var ('gnu', $cond, $flag,
1285                                 "'$flag' is a user variable, "
1286                                 . "you should not override it;\n"
1287                                 . "use 'AM_$flag' instead");
1288                 }
1289             }
1290         }
1291     }
1292 }
1293
1294 # Call finish function for each language that was used.
1295 sub handle_languages
1296 {
1297     if (! option 'no-dependencies')
1298     {
1299         # Include auto-dep code.  Don't include it if DEP_FILES would
1300         # be empty.
1301         if (&saw_sources_p (0) && keys %dep_files)
1302         {
1303             # Set location of depcomp.
1304             &define_variable ('depcomp',
1305                               "\$(SHELL) $am_config_aux_dir/depcomp",
1306                               INTERNAL);
1307             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1308
1309             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1310
1311             my @deplist = sort keys %dep_files;
1312             # Generate each 'include' individually.  Irix 6 make will
1313             # not properly include several files resulting from a
1314             # variable expansion; generating many separate includes
1315             # seems safest.
1316             $output_rules .= "\n";
1317             foreach my $iter (@deplist)
1318             {
1319                 $output_rules .= (subst ('AMDEP_TRUE')
1320                                   . subst ('am__include')
1321                                   . ' '
1322                                   . subst ('am__quote')
1323                                   . $iter
1324                                   . subst ('am__quote')
1325                                   . "\n");
1326             }
1327
1328             # Compute the set of directories to remove in distclean-depend.
1329             my @depdirs = uniq (map { dirname ($_) } @deplist);
1330             $output_rules .= &file_contents ('depend',
1331                                              new Automake::Location,
1332                                              DEPDIRS => "@depdirs");
1333         }
1334     }
1335     else
1336     {
1337         &define_variable ('depcomp', '', INTERNAL);
1338         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1339     }
1340
1341     my %done;
1342
1343     # Is the C linker needed?
1344     my $needs_c = 0;
1345     foreach my $ext (sort keys %extension_seen)
1346     {
1347         next unless $extension_map{$ext};
1348
1349         my $lang = $languages{$extension_map{$ext}};
1350
1351         my $rule_file = $lang->rule_file || 'depend2';
1352
1353         # Get information on $LANG.
1354         my $pfx = $lang->autodep;
1355         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1356
1357         my ($AMDEP, $FASTDEP) =
1358           (option 'no-dependencies' || $lang->autodep eq 'no')
1359           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1360
1361         my $verbose = verbose_flag ($lang->ccer || 'GEN');
1362         my $verbose_nodep = ($AMDEP eq 'FALSE')
1363           ? $verbose : verbose_nodep_flag ($lang->ccer || 'GEN');
1364         my $silent = silent_flag ();
1365
1366         my %transform = ('EXT'     => $ext,
1367                          'PFX'     => $pfx,
1368                          'FPFX'    => $fpfx,
1369                          'AMDEP'   => $AMDEP,
1370                          'FASTDEP' => $FASTDEP,
1371                          '-c'      => $lang->compile_flag || '',
1372                          # These are not used, but they need to be defined
1373                          # so &transform do not complain.
1374                          SUBDIROBJ     => 0,
1375                          'DERIVED-EXT' => 'BUG',
1376                          DIST_SOURCE   => 1,
1377                          VERBOSE   => $verbose,
1378                          'VERBOSE-NODEP' => $verbose_nodep,
1379                          SILENT    => $silent,
1380                         );
1381
1382         # Generate the appropriate rules for this extension.
1383         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1384             || defined $lang->compile)
1385         {
1386             # Some C compilers don't support -c -o.  Use it only if really
1387             # needed.
1388             my $output_flag = $lang->output_flag || '';
1389             $output_flag = '-o'
1390               if (! $output_flag
1391                   && $lang->name eq 'c'
1392                   && option 'subdir-objects');
1393
1394             # Compute a possible derived extension.
1395             # This is not used by depend2.am.
1396             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1397
1398             # When we output an inference rule like '.c.o:' we
1399             # have two cases to consider: either subdir-objects
1400             # is used, or it is not.
1401             #
1402             # In the latter case the rule is used to build objects
1403             # in the current directory, and dependencies always
1404             # go into './$(DEPDIR)/'.  We can hard-code this value.
1405             #
1406             # In the former case the rule can be used to build
1407             # objects in sub-directories too.  Dependencies should
1408             # go into the appropriate sub-directories, e.g.,
1409             # 'sub/$(DEPDIR)/'.  The value of this directory
1410             # needs to be computed on-the-fly.
1411             #
1412             # DEPBASE holds the name of this directory, plus the
1413             # basename part of the object file (extensions Po, TPo,
1414             # Plo, TPlo will be added later as appropriate).  It is
1415             # either hardcoded, or a shell variable ('$depbase') that
1416             # will be computed by the rule.
1417             my $depbase =
1418               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1419             $output_rules .=
1420               file_contents ($rule_file,
1421                              new Automake::Location,
1422                              %transform,
1423                              GENERIC   => 1,
1424
1425                              'DERIVED-EXT' => $der_ext,
1426
1427                              DEPBASE   => $depbase,
1428                              BASE      => '$*',
1429                              SOURCE    => '$<',
1430                              SOURCEFLAG => $sourceflags{$ext} || '',
1431                              OBJ       => '$@',
1432                              OBJOBJ    => '$@',
1433                              LTOBJ     => '$@',
1434
1435                              COMPILE   => '$(' . $lang->compiler . ')',
1436                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1437                              -o        => $output_flag,
1438                              SUBDIROBJ => !! option 'subdir-objects');
1439         }
1440
1441         # Now include code for each specially handled object with this
1442         # language.
1443         my %seen_files = ();
1444         foreach my $file (@{$lang_specific_files{$lang->name}})
1445         {
1446             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1447
1448             # We might see a given object twice, for instance if it is
1449             # used under different conditions.
1450             next if defined $seen_files{$obj};
1451             $seen_files{$obj} = 1;
1452
1453             prog_error ("found " . $lang->name .
1454                         " in handle_languages, but compiler not defined")
1455               unless defined $lang->compile;
1456
1457             my $obj_compile = $lang->compile;
1458
1459             # Rewrite each occurrence of 'AM_$flag' in the compile
1460             # rule into '${derived}_$flag' if it exists.
1461             for my $flag (@{$lang->flags})
1462               {
1463                 my $val = "${derived}_$flag";
1464                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1465                   if set_seen ($val);
1466               }
1467
1468             my $libtool_tag = '';
1469             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1470               {
1471                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1472               }
1473
1474             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1475             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1476
1477             my $ltverbose = define_verbose_libtool ();
1478             my $obj_ltcompile =
1479               "\$(LIBTOOL) $ltverbose $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1480               . "--mode=compile $obj_compile";
1481
1482             # We _need_ '-o' for per object rules.
1483             my $output_flag = $lang->output_flag || '-o';
1484
1485             my $depbase = dirname ($obj);
1486             $depbase = ''
1487                 if $depbase eq '.';
1488             $depbase .= '/'
1489                 unless $depbase eq '';
1490             $depbase .= '$(DEPDIR)/' . basename ($obj);
1491
1492             $output_rules .=
1493               file_contents ($rule_file,
1494                              new Automake::Location,
1495                              %transform,
1496                              GENERIC   => 0,
1497
1498                              DEPBASE   => $depbase,
1499                              BASE      => $obj,
1500                              SOURCE    => $source,
1501                              SOURCEFLAG => $sourceflags{$srcext} || '',
1502                              # Use $myext and not '.o' here, in case
1503                              # we are actually building a new source
1504                              # file -- e.g. via yacc.
1505                              OBJ       => "$obj$myext",
1506                              OBJOBJ    => "$obj.obj",
1507                              LTOBJ     => "$obj.lo",
1508
1509                              VERBOSE   => $verbose,
1510                              'VERBOSE-NODEP'  => $verbose_nodep,
1511                              SILENT    => $silent,
1512                              COMPILE   => $obj_compile,
1513                              LTCOMPILE => $obj_ltcompile,
1514                              -o        => $output_flag,
1515                              %file_transform);
1516         }
1517
1518         # The rest of the loop is done once per language.
1519         next if defined $done{$lang};
1520         $done{$lang} = 1;
1521
1522         # Load the language dependent Makefile chunks.
1523         my %lang = map { uc ($_) => 0 } keys %languages;
1524         $lang{uc ($lang->name)} = 1;
1525         $output_rules .= file_contents ('lang-compile',
1526                                         new Automake::Location,
1527                                         %transform, %lang);
1528
1529         # If the source to a program consists entirely of code from a
1530         # 'pure' language, for instance C++ or Fortran 77, then we
1531         # don't need the C compiler code.  However if we run into
1532         # something unusual then we do generate the C code.  There are
1533         # probably corner cases here that do not work properly.
1534         # People linking Java code to Fortran code deserve pain.
1535         $needs_c ||= ! $lang->pure;
1536
1537         define_compiler_variable ($lang)
1538           if ($lang->compile);
1539
1540         define_linker_variable ($lang)
1541           if ($lang->link);
1542
1543         require_variables ("$am_file.am", $lang->Name . " source seen",
1544                            TRUE, @{$lang->config_vars});
1545
1546         # Call the finisher.
1547         $lang->finish;
1548
1549         # Flags listed in '->flags' are user variables (per GNU Standards),
1550         # they should not be overridden in the Makefile...
1551         my @dont_override = @{$lang->flags};
1552         # ... and so is LDFLAGS.
1553         push @dont_override, 'LDFLAGS' if $lang->link;
1554
1555         check_user_variables @dont_override;
1556     }
1557
1558     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1559     # suffix rule was learned), don't bother with the C stuff.  But if
1560     # anything else creeps in, then use it.
1561     $needs_c = 1
1562       if $need_link || suffix_rules_count > 1;
1563
1564     if ($needs_c)
1565       {
1566         &define_compiler_variable ($languages{'c'})
1567           unless defined $done{$languages{'c'}};
1568         define_linker_variable ($languages{'c'});
1569       }
1570
1571     # Always provide the user with 'AM_V_GEN' for 'silent-rules' mode.
1572     define_verbose_tagvar ('GEN');
1573 }
1574
1575
1576 # append_exeext { PREDICATE } $MACRO
1577 # ----------------------------------
1578 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1579 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1580 # ignored.
1581 #
1582 # This is typically used on all filenames of *_PROGRAMS, and filenames
1583 # of TESTS that are programs.
1584 sub append_exeext (&$)
1585 {
1586   my ($pred, $macro) = @_;
1587
1588   transform_variable_recursively
1589     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1590      sub {
1591        my ($subvar, $val, $cond, $full_cond) = @_;
1592        # Append $(EXEEXT) unless the user did it already, or it's a
1593        # @substitution@.
1594        $val .= '$(EXEEXT)'
1595          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1596        return $val;
1597      });
1598 }
1599
1600
1601 # Check to make sure a source defined in LIBOBJS is not explicitly
1602 # mentioned.  This is a separate function (as opposed to being inlined
1603 # in handle_source_transform) because it isn't always appropriate to
1604 # do this check.
1605 sub check_libobjs_sources
1606 {
1607   my ($one_file, $unxformed) = @_;
1608
1609   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1610                       'dist_EXTRA_', 'nodist_EXTRA_')
1611     {
1612       my @files;
1613       my $varname = $prefix . $one_file . '_SOURCES';
1614       my $var = var ($varname);
1615       if ($var)
1616         {
1617           @files = $var->value_as_list_recursive;
1618         }
1619       elsif ($prefix eq '')
1620         {
1621           @files = ($unxformed . '.c');
1622         }
1623       else
1624         {
1625           next;
1626         }
1627
1628       foreach my $file (@files)
1629         {
1630           err_var ($prefix . $one_file . '_SOURCES',
1631                    "automatically discovered file '$file' should not" .
1632                    " be explicitly mentioned")
1633             if defined $libsources{$file};
1634         }
1635     }
1636 }
1637
1638
1639 # @OBJECTS
1640 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1641 # -----------------------------------------------------------------------------
1642 # Does much of the actual work for handle_source_transform.
1643 # Arguments are:
1644 #   $VAR is the name of the variable that the source filenames come from
1645 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1646 #   $DERIVED is the name of resulting executable or library
1647 #   $OBJ is the object extension (e.g., '.lo')
1648 #   $FILE the source file to transform
1649 #   %TRANSFORM contains extras arguments to pass to file_contents
1650 #     when producing explicit rules
1651 # Result is a list of the names of objects
1652 # %linkers_used will be updated with any linkers needed
1653 sub handle_single_transform ($$$$$%)
1654 {
1655     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1656     my @files = ($_file);
1657     my @result = ();
1658
1659     # Turn sources into objects.  We use a while loop like this
1660     # because we might add to @files in the loop.
1661     while (scalar @files > 0)
1662     {
1663         $_ = shift @files;
1664
1665         # Configure substitutions in _SOURCES variables are errors.
1666         if (/^\@.*\@$/)
1667         {
1668           my $parent_msg = '';
1669           $parent_msg = "\nand is referred to from '$topparent'"
1670             if $topparent ne $var->name;
1671           err_var ($var,
1672                    "'" . $var->name . "' includes configure substitution '$_'"
1673                    . $parent_msg . ";\nconfigure " .
1674                    "substitutions are not allowed in _SOURCES variables");
1675           next;
1676         }
1677
1678         # If the source file is in a subdirectory then the '.o' is put
1679         # into the current directory, unless the subdir-objects option
1680         # is in effect.
1681
1682         # Split file name into base and extension.
1683         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1684         my $full = $_;
1685         my $directory = $1 || '';
1686         my $base = $2;
1687         my $extension = $3;
1688
1689         # We must generate a rule for the object if it requires its own flags.
1690         my $renamed = 0;
1691         my ($linker, $object);
1692
1693         # This records whether we've seen a derived source file (e.g.
1694         # yacc output).
1695         my $derived_source = 0;
1696
1697         # This holds the 'aggregate context' of the file we are
1698         # currently examining.  If the file is compiled with
1699         # per-object flags, then it will be the name of the object.
1700         # Otherwise it will be 'AM'.  This is used by the target hook
1701         # language function.
1702         my $aggregate = 'AM';
1703
1704         $extension = &derive_suffix ($extension, $obj);
1705         my $lang;
1706         if ($extension_map{$extension} &&
1707             ($lang = $languages{$extension_map{$extension}}))
1708         {
1709             # Found the language, so see what it says.
1710             &saw_extension ($extension);
1711
1712             # Do we have per-executable flags for this executable?
1713             my $have_per_exec_flags = 0;
1714             my @peflags = @{$lang->flags};
1715             push @peflags, 'LIBTOOLFLAGS' if $obj eq '.lo';
1716             foreach my $flag (@peflags)
1717               {
1718                 if (set_seen ("${derived}_$flag"))
1719                   {
1720                     $have_per_exec_flags = 1;
1721                     last;
1722                   }
1723               }
1724
1725             # Note: computed subr call.  The language rewrite function
1726             # should return one of the LANG_* constants.  It could
1727             # also return a list whose first value is such a constant
1728             # and whose second value is a new source extension which
1729             # should be applied.  This means this particular language
1730             # generates another source file which we must then process
1731             # further.
1732             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1733             my ($r, $source_extension)
1734                 = &$subr ($directory, $base, $extension,
1735                           $obj, $have_per_exec_flags, $var);
1736             # Skip this entry if we were asked not to process it.
1737             next if $r == LANG_IGNORE;
1738
1739             # Now extract linker and other info.
1740             $linker = $lang->linker;
1741
1742             my $this_obj_ext;
1743             if (defined $source_extension)
1744             {
1745                 $this_obj_ext = $source_extension;
1746                 $derived_source = 1;
1747             }
1748             else
1749             {
1750                 $this_obj_ext = $obj;
1751             }
1752             $object = $base . $this_obj_ext;
1753
1754             if ($have_per_exec_flags)
1755             {
1756                 # We have a per-executable flag in effect for this
1757                 # object.  In this case we rewrite the object's
1758                 # name to ensure it is unique.
1759
1760                 # We choose the name 'DERIVED_OBJECT' to ensure
1761                 # (1) uniqueness, and (2) continuity between
1762                 # invocations.  However, this will result in a
1763                 # name that is too long for losing systems, in
1764                 # some situations.  So we provide _SHORTNAME to
1765                 # override.
1766
1767                 my $dname = $derived;
1768                 my $var = var ($derived . '_SHORTNAME');
1769                 if ($var)
1770                 {
1771                     # FIXME: should use the same Condition as
1772                     # the _SOURCES variable.  But this is really
1773                     # silly overkill -- nobody should have
1774                     # conditional shortnames.
1775                     $dname = $var->variable_value;
1776                 }
1777                 $object = $dname . '-' . $object;
1778
1779                 prog_error ($lang->name . " flags defined without compiler")
1780                   if ! defined $lang->compile;
1781
1782                 $renamed = 1;
1783             }
1784
1785             # If rewrite said it was ok, put the object into a
1786             # subdir.
1787             if ($r == LANG_SUBDIR && $directory ne '')
1788             {
1789                 $object = $directory . '/' . $object;
1790             }
1791
1792             # If the object file has been renamed (because per-target
1793             # flags are used) we cannot compile the file with an
1794             # inference rule: we need an explicit rule.
1795             #
1796             # If the source is in a subdirectory and the object is in
1797             # the current directory, we also need an explicit rule.
1798             #
1799             # If both source and object files are in a subdirectory
1800             # (this happens when the subdir-objects option is used),
1801             # then the inference will work.
1802             #
1803             # The latter case deserves a historical note.  When the
1804             # subdir-objects option was added on 1999-04-11 it was
1805             # thought that inferences rules would work for
1806             # subdirectory objects too.  Later, on 1999-11-22,
1807             # automake was changed to output explicit rules even for
1808             # subdir-objects.  Nobody remembers why, but this occurred
1809             # soon after the merge of the user-dep-gen-branch so it
1810             # might be related.  In late 2003 people complained about
1811             # the size of the generated Makefile.ins (libgcj, with
1812             # 2200+ subdir objects was reported to have a 9MB
1813             # Makefile), so we now rely on inference rules again.
1814             # Maybe we'll run across the same issue as in the past,
1815             # but at least this time we can document it.  However since
1816             # dependency tracking has evolved it is possible that
1817             # our old problem no longer exists.
1818             # Using inference rules for subdir-objects has been tested
1819             # with GNU make, Solaris make, Ultrix make, BSD make,
1820             # HP-UX make, and OSF1 make successfully.
1821             if ($renamed
1822                 || ($directory ne '' && ! option 'subdir-objects')
1823                 # We must also use specific rules for a nodist_ source
1824                 # if its language requests it.
1825                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1826             {
1827                 my $obj_sans_ext = substr ($object, 0,
1828                                            - length ($this_obj_ext));
1829                 my $full_ansi;
1830                 if ($directory ne '')
1831                   {
1832                         $full_ansi = $directory . '/' . $base . $extension;
1833                   }
1834                 else
1835                   {
1836                         $full_ansi = $base . $extension;
1837                   }
1838
1839                 my @specifics = ($full_ansi, $obj_sans_ext,
1840                                  # Only use $this_obj_ext in the derived
1841                                  # source case because in the other case we
1842                                  # *don't* want $(OBJEXT) to appear here.
1843                                  ($derived_source ? $this_obj_ext : '.o'),
1844                                  $extension);
1845
1846                 # If we renamed the object then we want to use the
1847                 # per-executable flag name.  But if this is simply a
1848                 # subdir build then we still want to use the AM_ flag
1849                 # name.
1850                 if ($renamed)
1851                   {
1852                     unshift @specifics, $derived;
1853                     $aggregate = $derived;
1854                   }
1855                 else
1856                   {
1857                     unshift @specifics, 'AM';
1858                   }
1859
1860                 # Each item on this list is a reference to a list consisting
1861                 # of four values followed by additional transform flags for
1862                 # file_contents.  The four values are the derived flag prefix
1863                 # (e.g. for 'foo_CFLAGS', it is 'foo'), the name of the
1864                 # source file, the base name of the output file, and
1865                 # the extension for the object file.
1866                 push (@{$lang_specific_files{$lang->name}},
1867                       [@specifics, %transform]);
1868             }
1869         }
1870         elsif ($extension eq $obj)
1871         {
1872             # This is probably the result of a direct suffix rule.
1873             # In this case we just accept the rewrite.
1874             $object = "$base$extension";
1875             $object = "$directory/$object" if $directory ne '';
1876             $linker = '';
1877         }
1878         else
1879         {
1880             # No error message here.  Used to have one, but it was
1881             # very unpopular.
1882             # FIXME: we could potentially do more processing here,
1883             # perhaps treating the new extension as though it were a
1884             # new source extension (as above).  This would require
1885             # more restructuring than is appropriate right now.
1886             next;
1887         }
1888
1889         err_am "object '$object' created by '$full' and '$object_map{$object}'"
1890           if (defined $object_map{$object}
1891               && $object_map{$object} ne $full);
1892
1893         my $comp_val = (($object =~ /\.lo$/)
1894                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1895         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1896         if (defined $object_compilation_map{$comp_obj}
1897             && $object_compilation_map{$comp_obj} != 0
1898             # Only see the error once.
1899             && ($object_compilation_map{$comp_obj}
1900                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1901             && $object_compilation_map{$comp_obj} != $comp_val)
1902           {
1903             err_am "object '$comp_obj' created both with libtool and without";
1904           }
1905         $object_compilation_map{$comp_obj} |= $comp_val;
1906
1907         if (defined $lang)
1908         {
1909             # Let the language do some special magic if required.
1910             $lang->target_hook ($aggregate, $object, $full, %transform);
1911         }
1912
1913         if ($derived_source)
1914           {
1915             prog_error ($lang->name . " has automatic dependency tracking")
1916               if $lang->autodep ne 'no';
1917             # Make sure this new source file is handled next.  That will
1918             # make it appear to be at the right place in the list.
1919             unshift (@files, $object);
1920             # Distribute derived sources unless the source they are
1921             # derived from is not.
1922             &push_dist_common ($object)
1923               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1924             next;
1925           }
1926
1927         $linkers_used{$linker} = 1;
1928
1929         push (@result, $object);
1930
1931         if (! defined $object_map{$object})
1932         {
1933             my @dep_list = ();
1934             $object_map{$object} = $full;
1935
1936             # If resulting object is in subdir, we need to make
1937             # sure the subdir exists at build time.
1938             if ($object =~ /\//)
1939             {
1940                 # FIXME: check that $DIRECTORY is somewhere in the
1941                 # project
1942
1943                 # For Java, the way we're handling it right now, a
1944                 # '..' component doesn't make sense.
1945                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1946                   {
1947                     err_am "'$full' should not contain a '..' component";
1948                   }
1949
1950                 # Make sure object is removed by 'make mostlyclean'.
1951                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1952                 # If we have a libtool object then we also must remove
1953                 # the ordinary .o.
1954                 if ($object =~ /\.lo$/)
1955                 {
1956                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1957                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1958
1959                     # Remove any libtool object in this directory.
1960                     $libtool_clean_directories{$directory} = 1;
1961                 }
1962
1963                 push (@dep_list, require_build_directory ($directory));
1964
1965                 # If we're generating dependencies, we also want
1966                 # to make sure that the appropriate subdir of the
1967                 # .deps directory is created.
1968                 push (@dep_list,
1969                       require_build_directory ($directory . '/$(DEPDIR)'))
1970                   unless option 'no-dependencies';
1971             }
1972
1973             &pretty_print_rule ($object . ':', "\t", @dep_list)
1974                 if scalar @dep_list > 0;
1975         }
1976
1977         # Transform .o or $o file into .P file (for automatic
1978         # dependency code).
1979         # Properly flatten multiple adjacent slashes, as Solaris 10 make
1980         # might fail over them in an include statement.
1981         # Leading double slashes may be special, as per Posix, so deal
1982         # with them carefully.
1983         if ($lang && $lang->autodep ne 'no')
1984         {
1985             my $depfile = $object;
1986             $depfile =~ s/\.([^.]*)$/.P$1/;
1987             $depfile =~ s/\$\(OBJEXT\)$/o/;
1988             my $maybe_extra_leading_slash = '';
1989             $maybe_extra_leading_slash = '/' if $depfile =~ m,^//[^/],;
1990             $depfile =~ s,/+,/,g;
1991             my $basename = basename ($depfile);
1992             # This might make $dirname empty, but we account for that below.
1993             (my $dirname = dirname ($depfile)) =~ s/\/*$//;
1994             $dirname = $maybe_extra_leading_slash . $dirname;
1995             $dep_files{$dirname . '/$(DEPDIR)/' . $basename} = 1;
1996         }
1997     }
1998
1999     return @result;
2000 }
2001
2002
2003 # $LINKER
2004 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
2005 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
2006 # ---------------------------------------------------------------------------
2007 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
2008 #
2009 # Arguments are:
2010 #   $VAR is the name of the _SOURCES variable
2011 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
2012 #     it will be generated and returned).
2013 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
2014 #     work done to determine the linker will be).
2015 #   $ONE_FILE is the canonical (transformed) name of object to build
2016 #   $OBJ is the object extension (i.e. either '.o' or '.lo').
2017 #   $TOPPARENT is the _SOURCES variable being processed.
2018 #   $WHERE context into which this definition is done
2019 #   %TRANSFORM extra arguments to pass to file_contents when producing
2020 #     rules
2021 #
2022 # Result is a pair ($LINKER, $OBJVAR):
2023 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
2024 sub define_objects_from_sources ($$$$$$$%)
2025 {
2026   my ($var, $objvar, $nodefine, $one_file,
2027       $obj, $topparent, $where, %transform) = @_;
2028
2029   my $needlinker = "";
2030
2031   transform_variable_recursively
2032     ($var, $objvar, 'am__objects', $nodefine, $where,
2033      # The transform code to run on each filename.
2034      sub {
2035        my ($subvar, $val, $cond, $full_cond) = @_;
2036        my @trans = handle_single_transform ($subvar, $topparent,
2037                                             $one_file, $obj, $val,
2038                                             %transform);
2039        $needlinker = "true" if @trans;
2040        return @trans;
2041      });
2042
2043   return $needlinker;
2044 }
2045
2046
2047 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
2048 # -----------------------------------------------------------------------------
2049 # Handle SOURCE->OBJECT transform for one program or library.
2050 # Arguments are:
2051 #   canonical (transformed) name of target to build
2052 #   actual target of object to build
2053 #   object extension (i.e., either '.o' or '$o')
2054 #   location of the source variable
2055 #   extra arguments to pass to file_contents when producing rules
2056 # Return the name of the linker variable that must be used.
2057 # Empty return means just use 'LINK'.
2058 sub handle_source_transform ($$$$%)
2059 {
2060     # one_file is canonical name.  unxformed is given name.  obj is
2061     # object extension.
2062     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
2063
2064     my $linker = '';
2065
2066     # No point in continuing if _OBJECTS is defined.
2067     return if reject_var ($one_file . '_OBJECTS',
2068                           $one_file . '_OBJECTS should not be defined');
2069
2070     my %used_pfx = ();
2071     my $needlinker;
2072     %linkers_used = ();
2073     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2074                         'dist_EXTRA_', 'nodist_EXTRA_')
2075     {
2076         my $varname = $prefix . $one_file . "_SOURCES";
2077         my $var = var $varname;
2078         next unless $var;
2079
2080         # We are going to define _OBJECTS variables using the prefix.
2081         # Then we glom them all together.  So we can't use the null
2082         # prefix here as we need it later.
2083         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2084
2085         # Keep track of which prefixes we saw.
2086         $used_pfx{$xpfx} = 1
2087           unless $prefix =~ /EXTRA_/;
2088
2089         push @sources, "\$($varname)";
2090         push @dist_sources, shadow_unconditionally ($varname, $where)
2091           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2092
2093         $needlinker |=
2094             define_objects_from_sources ($varname,
2095                                          $xpfx . $one_file . '_OBJECTS',
2096                                          $prefix =~ /EXTRA_/,
2097                                          $one_file, $obj, $varname, $where,
2098                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2099                                          %transform);
2100     }
2101     if ($needlinker)
2102     {
2103         $linker ||= &resolve_linker (%linkers_used);
2104     }
2105
2106     my @keys = sort keys %used_pfx;
2107     if (scalar @keys == 0)
2108     {
2109         # The default source for libfoo.la is libfoo.c, but for
2110         # backward compatibility we first look at libfoo_la.c,
2111         # if no default source suffix is given.
2112         my $old_default_source = "$one_file.c";
2113         my $ext_var = var ('AM_DEFAULT_SOURCE_EXT');
2114         my $default_source_ext = $ext_var ? variable_value ($ext_var) : '.c';
2115         msg_var ('unsupported', $ext_var, $ext_var->name . " can assume at most one value")
2116           if $default_source_ext =~ /[\t ]/;
2117         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,$default_source_ext,;
2118         if ($old_default_source ne $default_source
2119             && !$ext_var
2120             && (rule $old_default_source
2121                 || rule '$(srcdir)/' . $old_default_source
2122                 || rule '${srcdir}/' . $old_default_source
2123                 || -f $old_default_source))
2124           {
2125             my $loc = $where->clone;
2126             $loc->pop_context;
2127             msg ('obsolete', $loc,
2128                  "the default source for '$unxformed' has been changed "
2129                  . "to '$default_source'.\n(Using '$old_default_source' for "
2130                  . "backward compatibility.)");
2131             $default_source = $old_default_source;
2132           }
2133         # If a rule exists to build this source with a $(srcdir)
2134         # prefix, use that prefix in our variables too.  This is for
2135         # the sake of BSD Make.
2136         if (rule '$(srcdir)/' . $default_source
2137             || rule '${srcdir}/' . $default_source)
2138           {
2139             $default_source = '$(srcdir)/' . $default_source;
2140           }
2141
2142         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2143         push (@sources, $default_source);
2144         push (@dist_sources, $default_source);
2145
2146         %linkers_used = ();
2147         my (@result) =
2148           handle_single_transform ($one_file . '_SOURCES',
2149                                    $one_file . '_SOURCES',
2150                                    $one_file, $obj,
2151                                    $default_source, %transform);
2152         $linker ||= &resolve_linker (%linkers_used);
2153         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2154     }
2155     else
2156     {
2157         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2158         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2159     }
2160
2161     # If we want to use 'LINK' we must make sure it is defined.
2162     if ($linker eq '')
2163     {
2164         $need_link = 1;
2165     }
2166
2167     return $linker;
2168 }
2169
2170
2171 # handle_lib_objects ($XNAME, $VAR)
2172 # ---------------------------------
2173 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2174 # Also, generate _DEPENDENCIES variable if appropriate.
2175 # Arguments are:
2176 #   transformed name of object being built, or empty string if no object
2177 #   name of _LDADD/_LIBADD-type variable to examine
2178 # Returns 1 if LIBOBJS seen, 0 otherwise.
2179 sub handle_lib_objects
2180 {
2181   my ($xname, $varname) = @_;
2182
2183   my $var = var ($varname);
2184   prog_error "'$varname' undefined"
2185     unless $var;
2186   prog_error "unexpected variable name '$varname'"
2187     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2188   my $prefix = $1 || 'AM_';
2189
2190   my $seen_libobjs = 0;
2191   my $flagvar = 0;
2192
2193   transform_variable_recursively
2194     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2195      ! $xname, INTERNAL,
2196      # Transformation function, run on each filename.
2197      sub {
2198        my ($subvar, $val, $cond, $full_cond) = @_;
2199
2200        if ($val =~ /^-/)
2201          {
2202            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2203            if ($val !~ /^-[lL]/ &&
2204                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2205                # for Libtool libraries or programs.  (Actually we are a bit
2206                # lax here since this code also applies to non-libtool
2207                # libraries or programs, for which -dlopen and -dlopreopen
2208                # are pure nonsense.  Diagnosing this doesn't seem very
2209                # important: the developer will quickly get complaints from
2210                # the linker.)
2211                $val !~ /^-dl(?:pre)?open$/ &&
2212                # Only get this error once.
2213                ! $flagvar)
2214              {
2215                $flagvar = 1;
2216                # FIXME: should display a stack of nested variables
2217                # as context when $var != $subvar.
2218                err_var ($var, "linker flags such as '$val' belong in "
2219                         . "'${prefix}LDFLAGS'");
2220              }
2221            return ();
2222          }
2223        elsif ($val !~ /^\@.*\@$/)
2224          {
2225            # Assume we have a file of some sort, and output it into the
2226            # dependency variable.  Autoconf substitutions are not output;
2227            # rarely is a new dependency substituted into e.g. foo_LDADD
2228            # -- but bad things (e.g. -lX11) are routinely substituted.
2229            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2230            # and handled specially below.
2231            return $val;
2232          }
2233        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2234          {
2235            handle_LIBOBJS ($subvar, $cond, $1);
2236            $seen_libobjs = 1;
2237            return $val;
2238          }
2239        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2240          {
2241            handle_ALLOCA ($subvar, $cond, $1);
2242            return $val;
2243          }
2244        else
2245          {
2246            return ();
2247          }
2248      });
2249
2250   return $seen_libobjs;
2251 }
2252
2253 # handle_LIBOBJS_or_ALLOCA ($VAR)
2254 # -------------------------------
2255 # Definitions common to LIBOBJS and ALLOCA.
2256 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2257 sub handle_LIBOBJS_or_ALLOCA ($)
2258 {
2259   my ($var) = @_;
2260
2261   my $dir = '';
2262
2263   # If LIBOBJS files must be built in another directory we have
2264   # to define LIBOBJDIR and ensure the files get cleaned.
2265   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2266   # is achieved by 'rm -f *.$(OBJEXT)' in compile.am.
2267   if ($config_libobj_dir
2268       && $relative_dir ne $config_libobj_dir)
2269     {
2270       if (option 'subdir-objects')
2271         {
2272           # In the top-level Makefile we do not use $(top_builddir), because
2273           # we are already there, and since the targets are built without
2274           # a $(top_builddir), it helps BSD Make to match them with
2275           # dependencies.
2276           $dir = "$config_libobj_dir/" if $config_libobj_dir ne '.';
2277           $dir = "$topsrcdir/$dir" if $relative_dir ne '.';
2278           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2279           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2280           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2281           # be created by libtool as a side-effect of creating LTLIBOBJS).
2282           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2283         }
2284       else
2285         {
2286           error ("'\$($var)' cannot be used outside '$config_libobj_dir' if"
2287                  . " 'subdir-objects' is not set");
2288         }
2289     }
2290
2291   return $dir;
2292 }
2293
2294 sub handle_LIBOBJS ($$$)
2295 {
2296   my ($var, $cond, $lt) = @_;
2297   my $myobjext = $lt ? 'lo' : 'o';
2298   $lt ||= '';
2299
2300   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2301     if ! keys %libsources;
2302
2303   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2304
2305   foreach my $iter (keys %libsources)
2306     {
2307       if ($iter =~ /\.[cly]$/)
2308         {
2309           &saw_extension ($&);
2310           &saw_extension ('.c');
2311         }
2312
2313       if ($iter =~ /\.h$/)
2314         {
2315           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2316         }
2317       elsif ($iter ne 'alloca.c')
2318         {
2319           my $rewrite = $iter;
2320           $rewrite =~ s/\.c$/.P$myobjext/;
2321           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2322           $rewrite = "^" . quotemeta ($iter) . "\$";
2323           # Only require the file if it is not a built source.
2324           my $bs = var ('BUILT_SOURCES');
2325           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2326             {
2327               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2328             }
2329         }
2330     }
2331 }
2332
2333 sub handle_ALLOCA ($$$)
2334 {
2335   my ($var, $cond, $lt) = @_;
2336   my $myobjext = $lt ? 'lo' : 'o';
2337   $lt ||= '';
2338   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2339
2340   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2341   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2342   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2343   &saw_extension ('.c');
2344 }
2345
2346 # Canonicalize the input parameter
2347 sub canonicalize
2348 {
2349     my ($string) = @_;
2350     $string =~ tr/A-Za-z0-9_\@/_/c;
2351     return $string;
2352 }
2353
2354 # Canonicalize a name, and check to make sure the non-canonical name
2355 # is never used.  Returns canonical name.  Arguments are name and a
2356 # list of suffixes to check for.
2357 sub check_canonical_spelling
2358 {
2359   my ($name, @suffixes) = @_;
2360
2361   my $xname = &canonicalize ($name);
2362   if ($xname ne $name)
2363     {
2364       foreach my $xt (@suffixes)
2365         {
2366           reject_var ("$name$xt", "use '$xname$xt', not '$name$xt'");
2367         }
2368     }
2369
2370   return $xname;
2371 }
2372
2373
2374 # handle_compile ()
2375 # -----------------
2376 # Set up the compile suite.
2377 sub handle_compile ()
2378 {
2379    return if ! $must_handle_compiled_objects;
2380
2381     # Boilerplate.
2382     my $default_includes = '';
2383     if (! option 'nostdinc')
2384       {
2385         my @incs = ('-I.', subst ('am__isrc'));
2386
2387         my $var = var 'CONFIG_HEADER';
2388         if ($var)
2389           {
2390             foreach my $hdr (split (' ', $var->variable_value))
2391               {
2392                 push @incs, '-I' . dirname ($hdr);
2393               }
2394           }
2395         # We want '-I. -I$(srcdir)', but the latter -I is redundant
2396         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2397         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2398         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2399         # to just put @am__isrc@ right after '-I.', without a space.
2400         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2401       }
2402
2403     my (@mostly_rms, @dist_rms);
2404     foreach my $item (sort keys %compile_clean_files)
2405     {
2406         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2407         {
2408             push (@mostly_rms, "\t-rm -f $item");
2409         }
2410         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2411         {
2412             push (@dist_rms, "\t-rm -f $item");
2413         }
2414         else
2415         {
2416           prog_error 'invalid entry in %compile_clean_files';
2417         }
2418     }
2419
2420     my ($coms, $vars, $rules) =
2421       &file_contents_internal (1, "$libdir/am/compile.am",
2422                                new Automake::Location,
2423                                ('DEFAULT_INCLUDES' => $default_includes,
2424                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2425                                 'DISTRMS' => join ("\n", @dist_rms)));
2426     $output_vars .= $vars;
2427     $output_rules .= "$coms$rules";
2428 }
2429
2430 # handle_libtool ()
2431 # -----------------
2432 # Handle libtool rules.
2433 sub handle_libtool
2434 {
2435   return unless var ('LIBTOOL');
2436
2437   # Libtool requires some files, but only at top level.
2438   # (Starting with Libtool 2.0 we do not have to bother.  These
2439   # requirements are done with AC_REQUIRE_AUX_FILE.)
2440   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2441     if $relative_dir eq '.' && ! $libtool_new_api;
2442
2443   my @libtool_rms;
2444   foreach my $item (sort keys %libtool_clean_directories)
2445     {
2446       my $dir = ($item eq '.') ? '' : "$item/";
2447       # .libs is for Unix, _libs for DOS.
2448       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2449     }
2450
2451   check_user_variables 'LIBTOOLFLAGS';
2452
2453   # Output the libtool compilation rules.
2454   $output_rules .= &file_contents ('libtool',
2455                                    new Automake::Location,
2456                                    LTRMS => join ("\n", @libtool_rms));
2457 }
2458
2459 # handle_programs ()
2460 # ------------------
2461 # Handle C programs.
2462 sub handle_programs
2463 {
2464   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2465                                   'bin', 'sbin', 'libexec', 'pkglibexec',
2466                                   'noinst', 'check');
2467   return if ! @proglist;
2468   $must_handle_compiled_objects = 1;
2469
2470   my $seen_global_libobjs =
2471     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2472
2473   foreach my $pair (@proglist)
2474     {
2475       my ($where, $one_file) = @$pair;
2476
2477       my $seen_libobjs = 0;
2478       my $obj = '.$(OBJEXT)';
2479
2480       $known_programs{$one_file} = $where;
2481
2482       # Canonicalize names and check for misspellings.
2483       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2484                                              '_SOURCES', '_OBJECTS',
2485                                              '_DEPENDENCIES');
2486
2487       $where->push_context ("while processing program '$one_file'");
2488       $where->set (INTERNAL->get);
2489
2490       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2491                                              NONLIBTOOL => 1, LIBTOOL => 0);
2492
2493       if (var ($xname . "_LDADD"))
2494         {
2495           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2496         }
2497       else
2498         {
2499           # User didn't define prog_LDADD override.  So do it.
2500           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2501
2502           # This does a bit too much work.  But we need it to
2503           # generate _DEPENDENCIES when appropriate.
2504           if (var ('LDADD'))
2505             {
2506               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2507             }
2508         }
2509
2510       reject_var ($xname . '_LIBADD',
2511                   "use '${xname}_LDADD', not '${xname}_LIBADD'");
2512
2513       set_seen ($xname . '_DEPENDENCIES');
2514       set_seen ('EXTRA_' . $xname . '_DEPENDENCIES');
2515       set_seen ($xname . '_LDFLAGS');
2516
2517       # Determine program to use for link.
2518       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xname);
2519       $vlink = verbose_flag ($vlink || 'GEN');
2520
2521       # If the resulting program lies into a subdirectory,
2522       # make sure this directory will exist.
2523       my $dirstamp = require_build_directory_maybe ($one_file);
2524
2525       $libtool_clean_directories{dirname ($one_file)} = 1;
2526
2527       $output_rules .= &file_contents ('program',
2528                                        $where,
2529                                        PROGRAM  => $one_file,
2530                                        XPROGRAM => $xname,
2531                                        XLINK    => $xlink,
2532                                        VERBOSE  => $vlink,
2533                                        DIRSTAMP => $dirstamp,
2534                                        EXEEXT   => '$(EXEEXT)');
2535
2536       if ($seen_libobjs || $seen_global_libobjs)
2537         {
2538           if (var ($xname . '_LDADD'))
2539             {
2540               &check_libobjs_sources ($xname, $xname . '_LDADD');
2541             }
2542           elsif (var ('LDADD'))
2543             {
2544               &check_libobjs_sources ($xname, 'LDADD');
2545             }
2546         }
2547     }
2548 }
2549
2550
2551 # handle_libraries ()
2552 # -------------------
2553 # Handle libraries.
2554 sub handle_libraries
2555 {
2556   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2557                                  'lib', 'pkglib', 'noinst', 'check');
2558   return if ! @liblist;
2559   $must_handle_compiled_objects = 1;
2560
2561   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2562                                     'noinst', 'check');
2563
2564   if (@prefix)
2565     {
2566       my $var = rvar ($prefix[0] . '_LIBRARIES');
2567       $var->requires_variables ('library used', 'RANLIB');
2568     }
2569
2570   &define_variable ('AR', 'ar', INTERNAL);
2571   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2572   &define_verbose_tagvar ('AR');
2573
2574   foreach my $pair (@liblist)
2575     {
2576       my ($where, $onelib) = @$pair;
2577
2578       my $seen_libobjs = 0;
2579       # Check that the library fits the standard naming convention.
2580       my $bn = basename ($onelib);
2581       if ($bn !~ /^lib.*\.a$/)
2582         {
2583           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2584           my $suggestion = dirname ($onelib) . "/$bn";
2585           $suggestion =~ s|^\./||g;
2586           msg ('error-gnu/warn', $where,
2587                "'$onelib' is not a standard library name\n"
2588                . "did you mean '$suggestion'?")
2589         }
2590
2591       ($known_libraries{$onelib} = $bn) =~ s/\.a$//;
2592
2593       $where->push_context ("while processing library '$onelib'");
2594       $where->set (INTERNAL->get);
2595
2596       my $obj = '.$(OBJEXT)';
2597
2598       # Canonicalize names and check for misspellings.
2599       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2600                                             '_OBJECTS', '_DEPENDENCIES',
2601                                             '_AR');
2602
2603       if (! var ($xlib . '_AR'))
2604         {
2605           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2606         }
2607
2608       # Generate support for conditional object inclusion in
2609       # libraries.
2610       if (var ($xlib . '_LIBADD'))
2611         {
2612           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2613             {
2614               $seen_libobjs = 1;
2615             }
2616         }
2617       else
2618         {
2619           &define_variable ($xlib . "_LIBADD", '', $where);
2620         }
2621
2622       reject_var ($xlib . '_LDADD',
2623                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2624
2625       # Make sure we at look at this.
2626       set_seen ($xlib . '_DEPENDENCIES');
2627       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2628
2629       &handle_source_transform ($xlib, $onelib, $obj, $where,
2630                                 NONLIBTOOL => 1, LIBTOOL => 0);
2631
2632       # If the resulting library lies into a subdirectory,
2633       # make sure this directory will exist.
2634       my $dirstamp = require_build_directory_maybe ($onelib);
2635       my $verbose = verbose_flag ('AR');
2636       my $silent = silent_flag ();
2637
2638       $output_rules .= &file_contents ('library',
2639                                        $where,
2640                                        VERBOSE  => $verbose,
2641                                        SILENT   => $silent,
2642                                        LIBRARY  => $onelib,
2643                                        XLIBRARY => $xlib,
2644                                        DIRSTAMP => $dirstamp);
2645
2646       if ($seen_libobjs)
2647         {
2648           if (var ($xlib . '_LIBADD'))
2649             {
2650               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2651             }
2652         }
2653
2654       if (! $seen_ar)
2655         {
2656           msg ('extra-portability', $where,
2657                "'$onelib': linking libraries using a non-POSIX\n"
2658                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2659         }
2660     }
2661 }
2662
2663
2664 # handle_ltlibraries ()
2665 # ---------------------
2666 # Handle shared libraries.
2667 sub handle_ltlibraries
2668 {
2669   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2670                                  'noinst', 'lib', 'pkglib', 'check');
2671   return if ! @liblist;
2672   $must_handle_compiled_objects = 1;
2673
2674   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2675                                     'noinst', 'check');
2676
2677   if (@prefix)
2678     {
2679       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2680       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2681     }
2682
2683   my %instdirs = ();
2684   my %instsubdirs = ();
2685   my %instconds = ();
2686   my %liblocations = ();        # Location (in Makefile.am) of each library.
2687
2688   foreach my $key (@prefix)
2689     {
2690       # Get the installation directory of each library.
2691       my $dir = $key;
2692       my $strip_subdir = 1;
2693       if ($dir =~ /^nobase_/)
2694         {
2695           $dir =~ s/^nobase_//;
2696           $strip_subdir = 0;
2697         }
2698       my $var = rvar ($key . '_LTLIBRARIES');
2699
2700       # We reject libraries which are installed in several places
2701       # in the same condition, because we can only specify one
2702       # '-rpath' option.
2703       $var->traverse_recursively
2704         (sub
2705          {
2706            my ($var, $val, $cond, $full_cond) = @_;
2707            my $hcond = $full_cond->human;
2708            my $where = $var->rdef ($cond)->location;
2709            my $ldir = '';
2710            $ldir = '/' . dirname ($val)
2711              if (!$strip_subdir);
2712            # A library cannot be installed in different directories
2713            # in overlapping conditions.
2714            if (exists $instconds{$val})
2715              {
2716                my ($msg, $acond) =
2717                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2718
2719                if ($msg)
2720                  {
2721                    error ($where, $msg, partial => 1);
2722                    my $dirtxt = "installed " . ($strip_subdir ? "in" : "below") . " '$dir'";
2723                    $dirtxt = "built for '$dir'"
2724                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2725                    my $dircond =
2726                      $full_cond->true ? "" : " in condition $hcond";
2727
2728                    error ($where, "'$val' should be $dirtxt$dircond ...",
2729                           partial => 1);
2730
2731                    my $hacond = $acond->human;
2732                    my $adir = $instdirs{$val}{$acond};
2733                    my $adirtxt = "installed in '$adir'";
2734                    $adirtxt = "built for '$adir'"
2735                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2736                          || $adir eq 'check');
2737                    my $adircond = $acond->true ? "" : " in condition $hacond";
2738
2739                    my $onlyone = ($dir ne $adir) ?
2740                      ("\nLibtool libraries can be built for only one "
2741                       . "destination") : "";
2742
2743                    error ($liblocations{$val}{$acond},
2744                           "... and should also be $adirtxt$adircond.$onlyone");
2745                    return;
2746                  }
2747              }
2748            else
2749              {
2750                $instconds{$val} = new Automake::DisjConditions;
2751              }
2752            $instdirs{$val}{$full_cond} = $dir;
2753            $instsubdirs{$val}{$full_cond} = $ldir;
2754            $liblocations{$val}{$full_cond} = $where;
2755            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2756          },
2757          sub
2758          {
2759            return ();
2760          },
2761          skip_ac_subst => 1);
2762     }
2763
2764   foreach my $pair (@liblist)
2765     {
2766       my ($where, $onelib) = @$pair;
2767
2768       my $seen_libobjs = 0;
2769       my $obj = '.lo';
2770
2771       # Canonicalize names and check for misspellings.
2772       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2773                                             '_SOURCES', '_OBJECTS',
2774                                             '_DEPENDENCIES');
2775
2776       # Check that the library fits the standard naming convention.
2777       my $libname_rx = '^lib.*\.la';
2778       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2779       my $ldvar2 = var ('LDFLAGS');
2780       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2781           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2782         {
2783           # Relax name checking for libtool modules.
2784           $libname_rx = '\.la';
2785         }
2786
2787       my $bn = basename ($onelib);
2788       if ($bn !~ /$libname_rx$/)
2789         {
2790           my $type = 'library';
2791           if ($libname_rx eq '\.la')
2792             {
2793               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2794               $type = 'module';
2795             }
2796           else
2797             {
2798               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2799             }
2800           my $suggestion = dirname ($onelib) . "/$bn";
2801           $suggestion =~ s|^\./||g;
2802           msg ('error-gnu/warn', $where,
2803                "'$onelib' is not a standard libtool $type name\n"
2804                . "did you mean '$suggestion'?")
2805         }
2806
2807       ($known_libraries{$onelib} = $bn) =~ s/\.la$//;
2808
2809       $where->push_context ("while processing Libtool library '$onelib'");
2810       $where->set (INTERNAL->get);
2811
2812       # Make sure we look at these.
2813       set_seen ($xlib . '_LDFLAGS');
2814       set_seen ($xlib . '_DEPENDENCIES');
2815       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2816
2817       # Generate support for conditional object inclusion in
2818       # libraries.
2819       if (var ($xlib . '_LIBADD'))
2820         {
2821           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2822             {
2823               $seen_libobjs = 1;
2824             }
2825         }
2826       else
2827         {
2828           &define_variable ($xlib . "_LIBADD", '', $where);
2829         }
2830
2831       reject_var ("${xlib}_LDADD",
2832                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2833
2834
2835       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2836                                              NONLIBTOOL => 0, LIBTOOL => 1);
2837
2838       # Determine program to use for link.
2839       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xlib);
2840       $vlink = verbose_flag ($vlink || 'GEN');
2841
2842       my $rpathvar = "am_${xlib}_rpath";
2843       my $rpath = "\$($rpathvar)";
2844       foreach my $rcond ($instconds{$onelib}->conds)
2845         {
2846           my $val;
2847           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2848               || $instdirs{$onelib}{$rcond} eq 'noinst'
2849               || $instdirs{$onelib}{$rcond} eq 'check')
2850             {
2851               # It's an EXTRA_ library, so we can't specify -rpath,
2852               # because we don't know where the library will end up.
2853               # The user probably knows, but generally speaking automake
2854               # doesn't -- and in fact configure could decide
2855               # dynamically between two different locations.
2856               $val = '';
2857             }
2858           else
2859             {
2860               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2861               $val .= $instsubdirs{$onelib}{$rcond}
2862                 if defined $instsubdirs{$onelib}{$rcond};
2863             }
2864           if ($rcond->true)
2865             {
2866               # If $rcond is true there is only one condition and
2867               # there is no point defining an helper variable.
2868               $rpath = $val;
2869             }
2870           else
2871             {
2872               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2873             }
2874         }
2875
2876       # If the resulting library lies into a subdirectory,
2877       # make sure this directory will exist.
2878       my $dirstamp = require_build_directory_maybe ($onelib);
2879
2880       # Remember to cleanup .libs/ in this directory.
2881       my $dirname = dirname $onelib;
2882       $libtool_clean_directories{$dirname} = 1;
2883
2884       $output_rules .= &file_contents ('ltlibrary',
2885                                        $where,
2886                                        LTLIBRARY  => $onelib,
2887                                        XLTLIBRARY => $xlib,
2888                                        RPATH      => $rpath,
2889                                        XLINK      => $xlink,
2890                                        VERBOSE    => $vlink,
2891                                        DIRSTAMP   => $dirstamp);
2892       if ($seen_libobjs)
2893         {
2894           if (var ($xlib . '_LIBADD'))
2895             {
2896               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2897             }
2898         }
2899
2900       if (! $seen_ar)
2901         {
2902           msg ('extra-portability', $where,
2903                "'$onelib': linking libtool libraries using a non-POSIX\n"
2904                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2905         }
2906     }
2907 }
2908
2909 # See if any _SOURCES variable were misspelled.
2910 sub check_typos ()
2911 {
2912   # It is ok if the user sets this particular variable.
2913   set_seen 'AM_LDFLAGS';
2914
2915   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2916     {
2917       foreach my $var (variables $primary)
2918         {
2919           my $varname = $var->name;
2920           # A configure variable is always legitimate.
2921           next if exists $configure_vars{$varname};
2922
2923           for my $cond ($var->conditions->conds)
2924             {
2925               $varname =~ /^(?:EXTRA_)?(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2926               msg_var ('syntax', $var, "variable '$varname' is defined but no"
2927                        . " program or\nlibrary has '$1' as canonical name"
2928                        . " (possible typo)")
2929                 unless $var->rdef ($cond)->seen;
2930             }
2931         }
2932     }
2933 }
2934
2935
2936 # Handle scripts.
2937 sub handle_scripts
2938 {
2939     # NOTE we no longer automatically clean SCRIPTS, because it is
2940     # useful to sometimes distribute scripts verbatim.  This happens
2941     # e.g. in Automake itself.
2942     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2943                      'bin', 'sbin', 'libexec', 'pkglibexec', 'pkgdata',
2944                      'noinst', 'check');
2945 }
2946
2947
2948
2949
2950 ## ------------------------ ##
2951 ## Handling Texinfo files.  ##
2952 ## ------------------------ ##
2953
2954 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2955 # &scan_texinfo_file ($FILENAME)
2956 # ------------------------------
2957 # $OUTFILE     - name of the info file produced by $FILENAME.
2958 # $VFILE       - name of the version.texi file used (undef if none).
2959 # @CLEAN_FILES - list of byproducts (indexes etc.)
2960 sub scan_texinfo_file ($)
2961 {
2962   my ($filename) = @_;
2963
2964   # Some of the following extensions are always created, no matter
2965   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2966   # are only created when they are used.  We used to scan $FILENAME
2967   # for their use, but that is not enough: they could be used in
2968   # included files.  We can't scan included files because we don't
2969   # know the include path.  Therefore we always erase these files, no
2970   # matter whether they are used or not.
2971   #
2972   # (tmp is only created if an @macro is used and a certain e-TeX
2973   # feature is not available.)
2974   my %clean_suffixes =
2975     map { $_ => 1 } (qw(aux log toc tmp
2976                         cp cps
2977                         fn fns
2978                         ky kys
2979                         vr vrs
2980                         tp tps
2981                         pg pgs)); # grep 'new.*index' texinfo.tex
2982
2983   my $texi = new Automake::XFile "< $filename";
2984   verb "reading $filename";
2985
2986   my ($outfile, $vfile);
2987   while ($_ = $texi->getline)
2988     {
2989       if (/^\@setfilename +(\S+)/)
2990         {
2991           # Honor only the first @setfilename.  (It's possible to have
2992           # more occurrences later if the manual shows examples of how
2993           # to use @setfilename...)
2994           next if $outfile;
2995
2996           $outfile = $1;
2997           if ($outfile =~ /\.([^.]+)$/ && $1 ne 'info')
2998             {
2999               error ("$filename:$.",
3000                      "output '$outfile' has unrecognized extension");
3001               return;
3002             }
3003         }
3004       # A "version.texi" file is actually any file whose name matches
3005       # "vers*.texi".
3006       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
3007         {
3008           $vfile = $1;
3009         }
3010
3011       # Try to find new or unused indexes.
3012
3013       # Creating a new category of index.
3014       elsif (/^\@def(code)?index (\w+)/)
3015         {
3016           $clean_suffixes{$2} = 1;
3017           $clean_suffixes{"$2s"} = 1;
3018         }
3019
3020       # Merging an index into an another.
3021       elsif (/^\@syn(code)?index (\w+) (\w+)/)
3022         {
3023           delete $clean_suffixes{"$2s"};
3024           $clean_suffixes{"$3s"} = 1;
3025         }
3026
3027     }
3028
3029   if (! $outfile)
3030     {
3031       err_am "'$filename' missing \@setfilename";
3032       return;
3033     }
3034
3035   my $infobase = basename ($filename);
3036   $infobase =~ s/\.te?xi(nfo)?$//;
3037   return ($outfile, $vfile,
3038           map { "$infobase.$_" } (sort keys %clean_suffixes));
3039 }
3040
3041
3042 # ($DIRSTAMP, @CLEAN_FILES)
3043 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
3044 # ------------------------------------------------------------------
3045 # SOURCE - the source Texinfo file
3046 # DEST - the destination Info file
3047 # INSRC - whether DEST should be built in the source tree
3048 # DEPENDENCIES - known dependencies
3049 sub output_texinfo_build_rules ($$$@)
3050 {
3051   my ($source, $dest, $insrc, @deps) = @_;
3052
3053   # Split 'a.texi' into 'a' and '.texi'.
3054   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
3055   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
3056
3057   $ssfx ||= "";
3058   $dsfx ||= "";
3059
3060   # We can output two kinds of rules: the "generic" rules use Make
3061   # suffix rules and are appropriate when $source and $dest do not lie
3062   # in a sub-directory; the "specific" rules are needed in the other
3063   # case.
3064   #
3065   # The former are output only once (this is not really apparent here,
3066   # but just remember that some logic deeper in Automake will not
3067   # output the same rule twice); while the later need to be output for
3068   # each Texinfo source.
3069   my $generic;
3070   my $makeinfoflags;
3071   my $sdir = dirname $source;
3072   if ($sdir eq '.' && dirname ($dest) eq '.')
3073     {
3074       $generic = 1;
3075       $makeinfoflags = '-I $(srcdir)';
3076     }
3077   else
3078     {
3079       $generic = 0;
3080       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3081     }
3082
3083   # A directory can contain two kinds of info files: some built in the
3084   # source tree, and some built in the build tree.  The rules are
3085   # different in each case.  However we cannot output two different
3086   # set of generic rules.  Because in-source builds are more usual, we
3087   # use generic rules in this case and fall back to "specific" rules
3088   # for build-dir builds.  (It should not be a problem to invert this
3089   # if needed.)
3090   $generic = 0 unless $insrc;
3091
3092   # We cannot use a suffix rule to build info files with an empty
3093   # extension.  Otherwise we would output a single suffix inference
3094   # rule, with separate dependencies, as in
3095   #
3096   #    .texi:
3097   #             $(MAKEINFO) ...
3098   #    foo.info: foo.texi
3099   #
3100   # which confuse Solaris make.  (See the Autoconf manual for
3101   # details.)  Therefore we use a specific rule in this case.  This
3102   # applies to info files only (dvi and pdf files always have an
3103   # extension).
3104   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3105
3106   # If the resulting file lie into a subdirectory,
3107   # make sure this directory will exist.
3108   my $dirstamp = require_build_directory_maybe ($dest);
3109
3110   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3111
3112   $output_rules .= file_contents ('texibuild',
3113                                   new Automake::Location,
3114                                   AM_V_MAKEINFO    => verbose_flag('MAKEINFO'),
3115                                   AM_V_TEXI2DVI    => verbose_flag('TEXI2DVI'),
3116                                   AM_V_TEXI2PDF    => verbose_flag('TEXI2PDF'),
3117                                   DEPS             => "@deps",
3118                                   DEST_PREFIX      => $dpfx,
3119                                   DEST_INFO_PREFIX => $dipfx,
3120                                   DEST_SUFFIX      => $dsfx,
3121                                   DIRSTAMP         => $dirstamp,
3122                                   GENERIC          => $generic,
3123                                   GENERIC_INFO     => $generic_info,
3124                                   INSRC            => $insrc,
3125                                   MAKEINFOFLAGS    => $makeinfoflags,
3126                                   SILENT           => silent_flag(),
3127                                   SOURCE           => ($generic
3128                                                        ? '$<' : $source),
3129                                   SOURCE_INFO      => ($generic_info
3130                                                        ? '$<' : $source),
3131                                   SOURCE_REAL      => $source,
3132                                   SOURCE_SUFFIX    => $ssfx,
3133                                   TEXIQUIET        => verbose_flag('texinfo'),
3134                                   TEXIDEVNULL      => verbose_flag('texidevnull'),
3135                                   );
3136   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3137 }
3138
3139
3140 # ($MOSTLYCLEAN, $TEXICLEAN, $MAINTCLEAN)
3141 # handle_texinfo_helper ($info_texinfos)
3142 # --------------------------------------
3143 # Handle all Texinfo source; helper for handle_texinfo.
3144 sub handle_texinfo_helper ($)
3145 {
3146   my ($info_texinfos) = @_;
3147   my (@infobase, @info_deps_list, @texi_deps);
3148   my %versions;
3149   my $done = 0;
3150   my (@mostly_cleans, @texi_cleans, @maint_cleans) = ('', '', '');
3151
3152   # Build a regex matching user-cleaned files.
3153   my $d = var 'DISTCLEANFILES';
3154   my $c = var 'CLEANFILES';
3155   my @f = ();
3156   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3157   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3158   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3159   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3160
3161   foreach my $texi
3162       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3163     {
3164       my $infobase = $texi;
3165       $infobase =~ s/\.(txi|texinfo|texi)$//;
3166
3167       if ($infobase eq $texi)
3168         {
3169           # FIXME: report line number.
3170           err_am "texinfo file '$texi' has unrecognized extension";
3171           next;
3172         }
3173
3174       push @infobase, $infobase;
3175
3176       # If 'version.texi' is referenced by input file, then include
3177       # automatic versioning capability.
3178       my ($out_file, $vtexi, @clean_files) =
3179         scan_texinfo_file ("$relative_dir/$texi")
3180         or next;
3181       push (@mostly_cleans, @clean_files);
3182
3183       # If the Texinfo source is in a subdirectory, create the
3184       # resulting info in this subdirectory.  If it is in the current
3185       # directory, try hard to not prefix "./" because it breaks the
3186       # generic rules.
3187       my $outdir = dirname ($texi) . '/';
3188       $outdir = "" if $outdir eq './';
3189       $out_file =  $outdir . $out_file;
3190
3191       # Until Automake 1.6.3, .info files were built in the
3192       # source tree.  This was an obstacle to the support of
3193       # non-distributed .info files, and non-distributed .texi
3194       # files.
3195       #
3196       # * Non-distributed .texi files is important in some packages
3197       #   where .texi files are built at make time, probably using
3198       #   other binaries built in the package itself, maybe using
3199       #   tools or information found on the build host.  Because
3200       #   these files are not distributed they are always rebuilt
3201       #   at make time; they should therefore not lie in the source
3202       #   directory.  One plan was to support this using
3203       #   nodist_info_TEXINFOS or something similar.  (Doing this
3204       #   requires some sanity checks.  For instance Automake should
3205       #   not allow:
3206       #      dist_info_TEXINFOS = foo.texi
3207       #      nodist_foo_TEXINFOS = included.texi
3208       #   because a distributed file should never depend on a
3209       #   non-distributed file.)
3210       #
3211       # * If .texi files are not distributed, then .info files should
3212       #   not be distributed either.  There are also cases where one
3213       #   wants to distribute .texi files, but does not want to
3214       #   distribute the .info files.  For instance the Texinfo package
3215       #   distributes the tool used to build these files; it would
3216       #   be a waste of space to distribute them.  It's not clear
3217       #   which syntax we should use to indicate that .info files should
3218       #   not be distributed.  Akim Demaille suggested that eventually
3219       #   we switch to a new syntax:
3220       #   |  Maybe we should take some inspiration from what's already
3221       #   |  done in the rest of Automake.  Maybe there is too much
3222       #   |  syntactic sugar here, and you want
3223       #   |     nodist_INFO = bar.info
3224       #   |     dist_bar_info_SOURCES = bar.texi
3225       #   |     bar_texi_DEPENDENCIES = foo.texi
3226       #   |  with a bit of magic to have bar.info represent the whole
3227       #   |  bar*info set.  That's a lot more verbose that the current
3228       #   |  situation, but it is # not new, hence the user has less
3229       #   |  to learn.
3230       #   |
3231       #   |  But there is still too much room for meaningless specs:
3232       #   |     nodist_INFO = bar.info
3233       #   |     dist_bar_info_SOURCES = bar.texi
3234       #   |     dist_PS = bar.ps something-written-by-hand.ps
3235       #   |     nodist_bar_ps_SOURCES = bar.texi
3236       #   |     bar_texi_DEPENDENCIES = foo.texi
3237       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3238       #
3239       # Back to the point, it should be clear that in order to support
3240       # non-distributed .info files, we need to build them in the
3241       # build tree, not in the source tree (non-distributed .texi
3242       # files are less of a problem, because we do not output build
3243       # rules for them).  In Automake 1.7 .info build rules have been
3244       # largely cleaned up so that .info files get always build in the
3245       # build tree, even when distributed.  The idea was that
3246       #   (1) if during a VPATH build the .info file was found to be
3247       #       absent or out-of-date (in the source tree or in the
3248       #       build tree), Make would rebuild it in the build tree.
3249       #       If an up-to-date source-tree of the .info file existed,
3250       #       make would not rebuild it in the build tree.
3251       #   (2) having two copies of .info files, one in the source tree
3252       #       and one (newer) in the build tree is not a problem
3253       #       because 'make dist' always pick files in the build tree
3254       #       first.
3255       # However it turned out the be a bad idea for several reasons:
3256       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3257       #     like GNU Make on point (1) above.  These implementations
3258       #     of Make would always rebuild .info files in the build
3259       #     tree, even if such files were up to date in the source
3260       #     tree.  Consequently, it was impossible to perform a VPATH
3261       #     build of a package containing Texinfo files using these
3262       #     Make implementations.
3263       #     (Refer to the Autoconf Manual, section "Limitation of
3264       #     Make", paragraph "VPATH", item "target lookup", for
3265       #     an account of the differences between these
3266       #     implementations.)
3267       #   * The GNU Coding Standards require these files to be built
3268       #     in the source-tree (when they are distributed, that is).
3269       #   * Keeping a fresher copy of distributed files in the
3270       #     build tree can be annoying during development because
3271       #     - if the files is kept under CVS, you really want it
3272       #       to be updated in the source tree
3273       #     - it is confusing that 'make distclean' does not erase
3274       #       all files in the build tree.
3275       #
3276       # Consequently, starting with Automake 1.8, .info files are
3277       # built in the source tree again.  Because we still plan to
3278       # support non-distributed .info files at some point, we
3279       # have a single variable ($INSRC) that controls whether
3280       # the current .info file must be built in the source tree
3281       # or in the build tree.  Actually this variable is switched
3282       # off for .info files that appear to be cleaned; this is
3283       # for backward compatibility with package such as Texinfo,
3284       # which do things like
3285       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3286       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3287       #   # Do not create info files for distribution.
3288       #   dist-info:
3289       # in order not to distribute .info files.
3290       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3291
3292       my $soutdir = '$(srcdir)/' . $outdir;
3293       $outdir = $soutdir if $insrc;
3294
3295       # If user specified file_TEXINFOS, then use that as explicit
3296       # dependency list.
3297       @texi_deps = ();
3298       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3299
3300       my $canonical = canonicalize ($infobase);
3301       if (var ($canonical . "_TEXINFOS"))
3302         {
3303           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3304           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3305         }
3306
3307       my ($dirstamp, @cfiles) =
3308         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3309       push (@texi_cleans, @cfiles);
3310
3311       push (@info_deps_list, $out_file);
3312
3313       # If a vers*.texi file is needed, emit the rule.
3314       if ($vtexi)
3315         {
3316           err_am ("'$vtexi', included in '$texi', "
3317                   . "also included in '$versions{$vtexi}'")
3318             if defined $versions{$vtexi};
3319           $versions{$vtexi} = $texi;
3320
3321           # We number the stamp-vti files.  This is doable since the
3322           # actual names don't matter much.  We only number starting
3323           # with the second one, so that the common case looks nice.
3324           my $vti = ($done ? $done : 'vti');
3325           ++$done;
3326
3327           # This is ugly, but it is our historical practice.
3328           if ($config_aux_dir_set_in_configure_ac)
3329             {
3330               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3331                                             'mdate-sh');
3332             }
3333           else
3334             {
3335               require_file_with_macro (TRUE, 'info_TEXINFOS',
3336                                        FOREIGN, 'mdate-sh');
3337             }
3338
3339           my $conf_dir;
3340           if ($config_aux_dir_set_in_configure_ac)
3341             {
3342               $conf_dir = "$am_config_aux_dir/";
3343             }
3344           else
3345             {
3346               $conf_dir = '$(srcdir)/';
3347             }
3348           $output_rules .= file_contents ('texi-vers',
3349                                           new Automake::Location,
3350                                           TEXI     => $texi,
3351                                           VTI      => $vti,
3352                                           STAMPVTI => "${soutdir}stamp-$vti",
3353                                           VTEXI    => "$soutdir$vtexi",
3354                                           MDDIR    => $conf_dir,
3355                                           DIRSTAMP => $dirstamp);
3356         }
3357     }
3358
3359   # Handle location of texinfo.tex.
3360   my $need_texi_file = 0;
3361   my $texinfodir;
3362   if (var ('TEXINFO_TEX'))
3363     {
3364       # The user defined TEXINFO_TEX so assume he knows what he is
3365       # doing.
3366       $texinfodir = ('$(srcdir)/'
3367                      . dirname (variable_value ('TEXINFO_TEX')));
3368     }
3369   elsif (option 'cygnus')
3370     {
3371       $texinfodir = '$(top_srcdir)/../texinfo';
3372       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3373     }
3374   elsif ($config_aux_dir_set_in_configure_ac)
3375     {
3376       $texinfodir = $am_config_aux_dir;
3377       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3378       $need_texi_file = 2; # so that we require_conf_file later
3379     }
3380   else
3381     {
3382       $texinfodir = '$(srcdir)';
3383       $need_texi_file = 1;
3384     }
3385   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3386
3387   push (@dist_targets, 'dist-info');
3388
3389   if (! option 'no-installinfo')
3390     {
3391       # Make sure documentation is made and installed first.  Use
3392       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3393       # get run twice during "make all".
3394       unshift (@all, '$(INFO_DEPS)');
3395     }
3396
3397   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3398   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3399   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3400   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3401
3402   # This next isn't strictly needed now -- the places that look here
3403   # could easily be changed to look in info_TEXINFOS.  But this is
3404   # probably better, in case noinst_TEXINFOS is ever supported.
3405   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3406
3407   # Do some error checking.  Note that this file is not required
3408   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3409   # up above.
3410   if ($need_texi_file && ! option 'no-texinfo.tex')
3411     {
3412       if ($need_texi_file > 1)
3413         {
3414           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3415                                         'texinfo.tex');
3416         }
3417       else
3418         {
3419           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3420                                    'texinfo.tex');
3421         }
3422     }
3423
3424   return (makefile_wrap ("", "\t  ", @mostly_cleans),
3425           makefile_wrap ("", "\t  ", @texi_cleans),
3426           makefile_wrap ("", "\t  ", @maint_cleans));
3427 }
3428
3429
3430 # handle_texinfo ()
3431 # -----------------
3432 # Handle all Texinfo source.
3433 sub handle_texinfo ()
3434 {
3435   reject_var 'TEXINFOS', "'TEXINFOS' is an anachronism; use 'info_TEXINFOS'";
3436   # FIXME: I think this is an obsolete future feature name.
3437   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3438
3439   my $info_texinfos = var ('info_TEXINFOS');
3440   my ($mostlyclean, $clean, $maintclean) = ('', '', '');
3441   if ($info_texinfos)
3442     {
3443       define_verbose_texinfo;
3444       ($mostlyclean, $clean, $maintclean) = handle_texinfo_helper ($info_texinfos);
3445       chomp $mostlyclean;
3446       chomp $clean;
3447       chomp $maintclean;
3448     }
3449
3450   $output_rules .=  file_contents ('texinfos',
3451                                    new Automake::Location,
3452                                    AM_V_DVIPS    => verbose_flag('DVIPS'),
3453                                    MOSTLYCLEAN   => $mostlyclean,
3454                                    TEXICLEAN     => $clean,
3455                                    MAINTCLEAN    => $maintclean,
3456                                    'LOCAL-TEXIS' => !!$info_texinfos,
3457                                    TEXIQUIET     => verbose_flag('texinfo'));
3458 }
3459
3460
3461 # Handle any man pages.
3462 sub handle_man_pages
3463 {
3464   reject_var 'MANS', "'MANS' is an anachronism; use 'man_MANS'";
3465
3466   # Find all the sections in use.  We do this by first looking for
3467   # "standard" sections, and then looking for any additional
3468   # sections used in man_MANS.
3469   my (%sections, %notrans_sections, %trans_sections,
3470       %notrans_vars, %trans_vars, %notrans_sect_vars, %trans_sect_vars);
3471   # We handle nodist_ for uniformity.  man pages aren't distributed
3472   # by default so it isn't actually very important.
3473   foreach my $npfx ('', 'notrans_')
3474     {
3475       foreach my $pfx ('', 'dist_', 'nodist_')
3476         {
3477           # Add more sections as needed.
3478           foreach my $section ('0'..'9', 'n', 'l')
3479             {
3480               my $varname = $npfx . $pfx . 'man' . $section . '_MANS';
3481               if (var ($varname))
3482                 {
3483                   $sections{$section} = 1;
3484                   $varname = '$(' . $varname . ')';
3485                   if ($npfx eq 'notrans_')
3486                     {
3487                       $notrans_sections{$section} = 1;
3488                       $notrans_sect_vars{$varname} = 1;
3489                     }
3490                   else
3491                     {
3492                       $trans_sections{$section} = 1;
3493                       $trans_sect_vars{$varname} = 1;
3494                     }
3495
3496                   &push_dist_common ($varname)
3497                     if $pfx eq 'dist_';
3498                 }
3499             }
3500
3501           my $varname = $npfx . $pfx . 'man_MANS';
3502           my $var = var ($varname);
3503           if ($var)
3504             {
3505               foreach ($var->value_as_list_recursive)
3506                 {
3507                   # A page like 'foo.1c' goes into man1dir.
3508                   if (/\.([0-9a-z])([a-z]*)$/)
3509                     {
3510                       $sections{$1} = 1;
3511                       if ($npfx eq 'notrans_')
3512                         {
3513                           $notrans_sections{$1} = 1;
3514                         }
3515                       else
3516                         {
3517                           $trans_sections{$1} = 1;
3518                         }
3519                     }
3520                 }
3521
3522               $varname = '$(' . $varname . ')';
3523               if ($npfx eq 'notrans_')
3524                 {
3525                   $notrans_vars{$varname} = 1;
3526                 }
3527               else
3528                 {
3529                   $trans_vars{$varname} = 1;
3530                 }
3531               &push_dist_common ($varname)
3532                 if $pfx eq 'dist_';
3533             }
3534         }
3535     }
3536
3537   return unless %sections;
3538
3539   my @unsorted_deps;
3540
3541   # Build section independent variables.
3542   my $have_notrans = %notrans_vars;
3543   my @notrans_list = sort keys %notrans_vars;
3544   my $have_trans = %trans_vars;
3545   my @trans_list = sort keys %trans_vars;
3546
3547   # Now for each section, generate an install and uninstall rule.
3548   # Sort sections so output is deterministic.
3549   foreach my $section (sort keys %sections)
3550     {
3551       # Build section dependent variables.
3552       my $notrans_mans = $have_notrans || exists $notrans_sections{$section};
3553       my $trans_mans = $have_trans || exists $trans_sections{$section};
3554       my (%notrans_this_sect, %trans_this_sect);
3555       my $expr = 'man' . $section . '_MANS';
3556       foreach my $varname (keys %notrans_sect_vars)
3557         {
3558           if ($varname =~ /$expr/)
3559             {
3560               $notrans_this_sect{$varname} = 1;
3561             }
3562         }
3563       foreach my $varname (keys %trans_sect_vars)
3564         {
3565           if ($varname =~ /$expr/)
3566             {
3567               $trans_this_sect{$varname} = 1;
3568             }
3569         }
3570       my @notrans_sect_list = sort keys %notrans_this_sect;
3571       my @trans_sect_list = sort keys %trans_this_sect;
3572       @unsorted_deps = (keys %notrans_vars, keys %trans_vars,
3573                         keys %notrans_this_sect, keys %trans_this_sect);
3574       my @deps = sort @unsorted_deps;
3575       $output_rules .= &file_contents ('mans',
3576                                        new Automake::Location,
3577                                        SECTION           => $section,
3578                                        DEPS              => "@deps",
3579                                        NOTRANS_MANS      => $notrans_mans,
3580                                        NOTRANS_SECT_LIST => "@notrans_sect_list",
3581                                        HAVE_NOTRANS      => $have_notrans,
3582                                        NOTRANS_LIST      => "@notrans_list",
3583                                        TRANS_MANS        => $trans_mans,
3584                                        TRANS_SECT_LIST   => "@trans_sect_list",
3585                                        HAVE_TRANS        => $have_trans,
3586                                        TRANS_LIST        => "@trans_list");
3587     }
3588
3589   @unsorted_deps  = (keys %notrans_vars, keys %trans_vars,
3590                      keys %notrans_sect_vars, keys %trans_sect_vars);
3591   my @mans = sort @unsorted_deps;
3592   $output_vars .= file_contents ('mans-vars',
3593                                  new Automake::Location,
3594                                  MANS => "@mans");
3595
3596   push (@all, '$(MANS)')
3597     unless option 'no-installman';
3598 }
3599
3600 # Handle DATA variables.
3601 sub handle_data
3602 {
3603     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3604                      'data', 'dataroot', 'doc', 'dvi', 'html', 'pdf',
3605                      'ps', 'sysconf', 'sharedstate', 'localstate',
3606                      'pkgdata', 'lisp', 'noinst', 'check');
3607 }
3608
3609 # Handle TAGS.
3610 sub handle_tags
3611 {
3612     my @tag_deps = ();
3613     my @ctag_deps = ();
3614     my @cscope_deps = ();
3615     if (var ('SUBDIRS'))
3616     {
3617         $output_rules .= ("tags-recursive:\n"
3618                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3619                           # Never fail here if a subdir fails; it
3620                           # isn't important.
3621                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3622                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3623                           . "\tdone\n");
3624         push (@tag_deps, 'tags-recursive');
3625         &depend ('.PHONY', 'tags-recursive');
3626         &depend ('.MAKE', 'tags-recursive');
3627
3628         $output_rules .= ("ctags-recursive:\n"
3629                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3630                           # Never fail here if a subdir fails; it
3631                           # isn't important.
3632                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3633                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3634                           . "\tdone\n");
3635         push (@ctag_deps, 'ctags-recursive');
3636         &depend ('.PHONY', 'ctags-recursive');
3637         &depend ('.MAKE', 'ctags-recursive');
3638
3639         $output_rules .= ("cscopelist-recursive:\n"
3640                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3641                           # Never fail here if a subdir fails; it
3642                           # isn't important.
3643                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3644                           . " && \$(MAKE) \$(AM_MAKEFLAGS) cscopelist); \\\n"
3645                           . "\tdone\n");
3646         push (@cscope_deps, 'cscopelist-recursive');
3647         &depend ('.PHONY', 'cscopelist-recursive');
3648         &depend ('.MAKE', 'cscopelist-recursive');
3649     }
3650
3651     if (&saw_sources_p (1)
3652         || var ('ETAGS_ARGS')
3653         || @tag_deps)
3654     {
3655         my @config;
3656         foreach my $spec (@config_headers)
3657         {
3658             my ($out, @ins) = split_config_file_spec ($spec);
3659             foreach my $in (@ins)
3660               {
3661                 # If the config header source is in this directory,
3662                 # require it.
3663                 push @config, basename ($in)
3664                   if $relative_dir eq dirname ($in);
3665               }
3666         }
3667         $output_rules .= &file_contents ('tags',
3668                                          new Automake::Location,
3669                                          CONFIG    => "@config",
3670                                          TAGSDIRS  => "@tag_deps",
3671                                          CTAGSDIRS => "@ctag_deps",
3672                                          CSCOPEDIRS => "@cscope_deps");
3673
3674         set_seen 'TAGS_DEPENDENCIES';
3675     }
3676     elsif (reject_var ('TAGS_DEPENDENCIES',
3677                        "it doesn't make sense to define 'TAGS_DEPENDENCIES'"
3678                        . " without\nsources or 'ETAGS_ARGS'"))
3679     {
3680     }
3681     else
3682     {
3683         # Every Makefile must define some sort of TAGS rule.
3684         # Otherwise, it would be possible for a top-level "make TAGS"
3685         # to fail because some subdirectory failed.
3686         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3687         # Ditto ctags and cscope.
3688         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3689         $output_rules .= "cscope cscopelist:\n\n";
3690     }
3691 }
3692
3693
3694 # user_phony_rule ($NAME)
3695 # -----------------------
3696 # Return false if rule $NAME does not exist.  Otherwise,
3697 # declare it as phony, complete its definition (in case it is
3698 # conditional), and return its Automake::Rule instance.
3699 sub user_phony_rule ($)
3700 {
3701   my ($name) = @_;
3702   my $rule = rule $name;
3703   if ($rule)
3704     {
3705       depend ('.PHONY', $name);
3706       # Define $NAME in all condition where it is not already defined,
3707       # so that it is always OK to depend on $NAME.
3708       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3709         {
3710           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3711                                   $c, INTERNAL);
3712           $output_rules .= $c->subst_string . "$name:\n";
3713         }
3714     }
3715   return $rule;
3716 }
3717
3718
3719 # $BOOLEAN
3720 # &for_dist_common ($A, $B)
3721 # -------------------------
3722 # Subroutine for &handle_dist: sort files to dist.
3723 #
3724 # We put README first because it then becomes easier to make a
3725 # Usenet-compliant shar file (in these, README must be first).
3726 #
3727 # FIXME: do more ordering of files here.
3728 sub for_dist_common
3729 {
3730     return 0
3731         if $a eq $b;
3732     return -1
3733         if $a eq 'README';
3734     return 1
3735         if $b eq 'README';
3736     return $a cmp $b;
3737 }
3738
3739 # handle_dist
3740 # -----------
3741 # Handle 'dist' target.
3742 sub handle_dist ()
3743 {
3744   # Substitutions for distdir.am
3745   my %transform;
3746
3747   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3748   # no-dist setting: target like 'distclean' or 'maintainer-clean' use it.
3749   my $subdirs = var ('SUBDIRS');
3750   if ($subdirs)
3751     {
3752       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3753       # to all possible directories, and use it.  If DIST_SUBDIRS is
3754       # defined, just use it.
3755
3756       # Note that we check DIST_SUBDIRS first on purpose, so that
3757       # we don't call has_conditional_contents for now reason.
3758       # (In the past one project used so many conditional subdirectories
3759       # that calling has_conditional_contents on SUBDIRS caused
3760       # automake to grow to 150Mb -- this should not happen with
3761       # the current implementation of has_conditional_contents,
3762       # but it's more efficient to avoid the call anyway.)
3763       if (var ('DIST_SUBDIRS'))
3764         {
3765         }
3766       elsif ($subdirs->has_conditional_contents)
3767         {
3768           define_pretty_variable
3769             ('DIST_SUBDIRS', TRUE, INTERNAL,
3770              uniq ($subdirs->value_as_list_recursive));
3771         }
3772       else
3773         {
3774           # We always define this because that is what 'distclean'
3775           # wants.
3776           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3777                                   '$(SUBDIRS)');
3778         }
3779     }
3780
3781   # The remaining definitions are only required when a dist target is used.
3782   return if option 'no-dist';
3783
3784   # At least one of the archive formats must be enabled.
3785   if ($relative_dir eq '.')
3786     {
3787       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3788       $archive_defined ||=
3789         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzip lzma xz);
3790       error (option 'no-dist-gzip',
3791              "no-dist-gzip specified but no dist-* specified,\n"
3792              . "at least one archive format must be enabled")
3793         unless $archive_defined;
3794     }
3795
3796   # Look for common files that should be included in distribution.
3797   # If the aux dir is set, and it does not have a Makefile.am, then
3798   # we check for these files there as well.
3799   my $check_aux = 0;
3800   if ($relative_dir eq '.'
3801       && $config_aux_dir_set_in_configure_ac)
3802     {
3803       if (! &is_make_dir ($config_aux_dir))
3804         {
3805           $check_aux = 1;
3806         }
3807     }
3808   foreach my $cfile (@common_files)
3809     {
3810       if (dir_has_case_matching_file ($relative_dir, $cfile)
3811           # The file might be absent, but if it can be built it's ok.
3812           || rule $cfile)
3813         {
3814           &push_dist_common ($cfile);
3815         }
3816
3817       # Don't use 'elsif' here because a file might meaningfully
3818       # appear in both directories.
3819       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3820         {
3821           &push_dist_common ("$config_aux_dir/$cfile")
3822         }
3823     }
3824
3825   # We might copy elements from $configure_dist_common to
3826   # %dist_common if we think we need to.  If the file appears in our
3827   # directory, we would have discovered it already, so we don't
3828   # check that.  But if the file is in a subdir without a Makefile,
3829   # we want to distribute it here if we are doing '.'.  Ugly!
3830   # Also, in some corner cases, it's possible that the following code
3831   # will cause the same file to appear in the $(DIST_COMMON) variables
3832   # of two distinct Makefiles; but this is not a problem, since the
3833   # 'distdir' target in 'lib/am/distdir.am' can deal with the same
3834   # file being distributed multiple times.
3835   # See also automake bug#9651.
3836   if ($relative_dir eq '.')
3837     {
3838       foreach my $file (split (' ' , $configure_dist_common))
3839         {
3840           my $dir = dirname ($file);
3841           push_dist_common ($file)
3842             if ($dir eq '.' || ! is_make_dir ($dir));
3843         }
3844     }
3845
3846   # Files to distributed.  Don't use ->value_as_list_recursive
3847   # as it recursively expands '$(dist_pkgdata_DATA)' etc.
3848   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3849   @dist_common = uniq (sort for_dist_common (@dist_common));
3850   variable_delete 'DIST_COMMON';
3851   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3852
3853   # Now that we've processed DIST_COMMON, disallow further attempts
3854   # to set it.
3855   $handle_dist_run = 1;
3856
3857   # Scan EXTRA_DIST to see if we need to distribute anything from a
3858   # subdir.  If so, add it to the list.  I didn't want to do this
3859   # originally, but there were so many requests that I finally
3860   # relented.
3861   my $extra_dist = var ('EXTRA_DIST');
3862
3863   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3864   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3865
3866   # If the target 'dist-hook' exists, make sure it is run.  This
3867   # allows users to do random weird things to the distribution
3868   # before it is packaged up.
3869   push (@dist_targets, 'dist-hook')
3870     if user_phony_rule 'dist-hook';
3871   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3872
3873   my $flm = option ('filename-length-max');
3874   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3875
3876   $output_rules .= &file_contents ('distdir',
3877                                    new Automake::Location,
3878                                    %transform,
3879                                    FILENAME_FILTER => $filename_filter);
3880 }
3881
3882
3883 # check_directory ($NAME, $WHERE [, $RELATIVE_DIR = "."])
3884 # -------------------------------------------------------
3885 # Ensure $NAME is a directory (in $RELATIVE_DIR), and that it uses a sane
3886 # name.  Use $WHERE as a location in the diagnostic, if any.
3887 sub check_directory ($$;$)
3888 {
3889   my ($dir, $where, $reldir) = @_;
3890   $reldir = '.' unless defined $reldir;
3891
3892   error $where, "required directory $reldir/$dir does not exist"
3893     unless -d "$reldir/$dir";
3894
3895   # If an 'obj/' directory exists, BSD make will enter it before
3896   # reading 'Makefile'.  Hence the 'Makefile' in the current directory
3897   # will not be read.
3898   #
3899   #  % cat Makefile
3900   #  all:
3901   #          echo Hello
3902   #  % cat obj/Makefile
3903   #  all:
3904   #          echo World
3905   #  % make      # GNU make
3906   #  echo Hello
3907   #  Hello
3908   #  % pmake     # BSD make
3909   #  echo World
3910   #  World
3911   msg ('portability', $where,
3912        "naming a subdirectory 'obj' causes troubles with BSD make")
3913     if $dir eq 'obj';
3914
3915   # 'aux' is probably the most important of the following forbidden name,
3916   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3917   msg ('portability', $where,
3918        "name '$dir' is reserved on W32 and DOS platforms")
3919     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3920 }
3921
3922 # check_directories_in_var ($VARIABLE)
3923 # ------------------------------------
3924 # Recursively check all items in variables $VARIABLE as directories
3925 sub check_directories_in_var ($)
3926 {
3927   my ($var) = @_;
3928   $var->traverse_recursively
3929     (sub
3930      {
3931        my ($var, $val, $cond, $full_cond) = @_;
3932        check_directory ($val, $var->rdef ($cond)->location, $relative_dir);
3933        return ();
3934      },
3935      undef,
3936      skip_ac_subst => 1);
3937 }
3938
3939 # &handle_subdirs ()
3940 # ------------------
3941 # Handle subdirectories.
3942 sub handle_subdirs ()
3943 {
3944   my $subdirs = var ('SUBDIRS');
3945   return
3946     unless $subdirs;
3947
3948   check_directories_in_var $subdirs;
3949
3950   my $dsubdirs = var ('DIST_SUBDIRS');
3951   check_directories_in_var $dsubdirs
3952     if $dsubdirs;
3953
3954   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3955   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3956 }
3957
3958
3959 # ($REGEN, @DEPENDENCIES)
3960 # &scan_aclocal_m4
3961 # ----------------
3962 # If aclocal.m4 creation is automated, return the list of its dependencies.
3963 sub scan_aclocal_m4 ()
3964 {
3965   my $regen_aclocal = 0;
3966
3967   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3968   set_seen 'CONFIGURE_DEPENDENCIES';
3969
3970   if (-f 'aclocal.m4')
3971     {
3972       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3973
3974       my $aclocal = new Automake::XFile "< aclocal.m4";
3975       my $line = $aclocal->getline;
3976       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3977     }
3978
3979   my @ac_deps = ();
3980
3981   if (set_seen ('ACLOCAL_M4_SOURCES'))
3982     {
3983       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3984       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3985                "'ACLOCAL_M4_SOURCES' is obsolete.\n"
3986                . "It should be safe to simply remove it");
3987     }
3988
3989   # Note that it might be possible that aclocal.m4 doesn't exist but
3990   # should be auto-generated.  This case probably isn't very
3991   # important.
3992
3993   return ($regen_aclocal, @ac_deps);
3994 }
3995
3996
3997 # Helper function for substitute_ac_subst_variables.
3998 sub substitute_ac_subst_variables_worker($)
3999 {
4000   my ($token) = @_;
4001   return "\@$token\@" if var $token;
4002   return "\${$token\}";
4003 }
4004
4005 # substitute_ac_subst_variables ($TEXT)
4006 # -------------------------------------
4007 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
4008 # variable.
4009 sub substitute_ac_subst_variables ($)
4010 {
4011   my ($text) = @_;
4012   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
4013   return $text;
4014 }
4015
4016 # @DEPENDENCIES
4017 # &prepend_srcdir (@INPUTS)
4018 # -------------------------
4019 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
4020 # if an input file has a directory part the same as the current
4021 # directory, then the directory part is simply replaced by $(srcdir).
4022 # But if the directory part is different, then $(top_srcdir) is
4023 # prepended.
4024 sub prepend_srcdir (@)
4025 {
4026   my (@inputs) = @_;
4027   my @newinputs;
4028
4029   foreach my $single (@inputs)
4030     {
4031       if (dirname ($single) eq $relative_dir)
4032         {
4033           push (@newinputs, '$(srcdir)/' . basename ($single));
4034         }
4035       else
4036         {
4037           push (@newinputs, '$(top_srcdir)/' . $single);
4038         }
4039     }
4040   return @newinputs;
4041 }
4042
4043 # @DEPENDENCIES
4044 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
4045 # ---------------------------------------------------
4046 # Compute a list of dependencies appropriate for the rebuild
4047 # rule of
4048 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
4049 # Also distribute $INPUTs which are not built by another AC_CONFIG_FOOs.
4050 sub rewrite_inputs_into_dependencies ($@)
4051 {
4052   my ($file, @inputs) = @_;
4053   my @res = ();
4054
4055   for my $i (@inputs)
4056     {
4057       # We cannot create dependencies on shell variables.
4058       next if (substitute_ac_subst_variables $i) =~ /\$/;
4059
4060       if (exists $ac_config_files_location{$i} && $i ne $file)
4061         {
4062           my $di = dirname $i;
4063           if ($di eq $relative_dir)
4064             {
4065               $i = basename $i;
4066             }
4067           # In the top-level Makefile we do not use $(top_builddir), because
4068           # we are already there, and since the targets are built without
4069           # a $(top_builddir), it helps BSD Make to match them with
4070           # dependencies.
4071           elsif ($relative_dir ne '.')
4072             {
4073               $i = '$(top_builddir)/' . $i;
4074             }
4075         }
4076       else
4077         {
4078           msg ('error', $ac_config_files_location{$file},
4079                "required file '$i' not found")
4080             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
4081           ($i) = prepend_srcdir ($i);
4082           push_dist_common ($i);
4083         }
4084       push @res, $i;
4085     }
4086   return @res;
4087 }
4088
4089
4090
4091 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
4092 # ------------------------------------------------------------------
4093 # Handle remaking and configure stuff.
4094 # We need the name of the input file, to do proper remaking rules.
4095 sub handle_configure ($$$@)
4096 {
4097   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
4098
4099   prog_error 'empty @inputs'
4100     unless @inputs;
4101
4102   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
4103                                                             $makefile_in);
4104   my $rel_makefile = basename $makefile;
4105
4106   my $colon_infile = ':' . join (':', @inputs);
4107   $colon_infile = '' if $colon_infile eq ":$makefile.in";
4108   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
4109   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
4110   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
4111                           @configure_deps, @aclocal_m4_deps,
4112                           '$(top_srcdir)/' . $configure_ac);
4113   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
4114   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
4115   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
4116                           @configuredeps);
4117
4118   my $automake_options = '--' . (global_option 'cygnus' ? 'cygnus' : $strictness_name)
4119                          . (global_option 'no-dependencies' ? ' --ignore-deps' : '');
4120
4121   $output_rules .= file_contents
4122     ('configure',
4123      new Automake::Location,
4124      MAKEFILE              => $rel_makefile,
4125      'MAKEFILE-DEPS'       => "@rewritten",
4126      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
4127      'MAKEFILE-IN'         => $rel_makefile_in,
4128      'HAVE-MAKEFILE-IN-DEPS' => (@include_stack > 0),
4129      'MAKEFILE-IN-DEPS'    => "@include_stack",
4130      'MAKEFILE-AM'         => $rel_makefile_am,
4131      'AUTOMAKE-OPTIONS'    => $automake_options,
4132      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
4133      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
4134      VERBOSE               => verbose_flag ('GEN'));
4135
4136   if ($relative_dir eq '.')
4137     {
4138       &push_dist_common ('acconfig.h')
4139         if -f 'acconfig.h';
4140     }
4141
4142   # If we have a configure header, require it.
4143   my $hdr_index = 0;
4144   my @distclean_config;
4145   foreach my $spec (@config_headers)
4146     {
4147       $hdr_index += 1;
4148       # $CONFIG_H_PATH: config.h from top level.
4149       my ($config_h_path, @ins) = split_config_file_spec ($spec);
4150       my $config_h_dir = dirname ($config_h_path);
4151
4152       # If the header is in the current directory we want to build
4153       # the header here.  Otherwise, if we're at the topmost
4154       # directory and the header's directory doesn't have a
4155       # Makefile, then we also want to build the header.
4156       if ($relative_dir eq $config_h_dir
4157           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
4158         {
4159           my ($cn_sans_dir, $stamp_dir);
4160           if ($relative_dir eq $config_h_dir)
4161             {
4162               $cn_sans_dir = basename ($config_h_path);
4163               $stamp_dir = '';
4164             }
4165           else
4166             {
4167               $cn_sans_dir = $config_h_path;
4168               if ($config_h_dir eq '.')
4169                 {
4170                   $stamp_dir = '';
4171                 }
4172               else
4173                 {
4174                   $stamp_dir = $config_h_dir . '/';
4175                 }
4176             }
4177
4178           # This will also distribute all inputs.
4179           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
4180
4181           # Cannot define rebuild rules for filenames with shell variables.
4182           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4183
4184           # Header defined in this directory.
4185           my @files;
4186           if (-f $config_h_path . '.top')
4187             {
4188               push (@files, "$cn_sans_dir.top");
4189             }
4190           if (-f $config_h_path . '.bot')
4191             {
4192               push (@files, "$cn_sans_dir.bot");
4193             }
4194
4195           push_dist_common (@files);
4196
4197           # For now, acconfig.h can only appear in the top srcdir.
4198           if (-f 'acconfig.h')
4199             {
4200               push (@files, '$(top_srcdir)/acconfig.h');
4201             }
4202
4203           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4204           $output_rules .=
4205             file_contents ('remake-hdr',
4206                            new Automake::Location,
4207                            FILES            => "@files",
4208                            CONFIG_H         => $cn_sans_dir,
4209                            CONFIG_HIN       => $ins[0],
4210                            CONFIG_H_DEPS    => "@ins",
4211                            CONFIG_H_PATH    => $config_h_path,
4212                            STAMP            => "$stamp");
4213
4214           push @distclean_config, $cn_sans_dir, $stamp;
4215         }
4216     }
4217
4218   $output_rules .= file_contents ('clean-hdr',
4219                                   new Automake::Location,
4220                                   FILES => "@distclean_config")
4221     if @distclean_config;
4222
4223   # Distribute and define mkinstalldirs only if it is already present
4224   # in the package, for backward compatibility (some people may still
4225   # use $(mkinstalldirs)).
4226   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4227   if (-f $mkidpath)
4228     {
4229       # Use require_file so that any existing script gets updated
4230       # by --force-missing.
4231       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4232       define_variable ('mkinstalldirs',
4233                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4234     }
4235   else
4236     {
4237       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4238       # at least one argument, and $(mkinstalldirs) used to work
4239       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4240       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4241     }
4242
4243   reject_var ('CONFIG_HEADER',
4244               "'CONFIG_HEADER' is an anachronism; now determined "
4245               . "automatically\nfrom '$configure_ac'");
4246
4247   my @config_h;
4248   foreach my $spec (@config_headers)
4249     {
4250       my ($out, @ins) = split_config_file_spec ($spec);
4251       # Generate CONFIG_HEADER define.
4252       if ($relative_dir eq dirname ($out))
4253         {
4254           push @config_h, basename ($out);
4255         }
4256       else
4257         {
4258           push @config_h, "\$(top_builddir)/$out";
4259         }
4260     }
4261   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4262     if @config_h;
4263
4264   # Now look for other files in this directory which must be remade
4265   # by config.status, and generate rules for them.
4266   my @actual_other_files = ();
4267   # These get cleaned only in a VPATH build.
4268   my @actual_other_vpath_files = ();
4269   foreach my $lfile (@other_input_files)
4270     {
4271       my $file;
4272       my @inputs;
4273       if ($lfile =~ /^([^:]*):(.*)$/)
4274         {
4275           # This is the ":" syntax of AC_OUTPUT.
4276           $file = $1;
4277           @inputs = split (':', $2);
4278         }
4279       else
4280         {
4281           # Normal usage.
4282           $file = $lfile;
4283           @inputs = $file . '.in';
4284         }
4285
4286       # Automake files should not be stored in here, but in %MAKE_LIST.
4287       prog_error ("$lfile in \@other_input_files\n"
4288                   . "\@other_input_files = (@other_input_files)")
4289         if -f $file . '.am';
4290
4291       my $local = basename ($file);
4292
4293       # We skip files that aren't in this directory.  However, if
4294       # the file's directory does not have a Makefile, and we are
4295       # currently doing '.', then we create a rule to rebuild the
4296       # file in the subdir.
4297       my $fd = dirname ($file);
4298       if ($fd ne $relative_dir)
4299         {
4300           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4301             {
4302               $local = $file;
4303             }
4304           else
4305             {
4306               next;
4307             }
4308         }
4309
4310       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4311
4312       # Cannot output rules for shell variables.
4313       next if (substitute_ac_subst_variables $local) =~ /\$/;
4314
4315       my $condstr = '';
4316       my $cond = $ac_config_files_condition{$lfile};
4317       if (defined $cond)
4318         {
4319           $condstr = $cond->subst_string;
4320           Automake::Rule::define ($local, $configure_ac, RULE_AUTOMAKE, $cond,
4321                                   $ac_config_files_location{$file});
4322         }
4323       $output_rules .= ($condstr . $local . ': '
4324                         . '$(top_builddir)/config.status '
4325                         . "@rewritten_inputs\n"
4326                         . $condstr . "\t"
4327                         . 'cd $(top_builddir) && '
4328                         . '$(SHELL) ./config.status '
4329                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4330                         . '$@'
4331                         . "\n");
4332       push (@actual_other_files, $local);
4333     }
4334
4335   # For links we should clean destinations and distribute sources.
4336   foreach my $spec (@config_links)
4337     {
4338       my ($link, $file) = split /:/, $spec;
4339       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4340       # the DEST:SRC form.
4341       next unless $file;
4342       my $where = $ac_config_files_location{$link};
4343
4344       # Skip destinations that contain shell variables.
4345       if ((substitute_ac_subst_variables $link) !~ /\$/)
4346         {
4347           # We skip links that aren't in this directory.  However, if
4348           # the link's directory does not have a Makefile, and we are
4349           # currently doing '.', then we add the link to CONFIG_CLEAN_FILES
4350           # in '.'s Makefile.in.
4351           my $local = basename ($link);
4352           my $fd = dirname ($link);
4353           if ($fd ne $relative_dir)
4354             {
4355               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4356                 {
4357                   $local = $link;
4358                 }
4359               else
4360                 {
4361                   $local = undef;
4362                 }
4363             }
4364           if ($file ne $link)
4365             {
4366               push @actual_other_files, $local if $local;
4367             }
4368           else
4369             {
4370               push @actual_other_vpath_files, $local if $local;
4371             }
4372         }
4373
4374       # Do not process sources that contain shell variables.
4375       if ((substitute_ac_subst_variables $file) !~ /\$/)
4376         {
4377           my $fd = dirname ($file);
4378
4379           # We distribute files that are in this directory.
4380           # At the top-level ('.') we also distribute files whose
4381           # directory does not have a Makefile.
4382           if (($fd eq $relative_dir)
4383               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4384             {
4385               # The following will distribute $file as a side-effect when
4386               # it is appropriate (i.e., when $file is not already an output).
4387               # We do not need the result, just the side-effect.
4388               rewrite_inputs_into_dependencies ($link, $file);
4389             }
4390         }
4391     }
4392
4393   # These files get removed by "make distclean".
4394   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4395                           @actual_other_files);
4396   define_pretty_variable ('CONFIG_CLEAN_VPATH_FILES', TRUE, INTERNAL,
4397                           @actual_other_vpath_files);
4398 }
4399
4400 # Handle C headers.
4401 sub handle_headers
4402 {
4403     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4404                              'oldinclude', 'pkginclude',
4405                              'noinst', 'check');
4406     foreach (@r)
4407     {
4408       next unless $_->[1] =~ /\..*$/;
4409       &saw_extension ($&);
4410     }
4411 }
4412
4413 sub handle_gettext
4414 {
4415   return if ! $seen_gettext || $relative_dir ne '.';
4416
4417   my $subdirs = var 'SUBDIRS';
4418
4419   if (! $subdirs)
4420     {
4421       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4422       return;
4423     }
4424
4425   # Perform some sanity checks to help users get the right setup.
4426   # We disable these tests when po/ doesn't exist in order not to disallow
4427   # unusual gettext setups.
4428   #
4429   # Bruno Haible:
4430   # | The idea is:
4431   # |
4432   # |  1) If a package doesn't have a directory po/ at top level, it
4433   # |     will likely have multiple po/ directories in subpackages.
4434   # |
4435   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4436   # |     is used without 'external'. It is also useful to warn for the
4437   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4438   # |     warnings apply only to the usual layout of packages, therefore
4439   # |     they should both be disabled if no po/ directory is found at
4440   # |     top level.
4441
4442   if (-d 'po')
4443     {
4444       my @subdirs = $subdirs->value_as_list_recursive;
4445
4446       msg_var ('syntax', $subdirs,
4447                "AM_GNU_GETTEXT used but 'po' not in SUBDIRS")
4448         if ! grep ($_ eq 'po', @subdirs);
4449
4450       # intl/ is not required when AM_GNU_GETTEXT is called with the
4451       # 'external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4452       msg_var ('syntax', $subdirs,
4453                "AM_GNU_GETTEXT used but 'intl' not in SUBDIRS")
4454         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4455             && ! grep ($_ eq 'intl', @subdirs));
4456
4457       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4458       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4459       msg_var ('syntax', $subdirs,
4460                "'intl' should not be in SUBDIRS when "
4461                . "AM_GNU_GETTEXT([external]) is used")
4462         if ($seen_gettext_external && ! $seen_gettext_intl
4463             && grep ($_ eq 'intl', @subdirs));
4464     }
4465
4466   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4467 }
4468
4469 # Handle footer elements.
4470 sub handle_footer
4471 {
4472     reject_rule ('.SUFFIXES',
4473                  "use variable 'SUFFIXES', not target '.SUFFIXES'");
4474
4475     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4476     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4477     # anything else, by sticking it right after the default: target.
4478     $output_header .= ".SUFFIXES:\n";
4479     my $suffixes = var 'SUFFIXES';
4480     my @suffixes = Automake::Rule::suffixes;
4481     if (@suffixes || $suffixes)
4482     {
4483         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4484         # the output remains consistent.  However, $(SUFFIXES) is
4485         # always at the start of the list, unsorted.  This is done
4486         # because make will choose rules depending on the ordering of
4487         # suffixes, and this lets the user have some control.  Push
4488         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4489         # do not like variable substitutions on the .SUFFIXES line.
4490         my @user_suffixes = ($suffixes
4491                              ? $suffixes->value_as_list_recursive : ());
4492
4493         my %suffixes = map { $_ => 1 } @suffixes;
4494         delete @suffixes{@user_suffixes};
4495
4496         $output_header .= (".SUFFIXES: "
4497                            . join (' ', @user_suffixes, sort keys %suffixes)
4498                            . "\n");
4499     }
4500
4501     $output_trailer .= file_contents ('footer', new Automake::Location);
4502 }
4503
4504
4505 # Generate 'make install' rules.
4506 sub handle_install ()
4507 {
4508   $output_rules .= &file_contents
4509     ('install',
4510      new Automake::Location,
4511      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4512                              ? (" \$(BUILT_SOURCES)\n"
4513                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4514                              : ''),
4515      'installdirs-local' => (user_phony_rule 'installdirs-local'
4516                              ? ' installdirs-local' : ''),
4517      am__installdirs => variable_value ('am__installdirs') || '');
4518 }
4519
4520
4521 # Deal with all and all-am.
4522 sub handle_all ($)
4523 {
4524     my ($makefile) = @_;
4525
4526     # Output 'all-am'.
4527
4528     # Put this at the beginning for the sake of non-GNU makes.  This
4529     # is still wrong if these makes can run parallel jobs.  But it is
4530     # right enough.
4531     unshift (@all, basename ($makefile));
4532
4533     foreach my $spec (@config_headers)
4534       {
4535         my ($out, @ins) = split_config_file_spec ($spec);
4536         push (@all, basename ($out))
4537           if dirname ($out) eq $relative_dir;
4538       }
4539
4540     # Install 'all' hooks.
4541     push (@all, "all-local")
4542       if user_phony_rule "all-local";
4543
4544     &pretty_print_rule ("all-am:", "\t\t", @all);
4545     &depend ('.PHONY', 'all-am', 'all');
4546
4547
4548     # Output 'all'.
4549
4550     my @local_headers = ();
4551     push @local_headers, '$(BUILT_SOURCES)'
4552       if var ('BUILT_SOURCES');
4553     foreach my $spec (@config_headers)
4554       {
4555         my ($out, @ins) = split_config_file_spec ($spec);
4556         push @local_headers, basename ($out)
4557           if dirname ($out) eq $relative_dir;
4558       }
4559
4560     if (@local_headers)
4561       {
4562         # We need to make sure config.h is built before we recurse.
4563         # We also want to make sure that built sources are built
4564         # before any ordinary 'all' targets are run.  We can't do this
4565         # by changing the order of dependencies to the "all" because
4566         # that breaks when using parallel makes.  Instead we handle
4567         # things explicitly.
4568         $output_all .= ("all: @local_headers"
4569                         . "\n\t"
4570                         . '$(MAKE) $(AM_MAKEFLAGS) '
4571                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4572                         . "\n\n");
4573         depend ('.MAKE', 'all');
4574       }
4575     else
4576       {
4577         $output_all .= "all: " . (var ('SUBDIRS')
4578                                   ? 'all-recursive' : 'all-am') . "\n\n";
4579       }
4580 }
4581
4582
4583 # &do_check_merge_target ()
4584 # -------------------------
4585 # Handle check merge target specially.
4586 sub do_check_merge_target ()
4587 {
4588   # Include user-defined local form of target.
4589   push @check_tests, 'check-local'
4590     if user_phony_rule 'check-local';
4591
4592   # In --cygnus mode, check doesn't depend on all.
4593   if (option 'cygnus')
4594     {
4595       # Just run the local check rules.
4596       pretty_print_rule ('check-am:', "\t\t", @check);
4597     }
4598   else
4599     {
4600       # The check target must depend on the local equivalent of
4601       # 'all', to ensure all the primary targets are built.  Then it
4602       # must build the local check rules.
4603       $output_rules .= "check-am: all-am\n";
4604       if (@check)
4605         {
4606           pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4607                              @check);
4608           depend ('.MAKE', 'check-am');
4609         }
4610     }
4611   if (@check_tests)
4612     {
4613       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4614                          @check_tests);
4615       depend ('.MAKE', 'check-am');
4616     }
4617
4618   depend '.PHONY', 'check', 'check-am';
4619   # Handle recursion.  We have to honor BUILT_SOURCES like for 'all:'.
4620   $output_rules .= ("check: "
4621                     . (var ('BUILT_SOURCES')
4622                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4623                        : '')
4624                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4625                     . "\n");
4626   depend ('.MAKE', 'check')
4627     if var ('BUILT_SOURCES');
4628 }
4629
4630 # handle_clean ($MAKEFILE)
4631 # ------------------------
4632 # Handle all 'clean' targets.
4633 sub handle_clean ($)
4634 {
4635   my ($makefile) = @_;
4636
4637   # Clean the files listed in user variables if they exist.
4638   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4639     if var ('MOSTLYCLEANFILES');
4640   $clean_files{'$(CLEANFILES)'} = CLEAN
4641     if var ('CLEANFILES');
4642   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4643     if var ('DISTCLEANFILES');
4644   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4645     if var ('MAINTAINERCLEANFILES');
4646
4647   # Built sources are automatically removed by maintainer-clean.
4648   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4649     if var ('BUILT_SOURCES');
4650
4651   # Compute a list of "rm"s to run for each target.
4652   my %rms = (MOSTLY_CLEAN, [],
4653              CLEAN, [],
4654              DIST_CLEAN, [],
4655              MAINTAINER_CLEAN, []);
4656
4657   foreach my $file (keys %clean_files)
4658     {
4659       my $when = $clean_files{$file};
4660       prog_error 'invalid entry in %clean_files'
4661         unless exists $rms{$when};
4662
4663       my $rm = "rm -f $file";
4664       # If file is a variable, make sure when don't call 'rm -f' without args.
4665       $rm ="test -z \"$file\" || $rm"
4666         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4667
4668       push @{$rms{$when}}, "\t-$rm\n";
4669     }
4670
4671   $output_rules .= &file_contents
4672     ('clean',
4673      new Automake::Location,
4674      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4675      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4676      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4677      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4678      MAKEFILE             => basename $makefile,
4679      );
4680 }
4681
4682
4683 # &target_cmp ($A, $B)
4684 # --------------------
4685 # Subroutine for &handle_factored_dependencies to let '.PHONY' and
4686 # other '.TARGETS' be last.
4687 sub target_cmp
4688 {
4689   return 0 if $a eq $b;
4690
4691   my $a1 = substr ($a, 0, 1);
4692   my $b1 = substr ($b, 0, 1);
4693   if ($a1 ne $b1)
4694     {
4695       return -1 if $b1 eq '.';
4696       return 1 if $a1 eq '.';
4697     }
4698   return $a cmp $b;
4699 }
4700
4701
4702 # &handle_factored_dependencies ()
4703 # --------------------------------
4704 # Handle everything related to gathered targets.
4705 sub handle_factored_dependencies
4706 {
4707   # Reject bad hooks.
4708   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4709                      'uninstall-exec-local', 'uninstall-exec-hook',
4710                      'uninstall-dvi-local',
4711                      'uninstall-html-local',
4712                      'uninstall-info-local',
4713                      'uninstall-pdf-local',
4714                      'uninstall-ps-local')
4715     {
4716       my $x = $utarg;
4717       $x =~ s/-.*-/-/;
4718       reject_rule ($utarg, "use '$x', not '$utarg'");
4719     }
4720
4721   reject_rule ('install-local',
4722                "use 'install-data-local' or 'install-exec-local', "
4723                . "not 'install-local'");
4724
4725   reject_rule ('install-hook',
4726                "use 'install-data-hook' or 'install-exec-hook', "
4727                . "not 'install-hook'");
4728
4729   # Install the -local hooks.
4730   foreach (keys %dependencies)
4731     {
4732       # Hooks are installed on the -am targets.
4733       s/-am$// or next;
4734       depend ("$_-am", "$_-local")
4735         if user_phony_rule "$_-local";
4736     }
4737
4738   # Install the -hook hooks.
4739   # FIXME: Why not be as liberal as we are with -local hooks?
4740   foreach ('install-exec', 'install-data', 'uninstall')
4741     {
4742       if (user_phony_rule "$_-hook")
4743         {
4744           depend ('.MAKE', "$_-am");
4745           register_action("$_-am",
4746                           ("\t\@\$(NORMAL_INSTALL)\n"
4747                            . "\t\$(MAKE) \$(AM_MAKEFLAGS) $_-hook"));
4748         }
4749     }
4750
4751   # All the required targets are phony.
4752   depend ('.PHONY', keys %required_targets);
4753
4754   # Actually output gathered targets.
4755   foreach (sort target_cmp keys %dependencies)
4756     {
4757       # If there is nothing about this guy, skip it.
4758       next
4759         unless (@{$dependencies{$_}}
4760                 || $actions{$_}
4761                 || $required_targets{$_});
4762
4763       # Define gathered targets in undefined conditions.
4764       # FIXME: Right now we must handle .PHONY as an exception,
4765       # because people write things like
4766       #    .PHONY: myphonytarget
4767       # to append dependencies.  This would not work if Automake
4768       # refrained from defining its own .PHONY target as it does
4769       # with other overridden targets.
4770       # Likewise for '.MAKE'.
4771       my @undefined_conds = (TRUE,);
4772       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4773         {
4774           @undefined_conds =
4775             Automake::Rule::define ($_, 'internal',
4776                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4777         }
4778       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4779       foreach my $cond (@undefined_conds)
4780         {
4781           my $condstr = $cond->subst_string;
4782           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4783           $output_rules .= $actions{$_} if defined $actions{$_};
4784           $output_rules .= "\n";
4785         }
4786     }
4787 }
4788
4789
4790 # &handle_tests_dejagnu ()
4791 # ------------------------
4792 sub handle_tests_dejagnu
4793 {
4794     push (@check_tests, 'check-DEJAGNU');
4795     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4796 }
4797
4798 sub handle_per_suffix_test
4799 {
4800   my ($test_suffix, %transform) = @_;
4801   my ($pfx, $generic, $parallel_tests_option, $am_exeext);
4802   prog_error ("called with 'parallel-tests' option not set")
4803     unless $parallel_tests_option = option 'parallel-tests';
4804   if ($test_suffix eq '')
4805     {
4806       $pfx = '';
4807       $generic = 0;
4808       $am_exeext = 'FALSE';
4809     }
4810   else
4811     {
4812       prog_error ("test suffix '$test_suffix' lacks leading dot")
4813         unless $test_suffix =~ m/^\.(.*)/;
4814       $pfx = uc ($1) . '_';
4815       $generic = 1;
4816       $am_exeext = exists $configure_vars{'EXEEXT'} ? 'am__EXEEXT'
4817                                                     : 'FALSE';
4818     }
4819   # The "test driver" program, deputed to handle tests protocol used by
4820   # test scripts.  By default, it's assumed that no protocol is used,
4821   # so we fall back to the old "parallel-tests" behaviour, implemented
4822   # by the 'test-driver' auxiliary script.
4823   if (! var "${pfx}LOG_DRIVER")
4824     {
4825       require_conf_file ($parallel_tests_option->{position}, FOREIGN,
4826                         'test-driver');
4827       define_variable ("${pfx}LOG_DRIVER",
4828                        "\$(SHELL) $am_config_aux_dir/test-driver",
4829                        INTERNAL);
4830     }
4831   my $driver = '$(' . $pfx . 'LOG_DRIVER)';
4832   my $driver_flags = '$(AM_' . $pfx . 'LOG_DRIVER_FLAGS)'
4833                        . ' $(' . $pfx . 'LOG_DRIVER_FLAGS)';
4834   my $compile = "${pfx}LOG_COMPILE";
4835   define_variable ($compile,
4836                    '$(' . $pfx . 'LOG_COMPILER)'
4837                       . ' $(AM_' .  $pfx . 'LOG_FLAGS)'
4838                       . ' $(' . $pfx . 'LOG_FLAGS)',
4839                      INTERNAL);
4840   $output_rules .= file_contents ('check2', new Automake::Location,
4841                                    GENERIC => $generic,
4842                                    DRIVER => $driver,
4843                                    DRIVER_FLAGS => $driver_flags,
4844                                    COMPILE => '$(' . $compile . ')',
4845                                    EXT => $test_suffix,
4846                                    am__EXEEXT => $am_exeext,
4847                                    %transform);
4848 }
4849
4850 # is_valid_test_extension ($EXT)
4851 # ------------------------------
4852 # Return true if $EXT can appear in $(TEST_EXTENSIONS), return false
4853 # otherwise.
4854 sub is_valid_test_extension ($)
4855 {
4856   my $ext = shift;
4857   return 1
4858     if ($ext =~ /^\.[a-zA-Z_][a-zA-Z0-9_]*$/);
4859   return 1
4860     if (exists $configure_vars{'EXEEXT'} && $ext eq subst ('EXEEXT'));
4861   return 0;
4862 }
4863
4864 # Handle TESTS variable and other checks.
4865 sub handle_tests
4866 {
4867   if (option 'dejagnu')
4868     {
4869       &handle_tests_dejagnu;
4870     }
4871   else
4872     {
4873       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4874         {
4875           reject_var ($c, "'$c' defined but 'dejagnu' not in "
4876                       . "'AUTOMAKE_OPTIONS'");
4877         }
4878     }
4879
4880   if (var ('TESTS'))
4881     {
4882       push (@check_tests, 'check-TESTS');
4883       my $check_deps = "@check";
4884       $output_rules .= &file_contents ('check', new Automake::Location,
4885                                        COLOR => !! option 'color-tests',
4886                                        PARALLEL_TESTS => !! option 'parallel-tests',
4887                                        CHECK_DEPS => $check_deps);
4888
4889       # Tests that are known programs should have $(EXEEXT) appended.
4890       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4891       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4892       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4893         if (var ('XFAIL_TESTS'));
4894
4895       if (my $parallel_tests = option 'parallel-tests')
4896         {
4897           define_variable ('TEST_SUITE_LOG', 'test-suite.log', INTERNAL);
4898           my $suff = '.test';
4899           my $at_exeext = '';
4900           my $handle_exeext = exists $configure_vars{'EXEEXT'};
4901           if ($handle_exeext)
4902             {
4903               $at_exeext = subst ('EXEEXT');
4904               $suff = $at_exeext  . ' ' . $suff;
4905             }
4906           if (! var 'TEST_EXTENSIONS')
4907             {
4908               define_variable ('TEST_EXTENSIONS', $suff, INTERNAL);
4909             }
4910           my $var = var 'TEST_EXTENSIONS';
4911           # Currently, we are not able to deal with conditional contents
4912           # in TEST_EXTENSIONS.
4913           if ($var->has_conditional_contents)
4914            {
4915              msg_var 'unsupported', $var,
4916                      "'TEST_EXTENSIONS' cannot have conditional contents";
4917            }
4918           my @test_suffixes = $var->value_as_list_recursive;
4919           if ((my @invalid_test_suffixes =
4920                   grep { !is_valid_test_extension $_ } @test_suffixes) > 0)
4921             {
4922               error $var->rdef (TRUE)->location,
4923                     "invalid test extensions: @invalid_test_suffixes";
4924             }
4925           @test_suffixes = grep { is_valid_test_extension $_ } @test_suffixes;
4926           if ($handle_exeext)
4927             {
4928               unshift (@test_suffixes, $at_exeext)
4929                 unless $test_suffixes[0] eq $at_exeext;
4930             }
4931           unshift (@test_suffixes, '');
4932
4933           transform_variable_recursively
4934             ('TESTS', 'TEST_LOGS', 'am__testlogs', 1, INTERNAL,
4935               sub {
4936                 my ($subvar, $val, $cond, $full_cond) = @_;
4937                 my $obj = $val;
4938                 return $obj
4939                   if $val =~ /^\@.*\@$/;
4940                 $obj =~ s/\$\(EXEEXT\)$//o;
4941
4942                 if ($val =~ /(\$\((top_)?srcdir\))\//o)
4943                   {
4944                     msg ('error', $subvar->rdef ($cond)->location,
4945                          "parallel-tests: using '$1' in TESTS is currently broken: '$val'");
4946                   }
4947
4948                 foreach my $test_suffix (@test_suffixes)
4949                   {
4950                     next
4951                       if $test_suffix eq $at_exeext || $test_suffix eq '';
4952                     return substr ($obj, 0, length ($obj) - length ($test_suffix)) . '.log'
4953                       if substr ($obj, - length ($test_suffix)) eq $test_suffix;
4954                   }
4955                 my $base = $obj;
4956                 $obj .= '.log';
4957                 handle_per_suffix_test ('',
4958                                         OBJ => $obj,
4959                                         BASE => $base,
4960                                         SOURCE => $val);
4961                 return $obj;
4962               });
4963
4964           my $nhelper=1;
4965           my $prev = 'TESTS';
4966           my $post = '';
4967           my $last_suffix = $test_suffixes[$#test_suffixes];
4968           my $cur = '';
4969           foreach my $test_suffix (@test_suffixes)
4970             {
4971               if ($test_suffix eq $last_suffix)
4972                 {
4973                   $cur = 'TEST_LOGS';
4974                 }
4975               else
4976                 {
4977                   $cur = 'am__test_logs' . $nhelper;
4978                 }
4979               define_variable ($cur,
4980                 '$(' . $prev . ':' . $test_suffix . $post . '=.log)', INTERNAL);
4981               $post = '.log';
4982               $prev = $cur;
4983               $nhelper++;
4984               if ($test_suffix ne $at_exeext && $test_suffix ne '')
4985                 {
4986                   handle_per_suffix_test ($test_suffix,
4987                                           OBJ => '',
4988                                           BASE => '$*',
4989                                           SOURCE => '$<');
4990                 }
4991             }
4992           $clean_files{'$(TEST_LOGS)'} = MOSTLY_CLEAN;
4993           $clean_files{'$(TEST_LOGS:.log=.trs)'} = MOSTLY_CLEAN;
4994           $clean_files{'$(TEST_SUITE_LOG)'} = MOSTLY_CLEAN;
4995         }
4996     }
4997 }
4998
4999 # Handle Emacs Lisp.
5000 sub handle_emacs_lisp
5001 {
5002   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
5003                                  'lisp', 'noinst');
5004
5005   return if ! @elfiles;
5006
5007   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
5008                           map { $_->[1] } @elfiles);
5009   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
5010                           '$(am__ELFILES:.el=.elc)');
5011   # This one can be overridden by users.
5012   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
5013
5014   push @all, '$(ELCFILES)';
5015
5016   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
5017                      'EMACS', 'lispdir');
5018   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
5019   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
5020 }
5021
5022 # Handle Python
5023 sub handle_python
5024 {
5025   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
5026                                  'noinst');
5027   return if ! @pyfiles;
5028
5029   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
5030   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
5031   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
5032 }
5033
5034 # Handle Java.
5035 sub handle_java
5036 {
5037     my @sourcelist = &am_install_var ('-candist',
5038                                       'java', 'JAVA',
5039                                       'noinst', 'check');
5040     return if ! @sourcelist;
5041
5042     my @prefixes = am_primary_prefixes ('JAVA', 1,
5043                                         'noinst', 'check');
5044
5045     my $dir;
5046     my @java_sources = ();
5047     foreach my $prefix (@prefixes)
5048       {
5049         (my $curs = $prefix) =~ s/^(?:nobase_)?(?:dist_|nodist_)?//;
5050
5051         next
5052           if $curs eq 'EXTRA';
5053
5054         push @java_sources, '$(' . $prefix . '_JAVA' . ')';
5055
5056         if (defined $dir)
5057           {
5058             err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
5059              unless $curs eq $dir;
5060           }
5061
5062         $dir = $curs;
5063       }
5064
5065     define_pretty_variable ('am__java_sources', TRUE, INTERNAL,
5066                             "@java_sources");
5067
5068     if ($dir eq 'check')
5069       {
5070         push (@check, "class$dir.stamp");
5071       }
5072     else
5073       {
5074         push (@all, "class$dir.stamp");
5075       }
5076 }
5077
5078
5079 # Handle some of the minor options.
5080 sub handle_minor_options
5081 {
5082   if (option 'readme-alpha')
5083     {
5084       if ($relative_dir eq '.')
5085         {
5086           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
5087             {
5088               msg ('error-gnits', $package_version_location,
5089                    "version '$package_version' doesn't follow " .
5090                    "Gnits standards");
5091             }
5092           if (defined $1 && -f 'README-alpha')
5093             {
5094               # This means we have an alpha release.  See
5095               # GNITS_VERSION_PATTERN for details.
5096               push_dist_common ('README-alpha');
5097             }
5098         }
5099     }
5100 }
5101
5102 ################################################################
5103
5104 # ($OUTPUT, @INPUTS)
5105 # &split_config_file_spec ($SPEC)
5106 # -------------------------------
5107 # Decode the Autoconf syntax for config files (files, headers, links
5108 # etc.).
5109 sub split_config_file_spec ($)
5110 {
5111   my ($spec) = @_;
5112   my ($output, @inputs) = split (/:/, $spec);
5113
5114   push @inputs, "$output.in"
5115     unless @inputs;
5116
5117   return ($output, @inputs);
5118 }
5119
5120 # $input
5121 # locate_am (@POSSIBLE_SOURCES)
5122 # -----------------------------
5123 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
5124 # This functions returns the first *.in file for which a *.am exists.
5125 # It returns undef otherwise.
5126 sub locate_am (@)
5127 {
5128   my (@rest) = @_;
5129   my $input;
5130   foreach my $file (@rest)
5131     {
5132       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
5133         {
5134           $input = $file;
5135           last;
5136         }
5137     }
5138   return $input;
5139 }
5140
5141 my %make_list;
5142
5143 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
5144 # ---------------------------------------------------
5145 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
5146 # (or AC_OUTPUT).
5147 sub scan_autoconf_config_files ($$)
5148 {
5149   my ($where, $config_files) = @_;
5150
5151   # Look at potential Makefile.am's.
5152   foreach (split ' ', $config_files)
5153     {
5154       # Must skip empty string for Perl 4.
5155       next if $_ eq "\\" || $_ eq '';
5156
5157       # Handle $local:$input syntax.
5158       my ($local, @rest) = split (/:/);
5159       @rest = ("$local.in",) unless @rest;
5160       # Keep in sync with 'conffile-leading-dot.test'.
5161       msg ('unsupported', $where,
5162            "omit leading './' from config file names such as '$local';"
5163            . "\nremake rules might be subtly broken otherwise")
5164         if ($local =~ /^\.\//);
5165       my $input = locate_am @rest;
5166       if ($input)
5167         {
5168           # We have a file that automake should generate.
5169           $make_list{$input} = join (':', ($local, @rest));
5170         }
5171       else
5172         {
5173           # We have a file that automake should cause to be
5174           # rebuilt, but shouldn't generate itself.
5175           push (@other_input_files, $_);
5176         }
5177       $ac_config_files_location{$local} = $where;
5178       $ac_config_files_condition{$local} =
5179         new Automake::Condition (@cond_stack)
5180           if (@cond_stack);
5181     }
5182 }
5183
5184
5185 # &scan_autoconf_traces ($FILENAME)
5186 # ---------------------------------
5187 sub scan_autoconf_traces ($)
5188 {
5189   my ($filename) = @_;
5190
5191   # Macros to trace, with their minimal number of arguments.
5192   #
5193   # IMPORTANT: If you add a macro here, you should also add this macro
5194   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
5195   my %traced = (
5196                 AC_CANONICAL_BUILD => 0,
5197                 AC_CANONICAL_HOST => 0,
5198                 AC_CANONICAL_TARGET => 0,
5199                 AC_CONFIG_AUX_DIR => 1,
5200                 AC_CONFIG_FILES => 1,
5201                 AC_CONFIG_HEADERS => 1,
5202                 AC_CONFIG_LIBOBJ_DIR => 1,
5203                 AC_CONFIG_LINKS => 1,
5204                 AC_FC_SRCEXT => 1,
5205                 AC_INIT => 0,
5206                 AC_LIBSOURCE => 1,
5207                 AC_REQUIRE_AUX_FILE => 1,
5208                 AC_SUBST_TRACE => 1,
5209                 AM_AUTOMAKE_VERSION => 1,
5210                 AM_CONDITIONAL => 2,
5211                 AM_GNU_GETTEXT => 0,
5212                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
5213                 AM_INIT_AUTOMAKE => 0,
5214                 AM_MAINTAINER_MODE => 0,
5215                 AM_PROG_AR => 0,
5216                 AM_PROG_CC_C_O => 0,
5217                 AM_SILENT_RULES => 0,
5218                 _AM_SUBST_NOTMAKE => 1,
5219                 _AM_COND_IF => 1,
5220                 _AM_COND_ELSE => 1,
5221                 _AM_COND_ENDIF => 1,
5222                 LT_SUPPORTED_TAG => 1,
5223                 _LT_AC_TAGCONFIG => 0,
5224                 m4_include => 1,
5225                 m4_sinclude => 1,
5226                 sinclude => 1,
5227               );
5228
5229   my $traces = ($ENV{AUTOCONF} || '@am_AUTOCONF@') . " ";
5230
5231   # Use a separator unlikely to be used, not ':', the default, which
5232   # has a precise meaning for AC_CONFIG_FILES and so on.
5233   $traces .= join (' ',
5234                    map { "--trace=$_" . ':\$f:\$l::\$d::\$n::\${::}%' }
5235                    (keys %traced));
5236
5237   my $tracefh = new Automake::XFile ("$traces $filename |");
5238   verb "reading $traces";
5239
5240   @cond_stack = ();
5241   my $where;
5242
5243   while ($_ = $tracefh->getline)
5244     {
5245       chomp;
5246       my ($here, $depth, @args) = split (/::/);
5247       $where = new Automake::Location $here;
5248       my $macro = $args[0];
5249
5250       prog_error ("unrequested trace '$macro'")
5251         unless exists $traced{$macro};
5252
5253       # Skip and diagnose malformed calls.
5254       if ($#args < $traced{$macro})
5255         {
5256           msg ('syntax', $where, "not enough arguments for $macro");
5257           next;
5258         }
5259
5260       # Alphabetical ordering please.
5261       if ($macro eq 'AC_CANONICAL_BUILD')
5262         {
5263           if ($seen_canonical <= AC_CANONICAL_BUILD)
5264             {
5265               $seen_canonical = AC_CANONICAL_BUILD;
5266               $canonical_location = $where;
5267             }
5268         }
5269       elsif ($macro eq 'AC_CANONICAL_HOST')
5270         {
5271           if ($seen_canonical <= AC_CANONICAL_HOST)
5272             {
5273               $seen_canonical = AC_CANONICAL_HOST;
5274               $canonical_location = $where;
5275             }
5276         }
5277       elsif ($macro eq 'AC_CANONICAL_TARGET')
5278         {
5279           $seen_canonical = AC_CANONICAL_TARGET;
5280           $canonical_location = $where;
5281         }
5282       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
5283         {
5284           if ($seen_init_automake)
5285             {
5286               error ($where, "AC_CONFIG_AUX_DIR must be called before "
5287                      . "AM_INIT_AUTOMAKE ...", partial => 1);
5288               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
5289             }
5290           $config_aux_dir = $args[1];
5291           $config_aux_dir_set_in_configure_ac = 1;
5292           check_directory ($config_aux_dir, $where);
5293         }
5294       elsif ($macro eq 'AC_CONFIG_FILES')
5295         {
5296           # Look at potential Makefile.am's.
5297           scan_autoconf_config_files ($where, $args[1]);
5298         }
5299       elsif ($macro eq 'AC_CONFIG_HEADERS')
5300         {
5301           foreach my $spec (split (' ', $args[1]))
5302             {
5303               my ($dest, @src) = split (':', $spec);
5304               $ac_config_files_location{$dest} = $where;
5305               push @config_headers, $spec;
5306             }
5307         }
5308       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
5309         {
5310           $config_libobj_dir = $args[1];
5311           check_directory ($config_libobj_dir, $where);
5312         }
5313       elsif ($macro eq 'AC_CONFIG_LINKS')
5314         {
5315           foreach my $spec (split (' ', $args[1]))
5316             {
5317               my ($dest, $src) = split (':', $spec);
5318               $ac_config_files_location{$dest} = $where;
5319               push @config_links, $spec;
5320             }
5321         }
5322       elsif ($macro eq 'AC_FC_SRCEXT')
5323         {
5324           my $suffix = $args[1];
5325           # These flags are used as %SOURCEFLAG% in depend2.am,
5326           # where the trailing space is important.
5327           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
5328             if ($suffix eq 'f90' || $suffix eq 'f95' || $suffix eq 'f03' || $suffix eq 'f08');
5329         }
5330       elsif ($macro eq 'AC_INIT')
5331         {
5332           if (defined $args[2])
5333             {
5334               $package_version = $args[2];
5335               $package_version_location = $where;
5336             }
5337         }
5338       elsif ($macro eq 'AC_LIBSOURCE')
5339         {
5340           $libsources{$args[1]} = $here;
5341         }
5342       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
5343         {
5344           # Only remember the first time a file is required.
5345           $required_aux_file{$args[1]} = $where
5346             unless exists $required_aux_file{$args[1]};
5347         }
5348       elsif ($macro eq 'AC_SUBST_TRACE')
5349         {
5350           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
5351           # AC_SUBST(5), then too bad.
5352           $configure_vars{$args[1]} = $where
5353             if $args[1] =~ /^\w+$/;
5354         }
5355       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
5356         {
5357           error ($where,
5358                  "version mismatch.  This is Automake $VERSION,\n" .
5359                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
5360                  "comes from Automake $args[1].  You should recreate\n" .
5361                  "aclocal.m4 with aclocal and run automake again.\n",
5362                  # $? = 63 is used to indicate version mismatch to missing.
5363                  exit_code => 63)
5364             if $VERSION ne $args[1];
5365
5366           $seen_automake_version = 1;
5367         }
5368       elsif ($macro eq 'AM_CONDITIONAL')
5369         {
5370           $configure_cond{$args[1]} = $where;
5371         }
5372       elsif ($macro eq 'AM_GNU_GETTEXT')
5373         {
5374           $seen_gettext = $where;
5375           $ac_gettext_location = $where;
5376           $seen_gettext_external = grep ($_ eq 'external', @args);
5377         }
5378       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
5379         {
5380           $seen_gettext_intl = $where;
5381         }
5382       elsif ($macro eq 'AM_INIT_AUTOMAKE')
5383         {
5384           $seen_init_automake = $where;
5385           if (defined $args[2])
5386             {
5387               $package_version = $args[2];
5388               $package_version_location = $where;
5389             }
5390           elsif (defined $args[1])
5391             {
5392               my @opts = split (' ', $args[1]);
5393               @opts = map { { option => $_, where => $where } } @opts;
5394               exit $exit_code if process_global_option_list (@opts);
5395             }
5396         }
5397       elsif ($macro eq 'AM_MAINTAINER_MODE')
5398         {
5399           $seen_maint_mode = $where;
5400         }
5401       elsif ($macro eq 'AM_PROG_AR')
5402         {
5403           $seen_ar = $where;
5404         }
5405       elsif ($macro eq 'AM_PROG_CC_C_O')
5406         {
5407           $seen_cc_c_o = $where;
5408         }
5409       elsif ($macro eq 'AM_SILENT_RULES')
5410         {
5411           set_global_option ('silent-rules', $where);
5412         }
5413       elsif ($macro eq '_AM_COND_IF')
5414         {
5415           cond_stack_if ('', $args[1], $where);
5416           error ($where, "missing m4 quoting, macro depth $depth")
5417             if ($depth != 1);
5418         }
5419       elsif ($macro eq '_AM_COND_ELSE')
5420         {
5421           cond_stack_else ('!', $args[1], $where);
5422           error ($where, "missing m4 quoting, macro depth $depth")
5423             if ($depth != 1);
5424         }
5425       elsif ($macro eq '_AM_COND_ENDIF')
5426         {
5427           cond_stack_endif (undef, undef, $where);
5428           error ($where, "missing m4 quoting, macro depth $depth")
5429             if ($depth != 1);
5430         }
5431       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5432         {
5433           $ignored_configure_vars{$args[1]} = $where;
5434         }
5435       elsif ($macro eq 'm4_include'
5436              || $macro eq 'm4_sinclude'
5437              || $macro eq 'sinclude')
5438         {
5439           # Skip missing 'sinclude'd files.
5440           next if $macro ne 'm4_include' && ! -f $args[1];
5441
5442           # Some modified versions of Autoconf don't use
5443           # frozen files.  Consequently it's possible that we see all
5444           # m4_include's performed during Autoconf's startup.
5445           # Obviously we don't want to distribute Autoconf's files
5446           # so we skip absolute filenames here.
5447           push @configure_deps, '$(top_srcdir)/' . $args[1]
5448             unless $here =~ m,^(?:\w:)?[\\/],;
5449           # Keep track of the greatest timestamp.
5450           if (-e $args[1])
5451             {
5452               my $mtime = mtime $args[1];
5453               $configure_deps_greatest_timestamp = $mtime
5454                 if $mtime > $configure_deps_greatest_timestamp;
5455             }
5456         }
5457       elsif ($macro eq 'LT_SUPPORTED_TAG')
5458         {
5459           $libtool_tags{$args[1]} = 1;
5460           $libtool_new_api = 1;
5461         }
5462       elsif ($macro eq '_LT_AC_TAGCONFIG')
5463         {
5464           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5465           # We use it to detect whether tags are supported.  Our
5466           # preferred interface is LT_SUPPORTED_TAG, but it was
5467           # introduced in Libtool 1.6.
5468           if (0 == keys %libtool_tags)
5469             {
5470               # Hardcode the tags supported by Libtool 1.5.
5471               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5472             }
5473         }
5474     }
5475
5476   error ($where, "condition stack not properly closed")
5477     if (@cond_stack);
5478
5479   $tracefh->close;
5480 }
5481
5482
5483 # &scan_autoconf_files ()
5484 # -----------------------
5485 # Check whether we use 'configure.ac' or 'configure.in'.
5486 # Scan it (and possibly 'aclocal.m4') for interesting things.
5487 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5488 sub scan_autoconf_files ()
5489 {
5490   # Reinitialize libsources here.  This isn't really necessary,
5491   # since we currently assume there is only one configure.ac.  But
5492   # that won't always be the case.
5493   %libsources = ();
5494
5495   # Keep track of the youngest configure dependency.
5496   $configure_deps_greatest_timestamp = mtime $configure_ac;
5497   if (-e 'aclocal.m4')
5498     {
5499       my $mtime = mtime 'aclocal.m4';
5500       $configure_deps_greatest_timestamp = $mtime
5501         if $mtime > $configure_deps_greatest_timestamp;
5502     }
5503
5504   scan_autoconf_traces ($configure_ac);
5505
5506   @configure_input_files = sort keys %make_list;
5507   # Set input and output files if not specified by user.
5508   if (! @input_files)
5509     {
5510       @input_files = @configure_input_files;
5511       %output_files = %make_list;
5512     }
5513
5514
5515   if (! $seen_init_automake)
5516     {
5517       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5518               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5519               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5520               . "and that aclocal.m4 was recently regenerated "
5521               . "(using aclocal)");
5522     }
5523   else
5524     {
5525       if (! $seen_automake_version)
5526         {
5527           if (-f 'aclocal.m4')
5528             {
5529               error ($seen_init_automake,
5530                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5531                      "an\nold Automake version.  You should recreate " .
5532                      "aclocal.m4\nwith aclocal and run automake again",
5533                      # $? = 63 is used to indicate version mismatch to missing.
5534                      exit_code => 63);
5535             }
5536           else
5537             {
5538               error ($seen_init_automake,
5539                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5540                      "found,\nprobably because aclocal.m4 is missing.\n" .
5541                      "You should run aclocal to create this file, then\n" .
5542                      "run automake again");
5543             }
5544         }
5545     }
5546
5547   locate_aux_dir ();
5548
5549   # Look for some files we need.  Always check for these.  This
5550   # check must be done for every run, even those where we are only
5551   # looking at a subdir Makefile.  We must set relative_dir for
5552   # push_required_file to work.
5553   # Sort the files for stable verbose output.
5554   $relative_dir = '.';
5555   foreach my $file (sort keys %required_aux_file)
5556     {
5557       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5558     }
5559   err_am "'install.sh' is an anachronism; use 'install-sh' instead"
5560     if -f $config_aux_dir . '/install.sh';
5561
5562   # Preserve dist_common for later.
5563   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5564
5565 }
5566
5567 ################################################################
5568
5569 # Set up for Cygnus mode.
5570 sub check_cygnus
5571 {
5572   my $cygnus = option 'cygnus';
5573   return unless $cygnus;
5574
5575   set_strictness ('foreign');
5576   set_option ('no-installinfo', $cygnus);
5577   set_option ('no-dependencies', $cygnus);
5578   set_option ('no-dist', $cygnus);
5579
5580   err_ac "'AM_MAINTAINER_MODE' required when --cygnus specified"
5581     if !$seen_maint_mode;
5582 }
5583
5584 # Do any extra checking for GNU standards.
5585 sub check_gnu_standards
5586 {
5587   if ($relative_dir eq '.')
5588     {
5589       # In top level (or only) directory.
5590       require_file ("$am_file.am", GNU,
5591                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5592
5593       # Accept one of these three licenses; default to COPYING.
5594       # Make sure we do not overwrite an existing license.
5595       my $license;
5596       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5597         {
5598           if (-f $_)
5599             {
5600               $license = $_;
5601               last;
5602             }
5603         }
5604       require_file ("$am_file.am", GNU, 'COPYING')
5605         unless $license;
5606     }
5607
5608   for my $opt ('no-installman', 'no-installinfo')
5609     {
5610       msg ('error-gnu', option $opt,
5611            "option '$opt' disallowed by GNU standards")
5612         if option $opt;
5613     }
5614 }
5615
5616 # Do any extra checking for GNITS standards.
5617 sub check_gnits_standards
5618 {
5619   if ($relative_dir eq '.')
5620     {
5621       # In top level (or only) directory.
5622       require_file ("$am_file.am", GNITS, 'THANKS');
5623     }
5624 }
5625
5626 ################################################################
5627 #
5628 # Functions to handle files of each language.
5629
5630 # Each 'lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5631 # simple formula: Return value is LANG_SUBDIR if the resulting object
5632 # file should be in a subdir if the source file is, LANG_PROCESS if
5633 # file is to be dealt with, LANG_IGNORE otherwise.
5634
5635 # Much of the actual processing is handled in
5636 # handle_single_transform.  These functions exist so that
5637 # auxiliary information can be recorded for a later cleanup pass.
5638 # Note that the calls to these functions are computed, so don't bother
5639 # searching for their precise names in the source.
5640
5641 # This is just a convenience function that can be used to determine
5642 # when a subdir object should be used.
5643 sub lang_sub_obj
5644 {
5645     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5646 }
5647
5648 # Rewrite a single C source file.
5649 sub lang_c_rewrite
5650 {
5651   my ($directory, $base, $ext, $obj, $have_per_exec_flags, $var) = @_;
5652
5653   my $r = LANG_PROCESS;
5654   if (option 'subdir-objects')
5655     {
5656       $r = LANG_SUBDIR;
5657       if ($directory && $directory ne '.')
5658         {
5659           $base = $directory . '/' . $base;
5660
5661           # libtool is always able to put the object at the proper place,
5662           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5663           msg_var ('portability', $var,
5664                    "compiling '$base.c' in subdir requires "
5665                    . "'AM_PROG_CC_C_O' in '$configure_ac'",
5666                    uniq_scope => US_GLOBAL,
5667                    uniq_part => 'AM_PROG_CC_C_O subdir')
5668             unless $seen_cc_c_o || $obj eq '.lo';
5669         }
5670     }
5671
5672   if (! $seen_cc_c_o
5673       && $have_per_exec_flags
5674       && ! option 'subdir-objects'
5675       && $obj ne '.lo')
5676     {
5677       msg_var ('portability',
5678                $var, "compiling '$base.c' with per-target flags requires "
5679                . "'AM_PROG_CC_C_O' in '$configure_ac'",
5680                uniq_scope => US_GLOBAL,
5681                uniq_part => 'AM_PROG_CC_C_O per-target')
5682     }
5683
5684     return $r;
5685 }
5686
5687 # Rewrite a single C++ source file.
5688 sub lang_cxx_rewrite
5689 {
5690     return &lang_sub_obj;
5691 }
5692
5693 # Rewrite a single header file.
5694 sub lang_header_rewrite
5695 {
5696     # Header files are simply ignored.
5697     return LANG_IGNORE;
5698 }
5699
5700 # Rewrite a single Vala source file.
5701 sub lang_vala_rewrite
5702 {
5703     my ($directory, $base, $ext) = @_;
5704
5705     (my $newext = $ext) =~ s/vala$/c/;
5706     return (LANG_SUBDIR, $newext);
5707 }
5708
5709 # Rewrite a single yacc file.
5710 sub lang_yacc_rewrite
5711 {
5712     my ($directory, $base, $ext) = @_;
5713
5714     my $r = &lang_sub_obj;
5715     (my $newext = $ext) =~ tr/y/c/;
5716     return ($r, $newext);
5717 }
5718
5719 # Rewrite a single yacc++ file.
5720 sub lang_yaccxx_rewrite
5721 {
5722     my ($directory, $base, $ext) = @_;
5723
5724     my $r = &lang_sub_obj;
5725     (my $newext = $ext) =~ tr/y/c/;
5726     return ($r, $newext);
5727 }
5728
5729 # Rewrite a single lex file.
5730 sub lang_lex_rewrite
5731 {
5732     my ($directory, $base, $ext) = @_;
5733
5734     my $r = &lang_sub_obj;
5735     (my $newext = $ext) =~ tr/l/c/;
5736     return ($r, $newext);
5737 }
5738
5739 # Rewrite a single lex++ file.
5740 sub lang_lexxx_rewrite
5741 {
5742     my ($directory, $base, $ext) = @_;
5743
5744     my $r = &lang_sub_obj;
5745     (my $newext = $ext) =~ tr/l/c/;
5746     return ($r, $newext);
5747 }
5748
5749 # Rewrite a single assembly file.
5750 sub lang_asm_rewrite
5751 {
5752     return &lang_sub_obj;
5753 }
5754
5755 # Rewrite a single preprocessed assembly file.
5756 sub lang_cppasm_rewrite
5757 {
5758     return &lang_sub_obj;
5759 }
5760
5761 # Rewrite a single Fortran 77 file.
5762 sub lang_f77_rewrite
5763 {
5764     return &lang_sub_obj;
5765 }
5766
5767 # Rewrite a single Fortran file.
5768 sub lang_fc_rewrite
5769 {
5770     return &lang_sub_obj;
5771 }
5772
5773 # Rewrite a single preprocessed Fortran file.
5774 sub lang_ppfc_rewrite
5775 {
5776     return &lang_sub_obj;
5777 }
5778
5779 # Rewrite a single preprocessed Fortran 77 file.
5780 sub lang_ppf77_rewrite
5781 {
5782     return &lang_sub_obj;
5783 }
5784
5785 # Rewrite a single ratfor file.
5786 sub lang_ratfor_rewrite
5787 {
5788     return &lang_sub_obj;
5789 }
5790
5791 # Rewrite a single Objective C file.
5792 sub lang_objc_rewrite
5793 {
5794     return &lang_sub_obj;
5795 }
5796
5797 # Rewrite a single Unified Parallel C file.
5798 sub lang_upc_rewrite
5799 {
5800     return &lang_sub_obj;
5801 }
5802
5803 # Rewrite a single Java file.
5804 sub lang_java_rewrite
5805 {
5806     return LANG_SUBDIR;
5807 }
5808
5809 # The lang_X_finish functions are called after all source file
5810 # processing is done.  Each should handle defining rules for the
5811 # language, etc.  A finish function is only called if a source file of
5812 # the appropriate type has been seen.
5813
5814 sub lang_vala_finish_target ($$)
5815 {
5816   my ($self, $name) = @_;
5817
5818   my $derived = canonicalize ($name);
5819   my $var = var "${derived}_SOURCES";
5820   return unless $var;
5821
5822   my @vala_sources = grep { /\.vala$/ } ($var->value_as_list_recursive);
5823
5824   foreach my $vala_file (@vala_sources)
5825     {
5826       (my $c_file = $vala_file) =~ s/(.*)\.vala$/$1.c/;
5827       $output_rules .= "\$(srcdir)/$c_file: \$(srcdir)/${derived}_vala.stamp\n"
5828         . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5829         . "\t\@if test -f \$@; then :; else \\\n"
5830         . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5831         . "\tfi\n"
5832     }
5833
5834   # Add rebuild rules for generated header and vapi files
5835   my $flags = var ($derived . '_VALAFLAGS');
5836   if ($flags)
5837     {
5838       my $lastflag = '';
5839       foreach my $flag ($flags->value_as_list_recursive)
5840         {
5841           if (grep (/$lastflag/, ('-H', '-h', '--header', '--internal-header',
5842                                   '--vapi', '--internal-vapi', '--gir')))
5843             {
5844               my $headerfile = $flag;
5845               $output_rules .= "\$(srcdir)/$headerfile: \$(srcdir)/${derived}_vala.stamp\n"
5846                 . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5847                 . "\t\@if test -f \$@; then :; else \\\n"
5848                 . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5849                 . "\tfi\n";
5850
5851               # valac is not used when building from dist tarballs
5852               # distribute the generated files
5853               push_dist_common ($headerfile);
5854               $clean_files{$headerfile} = MAINTAINER_CLEAN;
5855             }
5856           $lastflag = $flag;
5857         }
5858     }
5859
5860   my $compile = $self->compile;
5861
5862   # Rewrite each occurrence of 'AM_VALAFLAGS' in the compile
5863   # rule into '${derived}_VALAFLAGS' if it exists.
5864   my $val = "${derived}_VALAFLAGS";
5865   $compile =~ s/\(AM_VALAFLAGS\)/\($val\)/
5866     if set_seen ($val);
5867
5868   # VALAFLAGS is a user variable (per GNU Standards),
5869   # it should not be overridden in the Makefile...
5870   check_user_variables ['VALAFLAGS'];
5871
5872   my $dirname = dirname ($name);
5873
5874   # Only generate C code, do not run C compiler
5875   $compile .= " -C";
5876
5877   my $verbose = verbose_flag ('VALAC');
5878   my $silent = silent_flag ();
5879
5880   $output_rules .=
5881     "\$(srcdir)/${derived}_vala.stamp: @vala_sources\n".
5882 # Since the C files generated from the vala sources depend on the
5883 # ${derived}_vala.stamp file, we must ensure its timestamp is older than
5884 # those of the C files generated by the valac invocation below (this is
5885 # especially important on systems with sub-second timestamp resolution).
5886 # Thus we need to create the stamp file *before* invoking valac, and to
5887 # move it to its final location only after valac has been invoked.
5888     "\t${silent}rm -f \$\@ && echo stamp > \$\@-t\n".
5889     "\t${verbose}\$(am__cd) \$(srcdir) && $compile @vala_sources\n".
5890     "\t${silent}mv -f \$\@-t \$\@\n";
5891
5892   push_dist_common ("${derived}_vala.stamp");
5893
5894   $clean_files{"${derived}_vala.stamp"} = MAINTAINER_CLEAN;
5895 }
5896
5897 # Add output rules to invoke valac and create stamp file as a witness
5898 # to handle multiple outputs. This function is called after all source
5899 # file processing is done.
5900 sub lang_vala_finish
5901 {
5902   my ($self) = @_;
5903
5904   foreach my $prog (keys %known_programs)
5905     {
5906       lang_vala_finish_target ($self, $prog);
5907     }
5908
5909   while (my ($name) = each %known_libraries)
5910     {
5911       lang_vala_finish_target ($self, $name);
5912     }
5913 }
5914
5915 # The built .c files should be cleaned only on maintainer-clean
5916 # as the .c files are distributed. This function is called for each
5917 # .vala source file.
5918 sub lang_vala_target_hook
5919 {
5920   my ($self, $aggregate, $output, $input, %transform) = @_;
5921
5922   $clean_files{$output} = MAINTAINER_CLEAN;
5923 }
5924
5925 # This is a yacc helper which is called whenever we have decided to
5926 # compile a yacc file.
5927 sub lang_yacc_target_hook
5928 {
5929     my ($self, $aggregate, $output, $input, %transform) = @_;
5930
5931     # If some relevant *YFLAGS variable contains the '-d' flag, we'll
5932     # have to to generate special code.
5933     my $yflags_contains_minus_d = 0;
5934
5935     foreach my $pfx ("", "${aggregate}_")
5936       {
5937         my $yflagsvar = var ("${pfx}YFLAGS");
5938         next unless $yflagsvar;
5939         # We cannot work reliably with conditionally-defined YFLAGS.
5940         if ($yflagsvar->has_conditional_contents)
5941           {
5942             msg_var ('unsupported', $yflagsvar,
5943                      "'${pfx}YFLAGS' cannot have conditional contents");
5944           }
5945         else
5946           {
5947             $yflags_contains_minus_d = 1
5948               if grep (/^-d$/, $yflagsvar->value_as_list_recursive);
5949           }
5950       }
5951
5952     if ($yflags_contains_minus_d)
5953       {
5954         # Found a '-d' that applies to the compilation of this file.
5955         # Add a dependency for the generated header file, and arrange
5956         # for that file to be included in the distribution.
5957
5958         # The extension of the output file (e.g., '.c' or '.cxx').
5959         # We'll need it to compute the name of the generated header file.
5960         (my $output_ext = basename ($output)) =~ s/.*(\.[^.]+)$/$1/;
5961
5962         # We know that a yacc input should be turned into either a C or
5963         # C++ output file.  We depend on this fact (here and in yacc.am),
5964         # so check that it really holds.
5965         my $lang = $languages{$extension_map{$output_ext}};
5966         prog_error "invalid output name '$output' for yacc file '$input'"
5967           if (!$lang || ($lang->name ne 'c' && $lang->name ne 'cxx'));
5968
5969         (my $header_ext = $output_ext) =~ s/c/h/g;
5970         # Quote $output_ext in the regexp, so that dots in it are taken
5971         # as literal dots, not as metacharacters.
5972         (my $header = $output) =~ s/\Q$output_ext\E$/$header_ext/;
5973
5974         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5975                                                   RULE_AUTOMAKE, TRUE,
5976                                                   INTERNAL))
5977           {
5978             my $condstr = $cond->subst_string;
5979             $output_rules .=
5980               "$condstr${header}: $output\n"
5981               # Recover from removal of $header
5982               . "$condstr\t\@if test ! -f \$@; then rm -f $output; else :; fi\n"
5983               . "$condstr\t\@if test ! -f \$@; then \$(MAKE) \$(AM_MAKEFLAGS) $output; else :; fi\n";
5984           }
5985         # Distribute the generated file, unless its .y source was
5986         # listed in a nodist_ variable.  (&handle_source_transform
5987         # will set DIST_SOURCE.)
5988         &push_dist_common ($header)
5989           if $transform{'DIST_SOURCE'};
5990
5991         # The GNU rules say that yacc/lex output files should be removed
5992         # by maintainer-clean.  However, if the files are not distributed,
5993         # then we want to remove them with "make clean"; otherwise,
5994         # "make distcheck" will fail.
5995         $clean_files{$header} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5996       }
5997     # See the comment above for $HEADER.
5998     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5999 }
6000
6001 # This is a lex helper which is called whenever we have decided to
6002 # compile a lex file.
6003 sub lang_lex_target_hook
6004 {
6005     my ($self, $aggregate, $output, $input, %transform) = @_;
6006     # The GNU rules say that yacc/lex output files should be removed
6007     # by maintainer-clean.  However, if the files are not distributed,
6008     # then we want to remove them with "make clean"; otherwise,
6009     # "make distcheck" will fail.
6010     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6011 }
6012
6013 # This is a helper for both lex and yacc.
6014 sub yacc_lex_finish_helper
6015 {
6016   return if defined $language_scratch{'lex-yacc-done'};
6017   $language_scratch{'lex-yacc-done'} = 1;
6018
6019   # FIXME: for now, no line number.
6020   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
6021   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
6022 }
6023
6024 sub lang_yacc_finish
6025 {
6026   return if defined $language_scratch{'yacc-done'};
6027   $language_scratch{'yacc-done'} = 1;
6028
6029   reject_var 'YACCFLAGS', "'YACCFLAGS' obsolete; use 'YFLAGS' instead";
6030
6031   yacc_lex_finish_helper;
6032 }
6033
6034
6035 sub lang_lex_finish
6036 {
6037   return if defined $language_scratch{'lex-done'};
6038   $language_scratch{'lex-done'} = 1;
6039
6040   yacc_lex_finish_helper;
6041 }
6042
6043
6044 # Given a hash table of linker names, pick the name that has the most
6045 # precedence.  This is lame, but something has to have global
6046 # knowledge in order to eliminate the conflict.  Add more linkers as
6047 # required.
6048 sub resolve_linker
6049 {
6050     my (%linkers) = @_;
6051
6052     foreach my $l (qw(GCJLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
6053     {
6054         return $l if defined $linkers{$l};
6055     }
6056     return 'LINK';
6057 }
6058
6059 # Called to indicate that an extension was used.
6060 sub saw_extension
6061 {
6062     my ($ext) = @_;
6063     if (! defined $extension_seen{$ext})
6064     {
6065         $extension_seen{$ext} = 1;
6066     }
6067     else
6068     {
6069         ++$extension_seen{$ext};
6070     }
6071 }
6072
6073 # Return the number of files seen for a given language.  Knows about
6074 # special cases we care about.  FIXME: this is hideous.  We need
6075 # something that involves real language objects.  For instance yacc
6076 # and yaccxx could both derive from a common yacc class which would
6077 # know about the strange ylwrap requirement.  (Or better yet we could
6078 # just not support legacy yacc!)
6079 sub count_files_for_language
6080 {
6081     my ($name) = @_;
6082
6083     my @names;
6084     if ($name eq 'yacc' || $name eq 'yaccxx')
6085     {
6086         @names = ('yacc', 'yaccxx');
6087     }
6088     elsif ($name eq 'lex' || $name eq 'lexxx')
6089     {
6090         @names = ('lex', 'lexxx');
6091     }
6092     else
6093     {
6094         @names = ($name);
6095     }
6096
6097     my $r = 0;
6098     foreach $name (@names)
6099     {
6100         my $lang = $languages{$name};
6101         foreach my $ext (@{$lang->extensions})
6102         {
6103             $r += $extension_seen{$ext}
6104                 if defined $extension_seen{$ext};
6105         }
6106     }
6107
6108     return $r
6109 }
6110
6111 # Called to ask whether source files have been seen . If HEADERS is 1,
6112 # headers can be included.
6113 sub saw_sources_p
6114 {
6115     my ($headers) = @_;
6116
6117     # count all the sources
6118     my $count = 0;
6119     foreach my $val (values %extension_seen)
6120     {
6121         $count += $val;
6122     }
6123
6124     if (!$headers)
6125     {
6126         $count -= count_files_for_language ('header');
6127     }
6128
6129     return $count > 0;
6130 }
6131
6132
6133 # register_language (%ATTRIBUTE)
6134 # ------------------------------
6135 # Register a single language.
6136 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
6137 sub register_language (%)
6138 {
6139   my (%option) = @_;
6140
6141   # Set the defaults.
6142   $option{'autodep'} = 'no'
6143     unless defined $option{'autodep'};
6144   $option{'linker'} = ''
6145     unless defined $option{'linker'};
6146   $option{'flags'} = []
6147     unless defined $option{'flags'};
6148   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
6149     unless defined $option{'output_extensions'};
6150   $option{'nodist_specific'} = 0
6151     unless defined $option{'nodist_specific'};
6152
6153   my $lang = new Language (%option);
6154
6155   # Fill indexes.
6156   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
6157   $languages{$lang->name} = $lang;
6158   my $link = $lang->linker;
6159   if ($link)
6160     {
6161       if (exists $link_languages{$link})
6162         {
6163           prog_error ("'$link' has different definitions in "
6164                       . $lang->name . " and " . $link_languages{$link}->name)
6165             if $lang->link ne $link_languages{$link}->link;
6166         }
6167       else
6168         {
6169           $link_languages{$link} = $lang;
6170         }
6171     }
6172
6173   # Update the pattern of known extensions.
6174   accept_extensions (@{$lang->extensions});
6175
6176   # Upate the $suffix_rule map.
6177   foreach my $suffix (@{$lang->extensions})
6178     {
6179       foreach my $dest (&{$lang->output_extensions} ($suffix))
6180         {
6181           register_suffix_rule (INTERNAL, $suffix, $dest);
6182         }
6183     }
6184 }
6185
6186 # derive_suffix ($EXT, $OBJ)
6187 # --------------------------
6188 # This function is used to find a path from a user-specified suffix $EXT
6189 # to $OBJ or to some other suffix we recognize internally, e.g. 'cc'.
6190 sub derive_suffix ($$)
6191 {
6192   my ($source_ext, $obj) = @_;
6193
6194   while (! $extension_map{$source_ext}
6195          && $source_ext ne $obj
6196          && exists $suffix_rules->{$source_ext}
6197          && exists $suffix_rules->{$source_ext}{$obj})
6198     {
6199       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
6200     }
6201
6202   return $source_ext;
6203 }
6204
6205
6206 ################################################################
6207
6208 # Pretty-print something and append to output_rules.
6209 sub pretty_print_rule
6210 {
6211     $output_rules .= &makefile_wrap (@_);
6212 }
6213
6214
6215 ################################################################
6216
6217
6218 ## -------------------------------- ##
6219 ## Handling the conditional stack.  ##
6220 ## -------------------------------- ##
6221
6222
6223 # $STRING
6224 # make_conditional_string ($NEGATE, $COND)
6225 # ----------------------------------------
6226 sub make_conditional_string ($$)
6227 {
6228   my ($negate, $cond) = @_;
6229   $cond = "${cond}_TRUE"
6230     unless $cond =~ /^TRUE|FALSE$/;
6231   $cond = Automake::Condition::conditional_negate ($cond)
6232     if $negate;
6233   return $cond;
6234 }
6235
6236
6237 my %_am_macro_for_cond =
6238   (
6239   AMDEP => "one of the compiler tests\n"
6240            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_CXX, AC_PROG_OBJC,\n"
6241            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
6242   am__fastdepCC => 'AC_PROG_CC',
6243   am__fastdepCCAS => 'AM_PROG_AS',
6244   am__fastdepCXX => 'AC_PROG_CXX',
6245   am__fastdepGCJ => 'AM_PROG_GCJ',
6246   am__fastdepOBJC => 'AC_PROG_OBJC',
6247   am__fastdepUPC => 'AM_PROG_UPC'
6248   );
6249
6250 # $COND
6251 # cond_stack_if ($NEGATE, $COND, $WHERE)
6252 # --------------------------------------
6253 sub cond_stack_if ($$$)
6254 {
6255   my ($negate, $cond, $where) = @_;
6256
6257   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
6258     {
6259       my $text = "$cond does not appear in AM_CONDITIONAL";
6260       my $scope = US_LOCAL;
6261       if (exists $_am_macro_for_cond{$cond})
6262         {
6263           my $mac = $_am_macro_for_cond{$cond};
6264           $text .= "\n  The usual way to define '$cond' is to add ";
6265           $text .= ($mac =~ / /) ? $mac : "'$mac'";
6266           $text .= "\n  to '$configure_ac' and run 'aclocal' and 'autoconf' again";
6267           # These warnings appear in Automake files (depend2.am),
6268           # so there is no need to display them more than once:
6269           $scope = US_GLOBAL;
6270         }
6271       error $where, $text, uniq_scope => $scope;
6272     }
6273
6274   push (@cond_stack, make_conditional_string ($negate, $cond));
6275
6276   return new Automake::Condition (@cond_stack);
6277 }
6278
6279
6280 # $COND
6281 # cond_stack_else ($NEGATE, $COND, $WHERE)
6282 # ----------------------------------------
6283 sub cond_stack_else ($$$)
6284 {
6285   my ($negate, $cond, $where) = @_;
6286
6287   if (! @cond_stack)
6288     {
6289       error $where, "else without if";
6290       return FALSE;
6291     }
6292
6293   $cond_stack[$#cond_stack] =
6294     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
6295
6296   # If $COND is given, check against it.
6297   if (defined $cond)
6298     {
6299       $cond = make_conditional_string ($negate, $cond);
6300
6301       error ($where, "else reminder ($negate$cond) incompatible with "
6302              . "current conditional: $cond_stack[$#cond_stack]")
6303         if $cond_stack[$#cond_stack] ne $cond;
6304     }
6305
6306   return new Automake::Condition (@cond_stack);
6307 }
6308
6309
6310 # $COND
6311 # cond_stack_endif ($NEGATE, $COND, $WHERE)
6312 # -----------------------------------------
6313 sub cond_stack_endif ($$$)
6314 {
6315   my ($negate, $cond, $where) = @_;
6316   my $old_cond;
6317
6318   if (! @cond_stack)
6319     {
6320       error $where, "endif without if";
6321       return TRUE;
6322     }
6323
6324   # If $COND is given, check against it.
6325   if (defined $cond)
6326     {
6327       $cond = make_conditional_string ($negate, $cond);
6328
6329       error ($where, "endif reminder ($negate$cond) incompatible with "
6330              . "current conditional: $cond_stack[$#cond_stack]")
6331         if $cond_stack[$#cond_stack] ne $cond;
6332     }
6333
6334   pop @cond_stack;
6335
6336   return new Automake::Condition (@cond_stack);
6337 }
6338
6339
6340
6341
6342
6343 ## ------------------------ ##
6344 ## Handling the variables.  ##
6345 ## ------------------------ ##
6346
6347
6348 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
6349 # -----------------------------------------------------
6350 # Like define_variable, but the value is a list, and the variable may
6351 # be defined conditionally.  The second argument is the condition
6352 # under which the value should be defined; this should be the empty
6353 # string to define the variable unconditionally.  The third argument
6354 # is a list holding the values to use for the variable.  The value is
6355 # pretty printed in the output file.
6356 sub define_pretty_variable ($$$@)
6357 {
6358     my ($var, $cond, $where, @value) = @_;
6359
6360     if (! vardef ($var, $cond))
6361     {
6362         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
6363                                     '', $where, VAR_PRETTY);
6364         rvar ($var)->rdef ($cond)->set_seen;
6365     }
6366 }
6367
6368
6369 # define_variable ($VAR, $VALUE, $WHERE)
6370 # --------------------------------------
6371 # Define a new Automake Makefile variable VAR to VALUE, but only if
6372 # not already defined.
6373 sub define_variable ($$$)
6374 {
6375     my ($var, $value, $where) = @_;
6376     define_pretty_variable ($var, TRUE, $where, $value);
6377 }
6378
6379
6380 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
6381 # ------------------------------------------------------------
6382 # Define the $VAR which content is the list of file names composed of
6383 # a @BASENAME and the $EXTENSION.
6384 sub define_files_variable ($\@$$)
6385 {
6386   my ($var, $basename, $extension, $where) = @_;
6387   define_variable ($var,
6388                    join (' ', map { "$_.$extension" } @$basename),
6389                    $where);
6390 }
6391
6392
6393 # Like define_variable, but define a variable to be the configure
6394 # substitution by the same name.
6395 sub define_configure_variable ($)
6396 {
6397   my ($var) = @_;
6398   # Some variables we do not want to output.  For instance it
6399   # would be a bad idea to output `U = @U@` when `@U@` can be
6400   # substituted as `\`.
6401   my $pretty = exists $ignored_configure_vars{$var} ? VAR_SILENT : VAR_ASIS;
6402   Automake::Variable::define ($var, VAR_CONFIGURE, '', TRUE, subst $var,
6403                               '', $configure_vars{$var}, $pretty);
6404 }
6405
6406
6407 # define_compiler_variable ($LANG)
6408 # --------------------------------
6409 # Define a compiler variable.  We also handle defining the 'LT'
6410 # version of the command when using libtool.
6411 sub define_compiler_variable ($)
6412 {
6413     my ($lang) = @_;
6414
6415     my ($var, $value) = ($lang->compiler, $lang->compile);
6416     my $libtool_tag = '';
6417     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6418       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6419     &define_variable ($var, $value, INTERNAL);
6420     if (var ('LIBTOOL'))
6421       {
6422         my $verbose = define_verbose_libtool ();
6423         &define_variable ("LT$var",
6424                           "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6425                           . "\$(LIBTOOLFLAGS) --mode=compile $value",
6426                           INTERNAL);
6427       }
6428     define_verbose_tagvar ($lang->ccer || 'GEN');
6429 }
6430
6431
6432 # define_linker_variable ($LANG)
6433 # ------------------------------
6434 # Define linker variables.
6435 sub define_linker_variable ($)
6436 {
6437     my ($lang) = @_;
6438
6439     my $libtool_tag = '';
6440     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6441       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6442     # CCLD = $(CC).
6443     &define_variable ($lang->lder, $lang->ld, INTERNAL);
6444     # CCLINK = $(CCLD) blah blah...
6445     my $link = '';
6446     if (var ('LIBTOOL'))
6447       {
6448         my $verbose = define_verbose_libtool ();
6449         $link = "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6450                 . "\$(LIBTOOLFLAGS) --mode=link ";
6451       }
6452     &define_variable ($lang->linker, $link . $lang->link, INTERNAL);
6453     &define_variable ($lang->compiler,  $lang);
6454     &define_verbose_tagvar ($lang->lder || 'GEN');
6455 }
6456
6457 sub define_per_target_linker_variable ($$)
6458 {
6459   my ($linker, $target) = @_;
6460
6461   # If the user wrote a custom link command, we don't define ours.
6462   return "${target}_LINK"
6463     if set_seen "${target}_LINK";
6464
6465   my $xlink = $linker ? $linker : 'LINK';
6466
6467   my $lang = $link_languages{$xlink};
6468   prog_error "Unknown language for linker variable '$xlink'"
6469     unless $lang;
6470
6471   my $link_command = $lang->link;
6472   if (var 'LIBTOOL')
6473     {
6474       my $libtool_tag = '';
6475       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6476         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6477
6478       my $verbose = define_verbose_libtool ();
6479       $link_command =
6480         "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6481         . "--mode=link " . $link_command;
6482     }
6483
6484   # Rewrite each occurrence of 'AM_$flag' in the link
6485   # command into '${derived}_$flag' if it exists.
6486   my $orig_command = $link_command;
6487   my @flags = (@{$lang->flags}, 'LDFLAGS');
6488   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6489   for my $flag (@flags)
6490     {
6491       my $val = "${target}_$flag";
6492       $link_command =~ s/\(AM_$flag\)/\($val\)/
6493         if set_seen ($val);
6494     }
6495
6496   # If the computed command is the same as the generic command, use
6497   # the command linker variable.
6498   return ($lang->linker, $lang->lder)
6499     if $link_command eq $orig_command;
6500
6501   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6502   return ("${target}_LINK", $lang->lder);
6503 }
6504
6505 ################################################################
6506
6507 # &check_trailing_slash ($WHERE, $LINE)
6508 # -------------------------------------
6509 # Return 1 iff $LINE ends with a slash.
6510 # Might modify $LINE.
6511 sub check_trailing_slash ($\$)
6512 {
6513   my ($where, $line) = @_;
6514
6515   # Ignore '##' lines.
6516   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6517
6518   # Catch and fix a common error.
6519   msg "syntax", $where, "whitespace following trailing backslash"
6520     if $$line =~ s/\\\s+\n$/\\\n/;
6521
6522   return $$line =~ /\\$/;
6523 }
6524
6525
6526 # &read_am_file ($AMFILE, $WHERE)
6527 # -------------------------------
6528 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6529 # from Makefile.am into $output_trailer, or define variables as
6530 # appropriate.  NOTE we put rules in the trailer section.  We want
6531 # user rules to come after our generated stuff.
6532 sub read_am_file ($$)
6533 {
6534     my ($amfile, $where) = @_;
6535
6536     my $am_file = new Automake::XFile ("< $amfile");
6537     verb "reading $amfile";
6538
6539     # Keep track of the youngest output dependency.
6540     my $mtime = mtime $amfile;
6541     $output_deps_greatest_timestamp = $mtime
6542       if $mtime > $output_deps_greatest_timestamp;
6543
6544     my $spacing = '';
6545     my $comment = '';
6546     my $blank = 0;
6547     my $saw_bk = 0;
6548     my $var_look = VAR_ASIS;
6549
6550     use constant IN_VAR_DEF => 0;
6551     use constant IN_RULE_DEF => 1;
6552     use constant IN_COMMENT => 2;
6553     my $prev_state = IN_RULE_DEF;
6554
6555     while ($_ = $am_file->getline)
6556     {
6557         $where->set ("$amfile:$.");
6558         if (/$IGNORE_PATTERN/o)
6559         {
6560             # Merely delete comments beginning with two hashes.
6561         }
6562         elsif (/$WHITE_PATTERN/o)
6563         {
6564             error $where, "blank line following trailing backslash"
6565               if $saw_bk;
6566             # Stick a single white line before the incoming macro or rule.
6567             $spacing = "\n";
6568             $blank = 1;
6569             # Flush all comments seen so far.
6570             if ($comment ne '')
6571             {
6572                 $output_vars .= $comment;
6573                 $comment = '';
6574             }
6575         }
6576         elsif (/$COMMENT_PATTERN/o)
6577         {
6578             # Stick comments before the incoming macro or rule.  Make
6579             # sure a blank line precedes the first block of comments.
6580             $spacing = "\n" unless $blank;
6581             $blank = 1;
6582             $comment .= $spacing . $_;
6583             $spacing = '';
6584             $prev_state = IN_COMMENT;
6585         }
6586         else
6587         {
6588             last;
6589         }
6590         $saw_bk = check_trailing_slash ($where, $_);
6591     }
6592
6593     # We save the conditional stack on entry, and then check to make
6594     # sure it is the same on exit.  This lets us conditionally include
6595     # other files.
6596     my @saved_cond_stack = @cond_stack;
6597     my $cond = new Automake::Condition (@cond_stack);
6598
6599     my $last_var_name = '';
6600     my $last_var_type = '';
6601     my $last_var_value = '';
6602     my $last_where;
6603     # FIXME: shouldn't use $_ in this loop; it is too big.
6604     while ($_)
6605     {
6606         $where->set ("$amfile:$.");
6607
6608         # Make sure the line is \n-terminated.
6609         chomp;
6610         $_ .= "\n";
6611
6612         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6613         # used by users.  @MAINT@ is an anachronism now.
6614         $_ =~ s/\@MAINT\@//g
6615             unless $seen_maint_mode;
6616
6617         my $new_saw_bk = check_trailing_slash ($where, $_);
6618
6619         if (/$IGNORE_PATTERN/o)
6620         {
6621             # Merely delete comments beginning with two hashes.
6622
6623             # Keep any backslash from the previous line.
6624             $new_saw_bk = $saw_bk;
6625         }
6626         elsif (/$WHITE_PATTERN/o)
6627         {
6628             # Stick a single white line before the incoming macro or rule.
6629             $spacing = "\n";
6630             error $where, "blank line following trailing backslash"
6631               if $saw_bk;
6632         }
6633         elsif (/$COMMENT_PATTERN/o)
6634         {
6635             error $where, "comment following trailing backslash"
6636               if $saw_bk && $prev_state != IN_COMMENT;
6637
6638             # Stick comments before the incoming macro or rule.
6639             $comment .= $spacing . $_;
6640             $spacing = '';
6641             $prev_state = IN_COMMENT;
6642         }
6643         elsif ($saw_bk)
6644         {
6645             if ($prev_state == IN_RULE_DEF)
6646             {
6647               my $cond = new Automake::Condition @cond_stack;
6648               $output_trailer .= $cond->subst_string;
6649               $output_trailer .= $_;
6650             }
6651             elsif ($prev_state == IN_COMMENT)
6652             {
6653                 # If the line doesn't start with a '#', add it.
6654                 # We do this because a continued comment like
6655                 #   # A = foo \
6656                 #         bar \
6657                 #         baz
6658                 # is not portable.  BSD make doesn't honor
6659                 # escaped newlines in comments.
6660                 s/^#?/#/;
6661                 $comment .= $spacing . $_;
6662             }
6663             else # $prev_state == IN_VAR_DEF
6664             {
6665               $last_var_value .= ' '
6666                 unless $last_var_value =~ /\s$/;
6667               $last_var_value .= $_;
6668
6669               if (!/\\$/)
6670                 {
6671                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6672                                               $last_var_type, $cond,
6673                                               $last_var_value, $comment,
6674                                               $last_where, VAR_ASIS)
6675                     if $cond != FALSE;
6676                   $comment = $spacing = '';
6677                 }
6678             }
6679         }
6680
6681         elsif (/$IF_PATTERN/o)
6682           {
6683             $cond = cond_stack_if ($1, $2, $where);
6684           }
6685         elsif (/$ELSE_PATTERN/o)
6686           {
6687             $cond = cond_stack_else ($1, $2, $where);
6688           }
6689         elsif (/$ENDIF_PATTERN/o)
6690           {
6691             $cond = cond_stack_endif ($1, $2, $where);
6692           }
6693
6694         elsif (/$RULE_PATTERN/o)
6695         {
6696             # Found a rule.
6697             $prev_state = IN_RULE_DEF;
6698
6699             # For now we have to output all definitions of user rules
6700             # and can't diagnose duplicates (see the comment in
6701             # Automake::Rule::define). So we go on and ignore the return value.
6702             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6703
6704             check_variable_expansions ($_, $where);
6705
6706             $output_trailer .= $comment . $spacing;
6707             my $cond = new Automake::Condition @cond_stack;
6708             $output_trailer .= $cond->subst_string;
6709             $output_trailer .= $_;
6710             $comment = $spacing = '';
6711         }
6712         elsif (/$ASSIGNMENT_PATTERN/o)
6713         {
6714             # Found a macro definition.
6715             $prev_state = IN_VAR_DEF;
6716             $last_var_name = $1;
6717             $last_var_type = $2;
6718             $last_var_value = $3;
6719             $last_where = $where->clone;
6720             if ($3 ne '' && substr ($3, -1) eq "\\")
6721               {
6722                 # We preserve the '\' because otherwise the long lines
6723                 # that are generated will be truncated by broken
6724                 # 'sed's.
6725                 $last_var_value = $3 . "\n";
6726               }
6727             # Normally we try to output variable definitions in the
6728             # same format they were input.  However, POSIX compliant
6729             # systems are not required to support lines longer than
6730             # 2048 bytes (most notably, some sed implementation are
6731             # limited to 4000 bytes, and sed is used by config.status
6732             # to rewrite Makefile.in into Makefile).  Moreover nobody
6733             # would really write such long lines by hand since it is
6734             # hardly maintainable.  So if a line is longer that 1000
6735             # bytes (an arbitrary limit), assume it has been
6736             # automatically generated by some tools, and flatten the
6737             # variable definition.  Otherwise, keep the variable as it
6738             # as been input.
6739             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6740
6741             if (!/\\$/)
6742               {
6743                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6744                                             $last_var_type, $cond,
6745                                             $last_var_value, $comment,
6746                                             $last_where, $var_look)
6747                   if $cond != FALSE;
6748                 $comment = $spacing = '';
6749                 $var_look = VAR_ASIS;
6750               }
6751         }
6752         elsif (/$INCLUDE_PATTERN/o)
6753         {
6754             my $path = $1;
6755
6756             if ($path =~ s/^\$\(top_srcdir\)\///)
6757               {
6758                 push (@include_stack, "\$\(top_srcdir\)/$path");
6759                 # Distribute any included file.
6760
6761                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6762                 # otherwise OSF make will implicitly copy the included
6763                 # file in the build tree during "make distdir" to satisfy
6764                 # the dependency.
6765                 # (subdircond2.test and subdircond3.test will fail.)
6766                 push_dist_common ("\$\(top_srcdir\)/$path");
6767               }
6768             else
6769               {
6770                 $path =~ s/\$\(srcdir\)\///;
6771                 push (@include_stack, "\$\(srcdir\)/$path");
6772                 # Always use the $(srcdir) prefix in DIST_COMMON,
6773                 # otherwise OSF make will implicitly copy the included
6774                 # file in the build tree during "make distdir" to satisfy
6775                 # the dependency.
6776                 # (subdircond2.test and subdircond3.test will fail.)
6777                 push_dist_common ("\$\(srcdir\)/$path");
6778                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6779               }
6780             $where->push_context ("'$path' included from here");
6781             &read_am_file ($path, $where);
6782             $where->pop_context;
6783         }
6784         else
6785         {
6786             # This isn't an error; it is probably a continued rule.
6787             # In fact, this is what we assume.
6788             $prev_state = IN_RULE_DEF;
6789             check_variable_expansions ($_, $where);
6790             $output_trailer .= $comment . $spacing;
6791             my $cond = new Automake::Condition @cond_stack;
6792             $output_trailer .= $cond->subst_string;
6793             $output_trailer .= $_;
6794             $comment = $spacing = '';
6795             error $where, "'#' comment at start of rule is unportable"
6796               if $_ =~ /^\t\s*\#/;
6797         }
6798
6799         $saw_bk = $new_saw_bk;
6800         $_ = $am_file->getline;
6801     }
6802
6803     $output_trailer .= $comment;
6804
6805     error ($where, "trailing backslash on last line")
6806       if $saw_bk;
6807
6808     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6809                     : "too many conditionals closed in include file"))
6810       if "@saved_cond_stack" ne "@cond_stack";
6811 }
6812
6813
6814 # define_standard_variables ()
6815 # ----------------------------
6816 # A helper for read_main_am_file which initializes configure variables
6817 # and variables from header-vars.am.
6818 sub define_standard_variables
6819 {
6820   my $saved_output_vars = $output_vars;
6821   my ($comments, undef, $rules) =
6822     file_contents_internal (1, "$libdir/am/header-vars.am",
6823                             new Automake::Location);
6824
6825   foreach my $var (sort keys %configure_vars)
6826     {
6827       &define_configure_variable ($var);
6828     }
6829
6830   $output_vars .= $comments . $rules;
6831 }
6832
6833 # Read main am file.
6834 sub read_main_am_file
6835 {
6836     my ($amfile) = @_;
6837
6838     # This supports the strange variable tricks we are about to play.
6839     prog_error ("variable defined before read_main_am_file\n" . variables_dump ())
6840       if (scalar (variables) > 0);
6841
6842     # Generate copyright header for generated Makefile.in.
6843     # We do discard the output of predefined variables, handled below.
6844     $output_vars = ("# $in_file_name generated by automake "
6845                    . $VERSION . " from $am_file_name.\n");
6846     $output_vars .= '# ' . subst ('configure_input') . "\n";
6847     $output_vars .= $gen_copyright;
6848
6849     # We want to predefine as many variables as possible.  This lets
6850     # the user set them with '+=' in Makefile.am.
6851     &define_standard_variables;
6852
6853     # Read user file, which might override some of our values.
6854     &read_am_file ($amfile, new Automake::Location);
6855 }
6856
6857
6858
6859 ################################################################
6860
6861 # $FLATTENED
6862 # &flatten ($STRING)
6863 # ------------------
6864 # Flatten the $STRING and return the result.
6865 sub flatten
6866 {
6867   $_ = shift;
6868
6869   s/\\\n//somg;
6870   s/\s+/ /g;
6871   s/^ //;
6872   s/ $//;
6873
6874   return $_;
6875 }
6876
6877
6878 # transform_token ($TOKEN, \%PAIRS, $KEY)
6879 # =======================================
6880 # Return the value associated to $KEY in %PAIRS, as used on $TOKEN
6881 # (which should be ?KEY? or any of the special %% requests)..
6882 sub transform_token ($$$)
6883 {
6884   my ($token, $transform, $key) = @_;
6885   my $res = $transform->{$key};
6886   prog_error "Unknown key '$key' in '$token'" unless defined $res;
6887   return $res;
6888 }
6889
6890
6891 # transform ($TOKEN, \%PAIRS)
6892 # ===========================
6893 # If ($TOKEN, $VAL) is in %PAIRS:
6894 #   - replaces %KEY% with $VAL,
6895 #   - enables/disables ?KEY? and ?!KEY?,
6896 #   - replaces %?KEY% with TRUE or FALSE.
6897 #   - replaces %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE% with
6898 #     IFTRUE / IFFALSE, as appropriate.
6899 sub transform ($$)
6900 {
6901   my ($token, $transform) = @_;
6902
6903   # %KEY%.
6904   # Must be before the following pattern to exclude the case
6905   # when there is neither IFTRUE nor IFFALSE.
6906   if ($token =~ /^%([\w\-]+)%$/)
6907     {
6908       return transform_token ($token, $transform, $1);
6909     }
6910   # %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE%.
6911   elsif ($token =~ /^%([\w\-]+)(?:\?([^?:%]+))?(?::([^?:%]+))?%$/)
6912     {
6913       return transform_token ($token, $transform, $1) ? ($2 || '') : ($3 || '');
6914     }
6915   # %?KEY%.
6916   elsif ($token =~ /^%\?([\w\-]+)%$/)
6917     {
6918       return transform_token ($token, $transform, $1) ? 'TRUE' : 'FALSE';
6919     }
6920   # ?KEY? and ?!KEY?.
6921   elsif ($token =~ /^ \? (!?) ([\w\-]+) \? $/x)
6922     {
6923       my $neg = ($1 eq '!') ? 1 : 0;
6924       my $val = transform_token ($token, $transform, $2);
6925       return (!!$val == $neg) ? '##%' : '';
6926     }
6927   else
6928     {
6929       prog_error "Unknown request format: $token";
6930     }
6931 }
6932
6933
6934 # @PARAGRAPHS
6935 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6936 # ------------------------------------------
6937 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6938 # paragraphs.
6939 sub make_paragraphs ($%)
6940 {
6941   my ($file, %transform) = @_;
6942
6943   # Complete %transform with global options.
6944   # Note that %transform goes last, so it overrides global options.
6945   %transform = ('CYGNUS'      => !! option 'cygnus',
6946                  'MAINTAINER-MODE'
6947                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6948
6949                  'XZ'          => !! option 'dist-xz',
6950                  'LZMA'        => !! option 'dist-lzma',
6951                  'LZIP'        => !! option 'dist-lzip',
6952                  'BZIP2'       => !! option 'dist-bzip2',
6953                  'COMPRESS'    => !! option 'dist-tarZ',
6954                  'GZIP'        =>  ! option 'no-dist-gzip',
6955                  'SHAR'        => !! option 'dist-shar',
6956                  'ZIP'         => !! option 'dist-zip',
6957
6958                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6959                  'INSTALL-MAN'  =>  ! option 'no-installman',
6960                  'HAVE-MANS'    => !! var ('MANS'),
6961                  'CK-NEWS'      => !! option 'check-news',
6962
6963                  'SUBDIRS'      => !! var ('SUBDIRS'),
6964                  'TOPDIR_P'     => $relative_dir eq '.',
6965
6966                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6967                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6968                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6969
6970                  'LIBTOOL'      => !! var ('LIBTOOL'),
6971                  'NONLIBTOOL'   => 1,
6972                  'FIRST'        => ! $transformed_files{$file},
6973                 %transform);
6974
6975   $transformed_files{$file} = 1;
6976   $_ = $am_file_cache{$file};
6977
6978   if (! defined $_)
6979     {
6980       verb "reading $file";
6981       # Swallow the whole file.
6982       my $fc_file = new Automake::XFile "< $file";
6983       my $saved_dollar_slash = $/;
6984       undef $/;
6985       $_ = $fc_file->getline;
6986       $/ = $saved_dollar_slash;
6987       $fc_file->close;
6988
6989       # Remove ##-comments.
6990       # Besides we don't need more than two consecutive new-lines.
6991       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6992
6993       $am_file_cache{$file} = $_;
6994     }
6995
6996   # Substitute Automake template tokens.
6997   s/(?: % \?? [\w\-]+ %
6998       | % [\w\-]+ (?:\?[^?:%]+)? (?::[^?:%]+)? %
6999       | \? !? [\w\-]+ \?
7000     )/transform($&, \%transform)/gex;
7001   # transform() may have added some ##%-comments to strip.
7002   # (we use '##%' instead of '##' so we can distinguish ##%##%##% from
7003   # ####### and do not remove the latter.)
7004   s/^[ \t]*(?:##%)+.*\n//gm;
7005
7006   # Split at unescaped new lines.
7007   my @lines = split (/(?<!\\)\n/, $_);
7008   my @res;
7009
7010   while (defined ($_ = shift @lines))
7011     {
7012       my $paragraph = $_;
7013       # If we are a rule, eat as long as we start with a tab.
7014       if (/$RULE_PATTERN/smo)
7015         {
7016           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
7017             {
7018               $paragraph .= "\n$_";
7019             }
7020           unshift (@lines, $_);
7021         }
7022
7023       # If we are a comments, eat as much comments as you can.
7024       elsif (/$COMMENT_PATTERN/smo)
7025         {
7026           while (defined ($_ = shift @lines)
7027                  && $_ =~ /$COMMENT_PATTERN/smo)
7028             {
7029               $paragraph .= "\n$_";
7030             }
7031           unshift (@lines, $_);
7032         }
7033
7034       push @res, $paragraph;
7035     }
7036
7037   return @res;
7038 }
7039
7040
7041
7042 # ($COMMENT, $VARIABLES, $RULES)
7043 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
7044 # -------------------------------------------------------------
7045 # Return contents of a file from $libdir/am, automatically skipping
7046 # macros or rules which are already known. $IS_AM iff the caller is
7047 # reading an Automake file (as opposed to the user's Makefile.am).
7048 sub file_contents_internal ($$$%)
7049 {
7050     my ($is_am, $file, $where, %transform) = @_;
7051
7052     $where->set ($file);
7053
7054     my $result_vars = '';
7055     my $result_rules = '';
7056     my $comment = '';
7057     my $spacing = '';
7058
7059     # The following flags are used to track rules spanning across
7060     # multiple paragraphs.
7061     my $is_rule = 0;            # 1 if we are processing a rule.
7062     my $discard_rule = 0;       # 1 if the current rule should not be output.
7063
7064     # We save the conditional stack on entry, and then check to make
7065     # sure it is the same on exit.  This lets us conditionally include
7066     # other files.
7067     my @saved_cond_stack = @cond_stack;
7068     my $cond = new Automake::Condition (@cond_stack);
7069
7070     foreach (make_paragraphs ($file, %transform))
7071     {
7072         # FIXME: no line number available.
7073         $where->set ($file);
7074
7075         # Sanity checks.
7076         error $where, "blank line following trailing backslash:\n$_"
7077           if /\\$/;
7078         error $where, "comment following trailing backslash:\n$_"
7079           if /\\#/;
7080
7081         if (/^$/)
7082         {
7083             $is_rule = 0;
7084             # Stick empty line before the incoming macro or rule.
7085             $spacing = "\n";
7086         }
7087         elsif (/$COMMENT_PATTERN/mso)
7088         {
7089             $is_rule = 0;
7090             # Stick comments before the incoming macro or rule.
7091             $comment = "$_\n";
7092         }
7093
7094         # Handle inclusion of other files.
7095         elsif (/$INCLUDE_PATTERN/o)
7096         {
7097             if ($cond != FALSE)
7098               {
7099                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
7100                 $where->push_context ("'$file' included from here");
7101                 # N-ary '.=' fails.
7102                 my ($com, $vars, $rules)
7103                   = file_contents_internal ($is_am, $file, $where, %transform);
7104                 $where->pop_context;
7105                 $comment .= $com;
7106                 $result_vars .= $vars;
7107                 $result_rules .= $rules;
7108               }
7109         }
7110
7111         # Handling the conditionals.
7112         elsif (/$IF_PATTERN/o)
7113           {
7114             $cond = cond_stack_if ($1, $2, $file);
7115           }
7116         elsif (/$ELSE_PATTERN/o)
7117           {
7118             $cond = cond_stack_else ($1, $2, $file);
7119           }
7120         elsif (/$ENDIF_PATTERN/o)
7121           {
7122             $cond = cond_stack_endif ($1, $2, $file);
7123           }
7124
7125         # Handling rules.
7126         elsif (/$RULE_PATTERN/mso)
7127         {
7128           $is_rule = 1;
7129           $discard_rule = 0;
7130           # Separate relationship from optional actions: the first
7131           # `new-line tab" not preceded by backslash (continuation
7132           # line).
7133           my $paragraph = $_;
7134           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
7135           my ($relationship, $actions) = ($1, $2 || '');
7136
7137           # Separate targets from dependencies: the first colon.
7138           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
7139           my ($targets, $dependencies) = ($1, $2);
7140           # Remove the escaped new lines.
7141           # I don't know why, but I have to use a tmp $flat_deps.
7142           my $flat_deps = &flatten ($dependencies);
7143           my @deps = split (' ', $flat_deps);
7144
7145           foreach (split (' ', $targets))
7146             {
7147               # FIXME: 1. We are not robust to people defining several targets
7148               # at once, only some of them being in %dependencies.  The
7149               # actions from the targets in %dependencies are usually generated
7150               # from the content of %actions, but if some targets in $targets
7151               # are not in %dependencies the ELSE branch will output
7152               # a rule for all $targets (i.e. the targets which are both
7153               # in %dependencies and $targets will have two rules).
7154
7155               # FIXME: 2. The logic here is not able to output a
7156               # multi-paragraph rule several time (e.g. for each condition
7157               # it is defined for) because it only knows the first paragraph.
7158
7159               # FIXME: 3. We are not robust to people defining a subset
7160               # of a previously defined "multiple-target" rule.  E.g.
7161               # 'foo:' after 'foo bar:'.
7162
7163               # Output only if not in FALSE.
7164               if (defined $dependencies{$_} && $cond != FALSE)
7165                 {
7166                   &depend ($_, @deps);
7167                   register_action ($_, $actions);
7168                 }
7169               else
7170                 {
7171                   # Free-lance dependency.  Output the rule for all the
7172                   # targets instead of one by one.
7173                   my @undefined_conds =
7174                     Automake::Rule::define ($targets, $file,
7175                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
7176                                             $cond, $where);
7177                   for my $undefined_cond (@undefined_conds)
7178                     {
7179                       my $condparagraph = $paragraph;
7180                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
7181                       $result_rules .= "$spacing$comment$condparagraph\n";
7182                     }
7183                   if (scalar @undefined_conds == 0)
7184                     {
7185                       # Remember to discard next paragraphs
7186                       # if they belong to this rule.
7187                       # (but see also FIXME: #2 above.)
7188                       $discard_rule = 1;
7189                     }
7190                   $comment = $spacing = '';
7191                   last;
7192                 }
7193             }
7194         }
7195
7196         elsif (/$ASSIGNMENT_PATTERN/mso)
7197         {
7198             my ($var, $type, $val) = ($1, $2, $3);
7199             error $where, "variable '$var' with trailing backslash"
7200               if /\\$/;
7201
7202             $is_rule = 0;
7203
7204             Automake::Variable::define ($var,
7205                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
7206                                         $type, $cond, $val, $comment, $where,
7207                                         VAR_ASIS)
7208               if $cond != FALSE;
7209
7210             $comment = $spacing = '';
7211         }
7212         else
7213         {
7214             # This isn't an error; it is probably some tokens which
7215             # configure is supposed to replace, such as '@SET-MAKE@',
7216             # or some part of a rule cut by an if/endif.
7217             if (! $cond->false && ! ($is_rule && $discard_rule))
7218               {
7219                 s/^/$cond->subst_string/gme;
7220                 $result_rules .= "$spacing$comment$_\n";
7221               }
7222             $comment = $spacing = '';
7223         }
7224     }
7225
7226     error ($where, @cond_stack ?
7227            "unterminated conditionals: @cond_stack" :
7228            "too many conditionals closed in include file")
7229       if "@saved_cond_stack" ne "@cond_stack";
7230
7231     return ($comment, $result_vars, $result_rules);
7232 }
7233
7234
7235 # $CONTENTS
7236 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
7237 # ------------------------------------------------
7238 # Return contents of a file from $libdir/am, automatically skipping
7239 # macros or rules which are already known.
7240 sub file_contents ($$%)
7241 {
7242     my ($basename, $where, %transform) = @_;
7243     my ($comments, $variables, $rules) =
7244       file_contents_internal (1, "$libdir/am/$basename.am", $where,
7245                               %transform);
7246     return "$comments$variables$rules";
7247 }
7248
7249
7250 # @PREFIX
7251 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
7252 # -----------------------------------------------------
7253 # Find all variable prefixes that are used for install directories.  A
7254 # prefix 'zar' qualifies iff:
7255 #
7256 # * 'zardir' is a variable.
7257 # * 'zar_PRIMARY' is a variable.
7258 #
7259 # As a side effect, it looks for misspellings.  It is an error to have
7260 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
7261 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
7262 # of the same name (with "dir" appended) exists.  For instance, if the
7263 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
7264 # This is to provide a little extra flexibility in those cases which
7265 # need it.
7266 sub am_primary_prefixes ($$@)
7267 {
7268   my ($primary, $can_dist, @prefixes) = @_;
7269
7270   local $_;
7271   my %valid = map { $_ => 0 } @prefixes;
7272   $valid{'EXTRA'} = 0;
7273   foreach my $var (variables $primary)
7274     {
7275       # Automake is allowed to define variables that look like primaries
7276       # but which aren't.  E.g. INSTALL_sh_DATA.
7277       # Autoconf can also define variables like INSTALL_DATA, so
7278       # ignore all configure variables (at least those which are not
7279       # redefined in Makefile.am).
7280       # FIXME: We should make sure that these variables are not
7281       # conditionally defined (or else adjust the condition below).
7282       my $def = $var->def (TRUE);
7283       next if $def && $def->owner != VAR_MAKEFILE;
7284
7285       my $varname = $var->name;
7286
7287       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
7288         {
7289           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
7290           if ($dist ne '' && ! $can_dist)
7291             {
7292               err_var ($var,
7293                        "invalid variable '$varname': 'dist' is forbidden");
7294             }
7295           # Standard directories must be explicitly allowed.
7296           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
7297             {
7298               err_var ($var,
7299                        "'${X}dir' is not a legitimate directory " .
7300                        "for '$primary'");
7301             }
7302           # A not explicitly valid directory is allowed if Xdir is defined.
7303           elsif (! defined $valid{$X} &&
7304                  $var->requires_variables ("'$varname' is used", "${X}dir"))
7305             {
7306               # Nothing to do.  Any error message has been output
7307               # by $var->requires_variables.
7308             }
7309           else
7310             {
7311               # Ensure all extended prefixes are actually used.
7312               $valid{"$base$dist$X"} = 1;
7313             }
7314         }
7315       else
7316         {
7317           prog_error "unexpected variable name: $varname";
7318         }
7319     }
7320
7321   # Return only those which are actually defined.
7322   return sort grep { var ($_ . '_' . $primary) } keys %valid;
7323 }
7324
7325
7326 # Handle 'where_HOW' variable magic.  Does all lookups, generates
7327 # install code, and possibly generates code to define the primary
7328 # variable.  The first argument is the name of the .am file to munge,
7329 # the second argument is the primary variable (e.g. HEADERS), and all
7330 # subsequent arguments are possible installation locations.
7331 #
7332 # Returns list of [$location, $value] pairs, where
7333 # $value's are the values in all where_HOW variable, and $location
7334 # there associated location (the place here their parent variables were
7335 # defined).
7336 #
7337 # FIXME: this should be rewritten to be cleaner.  It should be broken
7338 # up into multiple functions.
7339 #
7340 # Usage is: am_install_var (OPTION..., file, HOW, where...)
7341 sub am_install_var
7342 {
7343   my (@args) = @_;
7344
7345   my $do_require = 1;
7346   my $can_dist = 0;
7347   my $default_dist = 0;
7348   while (@args)
7349     {
7350       if ($args[0] eq '-noextra')
7351         {
7352           $do_require = 0;
7353         }
7354       elsif ($args[0] eq '-candist')
7355         {
7356           $can_dist = 1;
7357         }
7358       elsif ($args[0] eq '-defaultdist')
7359         {
7360           $default_dist = 1;
7361           $can_dist = 1;
7362         }
7363       elsif ($args[0] !~ /^-/)
7364         {
7365           last;
7366         }
7367       shift (@args);
7368     }
7369
7370   my ($file, $primary, @prefix) = @args;
7371
7372   # Now that configure substitutions are allowed in where_HOW
7373   # variables, it is an error to actually define the primary.  We
7374   # allow 'JAVA', as it is customarily used to mean the Java
7375   # interpreter.  This is but one of several Java hacks.  Similarly,
7376   # 'PYTHON' is customarily used to mean the Python interpreter.
7377   reject_var $primary, "'$primary' is an anachronism"
7378     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
7379
7380   # Get the prefixes which are valid and actually used.
7381   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
7382
7383   # If a primary includes a configure substitution, then the EXTRA_
7384   # form is required.  Otherwise we can't properly do our job.
7385   my $require_extra;
7386
7387   my @used = ();
7388   my @result = ();
7389
7390   foreach my $X (@prefix)
7391     {
7392       my $nodir_name = $X;
7393       my $one_name = $X . '_' . $primary;
7394       my $one_var = var $one_name;
7395
7396       my $strip_subdir = 1;
7397       # If subdir prefix should be preserved, do so.
7398       if ($nodir_name =~ /^nobase_/)
7399         {
7400           $strip_subdir = 0;
7401           $nodir_name =~ s/^nobase_//;
7402         }
7403
7404       # If files should be distributed, do so.
7405       my $dist_p = 0;
7406       if ($can_dist)
7407         {
7408           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
7409                      || (! $default_dist && $nodir_name =~ /^dist_/));
7410           $nodir_name =~ s/^(dist|nodist)_//;
7411         }
7412
7413
7414       # Use the location of the currently processed variable.
7415       # We are not processing a particular condition, so pick the first
7416       # available.
7417       my $tmpcond = $one_var->conditions->one_cond;
7418       my $where = $one_var->rdef ($tmpcond)->location->clone;
7419
7420       # Append actual contents of where_PRIMARY variable to
7421       # @result, skipping @substitutions@.
7422       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
7423         {
7424           my ($loc, $value) = @$locvals;
7425           # Skip configure substitutions.
7426           if ($value =~ /^\@.*\@$/)
7427             {
7428               if ($nodir_name eq 'EXTRA')
7429                 {
7430                   error ($where,
7431                          "'$one_name' contains configure substitution, "
7432                          . "but shouldn't");
7433                 }
7434               # Check here to make sure variables defined in
7435               # configure.ac do not imply that EXTRA_PRIMARY
7436               # must be defined.
7437               elsif (! defined $configure_vars{$one_name})
7438                 {
7439                   $require_extra = $one_name
7440                     if $do_require;
7441                 }
7442             }
7443           else
7444             {
7445               # Strip any $(EXEEXT) suffix the user might have added, or this
7446               # will confuse &handle_source_transform and &check_canonical_spelling.
7447               # We'll add $(EXEEXT) back later anyway.
7448               # Do it here rather than in handle_programs so the uniquifying at the
7449               # end of this function works.
7450               ${$locvals}[1] =~ s/\$\(EXEEXT\)$//
7451                 if $primary eq 'PROGRAMS';
7452
7453               push (@result, $locvals);
7454             }
7455         }
7456       # A blatant hack: we rewrite each _PROGRAMS primary to include
7457       # EXEEXT.
7458       append_exeext { 1 } $one_name
7459         if $primary eq 'PROGRAMS';
7460       # "EXTRA" shouldn't be used when generating clean targets,
7461       # all, or install targets.  We used to warn if EXTRA_FOO was
7462       # defined uselessly, but this was annoying.
7463       next
7464         if $nodir_name eq 'EXTRA';
7465
7466       if ($nodir_name eq 'check')
7467         {
7468           push (@check, '$(' . $one_name . ')');
7469         }
7470       else
7471         {
7472           push (@used, '$(' . $one_name . ')');
7473         }
7474
7475       # Is this to be installed?
7476       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
7477
7478       # If so, with install-exec? (or install-data?).
7479       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
7480
7481       my $check_options_p = $install_p && !! option 'std-options';
7482
7483       # Use the location of the currently processed variable as context.
7484       $where->push_context ("while processing '$one_name'");
7485
7486       # The variable containing all files to distribute.
7487       my $distvar = "\$($one_name)";
7488       $distvar = shadow_unconditionally ($one_name, $where)
7489         if ($dist_p && $one_var->has_conditional_contents);
7490
7491       # Singular form of $PRIMARY.
7492       (my $one_primary = $primary) =~ s/S$//;
7493       $output_rules .= &file_contents ($file, $where,
7494                                        PRIMARY     => $primary,
7495                                        ONE_PRIMARY => $one_primary,
7496                                        DIR         => $X,
7497                                        NDIR        => $nodir_name,
7498                                        BASE        => $strip_subdir,
7499
7500                                        EXEC      => $exec_p,
7501                                        INSTALL   => $install_p,
7502                                        DIST      => $dist_p,
7503                                        DISTVAR   => $distvar,
7504                                        'CK-OPTS' => $check_options_p);
7505     }
7506
7507   # The JAVA variable is used as the name of the Java interpreter.
7508   # The PYTHON variable is used as the name of the Python interpreter.
7509   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7510     {
7511       # Define it.
7512       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7513       $output_vars .= "\n";
7514     }
7515
7516   err_var ($require_extra,
7517            "'$require_extra' contains configure substitution,\n"
7518            . "but 'EXTRA_$primary' not defined")
7519     if ($require_extra && ! var ('EXTRA_' . $primary));
7520
7521   # Push here because PRIMARY might be configure time determined.
7522   push (@all, '$(' . $primary . ')')
7523     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7524
7525   # Make the result unique.  This lets the user use conditionals in
7526   # a natural way, but still lets us program lazily -- we don't have
7527   # to worry about handling a particular object more than once.
7528   # We will keep only one location per object.
7529   my %result = ();
7530   for my $pair (@result)
7531     {
7532       my ($loc, $val) = @$pair;
7533       $result{$val} = $loc;
7534     }
7535   my @l = sort keys %result;
7536   return map { [$result{$_}->clone, $_] } @l;
7537 }
7538
7539
7540 ################################################################
7541
7542 # Each key in this hash is the name of a directory holding a
7543 # Makefile.in.  These variables are local to 'is_make_dir'.
7544 my %make_dirs = ();
7545 my $make_dirs_set = 0;
7546
7547 sub is_make_dir
7548 {
7549     my ($dir) = @_;
7550     if (! $make_dirs_set)
7551     {
7552         foreach my $iter (@configure_input_files)
7553         {
7554             $make_dirs{dirname ($iter)} = 1;
7555         }
7556         # We also want to notice Makefile.in's.
7557         foreach my $iter (@other_input_files)
7558         {
7559             if ($iter =~ /Makefile\.in$/)
7560             {
7561                 $make_dirs{dirname ($iter)} = 1;
7562             }
7563         }
7564         $make_dirs_set = 1;
7565     }
7566     return defined $make_dirs{$dir};
7567 }
7568
7569 ################################################################
7570
7571 # Find the aux dir.  This should match the algorithm used by
7572 # ./configure. (See the Autoconf documentation for for
7573 # AC_CONFIG_AUX_DIR.)
7574 sub locate_aux_dir ()
7575 {
7576   if (! $config_aux_dir_set_in_configure_ac)
7577     {
7578       # The default auxiliary directory is the first
7579       # of ., .., or ../.. that contains install-sh.
7580       # Assume . if install-sh doesn't exist yet.
7581       for my $dir (qw (. .. ../..))
7582         {
7583           if (-f "$dir/install-sh")
7584             {
7585               $config_aux_dir = $dir;
7586               last;
7587             }
7588         }
7589       $config_aux_dir = '.' unless $config_aux_dir;
7590     }
7591   # Avoid unsightly '/.'s.
7592   $am_config_aux_dir =
7593     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7594   $am_config_aux_dir =~ s,/*$,,;
7595 }
7596
7597
7598 # &push_required_file ($DIR, $FILE, $FULLFILE)
7599 # --------------------------------------------------
7600 # Push the given file onto DIST_COMMON.
7601 sub push_required_file
7602 {
7603   my ($dir, $file, $fullfile) = @_;
7604
7605   # If the file to be distributed is in the same directory of the
7606   # currently processed Makefile.am, then we want to distribute it
7607   # from this same Makefile.am.
7608   if ($dir eq $relative_dir)
7609     {
7610       push_dist_common ($file);
7611     }
7612   # This is needed to allow a construct in a non-top-level Makefile.am
7613   # to require a file in the build-aux directory (see at least the test
7614   # script 'test-driver-is-distributed.test').  This is related to the
7615   # automake bug#9546.  Note that the use of $config_aux_dir instead
7616   # of $am_config_aux_dir here is deliberate and necessary.
7617   elsif ($dir eq $config_aux_dir)
7618     {
7619       push_dist_common ("$am_config_aux_dir/$file");
7620     }
7621   # FIXME: another spacial case, for AC_LIBOBJ/AC_LIBSOURCE support.
7622   # We probably need some refactoring of this function and its callers,
7623   # to have a more explicit and systematic handling of all the special
7624   # cases; but, since there are only two of them, this is low-priority
7625   # ATM.
7626   elsif ($config_libobj_dir && $dir eq $config_libobj_dir)
7627     {
7628       # Avoid unsightly '/.'s.
7629       my $am_config_libobj_dir =
7630         '$(top_srcdir)' .
7631         ($config_libobj_dir eq '.' ? "" : "/$config_libobj_dir");
7632       $am_config_libobj_dir =~ s|/*$||;
7633       push_dist_common ("$am_config_libobj_dir/$file");
7634     }
7635   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7636     {
7637       # If we are doing the topmost directory, and the file is in a
7638       # subdir which does not have a Makefile, then we distribute it
7639       # here.
7640
7641       # If a required file is above the source tree, it is important
7642       # to prefix it with '$(srcdir)' so that no VPATH search is
7643       # performed.  Otherwise problems occur with Make implementations
7644       # that rewrite and simplify rules whose dependencies are found in a
7645       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7646       #
7647       #   % cat Makefile
7648       #   VPATH = sub
7649       #   distdir: ../a
7650       #           echo ../a
7651       #   % ls
7652       #   Makefile a
7653       #   % make
7654       #   echo a
7655       #   a
7656       #
7657       # Dependency '../a' was found in 'sub/../a', but this make
7658       # implementation simplified it as 'a'.  (Note that the sub/
7659       # directory does not even exist.)
7660       #
7661       # This kind of VPATH rewriting seems hard to cancel.  The
7662       # distdir.am hack against VPATH rewriting works only when no
7663       # simplification is done, i.e., for dependencies which are in
7664       # subdirectories, not in enclosing directories.  Hence, in
7665       # the latter case we use a full path to make sure no VPATH
7666       # search occurs.
7667       $fullfile = '$(srcdir)/' . $fullfile
7668         if $dir =~ m,^\.\.(?:$|/),;
7669
7670       push_dist_common ($fullfile);
7671     }
7672   else
7673     {
7674       prog_error "a Makefile in relative directory $relative_dir " .
7675                  "can't add files in directory $dir to DIST_COMMON";
7676     }
7677 }
7678
7679
7680 # If a file name appears as a key in this hash, then it has already
7681 # been checked for.  This allows us not to report the same error more
7682 # than once.
7683 my %required_file_not_found = ();
7684
7685 # &required_file_check_or_copy ($WHERE, $DIRECTORY, $FILE)
7686 # --------------------------------------------------------
7687 # Verify that the file must exist in $DIRECTORY, or install it.
7688 sub required_file_check_or_copy ($$$)
7689 {
7690   my ($where, $dir, $file) = @_;
7691
7692   my $fullfile = "$dir/$file";
7693   my $found_it = 0;
7694   my $dangling_sym = 0;
7695
7696   if (-l $fullfile && ! -f $fullfile)
7697     {
7698       $dangling_sym = 1;
7699     }
7700   elsif (dir_has_case_matching_file ($dir, $file))
7701     {
7702       $found_it = 1;
7703     }
7704
7705   # '--force-missing' only has an effect if '--add-missing' is
7706   # specified.
7707   return
7708     if $found_it && (! $add_missing || ! $force_missing);
7709
7710   # If we've already looked for it, we're done.  You might
7711   # wonder why we don't do this before searching for the
7712   # file.  If we do that, then something like
7713   # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7714   # DIST_COMMON.
7715   if (! $found_it)
7716     {
7717       return if defined $required_file_not_found{$fullfile};
7718       $required_file_not_found{$fullfile} = 1;
7719     }
7720   if ($dangling_sym && $add_missing)
7721     {
7722       unlink ($fullfile);
7723     }
7724
7725   my $trailer = '';
7726   my $trailer2 = '';
7727   my $suppress = 0;
7728
7729   # Only install missing files according to our desired
7730   # strictness level.
7731   my $message = "required file '$fullfile' not found";
7732   if ($add_missing)
7733     {
7734       if (-f "$libdir/$file")
7735         {
7736           $suppress = 1;
7737
7738           # Install the missing file.  Symlink if we
7739           # can, copy if we must.  Note: delete the file
7740           # first, in case it is a dangling symlink.
7741           $message = "installing '$fullfile'";
7742
7743           # The license file should not be volatile.
7744           if ($file eq "COPYING")
7745             {
7746               $message .= " using GNU General Public License v3 file";
7747               $trailer2 = "\n    Consider adding the COPYING file"
7748                         . " to the version control system"
7749                         . "\n    for your code, to avoid questions"
7750                         . " about which license your project uses";
7751             }
7752
7753           # Windows Perl will hang if we try to delete a
7754           # file that doesn't exist.
7755           unlink ($fullfile) if -f $fullfile;
7756           if ($symlink_exists && ! $copy_missing)
7757             {
7758               if (! symlink ("$libdir/$file", $fullfile)
7759                   || ! -e $fullfile)
7760                 {
7761                   $suppress = 0;
7762                   $trailer = "; error while making link: $!";
7763                 }
7764             }
7765           elsif (system ('cp', "$libdir/$file", $fullfile))
7766             {
7767               $suppress = 0;
7768               $trailer = "\n    error while copying";
7769             }
7770           set_dir_cache_file ($dir, $file);
7771         }
7772     }
7773   else
7774     {
7775       $trailer = "\n  'automake --add-missing' can install '$file'"
7776         if -f "$libdir/$file";
7777     }
7778
7779   # If --force-missing was specified, and we have
7780   # actually found the file, then do nothing.
7781   return
7782     if $found_it && $force_missing;
7783
7784   # If we couldn't install the file, but it is a target in
7785   # the Makefile, don't print anything.  This allows files
7786   # like README, AUTHORS, or THANKS to be generated.
7787   return
7788     if !$suppress && rule $file;
7789
7790   msg ($suppress ? 'note' : 'error', $where, "$message$trailer$trailer2");
7791 }
7792
7793
7794 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, $QUEUE, @FILES)
7795 # ----------------------------------------------------------------------
7796 # Verify that the file must exist in $DIRECTORY, or install it.
7797 # $MYSTRICT is the strictness level at which this file becomes required.
7798 # Worker threads may queue up the action to be serialized by the master,
7799 # if $QUEUE is true
7800 sub require_file_internal ($$$@)
7801 {
7802   my ($where, $mystrict, $dir, $queue, @files) = @_;
7803
7804   return
7805     unless $strictness >= $mystrict;
7806
7807   foreach my $file (@files)
7808     {
7809       push_required_file ($dir, $file, "$dir/$file");
7810       if ($queue)
7811         {
7812           queue_required_file_check_or_copy ($required_conf_file_queue,
7813                                              QUEUE_CONF_FILE, $relative_dir,
7814                                              $where, $mystrict, @files);
7815         }
7816       else
7817         {
7818           required_file_check_or_copy ($where, $dir, $file);
7819         }
7820     }
7821 }
7822
7823 # &require_file ($WHERE, $MYSTRICT, @FILES)
7824 # -----------------------------------------
7825 sub require_file ($$@)
7826 {
7827     my ($where, $mystrict, @files) = @_;
7828     require_file_internal ($where, $mystrict, $relative_dir, 0, @files);
7829 }
7830
7831 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7832 # -----------------------------------------------------------
7833 sub require_file_with_macro ($$$@)
7834 {
7835     my ($cond, $macro, $mystrict, @files) = @_;
7836     $macro = rvar ($macro) unless ref $macro;
7837     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7838 }
7839
7840 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7841 # ----------------------------------------------------------------
7842 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7843 # must be in that directory.  Otherwise expect it in the current directory.
7844 sub require_libsource_with_macro ($$$@)
7845 {
7846     my ($cond, $macro, $mystrict, @files) = @_;
7847     $macro = rvar ($macro) unless ref $macro;
7848     if ($config_libobj_dir)
7849       {
7850         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7851                                $config_libobj_dir, 0, @files);
7852       }
7853     else
7854       {
7855         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7856       }
7857 }
7858
7859 # &queue_required_file_check_or_copy ($QUEUE, $KEY, $DIR, $WHERE,
7860 #                                     $MYSTRICT, @FILES)
7861 # ---------------------------------------------------------------
7862 sub queue_required_file_check_or_copy ($$$$@)
7863 {
7864     my ($queue, $key, $dir, $where, $mystrict, @files) = @_;
7865     my @serial_loc;
7866     if (ref $where)
7867       {
7868         @serial_loc = (QUEUE_LOCATION, $where->serialize ());
7869       }
7870     else
7871       {
7872         @serial_loc = (QUEUE_STRING, $where);
7873       }
7874     $queue->enqueue ($key, $dir, @serial_loc, $mystrict, 0 + @files, @files);
7875 }
7876
7877 # &require_queued_file_check_or_copy ($QUEUE)
7878 # -------------------------------------------
7879 sub require_queued_file_check_or_copy ($)
7880 {
7881     my ($queue) = @_;
7882     my $where;
7883     my $dir = $queue->dequeue ();
7884     my $loc_key = $queue->dequeue ();
7885     if ($loc_key eq QUEUE_LOCATION)
7886       {
7887         $where = Automake::Location::deserialize ($queue);
7888       }
7889     elsif ($loc_key eq QUEUE_STRING)
7890       {
7891         $where = $queue->dequeue ();
7892       }
7893     else
7894       {
7895         prog_error "unexpected key $loc_key";
7896       }
7897     my $mystrict = $queue->dequeue ();
7898     my $nfiles = $queue->dequeue ();
7899     my @files;
7900     push @files, $queue->dequeue ()
7901       foreach (1 .. $nfiles);
7902     return
7903       unless $strictness >= $mystrict;
7904     foreach my $file (@files)
7905       {
7906         required_file_check_or_copy ($where, $config_aux_dir, $file);
7907       }
7908 }
7909
7910 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7911 # ----------------------------------------------
7912 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7913 sub require_conf_file ($$@)
7914 {
7915     my ($where, $mystrict, @files) = @_;
7916     my $queue = defined $required_conf_file_queue ? 1 : 0;
7917     require_file_internal ($where, $mystrict, $config_aux_dir,
7918                            $queue, @files);
7919 }
7920
7921
7922 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7923 # ----------------------------------------------------------------
7924 sub require_conf_file_with_macro ($$$@)
7925 {
7926     my ($cond, $macro, $mystrict, @files) = @_;
7927     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7928                        $mystrict, @files);
7929 }
7930
7931 ################################################################
7932
7933 # &require_build_directory ($DIRECTORY)
7934 # -------------------------------------
7935 # Emit rules to create $DIRECTORY if needed, and return
7936 # the file that any target requiring this directory should be made
7937 # dependent upon.
7938 # We don't want to emit the rule twice, and want to reuse it
7939 # for directories with equivalent names (e.g., 'foo/bar' and './foo//bar').
7940 sub require_build_directory ($)
7941 {
7942   my $directory = shift;
7943
7944   return $directory_map{$directory} if exists $directory_map{$directory};
7945
7946   my $cdir = File::Spec->canonpath ($directory);
7947
7948   if (exists $directory_map{$cdir})
7949     {
7950       my $stamp = $directory_map{$cdir};
7951       $directory_map{$directory} = $stamp;
7952       return $stamp;
7953     }
7954
7955   my $dirstamp = "$cdir/\$(am__dirstamp)";
7956
7957   $directory_map{$directory} = $dirstamp;
7958   $directory_map{$cdir} = $dirstamp;
7959
7960   # Set a variable for the dirstamp basename.
7961   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7962                           '$(am__leading_dot)dirstamp');
7963
7964   # Directory must be removed by 'make distclean'.
7965   $clean_files{$dirstamp} = DIST_CLEAN;
7966
7967   $output_rules .= ("$dirstamp:\n"
7968                     . "\t\@\$(MKDIR_P) $directory\n"
7969                     . "\t\@: > $dirstamp\n");
7970
7971   return $dirstamp;
7972 }
7973
7974 # &require_build_directory_maybe ($FILE)
7975 # --------------------------------------
7976 # If $FILE lies in a subdirectory, emit a rule to create this
7977 # directory and return the file that $FILE should be made
7978 # dependent upon.  Otherwise, just return the empty string.
7979 sub require_build_directory_maybe ($)
7980 {
7981     my $file = shift;
7982     my $directory = dirname ($file);
7983
7984     if ($directory ne '.')
7985     {
7986         return require_build_directory ($directory);
7987     }
7988     else
7989     {
7990         return '';
7991     }
7992 }
7993
7994 ################################################################
7995
7996 # Push a list of files onto dist_common.
7997 sub push_dist_common
7998 {
7999   prog_error "push_dist_common run after handle_dist"
8000     if $handle_dist_run;
8001   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
8002                               '', INTERNAL, VAR_PRETTY);
8003 }
8004
8005
8006 ################################################################
8007
8008 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
8009 # ----------------------------------------------
8010 # Generate a Makefile.in given the name of the corresponding Makefile and
8011 # the name of the file output by config.status.
8012 sub generate_makefile ($$)
8013 {
8014   my ($makefile_am, $makefile_in) = @_;
8015
8016   # Reset all the Makefile.am related variables.
8017   initialize_per_input;
8018
8019   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
8020   # warnings for this file.  So hold any warning issued before
8021   # we have processed AUTOMAKE_OPTIONS.
8022   buffer_messages ('warning');
8023
8024   # Name of input file ("Makefile.am") and output file
8025   # ("Makefile.in").  These have no directory components.
8026   $am_file_name = basename ($makefile_am);
8027   $in_file_name = basename ($makefile_in);
8028
8029   # $OUTPUT is encoded.  If it contains a ":" then the first element
8030   # is the real output file, and all remaining elements are input
8031   # files.  We don't scan or otherwise deal with these input files,
8032   # other than to mark them as dependencies.  See
8033   # &scan_autoconf_files for details.
8034   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
8035
8036   $relative_dir = dirname ($makefile);
8037   $am_relative_dir = dirname ($makefile_am);
8038   $topsrcdir = backname ($relative_dir);
8039
8040   read_main_am_file ($makefile_am);
8041   if (handle_options)
8042     {
8043       # Process buffered warnings.
8044       flush_messages;
8045       # Fatal error.  Just return, so we can continue with next file.
8046       return;
8047     }
8048   # Process buffered warnings.
8049   flush_messages;
8050
8051   # There are a few install-related variables that you should not define.
8052   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
8053     {
8054       my $v = var $var;
8055       if ($v)
8056         {
8057           my $def = $v->def (TRUE);
8058           prog_error "$var not defined in condition TRUE"
8059             unless $def;
8060           reject_var $var, "'$var' should not be defined"
8061             if $def->owner != VAR_AUTOMAKE;
8062         }
8063     }
8064
8065   # Catch some obsolete variables.
8066   msg_var ('obsolete', 'INCLUDES',
8067            "'INCLUDES' is the old name for 'AM_CPPFLAGS' (or '*_CPPFLAGS')")
8068     if var ('INCLUDES');
8069
8070   # Must do this after reading .am file.
8071   define_variable ('subdir', $relative_dir, INTERNAL);
8072
8073   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
8074   # recursive rules are enabled.
8075   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
8076     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
8077
8078   # Check first, because we might modify some state.
8079   check_cygnus;
8080   check_gnu_standards;
8081   check_gnits_standards;
8082
8083   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
8084   handle_gettext;
8085   handle_libraries;
8086   handle_ltlibraries;
8087   handle_programs;
8088   handle_scripts;
8089
8090   # These must be run after all the sources are scanned.  They
8091   # use variables defined by &handle_libraries, &handle_ltlibraries,
8092   # or &handle_programs.
8093   handle_compile;
8094   handle_languages;
8095   handle_libtool;
8096
8097   # Variables used by distdir.am and tags.am.
8098   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
8099   if (! option 'no-dist')
8100     {
8101       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
8102     }
8103
8104   handle_texinfo;
8105   handle_emacs_lisp;
8106   handle_python;
8107   handle_java;
8108   handle_man_pages;
8109   handle_data;
8110   handle_headers;
8111   handle_subdirs;
8112   handle_tags;
8113   handle_minor_options;
8114   # Must come after handle_programs so that %known_programs is up-to-date.
8115   handle_tests;
8116
8117   # This must come after most other rules.
8118   handle_dist;
8119
8120   handle_footer;
8121   do_check_merge_target;
8122   handle_all ($makefile);
8123
8124   # FIXME: Gross!
8125   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8126     {
8127       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
8128     }
8129   if (var ('nobase_lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8130     {
8131       $output_rules .= "install-binPROGRAMS: install-nobase_libLTLIBRARIES\n\n";
8132     }
8133
8134   handle_install;
8135   handle_clean ($makefile);
8136   handle_factored_dependencies;
8137
8138   # Comes last, because all the above procedures may have
8139   # defined or overridden variables.
8140   $output_vars .= output_variables;
8141
8142   check_typos;
8143
8144   if ($exit_code != 0)
8145     {
8146       verb "not writing $makefile_in because of earlier errors";
8147       return;
8148     }
8149
8150   mkdir ($am_relative_dir, 0755) if ! -d $am_relative_dir;
8151
8152   # We make sure that 'all:' is the first target.
8153   my $output =
8154     "$output_vars$output_all$output_header$output_rules$output_trailer";
8155
8156   # Decide whether we must update the output file or not.
8157   # We have to update in the following situations.
8158   #  * $force_generation is set.
8159   #  * any of the output dependencies is younger than the output
8160   #  * the contents of the output is different (this can happen
8161   #    if the project has been populated with a file listed in
8162   #    @common_files since the last run).
8163   # Output's dependencies are split in two sets:
8164   #  * dependencies which are also configure dependencies
8165   #    These do not change between each Makefile.am
8166   #  * other dependencies, specific to the Makefile.am being processed
8167   #    (such as the Makefile.am itself, or any Makefile fragment
8168   #    it includes).
8169   my $timestamp = mtime $makefile_in;
8170   if (! $force_generation
8171       && $configure_deps_greatest_timestamp < $timestamp
8172       && $output_deps_greatest_timestamp < $timestamp
8173       && $output eq contents ($makefile_in))
8174     {
8175       verb "$makefile_in unchanged";
8176       # No need to update.
8177       return;
8178     }
8179
8180   if (-e $makefile_in)
8181     {
8182       unlink ($makefile_in)
8183         or fatal "cannot remove $makefile_in: $!";
8184     }
8185
8186   my $gm_file = new Automake::XFile "> $makefile_in";
8187   verb "creating $makefile_in";
8188   print $gm_file $output;
8189 }
8190
8191 ################################################################
8192
8193
8194
8195
8196 ################################################################
8197
8198 # Helper function for usage().
8199 sub print_autodist_files (@)
8200 {
8201   my @lcomm = sort (&uniq (@_));
8202
8203   my @four;
8204   format USAGE_FORMAT =
8205   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
8206   $four[0],           $four[1],           $four[2],           $four[3]
8207 .
8208   local $~ = "USAGE_FORMAT";
8209
8210   my $cols = 4;
8211   my $rows = int(@lcomm / $cols);
8212   my $rest = @lcomm % $cols;
8213
8214   if ($rest)
8215     {
8216       $rows++;
8217     }
8218   else
8219     {
8220       $rest = $cols;
8221     }
8222
8223   for (my $y = 0; $y < $rows; $y++)
8224     {
8225       @four = ("", "", "", "");
8226       for (my $x = 0; $x < $cols; $x++)
8227         {
8228           last if $y + 1 == $rows && $x == $rest;
8229
8230           my $idx = (($x > $rest)
8231                ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
8232                : ($rows * $x));
8233
8234           $idx += $y;
8235           $four[$x] = $lcomm[$idx];
8236         }
8237       write;
8238     }
8239 }
8240
8241
8242 # Print usage information.
8243 sub usage ()
8244 {
8245     print "Usage: $0 [OPTION]... [Makefile]...
8246
8247 Generate Makefile.in for configure from Makefile.am.
8248
8249 Operation modes:
8250       --help               print this help, then exit
8251       --version            print version number, then exit
8252   -v, --verbose            verbosely list files processed
8253       --no-force           only update Makefile.in's that are out of date
8254   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
8255
8256 Dependency tracking:
8257   -i, --ignore-deps      disable dependency tracking code
8258       --include-deps     enable dependency tracking code
8259
8260 Flavors:
8261       --cygnus           assume program is part of Cygnus-style tree
8262       --foreign          set strictness to foreign
8263       --gnits            set strictness to gnits
8264       --gnu              set strictness to gnu
8265
8266 Library files:
8267   -a, --add-missing      add missing standard files to package
8268       --libdir=DIR       set directory storing library files
8269       --print-libdir     print directory storing library files
8270   -c, --copy             with -a, copy missing files (default is symlink)
8271   -f, --force-missing    force update of standard files
8272
8273 ";
8274     Automake::ChannelDefs::usage;
8275
8276     print "\nFiles automatically distributed if found " .
8277           "(always):\n";
8278     print_autodist_files @common_files;
8279     print "\nFiles automatically distributed if found " .
8280           "(under certain conditions):\n";
8281     print_autodist_files @common_sometimes;
8282
8283     print '
8284 Report bugs to <@PACKAGE_BUGREPORT@>.
8285 GNU Automake home page: <@PACKAGE_URL@>.
8286 General help using GNU software: <http://www.gnu.org/gethelp/>.
8287 ';
8288
8289     # --help always returns 0 per GNU standards.
8290     exit 0;
8291 }
8292
8293
8294 # &version ()
8295 # -----------
8296 # Print version information
8297 sub version ()
8298 {
8299   print <<EOF;
8300 automake (GNU $PACKAGE) $VERSION
8301 Copyright (C) 2011 Free Software Foundation, Inc.
8302 License GPLv2+: GNU GPL version 2 or later <http://gnu.org/licenses/gpl-2.0.html>
8303 This is free software: you are free to change and redistribute it.
8304 There is NO WARRANTY, to the extent permitted by law.
8305
8306 Written by Tom Tromey <tromey\@redhat.com>
8307        and Alexandre Duret-Lutz <adl\@gnu.org>.
8308 EOF
8309   # --version always returns 0 per GNU standards.
8310   exit 0;
8311 }
8312
8313 ################################################################
8314
8315 # Parse command line.
8316 sub parse_arguments ()
8317 {
8318   my $strict = 'gnu';
8319   my $cygnus = 0;
8320   my $ignore_deps = 0;
8321   my @warnings = ();
8322
8323   my %cli_options =
8324     (
8325      'version' => \&version,
8326      'help'    => \&usage,
8327      'libdir=s' => \$libdir,
8328      'print-libdir'     => sub { print "$libdir\n"; exit 0; },
8329      'gnu'              => sub { $strict = 'gnu'; },
8330      'gnits'            => sub { $strict = 'gnits'; },
8331      'foreign'          => sub { $strict = 'foreign'; },
8332      'cygnus'           => \$cygnus,
8333      'include-deps'     => sub { $ignore_deps = 0; },
8334      'i|ignore-deps'    => sub { $ignore_deps = 1; },
8335      'no-force' => sub { $force_generation = 0; },
8336      'f|force-missing'  => \$force_missing,
8337      'a|add-missing'    => \$add_missing,
8338      'c|copy'           => \$copy_missing,
8339      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
8340      'W|warnings=s'     => \@warnings,
8341      );
8342
8343   use Automake::Getopt ();
8344   Automake::Getopt::parse_options %cli_options;
8345
8346   set_strictness ($strict);
8347   my $cli_where = new Automake::Location;
8348   set_global_option ('cygnus', $cli_where) if $cygnus;
8349   set_global_option ('no-dependencies', $cli_where) if $ignore_deps;
8350   for my $warning (@warnings)
8351     {
8352       &parse_warnings ('-W', $warning);
8353     }
8354
8355   return unless @ARGV;
8356
8357   my $errspec = 0;
8358   foreach my $arg (@ARGV)
8359     {
8360       fatal ("empty argument\nTry '$0 --help' for more information")
8361         if ($arg eq '');
8362
8363       # Handle $local:$input syntax.
8364       my ($local, @rest) = split (/:/, $arg);
8365       @rest = ("$local.in",) unless @rest;
8366       my $input = locate_am @rest;
8367       if ($input)
8368         {
8369           push @input_files, $input;
8370           $output_files{$input} = join (':', ($local, @rest));
8371         }
8372       else
8373         {
8374           error "no Automake input file found for '$arg'";
8375           $errspec = 1;
8376         }
8377     }
8378   fatal "no input file found among supplied arguments"
8379     if $errspec && ! @input_files;
8380 }
8381
8382
8383 # handle_makefile ($MAKEFILE_IN)
8384 # ------------------------------
8385 # Deal with $MAKEFILE_IN.
8386 sub handle_makefile ($)
8387 {
8388   my ($file) =  @_;
8389   ($am_file = $file) =~ s/\.in$//;
8390   if (! -f ($am_file . '.am'))
8391     {
8392       error "'$am_file.am' does not exist";
8393     }
8394   else
8395     {
8396       # Any warning setting now local to this Makefile.am.
8397       dup_channel_setup;
8398
8399       generate_makefile ($am_file . '.am', $file);
8400
8401       # Back out any warning setting.
8402       drop_channel_setup;
8403     }
8404 }
8405
8406 # handle_makefiles_serial ()
8407 # --------------------------
8408 # Deal with all makefiles, without threads.
8409 sub handle_makefiles_serial ()
8410 {
8411   foreach my $file (@input_files)
8412     {
8413       handle_makefile ($file);
8414     }
8415 }
8416
8417 # get_number_of_threads ()
8418 # ------------------------
8419 # Logic for deciding how many worker threads to use.
8420 sub get_number_of_threads
8421 {
8422   my $nthreads = $ENV{'AUTOMAKE_JOBS'} || 0;
8423
8424   $nthreads = 0
8425     unless $nthreads =~ /^[0-9]+$/;
8426
8427   # It doesn't make sense to use more threads than makefiles,
8428   my $max_threads = @input_files;
8429
8430   if ($nthreads > $max_threads)
8431     {
8432       $nthreads = $max_threads;
8433     }
8434   return $nthreads;
8435 }
8436
8437 # handle_makefiles_threaded ($NTHREADS)
8438 # -------------------------------------
8439 # Deal with all makefiles, using threads.  The general strategy is to
8440 # spawn NTHREADS worker threads, dispatch makefiles to them, and let the
8441 # worker threads push back everything that needs serialization:
8442 # * warning and (normal) error messages, for stable stderr output
8443 #   order and content (avoiding duplicates, for example),
8444 # * races when installing aux files (and respective messages),
8445 # * races when collecting aux files for distribution.
8446 #
8447 # The latter requires that the makefile that deals with the aux dir
8448 # files be handled last, done by the master thread.
8449 sub handle_makefiles_threaded ($)
8450 {
8451   my ($nthreads) = @_;
8452
8453   # The file queue distributes all makefiles, the message queues
8454   # collect all serializations needed for respective files.
8455   my $file_queue = Thread::Queue->new;
8456   my %msg_queues;
8457   foreach my $file (@input_files)
8458     {
8459       $msg_queues{$file} = Thread::Queue->new;
8460     }
8461
8462   verb "spawning $nthreads worker threads";
8463   my @threads = (1 .. $nthreads);
8464   foreach my $t (@threads)
8465     {
8466       $t = threads->new (sub
8467         {
8468           while (my $file = $file_queue->dequeue)
8469             {
8470               verb "handling $file";
8471               my $queue = $msg_queues{$file};
8472               setup_channel_queue ($queue, QUEUE_MESSAGE);
8473               $required_conf_file_queue = $queue;
8474               handle_makefile ($file);
8475               $queue->enqueue (undef);
8476               setup_channel_queue (undef, undef);
8477               $required_conf_file_queue = undef;
8478             }
8479           return $exit_code;
8480         });
8481     }
8482
8483   # Queue all makefiles.
8484   verb "queuing " . @input_files . " input files";
8485   $file_queue->enqueue (@input_files, (undef) x @threads);
8486
8487   # Collect and process serializations.
8488   foreach my $file (@input_files)
8489     {
8490       verb "dequeuing messages for " . $file;
8491       reset_local_duplicates ();
8492       my $queue = $msg_queues{$file};
8493       while (my $key = $queue->dequeue)
8494         {
8495           if ($key eq QUEUE_MESSAGE)
8496             {
8497               pop_channel_queue ($queue);
8498             }
8499           elsif ($key eq QUEUE_CONF_FILE)
8500             {
8501               require_queued_file_check_or_copy ($queue);
8502             }
8503           else
8504             {
8505               prog_error "unexpected key $key";
8506             }
8507         }
8508     }
8509
8510   foreach my $t (@threads)
8511     {
8512       my @exit_thread = $t->join;
8513       $exit_code = $exit_thread[0]
8514         if ($exit_thread[0] > $exit_code);
8515     }
8516 }
8517
8518 ################################################################
8519
8520 # Parse the WARNINGS environment variable.
8521 parse_WARNINGS;
8522
8523 # Parse command line.
8524 parse_arguments;
8525
8526 $configure_ac = require_configure_ac;
8527
8528 # Do configure.ac scan only once.
8529 scan_autoconf_files;
8530
8531 if (! @input_files)
8532   {
8533     my $msg = '';
8534     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
8535       if -f 'Makefile.am';
8536     fatal ("no 'Makefile.am' found for any configure output$msg");
8537   }
8538
8539 my $nthreads = get_number_of_threads ();
8540
8541 if ($perl_threads && $nthreads >= 1)
8542   {
8543     handle_makefiles_threaded ($nthreads);
8544   }
8545 else
8546   {
8547     handle_makefiles_serial ();
8548   }
8549
8550 exit $exit_code;
8551
8552
8553 ### Setup "GNU" style for perl-mode and cperl-mode.
8554 ## Local Variables:
8555 ## perl-indent-level: 2
8556 ## perl-continued-statement-offset: 2
8557 ## perl-continued-brace-offset: 0
8558 ## perl-brace-offset: 0
8559 ## perl-brace-imaginary-offset: 0
8560 ## perl-label-offset: -2
8561 ## cperl-indent-level: 2
8562 ## cperl-brace-offset: 0
8563 ## cperl-continued-brace-offset: 0
8564 ## cperl-label-offset: -2
8565 ## cperl-extra-newline-before-brace: t
8566 ## cperl-merge-trailing-else: nil
8567 ## cperl-continued-statement-offset: 2
8568 ## End: