automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994-2012 Free Software Foundation, Inc.
  10
  11 # This program is free software; you can redistribute it and/or modify
  12 # it under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 2, or (at your option)
  14 # any later version.
  15
  16 # This program is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 # GNU General Public License for more details.
  20
  21 # You should have received a copy of the GNU General Public License
  22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  25 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  26 # Alexandre Duret-Lutz <adl@gnu.org>.
  27
  28 package Language;
  29
  30 BEGIN
  31 {
  32   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  33   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  34
  35   # Override SHELL.  This is required on DJGPP so that system() uses
  36   # bash, not COMMAND.COM which doesn't quote arguments properly.
  37   # Other systems aren't expected to use $SHELL when Automake
  38   # runs, but it should be safe to drop the "if DJGPP" guard if
  39   # it turns up other systems need the same thing.  After all,
  40   # if SHELL is used, ./configure's SHELL is always better than
  41   # the user's SHELL (which may be something like tcsh).
  42   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJDIR'};
  43 }
  44
  45 use Class::Struct ();
  46 Class::Struct::struct (
  47         # Short name of the language (c, f77...).
  48         'name' => "\$",
  49         # Nice name of the language (C, Fortran 77...).
  50         'Name' => "\$",
  51
  52         # List of configure variables which must be defined.
  53         'config_vars' => '@',
  54
  55         # 'pure' is '1' or ''.  A 'pure' language is one where, if
  56         # all the files in a directory are of that language, then we
  57         # do not require the C compiler or any code to call it.
  58         'pure'   => "\$",
  59
  60         'autodep' => "\$",
  61
  62         # Name of the compiling variable (COMPILE).
  63         'compiler'  => "\$",
  64         # Content of the compiling variable.
  65         'compile'  => "\$",
  66         # Flag to require compilation without linking (-c).
  67         'compile_flag' => "\$",
  68         'extensions' => '@',
  69         # A subroutine to compute a list of possible extensions of
  70         # the product given the input extensions.
  71         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  72         'output_extensions' => "\$",
  73         # A list of flag variables used in 'compile'.
  74         # (defaults to [])
  75         'flags' => "@",
  76
  77         # Any tag to pass to libtool while compiling.
  78         'libtool_tag' => "\$",
  79
  80         # The file to use when generating rules for this language.
  81         # The default is 'depend2'.
  82         'rule_file' => "\$",
  83
  84         # Name of the linking variable (LINK).
  85         'linker' => "\$",
  86         # Content of the linking variable.
  87         'link' => "\$",
  88
  89         # Name of the compiler variable (CC).
  90         'ccer' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} (@_);
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 BEGIN
 134 {
 135   if ($perl_threads)
 136     {
 137       require threads;
 138       import threads;
 139       require Thread::Queue;
 140       import Thread::Queue;
 141     }
 142 }
 143 use Automake::General;
 144 use Automake::XFile;
 145 use Automake::Channels;
 146 use Automake::ChannelDefs;
 147 use Automake::Configure_ac;
 148 use Automake::FileUtils;
 149 use Automake::Location;
 150 use Automake::Condition qw/TRUE FALSE/;
 151 use Automake::DisjConditions;
 152 use Automake::Options;
 153 use Automake::Variable;
 154 use Automake::VarDef;
 155 use Automake::Rule;
 156 use Automake::RuleDef;
 157 use Automake::Wrap 'makefile_wrap';
 158 use File::Basename;
 159 use File::Spec;
 160 use Carp;
 161
 162 ## ----------- ##
 163 ## Constants.  ##
 164 ## ----------- ##
 165
 166 # Some regular expressions.  One reason to put them here is that it
 167 # makes indentation work better in Emacs.
 168
 169 # Writing singled-quoted-$-terminated regexes is a pain because
 170 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 171 # by a closing quote.  Letting perl-mode think the quote is not closed
 172 # leads to all sort of misindentations.  On the other hand, defining
 173 # regexes as double-quoted strings is far less readable.  So usually
 174 # we will write:
 175 #
 176 #  $REGEX = '^regex_value' . "\$";
 177
 178 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 179 my $WHITE_PATTERN = '^\s*' . "\$";
 180 my $COMMENT_PATTERN = '^#';
 181 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 182 # A rule has three parts: a list of targets, a list of dependencies,
 183 # and optionally actions.
 184 my $RULE_PATTERN =
 185   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 186
 187 # Only recognize leading spaces, not leading tabs.  If we recognize
 188 # leading tabs here then we need to make the reader smarter, because
 189 # otherwise it will think rules like 'foo=bar; \' are errors.
 190 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 191 # This pattern recognizes a Gnits version id and sets $1 if the
 192 # release is an alpha release.  We also allow a suffix which can be
 193 # used to extend the version number with a "fork" identifier.
 194 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 195
 196 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 197 my $ELSE_PATTERN =
 198   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 199 my $ENDIF_PATTERN =
 200   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 201 my $PATH_PATTERN = '(\w|[+/.-])+';
 202 # This will pass through anything not of the prescribed form.
 203 my $INCLUDE_PATTERN = ('^include\s+'
 204                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 205                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 206                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 207
 208 # Directories installed during 'install-exec' phase.
 209 my $EXEC_DIR_PATTERN =
 210   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 211
 212 # Values for AC_CANONICAL_*
 213 use constant AC_CANONICAL_BUILD  => 1;
 214 use constant AC_CANONICAL_HOST   => 2;
 215 use constant AC_CANONICAL_TARGET => 3;
 216
 217 # Values indicating when something should be cleaned.
 218 use constant MOSTLY_CLEAN     => 0;
 219 use constant CLEAN            => 1;
 220 use constant DIST_CLEAN       => 2;
 221 use constant MAINTAINER_CLEAN => 3;
 222
 223 # Libtool files.
 224 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 225 # ltconfig appears here for compatibility with old versions of libtool.
 226 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 227
 228 # Commonly found files we look for and automatically include in
 229 # DISTFILES.
 230 my @common_files =
 231     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 232         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 233         ar-lib compile config.guess config.rpath
 234         config.sub depcomp install-sh libversion.in mdate-sh
 235         missing mkinstalldirs py-compile texinfo.tex ylwrap),
 236      @libtool_files, @libtool_sometimes);
 237
 238 # Commonly used files we auto-include, but only sometimes.  This list
 239 # is used for the --help output only.
 240 my @common_sometimes =
 241   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 242      configure.ac configure.in stamp-vti);
 243
 244 # Standard directories from the GNU Coding Standards, and additional
 245 # pkg* directories from Automake.  Stored in a hash for fast member check.
 246 my %standard_prefix =
 247     map { $_ => 1 } (qw(bin data dataroot doc dvi exec html include info
 248                         lib libexec lisp locale localstate man man1 man2
 249                         man3 man4 man5 man6 man7 man8 man9 oldinclude pdf
 250                         pkgdata pkginclude pkglib pkglibexec ps sbin
 251                         sharedstate sysconf));
 252
 253 # Copyright on generated Makefile.ins.
 254 my $gen_copyright = "\
 255 # Copyright (C) 1994-$RELEASE_YEAR Free Software Foundation, Inc.
 256
 257 # This Makefile.in is free software; the Free Software Foundation
 258 # gives unlimited permission to copy and/or distribute it,
 259 # with or without modifications, as long as this notice is preserved.
 260
 261 # This program is distributed in the hope that it will be useful,
 262 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 263 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 264 # PARTICULAR PURPOSE.
 265 ";
 266
 267 # These constants are returned by the lang_*_rewrite functions.
 268 # LANG_SUBDIR means that the resulting object file should be in a
 269 # subdir if the source file is.  In this case the file name cannot
 270 # have '..' components.
 271 use constant LANG_IGNORE  => 0;
 272 use constant LANG_PROCESS => 1;
 273 use constant LANG_SUBDIR  => 2;
 274
 275 # These are used when keeping track of whether an object can be built
 276 # by two different paths.
 277 use constant COMPILE_LIBTOOL  => 1;
 278 use constant COMPILE_ORDINARY => 2;
 279
 280 # We can't always associate a location to a variable or a rule,
 281 # when it's defined by Automake.  We use INTERNAL in this case.
 282 use constant INTERNAL => new Automake::Location;
 283
 284 # Serialization keys for message queues.
 285 use constant QUEUE_MESSAGE   => "msg";
 286 use constant QUEUE_CONF_FILE => "conf file";
 287 use constant QUEUE_LOCATION  => "location";
 288 use constant QUEUE_STRING    => "string";
 289
 290 ## ---------------------------------- ##
 291 ## Variables related to the options.  ##
 292 ## ---------------------------------- ##
 293
 294 # TRUE if we should always generate Makefile.in.
 295 my $force_generation = 1;
 296
 297 # From the Perl manual.
 298 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 299
 300 # TRUE if missing standard files should be installed.
 301 my $add_missing = 0;
 302
 303 # TRUE if we should copy missing files; otherwise symlink if possible.
 304 my $copy_missing = 0;
 305
 306 # TRUE if we should always update files that we know about.
 307 my $force_missing = 0;
 308
 309
 310 ## ---------------------------------------- ##
 311 ## Variables filled during files scanning.  ##
 312 ## ---------------------------------------- ##
 313
 314 # Name of the configure.ac file.
 315 my $configure_ac;
 316
 317 # Files found by scanning configure.ac for LIBOBJS.
 318 my %libsources = ();
 319
 320 # Names used in AC_CONFIG_HEADER call.
 321 my @config_headers = ();
 322
 323 # Names used in AC_CONFIG_LINKS call.
 324 my @config_links = ();
 325
 326 # List of Makefile.am's to process, and their corresponding outputs.
 327 my @input_files = ();
 328 my %output_files = ();
 329
 330 # Complete list of Makefile.am's that exist.
 331 my @configure_input_files = ();
 332
 333 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 334 # and their outputs.
 335 my @other_input_files = ();
 336 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 337 # The keys are the files created by these macros.
 338 my %ac_config_files_location = ();
 339 # The condition under which AC_CONFIG_FOOS appears.
 340 my %ac_config_files_condition = ();
 341
 342 # Directory to search for configure-required files.  This
 343 # will be computed by &locate_aux_dir and can be set using
 344 # AC_CONFIG_AUX_DIR in configure.ac.
 345 # $CONFIG_AUX_DIR is the 'raw' directory, valid only in the source-tree.
 346 my $config_aux_dir = '';
 347 my $config_aux_dir_set_in_configure_ac = 0;
 348 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 349 # in Makefiles.
 350 my $am_config_aux_dir = '';
 351
 352 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 353 # in configure.ac.
 354 my $config_libobj_dir = '';
 355
 356 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 357 my $seen_gettext = 0;
 358 # Whether AM_GNU_GETTEXT([external]) is used.
 359 my $seen_gettext_external = 0;
 360 # Where AM_GNU_GETTEXT appears.
 361 my $ac_gettext_location;
 362 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 363 my $seen_gettext_intl = 0;
 364
 365 # The arguments of the AM_EXTRA_RECURSIVE_TARGETS call (if any).
 366 my @extra_recursive_targets = ();
 367
 368 # Lists of tags supported by Libtool.
 369 my %libtool_tags = ();
 370 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 371 # uses AC_REQUIRE_AUX_FILE.
 372 my $libtool_new_api = 0;
 373
 374 # Most important AC_CANONICAL_* macro seen so far.
 375 my $seen_canonical = 0;
 376
 377 # Where AM_MAINTAINER_MODE appears.
 378 my $seen_maint_mode;
 379
 380 # Actual version we've seen.
 381 my $package_version = '';
 382
 383 # Where version is defined.
 384 my $package_version_location;
 385
 386 # TRUE if we've seen AM_PROG_AR
 387 my $seen_ar = 0;
 388
 389 # TRUE if we've seen AM_PROG_CC_C_O
 390 my $seen_cc_c_o = 0;
 391
 392 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 393 my %required_aux_file = ();
 394
 395 # Where AM_INIT_AUTOMAKE is called;
 396 my $seen_init_automake = 0;
 397
 398 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 399 my $seen_automake_version = 0;
 400
 401 # Hash table of discovered configure substitutions.  Keys are names,
 402 # values are 'FILE:LINE' strings which are used by error message
 403 # generation.
 404 my %configure_vars = ();
 405
 406 # Ignored configure substitutions (i.e., variables not to be output in
 407 # Makefile.in)
 408 my %ignored_configure_vars = ();
 409
 410 # Files included by $configure_ac.
 411 my @configure_deps = ();
 412
 413 # Greatest timestamp of configure's dependencies.
 414 my $configure_deps_greatest_timestamp = 0;
 415
 416 # Hash table of AM_CONDITIONAL variables seen in configure.
 417 my %configure_cond = ();
 418
 419 # This maps extensions onto language names.
 420 my %extension_map = ();
 421
 422 # List of the DIST_COMMON files we discovered while reading
 423 # configure.ac.
 424 my $configure_dist_common = '';
 425
 426 # This maps languages names onto objects.
 427 my %languages = ();
 428 # Maps each linker variable onto a language object.
 429 my %link_languages = ();
 430
 431 # maps extensions to needed source flags.
 432 my %sourceflags = ();
 433
 434 # List of targets we must always output.
 435 # FIXME: Complete, and remove falsely required targets.
 436 my %required_targets =
 437   (
 438    'all'          => 1,
 439    'dvi'          => 1,
 440    'pdf'          => 1,
 441    'ps'           => 1,
 442    'info'         => 1,
 443    'install-info' => 1,
 444    'install'      => 1,
 445    'install-data' => 1,
 446    'install-exec' => 1,
 447    'uninstall'    => 1,
 448
 449    # FIXME: Not required, temporary hacks.
 450    # Well, actually they are sort of required: the -recursive
 451    # targets will run them anyway...
 452    'html-am'         => 1,
 453    'dvi-am'          => 1,
 454    'pdf-am'          => 1,
 455    'ps-am'           => 1,
 456    'info-am'         => 1,
 457    'install-data-am' => 1,
 458    'install-exec-am' => 1,
 459    'install-html-am' => 1,
 460    'install-dvi-am'  => 1,
 461    'install-pdf-am'  => 1,
 462    'install-ps-am'   => 1,
 463    'install-info-am' => 1,
 464    'installcheck-am' => 1,
 465    'uninstall-am'    => 1,
 466    'tags-am'         => 1,
 467    'ctags-am'        => 1,
 468    'cscopelist-am'   => 1,
 469    'install-man'     => 1,
 470   );
 471
 472 # Queue to push require_conf_file requirements to.
 473 my $required_conf_file_queue;
 474
 475 # The name of the Makefile currently being processed.
 476 my $am_file = 'BUG';
 477
 478 ################################################################
 479
 480 ## ------------------------------------------ ##
 481 ## Variables reset by &initialize_per_input.  ##
 482 ## ------------------------------------------ ##
 483
 484 # Relative dir of the output makefile.
 485 my $relative_dir;
 486
 487 # Greatest timestamp of the output's dependencies (excluding
 488 # configure's dependencies).
 489 my $output_deps_greatest_timestamp;
 490
 491 # These variables are used when generating each Makefile.in.
 492 # They hold the Makefile.in until it is ready to be printed.
 493 my $output_vars;
 494 my $output_all;
 495 my $output_header;
 496 my $output_rules;
 497 my $output_trailer;
 498
 499 # This is the conditional stack, updated on if/else/endif, and
 500 # used to build Condition objects.
 501 my @cond_stack;
 502
 503 # This holds the set of included files.
 504 my @include_stack;
 505
 506 # List of dependencies for the obvious targets.
 507 my @all;
 508 my @check;
 509 my @check_tests;
 510
 511 # Keys in this hash table are files to delete.  The associated
 512 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 513 my %clean_files;
 514
 515 # Keys in this hash table are object files or other files in
 516 # subdirectories which need to be removed.  This only holds files
 517 # which are created by compilations.  The value in the hash indicates
 518 # when the file should be removed.
 519 my %compile_clean_files;
 520
 521 # Keys in this hash table are directories where we expect to build a
 522 # libtool object.  We use this information to decide what directories
 523 # to delete.
 524 my %libtool_clean_directories;
 525
 526 # Value of $(SOURCES), used by tags.am.
 527 my @sources;
 528 # Sources which go in the distribution.
 529 my @dist_sources;
 530
 531 # This hash maps object file names onto their corresponding source
 532 # file names.  This is used to ensure that each object is created
 533 # by a single source file.
 534 my %object_map;
 535
 536 # This hash maps object file names onto an integer value representing
 537 # whether this object has been built via ordinary compilation or
 538 # libtool compilation (the COMPILE_* constants).
 539 my %object_compilation_map;
 540
 541
 542 # This keeps track of the directories for which we've already
 543 # created dirstamp code.  Keys are directories, values are stamp files.
 544 # Several keys can share the same stamp files if they are equivalent
 545 # (as are './/foo' and 'foo').
 546 my %directory_map;
 547
 548 # All .P files.
 549 my %dep_files;
 550
 551 # This is a list of all targets to run during "make dist".
 552 my @dist_targets;
 553
 554 # Keep track of all programs declared in this Makefile, without
 555 # $(EXEEXT).  @substitutions@ are not listed.
 556 my %known_programs;
 557 my %known_libraries;
 558
 559 # This keeps track of which extensions we've seen (that we care
 560 # about).
 561 my %extension_seen;
 562
 563 # This is random scratch space for the language finish functions.
 564 # Don't randomly overwrite it; examine other uses of keys first.
 565 my %language_scratch;
 566
 567 # We keep track of which objects need special (per-executable)
 568 # handling on a per-language basis.
 569 my %lang_specific_files;
 570
 571 # This is set when 'handle_dist' has finished.  Once this happens,
 572 # we should no longer push on dist_common.
 573 my $handle_dist_run;
 574
 575 # Used to store a set of linkers needed to generate the sources currently
 576 # under consideration.
 577 my %linkers_used;
 578
 579 # True if we need 'LINK' defined.  This is a hack.
 580 my $need_link;
 581
 582 # Does the generated Makefile have to build some compiled object
 583 # (for binary programs, or plain or libtool libraries)?
 584 my $must_handle_compiled_objects;
 585
 586 # Record each file processed by make_paragraphs.
 587 my %transformed_files;
 588
 589 ################################################################
 590
 591 ## ---------------------------------------------- ##
 592 ## Variables not reset by &initialize_per_input.  ##
 593 ## ---------------------------------------------- ##
 594
 595 # Cache each file processed by make_paragraphs.
 596 # (This is different from %transformed_files because
 597 # %transformed_files is reset for each file while %am_file_cache
 598 # it global to the run.)
 599 my %am_file_cache;
 600
 601 ################################################################
 602
 603 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 604 # ------------------------------------
 605 # This is called by Automake::Variable::define() when SUFFIXES
 606 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 607 # The work here needs to be performed as a side-effect of the
 608 # macro_define() call because SUFFIXES definitions impact
 609 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 610 # the input am file.
 611 sub var_SUFFIXES_trigger ($$)
 612 {
 613     my ($type, $value) = @_;
 614     accept_extensions (split (' ', $value));
 615 }
 616 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 617
 618 ################################################################
 619
 620 ## --------------------------------- ##
 621 ## Forward subroutine declarations.  ##
 622 ## --------------------------------- ##
 623 sub register_language (%);
 624 sub file_contents_internal ($$$%);
 625 sub define_files_variable ($\@$$);
 626
 627
 628 # &initialize_per_input ()
 629 # ------------------------
 630 # (Re)-Initialize per-Makefile.am variables.
 631 sub initialize_per_input ()
 632 {
 633     reset_local_duplicates ();
 634
 635     $relative_dir = undef;
 636
 637     $output_deps_greatest_timestamp = 0;
 638
 639     $output_vars = '';
 640     $output_all = '';
 641     $output_header = '';
 642     $output_rules = '';
 643     $output_trailer = '';
 644
 645     Automake::Options::reset;
 646     Automake::Variable::reset;
 647     Automake::Rule::reset;
 648
 649     @cond_stack = ();
 650
 651     @include_stack = ();
 652
 653     @all = ();
 654     @check = ();
 655     @check_tests = ();
 656
 657     %clean_files = ();
 658     %compile_clean_files = ();
 659
 660     # We always include '.'.  This isn't strictly correct.
 661     %libtool_clean_directories = ('.' => 1);
 662
 663     @sources = ();
 664     @dist_sources = ();
 665
 666     %object_map = ();
 667     %object_compilation_map = ();
 668
 669     %directory_map = ();
 670
 671     %dep_files = ();
 672
 673     @dist_targets = ();
 674
 675     %known_programs = ();
 676     %known_libraries= ();
 677
 678     %extension_seen = ();
 679
 680     %language_scratch = ();
 681
 682     %lang_specific_files = ();
 683
 684     $handle_dist_run = 0;
 685
 686     $need_link = 0;
 687
 688     $must_handle_compiled_objects = 0;
 689
 690     %transformed_files = ();
 691 }
 692
 693
 694 ################################################################
 695
 696 # Initialize our list of languages that are internally supported.
 697
 698 # C.
 699 register_language ('name' => 'c',
 700                    'Name' => 'C',
 701                    'config_vars' => ['CC'],
 702                    'autodep' => '',
 703                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 704                    'ccer' => 'CC',
 705                    'compiler' => 'COMPILE',
 706                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 707                    'lder' => 'CCLD',
 708                    'ld' => '$(CC)',
 709                    'linker' => 'LINK',
 710                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 711                    'compile_flag' => '-c',
 712                    'libtool_tag' => 'CC',
 713                    'extensions' => ['.c']);
 714
 715 # C++.
 716 register_language ('name' => 'cxx',
 717                    'Name' => 'C++',
 718                    'config_vars' => ['CXX'],
 719                    'linker' => 'CXXLINK',
 720                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 721                    'autodep' => 'CXX',
 722                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 723                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 724                    'ccer' => 'CXX',
 725                    'compiler' => 'CXXCOMPILE',
 726                    'compile_flag' => '-c',
 727                    'output_flag' => '-o',
 728                    'libtool_tag' => 'CXX',
 729                    'lder' => 'CXXLD',
 730                    'ld' => '$(CXX)',
 731                    'pure' => 1,
 732                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 733
 734 # Objective C.
 735 register_language ('name' => 'objc',
 736                    'Name' => 'Objective C',
 737                    'config_vars' => ['OBJC'],
 738                    'linker' => 'OBJCLINK',
 739                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 740                    'autodep' => 'OBJC',
 741                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 742                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 743                    'ccer' => 'OBJC',
 744                    'compiler' => 'OBJCCOMPILE',
 745                    'compile_flag' => '-c',
 746                    'output_flag' => '-o',
 747                    'lder' => 'OBJCLD',
 748                    'ld' => '$(OBJC)',
 749                    'pure' => 1,
 750                    'extensions' => ['.m']);
 751
 752 # Objective C++.
 753 register_language ('name' => 'objcxx',
 754                    'Name' => 'Objective C++',
 755                    'config_vars' => ['OBJCXX'],
 756                    'linker' => 'OBJCXXLINK',
 757                    'link' => '$(OBJCXXLD) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 758                    'autodep' => 'OBJCXX',
 759                    'flags' => ['OBJCXXFLAGS', 'CPPFLAGS'],
 760                    'compile' => '$(OBJCXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS)',
 761                    'ccer' => 'OBJCXX',
 762                    'compiler' => 'OBJCXXCOMPILE',
 763                    'compile_flag' => '-c',
 764                    'output_flag' => '-o',
 765                    'lder' => 'OBJCXXLD',
 766                    'ld' => '$(OBJCXX)',
 767                    'pure' => 1,
 768                    'extensions' => ['.mm']);
 769
 770 # Unified Parallel C.
 771 register_language ('name' => 'upc',
 772                    'Name' => 'Unified Parallel C',
 773                    'config_vars' => ['UPC'],
 774                    'linker' => 'UPCLINK',
 775                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 776                    'autodep' => 'UPC',
 777                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 778                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 779                    'ccer' => 'UPC',
 780                    'compiler' => 'UPCCOMPILE',
 781                    'compile_flag' => '-c',
 782                    'output_flag' => '-o',
 783                    'lder' => 'UPCLD',
 784                    'ld' => '$(UPC)',
 785                    'pure' => 1,
 786                    'extensions' => ['.upc']);
 787
 788 # Headers.
 789 register_language ('name' => 'header',
 790                    'Name' => 'Header',
 791                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 792                                     '.hpp', '.inc'],
 793                    # No output.
 794                    'output_extensions' => sub { return () },
 795                    # Nothing to do.
 796                    '_finish' => sub { });
 797
 798 # Vala
 799 register_language ('name' => 'vala',
 800                    'Name' => 'Vala',
 801                    'config_vars' => ['VALAC'],
 802                    'flags' => [],
 803                    'compile' => '$(VALAC) $(AM_VALAFLAGS) $(VALAFLAGS)',
 804                    'ccer' => 'VALAC',
 805                    'compiler' => 'VALACOMPILE',
 806                    'extensions' => ['.vala'],
 807                    'output_extensions' => sub { (my $ext = $_[0]) =~ s/vala$/c/;
 808                                                 return ($ext,) },
 809                    'rule_file' => 'vala',
 810                    '_finish' => \&lang_vala_finish,
 811                    '_target_hook' => \&lang_vala_target_hook,
 812                    'nodist_specific' => 1);
 813
 814 # Yacc (C & C++).
 815 register_language ('name' => 'yacc',
 816                    'Name' => 'Yacc',
 817                    'config_vars' => ['YACC'],
 818                    'flags' => ['YFLAGS'],
 819                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 820                    'ccer' => 'YACC',
 821                    'compiler' => 'YACCCOMPILE',
 822                    'extensions' => ['.y'],
 823                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 824                                                 return ($ext,) },
 825                    'rule_file' => 'yacc',
 826                    '_finish' => \&lang_yacc_finish,
 827                    '_target_hook' => \&lang_yacc_target_hook,
 828                    'nodist_specific' => 1);
 829 register_language ('name' => 'yaccxx',
 830                    'Name' => 'Yacc (C++)',
 831                    'config_vars' => ['YACC'],
 832                    'rule_file' => 'yacc',
 833                    'flags' => ['YFLAGS'],
 834                    'ccer' => 'YACC',
 835                    'compiler' => 'YACCCOMPILE',
 836                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 837                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 838                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 839                                                 return ($ext,) },
 840                    '_finish' => \&lang_yacc_finish,
 841                    '_target_hook' => \&lang_yacc_target_hook,
 842                    'nodist_specific' => 1);
 843
 844 # Lex (C & C++).
 845 register_language ('name' => 'lex',
 846                    'Name' => 'Lex',
 847                    'config_vars' => ['LEX'],
 848                    'rule_file' => 'lex',
 849                    'flags' => ['LFLAGS'],
 850                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 851                    'ccer' => 'LEX',
 852                    'compiler' => 'LEXCOMPILE',
 853                    'extensions' => ['.l'],
 854                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 855                                                 return ($ext,) },
 856                    '_finish' => \&lang_lex_finish,
 857                    '_target_hook' => \&lang_lex_target_hook,
 858                    'nodist_specific' => 1);
 859 register_language ('name' => 'lexxx',
 860                    'Name' => 'Lex (C++)',
 861                    'config_vars' => ['LEX'],
 862                    'rule_file' => 'lex',
 863                    'flags' => ['LFLAGS'],
 864                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 865                    'ccer' => 'LEX',
 866                    'compiler' => 'LEXCOMPILE',
 867                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 868                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 869                                                 return ($ext,) },
 870                    '_finish' => \&lang_lex_finish,
 871                    '_target_hook' => \&lang_lex_target_hook,
 872                    'nodist_specific' => 1);
 873
 874 # Assembler.
 875 register_language ('name' => 'asm',
 876                    'Name' => 'Assembler',
 877                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 878
 879                    'flags' => ['CCASFLAGS'],
 880                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 881                    # or anything else required.  They can also set CCAS.
 882                    # Or simply use Preprocessed Assembler.
 883                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 884                    'ccer' => 'CCAS',
 885                    'compiler' => 'CCASCOMPILE',
 886                    'compile_flag' => '-c',
 887                    'output_flag' => '-o',
 888                    'extensions' => ['.s']);
 889
 890 # Preprocessed Assembler.
 891 register_language ('name' => 'cppasm',
 892                    'Name' => 'Preprocessed Assembler',
 893                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 894
 895                    'autodep' => 'CCAS',
 896                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 897                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 898                    'ccer' => 'CPPAS',
 899                    'compiler' => 'CPPASCOMPILE',
 900                    'compile_flag' => '-c',
 901                    'output_flag' => '-o',
 902                    'extensions' => ['.S', '.sx']);
 903
 904 # Fortran 77
 905 register_language ('name' => 'f77',
 906                    'Name' => 'Fortran 77',
 907                    'config_vars' => ['F77'],
 908                    'linker' => 'F77LINK',
 909                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 910                    'flags' => ['FFLAGS'],
 911                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 912                    'ccer' => 'F77',
 913                    'compiler' => 'F77COMPILE',
 914                    'compile_flag' => '-c',
 915                    'output_flag' => '-o',
 916                    'libtool_tag' => 'F77',
 917                    'lder' => 'F77LD',
 918                    'ld' => '$(F77)',
 919                    'pure' => 1,
 920                    'extensions' => ['.f', '.for']);
 921
 922 # Fortran
 923 register_language ('name' => 'fc',
 924                    'Name' => 'Fortran',
 925                    'config_vars' => ['FC'],
 926                    'linker' => 'FCLINK',
 927                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 928                    'flags' => ['FCFLAGS'],
 929                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 930                    'ccer' => 'FC',
 931                    'compiler' => 'FCCOMPILE',
 932                    'compile_flag' => '-c',
 933                    'output_flag' => '-o',
 934                    'libtool_tag' => 'FC',
 935                    'lder' => 'FCLD',
 936                    'ld' => '$(FC)',
 937                    'pure' => 1,
 938                    'extensions' => ['.f90', '.f95', '.f03', '.f08']);
 939
 940 # Preprocessed Fortran
 941 register_language ('name' => 'ppfc',
 942                    'Name' => 'Preprocessed Fortran',
 943                    'config_vars' => ['FC'],
 944                    'linker' => 'FCLINK',
 945                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 946                    'lder' => 'FCLD',
 947                    'ld' => '$(FC)',
 948                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 949                    'ccer' => 'PPFC',
 950                    'compiler' => 'PPFCCOMPILE',
 951                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 952                    'compile_flag' => '-c',
 953                    'output_flag' => '-o',
 954                    'libtool_tag' => 'FC',
 955                    'pure' => 1,
 956                    'extensions' => ['.F90','.F95', '.F03', '.F08']);
 957
 958 # Preprocessed Fortran 77
 959 #
 960 # The current support for preprocessing Fortran 77 just involves
 961 # passing "$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 962 # $(CPPFLAGS)" as additional flags to the Fortran 77 compiler, since
 963 # this is how GNU Make does it; see the "GNU Make Manual, Edition 0.51
 964 # for 'make' Version 3.76 Beta" (specifically, from info file
 965 # '(make)Catalogue of Rules').
 966 #
 967 # A better approach would be to write an Autoconf test
 968 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 969 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 970 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 971 # preprocessing capabilities, and then fall back on cpp (if cpp were
 972 # available).
 973 register_language ('name' => 'ppf77',
 974                    'Name' => 'Preprocessed Fortran 77',
 975                    'config_vars' => ['F77'],
 976                    'linker' => 'F77LINK',
 977                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 978                    'lder' => 'F77LD',
 979                    'ld' => '$(F77)',
 980                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 981                    'ccer' => 'PPF77',
 982                    'compiler' => 'PPF77COMPILE',
 983                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 984                    'compile_flag' => '-c',
 985                    'output_flag' => '-o',
 986                    'libtool_tag' => 'F77',
 987                    'pure' => 1,
 988                    'extensions' => ['.F']);
 989
 990 # Ratfor.
 991 register_language ('name' => 'ratfor',
 992                    'Name' => 'Ratfor',
 993                    'config_vars' => ['F77'],
 994                    'linker' => 'F77LINK',
 995                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 996                    'lder' => 'F77LD',
 997                    'ld' => '$(F77)',
 998                    'flags' => ['RFLAGS', 'FFLAGS'],
 999                    # FIXME also FFLAGS.
1000                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
1001                    'ccer' => 'F77',
1002                    'compiler' => 'RCOMPILE',
1003                    'compile_flag' => '-c',
1004                    'output_flag' => '-o',
1005                    'libtool_tag' => 'F77',
1006                    'pure' => 1,
1007                    'extensions' => ['.r']);
1008
1009 # Java via gcj.
1010 register_language ('name' => 'java',
1011                    'Name' => 'Java',
1012                    'config_vars' => ['GCJ'],
1013                    'linker' => 'GCJLINK',
1014                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1015                    'autodep' => 'GCJ',
1016                    'flags' => ['GCJFLAGS'],
1017                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
1018                    'ccer' => 'GCJ',
1019                    'compiler' => 'GCJCOMPILE',
1020                    'compile_flag' => '-c',
1021                    'output_flag' => '-o',
1022                    'libtool_tag' => 'GCJ',
1023                    'lder' => 'GCJLD',
1024                    'ld' => '$(GCJ)',
1025                    'pure' => 1,
1026                    'extensions' => ['.java', '.class', '.zip', '.jar']);
1027
1028 ################################################################
1029
1030 # Error reporting functions.
1031
1032 # err_am ($MESSAGE, [%OPTIONS])
1033 # -----------------------------
1034 # Uncategorized errors about the current Makefile.am.
1035 sub err_am ($;%)
1036 {
1037   msg_am ('error', @_);
1038 }
1039
1040 # err_ac ($MESSAGE, [%OPTIONS])
1041 # -----------------------------
1042 # Uncategorized errors about configure.ac.
1043 sub err_ac ($;%)
1044 {
1045   msg_ac ('error', @_);
1046 }
1047
1048 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1049 # ---------------------------------------
1050 # Messages about about the current Makefile.am.
1051 sub msg_am ($$;%)
1052 {
1053   my ($channel, $msg, %opts) = @_;
1054   msg $channel, "${am_file}.am", $msg, %opts;
1055 }
1056
1057 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1058 # ---------------------------------------
1059 # Messages about about configure.ac.
1060 sub msg_ac ($$;%)
1061 {
1062   my ($channel, $msg, %opts) = @_;
1063   msg $channel, $configure_ac, $msg, %opts;
1064 }
1065
1066 ################################################################
1067
1068 # subst ($TEXT)
1069 # -------------
1070 # Return a configure-style substitution using the indicated text.
1071 # We do this to avoid having the substitutions directly in automake.in;
1072 # when we do that they are sometimes removed and this causes confusion
1073 # and bugs.
1074 sub subst ($)
1075 {
1076     my ($text) = @_;
1077     return '@' . $text . '@';
1078 }
1079
1080 ################################################################
1081
1082
1083 # $BACKPATH
1084 # &backname ($RELDIR)
1085 # --------------------
1086 # If I "cd $RELDIR", then to come back, I should "cd $BACKPATH".
1087 # For instance 'src/foo' => '../..'.
1088 # Works with non strictly increasing paths, i.e., 'src/../lib' => '..'.
1089 sub backname ($)
1090 {
1091     my ($file) = @_;
1092     my @res;
1093     foreach (split (/\//, $file))
1094     {
1095         next if $_ eq '.' || $_ eq '';
1096         if ($_ eq '..')
1097         {
1098             pop @res
1099               or prog_error ("trying to reverse path '$file' pointing outside tree");
1100         }
1101         else
1102         {
1103             push (@res, '..');
1104         }
1105     }
1106     return join ('/', @res) || '.';
1107 }
1108
1109 ################################################################
1110
1111 # Silent rules handling functions.
1112
1113 # verbose_var (NAME)
1114 # ------------------
1115 # The public variable stem used to implement silent rules.
1116 sub verbose_var ($)
1117 {
1118     my ($name) = @_;
1119     return 'AM_V_' . $name;
1120 }
1121
1122 # verbose_private_var (NAME)
1123 # --------------------------
1124 # The naming policy for the private variables for silent rules.
1125 sub verbose_private_var ($)
1126 {
1127     my ($name) = @_;
1128     return 'am__v_' . $name;
1129 }
1130
1131 # define_verbose_var (NAME, VAL-IF-SILENT, [VAL-IF-VERBOSE])
1132 # ----------------------------------------------------------
1133 # For  silent rules, setup VAR and dispatcher, to expand to
1134 # VAL-IF-SILENT if silent, to VAL-IF-VERBOSE (defaulting to
1135 # empty) if not.
1136 sub define_verbose_var ($$;$)
1137 {
1138     my ($name, $silent_val, $verbose_val) = @_;
1139     $verbose_val = '' unless defined $verbose_val;
1140     my $var = verbose_var ($name);
1141     my $pvar = verbose_private_var ($name);
1142     my $silent_var = $pvar . '_0';
1143     my $verbose_var = $pvar . '_1';
1144     # For typical 'make's, 'configure' replaces AM_V (inside @@) with $(V)
1145     # and AM_DEFAULT_V (inside @@) with $(AM_DEFAULT_VERBOSITY).
1146     # For strict POSIX 2008 'make's, it replaces them with 0 or 1 instead.
1147     # See AM_SILENT_RULES in m4/silent.m4.
1148     define_variable ($var, '$(' . $pvar . '_@'.'AM_V'.'@)', INTERNAL);
1149     define_variable ($pvar . '_', '$(' . $pvar . '_@'.'AM_DEFAULT_V'.'@)',
1150                      INTERNAL);
1151     Automake::Variable::define ($silent_var, VAR_AUTOMAKE, '', TRUE,
1152                                 $silent_val, '', INTERNAL, VAR_ASIS)
1153       if (! vardef ($silent_var, TRUE));
1154     Automake::Variable::define ($verbose_var, VAR_AUTOMAKE, '', TRUE,
1155                                 $verbose_val, '', INTERNAL, VAR_ASIS)
1156       if (! vardef ($verbose_var, TRUE));
1157 }
1158
1159 # Above should not be needed in the general automake code.
1160
1161 # verbose_flag (NAME)
1162 # -------------------
1163 # Contents of %VERBOSE%: variable to expand before rule command.
1164 sub verbose_flag ($)
1165 {
1166     my ($name) = @_;
1167     return '$(' . verbose_var ($name) . ')';
1168 }
1169
1170 sub verbose_nodep_flag ($)
1171 {
1172     my ($name) = @_;
1173     return '$(' . verbose_var ($name) . subst ('am__nodep') . ')';
1174 }
1175
1176 # silent_flag
1177 # -----------
1178 # Contents of %SILENT%: variable to expand to '@' when silent.
1179 sub silent_flag ()
1180 {
1181     return verbose_flag ('at');
1182 }
1183
1184 # define_verbose_tagvar (NAME)
1185 # ----------------------------
1186 # Engage the needed silent rules machinery for tag NAME.
1187 sub define_verbose_tagvar ($)
1188 {
1189     my ($name) = @_;
1190     define_verbose_var ($name, '@echo "  '. $name . ' ' x (8 - length ($name)) . '" $@;');
1191 }
1192
1193 # define_verbose_texinfo
1194 # ----------------------
1195 # Engage the needed silent rules machinery for assorted texinfo commands.
1196 sub define_verbose_texinfo ()
1197 {
1198   my @tagvars = ('DVIPS', 'MAKEINFO', 'INFOHTML', 'TEXI2DVI', 'TEXI2PDF');
1199   foreach my $tag (@tagvars)
1200     {
1201       define_verbose_tagvar($tag);
1202     }
1203   define_verbose_var('texinfo', '-q');
1204   define_verbose_var('texidevnull', '> /dev/null');
1205 }
1206
1207 # define_verbose_libtool
1208 # ----------------------
1209 # Engage the needed silent rules machinery for 'libtool --silent'.
1210 sub define_verbose_libtool ()
1211 {
1212     define_verbose_var ('lt', '--silent');
1213     return verbose_flag ('lt');
1214 }
1215
1216 sub handle_silent ()
1217 {
1218     # Define "$(AM_V_P)", expanding to a shell conditional that can be
1219     # used in make recipes to determine whether we are being run in
1220     # silent mode or not.  The choice of the name derives from the LISP
1221     # convention of appending the letter 'P' to denote a predicate (see
1222     # also "the '-P' convention" in the Jargon File); we do so for lack
1223     # of a better convention.
1224     define_verbose_var ('P', 'false', ':');
1225     # *Always* provide the user with '$(AM_V_GEN)', unconditionally.
1226     define_verbose_tagvar ('GEN');
1227     define_verbose_var ('at', '@');
1228 }
1229
1230
1231 ################################################################
1232
1233
1234 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1235 sub handle_options
1236 {
1237   my $var = var ('AUTOMAKE_OPTIONS');
1238   if ($var)
1239     {
1240       if ($var->has_conditional_contents)
1241         {
1242           msg_var ('unsupported', $var,
1243                    "'AUTOMAKE_OPTIONS' cannot have conditional contents");
1244         }
1245       my @options = map { { option => $_->[1], where => $_->[0] } }
1246                         $var->value_as_list_recursive (cond_filter => TRUE,
1247                                                        location => 1);
1248       return 1 if process_option_list (@options);
1249     }
1250
1251   if ($strictness == GNITS)
1252     {
1253       set_option ('readme-alpha', INTERNAL);
1254       set_option ('std-options', INTERNAL);
1255       set_option ('check-news', INTERNAL);
1256     }
1257
1258   return 0;
1259 }
1260
1261 # shadow_unconditionally ($varname, $where)
1262 # -----------------------------------------
1263 # Return a $(variable) that contains all possible values
1264 # $varname can take.
1265 # If the VAR wasn't defined conditionally, return $(VAR).
1266 # Otherwise we create an am__VAR_DIST variable which contains
1267 # all possible values, and return $(am__VAR_DIST).
1268 sub shadow_unconditionally ($$)
1269 {
1270   my ($varname, $where) = @_;
1271   my $var = var $varname;
1272   if ($var->has_conditional_contents)
1273     {
1274       $varname = "am__${varname}_DIST";
1275       my @files = uniq ($var->value_as_list_recursive);
1276       define_pretty_variable ($varname, TRUE, $where, @files);
1277     }
1278   return "\$($varname)"
1279 }
1280
1281 # check_user_variables (@LIST)
1282 # ----------------------------
1283 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1284 # otherwise.
1285 sub check_user_variables (@)
1286 {
1287   my @dont_override = @_;
1288   foreach my $flag (@dont_override)
1289     {
1290       my $var = var $flag;
1291       if ($var)
1292         {
1293           for my $cond ($var->conditions->conds)
1294             {
1295               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1296                 {
1297                   msg_cond_var ('gnu', $cond, $flag,
1298                                 "'$flag' is a user variable, "
1299                                 . "you should not override it;\n"
1300                                 . "use 'AM_$flag' instead");
1301                 }
1302             }
1303         }
1304     }
1305 }
1306
1307 # Call finish function for each language that was used.
1308 sub handle_languages
1309 {
1310     if (! option 'no-dependencies')
1311     {
1312         # Include auto-dep code.  Don't include it if DEP_FILES would
1313         # be empty.
1314         if (keys %extension_seen && keys %dep_files)
1315         {
1316             # Set location of depcomp.
1317             &define_variable ('depcomp',
1318                               "\$(SHELL) $am_config_aux_dir/depcomp",
1319                               INTERNAL);
1320             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1321
1322             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1323
1324             my @deplist = sort keys %dep_files;
1325             # Generate each 'include' individually.  Irix 6 make will
1326             # not properly include several files resulting from a
1327             # variable expansion; generating many separate includes
1328             # seems safest.
1329             $output_rules .= "\n";
1330             foreach my $iter (@deplist)
1331             {
1332                 $output_rules .= (subst ('AMDEP_TRUE')
1333                                   . subst ('am__include')
1334                                   . ' '
1335                                   . subst ('am__quote')
1336                                   . $iter
1337                                   . subst ('am__quote')
1338                                   . "\n");
1339             }
1340
1341             # Compute the set of directories to remove in distclean-depend.
1342             my @depdirs = uniq (map { dirname ($_) } @deplist);
1343             $output_rules .= &file_contents ('depend',
1344                                              new Automake::Location,
1345                                              DEPDIRS => "@depdirs");
1346         }
1347     }
1348     else
1349     {
1350         &define_variable ('depcomp', '', INTERNAL);
1351         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1352     }
1353
1354     my %done;
1355
1356     # Is the C linker needed?
1357     my $needs_c = 0;
1358     foreach my $ext (sort keys %extension_seen)
1359     {
1360         next unless $extension_map{$ext};
1361
1362         my $lang = $languages{$extension_map{$ext}};
1363
1364         my $rule_file = $lang->rule_file || 'depend2';
1365
1366         # Get information on $LANG.
1367         my $pfx = $lang->autodep;
1368         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1369
1370         my ($AMDEP, $FASTDEP) =
1371           (option 'no-dependencies' || $lang->autodep eq 'no')
1372           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1373
1374         my $verbose = verbose_flag ($lang->ccer || 'GEN');
1375         my $verbose_nodep = ($AMDEP eq 'FALSE')
1376           ? $verbose : verbose_nodep_flag ($lang->ccer || 'GEN');
1377         my $silent = silent_flag ();
1378
1379         my %transform = ('EXT'     => $ext,
1380                          'PFX'     => $pfx,
1381                          'FPFX'    => $fpfx,
1382                          'AMDEP'   => $AMDEP,
1383                          'FASTDEP' => $FASTDEP,
1384                          '-c'      => $lang->compile_flag || '',
1385                          # These are not used, but they need to be defined
1386                          # so &transform do not complain.
1387                          SUBDIROBJ     => 0,
1388                          'DERIVED-EXT' => 'BUG',
1389                          DIST_SOURCE   => 1,
1390                          VERBOSE   => $verbose,
1391                          'VERBOSE-NODEP' => $verbose_nodep,
1392                          SILENT    => $silent,
1393                         );
1394
1395         # Generate the appropriate rules for this extension.
1396         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1397             || defined $lang->compile)
1398         {
1399             # Some C compilers don't support -c -o.  Use it only if really
1400             # needed.
1401             my $output_flag = $lang->output_flag || '';
1402             $output_flag = '-o'
1403               if (! $output_flag
1404                   && $lang->name eq 'c'
1405                   && option 'subdir-objects');
1406
1407             # Compute a possible derived extension.
1408             # This is not used by depend2.am.
1409             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1410
1411             # When we output an inference rule like '.c.o:' we
1412             # have two cases to consider: either subdir-objects
1413             # is used, or it is not.
1414             #
1415             # In the latter case the rule is used to build objects
1416             # in the current directory, and dependencies always
1417             # go into './$(DEPDIR)/'.  We can hard-code this value.
1418             #
1419             # In the former case the rule can be used to build
1420             # objects in sub-directories too.  Dependencies should
1421             # go into the appropriate sub-directories, e.g.,
1422             # 'sub/$(DEPDIR)/'.  The value of this directory
1423             # needs to be computed on-the-fly.
1424             #
1425             # DEPBASE holds the name of this directory, plus the
1426             # basename part of the object file (extensions Po, TPo,
1427             # Plo, TPlo will be added later as appropriate).  It is
1428             # either hardcoded, or a shell variable ('$depbase') that
1429             # will be computed by the rule.
1430             my $depbase =
1431               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1432             $output_rules .=
1433               file_contents ($rule_file,
1434                              new Automake::Location,
1435                              %transform,
1436                              GENERIC   => 1,
1437
1438                              'DERIVED-EXT' => $der_ext,
1439
1440                              DEPBASE   => $depbase,
1441                              BASE      => '$*',
1442                              SOURCE    => '$<',
1443                              SOURCEFLAG => $sourceflags{$ext} || '',
1444                              OBJ       => '$@',
1445                              OBJOBJ    => '$@',
1446                              LTOBJ     => '$@',
1447
1448                              COMPILE   => '$(' . $lang->compiler . ')',
1449                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1450                              -o        => $output_flag,
1451                              SUBDIROBJ => !! option 'subdir-objects');
1452         }
1453
1454         # Now include code for each specially handled object with this
1455         # language.
1456         my %seen_files = ();
1457         foreach my $file (@{$lang_specific_files{$lang->name}})
1458         {
1459             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1460
1461             # We might see a given object twice, for instance if it is
1462             # used under different conditions.
1463             next if defined $seen_files{$obj};
1464             $seen_files{$obj} = 1;
1465
1466             prog_error ("found " . $lang->name .
1467                         " in handle_languages, but compiler not defined")
1468               unless defined $lang->compile;
1469
1470             my $obj_compile = $lang->compile;
1471
1472             # Rewrite each occurrence of 'AM_$flag' in the compile
1473             # rule into '${derived}_$flag' if it exists.
1474             for my $flag (@{$lang->flags})
1475               {
1476                 my $val = "${derived}_$flag";
1477                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1478                   if set_seen ($val);
1479               }
1480
1481             my $libtool_tag = '';
1482             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1483               {
1484                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1485               }
1486
1487             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1488             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1489
1490             my $ltverbose = define_verbose_libtool ();
1491             my $obj_ltcompile =
1492               "\$(LIBTOOL) $ltverbose $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1493               . "--mode=compile $obj_compile";
1494
1495             # We _need_ '-o' for per object rules.
1496             my $output_flag = $lang->output_flag || '-o';
1497
1498             my $depbase = dirname ($obj);
1499             $depbase = ''
1500                 if $depbase eq '.';
1501             $depbase .= '/'
1502                 unless $depbase eq '';
1503             $depbase .= '$(DEPDIR)/' . basename ($obj);
1504
1505             $output_rules .=
1506               file_contents ($rule_file,
1507                              new Automake::Location,
1508                              %transform,
1509                              GENERIC   => 0,
1510
1511                              DEPBASE   => $depbase,
1512                              BASE      => $obj,
1513                              SOURCE    => $source,
1514                              SOURCEFLAG => $sourceflags{$srcext} || '',
1515                              # Use $myext and not '.o' here, in case
1516                              # we are actually building a new source
1517                              # file -- e.g. via yacc.
1518                              OBJ       => "$obj$myext",
1519                              OBJOBJ    => "$obj.obj",
1520                              LTOBJ     => "$obj.lo",
1521
1522                              VERBOSE   => $verbose,
1523                              'VERBOSE-NODEP'  => $verbose_nodep,
1524                              SILENT    => $silent,
1525                              COMPILE   => $obj_compile,
1526                              LTCOMPILE => $obj_ltcompile,
1527                              -o        => $output_flag,
1528                              %file_transform);
1529         }
1530
1531         # The rest of the loop is done once per language.
1532         next if defined $done{$lang};
1533         $done{$lang} = 1;
1534
1535         # Load the language dependent Makefile chunks.
1536         my %lang = map { uc ($_) => 0 } keys %languages;
1537         $lang{uc ($lang->name)} = 1;
1538         $output_rules .= file_contents ('lang-compile',
1539                                         new Automake::Location,
1540                                         %transform, %lang);
1541
1542         # If the source to a program consists entirely of code from a
1543         # 'pure' language, for instance C++ or Fortran 77, then we
1544         # don't need the C compiler code.  However if we run into
1545         # something unusual then we do generate the C code.  There are
1546         # probably corner cases here that do not work properly.
1547         # People linking Java code to Fortran code deserve pain.
1548         $needs_c ||= ! $lang->pure;
1549
1550         define_compiler_variable ($lang)
1551           if ($lang->compile);
1552
1553         define_linker_variable ($lang)
1554           if ($lang->link);
1555
1556         require_variables ("$am_file.am", $lang->Name . " source seen",
1557                            TRUE, @{$lang->config_vars});
1558
1559         # Call the finisher.
1560         $lang->finish;
1561
1562         # Flags listed in '->flags' are user variables (per GNU Standards),
1563         # they should not be overridden in the Makefile...
1564         my @dont_override = @{$lang->flags};
1565         # ... and so is LDFLAGS.
1566         push @dont_override, 'LDFLAGS' if $lang->link;
1567
1568         check_user_variables @dont_override;
1569     }
1570
1571     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1572     # suffix rule was learned), don't bother with the C stuff.  But if
1573     # anything else creeps in, then use it.
1574     $needs_c = 1
1575       if $need_link || suffix_rules_count > 1;
1576
1577     if ($needs_c)
1578       {
1579         &define_compiler_variable ($languages{'c'})
1580           unless defined $done{$languages{'c'}};
1581         define_linker_variable ($languages{'c'});
1582       }
1583 }
1584
1585
1586 # append_exeext { PREDICATE } $MACRO
1587 # ----------------------------------
1588 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1589 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1590 # ignored.
1591 #
1592 # This is typically used on all filenames of *_PROGRAMS, and filenames
1593 # of TESTS that are programs.
1594 sub append_exeext (&$)
1595 {
1596   my ($pred, $macro) = @_;
1597
1598   transform_variable_recursively
1599     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1600      sub {
1601        my ($subvar, $val, $cond, $full_cond) = @_;
1602        # Append $(EXEEXT) unless the user did it already, or it's a
1603        # @substitution@.
1604        $val .= '$(EXEEXT)'
1605          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1606        return $val;
1607      });
1608 }
1609
1610
1611 # Check to make sure a source defined in LIBOBJS is not explicitly
1612 # mentioned.  This is a separate function (as opposed to being inlined
1613 # in handle_source_transform) because it isn't always appropriate to
1614 # do this check.
1615 sub check_libobjs_sources
1616 {
1617   my ($one_file, $unxformed) = @_;
1618
1619   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1620                       'dist_EXTRA_', 'nodist_EXTRA_')
1621     {
1622       my @files;
1623       my $varname = $prefix . $one_file . '_SOURCES';
1624       my $var = var ($varname);
1625       if ($var)
1626         {
1627           @files = $var->value_as_list_recursive;
1628         }
1629       elsif ($prefix eq '')
1630         {
1631           @files = ($unxformed . '.c');
1632         }
1633       else
1634         {
1635           next;
1636         }
1637
1638       foreach my $file (@files)
1639         {
1640           err_var ($prefix . $one_file . '_SOURCES',
1641                    "automatically discovered file '$file' should not" .
1642                    " be explicitly mentioned")
1643             if defined $libsources{$file};
1644         }
1645     }
1646 }
1647
1648
1649 # @OBJECTS
1650 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1651 # -----------------------------------------------------------------------------
1652 # Does much of the actual work for handle_source_transform.
1653 # Arguments are:
1654 #   $VAR is the name of the variable that the source filenames come from
1655 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1656 #   $DERIVED is the name of resulting executable or library
1657 #   $OBJ is the object extension (e.g., '.lo')
1658 #   $FILE the source file to transform
1659 #   %TRANSFORM contains extras arguments to pass to file_contents
1660 #     when producing explicit rules
1661 # Result is a list of the names of objects
1662 # %linkers_used will be updated with any linkers needed
1663 sub handle_single_transform ($$$$$%)
1664 {
1665     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1666     my @files = ($_file);
1667     my @result = ();
1668
1669     # Turn sources into objects.  We use a while loop like this
1670     # because we might add to @files in the loop.
1671     while (scalar @files > 0)
1672     {
1673         $_ = shift @files;
1674
1675         # Configure substitutions in _SOURCES variables are errors.
1676         if (/^\@.*\@$/)
1677         {
1678           my $parent_msg = '';
1679           $parent_msg = "\nand is referred to from '$topparent'"
1680             if $topparent ne $var->name;
1681           err_var ($var,
1682                    "'" . $var->name . "' includes configure substitution '$_'"
1683                    . $parent_msg . ";\nconfigure " .
1684                    "substitutions are not allowed in _SOURCES variables");
1685           next;
1686         }
1687
1688         # If the source file is in a subdirectory then the '.o' is put
1689         # into the current directory, unless the subdir-objects option
1690         # is in effect.
1691
1692         # Split file name into base and extension.
1693         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1694         my $full = $_;
1695         my $directory = $1 || '';
1696         my $base = $2;
1697         my $extension = $3;
1698
1699         # We must generate a rule for the object if it requires its own flags.
1700         my $renamed = 0;
1701         my ($linker, $object);
1702
1703         # This records whether we've seen a derived source file (e.g.
1704         # yacc output).
1705         my $derived_source = 0;
1706
1707         # This holds the 'aggregate context' of the file we are
1708         # currently examining.  If the file is compiled with
1709         # per-object flags, then it will be the name of the object.
1710         # Otherwise it will be 'AM'.  This is used by the target hook
1711         # language function.
1712         my $aggregate = 'AM';
1713
1714         $extension = &derive_suffix ($extension, $obj);
1715         my $lang;
1716         if ($extension_map{$extension} &&
1717             ($lang = $languages{$extension_map{$extension}}))
1718         {
1719             # Found the language, so see what it says.
1720             &saw_extension ($extension);
1721
1722             # Do we have per-executable flags for this executable?
1723             my $have_per_exec_flags = 0;
1724             my @peflags = @{$lang->flags};
1725             push @peflags, 'LIBTOOLFLAGS' if $obj eq '.lo';
1726             foreach my $flag (@peflags)
1727               {
1728                 if (set_seen ("${derived}_$flag"))
1729                   {
1730                     $have_per_exec_flags = 1;
1731                     last;
1732                   }
1733               }
1734
1735             # Note: computed subr call.  The language rewrite function
1736             # should return one of the LANG_* constants.  It could
1737             # also return a list whose first value is such a constant
1738             # and whose second value is a new source extension which
1739             # should be applied.  This means this particular language
1740             # generates another source file which we must then process
1741             # further.
1742             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1743             my ($r, $source_extension)
1744                 = &$subr ($directory, $base, $extension,
1745                           $obj, $have_per_exec_flags, $var);
1746             # Skip this entry if we were asked not to process it.
1747             next if $r == LANG_IGNORE;
1748
1749             # Now extract linker and other info.
1750             $linker = $lang->linker;
1751
1752             my $this_obj_ext;
1753             if (defined $source_extension)
1754             {
1755                 $this_obj_ext = $source_extension;
1756                 $derived_source = 1;
1757             }
1758             else
1759             {
1760                 $this_obj_ext = $obj;
1761             }
1762             $object = $base . $this_obj_ext;
1763
1764             if ($have_per_exec_flags)
1765             {
1766                 # We have a per-executable flag in effect for this
1767                 # object.  In this case we rewrite the object's
1768                 # name to ensure it is unique.
1769
1770                 # We choose the name 'DERIVED_OBJECT' to ensure
1771                 # (1) uniqueness, and (2) continuity between
1772                 # invocations.  However, this will result in a
1773                 # name that is too long for losing systems, in
1774                 # some situations.  So we provide _SHORTNAME to
1775                 # override.
1776
1777                 my $dname = $derived;
1778                 my $var = var ($derived . '_SHORTNAME');
1779                 if ($var)
1780                 {
1781                     # FIXME: should use the same Condition as
1782                     # the _SOURCES variable.  But this is really
1783                     # silly overkill -- nobody should have
1784                     # conditional shortnames.
1785                     $dname = $var->variable_value;
1786                 }
1787                 $object = $dname . '-' . $object;
1788
1789                 prog_error ($lang->name . " flags defined without compiler")
1790                   if ! defined $lang->compile;
1791
1792                 $renamed = 1;
1793             }
1794
1795             # If rewrite said it was ok, put the object into a
1796             # subdir.
1797             if ($r == LANG_SUBDIR && $directory ne '')
1798             {
1799                 $object = $directory . '/' . $object;
1800             }
1801
1802             # If the object file has been renamed (because per-target
1803             # flags are used) we cannot compile the file with an
1804             # inference rule: we need an explicit rule.
1805             #
1806             # If the source is in a subdirectory and the object is in
1807             # the current directory, we also need an explicit rule.
1808             #
1809             # If both source and object files are in a subdirectory
1810             # (this happens when the subdir-objects option is used),
1811             # then the inference will work.
1812             #
1813             # The latter case deserves a historical note.  When the
1814             # subdir-objects option was added on 1999-04-11 it was
1815             # thought that inferences rules would work for
1816             # subdirectory objects too.  Later, on 1999-11-22,
1817             # automake was changed to output explicit rules even for
1818             # subdir-objects.  Nobody remembers why, but this occurred
1819             # soon after the merge of the user-dep-gen-branch so it
1820             # might be related.  In late 2003 people complained about
1821             # the size of the generated Makefile.ins (libgcj, with
1822             # 2200+ subdir objects was reported to have a 9MB
1823             # Makefile), so we now rely on inference rules again.
1824             # Maybe we'll run across the same issue as in the past,
1825             # but at least this time we can document it.  However since
1826             # dependency tracking has evolved it is possible that
1827             # our old problem no longer exists.
1828             # Using inference rules for subdir-objects has been tested
1829             # with GNU make, Solaris make, Ultrix make, BSD make,
1830             # HP-UX make, and OSF1 make successfully.
1831             if ($renamed
1832                 || ($directory ne '' && ! option 'subdir-objects')
1833                 # We must also use specific rules for a nodist_ source
1834                 # if its language requests it.
1835                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1836             {
1837                 my $obj_sans_ext = substr ($object, 0,
1838                                            - length ($this_obj_ext));
1839                 my $full_ansi;
1840                 if ($directory ne '')
1841                   {
1842                         $full_ansi = $directory . '/' . $base . $extension;
1843                   }
1844                 else
1845                   {
1846                         $full_ansi = $base . $extension;
1847                   }
1848
1849                 my @specifics = ($full_ansi, $obj_sans_ext,
1850                                  # Only use $this_obj_ext in the derived
1851                                  # source case because in the other case we
1852                                  # *don't* want $(OBJEXT) to appear here.
1853                                  ($derived_source ? $this_obj_ext : '.o'),
1854                                  $extension);
1855
1856                 # If we renamed the object then we want to use the
1857                 # per-executable flag name.  But if this is simply a
1858                 # subdir build then we still want to use the AM_ flag
1859                 # name.
1860                 if ($renamed)
1861                   {
1862                     unshift @specifics, $derived;
1863                     $aggregate = $derived;
1864                   }
1865                 else
1866                   {
1867                     unshift @specifics, 'AM';
1868                   }
1869
1870                 # Each item on this list is a reference to a list consisting
1871                 # of four values followed by additional transform flags for
1872                 # file_contents.  The four values are the derived flag prefix
1873                 # (e.g. for 'foo_CFLAGS', it is 'foo'), the name of the
1874                 # source file, the base name of the output file, and
1875                 # the extension for the object file.
1876                 push (@{$lang_specific_files{$lang->name}},
1877                       [@specifics, %transform]);
1878             }
1879         }
1880         elsif ($extension eq $obj)
1881         {
1882             # This is probably the result of a direct suffix rule.
1883             # In this case we just accept the rewrite.
1884             $object = "$base$extension";
1885             $object = "$directory/$object" if $directory ne '';
1886             $linker = '';
1887         }
1888         else
1889         {
1890             # No error message here.  Used to have one, but it was
1891             # very unpopular.
1892             # FIXME: we could potentially do more processing here,
1893             # perhaps treating the new extension as though it were a
1894             # new source extension (as above).  This would require
1895             # more restructuring than is appropriate right now.
1896             next;
1897         }
1898
1899         err_am "object '$object' created by '$full' and '$object_map{$object}'"
1900           if (defined $object_map{$object}
1901               && $object_map{$object} ne $full);
1902
1903         my $comp_val = (($object =~ /\.lo$/)
1904                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1905         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1906         if (defined $object_compilation_map{$comp_obj}
1907             && $object_compilation_map{$comp_obj} != 0
1908             # Only see the error once.
1909             && ($object_compilation_map{$comp_obj}
1910                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1911             && $object_compilation_map{$comp_obj} != $comp_val)
1912           {
1913             err_am "object '$comp_obj' created both with libtool and without";
1914           }
1915         $object_compilation_map{$comp_obj} |= $comp_val;
1916
1917         if (defined $lang)
1918         {
1919             # Let the language do some special magic if required.
1920             $lang->target_hook ($aggregate, $object, $full, %transform);
1921         }
1922
1923         if ($derived_source)
1924           {
1925             prog_error ($lang->name . " has automatic dependency tracking")
1926               if $lang->autodep ne 'no';
1927             # Make sure this new source file is handled next.  That will
1928             # make it appear to be at the right place in the list.
1929             unshift (@files, $object);
1930             # Distribute derived sources unless the source they are
1931             # derived from is not.
1932             &push_dist_common ($object)
1933               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1934             next;
1935           }
1936
1937         $linkers_used{$linker} = 1;
1938
1939         push (@result, $object);
1940
1941         if (! defined $object_map{$object})
1942         {
1943             my @dep_list = ();
1944             $object_map{$object} = $full;
1945
1946             # If resulting object is in subdir, we need to make
1947             # sure the subdir exists at build time.
1948             if ($object =~ /\//)
1949             {
1950                 # FIXME: check that $DIRECTORY is somewhere in the
1951                 # project
1952
1953                 # For Java, the way we're handling it right now, a
1954                 # '..' component doesn't make sense.
1955                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1956                   {
1957                     err_am "'$full' should not contain a '..' component";
1958                   }
1959
1960                 # Make sure *all* objects files in the subdirectory are
1961                 # removed by "make mostlyclean".  Not only this is more
1962                 # efficient than listing the object files to be removed
1963                 # individually (which would cause an 'rm' invocation for
1964                 # each of them -- very inefficient, see bug#10697), it
1965                 # would also leave stale object files in the subdirectory
1966                 # whenever a source file there is removed or renamed.
1967                 $compile_clean_files{"$directory/*.\$(OBJEXT)"} = MOSTLY_CLEAN;
1968                 if ($object =~ /\.lo$/)
1969                   {
1970                     # If we have a libtool object, then we also must remove
1971                     # any '.lo' objects in its same subdirectory.
1972                     $compile_clean_files{"$directory/*.lo"} = MOSTLY_CLEAN;
1973                     # Remember to cleanup .libs/ in this directory.
1974                     $libtool_clean_directories{$directory} = 1;
1975                   }
1976
1977                 push (@dep_list, require_build_directory ($directory));
1978
1979                 # If we're generating dependencies, we also want
1980                 # to make sure that the appropriate subdir of the
1981                 # .deps directory is created.
1982                 push (@dep_list,
1983                       require_build_directory ($directory . '/$(DEPDIR)'))
1984                   unless option 'no-dependencies';
1985             }
1986
1987             &pretty_print_rule ($object . ':', "\t", @dep_list)
1988                 if scalar @dep_list > 0;
1989         }
1990
1991         # Transform .o or $o file into .P file (for automatic
1992         # dependency code).
1993         # Properly flatten multiple adjacent slashes, as Solaris 10 make
1994         # might fail over them in an include statement.
1995         # Leading double slashes may be special, as per Posix, so deal
1996         # with them carefully.
1997         if ($lang && $lang->autodep ne 'no')
1998         {
1999             my $depfile = $object;
2000             $depfile =~ s/\.([^.]*)$/.P$1/;
2001             $depfile =~ s/\$\(OBJEXT\)$/o/;
2002             my $maybe_extra_leading_slash = '';
2003             $maybe_extra_leading_slash = '/' if $depfile =~ m,^//[^/],;
2004             $depfile =~ s,/+,/,g;
2005             my $basename = basename ($depfile);
2006             # This might make $dirname empty, but we account for that below.
2007             (my $dirname = dirname ($depfile)) =~ s/\/*$//;
2008             $dirname = $maybe_extra_leading_slash . $dirname;
2009             $dep_files{$dirname . '/$(DEPDIR)/' . $basename} = 1;
2010         }
2011     }
2012
2013     return @result;
2014 }
2015
2016
2017 # $LINKER
2018 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
2019 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
2020 # ---------------------------------------------------------------------------
2021 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
2022 #
2023 # Arguments are:
2024 #   $VAR is the name of the _SOURCES variable
2025 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
2026 #     it will be generated and returned).
2027 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
2028 #     work done to determine the linker will be).
2029 #   $ONE_FILE is the canonical (transformed) name of object to build
2030 #   $OBJ is the object extension (i.e. either '.o' or '.lo').
2031 #   $TOPPARENT is the _SOURCES variable being processed.
2032 #   $WHERE context into which this definition is done
2033 #   %TRANSFORM extra arguments to pass to file_contents when producing
2034 #     rules
2035 #
2036 # Result is a pair ($LINKER, $OBJVAR):
2037 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
2038 sub define_objects_from_sources ($$$$$$$%)
2039 {
2040   my ($var, $objvar, $nodefine, $one_file,
2041       $obj, $topparent, $where, %transform) = @_;
2042
2043   my $needlinker = "";
2044
2045   transform_variable_recursively
2046     ($var, $objvar, 'am__objects', $nodefine, $where,
2047      # The transform code to run on each filename.
2048      sub {
2049        my ($subvar, $val, $cond, $full_cond) = @_;
2050        my @trans = handle_single_transform ($subvar, $topparent,
2051                                             $one_file, $obj, $val,
2052                                             %transform);
2053        $needlinker = "true" if @trans;
2054        return @trans;
2055      });
2056
2057   return $needlinker;
2058 }
2059
2060
2061 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
2062 # -----------------------------------------------------------------------------
2063 # Handle SOURCE->OBJECT transform for one program or library.
2064 # Arguments are:
2065 #   canonical (transformed) name of target to build
2066 #   actual target of object to build
2067 #   object extension (i.e., either '.o' or '$o')
2068 #   location of the source variable
2069 #   extra arguments to pass to file_contents when producing rules
2070 # Return the name of the linker variable that must be used.
2071 # Empty return means just use 'LINK'.
2072 sub handle_source_transform ($$$$%)
2073 {
2074     # one_file is canonical name.  unxformed is given name.  obj is
2075     # object extension.
2076     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
2077
2078     my $linker = '';
2079
2080     # No point in continuing if _OBJECTS is defined.
2081     return if reject_var ($one_file . '_OBJECTS',
2082                           $one_file . '_OBJECTS should not be defined');
2083
2084     my %used_pfx = ();
2085     my $needlinker;
2086     %linkers_used = ();
2087     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2088                         'dist_EXTRA_', 'nodist_EXTRA_')
2089     {
2090         my $varname = $prefix . $one_file . "_SOURCES";
2091         my $var = var $varname;
2092         next unless $var;
2093
2094         # We are going to define _OBJECTS variables using the prefix.
2095         # Then we glom them all together.  So we can't use the null
2096         # prefix here as we need it later.
2097         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2098
2099         # Keep track of which prefixes we saw.
2100         $used_pfx{$xpfx} = 1
2101           unless $prefix =~ /EXTRA_/;
2102
2103         push @sources, "\$($varname)";
2104         push @dist_sources, shadow_unconditionally ($varname, $where)
2105           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2106
2107         $needlinker |=
2108             define_objects_from_sources ($varname,
2109                                          $xpfx . $one_file . '_OBJECTS',
2110                                          $prefix =~ /EXTRA_/,
2111                                          $one_file, $obj, $varname, $where,
2112                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2113                                          %transform);
2114     }
2115     if ($needlinker)
2116     {
2117         $linker ||= &resolve_linker (%linkers_used);
2118     }
2119
2120     my @keys = sort keys %used_pfx;
2121     if (scalar @keys == 0)
2122     {
2123         # The default source for libfoo.la is libfoo.c, but for
2124         # backward compatibility we first look at libfoo_la.c,
2125         # if no default source suffix is given.
2126         my $old_default_source = "$one_file.c";
2127         my $ext_var = var ('AM_DEFAULT_SOURCE_EXT');
2128         my $default_source_ext = $ext_var ? variable_value ($ext_var) : '.c';
2129         msg_var ('unsupported', $ext_var, $ext_var->name . " can assume at most one value")
2130           if $default_source_ext =~ /[\t ]/;
2131         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,$default_source_ext,;
2132         if ($old_default_source ne $default_source
2133             && !$ext_var
2134             && (rule $old_default_source
2135                 || rule '$(srcdir)/' . $old_default_source
2136                 || rule '${srcdir}/' . $old_default_source
2137                 || -f $old_default_source))
2138           {
2139             my $loc = $where->clone;
2140             $loc->pop_context;
2141             msg ('obsolete', $loc,
2142                  "the default source for '$unxformed' has been changed "
2143                  . "to '$default_source'.\n(Using '$old_default_source' for "
2144                  . "backward compatibility.)");
2145             $default_source = $old_default_source;
2146           }
2147         # If a rule exists to build this source with a $(srcdir)
2148         # prefix, use that prefix in our variables too.  This is for
2149         # the sake of BSD Make.
2150         if (rule '$(srcdir)/' . $default_source
2151             || rule '${srcdir}/' . $default_source)
2152           {
2153             $default_source = '$(srcdir)/' . $default_source;
2154           }
2155
2156         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2157         push (@sources, $default_source);
2158         push (@dist_sources, $default_source);
2159
2160         %linkers_used = ();
2161         my (@result) =
2162           handle_single_transform ($one_file . '_SOURCES',
2163                                    $one_file . '_SOURCES',
2164                                    $one_file, $obj,
2165                                    $default_source, %transform);
2166         $linker ||= &resolve_linker (%linkers_used);
2167         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2168     }
2169     else
2170     {
2171         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2172         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2173     }
2174
2175     # If we want to use 'LINK' we must make sure it is defined.
2176     if ($linker eq '')
2177     {
2178         $need_link = 1;
2179     }
2180
2181     return $linker;
2182 }
2183
2184
2185 # handle_lib_objects ($XNAME, $VAR)
2186 # ---------------------------------
2187 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2188 # Also, generate _DEPENDENCIES variable if appropriate.
2189 # Arguments are:
2190 #   transformed name of object being built, or empty string if no object
2191 #   name of _LDADD/_LIBADD-type variable to examine
2192 # Returns 1 if LIBOBJS seen, 0 otherwise.
2193 sub handle_lib_objects
2194 {
2195   my ($xname, $varname) = @_;
2196
2197   my $var = var ($varname);
2198   prog_error "'$varname' undefined"
2199     unless $var;
2200   prog_error "unexpected variable name '$varname'"
2201     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2202   my $prefix = $1 || 'AM_';
2203
2204   my $seen_libobjs = 0;
2205   my $flagvar = 0;
2206
2207   transform_variable_recursively
2208     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2209      ! $xname, INTERNAL,
2210      # Transformation function, run on each filename.
2211      sub {
2212        my ($subvar, $val, $cond, $full_cond) = @_;
2213
2214        if ($val =~ /^-/)
2215          {
2216            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2217            if ($val !~ /^-[lL]/ &&
2218                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2219                # for Libtool libraries or programs.  (Actually we are a bit
2220                # lax here since this code also applies to non-libtool
2221                # libraries or programs, for which -dlopen and -dlopreopen
2222                # are pure nonsense.  Diagnosing this doesn't seem very
2223                # important: the developer will quickly get complaints from
2224                # the linker.)
2225                $val !~ /^-dl(?:pre)?open$/ &&
2226                # Only get this error once.
2227                ! $flagvar)
2228              {
2229                $flagvar = 1;
2230                # FIXME: should display a stack of nested variables
2231                # as context when $var != $subvar.
2232                err_var ($var, "linker flags such as '$val' belong in "
2233                         . "'${prefix}LDFLAGS'");
2234              }
2235            return ();
2236          }
2237        elsif ($val !~ /^\@.*\@$/)
2238          {
2239            # Assume we have a file of some sort, and output it into the
2240            # dependency variable.  Autoconf substitutions are not output;
2241            # rarely is a new dependency substituted into e.g. foo_LDADD
2242            # -- but bad things (e.g. -lX11) are routinely substituted.
2243            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2244            # and handled specially below.
2245            return $val;
2246          }
2247        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2248          {
2249            handle_LIBOBJS ($subvar, $cond, $1);
2250            $seen_libobjs = 1;
2251            return $val;
2252          }
2253        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2254          {
2255            handle_ALLOCA ($subvar, $cond, $1);
2256            return $val;
2257          }
2258        else
2259          {
2260            return ();
2261          }
2262      });
2263
2264   return $seen_libobjs;
2265 }
2266
2267 # handle_LIBOBJS_or_ALLOCA ($VAR)
2268 # -------------------------------
2269 # Definitions common to LIBOBJS and ALLOCA.
2270 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2271 sub handle_LIBOBJS_or_ALLOCA ($)
2272 {
2273   my ($var) = @_;
2274
2275   my $dir = '';
2276
2277   # If LIBOBJS files must be built in another directory we have
2278   # to define LIBOBJDIR and ensure the files get cleaned.
2279   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2280   # is achieved by 'rm -f *.$(OBJEXT)' in compile.am.
2281   if ($config_libobj_dir
2282       && $relative_dir ne $config_libobj_dir)
2283     {
2284       if (option 'subdir-objects')
2285         {
2286           # In the top-level Makefile we do not use $(top_builddir), because
2287           # we are already there, and since the targets are built without
2288           # a $(top_builddir), it helps BSD Make to match them with
2289           # dependencies.
2290           $dir = "$config_libobj_dir/"
2291             if $config_libobj_dir ne '.';
2292           $dir = backname ($relative_dir) . "/$dir"
2293             if $relative_dir ne '.';
2294           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2295           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2296           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2297           # be created by libtool as a side-effect of creating LTLIBOBJS).
2298           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2299         }
2300       else
2301         {
2302           error ("'\$($var)' cannot be used outside '$config_libobj_dir' if"
2303                  . " 'subdir-objects' is not set");
2304         }
2305     }
2306
2307   return $dir;
2308 }
2309
2310 sub handle_LIBOBJS ($$$)
2311 {
2312   my ($var, $cond, $lt) = @_;
2313   my $myobjext = $lt ? 'lo' : 'o';
2314   $lt ||= '';
2315
2316   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2317     if ! keys %libsources;
2318
2319   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2320
2321   foreach my $iter (keys %libsources)
2322     {
2323       if ($iter =~ /\.[cly]$/)
2324         {
2325           &saw_extension ($&);
2326           &saw_extension ('.c');
2327         }
2328
2329       if ($iter =~ /\.h$/)
2330         {
2331           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2332         }
2333       elsif ($iter ne 'alloca.c')
2334         {
2335           my $rewrite = $iter;
2336           $rewrite =~ s/\.c$/.P$myobjext/;
2337           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2338           $rewrite = "^" . quotemeta ($iter) . "\$";
2339           # Only require the file if it is not a built source.
2340           my $bs = var ('BUILT_SOURCES');
2341           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2342             {
2343               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2344             }
2345         }
2346     }
2347 }
2348
2349 sub handle_ALLOCA ($$$)
2350 {
2351   my ($var, $cond, $lt) = @_;
2352   my $myobjext = $lt ? 'lo' : 'o';
2353   $lt ||= '';
2354   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2355
2356   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2357   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2358   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2359   &saw_extension ('.c');
2360 }
2361
2362 # Canonicalize the input parameter
2363 sub canonicalize
2364 {
2365     my ($string) = @_;
2366     $string =~ tr/A-Za-z0-9_\@/_/c;
2367     return $string;
2368 }
2369
2370 # Canonicalize a name, and check to make sure the non-canonical name
2371 # is never used.  Returns canonical name.  Arguments are name and a
2372 # list of suffixes to check for.
2373 sub check_canonical_spelling
2374 {
2375   my ($name, @suffixes) = @_;
2376
2377   my $xname = &canonicalize ($name);
2378   if ($xname ne $name)
2379     {
2380       foreach my $xt (@suffixes)
2381         {
2382           reject_var ("$name$xt", "use '$xname$xt', not '$name$xt'");
2383         }
2384     }
2385
2386   return $xname;
2387 }
2388
2389
2390 # handle_compile ()
2391 # -----------------
2392 # Set up the compile suite.
2393 sub handle_compile ()
2394 {
2395    return if ! $must_handle_compiled_objects;
2396
2397     # Boilerplate.
2398     my $default_includes = '';
2399     if (! option 'nostdinc')
2400       {
2401         my @incs = ('-I.', subst ('am__isrc'));
2402
2403         my $var = var 'CONFIG_HEADER';
2404         if ($var)
2405           {
2406             foreach my $hdr (split (' ', $var->variable_value))
2407               {
2408                 push @incs, '-I' . dirname ($hdr);
2409               }
2410           }
2411         # We want '-I. -I$(srcdir)', but the latter -I is redundant
2412         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2413         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2414         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2415         # to just put @am__isrc@ right after '-I.', without a space.
2416         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2417       }
2418
2419     my (@mostly_rms, @dist_rms);
2420     foreach my $item (sort keys %compile_clean_files)
2421     {
2422         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2423         {
2424             push (@mostly_rms, "\t-rm -f $item");
2425         }
2426         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2427         {
2428             push (@dist_rms, "\t-rm -f $item");
2429         }
2430         else
2431         {
2432           prog_error 'invalid entry in %compile_clean_files';
2433         }
2434     }
2435
2436     my ($coms, $vars, $rules) =
2437       &file_contents_internal (1, "$libdir/am/compile.am",
2438                                new Automake::Location,
2439                                ('DEFAULT_INCLUDES' => $default_includes,
2440                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2441                                 'DISTRMS' => join ("\n", @dist_rms)));
2442     $output_vars .= $vars;
2443     $output_rules .= "$coms$rules";
2444 }
2445
2446 # handle_libtool ()
2447 # -----------------
2448 # Handle libtool rules.
2449 sub handle_libtool
2450 {
2451   return unless var ('LIBTOOL');
2452
2453   # Libtool requires some files, but only at top level.
2454   # (Starting with Libtool 2.0 we do not have to bother.  These
2455   # requirements are done with AC_REQUIRE_AUX_FILE.)
2456   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2457     if $relative_dir eq '.' && ! $libtool_new_api;
2458
2459   my @libtool_rms;
2460   foreach my $item (sort keys %libtool_clean_directories)
2461     {
2462       my $dir = ($item eq '.') ? '' : "$item/";
2463       # .libs is for Unix, _libs for DOS.
2464       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2465     }
2466
2467   check_user_variables 'LIBTOOLFLAGS';
2468
2469   # Output the libtool compilation rules.
2470   $output_rules .= &file_contents ('libtool',
2471                                    new Automake::Location,
2472                                    LTRMS => join ("\n", @libtool_rms));
2473 }
2474
2475 # handle_programs ()
2476 # ------------------
2477 # Handle C programs.
2478 sub handle_programs
2479 {
2480   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2481                                   'bin', 'sbin', 'libexec', 'pkglibexec',
2482                                   'noinst', 'check');
2483   return if ! @proglist;
2484   $must_handle_compiled_objects = 1;
2485
2486   my $seen_global_libobjs =
2487     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2488
2489   foreach my $pair (@proglist)
2490     {
2491       my ($where, $one_file) = @$pair;
2492
2493       my $seen_libobjs = 0;
2494       my $obj = '.$(OBJEXT)';
2495
2496       $known_programs{$one_file} = $where;
2497
2498       # Canonicalize names and check for misspellings.
2499       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2500                                              '_SOURCES', '_OBJECTS',
2501                                              '_DEPENDENCIES');
2502
2503       $where->push_context ("while processing program '$one_file'");
2504       $where->set (INTERNAL->get);
2505
2506       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2507                                              NONLIBTOOL => 1, LIBTOOL => 0);
2508
2509       if (var ($xname . "_LDADD"))
2510         {
2511           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2512         }
2513       else
2514         {
2515           # User didn't define prog_LDADD override.  So do it.
2516           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2517
2518           # This does a bit too much work.  But we need it to
2519           # generate _DEPENDENCIES when appropriate.
2520           if (var ('LDADD'))
2521             {
2522               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2523             }
2524         }
2525
2526       reject_var ($xname . '_LIBADD',
2527                   "use '${xname}_LDADD', not '${xname}_LIBADD'");
2528
2529       set_seen ($xname . '_DEPENDENCIES');
2530       set_seen ('EXTRA_' . $xname . '_DEPENDENCIES');
2531       set_seen ($xname . '_LDFLAGS');
2532
2533       # Determine program to use for link.
2534       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xname);
2535       $vlink = verbose_flag ($vlink || 'GEN');
2536
2537       # If the resulting program lies into a subdirectory,
2538       # make sure this directory will exist.
2539       my $dirstamp = require_build_directory_maybe ($one_file);
2540
2541       $libtool_clean_directories{dirname ($one_file)} = 1;
2542
2543       $output_rules .= &file_contents ('program',
2544                                        $where,
2545                                        PROGRAM  => $one_file,
2546                                        XPROGRAM => $xname,
2547                                        XLINK    => $xlink,
2548                                        VERBOSE  => $vlink,
2549                                        DIRSTAMP => $dirstamp,
2550                                        EXEEXT   => '$(EXEEXT)');
2551
2552       if ($seen_libobjs || $seen_global_libobjs)
2553         {
2554           if (var ($xname . '_LDADD'))
2555             {
2556               &check_libobjs_sources ($xname, $xname . '_LDADD');
2557             }
2558           elsif (var ('LDADD'))
2559             {
2560               &check_libobjs_sources ($xname, 'LDADD');
2561             }
2562         }
2563     }
2564 }
2565
2566
2567 # handle_libraries ()
2568 # -------------------
2569 # Handle libraries.
2570 sub handle_libraries
2571 {
2572   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2573                                  'lib', 'pkglib', 'noinst', 'check');
2574   return if ! @liblist;
2575   $must_handle_compiled_objects = 1;
2576
2577   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2578                                     'noinst', 'check');
2579
2580   if (@prefix)
2581     {
2582       my $var = rvar ($prefix[0] . '_LIBRARIES');
2583       $var->requires_variables ('library used', 'RANLIB');
2584     }
2585
2586   &define_variable ('AR', 'ar', INTERNAL);
2587   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2588   &define_verbose_tagvar ('AR');
2589
2590   foreach my $pair (@liblist)
2591     {
2592       my ($where, $onelib) = @$pair;
2593
2594       my $seen_libobjs = 0;
2595       # Check that the library fits the standard naming convention.
2596       my $bn = basename ($onelib);
2597       if ($bn !~ /^lib.*\.a$/)
2598         {
2599           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2600           my $suggestion = dirname ($onelib) . "/$bn";
2601           $suggestion =~ s|^\./||g;
2602           msg ('error-gnu/warn', $where,
2603                "'$onelib' is not a standard library name\n"
2604                . "did you mean '$suggestion'?")
2605         }
2606
2607       ($known_libraries{$onelib} = $bn) =~ s/\.a$//;
2608
2609       $where->push_context ("while processing library '$onelib'");
2610       $where->set (INTERNAL->get);
2611
2612       my $obj = '.$(OBJEXT)';
2613
2614       # Canonicalize names and check for misspellings.
2615       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2616                                             '_OBJECTS', '_DEPENDENCIES',
2617                                             '_AR');
2618
2619       if (! var ($xlib . '_AR'))
2620         {
2621           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2622         }
2623
2624       # Generate support for conditional object inclusion in
2625       # libraries.
2626       if (var ($xlib . '_LIBADD'))
2627         {
2628           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2629             {
2630               $seen_libobjs = 1;
2631             }
2632         }
2633       else
2634         {
2635           &define_variable ($xlib . "_LIBADD", '', $where);
2636         }
2637
2638       reject_var ($xlib . '_LDADD',
2639                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2640
2641       # Make sure we at look at this.
2642       set_seen ($xlib . '_DEPENDENCIES');
2643       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2644
2645       &handle_source_transform ($xlib, $onelib, $obj, $where,
2646                                 NONLIBTOOL => 1, LIBTOOL => 0);
2647
2648       # If the resulting library lies into a subdirectory,
2649       # make sure this directory will exist.
2650       my $dirstamp = require_build_directory_maybe ($onelib);
2651       my $verbose = verbose_flag ('AR');
2652       my $silent = silent_flag ();
2653
2654       $output_rules .= &file_contents ('library',
2655                                        $where,
2656                                        VERBOSE  => $verbose,
2657                                        SILENT   => $silent,
2658                                        LIBRARY  => $onelib,
2659                                        XLIBRARY => $xlib,
2660                                        DIRSTAMP => $dirstamp);
2661
2662       if ($seen_libobjs)
2663         {
2664           if (var ($xlib . '_LIBADD'))
2665             {
2666               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2667             }
2668         }
2669
2670       if (! $seen_ar)
2671         {
2672           msg ('extra-portability', $where,
2673                "'$onelib': linking libraries using a non-POSIX\n"
2674                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2675         }
2676     }
2677 }
2678
2679
2680 # handle_ltlibraries ()
2681 # ---------------------
2682 # Handle shared libraries.
2683 sub handle_ltlibraries
2684 {
2685   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2686                                  'noinst', 'lib', 'pkglib', 'check');
2687   return if ! @liblist;
2688   $must_handle_compiled_objects = 1;
2689
2690   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2691                                     'noinst', 'check');
2692
2693   if (@prefix)
2694     {
2695       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2696       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2697     }
2698
2699   my %instdirs = ();
2700   my %instsubdirs = ();
2701   my %instconds = ();
2702   my %liblocations = ();        # Location (in Makefile.am) of each library.
2703
2704   foreach my $key (@prefix)
2705     {
2706       # Get the installation directory of each library.
2707       my $dir = $key;
2708       my $strip_subdir = 1;
2709       if ($dir =~ /^nobase_/)
2710         {
2711           $dir =~ s/^nobase_//;
2712           $strip_subdir = 0;
2713         }
2714       my $var = rvar ($key . '_LTLIBRARIES');
2715
2716       # We reject libraries which are installed in several places
2717       # in the same condition, because we can only specify one
2718       # '-rpath' option.
2719       $var->traverse_recursively
2720         (sub
2721          {
2722            my ($var, $val, $cond, $full_cond) = @_;
2723            my $hcond = $full_cond->human;
2724            my $where = $var->rdef ($cond)->location;
2725            my $ldir = '';
2726            $ldir = '/' . dirname ($val)
2727              if (!$strip_subdir);
2728            # A library cannot be installed in different directories
2729            # in overlapping conditions.
2730            if (exists $instconds{$val})
2731              {
2732                my ($msg, $acond) =
2733                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2734
2735                if ($msg)
2736                  {
2737                    error ($where, $msg, partial => 1);
2738                    my $dirtxt = "installed " . ($strip_subdir ? "in" : "below") . " '$dir'";
2739                    $dirtxt = "built for '$dir'"
2740                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2741                    my $dircond =
2742                      $full_cond->true ? "" : " in condition $hcond";
2743
2744                    error ($where, "'$val' should be $dirtxt$dircond ...",
2745                           partial => 1);
2746
2747                    my $hacond = $acond->human;
2748                    my $adir = $instdirs{$val}{$acond};
2749                    my $adirtxt = "installed in '$adir'";
2750                    $adirtxt = "built for '$adir'"
2751                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2752                          || $adir eq 'check');
2753                    my $adircond = $acond->true ? "" : " in condition $hacond";
2754
2755                    my $onlyone = ($dir ne $adir) ?
2756                      ("\nLibtool libraries can be built for only one "
2757                       . "destination") : "";
2758
2759                    error ($liblocations{$val}{$acond},
2760                           "... and should also be $adirtxt$adircond.$onlyone");
2761                    return;
2762                  }
2763              }
2764            else
2765              {
2766                $instconds{$val} = new Automake::DisjConditions;
2767              }
2768            $instdirs{$val}{$full_cond} = $dir;
2769            $instsubdirs{$val}{$full_cond} = $ldir;
2770            $liblocations{$val}{$full_cond} = $where;
2771            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2772          },
2773          sub
2774          {
2775            return ();
2776          },
2777          skip_ac_subst => 1);
2778     }
2779
2780   foreach my $pair (@liblist)
2781     {
2782       my ($where, $onelib) = @$pair;
2783
2784       my $seen_libobjs = 0;
2785       my $obj = '.lo';
2786
2787       # Canonicalize names and check for misspellings.
2788       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2789                                             '_SOURCES', '_OBJECTS',
2790                                             '_DEPENDENCIES');
2791
2792       # Check that the library fits the standard naming convention.
2793       my $libname_rx = '^lib.*\.la';
2794       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2795       my $ldvar2 = var ('LDFLAGS');
2796       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2797           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2798         {
2799           # Relax name checking for libtool modules.
2800           $libname_rx = '\.la';
2801         }
2802
2803       my $bn = basename ($onelib);
2804       if ($bn !~ /$libname_rx$/)
2805         {
2806           my $type = 'library';
2807           if ($libname_rx eq '\.la')
2808             {
2809               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2810               $type = 'module';
2811             }
2812           else
2813             {
2814               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2815             }
2816           my $suggestion = dirname ($onelib) . "/$bn";
2817           $suggestion =~ s|^\./||g;
2818           msg ('error-gnu/warn', $where,
2819                "'$onelib' is not a standard libtool $type name\n"
2820                . "did you mean '$suggestion'?")
2821         }
2822
2823       ($known_libraries{$onelib} = $bn) =~ s/\.la$//;
2824
2825       $where->push_context ("while processing Libtool library '$onelib'");
2826       $where->set (INTERNAL->get);
2827
2828       # Make sure we look at these.
2829       set_seen ($xlib . '_LDFLAGS');
2830       set_seen ($xlib . '_DEPENDENCIES');
2831       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2832
2833       # Generate support for conditional object inclusion in
2834       # libraries.
2835       if (var ($xlib . '_LIBADD'))
2836         {
2837           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2838             {
2839               $seen_libobjs = 1;
2840             }
2841         }
2842       else
2843         {
2844           &define_variable ($xlib . "_LIBADD", '', $where);
2845         }
2846
2847       reject_var ("${xlib}_LDADD",
2848                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2849
2850
2851       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2852                                              NONLIBTOOL => 0, LIBTOOL => 1);
2853
2854       # Determine program to use for link.
2855       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xlib);
2856       $vlink = verbose_flag ($vlink || 'GEN');
2857
2858       my $rpathvar = "am_${xlib}_rpath";
2859       my $rpath = "\$($rpathvar)";
2860       foreach my $rcond ($instconds{$onelib}->conds)
2861         {
2862           my $val;
2863           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2864               || $instdirs{$onelib}{$rcond} eq 'noinst'
2865               || $instdirs{$onelib}{$rcond} eq 'check')
2866             {
2867               # It's an EXTRA_ library, so we can't specify -rpath,
2868               # because we don't know where the library will end up.
2869               # The user probably knows, but generally speaking automake
2870               # doesn't -- and in fact configure could decide
2871               # dynamically between two different locations.
2872               $val = '';
2873             }
2874           else
2875             {
2876               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2877               $val .= $instsubdirs{$onelib}{$rcond}
2878                 if defined $instsubdirs{$onelib}{$rcond};
2879             }
2880           if ($rcond->true)
2881             {
2882               # If $rcond is true there is only one condition and
2883               # there is no point defining an helper variable.
2884               $rpath = $val;
2885             }
2886           else
2887             {
2888               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2889             }
2890         }
2891
2892       # If the resulting library lies into a subdirectory,
2893       # make sure this directory will exist.
2894       my $dirstamp = require_build_directory_maybe ($onelib);
2895
2896       # Remember to cleanup .libs/ in this directory.
2897       my $dirname = dirname $onelib;
2898       $libtool_clean_directories{$dirname} = 1;
2899
2900       $output_rules .= &file_contents ('ltlibrary',
2901                                        $where,
2902                                        LTLIBRARY  => $onelib,
2903                                        XLTLIBRARY => $xlib,
2904                                        RPATH      => $rpath,
2905                                        XLINK      => $xlink,
2906                                        VERBOSE    => $vlink,
2907                                        DIRSTAMP   => $dirstamp);
2908       if ($seen_libobjs)
2909         {
2910           if (var ($xlib . '_LIBADD'))
2911             {
2912               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2913             }
2914         }
2915
2916       if (! $seen_ar)
2917         {
2918           msg ('extra-portability', $where,
2919                "'$onelib': linking libtool libraries using a non-POSIX\n"
2920                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2921         }
2922     }
2923 }
2924
2925 # See if any _SOURCES variable were misspelled.
2926 sub check_typos ()
2927 {
2928   # It is ok if the user sets this particular variable.
2929   set_seen 'AM_LDFLAGS';
2930
2931   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2932     {
2933       foreach my $var (variables $primary)
2934         {
2935           my $varname = $var->name;
2936           # A configure variable is always legitimate.
2937           next if exists $configure_vars{$varname};
2938
2939           for my $cond ($var->conditions->conds)
2940             {
2941               $varname =~ /^(?:EXTRA_)?(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2942               msg_var ('syntax', $var, "variable '$varname' is defined but no"
2943                        . " program or\nlibrary has '$1' as canonical name"
2944                        . " (possible typo)")
2945                 unless $var->rdef ($cond)->seen;
2946             }
2947         }
2948     }
2949 }
2950
2951
2952 # Handle scripts.
2953 sub handle_scripts
2954 {
2955     # NOTE we no longer automatically clean SCRIPTS, because it is
2956     # useful to sometimes distribute scripts verbatim.  This happens
2957     # e.g. in Automake itself.
2958     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2959                      'bin', 'sbin', 'libexec', 'pkglibexec', 'pkgdata',
2960                      'noinst', 'check');
2961 }
2962
2963
2964
2965
2966 ## ------------------------ ##
2967 ## Handling Texinfo files.  ##
2968 ## ------------------------ ##
2969
2970 # ($OUTFILE, $VFILE)
2971 # &scan_texinfo_file ($FILENAME)
2972 # ------------------------------
2973 # $OUTFILE     - name of the info file produced by $FILENAME.
2974 # $VFILE       - name of the version.texi file used (undef if none).
2975 sub scan_texinfo_file ($)
2976 {
2977   my ($filename) = @_;
2978
2979   my $texi = new Automake::XFile "< $filename";
2980   verb "reading $filename";
2981
2982   my ($outfile, $vfile);
2983   while ($_ = $texi->getline)
2984     {
2985       if (/^\@setfilename +(\S+)/)
2986         {
2987           # Honor only the first @setfilename.  (It's possible to have
2988           # more occurrences later if the manual shows examples of how
2989           # to use @setfilename...)
2990           next if $outfile;
2991
2992           $outfile = $1;
2993           if ($outfile =~ /\.([^.]+)$/ && $1 ne 'info')
2994             {
2995               error ("$filename:$.",
2996                      "output '$outfile' has unrecognized extension");
2997               return;
2998             }
2999         }
3000       # A "version.texi" file is actually any file whose name matches
3001       # "vers*.texi".
3002       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
3003         {
3004           $vfile = $1;
3005         }
3006     }
3007
3008   if (! $outfile)
3009     {
3010       err_am "'$filename' missing \@setfilename";
3011       return;
3012     }
3013
3014   my $infobase = basename ($filename);
3015   $infobase =~ s/\.te?xi(nfo)?$//;
3016   return ($outfile, $vfile);
3017 }
3018
3019
3020 # ($DIRSTAMP, @CLEAN_FILES)
3021 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
3022 # ------------------------------------------------------------------
3023 # SOURCE - the source Texinfo file
3024 # DEST - the destination Info file
3025 # INSRC - whether DEST should be built in the source tree
3026 # DEPENDENCIES - known dependencies
3027 sub output_texinfo_build_rules ($$$@)
3028 {
3029   my ($source, $dest, $insrc, @deps) = @_;
3030
3031   # Split 'a.texi' into 'a' and '.texi'.
3032   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
3033   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
3034
3035   $ssfx ||= "";
3036   $dsfx ||= "";
3037
3038   # We can output two kinds of rules: the "generic" rules use Make
3039   # suffix rules and are appropriate when $source and $dest do not lie
3040   # in a sub-directory; the "specific" rules are needed in the other
3041   # case.
3042   #
3043   # The former are output only once (this is not really apparent here,
3044   # but just remember that some logic deeper in Automake will not
3045   # output the same rule twice); while the later need to be output for
3046   # each Texinfo source.
3047   my $generic;
3048   my $makeinfoflags;
3049   my $sdir = dirname $source;
3050   if ($sdir eq '.' && dirname ($dest) eq '.')
3051     {
3052       $generic = 1;
3053       $makeinfoflags = '-I $(srcdir)';
3054     }
3055   else
3056     {
3057       $generic = 0;
3058       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3059     }
3060
3061   # A directory can contain two kinds of info files: some built in the
3062   # source tree, and some built in the build tree.  The rules are
3063   # different in each case.  However we cannot output two different
3064   # set of generic rules.  Because in-source builds are more usual, we
3065   # use generic rules in this case and fall back to "specific" rules
3066   # for build-dir builds.  (It should not be a problem to invert this
3067   # if needed.)
3068   $generic = 0 unless $insrc;
3069
3070   # We cannot use a suffix rule to build info files with an empty
3071   # extension.  Otherwise we would output a single suffix inference
3072   # rule, with separate dependencies, as in
3073   #
3074   #    .texi:
3075   #             $(MAKEINFO) ...
3076   #    foo.info: foo.texi
3077   #
3078   # which confuse Solaris make.  (See the Autoconf manual for
3079   # details.)  Therefore we use a specific rule in this case.  This
3080   # applies to info files only (dvi and pdf files always have an
3081   # extension).
3082   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3083
3084   # If the resulting file lie into a subdirectory,
3085   # make sure this directory will exist.
3086   my $dirstamp = require_build_directory_maybe ($dest);
3087
3088   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3089
3090   $output_rules .= file_contents ('texibuild',
3091                                   new Automake::Location,
3092                                   AM_V_MAKEINFO    => verbose_flag('MAKEINFO'),
3093                                   AM_V_TEXI2DVI    => verbose_flag('TEXI2DVI'),
3094                                   AM_V_TEXI2PDF    => verbose_flag('TEXI2PDF'),
3095                                   DEPS             => "@deps",
3096                                   DEST_PREFIX      => $dpfx,
3097                                   DEST_INFO_PREFIX => $dipfx,
3098                                   DEST_SUFFIX      => $dsfx,
3099                                   DIRSTAMP         => $dirstamp,
3100                                   GENERIC          => $generic,
3101                                   GENERIC_INFO     => $generic_info,
3102                                   INSRC            => $insrc,
3103                                   MAKEINFOFLAGS    => $makeinfoflags,
3104                                   SILENT           => silent_flag(),
3105                                   SOURCE           => ($generic
3106                                                        ? '$<' : $source),
3107                                   SOURCE_INFO      => ($generic_info
3108                                                        ? '$<' : $source),
3109                                   SOURCE_REAL      => $source,
3110                                   SOURCE_SUFFIX    => $ssfx,
3111                                   TEXIQUIET        => verbose_flag('texinfo'),
3112                                   TEXIDEVNULL      => verbose_flag('texidevnull'),
3113                                   );
3114   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3115 }
3116
3117
3118 # ($MOSTLYCLEAN, $TEXICLEAN, $MAINTCLEAN)
3119 # handle_texinfo_helper ($info_texinfos)
3120 # --------------------------------------
3121 # Handle all Texinfo source; helper for handle_texinfo.
3122 sub handle_texinfo_helper ($)
3123 {
3124   my ($info_texinfos) = @_;
3125   my (@infobase, @info_deps_list, @texi_deps);
3126   my %versions;
3127   my $done = 0;
3128   my (@mostly_cleans, @texi_cleans, @maint_cleans) = ('', '', '');
3129
3130   # Build a regex matching user-cleaned files.
3131   my $d = var 'DISTCLEANFILES';
3132   my $c = var 'CLEANFILES';
3133   my @f = ();
3134   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3135   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3136   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3137   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3138
3139   foreach my $texi
3140       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3141     {
3142       my $infobase = $texi;
3143       $infobase =~ s/\.(txi|texinfo|texi)$//;
3144
3145       if ($infobase eq $texi)
3146         {
3147           # FIXME: report line number.
3148           err_am "texinfo file '$texi' has unrecognized extension";
3149           next;
3150         }
3151
3152       push @infobase, $infobase;
3153
3154       # If 'version.texi' is referenced by input file, then include
3155       # automatic versioning capability.
3156       my ($out_file, $vtexi) =
3157         scan_texinfo_file ("$relative_dir/$texi")
3158         or next;
3159       # Directory of auxiliary files and build by-products used by texi2dvi
3160       # and texi2pdf.
3161       push @mostly_cleans, "$infobase.t2d";
3162       push @mostly_cleans, "$infobase.t2p";
3163
3164       # If the Texinfo source is in a subdirectory, create the
3165       # resulting info in this subdirectory.  If it is in the current
3166       # directory, try hard to not prefix "./" because it breaks the
3167       # generic rules.
3168       my $outdir = dirname ($texi) . '/';
3169       $outdir = "" if $outdir eq './';
3170       $out_file =  $outdir . $out_file;
3171
3172       # Until Automake 1.6.3, .info files were built in the
3173       # source tree.  This was an obstacle to the support of
3174       # non-distributed .info files, and non-distributed .texi
3175       # files.
3176       #
3177       # * Non-distributed .texi files is important in some packages
3178       #   where .texi files are built at make time, probably using
3179       #   other binaries built in the package itself, maybe using
3180       #   tools or information found on the build host.  Because
3181       #   these files are not distributed they are always rebuilt
3182       #   at make time; they should therefore not lie in the source
3183       #   directory.  One plan was to support this using
3184       #   nodist_info_TEXINFOS or something similar.  (Doing this
3185       #   requires some sanity checks.  For instance Automake should
3186       #   not allow:
3187       #      dist_info_TEXINFOS = foo.texi
3188       #      nodist_foo_TEXINFOS = included.texi
3189       #   because a distributed file should never depend on a
3190       #   non-distributed file.)
3191       #
3192       # * If .texi files are not distributed, then .info files should
3193       #   not be distributed either.  There are also cases where one
3194       #   wants to distribute .texi files, but does not want to
3195       #   distribute the .info files.  For instance the Texinfo package
3196       #   distributes the tool used to build these files; it would
3197       #   be a waste of space to distribute them.  It's not clear
3198       #   which syntax we should use to indicate that .info files should
3199       #   not be distributed.  Akim Demaille suggested that eventually
3200       #   we switch to a new syntax:
3201       #   |  Maybe we should take some inspiration from what's already
3202       #   |  done in the rest of Automake.  Maybe there is too much
3203       #   |  syntactic sugar here, and you want
3204       #   |     nodist_INFO = bar.info
3205       #   |     dist_bar_info_SOURCES = bar.texi
3206       #   |     bar_texi_DEPENDENCIES = foo.texi
3207       #   |  with a bit of magic to have bar.info represent the whole
3208       #   |  bar*info set.  That's a lot more verbose that the current
3209       #   |  situation, but it is # not new, hence the user has less
3210       #   |  to learn.
3211       #   |
3212       #   |  But there is still too much room for meaningless specs:
3213       #   |     nodist_INFO = bar.info
3214       #   |     dist_bar_info_SOURCES = bar.texi
3215       #   |     dist_PS = bar.ps something-written-by-hand.ps
3216       #   |     nodist_bar_ps_SOURCES = bar.texi
3217       #   |     bar_texi_DEPENDENCIES = foo.texi
3218       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3219       #
3220       # Back to the point, it should be clear that in order to support
3221       # non-distributed .info files, we need to build them in the
3222       # build tree, not in the source tree (non-distributed .texi
3223       # files are less of a problem, because we do not output build
3224       # rules for them).  In Automake 1.7 .info build rules have been
3225       # largely cleaned up so that .info files get always build in the
3226       # build tree, even when distributed.  The idea was that
3227       #   (1) if during a VPATH build the .info file was found to be
3228       #       absent or out-of-date (in the source tree or in the
3229       #       build tree), Make would rebuild it in the build tree.
3230       #       If an up-to-date source-tree of the .info file existed,
3231       #       make would not rebuild it in the build tree.
3232       #   (2) having two copies of .info files, one in the source tree
3233       #       and one (newer) in the build tree is not a problem
3234       #       because 'make dist' always pick files in the build tree
3235       #       first.
3236       # However it turned out the be a bad idea for several reasons:
3237       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3238       #     like GNU Make on point (1) above.  These implementations
3239       #     of Make would always rebuild .info files in the build
3240       #     tree, even if such files were up to date in the source
3241       #     tree.  Consequently, it was impossible to perform a VPATH
3242       #     build of a package containing Texinfo files using these
3243       #     Make implementations.
3244       #     (Refer to the Autoconf Manual, section "Limitation of
3245       #     Make", paragraph "VPATH", item "target lookup", for
3246       #     an account of the differences between these
3247       #     implementations.)
3248       #   * The GNU Coding Standards require these files to be built
3249       #     in the source-tree (when they are distributed, that is).
3250       #   * Keeping a fresher copy of distributed files in the
3251       #     build tree can be annoying during development because
3252       #     - if the files is kept under CVS, you really want it
3253       #       to be updated in the source tree
3254       #     - it is confusing that 'make distclean' does not erase
3255       #       all files in the build tree.
3256       #
3257       # Consequently, starting with Automake 1.8, .info files are
3258       # built in the source tree again.  Because we still plan to
3259       # support non-distributed .info files at some point, we
3260       # have a single variable ($INSRC) that controls whether
3261       # the current .info file must be built in the source tree
3262       # or in the build tree.  Actually this variable is switched
3263       # off for .info files that appear to be cleaned; this is
3264       # for backward compatibility with package such as Texinfo,
3265       # which do things like
3266       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3267       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3268       #   # Do not create info files for distribution.
3269       #   dist-info:
3270       # in order not to distribute .info files.
3271       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3272
3273       my $soutdir = '$(srcdir)/' . $outdir;
3274       $outdir = $soutdir if $insrc;
3275
3276       # If user specified file_TEXINFOS, then use that as explicit
3277       # dependency list.
3278       @texi_deps = ();
3279       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3280
3281       my $canonical = canonicalize ($infobase);
3282       if (var ($canonical . "_TEXINFOS"))
3283         {
3284           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3285           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3286         }
3287
3288       my ($dirstamp, @cfiles) =
3289         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3290       push (@texi_cleans, @cfiles);
3291
3292       push (@info_deps_list, $out_file);
3293
3294       # If a vers*.texi file is needed, emit the rule.
3295       if ($vtexi)
3296         {
3297           err_am ("'$vtexi', included in '$texi', "
3298                   . "also included in '$versions{$vtexi}'")
3299             if defined $versions{$vtexi};
3300           $versions{$vtexi} = $texi;
3301
3302           # We number the stamp-vti files.  This is doable since the
3303           # actual names don't matter much.  We only number starting
3304           # with the second one, so that the common case looks nice.
3305           my $vti = ($done ? $done : 'vti');
3306           ++$done;
3307
3308           # This is ugly, but it is our historical practice.
3309           if ($config_aux_dir_set_in_configure_ac)
3310             {
3311               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3312                                             'mdate-sh');
3313             }
3314           else
3315             {
3316               require_file_with_macro (TRUE, 'info_TEXINFOS',
3317                                        FOREIGN, 'mdate-sh');
3318             }
3319
3320           my $conf_dir;
3321           if ($config_aux_dir_set_in_configure_ac)
3322             {
3323               $conf_dir = "$am_config_aux_dir/";
3324             }
3325           else
3326             {
3327               $conf_dir = '$(srcdir)/';
3328             }
3329           $output_rules .= file_contents ('texi-vers',
3330                                           new Automake::Location,
3331                                           TEXI     => $texi,
3332                                           VTI      => $vti,
3333                                           STAMPVTI => "${soutdir}stamp-$vti",
3334                                           VTEXI    => "$soutdir$vtexi",
3335                                           MDDIR    => $conf_dir,
3336                                           DIRSTAMP => $dirstamp);
3337         }
3338     }
3339
3340   # Handle location of texinfo.tex.
3341   my $need_texi_file = 0;
3342   my $texinfodir;
3343   if (var ('TEXINFO_TEX'))
3344     {
3345       # The user defined TEXINFO_TEX so assume he knows what he is
3346       # doing.
3347       $texinfodir = ('$(srcdir)/'
3348                      . dirname (variable_value ('TEXINFO_TEX')));
3349     }
3350   elsif ($config_aux_dir_set_in_configure_ac)
3351     {
3352       $texinfodir = $am_config_aux_dir;
3353       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3354       $need_texi_file = 2; # so that we require_conf_file later
3355     }
3356   else
3357     {
3358       $texinfodir = '$(srcdir)';
3359       $need_texi_file = 1;
3360     }
3361   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3362
3363   push (@dist_targets, 'dist-info');
3364
3365   if (! option 'no-installinfo')
3366     {
3367       # Make sure documentation is made and installed first.  Use
3368       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3369       # get run twice during "make all".
3370       unshift (@all, '$(INFO_DEPS)');
3371     }
3372
3373   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3374   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3375   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3376   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3377
3378   # This next isn't strictly needed now -- the places that look here
3379   # could easily be changed to look in info_TEXINFOS.  But this is
3380   # probably better, in case noinst_TEXINFOS is ever supported.
3381   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3382
3383   # Do some error checking.  Note that this file is not required
3384   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3385   # up above.
3386   if ($need_texi_file && ! option 'no-texinfo.tex')
3387     {
3388       if ($need_texi_file > 1)
3389         {
3390           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3391                                         'texinfo.tex');
3392         }
3393       else
3394         {
3395           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3396                                    'texinfo.tex');
3397         }
3398     }
3399
3400   return (makefile_wrap ("", "\t  ", @mostly_cleans),
3401           makefile_wrap ("", "\t  ", @texi_cleans),
3402           makefile_wrap ("", "\t  ", @maint_cleans));
3403 }
3404
3405
3406 # handle_texinfo ()
3407 # -----------------
3408 # Handle all Texinfo source.
3409 sub handle_texinfo ()
3410 {
3411   reject_var 'TEXINFOS', "'TEXINFOS' is an anachronism; use 'info_TEXINFOS'";
3412   # FIXME: I think this is an obsolete future feature name.
3413   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3414
3415   my $info_texinfos = var ('info_TEXINFOS');
3416   my ($mostlyclean, $clean, $maintclean) = ('', '', '');
3417   if ($info_texinfos)
3418     {
3419       define_verbose_texinfo;
3420       ($mostlyclean, $clean, $maintclean) = handle_texinfo_helper ($info_texinfos);
3421       chomp $mostlyclean;
3422       chomp $clean;
3423       chomp $maintclean;
3424     }
3425
3426   $output_rules .=  file_contents ('texinfos',
3427                                    new Automake::Location,
3428                                    AM_V_DVIPS    => verbose_flag('DVIPS'),
3429                                    MOSTLYCLEAN   => $mostlyclean,
3430                                    TEXICLEAN     => $clean,
3431                                    MAINTCLEAN    => $maintclean,
3432                                    'LOCAL-TEXIS' => !!$info_texinfos,
3433                                    TEXIQUIET     => verbose_flag('texinfo'));
3434 }
3435
3436
3437 # Handle any man pages.
3438 sub handle_man_pages
3439 {
3440   reject_var 'MANS', "'MANS' is an anachronism; use 'man_MANS'";
3441
3442   # Find all the sections in use.  We do this by first looking for
3443   # "standard" sections, and then looking for any additional
3444   # sections used in man_MANS.
3445   my (%sections, %notrans_sections, %trans_sections,
3446       %notrans_vars, %trans_vars, %notrans_sect_vars, %trans_sect_vars);
3447   # We handle nodist_ for uniformity.  man pages aren't distributed
3448   # by default so it isn't actually very important.
3449   foreach my $npfx ('', 'notrans_')
3450     {
3451       foreach my $pfx ('', 'dist_', 'nodist_')
3452         {
3453           # Add more sections as needed.
3454           foreach my $section ('0'..'9', 'n', 'l')
3455             {
3456               my $varname = $npfx . $pfx . 'man' . $section . '_MANS';
3457               if (var ($varname))
3458                 {
3459                   $sections{$section} = 1;
3460                   $varname = '$(' . $varname . ')';
3461                   if ($npfx eq 'notrans_')
3462                     {
3463                       $notrans_sections{$section} = 1;
3464                       $notrans_sect_vars{$varname} = 1;
3465                     }
3466                   else
3467                     {
3468                       $trans_sections{$section} = 1;
3469                       $trans_sect_vars{$varname} = 1;
3470                     }
3471
3472                   &push_dist_common ($varname)
3473                     if $pfx eq 'dist_';
3474                 }
3475             }
3476
3477           my $varname = $npfx . $pfx . 'man_MANS';
3478           my $var = var ($varname);
3479           if ($var)
3480             {
3481               foreach ($var->value_as_list_recursive)
3482                 {
3483                   # A page like 'foo.1c' goes into man1dir.
3484                   if (/\.([0-9a-z])([a-z]*)$/)
3485                     {
3486                       $sections{$1} = 1;
3487                       if ($npfx eq 'notrans_')
3488                         {
3489                           $notrans_sections{$1} = 1;
3490                         }
3491                       else
3492                         {
3493                           $trans_sections{$1} = 1;
3494                         }
3495                     }
3496                 }
3497
3498               $varname = '$(' . $varname . ')';
3499               if ($npfx eq 'notrans_')
3500                 {
3501                   $notrans_vars{$varname} = 1;
3502                 }
3503               else
3504                 {
3505                   $trans_vars{$varname} = 1;
3506                 }
3507               &push_dist_common ($varname)
3508                 if $pfx eq 'dist_';
3509             }
3510         }
3511     }
3512
3513   return unless %sections;
3514
3515   my @unsorted_deps;
3516
3517   # Build section independent variables.
3518   my $have_notrans = %notrans_vars;
3519   my @notrans_list = sort keys %notrans_vars;
3520   my $have_trans = %trans_vars;
3521   my @trans_list = sort keys %trans_vars;
3522
3523   # Now for each section, generate an install and uninstall rule.
3524   # Sort sections so output is deterministic.
3525   foreach my $section (sort keys %sections)
3526     {
3527       # Build section dependent variables.
3528       my $notrans_mans = $have_notrans || exists $notrans_sections{$section};
3529       my $trans_mans = $have_trans || exists $trans_sections{$section};
3530       my (%notrans_this_sect, %trans_this_sect);
3531       my $expr = 'man' . $section . '_MANS';
3532       foreach my $varname (keys %notrans_sect_vars)
3533         {
3534           if ($varname =~ /$expr/)
3535             {
3536               $notrans_this_sect{$varname} = 1;
3537             }
3538         }
3539       foreach my $varname (keys %trans_sect_vars)
3540         {
3541           if ($varname =~ /$expr/)
3542             {
3543               $trans_this_sect{$varname} = 1;
3544             }
3545         }
3546       my @notrans_sect_list = sort keys %notrans_this_sect;
3547       my @trans_sect_list = sort keys %trans_this_sect;
3548       @unsorted_deps = (keys %notrans_vars, keys %trans_vars,
3549                         keys %notrans_this_sect, keys %trans_this_sect);
3550       my @deps = sort @unsorted_deps;
3551       $output_rules .= &file_contents ('mans',
3552                                        new Automake::Location,
3553                                        SECTION           => $section,
3554                                        DEPS              => "@deps",
3555                                        NOTRANS_MANS      => $notrans_mans,
3556                                        NOTRANS_SECT_LIST => "@notrans_sect_list",
3557                                        HAVE_NOTRANS      => $have_notrans,
3558                                        NOTRANS_LIST      => "@notrans_list",
3559                                        TRANS_MANS        => $trans_mans,
3560                                        TRANS_SECT_LIST   => "@trans_sect_list",
3561                                        HAVE_TRANS        => $have_trans,
3562                                        TRANS_LIST        => "@trans_list");
3563     }
3564
3565   @unsorted_deps  = (keys %notrans_vars, keys %trans_vars,
3566                      keys %notrans_sect_vars, keys %trans_sect_vars);
3567   my @mans = sort @unsorted_deps;
3568   $output_vars .= file_contents ('mans-vars',
3569                                  new Automake::Location,
3570                                  MANS => "@mans");
3571
3572   push (@all, '$(MANS)')
3573     unless option 'no-installman';
3574 }
3575
3576 # Handle DATA variables.
3577 sub handle_data
3578 {
3579     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3580                      'data', 'dataroot', 'doc', 'dvi', 'html', 'pdf',
3581                      'ps', 'sysconf', 'sharedstate', 'localstate',
3582                      'pkgdata', 'lisp', 'noinst', 'check');
3583 }
3584
3585 # Handle TAGS.
3586 sub handle_tags
3587 {
3588     my @config;
3589     foreach my $spec (@config_headers)
3590       {
3591         my ($out, @ins) = split_config_file_spec ($spec);
3592         foreach my $in (@ins)
3593           {
3594             # If the config header source is in this directory,
3595             # require it.
3596             push @config, basename ($in)
3597               if $relative_dir eq dirname ($in);
3598            }
3599       }
3600
3601     define_variable ('am__tagged_files',
3602                      '$(HEADERS) $(SOURCES) $(TAGS_FILES) $(LISP)'
3603                      . "@config", INTERNAL);
3604
3605     if (rvar('am__tagged_files')->value_as_list_recursive
3606           || var ('ETAGS_ARGS') || var ('SUBDIRS'))
3607       {
3608         $output_rules .= &file_contents ('tags', new Automake::Location);
3609         set_seen 'TAGS_DEPENDENCIES';
3610       }
3611     else
3612       {
3613         reject_var ('TAGS_DEPENDENCIES',
3614                     "it doesn't make sense to define 'TAGS_DEPENDENCIES'"
3615                     . " without\nsources or 'ETAGS_ARGS'");
3616         # Every Makefile must define some sort of TAGS rule.
3617         # Otherwise, it would be possible for a top-level "make TAGS"
3618         # to fail because some subdirectory failed.  Ditto ctags and
3619         # cscope.
3620         $output_rules .=
3621           "tags TAGS:\n\n" .
3622           "ctags CTAGS:\n\n" .
3623           "cscope cscopelist:\n\n";
3624       }
3625 }
3626
3627
3628 # user_phony_rule ($NAME)
3629 # -----------------------
3630 # Return false if rule $NAME does not exist.  Otherwise,
3631 # declare it as phony, complete its definition (in case it is
3632 # conditional), and return its Automake::Rule instance.
3633 sub user_phony_rule ($)
3634 {
3635   my ($name) = @_;
3636   my $rule = rule $name;
3637   if ($rule)
3638     {
3639       depend ('.PHONY', $name);
3640       # Define $NAME in all condition where it is not already defined,
3641       # so that it is always OK to depend on $NAME.
3642       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3643         {
3644           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3645                                   $c, INTERNAL);
3646           $output_rules .= $c->subst_string . "$name:\n";
3647         }
3648     }
3649   return $rule;
3650 }
3651
3652
3653 # handle_dist
3654 # -----------
3655 # Handle 'dist' target.
3656 sub handle_dist ()
3657 {
3658   # Substitutions for distdir.am
3659   my %transform;
3660
3661   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3662   # no-dist setting: target like 'distclean' or 'maintainer-clean' use it.
3663   my $subdirs = var ('SUBDIRS');
3664   if ($subdirs)
3665     {
3666       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3667       # to all possible directories, and use it.  If DIST_SUBDIRS is
3668       # defined, just use it.
3669
3670       # Note that we check DIST_SUBDIRS first on purpose, so that
3671       # we don't call has_conditional_contents for now reason.
3672       # (In the past one project used so many conditional subdirectories
3673       # that calling has_conditional_contents on SUBDIRS caused
3674       # automake to grow to 150Mb -- this should not happen with
3675       # the current implementation of has_conditional_contents,
3676       # but it's more efficient to avoid the call anyway.)
3677       if (var ('DIST_SUBDIRS'))
3678         {
3679         }
3680       elsif ($subdirs->has_conditional_contents)
3681         {
3682           define_pretty_variable
3683             ('DIST_SUBDIRS', TRUE, INTERNAL,
3684              uniq ($subdirs->value_as_list_recursive));
3685         }
3686       else
3687         {
3688           # We always define this because that is what 'distclean'
3689           # wants.
3690           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3691                                   '$(SUBDIRS)');
3692         }
3693     }
3694
3695   # The remaining definitions are only required when a dist target is used.
3696   return if option 'no-dist';
3697
3698   # At least one of the archive formats must be enabled.
3699   if ($relative_dir eq '.')
3700     {
3701       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3702       $archive_defined ||=
3703         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzip lzma xz);
3704       error (option 'no-dist-gzip',
3705              "no-dist-gzip specified but no dist-* specified,\n"
3706              . "at least one archive format must be enabled")
3707         unless $archive_defined;
3708     }
3709
3710   # Look for common files that should be included in distribution.
3711   # If the aux dir is set, and it does not have a Makefile.am, then
3712   # we check for these files there as well.
3713   my $check_aux = 0;
3714   if ($relative_dir eq '.'
3715       && $config_aux_dir_set_in_configure_ac)
3716     {
3717       if (! &is_make_dir ($config_aux_dir))
3718         {
3719           $check_aux = 1;
3720         }
3721     }
3722   foreach my $cfile (@common_files)
3723     {
3724       if (dir_has_case_matching_file ($relative_dir, $cfile)
3725           # The file might be absent, but if it can be built it's ok.
3726           || rule $cfile)
3727         {
3728           &push_dist_common ($cfile);
3729         }
3730
3731       # Don't use 'elsif' here because a file might meaningfully
3732       # appear in both directories.
3733       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3734         {
3735           &push_dist_common ("$config_aux_dir/$cfile")
3736         }
3737     }
3738
3739   # We might copy elements from $configure_dist_common to
3740   # %dist_common if we think we need to.  If the file appears in our
3741   # directory, we would have discovered it already, so we don't
3742   # check that.  But if the file is in a subdir without a Makefile,
3743   # we want to distribute it here if we are doing '.'.  Ugly!
3744   # Also, in some corner cases, it's possible that the following code
3745   # will cause the same file to appear in the $(DIST_COMMON) variables
3746   # of two distinct Makefiles; but this is not a problem, since the
3747   # 'distdir' target in 'lib/am/distdir.am' can deal with the same
3748   # file being distributed multiple times.
3749   # See also automake bug#9651.
3750   if ($relative_dir eq '.')
3751     {
3752       foreach my $file (split (' ' , $configure_dist_common))
3753         {
3754           my $dir = dirname ($file);
3755           push_dist_common ($file)
3756             if ($dir eq '.' || ! is_make_dir ($dir));
3757         }
3758     }
3759
3760   # Files to distributed.  Don't use ->value_as_list_recursive
3761   # as it recursively expands '$(dist_pkgdata_DATA)' etc.
3762   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3763   @dist_common = uniq @dist_common;
3764   variable_delete 'DIST_COMMON';
3765   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3766
3767   # Now that we've processed DIST_COMMON, disallow further attempts
3768   # to set it.
3769   $handle_dist_run = 1;
3770
3771   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3772   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3773
3774   # If the target 'dist-hook' exists, make sure it is run.  This
3775   # allows users to do random weird things to the distribution
3776   # before it is packaged up.
3777   push (@dist_targets, 'dist-hook')
3778     if user_phony_rule 'dist-hook';
3779   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3780
3781   my $flm = option ('filename-length-max');
3782   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3783
3784   $output_rules .= &file_contents ('distdir',
3785                                    new Automake::Location,
3786                                    %transform,
3787                                    FILENAME_FILTER => $filename_filter);
3788 }
3789
3790
3791 # check_directory ($NAME, $WHERE [, $RELATIVE_DIR = "."])
3792 # -------------------------------------------------------
3793 # Ensure $NAME is a directory (in $RELATIVE_DIR), and that it uses a sane
3794 # name.  Use $WHERE as a location in the diagnostic, if any.
3795 sub check_directory ($$;$)
3796 {
3797   my ($dir, $where, $reldir) = @_;
3798   $reldir = '.' unless defined $reldir;
3799
3800   error $where, "required directory $reldir/$dir does not exist"
3801     unless -d "$reldir/$dir";
3802
3803   # If an 'obj/' directory exists, BSD make will enter it before
3804   # reading 'Makefile'.  Hence the 'Makefile' in the current directory
3805   # will not be read.
3806   #
3807   #  % cat Makefile
3808   #  all:
3809   #          echo Hello
3810   #  % cat obj/Makefile
3811   #  all:
3812   #          echo World
3813   #  % make      # GNU make
3814   #  echo Hello
3815   #  Hello
3816   #  % pmake     # BSD make
3817   #  echo World
3818   #  World
3819   msg ('portability', $where,
3820        "naming a subdirectory 'obj' causes troubles with BSD make")
3821     if $dir eq 'obj';
3822
3823   # 'aux' is probably the most important of the following forbidden name,
3824   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3825   msg ('portability', $where,
3826        "name '$dir' is reserved on W32 and DOS platforms")
3827     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3828 }
3829
3830 # check_directories_in_var ($VARIABLE)
3831 # ------------------------------------
3832 # Recursively check all items in variables $VARIABLE as directories
3833 sub check_directories_in_var ($)
3834 {
3835   my ($var) = @_;
3836   $var->traverse_recursively
3837     (sub
3838      {
3839        my ($var, $val, $cond, $full_cond) = @_;
3840        check_directory ($val, $var->rdef ($cond)->location, $relative_dir);
3841        return ();
3842      },
3843      undef,
3844      skip_ac_subst => 1);
3845 }
3846
3847 # &handle_subdirs ()
3848 # ------------------
3849 # Handle subdirectories.
3850 sub handle_subdirs ()
3851 {
3852   my $subdirs = var ('SUBDIRS');
3853   return
3854     unless $subdirs;
3855
3856   check_directories_in_var $subdirs;
3857
3858   my $dsubdirs = var ('DIST_SUBDIRS');
3859   check_directories_in_var $dsubdirs
3860     if $dsubdirs;
3861
3862   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3863   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3864 }
3865
3866
3867 # ($REGEN, @DEPENDENCIES)
3868 # &scan_aclocal_m4
3869 # ----------------
3870 # If aclocal.m4 creation is automated, return the list of its dependencies.
3871 sub scan_aclocal_m4 ()
3872 {
3873   my $regen_aclocal = 0;
3874
3875   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3876   set_seen 'CONFIGURE_DEPENDENCIES';
3877
3878   if (-f 'aclocal.m4')
3879     {
3880       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3881
3882       my $aclocal = new Automake::XFile "< aclocal.m4";
3883       my $line = $aclocal->getline;
3884       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3885     }
3886
3887   my @ac_deps = ();
3888
3889   if (set_seen ('ACLOCAL_M4_SOURCES'))
3890     {
3891       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3892       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3893                "'ACLOCAL_M4_SOURCES' is obsolete.\n"
3894                . "It should be safe to simply remove it");
3895     }
3896
3897   # Note that it might be possible that aclocal.m4 doesn't exist but
3898   # should be auto-generated.  This case probably isn't very
3899   # important.
3900
3901   return ($regen_aclocal, @ac_deps);
3902 }
3903
3904
3905 # Helper function for substitute_ac_subst_variables.
3906 sub substitute_ac_subst_variables_worker($)
3907 {
3908   my ($token) = @_;
3909   return "\@$token\@" if var $token;
3910   return "\${$token\}";
3911 }
3912
3913 # substitute_ac_subst_variables ($TEXT)
3914 # -------------------------------------
3915 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
3916 # variable.
3917 sub substitute_ac_subst_variables ($)
3918 {
3919   my ($text) = @_;
3920   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
3921   return $text;
3922 }
3923
3924 # @DEPENDENCIES
3925 # &prepend_srcdir (@INPUTS)
3926 # -------------------------
3927 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
3928 # if an input file has a directory part the same as the current
3929 # directory, then the directory part is simply replaced by $(srcdir).
3930 # But if the directory part is different, then $(top_srcdir) is
3931 # prepended.
3932 sub prepend_srcdir (@)
3933 {
3934   my (@inputs) = @_;
3935   my @newinputs;
3936
3937   foreach my $single (@inputs)
3938     {
3939       if (dirname ($single) eq $relative_dir)
3940         {
3941           push (@newinputs, '$(srcdir)/' . basename ($single));
3942         }
3943       else
3944         {
3945           push (@newinputs, '$(top_srcdir)/' . $single);
3946         }
3947     }
3948   return @newinputs;
3949 }
3950
3951 # @DEPENDENCIES
3952 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
3953 # ---------------------------------------------------
3954 # Compute a list of dependencies appropriate for the rebuild
3955 # rule of
3956 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
3957 # Also distribute $INPUTs which are not built by another AC_CONFIG_FOOs.
3958 sub rewrite_inputs_into_dependencies ($@)
3959 {
3960   my ($file, @inputs) = @_;
3961   my @res = ();
3962
3963   for my $i (@inputs)
3964     {
3965       # We cannot create dependencies on shell variables.
3966       next if (substitute_ac_subst_variables $i) =~ /\$/;
3967
3968       if (exists $ac_config_files_location{$i} && $i ne $file)
3969         {
3970           my $di = dirname $i;
3971           if ($di eq $relative_dir)
3972             {
3973               $i = basename $i;
3974             }
3975           # In the top-level Makefile we do not use $(top_builddir), because
3976           # we are already there, and since the targets are built without
3977           # a $(top_builddir), it helps BSD Make to match them with
3978           # dependencies.
3979           elsif ($relative_dir ne '.')
3980             {
3981               $i = '$(top_builddir)/' . $i;
3982             }
3983         }
3984       else
3985         {
3986           msg ('error', $ac_config_files_location{$file},
3987                "required file '$i' not found")
3988             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
3989           ($i) = prepend_srcdir ($i);
3990           push_dist_common ($i);
3991         }
3992       push @res, $i;
3993     }
3994   return @res;
3995 }
3996
3997
3998
3999 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
4000 # ------------------------------------------------------------------
4001 # Handle remaking and configure stuff.
4002 # We need the name of the input file, to do proper remaking rules.
4003 sub handle_configure ($$$@)
4004 {
4005   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
4006
4007   prog_error 'empty @inputs'
4008     unless @inputs;
4009
4010   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
4011                                                             $makefile_in);
4012   my $rel_makefile = basename $makefile;
4013
4014   my $colon_infile = ':' . join (':', @inputs);
4015   $colon_infile = '' if $colon_infile eq ":$makefile.in";
4016   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
4017   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
4018   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
4019                           @configure_deps, @aclocal_m4_deps,
4020                           '$(top_srcdir)/' . $configure_ac);
4021   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
4022   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
4023   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
4024                           @configuredeps);
4025
4026   my $automake_options = '--' . $strictness_name .
4027                          (global_option 'no-dependencies' ? ' --ignore-deps' : '');
4028
4029   $output_rules .= file_contents
4030     ('configure',
4031      new Automake::Location,
4032      MAKEFILE              => $rel_makefile,
4033      'MAKEFILE-DEPS'       => "@rewritten",
4034      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
4035      'MAKEFILE-IN'         => $rel_makefile_in,
4036      'HAVE-MAKEFILE-IN-DEPS' => (@include_stack > 0),
4037      'MAKEFILE-IN-DEPS'    => "@include_stack",
4038      'MAKEFILE-AM'         => $rel_makefile_am,
4039      'AUTOMAKE-OPTIONS'    => $automake_options,
4040      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
4041      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
4042      VERBOSE               => verbose_flag ('GEN'));
4043
4044   if ($relative_dir eq '.')
4045     {
4046       &push_dist_common ('acconfig.h')
4047         if -f 'acconfig.h';
4048     }
4049
4050   # If we have a configure header, require it.
4051   my $hdr_index = 0;
4052   my @distclean_config;
4053   foreach my $spec (@config_headers)
4054     {
4055       $hdr_index += 1;
4056       # $CONFIG_H_PATH: config.h from top level.
4057       my ($config_h_path, @ins) = split_config_file_spec ($spec);
4058       my $config_h_dir = dirname ($config_h_path);
4059
4060       # If the header is in the current directory we want to build
4061       # the header here.  Otherwise, if we're at the topmost
4062       # directory and the header's directory doesn't have a
4063       # Makefile, then we also want to build the header.
4064       if ($relative_dir eq $config_h_dir
4065           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
4066         {
4067           my ($cn_sans_dir, $stamp_dir);
4068           if ($relative_dir eq $config_h_dir)
4069             {
4070               $cn_sans_dir = basename ($config_h_path);
4071               $stamp_dir = '';
4072             }
4073           else
4074             {
4075               $cn_sans_dir = $config_h_path;
4076               if ($config_h_dir eq '.')
4077                 {
4078                   $stamp_dir = '';
4079                 }
4080               else
4081                 {
4082                   $stamp_dir = $config_h_dir . '/';
4083                 }
4084             }
4085
4086           # This will also distribute all inputs.
4087           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
4088
4089           # Cannot define rebuild rules for filenames with shell variables.
4090           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4091
4092           # Header defined in this directory.
4093           my @files;
4094           if (-f $config_h_path . '.top')
4095             {
4096               push (@files, "$cn_sans_dir.top");
4097             }
4098           if (-f $config_h_path . '.bot')
4099             {
4100               push (@files, "$cn_sans_dir.bot");
4101             }
4102
4103           push_dist_common (@files);
4104
4105           # For now, acconfig.h can only appear in the top srcdir.
4106           if (-f 'acconfig.h')
4107             {
4108               push (@files, '$(top_srcdir)/acconfig.h');
4109             }
4110
4111           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4112           $output_rules .=
4113             file_contents ('remake-hdr',
4114                            new Automake::Location,
4115                            FILES            => "@files",
4116                            CONFIG_H         => $cn_sans_dir,
4117                            CONFIG_HIN       => $ins[0],
4118                            CONFIG_H_DEPS    => "@ins",
4119                            CONFIG_H_PATH    => $config_h_path,
4120                            STAMP            => "$stamp");
4121
4122           push @distclean_config, $cn_sans_dir, $stamp;
4123         }
4124     }
4125
4126   $output_rules .= file_contents ('clean-hdr',
4127                                   new Automake::Location,
4128                                   FILES => "@distclean_config")
4129     if @distclean_config;
4130
4131   # Distribute and define mkinstalldirs only if it is already present
4132   # in the package, for backward compatibility (some people may still
4133   # use $(mkinstalldirs)).
4134   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4135   if (-f $mkidpath)
4136     {
4137       # Use require_file so that any existing script gets updated
4138       # by --force-missing.
4139       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4140       define_variable ('mkinstalldirs',
4141                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4142     }
4143   else
4144     {
4145       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4146       # at least one argument, and $(mkinstalldirs) used to work
4147       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4148       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4149     }
4150
4151   reject_var ('CONFIG_HEADER',
4152               "'CONFIG_HEADER' is an anachronism; now determined "
4153               . "automatically\nfrom '$configure_ac'");
4154
4155   my @config_h;
4156   foreach my $spec (@config_headers)
4157     {
4158       my ($out, @ins) = split_config_file_spec ($spec);
4159       # Generate CONFIG_HEADER define.
4160       if ($relative_dir eq dirname ($out))
4161         {
4162           push @config_h, basename ($out);
4163         }
4164       else
4165         {
4166           push @config_h, "\$(top_builddir)/$out";
4167         }
4168     }
4169   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4170     if @config_h;
4171
4172   # Now look for other files in this directory which must be remade
4173   # by config.status, and generate rules for them.
4174   my @actual_other_files = ();
4175   # These get cleaned only in a VPATH build.
4176   my @actual_other_vpath_files = ();
4177   foreach my $lfile (@other_input_files)
4178     {
4179       my $file;
4180       my @inputs;
4181       if ($lfile =~ /^([^:]*):(.*)$/)
4182         {
4183           # This is the ":" syntax of AC_OUTPUT.
4184           $file = $1;
4185           @inputs = split (':', $2);
4186         }
4187       else
4188         {
4189           # Normal usage.
4190           $file = $lfile;
4191           @inputs = $file . '.in';
4192         }
4193
4194       # Automake files should not be stored in here, but in %MAKE_LIST.
4195       prog_error ("$lfile in \@other_input_files\n"
4196                   . "\@other_input_files = (@other_input_files)")
4197         if -f $file . '.am';
4198
4199       my $local = basename ($file);
4200
4201       # We skip files that aren't in this directory.  However, if
4202       # the file's directory does not have a Makefile, and we are
4203       # currently doing '.', then we create a rule to rebuild the
4204       # file in the subdir.
4205       my $fd = dirname ($file);
4206       if ($fd ne $relative_dir)
4207         {
4208           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4209             {
4210               $local = $file;
4211             }
4212           else
4213             {
4214               next;
4215             }
4216         }
4217
4218       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4219
4220       # Cannot output rules for shell variables.
4221       next if (substitute_ac_subst_variables $local) =~ /\$/;
4222
4223       my $condstr = '';
4224       my $cond = $ac_config_files_condition{$lfile};
4225       if (defined $cond)
4226         {
4227           $condstr = $cond->subst_string;
4228           Automake::Rule::define ($local, $configure_ac, RULE_AUTOMAKE, $cond,
4229                                   $ac_config_files_location{$file});
4230         }
4231       $output_rules .= ($condstr . $local . ': '
4232                         . '$(top_builddir)/config.status '
4233                         . "@rewritten_inputs\n"
4234                         . $condstr . "\t"
4235                         . 'cd $(top_builddir) && '
4236                         . '$(SHELL) ./config.status '
4237                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4238                         . '$@'
4239                         . "\n");
4240       push (@actual_other_files, $local);
4241     }
4242
4243   # For links we should clean destinations and distribute sources.
4244   foreach my $spec (@config_links)
4245     {
4246       my ($link, $file) = split /:/, $spec;
4247       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4248       # the DEST:SRC form.
4249       next unless $file;
4250       my $where = $ac_config_files_location{$link};
4251
4252       # Skip destinations that contain shell variables.
4253       if ((substitute_ac_subst_variables $link) !~ /\$/)
4254         {
4255           # We skip links that aren't in this directory.  However, if
4256           # the link's directory does not have a Makefile, and we are
4257           # currently doing '.', then we add the link to CONFIG_CLEAN_FILES
4258           # in '.'s Makefile.in.
4259           my $local = basename ($link);
4260           my $fd = dirname ($link);
4261           if ($fd ne $relative_dir)
4262             {
4263               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4264                 {
4265                   $local = $link;
4266                 }
4267               else
4268                 {
4269                   $local = undef;
4270                 }
4271             }
4272           if ($file ne $link)
4273             {
4274               push @actual_other_files, $local if $local;
4275             }
4276           else
4277             {
4278               push @actual_other_vpath_files, $local if $local;
4279             }
4280         }
4281
4282       # Do not process sources that contain shell variables.
4283       if ((substitute_ac_subst_variables $file) !~ /\$/)
4284         {
4285           my $fd = dirname ($file);
4286
4287           # We distribute files that are in this directory.
4288           # At the top-level ('.') we also distribute files whose
4289           # directory does not have a Makefile.
4290           if (($fd eq $relative_dir)
4291               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4292             {
4293               # The following will distribute $file as a side-effect when
4294               # it is appropriate (i.e., when $file is not already an output).
4295               # We do not need the result, just the side-effect.
4296               rewrite_inputs_into_dependencies ($link, $file);
4297             }
4298         }
4299     }
4300
4301   # These files get removed by "make distclean".
4302   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4303                           @actual_other_files);
4304   define_pretty_variable ('CONFIG_CLEAN_VPATH_FILES', TRUE, INTERNAL,
4305                           @actual_other_vpath_files);
4306 }
4307
4308 # Handle C headers.
4309 sub handle_headers
4310 {
4311     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4312                              'oldinclude', 'pkginclude',
4313                              'noinst', 'check');
4314     foreach (@r)
4315     {
4316       next unless $_->[1] =~ /\..*$/;
4317       &saw_extension ($&);
4318     }
4319 }
4320
4321 sub handle_gettext
4322 {
4323   return if ! $seen_gettext || $relative_dir ne '.';
4324
4325   my $subdirs = var 'SUBDIRS';
4326
4327   if (! $subdirs)
4328     {
4329       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4330       return;
4331     }
4332
4333   # Perform some sanity checks to help users get the right setup.
4334   # We disable these tests when po/ doesn't exist in order not to disallow
4335   # unusual gettext setups.
4336   #
4337   # Bruno Haible:
4338   # | The idea is:
4339   # |
4340   # |  1) If a package doesn't have a directory po/ at top level, it
4341   # |     will likely have multiple po/ directories in subpackages.
4342   # |
4343   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4344   # |     is used without 'external'. It is also useful to warn for the
4345   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4346   # |     warnings apply only to the usual layout of packages, therefore
4347   # |     they should both be disabled if no po/ directory is found at
4348   # |     top level.
4349
4350   if (-d 'po')
4351     {
4352       my @subdirs = $subdirs->value_as_list_recursive;
4353
4354       msg_var ('syntax', $subdirs,
4355                "AM_GNU_GETTEXT used but 'po' not in SUBDIRS")
4356         if ! grep ($_ eq 'po', @subdirs);
4357
4358       # intl/ is not required when AM_GNU_GETTEXT is called with the
4359       # 'external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4360       msg_var ('syntax', $subdirs,
4361                "AM_GNU_GETTEXT used but 'intl' not in SUBDIRS")
4362         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4363             && ! grep ($_ eq 'intl', @subdirs));
4364
4365       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4366       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4367       msg_var ('syntax', $subdirs,
4368                "'intl' should not be in SUBDIRS when "
4369                . "AM_GNU_GETTEXT([external]) is used")
4370         if ($seen_gettext_external && ! $seen_gettext_intl
4371             && grep ($_ eq 'intl', @subdirs));
4372     }
4373
4374   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4375 }
4376
4377 # Handle footer elements.
4378 sub handle_footer
4379 {
4380     reject_rule ('.SUFFIXES',
4381                  "use variable 'SUFFIXES', not target '.SUFFIXES'");
4382
4383     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4384     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4385     # anything else, by sticking it right after the default: target.
4386     $output_header .= ".SUFFIXES:\n";
4387     my $suffixes = var 'SUFFIXES';
4388     my @suffixes = Automake::Rule::suffixes;
4389     if (@suffixes || $suffixes)
4390     {
4391         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4392         # the output remains consistent.  However, $(SUFFIXES) is
4393         # always at the start of the list, unsorted.  This is done
4394         # because make will choose rules depending on the ordering of
4395         # suffixes, and this lets the user have some control.  Push
4396         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4397         # do not like variable substitutions on the .SUFFIXES line.
4398         my @user_suffixes = ($suffixes
4399                              ? $suffixes->value_as_list_recursive : ());
4400
4401         my %suffixes = map { $_ => 1 } @suffixes;
4402         delete @suffixes{@user_suffixes};
4403
4404         $output_header .= (".SUFFIXES: "
4405                            . join (' ', @user_suffixes, sort keys %suffixes)
4406                            . "\n");
4407     }
4408
4409     $output_trailer .= file_contents ('footer', new Automake::Location);
4410 }
4411
4412
4413 # Generate 'make install' rules.
4414 sub handle_install ()
4415 {
4416   $output_rules .= &file_contents
4417     ('install',
4418      new Automake::Location,
4419      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4420                              ? (" \$(BUILT_SOURCES)\n"
4421                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4422                              : ''),
4423      'installdirs-local' => (user_phony_rule 'installdirs-local'
4424                              ? ' installdirs-local' : ''),
4425      am__installdirs => variable_value ('am__installdirs') || '');
4426 }
4427
4428
4429 # Deal with all and all-am.
4430 sub handle_all ($)
4431 {
4432     my ($makefile) = @_;
4433
4434     # Output 'all-am'.
4435
4436     # Put this at the beginning for the sake of non-GNU makes.  This
4437     # is still wrong if these makes can run parallel jobs.  But it is
4438     # right enough.
4439     unshift (@all, basename ($makefile));
4440
4441     foreach my $spec (@config_headers)
4442       {
4443         my ($out, @ins) = split_config_file_spec ($spec);
4444         push (@all, basename ($out))
4445           if dirname ($out) eq $relative_dir;
4446       }
4447
4448     # Install 'all' hooks.
4449     push (@all, "all-local")
4450       if user_phony_rule "all-local";
4451
4452     &pretty_print_rule ("all-am:", "\t\t", @all);
4453     &depend ('.PHONY', 'all-am', 'all');
4454
4455
4456     # Output 'all'.
4457
4458     my @local_headers = ();
4459     push @local_headers, '$(BUILT_SOURCES)'
4460       if var ('BUILT_SOURCES');
4461     foreach my $spec (@config_headers)
4462       {
4463         my ($out, @ins) = split_config_file_spec ($spec);
4464         push @local_headers, basename ($out)
4465           if dirname ($out) eq $relative_dir;
4466       }
4467
4468     if (@local_headers)
4469       {
4470         # We need to make sure config.h is built before we recurse.
4471         # We also want to make sure that built sources are built
4472         # before any ordinary 'all' targets are run.  We can't do this
4473         # by changing the order of dependencies to the "all" because
4474         # that breaks when using parallel makes.  Instead we handle
4475         # things explicitly.
4476         $output_all .= ("all: @local_headers"
4477                         . "\n\t"
4478                         . '$(MAKE) $(AM_MAKEFLAGS) '
4479                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4480                         . "\n\n");
4481         depend ('.MAKE', 'all');
4482       }
4483     else
4484       {
4485         $output_all .= "all: " . (var ('SUBDIRS')
4486                                   ? 'all-recursive' : 'all-am') . "\n\n";
4487       }
4488 }
4489
4490 # Generate helper targets for user recursion, where needed.
4491 sub handle_user_recursion ()
4492 {
4493   return unless @extra_recursive_targets;
4494
4495   define_pretty_variable ('am__extra_recursive_targets', TRUE, INTERNAL,
4496                           map { "$_-recursive" } @extra_recursive_targets);
4497   my $aux = var ('SUBDIRS') ? 'recursive' : 'am';
4498   foreach my $target (@extra_recursive_targets)
4499     {
4500       # This allows the default target's rules to be overridden in
4501       # Makefile.am.
4502       user_phony_rule ($target);
4503       depend ("$target", "$target-$aux");
4504       depend ("$target-am", "$target-local");
4505       # Every user-defined recursive target 'foo' *must* have a valid
4506       # associated 'foo-local' rule; we define it as an empty rule by
4507       # default, so that the user can transparently extend it in his
4508       # own Makefile.am.
4509       pretty_print_rule ("$target-local:");
4510       # $target-recursive might as well be undefined, so do not add
4511       # it here; it's taken care of in subdirs.am anyway.
4512       depend (".PHONY", "$target-am", "$target-local");
4513     }
4514 }
4515
4516
4517 # &do_check_merge_target ()
4518 # -------------------------
4519 # Handle check merge target specially.
4520 sub do_check_merge_target ()
4521 {
4522   # Include user-defined local form of target.
4523   push @check_tests, 'check-local'
4524     if user_phony_rule 'check-local';
4525
4526   # The check target must depend on the local equivalent of
4527   # 'all', to ensure all the primary targets are built.  Then it
4528   # must build the local check rules.
4529   $output_rules .= "check-am: all-am\n";
4530   if (@check)
4531     {
4532       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ", @check);
4533       depend ('.MAKE', 'check-am');
4534     }
4535
4536   if (@check_tests)
4537     {
4538       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4539                          @check_tests);
4540       depend ('.MAKE', 'check-am');
4541     }
4542
4543   depend '.PHONY', 'check', 'check-am';
4544   # Handle recursion.  We have to honor BUILT_SOURCES like for 'all:'.
4545   $output_rules .= ("check: "
4546                     . (var ('BUILT_SOURCES')
4547                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4548                        : '')
4549                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4550                     . "\n");
4551   depend ('.MAKE', 'check')
4552     if var ('BUILT_SOURCES');
4553 }
4554
4555 # handle_clean ($MAKEFILE)
4556 # ------------------------
4557 # Handle all 'clean' targets.
4558 sub handle_clean ($)
4559 {
4560   my ($makefile) = @_;
4561
4562   # Clean the files listed in user variables if they exist.
4563   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4564     if var ('MOSTLYCLEANFILES');
4565   $clean_files{'$(CLEANFILES)'} = CLEAN
4566     if var ('CLEANFILES');
4567   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4568     if var ('DISTCLEANFILES');
4569   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4570     if var ('MAINTAINERCLEANFILES');
4571
4572   # Built sources are automatically removed by maintainer-clean.
4573   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4574     if var ('BUILT_SOURCES');
4575
4576   # Compute a list of "rm"s to run for each target.
4577   my %rms = (MOSTLY_CLEAN, [],
4578              CLEAN, [],
4579              DIST_CLEAN, [],
4580              MAINTAINER_CLEAN, []);
4581
4582   foreach my $file (keys %clean_files)
4583     {
4584       my $when = $clean_files{$file};
4585       prog_error 'invalid entry in %clean_files'
4586         unless exists $rms{$when};
4587
4588       my $rm = "rm -f $file";
4589       # If file is a variable, make sure when don't call 'rm -f' without args.
4590       $rm ="test -z \"$file\" || $rm"
4591         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4592
4593       push @{$rms{$when}}, "\t-$rm\n";
4594     }
4595
4596   $output_rules .= &file_contents
4597     ('clean',
4598      new Automake::Location,
4599      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4600      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4601      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4602      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4603      MAKEFILE             => basename $makefile,
4604      );
4605 }
4606
4607
4608 # &target_cmp ($A, $B)
4609 # --------------------
4610 # Subroutine for &handle_factored_dependencies to let '.PHONY' and
4611 # other '.TARGETS' be last.
4612 sub target_cmp
4613 {
4614   return 0 if $a eq $b;
4615
4616   my $a1 = substr ($a, 0, 1);
4617   my $b1 = substr ($b, 0, 1);
4618   if ($a1 ne $b1)
4619     {
4620       return -1 if $b1 eq '.';
4621       return 1 if $a1 eq '.';
4622     }
4623   return $a cmp $b;
4624 }
4625
4626
4627 # &handle_factored_dependencies ()
4628 # --------------------------------
4629 # Handle everything related to gathered targets.
4630 sub handle_factored_dependencies
4631 {
4632   # Reject bad hooks.
4633   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4634                      'uninstall-exec-local', 'uninstall-exec-hook',
4635                      'uninstall-dvi-local',
4636                      'uninstall-html-local',
4637                      'uninstall-info-local',
4638                      'uninstall-pdf-local',
4639                      'uninstall-ps-local')
4640     {
4641       my $x = $utarg;
4642       $x =~ s/-.*-/-/;
4643       reject_rule ($utarg, "use '$x', not '$utarg'");
4644     }
4645
4646   reject_rule ('install-local',
4647                "use 'install-data-local' or 'install-exec-local', "
4648                . "not 'install-local'");
4649
4650   reject_rule ('install-hook',
4651                "use 'install-data-hook' or 'install-exec-hook', "
4652                . "not 'install-hook'");
4653
4654   # Install the -local hooks.
4655   foreach (keys %dependencies)
4656     {
4657       # Hooks are installed on the -am targets.
4658       s/-am$// or next;
4659       depend ("$_-am", "$_-local")
4660         if user_phony_rule "$_-local";
4661     }
4662
4663   # Install the -hook hooks.
4664   # FIXME: Why not be as liberal as we are with -local hooks?
4665   foreach ('install-exec', 'install-data', 'uninstall')
4666     {
4667       if (user_phony_rule "$_-hook")
4668         {
4669           depend ('.MAKE', "$_-am");
4670           register_action("$_-am",
4671                           ("\t\@\$(NORMAL_INSTALL)\n"
4672                            . "\t\$(MAKE) \$(AM_MAKEFLAGS) $_-hook"));
4673         }
4674     }
4675
4676   # All the required targets are phony.
4677   depend ('.PHONY', keys %required_targets);
4678
4679   # Actually output gathered targets.
4680   foreach (sort target_cmp keys %dependencies)
4681     {
4682       # If there is nothing about this guy, skip it.
4683       next
4684         unless (@{$dependencies{$_}}
4685                 || $actions{$_}
4686                 || $required_targets{$_});
4687
4688       # Define gathered targets in undefined conditions.
4689       # FIXME: Right now we must handle .PHONY as an exception,
4690       # because people write things like
4691       #    .PHONY: myphonytarget
4692       # to append dependencies.  This would not work if Automake
4693       # refrained from defining its own .PHONY target as it does
4694       # with other overridden targets.
4695       # Likewise for '.MAKE'.
4696       my @undefined_conds = (TRUE,);
4697       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4698         {
4699           @undefined_conds =
4700             Automake::Rule::define ($_, 'internal',
4701                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4702         }
4703       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4704       foreach my $cond (@undefined_conds)
4705         {
4706           my $condstr = $cond->subst_string;
4707           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4708           $output_rules .= $actions{$_} if defined $actions{$_};
4709           $output_rules .= "\n";
4710         }
4711     }
4712 }
4713
4714
4715 # &handle_tests_dejagnu ()
4716 # ------------------------
4717 sub handle_tests_dejagnu
4718 {
4719     push (@check_tests, 'check-DEJAGNU');
4720     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4721 }
4722
4723 sub handle_per_suffix_test
4724 {
4725   my ($test_suffix, %transform) = @_;
4726   my ($pfx, $generic, $am_exeext);
4727   if ($test_suffix eq '')
4728     {
4729       $pfx = '';
4730       $generic = 0;
4731       $am_exeext = 'FALSE';
4732     }
4733   else
4734     {
4735       prog_error ("test suffix '$test_suffix' lacks leading dot")
4736         unless $test_suffix =~ m/^\.(.*)/;
4737       $pfx = uc ($1) . '_';
4738       $generic = 1;
4739       $am_exeext = exists $configure_vars{'EXEEXT'} ? 'am__EXEEXT'
4740                                                     : 'FALSE';
4741     }
4742   # The "test driver" program, deputed to handle tests protocol used by
4743   # test scripts.  By default, it's assumed that no protocol is used, so
4744   # we fall back to the old behaviour, implemented by the 'test-driver'
4745   # auxiliary script.
4746   if (! var "${pfx}LOG_DRIVER")
4747     {
4748       require_conf_file ("parallel-tests", FOREIGN, 'test-driver');
4749       define_variable ("${pfx}LOG_DRIVER",
4750                        "\$(SHELL) $am_config_aux_dir/test-driver",
4751                        INTERNAL);
4752     }
4753   my $driver = '$(' . $pfx . 'LOG_DRIVER)';
4754   my $driver_flags = '$(AM_' . $pfx . 'LOG_DRIVER_FLAGS)'
4755                        . ' $(' . $pfx . 'LOG_DRIVER_FLAGS)';
4756   my $compile = "${pfx}LOG_COMPILE";
4757   define_variable ($compile,
4758                    '$(' . $pfx . 'LOG_COMPILER)'
4759                       . ' $(AM_' .  $pfx . 'LOG_FLAGS)'
4760                       . ' $(' . $pfx . 'LOG_FLAGS)',
4761                      INTERNAL);
4762   $output_rules .= file_contents ('check2', new Automake::Location,
4763                                    GENERIC => $generic,
4764                                    DRIVER => $driver,
4765                                    DRIVER_FLAGS => $driver_flags,
4766                                    COMPILE => '$(' . $compile . ')',
4767                                    EXT => $test_suffix,
4768                                    am__EXEEXT => $am_exeext,
4769                                    %transform);
4770 }
4771
4772 # is_valid_test_extension ($EXT)
4773 # ------------------------------
4774 # Return true if $EXT can appear in $(TEST_EXTENSIONS), return false
4775 # otherwise.
4776 sub is_valid_test_extension ($)
4777 {
4778   my $ext = shift;
4779   return 1
4780     if ($ext =~ /^\.[a-zA-Z_][a-zA-Z0-9_]*$/);
4781   return 1
4782     if (exists $configure_vars{'EXEEXT'} && $ext eq subst ('EXEEXT'));
4783   return 0;
4784 }
4785
4786 # Handle TESTS variable and other checks.
4787 sub handle_tests
4788 {
4789   if (option 'dejagnu')
4790     {
4791       &handle_tests_dejagnu;
4792     }
4793   else
4794     {
4795       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4796         {
4797           reject_var ($c, "'$c' defined but 'dejagnu' not in "
4798                       . "'AUTOMAKE_OPTIONS'");
4799         }
4800     }
4801
4802   if (var ('TESTS'))
4803     {
4804       push (@check_tests, 'check-TESTS');
4805       my $check_deps = "@check";
4806       $output_rules .= &file_contents ('check', new Automake::Location,
4807                                        SERIAL_TESTS => !! option 'serial-tests',
4808                                        CHECK_DEPS => $check_deps);
4809
4810       # Tests that are known programs should have $(EXEEXT) appended.
4811       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4812       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4813       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4814         if (var ('XFAIL_TESTS'));
4815
4816       if (! option 'serial-tests')
4817         {
4818           define_variable ('TEST_SUITE_LOG', 'test-suite.log', INTERNAL);
4819           my $suff = '.test';
4820           my $at_exeext = '';
4821           my $handle_exeext = exists $configure_vars{'EXEEXT'};
4822           if ($handle_exeext)
4823             {
4824               $at_exeext = subst ('EXEEXT');
4825               $suff = $at_exeext  . ' ' . $suff;
4826             }
4827           if (! var 'TEST_EXTENSIONS')
4828             {
4829               define_variable ('TEST_EXTENSIONS', $suff, INTERNAL);
4830             }
4831           my $var = var 'TEST_EXTENSIONS';
4832           # Currently, we are not able to deal with conditional contents
4833           # in TEST_EXTENSIONS.
4834           if ($var->has_conditional_contents)
4835            {
4836              msg_var 'unsupported', $var,
4837                      "'TEST_EXTENSIONS' cannot have conditional contents";
4838            }
4839           my @test_suffixes = $var->value_as_list_recursive;
4840           if ((my @invalid_test_suffixes =
4841                   grep { !is_valid_test_extension $_ } @test_suffixes) > 0)
4842             {
4843               error $var->rdef (TRUE)->location,
4844                     "invalid test extensions: @invalid_test_suffixes";
4845             }
4846           @test_suffixes = grep { is_valid_test_extension $_ } @test_suffixes;
4847           if ($handle_exeext)
4848             {
4849               unshift (@test_suffixes, $at_exeext)
4850                 unless $test_suffixes[0] eq $at_exeext;
4851             }
4852           unshift (@test_suffixes, '');
4853
4854           transform_variable_recursively
4855             ('TESTS', 'TEST_LOGS', 'am__testlogs', 1, INTERNAL,
4856               sub {
4857                 my ($subvar, $val, $cond, $full_cond) = @_;
4858                 my $obj = $val;
4859                 return $obj
4860                   if $val =~ /^\@.*\@$/;
4861                 $obj =~ s/\$\(EXEEXT\)$//o;
4862
4863                 if ($val =~ /(\$\((top_)?srcdir\))\//o)
4864                   {
4865                     msg ('error', $subvar->rdef ($cond)->location,
4866                          "using '$1' in TESTS is currently broken: '$val'");
4867                   }
4868
4869                 foreach my $test_suffix (@test_suffixes)
4870                   {
4871                     next
4872                       if $test_suffix eq $at_exeext || $test_suffix eq '';
4873                     return substr ($obj, 0, length ($obj) - length ($test_suffix)) . '.log'
4874                       if substr ($obj, - length ($test_suffix)) eq $test_suffix;
4875                   }
4876                 my $base = $obj;
4877                 $obj .= '.log';
4878                 handle_per_suffix_test ('',
4879                                         OBJ => $obj,
4880                                         BASE => $base,
4881                                         SOURCE => $val);
4882                 return $obj;
4883               });
4884
4885           my $nhelper=1;
4886           my $prev = 'TESTS';
4887           my $post = '';
4888           my $last_suffix = $test_suffixes[$#test_suffixes];
4889           my $cur = '';
4890           foreach my $test_suffix (@test_suffixes)
4891             {
4892               if ($test_suffix eq $last_suffix)
4893                 {
4894                   $cur = 'TEST_LOGS';
4895                 }
4896               else
4897                 {
4898                   $cur = 'am__test_logs' . $nhelper;
4899                 }
4900               define_variable ($cur,
4901                 '$(' . $prev . ':' . $test_suffix . $post . '=.log)', INTERNAL);
4902               $post = '.log';
4903               $prev = $cur;
4904               $nhelper++;
4905               if ($test_suffix ne $at_exeext && $test_suffix ne '')
4906                 {
4907                   handle_per_suffix_test ($test_suffix,
4908                                           OBJ => '',
4909                                           BASE => '$*',
4910                                           SOURCE => '$<');
4911                 }
4912             }
4913           $clean_files{'$(TEST_LOGS)'} = MOSTLY_CLEAN;
4914           $clean_files{'$(TEST_LOGS:.log=.trs)'} = MOSTLY_CLEAN;
4915           $clean_files{'$(TEST_SUITE_LOG)'} = MOSTLY_CLEAN;
4916         }
4917     }
4918 }
4919
4920 # Handle Emacs Lisp.
4921 sub handle_emacs_lisp
4922 {
4923   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4924                                  'lisp', 'noinst');
4925
4926   return if ! @elfiles;
4927
4928   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4929                           map { $_->[1] } @elfiles);
4930   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
4931                           '$(am__ELFILES:.el=.elc)');
4932   # This one can be overridden by users.
4933   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
4934
4935   push @all, '$(ELCFILES)';
4936
4937   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
4938                      'EMACS', 'lispdir');
4939 }
4940
4941 # Handle Python
4942 sub handle_python
4943 {
4944   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
4945                                  'noinst');
4946   return if ! @pyfiles;
4947
4948   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
4949   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
4950   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
4951 }
4952
4953 # Handle Java.
4954 sub handle_java
4955 {
4956     my @sourcelist = &am_install_var ('-candist',
4957                                       'java', 'JAVA',
4958                                       'noinst', 'check');
4959     return if ! @sourcelist;
4960
4961     my @prefixes = am_primary_prefixes ('JAVA', 1,
4962                                         'noinst', 'check');
4963
4964     my $dir;
4965     my @java_sources = ();
4966     foreach my $prefix (@prefixes)
4967       {
4968         (my $curs = $prefix) =~ s/^(?:nobase_)?(?:dist_|nodist_)?//;
4969
4970         next
4971           if $curs eq 'EXTRA';
4972
4973         push @java_sources, '$(' . $prefix . '_JAVA' . ')';
4974
4975         if (defined $dir)
4976           {
4977             err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
4978              unless $curs eq $dir;
4979           }
4980
4981         $dir = $curs;
4982       }
4983
4984     define_pretty_variable ('am__java_sources', TRUE, INTERNAL,
4985                             "@java_sources");
4986
4987     if ($dir eq 'check')
4988       {
4989         push (@check, "class$dir.stamp");
4990       }
4991     else
4992       {
4993         push (@all, "class$dir.stamp");
4994       }
4995 }
4996
4997
4998 # Handle some of the minor options.
4999 sub handle_minor_options
5000 {
5001   if (option 'readme-alpha')
5002     {
5003       if ($relative_dir eq '.')
5004         {
5005           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
5006             {
5007               msg ('error-gnits', $package_version_location,
5008                    "version '$package_version' doesn't follow " .
5009                    "Gnits standards");
5010             }
5011           if (defined $1 && -f 'README-alpha')
5012             {
5013               # This means we have an alpha release.  See
5014               # GNITS_VERSION_PATTERN for details.
5015               push_dist_common ('README-alpha');
5016             }
5017         }
5018     }
5019 }
5020
5021 ################################################################
5022
5023 # ($OUTPUT, @INPUTS)
5024 # &split_config_file_spec ($SPEC)
5025 # -------------------------------
5026 # Decode the Autoconf syntax for config files (files, headers, links
5027 # etc.).
5028 sub split_config_file_spec ($)
5029 {
5030   my ($spec) = @_;
5031   my ($output, @inputs) = split (/:/, $spec);
5032
5033   push @inputs, "$output.in"
5034     unless @inputs;
5035
5036   return ($output, @inputs);
5037 }
5038
5039 # $input
5040 # locate_am (@POSSIBLE_SOURCES)
5041 # -----------------------------
5042 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
5043 # This functions returns the first *.in file for which a *.am exists.
5044 # It returns undef otherwise.
5045 sub locate_am (@)
5046 {
5047   my (@rest) = @_;
5048   my $input;
5049   foreach my $file (@rest)
5050     {
5051       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
5052         {
5053           $input = $file;
5054           last;
5055         }
5056     }
5057   return $input;
5058 }
5059
5060 my %make_list;
5061
5062 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
5063 # ---------------------------------------------------
5064 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
5065 # (or AC_OUTPUT).
5066 sub scan_autoconf_config_files ($$)
5067 {
5068   my ($where, $config_files) = @_;
5069
5070   # Look at potential Makefile.am's.
5071   foreach (split ' ', $config_files)
5072     {
5073       # Must skip empty string for Perl 4.
5074       next if $_ eq "\\" || $_ eq '';
5075
5076       # Handle $local:$input syntax.
5077       my ($local, @rest) = split (/:/);
5078       @rest = ("$local.in",) unless @rest;
5079       # Keep in sync with 'conffile-leading-dot.test'.
5080       msg ('unsupported', $where,
5081            "omit leading './' from config file names such as '$local';"
5082            . "\nremake rules might be subtly broken otherwise")
5083         if ($local =~ /^\.\//);
5084       my $input = locate_am @rest;
5085       if ($input)
5086         {
5087           # We have a file that automake should generate.
5088           $make_list{$input} = join (':', ($local, @rest));
5089         }
5090       else
5091         {
5092           # We have a file that automake should cause to be
5093           # rebuilt, but shouldn't generate itself.
5094           push (@other_input_files, $_);
5095         }
5096       $ac_config_files_location{$local} = $where;
5097       $ac_config_files_condition{$local} =
5098         new Automake::Condition (@cond_stack)
5099           if (@cond_stack);
5100     }
5101 }
5102
5103
5104 # &scan_autoconf_traces ($FILENAME)
5105 # ---------------------------------
5106 sub scan_autoconf_traces ($)
5107 {
5108   my ($filename) = @_;
5109
5110   # Macros to trace, with their minimal number of arguments.
5111   #
5112   # IMPORTANT: If you add a macro here, you should also add this macro
5113   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
5114   my %traced = (
5115                 AC_CANONICAL_BUILD => 0,
5116                 AC_CANONICAL_HOST => 0,
5117                 AC_CANONICAL_TARGET => 0,
5118                 AC_CONFIG_AUX_DIR => 1,
5119                 AC_CONFIG_FILES => 1,
5120                 AC_CONFIG_HEADERS => 1,
5121                 AC_CONFIG_LIBOBJ_DIR => 1,
5122                 AC_CONFIG_LINKS => 1,
5123                 AC_FC_SRCEXT => 1,
5124                 AC_INIT => 0,
5125                 AC_LIBSOURCE => 1,
5126                 AC_REQUIRE_AUX_FILE => 1,
5127                 AC_SUBST_TRACE => 1,
5128                 AM_AUTOMAKE_VERSION => 1,
5129                 AM_CONDITIONAL => 2,
5130                 _AM_EXTRA_RECURSIVE_TARGETS => 1,
5131                 AM_GNU_GETTEXT => 0,
5132                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
5133                 AM_INIT_AUTOMAKE => 0,
5134                 AM_MAINTAINER_MODE => 0,
5135                 AM_PROG_AR => 0,
5136                 AM_PROG_CC_C_O => 0,
5137                 _AM_SUBST_NOTMAKE => 1,
5138                 _AM_COND_IF => 1,
5139                 _AM_COND_ELSE => 1,
5140                 _AM_COND_ENDIF => 1,
5141                 LT_SUPPORTED_TAG => 1,
5142                 _LT_AC_TAGCONFIG => 0,
5143                 m4_include => 1,
5144                 m4_sinclude => 1,
5145                 sinclude => 1,
5146               );
5147
5148   my $traces = ($ENV{AUTOCONF} || '@am_AUTOCONF@') . " ";
5149
5150   # Use a separator unlikely to be used, not ':', the default, which
5151   # has a precise meaning for AC_CONFIG_FILES and so on.
5152   $traces .= join (' ',
5153                    map { "--trace=$_" . ':\$f:\$l::\$d::\$n::\${::}%' }
5154                    (keys %traced));
5155
5156   my $tracefh = new Automake::XFile ("$traces $filename |");
5157   verb "reading $traces";
5158
5159   @cond_stack = ();
5160   my $where;
5161
5162   while ($_ = $tracefh->getline)
5163     {
5164       chomp;
5165       my ($here, $depth, @args) = split (/::/);
5166       $where = new Automake::Location $here;
5167       my $macro = $args[0];
5168
5169       prog_error ("unrequested trace '$macro'")
5170         unless exists $traced{$macro};
5171
5172       # Skip and diagnose malformed calls.
5173       if ($#args < $traced{$macro})
5174         {
5175           msg ('syntax', $where, "not enough arguments for $macro");
5176           next;
5177         }
5178
5179       # Alphabetical ordering please.
5180       if ($macro eq 'AC_CANONICAL_BUILD')
5181         {
5182           if ($seen_canonical <= AC_CANONICAL_BUILD)
5183             {
5184               $seen_canonical = AC_CANONICAL_BUILD;
5185             }
5186         }
5187       elsif ($macro eq 'AC_CANONICAL_HOST')
5188         {
5189           if ($seen_canonical <= AC_CANONICAL_HOST)
5190             {
5191               $seen_canonical = AC_CANONICAL_HOST;
5192             }
5193         }
5194       elsif ($macro eq 'AC_CANONICAL_TARGET')
5195         {
5196           $seen_canonical = AC_CANONICAL_TARGET;
5197         }
5198       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
5199         {
5200           if ($seen_init_automake)
5201             {
5202               error ($where, "AC_CONFIG_AUX_DIR must be called before "
5203                      . "AM_INIT_AUTOMAKE ...", partial => 1);
5204               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
5205             }
5206           $config_aux_dir = $args[1];
5207           $config_aux_dir_set_in_configure_ac = 1;
5208           check_directory ($config_aux_dir, $where);
5209         }
5210       elsif ($macro eq 'AC_CONFIG_FILES')
5211         {
5212           # Look at potential Makefile.am's.
5213           scan_autoconf_config_files ($where, $args[1]);
5214         }
5215       elsif ($macro eq 'AC_CONFIG_HEADERS')
5216         {
5217           foreach my $spec (split (' ', $args[1]))
5218             {
5219               my ($dest, @src) = split (':', $spec);
5220               $ac_config_files_location{$dest} = $where;
5221               push @config_headers, $spec;
5222             }
5223         }
5224       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
5225         {
5226           $config_libobj_dir = $args[1];
5227           check_directory ($config_libobj_dir, $where);
5228         }
5229       elsif ($macro eq 'AC_CONFIG_LINKS')
5230         {
5231           foreach my $spec (split (' ', $args[1]))
5232             {
5233               my ($dest, $src) = split (':', $spec);
5234               $ac_config_files_location{$dest} = $where;
5235               push @config_links, $spec;
5236             }
5237         }
5238       elsif ($macro eq 'AC_FC_SRCEXT')
5239         {
5240           my $suffix = $args[1];
5241           # These flags are used as %SOURCEFLAG% in depend2.am,
5242           # where the trailing space is important.
5243           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
5244             if ($suffix eq 'f90' || $suffix eq 'f95' || $suffix eq 'f03' || $suffix eq 'f08');
5245         }
5246       elsif ($macro eq 'AC_INIT')
5247         {
5248           if (defined $args[2])
5249             {
5250               $package_version = $args[2];
5251               $package_version_location = $where;
5252             }
5253         }
5254       elsif ($macro eq 'AC_LIBSOURCE')
5255         {
5256           $libsources{$args[1]} = $here;
5257         }
5258       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
5259         {
5260           # Only remember the first time a file is required.
5261           $required_aux_file{$args[1]} = $where
5262             unless exists $required_aux_file{$args[1]};
5263         }
5264       elsif ($macro eq 'AC_SUBST_TRACE')
5265         {
5266           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
5267           # AC_SUBST(5), then too bad.
5268           $configure_vars{$args[1]} = $where
5269             if $args[1] =~ /^\w+$/;
5270         }
5271       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
5272         {
5273           error ($where,
5274                  "version mismatch.  This is Automake $VERSION,\n" .
5275                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
5276                  "comes from Automake $args[1].  You should recreate\n" .
5277                  "aclocal.m4 with aclocal and run automake again.\n",
5278                  # $? = 63 is used to indicate version mismatch to missing.
5279                  exit_code => 63)
5280             if $VERSION ne $args[1];
5281
5282           $seen_automake_version = 1;
5283         }
5284       elsif ($macro eq 'AM_CONDITIONAL')
5285         {
5286           $configure_cond{$args[1]} = $where;
5287         }
5288       elsif ($macro eq '_AM_EXTRA_RECURSIVE_TARGETS')
5289         {
5290           push @extra_recursive_targets, split (' ', $args[1]);
5291         }
5292       elsif ($macro eq 'AM_GNU_GETTEXT')
5293         {
5294           $seen_gettext = $where;
5295           $ac_gettext_location = $where;
5296           $seen_gettext_external = grep ($_ eq 'external', @args);
5297         }
5298       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
5299         {
5300           $seen_gettext_intl = $where;
5301         }
5302       elsif ($macro eq 'AM_INIT_AUTOMAKE')
5303         {
5304           $seen_init_automake = $where;
5305           if (defined $args[2])
5306             {
5307               msg 'obsolete', $where, <<'EOF';
5308 AM_INIT_AUTOMAKE: two- and three-arguments forms are deprecated.  For more info, see:
5309 http://www.gnu.org/software/automake/manual/automake.html#Modernize-AM_INIT_AUTOMAKE-invocation
5310 EOF
5311               $package_version = $args[2];
5312               $package_version_location = $where;
5313             }
5314           elsif (defined $args[1])
5315             {
5316               my @opts = split (' ', $args[1]);
5317               @opts = map { { option => $_, where => $where } } @opts;
5318               exit $exit_code if process_global_option_list (@opts);
5319             }
5320         }
5321       elsif ($macro eq 'AM_MAINTAINER_MODE')
5322         {
5323           $seen_maint_mode = $where;
5324         }
5325       elsif ($macro eq 'AM_PROG_AR')
5326         {
5327           $seen_ar = $where;
5328         }
5329       elsif ($macro eq 'AM_PROG_CC_C_O')
5330         {
5331           $seen_cc_c_o = $where;
5332         }
5333       elsif ($macro eq '_AM_COND_IF')
5334         {
5335           cond_stack_if ('', $args[1], $where);
5336           error ($where, "missing m4 quoting, macro depth $depth")
5337             if ($depth != 1);
5338         }
5339       elsif ($macro eq '_AM_COND_ELSE')
5340         {
5341           cond_stack_else ('!', $args[1], $where);
5342           error ($where, "missing m4 quoting, macro depth $depth")
5343             if ($depth != 1);
5344         }
5345       elsif ($macro eq '_AM_COND_ENDIF')
5346         {
5347           cond_stack_endif (undef, undef, $where);
5348           error ($where, "missing m4 quoting, macro depth $depth")
5349             if ($depth != 1);
5350         }
5351       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5352         {
5353           $ignored_configure_vars{$args[1]} = $where;
5354         }
5355       elsif ($macro eq 'm4_include'
5356              || $macro eq 'm4_sinclude'
5357              || $macro eq 'sinclude')
5358         {
5359           # Skip missing 'sinclude'd files.
5360           next if $macro ne 'm4_include' && ! -f $args[1];
5361
5362           # Some modified versions of Autoconf don't use
5363           # frozen files.  Consequently it's possible that we see all
5364           # m4_include's performed during Autoconf's startup.
5365           # Obviously we don't want to distribute Autoconf's files
5366           # so we skip absolute filenames here.
5367           push @configure_deps, '$(top_srcdir)/' . $args[1]
5368             unless $here =~ m,^(?:\w:)?[\\/],;
5369           # Keep track of the greatest timestamp.
5370           if (-e $args[1])
5371             {
5372               my $mtime = mtime $args[1];
5373               $configure_deps_greatest_timestamp = $mtime
5374                 if $mtime > $configure_deps_greatest_timestamp;
5375             }
5376         }
5377       elsif ($macro eq 'LT_SUPPORTED_TAG')
5378         {
5379           $libtool_tags{$args[1]} = 1;
5380           $libtool_new_api = 1;
5381         }
5382       elsif ($macro eq '_LT_AC_TAGCONFIG')
5383         {
5384           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5385           # We use it to detect whether tags are supported.  Our
5386           # preferred interface is LT_SUPPORTED_TAG, but it was
5387           # introduced in Libtool 1.6.
5388           if (0 == keys %libtool_tags)
5389             {
5390               # Hardcode the tags supported by Libtool 1.5.
5391               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5392             }
5393         }
5394     }
5395
5396   error ($where, "condition stack not properly closed")
5397     if (@cond_stack);
5398
5399   $tracefh->close;
5400 }
5401
5402
5403 # &scan_autoconf_files ()
5404 # -----------------------
5405 # Check whether we use 'configure.ac' or 'configure.in'.
5406 # Scan it (and possibly 'aclocal.m4') for interesting things.
5407 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5408 sub scan_autoconf_files ()
5409 {
5410   # Reinitialize libsources here.  This isn't really necessary,
5411   # since we currently assume there is only one configure.ac.  But
5412   # that won't always be the case.
5413   %libsources = ();
5414
5415   # Keep track of the youngest configure dependency.
5416   $configure_deps_greatest_timestamp = mtime $configure_ac;
5417   if (-e 'aclocal.m4')
5418     {
5419       my $mtime = mtime 'aclocal.m4';
5420       $configure_deps_greatest_timestamp = $mtime
5421         if $mtime > $configure_deps_greatest_timestamp;
5422     }
5423
5424   scan_autoconf_traces ($configure_ac);
5425
5426   @configure_input_files = sort keys %make_list;
5427   # Set input and output files if not specified by user.
5428   if (! @input_files)
5429     {
5430       @input_files = @configure_input_files;
5431       %output_files = %make_list;
5432     }
5433
5434
5435   if (! $seen_init_automake)
5436     {
5437       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5438               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5439               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5440               . "and that aclocal.m4 was recently regenerated "
5441               . "(using aclocal)");
5442     }
5443   else
5444     {
5445       if (! $seen_automake_version)
5446         {
5447           if (-f 'aclocal.m4')
5448             {
5449               error ($seen_init_automake,
5450                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5451                      "an\nold Automake version.  You should recreate " .
5452                      "aclocal.m4\nwith aclocal and run automake again",
5453                      # $? = 63 is used to indicate version mismatch to missing.
5454                      exit_code => 63);
5455             }
5456           else
5457             {
5458               error ($seen_init_automake,
5459                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5460                      "found,\nprobably because aclocal.m4 is missing.\n" .
5461                      "You should run aclocal to create this file, then\n" .
5462                      "run automake again");
5463             }
5464         }
5465     }
5466
5467   locate_aux_dir ();
5468
5469   # Look for some files we need.  Always check for these.  This
5470   # check must be done for every run, even those where we are only
5471   # looking at a subdir Makefile.  We must set relative_dir for
5472   # push_required_file to work.
5473   # Sort the files for stable verbose output.
5474   $relative_dir = '.';
5475   foreach my $file (sort keys %required_aux_file)
5476     {
5477       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5478     }
5479   err_am "'install.sh' is an anachronism; use 'install-sh' instead"
5480     if -f $config_aux_dir . '/install.sh';
5481
5482   # Preserve dist_common for later.
5483   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5484
5485 }
5486
5487 ################################################################
5488
5489 # Do any extra checking for GNU standards.
5490 sub check_gnu_standards
5491 {
5492   if ($relative_dir eq '.')
5493     {
5494       # In top level (or only) directory.
5495       require_file ("$am_file.am", GNU,
5496                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5497
5498       # Accept one of these three licenses; default to COPYING.
5499       # Make sure we do not overwrite an existing license.
5500       my $license;
5501       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5502         {
5503           if (-f $_)
5504             {
5505               $license = $_;
5506               last;
5507             }
5508         }
5509       require_file ("$am_file.am", GNU, 'COPYING')
5510         unless $license;
5511     }
5512
5513   for my $opt ('no-installman', 'no-installinfo')
5514     {
5515       msg ('error-gnu', option $opt,
5516            "option '$opt' disallowed by GNU standards")
5517         if option $opt;
5518     }
5519 }
5520
5521 # Do any extra checking for GNITS standards.
5522 sub check_gnits_standards
5523 {
5524   if ($relative_dir eq '.')
5525     {
5526       # In top level (or only) directory.
5527       require_file ("$am_file.am", GNITS, 'THANKS');
5528     }
5529 }
5530
5531 ################################################################
5532 #
5533 # Functions to handle files of each language.
5534
5535 # Each 'lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5536 # simple formula: Return value is LANG_SUBDIR if the resulting object
5537 # file should be in a subdir if the source file is, LANG_PROCESS if
5538 # file is to be dealt with, LANG_IGNORE otherwise.
5539
5540 # Much of the actual processing is handled in
5541 # handle_single_transform.  These functions exist so that
5542 # auxiliary information can be recorded for a later cleanup pass.
5543 # Note that the calls to these functions are computed, so don't bother
5544 # searching for their precise names in the source.
5545
5546 # This is just a convenience function that can be used to determine
5547 # when a subdir object should be used.
5548 sub lang_sub_obj
5549 {
5550     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5551 }
5552
5553 # Rewrite a single C source file.
5554 sub lang_c_rewrite
5555 {
5556   my ($directory, $base, $ext, $obj, $have_per_exec_flags, $var) = @_;
5557
5558   my $r = LANG_PROCESS;
5559   if (option 'subdir-objects')
5560     {
5561       $r = LANG_SUBDIR;
5562       if ($directory && $directory ne '.')
5563         {
5564           $base = $directory . '/' . $base;
5565
5566           # libtool is always able to put the object at the proper place,
5567           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5568           msg_var ('portability', $var,
5569                    "compiling '$base.c' in subdir requires "
5570                    . "'AM_PROG_CC_C_O' in '$configure_ac'",
5571                    uniq_scope => US_GLOBAL,
5572                    uniq_part => 'AM_PROG_CC_C_O subdir')
5573             unless $seen_cc_c_o || $obj eq '.lo';
5574         }
5575     }
5576
5577   if (! $seen_cc_c_o
5578       && $have_per_exec_flags
5579       && ! option 'subdir-objects'
5580       && $obj ne '.lo')
5581     {
5582       msg_var ('portability',
5583                $var, "compiling '$base.c' with per-target flags requires "
5584                . "'AM_PROG_CC_C_O' in '$configure_ac'",
5585                uniq_scope => US_GLOBAL,
5586                uniq_part => 'AM_PROG_CC_C_O per-target')
5587     }
5588
5589     return $r;
5590 }
5591
5592 # Rewrite a single C++ source file.
5593 sub lang_cxx_rewrite
5594 {
5595     return &lang_sub_obj;
5596 }
5597
5598 # Rewrite a single header file.
5599 sub lang_header_rewrite
5600 {
5601     # Header files are simply ignored.
5602     return LANG_IGNORE;
5603 }
5604
5605 # Rewrite a single Vala source file.
5606 sub lang_vala_rewrite
5607 {
5608     my ($directory, $base, $ext) = @_;
5609
5610     (my $newext = $ext) =~ s/vala$/c/;
5611     return (LANG_SUBDIR, $newext);
5612 }
5613
5614 # Rewrite a single yacc file.
5615 sub lang_yacc_rewrite
5616 {
5617     my ($directory, $base, $ext) = @_;
5618
5619     my $r = &lang_sub_obj;
5620     (my $newext = $ext) =~ tr/y/c/;
5621     return ($r, $newext);
5622 }
5623
5624 # Rewrite a single yacc++ file.
5625 sub lang_yaccxx_rewrite
5626 {
5627     my ($directory, $base, $ext) = @_;
5628
5629     my $r = &lang_sub_obj;
5630     (my $newext = $ext) =~ tr/y/c/;
5631     return ($r, $newext);
5632 }
5633
5634 # Rewrite a single lex file.
5635 sub lang_lex_rewrite
5636 {
5637     my ($directory, $base, $ext) = @_;
5638
5639     my $r = &lang_sub_obj;
5640     (my $newext = $ext) =~ tr/l/c/;
5641     return ($r, $newext);
5642 }
5643
5644 # Rewrite a single lex++ file.
5645 sub lang_lexxx_rewrite
5646 {
5647     my ($directory, $base, $ext) = @_;
5648
5649     my $r = &lang_sub_obj;
5650     (my $newext = $ext) =~ tr/l/c/;
5651     return ($r, $newext);
5652 }
5653
5654 # Rewrite a single assembly file.
5655 sub lang_asm_rewrite
5656 {
5657     return &lang_sub_obj;
5658 }
5659
5660 # Rewrite a single preprocessed assembly file.
5661 sub lang_cppasm_rewrite
5662 {
5663     return &lang_sub_obj;
5664 }
5665
5666 # Rewrite a single Fortran 77 file.
5667 sub lang_f77_rewrite
5668 {
5669     return &lang_sub_obj;
5670 }
5671
5672 # Rewrite a single Fortran file.
5673 sub lang_fc_rewrite
5674 {
5675     return &lang_sub_obj;
5676 }
5677
5678 # Rewrite a single preprocessed Fortran file.
5679 sub lang_ppfc_rewrite
5680 {
5681     return &lang_sub_obj;
5682 }
5683
5684 # Rewrite a single preprocessed Fortran 77 file.
5685 sub lang_ppf77_rewrite
5686 {
5687     return &lang_sub_obj;
5688 }
5689
5690 # Rewrite a single ratfor file.
5691 sub lang_ratfor_rewrite
5692 {
5693     return &lang_sub_obj;
5694 }
5695
5696 # Rewrite a single Objective C file.
5697 sub lang_objc_rewrite
5698 {
5699     return &lang_sub_obj;
5700 }
5701
5702 # Rewrite a single Objective C++ file.
5703 sub lang_objcxx_rewrite
5704 {
5705     return &lang_sub_obj;
5706 }
5707
5708 # Rewrite a single Unified Parallel C file.
5709 sub lang_upc_rewrite
5710 {
5711     return &lang_sub_obj;
5712 }
5713
5714 # Rewrite a single Java file.
5715 sub lang_java_rewrite
5716 {
5717     return LANG_SUBDIR;
5718 }
5719
5720 # The lang_X_finish functions are called after all source file
5721 # processing is done.  Each should handle defining rules for the
5722 # language, etc.  A finish function is only called if a source file of
5723 # the appropriate type has been seen.
5724
5725 sub lang_vala_finish_target ($$)
5726 {
5727   my ($self, $name) = @_;
5728
5729   my $derived = canonicalize ($name);
5730   my $var = var "${derived}_SOURCES";
5731   return unless $var;
5732
5733   my @vala_sources = grep { /\.(vala|vapi)$/ } ($var->value_as_list_recursive);
5734
5735   # For automake bug#11229.
5736   return unless @vala_sources;
5737
5738   foreach my $vala_file (@vala_sources)
5739     {
5740       my $c_file = $vala_file;
5741       if ($c_file =~ s/(.*)\.vala$/$1.c/)
5742         {
5743           $c_file = "\$(srcdir)/$c_file";
5744           $output_rules .= "$c_file: \$(srcdir)/${derived}_vala.stamp\n"
5745             . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5746             . "\t\@if test -f \$@; then :; else \\\n"
5747             . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5748             . "\tfi\n";
5749           $clean_files{$c_file} = MAINTAINER_CLEAN;
5750         }
5751     }
5752
5753   # Add rebuild rules for generated header and vapi files
5754   my $flags = var ($derived . '_VALAFLAGS');
5755   if ($flags)
5756     {
5757       my $lastflag = '';
5758       foreach my $flag ($flags->value_as_list_recursive)
5759         {
5760           if (grep (/$lastflag/, ('-H', '-h', '--header', '--internal-header',
5761                                   '--vapi', '--internal-vapi', '--gir')))
5762             {
5763               my $headerfile = "\$(srcdir)/$flag";
5764               $output_rules .= "$headerfile: \$(srcdir)/${derived}_vala.stamp\n"
5765                 . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5766                 . "\t\@if test -f \$@; then :; else \\\n"
5767                 . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5768                 . "\tfi\n";
5769
5770               # valac is not used when building from dist tarballs
5771               # distribute the generated files
5772               push_dist_common ($headerfile);
5773               $clean_files{$headerfile} = MAINTAINER_CLEAN;
5774             }
5775           $lastflag = $flag;
5776         }
5777     }
5778
5779   my $compile = $self->compile;
5780
5781   # Rewrite each occurrence of 'AM_VALAFLAGS' in the compile
5782   # rule into '${derived}_VALAFLAGS' if it exists.
5783   my $val = "${derived}_VALAFLAGS";
5784   $compile =~ s/\(AM_VALAFLAGS\)/\($val\)/
5785     if set_seen ($val);
5786
5787   # VALAFLAGS is a user variable (per GNU Standards),
5788   # it should not be overridden in the Makefile...
5789   check_user_variables 'VALAFLAGS';
5790
5791   my $dirname = dirname ($name);
5792
5793   # Only generate C code, do not run C compiler
5794   $compile .= " -C";
5795
5796   my $verbose = verbose_flag ('VALAC');
5797   my $silent = silent_flag ();
5798   my $stampfile = "\$(srcdir)/${derived}_vala.stamp";
5799
5800   $output_rules .=
5801     "\$(srcdir)/${derived}_vala.stamp: @vala_sources\n".
5802 # Since the C files generated from the vala sources depend on the
5803 # ${derived}_vala.stamp file, we must ensure its timestamp is older than
5804 # those of the C files generated by the valac invocation below (this is
5805 # especially important on systems with sub-second timestamp resolution).
5806 # Thus we need to create the stamp file *before* invoking valac, and to
5807 # move it to its final location only after valac has been invoked.
5808     "\t${silent}rm -f \$\@ && echo stamp > \$\@-t\n".
5809     "\t${verbose}\$(am__cd) \$(srcdir) && $compile @vala_sources\n".
5810     "\t${silent}mv -f \$\@-t \$\@\n";
5811
5812   push_dist_common ($stampfile);
5813
5814   $clean_files{$stampfile} = MAINTAINER_CLEAN;
5815 }
5816
5817 # Add output rules to invoke valac and create stamp file as a witness
5818 # to handle multiple outputs. This function is called after all source
5819 # file processing is done.
5820 sub lang_vala_finish
5821 {
5822   my ($self) = @_;
5823
5824   foreach my $prog (keys %known_programs)
5825     {
5826       lang_vala_finish_target ($self, $prog);
5827     }
5828
5829   while (my ($name) = each %known_libraries)
5830     {
5831       lang_vala_finish_target ($self, $name);
5832     }
5833 }
5834
5835 # The built .c files should be cleaned only on maintainer-clean
5836 # as the .c files are distributed. This function is called for each
5837 # .vala source file.
5838 sub lang_vala_target_hook
5839 {
5840   my ($self, $aggregate, $output, $input, %transform) = @_;
5841
5842   $clean_files{$output} = MAINTAINER_CLEAN;
5843 }
5844
5845 # This is a yacc helper which is called whenever we have decided to
5846 # compile a yacc file.
5847 sub lang_yacc_target_hook
5848 {
5849     my ($self, $aggregate, $output, $input, %transform) = @_;
5850
5851     # If some relevant *YFLAGS variable contains the '-d' flag, we'll
5852     # have to to generate special code.
5853     my $yflags_contains_minus_d = 0;
5854
5855     foreach my $pfx ("", "${aggregate}_")
5856       {
5857         my $yflagsvar = var ("${pfx}YFLAGS");
5858         next unless $yflagsvar;
5859         # We cannot work reliably with conditionally-defined YFLAGS.
5860         if ($yflagsvar->has_conditional_contents)
5861           {
5862             msg_var ('unsupported', $yflagsvar,
5863                      "'${pfx}YFLAGS' cannot have conditional contents");
5864           }
5865         else
5866           {
5867             $yflags_contains_minus_d = 1
5868               if grep (/^-d$/, $yflagsvar->value_as_list_recursive);
5869           }
5870       }
5871
5872     if ($yflags_contains_minus_d)
5873       {
5874         # Found a '-d' that applies to the compilation of this file.
5875         # Add a dependency for the generated header file, and arrange
5876         # for that file to be included in the distribution.
5877
5878         # The extension of the output file (e.g., '.c' or '.cxx').
5879         # We'll need it to compute the name of the generated header file.
5880         (my $output_ext = basename ($output)) =~ s/.*(\.[^.]+)$/$1/;
5881
5882         # We know that a yacc input should be turned into either a C or
5883         # C++ output file.  We depend on this fact (here and in yacc.am),
5884         # so check that it really holds.
5885         my $lang = $languages{$extension_map{$output_ext}};
5886         prog_error "invalid output name '$output' for yacc file '$input'"
5887           if (!$lang || ($lang->name ne 'c' && $lang->name ne 'cxx'));
5888
5889         (my $header_ext = $output_ext) =~ s/c/h/g;
5890         # Quote $output_ext in the regexp, so that dots in it are taken
5891         # as literal dots, not as metacharacters.
5892         (my $header = $output) =~ s/\Q$output_ext\E$/$header_ext/;
5893
5894         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5895                                                   RULE_AUTOMAKE, TRUE,
5896                                                   INTERNAL))
5897           {
5898             my $condstr = $cond->subst_string;
5899             $output_rules .=
5900               "$condstr${header}: $output\n"
5901               # Recover from removal of $header
5902               . "$condstr\t\@if test ! -f \$@; then rm -f $output; else :; fi\n"
5903               . "$condstr\t\@if test ! -f \$@; then \$(MAKE) \$(AM_MAKEFLAGS) $output; else :; fi\n";
5904           }
5905         # Distribute the generated file, unless its .y source was
5906         # listed in a nodist_ variable.  (&handle_source_transform
5907         # will set DIST_SOURCE.)
5908         &push_dist_common ($header)
5909           if $transform{'DIST_SOURCE'};
5910
5911         # The GNU rules say that yacc/lex output files should be removed
5912         # by maintainer-clean.  However, if the files are not distributed,
5913         # then we want to remove them with "make clean"; otherwise,
5914         # "make distcheck" will fail.
5915         $clean_files{$header} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5916       }
5917     # See the comment above for $HEADER.
5918     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5919 }
5920
5921 # This is a lex helper which is called whenever we have decided to
5922 # compile a lex file.
5923 sub lang_lex_target_hook
5924 {
5925     my ($self, $aggregate, $output, $input, %transform) = @_;
5926     # The GNU rules say that yacc/lex output files should be removed
5927     # by maintainer-clean.  However, if the files are not distributed,
5928     # then we want to remove them with "make clean"; otherwise,
5929     # "make distcheck" will fail.
5930     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5931 }
5932
5933 # This is a helper for both lex and yacc.
5934 sub yacc_lex_finish_helper
5935 {
5936   return if defined $language_scratch{'lex-yacc-done'};
5937   $language_scratch{'lex-yacc-done'} = 1;
5938
5939   # FIXME: for now, no line number.
5940   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
5941   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
5942 }
5943
5944 sub lang_yacc_finish
5945 {
5946   return if defined $language_scratch{'yacc-done'};
5947   $language_scratch{'yacc-done'} = 1;
5948
5949   reject_var 'YACCFLAGS', "'YACCFLAGS' obsolete; use 'YFLAGS' instead";
5950
5951   yacc_lex_finish_helper;
5952 }
5953
5954
5955 sub lang_lex_finish
5956 {
5957   return if defined $language_scratch{'lex-done'};
5958   $language_scratch{'lex-done'} = 1;
5959
5960   yacc_lex_finish_helper;
5961 }
5962
5963
5964 # Given a hash table of linker names, pick the name that has the most
5965 # precedence.  This is lame, but something has to have global
5966 # knowledge in order to eliminate the conflict.  Add more linkers as
5967 # required.
5968 sub resolve_linker
5969 {
5970     my (%linkers) = @_;
5971
5972     foreach my $l (qw(GCJLINK OBJCXXLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
5973     {
5974         return $l if defined $linkers{$l};
5975     }
5976     return 'LINK';
5977 }
5978
5979 # Called to indicate that an extension was used.
5980 sub saw_extension
5981 {
5982     my ($ext) = @_;
5983     $extension_seen{$ext} = 1;
5984 }
5985
5986 # register_language (%ATTRIBUTE)
5987 # ------------------------------
5988 # Register a single language.
5989 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
5990 sub register_language (%)
5991 {
5992   my (%option) = @_;
5993
5994   # Set the defaults.
5995   $option{'autodep'} = 'no'
5996     unless defined $option{'autodep'};
5997   $option{'linker'} = ''
5998     unless defined $option{'linker'};
5999   $option{'flags'} = []
6000     unless defined $option{'flags'};
6001   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
6002     unless defined $option{'output_extensions'};
6003   $option{'nodist_specific'} = 0
6004     unless defined $option{'nodist_specific'};
6005
6006   my $lang = new Language (%option);
6007
6008   # Fill indexes.
6009   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
6010   $languages{$lang->name} = $lang;
6011   my $link = $lang->linker;
6012   if ($link)
6013     {
6014       if (exists $link_languages{$link})
6015         {
6016           prog_error ("'$link' has different definitions in "
6017                       . $lang->name . " and " . $link_languages{$link}->name)
6018             if $lang->link ne $link_languages{$link}->link;
6019         }
6020       else
6021         {
6022           $link_languages{$link} = $lang;
6023         }
6024     }
6025
6026   # Update the pattern of known extensions.
6027   accept_extensions (@{$lang->extensions});
6028
6029   # Upate the $suffix_rule map.
6030   foreach my $suffix (@{$lang->extensions})
6031     {
6032       foreach my $dest (&{$lang->output_extensions} ($suffix))
6033         {
6034           register_suffix_rule (INTERNAL, $suffix, $dest);
6035         }
6036     }
6037 }
6038
6039 # derive_suffix ($EXT, $OBJ)
6040 # --------------------------
6041 # This function is used to find a path from a user-specified suffix $EXT
6042 # to $OBJ or to some other suffix we recognize internally, e.g. 'cc'.
6043 sub derive_suffix ($$)
6044 {
6045   my ($source_ext, $obj) = @_;
6046
6047   while (! $extension_map{$source_ext}
6048          && $source_ext ne $obj
6049          && exists $suffix_rules->{$source_ext}
6050          && exists $suffix_rules->{$source_ext}{$obj})
6051     {
6052       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
6053     }
6054
6055   return $source_ext;
6056 }
6057
6058
6059 ################################################################
6060
6061 # Pretty-print something and append to output_rules.
6062 sub pretty_print_rule
6063 {
6064     $output_rules .= &makefile_wrap (@_);
6065 }
6066
6067
6068 ################################################################
6069
6070
6071 ## -------------------------------- ##
6072 ## Handling the conditional stack.  ##
6073 ## -------------------------------- ##
6074
6075
6076 # $STRING
6077 # make_conditional_string ($NEGATE, $COND)
6078 # ----------------------------------------
6079 sub make_conditional_string ($$)
6080 {
6081   my ($negate, $cond) = @_;
6082   $cond = "${cond}_TRUE"
6083     unless $cond =~ /^TRUE|FALSE$/;
6084   $cond = Automake::Condition::conditional_negate ($cond)
6085     if $negate;
6086   return $cond;
6087 }
6088
6089
6090 my %_am_macro_for_cond =
6091   (
6092   AMDEP => "one of the compiler tests\n"
6093            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_OBJC, AC_PROG_OBJCXX,\n"
6094            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
6095   am__fastdepCC => 'AC_PROG_CC',
6096   am__fastdepCCAS => 'AM_PROG_AS',
6097   am__fastdepCXX => 'AC_PROG_CXX',
6098   am__fastdepGCJ => 'AM_PROG_GCJ',
6099   am__fastdepOBJC => 'AC_PROG_OBJC',
6100   am__fastdepOBJCXX => 'AC_PROG_OBJCXX',
6101   am__fastdepUPC => 'AM_PROG_UPC'
6102   );
6103
6104 # $COND
6105 # cond_stack_if ($NEGATE, $COND, $WHERE)
6106 # --------------------------------------
6107 sub cond_stack_if ($$$)
6108 {
6109   my ($negate, $cond, $where) = @_;
6110
6111   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
6112     {
6113       my $text = "$cond does not appear in AM_CONDITIONAL";
6114       my $scope = US_LOCAL;
6115       if (exists $_am_macro_for_cond{$cond})
6116         {
6117           my $mac = $_am_macro_for_cond{$cond};
6118           $text .= "\n  The usual way to define '$cond' is to add ";
6119           $text .= ($mac =~ / /) ? $mac : "'$mac'";
6120           $text .= "\n  to '$configure_ac' and run 'aclocal' and 'autoconf' again";
6121           # These warnings appear in Automake files (depend2.am),
6122           # so there is no need to display them more than once:
6123           $scope = US_GLOBAL;
6124         }
6125       error $where, $text, uniq_scope => $scope;
6126     }
6127
6128   push (@cond_stack, make_conditional_string ($negate, $cond));
6129
6130   return new Automake::Condition (@cond_stack);
6131 }
6132
6133
6134 # $COND
6135 # cond_stack_else ($NEGATE, $COND, $WHERE)
6136 # ----------------------------------------
6137 sub cond_stack_else ($$$)
6138 {
6139   my ($negate, $cond, $where) = @_;
6140
6141   if (! @cond_stack)
6142     {
6143       error $where, "else without if";
6144       return FALSE;
6145     }
6146
6147   $cond_stack[$#cond_stack] =
6148     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
6149
6150   # If $COND is given, check against it.
6151   if (defined $cond)
6152     {
6153       $cond = make_conditional_string ($negate, $cond);
6154
6155       error ($where, "else reminder ($negate$cond) incompatible with "
6156              . "current conditional: $cond_stack[$#cond_stack]")
6157         if $cond_stack[$#cond_stack] ne $cond;
6158     }
6159
6160   return new Automake::Condition (@cond_stack);
6161 }
6162
6163
6164 # $COND
6165 # cond_stack_endif ($NEGATE, $COND, $WHERE)
6166 # -----------------------------------------
6167 sub cond_stack_endif ($$$)
6168 {
6169   my ($negate, $cond, $where) = @_;
6170   my $old_cond;
6171
6172   if (! @cond_stack)
6173     {
6174       error $where, "endif without if";
6175       return TRUE;
6176     }
6177
6178   # If $COND is given, check against it.
6179   if (defined $cond)
6180     {
6181       $cond = make_conditional_string ($negate, $cond);
6182
6183       error ($where, "endif reminder ($negate$cond) incompatible with "
6184              . "current conditional: $cond_stack[$#cond_stack]")
6185         if $cond_stack[$#cond_stack] ne $cond;
6186     }
6187
6188   pop @cond_stack;
6189
6190   return new Automake::Condition (@cond_stack);
6191 }
6192
6193
6194
6195
6196
6197 ## ------------------------ ##
6198 ## Handling the variables.  ##
6199 ## ------------------------ ##
6200
6201
6202 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
6203 # -----------------------------------------------------
6204 # Like define_variable, but the value is a list, and the variable may
6205 # be defined conditionally.  The second argument is the condition
6206 # under which the value should be defined; this should be the empty
6207 # string to define the variable unconditionally.  The third argument
6208 # is a list holding the values to use for the variable.  The value is
6209 # pretty printed in the output file.
6210 sub define_pretty_variable ($$$@)
6211 {
6212     my ($var, $cond, $where, @value) = @_;
6213
6214     if (! vardef ($var, $cond))
6215     {
6216         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
6217                                     '', $where, VAR_PRETTY);
6218         rvar ($var)->rdef ($cond)->set_seen;
6219     }
6220 }
6221
6222
6223 # define_variable ($VAR, $VALUE, $WHERE)
6224 # --------------------------------------
6225 # Define a new Automake Makefile variable VAR to VALUE, but only if
6226 # not already defined.
6227 sub define_variable ($$$)
6228 {
6229     my ($var, $value, $where) = @_;
6230     define_pretty_variable ($var, TRUE, $where, $value);
6231 }
6232
6233
6234 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
6235 # ------------------------------------------------------------
6236 # Define the $VAR which content is the list of file names composed of
6237 # a @BASENAME and the $EXTENSION.
6238 sub define_files_variable ($\@$$)
6239 {
6240   my ($var, $basename, $extension, $where) = @_;
6241   define_variable ($var,
6242                    join (' ', map { "$_.$extension" } @$basename),
6243                    $where);
6244 }
6245
6246
6247 # Like define_variable, but define a variable to be the configure
6248 # substitution by the same name.
6249 sub define_configure_variable ($)
6250 {
6251   my ($var) = @_;
6252   # Some variables we do not want to output.  For instance it
6253   # would be a bad idea to output `U = @U@` when `@U@` can be
6254   # substituted as `\`.
6255   my $pretty = exists $ignored_configure_vars{$var} ? VAR_SILENT : VAR_ASIS;
6256   Automake::Variable::define ($var, VAR_CONFIGURE, '', TRUE, subst $var,
6257                               '', $configure_vars{$var}, $pretty);
6258 }
6259
6260
6261 # define_compiler_variable ($LANG)
6262 # --------------------------------
6263 # Define a compiler variable.  We also handle defining the 'LT'
6264 # version of the command when using libtool.
6265 sub define_compiler_variable ($)
6266 {
6267     my ($lang) = @_;
6268
6269     my ($var, $value) = ($lang->compiler, $lang->compile);
6270     my $libtool_tag = '';
6271     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6272       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6273     &define_variable ($var, $value, INTERNAL);
6274     if (var ('LIBTOOL'))
6275       {
6276         my $verbose = define_verbose_libtool ();
6277         &define_variable ("LT$var",
6278                           "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6279                           . "\$(LIBTOOLFLAGS) --mode=compile $value",
6280                           INTERNAL);
6281       }
6282     define_verbose_tagvar ($lang->ccer || 'GEN');
6283 }
6284
6285
6286 # define_linker_variable ($LANG)
6287 # ------------------------------
6288 # Define linker variables.
6289 sub define_linker_variable ($)
6290 {
6291     my ($lang) = @_;
6292
6293     my $libtool_tag = '';
6294     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6295       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6296     # CCLD = $(CC).
6297     &define_variable ($lang->lder, $lang->ld, INTERNAL);
6298     # CCLINK = $(CCLD) blah blah...
6299     my $link = '';
6300     if (var ('LIBTOOL'))
6301       {
6302         my $verbose = define_verbose_libtool ();
6303         $link = "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6304                 . "\$(LIBTOOLFLAGS) --mode=link ";
6305       }
6306     &define_variable ($lang->linker, $link . $lang->link, INTERNAL);
6307     &define_variable ($lang->compiler,  $lang);
6308     &define_verbose_tagvar ($lang->lder || 'GEN');
6309 }
6310
6311 sub define_per_target_linker_variable ($$)
6312 {
6313   my ($linker, $target) = @_;
6314
6315   # If the user wrote a custom link command, we don't define ours.
6316   return "${target}_LINK"
6317     if set_seen "${target}_LINK";
6318
6319   my $xlink = $linker ? $linker : 'LINK';
6320
6321   my $lang = $link_languages{$xlink};
6322   prog_error "Unknown language for linker variable '$xlink'"
6323     unless $lang;
6324
6325   my $link_command = $lang->link;
6326   if (var 'LIBTOOL')
6327     {
6328       my $libtool_tag = '';
6329       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6330         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6331
6332       my $verbose = define_verbose_libtool ();
6333       $link_command =
6334         "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6335         . "--mode=link " . $link_command;
6336     }
6337
6338   # Rewrite each occurrence of 'AM_$flag' in the link
6339   # command into '${derived}_$flag' if it exists.
6340   my $orig_command = $link_command;
6341   my @flags = (@{$lang->flags}, 'LDFLAGS');
6342   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6343   for my $flag (@flags)
6344     {
6345       my $val = "${target}_$flag";
6346       $link_command =~ s/\(AM_$flag\)/\($val\)/
6347         if set_seen ($val);
6348     }
6349
6350   # If the computed command is the same as the generic command, use
6351   # the command linker variable.
6352   return ($lang->linker, $lang->lder)
6353     if $link_command eq $orig_command;
6354
6355   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6356   return ("${target}_LINK", $lang->lder);
6357 }
6358
6359 ################################################################
6360
6361 # &check_trailing_slash ($WHERE, $LINE)
6362 # -------------------------------------
6363 # Return 1 iff $LINE ends with a slash.
6364 # Might modify $LINE.
6365 sub check_trailing_slash ($\$)
6366 {
6367   my ($where, $line) = @_;
6368
6369   # Ignore '##' lines.
6370   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6371
6372   # Catch and fix a common error.
6373   msg "syntax", $where, "whitespace following trailing backslash"
6374     if $$line =~ s/\\\s+\n$/\\\n/;
6375
6376   return $$line =~ /\\$/;
6377 }
6378
6379
6380 # &read_am_file ($AMFILE, $WHERE)
6381 # -------------------------------
6382 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6383 # from Makefile.am into $output_trailer, or define variables as
6384 # appropriate.  NOTE we put rules in the trailer section.  We want
6385 # user rules to come after our generated stuff.
6386 sub read_am_file ($$)
6387 {
6388     my ($amfile, $where) = @_;
6389
6390     my $am_file = new Automake::XFile ("< $amfile");
6391     verb "reading $amfile";
6392
6393     # Keep track of the youngest output dependency.
6394     my $mtime = mtime $amfile;
6395     $output_deps_greatest_timestamp = $mtime
6396       if $mtime > $output_deps_greatest_timestamp;
6397
6398     my $spacing = '';
6399     my $comment = '';
6400     my $blank = 0;
6401     my $saw_bk = 0;
6402     my $var_look = VAR_ASIS;
6403
6404     use constant IN_VAR_DEF => 0;
6405     use constant IN_RULE_DEF => 1;
6406     use constant IN_COMMENT => 2;
6407     my $prev_state = IN_RULE_DEF;
6408
6409     while ($_ = $am_file->getline)
6410     {
6411         $where->set ("$amfile:$.");
6412         if (/$IGNORE_PATTERN/o)
6413         {
6414             # Merely delete comments beginning with two hashes.
6415         }
6416         elsif (/$WHITE_PATTERN/o)
6417         {
6418             error $where, "blank line following trailing backslash"
6419               if $saw_bk;
6420             # Stick a single white line before the incoming macro or rule.
6421             $spacing = "\n";
6422             $blank = 1;
6423             # Flush all comments seen so far.
6424             if ($comment ne '')
6425             {
6426                 $output_vars .= $comment;
6427                 $comment = '';
6428             }
6429         }
6430         elsif (/$COMMENT_PATTERN/o)
6431         {
6432             # Stick comments before the incoming macro or rule.  Make
6433             # sure a blank line precedes the first block of comments.
6434             $spacing = "\n" unless $blank;
6435             $blank = 1;
6436             $comment .= $spacing . $_;
6437             $spacing = '';
6438             $prev_state = IN_COMMENT;
6439         }
6440         else
6441         {
6442             last;
6443         }
6444         $saw_bk = check_trailing_slash ($where, $_);
6445     }
6446
6447     # We save the conditional stack on entry, and then check to make
6448     # sure it is the same on exit.  This lets us conditionally include
6449     # other files.
6450     my @saved_cond_stack = @cond_stack;
6451     my $cond = new Automake::Condition (@cond_stack);
6452
6453     my $last_var_name = '';
6454     my $last_var_type = '';
6455     my $last_var_value = '';
6456     my $last_where;
6457     # FIXME: shouldn't use $_ in this loop; it is too big.
6458     while ($_)
6459     {
6460         $where->set ("$amfile:$.");
6461
6462         # Make sure the line is \n-terminated.
6463         chomp;
6464         $_ .= "\n";
6465
6466         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6467         # used by users.  @MAINT@ is an anachronism now.
6468         $_ =~ s/\@MAINT\@//g
6469             unless $seen_maint_mode;
6470
6471         my $new_saw_bk = check_trailing_slash ($where, $_);
6472
6473         if (/$IGNORE_PATTERN/o)
6474         {
6475             # Merely delete comments beginning with two hashes.
6476
6477             # Keep any backslash from the previous line.
6478             $new_saw_bk = $saw_bk;
6479         }
6480         elsif (/$WHITE_PATTERN/o)
6481         {
6482             # Stick a single white line before the incoming macro or rule.
6483             $spacing = "\n";
6484             error $where, "blank line following trailing backslash"
6485               if $saw_bk;
6486         }
6487         elsif (/$COMMENT_PATTERN/o)
6488         {
6489             error $where, "comment following trailing backslash"
6490               if $saw_bk && $prev_state != IN_COMMENT;
6491
6492             # Stick comments before the incoming macro or rule.
6493             $comment .= $spacing . $_;
6494             $spacing = '';
6495             $prev_state = IN_COMMENT;
6496         }
6497         elsif ($saw_bk)
6498         {
6499             if ($prev_state == IN_RULE_DEF)
6500             {
6501               my $cond = new Automake::Condition @cond_stack;
6502               $output_trailer .= $cond->subst_string;
6503               $output_trailer .= $_;
6504             }
6505             elsif ($prev_state == IN_COMMENT)
6506             {
6507                 # If the line doesn't start with a '#', add it.
6508                 # We do this because a continued comment like
6509                 #   # A = foo \
6510                 #         bar \
6511                 #         baz
6512                 # is not portable.  BSD make doesn't honor
6513                 # escaped newlines in comments.
6514                 s/^#?/#/;
6515                 $comment .= $spacing . $_;
6516             }
6517             else # $prev_state == IN_VAR_DEF
6518             {
6519               $last_var_value .= ' '
6520                 unless $last_var_value =~ /\s$/;
6521               $last_var_value .= $_;
6522
6523               if (!/\\$/)
6524                 {
6525                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6526                                               $last_var_type, $cond,
6527                                               $last_var_value, $comment,
6528                                               $last_where, VAR_ASIS)
6529                     if $cond != FALSE;
6530                   $comment = $spacing = '';
6531                 }
6532             }
6533         }
6534
6535         elsif (/$IF_PATTERN/o)
6536           {
6537             $cond = cond_stack_if ($1, $2, $where);
6538           }
6539         elsif (/$ELSE_PATTERN/o)
6540           {
6541             $cond = cond_stack_else ($1, $2, $where);
6542           }
6543         elsif (/$ENDIF_PATTERN/o)
6544           {
6545             $cond = cond_stack_endif ($1, $2, $where);
6546           }
6547
6548         elsif (/$RULE_PATTERN/o)
6549         {
6550             # Found a rule.
6551             $prev_state = IN_RULE_DEF;
6552
6553             # For now we have to output all definitions of user rules
6554             # and can't diagnose duplicates (see the comment in
6555             # Automake::Rule::define). So we go on and ignore the return value.
6556             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6557
6558             check_variable_expansions ($_, $where);
6559
6560             $output_trailer .= $comment . $spacing;
6561             my $cond = new Automake::Condition @cond_stack;
6562             $output_trailer .= $cond->subst_string;
6563             $output_trailer .= $_;
6564             $comment = $spacing = '';
6565         }
6566         elsif (/$ASSIGNMENT_PATTERN/o)
6567         {
6568             # Found a macro definition.
6569             $prev_state = IN_VAR_DEF;
6570             $last_var_name = $1;
6571             $last_var_type = $2;
6572             $last_var_value = $3;
6573             $last_where = $where->clone;
6574             if ($3 ne '' && substr ($3, -1) eq "\\")
6575               {
6576                 # We preserve the '\' because otherwise the long lines
6577                 # that are generated will be truncated by broken
6578                 # 'sed's.
6579                 $last_var_value = $3 . "\n";
6580               }
6581             # Normally we try to output variable definitions in the
6582             # same format they were input.  However, POSIX compliant
6583             # systems are not required to support lines longer than
6584             # 2048 bytes (most notably, some sed implementation are
6585             # limited to 4000 bytes, and sed is used by config.status
6586             # to rewrite Makefile.in into Makefile).  Moreover nobody
6587             # would really write such long lines by hand since it is
6588             # hardly maintainable.  So if a line is longer that 1000
6589             # bytes (an arbitrary limit), assume it has been
6590             # automatically generated by some tools, and flatten the
6591             # variable definition.  Otherwise, keep the variable as it
6592             # as been input.
6593             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6594
6595             if (!/\\$/)
6596               {
6597                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6598                                             $last_var_type, $cond,
6599                                             $last_var_value, $comment,
6600                                             $last_where, $var_look)
6601                   if $cond != FALSE;
6602                 $comment = $spacing = '';
6603                 $var_look = VAR_ASIS;
6604               }
6605         }
6606         elsif (/$INCLUDE_PATTERN/o)
6607         {
6608             my $path = $1;
6609
6610             if ($path =~ s/^\$\(top_srcdir\)\///)
6611               {
6612                 push (@include_stack, "\$\(top_srcdir\)/$path");
6613                 # Distribute any included file.
6614
6615                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6616                 # otherwise OSF make will implicitly copy the included
6617                 # file in the build tree during "make distdir" to satisfy
6618                 # the dependency.
6619                 # (subdircond2.test and subdircond3.test will fail.)
6620                 push_dist_common ("\$\(top_srcdir\)/$path");
6621               }
6622             else
6623               {
6624                 $path =~ s/\$\(srcdir\)\///;
6625                 push (@include_stack, "\$\(srcdir\)/$path");
6626                 # Always use the $(srcdir) prefix in DIST_COMMON,
6627                 # otherwise OSF make will implicitly copy the included
6628                 # file in the build tree during "make distdir" to satisfy
6629                 # the dependency.
6630                 # (subdircond2.test and subdircond3.test will fail.)
6631                 push_dist_common ("\$\(srcdir\)/$path");
6632                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6633               }
6634             $where->push_context ("'$path' included from here");
6635             &read_am_file ($path, $where);
6636             $where->pop_context;
6637         }
6638         else
6639         {
6640             # This isn't an error; it is probably a continued rule.
6641             # In fact, this is what we assume.
6642             $prev_state = IN_RULE_DEF;
6643             check_variable_expansions ($_, $where);
6644             $output_trailer .= $comment . $spacing;
6645             my $cond = new Automake::Condition @cond_stack;
6646             $output_trailer .= $cond->subst_string;
6647             $output_trailer .= $_;
6648             $comment = $spacing = '';
6649             error $where, "'#' comment at start of rule is unportable"
6650               if $_ =~ /^\t\s*\#/;
6651         }
6652
6653         $saw_bk = $new_saw_bk;
6654         $_ = $am_file->getline;
6655     }
6656
6657     $output_trailer .= $comment;
6658
6659     error ($where, "trailing backslash on last line")
6660       if $saw_bk;
6661
6662     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6663                     : "too many conditionals closed in include file"))
6664       if "@saved_cond_stack" ne "@cond_stack";
6665 }
6666
6667
6668 # define_standard_variables ()
6669 # ----------------------------
6670 # A helper for read_main_am_file which initializes configure variables
6671 # and variables from header-vars.am.
6672 sub define_standard_variables
6673 {
6674   my $saved_output_vars = $output_vars;
6675   my ($comments, undef, $rules) =
6676     file_contents_internal (1, "$libdir/am/header-vars.am",
6677                             new Automake::Location);
6678
6679   foreach my $var (sort keys %configure_vars)
6680     {
6681       &define_configure_variable ($var);
6682     }
6683
6684   $output_vars .= $comments . $rules;
6685 }
6686
6687 # Read main am file.
6688 sub read_main_am_file ($$)
6689 {
6690     my ($amfile, $infile) = @_;
6691
6692     # This supports the strange variable tricks we are about to play.
6693     prog_error ("variable defined before read_main_am_file\n" . variables_dump ())
6694       if (scalar (variables) > 0);
6695
6696     # Generate copyright header for generated Makefile.in.
6697     # We do discard the output of predefined variables, handled below.
6698     $output_vars = ("# " . basename ($infile) . " generated by automake "
6699                    . $VERSION . " from " . basename ($amfile) . ".\n");
6700     $output_vars .= '# ' . subst ('configure_input') . "\n";
6701     $output_vars .= $gen_copyright;
6702
6703     # We want to predefine as many variables as possible.  This lets
6704     # the user set them with '+=' in Makefile.am.
6705     &define_standard_variables;
6706
6707     # Read user file, which might override some of our values.
6708     &read_am_file ($amfile, new Automake::Location);
6709 }
6710
6711
6712
6713 ################################################################
6714
6715 # $FLATTENED
6716 # &flatten ($STRING)
6717 # ------------------
6718 # Flatten the $STRING and return the result.
6719 sub flatten
6720 {
6721   $_ = shift;
6722
6723   s/\\\n//somg;
6724   s/\s+/ /g;
6725   s/^ //;
6726   s/ $//;
6727
6728   return $_;
6729 }
6730
6731
6732 # transform_token ($TOKEN, \%PAIRS, $KEY)
6733 # =======================================
6734 # Return the value associated to $KEY in %PAIRS, as used on $TOKEN
6735 # (which should be ?KEY? or any of the special %% requests)..
6736 sub transform_token ($$$)
6737 {
6738   my ($token, $transform, $key) = @_;
6739   my $res = $transform->{$key};
6740   prog_error "Unknown key '$key' in '$token'" unless defined $res;
6741   return $res;
6742 }
6743
6744
6745 # transform ($TOKEN, \%PAIRS)
6746 # ===========================
6747 # If ($TOKEN, $VAL) is in %PAIRS:
6748 #   - replaces %KEY% with $VAL,
6749 #   - enables/disables ?KEY? and ?!KEY?,
6750 #   - replaces %?KEY% with TRUE or FALSE.
6751 sub transform ($$)
6752 {
6753   my ($token, $transform) = @_;
6754
6755   # %KEY%.
6756   # Must be before the following pattern to exclude the case
6757   # when there is neither IFTRUE nor IFFALSE.
6758   if ($token =~ /^%([\w\-]+)%$/)
6759     {
6760       return transform_token ($token, $transform, $1);
6761     }
6762   # %?KEY%.
6763   elsif ($token =~ /^%\?([\w\-]+)%$/)
6764     {
6765       return transform_token ($token, $transform, $1) ? 'TRUE' : 'FALSE';
6766     }
6767   # ?KEY? and ?!KEY?.
6768   elsif ($token =~ /^ \? (!?) ([\w\-]+) \? $/x)
6769     {
6770       my $neg = ($1 eq '!') ? 1 : 0;
6771       my $val = transform_token ($token, $transform, $2);
6772       return (!!$val == $neg) ? '##%' : '';
6773     }
6774   else
6775     {
6776       prog_error "Unknown request format: $token";
6777     }
6778 }
6779
6780 # $TEXT
6781 # preprocess_file ($MAKEFILE, [%TRANSFORM])
6782 # -----------------------------------------
6783 # Load a $MAKEFILE, apply the %TRANSFORM, and return the result.
6784 # No extra parsing or post-processing is done (i.e., recognition of
6785 # rules declaration or of make variables definitions).
6786 sub preprocess_file ($%)
6787 {
6788   my ($file, %transform) = @_;
6789
6790   # Complete %transform with global options.
6791   # Note that %transform goes last, so it overrides global options.
6792   %transform = ( 'MAINTAINER-MODE'
6793                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6794
6795                  'XZ'          => !! option 'dist-xz',
6796                  'LZMA'        => !! option 'dist-lzma',
6797                  'LZIP'        => !! option 'dist-lzip',
6798                  'BZIP2'       => !! option 'dist-bzip2',
6799                  'COMPRESS'    => !! option 'dist-tarZ',
6800                  'GZIP'        =>  ! option 'no-dist-gzip',
6801                  'SHAR'        => !! option 'dist-shar',
6802                  'ZIP'         => !! option 'dist-zip',
6803
6804                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6805                  'INSTALL-MAN'  =>  ! option 'no-installman',
6806                  'HAVE-MANS'    => !! var ('MANS'),
6807                  'CK-NEWS'      => !! option 'check-news',
6808
6809                  'SUBDIRS'      => !! var ('SUBDIRS'),
6810                  'TOPDIR_P'     => $relative_dir eq '.',
6811
6812                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6813                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6814                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6815
6816                  'LIBTOOL'      => !! var ('LIBTOOL'),
6817                  'NONLIBTOOL'   => 1,
6818                 %transform);
6819
6820   if (! defined ($_ = $am_file_cache{$file}))
6821     {
6822       verb "reading $file";
6823       # Swallow the whole file.
6824       my $fc_file = new Automake::XFile "< $file";
6825       my $saved_dollar_slash = $/;
6826       undef $/;
6827       $_ = $fc_file->getline;
6828       $/ = $saved_dollar_slash;
6829       $fc_file->close;
6830       # Remove ##-comments.
6831       # Besides we don't need more than two consecutive new-lines.
6832       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6833       # Remember the contents of the just-read file.
6834       $am_file_cache{$file} = $_;
6835     }
6836
6837   # Substitute Automake template tokens.
6838   s/(?: % \?? [\w\-]+ %
6839       | \? !? [\w\-]+ \?
6840     )/transform($&, \%transform)/gex;
6841   # transform() may have added some ##%-comments to strip.
6842   # (we use '##%' instead of '##' so we can distinguish ##%##%##% from
6843   # ####### and do not remove the latter.)
6844   s/^[ \t]*(?:##%)+.*\n//gm;
6845
6846   return $_;
6847 }
6848
6849
6850 # @PARAGRAPHS
6851 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6852 # ------------------------------------------
6853 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6854 # paragraphs.
6855 sub make_paragraphs ($%)
6856 {
6857   my ($file, %transform) = @_;
6858   $transform{FIRST} = !$transformed_files{$file};
6859   $transformed_files{$file} = 1;
6860
6861   my @lines = split /(?<!\\)\n/, preprocess_file ($file, %transform);
6862   my @res;
6863
6864   while (defined ($_ = shift @lines))
6865     {
6866       my $paragraph = $_;
6867       # If we are a rule, eat as long as we start with a tab.
6868       if (/$RULE_PATTERN/smo)
6869         {
6870           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
6871             {
6872               $paragraph .= "\n$_";
6873             }
6874           unshift (@lines, $_);
6875         }
6876
6877       # If we are a comments, eat as much comments as you can.
6878       elsif (/$COMMENT_PATTERN/smo)
6879         {
6880           while (defined ($_ = shift @lines)
6881                  && $_ =~ /$COMMENT_PATTERN/smo)
6882             {
6883               $paragraph .= "\n$_";
6884             }
6885           unshift (@lines, $_);
6886         }
6887
6888       push @res, $paragraph;
6889     }
6890
6891   return @res;
6892 }
6893
6894
6895
6896 # ($COMMENT, $VARIABLES, $RULES)
6897 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
6898 # -------------------------------------------------------------
6899 # Return contents of a file from $libdir/am, automatically skipping
6900 # macros or rules which are already known. $IS_AM iff the caller is
6901 # reading an Automake file (as opposed to the user's Makefile.am).
6902 sub file_contents_internal ($$$%)
6903 {
6904     my ($is_am, $file, $where, %transform) = @_;
6905
6906     $where->set ($file);
6907
6908     my $result_vars = '';
6909     my $result_rules = '';
6910     my $comment = '';
6911     my $spacing = '';
6912
6913     # The following flags are used to track rules spanning across
6914     # multiple paragraphs.
6915     my $is_rule = 0;            # 1 if we are processing a rule.
6916     my $discard_rule = 0;       # 1 if the current rule should not be output.
6917
6918     # We save the conditional stack on entry, and then check to make
6919     # sure it is the same on exit.  This lets us conditionally include
6920     # other files.
6921     my @saved_cond_stack = @cond_stack;
6922     my $cond = new Automake::Condition (@cond_stack);
6923
6924     foreach (make_paragraphs ($file, %transform))
6925     {
6926         # FIXME: no line number available.
6927         $where->set ($file);
6928
6929         # Sanity checks.
6930         error $where, "blank line following trailing backslash:\n$_"
6931           if /\\$/;
6932         error $where, "comment following trailing backslash:\n$_"
6933           if /\\#/;
6934
6935         if (/^$/)
6936         {
6937             $is_rule = 0;
6938             # Stick empty line before the incoming macro or rule.
6939             $spacing = "\n";
6940         }
6941         elsif (/$COMMENT_PATTERN/mso)
6942         {
6943             $is_rule = 0;
6944             # Stick comments before the incoming macro or rule.
6945             $comment = "$_\n";
6946         }
6947
6948         # Handle inclusion of other files.
6949         elsif (/$INCLUDE_PATTERN/o)
6950         {
6951             if ($cond != FALSE)
6952               {
6953                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
6954                 $where->push_context ("'$file' included from here");
6955                 # N-ary '.=' fails.
6956                 my ($com, $vars, $rules)
6957                   = file_contents_internal ($is_am, $file, $where, %transform);
6958                 $where->pop_context;
6959                 $comment .= $com;
6960                 $result_vars .= $vars;
6961                 $result_rules .= $rules;
6962               }
6963         }
6964
6965         # Handling the conditionals.
6966         elsif (/$IF_PATTERN/o)
6967           {
6968             $cond = cond_stack_if ($1, $2, $file);
6969           }
6970         elsif (/$ELSE_PATTERN/o)
6971           {
6972             $cond = cond_stack_else ($1, $2, $file);
6973           }
6974         elsif (/$ENDIF_PATTERN/o)
6975           {
6976             $cond = cond_stack_endif ($1, $2, $file);
6977           }
6978
6979         # Handling rules.
6980         elsif (/$RULE_PATTERN/mso)
6981         {
6982           $is_rule = 1;
6983           $discard_rule = 0;
6984           # Separate relationship from optional actions: the first
6985           # `new-line tab" not preceded by backslash (continuation
6986           # line).
6987           my $paragraph = $_;
6988           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
6989           my ($relationship, $actions) = ($1, $2 || '');
6990
6991           # Separate targets from dependencies: the first colon.
6992           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
6993           my ($targets, $dependencies) = ($1, $2);
6994           # Remove the escaped new lines.
6995           # I don't know why, but I have to use a tmp $flat_deps.
6996           my $flat_deps = &flatten ($dependencies);
6997           my @deps = split (' ', $flat_deps);
6998
6999           foreach (split (' ', $targets))
7000             {
7001               # FIXME: 1. We are not robust to people defining several targets
7002               # at once, only some of them being in %dependencies.  The
7003               # actions from the targets in %dependencies are usually generated
7004               # from the content of %actions, but if some targets in $targets
7005               # are not in %dependencies the ELSE branch will output
7006               # a rule for all $targets (i.e. the targets which are both
7007               # in %dependencies and $targets will have two rules).
7008
7009               # FIXME: 2. The logic here is not able to output a
7010               # multi-paragraph rule several time (e.g. for each condition
7011               # it is defined for) because it only knows the first paragraph.
7012
7013               # FIXME: 3. We are not robust to people defining a subset
7014               # of a previously defined "multiple-target" rule.  E.g.
7015               # 'foo:' after 'foo bar:'.
7016
7017               # Output only if not in FALSE.
7018               if (defined $dependencies{$_} && $cond != FALSE)
7019                 {
7020                   &depend ($_, @deps);
7021                   register_action ($_, $actions);
7022                 }
7023               else
7024                 {
7025                   # Free-lance dependency.  Output the rule for all the
7026                   # targets instead of one by one.
7027                   my @undefined_conds =
7028                     Automake::Rule::define ($targets, $file,
7029                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
7030                                             $cond, $where);
7031                   for my $undefined_cond (@undefined_conds)
7032                     {
7033                       my $condparagraph = $paragraph;
7034                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
7035                       $result_rules .= "$spacing$comment$condparagraph\n";
7036                     }
7037                   if (scalar @undefined_conds == 0)
7038                     {
7039                       # Remember to discard next paragraphs
7040                       # if they belong to this rule.
7041                       # (but see also FIXME: #2 above.)
7042                       $discard_rule = 1;
7043                     }
7044                   $comment = $spacing = '';
7045                   last;
7046                 }
7047             }
7048         }
7049
7050         elsif (/$ASSIGNMENT_PATTERN/mso)
7051         {
7052             my ($var, $type, $val) = ($1, $2, $3);
7053             error $where, "variable '$var' with trailing backslash"
7054               if /\\$/;
7055
7056             $is_rule = 0;
7057
7058             Automake::Variable::define ($var,
7059                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
7060                                         $type, $cond, $val, $comment, $where,
7061                                         VAR_ASIS)
7062               if $cond != FALSE;
7063
7064             $comment = $spacing = '';
7065         }
7066         else
7067         {
7068             # This isn't an error; it is probably some tokens which
7069             # configure is supposed to replace, such as '@SET-MAKE@',
7070             # or some part of a rule cut by an if/endif.
7071             if (! $cond->false && ! ($is_rule && $discard_rule))
7072               {
7073                 s/^/$cond->subst_string/gme;
7074                 $result_rules .= "$spacing$comment$_\n";
7075               }
7076             $comment = $spacing = '';
7077         }
7078     }
7079
7080     error ($where, @cond_stack ?
7081            "unterminated conditionals: @cond_stack" :
7082            "too many conditionals closed in include file")
7083       if "@saved_cond_stack" ne "@cond_stack";
7084
7085     return ($comment, $result_vars, $result_rules);
7086 }
7087
7088
7089 # $CONTENTS
7090 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
7091 # ------------------------------------------------
7092 # Return contents of a file from $libdir/am, automatically skipping
7093 # macros or rules which are already known.
7094 sub file_contents ($$%)
7095 {
7096     my ($basename, $where, %transform) = @_;
7097     my ($comments, $variables, $rules) =
7098       file_contents_internal (1, "$libdir/am/$basename.am", $where,
7099                               %transform);
7100     return "$comments$variables$rules";
7101 }
7102
7103
7104 # @PREFIX
7105 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
7106 # -----------------------------------------------------
7107 # Find all variable prefixes that are used for install directories.  A
7108 # prefix 'zar' qualifies iff:
7109 #
7110 # * 'zardir' is a variable.
7111 # * 'zar_PRIMARY' is a variable.
7112 #
7113 # As a side effect, it looks for misspellings.  It is an error to have
7114 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
7115 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
7116 # of the same name (with "dir" appended) exists.  For instance, if the
7117 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
7118 # This is to provide a little extra flexibility in those cases which
7119 # need it.
7120 sub am_primary_prefixes ($$@)
7121 {
7122   my ($primary, $can_dist, @prefixes) = @_;
7123
7124   local $_;
7125   my %valid = map { $_ => 0 } @prefixes;
7126   $valid{'EXTRA'} = 0;
7127   foreach my $var (variables $primary)
7128     {
7129       # Automake is allowed to define variables that look like primaries
7130       # but which aren't.  E.g. INSTALL_sh_DATA.
7131       # Autoconf can also define variables like INSTALL_DATA, so
7132       # ignore all configure variables (at least those which are not
7133       # redefined in Makefile.am).
7134       # FIXME: We should make sure that these variables are not
7135       # conditionally defined (or else adjust the condition below).
7136       my $def = $var->def (TRUE);
7137       next if $def && $def->owner != VAR_MAKEFILE;
7138
7139       my $varname = $var->name;
7140
7141       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
7142         {
7143           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
7144           if ($dist ne '' && ! $can_dist)
7145             {
7146               err_var ($var,
7147                        "invalid variable '$varname': 'dist' is forbidden");
7148             }
7149           # Standard directories must be explicitly allowed.
7150           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
7151             {
7152               err_var ($var,
7153                        "'${X}dir' is not a legitimate directory " .
7154                        "for '$primary'");
7155             }
7156           # A not explicitly valid directory is allowed if Xdir is defined.
7157           elsif (! defined $valid{$X} &&
7158                  $var->requires_variables ("'$varname' is used", "${X}dir"))
7159             {
7160               # Nothing to do.  Any error message has been output
7161               # by $var->requires_variables.
7162             }
7163           else
7164             {
7165               # Ensure all extended prefixes are actually used.
7166               $valid{"$base$dist$X"} = 1;
7167             }
7168         }
7169       else
7170         {
7171           prog_error "unexpected variable name: $varname";
7172         }
7173     }
7174
7175   # Return only those which are actually defined.
7176   return sort grep { var ($_ . '_' . $primary) } keys %valid;
7177 }
7178
7179
7180 # Handle 'where_HOW' variable magic.  Does all lookups, generates
7181 # install code, and possibly generates code to define the primary
7182 # variable.  The first argument is the name of the .am file to munge,
7183 # the second argument is the primary variable (e.g. HEADERS), and all
7184 # subsequent arguments are possible installation locations.
7185 #
7186 # Returns list of [$location, $value] pairs, where
7187 # $value's are the values in all where_HOW variable, and $location
7188 # there associated location (the place here their parent variables were
7189 # defined).
7190 #
7191 # FIXME: this should be rewritten to be cleaner.  It should be broken
7192 # up into multiple functions.
7193 #
7194 # Usage is: am_install_var (OPTION..., file, HOW, where...)
7195 sub am_install_var
7196 {
7197   my (@args) = @_;
7198
7199   my $do_require = 1;
7200   my $can_dist = 0;
7201   my $default_dist = 0;
7202   while (@args)
7203     {
7204       if ($args[0] eq '-noextra')
7205         {
7206           $do_require = 0;
7207         }
7208       elsif ($args[0] eq '-candist')
7209         {
7210           $can_dist = 1;
7211         }
7212       elsif ($args[0] eq '-defaultdist')
7213         {
7214           $default_dist = 1;
7215           $can_dist = 1;
7216         }
7217       elsif ($args[0] !~ /^-/)
7218         {
7219           last;
7220         }
7221       shift (@args);
7222     }
7223
7224   my ($file, $primary, @prefix) = @args;
7225
7226   # Now that configure substitutions are allowed in where_HOW
7227   # variables, it is an error to actually define the primary.  We
7228   # allow 'JAVA', as it is customarily used to mean the Java
7229   # interpreter.  This is but one of several Java hacks.  Similarly,
7230   # 'PYTHON' is customarily used to mean the Python interpreter.
7231   reject_var $primary, "'$primary' is an anachronism"
7232     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
7233
7234   # Get the prefixes which are valid and actually used.
7235   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
7236
7237   # If a primary includes a configure substitution, then the EXTRA_
7238   # form is required.  Otherwise we can't properly do our job.
7239   my $require_extra;
7240
7241   my @used = ();
7242   my @result = ();
7243
7244   foreach my $X (@prefix)
7245     {
7246       my $nodir_name = $X;
7247       my $one_name = $X . '_' . $primary;
7248       my $one_var = var $one_name;
7249
7250       my $strip_subdir = 1;
7251       # If subdir prefix should be preserved, do so.
7252       if ($nodir_name =~ /^nobase_/)
7253         {
7254           $strip_subdir = 0;
7255           $nodir_name =~ s/^nobase_//;
7256         }
7257
7258       # If files should be distributed, do so.
7259       my $dist_p = 0;
7260       if ($can_dist)
7261         {
7262           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
7263                      || (! $default_dist && $nodir_name =~ /^dist_/));
7264           $nodir_name =~ s/^(dist|nodist)_//;
7265         }
7266
7267
7268       # Use the location of the currently processed variable.
7269       # We are not processing a particular condition, so pick the first
7270       # available.
7271       my $tmpcond = $one_var->conditions->one_cond;
7272       my $where = $one_var->rdef ($tmpcond)->location->clone;
7273
7274       # Append actual contents of where_PRIMARY variable to
7275       # @result, skipping @substitutions@.
7276       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
7277         {
7278           my ($loc, $value) = @$locvals;
7279           # Skip configure substitutions.
7280           if ($value =~ /^\@.*\@$/)
7281             {
7282               if ($nodir_name eq 'EXTRA')
7283                 {
7284                   error ($where,
7285                          "'$one_name' contains configure substitution, "
7286                          . "but shouldn't");
7287                 }
7288               # Check here to make sure variables defined in
7289               # configure.ac do not imply that EXTRA_PRIMARY
7290               # must be defined.
7291               elsif (! defined $configure_vars{$one_name})
7292                 {
7293                   $require_extra = $one_name
7294                     if $do_require;
7295                 }
7296             }
7297           else
7298             {
7299               # Strip any $(EXEEXT) suffix the user might have added, or this
7300               # will confuse &handle_source_transform and &check_canonical_spelling.
7301               # We'll add $(EXEEXT) back later anyway.
7302               # Do it here rather than in handle_programs so the uniquifying at the
7303               # end of this function works.
7304               ${$locvals}[1] =~ s/\$\(EXEEXT\)$//
7305                 if $primary eq 'PROGRAMS';
7306
7307               push (@result, $locvals);
7308             }
7309         }
7310       # A blatant hack: we rewrite each _PROGRAMS primary to include
7311       # EXEEXT.
7312       append_exeext { 1 } $one_name
7313         if $primary eq 'PROGRAMS';
7314       # "EXTRA" shouldn't be used when generating clean targets,
7315       # all, or install targets.  We used to warn if EXTRA_FOO was
7316       # defined uselessly, but this was annoying.
7317       next
7318         if $nodir_name eq 'EXTRA';
7319
7320       if ($nodir_name eq 'check')
7321         {
7322           push (@check, '$(' . $one_name . ')');
7323         }
7324       else
7325         {
7326           push (@used, '$(' . $one_name . ')');
7327         }
7328
7329       # Is this to be installed?
7330       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
7331
7332       # If so, with install-exec? (or install-data?).
7333       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
7334
7335       my $check_options_p = $install_p && !! option 'std-options';
7336
7337       # Use the location of the currently processed variable as context.
7338       $where->push_context ("while processing '$one_name'");
7339
7340       # The variable containing all files to distribute.
7341       my $distvar = "\$($one_name)";
7342       $distvar = shadow_unconditionally ($one_name, $where)
7343         if ($dist_p && $one_var->has_conditional_contents);
7344
7345       # Singular form of $PRIMARY.
7346       (my $one_primary = $primary) =~ s/S$//;
7347       $output_rules .= &file_contents ($file, $where,
7348                                        PRIMARY     => $primary,
7349                                        ONE_PRIMARY => $one_primary,
7350                                        DIR         => $X,
7351                                        NDIR        => $nodir_name,
7352                                        BASE        => $strip_subdir,
7353
7354                                        EXEC      => $exec_p,
7355                                        INSTALL   => $install_p,
7356                                        DIST      => $dist_p,
7357                                        DISTVAR   => $distvar,
7358                                        'CK-OPTS' => $check_options_p);
7359     }
7360
7361   # The JAVA variable is used as the name of the Java interpreter.
7362   # The PYTHON variable is used as the name of the Python interpreter.
7363   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7364     {
7365       # Define it.
7366       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7367       $output_vars .= "\n";
7368     }
7369
7370   err_var ($require_extra,
7371            "'$require_extra' contains configure substitution,\n"
7372            . "but 'EXTRA_$primary' not defined")
7373     if ($require_extra && ! var ('EXTRA_' . $primary));
7374
7375   # Push here because PRIMARY might be configure time determined.
7376   push (@all, '$(' . $primary . ')')
7377     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7378
7379   # Make the result unique.  This lets the user use conditionals in
7380   # a natural way, but still lets us program lazily -- we don't have
7381   # to worry about handling a particular object more than once.
7382   # We will keep only one location per object.
7383   my %result = ();
7384   for my $pair (@result)
7385     {
7386       my ($loc, $val) = @$pair;
7387       $result{$val} = $loc;
7388     }
7389   my @l = sort keys %result;
7390   return map { [$result{$_}->clone, $_] } @l;
7391 }
7392
7393
7394 ################################################################
7395
7396 # Each key in this hash is the name of a directory holding a
7397 # Makefile.in.  These variables are local to 'is_make_dir'.
7398 my %make_dirs = ();
7399 my $make_dirs_set = 0;
7400
7401 sub is_make_dir
7402 {
7403     my ($dir) = @_;
7404     if (! $make_dirs_set)
7405     {
7406         foreach my $iter (@configure_input_files)
7407         {
7408             $make_dirs{dirname ($iter)} = 1;
7409         }
7410         # We also want to notice Makefile.in's.
7411         foreach my $iter (@other_input_files)
7412         {
7413             if ($iter =~ /Makefile\.in$/)
7414             {
7415                 $make_dirs{dirname ($iter)} = 1;
7416             }
7417         }
7418         $make_dirs_set = 1;
7419     }
7420     return defined $make_dirs{$dir};
7421 }
7422
7423 ################################################################
7424
7425 # Find the aux dir.  This should match the algorithm used by
7426 # ./configure. (See the Autoconf documentation for for
7427 # AC_CONFIG_AUX_DIR.)
7428 sub locate_aux_dir ()
7429 {
7430   if (! $config_aux_dir_set_in_configure_ac)
7431     {
7432       # The default auxiliary directory is the first
7433       # of ., .., or ../.. that contains install-sh.
7434       # Assume . if install-sh doesn't exist yet.
7435       for my $dir (qw (. .. ../..))
7436         {
7437           if (-f "$dir/install-sh")
7438             {
7439               $config_aux_dir = $dir;
7440               last;
7441             }
7442         }
7443       $config_aux_dir = '.' unless $config_aux_dir;
7444     }
7445   # Avoid unsightly '/.'s.
7446   $am_config_aux_dir =
7447     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7448   $am_config_aux_dir =~ s,/*$,,;
7449 }
7450
7451
7452 # &push_required_file ($DIR, $FILE, $FULLFILE)
7453 # --------------------------------------------------
7454 # Push the given file onto DIST_COMMON.
7455 sub push_required_file
7456 {
7457   my ($dir, $file, $fullfile) = @_;
7458
7459   # If the file to be distributed is in the same directory of the
7460   # currently processed Makefile.am, then we want to distribute it
7461   # from this same Makefile.am.
7462   if ($dir eq $relative_dir)
7463     {
7464       push_dist_common ($file);
7465     }
7466   # This is needed to allow a construct in a non-top-level Makefile.am
7467   # to require a file in the build-aux directory (see at least the test
7468   # script 'test-driver-is-distributed.test').  This is related to the
7469   # automake bug#9546.  Note that the use of $config_aux_dir instead
7470   # of $am_config_aux_dir here is deliberate and necessary.
7471   elsif ($dir eq $config_aux_dir)
7472     {
7473       push_dist_common ("$am_config_aux_dir/$file");
7474     }
7475   # FIXME: another spacial case, for AC_LIBOBJ/AC_LIBSOURCE support.
7476   # We probably need some refactoring of this function and its callers,
7477   # to have a more explicit and systematic handling of all the special
7478   # cases; but, since there are only two of them, this is low-priority
7479   # ATM.
7480   elsif ($config_libobj_dir && $dir eq $config_libobj_dir)
7481     {
7482       # Avoid unsightly '/.'s.
7483       my $am_config_libobj_dir =
7484         '$(top_srcdir)' .
7485         ($config_libobj_dir eq '.' ? "" : "/$config_libobj_dir");
7486       $am_config_libobj_dir =~ s|/*$||;
7487       push_dist_common ("$am_config_libobj_dir/$file");
7488     }
7489   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7490     {
7491       # If we are doing the topmost directory, and the file is in a
7492       # subdir which does not have a Makefile, then we distribute it
7493       # here.
7494
7495       # If a required file is above the source tree, it is important
7496       # to prefix it with '$(srcdir)' so that no VPATH search is
7497       # performed.  Otherwise problems occur with Make implementations
7498       # that rewrite and simplify rules whose dependencies are found in a
7499       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7500       #
7501       #   % cat Makefile
7502       #   VPATH = sub
7503       #   distdir: ../a
7504       #           echo ../a
7505       #   % ls
7506       #   Makefile a
7507       #   % make
7508       #   echo a
7509       #   a
7510       #
7511       # Dependency '../a' was found in 'sub/../a', but this make
7512       # implementation simplified it as 'a'.  (Note that the sub/
7513       # directory does not even exist.)
7514       #
7515       # This kind of VPATH rewriting seems hard to cancel.  The
7516       # distdir.am hack against VPATH rewriting works only when no
7517       # simplification is done, i.e., for dependencies which are in
7518       # subdirectories, not in enclosing directories.  Hence, in
7519       # the latter case we use a full path to make sure no VPATH
7520       # search occurs.
7521       $fullfile = '$(srcdir)/' . $fullfile
7522         if $dir =~ m,^\.\.(?:$|/),;
7523
7524       push_dist_common ($fullfile);
7525     }
7526   else
7527     {
7528       prog_error "a Makefile in relative directory $relative_dir " .
7529                  "can't add files in directory $dir to DIST_COMMON";
7530     }
7531 }
7532
7533
7534 # If a file name appears as a key in this hash, then it has already
7535 # been checked for.  This allows us not to report the same error more
7536 # than once.
7537 my %required_file_not_found = ();
7538
7539 # &required_file_check_or_copy ($WHERE, $DIRECTORY, $FILE)
7540 # --------------------------------------------------------
7541 # Verify that the file must exist in $DIRECTORY, or install it.
7542 sub required_file_check_or_copy ($$$)
7543 {
7544   my ($where, $dir, $file) = @_;
7545
7546   my $fullfile = "$dir/$file";
7547   my $found_it = 0;
7548   my $dangling_sym = 0;
7549
7550   if (-l $fullfile && ! -f $fullfile)
7551     {
7552       $dangling_sym = 1;
7553     }
7554   elsif (dir_has_case_matching_file ($dir, $file))
7555     {
7556       $found_it = 1;
7557     }
7558
7559   # '--force-missing' only has an effect if '--add-missing' is
7560   # specified.
7561   return
7562     if $found_it && (! $add_missing || ! $force_missing);
7563
7564   # If we've already looked for it, we're done.  You might
7565   # wonder why we don't do this before searching for the
7566   # file.  If we do that, then something like
7567   # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7568   # DIST_COMMON.
7569   if (! $found_it)
7570     {
7571       return if defined $required_file_not_found{$fullfile};
7572       $required_file_not_found{$fullfile} = 1;
7573     }
7574   if ($dangling_sym && $add_missing)
7575     {
7576       unlink ($fullfile);
7577     }
7578
7579   my $trailer = '';
7580   my $trailer2 = '';
7581   my $suppress = 0;
7582
7583   # Only install missing files according to our desired
7584   # strictness level.
7585   my $message = "required file '$fullfile' not found";
7586   if ($add_missing)
7587     {
7588       if (-f "$libdir/$file")
7589         {
7590           $suppress = 1;
7591
7592           # Install the missing file.  Symlink if we
7593           # can, copy if we must.  Note: delete the file
7594           # first, in case it is a dangling symlink.
7595           $message = "installing '$fullfile'";
7596
7597           # The license file should not be volatile.
7598           if ($file eq "COPYING")
7599             {
7600               $message .= " using GNU General Public License v3 file";
7601               $trailer2 = "\n    Consider adding the COPYING file"
7602                         . " to the version control system"
7603                         . "\n    for your code, to avoid questions"
7604                         . " about which license your project uses";
7605             }
7606
7607           # Windows Perl will hang if we try to delete a
7608           # file that doesn't exist.
7609           unlink ($fullfile) if -f $fullfile;
7610           if ($symlink_exists && ! $copy_missing)
7611             {
7612               if (! symlink ("$libdir/$file", $fullfile)
7613                   || ! -e $fullfile)
7614                 {
7615                   $suppress = 0;
7616                   $trailer = "; error while making link: $!";
7617                 }
7618             }
7619           elsif (system ('cp', "$libdir/$file", $fullfile))
7620             {
7621               $suppress = 0;
7622               $trailer = "\n    error while copying";
7623             }
7624           set_dir_cache_file ($dir, $file);
7625         }
7626     }
7627   else
7628     {
7629       $trailer = "\n  'automake --add-missing' can install '$file'"
7630         if -f "$libdir/$file";
7631     }
7632
7633   # If --force-missing was specified, and we have
7634   # actually found the file, then do nothing.
7635   return
7636     if $found_it && $force_missing;
7637
7638   # If we couldn't install the file, but it is a target in
7639   # the Makefile, don't print anything.  This allows files
7640   # like README, AUTHORS, or THANKS to be generated.
7641   return
7642     if !$suppress && rule $file;
7643
7644   msg ($suppress ? 'note' : 'error', $where, "$message$trailer$trailer2");
7645 }
7646
7647
7648 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, $QUEUE, @FILES)
7649 # ----------------------------------------------------------------------
7650 # Verify that the file must exist in $DIRECTORY, or install it.
7651 # $MYSTRICT is the strictness level at which this file becomes required.
7652 # Worker threads may queue up the action to be serialized by the master,
7653 # if $QUEUE is true
7654 sub require_file_internal ($$$@)
7655 {
7656   my ($where, $mystrict, $dir, $queue, @files) = @_;
7657
7658   return
7659     unless $strictness >= $mystrict;
7660
7661   foreach my $file (@files)
7662     {
7663       push_required_file ($dir, $file, "$dir/$file");
7664       if ($queue)
7665         {
7666           queue_required_file_check_or_copy ($required_conf_file_queue,
7667                                              QUEUE_CONF_FILE, $relative_dir,
7668                                              $where, $mystrict, @files);
7669         }
7670       else
7671         {
7672           required_file_check_or_copy ($where, $dir, $file);
7673         }
7674     }
7675 }
7676
7677 # &require_file ($WHERE, $MYSTRICT, @FILES)
7678 # -----------------------------------------
7679 sub require_file ($$@)
7680 {
7681     my ($where, $mystrict, @files) = @_;
7682     require_file_internal ($where, $mystrict, $relative_dir, 0, @files);
7683 }
7684
7685 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7686 # -----------------------------------------------------------
7687 sub require_file_with_macro ($$$@)
7688 {
7689     my ($cond, $macro, $mystrict, @files) = @_;
7690     $macro = rvar ($macro) unless ref $macro;
7691     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7692 }
7693
7694 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7695 # ----------------------------------------------------------------
7696 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7697 # must be in that directory.  Otherwise expect it in the current directory.
7698 sub require_libsource_with_macro ($$$@)
7699 {
7700     my ($cond, $macro, $mystrict, @files) = @_;
7701     $macro = rvar ($macro) unless ref $macro;
7702     if ($config_libobj_dir)
7703       {
7704         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7705                                $config_libobj_dir, 0, @files);
7706       }
7707     else
7708       {
7709         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7710       }
7711 }
7712
7713 # &queue_required_file_check_or_copy ($QUEUE, $KEY, $DIR, $WHERE,
7714 #                                     $MYSTRICT, @FILES)
7715 # ---------------------------------------------------------------
7716 sub queue_required_file_check_or_copy ($$$$@)
7717 {
7718     my ($queue, $key, $dir, $where, $mystrict, @files) = @_;
7719     my @serial_loc;
7720     if (ref $where)
7721       {
7722         @serial_loc = (QUEUE_LOCATION, $where->serialize ());
7723       }
7724     else
7725       {
7726         @serial_loc = (QUEUE_STRING, $where);
7727       }
7728     $queue->enqueue ($key, $dir, @serial_loc, $mystrict, 0 + @files, @files);
7729 }
7730
7731 # &require_queued_file_check_or_copy ($QUEUE)
7732 # -------------------------------------------
7733 sub require_queued_file_check_or_copy ($)
7734 {
7735     my ($queue) = @_;
7736     my $where;
7737     my $dir = $queue->dequeue ();
7738     my $loc_key = $queue->dequeue ();
7739     if ($loc_key eq QUEUE_LOCATION)
7740       {
7741         $where = Automake::Location::deserialize ($queue);
7742       }
7743     elsif ($loc_key eq QUEUE_STRING)
7744       {
7745         $where = $queue->dequeue ();
7746       }
7747     else
7748       {
7749         prog_error "unexpected key $loc_key";
7750       }
7751     my $mystrict = $queue->dequeue ();
7752     my $nfiles = $queue->dequeue ();
7753     my @files;
7754     push @files, $queue->dequeue ()
7755       foreach (1 .. $nfiles);
7756     return
7757       unless $strictness >= $mystrict;
7758     foreach my $file (@files)
7759       {
7760         required_file_check_or_copy ($where, $config_aux_dir, $file);
7761       }
7762 }
7763
7764 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7765 # ----------------------------------------------
7766 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7767 sub require_conf_file ($$@)
7768 {
7769     my ($where, $mystrict, @files) = @_;
7770     my $queue = defined $required_conf_file_queue ? 1 : 0;
7771     require_file_internal ($where, $mystrict, $config_aux_dir,
7772                            $queue, @files);
7773 }
7774
7775
7776 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7777 # ----------------------------------------------------------------
7778 sub require_conf_file_with_macro ($$$@)
7779 {
7780     my ($cond, $macro, $mystrict, @files) = @_;
7781     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7782                        $mystrict, @files);
7783 }
7784
7785 ################################################################
7786
7787 # &require_build_directory ($DIRECTORY)
7788 # -------------------------------------
7789 # Emit rules to create $DIRECTORY if needed, and return
7790 # the file that any target requiring this directory should be made
7791 # dependent upon.
7792 # We don't want to emit the rule twice, and want to reuse it
7793 # for directories with equivalent names (e.g., 'foo/bar' and './foo//bar').
7794 sub require_build_directory ($)
7795 {
7796   my $directory = shift;
7797
7798   return $directory_map{$directory} if exists $directory_map{$directory};
7799
7800   my $cdir = File::Spec->canonpath ($directory);
7801
7802   if (exists $directory_map{$cdir})
7803     {
7804       my $stamp = $directory_map{$cdir};
7805       $directory_map{$directory} = $stamp;
7806       return $stamp;
7807     }
7808
7809   my $dirstamp = "$cdir/\$(am__dirstamp)";
7810
7811   $directory_map{$directory} = $dirstamp;
7812   $directory_map{$cdir} = $dirstamp;
7813
7814   # Set a variable for the dirstamp basename.
7815   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7816                           '$(am__leading_dot)dirstamp');
7817
7818   # Directory must be removed by 'make distclean'.
7819   $clean_files{$dirstamp} = DIST_CLEAN;
7820
7821   $output_rules .= ("$dirstamp:\n"
7822                     . "\t\@\$(MKDIR_P) $directory\n"
7823                     . "\t\@: > $dirstamp\n");
7824
7825   return $dirstamp;
7826 }
7827
7828 # &require_build_directory_maybe ($FILE)
7829 # --------------------------------------
7830 # If $FILE lies in a subdirectory, emit a rule to create this
7831 # directory and return the file that $FILE should be made
7832 # dependent upon.  Otherwise, just return the empty string.
7833 sub require_build_directory_maybe ($)
7834 {
7835     my $file = shift;
7836     my $directory = dirname ($file);
7837
7838     if ($directory ne '.')
7839     {
7840         return require_build_directory ($directory);
7841     }
7842     else
7843     {
7844         return '';
7845     }
7846 }
7847
7848 ################################################################
7849
7850 # Push a list of files onto dist_common.
7851 sub push_dist_common
7852 {
7853   prog_error "push_dist_common run after handle_dist"
7854     if $handle_dist_run;
7855   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
7856                               '', INTERNAL, VAR_PRETTY);
7857 }
7858
7859
7860 ################################################################
7861
7862 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
7863 # ----------------------------------------------
7864 # Generate a Makefile.in given the name of the corresponding Makefile and
7865 # the name of the file output by config.status.
7866 sub generate_makefile ($$)
7867 {
7868   my ($makefile_am, $makefile_in) = @_;
7869
7870   # Reset all the Makefile.am related variables.
7871   initialize_per_input;
7872
7873   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
7874   # warnings for this file.  So hold any warning issued before
7875   # we have processed AUTOMAKE_OPTIONS.
7876   buffer_messages ('warning');
7877
7878   # $OUTPUT is encoded.  If it contains a ":" then the first element
7879   # is the real output file, and all remaining elements are input
7880   # files.  We don't scan or otherwise deal with these input files,
7881   # other than to mark them as dependencies.  See
7882   # &scan_autoconf_files for details.
7883   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
7884
7885   $relative_dir = dirname ($makefile);
7886
7887   read_main_am_file ($makefile_am, $makefile_in);
7888   if (handle_options)
7889     {
7890       # Process buffered warnings.
7891       flush_messages;
7892       # Fatal error.  Just return, so we can continue with next file.
7893       return;
7894     }
7895   # Process buffered warnings.
7896   flush_messages;
7897
7898   # There are a few install-related variables that you should not define.
7899   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
7900     {
7901       my $v = var $var;
7902       if ($v)
7903         {
7904           my $def = $v->def (TRUE);
7905           prog_error "$var not defined in condition TRUE"
7906             unless $def;
7907           reject_var $var, "'$var' should not be defined"
7908             if $def->owner != VAR_AUTOMAKE;
7909         }
7910     }
7911
7912   # Catch some obsolete variables.
7913   msg_var ('obsolete', 'INCLUDES',
7914            "'INCLUDES' is the old name for 'AM_CPPFLAGS' (or '*_CPPFLAGS')")
7915     if var ('INCLUDES');
7916
7917   # Must do this after reading .am file.
7918   define_variable ('subdir', $relative_dir, INTERNAL);
7919
7920   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
7921   # recursive rules are enabled.
7922   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
7923     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
7924
7925   # Check first, because we might modify some state.
7926   check_gnu_standards;
7927   check_gnits_standards;
7928
7929   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
7930   handle_gettext;
7931   handle_libraries;
7932   handle_ltlibraries;
7933   handle_programs;
7934   handle_scripts;
7935
7936   handle_silent;
7937
7938   # These must be run after all the sources are scanned.  They
7939   # use variables defined by &handle_libraries, &handle_ltlibraries,
7940   # or &handle_programs.
7941   handle_compile;
7942   handle_languages;
7943   handle_libtool;
7944
7945   # Variables used by distdir.am and tags.am.
7946   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
7947   if (! option 'no-dist')
7948     {
7949       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
7950     }
7951
7952   handle_texinfo;
7953   handle_emacs_lisp;
7954   handle_python;
7955   handle_java;
7956   handle_man_pages;
7957   handle_data;
7958   handle_headers;
7959   handle_subdirs;
7960   handle_user_recursion;
7961   handle_tags;
7962   handle_minor_options;
7963   # Must come after handle_programs so that %known_programs is up-to-date.
7964   handle_tests;
7965
7966   # This must come after most other rules.
7967   handle_dist;
7968
7969   handle_footer;
7970   do_check_merge_target;
7971   handle_all ($makefile);
7972
7973   # FIXME: Gross!
7974   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
7975     {
7976       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
7977     }
7978   if (var ('nobase_lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
7979     {
7980       $output_rules .= "install-binPROGRAMS: install-nobase_libLTLIBRARIES\n\n";
7981     }
7982
7983   handle_install;
7984   handle_clean ($makefile);
7985   handle_factored_dependencies;
7986
7987   # Comes last, because all the above procedures may have
7988   # defined or overridden variables.
7989   $output_vars .= output_variables;
7990
7991   check_typos;
7992
7993   if ($exit_code != 0)
7994     {
7995       verb "not writing $makefile_in because of earlier errors";
7996       return;
7997     }
7998
7999   my $am_relative_dir = dirname ($makefile_am);
8000   mkdir ($am_relative_dir, 0755) if ! -d $am_relative_dir;
8001
8002   # We make sure that 'all:' is the first target.
8003   my $output =
8004     "$output_vars$output_all$output_header$output_rules$output_trailer";
8005
8006   # Decide whether we must update the output file or not.
8007   # We have to update in the following situations.
8008   #  * $force_generation is set.
8009   #  * any of the output dependencies is younger than the output
8010   #  * the contents of the output is different (this can happen
8011   #    if the project has been populated with a file listed in
8012   #    @common_files since the last run).
8013   # Output's dependencies are split in two sets:
8014   #  * dependencies which are also configure dependencies
8015   #    These do not change between each Makefile.am
8016   #  * other dependencies, specific to the Makefile.am being processed
8017   #    (such as the Makefile.am itself, or any Makefile fragment
8018   #    it includes).
8019   my $timestamp = mtime $makefile_in;
8020   if (! $force_generation
8021       && $configure_deps_greatest_timestamp < $timestamp
8022       && $output_deps_greatest_timestamp < $timestamp
8023       && $output eq contents ($makefile_in))
8024     {
8025       verb "$makefile_in unchanged";
8026       # No need to update.
8027       return;
8028     }
8029
8030   if (-e $makefile_in)
8031     {
8032       unlink ($makefile_in)
8033         or fatal "cannot remove $makefile_in: $!";
8034     }
8035
8036   my $gm_file = new Automake::XFile "> $makefile_in";
8037   verb "creating $makefile_in";
8038   print $gm_file $output;
8039 }
8040
8041 ################################################################
8042
8043
8044
8045
8046 ################################################################
8047
8048 # Helper function for usage().
8049 sub print_autodist_files (@)
8050 {
8051   my @lcomm = sort (&uniq (@_));
8052
8053   my @four;
8054   format USAGE_FORMAT =
8055   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
8056   $four[0],           $four[1],           $four[2],           $four[3]
8057 .
8058   local $~ = "USAGE_FORMAT";
8059
8060   my $cols = 4;
8061   my $rows = int(@lcomm / $cols);
8062   my $rest = @lcomm % $cols;
8063
8064   if ($rest)
8065     {
8066       $rows++;
8067     }
8068   else
8069     {
8070       $rest = $cols;
8071     }
8072
8073   for (my $y = 0; $y < $rows; $y++)
8074     {
8075       @four = ("", "", "", "");
8076       for (my $x = 0; $x < $cols; $x++)
8077         {
8078           last if $y + 1 == $rows && $x == $rest;
8079
8080           my $idx = (($x > $rest)
8081                ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
8082                : ($rows * $x));
8083
8084           $idx += $y;
8085           $four[$x] = $lcomm[$idx];
8086         }
8087       write;
8088     }
8089 }
8090
8091
8092 # Print usage information.
8093 sub usage ()
8094 {
8095     print "Usage: $0 [OPTION]... [Makefile]...
8096
8097 Generate Makefile.in for configure from Makefile.am.
8098
8099 Operation modes:
8100       --help               print this help, then exit
8101       --version            print version number, then exit
8102   -v, --verbose            verbosely list files processed
8103       --no-force           only update Makefile.in's that are out of date
8104   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
8105
8106 Dependency tracking:
8107   -i, --ignore-deps      disable dependency tracking code
8108       --include-deps     enable dependency tracking code
8109
8110 Flavors:
8111       --foreign          set strictness to foreign
8112       --gnits            set strictness to gnits
8113       --gnu              set strictness to gnu
8114
8115 Library files:
8116   -a, --add-missing      add missing standard files to package
8117       --libdir=DIR       set directory storing library files
8118       --print-libdir     print directory storing library files
8119   -c, --copy             with -a, copy missing files (default is symlink)
8120   -f, --force-missing    force update of standard files
8121
8122 ";
8123     Automake::ChannelDefs::usage;
8124
8125     print "\nFiles automatically distributed if found " .
8126           "(always):\n";
8127     print_autodist_files @common_files;
8128     print "\nFiles automatically distributed if found " .
8129           "(under certain conditions):\n";
8130     print_autodist_files @common_sometimes;
8131
8132     print '
8133 Report bugs to <@PACKAGE_BUGREPORT@>.
8134 GNU Automake home page: <@PACKAGE_URL@>.
8135 General help using GNU software: <http://www.gnu.org/gethelp/>.
8136 ';
8137
8138     # --help always returns 0 per GNU standards.
8139     exit 0;
8140 }
8141
8142
8143 # &version ()
8144 # -----------
8145 # Print version information
8146 sub version ()
8147 {
8148   print <<EOF;
8149 automake (GNU $PACKAGE) $VERSION
8150 Copyright (C) $RELEASE_YEAR Free Software Foundation, Inc.
8151 License GPLv2+: GNU GPL version 2 or later <http://gnu.org/licenses/gpl-2.0.html>
8152 This is free software: you are free to change and redistribute it.
8153 There is NO WARRANTY, to the extent permitted by law.
8154
8155 Written by Tom Tromey <tromey\@redhat.com>
8156        and Alexandre Duret-Lutz <adl\@gnu.org>.
8157 EOF
8158   # --version always returns 0 per GNU standards.
8159   exit 0;
8160 }
8161
8162 ################################################################
8163
8164 # Parse command line.
8165 sub parse_arguments ()
8166 {
8167   my $strict = 'gnu';
8168   my $ignore_deps = 0;
8169   my @warnings = ();
8170
8171   my %cli_options =
8172     (
8173      'version' => \&version,
8174      'help'    => \&usage,
8175      'libdir=s' => \$libdir,
8176      'print-libdir'     => sub { print "$libdir\n"; exit 0; },
8177      'gnu'              => sub { $strict = 'gnu'; },
8178      'gnits'            => sub { $strict = 'gnits'; },
8179      'foreign'          => sub { $strict = 'foreign'; },
8180      'include-deps'     => sub { $ignore_deps = 0; },
8181      'i|ignore-deps'    => sub { $ignore_deps = 1; },
8182      'no-force' => sub { $force_generation = 0; },
8183      'f|force-missing'  => \$force_missing,
8184      'a|add-missing'    => \$add_missing,
8185      'c|copy'           => \$copy_missing,
8186      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
8187      'W|warnings=s'     => \@warnings,
8188      );
8189
8190   use Automake::Getopt ();
8191   Automake::Getopt::parse_options %cli_options;
8192
8193   set_strictness ($strict);
8194   my $cli_where = new Automake::Location;
8195   set_global_option ('no-dependencies', $cli_where) if $ignore_deps;
8196   for my $warning (@warnings)
8197     {
8198       &parse_warnings ('-W', $warning);
8199     }
8200
8201   return unless @ARGV;
8202
8203   my $errspec = 0;
8204   foreach my $arg (@ARGV)
8205     {
8206       fatal ("empty argument\nTry '$0 --help' for more information")
8207         if ($arg eq '');
8208
8209       # Handle $local:$input syntax.
8210       my ($local, @rest) = split (/:/, $arg);
8211       @rest = ("$local.in",) unless @rest;
8212       my $input = locate_am @rest;
8213       if ($input)
8214         {
8215           push @input_files, $input;
8216           $output_files{$input} = join (':', ($local, @rest));
8217         }
8218       else
8219         {
8220           error "no Automake input file found for '$arg'";
8221           $errspec = 1;
8222         }
8223     }
8224   fatal "no input file found among supplied arguments"
8225     if $errspec && ! @input_files;
8226 }
8227
8228
8229 # handle_makefile ($MAKEFILE_IN)
8230 # ------------------------------
8231 # Deal with $MAKEFILE_IN.
8232 sub handle_makefile ($)
8233 {
8234   my ($file) =  @_;
8235   ($am_file = $file) =~ s/\.in$//;
8236   if (! -f ($am_file . '.am'))
8237     {
8238       error "'$am_file.am' does not exist";
8239     }
8240   else
8241     {
8242       # Any warning setting now local to this Makefile.am.
8243       dup_channel_setup;
8244
8245       generate_makefile ($am_file . '.am', $file);
8246
8247       # Back out any warning setting.
8248       drop_channel_setup;
8249     }
8250 }
8251
8252 # handle_makefiles_serial ()
8253 # --------------------------
8254 # Deal with all makefiles, without threads.
8255 sub handle_makefiles_serial ()
8256 {
8257   foreach my $file (@input_files)
8258     {
8259       handle_makefile ($file);
8260     }
8261 }
8262
8263 # get_number_of_threads ()
8264 # ------------------------
8265 # Logic for deciding how many worker threads to use.
8266 sub get_number_of_threads
8267 {
8268   my $nthreads = $ENV{'AUTOMAKE_JOBS'} || 0;
8269
8270   $nthreads = 0
8271     unless $nthreads =~ /^[0-9]+$/;
8272
8273   # It doesn't make sense to use more threads than makefiles,
8274   my $max_threads = @input_files;
8275
8276   if ($nthreads > $max_threads)
8277     {
8278       $nthreads = $max_threads;
8279     }
8280   return $nthreads;
8281 }
8282
8283 # handle_makefiles_threaded ($NTHREADS)
8284 # -------------------------------------
8285 # Deal with all makefiles, using threads.  The general strategy is to
8286 # spawn NTHREADS worker threads, dispatch makefiles to them, and let the
8287 # worker threads push back everything that needs serialization:
8288 # * warning and (normal) error messages, for stable stderr output
8289 #   order and content (avoiding duplicates, for example),
8290 # * races when installing aux files (and respective messages),
8291 # * races when collecting aux files for distribution.
8292 #
8293 # The latter requires that the makefile that deals with the aux dir
8294 # files be handled last, done by the master thread.
8295 sub handle_makefiles_threaded ($)
8296 {
8297   my ($nthreads) = @_;
8298
8299   # The file queue distributes all makefiles, the message queues
8300   # collect all serializations needed for respective files.
8301   my $file_queue = Thread::Queue->new;
8302   my %msg_queues;
8303   foreach my $file (@input_files)
8304     {
8305       $msg_queues{$file} = Thread::Queue->new;
8306     }
8307
8308   verb "spawning $nthreads worker threads";
8309   my @threads = (1 .. $nthreads);
8310   foreach my $t (@threads)
8311     {
8312       $t = threads->new (sub
8313         {
8314           while (my $file = $file_queue->dequeue)
8315             {
8316               verb "handling $file";
8317               my $queue = $msg_queues{$file};
8318               setup_channel_queue ($queue, QUEUE_MESSAGE);
8319               $required_conf_file_queue = $queue;
8320               handle_makefile ($file);
8321               $queue->enqueue (undef);
8322               setup_channel_queue (undef, undef);
8323               $required_conf_file_queue = undef;
8324             }
8325           return $exit_code;
8326         });
8327     }
8328
8329   # Queue all makefiles.
8330   verb "queuing " . @input_files . " input files";
8331   $file_queue->enqueue (@input_files, (undef) x @threads);
8332
8333   # Collect and process serializations.
8334   foreach my $file (@input_files)
8335     {
8336       verb "dequeuing messages for " . $file;
8337       reset_local_duplicates ();
8338       my $queue = $msg_queues{$file};
8339       while (my $key = $queue->dequeue)
8340         {
8341           if ($key eq QUEUE_MESSAGE)
8342             {
8343               pop_channel_queue ($queue);
8344             }
8345           elsif ($key eq QUEUE_CONF_FILE)
8346             {
8347               require_queued_file_check_or_copy ($queue);
8348             }
8349           else
8350             {
8351               prog_error "unexpected key $key";
8352             }
8353         }
8354     }
8355
8356   foreach my $t (@threads)
8357     {
8358       my @exit_thread = $t->join;
8359       $exit_code = $exit_thread[0]
8360         if ($exit_thread[0] > $exit_code);
8361     }
8362 }
8363
8364 ################################################################
8365
8366 # Parse the WARNINGS environment variable.
8367 parse_WARNINGS;
8368
8369 # Parse command line.
8370 parse_arguments;
8371
8372 $configure_ac = require_configure_ac;
8373
8374 # Do configure.ac scan only once.
8375 scan_autoconf_files;
8376
8377 if (! @input_files)
8378   {
8379     my $msg = '';
8380     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
8381       if -f 'Makefile.am';
8382     fatal ("no 'Makefile.am' found for any configure output$msg");
8383   }
8384
8385 my $nthreads = get_number_of_threads ();
8386
8387 if ($perl_threads && $nthreads >= 1)
8388   {
8389     handle_makefiles_threaded ($nthreads);
8390   }
8391 else
8392   {
8393     handle_makefiles_serial ();
8394   }
8395
8396 exit $exit_code;
8397
8398
8399 ### Setup "GNU" style for perl-mode and cperl-mode.
8400 ## Local Variables:
8401 ## perl-indent-level: 2
8402 ## perl-continued-statement-offset: 2
8403 ## perl-continued-brace-offset: 0
8404 ## perl-brace-offset: 0
8405 ## perl-brace-imaginary-offset: 0
8406 ## perl-label-offset: -2
8407 ## cperl-indent-level: 2
8408 ## cperl-brace-offset: 0
8409 ## cperl-continued-brace-offset: 0
8410 ## cperl-label-offset: -2
8411 ## cperl-extra-newline-before-brace: t
8412 ## cperl-merge-trailing-else: nil
8413 ## cperl-continued-statement-offset: 2
8414 ## End: