automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
  10 # 2003, 2004  Free Software Foundation, Inc.
  11
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2, or (at your option)
  15 # any later version.
  16
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  25 # 02111-1307, USA.
  26
  27 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  28 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  29 # Alexandre Duret-Lutz <adl@gnu.org>.
  30
  31 package Language;
  32
  33 BEGIN
  34 {
  35   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  36   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  37
  38   # Override SHELL.  This is required on DJGPP so that system() uses
  39   # bash, not COMMAND.COM which doesn't quote arguments properly.
  40   # Other systems aren't expected to use $SHELL when Automake
  41   # runs, but it should be safe to drop the `if DJGPP' guard if
  42   # it turns up other systems need the same thing.  After all,
  43   # if SHELL is used, ./configure's SHELL is always better than
  44   # the user's SHELL (which may be something like tcsh).
  45   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJGPP'};
  46 }
  47
  48 use Automake::Struct;
  49 struct (# Short name of the language (c, f77...).
  50         'name' => "\$",
  51         # Nice name of the language (C, Fortran 77...).
  52         'Name' => "\$",
  53
  54         # List of configure variables which must be defined.
  55         'config_vars' => '@',
  56
  57         'ansi'    => "\$",
  58         # `pure' is `1' or `'.  A `pure' language is one where, if
  59         # all the files in a directory are of that language, then we
  60         # do not require the C compiler or any code to call it.
  61         'pure'   => "\$",
  62
  63         'autodep' => "\$",
  64
  65         # Name of the compiling variable (COMPILE).
  66         'compiler'  => "\$",
  67         # Content of the compiling variable.
  68         'compile'  => "\$",
  69         # Flag to require compilation without linking (-c).
  70         'compile_flag' => "\$",
  71         'extensions' => '@',
  72         # A subroutine to compute a list of possible extensions of
  73         # the product given the input extensions.
  74         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  75         'output_extensions' => "\$",
  76         # A list of flag variables used in 'compile'.
  77         # (defaults to [])
  78         'flags' => "@",
  79
  80         # Any tag to pass to libtool while compiling.
  81         'libtool_tag' => "\$",
  82
  83         # The file to use when generating rules for this language.
  84         # The default is 'depend2'.
  85         'rule_file' => "\$",
  86
  87         # Name of the linking variable (LINK).
  88         'linker' => "\$",
  89         # Content of the linking variable.
  90         'link' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} ();
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 use Automake::General;
 134 use Automake::XFile;
 135 use Automake::Channels;
 136 use Automake::ChannelDefs;
 137 use Automake::Configure_ac;
 138 use Automake::FileUtils;
 139 use Automake::Location;
 140 use Automake::Condition qw/TRUE FALSE/;
 141 use Automake::DisjConditions;
 142 use Automake::Options;
 143 use Automake::Version;
 144 use Automake::Variable;
 145 use Automake::VarDef;
 146 use Automake::Rule;
 147 use Automake::RuleDef;
 148 use Automake::Wrap 'makefile_wrap';
 149 use File::Basename;
 150 use Carp;
 151
 152 ## ----------- ##
 153 ## Constants.  ##
 154 ## ----------- ##
 155
 156 # Some regular expressions.  One reason to put them here is that it
 157 # makes indentation work better in Emacs.
 158
 159 # Writing singled-quoted-$-terminated regexes is a pain because
 160 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 161 # by a closing quote.  Letting perl-mode think the quote is not closed
 162 # leads to all sort of misindentations.  On the other hand, defining
 163 # regexes as double-quoted strings is far less readable.  So usually
 164 # we will write:
 165 #
 166 #  $REGEX = '^regex_value' . "\$";
 167
 168 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 169 my $WHITE_PATTERN = '^\s*' . "\$";
 170 my $COMMENT_PATTERN = '^#';
 171 my $TARGET_PATTERN='[$a-zA-Z_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 172 # A rule has three parts: a list of targets, a list of dependencies,
 173 # and optionally actions.
 174 my $RULE_PATTERN =
 175   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 176
 177 # Only recognize leading spaces, not leading tabs.  If we recognize
 178 # leading tabs here then we need to make the reader smarter, because
 179 # otherwise it will think rules like `foo=bar; \' are errors.
 180 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 181 # This pattern recognizes a Gnits version id and sets $1 if the
 182 # release is an alpha release.  We also allow a suffix which can be
 183 # used to extend the version number with a "fork" identifier.
 184 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 185
 186 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 187 my $ELSE_PATTERN =
 188   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 189 my $ENDIF_PATTERN =
 190   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 191 my $PATH_PATTERN = '(\w|[+/.-])+';
 192 # This will pass through anything not of the prescribed form.
 193 my $INCLUDE_PATTERN = ('^include\s+'
 194                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 195                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 196                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 197
 198 # Match `-d' as a command-line argument in a string.
 199 my $DASH_D_PATTERN = "(^|\\s)-d(\\s|\$)";
 200 # Directories installed during 'install-exec' phase.
 201 my $EXEC_DIR_PATTERN =
 202   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 203
 204 # Values for AC_CANONICAL_*
 205 use constant AC_CANONICAL_BUILD  => 1;
 206 use constant AC_CANONICAL_HOST   => 2;
 207 use constant AC_CANONICAL_TARGET => 3;
 208
 209 # Values indicating when something should be cleaned.
 210 use constant MOSTLY_CLEAN     => 0;
 211 use constant CLEAN            => 1;
 212 use constant DIST_CLEAN       => 2;
 213 use constant MAINTAINER_CLEAN => 3;
 214
 215 # Libtool files.
 216 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 217 # ltconfig appears here for compatibility with old versions of libtool.
 218 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 219
 220 # Commonly found files we look for and automatically include in
 221 # DISTFILES.
 222 my @common_files =
 223     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 224         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 225         ansi2knr.1 ansi2knr.c compile config.guess config.rpath config.sub
 226         depcomp elisp-comp install-sh libversion.in mdate-sh missing
 227         mkinstalldirs py-compile texinfo.tex ylwrap),
 228      @libtool_files, @libtool_sometimes);
 229
 230 # Commonly used files we auto-include, but only sometimes.  This list
 231 # is used for the --help output only.
 232 my @common_sometimes =
 233   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 234      configure.ac configure.in stamp-vti);
 235
 236 # Standard directories from the GNU Coding Standards, and additional
 237 # pkg* directories from Automake.  Stored in a hash for fast member check.
 238 my %standard_prefix =
 239     map { $_ => 1 } (qw(bin data exec include info lib libexec lisp
 240                         localstate man man1 man2 man3 man4 man5 man6
 241                         man7 man8 man9 oldinclude pkgdatadir
 242                         pkgincludedir pkglibdir sbin sharedstate
 243                         sysconf));
 244
 245 # Copyright on generated Makefile.ins.
 246 my $gen_copyright = "\
 247 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
 248 # 2003, 2004  Free Software Foundation, Inc.
 249 # This Makefile.in is free software; the Free Software Foundation
 250 # gives unlimited permission to copy and/or distribute it,
 251 # with or without modifications, as long as this notice is preserved.
 252
 253 # This program is distributed in the hope that it will be useful,
 254 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 255 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 256 # PARTICULAR PURPOSE.
 257 ";
 258
 259 # These constants are returned by lang_*_rewrite functions.
 260 # LANG_SUBDIR means that the resulting object file should be in a
 261 # subdir if the source file is.  In this case the file name cannot
 262 # have `..' components.
 263 use constant LANG_IGNORE  => 0;
 264 use constant LANG_PROCESS => 1;
 265 use constant LANG_SUBDIR  => 2;
 266
 267 # These are used when keeping track of whether an object can be built
 268 # by two different paths.
 269 use constant COMPILE_LIBTOOL  => 1;
 270 use constant COMPILE_ORDINARY => 2;
 271
 272 # We can't always associate a location to a variable or a rule,
 273 # when its defined by Automake.  We use INTERNAL in this case.
 274 use constant INTERNAL => new Automake::Location;
 275 \f
 276
 277 ## ---------------------------------- ##
 278 ## Variables related to the options.  ##
 279 ## ---------------------------------- ##
 280
 281 # TRUE if we should always generate Makefile.in.
 282 my $force_generation = 1;
 283
 284 # From the Perl manual.
 285 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 286
 287 # TRUE if missing standard files should be installed.
 288 my $add_missing = 0;
 289
 290 # TRUE if we should copy missing files; otherwise symlink if possible.
 291 my $copy_missing = 0;
 292
 293 # TRUE if we should always update files that we know about.
 294 my $force_missing = 0;
 295
 296
 297 ## ---------------------------------------- ##
 298 ## Variables filled during files scanning.  ##
 299 ## ---------------------------------------- ##
 300
 301 # Name of the configure.ac file.
 302 my $configure_ac;
 303
 304 # Files found by scanning configure.ac for LIBOBJS.
 305 my %libsources = ();
 306
 307 # Names used in AC_CONFIG_HEADER call.
 308 my @config_headers = ();
 309
 310 # Names used in AC_CONFIG_LINKS call.
 311 my @config_links = ();
 312
 313 # Directory where output files go.  Actually, output files are
 314 # relative to this directory.
 315 my $output_directory;
 316
 317 # List of Makefile.am's to process, and their corresponding outputs.
 318 my @input_files = ();
 319 my %output_files = ();
 320
 321 # Complete list of Makefile.am's that exist.
 322 my @configure_input_files = ();
 323
 324 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 325 # and their outputs.
 326 my @other_input_files = ();
 327 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 328 # The keys are the files created by these macros.
 329 my %ac_config_files_location = ();
 330
 331 # Directory to search for configure-required files.  This
 332 # will be computed by &locate_aux_dir and can be set using
 333 # AC_CONFIG_AUX_DIR in configure.ac.
 334 # $CONFIG_AUX_DIR is the `raw' directory, valid only in the source-tree.
 335 my $config_aux_dir = '';
 336 my $config_aux_dir_set_in_configure_ac = 0;
 337 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 338 # in Makefiles.
 339 my $am_config_aux_dir = '';
 340
 341 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 342 my $seen_gettext = 0;
 343 # Whether AM_GNU_GETTEXT([external]) is used.
 344 my $seen_gettext_external = 0;
 345 # Where AM_GNU_GETTEXT appears.
 346 my $ac_gettext_location;
 347
 348 # Lists of tags supported by Libtool.
 349 my %libtool_tags = ();
 350 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 351 # use AC_REQUIRE_AUX_FILE.
 352 my $libtool_new_api = 0;
 353
 354 # Most important AC_CANONICAL_* macro seen so far.
 355 my $seen_canonical = 0;
 356 # Location of that macro.
 357 my $canonical_location;
 358
 359 # Where AM_MAINTAINER_MODE appears.
 360 my $seen_maint_mode;
 361
 362 # Actual version we've seen.
 363 my $package_version = '';
 364
 365 # Where version is defined.
 366 my $package_version_location;
 367
 368 # TRUE if we've seen AC_ENABLE_MULTILIB.
 369 my $seen_multilib = 0;
 370
 371 # TRUE if we've seen AM_PROG_CC_C_O
 372 my $seen_cc_c_o = 0;
 373
 374 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 375 my %required_aux_file = ();
 376
 377 # Where AM_INIT_AUTOMAKE is called;
 378 my $seen_init_automake = 0;
 379
 380 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 381 my $seen_automake_version = 0;
 382
 383 # Hash table of discovered configure substitutions.  Keys are names,
 384 # values are `FILE:LINE' strings which are used by error message
 385 # generation.
 386 my %configure_vars = ();
 387
 388 # Files included by $configure_ac.
 389 my @configure_deps = ();
 390
 391 # Greatest timestamp of configure's dependencies.
 392 my $configure_deps_greatest_timestamp = 0;
 393
 394 # Hash table of AM_CONDITIONAL variables seen in configure.
 395 my %configure_cond = ();
 396
 397 # This maps extensions onto language names.
 398 my %extension_map = ();
 399
 400 # List of the DIST_COMMON files we discovered while reading
 401 # configure.in
 402 my $configure_dist_common = '';
 403
 404 # This maps languages names onto objects.
 405 my %languages = ();
 406
 407 # List of targets we must always output.
 408 # FIXME: Complete, and remove falsely required targets.
 409 my %required_targets =
 410   (
 411    'all'          => 1,
 412    'dvi'          => 1,
 413    'pdf'          => 1,
 414    'ps'           => 1,
 415    'info'         => 1,
 416    'install-info' => 1,
 417    'install'      => 1,
 418    'install-data' => 1,
 419    'install-exec' => 1,
 420    'uninstall'    => 1,
 421
 422    # FIXME: Not required, temporary hacks.
 423    # Well, actually they are sort of required: the -recursive
 424    # targets will run them anyway...
 425    'dvi-am'          => 1,
 426    'pdf-am'          => 1,
 427    'ps-am'           => 1,
 428    'info-am'         => 1,
 429    'install-data-am' => 1,
 430    'install-exec-am' => 1,
 431    'installcheck-am' => 1,
 432    'uninstall-am' => 1,
 433
 434    'install-man' => 1,
 435   );
 436
 437 # Set to 1 if this run will create the Makefile.in that distribute
 438 # the files in config_aux_dir.
 439 my $automake_will_process_aux_dir = 0;
 440
 441 # The name of the Makefile currently being processed.
 442 my $am_file = 'BUG';
 443 \f
 444
 445 ################################################################
 446
 447 ## ------------------------------------------ ##
 448 ## Variables reset by &initialize_per_input.  ##
 449 ## ------------------------------------------ ##
 450
 451 # Basename and relative dir of the input file.
 452 my $am_file_name;
 453 my $am_relative_dir;
 454
 455 # Same but wrt Makefile.in.
 456 my $in_file_name;
 457 my $relative_dir;
 458
 459 # Greatest timestamp of the output's dependencies (excluding
 460 # configure's dependencies).
 461 my $output_deps_greatest_timestamp;
 462
 463 # These two variables are used when generating each Makefile.in.
 464 # They hold the Makefile.in until it is ready to be printed.
 465 my $output_rules;
 466 my $output_vars;
 467 my $output_trailer;
 468 my $output_all;
 469 my $output_header;
 470
 471 # This is the conditional stack, updated on if/else/endif, and
 472 # used to build Condition objects.
 473 my @cond_stack;
 474
 475 # This holds the set of included files.
 476 my @include_stack;
 477
 478 # This holds a list of directories which we must create at `dist'
 479 # time.  This is used in some strange scenarios involving weird
 480 # AC_OUTPUT commands.
 481 my %dist_dirs;
 482
 483 # List of dependencies for the obvious targets.
 484 my @all;
 485 my @check;
 486 my @check_tests;
 487
 488 # Keys in this hash table are files to delete.  The associated
 489 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 490 my %clean_files;
 491
 492 # Keys in this hash table are object files or other files in
 493 # subdirectories which need to be removed.  This only holds files
 494 # which are created by compilations.  The value in the hash indicates
 495 # when the file should be removed.
 496 my %compile_clean_files;
 497
 498 # Keys in this hash table are directories where we expect to build a
 499 # libtool object.  We use this information to decide what directories
 500 # to delete.
 501 my %libtool_clean_directories;
 502
 503 # Value of `$(SOURCES)', used by tags.am.
 504 my @sources;
 505 # Sources which go in the distribution.
 506 my @dist_sources;
 507
 508 # This hash maps object file names onto their corresponding source
 509 # file names.  This is used to ensure that each object is created
 510 # by a single source file.
 511 my %object_map;
 512
 513 # This hash maps object file names onto an integer value representing
 514 # whether this object has been built via ordinary compilation or
 515 # libtool compilation (the COMPILE_* constants).
 516 my %object_compilation_map;
 517
 518
 519 # This keeps track of the directories for which we've already
 520 # created dirstamp code.
 521 my %directory_map;
 522
 523 # All .P files.
 524 my %dep_files;
 525
 526 # This is a list of all targets to run during "make dist".
 527 my @dist_targets;
 528
 529 # Keys in this hash are the basenames of files which must depend on
 530 # ansi2knr.  Values are either the empty string, or the directory in
 531 # which the ANSI source file appears; the directory must have a
 532 # trailing `/'.
 533 my %de_ansi_files;
 534
 535 # This is the name of the redirect `all' target to use.
 536 my $all_target;
 537
 538 # This keeps track of which extensions we've seen (that we care
 539 # about).
 540 my %extension_seen;
 541
 542 # This is random scratch space for the language finish functions.
 543 # Don't randomly overwrite it; examine other uses of keys first.
 544 my %language_scratch;
 545
 546 # We keep track of which objects need special (per-executable)
 547 # handling on a per-language basis.
 548 my %lang_specific_files;
 549
 550 # This is set when `handle_dist' has finished.  Once this happens,
 551 # we should no longer push on dist_common.
 552 my $handle_dist_run;
 553
 554 # Used to store a set of linkers needed to generate the sources currently
 555 # under consideration.
 556 my %linkers_used;
 557
 558 # True if we need `LINK' defined.  This is a hack.
 559 my $need_link;
 560
 561 # Was get_object_extension run?
 562 # FIXME: This is a hack. a better switch should be found.
 563 my $get_object_extension_was_run;
 564
 565 # Record each file processed by make_paragraphs.
 566 my %transformed_files;
 567
 568 # Cache each file processed by make_paragraphs.
 569 # (This is different from %transformed_files because
 570 # %transformed_files is reset for each file while %am_file_cache
 571 # it global to the run.)
 572 my %am_file_cache;
 573
 574 ################################################################
 575
 576 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 577 # ------------------------------------
 578 # This is called by Automake::Variable::define() when SUFFIXES
 579 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 580 # The work here needs to be performed as a side-effect of the
 581 # macro_define() call because SUFFIXES definitions impact
 582 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 583 # the input am file.
 584 sub var_SUFFIXES_trigger ($$)
 585 {
 586     my ($type, $value) = @_;
 587     accept_extensions (split (' ', $value));
 588 }
 589 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 590
 591 ################################################################
 592
 593 ## --------------------------------- ##
 594 ## Forward subroutine declarations.  ##
 595 ## --------------------------------- ##
 596 sub register_language (%);
 597 sub file_contents_internal ($$$%);
 598 sub define_files_variable ($\@$$);
 599
 600
 601 # &initialize_per_input ()
 602 # ------------------------
 603 # (Re)-Initialize per-Makefile.am variables.
 604 sub initialize_per_input ()
 605 {
 606     reset_local_duplicates ();
 607
 608     $am_file_name = '';
 609     $am_relative_dir = '';
 610
 611     $in_file_name = '';
 612     $relative_dir = '';
 613
 614     $output_deps_greatest_timestamp = 0;
 615
 616     $output_rules = '';
 617     $output_vars = '';
 618     $output_trailer = '';
 619     $output_all = '';
 620     $output_header = '';
 621
 622     Automake::Options::reset;
 623     Automake::Variable::reset;
 624     Automake::Rule::reset;
 625
 626     @cond_stack = ();
 627
 628     @include_stack = ();
 629
 630     %dist_dirs = ();
 631
 632     @all = ();
 633     @check = ();
 634     @check_tests = ();
 635
 636     %clean_files = ();
 637
 638     @sources = ();
 639     @dist_sources = ();
 640
 641     %object_map = ();
 642     %object_compilation_map = ();
 643
 644     %directory_map = ();
 645
 646     %dep_files = ();
 647
 648     @dist_targets = ();
 649
 650     %de_ansi_files = ();
 651
 652     $all_target = '';
 653
 654     %extension_seen = ();
 655
 656     %language_scratch = ();
 657
 658     %lang_specific_files = ();
 659
 660     $handle_dist_run = 0;
 661
 662     $need_link = 0;
 663
 664     $get_object_extension_was_run = 0;
 665
 666     %compile_clean_files = ();
 667
 668     # We always include `.'.  This isn't strictly correct.
 669     %libtool_clean_directories = ('.' => 1);
 670
 671     %transformed_files = ();
 672 }
 673
 674
 675 ################################################################
 676
 677 # Initialize our list of languages that are internally supported.
 678
 679 # C.
 680 register_language ('name' => 'c',
 681                    'Name' => 'C',
 682                    'config_vars' => ['CC'],
 683                    'ansi' => 1,
 684                    'autodep' => '',
 685                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 686                    'compiler' => 'COMPILE',
 687                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 688                    'lder' => 'CCLD',
 689                    'ld' => '$(CC)',
 690                    'linker' => 'LINK',
 691                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 692                    'compile_flag' => '-c',
 693                    'libtool_tag' => 'CC',
 694                    'extensions' => ['.c'],
 695                    '_finish' => \&lang_c_finish);
 696
 697 # C++.
 698 register_language ('name' => 'cxx',
 699                    'Name' => 'C++',
 700                    'config_vars' => ['CXX'],
 701                    'linker' => 'CXXLINK',
 702                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 703                    'autodep' => 'CXX',
 704                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 705                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 706                    'compiler' => 'CXXCOMPILE',
 707                    'compile_flag' => '-c',
 708                    'output_flag' => '-o',
 709                    'libtool_tag' => 'CXX',
 710                    'lder' => 'CXXLD',
 711                    'ld' => '$(CXX)',
 712                    'pure' => 1,
 713                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 714
 715 # Objective C.
 716 register_language ('name' => 'objc',
 717                    'Name' => 'Objective C',
 718                    'config_vars' => ['OBJC'],
 719                    'linker' => 'OBJCLINK',,
 720                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 721                    'autodep' => 'OBJC',
 722                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 723                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 724                    'compiler' => 'OBJCCOMPILE',
 725                    'compile_flag' => '-c',
 726                    'output_flag' => '-o',
 727                    'lder' => 'OBJCLD',
 728                    'ld' => '$(OBJC)',
 729                    'pure' => 1,
 730                    'extensions' => ['.m']);
 731
 732 # Headers.
 733 register_language ('name' => 'header',
 734                    'Name' => 'Header',
 735                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 736                                     '.hpp', '.inc'],
 737                    # No output.
 738                    'output_extensions' => sub { return () },
 739                    # Nothing to do.
 740                    '_finish' => sub { });
 741
 742 # Yacc (C & C++).
 743 register_language ('name' => 'yacc',
 744                    'Name' => 'Yacc',
 745                    'config_vars' => ['YACC'],
 746                    'flags' => ['YFLAGS'],
 747                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 748                    'compiler' => 'YACCCOMPILE',
 749                    'extensions' => ['.y'],
 750                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 751                                                 return ($ext,) },
 752                    'rule_file' => 'yacc',
 753                    '_finish' => \&lang_yacc_finish,
 754                    '_target_hook' => \&lang_yacc_target_hook,
 755                    'nodist_specific' => 1);
 756 register_language ('name' => 'yaccxx',
 757                    'Name' => 'Yacc (C++)',
 758                    'config_vars' => ['YACC'],
 759                    'rule_file' => 'yacc',
 760                    'flags' => ['YFLAGS'],
 761                    'compiler' => 'YACCCOMPILE',
 762                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 763                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 764                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 765                                                 return ($ext,) },
 766                    '_finish' => \&lang_yacc_finish,
 767                    '_target_hook' => \&lang_yacc_target_hook,
 768                    'nodist_specific' => 1);
 769
 770 # Lex (C & C++).
 771 register_language ('name' => 'lex',
 772                    'Name' => 'Lex',
 773                    'config_vars' => ['LEX'],
 774                    'rule_file' => 'lex',
 775                    'flags' => ['LFLAGS'],
 776                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 777                    'compiler' => 'LEXCOMPILE',
 778                    'extensions' => ['.l'],
 779                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 780                                                 return ($ext,) },
 781                    '_finish' => \&lang_lex_finish,
 782                    '_target_hook' => \&lang_lex_target_hook,
 783                    'nodist_specific' => 1);
 784 register_language ('name' => 'lexxx',
 785                    'Name' => 'Lex (C++)',
 786                    'config_vars' => ['LEX'],
 787                    'rule_file' => 'lex',
 788                    'flags' => ['LFLAGS'],
 789                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 790                    'compiler' => 'LEXCOMPILE',
 791                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 792                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 793                                                 return ($ext,) },
 794                    '_finish' => \&lang_lex_finish,
 795                    '_target_hook' => \&lang_lex_target_hook,
 796                    'nodist_specific' => 1);
 797
 798 # Assembler.
 799 register_language ('name' => 'asm',
 800                    'Name' => 'Assembler',
 801                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 802
 803                    'flags' => ['CCASFLAGS'],
 804                    # Users can set AM_ASFLAGS to includes DEFS, INCLUDES,
 805                    # or anything else required.  They can also set AS.
 806                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 807                    'compiler' => 'CCASCOMPILE',
 808                    'compile_flag' => '-c',
 809                    'extensions' => ['.s', '.S'],
 810
 811                    # With assembly we still use the C linker.
 812                    '_finish' => \&lang_c_finish);
 813
 814 # Fortran 77
 815 register_language ('name' => 'f77',
 816                    'Name' => 'Fortran 77',
 817                    'linker' => 'F77LINK',
 818                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 819                    'flags' => ['FFLAGS'],
 820                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 821                    'compiler' => 'F77COMPILE',
 822                    'compile_flag' => '-c',
 823                    'output_flag' => '-o',
 824                    'libtool_tag' => 'F77',
 825                    'lder' => 'F77LD',
 826                    'ld' => '$(F77)',
 827                    'pure' => 1,
 828                    'extensions' => ['.f', '.for']);
 829
 830 # Fortran
 831 register_language ('name' => 'fc',
 832                    'Name' => 'Fortran',
 833                    'linker' => 'FCLINK',
 834                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 835                    'flags' => ['FCFLAGS'],
 836                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 837                    'compiler' => 'FCCOMPILE',
 838                    'compile_flag' => '-c',
 839                    'output_flag' => '-o',
 840                    'lder' => 'FCLD',
 841                    'ld' => '$(FC)',
 842                    'pure' => 1,
 843                    'extensions' => ['.f90', '.f95']);
 844
 845 # Preprocessed Fortran
 846 register_language ('name' => 'ppfc',
 847                    'Name' => 'Preprocessed Fortran',
 848                    'config_vars' => ['FC'],
 849                    'linker' => 'FCLINK',
 850                    'link' => '$(FCLD) $(AM_FFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 851                    'lder' => 'FCLD',
 852                    'ld' => '$(FC)',
 853                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 854                    'compiler' => 'PPFCCOMPILE',
 855                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 856                    'compile_flag' => '-c',
 857                    'output_flag' => '-o',
 858                    'libtool_tag' => 'FC',
 859                    'pure' => 1,
 860                    'extensions' => ['.F90','.F95']);
 861
 862 # Preprocessed Fortran 77
 863 #
 864 # The current support for preprocessing Fortran 77 just involves
 865 # passing `$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 866 # $(CPPFLAGS)' as additional flags to the Fortran 77 compiler, since
 867 # this is how GNU Make does it; see the `GNU Make Manual, Edition 0.51
 868 # for `make' Version 3.76 Beta' (specifically, from info file
 869 # `(make)Catalogue of Rules').
 870 #
 871 # A better approach would be to write an Autoconf test
 872 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 873 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 874 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 875 # preprocessing capabilities, and then fall back on cpp (if cpp were
 876 # available).
 877 register_language ('name' => 'ppf77',
 878                    'Name' => 'Preprocessed Fortran 77',
 879                    'config_vars' => ['F77'],
 880                    'linker' => 'F77LINK',
 881                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 882                    'lder' => 'F77LD',
 883                    'ld' => '$(F77)',
 884                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 885                    'compiler' => 'PPF77COMPILE',
 886                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 887                    'compile_flag' => '-c',
 888                    'output_flag' => '-o',
 889                    'libtool_tag' => 'F77',
 890                    'pure' => 1,
 891                    'extensions' => ['.F']);
 892
 893 # Ratfor.
 894 register_language ('name' => 'ratfor',
 895                    'Name' => 'Ratfor',
 896                    'config_vars' => ['F77'],
 897                    'linker' => 'F77LINK',
 898                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 899                    'lder' => 'F77LD',
 900                    'ld' => '$(F77)',
 901                    'flags' => ['RFLAGS', 'FFLAGS'],
 902                    # FIXME also FFLAGS.
 903                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
 904                    'compiler' => 'RCOMPILE',
 905                    'compile_flag' => '-c',
 906                    'output_flag' => '-o',
 907                    'libtool_tag' => 'F77',
 908                    'pure' => 1,
 909                    'extensions' => ['.r']);
 910
 911 # Java via gcj.
 912 register_language ('name' => 'java',
 913                    'Name' => 'Java',
 914                    'config_vars' => ['GCJ'],
 915                    'linker' => 'GCJLINK',
 916                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 917                    'autodep' => 'GCJ',
 918                    'flags' => ['GCJFLAGS'],
 919                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
 920                    'compiler' => 'GCJCOMPILE',
 921                    'compile_flag' => '-c',
 922                    'output_flag' => '-o',
 923                    'libtool_tag' => 'GCJ',
 924                    'lder' => 'GCJLD',
 925                    'ld' => '$(GCJ)',
 926                    'pure' => 1,
 927                    'extensions' => ['.java', '.class', '.zip', '.jar']);
 928
 929 ################################################################
 930
 931 # Error reporting functions.
 932
 933 # err_am ($MESSAGE, [%OPTIONS])
 934 # -----------------------------
 935 # Uncategorized errors about the current Makefile.am.
 936 sub err_am ($;%)
 937 {
 938   msg_am ('error', @_);
 939 }
 940
 941 # err_ac ($MESSAGE, [%OPTIONS])
 942 # -----------------------------
 943 # Uncategorized errors about configure.ac.
 944 sub err_ac ($;%)
 945 {
 946   msg_ac ('error', @_);
 947 }
 948
 949 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
 950 # ---------------------------------------
 951 # Messages about about the current Makefile.am.
 952 sub msg_am ($$;%)
 953 {
 954   my ($channel, $msg, %opts) = @_;
 955   msg $channel, "${am_file}.am", $msg, %opts;
 956 }
 957
 958 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
 959 # ---------------------------------------
 960 # Messages about about configure.ac.
 961 sub msg_ac ($$;%)
 962 {
 963   my ($channel, $msg, %opts) = @_;
 964   msg $channel, $configure_ac, $msg, %opts;
 965 }
 966
 967 ################################################################
 968
 969 # subst ($TEXT)
 970 # -------------
 971 # Return a configure-style substitution using the indicated text.
 972 # We do this to avoid having the substitutions directly in automake.in;
 973 # when we do that they are sometimes removed and this causes confusion
 974 # and bugs.
 975 sub subst ($)
 976 {
 977     my ($text) = @_;
 978     return '@' . $text . '@';
 979 }
 980
 981 ################################################################
 982
 983
 984 # $BACKPATH
 985 # &backname ($REL-DIR)
 986 # --------------------
 987 # If I `cd $REL-DIR', then to come back, I should `cd $BACKPATH'.
 988 # For instance `src/foo' => `../..'.
 989 # Works with non strictly increasing paths, i.e., `src/../lib' => `..'.
 990 sub backname ($)
 991 {
 992     my ($file) = @_;
 993     my @res;
 994     foreach (split (/\//, $file))
 995     {
 996         next if $_ eq '.' || $_ eq '';
 997         if ($_ eq '..')
 998         {
 999             pop @res;
1000         }
1001         else
1002         {
1003             push (@res, '..');
1004         }
1005     }
1006     return join ('/', @res) || '.';
1007 }
1008
1009 ################################################################
1010
1011
1012 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1013 sub handle_options
1014 {
1015   my $var = var ('AUTOMAKE_OPTIONS');
1016   if ($var)
1017     {
1018       # FIXME: We should disallow conditional definitions of AUTOMAKE_OPTIONS.
1019       if (process_option_list ($var->rdef (TRUE)->location,
1020                                $var->value_as_list_recursive (cond_filter =>
1021                                                               TRUE)))
1022         {
1023           return 1;
1024         }
1025     }
1026
1027   if ($strictness == GNITS)
1028     {
1029       set_option ('readme-alpha', INTERNAL);
1030       set_option ('std-options', INTERNAL);
1031       set_option ('check-news', INTERNAL);
1032     }
1033
1034   return 0;
1035 }
1036
1037 # shadow_unconditionally ($varname, $where)
1038 # -----------------------------------------
1039 # Return a $(variable) that contains all possible values
1040 # $varname can take.
1041 # If the VAR wasn't defined conditionally, return $(VAR).
1042 # Otherwise we create a am__VAR_DIST variable which contains
1043 # all possible values, and return $(am__VAR_DIST).
1044 sub shadow_unconditionally ($$)
1045 {
1046   my ($varname, $where) = @_;
1047   my $var = var $varname;
1048   if ($var->has_conditional_contents)
1049     {
1050       $varname = "am__${varname}_DIST";
1051       my @files = uniq ($var->value_as_list_recursive);
1052       define_pretty_variable ($varname, TRUE, $where, @files);
1053     }
1054   return "\$($varname)"
1055 }
1056
1057 # get_object_extension ($OUT)
1058 # ---------------------------
1059 # Return object extension.  Just once, put some code into the output.
1060 # OUT is the name of the output file
1061 sub get_object_extension
1062 {
1063     my ($out) = @_;
1064
1065     # Maybe require libtool library object files.
1066     my $extension = '.$(OBJEXT)';
1067     $extension = '.lo' if ($out =~ /\.la$/);
1068
1069     # Check for automatic de-ANSI-fication.
1070     $extension = '$U' . $extension
1071       if option 'ansi2knr';
1072
1073     $get_object_extension_was_run = 1;
1074
1075     return $extension;
1076 }
1077
1078
1079 # Call finish function for each language that was used.
1080 sub handle_languages
1081 {
1082     if (! option 'no-dependencies')
1083     {
1084         # Include auto-dep code.  Don't include it if DEP_FILES would
1085         # be empty.
1086         if (&saw_sources_p (0) && keys %dep_files)
1087         {
1088             # Set location of depcomp.
1089             &define_variable ('depcomp',
1090                               "\$(SHELL) $am_config_aux_dir/depcomp",
1091                               INTERNAL);
1092             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1093
1094             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1095
1096             my @deplist = sort keys %dep_files;
1097             # Generate each `include' individually.  Irix 6 make will
1098             # not properly include several files resulting from a
1099             # variable expansion; generating many separate includes
1100             # seems safest.
1101             $output_rules .= "\n";
1102             foreach my $iter (@deplist)
1103             {
1104                 $output_rules .= (subst ('AMDEP_TRUE')
1105                                   . subst ('am__include')
1106                                   . ' '
1107                                   . subst ('am__quote')
1108                                   . $iter
1109                                   . subst ('am__quote')
1110                                   . "\n");
1111             }
1112
1113             # Compute the set of directories to remove in distclean-depend.
1114             my @depdirs = uniq (map { dirname ($_) } @deplist);
1115             $output_rules .= &file_contents ('depend',
1116                                              new Automake::Location,
1117                                              DEPDIRS => "@depdirs");
1118         }
1119     }
1120     else
1121     {
1122         &define_variable ('depcomp', '', INTERNAL);
1123         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1124     }
1125
1126     my %done;
1127
1128     # Is the c linker needed?
1129     my $needs_c = 0;
1130     foreach my $ext (sort keys %extension_seen)
1131     {
1132         next unless $extension_map{$ext};
1133
1134         my $lang = $languages{$extension_map{$ext}};
1135
1136         my $rule_file = $lang->rule_file || 'depend2';
1137
1138         # Get information on $LANG.
1139         my $pfx = $lang->autodep;
1140         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1141
1142         my ($AMDEP, $FASTDEP) =
1143           (option 'no-dependencies' || $lang->autodep eq 'no')
1144           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1145
1146         my %transform = ('EXT'     => $ext,
1147                          'PFX'     => $pfx,
1148                          'FPFX'    => $fpfx,
1149                          'AMDEP'   => $AMDEP,
1150                          'FASTDEP' => $FASTDEP,
1151                          '-c'      => $lang->compile_flag || '',
1152                          'MORE-THAN-ONE'
1153                                    => (count_files_for_language ($lang->name) > 1),
1154                          # These are not used, but they need to be defined
1155                          # so &transform do not complain.
1156                          SUBDIROBJ     => 0,
1157                          'DERIVED-EXT' => 'BUG',
1158                          DIST_SOURCE   => 1,
1159                         );
1160
1161         # Generate the appropriate rules for this extension.
1162         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1163             || defined $lang->compile)
1164         {
1165             # Some C compilers don't support -c -o.  Use it only if really
1166             # needed.
1167             my $output_flag = $lang->output_flag || '';
1168             $output_flag = '-o'
1169               if (! $output_flag
1170                   && $lang->name eq 'c'
1171                   && option 'subdir-objects');
1172
1173             # Compute a possible derived extension.
1174             # This is not used by depend2.am.
1175             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1176
1177             # When we output an inference rule like `.c.o:' we
1178             # have two cases to consider: either subdir-objects
1179             # is used, or it is not.
1180             #
1181             # In the latter case the rule is used to build objects
1182             # in the current directory, and dependencies always
1183             # go into `./$(DEPDIR)/'.  We can hard-code this value.
1184             #
1185             # In the former case the rule can be used to build
1186             # objects in sub-directories too.  Dependencies should
1187             # go into the appropriate sub-directories, e.g.,
1188             # `sub/$(DEPDIR)/'.  The value of this directory
1189             # need the be computed on-the-fly.
1190             #
1191             # DEPBASE holds the name of this directory, plus the
1192             # basename part of the object file (extensions Po, TPo,
1193             # Plo, TPlo will be added later as appropriate).  It is
1194             # either hardcoded, or a shell variable (`$depbase') that
1195             # will be computed by the rule.
1196             my $depbase =
1197               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1198             $output_rules .=
1199               file_contents ($rule_file,
1200                              new Automake::Location,
1201                              %transform,
1202                              GENERIC   => 1,
1203
1204                              'DERIVED-EXT' => $der_ext,
1205
1206                              DEPBASE   => $depbase,
1207                              BASE      => '$*',
1208                              SOURCE    => '$<',
1209                              OBJ       => '$@',
1210                              OBJOBJ    => '$@',
1211                              LTOBJ     => '$@',
1212
1213                              COMPILE   => '$(' . $lang->compiler . ')',
1214                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1215                              -o        => $output_flag,
1216                              SUBDIROBJ => !! option 'subdir-objects');
1217         }
1218
1219         # Now include code for each specially handled object with this
1220         # language.
1221         my %seen_files = ();
1222         foreach my $file (@{$lang_specific_files{$lang->name}})
1223         {
1224             my ($derived, $source, $obj, $myext, %file_transform) = @$file;
1225
1226             # We might see a given object twice, for instance if it is
1227             # used under different conditions.
1228             next if defined $seen_files{$obj};
1229             $seen_files{$obj} = 1;
1230
1231             prog_error ("found " . $lang->name .
1232                         " in handle_languages, but compiler not defined")
1233               unless defined $lang->compile;
1234
1235             my $obj_compile = $lang->compile;
1236
1237             # Rewrite each occurrence of `AM_$flag' in the compile
1238             # rule into `${derived}_$flag' if it exists.
1239             for my $flag (@{$lang->flags})
1240               {
1241                 my $val = "${derived}_$flag";
1242                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1243                   if set_seen ($val);
1244               }
1245
1246             my $libtool_tag = '';
1247             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1248               {
1249                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1250               }
1251
1252             my $obj_ltcompile =
1253               '$(LIBTOOL) --mode=compile ' . $libtool_tag . $obj_compile;
1254
1255             # We _need_ `-o' for per object rules.
1256             my $output_flag = $lang->output_flag || '-o';
1257
1258             my $depbase = dirname ($obj);
1259             $depbase = ''
1260                 if $depbase eq '.';
1261             $depbase .= '/'
1262                 unless $depbase eq '';
1263             $depbase .= '$(DEPDIR)/' . basename ($obj);
1264
1265             # Support for deansified files in subdirectories is ugly
1266             # enough to deserve an explanation.
1267             #
1268             # A Note about normal ansi2knr processing first.  On
1269             #
1270             #   AUTOMAKE_OPTIONS = ansi2knr
1271             #   bin_PROGRAMS = foo
1272             #   foo_SOURCES = foo.c
1273             #
1274             # we generate rules similar to:
1275             #
1276             #   foo: foo$U.o; link ...
1277             #   foo$U.o: foo$U.c; compile ...
1278             #   foo_.c: foo.c; ansi2knr ...
1279             #
1280             # this is fairly compact, and will call ansi2knr depending
1281             # on the value of $U (`' or `_').
1282             #
1283             # It's harder with subdir sources. On
1284             #
1285             #   AUTOMAKE_OPTIONS = ansi2knr
1286             #   bin_PROGRAMS = foo
1287             #   foo_SOURCES = sub/foo.c
1288             #
1289             # we have to create foo_.c in the current directory.
1290             # (Unless the user asks 'subdir-objects'.)  This is important
1291             # in case the same file (`foo.c') is compiled from other
1292             # directories with different cpp options: foo_.c would
1293             # be preprocessed for only one set of options if it were
1294             # put in the subdirectory.
1295             #
1296             # Because foo$U.o must be built from either foo_.c or
1297             # sub/foo.c we can't be as concise as in the first example.
1298             # Instead we output
1299             #
1300             #   foo: foo$U.o; link ...
1301             #   foo_.o: foo_.c; compile ...
1302             #   foo.o: sub/foo.c; compile ...
1303             #   foo_.c: foo.c; ansi2knr ...
1304             #
1305             # This is why we'll now transform $rule_file twice
1306             # if we detect this case.
1307             # A first time we output the compile rule with `$U'
1308             # replaced by `_' and the source directory removed,
1309             # and another time we simply remove `$U'.
1310             #
1311             # Note that at this point $source (as computed by
1312             # &handle_single_transform) is `sub/foo$U.c'.
1313             # This can be confusing: it can be used as-is when
1314             # subdir-objects is set, otherwise you have to know
1315             # it really means `foo_.c' or `sub/foo.c'.
1316             my $objdir = dirname ($obj);
1317             my $srcdir = dirname ($source);
1318             if ($lang->ansi && $obj =~ /\$U/)
1319               {
1320                 prog_error "`$obj' contains \$U, but `$source' doesn't."
1321                   if $source !~ /\$U/;
1322
1323                 (my $source_ = $source) =~ s/\$U/_/g;
1324                 # Output an additional rule if _.c and .c are not in
1325                 # the same directory.  (_.c is always in $objdir.)
1326                 if ($objdir ne $srcdir)
1327                   {
1328                     (my $obj_ = $obj) =~ s/\$U/_/g;
1329                     (my $depbase_ = $depbase) =~ s/\$U/_/g;
1330                     $source_ = basename ($source_);
1331
1332                     $output_rules .=
1333                       file_contents ($rule_file,
1334                                      new Automake::Location,
1335                                      %transform,
1336                                      GENERIC   => 0,
1337
1338                                      DEPBASE   => $depbase_,
1339                                      BASE      => $obj_,
1340                                      SOURCE    => $source_,
1341                                      OBJ       => "$obj_$myext",
1342                                      OBJOBJ    => "$obj_.obj",
1343                                      LTOBJ     => "$obj_.lo",
1344
1345                                      COMPILE   => $obj_compile,
1346                                      LTCOMPILE => $obj_ltcompile,
1347                                      -o        => $output_flag,
1348                                      %file_transform);
1349                     $obj =~ s/\$U//g;
1350                     $depbase =~ s/\$U//g;
1351                     $source =~ s/\$U//g;
1352                   }
1353               }
1354
1355             $output_rules .=
1356               file_contents ($rule_file,
1357                              new Automake::Location,
1358                              %transform,
1359                              GENERIC   => 0,
1360
1361                              DEPBASE   => $depbase,
1362                              BASE      => $obj,
1363                              SOURCE    => $source,
1364                              # Use $myext and not `.o' here, in case
1365                              # we are actually building a new source
1366                              # file -- e.g. via yacc.
1367                              OBJ       => "$obj$myext",
1368                              OBJOBJ    => "$obj.obj",
1369                              LTOBJ     => "$obj.lo",
1370
1371                              COMPILE   => $obj_compile,
1372                              LTCOMPILE => $obj_ltcompile,
1373                              -o        => $output_flag,
1374                              %file_transform);
1375         }
1376
1377         # The rest of the loop is done once per language.
1378         next if defined $done{$lang};
1379         $done{$lang} = 1;
1380
1381         # Load the language dependent Makefile chunks.
1382         my %lang = map { uc ($_) => 0 } keys %languages;
1383         $lang{uc ($lang->name)} = 1;
1384         $output_rules .= file_contents ('lang-compile',
1385                                         new Automake::Location,
1386                                         %transform, %lang);
1387
1388         # If the source to a program consists entirely of code from a
1389         # `pure' language, for instance C++ for Fortran 77, then we
1390         # don't need the C compiler code.  However if we run into
1391         # something unusual then we do generate the C code.  There are
1392         # probably corner cases here that do not work properly.
1393         # People linking Java code to Fortran code deserve pain.
1394         $needs_c ||= ! $lang->pure;
1395
1396         define_compiler_variable ($lang)
1397           if ($lang->compile);
1398
1399         define_linker_variable ($lang)
1400           if ($lang->link);
1401
1402         require_variables ("$am_file.am", $lang->Name . " source seen",
1403                            TRUE, @{$lang->config_vars});
1404
1405         # Call the finisher.
1406         $lang->finish;
1407
1408         # Flags listed in `->flags' are user variables (per GNU Standards),
1409         # they should not be overridden in the Makefile...
1410         my @dont_override = @{$lang->flags};
1411         # ... and so is LDFLAGS.
1412         push @dont_override, 'LDFLAGS' if $lang->link;
1413
1414         foreach my $flag (@dont_override)
1415           {
1416             my $var = var $flag;
1417             if ($var)
1418               {
1419                 for my $cond ($var->conditions->conds)
1420                   {
1421                     if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1422                       {
1423                         msg_cond_var ('gnu', $cond, $flag,
1424                                       "`$flag' is a user variable, "
1425                                       . "you should not override it;\n"
1426                                       . "use `AM_$flag' instead.");
1427                       }
1428                   }
1429               }
1430           }
1431     }
1432
1433     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1434     # suffix rule was learned), don't bother with the C stuff.  But if
1435     # anything else creeps in, then use it.
1436     $needs_c = 1
1437       if $need_link || suffix_rules_count > 1;
1438
1439     if ($needs_c)
1440       {
1441         &define_compiler_variable ($languages{'c'})
1442           unless defined $done{$languages{'c'}};
1443         define_linker_variable ($languages{'c'});
1444       }
1445 }
1446
1447 # Check to make sure a source defined in LIBOBJS is not explicitly
1448 # mentioned.  This is a separate function (as opposed to being inlined
1449 # in handle_source_transform) because it isn't always appropriate to
1450 # do this check.
1451 sub check_libobjs_sources
1452 {
1453   my ($one_file, $unxformed) = @_;
1454
1455   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1456                       'dist_EXTRA_', 'nodist_EXTRA_')
1457     {
1458       my @files;
1459       my $varname = $prefix . $one_file . '_SOURCES';
1460       my $var = var ($varname);
1461       if ($var)
1462         {
1463           @files = $var->value_as_list_recursive;
1464         }
1465       elsif ($prefix eq '')
1466         {
1467           @files = ($unxformed . '.c');
1468         }
1469       else
1470         {
1471           next;
1472         }
1473
1474       foreach my $file (@files)
1475         {
1476           err_var ($prefix . $one_file . '_SOURCES',
1477                    "automatically discovered file `$file' should not" .
1478                    " be explicitly mentioned")
1479             if defined $libsources{$file};
1480         }
1481     }
1482 }
1483
1484
1485 # @OBJECTS
1486 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1487 # -----------------------------------------------------------------------------
1488 # Does much of the actual work for handle_source_transform.
1489 # Arguments are:
1490 #   $VAR is the name of the variable that the source filenames come from
1491 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1492 #   $DERIVED is the name of resulting executable or library
1493 #   $OBJ is the object extension (e.g., `$U.lo')
1494 #   $FILE the source file to transform
1495 #   %TRANSFORM contains extras arguments to pass to file_contents
1496 #     when producing explicit rules
1497 # Result is a list of the names of objects
1498 # %linkers_used will be updated with any linkers needed
1499 sub handle_single_transform ($$$$$%)
1500 {
1501     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1502     my @files = ($_file);
1503     my @result = ();
1504     my $nonansi_obj = $obj;
1505     $nonansi_obj =~ s/\$U//g;
1506
1507     # Turn sources into objects.  We use a while loop like this
1508     # because we might add to @files in the loop.
1509     while (scalar @files > 0)
1510     {
1511         $_ = shift @files;
1512
1513         # Configure substitutions in _SOURCES variables are errors.
1514         if (/^\@.*\@$/)
1515         {
1516           my $parent_msg = '';
1517           $parent_msg = "\nand is referred to from `$topparent'"
1518             if $topparent ne $var->name;
1519           err_var ($var,
1520                    "`" . $var->name . "' includes configure substitution `$_'"
1521                    . $parent_msg . ";\nconfigure " .
1522                    "substitutions are not allowed in _SOURCES variables");
1523           next;
1524         }
1525
1526         # If the source file is in a subdirectory then the `.o' is put
1527         # into the current directory, unless the subdir-objects option
1528         # is in effect.
1529
1530         # Split file name into base and extension.
1531         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1532         my $full = $_;
1533         my $directory = $1 || '';
1534         my $base = $2;
1535         my $extension = $3;
1536
1537         # We must generate a rule for the object if it requires its own flags.
1538         my $renamed = 0;
1539         my ($linker, $object);
1540
1541         # This records whether we've seen a derived source file (e.g.
1542         # yacc output).
1543         my $derived_source = 0;
1544
1545         # This holds the `aggregate context' of the file we are
1546         # currently examining.  If the file is compiled with
1547         # per-object flags, then it will be the name of the object.
1548         # Otherwise it will be `AM'.  This is used by the target hook
1549         # language function.
1550         my $aggregate = 'AM';
1551
1552         $extension = &derive_suffix ($extension, $nonansi_obj);
1553         my $lang;
1554         if ($extension_map{$extension} &&
1555             ($lang = $languages{$extension_map{$extension}}))
1556         {
1557             # Found the language, so see what it says.
1558             &saw_extension ($extension);
1559
1560             # Do we have per-executable flags for this executable?
1561             my $have_per_exec_flags = 0;
1562             foreach my $flag (@{$lang->flags})
1563               {
1564                 if (set_seen ("${derived}_$flag"))
1565                   {
1566                     $have_per_exec_flags = 1;
1567                     last;
1568                   }
1569               }
1570
1571             # Note: computed subr call.  The language rewrite function
1572             # should return one of the LANG_* constants.  It could
1573             # also return a list whose first value is such a constant
1574             # and whose second value is a new source extension which
1575             # should be applied.  This means this particular language
1576             # generates another source file which we must then process
1577             # further.
1578             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1579             my ($r, $source_extension)
1580                 = &$subr ($directory, $base, $extension,
1581                           $nonansi_obj, $have_per_exec_flags, $var);
1582             # Skip this entry if we were asked not to process it.
1583             next if $r == LANG_IGNORE;
1584
1585             # Now extract linker and other info.
1586             $linker = $lang->linker;
1587
1588             my $this_obj_ext;
1589             if (defined $source_extension)
1590             {
1591                 $this_obj_ext = $source_extension;
1592                 $derived_source = 1;
1593             }
1594             elsif ($lang->ansi)
1595             {
1596                 $this_obj_ext = $obj;
1597             }
1598             else
1599             {
1600                 $this_obj_ext = $nonansi_obj;
1601             }
1602             $object = $base . $this_obj_ext;
1603
1604             if ($have_per_exec_flags)
1605             {
1606                 # We have a per-executable flag in effect for this
1607                 # object.  In this case we rewrite the object's
1608                 # name to ensure it is unique.
1609
1610                 # We choose the name `DERIVED_OBJECT' to ensure
1611                 # (1) uniqueness, and (2) continuity between
1612                 # invocations.  However, this will result in a
1613                 # name that is too long for losing systems, in
1614                 # some situations.  So we provide _SHORTNAME to
1615                 # override.
1616
1617                 my $dname = $derived;
1618                 my $var = var ($derived . '_SHORTNAME');
1619                 if ($var)
1620                 {
1621                     # FIXME: should use the same Condition as
1622                     # the _SOURCES variable.  But this is really
1623                     # silly overkill -- nobody should have
1624                     # conditional shortnames.
1625                     $dname = $var->variable_value;
1626                 }
1627                 $object = $dname . '-' . $object;
1628
1629                 prog_error ($lang->name . " flags defined without compiler")
1630                   if ! defined $lang->compile;
1631
1632                 $renamed = 1;
1633             }
1634
1635             # If rewrite said it was ok, put the object into a
1636             # subdir.
1637             if ($r == LANG_SUBDIR && $directory ne '')
1638             {
1639                 $object = $directory . '/' . $object;
1640             }
1641
1642             # If the object file has been renamed (because per-target
1643             # flags are used) we cannot compile the file with an
1644             # inference rule: we need an explicit rule.
1645             #
1646             # If the source is in a subdirectory and the object is in
1647             # the current directory, we also need an explicit rule.
1648             #
1649             # If both source and object files are in a subdirectory
1650             # (this happens when the subdir-objects option is used),
1651             # then the inference will work.
1652             #
1653             # The latter case deserves a historical note.  When the
1654             # subdir-objects option was added on 1999-04-11 it was
1655             # thought that inferences rules would work for
1656             # subdirectory objects too.  Later, on 1999-11-22,
1657             # automake was changed to output explicit rules even for
1658             # subdir-objects.  Nobody remembers why, but this occured
1659             # soon after the merge of the user-dep-gen-branch so it
1660             # might be related.  In late 2003 people complained about
1661             # the size of the generated Makefile.ins (libgcj, with
1662             # 2200+ subdir objects was reported to have a 9MB
1663             # Makefile), so we now rely on inference rules again.
1664             # Maybe we'll run across the same issue as in the past,
1665             # but at least this time we can document it.  However since
1666             # dependency tracking has evolved it is possible that
1667             # our old problem no longer exists.
1668             # Using inference rules for subdir-objects has been tested
1669             # with GNU make, Solaris make, Ultrix make, BSD make,
1670             # HP-UX make, and OSF1 make successfully.
1671             if ($renamed
1672                 || ($directory ne '' && ! option 'subdir-objects')
1673                 # We must also use specific rules for a nodist_ source
1674                 # if its language requests it.
1675                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1676             {
1677                 my $obj_sans_ext = substr ($object, 0,
1678                                            - length ($this_obj_ext));
1679                 my $full_ansi = $full;
1680                 if ($lang->ansi && option 'ansi2knr')
1681                   {
1682                     $full_ansi =~ s/$KNOWN_EXTENSIONS_PATTERN$/\$U$&/;
1683                     $obj_sans_ext .= '$U';
1684                   }
1685
1686                 my @specifics = ($full_ansi, $obj_sans_ext,
1687                                  # Only use $this_obj_ext in the derived
1688                                  # source case because in the other case we
1689                                  # *don't* want $(OBJEXT) to appear here.
1690                                  ($derived_source ? $this_obj_ext : '.o'));
1691
1692                 # If we renamed the object then we want to use the
1693                 # per-executable flag name.  But if this is simply a
1694                 # subdir build then we still want to use the AM_ flag
1695                 # name.
1696                 if ($renamed)
1697                   {
1698                     unshift @specifics, $derived;
1699                     $aggregate = $derived;
1700                   }
1701                 else
1702                   {
1703                     unshift @specifics, 'AM';
1704                   }
1705
1706                 # Each item on this list is a reference to a list consisting
1707                 # of four values followed by additional transform flags for
1708                 # file_contents.   The four values are the derived flag prefix
1709                 # (e.g. for `foo_CFLAGS', it is `foo'), the name of the
1710                 # source file, the base name of the output file, and
1711                 # the extension for the object file.
1712                 push (@{$lang_specific_files{$lang->name}},
1713                       [@specifics, %transform]);
1714             }
1715         }
1716         elsif ($extension eq $nonansi_obj)
1717         {
1718             # This is probably the result of a direct suffix rule.
1719             # In this case we just accept the rewrite.
1720             $object = "$base$extension";
1721             $linker = '';
1722         }
1723         else
1724         {
1725             # No error message here.  Used to have one, but it was
1726             # very unpopular.
1727             # FIXME: we could potentially do more processing here,
1728             # perhaps treating the new extension as though it were a
1729             # new source extension (as above).  This would require
1730             # more restructuring than is appropriate right now.
1731             next;
1732         }
1733
1734         err_am "object `$object' created by `$full' and `$object_map{$object}'"
1735           if (defined $object_map{$object}
1736               && $object_map{$object} ne $full);
1737
1738         my $comp_val = (($object =~ /\.lo$/)
1739                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1740         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1741         if (defined $object_compilation_map{$comp_obj}
1742             && $object_compilation_map{$comp_obj} != 0
1743             # Only see the error once.
1744             && ($object_compilation_map{$comp_obj}
1745                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1746             && $object_compilation_map{$comp_obj} != $comp_val)
1747           {
1748             err_am "object `$comp_obj' created both with libtool and without";
1749           }
1750         $object_compilation_map{$comp_obj} |= $comp_val;
1751
1752         if (defined $lang)
1753         {
1754             # Let the language do some special magic if required.
1755             $lang->target_hook ($aggregate, $object, $full, %transform);
1756         }
1757
1758         if ($derived_source)
1759           {
1760             prog_error ($lang->name . " has automatic dependency tracking")
1761               if $lang->autodep ne 'no';
1762             # Make sure this new source file is handled next.  That will
1763             # make it appear to be at the right place in the list.
1764             unshift (@files, $object);
1765             # Distribute derived sources unless the source they are
1766             # derived from is not.
1767             &push_dist_common ($object)
1768               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1769             next;
1770           }
1771
1772         $linkers_used{$linker} = 1;
1773
1774         push (@result, $object);
1775
1776         if (! defined $object_map{$object})
1777         {
1778             my @dep_list = ();
1779             $object_map{$object} = $full;
1780
1781             # If resulting object is in subdir, we need to make
1782             # sure the subdir exists at build time.
1783             if ($object =~ /\//)
1784             {
1785                 # FIXME: check that $DIRECTORY is somewhere in the
1786                 # project
1787
1788                 # For Java, the way we're handling it right now, a
1789                 # `..' component doesn't make sense.
1790                 if ($lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1791                   {
1792                     err_am "`$full' should not contain a `..' component";
1793                   }
1794
1795                 # Make sure object is removed by `make mostlyclean'.
1796                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1797                 # If we have a libtool object then we also must remove
1798                 # the ordinary .o.
1799                 if ($object =~ /\.lo$/)
1800                 {
1801                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1802                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1803
1804                     # Remove any libtool object in this directory.
1805                     $libtool_clean_directories{$directory} = 1;
1806                 }
1807
1808                 push (@dep_list, require_build_directory ($directory));
1809
1810                 # If we're generating dependencies, we also want
1811                 # to make sure that the appropriate subdir of the
1812                 # .deps directory is created.
1813                 push (@dep_list,
1814                       require_build_directory ($directory . '/$(DEPDIR)'))
1815                   unless option 'no-dependencies';
1816             }
1817
1818             &pretty_print_rule ($object . ':', "\t", @dep_list)
1819                 if scalar @dep_list > 0;
1820         }
1821
1822         # Transform .o or $o file into .P file (for automatic
1823         # dependency code).
1824         if ($lang && $lang->autodep ne 'no')
1825         {
1826             my $depfile = $object;
1827             $depfile =~ s/\.([^.]*)$/.P$1/;
1828             $depfile =~ s/\$\(OBJEXT\)$/o/;
1829             $dep_files{dirname ($depfile) . '/$(DEPDIR)/'
1830                            . basename ($depfile)} = 1;
1831         }
1832     }
1833
1834     return @result;
1835 }
1836
1837
1838 # $LINKER
1839 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
1840 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
1841 # ---------------------------------------------------------------------------
1842 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
1843 #
1844 # Arguments are:
1845 #   $VAR is the name of the _SOURCES variable
1846 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
1847 #     it will be generated and returned).
1848 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
1849 #     work done to determine the linker will be).
1850 #   $ONE_FILE is the canonical (transformed) name of object to build
1851 #   $OBJ is the object extension (i.e. either `.o' or `.lo').
1852 #   $TOPPARENT is the _SOURCES variable being processed.
1853 #   $WHERE context into which this definition is done
1854 #   %TRANSFORM extra arguments to pass to file_contents when producing
1855 #     rules
1856 #
1857 # Result is a pair ($LINKER, $OBJVAR):
1858 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
1859 sub define_objects_from_sources ($$$$$$$%)
1860 {
1861   my ($var, $objvar, $nodefine, $one_file,
1862       $obj, $topparent, $where, %transform) = @_;
1863
1864   my $needlinker = "";
1865
1866   transform_variable_recursively
1867     ($var, $objvar, 'am__objects', $nodefine, $where,
1868      # The transform code to run on each filename.
1869      sub {
1870        my ($subvar, $val, $cond, $full_cond) = @_;
1871        my @trans = handle_single_transform ($subvar, $topparent,
1872                                             $one_file, $obj, $val,
1873                                             %transform);
1874        $needlinker = "true" if @trans;
1875        return @trans;
1876      });
1877
1878   return $needlinker;
1879 }
1880
1881
1882 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
1883 # -----------------------------------------------------------------------------
1884 # Handle SOURCE->OBJECT transform for one program or library.
1885 # Arguments are:
1886 #   canonical (transformed) name of target to build
1887 #   actual target of object to build
1888 #   object extension (i.e. either `.o' or `$o'.
1889 #   location of the source variable
1890 #   extra arguments to pass to file_contents when producing rules
1891 # Return result is name of linker variable that must be used.
1892 # Empty return means just use `LINK'.
1893 sub handle_source_transform ($$$$%)
1894 {
1895     # one_file is canonical name.  unxformed is given name.  obj is
1896     # object extension.
1897     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
1898
1899     my ($linker) = '';
1900
1901     # No point in continuing if _OBJECTS is defined.
1902     return if reject_var ($one_file . '_OBJECTS',
1903                           $one_file . '_OBJECTS should not be defined');
1904
1905     my %used_pfx = ();
1906     my $needlinker;
1907     %linkers_used = ();
1908     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1909                         'dist_EXTRA_', 'nodist_EXTRA_')
1910     {
1911         my $varname = $prefix . $one_file . "_SOURCES";
1912         my $var = var $varname;
1913         next unless $var;
1914
1915         # We are going to define _OBJECTS variables using the prefix.
1916         # Then we glom them all together.  So we can't use the null
1917         # prefix here as we need it later.
1918         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
1919
1920         # Keep track of which prefixes we saw.
1921         $used_pfx{$xpfx} = 1
1922           unless $prefix =~ /EXTRA_/;
1923
1924         push @sources, "\$($varname)";
1925         push @dist_sources, shadow_unconditionally ($varname, $where)
1926           unless (option ('no-dist') || $prefix =~ /^nodist_/);
1927
1928         $needlinker |=
1929             define_objects_from_sources ($varname,
1930                                          $xpfx . $one_file . '_OBJECTS',
1931                                          $prefix =~ /EXTRA_/,
1932                                          $one_file, $obj, $varname, $where,
1933                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
1934                                          %transform);
1935     }
1936     if ($needlinker)
1937     {
1938         $linker ||= &resolve_linker (%linkers_used);
1939     }
1940
1941     my @keys = sort keys %used_pfx;
1942     if (scalar @keys == 0)
1943     {
1944         # The default source for libfoo.la is libfoo.c, but for
1945         # backward compatibility we first look at libfoo_la.c
1946         my $old_default_source = "$one_file.c";
1947         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,.c,;
1948         if ($old_default_source ne $default_source
1949             && (rule $old_default_source
1950                 || rule '$(srcdir)/' . $old_default_source
1951                 || rule '${srcdir}/' . $old_default_source
1952                 || -f $old_default_source))
1953           {
1954             my $loc = $where->clone;
1955             $loc->pop_context;
1956             msg ('obsolete', $loc,
1957                  "the default source for `$unxformed' has been changed "
1958                  . "to `$default_source'.\n(Using `$old_default_source' for "
1959                  . "backward compatibility.)");
1960             $default_source = $old_default_source;
1961           }
1962         # If a rule exists to build this source with a $(srcdir)
1963         # prefix, use that prefix in our variables too.  This is for
1964         # the sake of BSD Make.
1965         if (rule '$(srcdir)/' . $default_source
1966             || rule '${srcdir}/' . $default_source)
1967           {
1968             $default_source = '$(srcdir)/' . $default_source;
1969           }
1970
1971         &define_variable ($one_file . "_SOURCES", $default_source, $where);
1972         push (@sources, $default_source);
1973         push (@dist_sources, $default_source);
1974
1975         %linkers_used = ();
1976         my (@result) =
1977           handle_single_transform ($one_file . '_SOURCES',
1978                                    $one_file . '_SOURCES',
1979                                    $one_file, $obj,
1980                                    $default_source, %transform);
1981         $linker ||= &resolve_linker (%linkers_used);
1982         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
1983     }
1984     else
1985     {
1986         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
1987         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
1988     }
1989
1990     # If we want to use `LINK' we must make sure it is defined.
1991     if ($linker eq '')
1992     {
1993         $need_link = 1;
1994     }
1995
1996     return $linker;
1997 }
1998
1999
2000 # handle_lib_objects ($XNAME, $VAR)
2001 # ---------------------------------
2002 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2003 # Also, generate _DEPENDENCIES variable if appropriate.
2004 # Arguments are:
2005 #   transformed name of object being built, or empty string if no object
2006 #   name of _LDADD/_LIBADD-type variable to examine
2007 # Returns 1 if LIBOBJS seen, 0 otherwise.
2008 sub handle_lib_objects
2009 {
2010   my ($xname, $varname) = @_;
2011
2012   my $var = var ($varname);
2013   prog_error "handle_lib_objects: `$varname' undefined"
2014     unless $var;
2015   prog_error "handle_lib_objects: unexpected variable name `$varname'"
2016     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2017   my $prefix = $1 || 'AM_';
2018
2019   my $seen_libobjs = 0;
2020   my $flagvar = 0;
2021
2022   transform_variable_recursively
2023     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2024      ! $xname, INTERNAL,
2025      # Transformation function, run on each filename.
2026      sub {
2027        my ($subvar, $val, $cond, $full_cond) = @_;
2028
2029        if ($val =~ /^-/)
2030          {
2031            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2032            if ($val !~ /^-[lL]/ &&
2033                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2034                # for Libtool libraries or programs.  (Actually we are a bit
2035                # laxest here since this code also applies to non-libtool
2036                # libraries or programs, for which -dlopen and -dlopreopen
2037                # are pure non-sence.  Diagnosting this doesn't seems very
2038                # important: the developer will quickly get complaints from
2039                # the linker.)
2040                $val !~ /^-dl(?:pre)?open$/ &&
2041                # Only get this error once.
2042                ! $flagvar)
2043              {
2044                $flagvar = 1;
2045                # FIXME: should display a stack of nested variables
2046                # as context when $var != $subvar.
2047                err_var ($var, "linker flags such as `$val' belong in "
2048                         . "`${prefix}LDFLAGS");
2049              }
2050            return ();
2051          }
2052        elsif ($val !~ /^\@.*\@$/)
2053          {
2054            # Assume we have a file of some sort, and output it into the
2055            # dependency variable.  Autoconf substitutions are not output;
2056            # rarely is a new dependency substituted into e.g. foo_LDADD
2057            # -- but bad things (e.g. -lX11) are routinely substituted.
2058            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2059            # and handled specially below.
2060            return $val;
2061          }
2062        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2063          {
2064            handle_LIBOBJS ($subvar, $cond, $1);
2065            $seen_libobjs = 1;
2066            return $val;
2067          }
2068        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2069          {
2070            handle_ALLOCA ($subvar, $cond, $1);
2071            return $val;
2072          }
2073        else
2074          {
2075            return ();
2076          }
2077      });
2078
2079   return $seen_libobjs;
2080 }
2081
2082 sub handle_LIBOBJS ($$$)
2083 {
2084   my ($var, $cond, $lt) = @_;
2085   $lt ||= '';
2086   my $myobjext = ($1 ? 'l' : '') . 'o';
2087
2088   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2089     if ! keys %libsources;
2090
2091   foreach my $iter (keys %libsources)
2092     {
2093       if ($iter =~ /\.[cly]$/)
2094         {
2095           &saw_extension ($&);
2096           &saw_extension ('.c');
2097         }
2098
2099       if ($iter =~ /\.h$/)
2100         {
2101           require_file_with_macro ($cond, $var, FOREIGN, $iter);
2102         }
2103       elsif ($iter ne 'alloca.c')
2104         {
2105           my $rewrite = $iter;
2106           $rewrite =~ s/\.c$/.P$myobjext/;
2107           $dep_files{'$(DEPDIR)/' . $rewrite} = 1;
2108           $rewrite = "^" . quotemeta ($iter) . "\$";
2109           # Only require the file if it is not a built source.
2110           my $bs = var ('BUILT_SOURCES');
2111           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2112             {
2113               require_file_with_macro ($cond, $var, FOREIGN, $iter);
2114             }
2115         }
2116     }
2117 }
2118
2119 sub handle_ALLOCA ($$$)
2120 {
2121   my ($var, $cond, $lt) = @_;
2122   my $myobjext = ($lt ? 'l' : '') . 'o';
2123   $lt ||= '';
2124   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2125   $dep_files{'$(DEPDIR)/alloca.P' . $myobjext} = 1;
2126   require_file_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2127   &saw_extension ('c');
2128 }
2129
2130 # Canonicalize the input parameter
2131 sub canonicalize
2132 {
2133     my ($string) = @_;
2134     $string =~ tr/A-Za-z0-9_\@/_/c;
2135     return $string;
2136 }
2137
2138 # Canonicalize a name, and check to make sure the non-canonical name
2139 # is never used.  Returns canonical name.  Arguments are name and a
2140 # list of suffixes to check for.
2141 sub check_canonical_spelling
2142 {
2143   my ($name, @suffixes) = @_;
2144
2145   my $xname = &canonicalize ($name);
2146   if ($xname ne $name)
2147     {
2148       foreach my $xt (@suffixes)
2149         {
2150           reject_var ("$name$xt", "use `$xname$xt', not `$name$xt'");
2151         }
2152     }
2153
2154   return $xname;
2155 }
2156
2157
2158 # handle_compile ()
2159 # -----------------
2160 # Set up the compile suite.
2161 sub handle_compile ()
2162 {
2163     return
2164       unless $get_object_extension_was_run;
2165
2166     # Boilerplate.
2167     my $default_includes = '';
2168     if (! option 'nostdinc')
2169       {
2170         $default_includes = ' -I. -I$(srcdir)';
2171
2172         my $var = var 'CONFIG_HEADER';
2173         if ($var)
2174           {
2175             foreach my $hdr (split (' ', $var->variable_value))
2176               {
2177                 $default_includes .= ' -I' . dirname ($hdr);
2178               }
2179           }
2180       }
2181
2182     my (@mostly_rms, @dist_rms);
2183     foreach my $item (sort keys %compile_clean_files)
2184     {
2185         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2186         {
2187             push (@mostly_rms, "\t-rm -f $item");
2188         }
2189         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2190         {
2191             push (@dist_rms, "\t-rm -f $item");
2192         }
2193         else
2194         {
2195           prog_error 'invalid entry in %compile_clean_files';
2196         }
2197     }
2198
2199     my ($coms, $vars, $rules) =
2200       &file_contents_internal (1, "$libdir/am/compile.am",
2201                                new Automake::Location,
2202                                ('DEFAULT_INCLUDES' => $default_includes,
2203                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2204                                 'DISTRMS' => join ("\n", @dist_rms)));
2205     $output_vars .= $vars;
2206     $output_rules .= "$coms$rules";
2207
2208     # Check for automatic de-ANSI-fication.
2209     if (option 'ansi2knr')
2210       {
2211         my ($ansi2knr_filename, $ansi2knr_where) = @{option 'ansi2knr'};
2212         my $ansi2knr_dir = '';
2213
2214         require_variables ($ansi2knr_where, "option `ansi2knr' is used",
2215                            TRUE, "ANSI2KNR", "U");
2216
2217         # topdir is where ansi2knr should be.
2218         if ($ansi2knr_filename eq 'ansi2knr')
2219           {
2220             # Only require ansi2knr files if they should appear in
2221             # this directory.
2222             require_file ($ansi2knr_where, FOREIGN,
2223                           'ansi2knr.c', 'ansi2knr.1');
2224
2225             # ansi2knr needs to be built before subdirs, so unshift it.
2226             unshift (@all, '$(ANSI2KNR)');
2227           }
2228         else
2229           {
2230             $ansi2knr_dir = dirname ($ansi2knr_filename);
2231           }
2232
2233         $output_rules .= &file_contents ('ansi2knr',
2234                                          new Automake::Location,
2235                                          'ANSI2KNR-DIR' => $ansi2knr_dir);
2236
2237     }
2238 }
2239
2240 # handle_libtool ()
2241 # -----------------
2242 # Handle libtool rules.
2243 sub handle_libtool
2244 {
2245   return unless var ('LIBTOOL');
2246
2247   # Libtool requires some files, but only at top level.
2248   # (Starting with Libtool 2.0 we do not have to bother.  These
2249   # requirements are done with AC_REQUIRE_AUX_FILE.)
2250   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2251     if $relative_dir eq '.' && ! $libtool_new_api;
2252
2253   my @libtool_rms;
2254   foreach my $item (sort keys %libtool_clean_directories)
2255     {
2256       my $dir = ($item eq '.') ? '' : "$item/";
2257       # .libs is for Unix, _libs for DOS.
2258       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2259     }
2260
2261   # Output the libtool compilation rules.
2262   $output_rules .= &file_contents ('libtool',
2263                                    new Automake::Location,
2264                                    LTRMS => join ("\n", @libtool_rms));
2265 }
2266
2267 # handle_programs ()
2268 # ------------------
2269 # Handle C programs.
2270 sub handle_programs
2271 {
2272   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2273                                   'bin', 'sbin', 'libexec', 'pkglib',
2274                                   'noinst', 'check');
2275   return if ! @proglist;
2276
2277   my $seen_global_libobjs =
2278     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2279
2280   foreach my $pair (@proglist)
2281     {
2282       my ($where, $one_file) = @$pair;
2283
2284       my $seen_libobjs = 0;
2285       my $obj = &get_object_extension ($one_file);
2286
2287       # Strip any $(EXEEXT) suffix the user might have added, or this
2288       # will confuse &handle_source_transform and &check_canonical_spelling.
2289       # We'll add $(EXEEXT) back later anyway.
2290       $one_file =~ s/\$\(EXEEXT\)$//;
2291
2292       # Canonicalize names and check for misspellings.
2293       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2294                                              '_SOURCES', '_OBJECTS',
2295                                              '_DEPENDENCIES');
2296
2297       $where->push_context ("while processing program `$one_file'");
2298       $where->set (INTERNAL->get);
2299
2300       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2301                                              NONLIBTOOL => 1, LIBTOOL => 0);
2302
2303       if (var ($xname . "_LDADD"))
2304         {
2305           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2306         }
2307       else
2308         {
2309           # User didn't define prog_LDADD override.  So do it.
2310           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2311
2312           # This does a bit too much work.  But we need it to
2313           # generate _DEPENDENCIES when appropriate.
2314           if (var ('LDADD'))
2315             {
2316               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2317             }
2318         }
2319
2320       reject_var ($xname . '_LIBADD',
2321                   "use `${xname}_LDADD', not `${xname}_LIBADD'");
2322
2323       set_seen ($xname . '_DEPENDENCIES');
2324       set_seen ($xname . '_LDFLAGS');
2325
2326       # Determine program to use for link.
2327       my $xlink;
2328       if (var ($xname . '_LINK'))
2329         {
2330           $xlink = $xname . '_LINK';
2331         }
2332       else
2333         {
2334           $xlink = $linker ? $linker : 'LINK';
2335         }
2336
2337       # If the resulting program lies into a subdirectory,
2338       # make sure this directory will exist.
2339       my $dirstamp = require_build_directory_maybe ($one_file);
2340
2341       $output_rules .= &file_contents ('program',
2342                                        $where,
2343                                        PROGRAM  => $one_file,
2344                                        XPROGRAM => $xname,
2345                                        XLINK    => $xlink,
2346                                        DIRSTAMP => $dirstamp,
2347                                        EXEEXT   => '$(EXEEXT)');
2348
2349       if ($seen_libobjs || $seen_global_libobjs)
2350         {
2351           if (var ($xname . '_LDADD'))
2352             {
2353               &check_libobjs_sources ($xname, $xname . '_LDADD');
2354             }
2355           elsif (var ('LDADD'))
2356             {
2357               &check_libobjs_sources ($xname, 'LDADD');
2358             }
2359         }
2360     }
2361 }
2362
2363
2364 # handle_libraries ()
2365 # -------------------
2366 # Handle libraries.
2367 sub handle_libraries
2368 {
2369   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2370                                  'lib', 'pkglib', 'noinst', 'check');
2371   return if ! @liblist;
2372
2373   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2374                                     'noinst', 'check');
2375
2376   if (@prefix)
2377     {
2378       my $var = rvar ($prefix[0] . '_LIBRARIES');
2379       $var->requires_variables ('library used', 'RANLIB');
2380     }
2381
2382   &define_variable ('AR', 'ar', INTERNAL);
2383   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2384
2385   foreach my $pair (@liblist)
2386     {
2387       my ($where, $onelib) = @$pair;
2388
2389       my $seen_libobjs = 0;
2390       # Check that the library fits the standard naming convention.
2391       my $bn = basename ($onelib);
2392       if ($bn !~ /^lib.*\.a$/)
2393         {
2394           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2395           my $suggestion = dirname ($onelib) . "/$bn";
2396           $suggestion =~ s|^\./||g;
2397           msg ('error-gnu/warn', $where,
2398                "`$onelib' is not a standard library name\n"
2399                . "did you mean `$suggestion'?")
2400         }
2401
2402       $where->push_context ("while processing library `$onelib'");
2403       $where->set (INTERNAL->get);
2404
2405       my $obj = &get_object_extension ($onelib);
2406
2407       # Canonicalize names and check for misspellings.
2408       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2409                                             '_OBJECTS', '_DEPENDENCIES',
2410                                             '_AR');
2411
2412       if (! var ($xlib . '_AR'))
2413         {
2414           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2415         }
2416
2417       # Generate support for conditional object inclusion in
2418       # libraries.
2419       if (var ($xlib . '_LIBADD'))
2420         {
2421           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2422             {
2423               $seen_libobjs = 1;
2424             }
2425         }
2426       else
2427         {
2428           &define_variable ($xlib . "_LIBADD", '', $where);
2429         }
2430
2431       reject_var ($xlib . '_LDADD',
2432                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2433
2434       # Make sure we at look at this.
2435       set_seen ($xlib . '_DEPENDENCIES');
2436
2437       &handle_source_transform ($xlib, $onelib, $obj, $where,
2438                                 NONLIBTOOL => 1, LIBTOOL => 0);
2439
2440       # If the resulting library lies into a subdirectory,
2441       # make sure this directory will exist.
2442       my $dirstamp = require_build_directory_maybe ($onelib);
2443
2444       $output_rules .= &file_contents ('library',
2445                                        $where,
2446                                        LIBRARY  => $onelib,
2447                                        XLIBRARY => $xlib,
2448                                        DIRSTAMP => $dirstamp);
2449
2450       if ($seen_libobjs)
2451         {
2452           if (var ($xlib . '_LIBADD'))
2453             {
2454               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2455             }
2456         }
2457     }
2458 }
2459
2460
2461 # handle_ltlibraries ()
2462 # ---------------------
2463 # Handle shared libraries.
2464 sub handle_ltlibraries
2465 {
2466   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2467                                  'noinst', 'lib', 'pkglib', 'check');
2468   return if ! @liblist;
2469
2470   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2471                                     'noinst', 'check');
2472
2473   if (@prefix)
2474     {
2475       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2476       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2477     }
2478
2479   my %instdirs = ();
2480   my %instconds = ();
2481   my %liblocations = ();        # Location (in Makefile.am) of each library.
2482
2483   foreach my $key (@prefix)
2484     {
2485       # Get the installation directory of each library.
2486       (my $dir = $key) =~ s/^nobase_//;
2487       my $var = rvar ($key . '_LTLIBRARIES');
2488
2489       # We reject libraries which are installed in several places
2490       # in the same condition, because we can only specify one
2491       # `-rpath' option.
2492       $var->traverse_recursively
2493         (sub
2494          {
2495            my ($var, $val, $cond, $full_cond) = @_;
2496            my $hcond = $full_cond->human;
2497            my $where = $var->rdef ($cond)->location;
2498            # A library cannot be installed in different directory
2499            # in overlapping conditions.
2500            if (exists $instconds{$val})
2501              {
2502                my ($msg, $acond) =
2503                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2504
2505                if ($msg)
2506                  {
2507                    error ($where, $msg, partial => 1);
2508
2509                    my $dirtxt = "installed in `$dir'";
2510                    $dirtxt = "built for `$dir'"
2511                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2512                    my $dircond =
2513                      $full_cond->true ? "" : " in condition $hcond";
2514
2515                    error ($where, "`$val' should be $dirtxt$dircond ...",
2516                           partial => 1);
2517
2518                    my $hacond = $acond->human;
2519                    my $adir = $instdirs{$val}{$acond};
2520                    my $adirtxt = "installed in `$adir'";
2521                    $adirtxt = "built for `$adir'"
2522                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2523                          || $adir eq 'check');
2524                    my $adircond = $acond->true ? "" : " in condition $hacond";
2525
2526                    my $onlyone = ($dir ne $adir) ?
2527                      ("\nLibtool libraries can be built for only one "
2528                       . "destination.") : "";
2529
2530                    error ($liblocations{$val}{$acond},
2531                           "... and should also be $adirtxt$adircond.$onlyone");
2532                    return;
2533                  }
2534              }
2535            else
2536              {
2537                $instconds{$val} = new Automake::DisjConditions;
2538              }
2539            $instdirs{$val}{$full_cond} = $dir;
2540            $liblocations{$val}{$full_cond} = $where;
2541            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2542          },
2543          sub
2544          {
2545            return ();
2546          },
2547          skip_ac_subst => 1);
2548     }
2549
2550   foreach my $pair (@liblist)
2551     {
2552       my ($where, $onelib) = @$pair;
2553
2554       my $seen_libobjs = 0;
2555       my $obj = &get_object_extension ($onelib);
2556
2557       # Canonicalize names and check for misspellings.
2558       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2559                                             '_SOURCES', '_OBJECTS',
2560                                             '_DEPENDENCIES');
2561
2562       # Check that the library fits the standard naming convention.
2563       my $libname_rx = '^lib.*\.la';
2564       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2565       my $ldvar2 = var ('LDFLAGS');
2566       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2567           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2568         {
2569           # Relax name checking for libtool modules.
2570           $libname_rx = '\.la';
2571         }
2572
2573       my $bn = basename ($onelib);
2574       if ($bn !~ /$libname_rx$/)
2575         {
2576           my $type = 'library';
2577           if ($libname_rx eq '\.la')
2578             {
2579               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2580               $type = 'module';
2581             }
2582           else
2583             {
2584               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2585             }
2586           my $suggestion = dirname ($onelib) . "/$bn";
2587           $suggestion =~ s|^\./||g;
2588           msg ('error-gnu/warn', $where,
2589                "`$onelib' is not a standard libtool $type name\n"
2590                . "did you mean `$suggestion'?")
2591         }
2592
2593       $where->push_context ("while processing Libtool library `$onelib'");
2594       $where->set (INTERNAL->get);
2595
2596       # Make sure we look at these.
2597       set_seen ($xlib . '_LDFLAGS');
2598       set_seen ($xlib . '_DEPENDENCIES');
2599
2600       # Generate support for conditional object inclusion in
2601       # libraries.
2602       if (var ($xlib . '_LIBADD'))
2603         {
2604           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2605             {
2606               $seen_libobjs = 1;
2607             }
2608         }
2609       else
2610         {
2611           &define_variable ($xlib . "_LIBADD", '', $where);
2612         }
2613
2614       reject_var ("${xlib}_LDADD",
2615                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2616
2617
2618       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2619                                              NONLIBTOOL => 0, LIBTOOL => 1);
2620
2621       # Determine program to use for link.
2622       my $xlink;
2623       if (var ($xlib . '_LINK'))
2624         {
2625           $xlink = $xlib . '_LINK';
2626         }
2627       else
2628         {
2629           $xlink = $linker ? $linker : 'LINK';
2630         }
2631
2632       my $rpathvar = "am_${xlib}_rpath";
2633       my $rpath = "\$($rpathvar)";
2634       foreach my $rcond ($instconds{$onelib}->conds)
2635         {
2636           my $val;
2637           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2638               || $instdirs{$onelib}{$rcond} eq 'noinst'
2639               || $instdirs{$onelib}{$rcond} eq 'check')
2640             {
2641               # It's an EXTRA_ library, so we can't specify -rpath,
2642               # because we don't know where the library will end up.
2643               # The user probably knows, but generally speaking automake
2644               # doesn't -- and in fact configure could decide
2645               # dynamically between two different locations.
2646               $val = '';
2647             }
2648           else
2649             {
2650               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2651             }
2652           if ($rcond->true)
2653             {
2654               # If $rcond is true there is only one condition and
2655               # there is no point defining an helper variable.
2656               $rpath = $val;
2657             }
2658           else
2659             {
2660               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2661             }
2662         }
2663
2664       # If the resulting library lies into a subdirectory,
2665       # make sure this directory will exist.
2666       my $dirstamp = require_build_directory_maybe ($onelib);
2667
2668       # Remember to cleanup .libs/ in this directory.
2669       my $dirname = dirname $onelib;
2670       $libtool_clean_directories{$dirname} = 1;
2671
2672       $output_rules .= &file_contents ('ltlibrary',
2673                                        $where,
2674                                        LTLIBRARY  => $onelib,
2675                                        XLTLIBRARY => $xlib,
2676                                        RPATH      => $rpath,
2677                                        XLINK      => $xlink,
2678                                        DIRSTAMP   => $dirstamp);
2679       if ($seen_libobjs)
2680         {
2681           if (var ($xlib . '_LIBADD'))
2682             {
2683               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2684             }
2685         }
2686     }
2687 }
2688
2689 # See if any _SOURCES variable were misspelled.
2690 sub check_typos ()
2691 {
2692   # It is ok if the user sets this particular variable.
2693   set_seen 'AM_LDFLAGS';
2694
2695   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2696     {
2697       foreach my $var (variables $primary)
2698         {
2699           my $varname = $var->name;
2700           # A configure variable is always legitimate.
2701           next if exists $configure_vars{$varname};
2702
2703           for my $cond ($var->conditions->conds)
2704             {
2705               $varname =~ /^(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2706               msg_var ('syntax', $var, "variable `$varname' is defined but no"
2707                        . " program or\nlibrary has `$1' as canonic name"
2708                        . " (possible typo)")
2709                 unless $var->rdef ($cond)->seen;
2710             }
2711         }
2712     }
2713 }
2714
2715
2716 # Handle scripts.
2717 sub handle_scripts
2718 {
2719     # NOTE we no longer automatically clean SCRIPTS, because it is
2720     # useful to sometimes distribute scripts verbatim.  This happens
2721     # e.g. in Automake itself.
2722     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2723                      'bin', 'sbin', 'libexec', 'pkgdata',
2724                      'noinst', 'check');
2725 }
2726
2727
2728
2729
2730 ## ------------------------ ##
2731 ## Handling Texinfo files.  ##
2732 ## ------------------------ ##
2733
2734 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2735 # &scan_texinfo_file ($FILENAME)
2736 # ------------------------------
2737 # $OUTFILE     - name of the info file produced by $FILENAME.
2738 # $VFILE       - name of the version.texi file used (undef if none).
2739 # @CLEAN_FILES - list of byproducts (indexes etc.)
2740 sub scan_texinfo_file ($)
2741 {
2742   my ($filename) = @_;
2743
2744   # Some of the following extensions are always created, no matter
2745   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2746   # are only created when they are used.  We used to scan $FILENAME
2747   # for their use, but that is not enough: they could be used in
2748   # included files.  We can't scan included files because we don't
2749   # know the include path.  Therefore we always erase these files, no
2750   # matter whether they are used or not.
2751   #
2752   # (tmp is only created if an @macro is used and a certain e-TeX
2753   # feature is not available.)
2754   my %clean_suffixes =
2755     map { $_ => 1 } (qw(aux log toc tmp
2756                         cp cps
2757                         fn fns
2758                         ky kys
2759                         vr vrs
2760                         tp tps
2761                         pg pgs)); # grep 'new.*index' texinfo.tex
2762
2763   my $texi = new Automake::XFile "< $filename";
2764   verb "reading $filename";
2765
2766   my ($outfile, $vfile);
2767   while ($_ = $texi->getline)
2768     {
2769       if (/^\@setfilename +(\S+)/)
2770         {
2771           # Honor only the first @setfilename.  (It's possible to have
2772           # more occurrences later if the manual shows examples of how
2773           # to use @setfilename...)
2774           next if $outfile;
2775
2776           $outfile = $1;
2777           if ($outfile =~ /\.(.+)$/ && $1 ne 'info')
2778             {
2779               error ("$filename:$.",
2780                      "output `$outfile' has unrecognized extension");
2781               return;
2782             }
2783         }
2784       # A "version.texi" file is actually any file whose name matches
2785       # "vers*.texi".
2786       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
2787         {
2788           $vfile = $1;
2789         }
2790
2791       # Try to find new or unused indexes.
2792
2793       # Creating a new category of index.
2794       elsif (/^\@def(code)?index (\w+)/)
2795         {
2796           $clean_suffixes{$2} = 1;
2797           $clean_suffixes{"$2s"} = 1;
2798         }
2799
2800       # Merging an index into an another.
2801       elsif (/^\@syn(code)?index (\w+) (\w+)/)
2802         {
2803           delete $clean_suffixes{"$2s"};
2804           $clean_suffixes{"$3s"} = 1;
2805         }
2806
2807     }
2808
2809   if (! $outfile)
2810     {
2811       err_am "`$filename' missing \@setfilename";
2812       return;
2813     }
2814
2815   my $infobase = basename ($filename);
2816   $infobase =~ s/\.te?xi(nfo)?$//;
2817   return ($outfile, $vfile,
2818           map { "$infobase.$_" } (sort keys %clean_suffixes));
2819 }
2820
2821
2822 # ($DIRSTAMP, @CLEAN_FILES)
2823 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
2824 # ------------------------------------------------------------------
2825 # SOURCE - the source Texinfo file
2826 # DEST - the destination Info file
2827 # INSRC - wether DEST should be built in the source tree
2828 # DEPENDENCIES - known dependencies
2829 sub output_texinfo_build_rules ($$$@)
2830 {
2831   my ($source, $dest, $insrc, @deps) = @_;
2832
2833   # Split `a.texi' into `a' and `.texi'.
2834   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
2835   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
2836
2837   $ssfx ||= "";
2838   $dsfx ||= "";
2839
2840   # We can output two kinds of rules: the "generic" rules use Make
2841   # suffix rules and are appropriate when $source and $dest do not lie
2842   # in a sub-directory; the "specific" rules are needed in the other
2843   # case.
2844   #
2845   # The former are output only once (this is not really apparent here,
2846   # but just remember that some logic deeper in Automake will not
2847   # output the same rule twice); while the later need to be output for
2848   # each Texinfo source.
2849   my $generic;
2850   my $makeinfoflags;
2851   my $sdir = dirname $source;
2852   if ($sdir eq '.' && dirname ($dest) eq '.')
2853     {
2854       $generic = 1;
2855       $makeinfoflags = '-I $(srcdir)';
2856     }
2857   else
2858     {
2859       $generic = 0;
2860       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
2861     }
2862
2863   # A directory can contain two kinds of info files: some built in the
2864   # source tree, and some built in the build tree.  The rules are
2865   # different in each case.  However we cannot output two different
2866   # set of generic rules.  Because in-source builds are more usual, we
2867   # use generic rules in this case and fall back to "specific" rules
2868   # for build-dir builds.  (It should not be a problem to invert this
2869   # if needed.)
2870   $generic = 0 unless $insrc;
2871
2872   # We cannot use a suffix rule to build info files with an empty
2873   # extension.  Otherwise we would output a single suffix inference
2874   # rule, with separate dependencies, as in
2875   #
2876   #    .texi:
2877   #             $(MAKEINFO) ...
2878   #    foo.info: foo.texi
2879   #
2880   # which confuse Solaris make.  (See the Autoconf manual for
2881   # details.)  Therefore we use a specific rule in this case.  This
2882   # applies to info files only (dvi and pdf files always have an
2883   # extension).
2884   my $generic_info = ($generic && $dsfx) ? 1 : 0;
2885
2886   # If the resulting file lie into a subdirectory,
2887   # make sure this directory will exist.
2888   my $dirstamp = require_build_directory_maybe ($dest);
2889
2890   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
2891
2892   $output_rules .= file_contents ('texibuild',
2893                                   new Automake::Location,
2894                                   DEPS             => "@deps",
2895                                   DEST_PREFIX      => $dpfx,
2896                                   DEST_INFO_PREFIX => $dipfx,
2897                                   DEST_SUFFIX      => $dsfx,
2898                                   DIRSTAMP         => $dirstamp,
2899                                   GENERIC          => $generic,
2900                                   GENERIC_INFO     => $generic_info,
2901                                   INSRC            => $insrc,
2902                                   MAKEINFOFLAGS    => $makeinfoflags,
2903                                   SOURCE           => ($generic
2904                                                        ? '$<' : $source),
2905                                   SOURCE_INFO      => ($generic_info
2906                                                        ? '$<' : $source),
2907                                   SOURCE_REAL      => $source,
2908                                   SOURCE_SUFFIX    => $ssfx,
2909                                   );
2910   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
2911 }
2912
2913
2914 # $TEXICLEANS
2915 # handle_texinfo_helper ($info_texinfos)
2916 # --------------------------------------
2917 # Handle all Texinfo source; helper for handle_texinfo.
2918 sub handle_texinfo_helper ($)
2919 {
2920   my ($info_texinfos) = @_;
2921   my (@infobase, @info_deps_list, @texi_deps);
2922   my %versions;
2923   my $done = 0;
2924   my @texi_cleans;
2925
2926   # Build a regex matching user-cleaned files.
2927   my $d = var 'DISTCLEANFILES';
2928   my $c = var 'CLEANFILES';
2929   my @f = ();
2930   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
2931   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
2932   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
2933   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
2934
2935   foreach my $texi
2936       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
2937     {
2938       my $infobase = $texi;
2939       $infobase =~ s/\.(txi|texinfo|texi)$//;
2940
2941       if ($infobase eq $texi)
2942         {
2943           # FIXME: report line number.
2944           err_am "texinfo file `$texi' has unrecognized extension";
2945           next;
2946         }
2947
2948       push @infobase, $infobase;
2949
2950       # If 'version.texi' is referenced by input file, then include
2951       # automatic versioning capability.
2952       my ($out_file, $vtexi, @clean_files) =
2953         scan_texinfo_file ("$relative_dir/$texi")
2954         or next;
2955       push (@texi_cleans, @clean_files);
2956
2957       # If the Texinfo source is in a subdirectory, create the
2958       # resulting info in this subdirectory.  If it is in the current
2959       # directory, try hard to not prefix "./" because it breaks the
2960       # generic rules.
2961       my $outdir = dirname ($texi) . '/';
2962       $outdir = "" if $outdir eq './';
2963       $out_file =  $outdir . $out_file;
2964
2965       # Until Automake 1.6.3, .info files were built in the
2966       # source tree.  This was an obstacle to the support of
2967       # non-distributed .info files, and non-distributed .texi
2968       # files.
2969       #
2970       # * Non-distributed .texi files is important in some packages
2971       #   where .texi files are built at make time, probably using
2972       #   other binaries built in the package itself, maybe using
2973       #   tools or information found on the build host.  Because
2974       #   these files are not distributed they are always rebuilt
2975       #   at make time; they should therefore not lie in the source
2976       #   directory.  One plan was to support this using
2977       #   nodist_info_TEXINFOS or something similar.  (Doing this
2978       #   requires some sanity checks.  For instance Automake should
2979       #   not allow:
2980       #      dist_info_TEXINFO = foo.texi
2981       #      nodist_foo_TEXINFO = included.texi
2982       #   because a distributed file should never depend on a
2983       #   non-distributed file.)
2984       #
2985       # * If .texi files are not distributed, then .info files should
2986       #   not be distributed either.  There are also cases where one
2987       #   want to distribute .texi files, but do not want to
2988       #   distribute the .info files.  For instance the Texinfo package
2989       #   distributes the tool used to build these files; it would
2990       #   be a waste of space to distribute them.  It's not clear
2991       #   which syntax we should use to indicate that .info files should
2992       #   not be distributed.  Akim Demaille suggested that eventually
2993       #   we switch to a new syntax:
2994       #   |  Maybe we should take some inspiration from what's already
2995       #   |  done in the rest of Automake.  Maybe there is too much
2996       #   |  syntactic sugar here, and you want
2997       #   |     nodist_INFO = bar.info
2998       #   |     dist_bar_info_SOURCES = bar.texi
2999       #   |     bar_texi_DEPENDENCIES = foo.texi
3000       #   |  with a bit of magic to have bar.info represent the whole
3001       #   |  bar*info set.  That's a lot more verbose that the current
3002       #   |  situation, but it is # not new, hence the user has less
3003       #   |  to learn.
3004       #   |
3005       #   |  But there is still too much room for meaningless specs:
3006       #   |     nodist_INFO = bar.info
3007       #   |     dist_bar_info_SOURCES = bar.texi
3008       #   |     dist_PS = bar.ps something-written-by-hand.ps
3009       #   |     nodist_bar_ps_SOURCES = bar.texi
3010       #   |     bar_texi_DEPENDENCIES = foo.texi
3011       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3012       #
3013       # Back to the point, it should be clear that in order to support
3014       # non-distributed .info files, we need to build them in the
3015       # build tree, not in the source tree (non-distributed .texi
3016       # files are less of a problem, because we do not output build
3017       # rules for them).  In Automake 1.7 .info build rules have been
3018       # largely cleaned up so that .info files get always build in the
3019       # build tree, even when distributed.  The idea was that
3020       #   (1) if during a VPATH build the .info file was found to be
3021       #       absent or out-of-date (in the source tree or in the
3022       #       build tree), Make would rebuild it in the build tree.
3023       #       If an up-to-date source-tree of the .info file existed,
3024       #       make would not rebuild it in the build tree.
3025       #   (2) having two copies of .info files, one in the source tree
3026       #       and one (newer) in the build tree is not a problem
3027       #       because `make dist' always pick files in the build tree
3028       #       first.
3029       # However it turned out the be a bad idea for several reasons:
3030       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3031       #     like GNU Make on point (1) above.  These implementations
3032       #     of Make would always rebuild .info files in the build
3033       #     tree, even if such files were up to date in the source
3034       #     tree.  Consequently, it was impossible to perform a VPATH
3035       #     build of a package containing Texinfo files using these
3036       #     Make implementations.
3037       #     (Refer to the Autoconf Manual, section "Limitation of
3038       #     Make", paragraph "VPATH", item "target lookup", for
3039       #     an account of the differences between these
3040       #     implementations.)
3041       #   * The GNU Coding Standards require these files to be built
3042       #     in the source-tree (when they are distributed, that is).
3043       #   * Keeping a fresher copy of distributed files in the
3044       #     build tree can be annoying during development because
3045       #     - if the files is kept under CVS, you really want it
3046       #       to be updated in the source tree
3047       #     - it is confusing that `make distclean' does not erase
3048       #       all files in the build tree.
3049       #
3050       # Consequently, starting with Automake 1.8, .info files are
3051       # built in the source tree again.  Because we still plan to
3052       # support non-distributed .info files at some point, we
3053       # have a single variable ($INSRC) that controls whether
3054       # the current .info file must be built in the source tree
3055       # or in the build tree.  Actually this variable is switched
3056       # off for .info files that appear to be cleaned; this is
3057       # for backward compatibility with package such as Texinfo,
3058       # which do things like
3059       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3060       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3061       #   # Do not create info files for distribution.
3062       #   dist-info:
3063       # in order not to distribute .info files.
3064       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3065
3066       my $soutdir = '$(srcdir)/' . $outdir;
3067       $outdir = $soutdir if $insrc;
3068
3069       # If user specified file_TEXINFOS, then use that as explicit
3070       # dependency list.
3071       @texi_deps = ();
3072       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3073
3074       my $canonical = canonicalize ($infobase);
3075       if (var ($canonical . "_TEXINFOS"))
3076         {
3077           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3078           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3079         }
3080
3081       my ($dirstamp, @cfiles) =
3082         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3083       push (@texi_cleans, @cfiles);
3084
3085       push (@info_deps_list, $out_file);
3086
3087       # If a vers*.texi file is needed, emit the rule.
3088       if ($vtexi)
3089         {
3090           err_am ("`$vtexi', included in `$texi', "
3091                   . "also included in `$versions{$vtexi}'")
3092             if defined $versions{$vtexi};
3093           $versions{$vtexi} = $texi;
3094
3095           # We number the stamp-vti files.  This is doable since the
3096           # actual names don't matter much.  We only number starting
3097           # with the second one, so that the common case looks nice.
3098           my $vti = ($done ? $done : 'vti');
3099           ++$done;
3100
3101           # This is ugly, but it is our historical practice.
3102           if ($config_aux_dir_set_in_configure_ac)
3103             {
3104               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3105                                             'mdate-sh');
3106             }
3107           else
3108             {
3109               require_file_with_macro (TRUE, 'info_TEXINFOS',
3110                                        FOREIGN, 'mdate-sh');
3111             }
3112
3113           my $conf_dir;
3114           if ($config_aux_dir_set_in_configure_ac)
3115             {
3116               $conf_dir = "$am_config_aux_dir/";
3117             }
3118           else
3119             {
3120               $conf_dir = '$(srcdir)/';
3121             }
3122           $output_rules .= file_contents ('texi-vers',
3123                                           new Automake::Location,
3124                                           TEXI     => $texi,
3125                                           VTI      => $vti,
3126                                           STAMPVTI => "${soutdir}stamp-$vti",
3127                                           VTEXI    => "$soutdir$vtexi",
3128                                           MDDIR    => $conf_dir,
3129                                           DIRSTAMP => $dirstamp);
3130         }
3131     }
3132
3133   # Handle location of texinfo.tex.
3134   my $need_texi_file = 0;
3135   my $texinfodir;
3136   if (var ('TEXINFO_TEX'))
3137     {
3138       # The user defined TEXINFO_TEX so assume he knows what he is
3139       # doing.
3140       $texinfodir = ('$(srcdir)/'
3141                      . dirname (variable_value ('TEXINFO_TEX')));
3142     }
3143   elsif (option 'cygnus')
3144     {
3145       $texinfodir = '$(top_srcdir)/../texinfo';
3146       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3147     }
3148   elsif ($config_aux_dir_set_in_configure_ac)
3149     {
3150       $texinfodir = $am_config_aux_dir;
3151       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3152       $need_texi_file = 2; # so that we require_conf_file later
3153     }
3154   else
3155     {
3156       $texinfodir = '$(srcdir)';
3157       $need_texi_file = 1;
3158     }
3159   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3160
3161   push (@dist_targets, 'dist-info');
3162
3163   if (! option 'no-installinfo')
3164     {
3165       # Make sure documentation is made and installed first.  Use
3166       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3167       # get run twice during "make all".
3168       unshift (@all, '$(INFO_DEPS)');
3169     }
3170
3171   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3172   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3173   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3174   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3175
3176   # This next isn't strictly needed now -- the places that look here
3177   # could easily be changed to look in info_TEXINFOS.  But this is
3178   # probably better, in case noinst_TEXINFOS is ever supported.
3179   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3180
3181   # Do some error checking.  Note that this file is not required
3182   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3183   # up above.
3184   if ($need_texi_file && ! option 'no-texinfo.tex')
3185     {
3186       if ($need_texi_file > 1)
3187         {
3188           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3189                                         'texinfo.tex');
3190         }
3191       else
3192         {
3193           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3194                                    'texinfo.tex');
3195         }
3196     }
3197
3198   return makefile_wrap ("", "\t  ", @texi_cleans);
3199 }
3200
3201
3202 # handle_texinfo ()
3203 # -----------------
3204 # Handle all Texinfo source.
3205 sub handle_texinfo ()
3206 {
3207   reject_var 'TEXINFOS', "`TEXINFOS' is an anachronism; use `info_TEXINFOS'";
3208   # FIXME: I think this is an obsolete future feature name.
3209   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3210
3211   my $info_texinfos = var ('info_TEXINFOS');
3212   my $texiclean = "";
3213   if ($info_texinfos)
3214     {
3215       $texiclean = handle_texinfo_helper ($info_texinfos);
3216     }
3217   $output_rules .=  file_contents ('texinfos',
3218                                    new Automake::Location,
3219                                    TEXICLEAN     => $texiclean,
3220                                    'LOCAL-TEXIS' => !!$info_texinfos);
3221 }
3222
3223
3224 # Handle any man pages.
3225 sub handle_man_pages
3226 {
3227   reject_var 'MANS', "`MANS' is an anachronism; use `man_MANS'";
3228
3229   # Find all the sections in use.  We do this by first looking for
3230   # "standard" sections, and then looking for any additional
3231   # sections used in man_MANS.
3232   my (%sections, %vlist);
3233   # We handle nodist_ for uniformity.  man pages aren't distributed
3234   # by default so it isn't actually very important.
3235   foreach my $pfx ('', 'dist_', 'nodist_')
3236     {
3237       # Add more sections as needed.
3238       foreach my $section ('0'..'9', 'n', 'l')
3239         {
3240           my $varname = $pfx . 'man' . $section . '_MANS';
3241           if (var ($varname))
3242             {
3243               $sections{$section} = 1;
3244               $varname = '$(' . $varname . ')';
3245               $vlist{$varname} = 1;
3246
3247               &push_dist_common ($varname)
3248                 if $pfx eq 'dist_';
3249             }
3250         }
3251
3252       my $varname = $pfx . 'man_MANS';
3253       my $var = var ($varname);
3254       if ($var)
3255         {
3256           foreach ($var->value_as_list_recursive)
3257             {
3258               # A page like `foo.1c' goes into man1dir.
3259               if (/\.([0-9a-z])([a-z]*)$/)
3260                 {
3261                   $sections{$1} = 1;
3262                 }
3263             }
3264
3265           $varname = '$(' . $varname . ')';
3266           $vlist{$varname} = 1;
3267           &push_dist_common ($varname)
3268             if $pfx eq 'dist_';
3269         }
3270     }
3271
3272   return unless %sections;
3273
3274   # Now for each section, generate an install and uninstall rule.
3275   # Sort sections so output is deterministic.
3276   foreach my $section (sort keys %sections)
3277     {
3278       $output_rules .= &file_contents ('mans',
3279                                        new Automake::Location,
3280                                        SECTION => $section);
3281     }
3282
3283   my @mans = sort keys %vlist;
3284   $output_vars .= file_contents ('mans-vars',
3285                                  new Automake::Location,
3286                                  MANS => "@mans");
3287
3288   push (@all, '$(MANS)')
3289     unless option 'no-installman';
3290 }
3291
3292 # Handle DATA variables.
3293 sub handle_data
3294 {
3295     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3296                      'data', 'sysconf', 'sharedstate', 'localstate',
3297                      'pkgdata', 'lisp', 'noinst', 'check');
3298 }
3299
3300 # Handle TAGS.
3301 sub handle_tags
3302 {
3303     my @tag_deps = ();
3304     my @ctag_deps = ();
3305     if (var ('SUBDIRS'))
3306     {
3307         $output_rules .= ("tags-recursive:\n"
3308                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3309                           # Never fail here if a subdir fails; it
3310                           # isn't important.
3311                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3312                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3313                           . "\tdone\n");
3314         push (@tag_deps, 'tags-recursive');
3315         &depend ('.PHONY', 'tags-recursive');
3316
3317         $output_rules .= ("ctags-recursive:\n"
3318                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3319                           # Never fail here if a subdir fails; it
3320                           # isn't important.
3321                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3322                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3323                           . "\tdone\n");
3324         push (@ctag_deps, 'ctags-recursive');
3325         &depend ('.PHONY', 'ctags-recursive');
3326     }
3327
3328     if (&saw_sources_p (1)
3329         || var ('ETAGS_ARGS')
3330         || @tag_deps)
3331     {
3332         my @config;
3333         foreach my $spec (@config_headers)
3334         {
3335             my ($out, @ins) = split_config_file_spec ($spec);
3336             foreach my $in (@ins)
3337               {
3338                 # If the config header source is in this directory,
3339                 # require it.
3340                 push @config, basename ($in)
3341                   if $relative_dir eq dirname ($in);
3342               }
3343         }
3344         $output_rules .= &file_contents ('tags',
3345                                          new Automake::Location,
3346                                          CONFIG    => "@config",
3347                                          TAGSDIRS  => "@tag_deps",
3348                                          CTAGSDIRS => "@ctag_deps");
3349
3350         set_seen 'TAGS_DEPENDENCIES';
3351     }
3352     elsif (reject_var ('TAGS_DEPENDENCIES',
3353                        "doesn't make sense to define `TAGS_DEPENDENCIES'"
3354                        . "without\nsources or `ETAGS_ARGS'"))
3355     {
3356     }
3357     else
3358     {
3359         # Every Makefile must define some sort of TAGS rule.
3360         # Otherwise, it would be possible for a top-level "make TAGS"
3361         # to fail because some subdirectory failed.
3362         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3363         # Ditto ctags.
3364         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3365     }
3366 }
3367
3368 # Handle multilib support.
3369 sub handle_multilib
3370 {
3371   if ($seen_multilib && $relative_dir eq '.')
3372     {
3373       $output_rules .= &file_contents ('multilib', new Automake::Location);
3374       push (@all, 'all-multi');
3375     }
3376 }
3377
3378
3379 # user_phony_rule ($NAME)
3380 # -----------------------
3381 # Return false if rule $NAME does not exist.  Otherwise,
3382 # declare it as phony, complete its definition (in case it is
3383 # conditional), and return its Automake::Rule instance.
3384 sub user_phony_rule ($)
3385 {
3386   my ($name) = @_;
3387   my $rule = rule $name;
3388   if ($rule)
3389     {
3390       depend ('.PHONY', $name);
3391       # Define $NAME in all condition where it is not already defined,
3392       # so that it is always OK to depend on $NAME.
3393       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3394         {
3395           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3396                                   $c, INTERNAL);
3397           $output_rules .= $c->subst_string . "$name:\n";
3398         }
3399     }
3400   return $rule;
3401 }
3402
3403
3404 # $BOOLEAN
3405 # &for_dist_common ($A, $B)
3406 # -------------------------
3407 # Subroutine for &handle_dist: sort files to dist.
3408 #
3409 # We put README first because it then becomes easier to make a
3410 # Usenet-compliant shar file (in these, README must be first).
3411 #
3412 # FIXME: do more ordering of files here.
3413 sub for_dist_common
3414 {
3415     return 0
3416         if $a eq $b;
3417     return -1
3418         if $a eq 'README';
3419     return 1
3420         if $b eq 'README';
3421     return $a cmp $b;
3422 }
3423
3424
3425 # handle_dist
3426 # -----------
3427 # Handle 'dist' target.
3428 sub handle_dist ()
3429 {
3430   # Substutions for distdit.am
3431   my %transform;
3432
3433   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3434   # no-dist setting: target like `distclean' or `maintainer-clean' use it.
3435   my $subdirs = var ('SUBDIRS');
3436   if ($subdirs)
3437     {
3438       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3439       # to all possible directories, and use it.  If DIST_SUBDIRS is
3440       # defined, just use it.
3441
3442       # Note that we check DIST_SUBDIRS first on purpose, so that
3443       # we don't call has_conditional_contents for now reason.
3444       # (In the past one project used so many conditional subdirectories
3445       # that calling has_conditional_contents on SUBDIRS caused
3446       # automake to grow to 150Mb -- this should not happen with
3447       # the current implementation of has_conditional_contents,
3448       # but it's more efficient to avoid the call anyway.)
3449       if (var ('DIST_SUBDIRS'))
3450         {
3451         }
3452       elsif ($subdirs->has_conditional_contents)
3453         {
3454           define_pretty_variable
3455             ('DIST_SUBDIRS', TRUE, INTERNAL,
3456              uniq ($subdirs->value_as_list_recursive));
3457         }
3458       else
3459         {
3460           # We always define this because that is what `distclean'
3461           # wants.
3462           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3463                                   '$(SUBDIRS)');
3464         }
3465     }
3466
3467   # The remaining definitions are only required when a dist target is used.
3468   return if option 'no-dist';
3469
3470   # At least one of the archive formats must be enabled.
3471   if ($relative_dir eq '.')
3472     {
3473       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3474       $archive_defined ||=
3475         grep { option "dist-$_" } ('shar', 'zip', 'tarZ', 'bzip2');
3476       error (option 'no-dist-gzip',
3477              "no-dist-gzip specified but no dist-* specified, "
3478              . "at least one archive format must be enabled")
3479         unless $archive_defined;
3480     }
3481
3482   # Look for common files that should be included in distribution.
3483   # If the aux dir is set, and it does not have a Makefile.am, then
3484   # we check for these files there as well.
3485   my $check_aux = 0;
3486   if ($relative_dir eq '.'
3487       && $config_aux_dir_set_in_configure_ac)
3488     {
3489       if (! &is_make_dir ($config_aux_dir))
3490         {
3491           $check_aux = 1;
3492         }
3493     }
3494   foreach my $cfile (@common_files)
3495     {
3496       if (-f ($relative_dir . "/" . $cfile)
3497           # The file might be absent, but if it can be built it's ok.
3498           || rule $cfile)
3499         {
3500           &push_dist_common ($cfile);
3501         }
3502
3503       # Don't use `elsif' here because a file might meaningfully
3504       # appear in both directories.
3505       if ($check_aux && -f "$config_aux_dir/$cfile")
3506         {
3507           &push_dist_common ("$config_aux_dir/$cfile")
3508         }
3509     }
3510
3511   # We might copy elements from $configure_dist_common to
3512   # %dist_common if we think we need to.  If the file appears in our
3513   # directory, we would have discovered it already, so we don't
3514   # check that.  But if the file is in a subdir without a Makefile,
3515   # we want to distribute it here if we are doing `.'.  Ugly!
3516   if ($relative_dir eq '.')
3517     {
3518       foreach my $file (split (' ' , $configure_dist_common))
3519         {
3520           push_dist_common ($file)
3521             unless is_make_dir (dirname ($file));
3522         }
3523     }
3524
3525   # Files to distributed.  Don't use ->value_as_list_recursive
3526   # as it recursively expands `$(dist_pkgdata_DATA)' etc.
3527   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3528   @dist_common = uniq (sort for_dist_common (@dist_common));
3529   variable_delete 'DIST_COMMON';
3530   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3531
3532   # Now that we've processed DIST_COMMON, disallow further attempts
3533   # to set it.
3534   $handle_dist_run = 1;
3535
3536   # Scan EXTRA_DIST to see if we need to distribute anything from a
3537   # subdir.  If so, add it to the list.  I didn't want to do this
3538   # originally, but there were so many requests that I finally
3539   # relented.
3540   my $extra_dist = var ('EXTRA_DIST');
3541   if ($extra_dist)
3542     {
3543       # FIXME: This should be fixed to work with conditions.  That
3544       # will require only making the entries in %dist_dirs under the
3545       # appropriate condition.  This is meaningful if the nature of
3546       # the distribution should depend upon the configure options
3547       # used.
3548       foreach ($extra_dist->value_as_list_recursive (skip_ac_subst => 1))
3549         {
3550           next unless s,/+[^/]+$,,;
3551           $dist_dirs{$_} = 1
3552             unless $_ eq '.';
3553         }
3554     }
3555
3556   # We have to check DIST_COMMON for extra directories in case the
3557   # user put a source used in AC_OUTPUT into a subdir.
3558   my $topsrcdir = backname ($relative_dir);
3559   foreach (rvar ('DIST_COMMON')->value_as_list_recursive (skip_ac_subst => 1))
3560     {
3561       s/\$\(top_srcdir\)/$topsrcdir/;
3562       s/\$\(srcdir\)/./;
3563       # Strip any leading `./'.
3564       s,^(:?\./+)*,,;
3565       next unless s,/+[^/]+$,,;
3566       $dist_dirs{$_} = 1
3567         unless $_ eq '.';
3568     }
3569
3570   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3571   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3572
3573   # Prepend $(distdir) to each directory given.
3574   my %rewritten = map { '$(distdir)/' . "$_" => 1 } keys %dist_dirs;
3575   $transform{'DISTDIRS'} = join (' ', sort keys %rewritten);
3576
3577   # If the target `dist-hook' exists, make sure it is run.  This
3578   # allows users to do random weird things to the distribution
3579   # before it is packaged up.
3580   push (@dist_targets, 'dist-hook')
3581     if user_phony_rule 'dist-hook';
3582   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3583
3584   my $flm = option ('filename-length-max');
3585   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3586
3587   $output_rules .= &file_contents ('distdir',
3588                                    new Automake::Location,
3589                                    %transform,
3590                                    FILENAME_FILTER => $filename_filter);
3591 }
3592
3593
3594 # check_directory ($NAME, $WHERE)
3595 # -------------------------------
3596 # Ensure $NAME is a directory, and that it uses sane name.
3597 # Use $WHERE as a location in the diagnostic, if any.
3598 sub check_directory ($$)
3599 {
3600   my ($dir, $where) = @_;
3601
3602   error $where, "required directory $relative_dir/$dir does not exist"
3603     unless -d "$relative_dir/$dir";
3604
3605   # If an `obj/' directory exists, BSD make will enter it before
3606   # reading `Makefile'.  Hence the `Makefile' in the current directory
3607   # will not be read.
3608   #
3609   #  % cat Makefile
3610   #  all:
3611   #          echo Hello
3612   #  % cat obj/Makefile
3613   #  all:
3614   #          echo World
3615   #  % make      # GNU make
3616   #  echo Hello
3617   #  Hello
3618   #  % pmake     # BSD make
3619   #  echo World
3620   #  World
3621   msg ('portability', $where,
3622        "naming a subdirectory `obj' causes troubles with BSD make")
3623     if $dir eq 'obj';
3624
3625   # `aux' is probably the most important of the following forbidden name,
3626   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3627   msg ('portability', $where,
3628        "name `$dir' is reserved on W32 and DOS platforms")
3629     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3630 }
3631
3632 # check_directories_in_var ($VARIABLE)
3633 # ------------------------------------
3634 # Recursively check all items in variables $VARIABLE as directories
3635 sub check_directories_in_var ($)
3636 {
3637   my ($var) = @_;
3638   $var->traverse_recursively
3639     (sub
3640      {
3641        my ($var, $val, $cond, $full_cond) = @_;
3642        check_directory ($val, $var->rdef ($cond)->location);
3643        return ();
3644      },
3645      undef,
3646      skip_ac_subst => 1);
3647 }
3648
3649 # &handle_subdirs ()
3650 # ------------------
3651 # Handle subdirectories.
3652 sub handle_subdirs ()
3653 {
3654   my $subdirs = var ('SUBDIRS');
3655   return
3656     unless $subdirs;
3657
3658   check_directories_in_var $subdirs;
3659
3660   my $dsubdirs = var ('DIST_SUBDIRS');
3661   check_directories_in_var $dsubdirs
3662     if $dsubdirs;
3663
3664   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3665   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3666 }
3667
3668
3669 # ($REGEN, @DEPENDENCIES)
3670 # &scan_aclocal_m4
3671 # ----------------
3672 # If aclocal.m4 creation is automated, return the list of its dependencies.
3673 sub scan_aclocal_m4 ()
3674 {
3675   my $regen_aclocal = 0;
3676
3677   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3678   set_seen 'CONFIGURE_DEPENDENCIES';
3679
3680   if (-f 'aclocal.m4')
3681     {
3682       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3683
3684       my $aclocal = new Automake::XFile "< aclocal.m4";
3685       my $line = $aclocal->getline;
3686       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3687     }
3688
3689   my @ac_deps = ();
3690
3691   if (set_seen ('ACLOCAL_M4_SOURCES'))
3692     {
3693       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3694       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3695                "`ACLOCAL_M4_SOURCES' is obsolete.\n"
3696                . "It should be safe to simply remove it.");
3697     }
3698
3699   # Note that it might be possible that aclocal.m4 doesn't exist but
3700   # should be auto-generated.  This case probably isn't very
3701   # important.
3702
3703   return ($regen_aclocal, @ac_deps);
3704 }
3705
3706
3707 # @DEPENDENCIES
3708 # &prepend_srcdir (@INPUTS)
3709 # -------------------------
3710 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
3711 # if an input file has a directory part the same as the current
3712 # directory, then the directory part is simply replaced by $(srcdir).
3713 # But if the directory part is different, then $(top_srcdir) is
3714 # prepended.
3715 sub prepend_srcdir (@)
3716 {
3717   my (@inputs) = @_;
3718   my @newinputs;
3719
3720   foreach my $single (@inputs)
3721     {
3722       if (dirname ($single) eq $relative_dir)
3723         {
3724           push (@newinputs, '$(srcdir)/' . basename ($single));
3725         }
3726       else
3727         {
3728           push (@newinputs, '$(top_srcdir)/' . $single);
3729         }
3730     }
3731   return @newinputs;
3732 }
3733
3734 # @DEPENDENCIES
3735 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
3736 # ---------------------------------------------------
3737 # Compute a list of dependencies appropriate for the rebuild
3738 # rule of
3739 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
3740 # Also distribute $INPUTs which are not build by another AC_CONFIG_FILES.
3741 sub rewrite_inputs_into_dependencies ($@)
3742 {
3743   my ($file, @inputs) = @_;
3744   my @res = ();
3745
3746   for my $i (@inputs)
3747     {
3748       if (exists $ac_config_files_location{$i})
3749         {
3750           my $di = dirname $i;
3751           if ($di eq $relative_dir)
3752             {
3753               $i = basename $i;
3754             }
3755           # In the top-level Makefile we do not use $(top_builddir), because
3756           # we are already there, and since the targets are built without
3757           # a $(top_builddir), it helps BSD Make to match them with
3758           # dependencies.
3759           elsif ($relative_dir ne '.')
3760             {
3761               $i = '$(top_builddir)/' . $i;
3762             }
3763         }
3764       else
3765         {
3766           msg ('error', $ac_config_files_location{$file},
3767                "required file `$i' not found")
3768             unless exists $output_files{$i} || -f $i;
3769           ($i) = prepend_srcdir ($i);
3770           push_dist_common ($i);
3771         }
3772       push @res, $i;
3773     }
3774   return @res;
3775 }
3776
3777
3778
3779 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
3780 # ------------------------------------------------------------------
3781 # Handle remaking and configure stuff.
3782 # We need the name of the input file, to do proper remaking rules.
3783 sub handle_configure ($$$@)
3784 {
3785   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
3786
3787   prog_error 'empty @inputs'
3788     unless @inputs;
3789
3790   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
3791                                                             $makefile_in);
3792   my $rel_makefile = basename $makefile;
3793
3794   my $colon_infile = ':' . join (':', @inputs);
3795   $colon_infile = '' if $colon_infile eq ":$makefile.in";
3796   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
3797   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
3798   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
3799                           @configure_deps, @aclocal_m4_deps,
3800                           '$(top_srcdir)/' . $configure_ac);
3801   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
3802   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
3803   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
3804                           @configuredeps);
3805
3806   $output_rules .= file_contents
3807     ('configure',
3808      new Automake::Location,
3809      MAKEFILE              => $rel_makefile,
3810      'MAKEFILE-DEPS'       => "@rewritten",
3811      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
3812      'MAKEFILE-IN'         => $rel_makefile_in,
3813      'MAKEFILE-IN-DEPS'    => "@include_stack",
3814      'MAKEFILE-AM'         => $rel_makefile_am,
3815      STRICTNESS            => global_option 'cygnus'
3816                                 ? 'cygnus' : $strictness_name,
3817      'USE-DEPS'            => global_option 'no-dependencies'
3818                                 ? ' --ignore-deps' : '',
3819      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
3820      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4);
3821
3822   if ($relative_dir eq '.')
3823     {
3824       &push_dist_common ('acconfig.h')
3825         if -f 'acconfig.h';
3826     }
3827
3828   # If we have a configure header, require it.
3829   my $hdr_index = 0;
3830   my @distclean_config;
3831   foreach my $spec (@config_headers)
3832     {
3833       $hdr_index += 1;
3834       # $CONFIG_H_PATH: config.h from top level.
3835       my ($config_h_path, @ins) = split_config_file_spec ($spec);
3836       my $config_h_dir = dirname ($config_h_path);
3837
3838       # If the header is in the current directory we want to build
3839       # the header here.  Otherwise, if we're at the topmost
3840       # directory and the header's directory doesn't have a
3841       # Makefile, then we also want to build the header.
3842       if ($relative_dir eq $config_h_dir
3843           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
3844         {
3845           my ($cn_sans_dir, $stamp_dir);
3846           if ($relative_dir eq $config_h_dir)
3847             {
3848               $cn_sans_dir = basename ($config_h_path);
3849               $stamp_dir = '';
3850             }
3851           else
3852             {
3853               $cn_sans_dir = $config_h_path;
3854               if ($config_h_dir eq '.')
3855                 {
3856                   $stamp_dir = '';
3857                 }
3858               else
3859                 {
3860                   $stamp_dir = $config_h_dir . '/';
3861                 }
3862             }
3863
3864           # This will also distribute all inputs.
3865           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
3866
3867           # Header defined and in this directory.
3868           my @files;
3869           if (-f $config_h_path . '.top')
3870             {
3871               push (@files, "$cn_sans_dir.top");
3872             }
3873           if (-f $config_h_path . '.bot')
3874             {
3875               push (@files, "$cn_sans_dir.bot");
3876             }
3877
3878           push_dist_common (@files);
3879
3880           # For now, acconfig.h can only appear in the top srcdir.
3881           if (-f 'acconfig.h')
3882             {
3883               push (@files, '$(top_srcdir)/acconfig.h');
3884             }
3885
3886           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
3887           $output_rules .=
3888             file_contents ('remake-hdr',
3889                            new Automake::Location,
3890                            FILES            => "@files",
3891                            CONFIG_H         => $cn_sans_dir,
3892                            CONFIG_HIN       => $ins[0],
3893                            CONFIG_H_DEPS    => "@ins",
3894                            CONFIG_H_PATH    => $config_h_path,
3895                            STAMP            => "$stamp");
3896
3897           push @distclean_config, $cn_sans_dir, $stamp;
3898         }
3899     }
3900
3901   $output_rules .= file_contents ('clean-hdr',
3902                                   new Automake::Location,
3903                                   FILES => "@distclean_config")
3904     if @distclean_config;
3905
3906   # Distribute and define mkinstalldirs only if it is already present
3907   # in the package, for backward compatibility (some people may still
3908   # use $(mkinstalldirs)).
3909   my $mkidpath = "$config_aux_dir/mkinstalldirs";
3910   if (-f $mkidpath)
3911     {
3912       # Use require_file so that any existing script gets updated
3913       # by --force-missing.
3914       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
3915       define_variable ('mkinstalldirs',
3916                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
3917     }
3918   else
3919     {
3920       # Use $(install_sh), not $(mkdir_p) because the latter requires
3921       # at least one argument, and $(mkinstalldirs) used to work
3922       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
3923       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
3924     }
3925
3926   reject_var ('CONFIG_HEADER',
3927               "`CONFIG_HEADER' is an anachronism; now determined "
3928               . "automatically\nfrom `$configure_ac'");
3929
3930   my @config_h;
3931   foreach my $spec (@config_headers)
3932     {
3933       my ($out, @ins) = split_config_file_spec ($spec);
3934       # Generate CONFIG_HEADER define.
3935       if ($relative_dir eq dirname ($out))
3936         {
3937           push @config_h, basename ($out);
3938         }
3939       else
3940         {
3941           push @config_h, "\$(top_builddir)/$out";
3942         }
3943     }
3944   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
3945     if @config_h;
3946
3947   # Now look for other files in this directory which must be remade
3948   # by config.status, and generate rules for them.
3949   my @actual_other_files = ();
3950   foreach my $lfile (@other_input_files)
3951     {
3952       my $file;
3953       my @inputs;
3954       if ($lfile =~ /^([^:]*):(.*)$/)
3955         {
3956           # This is the ":" syntax of AC_OUTPUT.
3957           $file = $1;
3958           @inputs = split (':', $2);
3959         }
3960       else
3961         {
3962           # Normal usage.
3963           $file = $lfile;
3964           @inputs = $file . '.in';
3965         }
3966
3967       # Automake files should not be stored in here, but in %MAKE_LIST.
3968       prog_error ("$lfile in \@other_input_files\n"
3969                   . "\@other_input_files = (@other_input_files)")
3970         if -f $file . '.am';
3971
3972       my $local = basename ($file);
3973
3974       # Make sure the dist directory for each input file is created.
3975       # We only have to do this at the topmost level though.  This
3976       # is a bit ugly but it easier than spreading out the logic,
3977       # especially in cases like AC_OUTPUT(foo/out:bar/in), where
3978       # there is no Makefile in bar/.
3979       if ($relative_dir eq '.')
3980         {
3981           foreach (@inputs)
3982             {
3983               $dist_dirs{dirname ($_)} = 1;
3984             }
3985         }
3986
3987       # We skip files that aren't in this directory.  However, if
3988       # the file's directory does not have a Makefile, and we are
3989       # currently doing `.', then we create a rule to rebuild the
3990       # file in the subdir.
3991       my $fd = dirname ($file);
3992       if ($fd ne $relative_dir)
3993         {
3994           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
3995             {
3996               $local = $file;
3997             }
3998           else
3999             {
4000               next;
4001             }
4002         }
4003
4004       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4005
4006       $output_rules .= ($local . ': '
4007                         . '$(top_builddir)/config.status '
4008                         . "@rewritten_inputs\n"
4009                         . "\t"
4010                         . 'cd $(top_builddir) && '
4011                         . '$(SHELL) ./config.status '
4012                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4013                         . '$@'
4014                         . "\n");
4015       push (@actual_other_files, $local);
4016     }
4017
4018   # For links we should clean destinations and distribute sources.
4019   foreach my $spec (@config_links)
4020     {
4021       my ($link, $file) = split /:/, $spec;
4022       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4023       # the DEST:SRC form.
4024       next unless $file;
4025       my $where = $ac_config_files_location{$link};
4026
4027       # Skip destinations that contain shell variables.
4028       if ($link !~ /\$/)
4029         {
4030           # We skip links that aren't in this directory.  However, if
4031           # the link's directory does not have a Makefile, and we are
4032           # currently doing `.', then we add the link to CONFIG_CLEAN_FILES
4033           # in `.'s Makefile.in.
4034           my $local = basename ($link);
4035           my $fd = dirname ($link);
4036           if ($fd ne $relative_dir)
4037             {
4038               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4039                 {
4040                   $local = $link;
4041                 }
4042               else
4043                 {
4044                   $local = undef;
4045                 }
4046             }
4047           push @actual_other_files, $local if $local;
4048         }
4049
4050       # Do not process sources that contain shell variables.
4051       if ($file !~ /\$/)
4052         {
4053           my $fd = dirname ($file);
4054
4055           # Make sure the dist directory for each input file is created.
4056           # We only have to do this at the topmost level though.
4057           if ($relative_dir eq '.')
4058             {
4059               $dist_dirs{$fd} = 1;
4060             }
4061
4062           # We distribute files that are in this directory.
4063           # At the top-level (`.') we also distribute files whose
4064           # directory does not have a Makefile.
4065           if (($fd eq $relative_dir)
4066               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4067             {
4068               # The following will distribute $file as a side-effect when
4069               # it is appropriate (i.e., when $file is not already an output).
4070               # We do not need the result, just the side-effect.
4071               rewrite_inputs_into_dependencies ($link, $file);
4072             }
4073         }
4074     }
4075
4076   # These files get removed by "make distclean".
4077   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4078                           @actual_other_files);
4079 }
4080
4081 # Handle C headers.
4082 sub handle_headers
4083 {
4084     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4085                              'oldinclude', 'pkginclude',
4086                              'noinst', 'check');
4087     foreach (@r)
4088     {
4089       next unless $_->[1] =~ /\..*$/;
4090       &saw_extension ($&);
4091     }
4092 }
4093
4094 sub handle_gettext
4095 {
4096   return if ! $seen_gettext || $relative_dir ne '.';
4097
4098   my $subdirs = var 'SUBDIRS';
4099
4100   if (! $subdirs)
4101     {
4102       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4103       return;
4104     }
4105
4106   # Perform some sanity checks to help users get the right setup.
4107   # We disable these tests when po/ doesn't exist in order not to disallow
4108   # unusual gettext setups.
4109   #
4110   # Bruno Haible:
4111   # | The idea is:
4112   # |
4113   # |  1) If a package doesn't have a directory po/ at top level, it
4114   # |     will likely have multiple po/ directories in subpackages.
4115   # |
4116   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4117   # |     is used without 'external'. It is also useful to warn for the
4118   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4119   # |     warnings apply only to the usual layout of packages, therefore
4120   # |     they should both be disabled if no po/ directory is found at
4121   # |     top level.
4122
4123   if (-d 'po')
4124     {
4125       my @subdirs = $subdirs->value_as_list_recursive;
4126
4127       msg_var ('syntax', $subdirs,
4128                "AM_GNU_GETTEXT used but `po' not in SUBDIRS")
4129         if ! grep ($_ eq 'po', @subdirs);
4130
4131       # intl/ is not required when AM_GNU_GETTEXT is called with
4132       # the `external' option.
4133       msg_var ('syntax', $subdirs,
4134                "AM_GNU_GETTEXT used but `intl' not in SUBDIRS")
4135         if (! $seen_gettext_external
4136             && ! grep ($_ eq 'intl', @subdirs));
4137
4138       # intl/ should not be used with AM_GNU_GETTEXT([external])
4139       msg_var ('syntax', $subdirs,
4140                "`intl' should not be in SUBDIRS when "
4141                . "AM_GNU_GETTEXT([external]) is used")
4142         if ($seen_gettext_external && grep ($_ eq 'intl', @subdirs));
4143     }
4144
4145   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4146 }
4147
4148 # Handle footer elements.
4149 sub handle_footer
4150 {
4151     # NOTE don't use define_pretty_variable here, because
4152     # $contents{...} is already defined.
4153     $output_vars .= 'SOURCES = ' . variable_value ('SOURCES') . "\n\n"
4154       if variable_value ('SOURCES');
4155
4156     reject_rule ('.SUFFIXES',
4157                  "use variable `SUFFIXES', not target `.SUFFIXES'");
4158
4159     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4160     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4161     # anything else, by sticking it right after the default: target.
4162     $output_header .= ".SUFFIXES:\n";
4163     my $suffixes = var 'SUFFIXES';
4164     my @suffixes = Automake::Rule::suffixes;
4165     if (@suffixes || $suffixes)
4166     {
4167         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4168         # the output remains consistent.  However, $(SUFFIXES) is
4169         # always at the start of the list, unsorted.  This is done
4170         # because make will choose rules depending on the ordering of
4171         # suffixes, and this lets the user have some control.  Push
4172         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4173         # do not like variable substitutions on the .SUFFIXES line.
4174         my @user_suffixes = ($suffixes
4175                              ? $suffixes->value_as_list_recursive : ());
4176
4177         my %suffixes = map { $_ => 1 } @suffixes;
4178         delete @suffixes{@user_suffixes};
4179
4180         $output_header .= (".SUFFIXES: "
4181                            . join (' ', @user_suffixes, sort keys %suffixes)
4182                            . "\n");
4183     }
4184
4185     $output_trailer .= file_contents ('footer', new Automake::Location);
4186 }
4187
4188
4189 # Generate `make install' rules.
4190 sub handle_install ()
4191 {
4192   $output_rules .= &file_contents
4193     ('install',
4194      new Automake::Location,
4195      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4196                              ? (" \$(BUILT_SOURCES)\n"
4197                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4198                              : ''),
4199      'installdirs-local' => (user_phony_rule 'installdirs-local'
4200                              ? ' installdirs-local' : ''),
4201      am__installdirs => variable_value ('am__installdirs') || '');
4202 }
4203
4204
4205 # Deal with all and all-am.
4206 sub handle_all ($)
4207 {
4208     my ($makefile) = @_;
4209
4210     # Output `all-am'.
4211
4212     # Put this at the beginning for the sake of non-GNU makes.  This
4213     # is still wrong if these makes can run parallel jobs.  But it is
4214     # right enough.
4215     unshift (@all, basename ($makefile));
4216
4217     foreach my $spec (@config_headers)
4218       {
4219         my ($out, @ins) = split_config_file_spec ($spec);
4220         push (@all, basename ($out))
4221           if dirname ($out) eq $relative_dir;
4222       }
4223
4224     # Install `all' hooks.
4225     push (@all, "all-local")
4226       if user_phony_rule "all-local";
4227
4228     &pretty_print_rule ("all-am:", "\t\t", @all);
4229     &depend ('.PHONY', 'all-am', 'all');
4230
4231
4232     # Output `all'.
4233
4234     my @local_headers = ();
4235     push @local_headers, '$(BUILT_SOURCES)'
4236       if var ('BUILT_SOURCES');
4237     foreach my $spec (@config_headers)
4238       {
4239         my ($out, @ins) = split_config_file_spec ($spec);
4240         push @local_headers, basename ($out)
4241           if dirname ($out) eq $relative_dir;
4242       }
4243
4244     if (@local_headers)
4245       {
4246         # We need to make sure config.h is built before we recurse.
4247         # We also want to make sure that built sources are built
4248         # before any ordinary `all' targets are run.  We can't do this
4249         # by changing the order of dependencies to the "all" because
4250         # that breaks when using parallel makes.  Instead we handle
4251         # things explicitly.
4252         $output_all .= ("all: @local_headers"
4253                         . "\n\t"
4254                         . '$(MAKE) $(AM_MAKEFLAGS) '
4255                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4256                         . "\n\n");
4257       }
4258     else
4259       {
4260         $output_all .= "all: " . (var ('SUBDIRS')
4261                                   ? 'all-recursive' : 'all-am') . "\n\n";
4262       }
4263 }
4264
4265
4266 # &do_check_merge_target ()
4267 # -------------------------
4268 # Handle check merge target specially.
4269 sub do_check_merge_target ()
4270 {
4271   # Include user-defined local form of target.
4272   push @check_tests, 'check-local'
4273     if user_phony_rule 'check-local';
4274
4275   # In --cygnus mode, check doesn't depend on all.
4276   if (option 'cygnus')
4277     {
4278       # Just run the local check rules.
4279       pretty_print_rule ('check-am:', "\t\t", @check);
4280     }
4281   else
4282     {
4283       # The check target must depend on the local equivalent of
4284       # `all', to ensure all the primary targets are built.  Then it
4285       # must build the local check rules.
4286       $output_rules .= "check-am: all-am\n";
4287       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4288                          @check)
4289         if @check;
4290     }
4291   pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4292                      @check_tests)
4293     if @check_tests;
4294
4295   depend '.PHONY', 'check', 'check-am';
4296   # Handle recursion.  We have to honor BUILT_SOURCES like for `all:'.
4297   $output_rules .= ("check: "
4298                     . (var ('BUILT_SOURCES')
4299                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4300                        : '')
4301                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4302                     . "\n");
4303 }
4304
4305 # handle_clean ($MAKEFILE)
4306 # ------------------------
4307 # Handle all 'clean' targets.
4308 sub handle_clean ($)
4309 {
4310   my ($makefile) = @_;
4311
4312   # Clean the files listed in user variables if they exist.
4313   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4314     if var ('MOSTLYCLEANFILES');
4315   $clean_files{'$(CLEANFILES)'} = CLEAN
4316     if var ('CLEANFILES');
4317   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4318     if var ('DISTCLEANFILES');
4319   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4320     if var ('MAINTAINERCLEANFILES');
4321
4322   # Built sources are automatically removed by maintainer-clean.
4323   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4324     if var ('BUILT_SOURCES');
4325
4326   # Compute a list of "rm"s to run for each target.
4327   my %rms = (MOSTLY_CLEAN, [],
4328              CLEAN, [],
4329              DIST_CLEAN, [],
4330              MAINTAINER_CLEAN, []);
4331
4332   foreach my $file (keys %clean_files)
4333     {
4334       my $when = $clean_files{$file};
4335       prog_error 'invalid entry in %clean_files'
4336         unless exists $rms{$when};
4337
4338       my $rm = "rm -f $file";
4339       # If file is a variable, make sure when don't call `rm -f' without args.
4340       $rm ="test -z \"$file\" || $rm"
4341         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4342
4343       push @{$rms{$when}}, "\t-$rm\n";
4344     }
4345
4346   $output_rules .= &file_contents
4347     ('clean',
4348      new Automake::Location,
4349      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4350      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4351      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4352      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4353      MAKEFILE             => basename $makefile,
4354      );
4355 }
4356
4357
4358 # &target_cmp ($A, $B)
4359 # --------------------
4360 # Subroutine for &handle_factored_dependencies to let `.PHONY' be last.
4361 sub target_cmp
4362 {
4363     return 0
4364         if $a eq $b;
4365     return -1
4366         if $b eq '.PHONY';
4367     return 1
4368         if $a eq '.PHONY';
4369     return $a cmp $b;
4370 }
4371
4372
4373 # &handle_factored_dependencies ()
4374 # --------------------------------
4375 # Handle everything related to gathered targets.
4376 sub handle_factored_dependencies
4377 {
4378   # Reject bad hooks.
4379   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4380                      'uninstall-exec-local', 'uninstall-exec-hook')
4381     {
4382       my $x = $utarg;
4383       $x =~ s/(data|exec)-//;
4384       reject_rule ($utarg, "use `$x', not `$utarg'");
4385     }
4386
4387   reject_rule ('install-local',
4388                "use `install-data-local' or `install-exec-local', "
4389                . "not `install-local'");
4390
4391   reject_rule ('install-info-local',
4392                "`install-info-local' target defined but "
4393                . "`no-installinfo' option not in use")
4394     unless option 'no-installinfo';
4395
4396   # Install the -local hooks.
4397   foreach (keys %dependencies)
4398     {
4399       # Hooks are installed on the -am targets.
4400       s/-am$// or next;
4401       depend ("$_-am", "$_-local")
4402         if user_phony_rule "$_-local";
4403     }
4404
4405   # Install the -hook hooks.
4406   # FIXME: Why not be as liberal as we are with -local hooks?
4407   foreach ('install-exec', 'install-data', 'uninstall')
4408     {
4409       if (user_phony_rule "$_-hook")
4410         {
4411           $actions{"$_-am"} .=
4412             ("\t\@\$(NORMAL_INSTALL)\n"
4413              . "\t" . '$(MAKE) $(AM_MAKEFLAGS) ' . "$_-hook\n");
4414         }
4415     }
4416
4417   # All the required targets are phony.
4418   depend ('.PHONY', keys %required_targets);
4419
4420   # Actually output gathered targets.
4421   foreach (sort target_cmp keys %dependencies)
4422     {
4423       # If there is nothing about this guy, skip it.
4424       next
4425         unless (@{$dependencies{$_}}
4426                 || $actions{$_}
4427                 || $required_targets{$_});
4428
4429       # Define gathered targets in undefined conditions.
4430       # FIXME: Right now we must handle .PHONY as an exception,
4431       # because people write things like
4432       #    .PHONY: myphonytarget
4433       # to append dependencies.  This would not work if Automake
4434       # refrained from defining its own .PHONY target as it does
4435       # with other overridden targets.
4436       my @undefined_conds = (TRUE,);
4437       if ($_ ne '.PHONY')
4438         {
4439           @undefined_conds =
4440             Automake::Rule::define ($_, 'internal',
4441                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4442         }
4443       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4444       foreach my $cond (@undefined_conds)
4445         {
4446           my $condstr = $cond->subst_string;
4447           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4448           $output_rules .= $actions{$_} if defined $actions{$_};
4449           $output_rules .= "\n";
4450         }
4451     }
4452 }
4453
4454
4455 # &handle_tests_dejagnu ()
4456 # ------------------------
4457 sub handle_tests_dejagnu
4458 {
4459     push (@check_tests, 'check-DEJAGNU');
4460     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4461 }
4462
4463
4464 # Handle TESTS variable and other checks.
4465 sub handle_tests
4466 {
4467   if (option 'dejagnu')
4468     {
4469       &handle_tests_dejagnu;
4470     }
4471   else
4472     {
4473       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4474         {
4475           reject_var ($c, "`$c' defined but `dejagnu' not in "
4476                       . "`AUTOMAKE_OPTIONS'");
4477         }
4478     }
4479
4480   if (var ('TESTS'))
4481     {
4482       push (@check_tests, 'check-TESTS');
4483       $output_rules .= &file_contents ('check', new Automake::Location);
4484     }
4485 }
4486
4487 # Handle Emacs Lisp.
4488 sub handle_emacs_lisp
4489 {
4490   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4491                                  'lisp', 'noinst');
4492
4493   return if ! @elfiles;
4494
4495   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4496                           map { $_->[1] } @elfiles);
4497   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
4498                           '$(am__ELFILES:.el=.elc)');
4499   # This one can be overridden by users.
4500   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
4501
4502   push @all, '$(ELCFILES)';
4503
4504   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
4505                      'EMACS', 'lispdir');
4506   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
4507   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
4508 }
4509
4510 # Handle Python
4511 sub handle_python
4512 {
4513   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
4514                                  'noinst');
4515   return if ! @pyfiles;
4516
4517   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
4518   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
4519   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
4520 }
4521
4522 # Handle Java.
4523 sub handle_java
4524 {
4525     my @sourcelist = &am_install_var ('-candist',
4526                                       'java', 'JAVA',
4527                                       'java', 'noinst', 'check');
4528     return if ! @sourcelist;
4529
4530     my @prefix = am_primary_prefixes ('JAVA', 1,
4531                                       'java', 'noinst', 'check');
4532
4533     my $dir;
4534     foreach my $curs (@prefix)
4535       {
4536         next
4537           if $curs eq 'EXTRA';
4538
4539         err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
4540           if defined $dir;
4541         $dir = $curs;
4542       }
4543
4544
4545     push (@all, 'class' . $dir . '.stamp');
4546 }
4547
4548
4549 # Handle some of the minor options.
4550 sub handle_minor_options
4551 {
4552   if (option 'readme-alpha')
4553     {
4554       if ($relative_dir eq '.')
4555         {
4556           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
4557             {
4558               msg ('error-gnits', $package_version_location,
4559                    "version `$package_version' doesn't follow " .
4560                    "Gnits standards");
4561             }
4562           if (defined $1 && -f 'README-alpha')
4563             {
4564               # This means we have an alpha release.  See
4565               # GNITS_VERSION_PATTERN for details.
4566               push_dist_common ('README-alpha');
4567             }
4568         }
4569     }
4570 }
4571
4572 ################################################################
4573
4574 # ($OUTPUT, @INPUTS)
4575 # &split_config_file_spec ($SPEC)
4576 # -------------------------------
4577 # Decode the Autoconf syntax for config files (files, headers, links
4578 # etc.).
4579 sub split_config_file_spec ($)
4580 {
4581   my ($spec) = @_;
4582   my ($output, @inputs) = split (/:/, $spec);
4583
4584   push @inputs, "$output.in"
4585     unless @inputs;
4586
4587   return ($output, @inputs);
4588 }
4589
4590 # $input
4591 # locate_am (@POSSIBLE_SOURCES)
4592 # -----------------------------
4593 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
4594 # This functions returns the first *.in file for which a *.am exists.
4595 # It returns undef otherwise.
4596 sub locate_am (@)
4597 {
4598   my (@rest) = @_;
4599   my $input;
4600   foreach my $file (@rest)
4601     {
4602       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
4603         {
4604           $input = $file;
4605           last;
4606         }
4607     }
4608   return $input;
4609 }
4610
4611 my %make_list;
4612
4613 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
4614 # ---------------------------------------------------
4615 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
4616 # (or AC_OUTPUT).
4617 sub scan_autoconf_config_files ($$)
4618 {
4619   my ($where, $config_files) = @_;
4620
4621   # Look at potential Makefile.am's.
4622   foreach (split ' ', $config_files)
4623     {
4624       # Must skip empty string for Perl 4.
4625       next if $_ eq "\\" || $_ eq '';
4626
4627       # Handle $local:$input syntax.
4628       my ($local, @rest) = split (/:/);
4629       @rest = ("$local.in",) unless @rest;
4630       my $input = locate_am @rest;
4631       if ($input)
4632         {
4633           # We have a file that automake should generate.
4634           $make_list{$input} = join (':', ($local, @rest));
4635         }
4636       else
4637         {
4638           # We have a file that automake should cause to be
4639           # rebuilt, but shouldn't generate itself.
4640           push (@other_input_files, $_);
4641         }
4642       $ac_config_files_location{$local} = $where;
4643     }
4644 }
4645
4646
4647 # &scan_autoconf_traces ($FILENAME)
4648 # ---------------------------------
4649 sub scan_autoconf_traces ($)
4650 {
4651   my ($filename) = @_;
4652
4653   # Macros to trace, with their minimal number of arguments.
4654   #
4655   # IMPORTANT: If you add a macro here, you should also add this macro
4656   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
4657   my %traced = (
4658                 AC_CANONICAL_BUILD => 0,
4659                 AC_CANONICAL_HOST => 0,
4660                 AC_CANONICAL_TARGET => 0,
4661                 AC_CONFIG_AUX_DIR => 1,
4662                 AC_CONFIG_FILES => 1,
4663                 AC_CONFIG_HEADERS => 1,
4664                 AC_CONFIG_LINKS => 1,
4665                 AC_INIT => 0,
4666                 AC_LIBSOURCE => 1,
4667                 AC_REQUIRE_AUX_FILE => 1,
4668                 AC_SUBST => 1,
4669                 AM_AUTOMAKE_VERSION => 1,
4670                 AM_CONDITIONAL => 2,
4671                 AM_ENABLE_MULTILIB => 0,
4672                 AM_GNU_GETTEXT => 0,
4673                 AM_INIT_AUTOMAKE => 0,
4674                 AM_MAINTAINER_MODE => 0,
4675                 AM_PROG_CC_C_O => 0,
4676                 LT_SUPPORTED_TAG => 1,
4677                 _LT_AC_TAGCONFIG => 0,
4678                 m4_include => 1,
4679                 m4_sinclude => 1,
4680                 sinclude => 1,
4681               );
4682
4683   my $traces = ($ENV{AUTOCONF} || 'autoconf') . " ";
4684
4685   # Use a separator unlikely to be used, not `:', the default, which
4686   # has a precise meaning for AC_CONFIG_FILES and so on.
4687   $traces .= join (' ',
4688                    map { "--trace=$_" . ':\$f:\$l::\$n::\${::}%' }
4689                    (keys %traced));
4690
4691   my $tracefh = new Automake::XFile ("$traces $filename |");
4692   verb "reading $traces";
4693
4694   while ($_ = $tracefh->getline)
4695     {
4696       chomp;
4697       my ($here, @args) = split (/::/);
4698       my $where = new Automake::Location $here;
4699       my $macro = $args[0];
4700
4701       prog_error ("unrequested trace `$macro'")
4702         unless exists $traced{$macro};
4703
4704       # Skip and diagnose malformed calls.
4705       if ($#args < $traced{$macro})
4706         {
4707           msg ('syntax', $where, "not enough arguments for $macro");
4708           next;
4709         }
4710
4711       # Alphabetical ordering please.
4712       if ($macro eq 'AC_CANONICAL_BUILD')
4713         {
4714           if ($seen_canonical <= AC_CANONICAL_BUILD)
4715             {
4716               $seen_canonical = AC_CANONICAL_BUILD;
4717               $canonical_location = $where;
4718             }
4719         }
4720       elsif ($macro eq 'AC_CANONICAL_HOST')
4721         {
4722           if ($seen_canonical <= AC_CANONICAL_HOST)
4723             {
4724               $seen_canonical = AC_CANONICAL_HOST;
4725               $canonical_location = $where;
4726             }
4727         }
4728       elsif ($macro eq 'AC_CANONICAL_TARGET')
4729         {
4730           $seen_canonical = AC_CANONICAL_TARGET;
4731           $canonical_location = $where;
4732         }
4733       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
4734         {
4735           if ($seen_init_automake)
4736             {
4737               error ($where, "AC_CONFIG_AUX_DIR must be called before "
4738                      . "AM_INIT_AUTOMAKE...", partial => 1);
4739               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
4740             }
4741           $config_aux_dir = $args[1];
4742           $config_aux_dir_set_in_configure_ac = 1;
4743           $relative_dir = '.';
4744           check_directory ($config_aux_dir, $where);
4745         }
4746       elsif ($macro eq 'AC_CONFIG_FILES')
4747         {
4748           # Look at potential Makefile.am's.
4749           scan_autoconf_config_files ($where, $args[1]);
4750         }
4751       elsif ($macro eq 'AC_CONFIG_HEADERS')
4752         {
4753           foreach my $spec (split (' ', $args[1]))
4754             {
4755               my ($dest, @src) = split (':', $spec);
4756               $ac_config_files_location{$dest} = $where;
4757               push @config_headers, $spec;
4758             }
4759         }
4760       elsif ($macro eq 'AC_CONFIG_LINKS')
4761         {
4762           foreach my $spec (split (' ', $args[1]))
4763             {
4764               my ($dest, $src) = split (':', $spec);
4765               $ac_config_files_location{$dest} = $where;
4766               push @config_links, $spec;
4767             }
4768         }
4769       elsif ($macro eq 'AC_INIT')
4770         {
4771           if (defined $args[2])
4772             {
4773               $package_version = $args[2];
4774               $package_version_location = $where;
4775             }
4776         }
4777       elsif ($macro eq 'AC_LIBSOURCE')
4778         {
4779           $libsources{$args[1]} = $here;
4780         }
4781       elsif ($macro eq 'AC_SUBST')
4782         {
4783           # Just check for alphanumeric in AC_SUBST.  If you do
4784           # AC_SUBST(5), then too bad.
4785           $configure_vars{$args[1]} = $where
4786             if $args[1] =~ /^\w+$/;
4787         }
4788       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
4789         {
4790           error ($where,
4791                  "version mismatch.  This is Automake $VERSION,\n" .
4792                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
4793                  "comes from Automake $args[1].  You should recreate\n" .
4794                  "aclocal.m4 with aclocal and run automake again.\n",
4795                  # $? = 63 is used to indicate version mismatch to missing.
4796                  exit_code => 63)
4797             if $VERSION ne $args[1];
4798
4799           $seen_automake_version = 1;
4800         }
4801       elsif ($macro eq 'AM_CONDITIONAL')
4802         {
4803           $configure_cond{$args[1]} = $where;
4804         }
4805       elsif ($macro eq 'AM_ENABLE_MULTILIB')
4806         {
4807           $seen_multilib = $where;
4808         }
4809       elsif ($macro eq 'AM_GNU_GETTEXT')
4810         {
4811           $seen_gettext = $where;
4812           $ac_gettext_location = $where;
4813           $seen_gettext_external = grep ($_ eq 'external', @args);
4814         }
4815       elsif ($macro eq 'AM_INIT_AUTOMAKE')
4816         {
4817           $seen_init_automake = $where;
4818           if (defined $args[2])
4819             {
4820               $package_version = $args[2];
4821               $package_version_location = $where;
4822             }
4823           elsif (defined $args[1])
4824             {
4825               exit $exit_code
4826                 if (process_global_option_list ($where,
4827                                                 split (' ', $args[1])));
4828             }
4829         }
4830       elsif ($macro eq 'AM_MAINTAINER_MODE')
4831         {
4832           $seen_maint_mode = $where;
4833         }
4834       elsif ($macro eq 'AM_PROG_CC_C_O')
4835         {
4836           $seen_cc_c_o = $where;
4837         }
4838       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
4839         {
4840           # Only remember the first time a file is required.
4841           $required_aux_file{$args[1]} = $where
4842             unless exists $required_aux_file{$args[1]};
4843         }
4844       elsif ($macro eq 'm4_include'
4845              || $macro eq 'm4_sinclude'
4846              || $macro eq 'sinclude')
4847         {
4848           # Some modified versions of Autoconf don't use
4849           # forzen files.  Consequently it's possible that we see all
4850           # m4_include's performed during Autoconf's startup.
4851           # Obviously we don't want to distribute Autoconf's files
4852           # so we skip absolute filenames here.
4853           push @configure_deps, '$(top_srcdir)/' . $args[1]
4854             unless $here =~ m,^(?:\w:)?[\\/],;
4855           # Keep track of the greatest timestamp.
4856           if (-e $args[1])
4857             {
4858               my $mtime = mtime $args[1];
4859               $configure_deps_greatest_timestamp = $mtime
4860                 if $mtime > $configure_deps_greatest_timestamp;
4861             }
4862         }
4863       elsif ($macro eq 'LT_SUPPORTED_TAG')
4864         {
4865           $libtool_tags{$args[1]} = 1;
4866           $libtool_new_api = 1;
4867         }
4868       elsif ($macro eq '_LT_AC_TAGCONFIG')
4869         {
4870           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
4871           # We use it to detect whether tags are supported.  Our
4872           # prefered interface is LT_SUPPORTED_TAG, but it was
4873           # introduced in Libtool 1.6.
4874           if (0 == keys %libtool_tags)
4875             {
4876               # Hardcode the tags supported by Libtool 1.5.
4877               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
4878             }
4879         }
4880     }
4881
4882   $tracefh->close;
4883 }
4884
4885
4886 # &scan_autoconf_files ()
4887 # -----------------------
4888 # Check whether we use `configure.ac' or `configure.in'.
4889 # Scan it (and possibly `aclocal.m4') for interesting things.
4890 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
4891 sub scan_autoconf_files ()
4892 {
4893   # Reinitialize libsources here.  This isn't really necessary,
4894   # since we currently assume there is only one configure.ac.  But
4895   # that won't always be the case.
4896   %libsources = ();
4897
4898   # Keep track of the youngest configure dependency.
4899   $configure_deps_greatest_timestamp = mtime $configure_ac;
4900   if (-e 'aclocal.m4')
4901     {
4902       my $mtime = mtime 'aclocal.m4';
4903       $configure_deps_greatest_timestamp = $mtime
4904         if $mtime > $configure_deps_greatest_timestamp;
4905     }
4906
4907   scan_autoconf_traces ($configure_ac);
4908
4909   @configure_input_files = sort keys %make_list;
4910   # Set input and output files if not specified by user.
4911   if (! @input_files)
4912     {
4913       @input_files = @configure_input_files;
4914       %output_files = %make_list;
4915     }
4916
4917
4918   if (! $seen_init_automake)
4919     {
4920       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
4921               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
4922               . "\nthat aclocal.m4 is present in the top-level directory,\n"
4923               . "and that aclocal.m4 was recently regenerated "
4924               . "(using aclocal).");
4925     }
4926   else
4927     {
4928       if (! $seen_automake_version)
4929         {
4930           if (-f 'aclocal.m4')
4931             {
4932               error ($seen_init_automake,
4933                      "your implementation of AM_INIT_AUTOMAKE comes from " .
4934                      "an\nold Automake version.  You should recreate " .
4935                      "aclocal.m4\nwith aclocal and run automake again.\n",
4936                      # $? = 63 is used to indicate version mismatch to missing.
4937                      exit_code => 63);
4938             }
4939           else
4940             {
4941               error ($seen_init_automake,
4942                      "no proper implementation of AM_INIT_AUTOMAKE was " .
4943                      "found,\nprobably because aclocal.m4 is missing...\n" .
4944                      "You should run aclocal to create this file, then\n" .
4945                      "run automake again.\n");
4946             }
4947         }
4948     }
4949
4950   locate_aux_dir ();
4951
4952   # Reorder @input_files so that the Makefile that distributes aux
4953   # files is processed last.  This is important because each directory
4954   # can require auxiliary scripts and we should wait until they have
4955   # been installed before distributing them.
4956
4957   # The Makefile.in that distribute the aux files is the one in
4958   # $config_aux_dir or the top-level Makefile.
4959   my $auxdirdist = is_make_dir ($config_aux_dir) ? $config_aux_dir : '.';
4960   my @new_input_files = ();
4961   while (@input_files)
4962     {
4963       my $in = pop @input_files;
4964       my @ins = split (/:/, $output_files{$in});
4965       if (dirname ($ins[0]) eq $auxdirdist)
4966         {
4967           push @new_input_files, $in;
4968           $automake_will_process_aux_dir = 1;
4969         }
4970       else
4971         {
4972           unshift @new_input_files, $in;
4973         }
4974     }
4975   @input_files = @new_input_files;
4976
4977   # If neither the auxdir/Makefile nor the ./Makefile are generated
4978   # by Automake, we won't distribute the aux files anyway.  Assume
4979   # the user know what (s)he does, and pretend we will distribute
4980   # them to disable the error in require_file_internal.
4981   $automake_will_process_aux_dir = 1 if ! is_make_dir ($auxdirdist);
4982
4983   # Look for some files we need.  Always check for these.  This
4984   # check must be done for every run, even those where we are only
4985   # looking at a subdir Makefile.  We must set relative_dir for
4986   # maybe_push_required_file to work.
4987   $relative_dir = '.';
4988   foreach my $file (keys %required_aux_file)
4989     {
4990       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
4991     }
4992   err_am "`install.sh' is an anachronism; use `install-sh' instead"
4993     if -f $config_aux_dir . '/install.sh';
4994
4995   # Preserve dist_common for later.
4996   $configure_dist_common = variable_value ('DIST_COMMON') || '';
4997
4998 }
4999
5000 ################################################################
5001
5002 # Set up for Cygnus mode.
5003 sub check_cygnus
5004 {
5005   my $cygnus = option 'cygnus';
5006   return unless $cygnus;
5007
5008   set_strictness ('foreign');
5009   set_option ('no-installinfo', $cygnus);
5010   set_option ('no-dependencies', $cygnus);
5011   set_option ('no-dist', $cygnus);
5012
5013   err_ac "`AM_MAINTAINER_MODE' required when --cygnus specified"
5014     if !$seen_maint_mode;
5015 }
5016
5017 # Do any extra checking for GNU standards.
5018 sub check_gnu_standards
5019 {
5020   if ($relative_dir eq '.')
5021     {
5022       # In top level (or only) directory.
5023       require_file ("$am_file.am", GNU,
5024                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5025
5026       # Accept one of these three licenses; default to COPYING.
5027       # Make sure we do not overwrite an existing license.
5028       my $license;
5029       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5030         {
5031           if (-f $_)
5032             {
5033               $license = $_;
5034               last;
5035             }
5036         }
5037       require_file ("$am_file.am", GNU, 'COPYING')
5038         unless $license;
5039     }
5040
5041   for my $opt ('no-installman', 'no-installinfo')
5042     {
5043       msg ('error-gnu', option $opt,
5044            "option `$opt' disallowed by GNU standards")
5045         if option $opt;
5046     }
5047 }
5048
5049 # Do any extra checking for GNITS standards.
5050 sub check_gnits_standards
5051 {
5052   if ($relative_dir eq '.')
5053     {
5054       # In top level (or only) directory.
5055       require_file ("$am_file.am", GNITS, 'THANKS');
5056     }
5057 }
5058
5059 ################################################################
5060 #
5061 # Functions to handle files of each language.
5062
5063 # Each `lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5064 # simple formula: Return value is LANG_SUBDIR if the resulting object
5065 # file should be in a subdir if the source file is, LANG_PROCESS if
5066 # file is to be dealt with, LANG_IGNORE otherwise.
5067
5068 # Much of the actual processing is handled in
5069 # handle_single_transform.  These functions exist so that
5070 # auxiliary information can be recorded for a later cleanup pass.
5071 # Note that the calls to these functions are computed, so don't bother
5072 # searching for their precise names in the source.
5073
5074 # This is just a convenience function that can be used to determine
5075 # when a subdir object should be used.
5076 sub lang_sub_obj
5077 {
5078     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5079 }
5080
5081 # Rewrite a single C source file.
5082 sub lang_c_rewrite
5083 {
5084   my ($directory, $base, $ext, $nonansi_obj, $have_per_exec_flags, $var) = @_;
5085
5086   if (option 'ansi2knr' && $base =~ /_$/)
5087     {
5088       # FIXME: include line number in error.
5089       err_am "C source file `$base.c' would be deleted by ansi2knr rules";
5090     }
5091
5092   my $r = LANG_PROCESS;
5093   if (option 'subdir-objects')
5094     {
5095       $r = LANG_SUBDIR;
5096       if ($directory && $directory ne '.')
5097         {
5098           $base = $directory . '/' . $base;
5099
5100           # libtool is always able to put the object at the proper place,
5101           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5102           err_var ($var, "compiling `$base.c' in subdir requires "
5103                    . "`AM_PROG_CC_C_O' in `$configure_ac'",
5104                    uniq_scope => US_GLOBAL,
5105                    uniq_part => 'AM_PROG_CC_C_O subdir')
5106             unless $seen_cc_c_o || $nonansi_obj eq '.lo';
5107         }
5108
5109       # In this case we already have the directory information, so
5110       # don't add it again.
5111       $de_ansi_files{$base} = '';
5112     }
5113   else
5114     {
5115       $de_ansi_files{$base} = (($directory eq '.' || $directory eq '')
5116                                ? ''
5117                                : "$directory/");
5118     }
5119
5120   if (! $seen_cc_c_o
5121       && $have_per_exec_flags
5122       && ! option 'subdir-objects'
5123       && $nonansi_obj ne '.lo')
5124     {
5125       err_var ($var, "compiling `$base.c' with per-target flags requires "
5126                . "`AM_PROG_CC_C_O' in `$configure_ac'",
5127                uniq_scope => US_GLOBAL,
5128                uniq_part => 'AM_PROG_CC_C_O per-target')
5129     }
5130
5131     return $r;
5132 }
5133
5134 # Rewrite a single C++ source file.
5135 sub lang_cxx_rewrite
5136 {
5137     return &lang_sub_obj;
5138 }
5139
5140 # Rewrite a single header file.
5141 sub lang_header_rewrite
5142 {
5143     # Header files are simply ignored.
5144     return LANG_IGNORE;
5145 }
5146
5147 # Rewrite a single yacc file.
5148 sub lang_yacc_rewrite
5149 {
5150     my ($directory, $base, $ext) = @_;
5151
5152     my $r = &lang_sub_obj;
5153     (my $newext = $ext) =~ tr/y/c/;
5154     return ($r, $newext);
5155 }
5156
5157 # Rewrite a single yacc++ file.
5158 sub lang_yaccxx_rewrite
5159 {
5160     my ($directory, $base, $ext) = @_;
5161
5162     my $r = &lang_sub_obj;
5163     (my $newext = $ext) =~ tr/y/c/;
5164     return ($r, $newext);
5165 }
5166
5167 # Rewrite a single lex file.
5168 sub lang_lex_rewrite
5169 {
5170     my ($directory, $base, $ext) = @_;
5171
5172     my $r = &lang_sub_obj;
5173     (my $newext = $ext) =~ tr/l/c/;
5174     return ($r, $newext);
5175 }
5176
5177 # Rewrite a single lex++ file.
5178 sub lang_lexxx_rewrite
5179 {
5180     my ($directory, $base, $ext) = @_;
5181
5182     my $r = &lang_sub_obj;
5183     (my $newext = $ext) =~ tr/l/c/;
5184     return ($r, $newext);
5185 }
5186
5187 # Rewrite a single assembly file.
5188 sub lang_asm_rewrite
5189 {
5190     return &lang_sub_obj;
5191 }
5192
5193 # Rewrite a single Fortran 77 file.
5194 sub lang_f77_rewrite
5195 {
5196     return LANG_PROCESS;
5197 }
5198
5199 # Rewrite a single Fortran file.
5200 sub lang_fc_rewrite
5201 {
5202     return LANG_PROCESS;
5203 }
5204
5205 # Rewrite a single preprocessed Fortran file.
5206 sub lang_ppfc_rewrite
5207 {
5208     return LANG_PROCESS;
5209 }
5210
5211 # Rewrite a single preprocessed Fortran 77 file.
5212 sub lang_ppf77_rewrite
5213 {
5214     return LANG_PROCESS;
5215 }
5216
5217 # Rewrite a single ratfor file.
5218 sub lang_ratfor_rewrite
5219 {
5220     return LANG_PROCESS;
5221 }
5222
5223 # Rewrite a single Objective C file.
5224 sub lang_objc_rewrite
5225 {
5226     return &lang_sub_obj;
5227 }
5228
5229 # Rewrite a single Java file.
5230 sub lang_java_rewrite
5231 {
5232     return LANG_SUBDIR;
5233 }
5234
5235 # The lang_X_finish functions are called after all source file
5236 # processing is done.  Each should handle defining rules for the
5237 # language, etc.  A finish function is only called if a source file of
5238 # the appropriate type has been seen.
5239
5240 sub lang_c_finish
5241 {
5242     # Push all libobjs files onto de_ansi_files.  We actually only
5243     # push files which exist in the current directory, and which are
5244     # genuine source files.
5245     foreach my $file (keys %libsources)
5246     {
5247         if ($file =~ /^(.*)\.[cly]$/ && -f "$relative_dir/$file")
5248         {
5249             $de_ansi_files{$1} = ''
5250         }
5251     }
5252
5253     if (option 'ansi2knr' && keys %de_ansi_files)
5254     {
5255         # Make all _.c files depend on their corresponding .c files.
5256         my @objects;
5257         foreach my $base (sort keys %de_ansi_files)
5258         {
5259             # Each _.c file must depend on ansi2knr; otherwise it
5260             # might be used in a parallel build before it is built.
5261             # We need to support files in the srcdir and in the build
5262             # dir (because these files might be auto-generated.  But
5263             # we can't use $< -- some makes only define $< during a
5264             # suffix rule.
5265             my $ansfile = $de_ansi_files{$base} . $base . '.c';
5266             $output_rules .= ($base . "_.c: $ansfile \$(ANSI2KNR)\n\t"
5267                               . '$(CPP) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) '
5268                               . '`if test -f $(srcdir)/' . $ansfile
5269                               . '; then echo $(srcdir)/' . $ansfile
5270                               . '; else echo ' . $ansfile . '; fi` '
5271                               . "| sed 's/^# \\([0-9]\\)/#line \\1/' "
5272                               . '| $(ANSI2KNR) > $@'
5273                               # If ansi2knr fails then we shouldn't
5274                               # create the _.c file
5275                               . " || rm -f \$\@\n");
5276             push (@objects, $base . '_.$(OBJEXT)');
5277             push (@objects, $base . '_.lo')
5278               if var ('LIBTOOL');
5279
5280             # Explicitly clean the _.c files if they are in a
5281             # subdirectory. (In the current directory they get erased
5282             # by a `rm -f *_.c' rule.)
5283             $clean_files{$base . '_.c'} = MOSTLY_CLEAN
5284               if dirname ($base) ne '.';
5285         }
5286
5287         # Make all _.o (and _.lo) files depend on ansi2knr.
5288         # Use a sneaky little hack to make it print nicely.
5289         &pretty_print_rule ('', '', @objects, ':', '$(ANSI2KNR)');
5290     }
5291 }
5292
5293 # This is a yacc helper which is called whenever we have decided to
5294 # compile a yacc file.
5295 sub lang_yacc_target_hook
5296 {
5297     my ($self, $aggregate, $output, $input, %transform) = @_;
5298
5299     my $flag = $aggregate . "_YFLAGS";
5300     my $flagvar = var $flag;
5301     my $YFLAGSvar = var 'YFLAGS';
5302     if (($flagvar && $flagvar->variable_value =~ /$DASH_D_PATTERN/o)
5303         || ($YFLAGSvar && $YFLAGSvar->variable_value =~ /$DASH_D_PATTERN/o))
5304     {
5305         (my $output_base = $output) =~ s/$KNOWN_EXTENSIONS_PATTERN$//;
5306         my $header = $output_base . '.h';
5307
5308         # Found a `-d' that applies to the compilation of this file.
5309         # Add a dependency for the generated header file, and arrange
5310         # for that file to be included in the distribution.
5311         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5312                                                   RULE_AUTOMAKE, TRUE,
5313                                                   INTERNAL))
5314           {
5315             my $condstr = $cond->subst_string;
5316             $output_rules .= ("$condstr${header}: $output\n"
5317                               # Recover from removal of $header
5318                               . "$condstr\t\@if test ! -f \$@; then \\\n"
5319                               . "$condstr\t  rm -f $output; \\\n"
5320                               . "$condstr\t  \$(MAKE) $output; \\\n"
5321                               . "$condstr\telse :; fi\n");
5322           }
5323         # Distribute the generated file, unless its .y source was
5324         # listed in a nodist_ variable.  (&handle_source_transform
5325         # will set DIST_SOURCE.)
5326         &push_dist_common ($header)
5327           if $transform{'DIST_SOURCE'};
5328
5329         # If the files are built in the build directory, then we want
5330         # to remove them with `make clean'.  If they are in srcdir
5331         # they shouldn't be touched.  However, we can't determine this
5332         # statically, and the GNU rules say that yacc/lex output files
5333         # should be removed by maintainer-clean.  So that's what we
5334         # do.
5335         $clean_files{$header} = MAINTAINER_CLEAN;
5336     }
5337     # Erase $OUTPUT on `make maintainer-clean' (by GNU standards).
5338     # See the comment above for $HEADER.
5339     $clean_files{$output} = MAINTAINER_CLEAN;
5340 }
5341
5342 # This is a lex helper which is called whenever we have decided to
5343 # compile a lex file.
5344 sub lang_lex_target_hook
5345 {
5346     my ($self, $aggregate, $output, $input) = @_;
5347     # If the files are built in the build directory, then we want to
5348     # remove them with `make clean'.  If they are in srcdir they
5349     # shouldn't be touched.  However, we can't determine this
5350     # statically, and the GNU rules say that yacc/lex output files
5351     # should be removed by maintainer-clean.  So that's what we do.
5352     $clean_files{$output} = MAINTAINER_CLEAN;
5353 }
5354
5355 # This is a helper for both lex and yacc.
5356 sub yacc_lex_finish_helper
5357 {
5358   return if defined $language_scratch{'lex-yacc-done'};
5359   $language_scratch{'lex-yacc-done'} = 1;
5360
5361   # If there is more than one distinct yacc (resp lex) source file
5362   # in a given directory, then the `ylwrap' program is required to
5363   # allow parallel builds to work correctly.  FIXME: for now, no
5364   # line number.
5365   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
5366   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
5367 }
5368
5369 sub lang_yacc_finish
5370 {
5371   return if defined $language_scratch{'yacc-done'};
5372   $language_scratch{'yacc-done'} = 1;
5373
5374   reject_var 'YACCFLAGS', "`YACCFLAGS' obsolete; use `YFLAGS' instead";
5375
5376   &yacc_lex_finish_helper
5377     if count_files_for_language ('yacc') > 1;
5378 }
5379
5380
5381 sub lang_lex_finish
5382 {
5383   return if defined $language_scratch{'lex-done'};
5384   $language_scratch{'lex-done'} = 1;
5385
5386   &yacc_lex_finish_helper
5387     if count_files_for_language ('lex') > 1;
5388 }
5389
5390
5391 # Given a hash table of linker names, pick the name that has the most
5392 # precedence.  This is lame, but something has to have global
5393 # knowledge in order to eliminate the conflict.  Add more linkers as
5394 # required.
5395 sub resolve_linker
5396 {
5397     my (%linkers) = @_;
5398
5399     foreach my $l (qw(GCJLINK CXXLINK F77LINK FCLINK OBJCLINK))
5400     {
5401         return $l if defined $linkers{$l};
5402     }
5403     return 'LINK';
5404 }
5405
5406 # Called to indicate that an extension was used.
5407 sub saw_extension
5408 {
5409     my ($ext) = @_;
5410     if (! defined $extension_seen{$ext})
5411     {
5412         $extension_seen{$ext} = 1;
5413     }
5414     else
5415     {
5416         ++$extension_seen{$ext};
5417     }
5418 }
5419
5420 # Return the number of files seen for a given language.  Knows about
5421 # special cases we care about.  FIXME: this is hideous.  We need
5422 # something that involves real language objects.  For instance yacc
5423 # and yaccxx could both derive from a common yacc class which would
5424 # know about the strange ylwrap requirement.  (Or better yet we could
5425 # just not support legacy yacc!)
5426 sub count_files_for_language
5427 {
5428     my ($name) = @_;
5429
5430     my @names;
5431     if ($name eq 'yacc' || $name eq 'yaccxx')
5432     {
5433         @names = ('yacc', 'yaccxx');
5434     }
5435     elsif ($name eq 'lex' || $name eq 'lexxx')
5436     {
5437         @names = ('lex', 'lexxx');
5438     }
5439     else
5440     {
5441         @names = ($name);
5442     }
5443
5444     my $r = 0;
5445     foreach $name (@names)
5446     {
5447         my $lang = $languages{$name};
5448         foreach my $ext (@{$lang->extensions})
5449         {
5450             $r += $extension_seen{$ext}
5451                 if defined $extension_seen{$ext};
5452         }
5453     }
5454
5455     return $r
5456 }
5457
5458 # Called to ask whether source files have been seen . If HEADERS is 1,
5459 # headers can be included.
5460 sub saw_sources_p
5461 {
5462     my ($headers) = @_;
5463
5464     # count all the sources
5465     my $count = 0;
5466     foreach my $val (values %extension_seen)
5467     {
5468         $count += $val;
5469     }
5470
5471     if (!$headers)
5472     {
5473         $count -= count_files_for_language ('header');
5474     }
5475
5476     return $count > 0;
5477 }
5478
5479
5480 # register_language (%ATTRIBUTE)
5481 # ------------------------------
5482 # Register a single language.
5483 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
5484 sub register_language (%)
5485 {
5486   my (%option) = @_;
5487
5488   # Set the defaults.
5489   $option{'ansi'} = 0
5490     unless defined $option{'ansi'};
5491   $option{'autodep'} = 'no'
5492     unless defined $option{'autodep'};
5493   $option{'linker'} = ''
5494     unless defined $option{'linker'};
5495   $option{'flags'} = []
5496     unless defined $option{'flags'};
5497   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
5498     unless defined $option{'output_extensions'};
5499   $option{'nodist_specific'} = 0
5500     unless defined $option{'nodist_specific'};
5501
5502   my $lang = new Language (%option);
5503
5504   # Fill indexes.
5505   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
5506   $languages{$lang->name} = $lang;
5507
5508   # Update the pattern of known extensions.
5509   accept_extensions (@{$lang->extensions});
5510
5511   # Upate the $suffix_rule map.
5512   foreach my $suffix (@{$lang->extensions})
5513     {
5514       foreach my $dest (&{$lang->output_extensions} ($suffix))
5515         {
5516           register_suffix_rule (INTERNAL, $suffix, $dest);
5517         }
5518     }
5519 }
5520
5521 # derive_suffix ($EXT, $OBJ)
5522 # --------------------------
5523 # This function is used to find a path from a user-specified suffix $EXT
5524 # to $OBJ or to some other suffix we recognize internally, e.g. `cc'.
5525 sub derive_suffix ($$)
5526 {
5527   my ($source_ext, $obj) = @_;
5528
5529   while (! $extension_map{$source_ext}
5530          && $source_ext ne $obj
5531          && exists $suffix_rules->{$source_ext}
5532          && exists $suffix_rules->{$source_ext}{$obj})
5533     {
5534       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
5535     }
5536
5537   return $source_ext;
5538 }
5539
5540
5541 ################################################################
5542
5543 # Pretty-print something and append to output_rules.
5544 sub pretty_print_rule
5545 {
5546     $output_rules .= &makefile_wrap (@_);
5547 }
5548
5549
5550 ################################################################
5551
5552
5553 ## -------------------------------- ##
5554 ## Handling the conditional stack.  ##
5555 ## -------------------------------- ##
5556
5557
5558 # $STRING
5559 # make_conditional_string ($NEGATE, $COND)
5560 # ----------------------------------------
5561 sub make_conditional_string ($$)
5562 {
5563   my ($negate, $cond) = @_;
5564   $cond = "${cond}_TRUE"
5565     unless $cond =~ /^TRUE|FALSE$/;
5566   $cond = Automake::Condition::conditional_negate ($cond)
5567     if $negate;
5568   return $cond;
5569 }
5570
5571
5572 # $COND
5573 # cond_stack_if ($NEGATE, $COND, $WHERE)
5574 # --------------------------------------
5575 sub cond_stack_if ($$$)
5576 {
5577   my ($negate, $cond, $where) = @_;
5578
5579   error $where, "$cond does not appear in AM_CONDITIONAL"
5580     if ! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/;
5581
5582   push (@cond_stack, make_conditional_string ($negate, $cond));
5583
5584   return new Automake::Condition (@cond_stack);
5585 }
5586
5587
5588 # $COND
5589 # cond_stack_else ($NEGATE, $COND, $WHERE)
5590 # ----------------------------------------
5591 sub cond_stack_else ($$$)
5592 {
5593   my ($negate, $cond, $where) = @_;
5594
5595   if (! @cond_stack)
5596     {
5597       error $where, "else without if";
5598       return FALSE;
5599     }
5600
5601   $cond_stack[$#cond_stack] =
5602     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
5603
5604   # If $COND is given, check against it.
5605   if (defined $cond)
5606     {
5607       $cond = make_conditional_string ($negate, $cond);
5608
5609       error ($where, "else reminder ($negate$cond) incompatible with "
5610              . "current conditional: $cond_stack[$#cond_stack]")
5611         if $cond_stack[$#cond_stack] ne $cond;
5612     }
5613
5614   return new Automake::Condition (@cond_stack);
5615 }
5616
5617
5618 # $COND
5619 # cond_stack_endif ($NEGATE, $COND, $WHERE)
5620 # -----------------------------------------
5621 sub cond_stack_endif ($$$)
5622 {
5623   my ($negate, $cond, $where) = @_;
5624   my $old_cond;
5625
5626   if (! @cond_stack)
5627     {
5628       error $where, "endif without if";
5629       return TRUE;
5630     }
5631
5632   # If $COND is given, check against it.
5633   if (defined $cond)
5634     {
5635       $cond = make_conditional_string ($negate, $cond);
5636
5637       error ($where, "endif reminder ($negate$cond) incompatible with "
5638              . "current conditional: $cond_stack[$#cond_stack]")
5639         if $cond_stack[$#cond_stack] ne $cond;
5640     }
5641
5642   pop @cond_stack;
5643
5644   return new Automake::Condition (@cond_stack);
5645 }
5646
5647
5648
5649
5650
5651 ## ------------------------ ##
5652 ## Handling the variables.  ##
5653 ## ------------------------ ##
5654
5655
5656 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
5657 # -----------------------------------------------------
5658 # Like define_variable, but the value is a list, and the variable may
5659 # be defined conditionally.  The second argument is the Condition
5660 # under which the value should be defined; this should be the empty
5661 # string to define the variable unconditionally.  The third argument
5662 # is a list holding the values to use for the variable.  The value is
5663 # pretty printed in the output file.
5664 sub define_pretty_variable ($$$@)
5665 {
5666     my ($var, $cond, $where, @value) = @_;
5667
5668     if (! vardef ($var, $cond))
5669     {
5670         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
5671                                     '', $where, VAR_PRETTY);
5672         rvar ($var)->rdef ($cond)->set_seen;
5673     }
5674 }
5675
5676
5677 # define_variable ($VAR, $VALUE, $WHERE)
5678 # --------------------------------------
5679 # Define a new user variable VAR to VALUE, but only if not already defined.
5680 sub define_variable ($$$)
5681 {
5682     my ($var, $value, $where) = @_;
5683     define_pretty_variable ($var, TRUE, $where, $value);
5684 }
5685
5686
5687 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
5688 # -----------------------------------------------------------
5689 # Define the $VAR which content is the list of file names composed of
5690 # a @BASENAME and the $EXTENSION.
5691 sub define_files_variable ($\@$$)
5692 {
5693   my ($var, $basename, $extension, $where) = @_;
5694   define_variable ($var,
5695                    join (' ', map { "$_.$extension" } @$basename),
5696                    $where);
5697 }
5698
5699
5700 # Like define_variable, but define a variable to be the configure
5701 # substitution by the same name.
5702 sub define_configure_variable ($)
5703 {
5704   my ($var) = @_;
5705
5706   my $pretty = VAR_ASIS;
5707   my $owner = VAR_CONFIGURE;
5708
5709   # Do not output the ANSI2KNR configure variable -- we AC_SUBST
5710   # it in protos.m4, but later redefine it elsewhere.  This is
5711   # pretty hacky.  We also don't output AMDEPBACKSLASH: it might
5712   # be subst'd by `\', which certainly would not be appreciated by
5713   # Make.
5714   if ($var eq 'ANSI2KNR' || $var eq 'AMDEPBACKSLASH')
5715     {
5716       $pretty = VAR_SILENT;
5717       $owner = VAR_AUTOMAKE;
5718     }
5719
5720   Automake::Variable::define ($var, $owner, '', TRUE, subst $var,
5721                               '', $configure_vars{$var}, $pretty);
5722 }
5723
5724
5725 # define_compiler_variable ($LANG)
5726 # --------------------------------
5727 # Define a compiler variable.  We also handle defining the `LT'
5728 # version of the command when using libtool.
5729 sub define_compiler_variable ($)
5730 {
5731     my ($lang) = @_;
5732
5733     my ($var, $value) = ($lang->compiler, $lang->compile);
5734     my $libtool_tag = '';
5735     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5736       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5737     &define_variable ($var, $value, INTERNAL);
5738     &define_variable ("LT$var",
5739                       "\$(LIBTOOL) --mode=compile $libtool_tag$value",
5740                       INTERNAL)
5741       if var ('LIBTOOL');
5742 }
5743
5744
5745 # define_linker_variable ($LANG)
5746 # ------------------------------
5747 # Define linker variables.
5748 sub define_linker_variable ($)
5749 {
5750     my ($lang) = @_;
5751
5752     my ($var, $value) = ($lang->lder, $lang->ld);
5753     my $libtool_tag = '';
5754     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5755       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5756     # CCLD = $(CC).
5757     &define_variable ($lang->lder, $lang->ld, INTERNAL);
5758     # CCLINK = $(CCLD) blah blah...
5759     &define_variable ($lang->linker,
5760                       ((var ('LIBTOOL') ?
5761                         '$(LIBTOOL) --mode=link ' . $libtool_tag  : '')
5762                        . $lang->link),
5763                       INTERNAL);
5764 }
5765
5766 ################################################################
5767
5768 # &check_trailing_slash ($WHERE, $LINE)
5769 # --------------------------------------
5770 # Return 1 iff $LINE ends with a slash.
5771 # Might modify $LINE.
5772 sub check_trailing_slash ($\$)
5773 {
5774   my ($where, $line) = @_;
5775
5776   # Ignore `##' lines.
5777   return 0 if $$line =~ /$IGNORE_PATTERN/o;
5778
5779   # Catch and fix a common error.
5780   msg "syntax", $where, "whitespace following trailing backslash"
5781     if $$line =~ s/\\\s+\n$/\\\n/;
5782
5783   return $$line =~ /\\$/;
5784 }
5785
5786
5787 # &read_am_file ($AMFILE, $WHERE)
5788 # -------------------------------
5789 # Read Makefile.am and set up %contents.  Simultaneously copy lines
5790 # from Makefile.am into $output_trailer, or define variables as
5791 # appropriate.  NOTE we put rules in the trailer section.  We want
5792 # user rules to come after our generated stuff.
5793 sub read_am_file ($$)
5794 {
5795     my ($amfile, $where) = @_;
5796
5797     my $am_file = new Automake::XFile ("< $amfile");
5798     verb "reading $amfile";
5799
5800     # Keep track of the youngest output dependency.
5801     my $mtime = mtime $amfile;
5802     $output_deps_greatest_timestamp = $mtime
5803       if $mtime > $output_deps_greatest_timestamp;
5804
5805     my $spacing = '';
5806     my $comment = '';
5807     my $blank = 0;
5808     my $saw_bk = 0;
5809
5810     use constant IN_VAR_DEF => 0;
5811     use constant IN_RULE_DEF => 1;
5812     use constant IN_COMMENT => 2;
5813     my $prev_state = IN_RULE_DEF;
5814
5815     while ($_ = $am_file->getline)
5816     {
5817         $where->set ("$amfile:$.");
5818         if (/$IGNORE_PATTERN/o)
5819         {
5820             # Merely delete comments beginning with two hashes.
5821         }
5822         elsif (/$WHITE_PATTERN/o)
5823         {
5824             error $where, "blank line following trailing backslash"
5825               if $saw_bk;
5826             # Stick a single white line before the incoming macro or rule.
5827             $spacing = "\n";
5828             $blank = 1;
5829             # Flush all comments seen so far.
5830             if ($comment ne '')
5831             {
5832                 $output_vars .= $comment;
5833                 $comment = '';
5834             }
5835         }
5836         elsif (/$COMMENT_PATTERN/o)
5837         {
5838             # Stick comments before the incoming macro or rule.  Make
5839             # sure a blank line precedes the first block of comments.
5840             $spacing = "\n" unless $blank;
5841             $blank = 1;
5842             $comment .= $spacing . $_;
5843             $spacing = '';
5844             $prev_state = IN_COMMENT;
5845         }
5846         else
5847         {
5848             last;
5849         }
5850         $saw_bk = check_trailing_slash ($where, $_);
5851     }
5852
5853     # We save the conditional stack on entry, and then check to make
5854     # sure it is the same on exit.  This lets us conditionally include
5855     # other files.
5856     my @saved_cond_stack = @cond_stack;
5857     my $cond = new Automake::Condition (@cond_stack);
5858
5859     my $last_var_name = '';
5860     my $last_var_type = '';
5861     my $last_var_value = '';
5862     my $last_where;
5863     # FIXME: shouldn't use $_ in this loop; it is too big.
5864     while ($_)
5865     {
5866         $where->set ("$amfile:$.");
5867
5868         # Make sure the line is \n-terminated.
5869         chomp;
5870         $_ .= "\n";
5871
5872         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
5873         # used by users.  @MAINT@ is an anachronism now.
5874         $_ =~ s/\@MAINT\@//g
5875             unless $seen_maint_mode;
5876
5877         my $new_saw_bk = check_trailing_slash ($where, $_);
5878
5879         if (/$IGNORE_PATTERN/o)
5880         {
5881             # Merely delete comments beginning with two hashes.
5882         }
5883         elsif (/$WHITE_PATTERN/o)
5884         {
5885             # Stick a single white line before the incoming macro or rule.
5886             $spacing = "\n";
5887             error $where, "blank line following trailing backslash"
5888               if $saw_bk;
5889         }
5890         elsif (/$COMMENT_PATTERN/o)
5891         {
5892             # Stick comments before the incoming macro or rule.
5893             $comment .= $spacing . $_;
5894             $spacing = '';
5895             error $where, "comment following trailing backslash"
5896               if $saw_bk && $comment eq '';
5897             $prev_state = IN_COMMENT;
5898         }
5899         elsif ($saw_bk)
5900         {
5901             if ($prev_state == IN_RULE_DEF)
5902             {
5903               my $cond = new Automake::Condition @cond_stack;
5904               $output_trailer .= $cond->subst_string;
5905               $output_trailer .= $_;
5906             }
5907             elsif ($prev_state == IN_COMMENT)
5908             {
5909                 # If the line doesn't start with a `#', add it.
5910                 # We do this because a continued comment like
5911                 #   # A = foo \
5912                 #         bar \
5913                 #         baz
5914                 # is not portable.  BSD make doesn't honor
5915                 # escaped newlines in comments.
5916                 s/^#?/#/;
5917                 $comment .= $spacing . $_;
5918             }
5919             else # $prev_state == IN_VAR_DEF
5920             {
5921               $last_var_value .= ' '
5922                 unless $last_var_value =~ /\s$/;
5923               $last_var_value .= $_;
5924
5925               if (!/\\$/)
5926                 {
5927                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
5928                                               $last_var_type, $cond,
5929                                               $last_var_value, $comment,
5930                                               $last_where, VAR_ASIS)
5931                     if $cond != FALSE;
5932                   $comment = $spacing = '';
5933                 }
5934             }
5935         }
5936
5937         elsif (/$IF_PATTERN/o)
5938           {
5939             $cond = cond_stack_if ($1, $2, $where);
5940           }
5941         elsif (/$ELSE_PATTERN/o)
5942           {
5943             $cond = cond_stack_else ($1, $2, $where);
5944           }
5945         elsif (/$ENDIF_PATTERN/o)
5946           {
5947             $cond = cond_stack_endif ($1, $2, $where);
5948           }
5949
5950         elsif (/$RULE_PATTERN/o)
5951         {
5952             # Found a rule.
5953             $prev_state = IN_RULE_DEF;
5954
5955             # For now we have to output all definitions of user rules
5956             # and can't diagnose duplicates (see the comment in
5957             # rule_define). So we go on and ignore the return value.
5958             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
5959
5960             check_variable_expansions ($_, $where);
5961
5962             $output_trailer .= $comment . $spacing;
5963             my $cond = new Automake::Condition @cond_stack;
5964             $output_trailer .= $cond->subst_string;
5965             $output_trailer .= $_;
5966             $comment = $spacing = '';
5967         }
5968         elsif (/$ASSIGNMENT_PATTERN/o)
5969         {
5970             # Found a macro definition.
5971             $prev_state = IN_VAR_DEF;
5972             $last_var_name = $1;
5973             $last_var_type = $2;
5974             $last_var_value = $3;
5975             $last_where = $where->clone;
5976             if ($3 ne '' && substr ($3, -1) eq "\\")
5977             {
5978                 # We preserve the `\' because otherwise the long lines
5979                 # that are generated will be truncated by broken
5980                 # `sed's.
5981                 $last_var_value = $3 . "\n";
5982             }
5983
5984             if (!/\\$/)
5985               {
5986                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
5987                                             $last_var_type, $cond,
5988                                             $last_var_value, $comment,
5989                                             $last_where, VAR_ASIS)
5990                   if $cond != FALSE;
5991                 $comment = $spacing = '';
5992               }
5993         }
5994         elsif (/$INCLUDE_PATTERN/o)
5995         {
5996             my $path = $1;
5997
5998             if ($path =~ s/^\$\(top_srcdir\)\///)
5999               {
6000                 push (@include_stack, "\$\(top_srcdir\)/$path");
6001                 # Distribute any included file.
6002
6003                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6004                 # otherwise OSF make will implicitly copy the included
6005                 # file in the build tree during `make distdir' to satisfy
6006                 # the dependency.
6007                 # (subdircond2.test and subdircond3.test will fail.)
6008                 push_dist_common ("\$\(top_srcdir\)/$path");
6009               }
6010             else
6011               {
6012                 $path =~ s/\$\(srcdir\)\///;
6013                 push (@include_stack, "\$\(srcdir\)/$path");
6014                 # Always use the $(srcdir) prefix in DIST_COMMON,
6015                 # otherwise OSF make will implicitly copy the included
6016                 # file in the build tree during `make distdir' to satisfy
6017                 # the dependency.
6018                 # (subdircond2.test and subdircond3.test will fail.)
6019                 push_dist_common ("\$\(srcdir\)/$path");
6020                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6021               }
6022             $where->push_context ("`$path' included from here");
6023             &read_am_file ($path, $where);
6024             $where->pop_context;
6025         }
6026         else
6027         {
6028             # This isn't an error; it is probably a continued rule.
6029             # In fact, this is what we assume.
6030             $prev_state = IN_RULE_DEF;
6031             check_variable_expansions ($_, $where);
6032             $output_trailer .= $comment . $spacing;
6033             my $cond = new Automake::Condition @cond_stack;
6034             $output_trailer .= $cond->subst_string;
6035             $output_trailer .= $_;
6036             $comment = $spacing = '';
6037             error $where, "`#' comment at start of rule is unportable"
6038               if $_ =~ /^\t\s*\#/;
6039         }
6040
6041         $saw_bk = $new_saw_bk;
6042         $_ = $am_file->getline;
6043     }
6044
6045     $output_trailer .= $comment;
6046
6047     error ($where, "trailing backslash on last line")
6048       if $saw_bk;
6049
6050     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6051                     : "too many conditionals closed in include file"))
6052       if "@saved_cond_stack" ne "@cond_stack";
6053 }
6054
6055
6056 # define_standard_variables ()
6057 # ----------------------------
6058 # A helper for read_main_am_file which initializes configure variables
6059 # and variables from header-vars.am.
6060 sub define_standard_variables
6061 {
6062   my $saved_output_vars = $output_vars;
6063   my ($comments, undef, $rules) =
6064     file_contents_internal (1, "$libdir/am/header-vars.am",
6065                             new Automake::Location);
6066
6067   foreach my $var (sort keys %configure_vars)
6068     {
6069       &define_configure_variable ($var);
6070     }
6071
6072   $output_vars .= $comments . $rules;
6073 }
6074
6075 # Read main am file.
6076 sub read_main_am_file
6077 {
6078     my ($amfile) = @_;
6079
6080     # This supports the strange variable tricks we are about to play.
6081     prog_error (macros_dump () . "variable defined before read_main_am_file")
6082       if (scalar (variables) > 0);
6083
6084     # Generate copyright header for generated Makefile.in.
6085     # We do discard the output of predefined variables, handled below.
6086     $output_vars = ("# $in_file_name generated by automake "
6087                    . $VERSION . " from $am_file_name.\n");
6088     $output_vars .= '# ' . subst ('configure_input') . "\n";
6089     $output_vars .= $gen_copyright;
6090
6091     # We want to predefine as many variables as possible.  This lets
6092     # the user set them with `+=' in Makefile.am.
6093     &define_standard_variables;
6094
6095     # Read user file, which might override some of our values.
6096     &read_am_file ($amfile, new Automake::Location);
6097 }
6098
6099
6100
6101 ################################################################
6102
6103 # $FLATTENED
6104 # &flatten ($STRING)
6105 # ------------------
6106 # Flatten the $STRING and return the result.
6107 sub flatten
6108 {
6109   $_ = shift;
6110
6111   s/\\\n//somg;
6112   s/\s+/ /g;
6113   s/^ //;
6114   s/ $//;
6115
6116   return $_;
6117 }
6118
6119 # transform($TOKEN, \%PAIRS)
6120 # ==========================
6121 # If ($TOKEN, $VAL) is in %PAIRS:
6122 #   - replaces %$TOKEN% with $VAL,
6123 #   - enables/disables ?$TOKEN? and ?!$TOKEN?,
6124 #   - replaces %?$TOKEN% with TRUE or FALSE.
6125 sub transform($$)
6126 {
6127   my ($token, $transform) = @_;
6128
6129   if (substr ($token, 0, 1) eq '%')
6130     {
6131       my $cond = (substr ($token, 1, 1) eq '?') ? 1 : 0;
6132       $token = substr ($token, 1 + $cond, -1);
6133       my $val = $transform->{$token};
6134       prog_error "Unknown %token% `$token'" unless defined $val;
6135       if ($cond)
6136         {
6137           return $val ? 'TRUE' : 'FALSE';
6138         }
6139       else
6140         {
6141           return $val;
6142         }
6143     }
6144   # Now $token is '?xxx?' or '?!xxx?'.
6145   my $neg = (substr ($token, 1, 1) eq '!') ? 1 : 0;
6146   $token = substr ($token, 1 + $neg, -1);
6147   my $val = $transform->{$token};
6148   prog_error "Unknown ?token? `$token' (neg = $neg)" unless defined $val;
6149   return (!!$val == $neg) ? '##%' : '';
6150 }
6151
6152 # @PARAGRAPHS
6153 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6154 # ------------------------------------------
6155 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6156 # paragraphs.
6157 sub make_paragraphs ($%)
6158 {
6159   my ($file, %transform) = @_;
6160
6161   # Complete %transform with global options.
6162   # Note that %transform goes last, so it overrides global options.
6163   %transform = ('CYGNUS'      => !! option 'cygnus',
6164                  'MAINTAINER-MODE'
6165                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6166
6167                  'BZIP2'       => !! option 'dist-bzip2',
6168                  'COMPRESS'    => !! option 'dist-tarZ',
6169                  'GZIP'        =>  ! option 'no-dist-gzip',
6170                  'SHAR'        => !! option 'dist-shar',
6171                  'ZIP'         => !! option 'dist-zip',
6172
6173                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6174                  'INSTALL-MAN'  =>  ! option 'no-installman',
6175                  'CK-NEWS'      => !! option 'check-news',
6176
6177                  'SUBDIRS'      => !! var ('SUBDIRS'),
6178                  'TOPDIR'       => backname ($relative_dir),
6179                  'TOPDIR_P'     => $relative_dir eq '.',
6180
6181                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6182                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6183                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6184
6185                  'LIBTOOL'      => !! var ('LIBTOOL'),
6186                  'NONLIBTOOL'   => 1,
6187                  'FIRST'        => ! $transformed_files{$file},
6188                 %transform);
6189
6190   $transformed_files{$file} = 1;
6191   $_ = $am_file_cache{$file};
6192
6193   if (! defined $_)
6194     {
6195       verb "reading $file";
6196       # Swallow the whole file.
6197       my $fc_file = new Automake::XFile "< $file";
6198       my $saved_dollar_slash = $/;
6199       undef $/;
6200       $_ = $fc_file->getline;
6201       $/ = $saved_dollar_slash;
6202       $fc_file->close;
6203
6204       # Remove ##-comments.
6205       # Besides we don't need more than two consecutive new-lines.
6206       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6207
6208       $am_file_cache{$file} = $_;
6209     }
6210
6211   # Substitute Automake template tokens.
6212   s/(?:%\??[\w\-]+%|\?!?[\w\-]+\?)/transform($&, \%transform)/ge;
6213   # transform() may have added some ##%-comments to strip.
6214   # (we use `##%' instead of `##' so we can distinguish ##%##%##% from
6215   # ####### and do not remove the latter.)
6216   s/^[ \t]*(?:##%)+.*\n//gm;
6217
6218   # Split at unescaped new lines.
6219   my @lines = split (/(?<!\\)\n/, $_);
6220   my @res;
6221
6222   while (defined ($_ = shift @lines))
6223     {
6224       my $paragraph = $_;
6225       # If we are a rule, eat as long as we start with a tab.
6226       if (/$RULE_PATTERN/smo)
6227         {
6228           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
6229             {
6230               $paragraph .= "\n$_";
6231             }
6232           unshift (@lines, $_);
6233         }
6234
6235       # If we are a comments, eat as much comments as you can.
6236       elsif (/$COMMENT_PATTERN/smo)
6237         {
6238           while (defined ($_ = shift @lines)
6239                  && $_ =~ /$COMMENT_PATTERN/smo)
6240             {
6241               $paragraph .= "\n$_";
6242             }
6243           unshift (@lines, $_);
6244         }
6245
6246       push @res, $paragraph;
6247     }
6248
6249   return @res;
6250 }
6251
6252
6253
6254 # ($COMMENT, $VARIABLES, $RULES)
6255 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
6256 # -------------------------------------------------------------
6257 # Return contents of a file from $libdir/am, automatically skipping
6258 # macros or rules which are already known. $IS_AM iff the caller is
6259 # reading an Automake file (as opposed to the user's Makefile.am).
6260 sub file_contents_internal ($$$%)
6261 {
6262     my ($is_am, $file, $where, %transform) = @_;
6263
6264     $where->set ($file);
6265
6266     my $result_vars = '';
6267     my $result_rules = '';
6268     my $comment = '';
6269     my $spacing = '';
6270
6271     # The following flags are used to track rules spanning across
6272     # multiple paragraphs.
6273     my $is_rule = 0;            # 1 if we are processing a rule.
6274     my $discard_rule = 0;       # 1 if the current rule should not be output.
6275
6276     # We save the conditional stack on entry, and then check to make
6277     # sure it is the same on exit.  This lets us conditionally include
6278     # other files.
6279     my @saved_cond_stack = @cond_stack;
6280     my $cond = new Automake::Condition (@cond_stack);
6281
6282     foreach (make_paragraphs ($file, %transform))
6283     {
6284         # FIXME: no line number available.
6285         $where->set ($file);
6286
6287         # Sanity checks.
6288         error $where, "blank line following trailing backslash:\n$_"
6289           if /\\$/;
6290         error $where, "comment following trailing backslash:\n$_"
6291           if /\\#/;
6292
6293         if (/^$/)
6294         {
6295             $is_rule = 0;
6296             # Stick empty line before the incoming macro or rule.
6297             $spacing = "\n";
6298         }
6299         elsif (/$COMMENT_PATTERN/mso)
6300         {
6301             $is_rule = 0;
6302             # Stick comments before the incoming macro or rule.
6303             $comment = "$_\n";
6304         }
6305
6306         # Handle inclusion of other files.
6307         elsif (/$INCLUDE_PATTERN/o)
6308         {
6309             if ($cond != FALSE)
6310               {
6311                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
6312                 $where->push_context ("`$file' included from here");
6313                 # N-ary `.=' fails.
6314                 my ($com, $vars, $rules)
6315                   = file_contents_internal ($is_am, $file, $where, %transform);
6316                 $where->pop_context;
6317                 $comment .= $com;
6318                 $result_vars .= $vars;
6319                 $result_rules .= $rules;
6320               }
6321         }
6322
6323         # Handling the conditionals.
6324         elsif (/$IF_PATTERN/o)
6325           {
6326             $cond = cond_stack_if ($1, $2, $file);
6327           }
6328         elsif (/$ELSE_PATTERN/o)
6329           {
6330             $cond = cond_stack_else ($1, $2, $file);
6331           }
6332         elsif (/$ENDIF_PATTERN/o)
6333           {
6334             $cond = cond_stack_endif ($1, $2, $file);
6335           }
6336
6337         # Handling rules.
6338         elsif (/$RULE_PATTERN/mso)
6339         {
6340           $is_rule = 1;
6341           $discard_rule = 0;
6342           # Separate relationship from optional actions: the first
6343           # `new-line tab" not preceded by backslash (continuation
6344           # line).
6345           my $paragraph = $_;
6346           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
6347           my ($relationship, $actions) = ($1, $2 || '');
6348
6349           # Separate targets from dependencies: the first colon.
6350           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
6351           my ($targets, $dependencies) = ($1, $2);
6352           # Remove the escaped new lines.
6353           # I don't know why, but I have to use a tmp $flat_deps.
6354           my $flat_deps = &flatten ($dependencies);
6355           my @deps = split (' ', $flat_deps);
6356
6357           foreach (split (' ' , $targets))
6358             {
6359               # FIXME: 1. We are not robust to people defining several targets
6360               # at once, only some of them being in %dependencies.  The
6361               # actions from the targets in %dependencies are usually generated
6362               # from the content of %actions, but if some targets in $targets
6363               # are not in %dependencies the ELSE branch will output
6364               # a rule for all $targets (i.e. the targets which are both
6365               # in %dependencies and $targets will have two rules).
6366
6367               # FIXME: 2. The logic here is not able to output a
6368               # multi-paragraph rule several time (e.g. for each condition
6369               # it is defined for) because it only knows the first paragraph.
6370
6371               # FIXME: 3. We are not robust to people defining a subset
6372               # of a previously defined "multiple-target" rule.  E.g.
6373               # `foo:' after `foo bar:'.
6374
6375               # Output only if not in FALSE.
6376               if (defined $dependencies{$_} && $cond != FALSE)
6377                 {
6378                   &depend ($_, @deps);
6379                   if ($actions{$_})
6380                     {
6381                       $actions{$_} .= "\n$actions" if $actions;
6382                     }
6383                   else
6384                     {
6385                       $actions{$_} = $actions;
6386                     }
6387                 }
6388               else
6389                 {
6390                   # Free-lance dependency.  Output the rule for all the
6391                   # targets instead of one by one.
6392                   my @undefined_conds =
6393                     Automake::Rule::define ($targets, $file,
6394                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
6395                                             $cond, $where);
6396                   for my $undefined_cond (@undefined_conds)
6397                     {
6398                       my $condparagraph = $paragraph;
6399                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
6400                       $result_rules .= "$spacing$comment$condparagraph\n";
6401                     }
6402                   if (scalar @undefined_conds == 0)
6403                     {
6404                       # Remember to discard next paragraphs
6405                       # if they belong to this rule.
6406                       # (but see also FIXME: #2 above.)
6407                       $discard_rule = 1;
6408                     }
6409                   $comment = $spacing = '';
6410                   last;
6411                 }
6412             }
6413         }
6414
6415         elsif (/$ASSIGNMENT_PATTERN/mso)
6416         {
6417             my ($var, $type, $val) = ($1, $2, $3);
6418             error $where, "variable `$var' with trailing backslash"
6419               if /\\$/;
6420
6421             $is_rule = 0;
6422
6423             Automake::Variable::define ($var,
6424                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
6425                                         $type, $cond, $val, $comment, $where,
6426                                         VAR_ASIS)
6427               if $cond != FALSE;
6428
6429             $comment = $spacing = '';
6430         }
6431         else
6432         {
6433             # This isn't an error; it is probably some tokens which
6434             # configure is supposed to replace, such as `@SET-MAKE@',
6435             # or some part of a rule cut by an if/endif.
6436             if (! $cond->false && ! ($is_rule && $discard_rule))
6437               {
6438                 s/^/$cond->subst_string/gme;
6439                 $result_rules .= "$spacing$comment$_\n";
6440               }
6441             $comment = $spacing = '';
6442         }
6443     }
6444
6445     error ($where, @cond_stack ?
6446            "unterminated conditionals: @cond_stack" :
6447            "too many conditionals closed in include file")
6448       if "@saved_cond_stack" ne "@cond_stack";
6449
6450     return ($comment, $result_vars, $result_rules);
6451 }
6452
6453
6454 # $CONTENTS
6455 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
6456 # ------------------------------------------------
6457 # Return contents of a file from $libdir/am, automatically skipping
6458 # macros or rules which are already known.
6459 sub file_contents ($$%)
6460 {
6461     my ($basename, $where, %transform) = @_;
6462     my ($comments, $variables, $rules) =
6463       file_contents_internal (1, "$libdir/am/$basename.am", $where,
6464                               %transform);
6465     return "$comments$variables$rules";
6466 }
6467
6468
6469 # &append_exeext ($MACRO)
6470 # -----------------------
6471 # Macro is an Automake magic macro which primary is PROGRAMS, e.g.
6472 # bin_PROGRAMS.  Make sure these programs have $(EXEEXT) appended.
6473 sub append_exeext ($)
6474 {
6475   my ($macro) = @_;
6476
6477   prog_error "append_exeext ($macro)"
6478     unless $macro =~ /_PROGRAMS$/;
6479
6480   transform_variable_recursively
6481     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
6482      sub {
6483        my ($subvar, $val, $cond, $full_cond) = @_;
6484        # Append $(EXEEXT) unless the user did it already, or it's a
6485        # @substitution@.
6486        $val .= '$(EXEEXT)' unless $val =~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/;
6487        return $val;
6488      });
6489 }
6490
6491
6492 # @PREFIX
6493 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
6494 # -----------------------------------------------------
6495 # Find all variable prefixes that are used for install directories.  A
6496 # prefix `zar' qualifies iff:
6497 #
6498 # * `zardir' is a variable.
6499 # * `zar_PRIMARY' is a variable.
6500 #
6501 # As a side effect, it looks for misspellings.  It is an error to have
6502 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
6503 # "bin_PROGRAMS".  However, unusual prefixes are allowed if a variable
6504 # of the same name (with "dir" appended) exists.  For instance, if the
6505 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
6506 # This is to provide a little extra flexibility in those cases which
6507 # need it.
6508 sub am_primary_prefixes ($$@)
6509 {
6510   my ($primary, $can_dist, @prefixes) = @_;
6511
6512   local $_;
6513   my %valid = map { $_ => 0 } @prefixes;
6514   $valid{'EXTRA'} = 0;
6515   foreach my $var (variables $primary)
6516     {
6517       # Automake is allowed to define variables that look like primaries
6518       # but which aren't.  E.g. INSTALL_sh_DATA.
6519       # Autoconf can also define variables like INSTALL_DATA, so
6520       # ignore all configure variables (at least those which are not
6521       # redefined in Makefile.am).
6522       # FIXME: We should make sure that these variables are not
6523       # conditionally defined (or else adjust the condition below).
6524       my $def = $var->def (TRUE);
6525       next if $def && $def->owner != VAR_MAKEFILE;
6526
6527       my $varname = $var->name;
6528
6529       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
6530         {
6531           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
6532           if ($dist ne '' && ! $can_dist)
6533             {
6534               err_var ($var,
6535                        "invalid variable `$varname': `dist' is forbidden");
6536             }
6537           # Standard directories must be explicitly allowed.
6538           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
6539             {
6540               err_var ($var,
6541                        "`${X}dir' is not a legitimate directory " .
6542                        "for `$primary'");
6543             }
6544           # A not explicitly valid directory is allowed if Xdir is defined.
6545           elsif (! defined $valid{$X} &&
6546                  $var->requires_variables ("`$varname' is used", "${X}dir"))
6547             {
6548               # Nothing to do.  Any error message has been output
6549               # by $var->requires_variables.
6550             }
6551           else
6552             {
6553               # Ensure all extended prefixes are actually used.
6554               $valid{"$base$dist$X"} = 1;
6555             }
6556         }
6557       else
6558         {
6559           prog_error "unexpected variable name: $varname";
6560         }
6561     }
6562
6563   # Return only those which are actually defined.
6564   return sort grep { var ($_ . '_' . $primary) } keys %valid;
6565 }
6566
6567
6568 # Handle `where_HOW' variable magic.  Does all lookups, generates
6569 # install code, and possibly generates code to define the primary
6570 # variable.  The first argument is the name of the .am file to munge,
6571 # the second argument is the primary variable (e.g. HEADERS), and all
6572 # subsequent arguments are possible installation locations.
6573 #
6574 # Returns list of [$location, $value] pairs, where
6575 # $value's are the values in all where_HOW variable, and $location
6576 # there associated location (the place here their parent variables were
6577 # defined).
6578 #
6579 # FIXME: this should be rewritten to be cleaner.  It should be broken
6580 # up into multiple functions.
6581 #
6582 # Usage is: am_install_var (OPTION..., file, HOW, where...)
6583 sub am_install_var
6584 {
6585   my (@args) = @_;
6586
6587   my $do_require = 1;
6588   my $can_dist = 0;
6589   my $default_dist = 0;
6590   while (@args)
6591     {
6592       if ($args[0] eq '-noextra')
6593         {
6594           $do_require = 0;
6595         }
6596       elsif ($args[0] eq '-candist')
6597         {
6598           $can_dist = 1;
6599         }
6600       elsif ($args[0] eq '-defaultdist')
6601         {
6602           $default_dist = 1;
6603           $can_dist = 1;
6604         }
6605       elsif ($args[0] !~ /^-/)
6606         {
6607           last;
6608         }
6609       shift (@args);
6610     }
6611
6612   my ($file, $primary, @prefix) = @args;
6613
6614   # Now that configure substitutions are allowed in where_HOW
6615   # variables, it is an error to actually define the primary.  We
6616   # allow `JAVA', as it is customarily used to mean the Java
6617   # interpreter.  This is but one of several Java hacks.  Similarly,
6618   # `PYTHON' is customarily used to mean the Python interpreter.
6619   reject_var $primary, "`$primary' is an anachronism"
6620     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
6621
6622   # Get the prefixes which are valid and actually used.
6623   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
6624
6625   # If a primary includes a configure substitution, then the EXTRA_
6626   # form is required.  Otherwise we can't properly do our job.
6627   my $require_extra;
6628
6629   my @used = ();
6630   my @result = ();
6631
6632   foreach my $X (@prefix)
6633     {
6634       my $nodir_name = $X;
6635       my $one_name = $X . '_' . $primary;
6636       my $one_var = var $one_name;
6637
6638       my $strip_subdir = 1;
6639       # If subdir prefix should be preserved, do so.
6640       if ($nodir_name =~ /^nobase_/)
6641         {
6642           $strip_subdir = 0;
6643           $nodir_name =~ s/^nobase_//;
6644         }
6645
6646       # If files should be distributed, do so.
6647       my $dist_p = 0;
6648       if ($can_dist)
6649         {
6650           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
6651                      || (! $default_dist && $nodir_name =~ /^dist_/));
6652           $nodir_name =~ s/^(dist|nodist)_//;
6653         }
6654
6655
6656       # Use the location of the currently processed variable.
6657       # We are not processing a particular condition, so pick the first
6658       # available.
6659       my $tmpcond = $one_var->conditions->one_cond;
6660       my $where = $one_var->rdef ($tmpcond)->location->clone;
6661
6662       # Append actual contents of where_PRIMARY variable to
6663       # @result, skipping @substitutions@.
6664       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
6665         {
6666           my ($loc, $value) = @$locvals;
6667           # Skip configure substitutions.
6668           if ($value =~ /^\@.*\@$/)
6669             {
6670               if ($nodir_name eq 'EXTRA')
6671                 {
6672                   error ($where,
6673                          "`$one_name' contains configure substitution, "
6674                          . "but shouldn't");
6675                 }
6676               # Check here to make sure variables defined in
6677               # configure.ac do not imply that EXTRA_PRIMARY
6678               # must be defined.
6679               elsif (! defined $configure_vars{$one_name})
6680                 {
6681                   $require_extra = $one_name
6682                     if $do_require;
6683                 }
6684             }
6685           else
6686             {
6687               push (@result, $locvals);
6688             }
6689         }
6690       # A blatant hack: we rewrite each _PROGRAMS primary to include
6691       # EXEEXT.
6692       append_exeext ($one_name)
6693         if $primary eq 'PROGRAMS';
6694       # "EXTRA" shouldn't be used when generating clean targets,
6695       # all, or install targets.  We used to warn if EXTRA_FOO was
6696       # defined uselessly, but this was annoying.
6697       next
6698         if $nodir_name eq 'EXTRA';
6699
6700       if ($nodir_name eq 'check')
6701         {
6702           push (@check, '$(' . $one_name . ')');
6703         }
6704       else
6705         {
6706           push (@used, '$(' . $one_name . ')');
6707         }
6708
6709       # Is this to be installed?
6710       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
6711
6712       # If so, with install-exec? (or install-data?).
6713       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
6714
6715       my $check_options_p = $install_p && !! option 'std-options';
6716
6717       # Use the location of the currently processed variable as context.
6718       $where->push_context ("while processing `$one_name'");
6719
6720       # The variable containing all file to distribute.
6721       my $distvar = "\$($one_name)";
6722       $distvar = shadow_unconditionally ($one_name, $where)
6723         if ($dist_p && $one_var->has_conditional_contents);
6724
6725       # Singular form of $PRIMARY.
6726       (my $one_primary = $primary) =~ s/S$//;
6727       $output_rules .= &file_contents ($file, $where,
6728                                        PRIMARY     => $primary,
6729                                        ONE_PRIMARY => $one_primary,
6730                                        DIR         => $X,
6731                                        NDIR        => $nodir_name,
6732                                        BASE        => $strip_subdir,
6733
6734                                        EXEC      => $exec_p,
6735                                        INSTALL   => $install_p,
6736                                        DIST      => $dist_p,
6737                                        DISTVAR   => $distvar,
6738                                        'CK-OPTS' => $check_options_p);
6739     }
6740
6741   # The JAVA variable is used as the name of the Java interpreter.
6742   # The PYTHON variable is used as the name of the Python interpreter.
6743   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
6744     {
6745       # Define it.
6746       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
6747       $output_vars .= "\n";
6748     }
6749
6750   err_var ($require_extra,
6751            "`$require_extra' contains configure substitution,\n"
6752            . "but `EXTRA_$primary' not defined")
6753     if ($require_extra && ! var ('EXTRA_' . $primary));
6754
6755   # Push here because PRIMARY might be configure time determined.
6756   push (@all, '$(' . $primary . ')')
6757     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
6758
6759   # Make the result unique.  This lets the user use conditionals in
6760   # a natural way, but still lets us program lazily -- we don't have
6761   # to worry about handling a particular object more than once.
6762   # We will keep only one location per object.
6763   my %result = ();
6764   for my $pair (@result)
6765     {
6766       my ($loc, $val) = @$pair;
6767       $result{$val} = $loc;
6768     }
6769   my @l = sort keys %result;
6770   return map { [$result{$_}->clone, $_] } @l;
6771 }
6772
6773
6774 ################################################################
6775
6776 # Each key in this hash is the name of a directory holding a
6777 # Makefile.in.  These variables are local to `is_make_dir'.
6778 my %make_dirs = ();
6779 my $make_dirs_set = 0;
6780
6781 sub is_make_dir
6782 {
6783     my ($dir) = @_;
6784     if (! $make_dirs_set)
6785     {
6786         foreach my $iter (@configure_input_files)
6787         {
6788             $make_dirs{dirname ($iter)} = 1;
6789         }
6790         # We also want to notice Makefile.in's.
6791         foreach my $iter (@other_input_files)
6792         {
6793             if ($iter =~ /Makefile\.in$/)
6794             {
6795                 $make_dirs{dirname ($iter)} = 1;
6796             }
6797         }
6798         $make_dirs_set = 1;
6799     }
6800     return defined $make_dirs{$dir};
6801 }
6802
6803 ################################################################
6804
6805 # Find the aux dir.  This should match the algorithm used by
6806 # ./configure. (See the Autoconf documentation for for
6807 # AC_CONFIG_AUX_DIR.)
6808 sub locate_aux_dir ()
6809 {
6810   if (! $config_aux_dir_set_in_configure_ac)
6811     {
6812       # The default auxiliary directory is the first
6813       # of ., .., or ../.. that contains install-sh.
6814       # Assume . if install-sh doesn't exist yet.
6815       for my $dir (qw (. .. ../..))
6816         {
6817           if (-f "$dir/install-sh")
6818             {
6819               $config_aux_dir = $dir;
6820               last;
6821             }
6822         }
6823       $config_aux_dir = '.' unless $config_aux_dir;
6824     }
6825   # Avoid unsightly '/.'s.
6826   $am_config_aux_dir =
6827     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
6828   $am_config_aux_dir =~ s,/*$,,;
6829 }
6830
6831
6832 # &maybe_push_required_file ($DIR, $FILE, $FULLFILE)
6833 # --------------------------------------------------
6834 # See if we want to push this file onto dist_common.  This function
6835 # encodes the rules for deciding when to do so.
6836 sub maybe_push_required_file
6837 {
6838   my ($dir, $file, $fullfile) = @_;
6839
6840   if ($dir eq $relative_dir)
6841     {
6842       push_dist_common ($file);
6843       return 1;
6844     }
6845   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
6846     {
6847       # If we are doing the topmost directory, and the file is in a
6848       # subdir which does not have a Makefile, then we distribute it
6849       # here.
6850
6851       # If a required file is above the source tree, it is important
6852       # to prefix it with `$(srcdir)' so that no VPATH search is
6853       # performed.  Otherwise problems occur with Make implementations
6854       # that rewrite and simplify rules whose dependencies are found in a
6855       # VPATH location.  Here is an example with OSF1/Tru64 Make.
6856       #
6857       #   % cat Makefile
6858       #   VPATH = sub
6859       #   distdir: ../a
6860       #           echo ../a
6861       #   % ls
6862       #   Makefile a
6863       #   % make
6864       #   echo a
6865       #   a
6866       #
6867       # Dependency `../a' was found in `sub/../a', but this make
6868       # implementation simplified it as `a'.  (Note that the sub/
6869       # directory does not even exist.)
6870       #
6871       # This kind of VPATH rewriting seems hard to cancel.  The
6872       # distdir.am hack against VPATH rewriting works only when no
6873       # simplification is done, i.e., for dependencies which are in
6874       # subdirectories, not in enclosing directories.  Hence, in
6875       # the latter case we use a full path to make sure no VPATH
6876       # search occurs.
6877       $fullfile = '$(srcdir)/' . $fullfile
6878         if $dir =~ m,^\.\.(?:$|/),;
6879
6880       push_dist_common ($fullfile);
6881       return 1;
6882     }
6883   return 0;
6884 }
6885
6886
6887 # If a file name appears as a key in this hash, then it has already
6888 # been checked for.  This allows us not to report the same error more
6889 # than once.
6890 my %required_file_not_found = ();
6891
6892 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, @FILES)
6893 # --------------------------------------------------------------
6894 # Verify that the file must exist in $DIRECTORY, or install it.
6895 # $MYSTRICT is the strictness level at which this file becomes required.
6896 sub require_file_internal ($$$@)
6897 {
6898   my ($where, $mystrict, $dir, @files) = @_;
6899
6900   foreach my $file (@files)
6901     {
6902       my $fullfile = "$dir/$file";
6903       my $found_it = 0;
6904       my $dangling_sym = 0;
6905
6906       if (-l $fullfile && ! -f $fullfile)
6907         {
6908           $dangling_sym = 1;
6909         }
6910       elsif (-f $fullfile)
6911         {
6912           $found_it = 1;
6913           maybe_push_required_file ($dir, $file, $fullfile);
6914         }
6915
6916       # `--force-missing' only has an effect if `--add-missing' is
6917       # specified.
6918       if ($found_it && (! $add_missing || ! $force_missing))
6919         {
6920           next;
6921         }
6922       else
6923         {
6924           # If we've already looked for it, we're done.  You might
6925           # wonder why we don't do this before searching for the
6926           # file.  If we do that, then something like
6927           # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
6928           # DIST_COMMON.
6929           if (! $found_it)
6930             {
6931               next if defined $required_file_not_found{$fullfile};
6932               $required_file_not_found{$fullfile} = 1;
6933             }
6934
6935           if ($strictness >= $mystrict)
6936             {
6937               if ($dangling_sym && $add_missing)
6938                 {
6939                   unlink ($fullfile);
6940                 }
6941
6942               my $trailer = '';
6943               my $suppress = 0;
6944
6945               # Only install missing files according to our desired
6946               # strictness level.
6947               my $message = "required file `$fullfile' not found";
6948               if ($add_missing)
6949                 {
6950                   if (-f ("$libdir/$file"))
6951                     {
6952                       $suppress = 1;
6953
6954                       # Install the missing file.  Symlink if we
6955                       # can, copy if we must.  Note: delete the file
6956                       # first, in case it is a dangling symlink.
6957                       $message = "installing `$fullfile'";
6958                       # Windows Perl will hang if we try to delete a
6959                       # file that doesn't exist.
6960                       unlink ($fullfile) if -f $fullfile;
6961                       if ($symlink_exists && ! $copy_missing)
6962                         {
6963                           if (! symlink ("$libdir/$file", $fullfile))
6964                             {
6965                               $suppress = 0;
6966                               $trailer = "; error while making link: $!";
6967                             }
6968                         }
6969                       elsif (system ('cp', "$libdir/$file", $fullfile))
6970                         {
6971                           $suppress = 0;
6972                           $trailer = "\n    error while copying";
6973                         }
6974                     }
6975
6976                   if (! maybe_push_required_file (dirname ($fullfile),
6977                                                   $file, $fullfile))
6978                     {
6979                       if (! $found_it && ! $automake_will_process_aux_dir)
6980                         {
6981                           # We have added the file but could not push it
6982                           # into DIST_COMMON, probably because this is
6983                           # an auxiliary file and we are not processing
6984                           # the top level Makefile.  Furthermore Automake
6985                           # hasn't been asked to create the Makefile.in
6986                           # that distribute the aux dir files.
6987                           error ($where, 'Please make a full run of automake'
6988                                  . " so $fullfile gets distributed.");
6989                         }
6990                     }
6991                 }
6992
6993               # If --force-missing was specified, and we have
6994               # actually found the file, then do nothing.
6995               next
6996                 if $found_it && $force_missing;
6997
6998               # If we couldn' install the file, but it is a target in
6999               # the Makefile, don't print anything.  This allows files
7000               # like README, AUTHORS, or THANKS to be generated.
7001               next
7002                 if !$suppress && rule $file;
7003
7004               msg ($suppress ? 'note' : 'error', $where, "$message$trailer");
7005             }
7006         }
7007     }
7008 }
7009
7010 # &require_file ($WHERE, $MYSTRICT, @FILES)
7011 # -----------------------------------------
7012 sub require_file ($$@)
7013 {
7014     my ($where, $mystrict, @files) = @_;
7015     require_file_internal ($where, $mystrict, $relative_dir, @files);
7016 }
7017
7018 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7019 # -----------------------------------------------------------
7020 sub require_file_with_macro ($$$@)
7021 {
7022     my ($cond, $macro, $mystrict, @files) = @_;
7023     $macro = rvar ($macro) unless ref $macro;
7024     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7025 }
7026
7027
7028 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7029 # ----------------------------------------------
7030 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7031 sub require_conf_file ($$@)
7032 {
7033     my ($where, $mystrict, @files) = @_;
7034     require_file_internal ($where, $mystrict, $config_aux_dir, @files);
7035 }
7036
7037
7038 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7039 # ----------------------------------------------------------------
7040 sub require_conf_file_with_macro ($$$@)
7041 {
7042     my ($cond, $macro, $mystrict, @files) = @_;
7043     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7044                        $mystrict, @files);
7045 }
7046
7047 ################################################################
7048
7049 # &require_build_directory ($DIRECTORY)
7050 # ------------------------------------
7051 # Emit rules to create $DIRECTORY if needed, and return
7052 # the file that any target requiring this directory should be made
7053 # dependent upon.
7054 sub require_build_directory ($)
7055 {
7056   my $directory = shift;
7057   my $dirstamp = "$directory/\$(am__dirstamp)";
7058
7059   # Don't emit the rule twice.
7060   if (! defined $directory_map{$directory})
7061     {
7062       $directory_map{$directory} = 1;
7063
7064       # Set a variable for the dirstamp basename.
7065       define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7066                               '$(am__leading_dot)dirstamp');
7067
7068       # Directory must be removed by `make distclean'.
7069       $clean_files{$dirstamp} = DIST_CLEAN;
7070
7071       $output_rules .= ("$dirstamp:\n"
7072                         . "\t\@\$(mkdir_p) $directory\n"
7073                         . "\t\@: > $dirstamp\n");
7074     }
7075
7076   return $dirstamp;
7077 }
7078
7079 # &require_build_directory_maybe ($FILE)
7080 # --------------------------------------
7081 # If $FILE lies in a subdirectory, emit a rule to create this
7082 # directory and return the file that $FILE should be made
7083 # dependent upon.  Otherwise, just return the empty string.
7084 sub require_build_directory_maybe ($)
7085 {
7086     my $file = shift;
7087     my $directory = dirname ($file);
7088
7089     if ($directory ne '.')
7090     {
7091         return require_build_directory ($directory);
7092     }
7093     else
7094     {
7095         return '';
7096     }
7097 }
7098
7099 ################################################################
7100
7101 # Push a list of files onto dist_common.
7102 sub push_dist_common
7103 {
7104   prog_error "push_dist_common run after handle_dist"
7105     if $handle_dist_run;
7106   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
7107                               '', INTERNAL, VAR_PRETTY);
7108 }
7109
7110
7111 ################################################################
7112
7113 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
7114 # ----------------------------------------------
7115 # Generate a Makefile.in given the name of the corresponding Makefile and
7116 # the name of the file output by config.status.
7117 sub generate_makefile ($$)
7118 {
7119   my ($makefile_am, $makefile_in) = @_;
7120
7121   # Reset all the Makefile.am related variables.
7122   initialize_per_input;
7123
7124   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
7125   # warnings for this file.  So hold any warning issued before
7126   # we have processed AUTOMAKE_OPTIONS.
7127   buffer_messages ('warning');
7128
7129   # Name of input file ("Makefile.am") and output file
7130   # ("Makefile.in").  These have no directory components.
7131   $am_file_name = basename ($makefile_am);
7132   $in_file_name = basename ($makefile_in);
7133
7134   # $OUTPUT is encoded.  If it contains a ":" then the first element
7135   # is the real output file, and all remaining elements are input
7136   # files.  We don't scan or otherwise deal with these input files,
7137   # other than to mark them as dependencies.  See
7138   # &scan_autoconf_files for details.
7139   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
7140
7141   $relative_dir = dirname ($makefile);
7142   $am_relative_dir = dirname ($makefile_am);
7143
7144   read_main_am_file ($makefile_am);
7145   if (handle_options)
7146     {
7147       # Process buffered warnings.
7148       flush_messages;
7149       # Fatal error.  Just return, so we can continue with next file.
7150       return;
7151     }
7152   # Process buffered warnings.
7153   flush_messages;
7154
7155   # There are a few install-related variables that you should not define.
7156   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
7157     {
7158       my $v = var $var;
7159       if ($v)
7160         {
7161           my $def = $v->def (TRUE);
7162           prog_error "$var not defined in condition TRUE"
7163             unless $def;
7164           reject_var $var, "`$var' should not be defined"
7165             if $def->owner != VAR_AUTOMAKE;
7166         }
7167     }
7168
7169   # Catch some obsolete variables.
7170   msg_var ('obsolete', 'INCLUDES',
7171            "`INCLUDES' is the old name for `AM_CPPFLAGS' (or `*_CPPFLAGS')")
7172     if var ('INCLUDES');
7173
7174   # Must do this after reading .am file.
7175   define_variable ('subdir', $relative_dir, INTERNAL);
7176
7177   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
7178   # recursive rules are enabled.
7179   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
7180     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
7181
7182   # Check first, because we might modify some state.
7183   check_cygnus;
7184   check_gnu_standards;
7185   check_gnits_standards;
7186
7187   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
7188   handle_gettext;
7189   handle_libraries;
7190   handle_ltlibraries;
7191   handle_programs;
7192   handle_scripts;
7193
7194   # These must be run after all the sources are scanned.  They
7195   # use variables defined by &handle_libraries, &handle_ltlibraries,
7196   # or &handle_programs.
7197   handle_compile;
7198   handle_languages;
7199   handle_libtool;
7200
7201   # Variables used by distdir.am and tags.am.
7202   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
7203   if (! option 'no-dist')
7204     {
7205       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
7206     }
7207
7208   handle_multilib;
7209   handle_texinfo;
7210   handle_emacs_lisp;
7211   handle_python;
7212   handle_java;
7213   handle_man_pages;
7214   handle_data;
7215   handle_headers;
7216   handle_subdirs;
7217   handle_tags;
7218   handle_minor_options;
7219   handle_tests;
7220
7221   # This must come after most other rules.
7222   handle_dist;
7223
7224   handle_footer;
7225   do_check_merge_target;
7226   handle_all ($makefile);
7227
7228   # FIXME: Gross!
7229   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
7230     {
7231       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
7232     }
7233
7234   handle_install;
7235   handle_clean ($makefile);
7236   handle_factored_dependencies;
7237
7238   # Comes last, because all the above procedures may have
7239   # defined or overridden variables.
7240   $output_vars .= output_variables;
7241
7242   check_typos;
7243
7244   my ($out_file) = $output_directory . '/' . $makefile_in;
7245
7246   if ($exit_code != 0)
7247     {
7248       verb "not writing $out_file because of earlier errors";
7249       return;
7250     }
7251
7252   if (! -d ($output_directory . '/' . $am_relative_dir))
7253     {
7254       mkdir ($output_directory . '/' . $am_relative_dir, 0755);
7255     }
7256
7257   # We make sure that `all:' is the first target.
7258   my $output =
7259     "$output_vars$output_all$output_header$output_rules$output_trailer";
7260
7261   # Decide whether we must update the output file or not.
7262   # We have to update in the following situations.
7263   #  * $force_generation is set.
7264   #  * any of the output dependencies is younger than the output
7265   #  * the contents of the output is different (this can happen
7266   #    if the project has been populated with a file listed in
7267   #    @common_files since the last run).
7268   # Output's dependencies are split in two sets:
7269   #  * dependencies which are also configure dependencies
7270   #    These do not change between each Makefile.am
7271   #  * other dependencies, specific to the Makefile.am being processed
7272   #    (such as the Makefile.am itself, or any Makefile fragment
7273   #    it includes).
7274   my $timestamp = mtime $out_file;
7275   if (! $force_generation
7276       && $configure_deps_greatest_timestamp < $timestamp
7277       && $output_deps_greatest_timestamp < $timestamp
7278       && $output eq contents ($out_file))
7279     {
7280       verb "$out_file unchanged";
7281       # No need to update.
7282       return;
7283     }
7284
7285   if (-e $out_file)
7286     {
7287       unlink ($out_file)
7288         or fatal "cannot remove $out_file: $!\n";
7289     }
7290
7291   my $gm_file = new Automake::XFile "> $out_file";
7292   verb "creating $out_file";
7293   print $gm_file $output;
7294 }
7295
7296 ################################################################
7297
7298
7299
7300
7301 ################################################################
7302
7303 # Print usage information.
7304 sub usage ()
7305 {
7306     print "Usage: $0 [OPTION] ... [Makefile]...
7307
7308 Generate Makefile.in for configure from Makefile.am.
7309
7310 Operation modes:
7311       --help               print this help, then exit
7312       --version            print version number, then exit
7313   -v, --verbose            verbosely list files processed
7314       --no-force           only update Makefile.in's that are out of date
7315   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
7316
7317 Dependency tracking:
7318   -i, --ignore-deps      disable dependency tracking code
7319       --include-deps     enable dependency tracking code
7320
7321 Flavors:
7322       --cygnus           assume program is part of Cygnus-style tree
7323       --foreign          set strictness to foreign
7324       --gnits            set strictness to gnits
7325       --gnu              set strictness to gnu
7326
7327 Library files:
7328   -a, --add-missing      add missing standard files to package
7329       --libdir=DIR       directory storing library files
7330   -c, --copy             with -a, copy missing files (default is symlink)
7331   -f, --force-missing    force update of standard files
7332
7333 ";
7334     Automake::ChannelDefs::usage;
7335
7336     my ($last, @lcomm);
7337     $last = '';
7338     foreach my $iter (sort ((@common_files, @common_sometimes)))
7339     {
7340         push (@lcomm, $iter) unless $iter eq $last;
7341         $last = $iter;
7342     }
7343
7344     my @four;
7345     print "\nFiles which are automatically distributed, if found:\n";
7346     format USAGE_FORMAT =
7347   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
7348   $four[0],           $four[1],           $four[2],           $four[3]
7349 .
7350     $~ = "USAGE_FORMAT";
7351
7352     my $cols = 4;
7353     my $rows = int(@lcomm / $cols);
7354     my $rest = @lcomm % $cols;
7355
7356     if ($rest)
7357     {
7358         $rows++;
7359     }
7360     else
7361     {
7362         $rest = $cols;
7363     }
7364
7365     for (my $y = 0; $y < $rows; $y++)
7366     {
7367         @four = ("", "", "", "");
7368         for (my $x = 0; $x < $cols; $x++)
7369         {
7370             last if $y + 1 == $rows && $x == $rest;
7371
7372             my $idx = (($x > $rest)
7373                        ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
7374                        : ($rows * $x));
7375
7376             $idx += $y;
7377             $four[$x] = $lcomm[$idx];
7378         }
7379         write;
7380     }
7381
7382     print "\nReport bugs to <bug-automake\@gnu.org>.\n";
7383
7384     # --help always returns 0 per GNU standards.
7385     exit 0;
7386 }
7387
7388
7389 # &version ()
7390 # -----------
7391 # Print version information
7392 sub version ()
7393 {
7394   print <<EOF;
7395 automake (GNU $PACKAGE) $VERSION
7396 Written by Tom Tromey <tromey\@redhat.com>
7397        and Alexandre Duret-Lutz <adl\@gnu.org>.
7398
7399 Copyright 2004 Free Software Foundation, Inc.
7400 This is free software; see the source for copying conditions.  There is NO
7401 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
7402 EOF
7403   # --version always returns 0 per GNU standards.
7404   exit 0;
7405 }
7406
7407 ################################################################
7408
7409 # Parse command line.
7410 sub parse_arguments ()
7411 {
7412   # Start off as gnu.
7413   set_strictness ('gnu');
7414
7415   my $cli_where = new Automake::Location;
7416   my %cli_options =
7417     (
7418      'libdir:s'         => \$libdir,
7419      'gnu'              => sub { set_strictness ('gnu'); },
7420      'gnits'            => sub { set_strictness ('gnits'); },
7421      'cygnus'           => sub { set_global_option ('cygnus', $cli_where); },
7422      'foreign'          => sub { set_strictness ('foreign'); },
7423      'include-deps'     => sub { unset_global_option ('no-dependencies'); },
7424      'i|ignore-deps'    => sub { set_global_option ('no-dependencies',
7425                                                     $cli_where); },
7426      'no-force'         => sub { $force_generation = 0; },
7427      'f|force-missing'  => \$force_missing,
7428      'o|output-dir:s'   => \$output_directory,
7429      'a|add-missing'    => \$add_missing,
7430      'c|copy'           => \$copy_missing,
7431      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
7432      'W|warnings:s'     => \&parse_warnings,
7433      # These long options (--Werror and --Wno-error) for backward
7434      # compatibility.  Use -Werror and -Wno-error today.
7435      'Werror'           => sub { parse_warnings 'W', 'error'; },
7436      'Wno-error'        => sub { parse_warnings 'W', 'no-error'; },
7437      );
7438   use Getopt::Long;
7439   Getopt::Long::config ("bundling", "pass_through");
7440
7441   # See if --version or --help is used.  We want to process these before
7442   # anything else because the GNU Coding Standards require us to
7443   # `exit 0' after processing these options, and we can't guarantee this
7444   # if we treat other options first.  (Handling other options first
7445   # could produce error diagnostics, and in this condition it is
7446   # confusing if Automake does `exit 0'.)
7447   my %cli_options_1st_pass =
7448     (
7449      'version' => \&version,
7450      'help'    => \&usage,
7451      # Recognize all other options (and their arguments) but do nothing.
7452      map { $_ => sub {} } (keys %cli_options)
7453      );
7454   my @ARGV_backup = @ARGV;
7455   Getopt::Long::GetOptions %cli_options_1st_pass
7456     or exit 1;
7457   @ARGV = @ARGV_backup;
7458
7459   # Now *really* process the options.  This time we know
7460   # that --help and --version are not present.
7461   Getopt::Long::GetOptions %cli_options
7462     or exit 1;
7463
7464   if (defined $output_directory)
7465     {
7466       msg 'obsolete', "`--output-dir' is deprecated\n";
7467     }
7468   else
7469     {
7470       # In the next release we'll remove this entirely.
7471       $output_directory = '.';
7472     }
7473
7474   my $errspec = 0;
7475   foreach my $arg (@ARGV)
7476     {
7477       if ($arg =~ /^-./)
7478         {
7479           fatal ("unrecognized option `$arg'\n"
7480                  . "Try `$0 --help' for more information.");
7481         }
7482
7483       # Handle $local:$input syntax.
7484       my ($local, @rest) = split (/:/, $arg);
7485       @rest = ("$local.in",) unless @rest;
7486       my $input = locate_am @rest;
7487       if ($input)
7488         {
7489           push @input_files, $input;
7490           $output_files{$input} = join (':', ($local, @rest));
7491         }
7492       else
7493         {
7494           error "no Automake input file found for `$arg'";
7495           $errspec = 1;
7496         }
7497     }
7498   fatal "no input file found among supplied arguments"
7499     if $errspec && ! @input_files;
7500 }
7501
7502 ################################################################
7503
7504 # Parse the WARNINGS environment variable.
7505 parse_WARNINGS;
7506
7507 # Parse command line.
7508 parse_arguments;
7509
7510 $configure_ac = require_configure_ac;
7511
7512 # Do configure.ac scan only once.
7513 scan_autoconf_files;
7514
7515 if (! @input_files)
7516   {
7517     my $msg = '';
7518     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
7519       if -f 'Makefile.am';
7520     fatal ("no `Makefile.am' found for any configure output$msg");
7521   }
7522
7523 # Now do all the work on each file.
7524 foreach my $file (@input_files)
7525   {
7526     ($am_file = $file) =~ s/\.in$//;
7527     if (! -f ($am_file . '.am'))
7528       {
7529         error "`$am_file.am' does not exist";
7530       }
7531     else
7532       {
7533         # Any warning setting now local to this Makefile.am.
7534         dup_channel_setup;
7535
7536         generate_makefile ($am_file . '.am', $file);
7537
7538         # Back out any warning setting.
7539         drop_channel_setup;
7540       }
7541   }
7542
7543 exit $exit_code;
7544
7545
7546 ### Setup "GNU" style for perl-mode and cperl-mode.
7547 ## Local Variables:
7548 ## perl-indent-level: 2
7549 ## perl-continued-statement-offset: 2
7550 ## perl-continued-brace-offset: 0
7551 ## perl-brace-offset: 0
7552 ## perl-brace-imaginary-offset: 0
7553 ## perl-label-offset: -2
7554 ## cperl-indent-level: 2
7555 ## cperl-brace-offset: 0
7556 ## cperl-continued-brace-offset: 0
7557 ## cperl-label-offset: -2
7558 ## cperl-extra-newline-before-brace: t
7559 ## cperl-merge-trailing-else: nil
7560 ## cperl-continued-statement-offset: 2
7561 ## End: