automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994-2012 Free Software Foundation, Inc.
  10
  11 # This program is free software; you can redistribute it and/or modify
  12 # it under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 2, or (at your option)
  14 # any later version.
  15
  16 # This program is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 # GNU General Public License for more details.
  20
  21 # You should have received a copy of the GNU General Public License
  22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  25 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  26 # Alexandre Duret-Lutz <adl@gnu.org>.
  27
  28 package Language;
  29
  30 BEGIN
  31 {
  32   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  33   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  34
  35   # Override SHELL.  This is required on DJGPP so that system() uses
  36   # bash, not COMMAND.COM which doesn't quote arguments properly.
  37   # Other systems aren't expected to use $SHELL when Automake
  38   # runs, but it should be safe to drop the "if DJGPP" guard if
  39   # it turns up other systems need the same thing.  After all,
  40   # if SHELL is used, ./configure's SHELL is always better than
  41   # the user's SHELL (which may be something like tcsh).
  42   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJDIR'};
  43 }
  44
  45 use Class::Struct ();
  46 Class::Struct::struct (
  47         # Short name of the language (c, f77...).
  48         'name' => "\$",
  49         # Nice name of the language (C, Fortran 77...).
  50         'Name' => "\$",
  51
  52         # List of configure variables which must be defined.
  53         'config_vars' => '@',
  54
  55         # 'pure' is '1' or ''.  A 'pure' language is one where, if
  56         # all the files in a directory are of that language, then we
  57         # do not require the C compiler or any code to call it.
  58         'pure'   => "\$",
  59
  60         'autodep' => "\$",
  61
  62         # Name of the compiling variable (COMPILE).
  63         'compiler'  => "\$",
  64         # Content of the compiling variable.
  65         'compile'  => "\$",
  66         # Flag to require compilation without linking (-c).
  67         'compile_flag' => "\$",
  68         'extensions' => '@',
  69         # A subroutine to compute a list of possible extensions of
  70         # the product given the input extensions.
  71         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  72         'output_extensions' => "\$",
  73         # A list of flag variables used in 'compile'.
  74         # (defaults to [])
  75         'flags' => "@",
  76
  77         # Any tag to pass to libtool while compiling.
  78         'libtool_tag' => "\$",
  79
  80         # The file to use when generating rules for this language.
  81         # The default is 'depend2'.
  82         'rule_file' => "\$",
  83
  84         # Name of the linking variable (LINK).
  85         'linker' => "\$",
  86         # Content of the linking variable.
  87         'link' => "\$",
  88
  89         # Name of the compiler variable (CC).
  90         'ccer' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} (@_);
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 BEGIN
 134 {
 135   if ($perl_threads)
 136     {
 137       require threads;
 138       import threads;
 139       require Thread::Queue;
 140       import Thread::Queue;
 141     }
 142 }
 143 use Automake::General;
 144 use Automake::XFile;
 145 use Automake::Channels;
 146 use Automake::ChannelDefs;
 147 use Automake::Configure_ac;
 148 use Automake::FileUtils;
 149 use Automake::Location;
 150 use Automake::Condition qw/TRUE FALSE/;
 151 use Automake::DisjConditions;
 152 use Automake::Options;
 153 use Automake::Variable;
 154 use Automake::VarDef;
 155 use Automake::Rule;
 156 use Automake::RuleDef;
 157 use Automake::Wrap 'makefile_wrap';
 158 use File::Basename;
 159 use File::Spec;
 160 use Carp;
 161
 162 ## ----------- ##
 163 ## Constants.  ##
 164 ## ----------- ##
 165
 166 # Some regular expressions.  One reason to put them here is that it
 167 # makes indentation work better in Emacs.
 168
 169 # Writing singled-quoted-$-terminated regexes is a pain because
 170 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 171 # by a closing quote.  Letting perl-mode think the quote is not closed
 172 # leads to all sort of misindentations.  On the other hand, defining
 173 # regexes as double-quoted strings is far less readable.  So usually
 174 # we will write:
 175 #
 176 #  $REGEX = '^regex_value' . "\$";
 177
 178 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 179 my $WHITE_PATTERN = '^\s*' . "\$";
 180 my $COMMENT_PATTERN = '^#';
 181 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 182 # A rule has three parts: a list of targets, a list of dependencies,
 183 # and optionally actions.
 184 my $RULE_PATTERN =
 185   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 186
 187 # Only recognize leading spaces, not leading tabs.  If we recognize
 188 # leading tabs here then we need to make the reader smarter, because
 189 # otherwise it will think rules like 'foo=bar; \' are errors.
 190 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 191 # This pattern recognizes a Gnits version id and sets $1 if the
 192 # release is an alpha release.  We also allow a suffix which can be
 193 # used to extend the version number with a "fork" identifier.
 194 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 195
 196 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 197 my $ELSE_PATTERN =
 198   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 199 my $ENDIF_PATTERN =
 200   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 201 my $PATH_PATTERN = '(\w|[+/.-])+';
 202 # This will pass through anything not of the prescribed form.
 203 my $INCLUDE_PATTERN = ('^include\s+'
 204                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 205                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 206                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 207
 208 # Directories installed during 'install-exec' phase.
 209 my $EXEC_DIR_PATTERN =
 210   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 211
 212 # Values for AC_CANONICAL_*
 213 use constant AC_CANONICAL_BUILD  => 1;
 214 use constant AC_CANONICAL_HOST   => 2;
 215 use constant AC_CANONICAL_TARGET => 3;
 216
 217 # Values indicating when something should be cleaned.
 218 use constant MOSTLY_CLEAN     => 0;
 219 use constant CLEAN            => 1;
 220 use constant DIST_CLEAN       => 2;
 221 use constant MAINTAINER_CLEAN => 3;
 222
 223 # Libtool files.
 224 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 225 # ltconfig appears here for compatibility with old versions of libtool.
 226 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 227
 228 # Commonly found files we look for and automatically include in
 229 # DISTFILES.
 230 my @common_files =
 231     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 232         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 233         ar-lib compile config.guess config.rpath
 234         config.sub depcomp elisp-comp install-sh libversion.in mdate-sh
 235         missing mkinstalldirs py-compile texinfo.tex ylwrap),
 236      @libtool_files, @libtool_sometimes);
 237
 238 # Commonly used files we auto-include, but only sometimes.  This list
 239 # is used for the --help output only.
 240 my @common_sometimes =
 241   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 242      configure.ac configure.in stamp-vti);
 243
 244 # Standard directories from the GNU Coding Standards, and additional
 245 # pkg* directories from Automake.  Stored in a hash for fast member check.
 246 my %standard_prefix =
 247     map { $_ => 1 } (qw(bin data dataroot doc dvi exec html include info
 248                         lib libexec lisp locale localstate man man1 man2
 249                         man3 man4 man5 man6 man7 man8 man9 oldinclude pdf
 250                         pkgdata pkginclude pkglib pkglibexec ps sbin
 251                         sharedstate sysconf));
 252
 253 # Copyright on generated Makefile.ins.
 254 my $gen_copyright = "\
 255 # Copyright (C) 1994-$RELEASE_YEAR Free Software Foundation, Inc.
 256
 257 # This Makefile.in is free software; the Free Software Foundation
 258 # gives unlimited permission to copy and/or distribute it,
 259 # with or without modifications, as long as this notice is preserved.
 260
 261 # This program is distributed in the hope that it will be useful,
 262 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 263 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 264 # PARTICULAR PURPOSE.
 265 ";
 266
 267 # These constants are returned by the lang_*_rewrite functions.
 268 # LANG_SUBDIR means that the resulting object file should be in a
 269 # subdir if the source file is.  In this case the file name cannot
 270 # have '..' components.
 271 use constant LANG_IGNORE  => 0;
 272 use constant LANG_PROCESS => 1;
 273 use constant LANG_SUBDIR  => 2;
 274
 275 # These are used when keeping track of whether an object can be built
 276 # by two different paths.
 277 use constant COMPILE_LIBTOOL  => 1;
 278 use constant COMPILE_ORDINARY => 2;
 279
 280 # We can't always associate a location to a variable or a rule,
 281 # when it's defined by Automake.  We use INTERNAL in this case.
 282 use constant INTERNAL => new Automake::Location;
 283
 284 # Serialization keys for message queues.
 285 use constant QUEUE_MESSAGE   => "msg";
 286 use constant QUEUE_CONF_FILE => "conf file";
 287 use constant QUEUE_LOCATION  => "location";
 288 use constant QUEUE_STRING    => "string";
 289
 290 ## ---------------------------------- ##
 291 ## Variables related to the options.  ##
 292 ## ---------------------------------- ##
 293
 294 # TRUE if we should always generate Makefile.in.
 295 my $force_generation = 1;
 296
 297 # From the Perl manual.
 298 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 299
 300 # TRUE if missing standard files should be installed.
 301 my $add_missing = 0;
 302
 303 # TRUE if we should copy missing files; otherwise symlink if possible.
 304 my $copy_missing = 0;
 305
 306 # TRUE if we should always update files that we know about.
 307 my $force_missing = 0;
 308
 309
 310 ## ---------------------------------------- ##
 311 ## Variables filled during files scanning.  ##
 312 ## ---------------------------------------- ##
 313
 314 # Name of the configure.ac file.
 315 my $configure_ac;
 316
 317 # Files found by scanning configure.ac for LIBOBJS.
 318 my %libsources = ();
 319
 320 # Names used in AC_CONFIG_HEADER call.
 321 my @config_headers = ();
 322
 323 # Names used in AC_CONFIG_LINKS call.
 324 my @config_links = ();
 325
 326 # List of Makefile.am's to process, and their corresponding outputs.
 327 my @input_files = ();
 328 my %output_files = ();
 329
 330 # Complete list of Makefile.am's that exist.
 331 my @configure_input_files = ();
 332
 333 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 334 # and their outputs.
 335 my @other_input_files = ();
 336 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 337 # The keys are the files created by these macros.
 338 my %ac_config_files_location = ();
 339 # The condition under which AC_CONFIG_FOOS appears.
 340 my %ac_config_files_condition = ();
 341
 342 # Directory to search for configure-required files.  This
 343 # will be computed by &locate_aux_dir and can be set using
 344 # AC_CONFIG_AUX_DIR in configure.ac.
 345 # $CONFIG_AUX_DIR is the 'raw' directory, valid only in the source-tree.
 346 my $config_aux_dir = '';
 347 my $config_aux_dir_set_in_configure_ac = 0;
 348 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 349 # in Makefiles.
 350 my $am_config_aux_dir = '';
 351
 352 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 353 # in configure.ac.
 354 my $config_libobj_dir = '';
 355
 356 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 357 my $seen_gettext = 0;
 358 # Whether AM_GNU_GETTEXT([external]) is used.
 359 my $seen_gettext_external = 0;
 360 # Where AM_GNU_GETTEXT appears.
 361 my $ac_gettext_location;
 362 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 363 my $seen_gettext_intl = 0;
 364
 365 # Lists of tags supported by Libtool.
 366 my %libtool_tags = ();
 367 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 368 # uses AC_REQUIRE_AUX_FILE.
 369 my $libtool_new_api = 0;
 370
 371 # Most important AC_CANONICAL_* macro seen so far.
 372 my $seen_canonical = 0;
 373 # Location of that macro.
 374 my $canonical_location;
 375
 376 # Where AM_MAINTAINER_MODE appears.
 377 my $seen_maint_mode;
 378
 379 # Actual version we've seen.
 380 my $package_version = '';
 381
 382 # Where version is defined.
 383 my $package_version_location;
 384
 385 # TRUE if we've seen AM_PROG_AR
 386 my $seen_ar = 0;
 387
 388 # TRUE if we've seen AM_PROG_CC_C_O
 389 my $seen_cc_c_o = 0;
 390
 391 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 392 my %required_aux_file = ();
 393
 394 # Where AM_INIT_AUTOMAKE is called;
 395 my $seen_init_automake = 0;
 396
 397 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 398 my $seen_automake_version = 0;
 399
 400 # Hash table of discovered configure substitutions.  Keys are names,
 401 # values are 'FILE:LINE' strings which are used by error message
 402 # generation.
 403 my %configure_vars = ();
 404
 405 # Ignored configure substitutions (i.e., variables not to be output in
 406 # Makefile.in)
 407 my %ignored_configure_vars = ();
 408
 409 # Files included by $configure_ac.
 410 my @configure_deps = ();
 411
 412 # Greatest timestamp of configure's dependencies.
 413 my $configure_deps_greatest_timestamp = 0;
 414
 415 # Hash table of AM_CONDITIONAL variables seen in configure.
 416 my %configure_cond = ();
 417
 418 # This maps extensions onto language names.
 419 my %extension_map = ();
 420
 421 # List of the DIST_COMMON files we discovered while reading
 422 # configure.ac.
 423 my $configure_dist_common = '';
 424
 425 # This maps languages names onto objects.
 426 my %languages = ();
 427 # Maps each linker variable onto a language object.
 428 my %link_languages = ();
 429
 430 # maps extensions to needed source flags.
 431 my %sourceflags = ();
 432
 433 # List of targets we must always output.
 434 # FIXME: Complete, and remove falsely required targets.
 435 my %required_targets =
 436   (
 437    'all'          => 1,
 438    'dvi'          => 1,
 439    'pdf'          => 1,
 440    'ps'           => 1,
 441    'info'         => 1,
 442    'install-info' => 1,
 443    'install'      => 1,
 444    'install-data' => 1,
 445    'install-exec' => 1,
 446    'uninstall'    => 1,
 447
 448    # FIXME: Not required, temporary hacks.
 449    # Well, actually they are sort of required: the -recursive
 450    # targets will run them anyway...
 451    'html-am'         => 1,
 452    'dvi-am'          => 1,
 453    'pdf-am'          => 1,
 454    'ps-am'           => 1,
 455    'info-am'         => 1,
 456    'install-data-am' => 1,
 457    'install-exec-am' => 1,
 458    'install-html-am' => 1,
 459    'install-dvi-am'  => 1,
 460    'install-pdf-am'  => 1,
 461    'install-ps-am'   => 1,
 462    'install-info-am' => 1,
 463    'installcheck-am' => 1,
 464    'uninstall-am' => 1,
 465
 466    'install-man' => 1,
 467   );
 468
 469 # Queue to push require_conf_file requirements to.
 470 my $required_conf_file_queue;
 471
 472 # The name of the Makefile currently being processed.
 473 my $am_file = 'BUG';
 474
 475 ################################################################
 476
 477 ## ------------------------------------------ ##
 478 ## Variables reset by &initialize_per_input.  ##
 479 ## ------------------------------------------ ##
 480
 481 # Basename and relative dir of the input file.
 482 my $am_file_name;
 483 my $am_relative_dir;
 484
 485 # Same but wrt Makefile.in.
 486 my $in_file_name;
 487 my $relative_dir;
 488
 489 # Relative path to the top directory.
 490 my $topsrcdir;
 491
 492 # Greatest timestamp of the output's dependencies (excluding
 493 # configure's dependencies).
 494 my $output_deps_greatest_timestamp;
 495
 496 # These variables are used when generating each Makefile.in.
 497 # They hold the Makefile.in until it is ready to be printed.
 498 my $output_vars;
 499 my $output_all;
 500 my $output_header;
 501 my $output_rules;
 502 my $output_trailer;
 503
 504 # This is the conditional stack, updated on if/else/endif, and
 505 # used to build Condition objects.
 506 my @cond_stack;
 507
 508 # This holds the set of included files.
 509 my @include_stack;
 510
 511 # List of dependencies for the obvious targets.
 512 my @all;
 513 my @check;
 514 my @check_tests;
 515
 516 # Keys in this hash table are files to delete.  The associated
 517 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 518 my %clean_files;
 519
 520 # Keys in this hash table are object files or other files in
 521 # subdirectories which need to be removed.  This only holds files
 522 # which are created by compilations.  The value in the hash indicates
 523 # when the file should be removed.
 524 my %compile_clean_files;
 525
 526 # Keys in this hash table are directories where we expect to build a
 527 # libtool object.  We use this information to decide what directories
 528 # to delete.
 529 my %libtool_clean_directories;
 530
 531 # Value of $(SOURCES), used by tags.am.
 532 my @sources;
 533 # Sources which go in the distribution.
 534 my @dist_sources;
 535
 536 # This hash maps object file names onto their corresponding source
 537 # file names.  This is used to ensure that each object is created
 538 # by a single source file.
 539 my %object_map;
 540
 541 # This hash maps object file names onto an integer value representing
 542 # whether this object has been built via ordinary compilation or
 543 # libtool compilation (the COMPILE_* constants).
 544 my %object_compilation_map;
 545
 546
 547 # This keeps track of the directories for which we've already
 548 # created dirstamp code.  Keys are directories, values are stamp files.
 549 # Several keys can share the same stamp files if they are equivalent
 550 # (as are './/foo' and 'foo').
 551 my %directory_map;
 552
 553 # All .P files.
 554 my %dep_files;
 555
 556 # This is a list of all targets to run during "make dist".
 557 my @dist_targets;
 558
 559 # Keep track of all programs declared in this Makefile, without
 560 # $(EXEEXT).  @substitutions@ are not listed.
 561 my %known_programs;
 562 my %known_libraries;
 563
 564 # This keeps track of which extensions we've seen (that we care
 565 # about).
 566 my %extension_seen;
 567
 568 # This is random scratch space for the language finish functions.
 569 # Don't randomly overwrite it; examine other uses of keys first.
 570 my %language_scratch;
 571
 572 # We keep track of which objects need special (per-executable)
 573 # handling on a per-language basis.
 574 my %lang_specific_files;
 575
 576 # This is set when 'handle_dist' has finished.  Once this happens,
 577 # we should no longer push on dist_common.
 578 my $handle_dist_run;
 579
 580 # Used to store a set of linkers needed to generate the sources currently
 581 # under consideration.
 582 my %linkers_used;
 583
 584 # True if we need 'LINK' defined.  This is a hack.
 585 my $need_link;
 586
 587 # Does the generated Makefile have to build some compiled object
 588 # (for binary programs, or plain or libtool libraries)?
 589 my $must_handle_compiled_objects;
 590
 591 # Record each file processed by make_paragraphs.
 592 my %transformed_files;
 593
 594 ################################################################
 595
 596 ## ---------------------------------------------- ##
 597 ## Variables not reset by &initialize_per_input.  ##
 598 ## ---------------------------------------------- ##
 599
 600 # Cache each file processed by make_paragraphs.
 601 # (This is different from %transformed_files because
 602 # %transformed_files is reset for each file while %am_file_cache
 603 # it global to the run.)
 604 my %am_file_cache;
 605
 606 ################################################################
 607
 608 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 609 # ------------------------------------
 610 # This is called by Automake::Variable::define() when SUFFIXES
 611 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 612 # The work here needs to be performed as a side-effect of the
 613 # macro_define() call because SUFFIXES definitions impact
 614 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 615 # the input am file.
 616 sub var_SUFFIXES_trigger ($$)
 617 {
 618     my ($type, $value) = @_;
 619     accept_extensions (split (' ', $value));
 620 }
 621 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 622
 623 ################################################################
 624
 625 ## --------------------------------- ##
 626 ## Forward subroutine declarations.  ##
 627 ## --------------------------------- ##
 628 sub register_language (%);
 629 sub file_contents_internal ($$$%);
 630 sub define_files_variable ($\@$$);
 631
 632
 633 # &initialize_per_input ()
 634 # ------------------------
 635 # (Re)-Initialize per-Makefile.am variables.
 636 sub initialize_per_input ()
 637 {
 638     reset_local_duplicates ();
 639
 640     $am_file_name = undef;
 641     $am_relative_dir = undef;
 642
 643     $in_file_name = undef;
 644     $relative_dir = undef;
 645     $topsrcdir = undef;
 646
 647     $output_deps_greatest_timestamp = 0;
 648
 649     $output_vars = '';
 650     $output_all = '';
 651     $output_header = '';
 652     $output_rules = '';
 653     $output_trailer = '';
 654
 655     Automake::Options::reset;
 656     Automake::Variable::reset;
 657     Automake::Rule::reset;
 658
 659     @cond_stack = ();
 660
 661     @include_stack = ();
 662
 663     @all = ();
 664     @check = ();
 665     @check_tests = ();
 666
 667     %clean_files = ();
 668     %compile_clean_files = ();
 669
 670     # We always include '.'.  This isn't strictly correct.
 671     %libtool_clean_directories = ('.' => 1);
 672
 673     @sources = ();
 674     @dist_sources = ();
 675
 676     %object_map = ();
 677     %object_compilation_map = ();
 678
 679     %directory_map = ();
 680
 681     %dep_files = ();
 682
 683     @dist_targets = ();
 684
 685     %known_programs = ();
 686     %known_libraries= ();
 687
 688     %extension_seen = ();
 689
 690     %language_scratch = ();
 691
 692     %lang_specific_files = ();
 693
 694     $handle_dist_run = 0;
 695
 696     $need_link = 0;
 697
 698     $must_handle_compiled_objects = 0;
 699
 700     %transformed_files = ();
 701 }
 702
 703
 704 ################################################################
 705
 706 # Initialize our list of languages that are internally supported.
 707
 708 # C.
 709 register_language ('name' => 'c',
 710                    'Name' => 'C',
 711                    'config_vars' => ['CC'],
 712                    'autodep' => '',
 713                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 714                    'ccer' => 'CC',
 715                    'compiler' => 'COMPILE',
 716                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 717                    'lder' => 'CCLD',
 718                    'ld' => '$(CC)',
 719                    'linker' => 'LINK',
 720                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 721                    'compile_flag' => '-c',
 722                    'libtool_tag' => 'CC',
 723                    'extensions' => ['.c']);
 724
 725 # C++.
 726 register_language ('name' => 'cxx',
 727                    'Name' => 'C++',
 728                    'config_vars' => ['CXX'],
 729                    'linker' => 'CXXLINK',
 730                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 731                    'autodep' => 'CXX',
 732                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 733                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 734                    'ccer' => 'CXX',
 735                    'compiler' => 'CXXCOMPILE',
 736                    'compile_flag' => '-c',
 737                    'output_flag' => '-o',
 738                    'libtool_tag' => 'CXX',
 739                    'lder' => 'CXXLD',
 740                    'ld' => '$(CXX)',
 741                    'pure' => 1,
 742                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 743
 744 # Objective C.
 745 register_language ('name' => 'objc',
 746                    'Name' => 'Objective C',
 747                    'config_vars' => ['OBJC'],
 748                    'linker' => 'OBJCLINK',
 749                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 750                    'autodep' => 'OBJC',
 751                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 752                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 753                    'ccer' => 'OBJC',
 754                    'compiler' => 'OBJCCOMPILE',
 755                    'compile_flag' => '-c',
 756                    'output_flag' => '-o',
 757                    'lder' => 'OBJCLD',
 758                    'ld' => '$(OBJC)',
 759                    'pure' => 1,
 760                    'extensions' => ['.m']);
 761
 762 # Objective C++.
 763 register_language ('name' => 'objcxx',
 764                    'Name' => 'Objective C++',
 765                    'config_vars' => ['OBJCXX'],
 766                    'linker' => 'OBJCXXLINK',
 767                    'link' => '$(OBJCXXLD) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 768                    'autodep' => 'OBJCXX',
 769                    'flags' => ['OBJCXXFLAGS', 'CPPFLAGS'],
 770                    'compile' => '$(OBJCXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS)',
 771                    'ccer' => 'OBJCXX',
 772                    'compiler' => 'OBJCXXCOMPILE',
 773                    'compile_flag' => '-c',
 774                    'output_flag' => '-o',
 775                    'lder' => 'OBJCXXLD',
 776                    'ld' => '$(OBJCXX)',
 777                    'pure' => 1,
 778                    'extensions' => ['.mm']);
 779
 780 # Unified Parallel C.
 781 register_language ('name' => 'upc',
 782                    'Name' => 'Unified Parallel C',
 783                    'config_vars' => ['UPC'],
 784                    'linker' => 'UPCLINK',
 785                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 786                    'autodep' => 'UPC',
 787                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 788                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 789                    'ccer' => 'UPC',
 790                    'compiler' => 'UPCCOMPILE',
 791                    'compile_flag' => '-c',
 792                    'output_flag' => '-o',
 793                    'lder' => 'UPCLD',
 794                    'ld' => '$(UPC)',
 795                    'pure' => 1,
 796                    'extensions' => ['.upc']);
 797
 798 # Headers.
 799 register_language ('name' => 'header',
 800                    'Name' => 'Header',
 801                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 802                                     '.hpp', '.inc'],
 803                    # No output.
 804                    'output_extensions' => sub { return () },
 805                    # Nothing to do.
 806                    '_finish' => sub { });
 807
 808 # Vala
 809 register_language ('name' => 'vala',
 810                    'Name' => 'Vala',
 811                    'config_vars' => ['VALAC'],
 812                    'flags' => [],
 813                    'compile' => '$(VALAC) $(AM_VALAFLAGS) $(VALAFLAGS)',
 814                    'ccer' => 'VALAC',
 815                    'compiler' => 'VALACOMPILE',
 816                    'extensions' => ['.vala'],
 817                    'output_extensions' => sub { (my $ext = $_[0]) =~ s/vala$/c/;
 818                                                 return ($ext,) },
 819                    'rule_file' => 'vala',
 820                    '_finish' => \&lang_vala_finish,
 821                    '_target_hook' => \&lang_vala_target_hook,
 822                    'nodist_specific' => 1);
 823
 824 # Yacc (C & C++).
 825 register_language ('name' => 'yacc',
 826                    'Name' => 'Yacc',
 827                    'config_vars' => ['YACC'],
 828                    'flags' => ['YFLAGS'],
 829                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 830                    'ccer' => 'YACC',
 831                    'compiler' => 'YACCCOMPILE',
 832                    'extensions' => ['.y'],
 833                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 834                                                 return ($ext,) },
 835                    'rule_file' => 'yacc',
 836                    '_finish' => \&lang_yacc_finish,
 837                    '_target_hook' => \&lang_yacc_target_hook,
 838                    'nodist_specific' => 1);
 839 register_language ('name' => 'yaccxx',
 840                    'Name' => 'Yacc (C++)',
 841                    'config_vars' => ['YACC'],
 842                    'rule_file' => 'yacc',
 843                    'flags' => ['YFLAGS'],
 844                    'ccer' => 'YACC',
 845                    'compiler' => 'YACCCOMPILE',
 846                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 847                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 848                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 849                                                 return ($ext,) },
 850                    '_finish' => \&lang_yacc_finish,
 851                    '_target_hook' => \&lang_yacc_target_hook,
 852                    'nodist_specific' => 1);
 853
 854 # Lex (C & C++).
 855 register_language ('name' => 'lex',
 856                    'Name' => 'Lex',
 857                    'config_vars' => ['LEX'],
 858                    'rule_file' => 'lex',
 859                    'flags' => ['LFLAGS'],
 860                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 861                    'ccer' => 'LEX',
 862                    'compiler' => 'LEXCOMPILE',
 863                    'extensions' => ['.l'],
 864                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 865                                                 return ($ext,) },
 866                    '_finish' => \&lang_lex_finish,
 867                    '_target_hook' => \&lang_lex_target_hook,
 868                    'nodist_specific' => 1);
 869 register_language ('name' => 'lexxx',
 870                    'Name' => 'Lex (C++)',
 871                    'config_vars' => ['LEX'],
 872                    'rule_file' => 'lex',
 873                    'flags' => ['LFLAGS'],
 874                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 875                    'ccer' => 'LEX',
 876                    'compiler' => 'LEXCOMPILE',
 877                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 878                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 879                                                 return ($ext,) },
 880                    '_finish' => \&lang_lex_finish,
 881                    '_target_hook' => \&lang_lex_target_hook,
 882                    'nodist_specific' => 1);
 883
 884 # Assembler.
 885 register_language ('name' => 'asm',
 886                    'Name' => 'Assembler',
 887                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 888
 889                    'flags' => ['CCASFLAGS'],
 890                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 891                    # or anything else required.  They can also set CCAS.
 892                    # Or simply use Preprocessed Assembler.
 893                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 894                    'ccer' => 'CCAS',
 895                    'compiler' => 'CCASCOMPILE',
 896                    'compile_flag' => '-c',
 897                    'output_flag' => '-o',
 898                    'extensions' => ['.s']);
 899
 900 # Preprocessed Assembler.
 901 register_language ('name' => 'cppasm',
 902                    'Name' => 'Preprocessed Assembler',
 903                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 904
 905                    'autodep' => 'CCAS',
 906                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 907                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 908                    'ccer' => 'CPPAS',
 909                    'compiler' => 'CPPASCOMPILE',
 910                    'compile_flag' => '-c',
 911                    'output_flag' => '-o',
 912                    'extensions' => ['.S', '.sx']);
 913
 914 # Fortran 77
 915 register_language ('name' => 'f77',
 916                    'Name' => 'Fortran 77',
 917                    'config_vars' => ['F77'],
 918                    'linker' => 'F77LINK',
 919                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 920                    'flags' => ['FFLAGS'],
 921                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 922                    'ccer' => 'F77',
 923                    'compiler' => 'F77COMPILE',
 924                    'compile_flag' => '-c',
 925                    'output_flag' => '-o',
 926                    'libtool_tag' => 'F77',
 927                    'lder' => 'F77LD',
 928                    'ld' => '$(F77)',
 929                    'pure' => 1,
 930                    'extensions' => ['.f', '.for']);
 931
 932 # Fortran
 933 register_language ('name' => 'fc',
 934                    'Name' => 'Fortran',
 935                    'config_vars' => ['FC'],
 936                    'linker' => 'FCLINK',
 937                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 938                    'flags' => ['FCFLAGS'],
 939                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 940                    'ccer' => 'FC',
 941                    'compiler' => 'FCCOMPILE',
 942                    'compile_flag' => '-c',
 943                    'output_flag' => '-o',
 944                    'libtool_tag' => 'FC',
 945                    'lder' => 'FCLD',
 946                    'ld' => '$(FC)',
 947                    'pure' => 1,
 948                    'extensions' => ['.f90', '.f95', '.f03', '.f08']);
 949
 950 # Preprocessed Fortran
 951 register_language ('name' => 'ppfc',
 952                    'Name' => 'Preprocessed Fortran',
 953                    'config_vars' => ['FC'],
 954                    'linker' => 'FCLINK',
 955                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 956                    'lder' => 'FCLD',
 957                    'ld' => '$(FC)',
 958                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 959                    'ccer' => 'PPFC',
 960                    'compiler' => 'PPFCCOMPILE',
 961                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 962                    'compile_flag' => '-c',
 963                    'output_flag' => '-o',
 964                    'libtool_tag' => 'FC',
 965                    'pure' => 1,
 966                    'extensions' => ['.F90','.F95', '.F03', '.F08']);
 967
 968 # Preprocessed Fortran 77
 969 #
 970 # The current support for preprocessing Fortran 77 just involves
 971 # passing "$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 972 # $(CPPFLAGS)" as additional flags to the Fortran 77 compiler, since
 973 # this is how GNU Make does it; see the "GNU Make Manual, Edition 0.51
 974 # for 'make' Version 3.76 Beta" (specifically, from info file
 975 # '(make)Catalogue of Rules').
 976 #
 977 # A better approach would be to write an Autoconf test
 978 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 979 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 980 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 981 # preprocessing capabilities, and then fall back on cpp (if cpp were
 982 # available).
 983 register_language ('name' => 'ppf77',
 984                    'Name' => 'Preprocessed Fortran 77',
 985                    'config_vars' => ['F77'],
 986                    'linker' => 'F77LINK',
 987                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 988                    'lder' => 'F77LD',
 989                    'ld' => '$(F77)',
 990                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 991                    'ccer' => 'PPF77',
 992                    'compiler' => 'PPF77COMPILE',
 993                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 994                    'compile_flag' => '-c',
 995                    'output_flag' => '-o',
 996                    'libtool_tag' => 'F77',
 997                    'pure' => 1,
 998                    'extensions' => ['.F']);
 999
1000 # Ratfor.
1001 register_language ('name' => 'ratfor',
1002                    'Name' => 'Ratfor',
1003                    'config_vars' => ['F77'],
1004                    'linker' => 'F77LINK',
1005                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1006                    'lder' => 'F77LD',
1007                    'ld' => '$(F77)',
1008                    'flags' => ['RFLAGS', 'FFLAGS'],
1009                    # FIXME also FFLAGS.
1010                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
1011                    'ccer' => 'F77',
1012                    'compiler' => 'RCOMPILE',
1013                    'compile_flag' => '-c',
1014                    'output_flag' => '-o',
1015                    'libtool_tag' => 'F77',
1016                    'pure' => 1,
1017                    'extensions' => ['.r']);
1018
1019 # Java via gcj.
1020 register_language ('name' => 'java',
1021                    'Name' => 'Java',
1022                    'config_vars' => ['GCJ'],
1023                    'linker' => 'GCJLINK',
1024                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1025                    'autodep' => 'GCJ',
1026                    'flags' => ['GCJFLAGS'],
1027                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
1028                    'ccer' => 'GCJ',
1029                    'compiler' => 'GCJCOMPILE',
1030                    'compile_flag' => '-c',
1031                    'output_flag' => '-o',
1032                    'libtool_tag' => 'GCJ',
1033                    'lder' => 'GCJLD',
1034                    'ld' => '$(GCJ)',
1035                    'pure' => 1,
1036                    'extensions' => ['.java', '.class', '.zip', '.jar']);
1037
1038 ################################################################
1039
1040 # Error reporting functions.
1041
1042 # err_am ($MESSAGE, [%OPTIONS])
1043 # -----------------------------
1044 # Uncategorized errors about the current Makefile.am.
1045 sub err_am ($;%)
1046 {
1047   msg_am ('error', @_);
1048 }
1049
1050 # err_ac ($MESSAGE, [%OPTIONS])
1051 # -----------------------------
1052 # Uncategorized errors about configure.ac.
1053 sub err_ac ($;%)
1054 {
1055   msg_ac ('error', @_);
1056 }
1057
1058 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1059 # ---------------------------------------
1060 # Messages about about the current Makefile.am.
1061 sub msg_am ($$;%)
1062 {
1063   my ($channel, $msg, %opts) = @_;
1064   msg $channel, "${am_file}.am", $msg, %opts;
1065 }
1066
1067 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1068 # ---------------------------------------
1069 # Messages about about configure.ac.
1070 sub msg_ac ($$;%)
1071 {
1072   my ($channel, $msg, %opts) = @_;
1073   msg $channel, $configure_ac, $msg, %opts;
1074 }
1075
1076 ################################################################
1077
1078 # subst ($TEXT)
1079 # -------------
1080 # Return a configure-style substitution using the indicated text.
1081 # We do this to avoid having the substitutions directly in automake.in;
1082 # when we do that they are sometimes removed and this causes confusion
1083 # and bugs.
1084 sub subst ($)
1085 {
1086     my ($text) = @_;
1087     return '@' . $text . '@';
1088 }
1089
1090 ################################################################
1091
1092
1093 # $BACKPATH
1094 # &backname ($RELDIR)
1095 # --------------------
1096 # If I "cd $RELDIR", then to come back, I should "cd $BACKPATH".
1097 # For instance 'src/foo' => '../..'.
1098 # Works with non strictly increasing paths, i.e., 'src/../lib' => '..'.
1099 sub backname ($)
1100 {
1101     my ($file) = @_;
1102     my @res;
1103     foreach (split (/\//, $file))
1104     {
1105         next if $_ eq '.' || $_ eq '';
1106         if ($_ eq '..')
1107         {
1108             pop @res
1109               or prog_error ("trying to reverse path '$file' pointing outside tree");
1110         }
1111         else
1112         {
1113             push (@res, '..');
1114         }
1115     }
1116     return join ('/', @res) || '.';
1117 }
1118
1119 ################################################################
1120
1121 # 'silent-rules' mode handling functions.
1122
1123 # verbose_var (NAME)
1124 # ------------------
1125 # The public variable stem used to implement 'silent-rules'.
1126 sub verbose_var ($)
1127 {
1128     my ($name) = @_;
1129     return 'AM_V_' . $name;
1130 }
1131
1132 # verbose_private_var (NAME)
1133 # --------------------------
1134 # The naming policy for the private variables for 'silent-rules'.
1135 sub verbose_private_var ($)
1136 {
1137     my ($name) = @_;
1138     return 'am__v_' . $name;
1139 }
1140
1141 # define_verbose_var (NAME, VAL-IF-SILENT, [VAL-IF-VERBOSE])
1142 # ----------------------------------------------------------
1143 # For 'silent-rules' mode, setup VAR and dispatcher, to expand to
1144 # VAL-IF-SILENT if silent, to VAL-IF-VERBOSE (defaulting to empty)
1145 # if not.
1146 sub define_verbose_var ($$;$)
1147 {
1148     my ($name, $silent_val, $verbose_val) = @_;
1149     $verbose_val = '' unless defined $verbose_val;
1150     my $var = verbose_var ($name);
1151     my $pvar = verbose_private_var ($name);
1152     my $silent_var = $pvar . '_0';
1153     my $verbose_var = $pvar . '_1';
1154     if (option 'silent-rules')
1155       {
1156         # For typical 'make's, 'configure' replaces AM_V (inside @@) with $(V)
1157         # and AM_DEFAULT_V (inside @@) with $(AM_DEFAULT_VERBOSITY).
1158         # For strict POSIX 2008 'make's, it replaces them with 0 or 1 instead.
1159         # See AM_SILENT_RULES in m4/silent.m4.
1160         define_variable ($var, '$(' . $pvar . '_@'.'AM_V'.'@)', INTERNAL);
1161         define_variable ($pvar . '_', '$(' . $pvar . '_@'.'AM_DEFAULT_V'.'@)', INTERNAL);
1162         Automake::Variable::define ($silent_var, VAR_AUTOMAKE, '', TRUE,
1163                                     $silent_val, '', INTERNAL, VAR_ASIS)
1164           if (! vardef ($silent_var, TRUE));
1165         Automake::Variable::define ($verbose_var, VAR_AUTOMAKE, '', TRUE,
1166                                     $verbose_val, '', INTERNAL, VAR_ASIS)
1167           if (! vardef ($verbose_var, TRUE));
1168 }
1169 }
1170
1171 # Above should not be needed in the general automake code.
1172
1173 # verbose_flag (NAME)
1174 # -------------------
1175 # Contents of %VERBOSE%: variable to expand before rule command.
1176 sub verbose_flag ($)
1177 {
1178     my ($name) = @_;
1179     return '$(' . verbose_var ($name) . ')'
1180       if (option 'silent-rules');
1181     return '';
1182 }
1183
1184 sub verbose_nodep_flag ($)
1185 {
1186     my ($name) = @_;
1187     return '$(' . verbose_var ($name) . subst ('am__nodep') . ')'
1188       if (option 'silent-rules');
1189     return '';
1190 }
1191
1192 # silent_flag
1193 # -----------
1194 # Contents of %SILENT%: variable to expand to '@' when silent.
1195 sub silent_flag ()
1196 {
1197     return verbose_flag ('at');
1198 }
1199
1200 # define_verbose_tagvar (NAME)
1201 # ----------------------------
1202 # Engage the needed 'silent-rules' machinery for tag NAME.
1203 sub define_verbose_tagvar ($)
1204 {
1205     my ($name) = @_;
1206     if (option 'silent-rules')
1207       {
1208         define_verbose_var ($name, '@echo "  '. $name . ' ' x (8 - length ($name)) . '" $@;');
1209       }
1210 }
1211
1212 # define_verbose_texinfo
1213 # ----------------------
1214 # Engage the needed 'silent-rules' machinery for assorted texinfo commands.
1215 sub define_verbose_texinfo ()
1216 {
1217   my @tagvars = ('DVIPS', 'MAKEINFO', 'INFOHTML', 'TEXI2DVI', 'TEXI2PDF');
1218   foreach my $tag (@tagvars)
1219     {
1220       define_verbose_tagvar($tag);
1221     }
1222   define_verbose_var('texinfo', '-q');
1223   define_verbose_var('texidevnull', '> /dev/null');
1224 }
1225
1226 # define_verbose_libtool
1227 # ----------------------
1228 # Engage the needed 'silent-rules' machinery for 'libtool --silent'.
1229 sub define_verbose_libtool ()
1230 {
1231     define_verbose_var ('lt', '--silent');
1232     return verbose_flag ('lt');
1233 }
1234
1235 sub handle_silent ()
1236 {
1237     return unless option 'silent-rules';
1238     # *Always* provide the user with 'AM_V_GEN' for 'silent-rules' mode.
1239     define_verbose_tagvar ('GEN');
1240     define_verbose_var ('at', '@');
1241 }
1242
1243
1244 ################################################################
1245
1246
1247 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1248 sub handle_options
1249 {
1250   my $var = var ('AUTOMAKE_OPTIONS');
1251   if ($var)
1252     {
1253       if ($var->has_conditional_contents)
1254         {
1255           msg_var ('unsupported', $var,
1256                    "'AUTOMAKE_OPTIONS' cannot have conditional contents");
1257         }
1258       my @options = map { { option => $_->[1], where => $_->[0] } }
1259                         $var->value_as_list_recursive (cond_filter => TRUE,
1260                                                        location => 1);
1261       return 1 if process_option_list (@options);
1262     }
1263
1264   # Override portability-recursive warning.
1265   switch_warning ('no-portability-recursive')
1266     if option 'silent-rules';
1267
1268   if ($strictness == GNITS)
1269     {
1270       set_option ('readme-alpha', INTERNAL);
1271       set_option ('std-options', INTERNAL);
1272       set_option ('check-news', INTERNAL);
1273     }
1274
1275   return 0;
1276 }
1277
1278 # shadow_unconditionally ($varname, $where)
1279 # -----------------------------------------
1280 # Return a $(variable) that contains all possible values
1281 # $varname can take.
1282 # If the VAR wasn't defined conditionally, return $(VAR).
1283 # Otherwise we create an am__VAR_DIST variable which contains
1284 # all possible values, and return $(am__VAR_DIST).
1285 sub shadow_unconditionally ($$)
1286 {
1287   my ($varname, $where) = @_;
1288   my $var = var $varname;
1289   if ($var->has_conditional_contents)
1290     {
1291       $varname = "am__${varname}_DIST";
1292       my @files = uniq ($var->value_as_list_recursive);
1293       define_pretty_variable ($varname, TRUE, $where, @files);
1294     }
1295   return "\$($varname)"
1296 }
1297
1298 # check_user_variables (@LIST)
1299 # ----------------------------
1300 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1301 # otherwise.
1302 sub check_user_variables (@)
1303 {
1304   my @dont_override = @_;
1305   foreach my $flag (@dont_override)
1306     {
1307       my $var = var $flag;
1308       if ($var)
1309         {
1310           for my $cond ($var->conditions->conds)
1311             {
1312               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1313                 {
1314                   msg_cond_var ('gnu', $cond, $flag,
1315                                 "'$flag' is a user variable, "
1316                                 . "you should not override it;\n"
1317                                 . "use 'AM_$flag' instead");
1318                 }
1319             }
1320         }
1321     }
1322 }
1323
1324 # Call finish function for each language that was used.
1325 sub handle_languages
1326 {
1327     if (! option 'no-dependencies')
1328     {
1329         # Include auto-dep code.  Don't include it if DEP_FILES would
1330         # be empty.
1331         if (&saw_sources_p (0) && keys %dep_files)
1332         {
1333             # Set location of depcomp.
1334             &define_variable ('depcomp',
1335                               "\$(SHELL) $am_config_aux_dir/depcomp",
1336                               INTERNAL);
1337             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1338
1339             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1340
1341             my @deplist = sort keys %dep_files;
1342             # Generate each 'include' individually.  Irix 6 make will
1343             # not properly include several files resulting from a
1344             # variable expansion; generating many separate includes
1345             # seems safest.
1346             $output_rules .= "\n";
1347             foreach my $iter (@deplist)
1348             {
1349                 $output_rules .= (subst ('AMDEP_TRUE')
1350                                   . subst ('am__include')
1351                                   . ' '
1352                                   . subst ('am__quote')
1353                                   . $iter
1354                                   . subst ('am__quote')
1355                                   . "\n");
1356             }
1357
1358             # Compute the set of directories to remove in distclean-depend.
1359             my @depdirs = uniq (map { dirname ($_) } @deplist);
1360             $output_rules .= &file_contents ('depend',
1361                                              new Automake::Location,
1362                                              DEPDIRS => "@depdirs");
1363         }
1364     }
1365     else
1366     {
1367         &define_variable ('depcomp', '', INTERNAL);
1368         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1369     }
1370
1371     my %done;
1372
1373     # Is the C linker needed?
1374     my $needs_c = 0;
1375     foreach my $ext (sort keys %extension_seen)
1376     {
1377         next unless $extension_map{$ext};
1378
1379         my $lang = $languages{$extension_map{$ext}};
1380
1381         my $rule_file = $lang->rule_file || 'depend2';
1382
1383         # Get information on $LANG.
1384         my $pfx = $lang->autodep;
1385         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1386
1387         my ($AMDEP, $FASTDEP) =
1388           (option 'no-dependencies' || $lang->autodep eq 'no')
1389           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1390
1391         my $verbose = verbose_flag ($lang->ccer || 'GEN');
1392         my $verbose_nodep = ($AMDEP eq 'FALSE')
1393           ? $verbose : verbose_nodep_flag ($lang->ccer || 'GEN');
1394         my $silent = silent_flag ();
1395
1396         my %transform = ('EXT'     => $ext,
1397                          'PFX'     => $pfx,
1398                          'FPFX'    => $fpfx,
1399                          'AMDEP'   => $AMDEP,
1400                          'FASTDEP' => $FASTDEP,
1401                          '-c'      => $lang->compile_flag || '',
1402                          # These are not used, but they need to be defined
1403                          # so &transform do not complain.
1404                          SUBDIROBJ     => 0,
1405                          'DERIVED-EXT' => 'BUG',
1406                          DIST_SOURCE   => 1,
1407                          VERBOSE   => $verbose,
1408                          'VERBOSE-NODEP' => $verbose_nodep,
1409                          SILENT    => $silent,
1410                         );
1411
1412         # Generate the appropriate rules for this extension.
1413         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1414             || defined $lang->compile)
1415         {
1416             # Some C compilers don't support -c -o.  Use it only if really
1417             # needed.
1418             my $output_flag = $lang->output_flag || '';
1419             $output_flag = '-o'
1420               if (! $output_flag
1421                   && $lang->name eq 'c'
1422                   && option 'subdir-objects');
1423
1424             # Compute a possible derived extension.
1425             # This is not used by depend2.am.
1426             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1427
1428             # When we output an inference rule like '.c.o:' we
1429             # have two cases to consider: either subdir-objects
1430             # is used, or it is not.
1431             #
1432             # In the latter case the rule is used to build objects
1433             # in the current directory, and dependencies always
1434             # go into './$(DEPDIR)/'.  We can hard-code this value.
1435             #
1436             # In the former case the rule can be used to build
1437             # objects in sub-directories too.  Dependencies should
1438             # go into the appropriate sub-directories, e.g.,
1439             # 'sub/$(DEPDIR)/'.  The value of this directory
1440             # needs to be computed on-the-fly.
1441             #
1442             # DEPBASE holds the name of this directory, plus the
1443             # basename part of the object file (extensions Po, TPo,
1444             # Plo, TPlo will be added later as appropriate).  It is
1445             # either hardcoded, or a shell variable ('$depbase') that
1446             # will be computed by the rule.
1447             my $depbase =
1448               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1449             $output_rules .=
1450               file_contents ($rule_file,
1451                              new Automake::Location,
1452                              %transform,
1453                              GENERIC   => 1,
1454
1455                              'DERIVED-EXT' => $der_ext,
1456
1457                              DEPBASE   => $depbase,
1458                              BASE      => '$*',
1459                              SOURCE    => '$<',
1460                              SOURCEFLAG => $sourceflags{$ext} || '',
1461                              OBJ       => '$@',
1462                              OBJOBJ    => '$@',
1463                              LTOBJ     => '$@',
1464
1465                              COMPILE   => '$(' . $lang->compiler . ')',
1466                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1467                              -o        => $output_flag,
1468                              SUBDIROBJ => !! option 'subdir-objects');
1469         }
1470
1471         # Now include code for each specially handled object with this
1472         # language.
1473         my %seen_files = ();
1474         foreach my $file (@{$lang_specific_files{$lang->name}})
1475         {
1476             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1477
1478             # We might see a given object twice, for instance if it is
1479             # used under different conditions.
1480             next if defined $seen_files{$obj};
1481             $seen_files{$obj} = 1;
1482
1483             prog_error ("found " . $lang->name .
1484                         " in handle_languages, but compiler not defined")
1485               unless defined $lang->compile;
1486
1487             my $obj_compile = $lang->compile;
1488
1489             # Rewrite each occurrence of 'AM_$flag' in the compile
1490             # rule into '${derived}_$flag' if it exists.
1491             for my $flag (@{$lang->flags})
1492               {
1493                 my $val = "${derived}_$flag";
1494                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1495                   if set_seen ($val);
1496               }
1497
1498             my $libtool_tag = '';
1499             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1500               {
1501                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1502               }
1503
1504             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1505             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1506
1507             my $ltverbose = define_verbose_libtool ();
1508             my $obj_ltcompile =
1509               "\$(LIBTOOL) $ltverbose $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1510               . "--mode=compile $obj_compile";
1511
1512             # We _need_ '-o' for per object rules.
1513             my $output_flag = $lang->output_flag || '-o';
1514
1515             my $depbase = dirname ($obj);
1516             $depbase = ''
1517                 if $depbase eq '.';
1518             $depbase .= '/'
1519                 unless $depbase eq '';
1520             $depbase .= '$(DEPDIR)/' . basename ($obj);
1521
1522             $output_rules .=
1523               file_contents ($rule_file,
1524                              new Automake::Location,
1525                              %transform,
1526                              GENERIC   => 0,
1527
1528                              DEPBASE   => $depbase,
1529                              BASE      => $obj,
1530                              SOURCE    => $source,
1531                              SOURCEFLAG => $sourceflags{$srcext} || '',
1532                              # Use $myext and not '.o' here, in case
1533                              # we are actually building a new source
1534                              # file -- e.g. via yacc.
1535                              OBJ       => "$obj$myext",
1536                              OBJOBJ    => "$obj.obj",
1537                              LTOBJ     => "$obj.lo",
1538
1539                              VERBOSE   => $verbose,
1540                              'VERBOSE-NODEP'  => $verbose_nodep,
1541                              SILENT    => $silent,
1542                              COMPILE   => $obj_compile,
1543                              LTCOMPILE => $obj_ltcompile,
1544                              -o        => $output_flag,
1545                              %file_transform);
1546         }
1547
1548         # The rest of the loop is done once per language.
1549         next if defined $done{$lang};
1550         $done{$lang} = 1;
1551
1552         # Load the language dependent Makefile chunks.
1553         my %lang = map { uc ($_) => 0 } keys %languages;
1554         $lang{uc ($lang->name)} = 1;
1555         $output_rules .= file_contents ('lang-compile',
1556                                         new Automake::Location,
1557                                         %transform, %lang);
1558
1559         # If the source to a program consists entirely of code from a
1560         # 'pure' language, for instance C++ or Fortran 77, then we
1561         # don't need the C compiler code.  However if we run into
1562         # something unusual then we do generate the C code.  There are
1563         # probably corner cases here that do not work properly.
1564         # People linking Java code to Fortran code deserve pain.
1565         $needs_c ||= ! $lang->pure;
1566
1567         define_compiler_variable ($lang)
1568           if ($lang->compile);
1569
1570         define_linker_variable ($lang)
1571           if ($lang->link);
1572
1573         require_variables ("$am_file.am", $lang->Name . " source seen",
1574                            TRUE, @{$lang->config_vars});
1575
1576         # Call the finisher.
1577         $lang->finish;
1578
1579         # Flags listed in '->flags' are user variables (per GNU Standards),
1580         # they should not be overridden in the Makefile...
1581         my @dont_override = @{$lang->flags};
1582         # ... and so is LDFLAGS.
1583         push @dont_override, 'LDFLAGS' if $lang->link;
1584
1585         check_user_variables @dont_override;
1586     }
1587
1588     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1589     # suffix rule was learned), don't bother with the C stuff.  But if
1590     # anything else creeps in, then use it.
1591     $needs_c = 1
1592       if $need_link || suffix_rules_count > 1;
1593
1594     if ($needs_c)
1595       {
1596         &define_compiler_variable ($languages{'c'})
1597           unless defined $done{$languages{'c'}};
1598         define_linker_variable ($languages{'c'});
1599       }
1600 }
1601
1602
1603 # append_exeext { PREDICATE } $MACRO
1604 # ----------------------------------
1605 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1606 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1607 # ignored.
1608 #
1609 # This is typically used on all filenames of *_PROGRAMS, and filenames
1610 # of TESTS that are programs.
1611 sub append_exeext (&$)
1612 {
1613   my ($pred, $macro) = @_;
1614
1615   transform_variable_recursively
1616     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1617      sub {
1618        my ($subvar, $val, $cond, $full_cond) = @_;
1619        # Append $(EXEEXT) unless the user did it already, or it's a
1620        # @substitution@.
1621        $val .= '$(EXEEXT)'
1622          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1623        return $val;
1624      });
1625 }
1626
1627
1628 # Check to make sure a source defined in LIBOBJS is not explicitly
1629 # mentioned.  This is a separate function (as opposed to being inlined
1630 # in handle_source_transform) because it isn't always appropriate to
1631 # do this check.
1632 sub check_libobjs_sources
1633 {
1634   my ($one_file, $unxformed) = @_;
1635
1636   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1637                       'dist_EXTRA_', 'nodist_EXTRA_')
1638     {
1639       my @files;
1640       my $varname = $prefix . $one_file . '_SOURCES';
1641       my $var = var ($varname);
1642       if ($var)
1643         {
1644           @files = $var->value_as_list_recursive;
1645         }
1646       elsif ($prefix eq '')
1647         {
1648           @files = ($unxformed . '.c');
1649         }
1650       else
1651         {
1652           next;
1653         }
1654
1655       foreach my $file (@files)
1656         {
1657           err_var ($prefix . $one_file . '_SOURCES',
1658                    "automatically discovered file '$file' should not" .
1659                    " be explicitly mentioned")
1660             if defined $libsources{$file};
1661         }
1662     }
1663 }
1664
1665
1666 # @OBJECTS
1667 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1668 # -----------------------------------------------------------------------------
1669 # Does much of the actual work for handle_source_transform.
1670 # Arguments are:
1671 #   $VAR is the name of the variable that the source filenames come from
1672 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1673 #   $DERIVED is the name of resulting executable or library
1674 #   $OBJ is the object extension (e.g., '.lo')
1675 #   $FILE the source file to transform
1676 #   %TRANSFORM contains extras arguments to pass to file_contents
1677 #     when producing explicit rules
1678 # Result is a list of the names of objects
1679 # %linkers_used will be updated with any linkers needed
1680 sub handle_single_transform ($$$$$%)
1681 {
1682     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1683     my @files = ($_file);
1684     my @result = ();
1685
1686     # Turn sources into objects.  We use a while loop like this
1687     # because we might add to @files in the loop.
1688     while (scalar @files > 0)
1689     {
1690         $_ = shift @files;
1691
1692         # Configure substitutions in _SOURCES variables are errors.
1693         if (/^\@.*\@$/)
1694         {
1695           my $parent_msg = '';
1696           $parent_msg = "\nand is referred to from '$topparent'"
1697             if $topparent ne $var->name;
1698           err_var ($var,
1699                    "'" . $var->name . "' includes configure substitution '$_'"
1700                    . $parent_msg . ";\nconfigure " .
1701                    "substitutions are not allowed in _SOURCES variables");
1702           next;
1703         }
1704
1705         # If the source file is in a subdirectory then the '.o' is put
1706         # into the current directory, unless the subdir-objects option
1707         # is in effect.
1708
1709         # Split file name into base and extension.
1710         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1711         my $full = $_;
1712         my $directory = $1 || '';
1713         my $base = $2;
1714         my $extension = $3;
1715
1716         # We must generate a rule for the object if it requires its own flags.
1717         my $renamed = 0;
1718         my ($linker, $object);
1719
1720         # This records whether we've seen a derived source file (e.g.
1721         # yacc output).
1722         my $derived_source = 0;
1723
1724         # This holds the 'aggregate context' of the file we are
1725         # currently examining.  If the file is compiled with
1726         # per-object flags, then it will be the name of the object.
1727         # Otherwise it will be 'AM'.  This is used by the target hook
1728         # language function.
1729         my $aggregate = 'AM';
1730
1731         $extension = &derive_suffix ($extension, $obj);
1732         my $lang;
1733         if ($extension_map{$extension} &&
1734             ($lang = $languages{$extension_map{$extension}}))
1735         {
1736             # Found the language, so see what it says.
1737             &saw_extension ($extension);
1738
1739             # Do we have per-executable flags for this executable?
1740             my $have_per_exec_flags = 0;
1741             my @peflags = @{$lang->flags};
1742             push @peflags, 'LIBTOOLFLAGS' if $obj eq '.lo';
1743             foreach my $flag (@peflags)
1744               {
1745                 if (set_seen ("${derived}_$flag"))
1746                   {
1747                     $have_per_exec_flags = 1;
1748                     last;
1749                   }
1750               }
1751
1752             # Note: computed subr call.  The language rewrite function
1753             # should return one of the LANG_* constants.  It could
1754             # also return a list whose first value is such a constant
1755             # and whose second value is a new source extension which
1756             # should be applied.  This means this particular language
1757             # generates another source file which we must then process
1758             # further.
1759             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1760             my ($r, $source_extension)
1761                 = &$subr ($directory, $base, $extension,
1762                           $obj, $have_per_exec_flags, $var);
1763             # Skip this entry if we were asked not to process it.
1764             next if $r == LANG_IGNORE;
1765
1766             # Now extract linker and other info.
1767             $linker = $lang->linker;
1768
1769             my $this_obj_ext;
1770             if (defined $source_extension)
1771             {
1772                 $this_obj_ext = $source_extension;
1773                 $derived_source = 1;
1774             }
1775             else
1776             {
1777                 $this_obj_ext = $obj;
1778             }
1779             $object = $base . $this_obj_ext;
1780
1781             if ($have_per_exec_flags)
1782             {
1783                 # We have a per-executable flag in effect for this
1784                 # object.  In this case we rewrite the object's
1785                 # name to ensure it is unique.
1786
1787                 # We choose the name 'DERIVED_OBJECT' to ensure
1788                 # (1) uniqueness, and (2) continuity between
1789                 # invocations.  However, this will result in a
1790                 # name that is too long for losing systems, in
1791                 # some situations.  So we provide _SHORTNAME to
1792                 # override.
1793
1794                 my $dname = $derived;
1795                 my $var = var ($derived . '_SHORTNAME');
1796                 if ($var)
1797                 {
1798                     # FIXME: should use the same Condition as
1799                     # the _SOURCES variable.  But this is really
1800                     # silly overkill -- nobody should have
1801                     # conditional shortnames.
1802                     $dname = $var->variable_value;
1803                 }
1804                 $object = $dname . '-' . $object;
1805
1806                 prog_error ($lang->name . " flags defined without compiler")
1807                   if ! defined $lang->compile;
1808
1809                 $renamed = 1;
1810             }
1811
1812             # If rewrite said it was ok, put the object into a
1813             # subdir.
1814             if ($r == LANG_SUBDIR && $directory ne '')
1815             {
1816                 $object = $directory . '/' . $object;
1817             }
1818
1819             # If the object file has been renamed (because per-target
1820             # flags are used) we cannot compile the file with an
1821             # inference rule: we need an explicit rule.
1822             #
1823             # If the source is in a subdirectory and the object is in
1824             # the current directory, we also need an explicit rule.
1825             #
1826             # If both source and object files are in a subdirectory
1827             # (this happens when the subdir-objects option is used),
1828             # then the inference will work.
1829             #
1830             # The latter case deserves a historical note.  When the
1831             # subdir-objects option was added on 1999-04-11 it was
1832             # thought that inferences rules would work for
1833             # subdirectory objects too.  Later, on 1999-11-22,
1834             # automake was changed to output explicit rules even for
1835             # subdir-objects.  Nobody remembers why, but this occurred
1836             # soon after the merge of the user-dep-gen-branch so it
1837             # might be related.  In late 2003 people complained about
1838             # the size of the generated Makefile.ins (libgcj, with
1839             # 2200+ subdir objects was reported to have a 9MB
1840             # Makefile), so we now rely on inference rules again.
1841             # Maybe we'll run across the same issue as in the past,
1842             # but at least this time we can document it.  However since
1843             # dependency tracking has evolved it is possible that
1844             # our old problem no longer exists.
1845             # Using inference rules for subdir-objects has been tested
1846             # with GNU make, Solaris make, Ultrix make, BSD make,
1847             # HP-UX make, and OSF1 make successfully.
1848             if ($renamed
1849                 || ($directory ne '' && ! option 'subdir-objects')
1850                 # We must also use specific rules for a nodist_ source
1851                 # if its language requests it.
1852                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1853             {
1854                 my $obj_sans_ext = substr ($object, 0,
1855                                            - length ($this_obj_ext));
1856                 my $full_ansi;
1857                 if ($directory ne '')
1858                   {
1859                         $full_ansi = $directory . '/' . $base . $extension;
1860                   }
1861                 else
1862                   {
1863                         $full_ansi = $base . $extension;
1864                   }
1865
1866                 my @specifics = ($full_ansi, $obj_sans_ext,
1867                                  # Only use $this_obj_ext in the derived
1868                                  # source case because in the other case we
1869                                  # *don't* want $(OBJEXT) to appear here.
1870                                  ($derived_source ? $this_obj_ext : '.o'),
1871                                  $extension);
1872
1873                 # If we renamed the object then we want to use the
1874                 # per-executable flag name.  But if this is simply a
1875                 # subdir build then we still want to use the AM_ flag
1876                 # name.
1877                 if ($renamed)
1878                   {
1879                     unshift @specifics, $derived;
1880                     $aggregate = $derived;
1881                   }
1882                 else
1883                   {
1884                     unshift @specifics, 'AM';
1885                   }
1886
1887                 # Each item on this list is a reference to a list consisting
1888                 # of four values followed by additional transform flags for
1889                 # file_contents.  The four values are the derived flag prefix
1890                 # (e.g. for 'foo_CFLAGS', it is 'foo'), the name of the
1891                 # source file, the base name of the output file, and
1892                 # the extension for the object file.
1893                 push (@{$lang_specific_files{$lang->name}},
1894                       [@specifics, %transform]);
1895             }
1896         }
1897         elsif ($extension eq $obj)
1898         {
1899             # This is probably the result of a direct suffix rule.
1900             # In this case we just accept the rewrite.
1901             $object = "$base$extension";
1902             $object = "$directory/$object" if $directory ne '';
1903             $linker = '';
1904         }
1905         else
1906         {
1907             # No error message here.  Used to have one, but it was
1908             # very unpopular.
1909             # FIXME: we could potentially do more processing here,
1910             # perhaps treating the new extension as though it were a
1911             # new source extension (as above).  This would require
1912             # more restructuring than is appropriate right now.
1913             next;
1914         }
1915
1916         err_am "object '$object' created by '$full' and '$object_map{$object}'"
1917           if (defined $object_map{$object}
1918               && $object_map{$object} ne $full);
1919
1920         my $comp_val = (($object =~ /\.lo$/)
1921                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1922         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1923         if (defined $object_compilation_map{$comp_obj}
1924             && $object_compilation_map{$comp_obj} != 0
1925             # Only see the error once.
1926             && ($object_compilation_map{$comp_obj}
1927                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1928             && $object_compilation_map{$comp_obj} != $comp_val)
1929           {
1930             err_am "object '$comp_obj' created both with libtool and without";
1931           }
1932         $object_compilation_map{$comp_obj} |= $comp_val;
1933
1934         if (defined $lang)
1935         {
1936             # Let the language do some special magic if required.
1937             $lang->target_hook ($aggregate, $object, $full, %transform);
1938         }
1939
1940         if ($derived_source)
1941           {
1942             prog_error ($lang->name . " has automatic dependency tracking")
1943               if $lang->autodep ne 'no';
1944             # Make sure this new source file is handled next.  That will
1945             # make it appear to be at the right place in the list.
1946             unshift (@files, $object);
1947             # Distribute derived sources unless the source they are
1948             # derived from is not.
1949             &push_dist_common ($object)
1950               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1951             next;
1952           }
1953
1954         $linkers_used{$linker} = 1;
1955
1956         push (@result, $object);
1957
1958         if (! defined $object_map{$object})
1959         {
1960             my @dep_list = ();
1961             $object_map{$object} = $full;
1962
1963             # If resulting object is in subdir, we need to make
1964             # sure the subdir exists at build time.
1965             if ($object =~ /\//)
1966             {
1967                 # FIXME: check that $DIRECTORY is somewhere in the
1968                 # project
1969
1970                 # For Java, the way we're handling it right now, a
1971                 # '..' component doesn't make sense.
1972                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1973                   {
1974                     err_am "'$full' should not contain a '..' component";
1975                   }
1976
1977                 # Make sure object is removed by 'make mostlyclean'.
1978                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1979                 # If we have a libtool object then we also must remove
1980                 # the ordinary .o.
1981                 if ($object =~ /\.lo$/)
1982                 {
1983                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1984                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1985
1986                     # Remove any libtool object in this directory.
1987                     $libtool_clean_directories{$directory} = 1;
1988                 }
1989
1990                 push (@dep_list, require_build_directory ($directory));
1991
1992                 # If we're generating dependencies, we also want
1993                 # to make sure that the appropriate subdir of the
1994                 # .deps directory is created.
1995                 push (@dep_list,
1996                       require_build_directory ($directory . '/$(DEPDIR)'))
1997                   unless option 'no-dependencies';
1998             }
1999
2000             &pretty_print_rule ($object . ':', "\t", @dep_list)
2001                 if scalar @dep_list > 0;
2002         }
2003
2004         # Transform .o or $o file into .P file (for automatic
2005         # dependency code).
2006         # Properly flatten multiple adjacent slashes, as Solaris 10 make
2007         # might fail over them in an include statement.
2008         # Leading double slashes may be special, as per Posix, so deal
2009         # with them carefully.
2010         if ($lang && $lang->autodep ne 'no')
2011         {
2012             my $depfile = $object;
2013             $depfile =~ s/\.([^.]*)$/.P$1/;
2014             $depfile =~ s/\$\(OBJEXT\)$/o/;
2015             my $maybe_extra_leading_slash = '';
2016             $maybe_extra_leading_slash = '/' if $depfile =~ m,^//[^/],;
2017             $depfile =~ s,/+,/,g;
2018             my $basename = basename ($depfile);
2019             # This might make $dirname empty, but we account for that below.
2020             (my $dirname = dirname ($depfile)) =~ s/\/*$//;
2021             $dirname = $maybe_extra_leading_slash . $dirname;
2022             $dep_files{$dirname . '/$(DEPDIR)/' . $basename} = 1;
2023         }
2024     }
2025
2026     return @result;
2027 }
2028
2029
2030 # $LINKER
2031 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
2032 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
2033 # ---------------------------------------------------------------------------
2034 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
2035 #
2036 # Arguments are:
2037 #   $VAR is the name of the _SOURCES variable
2038 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
2039 #     it will be generated and returned).
2040 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
2041 #     work done to determine the linker will be).
2042 #   $ONE_FILE is the canonical (transformed) name of object to build
2043 #   $OBJ is the object extension (i.e. either '.o' or '.lo').
2044 #   $TOPPARENT is the _SOURCES variable being processed.
2045 #   $WHERE context into which this definition is done
2046 #   %TRANSFORM extra arguments to pass to file_contents when producing
2047 #     rules
2048 #
2049 # Result is a pair ($LINKER, $OBJVAR):
2050 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
2051 sub define_objects_from_sources ($$$$$$$%)
2052 {
2053   my ($var, $objvar, $nodefine, $one_file,
2054       $obj, $topparent, $where, %transform) = @_;
2055
2056   my $needlinker = "";
2057
2058   transform_variable_recursively
2059     ($var, $objvar, 'am__objects', $nodefine, $where,
2060      # The transform code to run on each filename.
2061      sub {
2062        my ($subvar, $val, $cond, $full_cond) = @_;
2063        my @trans = handle_single_transform ($subvar, $topparent,
2064                                             $one_file, $obj, $val,
2065                                             %transform);
2066        $needlinker = "true" if @trans;
2067        return @trans;
2068      });
2069
2070   return $needlinker;
2071 }
2072
2073
2074 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
2075 # -----------------------------------------------------------------------------
2076 # Handle SOURCE->OBJECT transform for one program or library.
2077 # Arguments are:
2078 #   canonical (transformed) name of target to build
2079 #   actual target of object to build
2080 #   object extension (i.e., either '.o' or '$o')
2081 #   location of the source variable
2082 #   extra arguments to pass to file_contents when producing rules
2083 # Return the name of the linker variable that must be used.
2084 # Empty return means just use 'LINK'.
2085 sub handle_source_transform ($$$$%)
2086 {
2087     # one_file is canonical name.  unxformed is given name.  obj is
2088     # object extension.
2089     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
2090
2091     my $linker = '';
2092
2093     # No point in continuing if _OBJECTS is defined.
2094     return if reject_var ($one_file . '_OBJECTS',
2095                           $one_file . '_OBJECTS should not be defined');
2096
2097     my %used_pfx = ();
2098     my $needlinker;
2099     %linkers_used = ();
2100     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2101                         'dist_EXTRA_', 'nodist_EXTRA_')
2102     {
2103         my $varname = $prefix . $one_file . "_SOURCES";
2104         my $var = var $varname;
2105         next unless $var;
2106
2107         # We are going to define _OBJECTS variables using the prefix.
2108         # Then we glom them all together.  So we can't use the null
2109         # prefix here as we need it later.
2110         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2111
2112         # Keep track of which prefixes we saw.
2113         $used_pfx{$xpfx} = 1
2114           unless $prefix =~ /EXTRA_/;
2115
2116         push @sources, "\$($varname)";
2117         push @dist_sources, shadow_unconditionally ($varname, $where)
2118           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2119
2120         $needlinker |=
2121             define_objects_from_sources ($varname,
2122                                          $xpfx . $one_file . '_OBJECTS',
2123                                          $prefix =~ /EXTRA_/,
2124                                          $one_file, $obj, $varname, $where,
2125                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2126                                          %transform);
2127     }
2128     if ($needlinker)
2129     {
2130         $linker ||= &resolve_linker (%linkers_used);
2131     }
2132
2133     my @keys = sort keys %used_pfx;
2134     if (scalar @keys == 0)
2135     {
2136         # The default source for libfoo.la is libfoo.c, but for
2137         # backward compatibility we first look at libfoo_la.c,
2138         # if no default source suffix is given.
2139         my $old_default_source = "$one_file.c";
2140         my $ext_var = var ('AM_DEFAULT_SOURCE_EXT');
2141         my $default_source_ext = $ext_var ? variable_value ($ext_var) : '.c';
2142         msg_var ('unsupported', $ext_var, $ext_var->name . " can assume at most one value")
2143           if $default_source_ext =~ /[\t ]/;
2144         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,$default_source_ext,;
2145         if ($old_default_source ne $default_source
2146             && !$ext_var
2147             && (rule $old_default_source
2148                 || rule '$(srcdir)/' . $old_default_source
2149                 || rule '${srcdir}/' . $old_default_source
2150                 || -f $old_default_source))
2151           {
2152             my $loc = $where->clone;
2153             $loc->pop_context;
2154             msg ('obsolete', $loc,
2155                  "the default source for '$unxformed' has been changed "
2156                  . "to '$default_source'.\n(Using '$old_default_source' for "
2157                  . "backward compatibility.)");
2158             $default_source = $old_default_source;
2159           }
2160         # If a rule exists to build this source with a $(srcdir)
2161         # prefix, use that prefix in our variables too.  This is for
2162         # the sake of BSD Make.
2163         if (rule '$(srcdir)/' . $default_source
2164             || rule '${srcdir}/' . $default_source)
2165           {
2166             $default_source = '$(srcdir)/' . $default_source;
2167           }
2168
2169         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2170         push (@sources, $default_source);
2171         push (@dist_sources, $default_source);
2172
2173         %linkers_used = ();
2174         my (@result) =
2175           handle_single_transform ($one_file . '_SOURCES',
2176                                    $one_file . '_SOURCES',
2177                                    $one_file, $obj,
2178                                    $default_source, %transform);
2179         $linker ||= &resolve_linker (%linkers_used);
2180         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2181     }
2182     else
2183     {
2184         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2185         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2186     }
2187
2188     # If we want to use 'LINK' we must make sure it is defined.
2189     if ($linker eq '')
2190     {
2191         $need_link = 1;
2192     }
2193
2194     return $linker;
2195 }
2196
2197
2198 # handle_lib_objects ($XNAME, $VAR)
2199 # ---------------------------------
2200 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2201 # Also, generate _DEPENDENCIES variable if appropriate.
2202 # Arguments are:
2203 #   transformed name of object being built, or empty string if no object
2204 #   name of _LDADD/_LIBADD-type variable to examine
2205 # Returns 1 if LIBOBJS seen, 0 otherwise.
2206 sub handle_lib_objects
2207 {
2208   my ($xname, $varname) = @_;
2209
2210   my $var = var ($varname);
2211   prog_error "'$varname' undefined"
2212     unless $var;
2213   prog_error "unexpected variable name '$varname'"
2214     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2215   my $prefix = $1 || 'AM_';
2216
2217   my $seen_libobjs = 0;
2218   my $flagvar = 0;
2219
2220   transform_variable_recursively
2221     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2222      ! $xname, INTERNAL,
2223      # Transformation function, run on each filename.
2224      sub {
2225        my ($subvar, $val, $cond, $full_cond) = @_;
2226
2227        if ($val =~ /^-/)
2228          {
2229            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2230            if ($val !~ /^-[lL]/ &&
2231                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2232                # for Libtool libraries or programs.  (Actually we are a bit
2233                # lax here since this code also applies to non-libtool
2234                # libraries or programs, for which -dlopen and -dlopreopen
2235                # are pure nonsense.  Diagnosing this doesn't seem very
2236                # important: the developer will quickly get complaints from
2237                # the linker.)
2238                $val !~ /^-dl(?:pre)?open$/ &&
2239                # Only get this error once.
2240                ! $flagvar)
2241              {
2242                $flagvar = 1;
2243                # FIXME: should display a stack of nested variables
2244                # as context when $var != $subvar.
2245                err_var ($var, "linker flags such as '$val' belong in "
2246                         . "'${prefix}LDFLAGS'");
2247              }
2248            return ();
2249          }
2250        elsif ($val !~ /^\@.*\@$/)
2251          {
2252            # Assume we have a file of some sort, and output it into the
2253            # dependency variable.  Autoconf substitutions are not output;
2254            # rarely is a new dependency substituted into e.g. foo_LDADD
2255            # -- but bad things (e.g. -lX11) are routinely substituted.
2256            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2257            # and handled specially below.
2258            return $val;
2259          }
2260        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2261          {
2262            handle_LIBOBJS ($subvar, $cond, $1);
2263            $seen_libobjs = 1;
2264            return $val;
2265          }
2266        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2267          {
2268            handle_ALLOCA ($subvar, $cond, $1);
2269            return $val;
2270          }
2271        else
2272          {
2273            return ();
2274          }
2275      });
2276
2277   return $seen_libobjs;
2278 }
2279
2280 # handle_LIBOBJS_or_ALLOCA ($VAR)
2281 # -------------------------------
2282 # Definitions common to LIBOBJS and ALLOCA.
2283 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2284 sub handle_LIBOBJS_or_ALLOCA ($)
2285 {
2286   my ($var) = @_;
2287
2288   my $dir = '';
2289
2290   # If LIBOBJS files must be built in another directory we have
2291   # to define LIBOBJDIR and ensure the files get cleaned.
2292   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2293   # is achieved by 'rm -f *.$(OBJEXT)' in compile.am.
2294   if ($config_libobj_dir
2295       && $relative_dir ne $config_libobj_dir)
2296     {
2297       if (option 'subdir-objects')
2298         {
2299           # In the top-level Makefile we do not use $(top_builddir), because
2300           # we are already there, and since the targets are built without
2301           # a $(top_builddir), it helps BSD Make to match them with
2302           # dependencies.
2303           $dir = "$config_libobj_dir/" if $config_libobj_dir ne '.';
2304           $dir = "$topsrcdir/$dir" if $relative_dir ne '.';
2305           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2306           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2307           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2308           # be created by libtool as a side-effect of creating LTLIBOBJS).
2309           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2310         }
2311       else
2312         {
2313           error ("'\$($var)' cannot be used outside '$config_libobj_dir' if"
2314                  . " 'subdir-objects' is not set");
2315         }
2316     }
2317
2318   return $dir;
2319 }
2320
2321 sub handle_LIBOBJS ($$$)
2322 {
2323   my ($var, $cond, $lt) = @_;
2324   my $myobjext = $lt ? 'lo' : 'o';
2325   $lt ||= '';
2326
2327   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2328     if ! keys %libsources;
2329
2330   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2331
2332   foreach my $iter (keys %libsources)
2333     {
2334       if ($iter =~ /\.[cly]$/)
2335         {
2336           &saw_extension ($&);
2337           &saw_extension ('.c');
2338         }
2339
2340       if ($iter =~ /\.h$/)
2341         {
2342           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2343         }
2344       elsif ($iter ne 'alloca.c')
2345         {
2346           my $rewrite = $iter;
2347           $rewrite =~ s/\.c$/.P$myobjext/;
2348           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2349           $rewrite = "^" . quotemeta ($iter) . "\$";
2350           # Only require the file if it is not a built source.
2351           my $bs = var ('BUILT_SOURCES');
2352           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2353             {
2354               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2355             }
2356         }
2357     }
2358 }
2359
2360 sub handle_ALLOCA ($$$)
2361 {
2362   my ($var, $cond, $lt) = @_;
2363   my $myobjext = $lt ? 'lo' : 'o';
2364   $lt ||= '';
2365   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2366
2367   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2368   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2369   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2370   &saw_extension ('.c');
2371 }
2372
2373 # Canonicalize the input parameter
2374 sub canonicalize
2375 {
2376     my ($string) = @_;
2377     $string =~ tr/A-Za-z0-9_\@/_/c;
2378     return $string;
2379 }
2380
2381 # Canonicalize a name, and check to make sure the non-canonical name
2382 # is never used.  Returns canonical name.  Arguments are name and a
2383 # list of suffixes to check for.
2384 sub check_canonical_spelling
2385 {
2386   my ($name, @suffixes) = @_;
2387
2388   my $xname = &canonicalize ($name);
2389   if ($xname ne $name)
2390     {
2391       foreach my $xt (@suffixes)
2392         {
2393           reject_var ("$name$xt", "use '$xname$xt', not '$name$xt'");
2394         }
2395     }
2396
2397   return $xname;
2398 }
2399
2400
2401 # handle_compile ()
2402 # -----------------
2403 # Set up the compile suite.
2404 sub handle_compile ()
2405 {
2406    return if ! $must_handle_compiled_objects;
2407
2408     # Boilerplate.
2409     my $default_includes = '';
2410     if (! option 'nostdinc')
2411       {
2412         my @incs = ('-I.', subst ('am__isrc'));
2413
2414         my $var = var 'CONFIG_HEADER';
2415         if ($var)
2416           {
2417             foreach my $hdr (split (' ', $var->variable_value))
2418               {
2419                 push @incs, '-I' . dirname ($hdr);
2420               }
2421           }
2422         # We want '-I. -I$(srcdir)', but the latter -I is redundant
2423         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2424         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2425         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2426         # to just put @am__isrc@ right after '-I.', without a space.
2427         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2428       }
2429
2430     my (@mostly_rms, @dist_rms);
2431     foreach my $item (sort keys %compile_clean_files)
2432     {
2433         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2434         {
2435             push (@mostly_rms, "\t-rm -f $item");
2436         }
2437         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2438         {
2439             push (@dist_rms, "\t-rm -f $item");
2440         }
2441         else
2442         {
2443           prog_error 'invalid entry in %compile_clean_files';
2444         }
2445     }
2446
2447     my ($coms, $vars, $rules) =
2448       &file_contents_internal (1, "$libdir/am/compile.am",
2449                                new Automake::Location,
2450                                ('DEFAULT_INCLUDES' => $default_includes,
2451                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2452                                 'DISTRMS' => join ("\n", @dist_rms)));
2453     $output_vars .= $vars;
2454     $output_rules .= "$coms$rules";
2455 }
2456
2457 # handle_libtool ()
2458 # -----------------
2459 # Handle libtool rules.
2460 sub handle_libtool
2461 {
2462   return unless var ('LIBTOOL');
2463
2464   # Libtool requires some files, but only at top level.
2465   # (Starting with Libtool 2.0 we do not have to bother.  These
2466   # requirements are done with AC_REQUIRE_AUX_FILE.)
2467   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2468     if $relative_dir eq '.' && ! $libtool_new_api;
2469
2470   my @libtool_rms;
2471   foreach my $item (sort keys %libtool_clean_directories)
2472     {
2473       my $dir = ($item eq '.') ? '' : "$item/";
2474       # .libs is for Unix, _libs for DOS.
2475       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2476     }
2477
2478   check_user_variables 'LIBTOOLFLAGS';
2479
2480   # Output the libtool compilation rules.
2481   $output_rules .= &file_contents ('libtool',
2482                                    new Automake::Location,
2483                                    LTRMS => join ("\n", @libtool_rms));
2484 }
2485
2486 # handle_programs ()
2487 # ------------------
2488 # Handle C programs.
2489 sub handle_programs
2490 {
2491   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2492                                   'bin', 'sbin', 'libexec', 'pkglibexec',
2493                                   'noinst', 'check');
2494   return if ! @proglist;
2495   $must_handle_compiled_objects = 1;
2496
2497   my $seen_global_libobjs =
2498     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2499
2500   foreach my $pair (@proglist)
2501     {
2502       my ($where, $one_file) = @$pair;
2503
2504       my $seen_libobjs = 0;
2505       my $obj = '.$(OBJEXT)';
2506
2507       $known_programs{$one_file} = $where;
2508
2509       # Canonicalize names and check for misspellings.
2510       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2511                                              '_SOURCES', '_OBJECTS',
2512                                              '_DEPENDENCIES');
2513
2514       $where->push_context ("while processing program '$one_file'");
2515       $where->set (INTERNAL->get);
2516
2517       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2518                                              NONLIBTOOL => 1, LIBTOOL => 0);
2519
2520       if (var ($xname . "_LDADD"))
2521         {
2522           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2523         }
2524       else
2525         {
2526           # User didn't define prog_LDADD override.  So do it.
2527           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2528
2529           # This does a bit too much work.  But we need it to
2530           # generate _DEPENDENCIES when appropriate.
2531           if (var ('LDADD'))
2532             {
2533               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2534             }
2535         }
2536
2537       reject_var ($xname . '_LIBADD',
2538                   "use '${xname}_LDADD', not '${xname}_LIBADD'");
2539
2540       set_seen ($xname . '_DEPENDENCIES');
2541       set_seen ('EXTRA_' . $xname . '_DEPENDENCIES');
2542       set_seen ($xname . '_LDFLAGS');
2543
2544       # Determine program to use for link.
2545       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xname);
2546       $vlink = verbose_flag ($vlink || 'GEN');
2547
2548       # If the resulting program lies into a subdirectory,
2549       # make sure this directory will exist.
2550       my $dirstamp = require_build_directory_maybe ($one_file);
2551
2552       $libtool_clean_directories{dirname ($one_file)} = 1;
2553
2554       $output_rules .= &file_contents ('program',
2555                                        $where,
2556                                        PROGRAM  => $one_file,
2557                                        XPROGRAM => $xname,
2558                                        XLINK    => $xlink,
2559                                        VERBOSE  => $vlink,
2560                                        DIRSTAMP => $dirstamp,
2561                                        EXEEXT   => '$(EXEEXT)');
2562
2563       if ($seen_libobjs || $seen_global_libobjs)
2564         {
2565           if (var ($xname . '_LDADD'))
2566             {
2567               &check_libobjs_sources ($xname, $xname . '_LDADD');
2568             }
2569           elsif (var ('LDADD'))
2570             {
2571               &check_libobjs_sources ($xname, 'LDADD');
2572             }
2573         }
2574     }
2575 }
2576
2577
2578 # handle_libraries ()
2579 # -------------------
2580 # Handle libraries.
2581 sub handle_libraries
2582 {
2583   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2584                                  'lib', 'pkglib', 'noinst', 'check');
2585   return if ! @liblist;
2586   $must_handle_compiled_objects = 1;
2587
2588   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2589                                     'noinst', 'check');
2590
2591   if (@prefix)
2592     {
2593       my $var = rvar ($prefix[0] . '_LIBRARIES');
2594       $var->requires_variables ('library used', 'RANLIB');
2595     }
2596
2597   &define_variable ('AR', 'ar', INTERNAL);
2598   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2599   &define_verbose_tagvar ('AR');
2600
2601   foreach my $pair (@liblist)
2602     {
2603       my ($where, $onelib) = @$pair;
2604
2605       my $seen_libobjs = 0;
2606       # Check that the library fits the standard naming convention.
2607       my $bn = basename ($onelib);
2608       if ($bn !~ /^lib.*\.a$/)
2609         {
2610           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2611           my $suggestion = dirname ($onelib) . "/$bn";
2612           $suggestion =~ s|^\./||g;
2613           msg ('error-gnu/warn', $where,
2614                "'$onelib' is not a standard library name\n"
2615                . "did you mean '$suggestion'?")
2616         }
2617
2618       ($known_libraries{$onelib} = $bn) =~ s/\.a$//;
2619
2620       $where->push_context ("while processing library '$onelib'");
2621       $where->set (INTERNAL->get);
2622
2623       my $obj = '.$(OBJEXT)';
2624
2625       # Canonicalize names and check for misspellings.
2626       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2627                                             '_OBJECTS', '_DEPENDENCIES',
2628                                             '_AR');
2629
2630       if (! var ($xlib . '_AR'))
2631         {
2632           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2633         }
2634
2635       # Generate support for conditional object inclusion in
2636       # libraries.
2637       if (var ($xlib . '_LIBADD'))
2638         {
2639           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2640             {
2641               $seen_libobjs = 1;
2642             }
2643         }
2644       else
2645         {
2646           &define_variable ($xlib . "_LIBADD", '', $where);
2647         }
2648
2649       reject_var ($xlib . '_LDADD',
2650                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2651
2652       # Make sure we at look at this.
2653       set_seen ($xlib . '_DEPENDENCIES');
2654       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2655
2656       &handle_source_transform ($xlib, $onelib, $obj, $where,
2657                                 NONLIBTOOL => 1, LIBTOOL => 0);
2658
2659       # If the resulting library lies into a subdirectory,
2660       # make sure this directory will exist.
2661       my $dirstamp = require_build_directory_maybe ($onelib);
2662       my $verbose = verbose_flag ('AR');
2663       my $silent = silent_flag ();
2664
2665       $output_rules .= &file_contents ('library',
2666                                        $where,
2667                                        VERBOSE  => $verbose,
2668                                        SILENT   => $silent,
2669                                        LIBRARY  => $onelib,
2670                                        XLIBRARY => $xlib,
2671                                        DIRSTAMP => $dirstamp);
2672
2673       if ($seen_libobjs)
2674         {
2675           if (var ($xlib . '_LIBADD'))
2676             {
2677               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2678             }
2679         }
2680
2681       if (! $seen_ar)
2682         {
2683           msg ('extra-portability', $where,
2684                "'$onelib': linking libraries using a non-POSIX\n"
2685                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2686         }
2687     }
2688 }
2689
2690
2691 # handle_ltlibraries ()
2692 # ---------------------
2693 # Handle shared libraries.
2694 sub handle_ltlibraries
2695 {
2696   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2697                                  'noinst', 'lib', 'pkglib', 'check');
2698   return if ! @liblist;
2699   $must_handle_compiled_objects = 1;
2700
2701   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2702                                     'noinst', 'check');
2703
2704   if (@prefix)
2705     {
2706       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2707       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2708     }
2709
2710   my %instdirs = ();
2711   my %instsubdirs = ();
2712   my %instconds = ();
2713   my %liblocations = ();        # Location (in Makefile.am) of each library.
2714
2715   foreach my $key (@prefix)
2716     {
2717       # Get the installation directory of each library.
2718       my $dir = $key;
2719       my $strip_subdir = 1;
2720       if ($dir =~ /^nobase_/)
2721         {
2722           $dir =~ s/^nobase_//;
2723           $strip_subdir = 0;
2724         }
2725       my $var = rvar ($key . '_LTLIBRARIES');
2726
2727       # We reject libraries which are installed in several places
2728       # in the same condition, because we can only specify one
2729       # '-rpath' option.
2730       $var->traverse_recursively
2731         (sub
2732          {
2733            my ($var, $val, $cond, $full_cond) = @_;
2734            my $hcond = $full_cond->human;
2735            my $where = $var->rdef ($cond)->location;
2736            my $ldir = '';
2737            $ldir = '/' . dirname ($val)
2738              if (!$strip_subdir);
2739            # A library cannot be installed in different directories
2740            # in overlapping conditions.
2741            if (exists $instconds{$val})
2742              {
2743                my ($msg, $acond) =
2744                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2745
2746                if ($msg)
2747                  {
2748                    error ($where, $msg, partial => 1);
2749                    my $dirtxt = "installed " . ($strip_subdir ? "in" : "below") . " '$dir'";
2750                    $dirtxt = "built for '$dir'"
2751                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2752                    my $dircond =
2753                      $full_cond->true ? "" : " in condition $hcond";
2754
2755                    error ($where, "'$val' should be $dirtxt$dircond ...",
2756                           partial => 1);
2757
2758                    my $hacond = $acond->human;
2759                    my $adir = $instdirs{$val}{$acond};
2760                    my $adirtxt = "installed in '$adir'";
2761                    $adirtxt = "built for '$adir'"
2762                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2763                          || $adir eq 'check');
2764                    my $adircond = $acond->true ? "" : " in condition $hacond";
2765
2766                    my $onlyone = ($dir ne $adir) ?
2767                      ("\nLibtool libraries can be built for only one "
2768                       . "destination") : "";
2769
2770                    error ($liblocations{$val}{$acond},
2771                           "... and should also be $adirtxt$adircond.$onlyone");
2772                    return;
2773                  }
2774              }
2775            else
2776              {
2777                $instconds{$val} = new Automake::DisjConditions;
2778              }
2779            $instdirs{$val}{$full_cond} = $dir;
2780            $instsubdirs{$val}{$full_cond} = $ldir;
2781            $liblocations{$val}{$full_cond} = $where;
2782            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2783          },
2784          sub
2785          {
2786            return ();
2787          },
2788          skip_ac_subst => 1);
2789     }
2790
2791   foreach my $pair (@liblist)
2792     {
2793       my ($where, $onelib) = @$pair;
2794
2795       my $seen_libobjs = 0;
2796       my $obj = '.lo';
2797
2798       # Canonicalize names and check for misspellings.
2799       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2800                                             '_SOURCES', '_OBJECTS',
2801                                             '_DEPENDENCIES');
2802
2803       # Check that the library fits the standard naming convention.
2804       my $libname_rx = '^lib.*\.la';
2805       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2806       my $ldvar2 = var ('LDFLAGS');
2807       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2808           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2809         {
2810           # Relax name checking for libtool modules.
2811           $libname_rx = '\.la';
2812         }
2813
2814       my $bn = basename ($onelib);
2815       if ($bn !~ /$libname_rx$/)
2816         {
2817           my $type = 'library';
2818           if ($libname_rx eq '\.la')
2819             {
2820               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2821               $type = 'module';
2822             }
2823           else
2824             {
2825               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2826             }
2827           my $suggestion = dirname ($onelib) . "/$bn";
2828           $suggestion =~ s|^\./||g;
2829           msg ('error-gnu/warn', $where,
2830                "'$onelib' is not a standard libtool $type name\n"
2831                . "did you mean '$suggestion'?")
2832         }
2833
2834       ($known_libraries{$onelib} = $bn) =~ s/\.la$//;
2835
2836       $where->push_context ("while processing Libtool library '$onelib'");
2837       $where->set (INTERNAL->get);
2838
2839       # Make sure we look at these.
2840       set_seen ($xlib . '_LDFLAGS');
2841       set_seen ($xlib . '_DEPENDENCIES');
2842       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2843
2844       # Generate support for conditional object inclusion in
2845       # libraries.
2846       if (var ($xlib . '_LIBADD'))
2847         {
2848           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2849             {
2850               $seen_libobjs = 1;
2851             }
2852         }
2853       else
2854         {
2855           &define_variable ($xlib . "_LIBADD", '', $where);
2856         }
2857
2858       reject_var ("${xlib}_LDADD",
2859                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2860
2861
2862       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2863                                              NONLIBTOOL => 0, LIBTOOL => 1);
2864
2865       # Determine program to use for link.
2866       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xlib);
2867       $vlink = verbose_flag ($vlink || 'GEN');
2868
2869       my $rpathvar = "am_${xlib}_rpath";
2870       my $rpath = "\$($rpathvar)";
2871       foreach my $rcond ($instconds{$onelib}->conds)
2872         {
2873           my $val;
2874           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2875               || $instdirs{$onelib}{$rcond} eq 'noinst'
2876               || $instdirs{$onelib}{$rcond} eq 'check')
2877             {
2878               # It's an EXTRA_ library, so we can't specify -rpath,
2879               # because we don't know where the library will end up.
2880               # The user probably knows, but generally speaking automake
2881               # doesn't -- and in fact configure could decide
2882               # dynamically between two different locations.
2883               $val = '';
2884             }
2885           else
2886             {
2887               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2888               $val .= $instsubdirs{$onelib}{$rcond}
2889                 if defined $instsubdirs{$onelib}{$rcond};
2890             }
2891           if ($rcond->true)
2892             {
2893               # If $rcond is true there is only one condition and
2894               # there is no point defining an helper variable.
2895               $rpath = $val;
2896             }
2897           else
2898             {
2899               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2900             }
2901         }
2902
2903       # If the resulting library lies into a subdirectory,
2904       # make sure this directory will exist.
2905       my $dirstamp = require_build_directory_maybe ($onelib);
2906
2907       # Remember to cleanup .libs/ in this directory.
2908       my $dirname = dirname $onelib;
2909       $libtool_clean_directories{$dirname} = 1;
2910
2911       $output_rules .= &file_contents ('ltlibrary',
2912                                        $where,
2913                                        LTLIBRARY  => $onelib,
2914                                        XLTLIBRARY => $xlib,
2915                                        RPATH      => $rpath,
2916                                        XLINK      => $xlink,
2917                                        VERBOSE    => $vlink,
2918                                        DIRSTAMP   => $dirstamp);
2919       if ($seen_libobjs)
2920         {
2921           if (var ($xlib . '_LIBADD'))
2922             {
2923               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2924             }
2925         }
2926
2927       if (! $seen_ar)
2928         {
2929           msg ('extra-portability', $where,
2930                "'$onelib': linking libtool libraries using a non-POSIX\n"
2931                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2932         }
2933     }
2934 }
2935
2936 # See if any _SOURCES variable were misspelled.
2937 sub check_typos ()
2938 {
2939   # It is ok if the user sets this particular variable.
2940   set_seen 'AM_LDFLAGS';
2941
2942   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2943     {
2944       foreach my $var (variables $primary)
2945         {
2946           my $varname = $var->name;
2947           # A configure variable is always legitimate.
2948           next if exists $configure_vars{$varname};
2949
2950           for my $cond ($var->conditions->conds)
2951             {
2952               $varname =~ /^(?:EXTRA_)?(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2953               msg_var ('syntax', $var, "variable '$varname' is defined but no"
2954                        . " program or\nlibrary has '$1' as canonical name"
2955                        . " (possible typo)")
2956                 unless $var->rdef ($cond)->seen;
2957             }
2958         }
2959     }
2960 }
2961
2962
2963 # Handle scripts.
2964 sub handle_scripts
2965 {
2966     # NOTE we no longer automatically clean SCRIPTS, because it is
2967     # useful to sometimes distribute scripts verbatim.  This happens
2968     # e.g. in Automake itself.
2969     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2970                      'bin', 'sbin', 'libexec', 'pkglibexec', 'pkgdata',
2971                      'noinst', 'check');
2972 }
2973
2974
2975
2976
2977 ## ------------------------ ##
2978 ## Handling Texinfo files.  ##
2979 ## ------------------------ ##
2980
2981 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2982 # &scan_texinfo_file ($FILENAME)
2983 # ------------------------------
2984 # $OUTFILE     - name of the info file produced by $FILENAME.
2985 # $VFILE       - name of the version.texi file used (undef if none).
2986 # @CLEAN_FILES - list of byproducts (indexes etc.)
2987 sub scan_texinfo_file ($)
2988 {
2989   my ($filename) = @_;
2990
2991   # Some of the following extensions are always created, no matter
2992   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2993   # are only created when they are used.  We used to scan $FILENAME
2994   # for their use, but that is not enough: they could be used in
2995   # included files.  We can't scan included files because we don't
2996   # know the include path.  Therefore we always erase these files, no
2997   # matter whether they are used or not.
2998   #
2999   # (tmp is only created if an @macro is used and a certain e-TeX
3000   # feature is not available.)
3001   my %clean_suffixes =
3002     map { $_ => 1 } (qw(aux log toc tmp
3003                         cp cps
3004                         fn fns
3005                         ky kys
3006                         vr vrs
3007                         tp tps
3008                         pg pgs)); # grep 'new.*index' texinfo.tex
3009
3010   my $texi = new Automake::XFile "< $filename";
3011   verb "reading $filename";
3012
3013   my ($outfile, $vfile);
3014   while ($_ = $texi->getline)
3015     {
3016       if (/^\@setfilename +(\S+)/)
3017         {
3018           # Honor only the first @setfilename.  (It's possible to have
3019           # more occurrences later if the manual shows examples of how
3020           # to use @setfilename...)
3021           next if $outfile;
3022
3023           $outfile = $1;
3024           if ($outfile =~ /\.([^.]+)$/ && $1 ne 'info')
3025             {
3026               error ("$filename:$.",
3027                      "output '$outfile' has unrecognized extension");
3028               return;
3029             }
3030         }
3031       # A "version.texi" file is actually any file whose name matches
3032       # "vers*.texi".
3033       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
3034         {
3035           $vfile = $1;
3036         }
3037
3038       # Try to find new or unused indexes.
3039
3040       # Creating a new category of index.
3041       elsif (/^\@def(code)?index (\w+)/)
3042         {
3043           $clean_suffixes{$2} = 1;
3044           $clean_suffixes{"$2s"} = 1;
3045         }
3046
3047       # Merging an index into an another.
3048       elsif (/^\@syn(code)?index (\w+) (\w+)/)
3049         {
3050           delete $clean_suffixes{"$2s"};
3051           $clean_suffixes{"$3s"} = 1;
3052         }
3053
3054     }
3055
3056   if (! $outfile)
3057     {
3058       err_am "'$filename' missing \@setfilename";
3059       return;
3060     }
3061
3062   my $infobase = basename ($filename);
3063   $infobase =~ s/\.te?xi(nfo)?$//;
3064   return ($outfile, $vfile,
3065           map { "$infobase.$_" } (sort keys %clean_suffixes));
3066 }
3067
3068
3069 # ($DIRSTAMP, @CLEAN_FILES)
3070 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
3071 # ------------------------------------------------------------------
3072 # SOURCE - the source Texinfo file
3073 # DEST - the destination Info file
3074 # INSRC - whether DEST should be built in the source tree
3075 # DEPENDENCIES - known dependencies
3076 sub output_texinfo_build_rules ($$$@)
3077 {
3078   my ($source, $dest, $insrc, @deps) = @_;
3079
3080   # Split 'a.texi' into 'a' and '.texi'.
3081   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
3082   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
3083
3084   $ssfx ||= "";
3085   $dsfx ||= "";
3086
3087   # We can output two kinds of rules: the "generic" rules use Make
3088   # suffix rules and are appropriate when $source and $dest do not lie
3089   # in a sub-directory; the "specific" rules are needed in the other
3090   # case.
3091   #
3092   # The former are output only once (this is not really apparent here,
3093   # but just remember that some logic deeper in Automake will not
3094   # output the same rule twice); while the later need to be output for
3095   # each Texinfo source.
3096   my $generic;
3097   my $makeinfoflags;
3098   my $sdir = dirname $source;
3099   if ($sdir eq '.' && dirname ($dest) eq '.')
3100     {
3101       $generic = 1;
3102       $makeinfoflags = '-I $(srcdir)';
3103     }
3104   else
3105     {
3106       $generic = 0;
3107       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3108     }
3109
3110   # A directory can contain two kinds of info files: some built in the
3111   # source tree, and some built in the build tree.  The rules are
3112   # different in each case.  However we cannot output two different
3113   # set of generic rules.  Because in-source builds are more usual, we
3114   # use generic rules in this case and fall back to "specific" rules
3115   # for build-dir builds.  (It should not be a problem to invert this
3116   # if needed.)
3117   $generic = 0 unless $insrc;
3118
3119   # We cannot use a suffix rule to build info files with an empty
3120   # extension.  Otherwise we would output a single suffix inference
3121   # rule, with separate dependencies, as in
3122   #
3123   #    .texi:
3124   #             $(MAKEINFO) ...
3125   #    foo.info: foo.texi
3126   #
3127   # which confuse Solaris make.  (See the Autoconf manual for
3128   # details.)  Therefore we use a specific rule in this case.  This
3129   # applies to info files only (dvi and pdf files always have an
3130   # extension).
3131   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3132
3133   # If the resulting file lie into a subdirectory,
3134   # make sure this directory will exist.
3135   my $dirstamp = require_build_directory_maybe ($dest);
3136
3137   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3138
3139   $output_rules .= file_contents ('texibuild',
3140                                   new Automake::Location,
3141                                   AM_V_MAKEINFO    => verbose_flag('MAKEINFO'),
3142                                   AM_V_TEXI2DVI    => verbose_flag('TEXI2DVI'),
3143                                   AM_V_TEXI2PDF    => verbose_flag('TEXI2PDF'),
3144                                   DEPS             => "@deps",
3145                                   DEST_PREFIX      => $dpfx,
3146                                   DEST_INFO_PREFIX => $dipfx,
3147                                   DEST_SUFFIX      => $dsfx,
3148                                   DIRSTAMP         => $dirstamp,
3149                                   GENERIC          => $generic,
3150                                   GENERIC_INFO     => $generic_info,
3151                                   INSRC            => $insrc,
3152                                   MAKEINFOFLAGS    => $makeinfoflags,
3153                                   SILENT           => silent_flag(),
3154                                   SOURCE           => ($generic
3155                                                        ? '$<' : $source),
3156                                   SOURCE_INFO      => ($generic_info
3157                                                        ? '$<' : $source),
3158                                   SOURCE_REAL      => $source,
3159                                   SOURCE_SUFFIX    => $ssfx,
3160                                   TEXIQUIET        => verbose_flag('texinfo'),
3161                                   TEXIDEVNULL      => verbose_flag('texidevnull'),
3162                                   );
3163   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3164 }
3165
3166
3167 # ($MOSTLYCLEAN, $TEXICLEAN, $MAINTCLEAN)
3168 # handle_texinfo_helper ($info_texinfos)
3169 # --------------------------------------
3170 # Handle all Texinfo source; helper for handle_texinfo.
3171 sub handle_texinfo_helper ($)
3172 {
3173   my ($info_texinfos) = @_;
3174   my (@infobase, @info_deps_list, @texi_deps);
3175   my %versions;
3176   my $done = 0;
3177   my (@mostly_cleans, @texi_cleans, @maint_cleans) = ('', '', '');
3178
3179   # Build a regex matching user-cleaned files.
3180   my $d = var 'DISTCLEANFILES';
3181   my $c = var 'CLEANFILES';
3182   my @f = ();
3183   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3184   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3185   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3186   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3187
3188   foreach my $texi
3189       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3190     {
3191       my $infobase = $texi;
3192       $infobase =~ s/\.(txi|texinfo|texi)$//;
3193
3194       if ($infobase eq $texi)
3195         {
3196           # FIXME: report line number.
3197           err_am "texinfo file '$texi' has unrecognized extension";
3198           next;
3199         }
3200
3201       push @infobase, $infobase;
3202
3203       # If 'version.texi' is referenced by input file, then include
3204       # automatic versioning capability.
3205       my ($out_file, $vtexi, @clean_files) =
3206         scan_texinfo_file ("$relative_dir/$texi")
3207         or next;
3208       push (@mostly_cleans, @clean_files);
3209
3210       # If the Texinfo source is in a subdirectory, create the
3211       # resulting info in this subdirectory.  If it is in the current
3212       # directory, try hard to not prefix "./" because it breaks the
3213       # generic rules.
3214       my $outdir = dirname ($texi) . '/';
3215       $outdir = "" if $outdir eq './';
3216       $out_file =  $outdir . $out_file;
3217
3218       # Until Automake 1.6.3, .info files were built in the
3219       # source tree.  This was an obstacle to the support of
3220       # non-distributed .info files, and non-distributed .texi
3221       # files.
3222       #
3223       # * Non-distributed .texi files is important in some packages
3224       #   where .texi files are built at make time, probably using
3225       #   other binaries built in the package itself, maybe using
3226       #   tools or information found on the build host.  Because
3227       #   these files are not distributed they are always rebuilt
3228       #   at make time; they should therefore not lie in the source
3229       #   directory.  One plan was to support this using
3230       #   nodist_info_TEXINFOS or something similar.  (Doing this
3231       #   requires some sanity checks.  For instance Automake should
3232       #   not allow:
3233       #      dist_info_TEXINFOS = foo.texi
3234       #      nodist_foo_TEXINFOS = included.texi
3235       #   because a distributed file should never depend on a
3236       #   non-distributed file.)
3237       #
3238       # * If .texi files are not distributed, then .info files should
3239       #   not be distributed either.  There are also cases where one
3240       #   wants to distribute .texi files, but does not want to
3241       #   distribute the .info files.  For instance the Texinfo package
3242       #   distributes the tool used to build these files; it would
3243       #   be a waste of space to distribute them.  It's not clear
3244       #   which syntax we should use to indicate that .info files should
3245       #   not be distributed.  Akim Demaille suggested that eventually
3246       #   we switch to a new syntax:
3247       #   |  Maybe we should take some inspiration from what's already
3248       #   |  done in the rest of Automake.  Maybe there is too much
3249       #   |  syntactic sugar here, and you want
3250       #   |     nodist_INFO = bar.info
3251       #   |     dist_bar_info_SOURCES = bar.texi
3252       #   |     bar_texi_DEPENDENCIES = foo.texi
3253       #   |  with a bit of magic to have bar.info represent the whole
3254       #   |  bar*info set.  That's a lot more verbose that the current
3255       #   |  situation, but it is # not new, hence the user has less
3256       #   |  to learn.
3257       #   |
3258       #   |  But there is still too much room for meaningless specs:
3259       #   |     nodist_INFO = bar.info
3260       #   |     dist_bar_info_SOURCES = bar.texi
3261       #   |     dist_PS = bar.ps something-written-by-hand.ps
3262       #   |     nodist_bar_ps_SOURCES = bar.texi
3263       #   |     bar_texi_DEPENDENCIES = foo.texi
3264       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3265       #
3266       # Back to the point, it should be clear that in order to support
3267       # non-distributed .info files, we need to build them in the
3268       # build tree, not in the source tree (non-distributed .texi
3269       # files are less of a problem, because we do not output build
3270       # rules for them).  In Automake 1.7 .info build rules have been
3271       # largely cleaned up so that .info files get always build in the
3272       # build tree, even when distributed.  The idea was that
3273       #   (1) if during a VPATH build the .info file was found to be
3274       #       absent or out-of-date (in the source tree or in the
3275       #       build tree), Make would rebuild it in the build tree.
3276       #       If an up-to-date source-tree of the .info file existed,
3277       #       make would not rebuild it in the build tree.
3278       #   (2) having two copies of .info files, one in the source tree
3279       #       and one (newer) in the build tree is not a problem
3280       #       because 'make dist' always pick files in the build tree
3281       #       first.
3282       # However it turned out the be a bad idea for several reasons:
3283       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3284       #     like GNU Make on point (1) above.  These implementations
3285       #     of Make would always rebuild .info files in the build
3286       #     tree, even if such files were up to date in the source
3287       #     tree.  Consequently, it was impossible to perform a VPATH
3288       #     build of a package containing Texinfo files using these
3289       #     Make implementations.
3290       #     (Refer to the Autoconf Manual, section "Limitation of
3291       #     Make", paragraph "VPATH", item "target lookup", for
3292       #     an account of the differences between these
3293       #     implementations.)
3294       #   * The GNU Coding Standards require these files to be built
3295       #     in the source-tree (when they are distributed, that is).
3296       #   * Keeping a fresher copy of distributed files in the
3297       #     build tree can be annoying during development because
3298       #     - if the files is kept under CVS, you really want it
3299       #       to be updated in the source tree
3300       #     - it is confusing that 'make distclean' does not erase
3301       #       all files in the build tree.
3302       #
3303       # Consequently, starting with Automake 1.8, .info files are
3304       # built in the source tree again.  Because we still plan to
3305       # support non-distributed .info files at some point, we
3306       # have a single variable ($INSRC) that controls whether
3307       # the current .info file must be built in the source tree
3308       # or in the build tree.  Actually this variable is switched
3309       # off for .info files that appear to be cleaned; this is
3310       # for backward compatibility with package such as Texinfo,
3311       # which do things like
3312       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3313       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3314       #   # Do not create info files for distribution.
3315       #   dist-info:
3316       # in order not to distribute .info files.
3317       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3318
3319       my $soutdir = '$(srcdir)/' . $outdir;
3320       $outdir = $soutdir if $insrc;
3321
3322       # If user specified file_TEXINFOS, then use that as explicit
3323       # dependency list.
3324       @texi_deps = ();
3325       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3326
3327       my $canonical = canonicalize ($infobase);
3328       if (var ($canonical . "_TEXINFOS"))
3329         {
3330           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3331           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3332         }
3333
3334       my ($dirstamp, @cfiles) =
3335         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3336       push (@texi_cleans, @cfiles);
3337
3338       push (@info_deps_list, $out_file);
3339
3340       # If a vers*.texi file is needed, emit the rule.
3341       if ($vtexi)
3342         {
3343           err_am ("'$vtexi', included in '$texi', "
3344                   . "also included in '$versions{$vtexi}'")
3345             if defined $versions{$vtexi};
3346           $versions{$vtexi} = $texi;
3347
3348           # We number the stamp-vti files.  This is doable since the
3349           # actual names don't matter much.  We only number starting
3350           # with the second one, so that the common case looks nice.
3351           my $vti = ($done ? $done : 'vti');
3352           ++$done;
3353
3354           # This is ugly, but it is our historical practice.
3355           if ($config_aux_dir_set_in_configure_ac)
3356             {
3357               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3358                                             'mdate-sh');
3359             }
3360           else
3361             {
3362               require_file_with_macro (TRUE, 'info_TEXINFOS',
3363                                        FOREIGN, 'mdate-sh');
3364             }
3365
3366           my $conf_dir;
3367           if ($config_aux_dir_set_in_configure_ac)
3368             {
3369               $conf_dir = "$am_config_aux_dir/";
3370             }
3371           else
3372             {
3373               $conf_dir = '$(srcdir)/';
3374             }
3375           $output_rules .= file_contents ('texi-vers',
3376                                           new Automake::Location,
3377                                           TEXI     => $texi,
3378                                           VTI      => $vti,
3379                                           STAMPVTI => "${soutdir}stamp-$vti",
3380                                           VTEXI    => "$soutdir$vtexi",
3381                                           MDDIR    => $conf_dir,
3382                                           DIRSTAMP => $dirstamp);
3383         }
3384     }
3385
3386   # Handle location of texinfo.tex.
3387   my $need_texi_file = 0;
3388   my $texinfodir;
3389   if (var ('TEXINFO_TEX'))
3390     {
3391       # The user defined TEXINFO_TEX so assume he knows what he is
3392       # doing.
3393       $texinfodir = ('$(srcdir)/'
3394                      . dirname (variable_value ('TEXINFO_TEX')));
3395     }
3396   elsif (option 'cygnus')
3397     {
3398       $texinfodir = '$(top_srcdir)/../texinfo';
3399       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3400     }
3401   elsif ($config_aux_dir_set_in_configure_ac)
3402     {
3403       $texinfodir = $am_config_aux_dir;
3404       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3405       $need_texi_file = 2; # so that we require_conf_file later
3406     }
3407   else
3408     {
3409       $texinfodir = '$(srcdir)';
3410       $need_texi_file = 1;
3411     }
3412   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3413
3414   push (@dist_targets, 'dist-info');
3415
3416   if (! option 'no-installinfo')
3417     {
3418       # Make sure documentation is made and installed first.  Use
3419       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3420       # get run twice during "make all".
3421       unshift (@all, '$(INFO_DEPS)');
3422     }
3423
3424   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3425   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3426   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3427   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3428
3429   # This next isn't strictly needed now -- the places that look here
3430   # could easily be changed to look in info_TEXINFOS.  But this is
3431   # probably better, in case noinst_TEXINFOS is ever supported.
3432   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3433
3434   # Do some error checking.  Note that this file is not required
3435   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3436   # up above.
3437   if ($need_texi_file && ! option 'no-texinfo.tex')
3438     {
3439       if ($need_texi_file > 1)
3440         {
3441           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3442                                         'texinfo.tex');
3443         }
3444       else
3445         {
3446           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3447                                    'texinfo.tex');
3448         }
3449     }
3450
3451   return (makefile_wrap ("", "\t  ", @mostly_cleans),
3452           makefile_wrap ("", "\t  ", @texi_cleans),
3453           makefile_wrap ("", "\t  ", @maint_cleans));
3454 }
3455
3456
3457 # handle_texinfo ()
3458 # -----------------
3459 # Handle all Texinfo source.
3460 sub handle_texinfo ()
3461 {
3462   reject_var 'TEXINFOS', "'TEXINFOS' is an anachronism; use 'info_TEXINFOS'";
3463   # FIXME: I think this is an obsolete future feature name.
3464   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3465
3466   my $info_texinfos = var ('info_TEXINFOS');
3467   my ($mostlyclean, $clean, $maintclean) = ('', '', '');
3468   if ($info_texinfos)
3469     {
3470       define_verbose_texinfo;
3471       ($mostlyclean, $clean, $maintclean) = handle_texinfo_helper ($info_texinfos);
3472       chomp $mostlyclean;
3473       chomp $clean;
3474       chomp $maintclean;
3475     }
3476
3477   $output_rules .=  file_contents ('texinfos',
3478                                    new Automake::Location,
3479                                    AM_V_DVIPS    => verbose_flag('DVIPS'),
3480                                    MOSTLYCLEAN   => $mostlyclean,
3481                                    TEXICLEAN     => $clean,
3482                                    MAINTCLEAN    => $maintclean,
3483                                    'LOCAL-TEXIS' => !!$info_texinfos,
3484                                    TEXIQUIET     => verbose_flag('texinfo'));
3485 }
3486
3487
3488 # Handle any man pages.
3489 sub handle_man_pages
3490 {
3491   reject_var 'MANS', "'MANS' is an anachronism; use 'man_MANS'";
3492
3493   # Find all the sections in use.  We do this by first looking for
3494   # "standard" sections, and then looking for any additional
3495   # sections used in man_MANS.
3496   my (%sections, %notrans_sections, %trans_sections,
3497       %notrans_vars, %trans_vars, %notrans_sect_vars, %trans_sect_vars);
3498   # We handle nodist_ for uniformity.  man pages aren't distributed
3499   # by default so it isn't actually very important.
3500   foreach my $npfx ('', 'notrans_')
3501     {
3502       foreach my $pfx ('', 'dist_', 'nodist_')
3503         {
3504           # Add more sections as needed.
3505           foreach my $section ('0'..'9', 'n', 'l')
3506             {
3507               my $varname = $npfx . $pfx . 'man' . $section . '_MANS';
3508               if (var ($varname))
3509                 {
3510                   $sections{$section} = 1;
3511                   $varname = '$(' . $varname . ')';
3512                   if ($npfx eq 'notrans_')
3513                     {
3514                       $notrans_sections{$section} = 1;
3515                       $notrans_sect_vars{$varname} = 1;
3516                     }
3517                   else
3518                     {
3519                       $trans_sections{$section} = 1;
3520                       $trans_sect_vars{$varname} = 1;
3521                     }
3522
3523                   &push_dist_common ($varname)
3524                     if $pfx eq 'dist_';
3525                 }
3526             }
3527
3528           my $varname = $npfx . $pfx . 'man_MANS';
3529           my $var = var ($varname);
3530           if ($var)
3531             {
3532               foreach ($var->value_as_list_recursive)
3533                 {
3534                   # A page like 'foo.1c' goes into man1dir.
3535                   if (/\.([0-9a-z])([a-z]*)$/)
3536                     {
3537                       $sections{$1} = 1;
3538                       if ($npfx eq 'notrans_')
3539                         {
3540                           $notrans_sections{$1} = 1;
3541                         }
3542                       else
3543                         {
3544                           $trans_sections{$1} = 1;
3545                         }
3546                     }
3547                 }
3548
3549               $varname = '$(' . $varname . ')';
3550               if ($npfx eq 'notrans_')
3551                 {
3552                   $notrans_vars{$varname} = 1;
3553                 }
3554               else
3555                 {
3556                   $trans_vars{$varname} = 1;
3557                 }
3558               &push_dist_common ($varname)
3559                 if $pfx eq 'dist_';
3560             }
3561         }
3562     }
3563
3564   return unless %sections;
3565
3566   my @unsorted_deps;
3567
3568   # Build section independent variables.
3569   my $have_notrans = %notrans_vars;
3570   my @notrans_list = sort keys %notrans_vars;
3571   my $have_trans = %trans_vars;
3572   my @trans_list = sort keys %trans_vars;
3573
3574   # Now for each section, generate an install and uninstall rule.
3575   # Sort sections so output is deterministic.
3576   foreach my $section (sort keys %sections)
3577     {
3578       # Build section dependent variables.
3579       my $notrans_mans = $have_notrans || exists $notrans_sections{$section};
3580       my $trans_mans = $have_trans || exists $trans_sections{$section};
3581       my (%notrans_this_sect, %trans_this_sect);
3582       my $expr = 'man' . $section . '_MANS';
3583       foreach my $varname (keys %notrans_sect_vars)
3584         {
3585           if ($varname =~ /$expr/)
3586             {
3587               $notrans_this_sect{$varname} = 1;
3588             }
3589         }
3590       foreach my $varname (keys %trans_sect_vars)
3591         {
3592           if ($varname =~ /$expr/)
3593             {
3594               $trans_this_sect{$varname} = 1;
3595             }
3596         }
3597       my @notrans_sect_list = sort keys %notrans_this_sect;
3598       my @trans_sect_list = sort keys %trans_this_sect;
3599       @unsorted_deps = (keys %notrans_vars, keys %trans_vars,
3600                         keys %notrans_this_sect, keys %trans_this_sect);
3601       my @deps = sort @unsorted_deps;
3602       $output_rules .= &file_contents ('mans',
3603                                        new Automake::Location,
3604                                        SECTION           => $section,
3605                                        DEPS              => "@deps",
3606                                        NOTRANS_MANS      => $notrans_mans,
3607                                        NOTRANS_SECT_LIST => "@notrans_sect_list",
3608                                        HAVE_NOTRANS      => $have_notrans,
3609                                        NOTRANS_LIST      => "@notrans_list",
3610                                        TRANS_MANS        => $trans_mans,
3611                                        TRANS_SECT_LIST   => "@trans_sect_list",
3612                                        HAVE_TRANS        => $have_trans,
3613                                        TRANS_LIST        => "@trans_list");
3614     }
3615
3616   @unsorted_deps  = (keys %notrans_vars, keys %trans_vars,
3617                      keys %notrans_sect_vars, keys %trans_sect_vars);
3618   my @mans = sort @unsorted_deps;
3619   $output_vars .= file_contents ('mans-vars',
3620                                  new Automake::Location,
3621                                  MANS => "@mans");
3622
3623   push (@all, '$(MANS)')
3624     unless option 'no-installman';
3625 }
3626
3627 # Handle DATA variables.
3628 sub handle_data
3629 {
3630     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3631                      'data', 'dataroot', 'doc', 'dvi', 'html', 'pdf',
3632                      'ps', 'sysconf', 'sharedstate', 'localstate',
3633                      'pkgdata', 'lisp', 'noinst', 'check');
3634 }
3635
3636 # Handle TAGS.
3637 sub handle_tags
3638 {
3639     my @tag_deps = ();
3640     my @ctag_deps = ();
3641     my @cscope_deps = ();
3642     if (var ('SUBDIRS'))
3643     {
3644         $output_rules .= ("tags-recursive:\n"
3645                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3646                           # Never fail here if a subdir fails; it
3647                           # isn't important.
3648                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3649                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3650                           . "\tdone\n");
3651         push (@tag_deps, 'tags-recursive');
3652         &depend ('.PHONY', 'tags-recursive');
3653         &depend ('.MAKE', 'tags-recursive');
3654
3655         $output_rules .= ("ctags-recursive:\n"
3656                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3657                           # Never fail here if a subdir fails; it
3658                           # isn't important.
3659                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3660                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3661                           . "\tdone\n");
3662         push (@ctag_deps, 'ctags-recursive');
3663         &depend ('.PHONY', 'ctags-recursive');
3664         &depend ('.MAKE', 'ctags-recursive');
3665
3666         $output_rules .= ("cscopelist-recursive:\n"
3667                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3668                           # Never fail here if a subdir fails; it
3669                           # isn't important.
3670                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3671                           . " && \$(MAKE) \$(AM_MAKEFLAGS) cscopelist); \\\n"
3672                           . "\tdone\n");
3673         push (@cscope_deps, 'cscopelist-recursive');
3674         &depend ('.PHONY', 'cscopelist-recursive');
3675         &depend ('.MAKE', 'cscopelist-recursive');
3676     }
3677
3678     if (&saw_sources_p (1)
3679         || var ('ETAGS_ARGS')
3680         || @tag_deps)
3681     {
3682         my @config;
3683         foreach my $spec (@config_headers)
3684         {
3685             my ($out, @ins) = split_config_file_spec ($spec);
3686             foreach my $in (@ins)
3687               {
3688                 # If the config header source is in this directory,
3689                 # require it.
3690                 push @config, basename ($in)
3691                   if $relative_dir eq dirname ($in);
3692               }
3693         }
3694         $output_rules .= &file_contents ('tags',
3695                                          new Automake::Location,
3696                                          CONFIG    => "@config",
3697                                          TAGSDIRS  => "@tag_deps",
3698                                          CTAGSDIRS => "@ctag_deps",
3699                                          CSCOPEDIRS => "@cscope_deps");
3700
3701         set_seen 'TAGS_DEPENDENCIES';
3702     }
3703     elsif (reject_var ('TAGS_DEPENDENCIES',
3704                        "it doesn't make sense to define 'TAGS_DEPENDENCIES'"
3705                        . " without\nsources or 'ETAGS_ARGS'"))
3706     {
3707     }
3708     else
3709     {
3710         # Every Makefile must define some sort of TAGS rule.
3711         # Otherwise, it would be possible for a top-level "make TAGS"
3712         # to fail because some subdirectory failed.
3713         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3714         # Ditto ctags and cscope.
3715         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3716         $output_rules .= "cscope cscopelist:\n\n";
3717     }
3718 }
3719
3720
3721 # user_phony_rule ($NAME)
3722 # -----------------------
3723 # Return false if rule $NAME does not exist.  Otherwise,
3724 # declare it as phony, complete its definition (in case it is
3725 # conditional), and return its Automake::Rule instance.
3726 sub user_phony_rule ($)
3727 {
3728   my ($name) = @_;
3729   my $rule = rule $name;
3730   if ($rule)
3731     {
3732       depend ('.PHONY', $name);
3733       # Define $NAME in all condition where it is not already defined,
3734       # so that it is always OK to depend on $NAME.
3735       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3736         {
3737           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3738                                   $c, INTERNAL);
3739           $output_rules .= $c->subst_string . "$name:\n";
3740         }
3741     }
3742   return $rule;
3743 }
3744
3745
3746 # $BOOLEAN
3747 # &for_dist_common ($A, $B)
3748 # -------------------------
3749 # Subroutine for &handle_dist: sort files to dist.
3750 #
3751 # We put README first because it then becomes easier to make a
3752 # Usenet-compliant shar file (in these, README must be first).
3753 #
3754 # FIXME: do more ordering of files here.
3755 sub for_dist_common
3756 {
3757     return 0
3758         if $a eq $b;
3759     return -1
3760         if $a eq 'README';
3761     return 1
3762         if $b eq 'README';
3763     return $a cmp $b;
3764 }
3765
3766 # handle_dist
3767 # -----------
3768 # Handle 'dist' target.
3769 sub handle_dist ()
3770 {
3771   # Substitutions for distdir.am
3772   my %transform;
3773
3774   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3775   # no-dist setting: target like 'distclean' or 'maintainer-clean' use it.
3776   my $subdirs = var ('SUBDIRS');
3777   if ($subdirs)
3778     {
3779       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3780       # to all possible directories, and use it.  If DIST_SUBDIRS is
3781       # defined, just use it.
3782
3783       # Note that we check DIST_SUBDIRS first on purpose, so that
3784       # we don't call has_conditional_contents for now reason.
3785       # (In the past one project used so many conditional subdirectories
3786       # that calling has_conditional_contents on SUBDIRS caused
3787       # automake to grow to 150Mb -- this should not happen with
3788       # the current implementation of has_conditional_contents,
3789       # but it's more efficient to avoid the call anyway.)
3790       if (var ('DIST_SUBDIRS'))
3791         {
3792         }
3793       elsif ($subdirs->has_conditional_contents)
3794         {
3795           define_pretty_variable
3796             ('DIST_SUBDIRS', TRUE, INTERNAL,
3797              uniq ($subdirs->value_as_list_recursive));
3798         }
3799       else
3800         {
3801           # We always define this because that is what 'distclean'
3802           # wants.
3803           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3804                                   '$(SUBDIRS)');
3805         }
3806     }
3807
3808   # The remaining definitions are only required when a dist target is used.
3809   return if option 'no-dist';
3810
3811   # At least one of the archive formats must be enabled.
3812   if ($relative_dir eq '.')
3813     {
3814       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3815       $archive_defined ||=
3816         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzip lzma xz);
3817       error (option 'no-dist-gzip',
3818              "no-dist-gzip specified but no dist-* specified,\n"
3819              . "at least one archive format must be enabled")
3820         unless $archive_defined;
3821     }
3822
3823   # Look for common files that should be included in distribution.
3824   # If the aux dir is set, and it does not have a Makefile.am, then
3825   # we check for these files there as well.
3826   my $check_aux = 0;
3827   if ($relative_dir eq '.'
3828       && $config_aux_dir_set_in_configure_ac)
3829     {
3830       if (! &is_make_dir ($config_aux_dir))
3831         {
3832           $check_aux = 1;
3833         }
3834     }
3835   foreach my $cfile (@common_files)
3836     {
3837       if (dir_has_case_matching_file ($relative_dir, $cfile)
3838           # The file might be absent, but if it can be built it's ok.
3839           || rule $cfile)
3840         {
3841           &push_dist_common ($cfile);
3842         }
3843
3844       # Don't use 'elsif' here because a file might meaningfully
3845       # appear in both directories.
3846       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3847         {
3848           &push_dist_common ("$config_aux_dir/$cfile")
3849         }
3850     }
3851
3852   # We might copy elements from $configure_dist_common to
3853   # %dist_common if we think we need to.  If the file appears in our
3854   # directory, we would have discovered it already, so we don't
3855   # check that.  But if the file is in a subdir without a Makefile,
3856   # we want to distribute it here if we are doing '.'.  Ugly!
3857   # Also, in some corner cases, it's possible that the following code
3858   # will cause the same file to appear in the $(DIST_COMMON) variables
3859   # of two distinct Makefiles; but this is not a problem, since the
3860   # 'distdir' target in 'lib/am/distdir.am' can deal with the same
3861   # file being distributed multiple times.
3862   # See also automake bug#9651.
3863   if ($relative_dir eq '.')
3864     {
3865       foreach my $file (split (' ' , $configure_dist_common))
3866         {
3867           my $dir = dirname ($file);
3868           push_dist_common ($file)
3869             if ($dir eq '.' || ! is_make_dir ($dir));
3870         }
3871     }
3872
3873   # Files to distributed.  Don't use ->value_as_list_recursive
3874   # as it recursively expands '$(dist_pkgdata_DATA)' etc.
3875   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3876   @dist_common = uniq (sort for_dist_common (@dist_common));
3877   variable_delete 'DIST_COMMON';
3878   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3879
3880   # Now that we've processed DIST_COMMON, disallow further attempts
3881   # to set it.
3882   $handle_dist_run = 1;
3883
3884   # Scan EXTRA_DIST to see if we need to distribute anything from a
3885   # subdir.  If so, add it to the list.  I didn't want to do this
3886   # originally, but there were so many requests that I finally
3887   # relented.
3888   my $extra_dist = var ('EXTRA_DIST');
3889
3890   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3891   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3892
3893   # If the target 'dist-hook' exists, make sure it is run.  This
3894   # allows users to do random weird things to the distribution
3895   # before it is packaged up.
3896   push (@dist_targets, 'dist-hook')
3897     if user_phony_rule 'dist-hook';
3898   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3899
3900   my $flm = option ('filename-length-max');
3901   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3902
3903   $output_rules .= &file_contents ('distdir',
3904                                    new Automake::Location,
3905                                    %transform,
3906                                    FILENAME_FILTER => $filename_filter);
3907 }
3908
3909
3910 # check_directory ($NAME, $WHERE [, $RELATIVE_DIR = "."])
3911 # -------------------------------------------------------
3912 # Ensure $NAME is a directory (in $RELATIVE_DIR), and that it uses a sane
3913 # name.  Use $WHERE as a location in the diagnostic, if any.
3914 sub check_directory ($$;$)
3915 {
3916   my ($dir, $where, $reldir) = @_;
3917   $reldir = '.' unless defined $reldir;
3918
3919   error $where, "required directory $reldir/$dir does not exist"
3920     unless -d "$reldir/$dir";
3921
3922   # If an 'obj/' directory exists, BSD make will enter it before
3923   # reading 'Makefile'.  Hence the 'Makefile' in the current directory
3924   # will not be read.
3925   #
3926   #  % cat Makefile
3927   #  all:
3928   #          echo Hello
3929   #  % cat obj/Makefile
3930   #  all:
3931   #          echo World
3932   #  % make      # GNU make
3933   #  echo Hello
3934   #  Hello
3935   #  % pmake     # BSD make
3936   #  echo World
3937   #  World
3938   msg ('portability', $where,
3939        "naming a subdirectory 'obj' causes troubles with BSD make")
3940     if $dir eq 'obj';
3941
3942   # 'aux' is probably the most important of the following forbidden name,
3943   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3944   msg ('portability', $where,
3945        "name '$dir' is reserved on W32 and DOS platforms")
3946     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3947 }
3948
3949 # check_directories_in_var ($VARIABLE)
3950 # ------------------------------------
3951 # Recursively check all items in variables $VARIABLE as directories
3952 sub check_directories_in_var ($)
3953 {
3954   my ($var) = @_;
3955   $var->traverse_recursively
3956     (sub
3957      {
3958        my ($var, $val, $cond, $full_cond) = @_;
3959        check_directory ($val, $var->rdef ($cond)->location, $relative_dir);
3960        return ();
3961      },
3962      undef,
3963      skip_ac_subst => 1);
3964 }
3965
3966 # &handle_subdirs ()
3967 # ------------------
3968 # Handle subdirectories.
3969 sub handle_subdirs ()
3970 {
3971   my $subdirs = var ('SUBDIRS');
3972   return
3973     unless $subdirs;
3974
3975   check_directories_in_var $subdirs;
3976
3977   my $dsubdirs = var ('DIST_SUBDIRS');
3978   check_directories_in_var $dsubdirs
3979     if $dsubdirs;
3980
3981   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3982   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3983 }
3984
3985
3986 # ($REGEN, @DEPENDENCIES)
3987 # &scan_aclocal_m4
3988 # ----------------
3989 # If aclocal.m4 creation is automated, return the list of its dependencies.
3990 sub scan_aclocal_m4 ()
3991 {
3992   my $regen_aclocal = 0;
3993
3994   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3995   set_seen 'CONFIGURE_DEPENDENCIES';
3996
3997   if (-f 'aclocal.m4')
3998     {
3999       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
4000
4001       my $aclocal = new Automake::XFile "< aclocal.m4";
4002       my $line = $aclocal->getline;
4003       $regen_aclocal = $line =~ 'generated automatically by aclocal';
4004     }
4005
4006   my @ac_deps = ();
4007
4008   if (set_seen ('ACLOCAL_M4_SOURCES'))
4009     {
4010       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
4011       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
4012                "'ACLOCAL_M4_SOURCES' is obsolete.\n"
4013                . "It should be safe to simply remove it");
4014     }
4015
4016   # Note that it might be possible that aclocal.m4 doesn't exist but
4017   # should be auto-generated.  This case probably isn't very
4018   # important.
4019
4020   return ($regen_aclocal, @ac_deps);
4021 }
4022
4023
4024 # Helper function for substitute_ac_subst_variables.
4025 sub substitute_ac_subst_variables_worker($)
4026 {
4027   my ($token) = @_;
4028   return "\@$token\@" if var $token;
4029   return "\${$token\}";
4030 }
4031
4032 # substitute_ac_subst_variables ($TEXT)
4033 # -------------------------------------
4034 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
4035 # variable.
4036 sub substitute_ac_subst_variables ($)
4037 {
4038   my ($text) = @_;
4039   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
4040   return $text;
4041 }
4042
4043 # @DEPENDENCIES
4044 # &prepend_srcdir (@INPUTS)
4045 # -------------------------
4046 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
4047 # if an input file has a directory part the same as the current
4048 # directory, then the directory part is simply replaced by $(srcdir).
4049 # But if the directory part is different, then $(top_srcdir) is
4050 # prepended.
4051 sub prepend_srcdir (@)
4052 {
4053   my (@inputs) = @_;
4054   my @newinputs;
4055
4056   foreach my $single (@inputs)
4057     {
4058       if (dirname ($single) eq $relative_dir)
4059         {
4060           push (@newinputs, '$(srcdir)/' . basename ($single));
4061         }
4062       else
4063         {
4064           push (@newinputs, '$(top_srcdir)/' . $single);
4065         }
4066     }
4067   return @newinputs;
4068 }
4069
4070 # @DEPENDENCIES
4071 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
4072 # ---------------------------------------------------
4073 # Compute a list of dependencies appropriate for the rebuild
4074 # rule of
4075 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
4076 # Also distribute $INPUTs which are not built by another AC_CONFIG_FOOs.
4077 sub rewrite_inputs_into_dependencies ($@)
4078 {
4079   my ($file, @inputs) = @_;
4080   my @res = ();
4081
4082   for my $i (@inputs)
4083     {
4084       # We cannot create dependencies on shell variables.
4085       next if (substitute_ac_subst_variables $i) =~ /\$/;
4086
4087       if (exists $ac_config_files_location{$i} && $i ne $file)
4088         {
4089           my $di = dirname $i;
4090           if ($di eq $relative_dir)
4091             {
4092               $i = basename $i;
4093             }
4094           # In the top-level Makefile we do not use $(top_builddir), because
4095           # we are already there, and since the targets are built without
4096           # a $(top_builddir), it helps BSD Make to match them with
4097           # dependencies.
4098           elsif ($relative_dir ne '.')
4099             {
4100               $i = '$(top_builddir)/' . $i;
4101             }
4102         }
4103       else
4104         {
4105           msg ('error', $ac_config_files_location{$file},
4106                "required file '$i' not found")
4107             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
4108           ($i) = prepend_srcdir ($i);
4109           push_dist_common ($i);
4110         }
4111       push @res, $i;
4112     }
4113   return @res;
4114 }
4115
4116
4117
4118 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
4119 # ------------------------------------------------------------------
4120 # Handle remaking and configure stuff.
4121 # We need the name of the input file, to do proper remaking rules.
4122 sub handle_configure ($$$@)
4123 {
4124   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
4125
4126   prog_error 'empty @inputs'
4127     unless @inputs;
4128
4129   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
4130                                                             $makefile_in);
4131   my $rel_makefile = basename $makefile;
4132
4133   my $colon_infile = ':' . join (':', @inputs);
4134   $colon_infile = '' if $colon_infile eq ":$makefile.in";
4135   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
4136   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
4137   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
4138                           @configure_deps, @aclocal_m4_deps,
4139                           '$(top_srcdir)/' . $configure_ac);
4140   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
4141   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
4142   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
4143                           @configuredeps);
4144
4145   my $automake_options = '--' . (global_option 'cygnus' ? 'cygnus' : $strictness_name)
4146                          . (global_option 'no-dependencies' ? ' --ignore-deps' : '');
4147
4148   $output_rules .= file_contents
4149     ('configure',
4150      new Automake::Location,
4151      MAKEFILE              => $rel_makefile,
4152      'MAKEFILE-DEPS'       => "@rewritten",
4153      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
4154      'MAKEFILE-IN'         => $rel_makefile_in,
4155      'HAVE-MAKEFILE-IN-DEPS' => (@include_stack > 0),
4156      'MAKEFILE-IN-DEPS'    => "@include_stack",
4157      'MAKEFILE-AM'         => $rel_makefile_am,
4158      'AUTOMAKE-OPTIONS'    => $automake_options,
4159      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
4160      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
4161      VERBOSE               => verbose_flag ('GEN'));
4162
4163   if ($relative_dir eq '.')
4164     {
4165       &push_dist_common ('acconfig.h')
4166         if -f 'acconfig.h';
4167     }
4168
4169   # If we have a configure header, require it.
4170   my $hdr_index = 0;
4171   my @distclean_config;
4172   foreach my $spec (@config_headers)
4173     {
4174       $hdr_index += 1;
4175       # $CONFIG_H_PATH: config.h from top level.
4176       my ($config_h_path, @ins) = split_config_file_spec ($spec);
4177       my $config_h_dir = dirname ($config_h_path);
4178
4179       # If the header is in the current directory we want to build
4180       # the header here.  Otherwise, if we're at the topmost
4181       # directory and the header's directory doesn't have a
4182       # Makefile, then we also want to build the header.
4183       if ($relative_dir eq $config_h_dir
4184           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
4185         {
4186           my ($cn_sans_dir, $stamp_dir);
4187           if ($relative_dir eq $config_h_dir)
4188             {
4189               $cn_sans_dir = basename ($config_h_path);
4190               $stamp_dir = '';
4191             }
4192           else
4193             {
4194               $cn_sans_dir = $config_h_path;
4195               if ($config_h_dir eq '.')
4196                 {
4197                   $stamp_dir = '';
4198                 }
4199               else
4200                 {
4201                   $stamp_dir = $config_h_dir . '/';
4202                 }
4203             }
4204
4205           # This will also distribute all inputs.
4206           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
4207
4208           # Cannot define rebuild rules for filenames with shell variables.
4209           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4210
4211           # Header defined in this directory.
4212           my @files;
4213           if (-f $config_h_path . '.top')
4214             {
4215               push (@files, "$cn_sans_dir.top");
4216             }
4217           if (-f $config_h_path . '.bot')
4218             {
4219               push (@files, "$cn_sans_dir.bot");
4220             }
4221
4222           push_dist_common (@files);
4223
4224           # For now, acconfig.h can only appear in the top srcdir.
4225           if (-f 'acconfig.h')
4226             {
4227               push (@files, '$(top_srcdir)/acconfig.h');
4228             }
4229
4230           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4231           $output_rules .=
4232             file_contents ('remake-hdr',
4233                            new Automake::Location,
4234                            FILES            => "@files",
4235                            CONFIG_H         => $cn_sans_dir,
4236                            CONFIG_HIN       => $ins[0],
4237                            CONFIG_H_DEPS    => "@ins",
4238                            CONFIG_H_PATH    => $config_h_path,
4239                            STAMP            => "$stamp");
4240
4241           push @distclean_config, $cn_sans_dir, $stamp;
4242         }
4243     }
4244
4245   $output_rules .= file_contents ('clean-hdr',
4246                                   new Automake::Location,
4247                                   FILES => "@distclean_config")
4248     if @distclean_config;
4249
4250   # Distribute and define mkinstalldirs only if it is already present
4251   # in the package, for backward compatibility (some people may still
4252   # use $(mkinstalldirs)).
4253   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4254   if (-f $mkidpath)
4255     {
4256       # Use require_file so that any existing script gets updated
4257       # by --force-missing.
4258       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4259       define_variable ('mkinstalldirs',
4260                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4261     }
4262   else
4263     {
4264       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4265       # at least one argument, and $(mkinstalldirs) used to work
4266       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4267       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4268     }
4269
4270   reject_var ('CONFIG_HEADER',
4271               "'CONFIG_HEADER' is an anachronism; now determined "
4272               . "automatically\nfrom '$configure_ac'");
4273
4274   my @config_h;
4275   foreach my $spec (@config_headers)
4276     {
4277       my ($out, @ins) = split_config_file_spec ($spec);
4278       # Generate CONFIG_HEADER define.
4279       if ($relative_dir eq dirname ($out))
4280         {
4281           push @config_h, basename ($out);
4282         }
4283       else
4284         {
4285           push @config_h, "\$(top_builddir)/$out";
4286         }
4287     }
4288   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4289     if @config_h;
4290
4291   # Now look for other files in this directory which must be remade
4292   # by config.status, and generate rules for them.
4293   my @actual_other_files = ();
4294   # These get cleaned only in a VPATH build.
4295   my @actual_other_vpath_files = ();
4296   foreach my $lfile (@other_input_files)
4297     {
4298       my $file;
4299       my @inputs;
4300       if ($lfile =~ /^([^:]*):(.*)$/)
4301         {
4302           # This is the ":" syntax of AC_OUTPUT.
4303           $file = $1;
4304           @inputs = split (':', $2);
4305         }
4306       else
4307         {
4308           # Normal usage.
4309           $file = $lfile;
4310           @inputs = $file . '.in';
4311         }
4312
4313       # Automake files should not be stored in here, but in %MAKE_LIST.
4314       prog_error ("$lfile in \@other_input_files\n"
4315                   . "\@other_input_files = (@other_input_files)")
4316         if -f $file . '.am';
4317
4318       my $local = basename ($file);
4319
4320       # We skip files that aren't in this directory.  However, if
4321       # the file's directory does not have a Makefile, and we are
4322       # currently doing '.', then we create a rule to rebuild the
4323       # file in the subdir.
4324       my $fd = dirname ($file);
4325       if ($fd ne $relative_dir)
4326         {
4327           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4328             {
4329               $local = $file;
4330             }
4331           else
4332             {
4333               next;
4334             }
4335         }
4336
4337       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4338
4339       # Cannot output rules for shell variables.
4340       next if (substitute_ac_subst_variables $local) =~ /\$/;
4341
4342       my $condstr = '';
4343       my $cond = $ac_config_files_condition{$lfile};
4344       if (defined $cond)
4345         {
4346           $condstr = $cond->subst_string;
4347           Automake::Rule::define ($local, $configure_ac, RULE_AUTOMAKE, $cond,
4348                                   $ac_config_files_location{$file});
4349         }
4350       $output_rules .= ($condstr . $local . ': '
4351                         . '$(top_builddir)/config.status '
4352                         . "@rewritten_inputs\n"
4353                         . $condstr . "\t"
4354                         . 'cd $(top_builddir) && '
4355                         . '$(SHELL) ./config.status '
4356                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4357                         . '$@'
4358                         . "\n");
4359       push (@actual_other_files, $local);
4360     }
4361
4362   # For links we should clean destinations and distribute sources.
4363   foreach my $spec (@config_links)
4364     {
4365       my ($link, $file) = split /:/, $spec;
4366       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4367       # the DEST:SRC form.
4368       next unless $file;
4369       my $where = $ac_config_files_location{$link};
4370
4371       # Skip destinations that contain shell variables.
4372       if ((substitute_ac_subst_variables $link) !~ /\$/)
4373         {
4374           # We skip links that aren't in this directory.  However, if
4375           # the link's directory does not have a Makefile, and we are
4376           # currently doing '.', then we add the link to CONFIG_CLEAN_FILES
4377           # in '.'s Makefile.in.
4378           my $local = basename ($link);
4379           my $fd = dirname ($link);
4380           if ($fd ne $relative_dir)
4381             {
4382               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4383                 {
4384                   $local = $link;
4385                 }
4386               else
4387                 {
4388                   $local = undef;
4389                 }
4390             }
4391           if ($file ne $link)
4392             {
4393               push @actual_other_files, $local if $local;
4394             }
4395           else
4396             {
4397               push @actual_other_vpath_files, $local if $local;
4398             }
4399         }
4400
4401       # Do not process sources that contain shell variables.
4402       if ((substitute_ac_subst_variables $file) !~ /\$/)
4403         {
4404           my $fd = dirname ($file);
4405
4406           # We distribute files that are in this directory.
4407           # At the top-level ('.') we also distribute files whose
4408           # directory does not have a Makefile.
4409           if (($fd eq $relative_dir)
4410               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4411             {
4412               # The following will distribute $file as a side-effect when
4413               # it is appropriate (i.e., when $file is not already an output).
4414               # We do not need the result, just the side-effect.
4415               rewrite_inputs_into_dependencies ($link, $file);
4416             }
4417         }
4418     }
4419
4420   # These files get removed by "make distclean".
4421   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4422                           @actual_other_files);
4423   define_pretty_variable ('CONFIG_CLEAN_VPATH_FILES', TRUE, INTERNAL,
4424                           @actual_other_vpath_files);
4425 }
4426
4427 # Handle C headers.
4428 sub handle_headers
4429 {
4430     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4431                              'oldinclude', 'pkginclude',
4432                              'noinst', 'check');
4433     foreach (@r)
4434     {
4435       next unless $_->[1] =~ /\..*$/;
4436       &saw_extension ($&);
4437     }
4438 }
4439
4440 sub handle_gettext
4441 {
4442   return if ! $seen_gettext || $relative_dir ne '.';
4443
4444   my $subdirs = var 'SUBDIRS';
4445
4446   if (! $subdirs)
4447     {
4448       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4449       return;
4450     }
4451
4452   # Perform some sanity checks to help users get the right setup.
4453   # We disable these tests when po/ doesn't exist in order not to disallow
4454   # unusual gettext setups.
4455   #
4456   # Bruno Haible:
4457   # | The idea is:
4458   # |
4459   # |  1) If a package doesn't have a directory po/ at top level, it
4460   # |     will likely have multiple po/ directories in subpackages.
4461   # |
4462   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4463   # |     is used without 'external'. It is also useful to warn for the
4464   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4465   # |     warnings apply only to the usual layout of packages, therefore
4466   # |     they should both be disabled if no po/ directory is found at
4467   # |     top level.
4468
4469   if (-d 'po')
4470     {
4471       my @subdirs = $subdirs->value_as_list_recursive;
4472
4473       msg_var ('syntax', $subdirs,
4474                "AM_GNU_GETTEXT used but 'po' not in SUBDIRS")
4475         if ! grep ($_ eq 'po', @subdirs);
4476
4477       # intl/ is not required when AM_GNU_GETTEXT is called with the
4478       # 'external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4479       msg_var ('syntax', $subdirs,
4480                "AM_GNU_GETTEXT used but 'intl' not in SUBDIRS")
4481         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4482             && ! grep ($_ eq 'intl', @subdirs));
4483
4484       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4485       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4486       msg_var ('syntax', $subdirs,
4487                "'intl' should not be in SUBDIRS when "
4488                . "AM_GNU_GETTEXT([external]) is used")
4489         if ($seen_gettext_external && ! $seen_gettext_intl
4490             && grep ($_ eq 'intl', @subdirs));
4491     }
4492
4493   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4494 }
4495
4496 # Handle footer elements.
4497 sub handle_footer
4498 {
4499     reject_rule ('.SUFFIXES',
4500                  "use variable 'SUFFIXES', not target '.SUFFIXES'");
4501
4502     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4503     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4504     # anything else, by sticking it right after the default: target.
4505     $output_header .= ".SUFFIXES:\n";
4506     my $suffixes = var 'SUFFIXES';
4507     my @suffixes = Automake::Rule::suffixes;
4508     if (@suffixes || $suffixes)
4509     {
4510         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4511         # the output remains consistent.  However, $(SUFFIXES) is
4512         # always at the start of the list, unsorted.  This is done
4513         # because make will choose rules depending on the ordering of
4514         # suffixes, and this lets the user have some control.  Push
4515         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4516         # do not like variable substitutions on the .SUFFIXES line.
4517         my @user_suffixes = ($suffixes
4518                              ? $suffixes->value_as_list_recursive : ());
4519
4520         my %suffixes = map { $_ => 1 } @suffixes;
4521         delete @suffixes{@user_suffixes};
4522
4523         $output_header .= (".SUFFIXES: "
4524                            . join (' ', @user_suffixes, sort keys %suffixes)
4525                            . "\n");
4526     }
4527
4528     $output_trailer .= file_contents ('footer', new Automake::Location);
4529 }
4530
4531
4532 # Generate 'make install' rules.
4533 sub handle_install ()
4534 {
4535   $output_rules .= &file_contents
4536     ('install',
4537      new Automake::Location,
4538      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4539                              ? (" \$(BUILT_SOURCES)\n"
4540                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4541                              : ''),
4542      'installdirs-local' => (user_phony_rule 'installdirs-local'
4543                              ? ' installdirs-local' : ''),
4544      am__installdirs => variable_value ('am__installdirs') || '');
4545 }
4546
4547
4548 # Deal with all and all-am.
4549 sub handle_all ($)
4550 {
4551     my ($makefile) = @_;
4552
4553     # Output 'all-am'.
4554
4555     # Put this at the beginning for the sake of non-GNU makes.  This
4556     # is still wrong if these makes can run parallel jobs.  But it is
4557     # right enough.
4558     unshift (@all, basename ($makefile));
4559
4560     foreach my $spec (@config_headers)
4561       {
4562         my ($out, @ins) = split_config_file_spec ($spec);
4563         push (@all, basename ($out))
4564           if dirname ($out) eq $relative_dir;
4565       }
4566
4567     # Install 'all' hooks.
4568     push (@all, "all-local")
4569       if user_phony_rule "all-local";
4570
4571     &pretty_print_rule ("all-am:", "\t\t", @all);
4572     &depend ('.PHONY', 'all-am', 'all');
4573
4574
4575     # Output 'all'.
4576
4577     my @local_headers = ();
4578     push @local_headers, '$(BUILT_SOURCES)'
4579       if var ('BUILT_SOURCES');
4580     foreach my $spec (@config_headers)
4581       {
4582         my ($out, @ins) = split_config_file_spec ($spec);
4583         push @local_headers, basename ($out)
4584           if dirname ($out) eq $relative_dir;
4585       }
4586
4587     if (@local_headers)
4588       {
4589         # We need to make sure config.h is built before we recurse.
4590         # We also want to make sure that built sources are built
4591         # before any ordinary 'all' targets are run.  We can't do this
4592         # by changing the order of dependencies to the "all" because
4593         # that breaks when using parallel makes.  Instead we handle
4594         # things explicitly.
4595         $output_all .= ("all: @local_headers"
4596                         . "\n\t"
4597                         . '$(MAKE) $(AM_MAKEFLAGS) '
4598                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4599                         . "\n\n");
4600         depend ('.MAKE', 'all');
4601       }
4602     else
4603       {
4604         $output_all .= "all: " . (var ('SUBDIRS')
4605                                   ? 'all-recursive' : 'all-am') . "\n\n";
4606       }
4607 }
4608
4609
4610 # &do_check_merge_target ()
4611 # -------------------------
4612 # Handle check merge target specially.
4613 sub do_check_merge_target ()
4614 {
4615   # Include user-defined local form of target.
4616   push @check_tests, 'check-local'
4617     if user_phony_rule 'check-local';
4618
4619   # In --cygnus mode, check doesn't depend on all.
4620   if (option 'cygnus')
4621     {
4622       # Just run the local check rules.
4623       pretty_print_rule ('check-am:', "\t\t", @check);
4624     }
4625   else
4626     {
4627       # The check target must depend on the local equivalent of
4628       # 'all', to ensure all the primary targets are built.  Then it
4629       # must build the local check rules.
4630       $output_rules .= "check-am: all-am\n";
4631       if (@check)
4632         {
4633           pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4634                              @check);
4635           depend ('.MAKE', 'check-am');
4636         }
4637     }
4638   if (@check_tests)
4639     {
4640       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4641                          @check_tests);
4642       depend ('.MAKE', 'check-am');
4643     }
4644
4645   depend '.PHONY', 'check', 'check-am';
4646   # Handle recursion.  We have to honor BUILT_SOURCES like for 'all:'.
4647   $output_rules .= ("check: "
4648                     . (var ('BUILT_SOURCES')
4649                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4650                        : '')
4651                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4652                     . "\n");
4653   depend ('.MAKE', 'check')
4654     if var ('BUILT_SOURCES');
4655 }
4656
4657 # handle_clean ($MAKEFILE)
4658 # ------------------------
4659 # Handle all 'clean' targets.
4660 sub handle_clean ($)
4661 {
4662   my ($makefile) = @_;
4663
4664   # Clean the files listed in user variables if they exist.
4665   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4666     if var ('MOSTLYCLEANFILES');
4667   $clean_files{'$(CLEANFILES)'} = CLEAN
4668     if var ('CLEANFILES');
4669   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4670     if var ('DISTCLEANFILES');
4671   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4672     if var ('MAINTAINERCLEANFILES');
4673
4674   # Built sources are automatically removed by maintainer-clean.
4675   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4676     if var ('BUILT_SOURCES');
4677
4678   # Compute a list of "rm"s to run for each target.
4679   my %rms = (MOSTLY_CLEAN, [],
4680              CLEAN, [],
4681              DIST_CLEAN, [],
4682              MAINTAINER_CLEAN, []);
4683
4684   foreach my $file (keys %clean_files)
4685     {
4686       my $when = $clean_files{$file};
4687       prog_error 'invalid entry in %clean_files'
4688         unless exists $rms{$when};
4689
4690       my $rm = "rm -f $file";
4691       # If file is a variable, make sure when don't call 'rm -f' without args.
4692       $rm ="test -z \"$file\" || $rm"
4693         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4694
4695       push @{$rms{$when}}, "\t-$rm\n";
4696     }
4697
4698   $output_rules .= &file_contents
4699     ('clean',
4700      new Automake::Location,
4701      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4702      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4703      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4704      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4705      MAKEFILE             => basename $makefile,
4706      );
4707 }
4708
4709
4710 # &target_cmp ($A, $B)
4711 # --------------------
4712 # Subroutine for &handle_factored_dependencies to let '.PHONY' and
4713 # other '.TARGETS' be last.
4714 sub target_cmp
4715 {
4716   return 0 if $a eq $b;
4717
4718   my $a1 = substr ($a, 0, 1);
4719   my $b1 = substr ($b, 0, 1);
4720   if ($a1 ne $b1)
4721     {
4722       return -1 if $b1 eq '.';
4723       return 1 if $a1 eq '.';
4724     }
4725   return $a cmp $b;
4726 }
4727
4728
4729 # &handle_factored_dependencies ()
4730 # --------------------------------
4731 # Handle everything related to gathered targets.
4732 sub handle_factored_dependencies
4733 {
4734   # Reject bad hooks.
4735   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4736                      'uninstall-exec-local', 'uninstall-exec-hook',
4737                      'uninstall-dvi-local',
4738                      'uninstall-html-local',
4739                      'uninstall-info-local',
4740                      'uninstall-pdf-local',
4741                      'uninstall-ps-local')
4742     {
4743       my $x = $utarg;
4744       $x =~ s/-.*-/-/;
4745       reject_rule ($utarg, "use '$x', not '$utarg'");
4746     }
4747
4748   reject_rule ('install-local',
4749                "use 'install-data-local' or 'install-exec-local', "
4750                . "not 'install-local'");
4751
4752   reject_rule ('install-hook',
4753                "use 'install-data-hook' or 'install-exec-hook', "
4754                . "not 'install-hook'");
4755
4756   # Install the -local hooks.
4757   foreach (keys %dependencies)
4758     {
4759       # Hooks are installed on the -am targets.
4760       s/-am$// or next;
4761       depend ("$_-am", "$_-local")
4762         if user_phony_rule "$_-local";
4763     }
4764
4765   # Install the -hook hooks.
4766   # FIXME: Why not be as liberal as we are with -local hooks?
4767   foreach ('install-exec', 'install-data', 'uninstall')
4768     {
4769       if (user_phony_rule "$_-hook")
4770         {
4771           depend ('.MAKE', "$_-am");
4772           register_action("$_-am",
4773                           ("\t\@\$(NORMAL_INSTALL)\n"
4774                            . "\t\$(MAKE) \$(AM_MAKEFLAGS) $_-hook"));
4775         }
4776     }
4777
4778   # All the required targets are phony.
4779   depend ('.PHONY', keys %required_targets);
4780
4781   # Actually output gathered targets.
4782   foreach (sort target_cmp keys %dependencies)
4783     {
4784       # If there is nothing about this guy, skip it.
4785       next
4786         unless (@{$dependencies{$_}}
4787                 || $actions{$_}
4788                 || $required_targets{$_});
4789
4790       # Define gathered targets in undefined conditions.
4791       # FIXME: Right now we must handle .PHONY as an exception,
4792       # because people write things like
4793       #    .PHONY: myphonytarget
4794       # to append dependencies.  This would not work if Automake
4795       # refrained from defining its own .PHONY target as it does
4796       # with other overridden targets.
4797       # Likewise for '.MAKE'.
4798       my @undefined_conds = (TRUE,);
4799       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4800         {
4801           @undefined_conds =
4802             Automake::Rule::define ($_, 'internal',
4803                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4804         }
4805       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4806       foreach my $cond (@undefined_conds)
4807         {
4808           my $condstr = $cond->subst_string;
4809           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4810           $output_rules .= $actions{$_} if defined $actions{$_};
4811           $output_rules .= "\n";
4812         }
4813     }
4814 }
4815
4816
4817 # &handle_tests_dejagnu ()
4818 # ------------------------
4819 sub handle_tests_dejagnu
4820 {
4821     push (@check_tests, 'check-DEJAGNU');
4822     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4823 }
4824
4825 sub handle_per_suffix_test
4826 {
4827   my ($test_suffix, %transform) = @_;
4828   my ($pfx, $generic, $parallel_tests_option, $am_exeext);
4829   prog_error ("called with 'parallel-tests' option not set")
4830     unless $parallel_tests_option = option 'parallel-tests';
4831   if ($test_suffix eq '')
4832     {
4833       $pfx = '';
4834       $generic = 0;
4835       $am_exeext = 'FALSE';
4836     }
4837   else
4838     {
4839       prog_error ("test suffix '$test_suffix' lacks leading dot")
4840         unless $test_suffix =~ m/^\.(.*)/;
4841       $pfx = uc ($1) . '_';
4842       $generic = 1;
4843       $am_exeext = exists $configure_vars{'EXEEXT'} ? 'am__EXEEXT'
4844                                                     : 'FALSE';
4845     }
4846   # The "test driver" program, deputed to handle tests protocol used by
4847   # test scripts.  By default, it's assumed that no protocol is used,
4848   # so we fall back to the old "parallel-tests" behaviour, implemented
4849   # by the 'test-driver' auxiliary script.
4850   if (! var "${pfx}LOG_DRIVER")
4851     {
4852       require_conf_file ($parallel_tests_option->{position}, FOREIGN,
4853                         'test-driver');
4854       define_variable ("${pfx}LOG_DRIVER",
4855                        "\$(SHELL) $am_config_aux_dir/test-driver",
4856                        INTERNAL);
4857     }
4858   my $driver = '$(' . $pfx . 'LOG_DRIVER)';
4859   my $driver_flags = '$(AM_' . $pfx . 'LOG_DRIVER_FLAGS)'
4860                        . ' $(' . $pfx . 'LOG_DRIVER_FLAGS)';
4861   my $compile = "${pfx}LOG_COMPILE";
4862   define_variable ($compile,
4863                    '$(' . $pfx . 'LOG_COMPILER)'
4864                       . ' $(AM_' .  $pfx . 'LOG_FLAGS)'
4865                       . ' $(' . $pfx . 'LOG_FLAGS)',
4866                      INTERNAL);
4867   $output_rules .= file_contents ('check2', new Automake::Location,
4868                                    GENERIC => $generic,
4869                                    DRIVER => $driver,
4870                                    DRIVER_FLAGS => $driver_flags,
4871                                    COMPILE => '$(' . $compile . ')',
4872                                    EXT => $test_suffix,
4873                                    am__EXEEXT => $am_exeext,
4874                                    %transform);
4875 }
4876
4877 # is_valid_test_extension ($EXT)
4878 # ------------------------------
4879 # Return true if $EXT can appear in $(TEST_EXTENSIONS), return false
4880 # otherwise.
4881 sub is_valid_test_extension ($)
4882 {
4883   my $ext = shift;
4884   return 1
4885     if ($ext =~ /^\.[a-zA-Z_][a-zA-Z0-9_]*$/);
4886   return 1
4887     if (exists $configure_vars{'EXEEXT'} && $ext eq subst ('EXEEXT'));
4888   return 0;
4889 }
4890
4891 # Handle TESTS variable and other checks.
4892 sub handle_tests
4893 {
4894   if (option 'dejagnu')
4895     {
4896       &handle_tests_dejagnu;
4897     }
4898   else
4899     {
4900       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4901         {
4902           reject_var ($c, "'$c' defined but 'dejagnu' not in "
4903                       . "'AUTOMAKE_OPTIONS'");
4904         }
4905     }
4906
4907   if (var ('TESTS'))
4908     {
4909       push (@check_tests, 'check-TESTS');
4910       my $check_deps = "@check";
4911       $output_rules .= &file_contents ('check', new Automake::Location,
4912                                        COLOR => !! option 'color-tests',
4913                                        PARALLEL_TESTS => !! option 'parallel-tests',
4914                                        CHECK_DEPS => $check_deps);
4915
4916       # Tests that are known programs should have $(EXEEXT) appended.
4917       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4918       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4919       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4920         if (var ('XFAIL_TESTS'));
4921
4922       if (my $parallel_tests = option 'parallel-tests')
4923         {
4924           define_variable ('TEST_SUITE_LOG', 'test-suite.log', INTERNAL);
4925           my $suff = '.test';
4926           my $at_exeext = '';
4927           my $handle_exeext = exists $configure_vars{'EXEEXT'};
4928           if ($handle_exeext)
4929             {
4930               $at_exeext = subst ('EXEEXT');
4931               $suff = $at_exeext  . ' ' . $suff;
4932             }
4933           if (! var 'TEST_EXTENSIONS')
4934             {
4935               define_variable ('TEST_EXTENSIONS', $suff, INTERNAL);
4936             }
4937           my $var = var 'TEST_EXTENSIONS';
4938           # Currently, we are not able to deal with conditional contents
4939           # in TEST_EXTENSIONS.
4940           if ($var->has_conditional_contents)
4941            {
4942              msg_var 'unsupported', $var,
4943                      "'TEST_EXTENSIONS' cannot have conditional contents";
4944            }
4945           my @test_suffixes = $var->value_as_list_recursive;
4946           if ((my @invalid_test_suffixes =
4947                   grep { !is_valid_test_extension $_ } @test_suffixes) > 0)
4948             {
4949               error $var->rdef (TRUE)->location,
4950                     "invalid test extensions: @invalid_test_suffixes";
4951             }
4952           @test_suffixes = grep { is_valid_test_extension $_ } @test_suffixes;
4953           if ($handle_exeext)
4954             {
4955               unshift (@test_suffixes, $at_exeext)
4956                 unless $test_suffixes[0] eq $at_exeext;
4957             }
4958           unshift (@test_suffixes, '');
4959
4960           transform_variable_recursively
4961             ('TESTS', 'TEST_LOGS', 'am__testlogs', 1, INTERNAL,
4962               sub {
4963                 my ($subvar, $val, $cond, $full_cond) = @_;
4964                 my $obj = $val;
4965                 return $obj
4966                   if $val =~ /^\@.*\@$/;
4967                 $obj =~ s/\$\(EXEEXT\)$//o;
4968
4969                 if ($val =~ /(\$\((top_)?srcdir\))\//o)
4970                   {
4971                     msg ('error', $subvar->rdef ($cond)->location,
4972                          "parallel-tests: using '$1' in TESTS is currently broken: '$val'");
4973                   }
4974
4975                 foreach my $test_suffix (@test_suffixes)
4976                   {
4977                     next
4978                       if $test_suffix eq $at_exeext || $test_suffix eq '';
4979                     return substr ($obj, 0, length ($obj) - length ($test_suffix)) . '.log'
4980                       if substr ($obj, - length ($test_suffix)) eq $test_suffix;
4981                   }
4982                 my $base = $obj;
4983                 $obj .= '.log';
4984                 handle_per_suffix_test ('',
4985                                         OBJ => $obj,
4986                                         BASE => $base,
4987                                         SOURCE => $val);
4988                 return $obj;
4989               });
4990
4991           my $nhelper=1;
4992           my $prev = 'TESTS';
4993           my $post = '';
4994           my $last_suffix = $test_suffixes[$#test_suffixes];
4995           my $cur = '';
4996           foreach my $test_suffix (@test_suffixes)
4997             {
4998               if ($test_suffix eq $last_suffix)
4999                 {
5000                   $cur = 'TEST_LOGS';
5001                 }
5002               else
5003                 {
5004                   $cur = 'am__test_logs' . $nhelper;
5005                 }
5006               define_variable ($cur,
5007                 '$(' . $prev . ':' . $test_suffix . $post . '=.log)', INTERNAL);
5008               $post = '.log';
5009               $prev = $cur;
5010               $nhelper++;
5011               if ($test_suffix ne $at_exeext && $test_suffix ne '')
5012                 {
5013                   handle_per_suffix_test ($test_suffix,
5014                                           OBJ => '',
5015                                           BASE => '$*',
5016                                           SOURCE => '$<');
5017                 }
5018             }
5019           $clean_files{'$(TEST_LOGS)'} = MOSTLY_CLEAN;
5020           $clean_files{'$(TEST_LOGS:.log=.trs)'} = MOSTLY_CLEAN;
5021           $clean_files{'$(TEST_SUITE_LOG)'} = MOSTLY_CLEAN;
5022         }
5023     }
5024 }
5025
5026 # Handle Emacs Lisp.
5027 sub handle_emacs_lisp
5028 {
5029   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
5030                                  'lisp', 'noinst');
5031
5032   return if ! @elfiles;
5033
5034   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
5035                           map { $_->[1] } @elfiles);
5036   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
5037                           '$(am__ELFILES:.el=.elc)');
5038   # This one can be overridden by users.
5039   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
5040
5041   push @all, '$(ELCFILES)';
5042
5043   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
5044                      'EMACS', 'lispdir');
5045   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
5046   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
5047 }
5048
5049 # Handle Python
5050 sub handle_python
5051 {
5052   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
5053                                  'noinst');
5054   return if ! @pyfiles;
5055
5056   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
5057   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
5058   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
5059 }
5060
5061 # Handle Java.
5062 sub handle_java
5063 {
5064     my @sourcelist = &am_install_var ('-candist',
5065                                       'java', 'JAVA',
5066                                       'noinst', 'check');
5067     return if ! @sourcelist;
5068
5069     my @prefixes = am_primary_prefixes ('JAVA', 1,
5070                                         'noinst', 'check');
5071
5072     my $dir;
5073     my @java_sources = ();
5074     foreach my $prefix (@prefixes)
5075       {
5076         (my $curs = $prefix) =~ s/^(?:nobase_)?(?:dist_|nodist_)?//;
5077
5078         next
5079           if $curs eq 'EXTRA';
5080
5081         push @java_sources, '$(' . $prefix . '_JAVA' . ')';
5082
5083         if (defined $dir)
5084           {
5085             err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
5086              unless $curs eq $dir;
5087           }
5088
5089         $dir = $curs;
5090       }
5091
5092     define_pretty_variable ('am__java_sources', TRUE, INTERNAL,
5093                             "@java_sources");
5094
5095     if ($dir eq 'check')
5096       {
5097         push (@check, "class$dir.stamp");
5098       }
5099     else
5100       {
5101         push (@all, "class$dir.stamp");
5102       }
5103 }
5104
5105
5106 # Handle some of the minor options.
5107 sub handle_minor_options
5108 {
5109   if (option 'readme-alpha')
5110     {
5111       if ($relative_dir eq '.')
5112         {
5113           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
5114             {
5115               msg ('error-gnits', $package_version_location,
5116                    "version '$package_version' doesn't follow " .
5117                    "Gnits standards");
5118             }
5119           if (defined $1 && -f 'README-alpha')
5120             {
5121               # This means we have an alpha release.  See
5122               # GNITS_VERSION_PATTERN for details.
5123               push_dist_common ('README-alpha');
5124             }
5125         }
5126     }
5127 }
5128
5129 ################################################################
5130
5131 # ($OUTPUT, @INPUTS)
5132 # &split_config_file_spec ($SPEC)
5133 # -------------------------------
5134 # Decode the Autoconf syntax for config files (files, headers, links
5135 # etc.).
5136 sub split_config_file_spec ($)
5137 {
5138   my ($spec) = @_;
5139   my ($output, @inputs) = split (/:/, $spec);
5140
5141   push @inputs, "$output.in"
5142     unless @inputs;
5143
5144   return ($output, @inputs);
5145 }
5146
5147 # $input
5148 # locate_am (@POSSIBLE_SOURCES)
5149 # -----------------------------
5150 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
5151 # This functions returns the first *.in file for which a *.am exists.
5152 # It returns undef otherwise.
5153 sub locate_am (@)
5154 {
5155   my (@rest) = @_;
5156   my $input;
5157   foreach my $file (@rest)
5158     {
5159       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
5160         {
5161           $input = $file;
5162           last;
5163         }
5164     }
5165   return $input;
5166 }
5167
5168 my %make_list;
5169
5170 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
5171 # ---------------------------------------------------
5172 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
5173 # (or AC_OUTPUT).
5174 sub scan_autoconf_config_files ($$)
5175 {
5176   my ($where, $config_files) = @_;
5177
5178   # Look at potential Makefile.am's.
5179   foreach (split ' ', $config_files)
5180     {
5181       # Must skip empty string for Perl 4.
5182       next if $_ eq "\\" || $_ eq '';
5183
5184       # Handle $local:$input syntax.
5185       my ($local, @rest) = split (/:/);
5186       @rest = ("$local.in",) unless @rest;
5187       # Keep in sync with 'conffile-leading-dot.test'.
5188       msg ('unsupported', $where,
5189            "omit leading './' from config file names such as '$local';"
5190            . "\nremake rules might be subtly broken otherwise")
5191         if ($local =~ /^\.\//);
5192       my $input = locate_am @rest;
5193       if ($input)
5194         {
5195           # We have a file that automake should generate.
5196           $make_list{$input} = join (':', ($local, @rest));
5197         }
5198       else
5199         {
5200           # We have a file that automake should cause to be
5201           # rebuilt, but shouldn't generate itself.
5202           push (@other_input_files, $_);
5203         }
5204       $ac_config_files_location{$local} = $where;
5205       $ac_config_files_condition{$local} =
5206         new Automake::Condition (@cond_stack)
5207           if (@cond_stack);
5208     }
5209 }
5210
5211
5212 # &scan_autoconf_traces ($FILENAME)
5213 # ---------------------------------
5214 sub scan_autoconf_traces ($)
5215 {
5216   my ($filename) = @_;
5217
5218   # Macros to trace, with their minimal number of arguments.
5219   #
5220   # IMPORTANT: If you add a macro here, you should also add this macro
5221   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
5222   my %traced = (
5223                 AC_CANONICAL_BUILD => 0,
5224                 AC_CANONICAL_HOST => 0,
5225                 AC_CANONICAL_TARGET => 0,
5226                 AC_CONFIG_AUX_DIR => 1,
5227                 AC_CONFIG_FILES => 1,
5228                 AC_CONFIG_HEADERS => 1,
5229                 AC_CONFIG_LIBOBJ_DIR => 1,
5230                 AC_CONFIG_LINKS => 1,
5231                 AC_FC_SRCEXT => 1,
5232                 AC_INIT => 0,
5233                 AC_LIBSOURCE => 1,
5234                 AC_REQUIRE_AUX_FILE => 1,
5235                 AC_SUBST_TRACE => 1,
5236                 AM_AUTOMAKE_VERSION => 1,
5237                 AM_PROG_MKDIR_P => 0, # FIXME: to be removed in 1.13
5238                 AM_CONDITIONAL => 2,
5239                 AM_GNU_GETTEXT => 0,
5240                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
5241                 AM_INIT_AUTOMAKE => 0,
5242                 AM_MAINTAINER_MODE => 0,
5243                 AM_PROG_AR => 0,
5244                 AM_PROG_CC_C_O => 0,
5245                 AM_SILENT_RULES => 0,
5246                 _AM_SUBST_NOTMAKE => 1,
5247                 _AM_COND_IF => 1,
5248                 _AM_COND_ELSE => 1,
5249                 _AM_COND_ENDIF => 1,
5250                 LT_SUPPORTED_TAG => 1,
5251                 _LT_AC_TAGCONFIG => 0,
5252                 m4_include => 1,
5253                 m4_sinclude => 1,
5254                 sinclude => 1,
5255               );
5256
5257   my $traces = ($ENV{AUTOCONF} || '@am_AUTOCONF@') . " ";
5258
5259   # Use a separator unlikely to be used, not ':', the default, which
5260   # has a precise meaning for AC_CONFIG_FILES and so on.
5261   $traces .= join (' ',
5262                    map { "--trace=$_" . ':\$f:\$l::\$d::\$n::\${::}%' }
5263                    (keys %traced));
5264
5265   my $tracefh = new Automake::XFile ("$traces $filename |");
5266   verb "reading $traces";
5267
5268   @cond_stack = ();
5269   my $where;
5270
5271   while ($_ = $tracefh->getline)
5272     {
5273       chomp;
5274       my ($here, $depth, @args) = split (/::/);
5275       $where = new Automake::Location $here;
5276       my $macro = $args[0];
5277
5278       prog_error ("unrequested trace '$macro'")
5279         unless exists $traced{$macro};
5280
5281       # Skip and diagnose malformed calls.
5282       if ($#args < $traced{$macro})
5283         {
5284           msg ('syntax', $where, "not enough arguments for $macro");
5285           next;
5286         }
5287
5288       # Alphabetical ordering please.
5289       if ($macro eq 'AC_CANONICAL_BUILD')
5290         {
5291           if ($seen_canonical <= AC_CANONICAL_BUILD)
5292             {
5293               $seen_canonical = AC_CANONICAL_BUILD;
5294               $canonical_location = $where;
5295             }
5296         }
5297       elsif ($macro eq 'AC_CANONICAL_HOST')
5298         {
5299           if ($seen_canonical <= AC_CANONICAL_HOST)
5300             {
5301               $seen_canonical = AC_CANONICAL_HOST;
5302               $canonical_location = $where;
5303             }
5304         }
5305       elsif ($macro eq 'AC_CANONICAL_TARGET')
5306         {
5307           $seen_canonical = AC_CANONICAL_TARGET;
5308           $canonical_location = $where;
5309         }
5310       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
5311         {
5312           if ($seen_init_automake)
5313             {
5314               error ($where, "AC_CONFIG_AUX_DIR must be called before "
5315                      . "AM_INIT_AUTOMAKE ...", partial => 1);
5316               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
5317             }
5318           $config_aux_dir = $args[1];
5319           $config_aux_dir_set_in_configure_ac = 1;
5320           check_directory ($config_aux_dir, $where);
5321         }
5322       elsif ($macro eq 'AC_CONFIG_FILES')
5323         {
5324           # Look at potential Makefile.am's.
5325           scan_autoconf_config_files ($where, $args[1]);
5326         }
5327       elsif ($macro eq 'AC_CONFIG_HEADERS')
5328         {
5329           foreach my $spec (split (' ', $args[1]))
5330             {
5331               my ($dest, @src) = split (':', $spec);
5332               $ac_config_files_location{$dest} = $where;
5333               push @config_headers, $spec;
5334             }
5335         }
5336       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
5337         {
5338           $config_libobj_dir = $args[1];
5339           check_directory ($config_libobj_dir, $where);
5340         }
5341       elsif ($macro eq 'AC_CONFIG_LINKS')
5342         {
5343           foreach my $spec (split (' ', $args[1]))
5344             {
5345               my ($dest, $src) = split (':', $spec);
5346               $ac_config_files_location{$dest} = $where;
5347               push @config_links, $spec;
5348             }
5349         }
5350       elsif ($macro eq 'AC_FC_SRCEXT')
5351         {
5352           my $suffix = $args[1];
5353           # These flags are used as %SOURCEFLAG% in depend2.am,
5354           # where the trailing space is important.
5355           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
5356             if ($suffix eq 'f90' || $suffix eq 'f95' || $suffix eq 'f03' || $suffix eq 'f08');
5357         }
5358       elsif ($macro eq 'AC_INIT')
5359         {
5360           if (defined $args[2])
5361             {
5362               $package_version = $args[2];
5363               $package_version_location = $where;
5364             }
5365         }
5366       elsif ($macro eq 'AC_LIBSOURCE')
5367         {
5368           $libsources{$args[1]} = $here;
5369         }
5370       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
5371         {
5372           # Only remember the first time a file is required.
5373           $required_aux_file{$args[1]} = $where
5374             unless exists $required_aux_file{$args[1]};
5375         }
5376       elsif ($macro eq 'AC_SUBST_TRACE')
5377         {
5378           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
5379           # AC_SUBST(5), then too bad.
5380           $configure_vars{$args[1]} = $where
5381             if $args[1] =~ /^\w+$/;
5382         }
5383       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
5384         {
5385           error ($where,
5386                  "version mismatch.  This is Automake $VERSION,\n" .
5387                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
5388                  "comes from Automake $args[1].  You should recreate\n" .
5389                  "aclocal.m4 with aclocal and run automake again.\n",
5390                  # $? = 63 is used to indicate version mismatch to missing.
5391                  exit_code => 63)
5392             if $VERSION ne $args[1];
5393
5394           $seen_automake_version = 1;
5395         }
5396       elsif ($macro eq 'AM_PROG_MKDIR_P') # FIXME: to be removed in 1.13
5397         {
5398           msg 'obsolete', $where, <<'EOF';
5399 The 'AM_PROG_MKDIR_P' macro is deprecated, and will soon be removed.
5400 You should use the Autoconf-provided 'AC_PROG_MKDIR_P' macro instead,
5401 and use '$(MKDIR_P)' instead of '$(mkdir_p)'in your Makefile.am files.
5402 EOF
5403         }
5404       elsif ($macro eq 'AM_CONDITIONAL')
5405         {
5406           $configure_cond{$args[1]} = $where;
5407         }
5408       elsif ($macro eq 'AM_GNU_GETTEXT')
5409         {
5410           $seen_gettext = $where;
5411           $ac_gettext_location = $where;
5412           $seen_gettext_external = grep ($_ eq 'external', @args);
5413         }
5414       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
5415         {
5416           $seen_gettext_intl = $where;
5417         }
5418       elsif ($macro eq 'AM_INIT_AUTOMAKE')
5419         {
5420           $seen_init_automake = $where;
5421           if (defined $args[2])
5422             {
5423               msg 'obsolete', $where, <<'EOF';
5424 AM_INIT_AUTOMAKE: two- and three-arguments forms are deprecated.  For more info, see:
5425 http://www.gnu.org/software/automake/manual/automake.html#Modernize-AM_INIT_AUTOMAKE-invocation
5426 EOF
5427               $package_version = $args[2];
5428               $package_version_location = $where;
5429             }
5430           elsif (defined $args[1])
5431             {
5432               my @opts = split (' ', $args[1]);
5433               @opts = map { { option => $_, where => $where } } @opts;
5434               exit $exit_code if process_global_option_list (@opts);
5435             }
5436         }
5437       elsif ($macro eq 'AM_MAINTAINER_MODE')
5438         {
5439           $seen_maint_mode = $where;
5440         }
5441       elsif ($macro eq 'AM_PROG_AR')
5442         {
5443           $seen_ar = $where;
5444         }
5445       elsif ($macro eq 'AM_PROG_CC_C_O')
5446         {
5447           $seen_cc_c_o = $where;
5448         }
5449       elsif ($macro eq 'AM_SILENT_RULES')
5450         {
5451           set_global_option ('silent-rules', $where);
5452         }
5453       elsif ($macro eq '_AM_COND_IF')
5454         {
5455           cond_stack_if ('', $args[1], $where);
5456           error ($where, "missing m4 quoting, macro depth $depth")
5457             if ($depth != 1);
5458         }
5459       elsif ($macro eq '_AM_COND_ELSE')
5460         {
5461           cond_stack_else ('!', $args[1], $where);
5462           error ($where, "missing m4 quoting, macro depth $depth")
5463             if ($depth != 1);
5464         }
5465       elsif ($macro eq '_AM_COND_ENDIF')
5466         {
5467           cond_stack_endif (undef, undef, $where);
5468           error ($where, "missing m4 quoting, macro depth $depth")
5469             if ($depth != 1);
5470         }
5471       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5472         {
5473           $ignored_configure_vars{$args[1]} = $where;
5474         }
5475       elsif ($macro eq 'm4_include'
5476              || $macro eq 'm4_sinclude'
5477              || $macro eq 'sinclude')
5478         {
5479           # Skip missing 'sinclude'd files.
5480           next if $macro ne 'm4_include' && ! -f $args[1];
5481
5482           # Some modified versions of Autoconf don't use
5483           # frozen files.  Consequently it's possible that we see all
5484           # m4_include's performed during Autoconf's startup.
5485           # Obviously we don't want to distribute Autoconf's files
5486           # so we skip absolute filenames here.
5487           push @configure_deps, '$(top_srcdir)/' . $args[1]
5488             unless $here =~ m,^(?:\w:)?[\\/],;
5489           # Keep track of the greatest timestamp.
5490           if (-e $args[1])
5491             {
5492               my $mtime = mtime $args[1];
5493               $configure_deps_greatest_timestamp = $mtime
5494                 if $mtime > $configure_deps_greatest_timestamp;
5495             }
5496         }
5497       elsif ($macro eq 'LT_SUPPORTED_TAG')
5498         {
5499           $libtool_tags{$args[1]} = 1;
5500           $libtool_new_api = 1;
5501         }
5502       elsif ($macro eq '_LT_AC_TAGCONFIG')
5503         {
5504           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5505           # We use it to detect whether tags are supported.  Our
5506           # preferred interface is LT_SUPPORTED_TAG, but it was
5507           # introduced in Libtool 1.6.
5508           if (0 == keys %libtool_tags)
5509             {
5510               # Hardcode the tags supported by Libtool 1.5.
5511               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5512             }
5513         }
5514     }
5515
5516   error ($where, "condition stack not properly closed")
5517     if (@cond_stack);
5518
5519   $tracefh->close;
5520 }
5521
5522
5523 # &scan_autoconf_files ()
5524 # -----------------------
5525 # Check whether we use 'configure.ac' or 'configure.in'.
5526 # Scan it (and possibly 'aclocal.m4') for interesting things.
5527 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5528 sub scan_autoconf_files ()
5529 {
5530   # Reinitialize libsources here.  This isn't really necessary,
5531   # since we currently assume there is only one configure.ac.  But
5532   # that won't always be the case.
5533   %libsources = ();
5534
5535   # Keep track of the youngest configure dependency.
5536   $configure_deps_greatest_timestamp = mtime $configure_ac;
5537   if (-e 'aclocal.m4')
5538     {
5539       my $mtime = mtime 'aclocal.m4';
5540       $configure_deps_greatest_timestamp = $mtime
5541         if $mtime > $configure_deps_greatest_timestamp;
5542     }
5543
5544   scan_autoconf_traces ($configure_ac);
5545
5546   @configure_input_files = sort keys %make_list;
5547   # Set input and output files if not specified by user.
5548   if (! @input_files)
5549     {
5550       @input_files = @configure_input_files;
5551       %output_files = %make_list;
5552     }
5553
5554
5555   if (! $seen_init_automake)
5556     {
5557       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5558               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5559               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5560               . "and that aclocal.m4 was recently regenerated "
5561               . "(using aclocal)");
5562     }
5563   else
5564     {
5565       if (! $seen_automake_version)
5566         {
5567           if (-f 'aclocal.m4')
5568             {
5569               error ($seen_init_automake,
5570                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5571                      "an\nold Automake version.  You should recreate " .
5572                      "aclocal.m4\nwith aclocal and run automake again",
5573                      # $? = 63 is used to indicate version mismatch to missing.
5574                      exit_code => 63);
5575             }
5576           else
5577             {
5578               error ($seen_init_automake,
5579                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5580                      "found,\nprobably because aclocal.m4 is missing.\n" .
5581                      "You should run aclocal to create this file, then\n" .
5582                      "run automake again");
5583             }
5584         }
5585     }
5586
5587   locate_aux_dir ();
5588
5589   # Look for some files we need.  Always check for these.  This
5590   # check must be done for every run, even those where we are only
5591   # looking at a subdir Makefile.  We must set relative_dir for
5592   # push_required_file to work.
5593   # Sort the files for stable verbose output.
5594   $relative_dir = '.';
5595   foreach my $file (sort keys %required_aux_file)
5596     {
5597       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5598     }
5599   err_am "'install.sh' is an anachronism; use 'install-sh' instead"
5600     if -f $config_aux_dir . '/install.sh';
5601
5602   # Preserve dist_common for later.
5603   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5604
5605 }
5606
5607 ################################################################
5608
5609 # Set up for Cygnus mode.
5610 sub check_cygnus
5611 {
5612   my $cygnus = option 'cygnus';
5613   return unless $cygnus;
5614
5615   # This feature is deprecated, will be removed in the next
5616   # Automake major release.
5617   msg 'obsolete', $cygnus->get,
5618       "support for Cygnus-style trees is deprecated";
5619
5620   set_strictness ('foreign');
5621   set_option ('no-installinfo', $cygnus);
5622   set_option ('no-dependencies', $cygnus);
5623   set_option ('no-dist', $cygnus);
5624
5625   err_ac "'AM_MAINTAINER_MODE' required when --cygnus specified"
5626     if !$seen_maint_mode;
5627 }
5628
5629 # Do any extra checking for GNU standards.
5630 sub check_gnu_standards
5631 {
5632   if ($relative_dir eq '.')
5633     {
5634       # In top level (or only) directory.
5635       require_file ("$am_file.am", GNU,
5636                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5637
5638       # Accept one of these three licenses; default to COPYING.
5639       # Make sure we do not overwrite an existing license.
5640       my $license;
5641       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5642         {
5643           if (-f $_)
5644             {
5645               $license = $_;
5646               last;
5647             }
5648         }
5649       require_file ("$am_file.am", GNU, 'COPYING')
5650         unless $license;
5651     }
5652
5653   for my $opt ('no-installman', 'no-installinfo')
5654     {
5655       msg ('error-gnu', option $opt,
5656            "option '$opt' disallowed by GNU standards")
5657         if option $opt;
5658     }
5659 }
5660
5661 # Do any extra checking for GNITS standards.
5662 sub check_gnits_standards
5663 {
5664   if ($relative_dir eq '.')
5665     {
5666       # In top level (or only) directory.
5667       require_file ("$am_file.am", GNITS, 'THANKS');
5668     }
5669 }
5670
5671 ################################################################
5672 #
5673 # Functions to handle files of each language.
5674
5675 # Each 'lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5676 # simple formula: Return value is LANG_SUBDIR if the resulting object
5677 # file should be in a subdir if the source file is, LANG_PROCESS if
5678 # file is to be dealt with, LANG_IGNORE otherwise.
5679
5680 # Much of the actual processing is handled in
5681 # handle_single_transform.  These functions exist so that
5682 # auxiliary information can be recorded for a later cleanup pass.
5683 # Note that the calls to these functions are computed, so don't bother
5684 # searching for their precise names in the source.
5685
5686 # This is just a convenience function that can be used to determine
5687 # when a subdir object should be used.
5688 sub lang_sub_obj
5689 {
5690     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5691 }
5692
5693 # Rewrite a single C source file.
5694 sub lang_c_rewrite
5695 {
5696   my ($directory, $base, $ext, $obj, $have_per_exec_flags, $var) = @_;
5697
5698   my $r = LANG_PROCESS;
5699   if (option 'subdir-objects')
5700     {
5701       $r = LANG_SUBDIR;
5702       if ($directory && $directory ne '.')
5703         {
5704           $base = $directory . '/' . $base;
5705
5706           # libtool is always able to put the object at the proper place,
5707           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5708           msg_var ('portability', $var,
5709                    "compiling '$base.c' in subdir requires "
5710                    . "'AM_PROG_CC_C_O' in '$configure_ac'",
5711                    uniq_scope => US_GLOBAL,
5712                    uniq_part => 'AM_PROG_CC_C_O subdir')
5713             unless $seen_cc_c_o || $obj eq '.lo';
5714         }
5715     }
5716
5717   if (! $seen_cc_c_o
5718       && $have_per_exec_flags
5719       && ! option 'subdir-objects'
5720       && $obj ne '.lo')
5721     {
5722       msg_var ('portability',
5723                $var, "compiling '$base.c' with per-target flags requires "
5724                . "'AM_PROG_CC_C_O' in '$configure_ac'",
5725                uniq_scope => US_GLOBAL,
5726                uniq_part => 'AM_PROG_CC_C_O per-target')
5727     }
5728
5729     return $r;
5730 }
5731
5732 # Rewrite a single C++ source file.
5733 sub lang_cxx_rewrite
5734 {
5735     return &lang_sub_obj;
5736 }
5737
5738 # Rewrite a single header file.
5739 sub lang_header_rewrite
5740 {
5741     # Header files are simply ignored.
5742     return LANG_IGNORE;
5743 }
5744
5745 # Rewrite a single Vala source file.
5746 sub lang_vala_rewrite
5747 {
5748     my ($directory, $base, $ext) = @_;
5749
5750     (my $newext = $ext) =~ s/vala$/c/;
5751     return (LANG_SUBDIR, $newext);
5752 }
5753
5754 # Rewrite a single yacc file.
5755 sub lang_yacc_rewrite
5756 {
5757     my ($directory, $base, $ext) = @_;
5758
5759     my $r = &lang_sub_obj;
5760     (my $newext = $ext) =~ tr/y/c/;
5761     return ($r, $newext);
5762 }
5763
5764 # Rewrite a single yacc++ file.
5765 sub lang_yaccxx_rewrite
5766 {
5767     my ($directory, $base, $ext) = @_;
5768
5769     my $r = &lang_sub_obj;
5770     (my $newext = $ext) =~ tr/y/c/;
5771     return ($r, $newext);
5772 }
5773
5774 # Rewrite a single lex file.
5775 sub lang_lex_rewrite
5776 {
5777     my ($directory, $base, $ext) = @_;
5778
5779     my $r = &lang_sub_obj;
5780     (my $newext = $ext) =~ tr/l/c/;
5781     return ($r, $newext);
5782 }
5783
5784 # Rewrite a single lex++ file.
5785 sub lang_lexxx_rewrite
5786 {
5787     my ($directory, $base, $ext) = @_;
5788
5789     my $r = &lang_sub_obj;
5790     (my $newext = $ext) =~ tr/l/c/;
5791     return ($r, $newext);
5792 }
5793
5794 # Rewrite a single assembly file.
5795 sub lang_asm_rewrite
5796 {
5797     return &lang_sub_obj;
5798 }
5799
5800 # Rewrite a single preprocessed assembly file.
5801 sub lang_cppasm_rewrite
5802 {
5803     return &lang_sub_obj;
5804 }
5805
5806 # Rewrite a single Fortran 77 file.
5807 sub lang_f77_rewrite
5808 {
5809     return &lang_sub_obj;
5810 }
5811
5812 # Rewrite a single Fortran file.
5813 sub lang_fc_rewrite
5814 {
5815     return &lang_sub_obj;
5816 }
5817
5818 # Rewrite a single preprocessed Fortran file.
5819 sub lang_ppfc_rewrite
5820 {
5821     return &lang_sub_obj;
5822 }
5823
5824 # Rewrite a single preprocessed Fortran 77 file.
5825 sub lang_ppf77_rewrite
5826 {
5827     return &lang_sub_obj;
5828 }
5829
5830 # Rewrite a single ratfor file.
5831 sub lang_ratfor_rewrite
5832 {
5833     return &lang_sub_obj;
5834 }
5835
5836 # Rewrite a single Objective C file.
5837 sub lang_objc_rewrite
5838 {
5839     return &lang_sub_obj;
5840 }
5841
5842 # Rewrite a single Objective C++ file.
5843 sub lang_objcxx_rewrite
5844 {
5845     return &lang_sub_obj;
5846 }
5847
5848 # Rewrite a single Unified Parallel C file.
5849 sub lang_upc_rewrite
5850 {
5851     return &lang_sub_obj;
5852 }
5853
5854 # Rewrite a single Java file.
5855 sub lang_java_rewrite
5856 {
5857     return LANG_SUBDIR;
5858 }
5859
5860 # The lang_X_finish functions are called after all source file
5861 # processing is done.  Each should handle defining rules for the
5862 # language, etc.  A finish function is only called if a source file of
5863 # the appropriate type has been seen.
5864
5865 sub lang_vala_finish_target ($$)
5866 {
5867   my ($self, $name) = @_;
5868
5869   my $derived = canonicalize ($name);
5870   my $var = var "${derived}_SOURCES";
5871   return unless $var;
5872
5873   my @vala_sources = grep { /\.(vala|vapi)$/ } ($var->value_as_list_recursive);
5874
5875   # For automake bug#11229.
5876   return unless @vala_sources;
5877
5878   foreach my $vala_file (@vala_sources)
5879     {
5880       my $c_file = $vala_file;
5881       if ($c_file =~ s/(.*)\.vala$/$1.c/)
5882         {
5883           $c_file = "\$(srcdir)/$c_file";
5884           $output_rules .= "$c_file: \$(srcdir)/${derived}_vala.stamp\n"
5885             . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5886             . "\t\@if test -f \$@; then :; else \\\n"
5887             . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5888             . "\tfi\n";
5889           $clean_files{$c_file} = MAINTAINER_CLEAN;
5890         }
5891     }
5892
5893   # Add rebuild rules for generated header and vapi files
5894   my $flags = var ($derived . '_VALAFLAGS');
5895   if ($flags)
5896     {
5897       my $lastflag = '';
5898       foreach my $flag ($flags->value_as_list_recursive)
5899         {
5900           if (grep (/$lastflag/, ('-H', '-h', '--header', '--internal-header',
5901                                   '--vapi', '--internal-vapi', '--gir')))
5902             {
5903               my $headerfile = "\$(srcdir)/$flag";
5904               $output_rules .= "$headerfile: \$(srcdir)/${derived}_vala.stamp\n"
5905                 . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5906                 . "\t\@if test -f \$@; then :; else \\\n"
5907                 . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5908                 . "\tfi\n";
5909
5910               # valac is not used when building from dist tarballs
5911               # distribute the generated files
5912               push_dist_common ($headerfile);
5913               $clean_files{$headerfile} = MAINTAINER_CLEAN;
5914             }
5915           $lastflag = $flag;
5916         }
5917     }
5918
5919   my $compile = $self->compile;
5920
5921   # Rewrite each occurrence of 'AM_VALAFLAGS' in the compile
5922   # rule into '${derived}_VALAFLAGS' if it exists.
5923   my $val = "${derived}_VALAFLAGS";
5924   $compile =~ s/\(AM_VALAFLAGS\)/\($val\)/
5925     if set_seen ($val);
5926
5927   # VALAFLAGS is a user variable (per GNU Standards),
5928   # it should not be overridden in the Makefile...
5929   check_user_variables 'VALAFLAGS';
5930
5931   my $dirname = dirname ($name);
5932
5933   # Only generate C code, do not run C compiler
5934   $compile .= " -C";
5935
5936   my $verbose = verbose_flag ('VALAC');
5937   my $silent = silent_flag ();
5938   my $stampfile = "\$(srcdir)/${derived}_vala.stamp";
5939
5940   $output_rules .=
5941     "\$(srcdir)/${derived}_vala.stamp: @vala_sources\n".
5942 # Since the C files generated from the vala sources depend on the
5943 # ${derived}_vala.stamp file, we must ensure its timestamp is older than
5944 # those of the C files generated by the valac invocation below (this is
5945 # especially important on systems with sub-second timestamp resolution).
5946 # Thus we need to create the stamp file *before* invoking valac, and to
5947 # move it to its final location only after valac has been invoked.
5948     "\t${silent}rm -f \$\@ && echo stamp > \$\@-t\n".
5949     "\t${verbose}\$(am__cd) \$(srcdir) && $compile @vala_sources\n".
5950     "\t${silent}mv -f \$\@-t \$\@\n";
5951
5952   push_dist_common ($stampfile);
5953
5954   $clean_files{$stampfile} = MAINTAINER_CLEAN;
5955 }
5956
5957 # Add output rules to invoke valac and create stamp file as a witness
5958 # to handle multiple outputs. This function is called after all source
5959 # file processing is done.
5960 sub lang_vala_finish
5961 {
5962   my ($self) = @_;
5963
5964   foreach my $prog (keys %known_programs)
5965     {
5966       lang_vala_finish_target ($self, $prog);
5967     }
5968
5969   while (my ($name) = each %known_libraries)
5970     {
5971       lang_vala_finish_target ($self, $name);
5972     }
5973 }
5974
5975 # The built .c files should be cleaned only on maintainer-clean
5976 # as the .c files are distributed. This function is called for each
5977 # .vala source file.
5978 sub lang_vala_target_hook
5979 {
5980   my ($self, $aggregate, $output, $input, %transform) = @_;
5981
5982   $clean_files{$output} = MAINTAINER_CLEAN;
5983 }
5984
5985 # This is a yacc helper which is called whenever we have decided to
5986 # compile a yacc file.
5987 sub lang_yacc_target_hook
5988 {
5989     my ($self, $aggregate, $output, $input, %transform) = @_;
5990
5991     # If some relevant *YFLAGS variable contains the '-d' flag, we'll
5992     # have to to generate special code.
5993     my $yflags_contains_minus_d = 0;
5994
5995     foreach my $pfx ("", "${aggregate}_")
5996       {
5997         my $yflagsvar = var ("${pfx}YFLAGS");
5998         next unless $yflagsvar;
5999         # We cannot work reliably with conditionally-defined YFLAGS.
6000         if ($yflagsvar->has_conditional_contents)
6001           {
6002             msg_var ('unsupported', $yflagsvar,
6003                      "'${pfx}YFLAGS' cannot have conditional contents");
6004           }
6005         else
6006           {
6007             $yflags_contains_minus_d = 1
6008               if grep (/^-d$/, $yflagsvar->value_as_list_recursive);
6009           }
6010       }
6011
6012     if ($yflags_contains_minus_d)
6013       {
6014         # Found a '-d' that applies to the compilation of this file.
6015         # Add a dependency for the generated header file, and arrange
6016         # for that file to be included in the distribution.
6017
6018         # The extension of the output file (e.g., '.c' or '.cxx').
6019         # We'll need it to compute the name of the generated header file.
6020         (my $output_ext = basename ($output)) =~ s/.*(\.[^.]+)$/$1/;
6021
6022         # We know that a yacc input should be turned into either a C or
6023         # C++ output file.  We depend on this fact (here and in yacc.am),
6024         # so check that it really holds.
6025         my $lang = $languages{$extension_map{$output_ext}};
6026         prog_error "invalid output name '$output' for yacc file '$input'"
6027           if (!$lang || ($lang->name ne 'c' && $lang->name ne 'cxx'));
6028
6029         (my $header_ext = $output_ext) =~ s/c/h/g;
6030         # Quote $output_ext in the regexp, so that dots in it are taken
6031         # as literal dots, not as metacharacters.
6032         (my $header = $output) =~ s/\Q$output_ext\E$/$header_ext/;
6033
6034         foreach my $cond (Automake::Rule::define (${header}, 'internal',
6035                                                   RULE_AUTOMAKE, TRUE,
6036                                                   INTERNAL))
6037           {
6038             my $condstr = $cond->subst_string;
6039             $output_rules .=
6040               "$condstr${header}: $output\n"
6041               # Recover from removal of $header
6042               . "$condstr\t\@if test ! -f \$@; then rm -f $output; else :; fi\n"
6043               . "$condstr\t\@if test ! -f \$@; then \$(MAKE) \$(AM_MAKEFLAGS) $output; else :; fi\n";
6044           }
6045         # Distribute the generated file, unless its .y source was
6046         # listed in a nodist_ variable.  (&handle_source_transform
6047         # will set DIST_SOURCE.)
6048         &push_dist_common ($header)
6049           if $transform{'DIST_SOURCE'};
6050
6051         # The GNU rules say that yacc/lex output files should be removed
6052         # by maintainer-clean.  However, if the files are not distributed,
6053         # then we want to remove them with "make clean"; otherwise,
6054         # "make distcheck" will fail.
6055         $clean_files{$header} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6056       }
6057     # See the comment above for $HEADER.
6058     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6059 }
6060
6061 # This is a lex helper which is called whenever we have decided to
6062 # compile a lex file.
6063 sub lang_lex_target_hook
6064 {
6065     my ($self, $aggregate, $output, $input, %transform) = @_;
6066     # The GNU rules say that yacc/lex output files should be removed
6067     # by maintainer-clean.  However, if the files are not distributed,
6068     # then we want to remove them with "make clean"; otherwise,
6069     # "make distcheck" will fail.
6070     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6071 }
6072
6073 # This is a helper for both lex and yacc.
6074 sub yacc_lex_finish_helper
6075 {
6076   return if defined $language_scratch{'lex-yacc-done'};
6077   $language_scratch{'lex-yacc-done'} = 1;
6078
6079   # FIXME: for now, no line number.
6080   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
6081   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
6082 }
6083
6084 sub lang_yacc_finish
6085 {
6086   return if defined $language_scratch{'yacc-done'};
6087   $language_scratch{'yacc-done'} = 1;
6088
6089   reject_var 'YACCFLAGS', "'YACCFLAGS' obsolete; use 'YFLAGS' instead";
6090
6091   yacc_lex_finish_helper;
6092 }
6093
6094
6095 sub lang_lex_finish
6096 {
6097   return if defined $language_scratch{'lex-done'};
6098   $language_scratch{'lex-done'} = 1;
6099
6100   yacc_lex_finish_helper;
6101 }
6102
6103
6104 # Given a hash table of linker names, pick the name that has the most
6105 # precedence.  This is lame, but something has to have global
6106 # knowledge in order to eliminate the conflict.  Add more linkers as
6107 # required.
6108 sub resolve_linker
6109 {
6110     my (%linkers) = @_;
6111
6112     foreach my $l (qw(GCJLINK OBJCXXLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
6113     {
6114         return $l if defined $linkers{$l};
6115     }
6116     return 'LINK';
6117 }
6118
6119 # Called to indicate that an extension was used.
6120 sub saw_extension
6121 {
6122     my ($ext) = @_;
6123     if (! defined $extension_seen{$ext})
6124     {
6125         $extension_seen{$ext} = 1;
6126     }
6127     else
6128     {
6129         ++$extension_seen{$ext};
6130     }
6131 }
6132
6133 # Return the number of files seen for a given language.  Knows about
6134 # special cases we care about.  FIXME: this is hideous.  We need
6135 # something that involves real language objects.  For instance yacc
6136 # and yaccxx could both derive from a common yacc class which would
6137 # know about the strange ylwrap requirement.  (Or better yet we could
6138 # just not support legacy yacc!)
6139 sub count_files_for_language
6140 {
6141     my ($name) = @_;
6142
6143     my @names;
6144     if ($name eq 'yacc' || $name eq 'yaccxx')
6145     {
6146         @names = ('yacc', 'yaccxx');
6147     }
6148     elsif ($name eq 'lex' || $name eq 'lexxx')
6149     {
6150         @names = ('lex', 'lexxx');
6151     }
6152     else
6153     {
6154         @names = ($name);
6155     }
6156
6157     my $r = 0;
6158     foreach $name (@names)
6159     {
6160         my $lang = $languages{$name};
6161         foreach my $ext (@{$lang->extensions})
6162         {
6163             $r += $extension_seen{$ext}
6164                 if defined $extension_seen{$ext};
6165         }
6166     }
6167
6168     return $r
6169 }
6170
6171 # Called to ask whether source files have been seen . If HEADERS is 1,
6172 # headers can be included.
6173 sub saw_sources_p
6174 {
6175     my ($headers) = @_;
6176
6177     # count all the sources
6178     my $count = 0;
6179     foreach my $val (values %extension_seen)
6180     {
6181         $count += $val;
6182     }
6183
6184     if (!$headers)
6185     {
6186         $count -= count_files_for_language ('header');
6187     }
6188
6189     return $count > 0;
6190 }
6191
6192
6193 # register_language (%ATTRIBUTE)
6194 # ------------------------------
6195 # Register a single language.
6196 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
6197 sub register_language (%)
6198 {
6199   my (%option) = @_;
6200
6201   # Set the defaults.
6202   $option{'autodep'} = 'no'
6203     unless defined $option{'autodep'};
6204   $option{'linker'} = ''
6205     unless defined $option{'linker'};
6206   $option{'flags'} = []
6207     unless defined $option{'flags'};
6208   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
6209     unless defined $option{'output_extensions'};
6210   $option{'nodist_specific'} = 0
6211     unless defined $option{'nodist_specific'};
6212
6213   my $lang = new Language (%option);
6214
6215   # Fill indexes.
6216   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
6217   $languages{$lang->name} = $lang;
6218   my $link = $lang->linker;
6219   if ($link)
6220     {
6221       if (exists $link_languages{$link})
6222         {
6223           prog_error ("'$link' has different definitions in "
6224                       . $lang->name . " and " . $link_languages{$link}->name)
6225             if $lang->link ne $link_languages{$link}->link;
6226         }
6227       else
6228         {
6229           $link_languages{$link} = $lang;
6230         }
6231     }
6232
6233   # Update the pattern of known extensions.
6234   accept_extensions (@{$lang->extensions});
6235
6236   # Upate the $suffix_rule map.
6237   foreach my $suffix (@{$lang->extensions})
6238     {
6239       foreach my $dest (&{$lang->output_extensions} ($suffix))
6240         {
6241           register_suffix_rule (INTERNAL, $suffix, $dest);
6242         }
6243     }
6244 }
6245
6246 # derive_suffix ($EXT, $OBJ)
6247 # --------------------------
6248 # This function is used to find a path from a user-specified suffix $EXT
6249 # to $OBJ or to some other suffix we recognize internally, e.g. 'cc'.
6250 sub derive_suffix ($$)
6251 {
6252   my ($source_ext, $obj) = @_;
6253
6254   while (! $extension_map{$source_ext}
6255          && $source_ext ne $obj
6256          && exists $suffix_rules->{$source_ext}
6257          && exists $suffix_rules->{$source_ext}{$obj})
6258     {
6259       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
6260     }
6261
6262   return $source_ext;
6263 }
6264
6265
6266 ################################################################
6267
6268 # Pretty-print something and append to output_rules.
6269 sub pretty_print_rule
6270 {
6271     $output_rules .= &makefile_wrap (@_);
6272 }
6273
6274
6275 ################################################################
6276
6277
6278 ## -------------------------------- ##
6279 ## Handling the conditional stack.  ##
6280 ## -------------------------------- ##
6281
6282
6283 # $STRING
6284 # make_conditional_string ($NEGATE, $COND)
6285 # ----------------------------------------
6286 sub make_conditional_string ($$)
6287 {
6288   my ($negate, $cond) = @_;
6289   $cond = "${cond}_TRUE"
6290     unless $cond =~ /^TRUE|FALSE$/;
6291   $cond = Automake::Condition::conditional_negate ($cond)
6292     if $negate;
6293   return $cond;
6294 }
6295
6296
6297 my %_am_macro_for_cond =
6298   (
6299   AMDEP => "one of the compiler tests\n"
6300            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_OBJC, AC_PROG_OBJCXX,\n"
6301            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
6302   am__fastdepCC => 'AC_PROG_CC',
6303   am__fastdepCCAS => 'AM_PROG_AS',
6304   am__fastdepCXX => 'AC_PROG_CXX',
6305   am__fastdepGCJ => 'AM_PROG_GCJ',
6306   am__fastdepOBJC => 'AC_PROG_OBJC',
6307   am__fastdepOBJCXX => 'AC_PROG_OBJCXX',
6308   am__fastdepUPC => 'AM_PROG_UPC'
6309   );
6310
6311 # $COND
6312 # cond_stack_if ($NEGATE, $COND, $WHERE)
6313 # --------------------------------------
6314 sub cond_stack_if ($$$)
6315 {
6316   my ($negate, $cond, $where) = @_;
6317
6318   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
6319     {
6320       my $text = "$cond does not appear in AM_CONDITIONAL";
6321       my $scope = US_LOCAL;
6322       if (exists $_am_macro_for_cond{$cond})
6323         {
6324           my $mac = $_am_macro_for_cond{$cond};
6325           $text .= "\n  The usual way to define '$cond' is to add ";
6326           $text .= ($mac =~ / /) ? $mac : "'$mac'";
6327           $text .= "\n  to '$configure_ac' and run 'aclocal' and 'autoconf' again";
6328           # These warnings appear in Automake files (depend2.am),
6329           # so there is no need to display them more than once:
6330           $scope = US_GLOBAL;
6331         }
6332       error $where, $text, uniq_scope => $scope;
6333     }
6334
6335   push (@cond_stack, make_conditional_string ($negate, $cond));
6336
6337   return new Automake::Condition (@cond_stack);
6338 }
6339
6340
6341 # $COND
6342 # cond_stack_else ($NEGATE, $COND, $WHERE)
6343 # ----------------------------------------
6344 sub cond_stack_else ($$$)
6345 {
6346   my ($negate, $cond, $where) = @_;
6347
6348   if (! @cond_stack)
6349     {
6350       error $where, "else without if";
6351       return FALSE;
6352     }
6353
6354   $cond_stack[$#cond_stack] =
6355     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
6356
6357   # If $COND is given, check against it.
6358   if (defined $cond)
6359     {
6360       $cond = make_conditional_string ($negate, $cond);
6361
6362       error ($where, "else reminder ($negate$cond) incompatible with "
6363              . "current conditional: $cond_stack[$#cond_stack]")
6364         if $cond_stack[$#cond_stack] ne $cond;
6365     }
6366
6367   return new Automake::Condition (@cond_stack);
6368 }
6369
6370
6371 # $COND
6372 # cond_stack_endif ($NEGATE, $COND, $WHERE)
6373 # -----------------------------------------
6374 sub cond_stack_endif ($$$)
6375 {
6376   my ($negate, $cond, $where) = @_;
6377   my $old_cond;
6378
6379   if (! @cond_stack)
6380     {
6381       error $where, "endif without if";
6382       return TRUE;
6383     }
6384
6385   # If $COND is given, check against it.
6386   if (defined $cond)
6387     {
6388       $cond = make_conditional_string ($negate, $cond);
6389
6390       error ($where, "endif reminder ($negate$cond) incompatible with "
6391              . "current conditional: $cond_stack[$#cond_stack]")
6392         if $cond_stack[$#cond_stack] ne $cond;
6393     }
6394
6395   pop @cond_stack;
6396
6397   return new Automake::Condition (@cond_stack);
6398 }
6399
6400
6401
6402
6403
6404 ## ------------------------ ##
6405 ## Handling the variables.  ##
6406 ## ------------------------ ##
6407
6408
6409 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
6410 # -----------------------------------------------------
6411 # Like define_variable, but the value is a list, and the variable may
6412 # be defined conditionally.  The second argument is the condition
6413 # under which the value should be defined; this should be the empty
6414 # string to define the variable unconditionally.  The third argument
6415 # is a list holding the values to use for the variable.  The value is
6416 # pretty printed in the output file.
6417 sub define_pretty_variable ($$$@)
6418 {
6419     my ($var, $cond, $where, @value) = @_;
6420
6421     if (! vardef ($var, $cond))
6422     {
6423         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
6424                                     '', $where, VAR_PRETTY);
6425         rvar ($var)->rdef ($cond)->set_seen;
6426     }
6427 }
6428
6429
6430 # define_variable ($VAR, $VALUE, $WHERE)
6431 # --------------------------------------
6432 # Define a new Automake Makefile variable VAR to VALUE, but only if
6433 # not already defined.
6434 sub define_variable ($$$)
6435 {
6436     my ($var, $value, $where) = @_;
6437     define_pretty_variable ($var, TRUE, $where, $value);
6438 }
6439
6440
6441 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
6442 # ------------------------------------------------------------
6443 # Define the $VAR which content is the list of file names composed of
6444 # a @BASENAME and the $EXTENSION.
6445 sub define_files_variable ($\@$$)
6446 {
6447   my ($var, $basename, $extension, $where) = @_;
6448   define_variable ($var,
6449                    join (' ', map { "$_.$extension" } @$basename),
6450                    $where);
6451 }
6452
6453
6454 # Like define_variable, but define a variable to be the configure
6455 # substitution by the same name.
6456 sub define_configure_variable ($)
6457 {
6458   my ($var) = @_;
6459   # Some variables we do not want to output.  For instance it
6460   # would be a bad idea to output `U = @U@` when `@U@` can be
6461   # substituted as `\`.
6462   my $pretty = exists $ignored_configure_vars{$var} ? VAR_SILENT : VAR_ASIS;
6463   Automake::Variable::define ($var, VAR_CONFIGURE, '', TRUE, subst $var,
6464                               '', $configure_vars{$var}, $pretty);
6465 }
6466
6467
6468 # define_compiler_variable ($LANG)
6469 # --------------------------------
6470 # Define a compiler variable.  We also handle defining the 'LT'
6471 # version of the command when using libtool.
6472 sub define_compiler_variable ($)
6473 {
6474     my ($lang) = @_;
6475
6476     my ($var, $value) = ($lang->compiler, $lang->compile);
6477     my $libtool_tag = '';
6478     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6479       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6480     &define_variable ($var, $value, INTERNAL);
6481     if (var ('LIBTOOL'))
6482       {
6483         my $verbose = define_verbose_libtool ();
6484         &define_variable ("LT$var",
6485                           "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6486                           . "\$(LIBTOOLFLAGS) --mode=compile $value",
6487                           INTERNAL);
6488       }
6489     define_verbose_tagvar ($lang->ccer || 'GEN');
6490 }
6491
6492
6493 # define_linker_variable ($LANG)
6494 # ------------------------------
6495 # Define linker variables.
6496 sub define_linker_variable ($)
6497 {
6498     my ($lang) = @_;
6499
6500     my $libtool_tag = '';
6501     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6502       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6503     # CCLD = $(CC).
6504     &define_variable ($lang->lder, $lang->ld, INTERNAL);
6505     # CCLINK = $(CCLD) blah blah...
6506     my $link = '';
6507     if (var ('LIBTOOL'))
6508       {
6509         my $verbose = define_verbose_libtool ();
6510         $link = "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6511                 . "\$(LIBTOOLFLAGS) --mode=link ";
6512       }
6513     &define_variable ($lang->linker, $link . $lang->link, INTERNAL);
6514     &define_variable ($lang->compiler,  $lang);
6515     &define_verbose_tagvar ($lang->lder || 'GEN');
6516 }
6517
6518 sub define_per_target_linker_variable ($$)
6519 {
6520   my ($linker, $target) = @_;
6521
6522   # If the user wrote a custom link command, we don't define ours.
6523   return "${target}_LINK"
6524     if set_seen "${target}_LINK";
6525
6526   my $xlink = $linker ? $linker : 'LINK';
6527
6528   my $lang = $link_languages{$xlink};
6529   prog_error "Unknown language for linker variable '$xlink'"
6530     unless $lang;
6531
6532   my $link_command = $lang->link;
6533   if (var 'LIBTOOL')
6534     {
6535       my $libtool_tag = '';
6536       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6537         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6538
6539       my $verbose = define_verbose_libtool ();
6540       $link_command =
6541         "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6542         . "--mode=link " . $link_command;
6543     }
6544
6545   # Rewrite each occurrence of 'AM_$flag' in the link
6546   # command into '${derived}_$flag' if it exists.
6547   my $orig_command = $link_command;
6548   my @flags = (@{$lang->flags}, 'LDFLAGS');
6549   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6550   for my $flag (@flags)
6551     {
6552       my $val = "${target}_$flag";
6553       $link_command =~ s/\(AM_$flag\)/\($val\)/
6554         if set_seen ($val);
6555     }
6556
6557   # If the computed command is the same as the generic command, use
6558   # the command linker variable.
6559   return ($lang->linker, $lang->lder)
6560     if $link_command eq $orig_command;
6561
6562   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6563   return ("${target}_LINK", $lang->lder);
6564 }
6565
6566 ################################################################
6567
6568 # &check_trailing_slash ($WHERE, $LINE)
6569 # -------------------------------------
6570 # Return 1 iff $LINE ends with a slash.
6571 # Might modify $LINE.
6572 sub check_trailing_slash ($\$)
6573 {
6574   my ($where, $line) = @_;
6575
6576   # Ignore '##' lines.
6577   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6578
6579   # Catch and fix a common error.
6580   msg "syntax", $where, "whitespace following trailing backslash"
6581     if $$line =~ s/\\\s+\n$/\\\n/;
6582
6583   return $$line =~ /\\$/;
6584 }
6585
6586
6587 # &read_am_file ($AMFILE, $WHERE)
6588 # -------------------------------
6589 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6590 # from Makefile.am into $output_trailer, or define variables as
6591 # appropriate.  NOTE we put rules in the trailer section.  We want
6592 # user rules to come after our generated stuff.
6593 sub read_am_file ($$)
6594 {
6595     my ($amfile, $where) = @_;
6596
6597     my $am_file = new Automake::XFile ("< $amfile");
6598     verb "reading $amfile";
6599
6600     # Keep track of the youngest output dependency.
6601     my $mtime = mtime $amfile;
6602     $output_deps_greatest_timestamp = $mtime
6603       if $mtime > $output_deps_greatest_timestamp;
6604
6605     my $spacing = '';
6606     my $comment = '';
6607     my $blank = 0;
6608     my $saw_bk = 0;
6609     my $var_look = VAR_ASIS;
6610
6611     use constant IN_VAR_DEF => 0;
6612     use constant IN_RULE_DEF => 1;
6613     use constant IN_COMMENT => 2;
6614     my $prev_state = IN_RULE_DEF;
6615
6616     while ($_ = $am_file->getline)
6617     {
6618         $where->set ("$amfile:$.");
6619         if (/$IGNORE_PATTERN/o)
6620         {
6621             # Merely delete comments beginning with two hashes.
6622         }
6623         elsif (/$WHITE_PATTERN/o)
6624         {
6625             error $where, "blank line following trailing backslash"
6626               if $saw_bk;
6627             # Stick a single white line before the incoming macro or rule.
6628             $spacing = "\n";
6629             $blank = 1;
6630             # Flush all comments seen so far.
6631             if ($comment ne '')
6632             {
6633                 $output_vars .= $comment;
6634                 $comment = '';
6635             }
6636         }
6637         elsif (/$COMMENT_PATTERN/o)
6638         {
6639             # Stick comments before the incoming macro or rule.  Make
6640             # sure a blank line precedes the first block of comments.
6641             $spacing = "\n" unless $blank;
6642             $blank = 1;
6643             $comment .= $spacing . $_;
6644             $spacing = '';
6645             $prev_state = IN_COMMENT;
6646         }
6647         else
6648         {
6649             last;
6650         }
6651         $saw_bk = check_trailing_slash ($where, $_);
6652     }
6653
6654     # We save the conditional stack on entry, and then check to make
6655     # sure it is the same on exit.  This lets us conditionally include
6656     # other files.
6657     my @saved_cond_stack = @cond_stack;
6658     my $cond = new Automake::Condition (@cond_stack);
6659
6660     my $last_var_name = '';
6661     my $last_var_type = '';
6662     my $last_var_value = '';
6663     my $last_where;
6664     # FIXME: shouldn't use $_ in this loop; it is too big.
6665     while ($_)
6666     {
6667         $where->set ("$amfile:$.");
6668
6669         # Make sure the line is \n-terminated.
6670         chomp;
6671         $_ .= "\n";
6672
6673         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6674         # used by users.  @MAINT@ is an anachronism now.
6675         $_ =~ s/\@MAINT\@//g
6676             unless $seen_maint_mode;
6677
6678         my $new_saw_bk = check_trailing_slash ($where, $_);
6679
6680         if (/$IGNORE_PATTERN/o)
6681         {
6682             # Merely delete comments beginning with two hashes.
6683
6684             # Keep any backslash from the previous line.
6685             $new_saw_bk = $saw_bk;
6686         }
6687         elsif (/$WHITE_PATTERN/o)
6688         {
6689             # Stick a single white line before the incoming macro or rule.
6690             $spacing = "\n";
6691             error $where, "blank line following trailing backslash"
6692               if $saw_bk;
6693         }
6694         elsif (/$COMMENT_PATTERN/o)
6695         {
6696             error $where, "comment following trailing backslash"
6697               if $saw_bk && $prev_state != IN_COMMENT;
6698
6699             # Stick comments before the incoming macro or rule.
6700             $comment .= $spacing . $_;
6701             $spacing = '';
6702             $prev_state = IN_COMMENT;
6703         }
6704         elsif ($saw_bk)
6705         {
6706             if ($prev_state == IN_RULE_DEF)
6707             {
6708               my $cond = new Automake::Condition @cond_stack;
6709               $output_trailer .= $cond->subst_string;
6710               $output_trailer .= $_;
6711             }
6712             elsif ($prev_state == IN_COMMENT)
6713             {
6714                 # If the line doesn't start with a '#', add it.
6715                 # We do this because a continued comment like
6716                 #   # A = foo \
6717                 #         bar \
6718                 #         baz
6719                 # is not portable.  BSD make doesn't honor
6720                 # escaped newlines in comments.
6721                 s/^#?/#/;
6722                 $comment .= $spacing . $_;
6723             }
6724             else # $prev_state == IN_VAR_DEF
6725             {
6726               $last_var_value .= ' '
6727                 unless $last_var_value =~ /\s$/;
6728               $last_var_value .= $_;
6729
6730               if (!/\\$/)
6731                 {
6732                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6733                                               $last_var_type, $cond,
6734                                               $last_var_value, $comment,
6735                                               $last_where, VAR_ASIS)
6736                     if $cond != FALSE;
6737                   $comment = $spacing = '';
6738                 }
6739             }
6740         }
6741
6742         elsif (/$IF_PATTERN/o)
6743           {
6744             $cond = cond_stack_if ($1, $2, $where);
6745           }
6746         elsif (/$ELSE_PATTERN/o)
6747           {
6748             $cond = cond_stack_else ($1, $2, $where);
6749           }
6750         elsif (/$ENDIF_PATTERN/o)
6751           {
6752             $cond = cond_stack_endif ($1, $2, $where);
6753           }
6754
6755         elsif (/$RULE_PATTERN/o)
6756         {
6757             # Found a rule.
6758             $prev_state = IN_RULE_DEF;
6759
6760             # For now we have to output all definitions of user rules
6761             # and can't diagnose duplicates (see the comment in
6762             # Automake::Rule::define). So we go on and ignore the return value.
6763             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6764
6765             check_variable_expansions ($_, $where);
6766
6767             $output_trailer .= $comment . $spacing;
6768             my $cond = new Automake::Condition @cond_stack;
6769             $output_trailer .= $cond->subst_string;
6770             $output_trailer .= $_;
6771             $comment = $spacing = '';
6772         }
6773         elsif (/$ASSIGNMENT_PATTERN/o)
6774         {
6775             # Found a macro definition.
6776             $prev_state = IN_VAR_DEF;
6777             $last_var_name = $1;
6778             $last_var_type = $2;
6779             $last_var_value = $3;
6780             $last_where = $where->clone;
6781             if ($3 ne '' && substr ($3, -1) eq "\\")
6782               {
6783                 # We preserve the '\' because otherwise the long lines
6784                 # that are generated will be truncated by broken
6785                 # 'sed's.
6786                 $last_var_value = $3 . "\n";
6787               }
6788             # Normally we try to output variable definitions in the
6789             # same format they were input.  However, POSIX compliant
6790             # systems are not required to support lines longer than
6791             # 2048 bytes (most notably, some sed implementation are
6792             # limited to 4000 bytes, and sed is used by config.status
6793             # to rewrite Makefile.in into Makefile).  Moreover nobody
6794             # would really write such long lines by hand since it is
6795             # hardly maintainable.  So if a line is longer that 1000
6796             # bytes (an arbitrary limit), assume it has been
6797             # automatically generated by some tools, and flatten the
6798             # variable definition.  Otherwise, keep the variable as it
6799             # as been input.
6800             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6801
6802             if (!/\\$/)
6803               {
6804                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6805                                             $last_var_type, $cond,
6806                                             $last_var_value, $comment,
6807                                             $last_where, $var_look)
6808                   if $cond != FALSE;
6809                 $comment = $spacing = '';
6810                 $var_look = VAR_ASIS;
6811               }
6812         }
6813         elsif (/$INCLUDE_PATTERN/o)
6814         {
6815             my $path = $1;
6816
6817             if ($path =~ s/^\$\(top_srcdir\)\///)
6818               {
6819                 push (@include_stack, "\$\(top_srcdir\)/$path");
6820                 # Distribute any included file.
6821
6822                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6823                 # otherwise OSF make will implicitly copy the included
6824                 # file in the build tree during "make distdir" to satisfy
6825                 # the dependency.
6826                 # (subdircond2.test and subdircond3.test will fail.)
6827                 push_dist_common ("\$\(top_srcdir\)/$path");
6828               }
6829             else
6830               {
6831                 $path =~ s/\$\(srcdir\)\///;
6832                 push (@include_stack, "\$\(srcdir\)/$path");
6833                 # Always use the $(srcdir) prefix in DIST_COMMON,
6834                 # otherwise OSF make will implicitly copy the included
6835                 # file in the build tree during "make distdir" to satisfy
6836                 # the dependency.
6837                 # (subdircond2.test and subdircond3.test will fail.)
6838                 push_dist_common ("\$\(srcdir\)/$path");
6839                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6840               }
6841             $where->push_context ("'$path' included from here");
6842             &read_am_file ($path, $where);
6843             $where->pop_context;
6844         }
6845         else
6846         {
6847             # This isn't an error; it is probably a continued rule.
6848             # In fact, this is what we assume.
6849             $prev_state = IN_RULE_DEF;
6850             check_variable_expansions ($_, $where);
6851             $output_trailer .= $comment . $spacing;
6852             my $cond = new Automake::Condition @cond_stack;
6853             $output_trailer .= $cond->subst_string;
6854             $output_trailer .= $_;
6855             $comment = $spacing = '';
6856             error $where, "'#' comment at start of rule is unportable"
6857               if $_ =~ /^\t\s*\#/;
6858         }
6859
6860         $saw_bk = $new_saw_bk;
6861         $_ = $am_file->getline;
6862     }
6863
6864     $output_trailer .= $comment;
6865
6866     error ($where, "trailing backslash on last line")
6867       if $saw_bk;
6868
6869     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6870                     : "too many conditionals closed in include file"))
6871       if "@saved_cond_stack" ne "@cond_stack";
6872 }
6873
6874
6875 # define_standard_variables ()
6876 # ----------------------------
6877 # A helper for read_main_am_file which initializes configure variables
6878 # and variables from header-vars.am.
6879 sub define_standard_variables
6880 {
6881   my $saved_output_vars = $output_vars;
6882   my ($comments, undef, $rules) =
6883     file_contents_internal (1, "$libdir/am/header-vars.am",
6884                             new Automake::Location);
6885
6886   foreach my $var (sort keys %configure_vars)
6887     {
6888       &define_configure_variable ($var);
6889     }
6890
6891   $output_vars .= $comments . $rules;
6892 }
6893
6894 # Read main am file.
6895 sub read_main_am_file
6896 {
6897     my ($amfile) = @_;
6898
6899     # This supports the strange variable tricks we are about to play.
6900     prog_error ("variable defined before read_main_am_file\n" . variables_dump ())
6901       if (scalar (variables) > 0);
6902
6903     # Generate copyright header for generated Makefile.in.
6904     # We do discard the output of predefined variables, handled below.
6905     $output_vars = ("# $in_file_name generated by automake "
6906                    . $VERSION . " from $am_file_name.\n");
6907     $output_vars .= '# ' . subst ('configure_input') . "\n";
6908     $output_vars .= $gen_copyright;
6909
6910     # We want to predefine as many variables as possible.  This lets
6911     # the user set them with '+=' in Makefile.am.
6912     &define_standard_variables;
6913
6914     # Read user file, which might override some of our values.
6915     &read_am_file ($amfile, new Automake::Location);
6916 }
6917
6918
6919
6920 ################################################################
6921
6922 # $FLATTENED
6923 # &flatten ($STRING)
6924 # ------------------
6925 # Flatten the $STRING and return the result.
6926 sub flatten
6927 {
6928   $_ = shift;
6929
6930   s/\\\n//somg;
6931   s/\s+/ /g;
6932   s/^ //;
6933   s/ $//;
6934
6935   return $_;
6936 }
6937
6938
6939 # transform_token ($TOKEN, \%PAIRS, $KEY)
6940 # =======================================
6941 # Return the value associated to $KEY in %PAIRS, as used on $TOKEN
6942 # (which should be ?KEY? or any of the special %% requests)..
6943 sub transform_token ($$$)
6944 {
6945   my ($token, $transform, $key) = @_;
6946   my $res = $transform->{$key};
6947   prog_error "Unknown key '$key' in '$token'" unless defined $res;
6948   return $res;
6949 }
6950
6951
6952 # transform ($TOKEN, \%PAIRS)
6953 # ===========================
6954 # If ($TOKEN, $VAL) is in %PAIRS:
6955 #   - replaces %KEY% with $VAL,
6956 #   - enables/disables ?KEY? and ?!KEY?,
6957 #   - replaces %?KEY% with TRUE or FALSE.
6958 #   - replaces %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE% with
6959 #     IFTRUE / IFFALSE, as appropriate.
6960 sub transform ($$)
6961 {
6962   my ($token, $transform) = @_;
6963
6964   # %KEY%.
6965   # Must be before the following pattern to exclude the case
6966   # when there is neither IFTRUE nor IFFALSE.
6967   if ($token =~ /^%([\w\-]+)%$/)
6968     {
6969       return transform_token ($token, $transform, $1);
6970     }
6971   # %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE%.
6972   elsif ($token =~ /^%([\w\-]+)(?:\?([^?:%]+))?(?::([^?:%]+))?%$/)
6973     {
6974       return transform_token ($token, $transform, $1) ? ($2 || '') : ($3 || '');
6975     }
6976   # %?KEY%.
6977   elsif ($token =~ /^%\?([\w\-]+)%$/)
6978     {
6979       return transform_token ($token, $transform, $1) ? 'TRUE' : 'FALSE';
6980     }
6981   # ?KEY? and ?!KEY?.
6982   elsif ($token =~ /^ \? (!?) ([\w\-]+) \? $/x)
6983     {
6984       my $neg = ($1 eq '!') ? 1 : 0;
6985       my $val = transform_token ($token, $transform, $2);
6986       return (!!$val == $neg) ? '##%' : '';
6987     }
6988   else
6989     {
6990       prog_error "Unknown request format: $token";
6991     }
6992 }
6993
6994 # $TEXT
6995 # preprocess_file ($MAKEFILE, [%TRANSFORM])
6996 # -----------------------------------------
6997 # Load a $MAKEFILE, apply the %TRANSFORM, and return the result.
6998 # No extra parsing of post-processing is done (i.e., recognition of
6999 # rules declaration or of make variables definitions).
7000 sub preprocess_file ($%)
7001 {
7002   my ($file, %transform) = @_;
7003
7004   # Complete %transform with global options.
7005   # Note that %transform goes last, so it overrides global options.
7006   %transform = ('CYGNUS'      => !! option 'cygnus',
7007                  'MAINTAINER-MODE'
7008                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
7009
7010                  'XZ'          => !! option 'dist-xz',
7011                  'LZMA'        => !! option 'dist-lzma',
7012                  'LZIP'        => !! option 'dist-lzip',
7013                  'BZIP2'       => !! option 'dist-bzip2',
7014                  'COMPRESS'    => !! option 'dist-tarZ',
7015                  'GZIP'        =>  ! option 'no-dist-gzip',
7016                  'SHAR'        => !! option 'dist-shar',
7017                  'ZIP'         => !! option 'dist-zip',
7018
7019                  'INSTALL-INFO' =>  ! option 'no-installinfo',
7020                  'INSTALL-MAN'  =>  ! option 'no-installman',
7021                  'HAVE-MANS'    => !! var ('MANS'),
7022                  'CK-NEWS'      => !! option 'check-news',
7023
7024                  'SUBDIRS'      => !! var ('SUBDIRS'),
7025                  'TOPDIR_P'     => $relative_dir eq '.',
7026
7027                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
7028                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
7029                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
7030
7031                  'LIBTOOL'      => !! var ('LIBTOOL'),
7032                  'NONLIBTOOL'   => 1,
7033                 %transform);
7034
7035   if (! defined ($_ = $am_file_cache{$file}))
7036     {
7037       verb "reading $file";
7038       # Swallow the whole file.
7039       my $fc_file = new Automake::XFile "< $file";
7040       my $saved_dollar_slash = $/;
7041       undef $/;
7042       $_ = $fc_file->getline;
7043       $/ = $saved_dollar_slash;
7044       $fc_file->close;
7045       # Remove ##-comments.
7046       # Besides we don't need more than two consecutive new-lines.
7047       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
7048       # Remember the contents of the just-read file.
7049       $am_file_cache{$file} = $_;
7050     }
7051
7052   # Substitute Automake template tokens.
7053   s/(?: % \?? [\w\-]+ %
7054       | % [\w\-]+ (?:\?[^?:%]+)? (?::[^?:%]+)? %
7055       | \? !? [\w\-]+ \?
7056     )/transform($&, \%transform)/gex;
7057   # transform() may have added some ##%-comments to strip.
7058   # (we use '##%' instead of '##' so we can distinguish ##%##%##% from
7059   # ####### and do not remove the latter.)
7060   s/^[ \t]*(?:##%)+.*\n//gm;
7061
7062   return $_;
7063 }
7064
7065
7066 # @PARAGRAPHS
7067 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
7068 # ------------------------------------------
7069 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
7070 # paragraphs.
7071 sub make_paragraphs ($%)
7072 {
7073   my ($file, %transform) = @_;
7074   $transform{FIRST} = !$transformed_files{$file};
7075   $transformed_files{$file} = 1;
7076
7077   my @lines = split /(?<!\\)\n/, preprocess_file ($file, %transform);
7078   my @res;
7079
7080   while (defined ($_ = shift @lines))
7081     {
7082       my $paragraph = $_;
7083       # If we are a rule, eat as long as we start with a tab.
7084       if (/$RULE_PATTERN/smo)
7085         {
7086           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
7087             {
7088               $paragraph .= "\n$_";
7089             }
7090           unshift (@lines, $_);
7091         }
7092
7093       # If we are a comments, eat as much comments as you can.
7094       elsif (/$COMMENT_PATTERN/smo)
7095         {
7096           while (defined ($_ = shift @lines)
7097                  && $_ =~ /$COMMENT_PATTERN/smo)
7098             {
7099               $paragraph .= "\n$_";
7100             }
7101           unshift (@lines, $_);
7102         }
7103
7104       push @res, $paragraph;
7105     }
7106
7107   return @res;
7108 }
7109
7110
7111
7112 # ($COMMENT, $VARIABLES, $RULES)
7113 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
7114 # -------------------------------------------------------------
7115 # Return contents of a file from $libdir/am, automatically skipping
7116 # macros or rules which are already known. $IS_AM iff the caller is
7117 # reading an Automake file (as opposed to the user's Makefile.am).
7118 sub file_contents_internal ($$$%)
7119 {
7120     my ($is_am, $file, $where, %transform) = @_;
7121
7122     $where->set ($file);
7123
7124     my $result_vars = '';
7125     my $result_rules = '';
7126     my $comment = '';
7127     my $spacing = '';
7128
7129     # The following flags are used to track rules spanning across
7130     # multiple paragraphs.
7131     my $is_rule = 0;            # 1 if we are processing a rule.
7132     my $discard_rule = 0;       # 1 if the current rule should not be output.
7133
7134     # We save the conditional stack on entry, and then check to make
7135     # sure it is the same on exit.  This lets us conditionally include
7136     # other files.
7137     my @saved_cond_stack = @cond_stack;
7138     my $cond = new Automake::Condition (@cond_stack);
7139
7140     foreach (make_paragraphs ($file, %transform))
7141     {
7142         # FIXME: no line number available.
7143         $where->set ($file);
7144
7145         # Sanity checks.
7146         error $where, "blank line following trailing backslash:\n$_"
7147           if /\\$/;
7148         error $where, "comment following trailing backslash:\n$_"
7149           if /\\#/;
7150
7151         if (/^$/)
7152         {
7153             $is_rule = 0;
7154             # Stick empty line before the incoming macro or rule.
7155             $spacing = "\n";
7156         }
7157         elsif (/$COMMENT_PATTERN/mso)
7158         {
7159             $is_rule = 0;
7160             # Stick comments before the incoming macro or rule.
7161             $comment = "$_\n";
7162         }
7163
7164         # Handle inclusion of other files.
7165         elsif (/$INCLUDE_PATTERN/o)
7166         {
7167             if ($cond != FALSE)
7168               {
7169                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
7170                 $where->push_context ("'$file' included from here");
7171                 # N-ary '.=' fails.
7172                 my ($com, $vars, $rules)
7173                   = file_contents_internal ($is_am, $file, $where, %transform);
7174                 $where->pop_context;
7175                 $comment .= $com;
7176                 $result_vars .= $vars;
7177                 $result_rules .= $rules;
7178               }
7179         }
7180
7181         # Handling the conditionals.
7182         elsif (/$IF_PATTERN/o)
7183           {
7184             $cond = cond_stack_if ($1, $2, $file);
7185           }
7186         elsif (/$ELSE_PATTERN/o)
7187           {
7188             $cond = cond_stack_else ($1, $2, $file);
7189           }
7190         elsif (/$ENDIF_PATTERN/o)
7191           {
7192             $cond = cond_stack_endif ($1, $2, $file);
7193           }
7194
7195         # Handling rules.
7196         elsif (/$RULE_PATTERN/mso)
7197         {
7198           $is_rule = 1;
7199           $discard_rule = 0;
7200           # Separate relationship from optional actions: the first
7201           # `new-line tab" not preceded by backslash (continuation
7202           # line).
7203           my $paragraph = $_;
7204           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
7205           my ($relationship, $actions) = ($1, $2 || '');
7206
7207           # Separate targets from dependencies: the first colon.
7208           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
7209           my ($targets, $dependencies) = ($1, $2);
7210           # Remove the escaped new lines.
7211           # I don't know why, but I have to use a tmp $flat_deps.
7212           my $flat_deps = &flatten ($dependencies);
7213           my @deps = split (' ', $flat_deps);
7214
7215           foreach (split (' ', $targets))
7216             {
7217               # FIXME: 1. We are not robust to people defining several targets
7218               # at once, only some of them being in %dependencies.  The
7219               # actions from the targets in %dependencies are usually generated
7220               # from the content of %actions, but if some targets in $targets
7221               # are not in %dependencies the ELSE branch will output
7222               # a rule for all $targets (i.e. the targets which are both
7223               # in %dependencies and $targets will have two rules).
7224
7225               # FIXME: 2. The logic here is not able to output a
7226               # multi-paragraph rule several time (e.g. for each condition
7227               # it is defined for) because it only knows the first paragraph.
7228
7229               # FIXME: 3. We are not robust to people defining a subset
7230               # of a previously defined "multiple-target" rule.  E.g.
7231               # 'foo:' after 'foo bar:'.
7232
7233               # Output only if not in FALSE.
7234               if (defined $dependencies{$_} && $cond != FALSE)
7235                 {
7236                   &depend ($_, @deps);
7237                   register_action ($_, $actions);
7238                 }
7239               else
7240                 {
7241                   # Free-lance dependency.  Output the rule for all the
7242                   # targets instead of one by one.
7243                   my @undefined_conds =
7244                     Automake::Rule::define ($targets, $file,
7245                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
7246                                             $cond, $where);
7247                   for my $undefined_cond (@undefined_conds)
7248                     {
7249                       my $condparagraph = $paragraph;
7250                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
7251                       $result_rules .= "$spacing$comment$condparagraph\n";
7252                     }
7253                   if (scalar @undefined_conds == 0)
7254                     {
7255                       # Remember to discard next paragraphs
7256                       # if they belong to this rule.
7257                       # (but see also FIXME: #2 above.)
7258                       $discard_rule = 1;
7259                     }
7260                   $comment = $spacing = '';
7261                   last;
7262                 }
7263             }
7264         }
7265
7266         elsif (/$ASSIGNMENT_PATTERN/mso)
7267         {
7268             my ($var, $type, $val) = ($1, $2, $3);
7269             error $where, "variable '$var' with trailing backslash"
7270               if /\\$/;
7271
7272             $is_rule = 0;
7273
7274             Automake::Variable::define ($var,
7275                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
7276                                         $type, $cond, $val, $comment, $where,
7277                                         VAR_ASIS)
7278               if $cond != FALSE;
7279
7280             $comment = $spacing = '';
7281         }
7282         else
7283         {
7284             # This isn't an error; it is probably some tokens which
7285             # configure is supposed to replace, such as '@SET-MAKE@',
7286             # or some part of a rule cut by an if/endif.
7287             if (! $cond->false && ! ($is_rule && $discard_rule))
7288               {
7289                 s/^/$cond->subst_string/gme;
7290                 $result_rules .= "$spacing$comment$_\n";
7291               }
7292             $comment = $spacing = '';
7293         }
7294     }
7295
7296     error ($where, @cond_stack ?
7297            "unterminated conditionals: @cond_stack" :
7298            "too many conditionals closed in include file")
7299       if "@saved_cond_stack" ne "@cond_stack";
7300
7301     return ($comment, $result_vars, $result_rules);
7302 }
7303
7304
7305 # $CONTENTS
7306 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
7307 # ------------------------------------------------
7308 # Return contents of a file from $libdir/am, automatically skipping
7309 # macros or rules which are already known.
7310 sub file_contents ($$%)
7311 {
7312     my ($basename, $where, %transform) = @_;
7313     my ($comments, $variables, $rules) =
7314       file_contents_internal (1, "$libdir/am/$basename.am", $where,
7315                               %transform);
7316     return "$comments$variables$rules";
7317 }
7318
7319
7320 # @PREFIX
7321 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
7322 # -----------------------------------------------------
7323 # Find all variable prefixes that are used for install directories.  A
7324 # prefix 'zar' qualifies iff:
7325 #
7326 # * 'zardir' is a variable.
7327 # * 'zar_PRIMARY' is a variable.
7328 #
7329 # As a side effect, it looks for misspellings.  It is an error to have
7330 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
7331 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
7332 # of the same name (with "dir" appended) exists.  For instance, if the
7333 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
7334 # This is to provide a little extra flexibility in those cases which
7335 # need it.
7336 sub am_primary_prefixes ($$@)
7337 {
7338   my ($primary, $can_dist, @prefixes) = @_;
7339
7340   local $_;
7341   my %valid = map { $_ => 0 } @prefixes;
7342   $valid{'EXTRA'} = 0;
7343   foreach my $var (variables $primary)
7344     {
7345       # Automake is allowed to define variables that look like primaries
7346       # but which aren't.  E.g. INSTALL_sh_DATA.
7347       # Autoconf can also define variables like INSTALL_DATA, so
7348       # ignore all configure variables (at least those which are not
7349       # redefined in Makefile.am).
7350       # FIXME: We should make sure that these variables are not
7351       # conditionally defined (or else adjust the condition below).
7352       my $def = $var->def (TRUE);
7353       next if $def && $def->owner != VAR_MAKEFILE;
7354
7355       my $varname = $var->name;
7356
7357       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
7358         {
7359           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
7360           if ($dist ne '' && ! $can_dist)
7361             {
7362               err_var ($var,
7363                        "invalid variable '$varname': 'dist' is forbidden");
7364             }
7365           # Standard directories must be explicitly allowed.
7366           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
7367             {
7368               err_var ($var,
7369                        "'${X}dir' is not a legitimate directory " .
7370                        "for '$primary'");
7371             }
7372           # A not explicitly valid directory is allowed if Xdir is defined.
7373           elsif (! defined $valid{$X} &&
7374                  $var->requires_variables ("'$varname' is used", "${X}dir"))
7375             {
7376               # Nothing to do.  Any error message has been output
7377               # by $var->requires_variables.
7378             }
7379           else
7380             {
7381               # Ensure all extended prefixes are actually used.
7382               $valid{"$base$dist$X"} = 1;
7383             }
7384         }
7385       else
7386         {
7387           prog_error "unexpected variable name: $varname";
7388         }
7389     }
7390
7391   # Return only those which are actually defined.
7392   return sort grep { var ($_ . '_' . $primary) } keys %valid;
7393 }
7394
7395
7396 # Handle 'where_HOW' variable magic.  Does all lookups, generates
7397 # install code, and possibly generates code to define the primary
7398 # variable.  The first argument is the name of the .am file to munge,
7399 # the second argument is the primary variable (e.g. HEADERS), and all
7400 # subsequent arguments are possible installation locations.
7401 #
7402 # Returns list of [$location, $value] pairs, where
7403 # $value's are the values in all where_HOW variable, and $location
7404 # there associated location (the place here their parent variables were
7405 # defined).
7406 #
7407 # FIXME: this should be rewritten to be cleaner.  It should be broken
7408 # up into multiple functions.
7409 #
7410 # Usage is: am_install_var (OPTION..., file, HOW, where...)
7411 sub am_install_var
7412 {
7413   my (@args) = @_;
7414
7415   my $do_require = 1;
7416   my $can_dist = 0;
7417   my $default_dist = 0;
7418   while (@args)
7419     {
7420       if ($args[0] eq '-noextra')
7421         {
7422           $do_require = 0;
7423         }
7424       elsif ($args[0] eq '-candist')
7425         {
7426           $can_dist = 1;
7427         }
7428       elsif ($args[0] eq '-defaultdist')
7429         {
7430           $default_dist = 1;
7431           $can_dist = 1;
7432         }
7433       elsif ($args[0] !~ /^-/)
7434         {
7435           last;
7436         }
7437       shift (@args);
7438     }
7439
7440   my ($file, $primary, @prefix) = @args;
7441
7442   # Now that configure substitutions are allowed in where_HOW
7443   # variables, it is an error to actually define the primary.  We
7444   # allow 'JAVA', as it is customarily used to mean the Java
7445   # interpreter.  This is but one of several Java hacks.  Similarly,
7446   # 'PYTHON' is customarily used to mean the Python interpreter.
7447   reject_var $primary, "'$primary' is an anachronism"
7448     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
7449
7450   # Get the prefixes which are valid and actually used.
7451   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
7452
7453   # If a primary includes a configure substitution, then the EXTRA_
7454   # form is required.  Otherwise we can't properly do our job.
7455   my $require_extra;
7456
7457   my @used = ();
7458   my @result = ();
7459
7460   foreach my $X (@prefix)
7461     {
7462       my $nodir_name = $X;
7463       my $one_name = $X . '_' . $primary;
7464       my $one_var = var $one_name;
7465
7466       my $strip_subdir = 1;
7467       # If subdir prefix should be preserved, do so.
7468       if ($nodir_name =~ /^nobase_/)
7469         {
7470           $strip_subdir = 0;
7471           $nodir_name =~ s/^nobase_//;
7472         }
7473
7474       # If files should be distributed, do so.
7475       my $dist_p = 0;
7476       if ($can_dist)
7477         {
7478           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
7479                      || (! $default_dist && $nodir_name =~ /^dist_/));
7480           $nodir_name =~ s/^(dist|nodist)_//;
7481         }
7482
7483
7484       # Use the location of the currently processed variable.
7485       # We are not processing a particular condition, so pick the first
7486       # available.
7487       my $tmpcond = $one_var->conditions->one_cond;
7488       my $where = $one_var->rdef ($tmpcond)->location->clone;
7489
7490       # Append actual contents of where_PRIMARY variable to
7491       # @result, skipping @substitutions@.
7492       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
7493         {
7494           my ($loc, $value) = @$locvals;
7495           # Skip configure substitutions.
7496           if ($value =~ /^\@.*\@$/)
7497             {
7498               if ($nodir_name eq 'EXTRA')
7499                 {
7500                   error ($where,
7501                          "'$one_name' contains configure substitution, "
7502                          . "but shouldn't");
7503                 }
7504               # Check here to make sure variables defined in
7505               # configure.ac do not imply that EXTRA_PRIMARY
7506               # must be defined.
7507               elsif (! defined $configure_vars{$one_name})
7508                 {
7509                   $require_extra = $one_name
7510                     if $do_require;
7511                 }
7512             }
7513           else
7514             {
7515               # Strip any $(EXEEXT) suffix the user might have added, or this
7516               # will confuse &handle_source_transform and &check_canonical_spelling.
7517               # We'll add $(EXEEXT) back later anyway.
7518               # Do it here rather than in handle_programs so the uniquifying at the
7519               # end of this function works.
7520               ${$locvals}[1] =~ s/\$\(EXEEXT\)$//
7521                 if $primary eq 'PROGRAMS';
7522
7523               push (@result, $locvals);
7524             }
7525         }
7526       # A blatant hack: we rewrite each _PROGRAMS primary to include
7527       # EXEEXT.
7528       append_exeext { 1 } $one_name
7529         if $primary eq 'PROGRAMS';
7530       # "EXTRA" shouldn't be used when generating clean targets,
7531       # all, or install targets.  We used to warn if EXTRA_FOO was
7532       # defined uselessly, but this was annoying.
7533       next
7534         if $nodir_name eq 'EXTRA';
7535
7536       if ($nodir_name eq 'check')
7537         {
7538           push (@check, '$(' . $one_name . ')');
7539         }
7540       else
7541         {
7542           push (@used, '$(' . $one_name . ')');
7543         }
7544
7545       # Is this to be installed?
7546       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
7547
7548       # If so, with install-exec? (or install-data?).
7549       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
7550
7551       my $check_options_p = $install_p && !! option 'std-options';
7552
7553       # Use the location of the currently processed variable as context.
7554       $where->push_context ("while processing '$one_name'");
7555
7556       # The variable containing all files to distribute.
7557       my $distvar = "\$($one_name)";
7558       $distvar = shadow_unconditionally ($one_name, $where)
7559         if ($dist_p && $one_var->has_conditional_contents);
7560
7561       # Singular form of $PRIMARY.
7562       (my $one_primary = $primary) =~ s/S$//;
7563       $output_rules .= &file_contents ($file, $where,
7564                                        PRIMARY     => $primary,
7565                                        ONE_PRIMARY => $one_primary,
7566                                        DIR         => $X,
7567                                        NDIR        => $nodir_name,
7568                                        BASE        => $strip_subdir,
7569
7570                                        EXEC      => $exec_p,
7571                                        INSTALL   => $install_p,
7572                                        DIST      => $dist_p,
7573                                        DISTVAR   => $distvar,
7574                                        'CK-OPTS' => $check_options_p);
7575     }
7576
7577   # The JAVA variable is used as the name of the Java interpreter.
7578   # The PYTHON variable is used as the name of the Python interpreter.
7579   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7580     {
7581       # Define it.
7582       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7583       $output_vars .= "\n";
7584     }
7585
7586   err_var ($require_extra,
7587            "'$require_extra' contains configure substitution,\n"
7588            . "but 'EXTRA_$primary' not defined")
7589     if ($require_extra && ! var ('EXTRA_' . $primary));
7590
7591   # Push here because PRIMARY might be configure time determined.
7592   push (@all, '$(' . $primary . ')')
7593     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7594
7595   # Make the result unique.  This lets the user use conditionals in
7596   # a natural way, but still lets us program lazily -- we don't have
7597   # to worry about handling a particular object more than once.
7598   # We will keep only one location per object.
7599   my %result = ();
7600   for my $pair (@result)
7601     {
7602       my ($loc, $val) = @$pair;
7603       $result{$val} = $loc;
7604     }
7605   my @l = sort keys %result;
7606   return map { [$result{$_}->clone, $_] } @l;
7607 }
7608
7609
7610 ################################################################
7611
7612 # Each key in this hash is the name of a directory holding a
7613 # Makefile.in.  These variables are local to 'is_make_dir'.
7614 my %make_dirs = ();
7615 my $make_dirs_set = 0;
7616
7617 sub is_make_dir
7618 {
7619     my ($dir) = @_;
7620     if (! $make_dirs_set)
7621     {
7622         foreach my $iter (@configure_input_files)
7623         {
7624             $make_dirs{dirname ($iter)} = 1;
7625         }
7626         # We also want to notice Makefile.in's.
7627         foreach my $iter (@other_input_files)
7628         {
7629             if ($iter =~ /Makefile\.in$/)
7630             {
7631                 $make_dirs{dirname ($iter)} = 1;
7632             }
7633         }
7634         $make_dirs_set = 1;
7635     }
7636     return defined $make_dirs{$dir};
7637 }
7638
7639 ################################################################
7640
7641 # Find the aux dir.  This should match the algorithm used by
7642 # ./configure. (See the Autoconf documentation for for
7643 # AC_CONFIG_AUX_DIR.)
7644 sub locate_aux_dir ()
7645 {
7646   if (! $config_aux_dir_set_in_configure_ac)
7647     {
7648       # The default auxiliary directory is the first
7649       # of ., .., or ../.. that contains install-sh.
7650       # Assume . if install-sh doesn't exist yet.
7651       for my $dir (qw (. .. ../..))
7652         {
7653           if (-f "$dir/install-sh")
7654             {
7655               $config_aux_dir = $dir;
7656               last;
7657             }
7658         }
7659       $config_aux_dir = '.' unless $config_aux_dir;
7660     }
7661   # Avoid unsightly '/.'s.
7662   $am_config_aux_dir =
7663     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7664   $am_config_aux_dir =~ s,/*$,,;
7665 }
7666
7667
7668 # &push_required_file ($DIR, $FILE, $FULLFILE)
7669 # --------------------------------------------------
7670 # Push the given file onto DIST_COMMON.
7671 sub push_required_file
7672 {
7673   my ($dir, $file, $fullfile) = @_;
7674
7675   # If the file to be distributed is in the same directory of the
7676   # currently processed Makefile.am, then we want to distribute it
7677   # from this same Makefile.am.
7678   if ($dir eq $relative_dir)
7679     {
7680       push_dist_common ($file);
7681     }
7682   # This is needed to allow a construct in a non-top-level Makefile.am
7683   # to require a file in the build-aux directory (see at least the test
7684   # script 'test-driver-is-distributed.test').  This is related to the
7685   # automake bug#9546.  Note that the use of $config_aux_dir instead
7686   # of $am_config_aux_dir here is deliberate and necessary.
7687   elsif ($dir eq $config_aux_dir)
7688     {
7689       push_dist_common ("$am_config_aux_dir/$file");
7690     }
7691   # FIXME: another spacial case, for AC_LIBOBJ/AC_LIBSOURCE support.
7692   # We probably need some refactoring of this function and its callers,
7693   # to have a more explicit and systematic handling of all the special
7694   # cases; but, since there are only two of them, this is low-priority
7695   # ATM.
7696   elsif ($config_libobj_dir && $dir eq $config_libobj_dir)
7697     {
7698       # Avoid unsightly '/.'s.
7699       my $am_config_libobj_dir =
7700         '$(top_srcdir)' .
7701         ($config_libobj_dir eq '.' ? "" : "/$config_libobj_dir");
7702       $am_config_libobj_dir =~ s|/*$||;
7703       push_dist_common ("$am_config_libobj_dir/$file");
7704     }
7705   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7706     {
7707       # If we are doing the topmost directory, and the file is in a
7708       # subdir which does not have a Makefile, then we distribute it
7709       # here.
7710
7711       # If a required file is above the source tree, it is important
7712       # to prefix it with '$(srcdir)' so that no VPATH search is
7713       # performed.  Otherwise problems occur with Make implementations
7714       # that rewrite and simplify rules whose dependencies are found in a
7715       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7716       #
7717       #   % cat Makefile
7718       #   VPATH = sub
7719       #   distdir: ../a
7720       #           echo ../a
7721       #   % ls
7722       #   Makefile a
7723       #   % make
7724       #   echo a
7725       #   a
7726       #
7727       # Dependency '../a' was found in 'sub/../a', but this make
7728       # implementation simplified it as 'a'.  (Note that the sub/
7729       # directory does not even exist.)
7730       #
7731       # This kind of VPATH rewriting seems hard to cancel.  The
7732       # distdir.am hack against VPATH rewriting works only when no
7733       # simplification is done, i.e., for dependencies which are in
7734       # subdirectories, not in enclosing directories.  Hence, in
7735       # the latter case we use a full path to make sure no VPATH
7736       # search occurs.
7737       $fullfile = '$(srcdir)/' . $fullfile
7738         if $dir =~ m,^\.\.(?:$|/),;
7739
7740       push_dist_common ($fullfile);
7741     }
7742   else
7743     {
7744       prog_error "a Makefile in relative directory $relative_dir " .
7745                  "can't add files in directory $dir to DIST_COMMON";
7746     }
7747 }
7748
7749
7750 # If a file name appears as a key in this hash, then it has already
7751 # been checked for.  This allows us not to report the same error more
7752 # than once.
7753 my %required_file_not_found = ();
7754
7755 # &required_file_check_or_copy ($WHERE, $DIRECTORY, $FILE)
7756 # --------------------------------------------------------
7757 # Verify that the file must exist in $DIRECTORY, or install it.
7758 sub required_file_check_or_copy ($$$)
7759 {
7760   my ($where, $dir, $file) = @_;
7761
7762   my $fullfile = "$dir/$file";
7763   my $found_it = 0;
7764   my $dangling_sym = 0;
7765
7766   if (-l $fullfile && ! -f $fullfile)
7767     {
7768       $dangling_sym = 1;
7769     }
7770   elsif (dir_has_case_matching_file ($dir, $file))
7771     {
7772       $found_it = 1;
7773     }
7774
7775   # '--force-missing' only has an effect if '--add-missing' is
7776   # specified.
7777   return
7778     if $found_it && (! $add_missing || ! $force_missing);
7779
7780   # If we've already looked for it, we're done.  You might
7781   # wonder why we don't do this before searching for the
7782   # file.  If we do that, then something like
7783   # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7784   # DIST_COMMON.
7785   if (! $found_it)
7786     {
7787       return if defined $required_file_not_found{$fullfile};
7788       $required_file_not_found{$fullfile} = 1;
7789     }
7790   if ($dangling_sym && $add_missing)
7791     {
7792       unlink ($fullfile);
7793     }
7794
7795   my $trailer = '';
7796   my $trailer2 = '';
7797   my $suppress = 0;
7798
7799   # Only install missing files according to our desired
7800   # strictness level.
7801   my $message = "required file '$fullfile' not found";
7802   if ($add_missing)
7803     {
7804       if (-f "$libdir/$file")
7805         {
7806           $suppress = 1;
7807
7808           # Install the missing file.  Symlink if we
7809           # can, copy if we must.  Note: delete the file
7810           # first, in case it is a dangling symlink.
7811           $message = "installing '$fullfile'";
7812
7813           # The license file should not be volatile.
7814           if ($file eq "COPYING")
7815             {
7816               $message .= " using GNU General Public License v3 file";
7817               $trailer2 = "\n    Consider adding the COPYING file"
7818                         . " to the version control system"
7819                         . "\n    for your code, to avoid questions"
7820                         . " about which license your project uses";
7821             }
7822
7823           # Windows Perl will hang if we try to delete a
7824           # file that doesn't exist.
7825           unlink ($fullfile) if -f $fullfile;
7826           if ($symlink_exists && ! $copy_missing)
7827             {
7828               if (! symlink ("$libdir/$file", $fullfile)
7829                   || ! -e $fullfile)
7830                 {
7831                   $suppress = 0;
7832                   $trailer = "; error while making link: $!";
7833                 }
7834             }
7835           elsif (system ('cp', "$libdir/$file", $fullfile))
7836             {
7837               $suppress = 0;
7838               $trailer = "\n    error while copying";
7839             }
7840           set_dir_cache_file ($dir, $file);
7841         }
7842     }
7843   else
7844     {
7845       $trailer = "\n  'automake --add-missing' can install '$file'"
7846         if -f "$libdir/$file";
7847     }
7848
7849   # If --force-missing was specified, and we have
7850   # actually found the file, then do nothing.
7851   return
7852     if $found_it && $force_missing;
7853
7854   # If we couldn't install the file, but it is a target in
7855   # the Makefile, don't print anything.  This allows files
7856   # like README, AUTHORS, or THANKS to be generated.
7857   return
7858     if !$suppress && rule $file;
7859
7860   msg ($suppress ? 'note' : 'error', $where, "$message$trailer$trailer2");
7861 }
7862
7863
7864 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, $QUEUE, @FILES)
7865 # ----------------------------------------------------------------------
7866 # Verify that the file must exist in $DIRECTORY, or install it.
7867 # $MYSTRICT is the strictness level at which this file becomes required.
7868 # Worker threads may queue up the action to be serialized by the master,
7869 # if $QUEUE is true
7870 sub require_file_internal ($$$@)
7871 {
7872   my ($where, $mystrict, $dir, $queue, @files) = @_;
7873
7874   return
7875     unless $strictness >= $mystrict;
7876
7877   foreach my $file (@files)
7878     {
7879       push_required_file ($dir, $file, "$dir/$file");
7880       if ($queue)
7881         {
7882           queue_required_file_check_or_copy ($required_conf_file_queue,
7883                                              QUEUE_CONF_FILE, $relative_dir,
7884                                              $where, $mystrict, @files);
7885         }
7886       else
7887         {
7888           required_file_check_or_copy ($where, $dir, $file);
7889         }
7890     }
7891 }
7892
7893 # &require_file ($WHERE, $MYSTRICT, @FILES)
7894 # -----------------------------------------
7895 sub require_file ($$@)
7896 {
7897     my ($where, $mystrict, @files) = @_;
7898     require_file_internal ($where, $mystrict, $relative_dir, 0, @files);
7899 }
7900
7901 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7902 # -----------------------------------------------------------
7903 sub require_file_with_macro ($$$@)
7904 {
7905     my ($cond, $macro, $mystrict, @files) = @_;
7906     $macro = rvar ($macro) unless ref $macro;
7907     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7908 }
7909
7910 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7911 # ----------------------------------------------------------------
7912 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7913 # must be in that directory.  Otherwise expect it in the current directory.
7914 sub require_libsource_with_macro ($$$@)
7915 {
7916     my ($cond, $macro, $mystrict, @files) = @_;
7917     $macro = rvar ($macro) unless ref $macro;
7918     if ($config_libobj_dir)
7919       {
7920         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7921                                $config_libobj_dir, 0, @files);
7922       }
7923     else
7924       {
7925         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7926       }
7927 }
7928
7929 # &queue_required_file_check_or_copy ($QUEUE, $KEY, $DIR, $WHERE,
7930 #                                     $MYSTRICT, @FILES)
7931 # ---------------------------------------------------------------
7932 sub queue_required_file_check_or_copy ($$$$@)
7933 {
7934     my ($queue, $key, $dir, $where, $mystrict, @files) = @_;
7935     my @serial_loc;
7936     if (ref $where)
7937       {
7938         @serial_loc = (QUEUE_LOCATION, $where->serialize ());
7939       }
7940     else
7941       {
7942         @serial_loc = (QUEUE_STRING, $where);
7943       }
7944     $queue->enqueue ($key, $dir, @serial_loc, $mystrict, 0 + @files, @files);
7945 }
7946
7947 # &require_queued_file_check_or_copy ($QUEUE)
7948 # -------------------------------------------
7949 sub require_queued_file_check_or_copy ($)
7950 {
7951     my ($queue) = @_;
7952     my $where;
7953     my $dir = $queue->dequeue ();
7954     my $loc_key = $queue->dequeue ();
7955     if ($loc_key eq QUEUE_LOCATION)
7956       {
7957         $where = Automake::Location::deserialize ($queue);
7958       }
7959     elsif ($loc_key eq QUEUE_STRING)
7960       {
7961         $where = $queue->dequeue ();
7962       }
7963     else
7964       {
7965         prog_error "unexpected key $loc_key";
7966       }
7967     my $mystrict = $queue->dequeue ();
7968     my $nfiles = $queue->dequeue ();
7969     my @files;
7970     push @files, $queue->dequeue ()
7971       foreach (1 .. $nfiles);
7972     return
7973       unless $strictness >= $mystrict;
7974     foreach my $file (@files)
7975       {
7976         required_file_check_or_copy ($where, $config_aux_dir, $file);
7977       }
7978 }
7979
7980 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7981 # ----------------------------------------------
7982 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7983 sub require_conf_file ($$@)
7984 {
7985     my ($where, $mystrict, @files) = @_;
7986     my $queue = defined $required_conf_file_queue ? 1 : 0;
7987     require_file_internal ($where, $mystrict, $config_aux_dir,
7988                            $queue, @files);
7989 }
7990
7991
7992 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7993 # ----------------------------------------------------------------
7994 sub require_conf_file_with_macro ($$$@)
7995 {
7996     my ($cond, $macro, $mystrict, @files) = @_;
7997     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7998                        $mystrict, @files);
7999 }
8000
8001 ################################################################
8002
8003 # &require_build_directory ($DIRECTORY)
8004 # -------------------------------------
8005 # Emit rules to create $DIRECTORY if needed, and return
8006 # the file that any target requiring this directory should be made
8007 # dependent upon.
8008 # We don't want to emit the rule twice, and want to reuse it
8009 # for directories with equivalent names (e.g., 'foo/bar' and './foo//bar').
8010 sub require_build_directory ($)
8011 {
8012   my $directory = shift;
8013
8014   return $directory_map{$directory} if exists $directory_map{$directory};
8015
8016   my $cdir = File::Spec->canonpath ($directory);
8017
8018   if (exists $directory_map{$cdir})
8019     {
8020       my $stamp = $directory_map{$cdir};
8021       $directory_map{$directory} = $stamp;
8022       return $stamp;
8023     }
8024
8025   my $dirstamp = "$cdir/\$(am__dirstamp)";
8026
8027   $directory_map{$directory} = $dirstamp;
8028   $directory_map{$cdir} = $dirstamp;
8029
8030   # Set a variable for the dirstamp basename.
8031   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
8032                           '$(am__leading_dot)dirstamp');
8033
8034   # Directory must be removed by 'make distclean'.
8035   $clean_files{$dirstamp} = DIST_CLEAN;
8036
8037   $output_rules .= ("$dirstamp:\n"
8038                     . "\t\@\$(MKDIR_P) $directory\n"
8039                     . "\t\@: > $dirstamp\n");
8040
8041   return $dirstamp;
8042 }
8043
8044 # &require_build_directory_maybe ($FILE)
8045 # --------------------------------------
8046 # If $FILE lies in a subdirectory, emit a rule to create this
8047 # directory and return the file that $FILE should be made
8048 # dependent upon.  Otherwise, just return the empty string.
8049 sub require_build_directory_maybe ($)
8050 {
8051     my $file = shift;
8052     my $directory = dirname ($file);
8053
8054     if ($directory ne '.')
8055     {
8056         return require_build_directory ($directory);
8057     }
8058     else
8059     {
8060         return '';
8061     }
8062 }
8063
8064 ################################################################
8065
8066 # Push a list of files onto dist_common.
8067 sub push_dist_common
8068 {
8069   prog_error "push_dist_common run after handle_dist"
8070     if $handle_dist_run;
8071   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
8072                               '', INTERNAL, VAR_PRETTY);
8073 }
8074
8075
8076 ################################################################
8077
8078 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
8079 # ----------------------------------------------
8080 # Generate a Makefile.in given the name of the corresponding Makefile and
8081 # the name of the file output by config.status.
8082 sub generate_makefile ($$)
8083 {
8084   my ($makefile_am, $makefile_in) = @_;
8085
8086   # Reset all the Makefile.am related variables.
8087   initialize_per_input;
8088
8089   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
8090   # warnings for this file.  So hold any warning issued before
8091   # we have processed AUTOMAKE_OPTIONS.
8092   buffer_messages ('warning');
8093
8094   # Name of input file ("Makefile.am") and output file
8095   # ("Makefile.in").  These have no directory components.
8096   $am_file_name = basename ($makefile_am);
8097   $in_file_name = basename ($makefile_in);
8098
8099   # $OUTPUT is encoded.  If it contains a ":" then the first element
8100   # is the real output file, and all remaining elements are input
8101   # files.  We don't scan or otherwise deal with these input files,
8102   # other than to mark them as dependencies.  See
8103   # &scan_autoconf_files for details.
8104   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
8105
8106   $relative_dir = dirname ($makefile);
8107   $am_relative_dir = dirname ($makefile_am);
8108   $topsrcdir = backname ($relative_dir);
8109
8110   read_main_am_file ($makefile_am);
8111   if (handle_options)
8112     {
8113       # Process buffered warnings.
8114       flush_messages;
8115       # Fatal error.  Just return, so we can continue with next file.
8116       return;
8117     }
8118   # Process buffered warnings.
8119   flush_messages;
8120
8121   # There are a few install-related variables that you should not define.
8122   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
8123     {
8124       my $v = var $var;
8125       if ($v)
8126         {
8127           my $def = $v->def (TRUE);
8128           prog_error "$var not defined in condition TRUE"
8129             unless $def;
8130           reject_var $var, "'$var' should not be defined"
8131             if $def->owner != VAR_AUTOMAKE;
8132         }
8133     }
8134
8135   # Catch some obsolete variables.
8136   msg_var ('obsolete', 'INCLUDES',
8137            "'INCLUDES' is the old name for 'AM_CPPFLAGS' (or '*_CPPFLAGS')")
8138     if var ('INCLUDES');
8139
8140   # Must do this after reading .am file.
8141   define_variable ('subdir', $relative_dir, INTERNAL);
8142
8143   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
8144   # recursive rules are enabled.
8145   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
8146     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
8147
8148   # Check first, because we might modify some state.
8149   check_cygnus;
8150   check_gnu_standards;
8151   check_gnits_standards;
8152
8153   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
8154   handle_gettext;
8155   handle_libraries;
8156   handle_ltlibraries;
8157   handle_programs;
8158   handle_scripts;
8159
8160   handle_silent;
8161
8162   # These must be run after all the sources are scanned.  They
8163   # use variables defined by &handle_libraries, &handle_ltlibraries,
8164   # or &handle_programs.
8165   handle_compile;
8166   handle_languages;
8167   handle_libtool;
8168
8169   # Variables used by distdir.am and tags.am.
8170   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
8171   if (! option 'no-dist')
8172     {
8173       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
8174     }
8175
8176   handle_texinfo;
8177   handle_emacs_lisp;
8178   handle_python;
8179   handle_java;
8180   handle_man_pages;
8181   handle_data;
8182   handle_headers;
8183   handle_subdirs;
8184   handle_tags;
8185   handle_minor_options;
8186   # Must come after handle_programs so that %known_programs is up-to-date.
8187   handle_tests;
8188
8189   # This must come after most other rules.
8190   handle_dist;
8191
8192   handle_footer;
8193   do_check_merge_target;
8194   handle_all ($makefile);
8195
8196   # FIXME: Gross!
8197   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8198     {
8199       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
8200     }
8201   if (var ('nobase_lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8202     {
8203       $output_rules .= "install-binPROGRAMS: install-nobase_libLTLIBRARIES\n\n";
8204     }
8205
8206   handle_install;
8207   handle_clean ($makefile);
8208   handle_factored_dependencies;
8209
8210   # Comes last, because all the above procedures may have
8211   # defined or overridden variables.
8212   $output_vars .= output_variables;
8213
8214   check_typos;
8215
8216   if ($exit_code != 0)
8217     {
8218       verb "not writing $makefile_in because of earlier errors";
8219       return;
8220     }
8221
8222   mkdir ($am_relative_dir, 0755) if ! -d $am_relative_dir;
8223
8224   # We make sure that 'all:' is the first target.
8225   my $output =
8226     "$output_vars$output_all$output_header$output_rules$output_trailer";
8227
8228   # Decide whether we must update the output file or not.
8229   # We have to update in the following situations.
8230   #  * $force_generation is set.
8231   #  * any of the output dependencies is younger than the output
8232   #  * the contents of the output is different (this can happen
8233   #    if the project has been populated with a file listed in
8234   #    @common_files since the last run).
8235   # Output's dependencies are split in two sets:
8236   #  * dependencies which are also configure dependencies
8237   #    These do not change between each Makefile.am
8238   #  * other dependencies, specific to the Makefile.am being processed
8239   #    (such as the Makefile.am itself, or any Makefile fragment
8240   #    it includes).
8241   my $timestamp = mtime $makefile_in;
8242   if (! $force_generation
8243       && $configure_deps_greatest_timestamp < $timestamp
8244       && $output_deps_greatest_timestamp < $timestamp
8245       && $output eq contents ($makefile_in))
8246     {
8247       verb "$makefile_in unchanged";
8248       # No need to update.
8249       return;
8250     }
8251
8252   if (-e $makefile_in)
8253     {
8254       unlink ($makefile_in)
8255         or fatal "cannot remove $makefile_in: $!";
8256     }
8257
8258   my $gm_file = new Automake::XFile "> $makefile_in";
8259   verb "creating $makefile_in";
8260   print $gm_file $output;
8261 }
8262
8263 ################################################################
8264
8265
8266
8267
8268 ################################################################
8269
8270 # Helper function for usage().
8271 sub print_autodist_files (@)
8272 {
8273   my @lcomm = sort (&uniq (@_));
8274
8275   my @four;
8276   format USAGE_FORMAT =
8277   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
8278   $four[0],           $four[1],           $four[2],           $four[3]
8279 .
8280   local $~ = "USAGE_FORMAT";
8281
8282   my $cols = 4;
8283   my $rows = int(@lcomm / $cols);
8284   my $rest = @lcomm % $cols;
8285
8286   if ($rest)
8287     {
8288       $rows++;
8289     }
8290   else
8291     {
8292       $rest = $cols;
8293     }
8294
8295   for (my $y = 0; $y < $rows; $y++)
8296     {
8297       @four = ("", "", "", "");
8298       for (my $x = 0; $x < $cols; $x++)
8299         {
8300           last if $y + 1 == $rows && $x == $rest;
8301
8302           my $idx = (($x > $rest)
8303                ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
8304                : ($rows * $x));
8305
8306           $idx += $y;
8307           $four[$x] = $lcomm[$idx];
8308         }
8309       write;
8310     }
8311 }
8312
8313
8314 # Print usage information.
8315 sub usage ()
8316 {
8317     print "Usage: $0 [OPTION]... [Makefile]...
8318
8319 Generate Makefile.in for configure from Makefile.am.
8320
8321 Operation modes:
8322       --help               print this help, then exit
8323       --version            print version number, then exit
8324   -v, --verbose            verbosely list files processed
8325       --no-force           only update Makefile.in's that are out of date
8326   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
8327
8328 Dependency tracking:
8329   -i, --ignore-deps      disable dependency tracking code
8330       --include-deps     enable dependency tracking code
8331
8332 Flavors:
8333       --cygnus           assume program is part of Cygnus-style tree
8334       --foreign          set strictness to foreign
8335       --gnits            set strictness to gnits
8336       --gnu              set strictness to gnu
8337
8338 Library files:
8339   -a, --add-missing      add missing standard files to package
8340       --libdir=DIR       set directory storing library files
8341       --print-libdir     print directory storing library files
8342   -c, --copy             with -a, copy missing files (default is symlink)
8343   -f, --force-missing    force update of standard files
8344
8345 ";
8346     Automake::ChannelDefs::usage;
8347
8348     print "\nFiles automatically distributed if found " .
8349           "(always):\n";
8350     print_autodist_files @common_files;
8351     print "\nFiles automatically distributed if found " .
8352           "(under certain conditions):\n";
8353     print_autodist_files @common_sometimes;
8354
8355     print '
8356 Report bugs to <@PACKAGE_BUGREPORT@>.
8357 GNU Automake home page: <@PACKAGE_URL@>.
8358 General help using GNU software: <http://www.gnu.org/gethelp/>.
8359 ';
8360
8361     # --help always returns 0 per GNU standards.
8362     exit 0;
8363 }
8364
8365
8366 # &version ()
8367 # -----------
8368 # Print version information
8369 sub version ()
8370 {
8371   print <<EOF;
8372 automake (GNU $PACKAGE) $VERSION
8373 Copyright (C) $RELEASE_YEAR Free Software Foundation, Inc.
8374 License GPLv2+: GNU GPL version 2 or later <http://gnu.org/licenses/gpl-2.0.html>
8375 This is free software: you are free to change and redistribute it.
8376 There is NO WARRANTY, to the extent permitted by law.
8377
8378 Written by Tom Tromey <tromey\@redhat.com>
8379        and Alexandre Duret-Lutz <adl\@gnu.org>.
8380 EOF
8381   # --version always returns 0 per GNU standards.
8382   exit 0;
8383 }
8384
8385 ################################################################
8386
8387 # Parse command line.
8388 sub parse_arguments ()
8389 {
8390   my $strict = 'gnu';
8391   my $cygnus = 0;
8392   my $ignore_deps = 0;
8393   my @warnings = ();
8394
8395   my %cli_options =
8396     (
8397      'version' => \&version,
8398      'help'    => \&usage,
8399      'libdir=s' => \$libdir,
8400      'print-libdir'     => sub { print "$libdir\n"; exit 0; },
8401      'gnu'              => sub { $strict = 'gnu'; },
8402      'gnits'            => sub { $strict = 'gnits'; },
8403      'foreign'          => sub { $strict = 'foreign'; },
8404      'cygnus'           => \$cygnus,
8405      'include-deps'     => sub { $ignore_deps = 0; },
8406      'i|ignore-deps'    => sub { $ignore_deps = 1; },
8407      'no-force' => sub { $force_generation = 0; },
8408      'f|force-missing'  => \$force_missing,
8409      'a|add-missing'    => \$add_missing,
8410      'c|copy'           => \$copy_missing,
8411      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
8412      'W|warnings=s'     => \@warnings,
8413      );
8414
8415   use Automake::Getopt ();
8416   Automake::Getopt::parse_options %cli_options;
8417
8418   set_strictness ($strict);
8419   my $cli_where = new Automake::Location;
8420   set_global_option ('cygnus', $cli_where) if $cygnus;
8421   set_global_option ('no-dependencies', $cli_where) if $ignore_deps;
8422   for my $warning (@warnings)
8423     {
8424       &parse_warnings ('-W', $warning);
8425     }
8426
8427   return unless @ARGV;
8428
8429   my $errspec = 0;
8430   foreach my $arg (@ARGV)
8431     {
8432       fatal ("empty argument\nTry '$0 --help' for more information")
8433         if ($arg eq '');
8434
8435       # Handle $local:$input syntax.
8436       my ($local, @rest) = split (/:/, $arg);
8437       @rest = ("$local.in",) unless @rest;
8438       my $input = locate_am @rest;
8439       if ($input)
8440         {
8441           push @input_files, $input;
8442           $output_files{$input} = join (':', ($local, @rest));
8443         }
8444       else
8445         {
8446           error "no Automake input file found for '$arg'";
8447           $errspec = 1;
8448         }
8449     }
8450   fatal "no input file found among supplied arguments"
8451     if $errspec && ! @input_files;
8452 }
8453
8454
8455 # handle_makefile ($MAKEFILE_IN)
8456 # ------------------------------
8457 # Deal with $MAKEFILE_IN.
8458 sub handle_makefile ($)
8459 {
8460   my ($file) =  @_;
8461   ($am_file = $file) =~ s/\.in$//;
8462   if (! -f ($am_file . '.am'))
8463     {
8464       error "'$am_file.am' does not exist";
8465     }
8466   else
8467     {
8468       # Any warning setting now local to this Makefile.am.
8469       dup_channel_setup;
8470
8471       generate_makefile ($am_file . '.am', $file);
8472
8473       # Back out any warning setting.
8474       drop_channel_setup;
8475     }
8476 }
8477
8478 # handle_makefiles_serial ()
8479 # --------------------------
8480 # Deal with all makefiles, without threads.
8481 sub handle_makefiles_serial ()
8482 {
8483   foreach my $file (@input_files)
8484     {
8485       handle_makefile ($file);
8486     }
8487 }
8488
8489 # get_number_of_threads ()
8490 # ------------------------
8491 # Logic for deciding how many worker threads to use.
8492 sub get_number_of_threads
8493 {
8494   my $nthreads = $ENV{'AUTOMAKE_JOBS'} || 0;
8495
8496   $nthreads = 0
8497     unless $nthreads =~ /^[0-9]+$/;
8498
8499   # It doesn't make sense to use more threads than makefiles,
8500   my $max_threads = @input_files;
8501
8502   if ($nthreads > $max_threads)
8503     {
8504       $nthreads = $max_threads;
8505     }
8506   return $nthreads;
8507 }
8508
8509 # handle_makefiles_threaded ($NTHREADS)
8510 # -------------------------------------
8511 # Deal with all makefiles, using threads.  The general strategy is to
8512 # spawn NTHREADS worker threads, dispatch makefiles to them, and let the
8513 # worker threads push back everything that needs serialization:
8514 # * warning and (normal) error messages, for stable stderr output
8515 #   order and content (avoiding duplicates, for example),
8516 # * races when installing aux files (and respective messages),
8517 # * races when collecting aux files for distribution.
8518 #
8519 # The latter requires that the makefile that deals with the aux dir
8520 # files be handled last, done by the master thread.
8521 sub handle_makefiles_threaded ($)
8522 {
8523   my ($nthreads) = @_;
8524
8525   # The file queue distributes all makefiles, the message queues
8526   # collect all serializations needed for respective files.
8527   my $file_queue = Thread::Queue->new;
8528   my %msg_queues;
8529   foreach my $file (@input_files)
8530     {
8531       $msg_queues{$file} = Thread::Queue->new;
8532     }
8533
8534   verb "spawning $nthreads worker threads";
8535   my @threads = (1 .. $nthreads);
8536   foreach my $t (@threads)
8537     {
8538       $t = threads->new (sub
8539         {
8540           while (my $file = $file_queue->dequeue)
8541             {
8542               verb "handling $file";
8543               my $queue = $msg_queues{$file};
8544               setup_channel_queue ($queue, QUEUE_MESSAGE);
8545               $required_conf_file_queue = $queue;
8546               handle_makefile ($file);
8547               $queue->enqueue (undef);
8548               setup_channel_queue (undef, undef);
8549               $required_conf_file_queue = undef;
8550             }
8551           return $exit_code;
8552         });
8553     }
8554
8555   # Queue all makefiles.
8556   verb "queuing " . @input_files . " input files";
8557   $file_queue->enqueue (@input_files, (undef) x @threads);
8558
8559   # Collect and process serializations.
8560   foreach my $file (@input_files)
8561     {
8562       verb "dequeuing messages for " . $file;
8563       reset_local_duplicates ();
8564       my $queue = $msg_queues{$file};
8565       while (my $key = $queue->dequeue)
8566         {
8567           if ($key eq QUEUE_MESSAGE)
8568             {
8569               pop_channel_queue ($queue);
8570             }
8571           elsif ($key eq QUEUE_CONF_FILE)
8572             {
8573               require_queued_file_check_or_copy ($queue);
8574             }
8575           else
8576             {
8577               prog_error "unexpected key $key";
8578             }
8579         }
8580     }
8581
8582   foreach my $t (@threads)
8583     {
8584       my @exit_thread = $t->join;
8585       $exit_code = $exit_thread[0]
8586         if ($exit_thread[0] > $exit_code);
8587     }
8588 }
8589
8590 ################################################################
8591
8592 # Parse the WARNINGS environment variable.
8593 parse_WARNINGS;
8594
8595 # Parse command line.
8596 parse_arguments;
8597
8598 $configure_ac = require_configure_ac;
8599
8600 # Do configure.ac scan only once.
8601 scan_autoconf_files;
8602
8603 if (! @input_files)
8604   {
8605     my $msg = '';
8606     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
8607       if -f 'Makefile.am';
8608     fatal ("no 'Makefile.am' found for any configure output$msg");
8609   }
8610
8611 my $nthreads = get_number_of_threads ();
8612
8613 if ($perl_threads && $nthreads >= 1)
8614   {
8615     handle_makefiles_threaded ($nthreads);
8616   }
8617 else
8618   {
8619     handle_makefiles_serial ();
8620   }
8621
8622 exit $exit_code;
8623
8624
8625 ### Setup "GNU" style for perl-mode and cperl-mode.
8626 ## Local Variables:
8627 ## perl-indent-level: 2
8628 ## perl-continued-statement-offset: 2
8629 ## perl-continued-brace-offset: 0
8630 ## perl-brace-offset: 0
8631 ## perl-brace-imaginary-offset: 0
8632 ## perl-label-offset: -2
8633 ## cperl-indent-level: 2
8634 ## cperl-brace-offset: 0
8635 ## cperl-continued-brace-offset: 0
8636 ## cperl-label-offset: -2
8637 ## cperl-extra-newline-before-brace: t
8638 ## cperl-merge-trailing-else: nil
8639 ## cperl-continued-statement-offset: 2
8640 ## End: