automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
  10 # 2003, 2004, 2005, 2006  Free Software Foundation, Inc.
  11
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2, or (at your option)
  15 # any later version.
  16
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  25 # 02110-1301, USA.
  26
  27 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  28 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  29 # Alexandre Duret-Lutz <adl@gnu.org>.
  30
  31 package Language;
  32
  33 BEGIN
  34 {
  35   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  36   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  37
  38   # Override SHELL.  This is required on DJGPP so that system() uses
  39   # bash, not COMMAND.COM which doesn't quote arguments properly.
  40   # Other systems aren't expected to use $SHELL when Automake
  41   # runs, but it should be safe to drop the `if DJGPP' guard if
  42   # it turns up other systems need the same thing.  After all,
  43   # if SHELL is used, ./configure's SHELL is always better than
  44   # the user's SHELL (which may be something like tcsh).
  45   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJGPP'};
  46 }
  47
  48 use Automake::Struct;
  49 struct (# Short name of the language (c, f77...).
  50         'name' => "\$",
  51         # Nice name of the language (C, Fortran 77...).
  52         'Name' => "\$",
  53
  54         # List of configure variables which must be defined.
  55         'config_vars' => '@',
  56
  57         'ansi'    => "\$",
  58         # `pure' is `1' or `'.  A `pure' language is one where, if
  59         # all the files in a directory are of that language, then we
  60         # do not require the C compiler or any code to call it.
  61         'pure'   => "\$",
  62
  63         'autodep' => "\$",
  64
  65         # Name of the compiling variable (COMPILE).
  66         'compiler'  => "\$",
  67         # Content of the compiling variable.
  68         'compile'  => "\$",
  69         # Flag to require compilation without linking (-c).
  70         'compile_flag' => "\$",
  71         'extensions' => '@',
  72         # A subroutine to compute a list of possible extensions of
  73         # the product given the input extensions.
  74         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  75         'output_extensions' => "\$",
  76         # A list of flag variables used in 'compile'.
  77         # (defaults to [])
  78         'flags' => "@",
  79
  80         # Any tag to pass to libtool while compiling.
  81         'libtool_tag' => "\$",
  82
  83         # The file to use when generating rules for this language.
  84         # The default is 'depend2'.
  85         'rule_file' => "\$",
  86
  87         # Name of the linking variable (LINK).
  88         'linker' => "\$",
  89         # Content of the linking variable.
  90         'link' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} ();
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 use Automake::General;
 134 use Automake::XFile;
 135 use Automake::Channels;
 136 use Automake::ChannelDefs;
 137 use Automake::Configure_ac;
 138 use Automake::FileUtils;
 139 use Automake::Location;
 140 use Automake::Condition qw/TRUE FALSE/;
 141 use Automake::DisjConditions;
 142 use Automake::Options;
 143 use Automake::Version;
 144 use Automake::Variable;
 145 use Automake::VarDef;
 146 use Automake::Rule;
 147 use Automake::RuleDef;
 148 use Automake::Wrap 'makefile_wrap';
 149 use File::Basename;
 150 use File::Spec;
 151 use Carp;
 152
 153 ## ----------- ##
 154 ## Constants.  ##
 155 ## ----------- ##
 156
 157 # Some regular expressions.  One reason to put them here is that it
 158 # makes indentation work better in Emacs.
 159
 160 # Writing singled-quoted-$-terminated regexes is a pain because
 161 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 162 # by a closing quote.  Letting perl-mode think the quote is not closed
 163 # leads to all sort of misindentations.  On the other hand, defining
 164 # regexes as double-quoted strings is far less readable.  So usually
 165 # we will write:
 166 #
 167 #  $REGEX = '^regex_value' . "\$";
 168
 169 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 170 my $WHITE_PATTERN = '^\s*' . "\$";
 171 my $COMMENT_PATTERN = '^#';
 172 my $TARGET_PATTERN='[$a-zA-Z_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 173 # A rule has three parts: a list of targets, a list of dependencies,
 174 # and optionally actions.
 175 my $RULE_PATTERN =
 176   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 177
 178 # Only recognize leading spaces, not leading tabs.  If we recognize
 179 # leading tabs here then we need to make the reader smarter, because
 180 # otherwise it will think rules like `foo=bar; \' are errors.
 181 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 182 # This pattern recognizes a Gnits version id and sets $1 if the
 183 # release is an alpha release.  We also allow a suffix which can be
 184 # used to extend the version number with a "fork" identifier.
 185 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 186
 187 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 188 my $ELSE_PATTERN =
 189   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 190 my $ENDIF_PATTERN =
 191   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 192 my $PATH_PATTERN = '(\w|[+/.-])+';
 193 # This will pass through anything not of the prescribed form.
 194 my $INCLUDE_PATTERN = ('^include\s+'
 195                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 196                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 197                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 198
 199 # Match `-d' as a command-line argument in a string.
 200 my $DASH_D_PATTERN = "(^|\\s)-d(\\s|\$)";
 201 # Directories installed during 'install-exec' phase.
 202 my $EXEC_DIR_PATTERN =
 203   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 204
 205 # Values for AC_CANONICAL_*
 206 use constant AC_CANONICAL_BUILD  => 1;
 207 use constant AC_CANONICAL_HOST   => 2;
 208 use constant AC_CANONICAL_TARGET => 3;
 209
 210 # Values indicating when something should be cleaned.
 211 use constant MOSTLY_CLEAN     => 0;
 212 use constant CLEAN            => 1;
 213 use constant DIST_CLEAN       => 2;
 214 use constant MAINTAINER_CLEAN => 3;
 215
 216 # Libtool files.
 217 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 218 # ltconfig appears here for compatibility with old versions of libtool.
 219 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 220
 221 # Commonly found files we look for and automatically include in
 222 # DISTFILES.
 223 my @common_files =
 224     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 225         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 226         ansi2knr.1 ansi2knr.c compile config.guess config.rpath config.sub
 227         depcomp elisp-comp install-sh libversion.in mdate-sh missing
 228         mkinstalldirs py-compile texinfo.tex ylwrap),
 229      @libtool_files, @libtool_sometimes);
 230
 231 # Commonly used files we auto-include, but only sometimes.  This list
 232 # is used for the --help output only.
 233 my @common_sometimes =
 234   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 235      configure.ac configure.in stamp-vti);
 236
 237 # Standard directories from the GNU Coding Standards, and additional
 238 # pkg* directories from Automake.  Stored in a hash for fast member check.
 239 my %standard_prefix =
 240     map { $_ => 1 } (qw(bin data dataroot dvi exec html include info
 241                         lib libexec lisp localstate man man1 man2 man3
 242                         man4 man5 man6 man7 man8 man9 oldinclude pdf
 243                         pkgdatadir pkgincludedir pkglibdir ps sbin
 244                         sharedstate sysconf));
 245
 246 # Copyright on generated Makefile.ins.
 247 my $gen_copyright = "\
 248 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
 249 # 2003, 2004, 2005, 2006  Free Software Foundation, Inc.
 250 # This Makefile.in is free software; the Free Software Foundation
 251 # gives unlimited permission to copy and/or distribute it,
 252 # with or without modifications, as long as this notice is preserved.
 253
 254 # This program is distributed in the hope that it will be useful,
 255 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 256 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 257 # PARTICULAR PURPOSE.
 258 ";
 259
 260 # These constants are returned by lang_*_rewrite functions.
 261 # LANG_SUBDIR means that the resulting object file should be in a
 262 # subdir if the source file is.  In this case the file name cannot
 263 # have `..' components.
 264 use constant LANG_IGNORE  => 0;
 265 use constant LANG_PROCESS => 1;
 266 use constant LANG_SUBDIR  => 2;
 267
 268 # These are used when keeping track of whether an object can be built
 269 # by two different paths.
 270 use constant COMPILE_LIBTOOL  => 1;
 271 use constant COMPILE_ORDINARY => 2;
 272
 273 # We can't always associate a location to a variable or a rule,
 274 # when its defined by Automake.  We use INTERNAL in this case.
 275 use constant INTERNAL => new Automake::Location;
 276 \f
 277
 278 ## ---------------------------------- ##
 279 ## Variables related to the options.  ##
 280 ## ---------------------------------- ##
 281
 282 # TRUE if we should always generate Makefile.in.
 283 my $force_generation = 1;
 284
 285 # From the Perl manual.
 286 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 287
 288 # TRUE if missing standard files should be installed.
 289 my $add_missing = 0;
 290
 291 # TRUE if we should copy missing files; otherwise symlink if possible.
 292 my $copy_missing = 0;
 293
 294 # TRUE if we should always update files that we know about.
 295 my $force_missing = 0;
 296
 297
 298 ## ---------------------------------------- ##
 299 ## Variables filled during files scanning.  ##
 300 ## ---------------------------------------- ##
 301
 302 # Name of the configure.ac file.
 303 my $configure_ac;
 304
 305 # Files found by scanning configure.ac for LIBOBJS.
 306 my %libsources = ();
 307
 308 # Names used in AC_CONFIG_HEADER call.
 309 my @config_headers = ();
 310
 311 # Names used in AC_CONFIG_LINKS call.
 312 my @config_links = ();
 313
 314 # Directory where output files go.  Actually, output files are
 315 # relative to this directory.
 316 my $output_directory;
 317
 318 # List of Makefile.am's to process, and their corresponding outputs.
 319 my @input_files = ();
 320 my %output_files = ();
 321
 322 # Complete list of Makefile.am's that exist.
 323 my @configure_input_files = ();
 324
 325 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 326 # and their outputs.
 327 my @other_input_files = ();
 328 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 329 # The keys are the files created by these macros.
 330 my %ac_config_files_location = ();
 331
 332 # Directory to search for configure-required files.  This
 333 # will be computed by &locate_aux_dir and can be set using
 334 # AC_CONFIG_AUX_DIR in configure.ac.
 335 # $CONFIG_AUX_DIR is the `raw' directory, valid only in the source-tree.
 336 my $config_aux_dir = '';
 337 my $config_aux_dir_set_in_configure_ac = 0;
 338 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 339 # in Makefiles.
 340 my $am_config_aux_dir = '';
 341
 342 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 343 # in configure.ac.
 344 my $config_libobj_dir = '';
 345
 346 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 347 my $seen_gettext = 0;
 348 # Whether AM_GNU_GETTEXT([external]) is used.
 349 my $seen_gettext_external = 0;
 350 # Where AM_GNU_GETTEXT appears.
 351 my $ac_gettext_location;
 352
 353 # Lists of tags supported by Libtool.
 354 my %libtool_tags = ();
 355 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 356 # use AC_REQUIRE_AUX_FILE.
 357 my $libtool_new_api = 0;
 358
 359 # Most important AC_CANONICAL_* macro seen so far.
 360 my $seen_canonical = 0;
 361 # Location of that macro.
 362 my $canonical_location;
 363
 364 # Where AM_MAINTAINER_MODE appears.
 365 my $seen_maint_mode;
 366
 367 # Actual version we've seen.
 368 my $package_version = '';
 369
 370 # Where version is defined.
 371 my $package_version_location;
 372
 373 # TRUE if we've seen AC_ENABLE_MULTILIB.
 374 my $seen_multilib = 0;
 375
 376 # TRUE if we've seen AM_PROG_CC_C_O
 377 my $seen_cc_c_o = 0;
 378
 379 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 380 my %required_aux_file = ();
 381
 382 # Where AM_INIT_AUTOMAKE is called;
 383 my $seen_init_automake = 0;
 384
 385 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 386 my $seen_automake_version = 0;
 387
 388 # Hash table of discovered configure substitutions.  Keys are names,
 389 # values are `FILE:LINE' strings which are used by error message
 390 # generation.
 391 my %configure_vars = ();
 392
 393 # Files included by $configure_ac.
 394 my @configure_deps = ();
 395
 396 # Greatest timestamp of configure's dependencies.
 397 my $configure_deps_greatest_timestamp = 0;
 398
 399 # Hash table of AM_CONDITIONAL variables seen in configure.
 400 my %configure_cond = ();
 401
 402 # This maps extensions onto language names.
 403 my %extension_map = ();
 404
 405 # List of the DIST_COMMON files we discovered while reading
 406 # configure.in
 407 my $configure_dist_common = '';
 408
 409 # This maps languages names onto objects.
 410 my %languages = ();
 411 # Maps each linker variable onto a language object.
 412 my %link_languages = ();
 413
 414 # List of targets we must always output.
 415 # FIXME: Complete, and remove falsely required targets.
 416 my %required_targets =
 417   (
 418    'all'          => 1,
 419    'dvi'          => 1,
 420    'pdf'          => 1,
 421    'ps'           => 1,
 422    'info'         => 1,
 423    'install-info' => 1,
 424    'install'      => 1,
 425    'install-data' => 1,
 426    'install-exec' => 1,
 427    'uninstall'    => 1,
 428
 429    # FIXME: Not required, temporary hacks.
 430    # Well, actually they are sort of required: the -recursive
 431    # targets will run them anyway...
 432    'dvi-am'          => 1,
 433    'pdf-am'          => 1,
 434    'ps-am'           => 1,
 435    'info-am'         => 1,
 436    'install-data-am' => 1,
 437    'install-exec-am' => 1,
 438    'installcheck-am' => 1,
 439    'uninstall-am' => 1,
 440
 441    'install-man' => 1,
 442   );
 443
 444 # Set to 1 if this run will create the Makefile.in that distribute
 445 # the files in config_aux_dir.
 446 my $automake_will_process_aux_dir = 0;
 447
 448 # The name of the Makefile currently being processed.
 449 my $am_file = 'BUG';
 450 \f
 451
 452 ################################################################
 453
 454 ## ------------------------------------------ ##
 455 ## Variables reset by &initialize_per_input.  ##
 456 ## ------------------------------------------ ##
 457
 458 # Basename and relative dir of the input file.
 459 my $am_file_name;
 460 my $am_relative_dir;
 461
 462 # Same but wrt Makefile.in.
 463 my $in_file_name;
 464 my $relative_dir;
 465
 466 # Relative path to the top directory.
 467 my $topsrcdir;
 468
 469 # Greatest timestamp of the output's dependencies (excluding
 470 # configure's dependencies).
 471 my $output_deps_greatest_timestamp;
 472
 473 # These two variables are used when generating each Makefile.in.
 474 # They hold the Makefile.in until it is ready to be printed.
 475 my $output_rules;
 476 my $output_vars;
 477 my $output_trailer;
 478 my $output_all;
 479 my $output_header;
 480
 481 # This is the conditional stack, updated on if/else/endif, and
 482 # used to build Condition objects.
 483 my @cond_stack;
 484
 485 # This holds the set of included files.
 486 my @include_stack;
 487
 488 # This holds a list of directories which we must create at `dist'
 489 # time.  This is used in some strange scenarios involving weird
 490 # AC_OUTPUT commands.
 491 my %dist_dirs;
 492
 493 # List of dependencies for the obvious targets.
 494 my @all;
 495 my @check;
 496 my @check_tests;
 497
 498 # Keys in this hash table are files to delete.  The associated
 499 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 500 my %clean_files;
 501
 502 # Keys in this hash table are object files or other files in
 503 # subdirectories which need to be removed.  This only holds files
 504 # which are created by compilations.  The value in the hash indicates
 505 # when the file should be removed.
 506 my %compile_clean_files;
 507
 508 # Keys in this hash table are directories where we expect to build a
 509 # libtool object.  We use this information to decide what directories
 510 # to delete.
 511 my %libtool_clean_directories;
 512
 513 # Value of `$(SOURCES)', used by tags.am.
 514 my @sources;
 515 # Sources which go in the distribution.
 516 my @dist_sources;
 517
 518 # This hash maps object file names onto their corresponding source
 519 # file names.  This is used to ensure that each object is created
 520 # by a single source file.
 521 my %object_map;
 522
 523 # This hash maps object file names onto an integer value representing
 524 # whether this object has been built via ordinary compilation or
 525 # libtool compilation (the COMPILE_* constants).
 526 my %object_compilation_map;
 527
 528
 529 # This keeps track of the directories for which we've already
 530 # created dirstamp code.  Keys are directories, values are stamp files.
 531 # Several keys can share the same stamp files if they are equivalent
 532 # (as are `.//foo' and `foo').
 533 my %directory_map;
 534
 535 # All .P files.
 536 my %dep_files;
 537
 538 # This is a list of all targets to run during "make dist".
 539 my @dist_targets;
 540
 541 # Keys in this hash are the basenames of files which must depend on
 542 # ansi2knr.  Values are either the empty string, or the directory in
 543 # which the ANSI source file appears; the directory must have a
 544 # trailing `/'.
 545 my %de_ansi_files;
 546
 547 # This is the name of the redirect `all' target to use.
 548 my $all_target;
 549
 550 # This keeps track of which extensions we've seen (that we care
 551 # about).
 552 my %extension_seen;
 553
 554 # This is random scratch space for the language finish functions.
 555 # Don't randomly overwrite it; examine other uses of keys first.
 556 my %language_scratch;
 557
 558 # We keep track of which objects need special (per-executable)
 559 # handling on a per-language basis.
 560 my %lang_specific_files;
 561
 562 # This is set when `handle_dist' has finished.  Once this happens,
 563 # we should no longer push on dist_common.
 564 my $handle_dist_run;
 565
 566 # Used to store a set of linkers needed to generate the sources currently
 567 # under consideration.
 568 my %linkers_used;
 569
 570 # True if we need `LINK' defined.  This is a hack.
 571 my $need_link;
 572
 573 # Was get_object_extension run?
 574 # FIXME: This is a hack. a better switch should be found.
 575 my $get_object_extension_was_run;
 576
 577 # Record each file processed by make_paragraphs.
 578 my %transformed_files;
 579
 580 # Cache each file processed by make_paragraphs.
 581 # (This is different from %transformed_files because
 582 # %transformed_files is reset for each file while %am_file_cache
 583 # it global to the run.)
 584 my %am_file_cache;
 585
 586 ################################################################
 587
 588 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 589 # ------------------------------------
 590 # This is called by Automake::Variable::define() when SUFFIXES
 591 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 592 # The work here needs to be performed as a side-effect of the
 593 # macro_define() call because SUFFIXES definitions impact
 594 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 595 # the input am file.
 596 sub var_SUFFIXES_trigger ($$)
 597 {
 598     my ($type, $value) = @_;
 599     accept_extensions (split (' ', $value));
 600 }
 601 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 602
 603 ################################################################
 604
 605 ## --------------------------------- ##
 606 ## Forward subroutine declarations.  ##
 607 ## --------------------------------- ##
 608 sub register_language (%);
 609 sub file_contents_internal ($$$%);
 610 sub define_files_variable ($\@$$);
 611
 612
 613 # &initialize_per_input ()
 614 # ------------------------
 615 # (Re)-Initialize per-Makefile.am variables.
 616 sub initialize_per_input ()
 617 {
 618     reset_local_duplicates ();
 619
 620     $am_file_name = '';
 621     $am_relative_dir = '';
 622
 623     $in_file_name = '';
 624     $relative_dir = '';
 625
 626     $output_deps_greatest_timestamp = 0;
 627
 628     $output_rules = '';
 629     $output_vars = '';
 630     $output_trailer = '';
 631     $output_all = '';
 632     $output_header = '';
 633
 634     Automake::Options::reset;
 635     Automake::Variable::reset;
 636     Automake::Rule::reset;
 637
 638     @cond_stack = ();
 639
 640     @include_stack = ();
 641
 642     %dist_dirs = ();
 643
 644     @all = ();
 645     @check = ();
 646     @check_tests = ();
 647
 648     %clean_files = ();
 649
 650     @sources = ();
 651     @dist_sources = ();
 652
 653     %object_map = ();
 654     %object_compilation_map = ();
 655
 656     %directory_map = ();
 657
 658     %dep_files = ();
 659
 660     @dist_targets = ();
 661
 662     %de_ansi_files = ();
 663
 664     $all_target = '';
 665
 666     %extension_seen = ();
 667
 668     %language_scratch = ();
 669
 670     %lang_specific_files = ();
 671
 672     $handle_dist_run = 0;
 673
 674     $need_link = 0;
 675
 676     $get_object_extension_was_run = 0;
 677
 678     %compile_clean_files = ();
 679
 680     # We always include `.'.  This isn't strictly correct.
 681     %libtool_clean_directories = ('.' => 1);
 682
 683     %transformed_files = ();
 684 }
 685
 686
 687 ################################################################
 688
 689 # Initialize our list of languages that are internally supported.
 690
 691 # C.
 692 register_language ('name' => 'c',
 693                    'Name' => 'C',
 694                    'config_vars' => ['CC'],
 695                    'ansi' => 1,
 696                    'autodep' => '',
 697                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 698                    'compiler' => 'COMPILE',
 699                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 700                    'lder' => 'CCLD',
 701                    'ld' => '$(CC)',
 702                    'linker' => 'LINK',
 703                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 704                    'compile_flag' => '-c',
 705                    'libtool_tag' => 'CC',
 706                    'extensions' => ['.c'],
 707                    '_finish' => \&lang_c_finish);
 708
 709 # C++.
 710 register_language ('name' => 'cxx',
 711                    'Name' => 'C++',
 712                    'config_vars' => ['CXX'],
 713                    'linker' => 'CXXLINK',
 714                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 715                    'autodep' => 'CXX',
 716                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 717                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 718                    'compiler' => 'CXXCOMPILE',
 719                    'compile_flag' => '-c',
 720                    'output_flag' => '-o',
 721                    'libtool_tag' => 'CXX',
 722                    'lder' => 'CXXLD',
 723                    'ld' => '$(CXX)',
 724                    'pure' => 1,
 725                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 726
 727 # Objective C.
 728 register_language ('name' => 'objc',
 729                    'Name' => 'Objective C',
 730                    'config_vars' => ['OBJC'],
 731                    'linker' => 'OBJCLINK',,
 732                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 733                    'autodep' => 'OBJC',
 734                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 735                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 736                    'compiler' => 'OBJCCOMPILE',
 737                    'compile_flag' => '-c',
 738                    'output_flag' => '-o',
 739                    'lder' => 'OBJCLD',
 740                    'ld' => '$(OBJC)',
 741                    'pure' => 1,
 742                    'extensions' => ['.m']);
 743
 744 # Headers.
 745 register_language ('name' => 'header',
 746                    'Name' => 'Header',
 747                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 748                                     '.hpp', '.inc'],
 749                    # No output.
 750                    'output_extensions' => sub { return () },
 751                    # Nothing to do.
 752                    '_finish' => sub { });
 753
 754 # Yacc (C & C++).
 755 register_language ('name' => 'yacc',
 756                    'Name' => 'Yacc',
 757                    'config_vars' => ['YACC'],
 758                    'flags' => ['YFLAGS'],
 759                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 760                    'compiler' => 'YACCCOMPILE',
 761                    'extensions' => ['.y'],
 762                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 763                                                 return ($ext,) },
 764                    'rule_file' => 'yacc',
 765                    '_finish' => \&lang_yacc_finish,
 766                    '_target_hook' => \&lang_yacc_target_hook,
 767                    'nodist_specific' => 1);
 768 register_language ('name' => 'yaccxx',
 769                    'Name' => 'Yacc (C++)',
 770                    'config_vars' => ['YACC'],
 771                    'rule_file' => 'yacc',
 772                    'flags' => ['YFLAGS'],
 773                    'compiler' => 'YACCCOMPILE',
 774                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 775                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 776                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 777                                                 return ($ext,) },
 778                    '_finish' => \&lang_yacc_finish,
 779                    '_target_hook' => \&lang_yacc_target_hook,
 780                    'nodist_specific' => 1);
 781
 782 # Lex (C & C++).
 783 register_language ('name' => 'lex',
 784                    'Name' => 'Lex',
 785                    'config_vars' => ['LEX'],
 786                    'rule_file' => 'lex',
 787                    'flags' => ['LFLAGS'],
 788                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 789                    'compiler' => 'LEXCOMPILE',
 790                    'extensions' => ['.l'],
 791                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 792                                                 return ($ext,) },
 793                    '_finish' => \&lang_lex_finish,
 794                    '_target_hook' => \&lang_lex_target_hook,
 795                    'nodist_specific' => 1);
 796 register_language ('name' => 'lexxx',
 797                    'Name' => 'Lex (C++)',
 798                    'config_vars' => ['LEX'],
 799                    'rule_file' => 'lex',
 800                    'flags' => ['LFLAGS'],
 801                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 802                    'compiler' => 'LEXCOMPILE',
 803                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 804                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 805                                                 return ($ext,) },
 806                    '_finish' => \&lang_lex_finish,
 807                    '_target_hook' => \&lang_lex_target_hook,
 808                    'nodist_specific' => 1);
 809
 810 # Assembler.
 811 register_language ('name' => 'asm',
 812                    'Name' => 'Assembler',
 813                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 814
 815                    'flags' => ['CCASFLAGS'],
 816                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 817                    # or anything else required.  They can also set CCAS.
 818                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 819                    'compiler' => 'CCASCOMPILE',
 820                    'compile_flag' => '-c',
 821                    'extensions' => ['.s'],
 822
 823                    # With assembly we still use the C linker.
 824                    '_finish' => \&lang_c_finish);
 825
 826 # Preprocessed Assembler.
 827 register_language ('name' => 'cppasm',
 828                    'Name' => 'Preprocessed Assembler',
 829                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 830
 831                    'autodep' => 'CCAS',
 832                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 833                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 834                    # or anything else required beyond AM_CPPFLAGS.  They
 835                    # can also set CCAS.
 836                    'compile' => '$(CCAS) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 837                    'compiler' => 'CPPASCOMPILE',
 838                    'compile_flag' => '-c',
 839                    'extensions' => ['.S'],
 840
 841                    # With assembly we still use the C linker.
 842                    '_finish' => \&lang_c_finish);
 843
 844 # Fortran 77
 845 register_language ('name' => 'f77',
 846                    'Name' => 'Fortran 77',
 847                    'linker' => 'F77LINK',
 848                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 849                    'flags' => ['FFLAGS'],
 850                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 851                    'compiler' => 'F77COMPILE',
 852                    'compile_flag' => '-c',
 853                    'output_flag' => '-o',
 854                    'libtool_tag' => 'F77',
 855                    'lder' => 'F77LD',
 856                    'ld' => '$(F77)',
 857                    'pure' => 1,
 858                    'extensions' => ['.f', '.for']);
 859
 860 # Fortran
 861 register_language ('name' => 'fc',
 862                    'Name' => 'Fortran',
 863                    'linker' => 'FCLINK',
 864                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 865                    'flags' => ['FCFLAGS'],
 866                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 867                    'compiler' => 'FCCOMPILE',
 868                    'compile_flag' => '-c',
 869                    'output_flag' => '-o',
 870                    'lder' => 'FCLD',
 871                    'ld' => '$(FC)',
 872                    'pure' => 1,
 873                    'extensions' => ['.f90', '.f95']);
 874
 875 # Preprocessed Fortran
 876 register_language ('name' => 'ppfc',
 877                    'Name' => 'Preprocessed Fortran',
 878                    'config_vars' => ['FC'],
 879                    'linker' => 'FCLINK',
 880                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 881                    'lder' => 'FCLD',
 882                    'ld' => '$(FC)',
 883                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 884                    'compiler' => 'PPFCCOMPILE',
 885                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 886                    'compile_flag' => '-c',
 887                    'output_flag' => '-o',
 888                    'libtool_tag' => 'FC',
 889                    'pure' => 1,
 890                    'extensions' => ['.F90','.F95']);
 891
 892 # Preprocessed Fortran 77
 893 #
 894 # The current support for preprocessing Fortran 77 just involves
 895 # passing `$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 896 # $(CPPFLAGS)' as additional flags to the Fortran 77 compiler, since
 897 # this is how GNU Make does it; see the `GNU Make Manual, Edition 0.51
 898 # for `make' Version 3.76 Beta' (specifically, from info file
 899 # `(make)Catalogue of Rules').
 900 #
 901 # A better approach would be to write an Autoconf test
 902 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 903 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 904 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 905 # preprocessing capabilities, and then fall back on cpp (if cpp were
 906 # available).
 907 register_language ('name' => 'ppf77',
 908                    'Name' => 'Preprocessed Fortran 77',
 909                    'config_vars' => ['F77'],
 910                    'linker' => 'F77LINK',
 911                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 912                    'lder' => 'F77LD',
 913                    'ld' => '$(F77)',
 914                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 915                    'compiler' => 'PPF77COMPILE',
 916                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 917                    'compile_flag' => '-c',
 918                    'output_flag' => '-o',
 919                    'libtool_tag' => 'F77',
 920                    'pure' => 1,
 921                    'extensions' => ['.F']);
 922
 923 # Ratfor.
 924 register_language ('name' => 'ratfor',
 925                    'Name' => 'Ratfor',
 926                    'config_vars' => ['F77'],
 927                    'linker' => 'F77LINK',
 928                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 929                    'lder' => 'F77LD',
 930                    'ld' => '$(F77)',
 931                    'flags' => ['RFLAGS', 'FFLAGS'],
 932                    # FIXME also FFLAGS.
 933                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
 934                    'compiler' => 'RCOMPILE',
 935                    'compile_flag' => '-c',
 936                    'output_flag' => '-o',
 937                    'libtool_tag' => 'F77',
 938                    'pure' => 1,
 939                    'extensions' => ['.r']);
 940
 941 # Java via gcj.
 942 register_language ('name' => 'java',
 943                    'Name' => 'Java',
 944                    'config_vars' => ['GCJ'],
 945                    'linker' => 'GCJLINK',
 946                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 947                    'autodep' => 'GCJ',
 948                    'flags' => ['GCJFLAGS'],
 949                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
 950                    'compiler' => 'GCJCOMPILE',
 951                    'compile_flag' => '-c',
 952                    'output_flag' => '-o',
 953                    'libtool_tag' => 'GCJ',
 954                    'lder' => 'GCJLD',
 955                    'ld' => '$(GCJ)',
 956                    'pure' => 1,
 957                    'extensions' => ['.java', '.class', '.zip', '.jar']);
 958
 959 ################################################################
 960
 961 # Error reporting functions.
 962
 963 # err_am ($MESSAGE, [%OPTIONS])
 964 # -----------------------------
 965 # Uncategorized errors about the current Makefile.am.
 966 sub err_am ($;%)
 967 {
 968   msg_am ('error', @_);
 969 }
 970
 971 # err_ac ($MESSAGE, [%OPTIONS])
 972 # -----------------------------
 973 # Uncategorized errors about configure.ac.
 974 sub err_ac ($;%)
 975 {
 976   msg_ac ('error', @_);
 977 }
 978
 979 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
 980 # ---------------------------------------
 981 # Messages about about the current Makefile.am.
 982 sub msg_am ($$;%)
 983 {
 984   my ($channel, $msg, %opts) = @_;
 985   msg $channel, "${am_file}.am", $msg, %opts;
 986 }
 987
 988 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
 989 # ---------------------------------------
 990 # Messages about about configure.ac.
 991 sub msg_ac ($$;%)
 992 {
 993   my ($channel, $msg, %opts) = @_;
 994   msg $channel, $configure_ac, $msg, %opts;
 995 }
 996
 997 ################################################################
 998
 999 # subst ($TEXT)
1000 # -------------
1001 # Return a configure-style substitution using the indicated text.
1002 # We do this to avoid having the substitutions directly in automake.in;
1003 # when we do that they are sometimes removed and this causes confusion
1004 # and bugs.
1005 sub subst ($)
1006 {
1007     my ($text) = @_;
1008     return '@' . $text . '@';
1009 }
1010
1011 ################################################################
1012
1013
1014 # $BACKPATH
1015 # &backname ($REL-DIR)
1016 # --------------------
1017 # If I `cd $REL-DIR', then to come back, I should `cd $BACKPATH'.
1018 # For instance `src/foo' => `../..'.
1019 # Works with non strictly increasing paths, i.e., `src/../lib' => `..'.
1020 sub backname ($)
1021 {
1022     my ($file) = @_;
1023     my @res;
1024     foreach (split (/\//, $file))
1025     {
1026         next if $_ eq '.' || $_ eq '';
1027         if ($_ eq '..')
1028         {
1029             pop @res;
1030         }
1031         else
1032         {
1033             push (@res, '..');
1034         }
1035     }
1036     return join ('/', @res) || '.';
1037 }
1038
1039 ################################################################
1040
1041
1042 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1043 sub handle_options
1044 {
1045   my $var = var ('AUTOMAKE_OPTIONS');
1046   if ($var)
1047     {
1048       # FIXME: We should disallow conditional definitions of AUTOMAKE_OPTIONS.
1049       if (process_option_list ($var->rdef (TRUE)->location,
1050                                $var->value_as_list_recursive (cond_filter =>
1051                                                               TRUE)))
1052         {
1053           return 1;
1054         }
1055     }
1056
1057   if ($strictness == GNITS)
1058     {
1059       set_option ('readme-alpha', INTERNAL);
1060       set_option ('std-options', INTERNAL);
1061       set_option ('check-news', INTERNAL);
1062     }
1063
1064   return 0;
1065 }
1066
1067 # shadow_unconditionally ($varname, $where)
1068 # -----------------------------------------
1069 # Return a $(variable) that contains all possible values
1070 # $varname can take.
1071 # If the VAR wasn't defined conditionally, return $(VAR).
1072 # Otherwise we create a am__VAR_DIST variable which contains
1073 # all possible values, and return $(am__VAR_DIST).
1074 sub shadow_unconditionally ($$)
1075 {
1076   my ($varname, $where) = @_;
1077   my $var = var $varname;
1078   if ($var->has_conditional_contents)
1079     {
1080       $varname = "am__${varname}_DIST";
1081       my @files = uniq ($var->value_as_list_recursive);
1082       define_pretty_variable ($varname, TRUE, $where, @files);
1083     }
1084   return "\$($varname)"
1085 }
1086
1087 # get_object_extension ($EXTENSION)
1088 # ---------------------------------
1089 # Prefix $EXTENSION with $U if ansi2knr is in use.
1090 sub get_object_extension ($)
1091 {
1092     my ($extension) = @_;
1093
1094     # Check for automatic de-ANSI-fication.
1095     $extension = '$U' . $extension
1096       if option 'ansi2knr';
1097
1098     $get_object_extension_was_run = 1;
1099
1100     return $extension;
1101 }
1102
1103 # check_user_variables (@LIST)
1104 # ----------------------------
1105 # Make sure each variable VAR in @LIST do not exist, suggest using AM_VAR
1106 # otherwise.
1107 sub check_user_variables (@)
1108 {
1109   my @dont_override = @_;
1110   foreach my $flag (@dont_override)
1111     {
1112       my $var = var $flag;
1113       if ($var)
1114         {
1115           for my $cond ($var->conditions->conds)
1116             {
1117               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1118                 {
1119                   msg_cond_var ('gnu', $cond, $flag,
1120                                 "`$flag' is a user variable, "
1121                                 . "you should not override it;\n"
1122                                 . "use `AM_$flag' instead.");
1123                 }
1124             }
1125         }
1126     }
1127 }
1128
1129 # Call finish function for each language that was used.
1130 sub handle_languages
1131 {
1132     if (! option 'no-dependencies')
1133     {
1134         # Include auto-dep code.  Don't include it if DEP_FILES would
1135         # be empty.
1136         if (&saw_sources_p (0) && keys %dep_files)
1137         {
1138             # Set location of depcomp.
1139             &define_variable ('depcomp',
1140                               "\$(SHELL) $am_config_aux_dir/depcomp",
1141                               INTERNAL);
1142             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1143
1144             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1145
1146             my @deplist = sort keys %dep_files;
1147             # Generate each `include' individually.  Irix 6 make will
1148             # not properly include several files resulting from a
1149             # variable expansion; generating many separate includes
1150             # seems safest.
1151             $output_rules .= "\n";
1152             foreach my $iter (@deplist)
1153             {
1154                 $output_rules .= (subst ('AMDEP_TRUE')
1155                                   . subst ('am__include')
1156                                   . ' '
1157                                   . subst ('am__quote')
1158                                   . $iter
1159                                   . subst ('am__quote')
1160                                   . "\n");
1161             }
1162
1163             # Compute the set of directories to remove in distclean-depend.
1164             my @depdirs = uniq (map { dirname ($_) } @deplist);
1165             $output_rules .= &file_contents ('depend',
1166                                              new Automake::Location,
1167                                              DEPDIRS => "@depdirs");
1168         }
1169     }
1170     else
1171     {
1172         &define_variable ('depcomp', '', INTERNAL);
1173         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1174     }
1175
1176     my %done;
1177
1178     # Is the c linker needed?
1179     my $needs_c = 0;
1180     foreach my $ext (sort keys %extension_seen)
1181     {
1182         next unless $extension_map{$ext};
1183
1184         my $lang = $languages{$extension_map{$ext}};
1185
1186         my $rule_file = $lang->rule_file || 'depend2';
1187
1188         # Get information on $LANG.
1189         my $pfx = $lang->autodep;
1190         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1191
1192         my ($AMDEP, $FASTDEP) =
1193           (option 'no-dependencies' || $lang->autodep eq 'no')
1194           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1195
1196         my %transform = ('EXT'     => $ext,
1197                          'PFX'     => $pfx,
1198                          'FPFX'    => $fpfx,
1199                          'AMDEP'   => $AMDEP,
1200                          'FASTDEP' => $FASTDEP,
1201                          '-c'      => $lang->compile_flag || '',
1202                          'MORE-THAN-ONE'
1203                                    => (count_files_for_language ($lang->name) > 1),
1204                          # These are not used, but they need to be defined
1205                          # so &transform do not complain.
1206                          SUBDIROBJ     => 0,
1207                          'DERIVED-EXT' => 'BUG',
1208                          DIST_SOURCE   => 1,
1209                         );
1210
1211         # Generate the appropriate rules for this extension.
1212         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1213             || defined $lang->compile)
1214         {
1215             # Some C compilers don't support -c -o.  Use it only if really
1216             # needed.
1217             my $output_flag = $lang->output_flag || '';
1218             $output_flag = '-o'
1219               if (! $output_flag
1220                   && $lang->name eq 'c'
1221                   && option 'subdir-objects');
1222
1223             # Compute a possible derived extension.
1224             # This is not used by depend2.am.
1225             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1226
1227             # When we output an inference rule like `.c.o:' we
1228             # have two cases to consider: either subdir-objects
1229             # is used, or it is not.
1230             #
1231             # In the latter case the rule is used to build objects
1232             # in the current directory, and dependencies always
1233             # go into `./$(DEPDIR)/'.  We can hard-code this value.
1234             #
1235             # In the former case the rule can be used to build
1236             # objects in sub-directories too.  Dependencies should
1237             # go into the appropriate sub-directories, e.g.,
1238             # `sub/$(DEPDIR)/'.  The value of this directory
1239             # need the be computed on-the-fly.
1240             #
1241             # DEPBASE holds the name of this directory, plus the
1242             # basename part of the object file (extensions Po, TPo,
1243             # Plo, TPlo will be added later as appropriate).  It is
1244             # either hardcoded, or a shell variable (`$depbase') that
1245             # will be computed by the rule.
1246             my $depbase =
1247               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1248             $output_rules .=
1249               file_contents ($rule_file,
1250                              new Automake::Location,
1251                              %transform,
1252                              GENERIC   => 1,
1253
1254                              'DERIVED-EXT' => $der_ext,
1255
1256                              DEPBASE   => $depbase,
1257                              BASE      => '$*',
1258                              SOURCE    => '$<',
1259                              OBJ       => '$@',
1260                              OBJOBJ    => '$@',
1261                              LTOBJ     => '$@',
1262
1263                              COMPILE   => '$(' . $lang->compiler . ')',
1264                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1265                              -o        => $output_flag,
1266                              SUBDIROBJ => !! option 'subdir-objects');
1267         }
1268
1269         # Now include code for each specially handled object with this
1270         # language.
1271         my %seen_files = ();
1272         foreach my $file (@{$lang_specific_files{$lang->name}})
1273         {
1274             my ($derived, $source, $obj, $myext, %file_transform) = @$file;
1275
1276             # We might see a given object twice, for instance if it is
1277             # used under different conditions.
1278             next if defined $seen_files{$obj};
1279             $seen_files{$obj} = 1;
1280
1281             prog_error ("found " . $lang->name .
1282                         " in handle_languages, but compiler not defined")
1283               unless defined $lang->compile;
1284
1285             my $obj_compile = $lang->compile;
1286
1287             # Rewrite each occurrence of `AM_$flag' in the compile
1288             # rule into `${derived}_$flag' if it exists.
1289             for my $flag (@{$lang->flags})
1290               {
1291                 my $val = "${derived}_$flag";
1292                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1293                   if set_seen ($val);
1294               }
1295
1296             my $libtool_tag = '';
1297             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1298               {
1299                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1300               }
1301
1302             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1303             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1304
1305             my $obj_ltcompile =
1306               "\$(LIBTOOL) $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1307               . "--mode=compile $obj_compile";
1308
1309             # We _need_ `-o' for per object rules.
1310             my $output_flag = $lang->output_flag || '-o';
1311
1312             my $depbase = dirname ($obj);
1313             $depbase = ''
1314                 if $depbase eq '.';
1315             $depbase .= '/'
1316                 unless $depbase eq '';
1317             $depbase .= '$(DEPDIR)/' . basename ($obj);
1318
1319             # Support for deansified files in subdirectories is ugly
1320             # enough to deserve an explanation.
1321             #
1322             # A Note about normal ansi2knr processing first.  On
1323             #
1324             #   AUTOMAKE_OPTIONS = ansi2knr
1325             #   bin_PROGRAMS = foo
1326             #   foo_SOURCES = foo.c
1327             #
1328             # we generate rules similar to:
1329             #
1330             #   foo: foo$U.o; link ...
1331             #   foo$U.o: foo$U.c; compile ...
1332             #   foo_.c: foo.c; ansi2knr ...
1333             #
1334             # this is fairly compact, and will call ansi2knr depending
1335             # on the value of $U (`' or `_').
1336             #
1337             # It's harder with subdir sources. On
1338             #
1339             #   AUTOMAKE_OPTIONS = ansi2knr
1340             #   bin_PROGRAMS = foo
1341             #   foo_SOURCES = sub/foo.c
1342             #
1343             # we have to create foo_.c in the current directory.
1344             # (Unless the user asks 'subdir-objects'.)  This is important
1345             # in case the same file (`foo.c') is compiled from other
1346             # directories with different cpp options: foo_.c would
1347             # be preprocessed for only one set of options if it were
1348             # put in the subdirectory.
1349             #
1350             # Because foo$U.o must be built from either foo_.c or
1351             # sub/foo.c we can't be as concise as in the first example.
1352             # Instead we output
1353             #
1354             #   foo: foo$U.o; link ...
1355             #   foo_.o: foo_.c; compile ...
1356             #   foo.o: sub/foo.c; compile ...
1357             #   foo_.c: foo.c; ansi2knr ...
1358             #
1359             # This is why we'll now transform $rule_file twice
1360             # if we detect this case.
1361             # A first time we output the compile rule with `$U'
1362             # replaced by `_' and the source directory removed,
1363             # and another time we simply remove `$U'.
1364             #
1365             # Note that at this point $source (as computed by
1366             # &handle_single_transform) is `sub/foo$U.c'.
1367             # This can be confusing: it can be used as-is when
1368             # subdir-objects is set, otherwise you have to know
1369             # it really means `foo_.c' or `sub/foo.c'.
1370             my $objdir = dirname ($obj);
1371             my $srcdir = dirname ($source);
1372             if ($lang->ansi && $obj =~ /\$U/)
1373               {
1374                 prog_error "`$obj' contains \$U, but `$source' doesn't."
1375                   if $source !~ /\$U/;
1376
1377                 (my $source_ = $source) =~ s/\$U/_/g;
1378                 # Output an additional rule if _.c and .c are not in
1379                 # the same directory.  (_.c is always in $objdir.)
1380                 if ($objdir ne $srcdir)
1381                   {
1382                     (my $obj_ = $obj) =~ s/\$U/_/g;
1383                     (my $depbase_ = $depbase) =~ s/\$U/_/g;
1384                     $source_ = basename ($source_);
1385
1386                     $output_rules .=
1387                       file_contents ($rule_file,
1388                                      new Automake::Location,
1389                                      %transform,
1390                                      GENERIC   => 0,
1391
1392                                      DEPBASE   => $depbase_,
1393                                      BASE      => $obj_,
1394                                      SOURCE    => $source_,
1395                                      OBJ       => "$obj_$myext",
1396                                      OBJOBJ    => "$obj_.obj",
1397                                      LTOBJ     => "$obj_.lo",
1398
1399                                      COMPILE   => $obj_compile,
1400                                      LTCOMPILE => $obj_ltcompile,
1401                                      -o        => $output_flag,
1402                                      %file_transform);
1403                     $obj =~ s/\$U//g;
1404                     $depbase =~ s/\$U//g;
1405                     $source =~ s/\$U//g;
1406                   }
1407               }
1408
1409             $output_rules .=
1410               file_contents ($rule_file,
1411                              new Automake::Location,
1412                              %transform,
1413                              GENERIC   => 0,
1414
1415                              DEPBASE   => $depbase,
1416                              BASE      => $obj,
1417                              SOURCE    => $source,
1418                              # Use $myext and not `.o' here, in case
1419                              # we are actually building a new source
1420                              # file -- e.g. via yacc.
1421                              OBJ       => "$obj$myext",
1422                              OBJOBJ    => "$obj.obj",
1423                              LTOBJ     => "$obj.lo",
1424
1425                              COMPILE   => $obj_compile,
1426                              LTCOMPILE => $obj_ltcompile,
1427                              -o        => $output_flag,
1428                              %file_transform);
1429         }
1430
1431         # The rest of the loop is done once per language.
1432         next if defined $done{$lang};
1433         $done{$lang} = 1;
1434
1435         # Load the language dependent Makefile chunks.
1436         my %lang = map { uc ($_) => 0 } keys %languages;
1437         $lang{uc ($lang->name)} = 1;
1438         $output_rules .= file_contents ('lang-compile',
1439                                         new Automake::Location,
1440                                         %transform, %lang);
1441
1442         # If the source to a program consists entirely of code from a
1443         # `pure' language, for instance C++ or Fortran 77, then we
1444         # don't need the C compiler code.  However if we run into
1445         # something unusual then we do generate the C code.  There are
1446         # probably corner cases here that do not work properly.
1447         # People linking Java code to Fortran code deserve pain.
1448         $needs_c ||= ! $lang->pure;
1449
1450         define_compiler_variable ($lang)
1451           if ($lang->compile);
1452
1453         define_linker_variable ($lang)
1454           if ($lang->link);
1455
1456         require_variables ("$am_file.am", $lang->Name . " source seen",
1457                            TRUE, @{$lang->config_vars});
1458
1459         # Call the finisher.
1460         $lang->finish;
1461
1462         # Flags listed in `->flags' are user variables (per GNU Standards),
1463         # they should not be overridden in the Makefile...
1464         my @dont_override = @{$lang->flags};
1465         # ... and so is LDFLAGS.
1466         push @dont_override, 'LDFLAGS' if $lang->link;
1467
1468         check_user_variables @dont_override;
1469     }
1470
1471     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1472     # suffix rule was learned), don't bother with the C stuff.  But if
1473     # anything else creeps in, then use it.
1474     $needs_c = 1
1475       if $need_link || suffix_rules_count > 1;
1476
1477     if ($needs_c)
1478       {
1479         &define_compiler_variable ($languages{'c'})
1480           unless defined $done{$languages{'c'}};
1481         define_linker_variable ($languages{'c'});
1482       }
1483 }
1484
1485 # Check to make sure a source defined in LIBOBJS is not explicitly
1486 # mentioned.  This is a separate function (as opposed to being inlined
1487 # in handle_source_transform) because it isn't always appropriate to
1488 # do this check.
1489 sub check_libobjs_sources
1490 {
1491   my ($one_file, $unxformed) = @_;
1492
1493   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1494                       'dist_EXTRA_', 'nodist_EXTRA_')
1495     {
1496       my @files;
1497       my $varname = $prefix . $one_file . '_SOURCES';
1498       my $var = var ($varname);
1499       if ($var)
1500         {
1501           @files = $var->value_as_list_recursive;
1502         }
1503       elsif ($prefix eq '')
1504         {
1505           @files = ($unxformed . '.c');
1506         }
1507       else
1508         {
1509           next;
1510         }
1511
1512       foreach my $file (@files)
1513         {
1514           err_var ($prefix . $one_file . '_SOURCES',
1515                    "automatically discovered file `$file' should not" .
1516                    " be explicitly mentioned")
1517             if defined $libsources{$file};
1518         }
1519     }
1520 }
1521
1522
1523 # @OBJECTS
1524 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1525 # -----------------------------------------------------------------------------
1526 # Does much of the actual work for handle_source_transform.
1527 # Arguments are:
1528 #   $VAR is the name of the variable that the source filenames come from
1529 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1530 #   $DERIVED is the name of resulting executable or library
1531 #   $OBJ is the object extension (e.g., `$U.lo')
1532 #   $FILE the source file to transform
1533 #   %TRANSFORM contains extras arguments to pass to file_contents
1534 #     when producing explicit rules
1535 # Result is a list of the names of objects
1536 # %linkers_used will be updated with any linkers needed
1537 sub handle_single_transform ($$$$$%)
1538 {
1539     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1540     my @files = ($_file);
1541     my @result = ();
1542     my $nonansi_obj = $obj;
1543     $nonansi_obj =~ s/\$U//g;
1544
1545     # Turn sources into objects.  We use a while loop like this
1546     # because we might add to @files in the loop.
1547     while (scalar @files > 0)
1548     {
1549         $_ = shift @files;
1550
1551         # Configure substitutions in _SOURCES variables are errors.
1552         if (/^\@.*\@$/)
1553         {
1554           my $parent_msg = '';
1555           $parent_msg = "\nand is referred to from `$topparent'"
1556             if $topparent ne $var->name;
1557           err_var ($var,
1558                    "`" . $var->name . "' includes configure substitution `$_'"
1559                    . $parent_msg . ";\nconfigure " .
1560                    "substitutions are not allowed in _SOURCES variables");
1561           next;
1562         }
1563
1564         # If the source file is in a subdirectory then the `.o' is put
1565         # into the current directory, unless the subdir-objects option
1566         # is in effect.
1567
1568         # Split file name into base and extension.
1569         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1570         my $full = $_;
1571         my $directory = $1 || '';
1572         my $base = $2;
1573         my $extension = $3;
1574
1575         # We must generate a rule for the object if it requires its own flags.
1576         my $renamed = 0;
1577         my ($linker, $object);
1578
1579         # This records whether we've seen a derived source file (e.g.
1580         # yacc output).
1581         my $derived_source = 0;
1582
1583         # This holds the `aggregate context' of the file we are
1584         # currently examining.  If the file is compiled with
1585         # per-object flags, then it will be the name of the object.
1586         # Otherwise it will be `AM'.  This is used by the target hook
1587         # language function.
1588         my $aggregate = 'AM';
1589
1590         $extension = &derive_suffix ($extension, $nonansi_obj);
1591         my $lang;
1592         if ($extension_map{$extension} &&
1593             ($lang = $languages{$extension_map{$extension}}))
1594         {
1595             # Found the language, so see what it says.
1596             &saw_extension ($extension);
1597
1598             # Do we have per-executable flags for this executable?
1599             my $have_per_exec_flags = 0;
1600             my @peflags = @{$lang->flags};
1601             push @peflags, 'LIBTOOLFLAGS' if $nonansi_obj eq '.lo';
1602             foreach my $flag (@peflags)
1603               {
1604                 if (set_seen ("${derived}_$flag"))
1605                   {
1606                     $have_per_exec_flags = 1;
1607                     last;
1608                   }
1609               }
1610
1611             # Note: computed subr call.  The language rewrite function
1612             # should return one of the LANG_* constants.  It could
1613             # also return a list whose first value is such a constant
1614             # and whose second value is a new source extension which
1615             # should be applied.  This means this particular language
1616             # generates another source file which we must then process
1617             # further.
1618             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1619             my ($r, $source_extension)
1620                 = &$subr ($directory, $base, $extension,
1621                           $nonansi_obj, $have_per_exec_flags, $var);
1622             # Skip this entry if we were asked not to process it.
1623             next if $r == LANG_IGNORE;
1624
1625             # Now extract linker and other info.
1626             $linker = $lang->linker;
1627
1628             my $this_obj_ext;
1629             if (defined $source_extension)
1630             {
1631                 $this_obj_ext = $source_extension;
1632                 $derived_source = 1;
1633             }
1634             elsif ($lang->ansi)
1635             {
1636                 $this_obj_ext = $obj;
1637             }
1638             else
1639             {
1640                 $this_obj_ext = $nonansi_obj;
1641             }
1642             $object = $base . $this_obj_ext;
1643
1644             if ($have_per_exec_flags)
1645             {
1646                 # We have a per-executable flag in effect for this
1647                 # object.  In this case we rewrite the object's
1648                 # name to ensure it is unique.
1649
1650                 # We choose the name `DERIVED_OBJECT' to ensure
1651                 # (1) uniqueness, and (2) continuity between
1652                 # invocations.  However, this will result in a
1653                 # name that is too long for losing systems, in
1654                 # some situations.  So we provide _SHORTNAME to
1655                 # override.
1656
1657                 my $dname = $derived;
1658                 my $var = var ($derived . '_SHORTNAME');
1659                 if ($var)
1660                 {
1661                     # FIXME: should use the same Condition as
1662                     # the _SOURCES variable.  But this is really
1663                     # silly overkill -- nobody should have
1664                     # conditional shortnames.
1665                     $dname = $var->variable_value;
1666                 }
1667                 $object = $dname . '-' . $object;
1668
1669                 prog_error ($lang->name . " flags defined without compiler")
1670                   if ! defined $lang->compile;
1671
1672                 $renamed = 1;
1673             }
1674
1675             # If rewrite said it was ok, put the object into a
1676             # subdir.
1677             if ($r == LANG_SUBDIR && $directory ne '')
1678             {
1679                 $object = $directory . '/' . $object;
1680             }
1681
1682             # If the object file has been renamed (because per-target
1683             # flags are used) we cannot compile the file with an
1684             # inference rule: we need an explicit rule.
1685             #
1686             # If the source is in a subdirectory and the object is in
1687             # the current directory, we also need an explicit rule.
1688             #
1689             # If both source and object files are in a subdirectory
1690             # (this happens when the subdir-objects option is used),
1691             # then the inference will work.
1692             #
1693             # The latter case deserves a historical note.  When the
1694             # subdir-objects option was added on 1999-04-11 it was
1695             # thought that inferences rules would work for
1696             # subdirectory objects too.  Later, on 1999-11-22,
1697             # automake was changed to output explicit rules even for
1698             # subdir-objects.  Nobody remembers why, but this occured
1699             # soon after the merge of the user-dep-gen-branch so it
1700             # might be related.  In late 2003 people complained about
1701             # the size of the generated Makefile.ins (libgcj, with
1702             # 2200+ subdir objects was reported to have a 9MB
1703             # Makefile), so we now rely on inference rules again.
1704             # Maybe we'll run across the same issue as in the past,
1705             # but at least this time we can document it.  However since
1706             # dependency tracking has evolved it is possible that
1707             # our old problem no longer exists.
1708             # Using inference rules for subdir-objects has been tested
1709             # with GNU make, Solaris make, Ultrix make, BSD make,
1710             # HP-UX make, and OSF1 make successfully.
1711             if ($renamed
1712                 || ($directory ne '' && ! option 'subdir-objects')
1713                 # We must also use specific rules for a nodist_ source
1714                 # if its language requests it.
1715                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1716             {
1717                 my $obj_sans_ext = substr ($object, 0,
1718                                            - length ($this_obj_ext));
1719                 my $full_ansi = $full;
1720                 if ($lang->ansi && option 'ansi2knr')
1721                   {
1722                     $full_ansi =~ s/$KNOWN_EXTENSIONS_PATTERN$/\$U$&/;
1723                     $obj_sans_ext .= '$U';
1724                   }
1725
1726                 my @specifics = ($full_ansi, $obj_sans_ext,
1727                                  # Only use $this_obj_ext in the derived
1728                                  # source case because in the other case we
1729                                  # *don't* want $(OBJEXT) to appear here.
1730                                  ($derived_source ? $this_obj_ext : '.o'));
1731
1732                 # If we renamed the object then we want to use the
1733                 # per-executable flag name.  But if this is simply a
1734                 # subdir build then we still want to use the AM_ flag
1735                 # name.
1736                 if ($renamed)
1737                   {
1738                     unshift @specifics, $derived;
1739                     $aggregate = $derived;
1740                   }
1741                 else
1742                   {
1743                     unshift @specifics, 'AM';
1744                   }
1745
1746                 # Each item on this list is a reference to a list consisting
1747                 # of four values followed by additional transform flags for
1748                 # file_contents.   The four values are the derived flag prefix
1749                 # (e.g. for `foo_CFLAGS', it is `foo'), the name of the
1750                 # source file, the base name of the output file, and
1751                 # the extension for the object file.
1752                 push (@{$lang_specific_files{$lang->name}},
1753                       [@specifics, %transform]);
1754             }
1755         }
1756         elsif ($extension eq $nonansi_obj)
1757         {
1758             # This is probably the result of a direct suffix rule.
1759             # In this case we just accept the rewrite.
1760             $object = "$base$extension";
1761             $linker = '';
1762         }
1763         else
1764         {
1765             # No error message here.  Used to have one, but it was
1766             # very unpopular.
1767             # FIXME: we could potentially do more processing here,
1768             # perhaps treating the new extension as though it were a
1769             # new source extension (as above).  This would require
1770             # more restructuring than is appropriate right now.
1771             next;
1772         }
1773
1774         err_am "object `$object' created by `$full' and `$object_map{$object}'"
1775           if (defined $object_map{$object}
1776               && $object_map{$object} ne $full);
1777
1778         my $comp_val = (($object =~ /\.lo$/)
1779                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1780         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1781         if (defined $object_compilation_map{$comp_obj}
1782             && $object_compilation_map{$comp_obj} != 0
1783             # Only see the error once.
1784             && ($object_compilation_map{$comp_obj}
1785                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1786             && $object_compilation_map{$comp_obj} != $comp_val)
1787           {
1788             err_am "object `$comp_obj' created both with libtool and without";
1789           }
1790         $object_compilation_map{$comp_obj} |= $comp_val;
1791
1792         if (defined $lang)
1793         {
1794             # Let the language do some special magic if required.
1795             $lang->target_hook ($aggregate, $object, $full, %transform);
1796         }
1797
1798         if ($derived_source)
1799           {
1800             prog_error ($lang->name . " has automatic dependency tracking")
1801               if $lang->autodep ne 'no';
1802             # Make sure this new source file is handled next.  That will
1803             # make it appear to be at the right place in the list.
1804             unshift (@files, $object);
1805             # Distribute derived sources unless the source they are
1806             # derived from is not.
1807             &push_dist_common ($object)
1808               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1809             next;
1810           }
1811
1812         $linkers_used{$linker} = 1;
1813
1814         push (@result, $object);
1815
1816         if (! defined $object_map{$object})
1817         {
1818             my @dep_list = ();
1819             $object_map{$object} = $full;
1820
1821             # If resulting object is in subdir, we need to make
1822             # sure the subdir exists at build time.
1823             if ($object =~ /\//)
1824             {
1825                 # FIXME: check that $DIRECTORY is somewhere in the
1826                 # project
1827
1828                 # For Java, the way we're handling it right now, a
1829                 # `..' component doesn't make sense.
1830                 if ($lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1831                   {
1832                     err_am "`$full' should not contain a `..' component";
1833                   }
1834
1835                 # Make sure object is removed by `make mostlyclean'.
1836                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1837                 # If we have a libtool object then we also must remove
1838                 # the ordinary .o.
1839                 if ($object =~ /\.lo$/)
1840                 {
1841                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1842                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1843
1844                     # Remove any libtool object in this directory.
1845                     $libtool_clean_directories{$directory} = 1;
1846                 }
1847
1848                 push (@dep_list, require_build_directory ($directory));
1849
1850                 # If we're generating dependencies, we also want
1851                 # to make sure that the appropriate subdir of the
1852                 # .deps directory is created.
1853                 push (@dep_list,
1854                       require_build_directory ($directory . '/$(DEPDIR)'))
1855                   unless option 'no-dependencies';
1856             }
1857
1858             &pretty_print_rule ($object . ':', "\t", @dep_list)
1859                 if scalar @dep_list > 0;
1860         }
1861
1862         # Transform .o or $o file into .P file (for automatic
1863         # dependency code).
1864         if ($lang && $lang->autodep ne 'no')
1865         {
1866             my $depfile = $object;
1867             $depfile =~ s/\.([^.]*)$/.P$1/;
1868             $depfile =~ s/\$\(OBJEXT\)$/o/;
1869             $dep_files{dirname ($depfile) . '/$(DEPDIR)/'
1870                          . basename ($depfile)} = 1;
1871         }
1872     }
1873
1874     return @result;
1875 }
1876
1877
1878 # $LINKER
1879 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
1880 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
1881 # ---------------------------------------------------------------------------
1882 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
1883 #
1884 # Arguments are:
1885 #   $VAR is the name of the _SOURCES variable
1886 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
1887 #     it will be generated and returned).
1888 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
1889 #     work done to determine the linker will be).
1890 #   $ONE_FILE is the canonical (transformed) name of object to build
1891 #   $OBJ is the object extension (i.e. either `.o' or `.lo').
1892 #   $TOPPARENT is the _SOURCES variable being processed.
1893 #   $WHERE context into which this definition is done
1894 #   %TRANSFORM extra arguments to pass to file_contents when producing
1895 #     rules
1896 #
1897 # Result is a pair ($LINKER, $OBJVAR):
1898 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
1899 sub define_objects_from_sources ($$$$$$$%)
1900 {
1901   my ($var, $objvar, $nodefine, $one_file,
1902       $obj, $topparent, $where, %transform) = @_;
1903
1904   my $needlinker = "";
1905
1906   transform_variable_recursively
1907     ($var, $objvar, 'am__objects', $nodefine, $where,
1908      # The transform code to run on each filename.
1909      sub {
1910        my ($subvar, $val, $cond, $full_cond) = @_;
1911        my @trans = handle_single_transform ($subvar, $topparent,
1912                                             $one_file, $obj, $val,
1913                                             %transform);
1914        $needlinker = "true" if @trans;
1915        return @trans;
1916      });
1917
1918   return $needlinker;
1919 }
1920
1921
1922 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
1923 # -----------------------------------------------------------------------------
1924 # Handle SOURCE->OBJECT transform for one program or library.
1925 # Arguments are:
1926 #   canonical (transformed) name of target to build
1927 #   actual target of object to build
1928 #   object extension (i.e., either `.o' or `$o')
1929 #   location of the source variable
1930 #   extra arguments to pass to file_contents when producing rules
1931 # Return the name of the linker variable that must be used.
1932 # Empty return means just use `LINK'.
1933 sub handle_source_transform ($$$$%)
1934 {
1935     # one_file is canonical name.  unxformed is given name.  obj is
1936     # object extension.
1937     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
1938
1939     my $linker = '';
1940
1941     # No point in continuing if _OBJECTS is defined.
1942     return if reject_var ($one_file . '_OBJECTS',
1943                           $one_file . '_OBJECTS should not be defined');
1944
1945     my %used_pfx = ();
1946     my $needlinker;
1947     %linkers_used = ();
1948     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1949                         'dist_EXTRA_', 'nodist_EXTRA_')
1950     {
1951         my $varname = $prefix . $one_file . "_SOURCES";
1952         my $var = var $varname;
1953         next unless $var;
1954
1955         # We are going to define _OBJECTS variables using the prefix.
1956         # Then we glom them all together.  So we can't use the null
1957         # prefix here as we need it later.
1958         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
1959
1960         # Keep track of which prefixes we saw.
1961         $used_pfx{$xpfx} = 1
1962           unless $prefix =~ /EXTRA_/;
1963
1964         push @sources, "\$($varname)";
1965         push @dist_sources, shadow_unconditionally ($varname, $where)
1966           unless (option ('no-dist') || $prefix =~ /^nodist_/);
1967
1968         $needlinker |=
1969             define_objects_from_sources ($varname,
1970                                          $xpfx . $one_file . '_OBJECTS',
1971                                          $prefix =~ /EXTRA_/,
1972                                          $one_file, $obj, $varname, $where,
1973                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
1974                                          %transform);
1975     }
1976     if ($needlinker)
1977     {
1978         $linker ||= &resolve_linker (%linkers_used);
1979     }
1980
1981     my @keys = sort keys %used_pfx;
1982     if (scalar @keys == 0)
1983     {
1984         # The default source for libfoo.la is libfoo.c, but for
1985         # backward compatibility we first look at libfoo_la.c
1986         my $old_default_source = "$one_file.c";
1987         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,.c,;
1988         if ($old_default_source ne $default_source
1989             && (rule $old_default_source
1990                 || rule '$(srcdir)/' . $old_default_source
1991                 || rule '${srcdir}/' . $old_default_source
1992                 || -f $old_default_source))
1993           {
1994             my $loc = $where->clone;
1995             $loc->pop_context;
1996             msg ('obsolete', $loc,
1997                  "the default source for `$unxformed' has been changed "
1998                  . "to `$default_source'.\n(Using `$old_default_source' for "
1999                  . "backward compatibility.)");
2000             $default_source = $old_default_source;
2001           }
2002         # If a rule exists to build this source with a $(srcdir)
2003         # prefix, use that prefix in our variables too.  This is for
2004         # the sake of BSD Make.
2005         if (rule '$(srcdir)/' . $default_source
2006             || rule '${srcdir}/' . $default_source)
2007           {
2008             $default_source = '$(srcdir)/' . $default_source;
2009           }
2010
2011         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2012         push (@sources, $default_source);
2013         push (@dist_sources, $default_source);
2014
2015         %linkers_used = ();
2016         my (@result) =
2017           handle_single_transform ($one_file . '_SOURCES',
2018                                    $one_file . '_SOURCES',
2019                                    $one_file, $obj,
2020                                    $default_source, %transform);
2021         $linker ||= &resolve_linker (%linkers_used);
2022         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2023     }
2024     else
2025     {
2026         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2027         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2028     }
2029
2030     # If we want to use `LINK' we must make sure it is defined.
2031     if ($linker eq '')
2032     {
2033         $need_link = 1;
2034     }
2035
2036     return $linker;
2037 }
2038
2039
2040 # handle_lib_objects ($XNAME, $VAR)
2041 # ---------------------------------
2042 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2043 # Also, generate _DEPENDENCIES variable if appropriate.
2044 # Arguments are:
2045 #   transformed name of object being built, or empty string if no object
2046 #   name of _LDADD/_LIBADD-type variable to examine
2047 # Returns 1 if LIBOBJS seen, 0 otherwise.
2048 sub handle_lib_objects
2049 {
2050   my ($xname, $varname) = @_;
2051
2052   my $var = var ($varname);
2053   prog_error "handle_lib_objects: `$varname' undefined"
2054     unless $var;
2055   prog_error "handle_lib_objects: unexpected variable name `$varname'"
2056     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2057   my $prefix = $1 || 'AM_';
2058
2059   my $seen_libobjs = 0;
2060   my $flagvar = 0;
2061
2062   transform_variable_recursively
2063     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2064      ! $xname, INTERNAL,
2065      # Transformation function, run on each filename.
2066      sub {
2067        my ($subvar, $val, $cond, $full_cond) = @_;
2068
2069        if ($val =~ /^-/)
2070          {
2071            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2072            if ($val !~ /^-[lL]/ &&
2073                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2074                # for Libtool libraries or programs.  (Actually we are a bit
2075                # laxest here since this code also applies to non-libtool
2076                # libraries or programs, for which -dlopen and -dlopreopen
2077                # are pure non-sence.  Diagnosting this doesn't seems very
2078                # important: the developer will quickly get complaints from
2079                # the linker.)
2080                $val !~ /^-dl(?:pre)?open$/ &&
2081                # Only get this error once.
2082                ! $flagvar)
2083              {
2084                $flagvar = 1;
2085                # FIXME: should display a stack of nested variables
2086                # as context when $var != $subvar.
2087                err_var ($var, "linker flags such as `$val' belong in "
2088                         . "`${prefix}LDFLAGS");
2089              }
2090            return ();
2091          }
2092        elsif ($val !~ /^\@.*\@$/)
2093          {
2094            # Assume we have a file of some sort, and output it into the
2095            # dependency variable.  Autoconf substitutions are not output;
2096            # rarely is a new dependency substituted into e.g. foo_LDADD
2097            # -- but bad things (e.g. -lX11) are routinely substituted.
2098            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2099            # and handled specially below.
2100            return $val;
2101          }
2102        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2103          {
2104            handle_LIBOBJS ($subvar, $cond, $1);
2105            $seen_libobjs = 1;
2106            return $val;
2107          }
2108        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2109          {
2110            handle_ALLOCA ($subvar, $cond, $1);
2111            return $val;
2112          }
2113        else
2114          {
2115            return ();
2116          }
2117      });
2118
2119   return $seen_libobjs;
2120 }
2121
2122 # handle_LIBOBJS_or_ALLOCA ($VAR)
2123 # -------------------------------
2124 # Definitions common to LIBOBJS and ALLOCA.
2125 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2126 sub handle_LIBOBJS_or_ALLOCA ($)
2127 {
2128   my ($var) = @_;
2129
2130   my $dir = $config_libobj_dir ? "$config_libobj_dir/" : '';
2131
2132   # If LIBOBJS files must be built in another directory we have
2133   # to define LIBOBJDIR and ensure the files get cleaned.
2134   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2135   # is achieved by `rm -f *.($OBJEXT)' in compile.am.
2136   if ($config_libobj_dir
2137       && $relative_dir ne $config_libobj_dir)
2138     {
2139       if (option 'subdir-objects')
2140         {
2141           define_variable ('LIBOBJDIR', "\$(top_builddir)/$dir", INTERNAL);
2142           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2143           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2144           # be created by libtool as a side-effect of creating LTLIBOBJS).
2145           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2146
2147         }
2148       else
2149         {
2150           error ("`\$($var)' cannot be used outside `$dir' if"
2151                  . " `subdir-objects' is not set");
2152         }
2153     }
2154
2155   return $dir;
2156 }
2157
2158 sub handle_LIBOBJS ($$$)
2159 {
2160   my ($var, $cond, $lt) = @_;
2161   $lt ||= '';
2162   my $myobjext = ($1 ? 'l' : '') . 'o';
2163
2164   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2165     if ! keys %libsources;
2166
2167   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2168
2169   foreach my $iter (keys %libsources)
2170     {
2171       if ($iter =~ /\.[cly]$/)
2172         {
2173           &saw_extension ($&);
2174           &saw_extension ('.c');
2175         }
2176
2177       if ($iter =~ /\.h$/)
2178         {
2179           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2180         }
2181       elsif ($iter ne 'alloca.c')
2182         {
2183           my $rewrite = $iter;
2184           $rewrite =~ s/\.c$/.P$myobjext/;
2185           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2186           $rewrite = "^" . quotemeta ($iter) . "\$";
2187           # Only require the file if it is not a built source.
2188           my $bs = var ('BUILT_SOURCES');
2189           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2190             {
2191               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2192             }
2193         }
2194     }
2195 }
2196
2197 sub handle_ALLOCA ($$$)
2198 {
2199   my ($var, $cond, $lt) = @_;
2200   my $myobjext = ($lt ? 'l' : '') . 'o';
2201   $lt ||= '';
2202   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2203
2204   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2205   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2206   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2207   &saw_extension ('.c');
2208 }
2209
2210 # Canonicalize the input parameter
2211 sub canonicalize
2212 {
2213     my ($string) = @_;
2214     $string =~ tr/A-Za-z0-9_\@/_/c;
2215     return $string;
2216 }
2217
2218 # Canonicalize a name, and check to make sure the non-canonical name
2219 # is never used.  Returns canonical name.  Arguments are name and a
2220 # list of suffixes to check for.
2221 sub check_canonical_spelling
2222 {
2223   my ($name, @suffixes) = @_;
2224
2225   my $xname = &canonicalize ($name);
2226   if ($xname ne $name)
2227     {
2228       foreach my $xt (@suffixes)
2229         {
2230           reject_var ("$name$xt", "use `$xname$xt', not `$name$xt'");
2231         }
2232     }
2233
2234   return $xname;
2235 }
2236
2237
2238 # handle_compile ()
2239 # -----------------
2240 # Set up the compile suite.
2241 sub handle_compile ()
2242 {
2243     return
2244       unless $get_object_extension_was_run;
2245
2246     # Boilerplate.
2247     my $default_includes = '';
2248     if (! option 'nostdinc')
2249       {
2250         $default_includes = ' -I. -I$(srcdir)';
2251
2252         my $var = var 'CONFIG_HEADER';
2253         if ($var)
2254           {
2255             foreach my $hdr (split (' ', $var->variable_value))
2256               {
2257                 $default_includes .= ' -I' . dirname ($hdr);
2258               }
2259           }
2260       }
2261
2262     my (@mostly_rms, @dist_rms);
2263     foreach my $item (sort keys %compile_clean_files)
2264     {
2265         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2266         {
2267             push (@mostly_rms, "\t-rm -f $item");
2268         }
2269         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2270         {
2271             push (@dist_rms, "\t-rm -f $item");
2272         }
2273         else
2274         {
2275           prog_error 'invalid entry in %compile_clean_files';
2276         }
2277     }
2278
2279     my ($coms, $vars, $rules) =
2280       &file_contents_internal (1, "$libdir/am/compile.am",
2281                                new Automake::Location,
2282                                ('DEFAULT_INCLUDES' => $default_includes,
2283                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2284                                 'DISTRMS' => join ("\n", @dist_rms)));
2285     $output_vars .= $vars;
2286     $output_rules .= "$coms$rules";
2287
2288     # Check for automatic de-ANSI-fication.
2289     if (option 'ansi2knr')
2290       {
2291         my ($ansi2knr_filename, $ansi2knr_where) = @{option 'ansi2knr'};
2292         my $ansi2knr_dir = '';
2293
2294         require_variables ($ansi2knr_where, "option `ansi2knr' is used",
2295                            TRUE, "ANSI2KNR", "U");
2296
2297         # topdir is where ansi2knr should be.
2298         if ($ansi2knr_filename eq 'ansi2knr')
2299           {
2300             # Only require ansi2knr files if they should appear in
2301             # this directory.
2302             require_file ($ansi2knr_where, FOREIGN,
2303                           'ansi2knr.c', 'ansi2knr.1');
2304
2305             # ansi2knr needs to be built before subdirs, so unshift it.
2306             unshift (@all, '$(ANSI2KNR)');
2307           }
2308         else
2309           {
2310             $ansi2knr_dir = dirname ($ansi2knr_filename);
2311           }
2312
2313         $output_rules .= &file_contents ('ansi2knr',
2314                                          new Automake::Location,
2315                                          'ANSI2KNR-DIR' => $ansi2knr_dir);
2316
2317     }
2318 }
2319
2320 # handle_libtool ()
2321 # -----------------
2322 # Handle libtool rules.
2323 sub handle_libtool
2324 {
2325   return unless var ('LIBTOOL');
2326
2327   # Libtool requires some files, but only at top level.
2328   # (Starting with Libtool 2.0 we do not have to bother.  These
2329   # requirements are done with AC_REQUIRE_AUX_FILE.)
2330   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2331     if $relative_dir eq '.' && ! $libtool_new_api;
2332
2333   my @libtool_rms;
2334   foreach my $item (sort keys %libtool_clean_directories)
2335     {
2336       my $dir = ($item eq '.') ? '' : "$item/";
2337       # .libs is for Unix, _libs for DOS.
2338       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2339     }
2340
2341   check_user_variables 'LIBTOOLFLAGS';
2342
2343   # Output the libtool compilation rules.
2344   $output_rules .= &file_contents ('libtool',
2345                                    new Automake::Location,
2346                                    LTRMS => join ("\n", @libtool_rms));
2347 }
2348
2349 # handle_programs ()
2350 # ------------------
2351 # Handle C programs.
2352 sub handle_programs
2353 {
2354   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2355                                   'bin', 'sbin', 'libexec', 'pkglib',
2356                                   'noinst', 'check');
2357   return if ! @proglist;
2358
2359   my $seen_global_libobjs =
2360     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2361
2362   foreach my $pair (@proglist)
2363     {
2364       my ($where, $one_file) = @$pair;
2365
2366       my $seen_libobjs = 0;
2367       my $obj = get_object_extension '.$(OBJEXT)';
2368
2369       # Strip any $(EXEEXT) suffix the user might have added, or this
2370       # will confuse &handle_source_transform and &check_canonical_spelling.
2371       # We'll add $(EXEEXT) back later anyway.
2372       $one_file =~ s/\$\(EXEEXT\)$//;
2373
2374       # Canonicalize names and check for misspellings.
2375       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2376                                              '_SOURCES', '_OBJECTS',
2377                                              '_DEPENDENCIES');
2378
2379       $where->push_context ("while processing program `$one_file'");
2380       $where->set (INTERNAL->get);
2381
2382       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2383                                              NONLIBTOOL => 1, LIBTOOL => 0);
2384
2385       if (var ($xname . "_LDADD"))
2386         {
2387           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2388         }
2389       else
2390         {
2391           # User didn't define prog_LDADD override.  So do it.
2392           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2393
2394           # This does a bit too much work.  But we need it to
2395           # generate _DEPENDENCIES when appropriate.
2396           if (var ('LDADD'))
2397             {
2398               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2399             }
2400         }
2401
2402       reject_var ($xname . '_LIBADD',
2403                   "use `${xname}_LDADD', not `${xname}_LIBADD'");
2404
2405       set_seen ($xname . '_DEPENDENCIES');
2406       set_seen ($xname . '_LDFLAGS');
2407
2408       # Determine program to use for link.
2409       my $xlink = &define_per_target_linker_variable ($linker, $xname);
2410
2411       # If the resulting program lies into a subdirectory,
2412       # make sure this directory will exist.
2413       my $dirstamp = require_build_directory_maybe ($one_file);
2414
2415       $output_rules .= &file_contents ('program',
2416                                        $where,
2417                                        PROGRAM  => $one_file,
2418                                        XPROGRAM => $xname,
2419                                        XLINK    => $xlink,
2420                                        DIRSTAMP => $dirstamp,
2421                                        EXEEXT   => '$(EXEEXT)');
2422
2423       if ($seen_libobjs || $seen_global_libobjs)
2424         {
2425           if (var ($xname . '_LDADD'))
2426             {
2427               &check_libobjs_sources ($xname, $xname . '_LDADD');
2428             }
2429           elsif (var ('LDADD'))
2430             {
2431               &check_libobjs_sources ($xname, 'LDADD');
2432             }
2433         }
2434     }
2435 }
2436
2437
2438 # handle_libraries ()
2439 # -------------------
2440 # Handle libraries.
2441 sub handle_libraries
2442 {
2443   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2444                                  'lib', 'pkglib', 'noinst', 'check');
2445   return if ! @liblist;
2446
2447   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2448                                     'noinst', 'check');
2449
2450   if (@prefix)
2451     {
2452       my $var = rvar ($prefix[0] . '_LIBRARIES');
2453       $var->requires_variables ('library used', 'RANLIB');
2454     }
2455
2456   &define_variable ('AR', 'ar', INTERNAL);
2457   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2458
2459   foreach my $pair (@liblist)
2460     {
2461       my ($where, $onelib) = @$pair;
2462
2463       my $seen_libobjs = 0;
2464       # Check that the library fits the standard naming convention.
2465       my $bn = basename ($onelib);
2466       if ($bn !~ /^lib.*\.a$/)
2467         {
2468           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2469           my $suggestion = dirname ($onelib) . "/$bn";
2470           $suggestion =~ s|^\./||g;
2471           msg ('error-gnu/warn', $where,
2472                "`$onelib' is not a standard library name\n"
2473                . "did you mean `$suggestion'?")
2474         }
2475
2476       $where->push_context ("while processing library `$onelib'");
2477       $where->set (INTERNAL->get);
2478
2479       my $obj = get_object_extension '.$(OBJEXT)';
2480
2481       # Canonicalize names and check for misspellings.
2482       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2483                                             '_OBJECTS', '_DEPENDENCIES',
2484                                             '_AR');
2485
2486       if (! var ($xlib . '_AR'))
2487         {
2488           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2489         }
2490
2491       # Generate support for conditional object inclusion in
2492       # libraries.
2493       if (var ($xlib . '_LIBADD'))
2494         {
2495           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2496             {
2497               $seen_libobjs = 1;
2498             }
2499         }
2500       else
2501         {
2502           &define_variable ($xlib . "_LIBADD", '', $where);
2503         }
2504
2505       reject_var ($xlib . '_LDADD',
2506                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2507
2508       # Make sure we at look at this.
2509       set_seen ($xlib . '_DEPENDENCIES');
2510
2511       &handle_source_transform ($xlib, $onelib, $obj, $where,
2512                                 NONLIBTOOL => 1, LIBTOOL => 0);
2513
2514       # If the resulting library lies into a subdirectory,
2515       # make sure this directory will exist.
2516       my $dirstamp = require_build_directory_maybe ($onelib);
2517
2518       $output_rules .= &file_contents ('library',
2519                                        $where,
2520                                        LIBRARY  => $onelib,
2521                                        XLIBRARY => $xlib,
2522                                        DIRSTAMP => $dirstamp);
2523
2524       if ($seen_libobjs)
2525         {
2526           if (var ($xlib . '_LIBADD'))
2527             {
2528               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2529             }
2530         }
2531     }
2532 }
2533
2534
2535 # handle_ltlibraries ()
2536 # ---------------------
2537 # Handle shared libraries.
2538 sub handle_ltlibraries
2539 {
2540   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2541                                  'noinst', 'lib', 'pkglib', 'check');
2542   return if ! @liblist;
2543
2544   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2545                                     'noinst', 'check');
2546
2547   if (@prefix)
2548     {
2549       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2550       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2551     }
2552
2553   my %instdirs = ();
2554   my %instconds = ();
2555   my %liblocations = ();        # Location (in Makefile.am) of each library.
2556
2557   foreach my $key (@prefix)
2558     {
2559       # Get the installation directory of each library.
2560       (my $dir = $key) =~ s/^nobase_//;
2561       my $var = rvar ($key . '_LTLIBRARIES');
2562
2563       # We reject libraries which are installed in several places
2564       # in the same condition, because we can only specify one
2565       # `-rpath' option.
2566       $var->traverse_recursively
2567         (sub
2568          {
2569            my ($var, $val, $cond, $full_cond) = @_;
2570            my $hcond = $full_cond->human;
2571            my $where = $var->rdef ($cond)->location;
2572            # A library cannot be installed in different directory
2573            # in overlapping conditions.
2574            if (exists $instconds{$val})
2575              {
2576                my ($msg, $acond) =
2577                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2578
2579                if ($msg)
2580                  {
2581                    error ($where, $msg, partial => 1);
2582
2583                    my $dirtxt = "installed in `$dir'";
2584                    $dirtxt = "built for `$dir'"
2585                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2586                    my $dircond =
2587                      $full_cond->true ? "" : " in condition $hcond";
2588
2589                    error ($where, "`$val' should be $dirtxt$dircond ...",
2590                           partial => 1);
2591
2592                    my $hacond = $acond->human;
2593                    my $adir = $instdirs{$val}{$acond};
2594                    my $adirtxt = "installed in `$adir'";
2595                    $adirtxt = "built for `$adir'"
2596                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2597                          || $adir eq 'check');
2598                    my $adircond = $acond->true ? "" : " in condition $hacond";
2599
2600                    my $onlyone = ($dir ne $adir) ?
2601                      ("\nLibtool libraries can be built for only one "
2602                       . "destination.") : "";
2603
2604                    error ($liblocations{$val}{$acond},
2605                           "... and should also be $adirtxt$adircond.$onlyone");
2606                    return;
2607                  }
2608              }
2609            else
2610              {
2611                $instconds{$val} = new Automake::DisjConditions;
2612              }
2613            $instdirs{$val}{$full_cond} = $dir;
2614            $liblocations{$val}{$full_cond} = $where;
2615            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2616          },
2617          sub
2618          {
2619            return ();
2620          },
2621          skip_ac_subst => 1);
2622     }
2623
2624   foreach my $pair (@liblist)
2625     {
2626       my ($where, $onelib) = @$pair;
2627
2628       my $seen_libobjs = 0;
2629       my $obj = get_object_extension '.lo';
2630
2631       # Canonicalize names and check for misspellings.
2632       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2633                                             '_SOURCES', '_OBJECTS',
2634                                             '_DEPENDENCIES');
2635
2636       # Check that the library fits the standard naming convention.
2637       my $libname_rx = '^lib.*\.la';
2638       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2639       my $ldvar2 = var ('LDFLAGS');
2640       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2641           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2642         {
2643           # Relax name checking for libtool modules.
2644           $libname_rx = '\.la';
2645         }
2646
2647       my $bn = basename ($onelib);
2648       if ($bn !~ /$libname_rx$/)
2649         {
2650           my $type = 'library';
2651           if ($libname_rx eq '\.la')
2652             {
2653               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2654               $type = 'module';
2655             }
2656           else
2657             {
2658               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2659             }
2660           my $suggestion = dirname ($onelib) . "/$bn";
2661           $suggestion =~ s|^\./||g;
2662           msg ('error-gnu/warn', $where,
2663                "`$onelib' is not a standard libtool $type name\n"
2664                . "did you mean `$suggestion'?")
2665         }
2666
2667       $where->push_context ("while processing Libtool library `$onelib'");
2668       $where->set (INTERNAL->get);
2669
2670       # Make sure we look at these.
2671       set_seen ($xlib . '_LDFLAGS');
2672       set_seen ($xlib . '_DEPENDENCIES');
2673
2674       # Generate support for conditional object inclusion in
2675       # libraries.
2676       if (var ($xlib . '_LIBADD'))
2677         {
2678           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2679             {
2680               $seen_libobjs = 1;
2681             }
2682         }
2683       else
2684         {
2685           &define_variable ($xlib . "_LIBADD", '', $where);
2686         }
2687
2688       reject_var ("${xlib}_LDADD",
2689                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2690
2691
2692       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2693                                              NONLIBTOOL => 0, LIBTOOL => 1);
2694
2695       # Determine program to use for link.
2696       my $xlink = &define_per_target_linker_variable ($linker, $xlib);
2697
2698       my $rpathvar = "am_${xlib}_rpath";
2699       my $rpath = "\$($rpathvar)";
2700       foreach my $rcond ($instconds{$onelib}->conds)
2701         {
2702           my $val;
2703           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2704               || $instdirs{$onelib}{$rcond} eq 'noinst'
2705               || $instdirs{$onelib}{$rcond} eq 'check')
2706             {
2707               # It's an EXTRA_ library, so we can't specify -rpath,
2708               # because we don't know where the library will end up.
2709               # The user probably knows, but generally speaking automake
2710               # doesn't -- and in fact configure could decide
2711               # dynamically between two different locations.
2712               $val = '';
2713             }
2714           else
2715             {
2716               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2717             }
2718           if ($rcond->true)
2719             {
2720               # If $rcond is true there is only one condition and
2721               # there is no point defining an helper variable.
2722               $rpath = $val;
2723             }
2724           else
2725             {
2726               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2727             }
2728         }
2729
2730       # If the resulting library lies into a subdirectory,
2731       # make sure this directory will exist.
2732       my $dirstamp = require_build_directory_maybe ($onelib);
2733
2734       # Remember to cleanup .libs/ in this directory.
2735       my $dirname = dirname $onelib;
2736       $libtool_clean_directories{$dirname} = 1;
2737
2738       $output_rules .= &file_contents ('ltlibrary',
2739                                        $where,
2740                                        LTLIBRARY  => $onelib,
2741                                        XLTLIBRARY => $xlib,
2742                                        RPATH      => $rpath,
2743                                        XLINK      => $xlink,
2744                                        DIRSTAMP   => $dirstamp);
2745       if ($seen_libobjs)
2746         {
2747           if (var ($xlib . '_LIBADD'))
2748             {
2749               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2750             }
2751         }
2752     }
2753 }
2754
2755 # See if any _SOURCES variable were misspelled.
2756 sub check_typos ()
2757 {
2758   # It is ok if the user sets this particular variable.
2759   set_seen 'AM_LDFLAGS';
2760
2761   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2762     {
2763       foreach my $var (variables $primary)
2764         {
2765           my $varname = $var->name;
2766           # A configure variable is always legitimate.
2767           next if exists $configure_vars{$varname};
2768
2769           for my $cond ($var->conditions->conds)
2770             {
2771               $varname =~ /^(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2772               msg_var ('syntax', $var, "variable `$varname' is defined but no"
2773                        . " program or\nlibrary has `$1' as canonic name"
2774                        . " (possible typo)")
2775                 unless $var->rdef ($cond)->seen;
2776             }
2777         }
2778     }
2779 }
2780
2781
2782 # Handle scripts.
2783 sub handle_scripts
2784 {
2785     # NOTE we no longer automatically clean SCRIPTS, because it is
2786     # useful to sometimes distribute scripts verbatim.  This happens
2787     # e.g. in Automake itself.
2788     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2789                      'bin', 'sbin', 'libexec', 'pkgdata',
2790                      'noinst', 'check');
2791 }
2792
2793
2794
2795
2796 ## ------------------------ ##
2797 ## Handling Texinfo files.  ##
2798 ## ------------------------ ##
2799
2800 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2801 # &scan_texinfo_file ($FILENAME)
2802 # ------------------------------
2803 # $OUTFILE     - name of the info file produced by $FILENAME.
2804 # $VFILE       - name of the version.texi file used (undef if none).
2805 # @CLEAN_FILES - list of byproducts (indexes etc.)
2806 sub scan_texinfo_file ($)
2807 {
2808   my ($filename) = @_;
2809
2810   # Some of the following extensions are always created, no matter
2811   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2812   # are only created when they are used.  We used to scan $FILENAME
2813   # for their use, but that is not enough: they could be used in
2814   # included files.  We can't scan included files because we don't
2815   # know the include path.  Therefore we always erase these files, no
2816   # matter whether they are used or not.
2817   #
2818   # (tmp is only created if an @macro is used and a certain e-TeX
2819   # feature is not available.)
2820   my %clean_suffixes =
2821     map { $_ => 1 } (qw(aux log toc tmp
2822                         cp cps
2823                         fn fns
2824                         ky kys
2825                         vr vrs
2826                         tp tps
2827                         pg pgs)); # grep 'new.*index' texinfo.tex
2828
2829   my $texi = new Automake::XFile "< $filename";
2830   verb "reading $filename";
2831
2832   my ($outfile, $vfile);
2833   while ($_ = $texi->getline)
2834     {
2835       if (/^\@setfilename +(\S+)/)
2836         {
2837           # Honor only the first @setfilename.  (It's possible to have
2838           # more occurrences later if the manual shows examples of how
2839           # to use @setfilename...)
2840           next if $outfile;
2841
2842           $outfile = $1;
2843           if ($outfile =~ /\.(.+)$/ && $1 ne 'info')
2844             {
2845               error ("$filename:$.",
2846                      "output `$outfile' has unrecognized extension");
2847               return;
2848             }
2849         }
2850       # A "version.texi" file is actually any file whose name matches
2851       # "vers*.texi".
2852       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
2853         {
2854           $vfile = $1;
2855         }
2856
2857       # Try to find new or unused indexes.
2858
2859       # Creating a new category of index.
2860       elsif (/^\@def(code)?index (\w+)/)
2861         {
2862           $clean_suffixes{$2} = 1;
2863           $clean_suffixes{"$2s"} = 1;
2864         }
2865
2866       # Merging an index into an another.
2867       elsif (/^\@syn(code)?index (\w+) (\w+)/)
2868         {
2869           delete $clean_suffixes{"$2s"};
2870           $clean_suffixes{"$3s"} = 1;
2871         }
2872
2873     }
2874
2875   if (! $outfile)
2876     {
2877       err_am "`$filename' missing \@setfilename";
2878       return;
2879     }
2880
2881   my $infobase = basename ($filename);
2882   $infobase =~ s/\.te?xi(nfo)?$//;
2883   return ($outfile, $vfile,
2884           map { "$infobase.$_" } (sort keys %clean_suffixes));
2885 }
2886
2887
2888 # ($DIRSTAMP, @CLEAN_FILES)
2889 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
2890 # ------------------------------------------------------------------
2891 # SOURCE - the source Texinfo file
2892 # DEST - the destination Info file
2893 # INSRC - wether DEST should be built in the source tree
2894 # DEPENDENCIES - known dependencies
2895 sub output_texinfo_build_rules ($$$@)
2896 {
2897   my ($source, $dest, $insrc, @deps) = @_;
2898
2899   # Split `a.texi' into `a' and `.texi'.
2900   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
2901   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
2902
2903   $ssfx ||= "";
2904   $dsfx ||= "";
2905
2906   # We can output two kinds of rules: the "generic" rules use Make
2907   # suffix rules and are appropriate when $source and $dest do not lie
2908   # in a sub-directory; the "specific" rules are needed in the other
2909   # case.
2910   #
2911   # The former are output only once (this is not really apparent here,
2912   # but just remember that some logic deeper in Automake will not
2913   # output the same rule twice); while the later need to be output for
2914   # each Texinfo source.
2915   my $generic;
2916   my $makeinfoflags;
2917   my $sdir = dirname $source;
2918   if ($sdir eq '.' && dirname ($dest) eq '.')
2919     {
2920       $generic = 1;
2921       $makeinfoflags = '-I $(srcdir)';
2922     }
2923   else
2924     {
2925       $generic = 0;
2926       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
2927     }
2928
2929   # A directory can contain two kinds of info files: some built in the
2930   # source tree, and some built in the build tree.  The rules are
2931   # different in each case.  However we cannot output two different
2932   # set of generic rules.  Because in-source builds are more usual, we
2933   # use generic rules in this case and fall back to "specific" rules
2934   # for build-dir builds.  (It should not be a problem to invert this
2935   # if needed.)
2936   $generic = 0 unless $insrc;
2937
2938   # We cannot use a suffix rule to build info files with an empty
2939   # extension.  Otherwise we would output a single suffix inference
2940   # rule, with separate dependencies, as in
2941   #
2942   #    .texi:
2943   #             $(MAKEINFO) ...
2944   #    foo.info: foo.texi
2945   #
2946   # which confuse Solaris make.  (See the Autoconf manual for
2947   # details.)  Therefore we use a specific rule in this case.  This
2948   # applies to info files only (dvi and pdf files always have an
2949   # extension).
2950   my $generic_info = ($generic && $dsfx) ? 1 : 0;
2951
2952   # If the resulting file lie into a subdirectory,
2953   # make sure this directory will exist.
2954   my $dirstamp = require_build_directory_maybe ($dest);
2955
2956   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
2957
2958   $output_rules .= file_contents ('texibuild',
2959                                   new Automake::Location,
2960                                   DEPS             => "@deps",
2961                                   DEST_PREFIX      => $dpfx,
2962                                   DEST_INFO_PREFIX => $dipfx,
2963                                   DEST_SUFFIX      => $dsfx,
2964                                   DIRSTAMP         => $dirstamp,
2965                                   GENERIC          => $generic,
2966                                   GENERIC_INFO     => $generic_info,
2967                                   INSRC            => $insrc,
2968                                   MAKEINFOFLAGS    => $makeinfoflags,
2969                                   SOURCE           => ($generic
2970                                                        ? '$<' : $source),
2971                                   SOURCE_INFO      => ($generic_info
2972                                                        ? '$<' : $source),
2973                                   SOURCE_REAL      => $source,
2974                                   SOURCE_SUFFIX    => $ssfx,
2975                                   );
2976   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
2977 }
2978
2979
2980 # $TEXICLEANS
2981 # handle_texinfo_helper ($info_texinfos)
2982 # --------------------------------------
2983 # Handle all Texinfo source; helper for handle_texinfo.
2984 sub handle_texinfo_helper ($)
2985 {
2986   my ($info_texinfos) = @_;
2987   my (@infobase, @info_deps_list, @texi_deps);
2988   my %versions;
2989   my $done = 0;
2990   my @texi_cleans;
2991
2992   # Build a regex matching user-cleaned files.
2993   my $d = var 'DISTCLEANFILES';
2994   my $c = var 'CLEANFILES';
2995   my @f = ();
2996   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
2997   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
2998   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
2999   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3000
3001   foreach my $texi
3002       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3003     {
3004       my $infobase = $texi;
3005       $infobase =~ s/\.(txi|texinfo|texi)$//;
3006
3007       if ($infobase eq $texi)
3008         {
3009           # FIXME: report line number.
3010           err_am "texinfo file `$texi' has unrecognized extension";
3011           next;
3012         }
3013
3014       push @infobase, $infobase;
3015
3016       # If 'version.texi' is referenced by input file, then include
3017       # automatic versioning capability.
3018       my ($out_file, $vtexi, @clean_files) =
3019         scan_texinfo_file ("$relative_dir/$texi")
3020         or next;
3021       push (@texi_cleans, @clean_files);
3022
3023       # If the Texinfo source is in a subdirectory, create the
3024       # resulting info in this subdirectory.  If it is in the current
3025       # directory, try hard to not prefix "./" because it breaks the
3026       # generic rules.
3027       my $outdir = dirname ($texi) . '/';
3028       $outdir = "" if $outdir eq './';
3029       $out_file =  $outdir . $out_file;
3030
3031       # Until Automake 1.6.3, .info files were built in the
3032       # source tree.  This was an obstacle to the support of
3033       # non-distributed .info files, and non-distributed .texi
3034       # files.
3035       #
3036       # * Non-distributed .texi files is important in some packages
3037       #   where .texi files are built at make time, probably using
3038       #   other binaries built in the package itself, maybe using
3039       #   tools or information found on the build host.  Because
3040       #   these files are not distributed they are always rebuilt
3041       #   at make time; they should therefore not lie in the source
3042       #   directory.  One plan was to support this using
3043       #   nodist_info_TEXINFOS or something similar.  (Doing this
3044       #   requires some sanity checks.  For instance Automake should
3045       #   not allow:
3046       #      dist_info_TEXINFO = foo.texi
3047       #      nodist_foo_TEXINFO = included.texi
3048       #   because a distributed file should never depend on a
3049       #   non-distributed file.)
3050       #
3051       # * If .texi files are not distributed, then .info files should
3052       #   not be distributed either.  There are also cases where one
3053       #   want to distribute .texi files, but do not want to
3054       #   distribute the .info files.  For instance the Texinfo package
3055       #   distributes the tool used to build these files; it would
3056       #   be a waste of space to distribute them.  It's not clear
3057       #   which syntax we should use to indicate that .info files should
3058       #   not be distributed.  Akim Demaille suggested that eventually
3059       #   we switch to a new syntax:
3060       #   |  Maybe we should take some inspiration from what's already
3061       #   |  done in the rest of Automake.  Maybe there is too much
3062       #   |  syntactic sugar here, and you want
3063       #   |     nodist_INFO = bar.info
3064       #   |     dist_bar_info_SOURCES = bar.texi
3065       #   |     bar_texi_DEPENDENCIES = foo.texi
3066       #   |  with a bit of magic to have bar.info represent the whole
3067       #   |  bar*info set.  That's a lot more verbose that the current
3068       #   |  situation, but it is # not new, hence the user has less
3069       #   |  to learn.
3070       #   |
3071       #   |  But there is still too much room for meaningless specs:
3072       #   |     nodist_INFO = bar.info
3073       #   |     dist_bar_info_SOURCES = bar.texi
3074       #   |     dist_PS = bar.ps something-written-by-hand.ps
3075       #   |     nodist_bar_ps_SOURCES = bar.texi
3076       #   |     bar_texi_DEPENDENCIES = foo.texi
3077       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3078       #
3079       # Back to the point, it should be clear that in order to support
3080       # non-distributed .info files, we need to build them in the
3081       # build tree, not in the source tree (non-distributed .texi
3082       # files are less of a problem, because we do not output build
3083       # rules for them).  In Automake 1.7 .info build rules have been
3084       # largely cleaned up so that .info files get always build in the
3085       # build tree, even when distributed.  The idea was that
3086       #   (1) if during a VPATH build the .info file was found to be
3087       #       absent or out-of-date (in the source tree or in the
3088       #       build tree), Make would rebuild it in the build tree.
3089       #       If an up-to-date source-tree of the .info file existed,
3090       #       make would not rebuild it in the build tree.
3091       #   (2) having two copies of .info files, one in the source tree
3092       #       and one (newer) in the build tree is not a problem
3093       #       because `make dist' always pick files in the build tree
3094       #       first.
3095       # However it turned out the be a bad idea for several reasons:
3096       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3097       #     like GNU Make on point (1) above.  These implementations
3098       #     of Make would always rebuild .info files in the build
3099       #     tree, even if such files were up to date in the source
3100       #     tree.  Consequently, it was impossible to perform a VPATH
3101       #     build of a package containing Texinfo files using these
3102       #     Make implementations.
3103       #     (Refer to the Autoconf Manual, section "Limitation of
3104       #     Make", paragraph "VPATH", item "target lookup", for
3105       #     an account of the differences between these
3106       #     implementations.)
3107       #   * The GNU Coding Standards require these files to be built
3108       #     in the source-tree (when they are distributed, that is).
3109       #   * Keeping a fresher copy of distributed files in the
3110       #     build tree can be annoying during development because
3111       #     - if the files is kept under CVS, you really want it
3112       #       to be updated in the source tree
3113       #     - it is confusing that `make distclean' does not erase
3114       #       all files in the build tree.
3115       #
3116       # Consequently, starting with Automake 1.8, .info files are
3117       # built in the source tree again.  Because we still plan to
3118       # support non-distributed .info files at some point, we
3119       # have a single variable ($INSRC) that controls whether
3120       # the current .info file must be built in the source tree
3121       # or in the build tree.  Actually this variable is switched
3122       # off for .info files that appear to be cleaned; this is
3123       # for backward compatibility with package such as Texinfo,
3124       # which do things like
3125       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3126       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3127       #   # Do not create info files for distribution.
3128       #   dist-info:
3129       # in order not to distribute .info files.
3130       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3131
3132       my $soutdir = '$(srcdir)/' . $outdir;
3133       $outdir = $soutdir if $insrc;
3134
3135       # If user specified file_TEXINFOS, then use that as explicit
3136       # dependency list.
3137       @texi_deps = ();
3138       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3139
3140       my $canonical = canonicalize ($infobase);
3141       if (var ($canonical . "_TEXINFOS"))
3142         {
3143           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3144           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3145         }
3146
3147       my ($dirstamp, @cfiles) =
3148         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3149       push (@texi_cleans, @cfiles);
3150
3151       push (@info_deps_list, $out_file);
3152
3153       # If a vers*.texi file is needed, emit the rule.
3154       if ($vtexi)
3155         {
3156           err_am ("`$vtexi', included in `$texi', "
3157                   . "also included in `$versions{$vtexi}'")
3158             if defined $versions{$vtexi};
3159           $versions{$vtexi} = $texi;
3160
3161           # We number the stamp-vti files.  This is doable since the
3162           # actual names don't matter much.  We only number starting
3163           # with the second one, so that the common case looks nice.
3164           my $vti = ($done ? $done : 'vti');
3165           ++$done;
3166
3167           # This is ugly, but it is our historical practice.
3168           if ($config_aux_dir_set_in_configure_ac)
3169             {
3170               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3171                                             'mdate-sh');
3172             }
3173           else
3174             {
3175               require_file_with_macro (TRUE, 'info_TEXINFOS',
3176                                        FOREIGN, 'mdate-sh');
3177             }
3178
3179           my $conf_dir;
3180           if ($config_aux_dir_set_in_configure_ac)
3181             {
3182               $conf_dir = "$am_config_aux_dir/";
3183             }
3184           else
3185             {
3186               $conf_dir = '$(srcdir)/';
3187             }
3188           $output_rules .= file_contents ('texi-vers',
3189                                           new Automake::Location,
3190                                           TEXI     => $texi,
3191                                           VTI      => $vti,
3192                                           STAMPVTI => "${soutdir}stamp-$vti",
3193                                           VTEXI    => "$soutdir$vtexi",
3194                                           MDDIR    => $conf_dir,
3195                                           DIRSTAMP => $dirstamp);
3196         }
3197     }
3198
3199   # Handle location of texinfo.tex.
3200   my $need_texi_file = 0;
3201   my $texinfodir;
3202   if (var ('TEXINFO_TEX'))
3203     {
3204       # The user defined TEXINFO_TEX so assume he knows what he is
3205       # doing.
3206       $texinfodir = ('$(srcdir)/'
3207                      . dirname (variable_value ('TEXINFO_TEX')));
3208     }
3209   elsif (option 'cygnus')
3210     {
3211       $texinfodir = '$(top_srcdir)/../texinfo';
3212       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3213     }
3214   elsif ($config_aux_dir_set_in_configure_ac)
3215     {
3216       $texinfodir = $am_config_aux_dir;
3217       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3218       $need_texi_file = 2; # so that we require_conf_file later
3219     }
3220   else
3221     {
3222       $texinfodir = '$(srcdir)';
3223       $need_texi_file = 1;
3224     }
3225   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3226
3227   push (@dist_targets, 'dist-info');
3228
3229   if (! option 'no-installinfo')
3230     {
3231       # Make sure documentation is made and installed first.  Use
3232       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3233       # get run twice during "make all".
3234       unshift (@all, '$(INFO_DEPS)');
3235     }
3236
3237   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3238   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3239   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3240   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3241
3242   # This next isn't strictly needed now -- the places that look here
3243   # could easily be changed to look in info_TEXINFOS.  But this is
3244   # probably better, in case noinst_TEXINFOS is ever supported.
3245   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3246
3247   # Do some error checking.  Note that this file is not required
3248   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3249   # up above.
3250   if ($need_texi_file && ! option 'no-texinfo.tex')
3251     {
3252       if ($need_texi_file > 1)
3253         {
3254           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3255                                         'texinfo.tex');
3256         }
3257       else
3258         {
3259           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3260                                    'texinfo.tex');
3261         }
3262     }
3263
3264   return makefile_wrap ("", "\t  ", @texi_cleans);
3265 }
3266
3267
3268 # handle_texinfo ()
3269 # -----------------
3270 # Handle all Texinfo source.
3271 sub handle_texinfo ()
3272 {
3273   reject_var 'TEXINFOS', "`TEXINFOS' is an anachronism; use `info_TEXINFOS'";
3274   # FIXME: I think this is an obsolete future feature name.
3275   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3276
3277   my $info_texinfos = var ('info_TEXINFOS');
3278   my $texiclean = "";
3279   if ($info_texinfos)
3280     {
3281       $texiclean = handle_texinfo_helper ($info_texinfos);
3282     }
3283   $output_rules .=  file_contents ('texinfos',
3284                                    new Automake::Location,
3285                                    TEXICLEAN     => $texiclean,
3286                                    'LOCAL-TEXIS' => !!$info_texinfos);
3287 }
3288
3289
3290 # Handle any man pages.
3291 sub handle_man_pages
3292 {
3293   reject_var 'MANS', "`MANS' is an anachronism; use `man_MANS'";
3294
3295   # Find all the sections in use.  We do this by first looking for
3296   # "standard" sections, and then looking for any additional
3297   # sections used in man_MANS.
3298   my (%sections, %vlist);
3299   # We handle nodist_ for uniformity.  man pages aren't distributed
3300   # by default so it isn't actually very important.
3301   foreach my $pfx ('', 'dist_', 'nodist_')
3302     {
3303       # Add more sections as needed.
3304       foreach my $section ('0'..'9', 'n', 'l')
3305         {
3306           my $varname = $pfx . 'man' . $section . '_MANS';
3307           if (var ($varname))
3308             {
3309               $sections{$section} = 1;
3310               $varname = '$(' . $varname . ')';
3311               $vlist{$varname} = 1;
3312
3313               &push_dist_common ($varname)
3314                 if $pfx eq 'dist_';
3315             }
3316         }
3317
3318       my $varname = $pfx . 'man_MANS';
3319       my $var = var ($varname);
3320       if ($var)
3321         {
3322           foreach ($var->value_as_list_recursive)
3323             {
3324               # A page like `foo.1c' goes into man1dir.
3325               if (/\.([0-9a-z])([a-z]*)$/)
3326                 {
3327                   $sections{$1} = 1;
3328                 }
3329             }
3330
3331           $varname = '$(' . $varname . ')';
3332           $vlist{$varname} = 1;
3333           &push_dist_common ($varname)
3334             if $pfx eq 'dist_';
3335         }
3336     }
3337
3338   return unless %sections;
3339
3340   # Now for each section, generate an install and uninstall rule.
3341   # Sort sections so output is deterministic.
3342   foreach my $section (sort keys %sections)
3343     {
3344       $output_rules .= &file_contents ('mans',
3345                                        new Automake::Location,
3346                                        SECTION => $section);
3347     }
3348
3349   my @mans = sort keys %vlist;
3350   $output_vars .= file_contents ('mans-vars',
3351                                  new Automake::Location,
3352                                  MANS => "@mans");
3353
3354   push (@all, '$(MANS)')
3355     unless option 'no-installman';
3356 }
3357
3358 # Handle DATA variables.
3359 sub handle_data
3360 {
3361     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3362                      'data', 'dataroot', 'dvi', 'html', 'pdf', 'ps',
3363                      'sysconf', 'sharedstate', 'localstate',
3364                      'pkgdata', 'lisp', 'noinst', 'check');
3365 }
3366
3367 # Handle TAGS.
3368 sub handle_tags
3369 {
3370     my @tag_deps = ();
3371     my @ctag_deps = ();
3372     if (var ('SUBDIRS'))
3373     {
3374         $output_rules .= ("tags-recursive:\n"
3375                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3376                           # Never fail here if a subdir fails; it
3377                           # isn't important.
3378                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3379                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3380                           . "\tdone\n");
3381         push (@tag_deps, 'tags-recursive');
3382         &depend ('.PHONY', 'tags-recursive');
3383
3384         $output_rules .= ("ctags-recursive:\n"
3385                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3386                           # Never fail here if a subdir fails; it
3387                           # isn't important.
3388                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3389                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3390                           . "\tdone\n");
3391         push (@ctag_deps, 'ctags-recursive');
3392         &depend ('.PHONY', 'ctags-recursive');
3393     }
3394
3395     if (&saw_sources_p (1)
3396         || var ('ETAGS_ARGS')
3397         || @tag_deps)
3398     {
3399         my @config;
3400         foreach my $spec (@config_headers)
3401         {
3402             my ($out, @ins) = split_config_file_spec ($spec);
3403             foreach my $in (@ins)
3404               {
3405                 # If the config header source is in this directory,
3406                 # require it.
3407                 push @config, basename ($in)
3408                   if $relative_dir eq dirname ($in);
3409               }
3410         }
3411         $output_rules .= &file_contents ('tags',
3412                                          new Automake::Location,
3413                                          CONFIG    => "@config",
3414                                          TAGSDIRS  => "@tag_deps",
3415                                          CTAGSDIRS => "@ctag_deps");
3416
3417         set_seen 'TAGS_DEPENDENCIES';
3418     }
3419     elsif (reject_var ('TAGS_DEPENDENCIES',
3420                        "doesn't make sense to define `TAGS_DEPENDENCIES'"
3421                        . "without\nsources or `ETAGS_ARGS'"))
3422     {
3423     }
3424     else
3425     {
3426         # Every Makefile must define some sort of TAGS rule.
3427         # Otherwise, it would be possible for a top-level "make TAGS"
3428         # to fail because some subdirectory failed.
3429         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3430         # Ditto ctags.
3431         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3432     }
3433 }
3434
3435 # Handle multilib support.
3436 sub handle_multilib
3437 {
3438   if ($seen_multilib && $relative_dir eq '.')
3439     {
3440       $output_rules .= &file_contents ('multilib', new Automake::Location);
3441       push (@all, 'all-multi');
3442     }
3443 }
3444
3445
3446 # user_phony_rule ($NAME)
3447 # -----------------------
3448 # Return false if rule $NAME does not exist.  Otherwise,
3449 # declare it as phony, complete its definition (in case it is
3450 # conditional), and return its Automake::Rule instance.
3451 sub user_phony_rule ($)
3452 {
3453   my ($name) = @_;
3454   my $rule = rule $name;
3455   if ($rule)
3456     {
3457       depend ('.PHONY', $name);
3458       # Define $NAME in all condition where it is not already defined,
3459       # so that it is always OK to depend on $NAME.
3460       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3461         {
3462           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3463                                   $c, INTERNAL);
3464           $output_rules .= $c->subst_string . "$name:\n";
3465         }
3466     }
3467   return $rule;
3468 }
3469
3470
3471 # $BOOLEAN
3472 # &for_dist_common ($A, $B)
3473 # -------------------------
3474 # Subroutine for &handle_dist: sort files to dist.
3475 #
3476 # We put README first because it then becomes easier to make a
3477 # Usenet-compliant shar file (in these, README must be first).
3478 #
3479 # FIXME: do more ordering of files here.
3480 sub for_dist_common
3481 {
3482     return 0
3483         if $a eq $b;
3484     return -1
3485         if $a eq 'README';
3486     return 1
3487         if $b eq 'README';
3488     return $a cmp $b;
3489 }
3490
3491 # fill_dist_dirs(@FILES)
3492 # ----------------------
3493 # Record in %dist_dirs the directory part of any file passed.
3494 sub fill_dist_dirs (@)
3495 {
3496   my @copy = @_;
3497   foreach (@copy)
3498     {
3499       s/\$\(top_srcdir\)/$topsrcdir/;
3500       s/\$\(srcdir\)/./;
3501       # Strip any leading `./'.
3502       s,^(:?\./+)*,,;
3503       next unless s,/+[^/]+$,,;
3504       $dist_dirs{$_} = 1
3505         unless $_ eq '.';
3506     }
3507 }
3508
3509 # handle_dist
3510 # -----------
3511 # Handle 'dist' target.
3512 sub handle_dist ()
3513 {
3514   # Substutions for distdit.am
3515   my %transform;
3516
3517   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3518   # no-dist setting: target like `distclean' or `maintainer-clean' use it.
3519   my $subdirs = var ('SUBDIRS');
3520   if ($subdirs)
3521     {
3522       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3523       # to all possible directories, and use it.  If DIST_SUBDIRS is
3524       # defined, just use it.
3525
3526       # Note that we check DIST_SUBDIRS first on purpose, so that
3527       # we don't call has_conditional_contents for now reason.
3528       # (In the past one project used so many conditional subdirectories
3529       # that calling has_conditional_contents on SUBDIRS caused
3530       # automake to grow to 150Mb -- this should not happen with
3531       # the current implementation of has_conditional_contents,
3532       # but it's more efficient to avoid the call anyway.)
3533       if (var ('DIST_SUBDIRS'))
3534         {
3535         }
3536       elsif ($subdirs->has_conditional_contents)
3537         {
3538           define_pretty_variable
3539             ('DIST_SUBDIRS', TRUE, INTERNAL,
3540              uniq ($subdirs->value_as_list_recursive));
3541         }
3542       else
3543         {
3544           # We always define this because that is what `distclean'
3545           # wants.
3546           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3547                                   '$(SUBDIRS)');
3548         }
3549     }
3550
3551   # The remaining definitions are only required when a dist target is used.
3552   return if option 'no-dist';
3553
3554   # At least one of the archive formats must be enabled.
3555   if ($relative_dir eq '.')
3556     {
3557       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3558       $archive_defined ||=
3559         grep { option "dist-$_" } ('shar', 'zip', 'tarZ', 'bzip2');
3560       error (option 'no-dist-gzip',
3561              "no-dist-gzip specified but no dist-* specified, "
3562              . "at least one archive format must be enabled")
3563         unless $archive_defined;
3564     }
3565
3566   # Look for common files that should be included in distribution.
3567   # If the aux dir is set, and it does not have a Makefile.am, then
3568   # we check for these files there as well.
3569   my $check_aux = 0;
3570   if ($relative_dir eq '.'
3571       && $config_aux_dir_set_in_configure_ac)
3572     {
3573       if (! &is_make_dir ($config_aux_dir))
3574         {
3575           $check_aux = 1;
3576         }
3577     }
3578   foreach my $cfile (@common_files)
3579     {
3580       if (dir_has_case_matching_file ($relative_dir, $cfile)
3581           # The file might be absent, but if it can be built it's ok.
3582           || rule $cfile)
3583         {
3584           &push_dist_common ($cfile);
3585         }
3586
3587       # Don't use `elsif' here because a file might meaningfully
3588       # appear in both directories.
3589       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3590         {
3591           &push_dist_common ("$config_aux_dir/$cfile")
3592         }
3593     }
3594
3595   # We might copy elements from $configure_dist_common to
3596   # %dist_common if we think we need to.  If the file appears in our
3597   # directory, we would have discovered it already, so we don't
3598   # check that.  But if the file is in a subdir without a Makefile,
3599   # we want to distribute it here if we are doing `.'.  Ugly!
3600   if ($relative_dir eq '.')
3601     {
3602       foreach my $file (split (' ' , $configure_dist_common))
3603         {
3604           push_dist_common ($file)
3605             unless is_make_dir (dirname ($file));
3606         }
3607     }
3608
3609   # Files to distributed.  Don't use ->value_as_list_recursive
3610   # as it recursively expands `$(dist_pkgdata_DATA)' etc.
3611   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3612   @dist_common = uniq (sort for_dist_common (@dist_common));
3613   variable_delete 'DIST_COMMON';
3614   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3615
3616   # Now that we've processed DIST_COMMON, disallow further attempts
3617   # to set it.
3618   $handle_dist_run = 1;
3619
3620   # Scan EXTRA_DIST to see if we need to distribute anything from a
3621   # subdir.  If so, add it to the list.  I didn't want to do this
3622   # originally, but there were so many requests that I finally
3623   # relented.
3624   my $extra_dist = var ('EXTRA_DIST');
3625   # FIXME: This should be fixed to work with conditions.  That
3626   # will require only making the entries in %dist_dirs under the
3627   # appropriate condition.  This is meaningful if the nature of
3628   # the distribution should depend upon the configure options
3629   # used.
3630   fill_dist_dirs ($extra_dist->value_as_list_recursive (skip_ac_subst => 1))
3631     if $extra_dist;
3632
3633   # We have to check DIST_COMMON for extra directories in case the
3634   # user put a source used in AC_OUTPUT into a subdir.
3635   fill_dist_dirs (rvar ('DIST_COMMON')
3636                   ->value_as_list_recursive (skip_ac_subst => 1));
3637
3638   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3639   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3640
3641   # Prepend $(distdir) to each directory given.
3642   my %rewritten = map { '$(distdir)/' . "$_" => 1 } keys %dist_dirs;
3643   $transform{'DISTDIRS'} = join (' ', sort keys %rewritten);
3644
3645   # If the target `dist-hook' exists, make sure it is run.  This
3646   # allows users to do random weird things to the distribution
3647   # before it is packaged up.
3648   push (@dist_targets, 'dist-hook')
3649     if user_phony_rule 'dist-hook';
3650   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3651
3652   my $flm = option ('filename-length-max');
3653   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3654
3655   $output_rules .= &file_contents ('distdir',
3656                                    new Automake::Location,
3657                                    %transform,
3658                                    FILENAME_FILTER => $filename_filter);
3659 }
3660
3661
3662 # check_directory ($NAME, $WHERE)
3663 # -------------------------------
3664 # Ensure $NAME is a directory, and that it uses sane name.
3665 # Use $WHERE as a location in the diagnostic, if any.
3666 sub check_directory ($$)
3667 {
3668   my ($dir, $where) = @_;
3669
3670   error $where, "required directory $relative_dir/$dir does not exist"
3671     unless -d "$relative_dir/$dir";
3672
3673   # If an `obj/' directory exists, BSD make will enter it before
3674   # reading `Makefile'.  Hence the `Makefile' in the current directory
3675   # will not be read.
3676   #
3677   #  % cat Makefile
3678   #  all:
3679   #          echo Hello
3680   #  % cat obj/Makefile
3681   #  all:
3682   #          echo World
3683   #  % make      # GNU make
3684   #  echo Hello
3685   #  Hello
3686   #  % pmake     # BSD make
3687   #  echo World
3688   #  World
3689   msg ('portability', $where,
3690        "naming a subdirectory `obj' causes troubles with BSD make")
3691     if $dir eq 'obj';
3692
3693   # `aux' is probably the most important of the following forbidden name,
3694   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3695   msg ('portability', $where,
3696        "name `$dir' is reserved on W32 and DOS platforms")
3697     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3698 }
3699
3700 # check_directories_in_var ($VARIABLE)
3701 # ------------------------------------
3702 # Recursively check all items in variables $VARIABLE as directories
3703 sub check_directories_in_var ($)
3704 {
3705   my ($var) = @_;
3706   $var->traverse_recursively
3707     (sub
3708      {
3709        my ($var, $val, $cond, $full_cond) = @_;
3710        check_directory ($val, $var->rdef ($cond)->location);
3711        return ();
3712      },
3713      undef,
3714      skip_ac_subst => 1);
3715 }
3716
3717 # &handle_subdirs ()
3718 # ------------------
3719 # Handle subdirectories.
3720 sub handle_subdirs ()
3721 {
3722   my $subdirs = var ('SUBDIRS');
3723   return
3724     unless $subdirs;
3725
3726   check_directories_in_var $subdirs;
3727
3728   my $dsubdirs = var ('DIST_SUBDIRS');
3729   check_directories_in_var $dsubdirs
3730     if $dsubdirs;
3731
3732   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3733   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3734 }
3735
3736
3737 # ($REGEN, @DEPENDENCIES)
3738 # &scan_aclocal_m4
3739 # ----------------
3740 # If aclocal.m4 creation is automated, return the list of its dependencies.
3741 sub scan_aclocal_m4 ()
3742 {
3743   my $regen_aclocal = 0;
3744
3745   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3746   set_seen 'CONFIGURE_DEPENDENCIES';
3747
3748   if (-f 'aclocal.m4')
3749     {
3750       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3751
3752       my $aclocal = new Automake::XFile "< aclocal.m4";
3753       my $line = $aclocal->getline;
3754       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3755     }
3756
3757   my @ac_deps = ();
3758
3759   if (set_seen ('ACLOCAL_M4_SOURCES'))
3760     {
3761       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3762       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3763                "`ACLOCAL_M4_SOURCES' is obsolete.\n"
3764                . "It should be safe to simply remove it.");
3765     }
3766
3767   # Note that it might be possible that aclocal.m4 doesn't exist but
3768   # should be auto-generated.  This case probably isn't very
3769   # important.
3770
3771   return ($regen_aclocal, @ac_deps);
3772 }
3773
3774
3775 # Helper function for substitute_ac_subst_variables.
3776 sub substitute_ac_subst_variables_worker($)
3777 {
3778   my ($token) = @_;
3779   return "\@$token\@" if var $token;
3780   return "\${$token\}";
3781 }
3782
3783 # substitute_ac_subst_variables ($TEXT)
3784 # -------------------------------------
3785 # Replace any occurence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
3786 # variable.
3787 sub substitute_ac_subst_variables ($)
3788 {
3789   my ($text) = @_;
3790   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
3791   return $text;
3792 }
3793
3794 # @DEPENDENCIES
3795 # &prepend_srcdir (@INPUTS)
3796 # -------------------------
3797 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
3798 # if an input file has a directory part the same as the current
3799 # directory, then the directory part is simply replaced by $(srcdir).
3800 # But if the directory part is different, then $(top_srcdir) is
3801 # prepended.
3802 sub prepend_srcdir (@)
3803 {
3804   my (@inputs) = @_;
3805   my @newinputs;
3806
3807   foreach my $single (@inputs)
3808     {
3809       if (dirname ($single) eq $relative_dir)
3810         {
3811           push (@newinputs, '$(srcdir)/' . basename ($single));
3812         }
3813       else
3814         {
3815           push (@newinputs, '$(top_srcdir)/' . $single);
3816         }
3817     }
3818   return @newinputs;
3819 }
3820
3821 # @DEPENDENCIES
3822 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
3823 # ---------------------------------------------------
3824 # Compute a list of dependencies appropriate for the rebuild
3825 # rule of
3826 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
3827 # Also distribute $INPUTs which are not build by another AC_CONFIG_FILES.
3828 sub rewrite_inputs_into_dependencies ($@)
3829 {
3830   my ($file, @inputs) = @_;
3831   my @res = ();
3832
3833   for my $i (@inputs)
3834     {
3835       # We cannot create dependencies on shell variables.
3836       next if (substitute_ac_subst_variables $i) =~ /\$/;
3837
3838       if (exists $ac_config_files_location{$i})
3839         {
3840           my $di = dirname $i;
3841           if ($di eq $relative_dir)
3842             {
3843               $i = basename $i;
3844             }
3845           # In the top-level Makefile we do not use $(top_builddir), because
3846           # we are already there, and since the targets are built without
3847           # a $(top_builddir), it helps BSD Make to match them with
3848           # dependencies.
3849           elsif ($relative_dir ne '.')
3850             {
3851               $i = '$(top_builddir)/' . $i;
3852             }
3853         }
3854       else
3855         {
3856           msg ('error', $ac_config_files_location{$file},
3857                "required file `$i' not found")
3858             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
3859           ($i) = prepend_srcdir ($i);
3860           push_dist_common ($i);
3861         }
3862       push @res, $i;
3863     }
3864   return @res;
3865 }
3866
3867
3868
3869 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
3870 # ------------------------------------------------------------------
3871 # Handle remaking and configure stuff.
3872 # We need the name of the input file, to do proper remaking rules.
3873 sub handle_configure ($$$@)
3874 {
3875   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
3876
3877   prog_error 'empty @inputs'
3878     unless @inputs;
3879
3880   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
3881                                                             $makefile_in);
3882   my $rel_makefile = basename $makefile;
3883
3884   my $colon_infile = ':' . join (':', @inputs);
3885   $colon_infile = '' if $colon_infile eq ":$makefile.in";
3886   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
3887   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
3888   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
3889                           @configure_deps, @aclocal_m4_deps,
3890                           '$(top_srcdir)/' . $configure_ac);
3891   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
3892   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
3893   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
3894                           @configuredeps);
3895
3896   $output_rules .= file_contents
3897     ('configure',
3898      new Automake::Location,
3899      MAKEFILE              => $rel_makefile,
3900      'MAKEFILE-DEPS'       => "@rewritten",
3901      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
3902      'MAKEFILE-IN'         => $rel_makefile_in,
3903      'MAKEFILE-IN-DEPS'    => "@include_stack",
3904      'MAKEFILE-AM'         => $rel_makefile_am,
3905      STRICTNESS            => global_option 'cygnus'
3906                                 ? 'cygnus' : $strictness_name,
3907      'USE-DEPS'            => global_option 'no-dependencies'
3908                                 ? ' --ignore-deps' : '',
3909      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
3910      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4);
3911
3912   if ($relative_dir eq '.')
3913     {
3914       &push_dist_common ('acconfig.h')
3915         if -f 'acconfig.h';
3916     }
3917
3918   # If we have a configure header, require it.
3919   my $hdr_index = 0;
3920   my @distclean_config;
3921   foreach my $spec (@config_headers)
3922     {
3923       $hdr_index += 1;
3924       # $CONFIG_H_PATH: config.h from top level.
3925       my ($config_h_path, @ins) = split_config_file_spec ($spec);
3926       my $config_h_dir = dirname ($config_h_path);
3927
3928       # If the header is in the current directory we want to build
3929       # the header here.  Otherwise, if we're at the topmost
3930       # directory and the header's directory doesn't have a
3931       # Makefile, then we also want to build the header.
3932       if ($relative_dir eq $config_h_dir
3933           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
3934         {
3935           my ($cn_sans_dir, $stamp_dir);
3936           if ($relative_dir eq $config_h_dir)
3937             {
3938               $cn_sans_dir = basename ($config_h_path);
3939               $stamp_dir = '';
3940             }
3941           else
3942             {
3943               $cn_sans_dir = $config_h_path;
3944               if ($config_h_dir eq '.')
3945                 {
3946                   $stamp_dir = '';
3947                 }
3948               else
3949                 {
3950                   $stamp_dir = $config_h_dir . '/';
3951                 }
3952             }
3953
3954           # This will also distribute all inputs.
3955           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
3956
3957           # Cannot define rebuild rules for filenames with shell variables.
3958           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
3959
3960           # Header defined in this directory.
3961           my @files;
3962           if (-f $config_h_path . '.top')
3963             {
3964               push (@files, "$cn_sans_dir.top");
3965             }
3966           if (-f $config_h_path . '.bot')
3967             {
3968               push (@files, "$cn_sans_dir.bot");
3969             }
3970
3971           push_dist_common (@files);
3972
3973           # For now, acconfig.h can only appear in the top srcdir.
3974           if (-f 'acconfig.h')
3975             {
3976               push (@files, '$(top_srcdir)/acconfig.h');
3977             }
3978
3979           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
3980           $output_rules .=
3981             file_contents ('remake-hdr',
3982                            new Automake::Location,
3983                            FILES            => "@files",
3984                            CONFIG_H         => $cn_sans_dir,
3985                            CONFIG_HIN       => $ins[0],
3986                            CONFIG_H_DEPS    => "@ins",
3987                            CONFIG_H_PATH    => $config_h_path,
3988                            STAMP            => "$stamp");
3989
3990           push @distclean_config, $cn_sans_dir, $stamp;
3991         }
3992     }
3993
3994   $output_rules .= file_contents ('clean-hdr',
3995                                   new Automake::Location,
3996                                   FILES => "@distclean_config")
3997     if @distclean_config;
3998
3999   # Distribute and define mkinstalldirs only if it is already present
4000   # in the package, for backward compatibility (some people may still
4001   # use $(mkinstalldirs)).
4002   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4003   if (-f $mkidpath)
4004     {
4005       # Use require_file so that any existing script gets updated
4006       # by --force-missing.
4007       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4008       define_variable ('mkinstalldirs',
4009                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4010     }
4011   else
4012     {
4013       # Use $(install_sh), not $(mkdir_p) because the latter requires
4014       # at least one argument, and $(mkinstalldirs) used to work
4015       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4016       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4017     }
4018
4019   reject_var ('CONFIG_HEADER',
4020               "`CONFIG_HEADER' is an anachronism; now determined "
4021               . "automatically\nfrom `$configure_ac'");
4022
4023   my @config_h;
4024   foreach my $spec (@config_headers)
4025     {
4026       my ($out, @ins) = split_config_file_spec ($spec);
4027       # Generate CONFIG_HEADER define.
4028       if ($relative_dir eq dirname ($out))
4029         {
4030           push @config_h, basename ($out);
4031         }
4032       else
4033         {
4034           push @config_h, "\$(top_builddir)/$out";
4035         }
4036     }
4037   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4038     if @config_h;
4039
4040   # Now look for other files in this directory which must be remade
4041   # by config.status, and generate rules for them.
4042   my @actual_other_files = ();
4043   foreach my $lfile (@other_input_files)
4044     {
4045       my $file;
4046       my @inputs;
4047       if ($lfile =~ /^([^:]*):(.*)$/)
4048         {
4049           # This is the ":" syntax of AC_OUTPUT.
4050           $file = $1;
4051           @inputs = split (':', $2);
4052         }
4053       else
4054         {
4055           # Normal usage.
4056           $file = $lfile;
4057           @inputs = $file . '.in';
4058         }
4059
4060       # Automake files should not be stored in here, but in %MAKE_LIST.
4061       prog_error ("$lfile in \@other_input_files\n"
4062                   . "\@other_input_files = (@other_input_files)")
4063         if -f $file . '.am';
4064
4065       my $local = basename ($file);
4066
4067       # Make sure the dist directory for each input file is created.
4068       # We only have to do this at the topmost level though.  This
4069       # is a bit ugly but it easier than spreading out the logic,
4070       # especially in cases like AC_OUTPUT(foo/out:bar/in), where
4071       # there is no Makefile in bar/.
4072       fill_dist_dirs (@inputs)
4073         if $relative_dir eq '.';
4074
4075       # We skip files that aren't in this directory.  However, if
4076       # the file's directory does not have a Makefile, and we are
4077       # currently doing `.', then we create a rule to rebuild the
4078       # file in the subdir.
4079       my $fd = dirname ($file);
4080       if ($fd ne $relative_dir)
4081         {
4082           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4083             {
4084               $local = $file;
4085             }
4086           else
4087             {
4088               next;
4089             }
4090         }
4091
4092       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4093
4094       # Cannot output rules for shell variables.
4095       next if (substitute_ac_subst_variables $local) =~ /\$/;
4096
4097       $output_rules .= ($local . ': '
4098                         . '$(top_builddir)/config.status '
4099                         . "@rewritten_inputs\n"
4100                         . "\t"
4101                         . 'cd $(top_builddir) && '
4102                         . '$(SHELL) ./config.status '
4103                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4104                         . '$@'
4105                         . "\n");
4106       push (@actual_other_files, $local);
4107     }
4108
4109   # For links we should clean destinations and distribute sources.
4110   foreach my $spec (@config_links)
4111     {
4112       my ($link, $file) = split /:/, $spec;
4113       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4114       # the DEST:SRC form.
4115       next unless $file;
4116       my $where = $ac_config_files_location{$link};
4117
4118       # Skip destinations that contain shell variables.
4119       if ((substitute_ac_subst_variables $link) !~ /\$/)
4120         {
4121           # We skip links that aren't in this directory.  However, if
4122           # the link's directory does not have a Makefile, and we are
4123           # currently doing `.', then we add the link to CONFIG_CLEAN_FILES
4124           # in `.'s Makefile.in.
4125           my $local = basename ($link);
4126           my $fd = dirname ($link);
4127           if ($fd ne $relative_dir)
4128             {
4129               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4130                 {
4131                   $local = $link;
4132                 }
4133               else
4134                 {
4135                   $local = undef;
4136                 }
4137             }
4138           push @actual_other_files, $local if $local;
4139         }
4140
4141       # Do not process sources that contain shell variables.
4142       if ((substitute_ac_subst_variables $file) !~ /\$/)
4143         {
4144           my $fd = dirname ($file);
4145
4146           # Make sure the dist directory for each input file is created.
4147           # We only have to do this at the topmost level though.
4148           if ($relative_dir eq '.')
4149             {
4150               $dist_dirs{$fd} = 1;
4151             }
4152
4153           # We distribute files that are in this directory.
4154           # At the top-level (`.') we also distribute files whose
4155           # directory does not have a Makefile.
4156           if (($fd eq $relative_dir)
4157               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4158             {
4159               # The following will distribute $file as a side-effect when
4160               # it is appropriate (i.e., when $file is not already an output).
4161               # We do not need the result, just the side-effect.
4162               rewrite_inputs_into_dependencies ($link, $file);
4163             }
4164         }
4165     }
4166
4167   # These files get removed by "make distclean".
4168   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4169                           @actual_other_files);
4170 }
4171
4172 # Handle C headers.
4173 sub handle_headers
4174 {
4175     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4176                              'oldinclude', 'pkginclude',
4177                              'noinst', 'check');
4178     foreach (@r)
4179     {
4180       next unless $_->[1] =~ /\..*$/;
4181       &saw_extension ($&);
4182     }
4183 }
4184
4185 sub handle_gettext
4186 {
4187   return if ! $seen_gettext || $relative_dir ne '.';
4188
4189   my $subdirs = var 'SUBDIRS';
4190
4191   if (! $subdirs)
4192     {
4193       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4194       return;
4195     }
4196
4197   # Perform some sanity checks to help users get the right setup.
4198   # We disable these tests when po/ doesn't exist in order not to disallow
4199   # unusual gettext setups.
4200   #
4201   # Bruno Haible:
4202   # | The idea is:
4203   # |
4204   # |  1) If a package doesn't have a directory po/ at top level, it
4205   # |     will likely have multiple po/ directories in subpackages.
4206   # |
4207   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4208   # |     is used without 'external'. It is also useful to warn for the
4209   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4210   # |     warnings apply only to the usual layout of packages, therefore
4211   # |     they should both be disabled if no po/ directory is found at
4212   # |     top level.
4213
4214   if (-d 'po')
4215     {
4216       my @subdirs = $subdirs->value_as_list_recursive;
4217
4218       msg_var ('syntax', $subdirs,
4219                "AM_GNU_GETTEXT used but `po' not in SUBDIRS")
4220         if ! grep ($_ eq 'po', @subdirs);
4221
4222       # intl/ is not required when AM_GNU_GETTEXT is called with
4223       # the `external' option.
4224       msg_var ('syntax', $subdirs,
4225                "AM_GNU_GETTEXT used but `intl' not in SUBDIRS")
4226         if (! $seen_gettext_external
4227             && ! grep ($_ eq 'intl', @subdirs));
4228
4229       # intl/ should not be used with AM_GNU_GETTEXT([external])
4230       msg_var ('syntax', $subdirs,
4231                "`intl' should not be in SUBDIRS when "
4232                . "AM_GNU_GETTEXT([external]) is used")
4233         if ($seen_gettext_external && grep ($_ eq 'intl', @subdirs));
4234     }
4235
4236   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4237 }
4238
4239 # Handle footer elements.
4240 sub handle_footer
4241 {
4242     reject_rule ('.SUFFIXES',
4243                  "use variable `SUFFIXES', not target `.SUFFIXES'");
4244
4245     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4246     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4247     # anything else, by sticking it right after the default: target.
4248     $output_header .= ".SUFFIXES:\n";
4249     my $suffixes = var 'SUFFIXES';
4250     my @suffixes = Automake::Rule::suffixes;
4251     if (@suffixes || $suffixes)
4252     {
4253         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4254         # the output remains consistent.  However, $(SUFFIXES) is
4255         # always at the start of the list, unsorted.  This is done
4256         # because make will choose rules depending on the ordering of
4257         # suffixes, and this lets the user have some control.  Push
4258         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4259         # do not like variable substitutions on the .SUFFIXES line.
4260         my @user_suffixes = ($suffixes
4261                              ? $suffixes->value_as_list_recursive : ());
4262
4263         my %suffixes = map { $_ => 1 } @suffixes;
4264         delete @suffixes{@user_suffixes};
4265
4266         $output_header .= (".SUFFIXES: "
4267                            . join (' ', @user_suffixes, sort keys %suffixes)
4268                            . "\n");
4269     }
4270
4271     $output_trailer .= file_contents ('footer', new Automake::Location);
4272 }
4273
4274
4275 # Generate `make install' rules.
4276 sub handle_install ()
4277 {
4278   $output_rules .= &file_contents
4279     ('install',
4280      new Automake::Location,
4281      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4282                              ? (" \$(BUILT_SOURCES)\n"
4283                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4284                              : ''),
4285      'installdirs-local' => (user_phony_rule 'installdirs-local'
4286                              ? ' installdirs-local' : ''),
4287      am__installdirs => variable_value ('am__installdirs') || '');
4288 }
4289
4290
4291 # Deal with all and all-am.
4292 sub handle_all ($)
4293 {
4294     my ($makefile) = @_;
4295
4296     # Output `all-am'.
4297
4298     # Put this at the beginning for the sake of non-GNU makes.  This
4299     # is still wrong if these makes can run parallel jobs.  But it is
4300     # right enough.
4301     unshift (@all, basename ($makefile));
4302
4303     foreach my $spec (@config_headers)
4304       {
4305         my ($out, @ins) = split_config_file_spec ($spec);
4306         push (@all, basename ($out))
4307           if dirname ($out) eq $relative_dir;
4308       }
4309
4310     # Install `all' hooks.
4311     push (@all, "all-local")
4312       if user_phony_rule "all-local";
4313
4314     &pretty_print_rule ("all-am:", "\t\t", @all);
4315     &depend ('.PHONY', 'all-am', 'all');
4316
4317
4318     # Output `all'.
4319
4320     my @local_headers = ();
4321     push @local_headers, '$(BUILT_SOURCES)'
4322       if var ('BUILT_SOURCES');
4323     foreach my $spec (@config_headers)
4324       {
4325         my ($out, @ins) = split_config_file_spec ($spec);
4326         push @local_headers, basename ($out)
4327           if dirname ($out) eq $relative_dir;
4328       }
4329
4330     if (@local_headers)
4331       {
4332         # We need to make sure config.h is built before we recurse.
4333         # We also want to make sure that built sources are built
4334         # before any ordinary `all' targets are run.  We can't do this
4335         # by changing the order of dependencies to the "all" because
4336         # that breaks when using parallel makes.  Instead we handle
4337         # things explicitly.
4338         $output_all .= ("all: @local_headers"
4339                         . "\n\t"
4340                         . '$(MAKE) $(AM_MAKEFLAGS) '
4341                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4342                         . "\n\n");
4343       }
4344     else
4345       {
4346         $output_all .= "all: " . (var ('SUBDIRS')
4347                                   ? 'all-recursive' : 'all-am') . "\n\n";
4348       }
4349 }
4350
4351
4352 # &do_check_merge_target ()
4353 # -------------------------
4354 # Handle check merge target specially.
4355 sub do_check_merge_target ()
4356 {
4357   # Include user-defined local form of target.
4358   push @check_tests, 'check-local'
4359     if user_phony_rule 'check-local';
4360
4361   # In --cygnus mode, check doesn't depend on all.
4362   if (option 'cygnus')
4363     {
4364       # Just run the local check rules.
4365       pretty_print_rule ('check-am:', "\t\t", @check);
4366     }
4367   else
4368     {
4369       # The check target must depend on the local equivalent of
4370       # `all', to ensure all the primary targets are built.  Then it
4371       # must build the local check rules.
4372       $output_rules .= "check-am: all-am\n";
4373       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4374                          @check)
4375         if @check;
4376     }
4377   pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4378                      @check_tests)
4379     if @check_tests;
4380
4381   depend '.PHONY', 'check', 'check-am';
4382   # Handle recursion.  We have to honor BUILT_SOURCES like for `all:'.
4383   $output_rules .= ("check: "
4384                     . (var ('BUILT_SOURCES')
4385                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4386                        : '')
4387                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4388                     . "\n");
4389 }
4390
4391 # handle_clean ($MAKEFILE)
4392 # ------------------------
4393 # Handle all 'clean' targets.
4394 sub handle_clean ($)
4395 {
4396   my ($makefile) = @_;
4397
4398   # Clean the files listed in user variables if they exist.
4399   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4400     if var ('MOSTLYCLEANFILES');
4401   $clean_files{'$(CLEANFILES)'} = CLEAN
4402     if var ('CLEANFILES');
4403   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4404     if var ('DISTCLEANFILES');
4405   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4406     if var ('MAINTAINERCLEANFILES');
4407
4408   # Built sources are automatically removed by maintainer-clean.
4409   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4410     if var ('BUILT_SOURCES');
4411
4412   # Compute a list of "rm"s to run for each target.
4413   my %rms = (MOSTLY_CLEAN, [],
4414              CLEAN, [],
4415              DIST_CLEAN, [],
4416              MAINTAINER_CLEAN, []);
4417
4418   foreach my $file (keys %clean_files)
4419     {
4420       my $when = $clean_files{$file};
4421       prog_error 'invalid entry in %clean_files'
4422         unless exists $rms{$when};
4423
4424       my $rm = "rm -f $file";
4425       # If file is a variable, make sure when don't call `rm -f' without args.
4426       $rm ="test -z \"$file\" || $rm"
4427         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4428
4429       push @{$rms{$when}}, "\t-$rm\n";
4430     }
4431
4432   $output_rules .= &file_contents
4433     ('clean',
4434      new Automake::Location,
4435      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4436      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4437      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4438      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4439      MAKEFILE             => basename $makefile,
4440      );
4441 }
4442
4443
4444 # &target_cmp ($A, $B)
4445 # --------------------
4446 # Subroutine for &handle_factored_dependencies to let `.PHONY' and
4447 # other `.TARGETS' be last.
4448 sub target_cmp
4449 {
4450   return 0 if $a eq $b;
4451
4452   my $a1 = substr ($a, 0, 1);
4453   my $b1 = substr ($b, 0, 1);
4454   if ($a1 ne $b1)
4455     {
4456       return -1 if $b1 eq '.';
4457       return 1 if $a1 eq '.';
4458     }
4459   return $a cmp $b;
4460 }
4461
4462
4463 # &handle_factored_dependencies ()
4464 # --------------------------------
4465 # Handle everything related to gathered targets.
4466 sub handle_factored_dependencies
4467 {
4468   # Reject bad hooks.
4469   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4470                      'uninstall-exec-local', 'uninstall-exec-hook',
4471                      'uninstall-dvi-local',
4472                      'uninstall-html-local',
4473                      'uninstall-info-local',
4474                      'uninstall-pdf-local',
4475                      'uninstall-ps-local')
4476     {
4477       my $x = $utarg;
4478       $x =~ s/-.*-/-/;
4479       reject_rule ($utarg, "use `$x', not `$utarg'");
4480     }
4481
4482   reject_rule ('install-local',
4483                "use `install-data-local' or `install-exec-local', "
4484                . "not `install-local'");
4485
4486   reject_rule ('install-hook',
4487                "use `install-data-hook' or `install-exec-hook', "
4488                . "not `install-hook'");
4489
4490   # Install the -local hooks.
4491   foreach (keys %dependencies)
4492     {
4493       # Hooks are installed on the -am targets.
4494       s/-am$// or next;
4495       depend ("$_-am", "$_-local")
4496         if user_phony_rule "$_-local";
4497     }
4498
4499   # Install the -hook hooks.
4500   # FIXME: Why not be as liberal as we are with -local hooks?
4501   foreach ('install-exec', 'install-data', 'uninstall')
4502     {
4503       if (user_phony_rule "$_-hook")
4504         {
4505           $actions{"$_-am"} .=
4506             ("\t\@\$(NORMAL_INSTALL)\n"
4507              . "\t" . '$(MAKE) $(AM_MAKEFLAGS) ' . "$_-hook\n");
4508           depend ('.MAKE', "$_-am");
4509         }
4510     }
4511
4512   # All the required targets are phony.
4513   depend ('.PHONY', keys %required_targets);
4514
4515   # Actually output gathered targets.
4516   foreach (sort target_cmp keys %dependencies)
4517     {
4518       # If there is nothing about this guy, skip it.
4519       next
4520         unless (@{$dependencies{$_}}
4521                 || $actions{$_}
4522                 || $required_targets{$_});
4523
4524       # Define gathered targets in undefined conditions.
4525       # FIXME: Right now we must handle .PHONY as an exception,
4526       # because people write things like
4527       #    .PHONY: myphonytarget
4528       # to append dependencies.  This would not work if Automake
4529       # refrained from defining its own .PHONY target as it does
4530       # with other overridden targets.
4531       # Likewise for `.MAKE'.
4532       my @undefined_conds = (TRUE,);
4533       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4534         {
4535           @undefined_conds =
4536             Automake::Rule::define ($_, 'internal',
4537                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4538         }
4539       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4540       foreach my $cond (@undefined_conds)
4541         {
4542           my $condstr = $cond->subst_string;
4543           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4544           $output_rules .= $actions{$_} if defined $actions{$_};
4545           $output_rules .= "\n";
4546         }
4547     }
4548 }
4549
4550
4551 # &handle_tests_dejagnu ()
4552 # ------------------------
4553 sub handle_tests_dejagnu
4554 {
4555     push (@check_tests, 'check-DEJAGNU');
4556     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4557 }
4558
4559
4560 # Handle TESTS variable and other checks.
4561 sub handle_tests
4562 {
4563   if (option 'dejagnu')
4564     {
4565       &handle_tests_dejagnu;
4566     }
4567   else
4568     {
4569       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4570         {
4571           reject_var ($c, "`$c' defined but `dejagnu' not in "
4572                       . "`AUTOMAKE_OPTIONS'");
4573         }
4574     }
4575
4576   if (var ('TESTS'))
4577     {
4578       push (@check_tests, 'check-TESTS');
4579       $output_rules .= &file_contents ('check', new Automake::Location);
4580     }
4581 }
4582
4583 # Handle Emacs Lisp.
4584 sub handle_emacs_lisp
4585 {
4586   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4587                                  'lisp', 'noinst');
4588
4589   return if ! @elfiles;
4590
4591   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4592                           map { $_->[1] } @elfiles);
4593   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
4594                           '$(am__ELFILES:.el=.elc)');
4595   # This one can be overridden by users.
4596   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
4597
4598   push @all, '$(ELCFILES)';
4599
4600   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
4601                      'EMACS', 'lispdir');
4602   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
4603   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
4604 }
4605
4606 # Handle Python
4607 sub handle_python
4608 {
4609   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
4610                                  'noinst');
4611   return if ! @pyfiles;
4612
4613   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
4614   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
4615   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
4616 }
4617
4618 # Handle Java.
4619 sub handle_java
4620 {
4621     my @sourcelist = &am_install_var ('-candist',
4622                                       'java', 'JAVA',
4623                                       'java', 'noinst', 'check');
4624     return if ! @sourcelist;
4625
4626     my @prefix = am_primary_prefixes ('JAVA', 1,
4627                                       'java', 'noinst', 'check');
4628
4629     my $dir;
4630     foreach my $curs (@prefix)
4631       {
4632         next
4633           if $curs eq 'EXTRA';
4634
4635         err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
4636           if defined $dir;
4637         $dir = $curs;
4638       }
4639
4640
4641     push (@all, 'class' . $dir . '.stamp');
4642 }
4643
4644
4645 # Handle some of the minor options.
4646 sub handle_minor_options
4647 {
4648   if (option 'readme-alpha')
4649     {
4650       if ($relative_dir eq '.')
4651         {
4652           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
4653             {
4654               msg ('error-gnits', $package_version_location,
4655                    "version `$package_version' doesn't follow " .
4656                    "Gnits standards");
4657             }
4658           if (defined $1 && -f 'README-alpha')
4659             {
4660               # This means we have an alpha release.  See
4661               # GNITS_VERSION_PATTERN for details.
4662               push_dist_common ('README-alpha');
4663             }
4664         }
4665     }
4666 }
4667
4668 ################################################################
4669
4670 # ($OUTPUT, @INPUTS)
4671 # &split_config_file_spec ($SPEC)
4672 # -------------------------------
4673 # Decode the Autoconf syntax for config files (files, headers, links
4674 # etc.).
4675 sub split_config_file_spec ($)
4676 {
4677   my ($spec) = @_;
4678   my ($output, @inputs) = split (/:/, $spec);
4679
4680   push @inputs, "$output.in"
4681     unless @inputs;
4682
4683   return ($output, @inputs);
4684 }
4685
4686 # $input
4687 # locate_am (@POSSIBLE_SOURCES)
4688 # -----------------------------
4689 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
4690 # This functions returns the first *.in file for which a *.am exists.
4691 # It returns undef otherwise.
4692 sub locate_am (@)
4693 {
4694   my (@rest) = @_;
4695   my $input;
4696   foreach my $file (@rest)
4697     {
4698       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
4699         {
4700           $input = $file;
4701           last;
4702         }
4703     }
4704   return $input;
4705 }
4706
4707 my %make_list;
4708
4709 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
4710 # ---------------------------------------------------
4711 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
4712 # (or AC_OUTPUT).
4713 sub scan_autoconf_config_files ($$)
4714 {
4715   my ($where, $config_files) = @_;
4716
4717   # Look at potential Makefile.am's.
4718   foreach (split ' ', $config_files)
4719     {
4720       # Must skip empty string for Perl 4.
4721       next if $_ eq "\\" || $_ eq '';
4722
4723       # Handle $local:$input syntax.
4724       my ($local, @rest) = split (/:/);
4725       @rest = ("$local.in",) unless @rest;
4726       my $input = locate_am @rest;
4727       if ($input)
4728         {
4729           # We have a file that automake should generate.
4730           $make_list{$input} = join (':', ($local, @rest));
4731         }
4732       else
4733         {
4734           # We have a file that automake should cause to be
4735           # rebuilt, but shouldn't generate itself.
4736           push (@other_input_files, $_);
4737         }
4738       $ac_config_files_location{$local} = $where;
4739     }
4740 }
4741
4742
4743 # &scan_autoconf_traces ($FILENAME)
4744 # ---------------------------------
4745 sub scan_autoconf_traces ($)
4746 {
4747   my ($filename) = @_;
4748
4749   # Macros to trace, with their minimal number of arguments.
4750   #
4751   # IMPORTANT: If you add a macro here, you should also add this macro
4752   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
4753   my %traced = (
4754                 AC_CANONICAL_BUILD => 0,
4755                 AC_CANONICAL_HOST => 0,
4756                 AC_CANONICAL_TARGET => 0,
4757                 AC_CONFIG_AUX_DIR => 1,
4758                 AC_CONFIG_FILES => 1,
4759                 AC_CONFIG_HEADERS => 1,
4760                 AC_CONFIG_LIBOBJ_DIR => 1,
4761                 AC_CONFIG_LINKS => 1,
4762                 AC_INIT => 0,
4763                 AC_LIBSOURCE => 1,
4764                 AC_REQUIRE_AUX_FILE => 1,
4765                 AC_SUBST_TRACE => 1,
4766                 AM_AUTOMAKE_VERSION => 1,
4767                 AM_CONDITIONAL => 2,
4768                 AM_ENABLE_MULTILIB => 0,
4769                 AM_GNU_GETTEXT => 0,
4770                 AM_INIT_AUTOMAKE => 0,
4771                 AM_MAINTAINER_MODE => 0,
4772                 AM_PROG_CC_C_O => 0,
4773                 LT_SUPPORTED_TAG => 1,
4774                 _LT_AC_TAGCONFIG => 0,
4775                 m4_include => 1,
4776                 m4_sinclude => 1,
4777                 sinclude => 1,
4778               );
4779
4780   my $traces = ($ENV{AUTOCONF} || 'autoconf') . " ";
4781
4782   # Use a separator unlikely to be used, not `:', the default, which
4783   # has a precise meaning for AC_CONFIG_FILES and so on.
4784   $traces .= join (' ',
4785                    map { "--trace=$_" . ':\$f:\$l::\$n::\${::}%' }
4786                    (keys %traced));
4787
4788   my $tracefh = new Automake::XFile ("$traces $filename |");
4789   verb "reading $traces";
4790
4791   while ($_ = $tracefh->getline)
4792     {
4793       chomp;
4794       my ($here, @args) = split (/::/);
4795       my $where = new Automake::Location $here;
4796       my $macro = $args[0];
4797
4798       prog_error ("unrequested trace `$macro'")
4799         unless exists $traced{$macro};
4800
4801       # Skip and diagnose malformed calls.
4802       if ($#args < $traced{$macro})
4803         {
4804           msg ('syntax', $where, "not enough arguments for $macro");
4805           next;
4806         }
4807
4808       # Alphabetical ordering please.
4809       if ($macro eq 'AC_CANONICAL_BUILD')
4810         {
4811           if ($seen_canonical <= AC_CANONICAL_BUILD)
4812             {
4813               $seen_canonical = AC_CANONICAL_BUILD;
4814               $canonical_location = $where;
4815             }
4816         }
4817       elsif ($macro eq 'AC_CANONICAL_HOST')
4818         {
4819           if ($seen_canonical <= AC_CANONICAL_HOST)
4820             {
4821               $seen_canonical = AC_CANONICAL_HOST;
4822               $canonical_location = $where;
4823             }
4824         }
4825       elsif ($macro eq 'AC_CANONICAL_TARGET')
4826         {
4827           $seen_canonical = AC_CANONICAL_TARGET;
4828           $canonical_location = $where;
4829         }
4830       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
4831         {
4832           if ($seen_init_automake)
4833             {
4834               error ($where, "AC_CONFIG_AUX_DIR must be called before "
4835                      . "AM_INIT_AUTOMAKE...", partial => 1);
4836               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
4837             }
4838           $config_aux_dir = $args[1];
4839           $config_aux_dir_set_in_configure_ac = 1;
4840           $relative_dir = '.';
4841           check_directory ($config_aux_dir, $where);
4842         }
4843       elsif ($macro eq 'AC_CONFIG_FILES')
4844         {
4845           # Look at potential Makefile.am's.
4846           scan_autoconf_config_files ($where, $args[1]);
4847         }
4848       elsif ($macro eq 'AC_CONFIG_HEADERS')
4849         {
4850           foreach my $spec (split (' ', $args[1]))
4851             {
4852               my ($dest, @src) = split (':', $spec);
4853               $ac_config_files_location{$dest} = $where;
4854               push @config_headers, $spec;
4855             }
4856         }
4857       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
4858         {
4859           $config_libobj_dir = $args[1];
4860           $relative_dir = '.';
4861           check_directory ($config_libobj_dir, $where);
4862         }
4863       elsif ($macro eq 'AC_CONFIG_LINKS')
4864         {
4865           foreach my $spec (split (' ', $args[1]))
4866             {
4867               my ($dest, $src) = split (':', $spec);
4868               $ac_config_files_location{$dest} = $where;
4869               push @config_links, $spec;
4870             }
4871         }
4872       elsif ($macro eq 'AC_INIT')
4873         {
4874           if (defined $args[2])
4875             {
4876               $package_version = $args[2];
4877               $package_version_location = $where;
4878             }
4879         }
4880       elsif ($macro eq 'AC_LIBSOURCE')
4881         {
4882           $libsources{$args[1]} = $here;
4883         }
4884       elsif ($macro eq 'AC_SUBST_TRACE')
4885         {
4886           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
4887           # AC_SUBST(5), then too bad.
4888           $configure_vars{$args[1]} = $where
4889             if $args[1] =~ /^\w+$/;
4890         }
4891       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
4892         {
4893           error ($where,
4894                  "version mismatch.  This is Automake $VERSION,\n" .
4895                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
4896                  "comes from Automake $args[1].  You should recreate\n" .
4897                  "aclocal.m4 with aclocal and run automake again.\n",
4898                  # $? = 63 is used to indicate version mismatch to missing.
4899                  exit_code => 63)
4900             if $VERSION ne $args[1];
4901
4902           $seen_automake_version = 1;
4903         }
4904       elsif ($macro eq 'AM_CONDITIONAL')
4905         {
4906           $configure_cond{$args[1]} = $where;
4907         }
4908       elsif ($macro eq 'AM_ENABLE_MULTILIB')
4909         {
4910           $seen_multilib = $where;
4911         }
4912       elsif ($macro eq 'AM_GNU_GETTEXT')
4913         {
4914           $seen_gettext = $where;
4915           $ac_gettext_location = $where;
4916           $seen_gettext_external = grep ($_ eq 'external', @args);
4917         }
4918       elsif ($macro eq 'AM_INIT_AUTOMAKE')
4919         {
4920           $seen_init_automake = $where;
4921           if (defined $args[2])
4922             {
4923               $package_version = $args[2];
4924               $package_version_location = $where;
4925             }
4926           elsif (defined $args[1])
4927             {
4928               exit $exit_code
4929                 if (process_global_option_list ($where,
4930                                                 split (' ', $args[1])));
4931             }
4932         }
4933       elsif ($macro eq 'AM_MAINTAINER_MODE')
4934         {
4935           $seen_maint_mode = $where;
4936         }
4937       elsif ($macro eq 'AM_PROG_CC_C_O')
4938         {
4939           $seen_cc_c_o = $where;
4940         }
4941       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
4942         {
4943           # Only remember the first time a file is required.
4944           $required_aux_file{$args[1]} = $where
4945             unless exists $required_aux_file{$args[1]};
4946         }
4947       elsif ($macro eq 'm4_include'
4948              || $macro eq 'm4_sinclude'
4949              || $macro eq 'sinclude')
4950         {
4951           # Skip missing `sinclude'd files.
4952           next if $macro ne 'm4_include' && ! -f $args[1];
4953
4954           # Some modified versions of Autoconf don't use
4955           # forzen files.  Consequently it's possible that we see all
4956           # m4_include's performed during Autoconf's startup.
4957           # Obviously we don't want to distribute Autoconf's files
4958           # so we skip absolute filenames here.
4959           push @configure_deps, '$(top_srcdir)/' . $args[1]
4960             unless $here =~ m,^(?:\w:)?[\\/],;
4961           # Keep track of the greatest timestamp.
4962           if (-e $args[1])
4963             {
4964               my $mtime = mtime $args[1];
4965               $configure_deps_greatest_timestamp = $mtime
4966                 if $mtime > $configure_deps_greatest_timestamp;
4967             }
4968         }
4969       elsif ($macro eq 'LT_SUPPORTED_TAG')
4970         {
4971           $libtool_tags{$args[1]} = 1;
4972           $libtool_new_api = 1;
4973         }
4974       elsif ($macro eq '_LT_AC_TAGCONFIG')
4975         {
4976           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
4977           # We use it to detect whether tags are supported.  Our
4978           # prefered interface is LT_SUPPORTED_TAG, but it was
4979           # introduced in Libtool 1.6.
4980           if (0 == keys %libtool_tags)
4981             {
4982               # Hardcode the tags supported by Libtool 1.5.
4983               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
4984             }
4985         }
4986     }
4987
4988   $tracefh->close;
4989 }
4990
4991
4992 # &scan_autoconf_files ()
4993 # -----------------------
4994 # Check whether we use `configure.ac' or `configure.in'.
4995 # Scan it (and possibly `aclocal.m4') for interesting things.
4996 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
4997 sub scan_autoconf_files ()
4998 {
4999   # Reinitialize libsources here.  This isn't really necessary,
5000   # since we currently assume there is only one configure.ac.  But
5001   # that won't always be the case.
5002   %libsources = ();
5003
5004   # Keep track of the youngest configure dependency.
5005   $configure_deps_greatest_timestamp = mtime $configure_ac;
5006   if (-e 'aclocal.m4')
5007     {
5008       my $mtime = mtime 'aclocal.m4';
5009       $configure_deps_greatest_timestamp = $mtime
5010         if $mtime > $configure_deps_greatest_timestamp;
5011     }
5012
5013   scan_autoconf_traces ($configure_ac);
5014
5015   @configure_input_files = sort keys %make_list;
5016   # Set input and output files if not specified by user.
5017   if (! @input_files)
5018     {
5019       @input_files = @configure_input_files;
5020       %output_files = %make_list;
5021     }
5022
5023
5024   if (! $seen_init_automake)
5025     {
5026       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5027               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5028               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5029               . "and that aclocal.m4 was recently regenerated "
5030               . "(using aclocal).");
5031     }
5032   else
5033     {
5034       if (! $seen_automake_version)
5035         {
5036           if (-f 'aclocal.m4')
5037             {
5038               error ($seen_init_automake,
5039                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5040                      "an\nold Automake version.  You should recreate " .
5041                      "aclocal.m4\nwith aclocal and run automake again.\n",
5042                      # $? = 63 is used to indicate version mismatch to missing.
5043                      exit_code => 63);
5044             }
5045           else
5046             {
5047               error ($seen_init_automake,
5048                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5049                      "found,\nprobably because aclocal.m4 is missing...\n" .
5050                      "You should run aclocal to create this file, then\n" .
5051                      "run automake again.\n");
5052             }
5053         }
5054     }
5055
5056   locate_aux_dir ();
5057
5058   # Reorder @input_files so that the Makefile that distributes aux
5059   # files is processed last.  This is important because each directory
5060   # can require auxiliary scripts and we should wait until they have
5061   # been installed before distributing them.
5062
5063   # The Makefile.in that distribute the aux files is the one in
5064   # $config_aux_dir or the top-level Makefile.
5065   my $auxdirdist = is_make_dir ($config_aux_dir) ? $config_aux_dir : '.';
5066   my @new_input_files = ();
5067   while (@input_files)
5068     {
5069       my $in = pop @input_files;
5070       my @ins = split (/:/, $output_files{$in});
5071       if (dirname ($ins[0]) eq $auxdirdist)
5072         {
5073           push @new_input_files, $in;
5074           $automake_will_process_aux_dir = 1;
5075         }
5076       else
5077         {
5078           unshift @new_input_files, $in;
5079         }
5080     }
5081   @input_files = @new_input_files;
5082
5083   # If neither the auxdir/Makefile nor the ./Makefile are generated
5084   # by Automake, we won't distribute the aux files anyway.  Assume
5085   # the user know what (s)he does, and pretend we will distribute
5086   # them to disable the error in require_file_internal.
5087   $automake_will_process_aux_dir = 1 if ! is_make_dir ($auxdirdist);
5088
5089   # Look for some files we need.  Always check for these.  This
5090   # check must be done for every run, even those where we are only
5091   # looking at a subdir Makefile.  We must set relative_dir for
5092   # maybe_push_required_file to work.
5093   $relative_dir = '.';
5094   foreach my $file (keys %required_aux_file)
5095     {
5096       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5097     }
5098   err_am "`install.sh' is an anachronism; use `install-sh' instead"
5099     if -f $config_aux_dir . '/install.sh';
5100
5101   # Preserve dist_common for later.
5102   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5103
5104 }
5105
5106 ################################################################
5107
5108 # Set up for Cygnus mode.
5109 sub check_cygnus
5110 {
5111   my $cygnus = option 'cygnus';
5112   return unless $cygnus;
5113
5114   set_strictness ('foreign');
5115   set_option ('no-installinfo', $cygnus);
5116   set_option ('no-dependencies', $cygnus);
5117   set_option ('no-dist', $cygnus);
5118
5119   err_ac "`AM_MAINTAINER_MODE' required when --cygnus specified"
5120     if !$seen_maint_mode;
5121 }
5122
5123 # Do any extra checking for GNU standards.
5124 sub check_gnu_standards
5125 {
5126   if ($relative_dir eq '.')
5127     {
5128       # In top level (or only) directory.
5129       require_file ("$am_file.am", GNU,
5130                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5131
5132       # Accept one of these three licenses; default to COPYING.
5133       # Make sure we do not overwrite an existing license.
5134       my $license;
5135       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5136         {
5137           if (-f $_)
5138             {
5139               $license = $_;
5140               last;
5141             }
5142         }
5143       require_file ("$am_file.am", GNU, 'COPYING')
5144         unless $license;
5145     }
5146
5147   for my $opt ('no-installman', 'no-installinfo')
5148     {
5149       msg ('error-gnu', option $opt,
5150            "option `$opt' disallowed by GNU standards")
5151         if option $opt;
5152     }
5153 }
5154
5155 # Do any extra checking for GNITS standards.
5156 sub check_gnits_standards
5157 {
5158   if ($relative_dir eq '.')
5159     {
5160       # In top level (or only) directory.
5161       require_file ("$am_file.am", GNITS, 'THANKS');
5162     }
5163 }
5164
5165 ################################################################
5166 #
5167 # Functions to handle files of each language.
5168
5169 # Each `lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5170 # simple formula: Return value is LANG_SUBDIR if the resulting object
5171 # file should be in a subdir if the source file is, LANG_PROCESS if
5172 # file is to be dealt with, LANG_IGNORE otherwise.
5173
5174 # Much of the actual processing is handled in
5175 # handle_single_transform.  These functions exist so that
5176 # auxiliary information can be recorded for a later cleanup pass.
5177 # Note that the calls to these functions are computed, so don't bother
5178 # searching for their precise names in the source.
5179
5180 # This is just a convenience function that can be used to determine
5181 # when a subdir object should be used.
5182 sub lang_sub_obj
5183 {
5184     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5185 }
5186
5187 # Rewrite a single C source file.
5188 sub lang_c_rewrite
5189 {
5190   my ($directory, $base, $ext, $nonansi_obj, $have_per_exec_flags, $var) = @_;
5191
5192   if (option 'ansi2knr' && $base =~ /_$/)
5193     {
5194       # FIXME: include line number in error.
5195       err_am "C source file `$base.c' would be deleted by ansi2knr rules";
5196     }
5197
5198   my $r = LANG_PROCESS;
5199   if (option 'subdir-objects')
5200     {
5201       $r = LANG_SUBDIR;
5202       if ($directory && $directory ne '.')
5203         {
5204           $base = $directory . '/' . $base;
5205
5206           # libtool is always able to put the object at the proper place,
5207           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5208           err_var ($var, "compiling `$base.c' in subdir requires "
5209                    . "`AM_PROG_CC_C_O' in `$configure_ac'",
5210                    uniq_scope => US_GLOBAL,
5211                    uniq_part => 'AM_PROG_CC_C_O subdir')
5212             unless $seen_cc_c_o || $nonansi_obj eq '.lo';
5213         }
5214
5215       # In this case we already have the directory information, so
5216       # don't add it again.
5217       $de_ansi_files{$base} = '';
5218     }
5219   else
5220     {
5221       $de_ansi_files{$base} = (($directory eq '.' || $directory eq '')
5222                                ? ''
5223                                : "$directory/");
5224     }
5225
5226   if (! $seen_cc_c_o
5227       && $have_per_exec_flags
5228       && ! option 'subdir-objects'
5229       && $nonansi_obj ne '.lo')
5230     {
5231       err_var ($var, "compiling `$base.c' with per-target flags requires "
5232                . "`AM_PROG_CC_C_O' in `$configure_ac'",
5233                uniq_scope => US_GLOBAL,
5234                uniq_part => 'AM_PROG_CC_C_O per-target')
5235     }
5236
5237     return $r;
5238 }
5239
5240 # Rewrite a single C++ source file.
5241 sub lang_cxx_rewrite
5242 {
5243     return &lang_sub_obj;
5244 }
5245
5246 # Rewrite a single header file.
5247 sub lang_header_rewrite
5248 {
5249     # Header files are simply ignored.
5250     return LANG_IGNORE;
5251 }
5252
5253 # Rewrite a single yacc file.
5254 sub lang_yacc_rewrite
5255 {
5256     my ($directory, $base, $ext) = @_;
5257
5258     my $r = &lang_sub_obj;
5259     (my $newext = $ext) =~ tr/y/c/;
5260     return ($r, $newext);
5261 }
5262
5263 # Rewrite a single yacc++ file.
5264 sub lang_yaccxx_rewrite
5265 {
5266     my ($directory, $base, $ext) = @_;
5267
5268     my $r = &lang_sub_obj;
5269     (my $newext = $ext) =~ tr/y/c/;
5270     return ($r, $newext);
5271 }
5272
5273 # Rewrite a single lex file.
5274 sub lang_lex_rewrite
5275 {
5276     my ($directory, $base, $ext) = @_;
5277
5278     my $r = &lang_sub_obj;
5279     (my $newext = $ext) =~ tr/l/c/;
5280     return ($r, $newext);
5281 }
5282
5283 # Rewrite a single lex++ file.
5284 sub lang_lexxx_rewrite
5285 {
5286     my ($directory, $base, $ext) = @_;
5287
5288     my $r = &lang_sub_obj;
5289     (my $newext = $ext) =~ tr/l/c/;
5290     return ($r, $newext);
5291 }
5292
5293 # Rewrite a single assembly file.
5294 sub lang_asm_rewrite
5295 {
5296     return &lang_sub_obj;
5297 }
5298
5299 # Rewrite a single preprocessed assembly file.
5300 sub lang_cppasm_rewrite
5301 {
5302     return &lang_sub_obj;
5303 }
5304
5305 # Rewrite a single Fortran 77 file.
5306 sub lang_f77_rewrite
5307 {
5308     return LANG_PROCESS;
5309 }
5310
5311 # Rewrite a single Fortran file.
5312 sub lang_fc_rewrite
5313 {
5314     return LANG_PROCESS;
5315 }
5316
5317 # Rewrite a single preprocessed Fortran file.
5318 sub lang_ppfc_rewrite
5319 {
5320     return LANG_PROCESS;
5321 }
5322
5323 # Rewrite a single preprocessed Fortran 77 file.
5324 sub lang_ppf77_rewrite
5325 {
5326     return LANG_PROCESS;
5327 }
5328
5329 # Rewrite a single ratfor file.
5330 sub lang_ratfor_rewrite
5331 {
5332     return LANG_PROCESS;
5333 }
5334
5335 # Rewrite a single Objective C file.
5336 sub lang_objc_rewrite
5337 {
5338     return &lang_sub_obj;
5339 }
5340
5341 # Rewrite a single Java file.
5342 sub lang_java_rewrite
5343 {
5344     return LANG_SUBDIR;
5345 }
5346
5347 # The lang_X_finish functions are called after all source file
5348 # processing is done.  Each should handle defining rules for the
5349 # language, etc.  A finish function is only called if a source file of
5350 # the appropriate type has been seen.
5351
5352 sub lang_c_finish
5353 {
5354     # Push all libobjs files onto de_ansi_files.  We actually only
5355     # push files which exist in the current directory, and which are
5356     # genuine source files.
5357     foreach my $file (keys %libsources)
5358     {
5359         if ($file =~ /^(.*)\.[cly]$/ && -f "$relative_dir/$file")
5360         {
5361             $de_ansi_files{$1} = ''
5362         }
5363     }
5364
5365     if (option 'ansi2knr' && keys %de_ansi_files)
5366     {
5367         # Make all _.c files depend on their corresponding .c files.
5368         my @objects;
5369         foreach my $base (sort keys %de_ansi_files)
5370         {
5371             # Each _.c file must depend on ansi2knr; otherwise it
5372             # might be used in a parallel build before it is built.
5373             # We need to support files in the srcdir and in the build
5374             # dir (because these files might be auto-generated.  But
5375             # we can't use $< -- some makes only define $< during a
5376             # suffix rule.
5377             my $ansfile = $de_ansi_files{$base} . $base . '.c';
5378             $output_rules .= ($base . "_.c: $ansfile \$(ANSI2KNR)\n\t"
5379                               . '$(CPP) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) '
5380                               . '`if test -f $(srcdir)/' . $ansfile
5381                               . '; then echo $(srcdir)/' . $ansfile
5382                               . '; else echo ' . $ansfile . '; fi` '
5383                               . "| sed 's/^# \\([0-9]\\)/#line \\1/' "
5384                               . '| $(ANSI2KNR) > $@'
5385                               # If ansi2knr fails then we shouldn't
5386                               # create the _.c file
5387                               . " || rm -f \$\@\n");
5388             push (@objects, $base . '_.$(OBJEXT)');
5389             push (@objects, $base . '_.lo')
5390               if var ('LIBTOOL');
5391
5392             # Explicitly clean the _.c files if they are in a
5393             # subdirectory. (In the current directory they get erased
5394             # by a `rm -f *_.c' rule.)
5395             $clean_files{$base . '_.c'} = MOSTLY_CLEAN
5396               if dirname ($base) ne '.';
5397         }
5398
5399         # Make all _.o (and _.lo) files depend on ansi2knr.
5400         # Use a sneaky little hack to make it print nicely.
5401         &pretty_print_rule ('', '', @objects, ':', '$(ANSI2KNR)');
5402     }
5403 }
5404
5405 # This is a yacc helper which is called whenever we have decided to
5406 # compile a yacc file.
5407 sub lang_yacc_target_hook
5408 {
5409     my ($self, $aggregate, $output, $input, %transform) = @_;
5410
5411     my $flag = $aggregate . "_YFLAGS";
5412     my $flagvar = var $flag;
5413     my $YFLAGSvar = var 'YFLAGS';
5414     if (($flagvar && $flagvar->variable_value =~ /$DASH_D_PATTERN/o)
5415         || ($YFLAGSvar && $YFLAGSvar->variable_value =~ /$DASH_D_PATTERN/o))
5416     {
5417         (my $output_base = $output) =~ s/$KNOWN_EXTENSIONS_PATTERN$//;
5418         my $header = $output_base . '.h';
5419
5420         # Found a `-d' that applies to the compilation of this file.
5421         # Add a dependency for the generated header file, and arrange
5422         # for that file to be included in the distribution.
5423         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5424                                                   RULE_AUTOMAKE, TRUE,
5425                                                   INTERNAL))
5426           {
5427             my $condstr = $cond->subst_string;
5428             $output_rules .=
5429               "$condstr${header}: $output\n"
5430               # Recover from removal of $header
5431               . "$condstr\t\@if test ! -f \$@; then \\\n"
5432               . "$condstr\t  rm -f $output; \\\n"
5433               . "$condstr\t  \$(MAKE) \$(AM_MAKEFLAGS) $output; \\\n"
5434               . "$condstr\telse :; fi\n";
5435           }
5436         # Distribute the generated file, unless its .y source was
5437         # listed in a nodist_ variable.  (&handle_source_transform
5438         # will set DIST_SOURCE.)
5439         &push_dist_common ($header)
5440           if $transform{'DIST_SOURCE'};
5441
5442         # If the files are built in the build directory, then we want
5443         # to remove them with `make clean'.  If they are in srcdir
5444         # they shouldn't be touched.  However, we can't determine this
5445         # statically, and the GNU rules say that yacc/lex output files
5446         # should be removed by maintainer-clean.  So that's what we
5447         # do.
5448         $clean_files{$header} = MAINTAINER_CLEAN;
5449     }
5450     # Erase $OUTPUT on `make maintainer-clean' (by GNU standards).
5451     # See the comment above for $HEADER.
5452     $clean_files{$output} = MAINTAINER_CLEAN;
5453 }
5454
5455 # This is a lex helper which is called whenever we have decided to
5456 # compile a lex file.
5457 sub lang_lex_target_hook
5458 {
5459     my ($self, $aggregate, $output, $input) = @_;
5460     # If the files are built in the build directory, then we want to
5461     # remove them with `make clean'.  If they are in srcdir they
5462     # shouldn't be touched.  However, we can't determine this
5463     # statically, and the GNU rules say that yacc/lex output files
5464     # should be removed by maintainer-clean.  So that's what we do.
5465     $clean_files{$output} = MAINTAINER_CLEAN;
5466 }
5467
5468 # This is a helper for both lex and yacc.
5469 sub yacc_lex_finish_helper
5470 {
5471   return if defined $language_scratch{'lex-yacc-done'};
5472   $language_scratch{'lex-yacc-done'} = 1;
5473
5474   # If there is more than one distinct yacc (resp lex) source file
5475   # in a given directory, then the `ylwrap' program is required to
5476   # allow parallel builds to work correctly.  FIXME: for now, no
5477   # line number.
5478   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
5479   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
5480 }
5481
5482 sub lang_yacc_finish
5483 {
5484   return if defined $language_scratch{'yacc-done'};
5485   $language_scratch{'yacc-done'} = 1;
5486
5487   reject_var 'YACCFLAGS', "`YACCFLAGS' obsolete; use `YFLAGS' instead";
5488
5489   &yacc_lex_finish_helper
5490     if count_files_for_language ('yacc') > 1;
5491 }
5492
5493
5494 sub lang_lex_finish
5495 {
5496   return if defined $language_scratch{'lex-done'};
5497   $language_scratch{'lex-done'} = 1;
5498
5499   &yacc_lex_finish_helper
5500     if count_files_for_language ('lex') > 1;
5501 }
5502
5503
5504 # Given a hash table of linker names, pick the name that has the most
5505 # precedence.  This is lame, but something has to have global
5506 # knowledge in order to eliminate the conflict.  Add more linkers as
5507 # required.
5508 sub resolve_linker
5509 {
5510     my (%linkers) = @_;
5511
5512     foreach my $l (qw(GCJLINK CXXLINK F77LINK FCLINK OBJCLINK))
5513     {
5514         return $l if defined $linkers{$l};
5515     }
5516     return 'LINK';
5517 }
5518
5519 # Called to indicate that an extension was used.
5520 sub saw_extension
5521 {
5522     my ($ext) = @_;
5523     if (! defined $extension_seen{$ext})
5524     {
5525         $extension_seen{$ext} = 1;
5526     }
5527     else
5528     {
5529         ++$extension_seen{$ext};
5530     }
5531 }
5532
5533 # Return the number of files seen for a given language.  Knows about
5534 # special cases we care about.  FIXME: this is hideous.  We need
5535 # something that involves real language objects.  For instance yacc
5536 # and yaccxx could both derive from a common yacc class which would
5537 # know about the strange ylwrap requirement.  (Or better yet we could
5538 # just not support legacy yacc!)
5539 sub count_files_for_language
5540 {
5541     my ($name) = @_;
5542
5543     my @names;
5544     if ($name eq 'yacc' || $name eq 'yaccxx')
5545     {
5546         @names = ('yacc', 'yaccxx');
5547     }
5548     elsif ($name eq 'lex' || $name eq 'lexxx')
5549     {
5550         @names = ('lex', 'lexxx');
5551     }
5552     else
5553     {
5554         @names = ($name);
5555     }
5556
5557     my $r = 0;
5558     foreach $name (@names)
5559     {
5560         my $lang = $languages{$name};
5561         foreach my $ext (@{$lang->extensions})
5562         {
5563             $r += $extension_seen{$ext}
5564                 if defined $extension_seen{$ext};
5565         }
5566     }
5567
5568     return $r
5569 }
5570
5571 # Called to ask whether source files have been seen . If HEADERS is 1,
5572 # headers can be included.
5573 sub saw_sources_p
5574 {
5575     my ($headers) = @_;
5576
5577     # count all the sources
5578     my $count = 0;
5579     foreach my $val (values %extension_seen)
5580     {
5581         $count += $val;
5582     }
5583
5584     if (!$headers)
5585     {
5586         $count -= count_files_for_language ('header');
5587     }
5588
5589     return $count > 0;
5590 }
5591
5592
5593 # register_language (%ATTRIBUTE)
5594 # ------------------------------
5595 # Register a single language.
5596 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
5597 sub register_language (%)
5598 {
5599   my (%option) = @_;
5600
5601   # Set the defaults.
5602   $option{'ansi'} = 0
5603     unless defined $option{'ansi'};
5604   $option{'autodep'} = 'no'
5605     unless defined $option{'autodep'};
5606   $option{'linker'} = ''
5607     unless defined $option{'linker'};
5608   $option{'flags'} = []
5609     unless defined $option{'flags'};
5610   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
5611     unless defined $option{'output_extensions'};
5612   $option{'nodist_specific'} = 0
5613     unless defined $option{'nodist_specific'};
5614
5615   my $lang = new Language (%option);
5616
5617   # Fill indexes.
5618   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
5619   $languages{$lang->name} = $lang;
5620   my $link = $lang->linker;
5621   if ($link)
5622     {
5623       if (exists $link_languages{$link})
5624         {
5625           prog_error ("`$link' has different definitions in "
5626                       . $lang->name . " and " . $link_languages{$link}->name)
5627             if $lang->link ne $link_languages{$link}->link;
5628         }
5629       else
5630         {
5631           $link_languages{$link} = $lang;
5632         }
5633     }
5634
5635   # Update the pattern of known extensions.
5636   accept_extensions (@{$lang->extensions});
5637
5638   # Upate the $suffix_rule map.
5639   foreach my $suffix (@{$lang->extensions})
5640     {
5641       foreach my $dest (&{$lang->output_extensions} ($suffix))
5642         {
5643           register_suffix_rule (INTERNAL, $suffix, $dest);
5644         }
5645     }
5646 }
5647
5648 # derive_suffix ($EXT, $OBJ)
5649 # --------------------------
5650 # This function is used to find a path from a user-specified suffix $EXT
5651 # to $OBJ or to some other suffix we recognize internally, e.g. `cc'.
5652 sub derive_suffix ($$)
5653 {
5654   my ($source_ext, $obj) = @_;
5655
5656   while (! $extension_map{$source_ext}
5657          && $source_ext ne $obj
5658          && exists $suffix_rules->{$source_ext}
5659          && exists $suffix_rules->{$source_ext}{$obj})
5660     {
5661       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
5662     }
5663
5664   return $source_ext;
5665 }
5666
5667
5668 ################################################################
5669
5670 # Pretty-print something and append to output_rules.
5671 sub pretty_print_rule
5672 {
5673     $output_rules .= &makefile_wrap (@_);
5674 }
5675
5676
5677 ################################################################
5678
5679
5680 ## -------------------------------- ##
5681 ## Handling the conditional stack.  ##
5682 ## -------------------------------- ##
5683
5684
5685 # $STRING
5686 # make_conditional_string ($NEGATE, $COND)
5687 # ----------------------------------------
5688 sub make_conditional_string ($$)
5689 {
5690   my ($negate, $cond) = @_;
5691   $cond = "${cond}_TRUE"
5692     unless $cond =~ /^TRUE|FALSE$/;
5693   $cond = Automake::Condition::conditional_negate ($cond)
5694     if $negate;
5695   return $cond;
5696 }
5697
5698
5699 # $COND
5700 # cond_stack_if ($NEGATE, $COND, $WHERE)
5701 # --------------------------------------
5702 sub cond_stack_if ($$$)
5703 {
5704   my ($negate, $cond, $where) = @_;
5705
5706   error $where, "$cond does not appear in AM_CONDITIONAL"
5707     if ! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/;
5708
5709   push (@cond_stack, make_conditional_string ($negate, $cond));
5710
5711   return new Automake::Condition (@cond_stack);
5712 }
5713
5714
5715 # $COND
5716 # cond_stack_else ($NEGATE, $COND, $WHERE)
5717 # ----------------------------------------
5718 sub cond_stack_else ($$$)
5719 {
5720   my ($negate, $cond, $where) = @_;
5721
5722   if (! @cond_stack)
5723     {
5724       error $where, "else without if";
5725       return FALSE;
5726     }
5727
5728   $cond_stack[$#cond_stack] =
5729     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
5730
5731   # If $COND is given, check against it.
5732   if (defined $cond)
5733     {
5734       $cond = make_conditional_string ($negate, $cond);
5735
5736       error ($where, "else reminder ($negate$cond) incompatible with "
5737              . "current conditional: $cond_stack[$#cond_stack]")
5738         if $cond_stack[$#cond_stack] ne $cond;
5739     }
5740
5741   return new Automake::Condition (@cond_stack);
5742 }
5743
5744
5745 # $COND
5746 # cond_stack_endif ($NEGATE, $COND, $WHERE)
5747 # -----------------------------------------
5748 sub cond_stack_endif ($$$)
5749 {
5750   my ($negate, $cond, $where) = @_;
5751   my $old_cond;
5752
5753   if (! @cond_stack)
5754     {
5755       error $where, "endif without if";
5756       return TRUE;
5757     }
5758
5759   # If $COND is given, check against it.
5760   if (defined $cond)
5761     {
5762       $cond = make_conditional_string ($negate, $cond);
5763
5764       error ($where, "endif reminder ($negate$cond) incompatible with "
5765              . "current conditional: $cond_stack[$#cond_stack]")
5766         if $cond_stack[$#cond_stack] ne $cond;
5767     }
5768
5769   pop @cond_stack;
5770
5771   return new Automake::Condition (@cond_stack);
5772 }
5773
5774
5775
5776
5777
5778 ## ------------------------ ##
5779 ## Handling the variables.  ##
5780 ## ------------------------ ##
5781
5782
5783 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
5784 # -----------------------------------------------------
5785 # Like define_variable, but the value is a list, and the variable may
5786 # be defined conditionally.  The second argument is the Condition
5787 # under which the value should be defined; this should be the empty
5788 # string to define the variable unconditionally.  The third argument
5789 # is a list holding the values to use for the variable.  The value is
5790 # pretty printed in the output file.
5791 sub define_pretty_variable ($$$@)
5792 {
5793     my ($var, $cond, $where, @value) = @_;
5794
5795     if (! vardef ($var, $cond))
5796     {
5797         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
5798                                     '', $where, VAR_PRETTY);
5799         rvar ($var)->rdef ($cond)->set_seen;
5800     }
5801 }
5802
5803
5804 # define_variable ($VAR, $VALUE, $WHERE)
5805 # --------------------------------------
5806 # Define a new Automake Makefile variable VAR to VALUE, but only if
5807 # not already defined.
5808 sub define_variable ($$$)
5809 {
5810     my ($var, $value, $where) = @_;
5811     define_pretty_variable ($var, TRUE, $where, $value);
5812 }
5813
5814
5815 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
5816 # -----------------------------------------------------------
5817 # Define the $VAR which content is the list of file names composed of
5818 # a @BASENAME and the $EXTENSION.
5819 sub define_files_variable ($\@$$)
5820 {
5821   my ($var, $basename, $extension, $where) = @_;
5822   define_variable ($var,
5823                    join (' ', map { "$_.$extension" } @$basename),
5824                    $where);
5825 }
5826
5827
5828 # Like define_variable, but define a variable to be the configure
5829 # substitution by the same name.
5830 sub define_configure_variable ($)
5831 {
5832   my ($var) = @_;
5833
5834   my $pretty = VAR_ASIS;
5835   my $owner = VAR_CONFIGURE;
5836
5837   # Do not output the ANSI2KNR configure variable -- we AC_SUBST
5838   # it in protos.m4, but later redefine it elsewhere.  This is
5839   # pretty hacky.  We also don't output AMDEPBACKSLASH: it might
5840   # be subst'd by `\', which certainly would not be appreciated by
5841   # Make.
5842   if ($var eq 'ANSI2KNR' || $var eq 'AMDEPBACKSLASH')
5843     {
5844       $pretty = VAR_SILENT;
5845       $owner = VAR_AUTOMAKE;
5846     }
5847
5848   Automake::Variable::define ($var, $owner, '', TRUE, subst $var,
5849                               '', $configure_vars{$var}, $pretty);
5850 }
5851
5852
5853 # define_compiler_variable ($LANG)
5854 # --------------------------------
5855 # Define a compiler variable.  We also handle defining the `LT'
5856 # version of the command when using libtool.
5857 sub define_compiler_variable ($)
5858 {
5859     my ($lang) = @_;
5860
5861     my ($var, $value) = ($lang->compiler, $lang->compile);
5862     my $libtool_tag = '';
5863     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5864       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5865     &define_variable ($var, $value, INTERNAL);
5866     &define_variable ("LT$var",
5867                       "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) "
5868                       . "\$(LIBTOOLFLAGS) --mode=compile $value",
5869                       INTERNAL)
5870       if var ('LIBTOOL');
5871 }
5872
5873
5874 # define_linker_variable ($LANG)
5875 # ------------------------------
5876 # Define linker variables.
5877 sub define_linker_variable ($)
5878 {
5879     my ($lang) = @_;
5880
5881     my $libtool_tag = '';
5882     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5883       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5884     # CCLD = $(CC).
5885     &define_variable ($lang->lder, $lang->ld, INTERNAL);
5886     # CCLINK = $(CCLD) blah blah...
5887     &define_variable ($lang->linker,
5888                       ((var ('LIBTOOL') ?
5889                         "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) "
5890                         . "\$(LIBTOOLFLAGS) --mode=link " : '')
5891                        . $lang->link),
5892                       INTERNAL);
5893 }
5894
5895 sub define_per_target_linker_variable ($$)
5896 {
5897   my ($linker, $target) = @_;
5898
5899   # If the user wrote a custom link command, we don't define ours.
5900   return "${target}_LINK"
5901     if set_seen "${target}_LINK";
5902
5903   my $xlink = $linker ? $linker : 'LINK';
5904
5905   my $lang = $link_languages{$xlink};
5906   prog_error "Unknown language for linker variable `$xlink'"
5907     unless $lang;
5908
5909   my $link_command = $lang->link;
5910   if (var 'LIBTOOL')
5911     {
5912       my $libtool_tag = '';
5913       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5914         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5915
5916       $link_command =
5917         "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
5918         . "--mode=link " . $link_command;
5919     }
5920
5921   # Rewrite each occurrence of `AM_$flag' in the link
5922   # command into `${derived}_$flag' if it exists.
5923   my $orig_command = $link_command;
5924   my @flags = (@{$lang->flags}, 'LDFLAGS');
5925   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
5926   for my $flag (@flags)
5927     {
5928       my $val = "${target}_$flag";
5929       $link_command =~ s/\(AM_$flag\)/\($val\)/
5930         if set_seen ($val);
5931     }
5932
5933   # If the computed command is the same as the generic command, use
5934   # the command linker variable.
5935   return $lang->linker
5936     if $link_command eq $orig_command;
5937
5938   &define_variable ("${target}_LINK", $link_command, INTERNAL);
5939   return "${target}_LINK";
5940 }
5941
5942 ################################################################
5943
5944 # &check_trailing_slash ($WHERE, $LINE)
5945 # --------------------------------------
5946 # Return 1 iff $LINE ends with a slash.
5947 # Might modify $LINE.
5948 sub check_trailing_slash ($\$)
5949 {
5950   my ($where, $line) = @_;
5951
5952   # Ignore `##' lines.
5953   return 0 if $$line =~ /$IGNORE_PATTERN/o;
5954
5955   # Catch and fix a common error.
5956   msg "syntax", $where, "whitespace following trailing backslash"
5957     if $$line =~ s/\\\s+\n$/\\\n/;
5958
5959   return $$line =~ /\\$/;
5960 }
5961
5962
5963 # &read_am_file ($AMFILE, $WHERE)
5964 # -------------------------------
5965 # Read Makefile.am and set up %contents.  Simultaneously copy lines
5966 # from Makefile.am into $output_trailer, or define variables as
5967 # appropriate.  NOTE we put rules in the trailer section.  We want
5968 # user rules to come after our generated stuff.
5969 sub read_am_file ($$)
5970 {
5971     my ($amfile, $where) = @_;
5972
5973     my $am_file = new Automake::XFile ("< $amfile");
5974     verb "reading $amfile";
5975
5976     # Keep track of the youngest output dependency.
5977     my $mtime = mtime $amfile;
5978     $output_deps_greatest_timestamp = $mtime
5979       if $mtime > $output_deps_greatest_timestamp;
5980
5981     my $spacing = '';
5982     my $comment = '';
5983     my $blank = 0;
5984     my $saw_bk = 0;
5985     my $var_look = VAR_ASIS;
5986
5987     use constant IN_VAR_DEF => 0;
5988     use constant IN_RULE_DEF => 1;
5989     use constant IN_COMMENT => 2;
5990     my $prev_state = IN_RULE_DEF;
5991
5992     while ($_ = $am_file->getline)
5993     {
5994         $where->set ("$amfile:$.");
5995         if (/$IGNORE_PATTERN/o)
5996         {
5997             # Merely delete comments beginning with two hashes.
5998         }
5999         elsif (/$WHITE_PATTERN/o)
6000         {
6001             error $where, "blank line following trailing backslash"
6002               if $saw_bk;
6003             # Stick a single white line before the incoming macro or rule.
6004             $spacing = "\n";
6005             $blank = 1;
6006             # Flush all comments seen so far.
6007             if ($comment ne '')
6008             {
6009                 $output_vars .= $comment;
6010                 $comment = '';
6011             }
6012         }
6013         elsif (/$COMMENT_PATTERN/o)
6014         {
6015             # Stick comments before the incoming macro or rule.  Make
6016             # sure a blank line precedes the first block of comments.
6017             $spacing = "\n" unless $blank;
6018             $blank = 1;
6019             $comment .= $spacing . $_;
6020             $spacing = '';
6021             $prev_state = IN_COMMENT;
6022         }
6023         else
6024         {
6025             last;
6026         }
6027         $saw_bk = check_trailing_slash ($where, $_);
6028     }
6029
6030     # We save the conditional stack on entry, and then check to make
6031     # sure it is the same on exit.  This lets us conditionally include
6032     # other files.
6033     my @saved_cond_stack = @cond_stack;
6034     my $cond = new Automake::Condition (@cond_stack);
6035
6036     my $last_var_name = '';
6037     my $last_var_type = '';
6038     my $last_var_value = '';
6039     my $last_where;
6040     # FIXME: shouldn't use $_ in this loop; it is too big.
6041     while ($_)
6042     {
6043         $where->set ("$amfile:$.");
6044
6045         # Make sure the line is \n-terminated.
6046         chomp;
6047         $_ .= "\n";
6048
6049         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6050         # used by users.  @MAINT@ is an anachronism now.
6051         $_ =~ s/\@MAINT\@//g
6052             unless $seen_maint_mode;
6053
6054         my $new_saw_bk = check_trailing_slash ($where, $_);
6055
6056         if (/$IGNORE_PATTERN/o)
6057         {
6058             # Merely delete comments beginning with two hashes.
6059
6060             # Keep any backslash from the previous line.
6061             $new_saw_bk = $saw_bk;
6062         }
6063         elsif (/$WHITE_PATTERN/o)
6064         {
6065             # Stick a single white line before the incoming macro or rule.
6066             $spacing = "\n";
6067             error $where, "blank line following trailing backslash"
6068               if $saw_bk;
6069         }
6070         elsif (/$COMMENT_PATTERN/o)
6071         {
6072             error $where, "comment following trailing backslash"
6073               if $saw_bk && $comment eq '';
6074
6075             # Stick comments before the incoming macro or rule.
6076             $comment .= $spacing . $_;
6077             $spacing = '';
6078             $prev_state = IN_COMMENT;
6079         }
6080         elsif ($saw_bk)
6081         {
6082             if ($prev_state == IN_RULE_DEF)
6083             {
6084               my $cond = new Automake::Condition @cond_stack;
6085               $output_trailer .= $cond->subst_string;
6086               $output_trailer .= $_;
6087             }
6088             elsif ($prev_state == IN_COMMENT)
6089             {
6090                 # If the line doesn't start with a `#', add it.
6091                 # We do this because a continued comment like
6092                 #   # A = foo \
6093                 #         bar \
6094                 #         baz
6095                 # is not portable.  BSD make doesn't honor
6096                 # escaped newlines in comments.
6097                 s/^#?/#/;
6098                 $comment .= $spacing . $_;
6099             }
6100             else # $prev_state == IN_VAR_DEF
6101             {
6102               $last_var_value .= ' '
6103                 unless $last_var_value =~ /\s$/;
6104               $last_var_value .= $_;
6105
6106               if (!/\\$/)
6107                 {
6108                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6109                                               $last_var_type, $cond,
6110                                               $last_var_value, $comment,
6111                                               $last_where, VAR_ASIS)
6112                     if $cond != FALSE;
6113                   $comment = $spacing = '';
6114                 }
6115             }
6116         }
6117
6118         elsif (/$IF_PATTERN/o)
6119           {
6120             $cond = cond_stack_if ($1, $2, $where);
6121           }
6122         elsif (/$ELSE_PATTERN/o)
6123           {
6124             $cond = cond_stack_else ($1, $2, $where);
6125           }
6126         elsif (/$ENDIF_PATTERN/o)
6127           {
6128             $cond = cond_stack_endif ($1, $2, $where);
6129           }
6130
6131         elsif (/$RULE_PATTERN/o)
6132         {
6133             # Found a rule.
6134             $prev_state = IN_RULE_DEF;
6135
6136             # For now we have to output all definitions of user rules
6137             # and can't diagnose duplicates (see the comment in
6138             # Automake::Rule::define). So we go on and ignore the return value.
6139             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6140
6141             check_variable_expansions ($_, $where);
6142
6143             $output_trailer .= $comment . $spacing;
6144             my $cond = new Automake::Condition @cond_stack;
6145             $output_trailer .= $cond->subst_string;
6146             $output_trailer .= $_;
6147             $comment = $spacing = '';
6148         }
6149         elsif (/$ASSIGNMENT_PATTERN/o)
6150         {
6151             # Found a macro definition.
6152             $prev_state = IN_VAR_DEF;
6153             $last_var_name = $1;
6154             $last_var_type = $2;
6155             $last_var_value = $3;
6156             $last_where = $where->clone;
6157             if ($3 ne '' && substr ($3, -1) eq "\\")
6158               {
6159                 # We preserve the `\' because otherwise the long lines
6160                 # that are generated will be truncated by broken
6161                 # `sed's.
6162                 $last_var_value = $3 . "\n";
6163               }
6164             # Normally we try to output variable definitions in the
6165             # same format they were input.  However, POSIX compliant
6166             # systems are not required to support lines longer than
6167             # 2048 bytes (most notably, some sed implementation are
6168             # limited to 4000 bytes, and sed is used by config.status
6169             # to rewrite Makefile.in into Makefile).  Moreover nobody
6170             # would really write such long lines by hand since it is
6171             # hardly maintainable.  So if a line is longer that 1000
6172             # bytes (an arbitrary limit), assume it has been
6173             # automatically generated by some tools, and flatten the
6174             # variable definition.  Otherwise, keep the variable as it
6175             # as been input.
6176             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6177
6178             if (!/\\$/)
6179               {
6180                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6181                                             $last_var_type, $cond,
6182                                             $last_var_value, $comment,
6183                                             $last_where, $var_look)
6184                   if $cond != FALSE;
6185                 $comment = $spacing = '';
6186                 $var_look = VAR_ASIS;
6187               }
6188         }
6189         elsif (/$INCLUDE_PATTERN/o)
6190         {
6191             my $path = $1;
6192
6193             if ($path =~ s/^\$\(top_srcdir\)\///)
6194               {
6195                 push (@include_stack, "\$\(top_srcdir\)/$path");
6196                 # Distribute any included file.
6197
6198                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6199                 # otherwise OSF make will implicitly copy the included
6200                 # file in the build tree during `make distdir' to satisfy
6201                 # the dependency.
6202                 # (subdircond2.test and subdircond3.test will fail.)
6203                 push_dist_common ("\$\(top_srcdir\)/$path");
6204               }
6205             else
6206               {
6207                 $path =~ s/\$\(srcdir\)\///;
6208                 push (@include_stack, "\$\(srcdir\)/$path");
6209                 # Always use the $(srcdir) prefix in DIST_COMMON,
6210                 # otherwise OSF make will implicitly copy the included
6211                 # file in the build tree during `make distdir' to satisfy
6212                 # the dependency.
6213                 # (subdircond2.test and subdircond3.test will fail.)
6214                 push_dist_common ("\$\(srcdir\)/$path");
6215                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6216               }
6217             $where->push_context ("`$path' included from here");
6218             &read_am_file ($path, $where);
6219             $where->pop_context;
6220         }
6221         else
6222         {
6223             # This isn't an error; it is probably a continued rule.
6224             # In fact, this is what we assume.
6225             $prev_state = IN_RULE_DEF;
6226             check_variable_expansions ($_, $where);
6227             $output_trailer .= $comment . $spacing;
6228             my $cond = new Automake::Condition @cond_stack;
6229             $output_trailer .= $cond->subst_string;
6230             $output_trailer .= $_;
6231             $comment = $spacing = '';
6232             error $where, "`#' comment at start of rule is unportable"
6233               if $_ =~ /^\t\s*\#/;
6234         }
6235
6236         $saw_bk = $new_saw_bk;
6237         $_ = $am_file->getline;
6238     }
6239
6240     $output_trailer .= $comment;
6241
6242     error ($where, "trailing backslash on last line")
6243       if $saw_bk;
6244
6245     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6246                     : "too many conditionals closed in include file"))
6247       if "@saved_cond_stack" ne "@cond_stack";
6248 }
6249
6250
6251 # define_standard_variables ()
6252 # ----------------------------
6253 # A helper for read_main_am_file which initializes configure variables
6254 # and variables from header-vars.am.
6255 sub define_standard_variables
6256 {
6257   my $saved_output_vars = $output_vars;
6258   my ($comments, undef, $rules) =
6259     file_contents_internal (1, "$libdir/am/header-vars.am",
6260                             new Automake::Location);
6261
6262   foreach my $var (sort keys %configure_vars)
6263     {
6264       &define_configure_variable ($var);
6265     }
6266
6267   $output_vars .= $comments . $rules;
6268 }
6269
6270 # Read main am file.
6271 sub read_main_am_file
6272 {
6273     my ($amfile) = @_;
6274
6275     # This supports the strange variable tricks we are about to play.
6276     prog_error (macros_dump () . "variable defined before read_main_am_file")
6277       if (scalar (variables) > 0);
6278
6279     # Generate copyright header for generated Makefile.in.
6280     # We do discard the output of predefined variables, handled below.
6281     $output_vars = ("# $in_file_name generated by automake "
6282                    . $VERSION . " from $am_file_name.\n");
6283     $output_vars .= '# ' . subst ('configure_input') . "\n";
6284     $output_vars .= $gen_copyright;
6285
6286     # We want to predefine as many variables as possible.  This lets
6287     # the user set them with `+=' in Makefile.am.
6288     &define_standard_variables;
6289
6290     # Read user file, which might override some of our values.
6291     &read_am_file ($amfile, new Automake::Location);
6292 }
6293
6294
6295
6296 ################################################################
6297
6298 # $FLATTENED
6299 # &flatten ($STRING)
6300 # ------------------
6301 # Flatten the $STRING and return the result.
6302 sub flatten
6303 {
6304   $_ = shift;
6305
6306   s/\\\n//somg;
6307   s/\s+/ /g;
6308   s/^ //;
6309   s/ $//;
6310
6311   return $_;
6312 }
6313
6314 # transform($TOKEN, \%PAIRS)
6315 # ==========================
6316 # If ($TOKEN, $VAL) is in %PAIRS:
6317 #   - replaces %$TOKEN% with $VAL,
6318 #   - enables/disables ?$TOKEN? and ?!$TOKEN?,
6319 #   - replaces %?$TOKEN% with TRUE or FALSE.
6320 sub transform($$)
6321 {
6322   my ($token, $transform) = @_;
6323
6324   if (substr ($token, 0, 1) eq '%')
6325     {
6326       my $cond = (substr ($token, 1, 1) eq '?') ? 1 : 0;
6327       $token = substr ($token, 1 + $cond, -1);
6328       my $val = $transform->{$token};
6329       prog_error "Unknown %token% `$token'" unless defined $val;
6330       if ($cond)
6331         {
6332           return $val ? 'TRUE' : 'FALSE';
6333         }
6334       else
6335         {
6336           return $val;
6337         }
6338     }
6339   # Now $token is '?xxx?' or '?!xxx?'.
6340   my $neg = (substr ($token, 1, 1) eq '!') ? 1 : 0;
6341   $token = substr ($token, 1 + $neg, -1);
6342   my $val = $transform->{$token};
6343   prog_error "Unknown ?token? `$token' (neg = $neg)" unless defined $val;
6344   return (!!$val == $neg) ? '##%' : '';
6345 }
6346
6347 # @PARAGRAPHS
6348 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6349 # ------------------------------------------
6350 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6351 # paragraphs.
6352 sub make_paragraphs ($%)
6353 {
6354   my ($file, %transform) = @_;
6355
6356   # Complete %transform with global options.
6357   # Note that %transform goes last, so it overrides global options.
6358   %transform = ('CYGNUS'      => !! option 'cygnus',
6359                  'MAINTAINER-MODE'
6360                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6361
6362                  'BZIP2'       => !! option 'dist-bzip2',
6363                  'COMPRESS'    => !! option 'dist-tarZ',
6364                  'GZIP'        =>  ! option 'no-dist-gzip',
6365                  'SHAR'        => !! option 'dist-shar',
6366                  'ZIP'         => !! option 'dist-zip',
6367
6368                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6369                  'INSTALL-MAN'  =>  ! option 'no-installman',
6370                  'CK-NEWS'      => !! option 'check-news',
6371
6372                  'SUBDIRS'      => !! var ('SUBDIRS'),
6373                  'TOPDIR_P'     => $relative_dir eq '.',
6374
6375                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6376                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6377                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6378
6379                  'LIBTOOL'      => !! var ('LIBTOOL'),
6380                  'NONLIBTOOL'   => 1,
6381                  'FIRST'        => ! $transformed_files{$file},
6382                 %transform);
6383
6384   $transformed_files{$file} = 1;
6385   $_ = $am_file_cache{$file};
6386
6387   if (! defined $_)
6388     {
6389       verb "reading $file";
6390       # Swallow the whole file.
6391       my $fc_file = new Automake::XFile "< $file";
6392       my $saved_dollar_slash = $/;
6393       undef $/;
6394       $_ = $fc_file->getline;
6395       $/ = $saved_dollar_slash;
6396       $fc_file->close;
6397
6398       # Remove ##-comments.
6399       # Besides we don't need more than two consecutive new-lines.
6400       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6401
6402       $am_file_cache{$file} = $_;
6403     }
6404
6405   # Substitute Automake template tokens.
6406   s/(?:%\??[\w\-]+%|\?!?[\w\-]+\?)/transform($&, \%transform)/ge;
6407   # transform() may have added some ##%-comments to strip.
6408   # (we use `##%' instead of `##' so we can distinguish ##%##%##% from
6409   # ####### and do not remove the latter.)
6410   s/^[ \t]*(?:##%)+.*\n//gm;
6411
6412   # Split at unescaped new lines.
6413   my @lines = split (/(?<!\\)\n/, $_);
6414   my @res;
6415
6416   while (defined ($_ = shift @lines))
6417     {
6418       my $paragraph = $_;
6419       # If we are a rule, eat as long as we start with a tab.
6420       if (/$RULE_PATTERN/smo)
6421         {
6422           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
6423             {
6424               $paragraph .= "\n$_";
6425             }
6426           unshift (@lines, $_);
6427         }
6428
6429       # If we are a comments, eat as much comments as you can.
6430       elsif (/$COMMENT_PATTERN/smo)
6431         {
6432           while (defined ($_ = shift @lines)
6433                  && $_ =~ /$COMMENT_PATTERN/smo)
6434             {
6435               $paragraph .= "\n$_";
6436             }
6437           unshift (@lines, $_);
6438         }
6439
6440       push @res, $paragraph;
6441     }
6442
6443   return @res;
6444 }
6445
6446
6447
6448 # ($COMMENT, $VARIABLES, $RULES)
6449 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
6450 # -------------------------------------------------------------
6451 # Return contents of a file from $libdir/am, automatically skipping
6452 # macros or rules which are already known. $IS_AM iff the caller is
6453 # reading an Automake file (as opposed to the user's Makefile.am).
6454 sub file_contents_internal ($$$%)
6455 {
6456     my ($is_am, $file, $where, %transform) = @_;
6457
6458     $where->set ($file);
6459
6460     my $result_vars = '';
6461     my $result_rules = '';
6462     my $comment = '';
6463     my $spacing = '';
6464
6465     # The following flags are used to track rules spanning across
6466     # multiple paragraphs.
6467     my $is_rule = 0;            # 1 if we are processing a rule.
6468     my $discard_rule = 0;       # 1 if the current rule should not be output.
6469
6470     # We save the conditional stack on entry, and then check to make
6471     # sure it is the same on exit.  This lets us conditionally include
6472     # other files.
6473     my @saved_cond_stack = @cond_stack;
6474     my $cond = new Automake::Condition (@cond_stack);
6475
6476     foreach (make_paragraphs ($file, %transform))
6477     {
6478         # FIXME: no line number available.
6479         $where->set ($file);
6480
6481         # Sanity checks.
6482         error $where, "blank line following trailing backslash:\n$_"
6483           if /\\$/;
6484         error $where, "comment following trailing backslash:\n$_"
6485           if /\\#/;
6486
6487         if (/^$/)
6488         {
6489             $is_rule = 0;
6490             # Stick empty line before the incoming macro or rule.
6491             $spacing = "\n";
6492         }
6493         elsif (/$COMMENT_PATTERN/mso)
6494         {
6495             $is_rule = 0;
6496             # Stick comments before the incoming macro or rule.
6497             $comment = "$_\n";
6498         }
6499
6500         # Handle inclusion of other files.
6501         elsif (/$INCLUDE_PATTERN/o)
6502         {
6503             if ($cond != FALSE)
6504               {
6505                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
6506                 $where->push_context ("`$file' included from here");
6507                 # N-ary `.=' fails.
6508                 my ($com, $vars, $rules)
6509                   = file_contents_internal ($is_am, $file, $where, %transform);
6510                 $where->pop_context;
6511                 $comment .= $com;
6512                 $result_vars .= $vars;
6513                 $result_rules .= $rules;
6514               }
6515         }
6516
6517         # Handling the conditionals.
6518         elsif (/$IF_PATTERN/o)
6519           {
6520             $cond = cond_stack_if ($1, $2, $file);
6521           }
6522         elsif (/$ELSE_PATTERN/o)
6523           {
6524             $cond = cond_stack_else ($1, $2, $file);
6525           }
6526         elsif (/$ENDIF_PATTERN/o)
6527           {
6528             $cond = cond_stack_endif ($1, $2, $file);
6529           }
6530
6531         # Handling rules.
6532         elsif (/$RULE_PATTERN/mso)
6533         {
6534           $is_rule = 1;
6535           $discard_rule = 0;
6536           # Separate relationship from optional actions: the first
6537           # `new-line tab" not preceded by backslash (continuation
6538           # line).
6539           my $paragraph = $_;
6540           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
6541           my ($relationship, $actions) = ($1, $2 || '');
6542
6543           # Separate targets from dependencies: the first colon.
6544           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
6545           my ($targets, $dependencies) = ($1, $2);
6546           # Remove the escaped new lines.
6547           # I don't know why, but I have to use a tmp $flat_deps.
6548           my $flat_deps = &flatten ($dependencies);
6549           my @deps = split (' ', $flat_deps);
6550
6551           foreach (split (' ' , $targets))
6552             {
6553               # FIXME: 1. We are not robust to people defining several targets
6554               # at once, only some of them being in %dependencies.  The
6555               # actions from the targets in %dependencies are usually generated
6556               # from the content of %actions, but if some targets in $targets
6557               # are not in %dependencies the ELSE branch will output
6558               # a rule for all $targets (i.e. the targets which are both
6559               # in %dependencies and $targets will have two rules).
6560
6561               # FIXME: 2. The logic here is not able to output a
6562               # multi-paragraph rule several time (e.g. for each condition
6563               # it is defined for) because it only knows the first paragraph.
6564
6565               # FIXME: 3. We are not robust to people defining a subset
6566               # of a previously defined "multiple-target" rule.  E.g.
6567               # `foo:' after `foo bar:'.
6568
6569               # Output only if not in FALSE.
6570               if (defined $dependencies{$_} && $cond != FALSE)
6571                 {
6572                   &depend ($_, @deps);
6573                   if ($actions{$_})
6574                     {
6575                       $actions{$_} .= "\n$actions" if $actions;
6576                     }
6577                   else
6578                     {
6579                       $actions{$_} = $actions;
6580                     }
6581                 }
6582               else
6583                 {
6584                   # Free-lance dependency.  Output the rule for all the
6585                   # targets instead of one by one.
6586                   my @undefined_conds =
6587                     Automake::Rule::define ($targets, $file,
6588                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
6589                                             $cond, $where);
6590                   for my $undefined_cond (@undefined_conds)
6591                     {
6592                       my $condparagraph = $paragraph;
6593                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
6594                       $result_rules .= "$spacing$comment$condparagraph\n";
6595                     }
6596                   if (scalar @undefined_conds == 0)
6597                     {
6598                       # Remember to discard next paragraphs
6599                       # if they belong to this rule.
6600                       # (but see also FIXME: #2 above.)
6601                       $discard_rule = 1;
6602                     }
6603                   $comment = $spacing = '';
6604                   last;
6605                 }
6606             }
6607         }
6608
6609         elsif (/$ASSIGNMENT_PATTERN/mso)
6610         {
6611             my ($var, $type, $val) = ($1, $2, $3);
6612             error $where, "variable `$var' with trailing backslash"
6613               if /\\$/;
6614
6615             $is_rule = 0;
6616
6617             Automake::Variable::define ($var,
6618                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
6619                                         $type, $cond, $val, $comment, $where,
6620                                         VAR_ASIS)
6621               if $cond != FALSE;
6622
6623             $comment = $spacing = '';
6624         }
6625         else
6626         {
6627             # This isn't an error; it is probably some tokens which
6628             # configure is supposed to replace, such as `@SET-MAKE@',
6629             # or some part of a rule cut by an if/endif.
6630             if (! $cond->false && ! ($is_rule && $discard_rule))
6631               {
6632                 s/^/$cond->subst_string/gme;
6633                 $result_rules .= "$spacing$comment$_\n";
6634               }
6635             $comment = $spacing = '';
6636         }
6637     }
6638
6639     error ($where, @cond_stack ?
6640            "unterminated conditionals: @cond_stack" :
6641            "too many conditionals closed in include file")
6642       if "@saved_cond_stack" ne "@cond_stack";
6643
6644     return ($comment, $result_vars, $result_rules);
6645 }
6646
6647
6648 # $CONTENTS
6649 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
6650 # ------------------------------------------------
6651 # Return contents of a file from $libdir/am, automatically skipping
6652 # macros or rules which are already known.
6653 sub file_contents ($$%)
6654 {
6655     my ($basename, $where, %transform) = @_;
6656     my ($comments, $variables, $rules) =
6657       file_contents_internal (1, "$libdir/am/$basename.am", $where,
6658                               %transform);
6659     return "$comments$variables$rules";
6660 }
6661
6662
6663 # &append_exeext ($MACRO)
6664 # -----------------------
6665 # Macro is an Automake magic macro which primary is PROGRAMS, e.g.
6666 # bin_PROGRAMS.  Make sure these programs have $(EXEEXT) appended.
6667 sub append_exeext ($)
6668 {
6669   my ($macro) = @_;
6670
6671   prog_error "append_exeext ($macro)"
6672     unless $macro =~ /_PROGRAMS$/;
6673
6674   transform_variable_recursively
6675     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
6676      sub {
6677        my ($subvar, $val, $cond, $full_cond) = @_;
6678        # Append $(EXEEXT) unless the user did it already, or it's a
6679        # @substitution@.
6680        $val .= '$(EXEEXT)' unless $val =~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/;
6681        return $val;
6682      });
6683 }
6684
6685
6686 # @PREFIX
6687 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
6688 # -----------------------------------------------------
6689 # Find all variable prefixes that are used for install directories.  A
6690 # prefix `zar' qualifies iff:
6691 #
6692 # * `zardir' is a variable.
6693 # * `zar_PRIMARY' is a variable.
6694 #
6695 # As a side effect, it looks for misspellings.  It is an error to have
6696 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
6697 # "bin_PROGRAMS".  However, unusual prefixes are allowed if a variable
6698 # of the same name (with "dir" appended) exists.  For instance, if the
6699 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
6700 # This is to provide a little extra flexibility in those cases which
6701 # need it.
6702 sub am_primary_prefixes ($$@)
6703 {
6704   my ($primary, $can_dist, @prefixes) = @_;
6705
6706   local $_;
6707   my %valid = map { $_ => 0 } @prefixes;
6708   $valid{'EXTRA'} = 0;
6709   foreach my $var (variables $primary)
6710     {
6711       # Automake is allowed to define variables that look like primaries
6712       # but which aren't.  E.g. INSTALL_sh_DATA.
6713       # Autoconf can also define variables like INSTALL_DATA, so
6714       # ignore all configure variables (at least those which are not
6715       # redefined in Makefile.am).
6716       # FIXME: We should make sure that these variables are not
6717       # conditionally defined (or else adjust the condition below).
6718       my $def = $var->def (TRUE);
6719       next if $def && $def->owner != VAR_MAKEFILE;
6720
6721       my $varname = $var->name;
6722
6723       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
6724         {
6725           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
6726           if ($dist ne '' && ! $can_dist)
6727             {
6728               err_var ($var,
6729                        "invalid variable `$varname': `dist' is forbidden");
6730             }
6731           # Standard directories must be explicitly allowed.
6732           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
6733             {
6734               err_var ($var,
6735                        "`${X}dir' is not a legitimate directory " .
6736                        "for `$primary'");
6737             }
6738           # A not explicitly valid directory is allowed if Xdir is defined.
6739           elsif (! defined $valid{$X} &&
6740                  $var->requires_variables ("`$varname' is used", "${X}dir"))
6741             {
6742               # Nothing to do.  Any error message has been output
6743               # by $var->requires_variables.
6744             }
6745           else
6746             {
6747               # Ensure all extended prefixes are actually used.
6748               $valid{"$base$dist$X"} = 1;
6749             }
6750         }
6751       else
6752         {
6753           prog_error "unexpected variable name: $varname";
6754         }
6755     }
6756
6757   # Return only those which are actually defined.
6758   return sort grep { var ($_ . '_' . $primary) } keys %valid;
6759 }
6760
6761
6762 # Handle `where_HOW' variable magic.  Does all lookups, generates
6763 # install code, and possibly generates code to define the primary
6764 # variable.  The first argument is the name of the .am file to munge,
6765 # the second argument is the primary variable (e.g. HEADERS), and all
6766 # subsequent arguments are possible installation locations.
6767 #
6768 # Returns list of [$location, $value] pairs, where
6769 # $value's are the values in all where_HOW variable, and $location
6770 # there associated location (the place here their parent variables were
6771 # defined).
6772 #
6773 # FIXME: this should be rewritten to be cleaner.  It should be broken
6774 # up into multiple functions.
6775 #
6776 # Usage is: am_install_var (OPTION..., file, HOW, where...)
6777 sub am_install_var
6778 {
6779   my (@args) = @_;
6780
6781   my $do_require = 1;
6782   my $can_dist = 0;
6783   my $default_dist = 0;
6784   while (@args)
6785     {
6786       if ($args[0] eq '-noextra')
6787         {
6788           $do_require = 0;
6789         }
6790       elsif ($args[0] eq '-candist')
6791         {
6792           $can_dist = 1;
6793         }
6794       elsif ($args[0] eq '-defaultdist')
6795         {
6796           $default_dist = 1;
6797           $can_dist = 1;
6798         }
6799       elsif ($args[0] !~ /^-/)
6800         {
6801           last;
6802         }
6803       shift (@args);
6804     }
6805
6806   my ($file, $primary, @prefix) = @args;
6807
6808   # Now that configure substitutions are allowed in where_HOW
6809   # variables, it is an error to actually define the primary.  We
6810   # allow `JAVA', as it is customarily used to mean the Java
6811   # interpreter.  This is but one of several Java hacks.  Similarly,
6812   # `PYTHON' is customarily used to mean the Python interpreter.
6813   reject_var $primary, "`$primary' is an anachronism"
6814     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
6815
6816   # Get the prefixes which are valid and actually used.
6817   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
6818
6819   # If a primary includes a configure substitution, then the EXTRA_
6820   # form is required.  Otherwise we can't properly do our job.
6821   my $require_extra;
6822
6823   my @used = ();
6824   my @result = ();
6825
6826   foreach my $X (@prefix)
6827     {
6828       my $nodir_name = $X;
6829       my $one_name = $X . '_' . $primary;
6830       my $one_var = var $one_name;
6831
6832       my $strip_subdir = 1;
6833       # If subdir prefix should be preserved, do so.
6834       if ($nodir_name =~ /^nobase_/)
6835         {
6836           $strip_subdir = 0;
6837           $nodir_name =~ s/^nobase_//;
6838         }
6839
6840       # If files should be distributed, do so.
6841       my $dist_p = 0;
6842       if ($can_dist)
6843         {
6844           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
6845                      || (! $default_dist && $nodir_name =~ /^dist_/));
6846           $nodir_name =~ s/^(dist|nodist)_//;
6847         }
6848
6849
6850       # Use the location of the currently processed variable.
6851       # We are not processing a particular condition, so pick the first
6852       # available.
6853       my $tmpcond = $one_var->conditions->one_cond;
6854       my $where = $one_var->rdef ($tmpcond)->location->clone;
6855
6856       # Append actual contents of where_PRIMARY variable to
6857       # @result, skipping @substitutions@.
6858       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
6859         {
6860           my ($loc, $value) = @$locvals;
6861           # Skip configure substitutions.
6862           if ($value =~ /^\@.*\@$/)
6863             {
6864               if ($nodir_name eq 'EXTRA')
6865                 {
6866                   error ($where,
6867                          "`$one_name' contains configure substitution, "
6868                          . "but shouldn't");
6869                 }
6870               # Check here to make sure variables defined in
6871               # configure.ac do not imply that EXTRA_PRIMARY
6872               # must be defined.
6873               elsif (! defined $configure_vars{$one_name})
6874                 {
6875                   $require_extra = $one_name
6876                     if $do_require;
6877                 }
6878             }
6879           else
6880             {
6881               push (@result, $locvals);
6882             }
6883         }
6884       # A blatant hack: we rewrite each _PROGRAMS primary to include
6885       # EXEEXT.
6886       append_exeext ($one_name)
6887         if $primary eq 'PROGRAMS';
6888       # "EXTRA" shouldn't be used when generating clean targets,
6889       # all, or install targets.  We used to warn if EXTRA_FOO was
6890       # defined uselessly, but this was annoying.
6891       next
6892         if $nodir_name eq 'EXTRA';
6893
6894       if ($nodir_name eq 'check')
6895         {
6896           push (@check, '$(' . $one_name . ')');
6897         }
6898       else
6899         {
6900           push (@used, '$(' . $one_name . ')');
6901         }
6902
6903       # Is this to be installed?
6904       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
6905
6906       # If so, with install-exec? (or install-data?).
6907       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
6908
6909       my $check_options_p = $install_p && !! option 'std-options';
6910
6911       # Use the location of the currently processed variable as context.
6912       $where->push_context ("while processing `$one_name'");
6913
6914       # The variable containing all file to distribute.
6915       my $distvar = "\$($one_name)";
6916       $distvar = shadow_unconditionally ($one_name, $where)
6917         if ($dist_p && $one_var->has_conditional_contents);
6918
6919       # Singular form of $PRIMARY.
6920       (my $one_primary = $primary) =~ s/S$//;
6921       $output_rules .= &file_contents ($file, $where,
6922                                        PRIMARY     => $primary,
6923                                        ONE_PRIMARY => $one_primary,
6924                                        DIR         => $X,
6925                                        NDIR        => $nodir_name,
6926                                        BASE        => $strip_subdir,
6927
6928                                        EXEC      => $exec_p,
6929                                        INSTALL   => $install_p,
6930                                        DIST      => $dist_p,
6931                                        DISTVAR   => $distvar,
6932                                        'CK-OPTS' => $check_options_p);
6933     }
6934
6935   # The JAVA variable is used as the name of the Java interpreter.
6936   # The PYTHON variable is used as the name of the Python interpreter.
6937   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
6938     {
6939       # Define it.
6940       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
6941       $output_vars .= "\n";
6942     }
6943
6944   err_var ($require_extra,
6945            "`$require_extra' contains configure substitution,\n"
6946            . "but `EXTRA_$primary' not defined")
6947     if ($require_extra && ! var ('EXTRA_' . $primary));
6948
6949   # Push here because PRIMARY might be configure time determined.
6950   push (@all, '$(' . $primary . ')')
6951     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
6952
6953   # Make the result unique.  This lets the user use conditionals in
6954   # a natural way, but still lets us program lazily -- we don't have
6955   # to worry about handling a particular object more than once.
6956   # We will keep only one location per object.
6957   my %result = ();
6958   for my $pair (@result)
6959     {
6960       my ($loc, $val) = @$pair;
6961       $result{$val} = $loc;
6962     }
6963   my @l = sort keys %result;
6964   return map { [$result{$_}->clone, $_] } @l;
6965 }
6966
6967
6968 ################################################################
6969
6970 # Each key in this hash is the name of a directory holding a
6971 # Makefile.in.  These variables are local to `is_make_dir'.
6972 my %make_dirs = ();
6973 my $make_dirs_set = 0;
6974
6975 sub is_make_dir
6976 {
6977     my ($dir) = @_;
6978     if (! $make_dirs_set)
6979     {
6980         foreach my $iter (@configure_input_files)
6981         {
6982             $make_dirs{dirname ($iter)} = 1;
6983         }
6984         # We also want to notice Makefile.in's.
6985         foreach my $iter (@other_input_files)
6986         {
6987             if ($iter =~ /Makefile\.in$/)
6988             {
6989                 $make_dirs{dirname ($iter)} = 1;
6990             }
6991         }
6992         $make_dirs_set = 1;
6993     }
6994     return defined $make_dirs{$dir};
6995 }
6996
6997 ################################################################
6998
6999 # Find the aux dir.  This should match the algorithm used by
7000 # ./configure. (See the Autoconf documentation for for
7001 # AC_CONFIG_AUX_DIR.)
7002 sub locate_aux_dir ()
7003 {
7004   if (! $config_aux_dir_set_in_configure_ac)
7005     {
7006       # The default auxiliary directory is the first
7007       # of ., .., or ../.. that contains install-sh.
7008       # Assume . if install-sh doesn't exist yet.
7009       for my $dir (qw (. .. ../..))
7010         {
7011           if (-f "$dir/install-sh")
7012             {
7013               $config_aux_dir = $dir;
7014               last;
7015             }
7016         }
7017       $config_aux_dir = '.' unless $config_aux_dir;
7018     }
7019   # Avoid unsightly '/.'s.
7020   $am_config_aux_dir =
7021     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7022   $am_config_aux_dir =~ s,/*$,,;
7023 }
7024
7025
7026 # &maybe_push_required_file ($DIR, $FILE, $FULLFILE)
7027 # --------------------------------------------------
7028 # See if we want to push this file onto dist_common.  This function
7029 # encodes the rules for deciding when to do so.
7030 sub maybe_push_required_file
7031 {
7032   my ($dir, $file, $fullfile) = @_;
7033
7034   if ($dir eq $relative_dir)
7035     {
7036       push_dist_common ($file);
7037       return 1;
7038     }
7039   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7040     {
7041       # If we are doing the topmost directory, and the file is in a
7042       # subdir which does not have a Makefile, then we distribute it
7043       # here.
7044
7045       # If a required file is above the source tree, it is important
7046       # to prefix it with `$(srcdir)' so that no VPATH search is
7047       # performed.  Otherwise problems occur with Make implementations
7048       # that rewrite and simplify rules whose dependencies are found in a
7049       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7050       #
7051       #   % cat Makefile
7052       #   VPATH = sub
7053       #   distdir: ../a
7054       #           echo ../a
7055       #   % ls
7056       #   Makefile a
7057       #   % make
7058       #   echo a
7059       #   a
7060       #
7061       # Dependency `../a' was found in `sub/../a', but this make
7062       # implementation simplified it as `a'.  (Note that the sub/
7063       # directory does not even exist.)
7064       #
7065       # This kind of VPATH rewriting seems hard to cancel.  The
7066       # distdir.am hack against VPATH rewriting works only when no
7067       # simplification is done, i.e., for dependencies which are in
7068       # subdirectories, not in enclosing directories.  Hence, in
7069       # the latter case we use a full path to make sure no VPATH
7070       # search occurs.
7071       $fullfile = '$(srcdir)/' . $fullfile
7072         if $dir =~ m,^\.\.(?:$|/),;
7073
7074       push_dist_common ($fullfile);
7075       return 1;
7076     }
7077   return 0;
7078 }
7079
7080
7081 # If a file name appears as a key in this hash, then it has already
7082 # been checked for.  This allows us not to report the same error more
7083 # than once.
7084 my %required_file_not_found = ();
7085
7086 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, @FILES)
7087 # --------------------------------------------------------------
7088 # Verify that the file must exist in $DIRECTORY, or install it.
7089 # $MYSTRICT is the strictness level at which this file becomes required.
7090 sub require_file_internal ($$$@)
7091 {
7092   my ($where, $mystrict, $dir, @files) = @_;
7093
7094   foreach my $file (@files)
7095     {
7096       my $fullfile = "$dir/$file";
7097       my $found_it = 0;
7098       my $dangling_sym = 0;
7099
7100       if (-l $fullfile && ! -f $fullfile)
7101         {
7102           $dangling_sym = 1;
7103         }
7104       elsif (dir_has_case_matching_file ($dir, $file))
7105         {
7106           $found_it = 1;
7107           maybe_push_required_file ($dir, $file, $fullfile);
7108         }
7109
7110       # `--force-missing' only has an effect if `--add-missing' is
7111       # specified.
7112       if ($found_it && (! $add_missing || ! $force_missing))
7113         {
7114           next;
7115         }
7116       else
7117         {
7118           # If we've already looked for it, we're done.  You might
7119           # wonder why we don't do this before searching for the
7120           # file.  If we do that, then something like
7121           # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7122           # DIST_COMMON.
7123           if (! $found_it)
7124             {
7125               next if defined $required_file_not_found{$fullfile};
7126               $required_file_not_found{$fullfile} = 1;
7127             }
7128
7129           if ($strictness >= $mystrict)
7130             {
7131               if ($dangling_sym && $add_missing)
7132                 {
7133                   unlink ($fullfile);
7134                 }
7135
7136               my $trailer = '';
7137               my $suppress = 0;
7138
7139               # Only install missing files according to our desired
7140               # strictness level.
7141               my $message = "required file `$fullfile' not found";
7142               if ($add_missing)
7143                 {
7144                   if (-f "$libdir/$file")
7145                     {
7146                       $suppress = 1;
7147
7148                       # Install the missing file.  Symlink if we
7149                       # can, copy if we must.  Note: delete the file
7150                       # first, in case it is a dangling symlink.
7151                       $message = "installing `$fullfile'";
7152                       # Windows Perl will hang if we try to delete a
7153                       # file that doesn't exist.
7154                       unlink ($fullfile) if -f $fullfile;
7155                       if ($symlink_exists && ! $copy_missing)
7156                         {
7157                           if (! symlink ("$libdir/$file", $fullfile))
7158                             {
7159                               $suppress = 0;
7160                               $trailer = "; error while making link: $!";
7161                             }
7162                         }
7163                       elsif (system ('cp', "$libdir/$file", $fullfile))
7164                         {
7165                           $suppress = 0;
7166                           $trailer = "\n    error while copying";
7167                         }
7168                       reset_dir_cache ($dir);
7169                     }
7170
7171                   if (! maybe_push_required_file (dirname ($fullfile),
7172                                                   $file, $fullfile))
7173                     {
7174                       if (! $found_it && ! $automake_will_process_aux_dir)
7175                         {
7176                           # We have added the file but could not push it
7177                           # into DIST_COMMON, probably because this is
7178                           # an auxiliary file and we are not processing
7179                           # the top level Makefile.  Furthermore Automake
7180                           # hasn't been asked to create the Makefile.in
7181                           # that distribute the aux dir files.
7182                           error ($where, 'Please make a full run of automake'
7183                                  . " so $fullfile gets distributed.");
7184                         }
7185                     }
7186                 }
7187               else
7188                 {
7189                   $trailer = "\n  `automake --add-missing' can install `$file'"
7190                     if -f "$libdir/$file";
7191                 }
7192
7193               # If --force-missing was specified, and we have
7194               # actually found the file, then do nothing.
7195               next
7196                 if $found_it && $force_missing;
7197
7198               # If we couldn' install the file, but it is a target in
7199               # the Makefile, don't print anything.  This allows files
7200               # like README, AUTHORS, or THANKS to be generated.
7201               next
7202                 if !$suppress && rule $file;
7203
7204               msg ($suppress ? 'note' : 'error', $where, "$message$trailer");
7205             }
7206         }
7207     }
7208 }
7209
7210 # &require_file ($WHERE, $MYSTRICT, @FILES)
7211 # -----------------------------------------
7212 sub require_file ($$@)
7213 {
7214     my ($where, $mystrict, @files) = @_;
7215     require_file_internal ($where, $mystrict, $relative_dir, @files);
7216 }
7217
7218 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7219 # -----------------------------------------------------------
7220 sub require_file_with_macro ($$$@)
7221 {
7222     my ($cond, $macro, $mystrict, @files) = @_;
7223     $macro = rvar ($macro) unless ref $macro;
7224     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7225 }
7226
7227 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7228 # ----------------------------------------------------------------
7229 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7230 # must be in that directory.  Otherwise expect it in the current directory.
7231 sub require_libsource_with_macro ($$$@)
7232 {
7233     my ($cond, $macro, $mystrict, @files) = @_;
7234     $macro = rvar ($macro) unless ref $macro;
7235     if ($config_libobj_dir)
7236       {
7237         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7238                                $config_libobj_dir, @files);
7239       }
7240     else
7241       {
7242         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7243       }
7244 }
7245
7246 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7247 # ----------------------------------------------
7248 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7249 sub require_conf_file ($$@)
7250 {
7251     my ($where, $mystrict, @files) = @_;
7252     require_file_internal ($where, $mystrict, $config_aux_dir, @files);
7253 }
7254
7255
7256 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7257 # ----------------------------------------------------------------
7258 sub require_conf_file_with_macro ($$$@)
7259 {
7260     my ($cond, $macro, $mystrict, @files) = @_;
7261     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7262                        $mystrict, @files);
7263 }
7264
7265 ################################################################
7266
7267 # &require_build_directory ($DIRECTORY)
7268 # ------------------------------------
7269 # Emit rules to create $DIRECTORY if needed, and return
7270 # the file that any target requiring this directory should be made
7271 # dependent upon.
7272 # We don't want to emit the rule twice, and want to reuse it
7273 # for directories with equivalent names (e.g., `foo/bar' and `./foo//bar').
7274 sub require_build_directory ($)
7275 {
7276   my $directory = shift;
7277
7278   return $directory_map{$directory} if exists $directory_map{$directory};
7279
7280   my $cdir = File::Spec->canonpath ($directory);
7281
7282   if (exists $directory_map{$cdir})
7283     {
7284       my $stamp = $directory_map{$cdir};
7285       $directory_map{$directory} = $stamp;
7286       return $stamp;
7287     }
7288
7289   my $dirstamp = "$cdir/\$(am__dirstamp)";
7290
7291   $directory_map{$directory} = $dirstamp;
7292   $directory_map{$cdir} = $dirstamp;
7293
7294   # Set a variable for the dirstamp basename.
7295   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7296                           '$(am__leading_dot)dirstamp');
7297
7298   # Directory must be removed by `make distclean'.
7299   $clean_files{$dirstamp} = DIST_CLEAN;
7300
7301   $output_rules .= ("$dirstamp:\n"
7302                     . "\t\@\$(mkdir_p) $directory\n"
7303                     . "\t\@: > $dirstamp\n");
7304
7305   return $dirstamp;
7306 }
7307
7308 # &require_build_directory_maybe ($FILE)
7309 # --------------------------------------
7310 # If $FILE lies in a subdirectory, emit a rule to create this
7311 # directory and return the file that $FILE should be made
7312 # dependent upon.  Otherwise, just return the empty string.
7313 sub require_build_directory_maybe ($)
7314 {
7315     my $file = shift;
7316     my $directory = dirname ($file);
7317
7318     if ($directory ne '.')
7319     {
7320         return require_build_directory ($directory);
7321     }
7322     else
7323     {
7324         return '';
7325     }
7326 }
7327
7328 ################################################################
7329
7330 # Push a list of files onto dist_common.
7331 sub push_dist_common
7332 {
7333   prog_error "push_dist_common run after handle_dist"
7334     if $handle_dist_run;
7335   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
7336                               '', INTERNAL, VAR_PRETTY);
7337 }
7338
7339
7340 ################################################################
7341
7342 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
7343 # ----------------------------------------------
7344 # Generate a Makefile.in given the name of the corresponding Makefile and
7345 # the name of the file output by config.status.
7346 sub generate_makefile ($$)
7347 {
7348   my ($makefile_am, $makefile_in) = @_;
7349
7350   # Reset all the Makefile.am related variables.
7351   initialize_per_input;
7352
7353   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
7354   # warnings for this file.  So hold any warning issued before
7355   # we have processed AUTOMAKE_OPTIONS.
7356   buffer_messages ('warning');
7357
7358   # Name of input file ("Makefile.am") and output file
7359   # ("Makefile.in").  These have no directory components.
7360   $am_file_name = basename ($makefile_am);
7361   $in_file_name = basename ($makefile_in);
7362
7363   # $OUTPUT is encoded.  If it contains a ":" then the first element
7364   # is the real output file, and all remaining elements are input
7365   # files.  We don't scan or otherwise deal with these input files,
7366   # other than to mark them as dependencies.  See
7367   # &scan_autoconf_files for details.
7368   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
7369
7370   $relative_dir = dirname ($makefile);
7371   $am_relative_dir = dirname ($makefile_am);
7372   $topsrcdir = backname ($relative_dir);
7373
7374   read_main_am_file ($makefile_am);
7375   if (handle_options)
7376     {
7377       # Process buffered warnings.
7378       flush_messages;
7379       # Fatal error.  Just return, so we can continue with next file.
7380       return;
7381     }
7382   # Process buffered warnings.
7383   flush_messages;
7384
7385   # There are a few install-related variables that you should not define.
7386   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
7387     {
7388       my $v = var $var;
7389       if ($v)
7390         {
7391           my $def = $v->def (TRUE);
7392           prog_error "$var not defined in condition TRUE"
7393             unless $def;
7394           reject_var $var, "`$var' should not be defined"
7395             if $def->owner != VAR_AUTOMAKE;
7396         }
7397     }
7398
7399   # Catch some obsolete variables.
7400   msg_var ('obsolete', 'INCLUDES',
7401            "`INCLUDES' is the old name for `AM_CPPFLAGS' (or `*_CPPFLAGS')")
7402     if var ('INCLUDES');
7403
7404   # Must do this after reading .am file.
7405   define_variable ('subdir', $relative_dir, INTERNAL);
7406
7407   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
7408   # recursive rules are enabled.
7409   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
7410     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
7411
7412   # Check first, because we might modify some state.
7413   check_cygnus;
7414   check_gnu_standards;
7415   check_gnits_standards;
7416
7417   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
7418   handle_gettext;
7419   handle_libraries;
7420   handle_ltlibraries;
7421   handle_programs;
7422   handle_scripts;
7423
7424   # These must be run after all the sources are scanned.  They
7425   # use variables defined by &handle_libraries, &handle_ltlibraries,
7426   # or &handle_programs.
7427   handle_compile;
7428   handle_languages;
7429   handle_libtool;
7430
7431   # Variables used by distdir.am and tags.am.
7432   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
7433   if (! option 'no-dist')
7434     {
7435       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
7436     }
7437
7438   handle_multilib;
7439   handle_texinfo;
7440   handle_emacs_lisp;
7441   handle_python;
7442   handle_java;
7443   handle_man_pages;
7444   handle_data;
7445   handle_headers;
7446   handle_subdirs;
7447   handle_tags;
7448   handle_minor_options;
7449   handle_tests;
7450
7451   # This must come after most other rules.
7452   handle_dist;
7453
7454   handle_footer;
7455   do_check_merge_target;
7456   handle_all ($makefile);
7457
7458   # FIXME: Gross!
7459   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
7460     {
7461       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
7462     }
7463
7464   handle_install;
7465   handle_clean ($makefile);
7466   handle_factored_dependencies;
7467
7468   # Comes last, because all the above procedures may have
7469   # defined or overridden variables.
7470   $output_vars .= output_variables;
7471
7472   check_typos;
7473
7474   my ($out_file) = $output_directory . '/' . $makefile_in;
7475
7476   if ($exit_code != 0)
7477     {
7478       verb "not writing $out_file because of earlier errors";
7479       return;
7480     }
7481
7482   if (! -d ($output_directory . '/' . $am_relative_dir))
7483     {
7484       mkdir ($output_directory . '/' . $am_relative_dir, 0755);
7485     }
7486
7487   # We make sure that `all:' is the first target.
7488   my $output =
7489     "$output_vars$output_all$output_header$output_rules$output_trailer";
7490
7491   # Decide whether we must update the output file or not.
7492   # We have to update in the following situations.
7493   #  * $force_generation is set.
7494   #  * any of the output dependencies is younger than the output
7495   #  * the contents of the output is different (this can happen
7496   #    if the project has been populated with a file listed in
7497   #    @common_files since the last run).
7498   # Output's dependencies are split in two sets:
7499   #  * dependencies which are also configure dependencies
7500   #    These do not change between each Makefile.am
7501   #  * other dependencies, specific to the Makefile.am being processed
7502   #    (such as the Makefile.am itself, or any Makefile fragment
7503   #    it includes).
7504   my $timestamp = mtime $out_file;
7505   if (! $force_generation
7506       && $configure_deps_greatest_timestamp < $timestamp
7507       && $output_deps_greatest_timestamp < $timestamp
7508       && $output eq contents ($out_file))
7509     {
7510       verb "$out_file unchanged";
7511       # No need to update.
7512       return;
7513     }
7514
7515   if (-e $out_file)
7516     {
7517       unlink ($out_file)
7518         or fatal "cannot remove $out_file: $!\n";
7519     }
7520
7521   my $gm_file = new Automake::XFile "> $out_file";
7522   verb "creating $out_file";
7523   print $gm_file $output;
7524 }
7525
7526 ################################################################
7527
7528
7529
7530
7531 ################################################################
7532
7533 # Print usage information.
7534 sub usage ()
7535 {
7536     print "Usage: $0 [OPTION] ... [Makefile]...
7537
7538 Generate Makefile.in for configure from Makefile.am.
7539
7540 Operation modes:
7541       --help               print this help, then exit
7542       --version            print version number, then exit
7543   -v, --verbose            verbosely list files processed
7544       --no-force           only update Makefile.in's that are out of date
7545   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
7546
7547 Dependency tracking:
7548   -i, --ignore-deps      disable dependency tracking code
7549       --include-deps     enable dependency tracking code
7550
7551 Flavors:
7552       --cygnus           assume program is part of Cygnus-style tree
7553       --foreign          set strictness to foreign
7554       --gnits            set strictness to gnits
7555       --gnu              set strictness to gnu
7556
7557 Library files:
7558   -a, --add-missing      add missing standard files to package
7559       --libdir=DIR       directory storing library files
7560   -c, --copy             with -a, copy missing files (default is symlink)
7561   -f, --force-missing    force update of standard files
7562
7563 ";
7564     Automake::ChannelDefs::usage;
7565
7566     my ($last, @lcomm);
7567     $last = '';
7568     foreach my $iter (sort ((@common_files, @common_sometimes)))
7569     {
7570         push (@lcomm, $iter) unless $iter eq $last;
7571         $last = $iter;
7572     }
7573
7574     my @four;
7575     print "\nFiles which are automatically distributed, if found:\n";
7576     format USAGE_FORMAT =
7577   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
7578   $four[0],           $four[1],           $four[2],           $four[3]
7579 .
7580     $~ = "USAGE_FORMAT";
7581
7582     my $cols = 4;
7583     my $rows = int(@lcomm / $cols);
7584     my $rest = @lcomm % $cols;
7585
7586     if ($rest)
7587     {
7588         $rows++;
7589     }
7590     else
7591     {
7592         $rest = $cols;
7593     }
7594
7595     for (my $y = 0; $y < $rows; $y++)
7596     {
7597         @four = ("", "", "", "");
7598         for (my $x = 0; $x < $cols; $x++)
7599         {
7600             last if $y + 1 == $rows && $x == $rest;
7601
7602             my $idx = (($x > $rest)
7603                        ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
7604                        : ($rows * $x));
7605
7606             $idx += $y;
7607             $four[$x] = $lcomm[$idx];
7608         }
7609         write;
7610     }
7611
7612     print "\nReport bugs to <bug-automake\@gnu.org>.\n";
7613
7614     # --help always returns 0 per GNU standards.
7615     exit 0;
7616 }
7617
7618
7619 # &version ()
7620 # -----------
7621 # Print version information
7622 sub version ()
7623 {
7624   print <<EOF;
7625 automake (GNU $PACKAGE) $VERSION
7626 Written by Tom Tromey <tromey\@redhat.com>
7627        and Alexandre Duret-Lutz <adl\@gnu.org>.
7628
7629 Copyright 2006 Free Software Foundation, Inc.
7630 This is free software; see the source for copying conditions.  There is NO
7631 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
7632 EOF
7633   # --version always returns 0 per GNU standards.
7634   exit 0;
7635 }
7636
7637 ################################################################
7638
7639 # Parse command line.
7640 sub parse_arguments ()
7641 {
7642   # Start off as gnu.
7643   set_strictness ('gnu');
7644
7645   my $cli_where = new Automake::Location;
7646   my %cli_options =
7647     (
7648      'libdir=s'         => \$libdir,
7649      'gnu'              => sub { set_strictness ('gnu'); },
7650      'gnits'            => sub { set_strictness ('gnits'); },
7651      'cygnus'           => sub { set_global_option ('cygnus', $cli_where); },
7652      'foreign'          => sub { set_strictness ('foreign'); },
7653      'include-deps'     => sub { unset_global_option ('no-dependencies'); },
7654      'i|ignore-deps'    => sub { set_global_option ('no-dependencies',
7655                                                     $cli_where); },
7656      'no-force'         => sub { $force_generation = 0; },
7657      'f|force-missing'  => \$force_missing,
7658      'o|output-dir=s'   => \$output_directory,
7659      'a|add-missing'    => \$add_missing,
7660      'c|copy'           => \$copy_missing,
7661      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
7662      'W|warnings=s'     => \&parse_warnings,
7663      # These long options (--Werror and --Wno-error) for backward
7664      # compatibility.  Use -Werror and -Wno-error today.
7665      'Werror'           => sub { parse_warnings 'W', 'error'; },
7666      'Wno-error'        => sub { parse_warnings 'W', 'no-error'; },
7667      );
7668   use Getopt::Long;
7669   Getopt::Long::config ("bundling", "pass_through");
7670
7671   # See if --version or --help is used.  We want to process these before
7672   # anything else because the GNU Coding Standards require us to
7673   # `exit 0' after processing these options, and we can't guarantee this
7674   # if we treat other options first.  (Handling other options first
7675   # could produce error diagnostics, and in this condition it is
7676   # confusing if Automake does `exit 0'.)
7677   my %cli_options_1st_pass =
7678     (
7679      'version' => \&version,
7680      'help'    => \&usage,
7681      # Recognize all other options (and their arguments) but do nothing.
7682      map { $_ => sub {} } (keys %cli_options)
7683      );
7684   my @ARGV_backup = @ARGV;
7685   Getopt::Long::GetOptions %cli_options_1st_pass
7686     or exit 1;
7687   @ARGV = @ARGV_backup;
7688
7689   # Now *really* process the options.  This time we know that --help
7690   # and --version are not present, but we specify them nonetheless so
7691   # that ambiguous abbreviation are diagnosed.
7692   Getopt::Long::GetOptions %cli_options, 'version' => sub {}, 'help' => sub {}
7693     or exit 1;
7694
7695   if (defined $output_directory)
7696     {
7697       msg 'obsolete', "`--output-dir' is deprecated\n";
7698     }
7699   else
7700     {
7701       # In the next release we'll remove this entirely.
7702       $output_directory = '.';
7703     }
7704
7705   return unless @ARGV;
7706
7707   if ($ARGV[0] =~ /^-./)
7708     {
7709       my %argopts;
7710       for my $k (keys %cli_options)
7711         {
7712           if ($k =~ /(.*)=s$/)
7713             {
7714               map { $argopts{(length ($_) == 1)
7715                              ? "-$_" : "--$_" } = 1; } (split (/\|/, $1));
7716             }
7717         }
7718       if ($ARGV[0] eq '--')
7719         {
7720           shift @ARGV;
7721         }
7722       elsif (exists $argopts{$ARGV[0]})
7723         {
7724           fatal ("option `$ARGV[0]' requires an argument\n"
7725                  . "Try `$0 --help' for more information.");
7726         }
7727       else
7728         {
7729           fatal ("unrecognized option `$ARGV[0]'.\n"
7730                  . "Try `$0 --help' for more information.");
7731         }
7732     }
7733
7734   my $errspec = 0;
7735   foreach my $arg (@ARGV)
7736     {
7737       fatal ("empty argument\nTry `$0 --help' for more information.")
7738         if ($arg eq '');
7739
7740       # Handle $local:$input syntax.
7741       my ($local, @rest) = split (/:/, $arg);
7742       @rest = ("$local.in",) unless @rest;
7743       my $input = locate_am @rest;
7744       if ($input)
7745         {
7746           push @input_files, $input;
7747           $output_files{$input} = join (':', ($local, @rest));
7748         }
7749       else
7750         {
7751           error "no Automake input file found for `$arg'";
7752           $errspec = 1;
7753         }
7754     }
7755   fatal "no input file found among supplied arguments"
7756     if $errspec && ! @input_files;
7757 }
7758
7759 ################################################################
7760
7761 # Parse the WARNINGS environment variable.
7762 parse_WARNINGS;
7763
7764 # Parse command line.
7765 parse_arguments;
7766
7767 $configure_ac = require_configure_ac;
7768
7769 # Do configure.ac scan only once.
7770 scan_autoconf_files;
7771
7772 if (! @input_files)
7773   {
7774     my $msg = '';
7775     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
7776       if -f 'Makefile.am';
7777     fatal ("no `Makefile.am' found for any configure output$msg");
7778   }
7779
7780 # Now do all the work on each file.
7781 foreach my $file (@input_files)
7782   {
7783     ($am_file = $file) =~ s/\.in$//;
7784     if (! -f ($am_file . '.am'))
7785       {
7786         error "`$am_file.am' does not exist";
7787       }
7788     else
7789       {
7790         # Any warning setting now local to this Makefile.am.
7791         dup_channel_setup;
7792
7793         generate_makefile ($am_file . '.am', $file);
7794
7795         # Back out any warning setting.
7796         drop_channel_setup;
7797       }
7798   }
7799
7800 exit $exit_code;
7801
7802
7803 ### Setup "GNU" style for perl-mode and cperl-mode.
7804 ## Local Variables:
7805 ## perl-indent-level: 2
7806 ## perl-continued-statement-offset: 2
7807 ## perl-continued-brace-offset: 0
7808 ## perl-brace-offset: 0
7809 ## perl-brace-imaginary-offset: 0
7810 ## perl-label-offset: -2
7811 ## cperl-indent-level: 2
7812 ## cperl-brace-offset: 0
7813 ## cperl-continued-brace-offset: 0
7814 ## cperl-label-offset: -2
7815 ## cperl-extra-newline-before-brace: t
7816 ## cperl-merge-trailing-else: nil
7817 ## cperl-continued-statement-offset: 2
7818 ## End: