automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
  10 # 2003, 2004, 2005  Free Software Foundation, Inc.
  11
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2, or (at your option)
  15 # any later version.
  16
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  25 # 02110-1301, USA.
  26
  27 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  28 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  29 # Alexandre Duret-Lutz <adl@gnu.org>.
  30
  31 package Language;
  32
  33 BEGIN
  34 {
  35   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  36   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  37
  38   # Override SHELL.  This is required on DJGPP so that system() uses
  39   # bash, not COMMAND.COM which doesn't quote arguments properly.
  40   # Other systems aren't expected to use $SHELL when Automake
  41   # runs, but it should be safe to drop the `if DJGPP' guard if
  42   # it turns up other systems need the same thing.  After all,
  43   # if SHELL is used, ./configure's SHELL is always better than
  44   # the user's SHELL (which may be something like tcsh).
  45   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJGPP'};
  46 }
  47
  48 use Automake::Struct;
  49 struct (# Short name of the language (c, f77...).
  50         'name' => "\$",
  51         # Nice name of the language (C, Fortran 77...).
  52         'Name' => "\$",
  53
  54         # List of configure variables which must be defined.
  55         'config_vars' => '@',
  56
  57         'ansi'    => "\$",
  58         # `pure' is `1' or `'.  A `pure' language is one where, if
  59         # all the files in a directory are of that language, then we
  60         # do not require the C compiler or any code to call it.
  61         'pure'   => "\$",
  62
  63         'autodep' => "\$",
  64
  65         # Name of the compiling variable (COMPILE).
  66         'compiler'  => "\$",
  67         # Content of the compiling variable.
  68         'compile'  => "\$",
  69         # Flag to require compilation without linking (-c).
  70         'compile_flag' => "\$",
  71         'extensions' => '@',
  72         # A subroutine to compute a list of possible extensions of
  73         # the product given the input extensions.
  74         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  75         'output_extensions' => "\$",
  76         # A list of flag variables used in 'compile'.
  77         # (defaults to [])
  78         'flags' => "@",
  79
  80         # Any tag to pass to libtool while compiling.
  81         'libtool_tag' => "\$",
  82
  83         # The file to use when generating rules for this language.
  84         # The default is 'depend2'.
  85         'rule_file' => "\$",
  86
  87         # Name of the linking variable (LINK).
  88         'linker' => "\$",
  89         # Content of the linking variable.
  90         'link' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} ();
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 use Automake::General;
 134 use Automake::XFile;
 135 use Automake::Channels;
 136 use Automake::ChannelDefs;
 137 use Automake::Configure_ac;
 138 use Automake::FileUtils;
 139 use Automake::Location;
 140 use Automake::Condition qw/TRUE FALSE/;
 141 use Automake::DisjConditions;
 142 use Automake::Options;
 143 use Automake::Version;
 144 use Automake::Variable;
 145 use Automake::VarDef;
 146 use Automake::Rule;
 147 use Automake::RuleDef;
 148 use Automake::Wrap 'makefile_wrap';
 149 use File::Basename;
 150 use File::Spec;
 151 use Carp;
 152
 153 ## ----------- ##
 154 ## Constants.  ##
 155 ## ----------- ##
 156
 157 # Some regular expressions.  One reason to put them here is that it
 158 # makes indentation work better in Emacs.
 159
 160 # Writing singled-quoted-$-terminated regexes is a pain because
 161 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 162 # by a closing quote.  Letting perl-mode think the quote is not closed
 163 # leads to all sort of misindentations.  On the other hand, defining
 164 # regexes as double-quoted strings is far less readable.  So usually
 165 # we will write:
 166 #
 167 #  $REGEX = '^regex_value' . "\$";
 168
 169 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 170 my $WHITE_PATTERN = '^\s*' . "\$";
 171 my $COMMENT_PATTERN = '^#';
 172 my $TARGET_PATTERN='[$a-zA-Z_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 173 # A rule has three parts: a list of targets, a list of dependencies,
 174 # and optionally actions.
 175 my $RULE_PATTERN =
 176   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 177
 178 # Only recognize leading spaces, not leading tabs.  If we recognize
 179 # leading tabs here then we need to make the reader smarter, because
 180 # otherwise it will think rules like `foo=bar; \' are errors.
 181 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 182 # This pattern recognizes a Gnits version id and sets $1 if the
 183 # release is an alpha release.  We also allow a suffix which can be
 184 # used to extend the version number with a "fork" identifier.
 185 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 186
 187 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 188 my $ELSE_PATTERN =
 189   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 190 my $ENDIF_PATTERN =
 191   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 192 my $PATH_PATTERN = '(\w|[+/.-])+';
 193 # This will pass through anything not of the prescribed form.
 194 my $INCLUDE_PATTERN = ('^include\s+'
 195                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 196                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 197                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 198
 199 # Match `-d' as a command-line argument in a string.
 200 my $DASH_D_PATTERN = "(^|\\s)-d(\\s|\$)";
 201 # Directories installed during 'install-exec' phase.
 202 my $EXEC_DIR_PATTERN =
 203   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 204
 205 # Values for AC_CANONICAL_*
 206 use constant AC_CANONICAL_BUILD  => 1;
 207 use constant AC_CANONICAL_HOST   => 2;
 208 use constant AC_CANONICAL_TARGET => 3;
 209
 210 # Values indicating when something should be cleaned.
 211 use constant MOSTLY_CLEAN     => 0;
 212 use constant CLEAN            => 1;
 213 use constant DIST_CLEAN       => 2;
 214 use constant MAINTAINER_CLEAN => 3;
 215
 216 # Libtool files.
 217 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 218 # ltconfig appears here for compatibility with old versions of libtool.
 219 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 220
 221 # Commonly found files we look for and automatically include in
 222 # DISTFILES.
 223 my @common_files =
 224     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 225         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 226         ansi2knr.1 ansi2knr.c compile config.guess config.rpath config.sub
 227         depcomp elisp-comp install-sh libversion.in mdate-sh missing
 228         mkinstalldirs py-compile texinfo.tex ylwrap),
 229      @libtool_files, @libtool_sometimes);
 230
 231 # Commonly used files we auto-include, but only sometimes.  This list
 232 # is used for the --help output only.
 233 my @common_sometimes =
 234   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 235      configure.ac configure.in stamp-vti);
 236
 237 # Standard directories from the GNU Coding Standards, and additional
 238 # pkg* directories from Automake.  Stored in a hash for fast member check.
 239 my %standard_prefix =
 240     map { $_ => 1 } (qw(bin data dataroot dvi exec html include info
 241                         lib libexec lisp localstate man man1 man2 man3
 242                         man4 man5 man6 man7 man8 man9 oldinclude pdf
 243                         pkgdatadir pkgincludedir pkglibdir ps sbin
 244                         sharedstate sysconf));
 245
 246 # Copyright on generated Makefile.ins.
 247 my $gen_copyright = "\
 248 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
 249 # 2003, 2004, 2005  Free Software Foundation, Inc.
 250 # This Makefile.in is free software; the Free Software Foundation
 251 # gives unlimited permission to copy and/or distribute it,
 252 # with or without modifications, as long as this notice is preserved.
 253
 254 # This program is distributed in the hope that it will be useful,
 255 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 256 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 257 # PARTICULAR PURPOSE.
 258 ";
 259
 260 # These constants are returned by lang_*_rewrite functions.
 261 # LANG_SUBDIR means that the resulting object file should be in a
 262 # subdir if the source file is.  In this case the file name cannot
 263 # have `..' components.
 264 use constant LANG_IGNORE  => 0;
 265 use constant LANG_PROCESS => 1;
 266 use constant LANG_SUBDIR  => 2;
 267
 268 # These are used when keeping track of whether an object can be built
 269 # by two different paths.
 270 use constant COMPILE_LIBTOOL  => 1;
 271 use constant COMPILE_ORDINARY => 2;
 272
 273 # We can't always associate a location to a variable or a rule,
 274 # when its defined by Automake.  We use INTERNAL in this case.
 275 use constant INTERNAL => new Automake::Location;
 276 \f
 277
 278 ## ---------------------------------- ##
 279 ## Variables related to the options.  ##
 280 ## ---------------------------------- ##
 281
 282 # TRUE if we should always generate Makefile.in.
 283 my $force_generation = 1;
 284
 285 # From the Perl manual.
 286 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 287
 288 # TRUE if missing standard files should be installed.
 289 my $add_missing = 0;
 290
 291 # TRUE if we should copy missing files; otherwise symlink if possible.
 292 my $copy_missing = 0;
 293
 294 # TRUE if we should always update files that we know about.
 295 my $force_missing = 0;
 296
 297
 298 ## ---------------------------------------- ##
 299 ## Variables filled during files scanning.  ##
 300 ## ---------------------------------------- ##
 301
 302 # Name of the configure.ac file.
 303 my $configure_ac;
 304
 305 # Files found by scanning configure.ac for LIBOBJS.
 306 my %libsources = ();
 307
 308 # Names used in AC_CONFIG_HEADER call.
 309 my @config_headers = ();
 310
 311 # Names used in AC_CONFIG_LINKS call.
 312 my @config_links = ();
 313
 314 # Directory where output files go.  Actually, output files are
 315 # relative to this directory.
 316 my $output_directory;
 317
 318 # List of Makefile.am's to process, and their corresponding outputs.
 319 my @input_files = ();
 320 my %output_files = ();
 321
 322 # Complete list of Makefile.am's that exist.
 323 my @configure_input_files = ();
 324
 325 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 326 # and their outputs.
 327 my @other_input_files = ();
 328 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 329 # The keys are the files created by these macros.
 330 my %ac_config_files_location = ();
 331
 332 # Directory to search for configure-required files.  This
 333 # will be computed by &locate_aux_dir and can be set using
 334 # AC_CONFIG_AUX_DIR in configure.ac.
 335 # $CONFIG_AUX_DIR is the `raw' directory, valid only in the source-tree.
 336 my $config_aux_dir = '';
 337 my $config_aux_dir_set_in_configure_ac = 0;
 338 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 339 # in Makefiles.
 340 my $am_config_aux_dir = '';
 341
 342 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 343 # in configure.ac.
 344 my $config_libobj_dir = '';
 345
 346 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 347 my $seen_gettext = 0;
 348 # Whether AM_GNU_GETTEXT([external]) is used.
 349 my $seen_gettext_external = 0;
 350 # Where AM_GNU_GETTEXT appears.
 351 my $ac_gettext_location;
 352
 353 # Lists of tags supported by Libtool.
 354 my %libtool_tags = ();
 355 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 356 # use AC_REQUIRE_AUX_FILE.
 357 my $libtool_new_api = 0;
 358
 359 # Most important AC_CANONICAL_* macro seen so far.
 360 my $seen_canonical = 0;
 361 # Location of that macro.
 362 my $canonical_location;
 363
 364 # Where AM_MAINTAINER_MODE appears.
 365 my $seen_maint_mode;
 366
 367 # Actual version we've seen.
 368 my $package_version = '';
 369
 370 # Where version is defined.
 371 my $package_version_location;
 372
 373 # TRUE if we've seen AC_ENABLE_MULTILIB.
 374 my $seen_multilib = 0;
 375
 376 # TRUE if we've seen AM_PROG_CC_C_O
 377 my $seen_cc_c_o = 0;
 378
 379 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 380 my %required_aux_file = ();
 381
 382 # Where AM_INIT_AUTOMAKE is called;
 383 my $seen_init_automake = 0;
 384
 385 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 386 my $seen_automake_version = 0;
 387
 388 # Hash table of discovered configure substitutions.  Keys are names,
 389 # values are `FILE:LINE' strings which are used by error message
 390 # generation.
 391 my %configure_vars = ();
 392
 393 # Files included by $configure_ac.
 394 my @configure_deps = ();
 395
 396 # Greatest timestamp of configure's dependencies.
 397 my $configure_deps_greatest_timestamp = 0;
 398
 399 # Hash table of AM_CONDITIONAL variables seen in configure.
 400 my %configure_cond = ();
 401
 402 # This maps extensions onto language names.
 403 my %extension_map = ();
 404
 405 # List of the DIST_COMMON files we discovered while reading
 406 # configure.in
 407 my $configure_dist_common = '';
 408
 409 # This maps languages names onto objects.
 410 my %languages = ();
 411 # Maps each linker variable onto a language object.
 412 my %link_languages = ();
 413
 414 # List of targets we must always output.
 415 # FIXME: Complete, and remove falsely required targets.
 416 my %required_targets =
 417   (
 418    'all'          => 1,
 419    'dvi'          => 1,
 420    'pdf'          => 1,
 421    'ps'           => 1,
 422    'info'         => 1,
 423    'install-info' => 1,
 424    'install'      => 1,
 425    'install-data' => 1,
 426    'install-exec' => 1,
 427    'uninstall'    => 1,
 428
 429    # FIXME: Not required, temporary hacks.
 430    # Well, actually they are sort of required: the -recursive
 431    # targets will run them anyway...
 432    'dvi-am'          => 1,
 433    'pdf-am'          => 1,
 434    'ps-am'           => 1,
 435    'info-am'         => 1,
 436    'install-data-am' => 1,
 437    'install-exec-am' => 1,
 438    'installcheck-am' => 1,
 439    'uninstall-am' => 1,
 440
 441    'install-man' => 1,
 442   );
 443
 444 # Set to 1 if this run will create the Makefile.in that distribute
 445 # the files in config_aux_dir.
 446 my $automake_will_process_aux_dir = 0;
 447
 448 # The name of the Makefile currently being processed.
 449 my $am_file = 'BUG';
 450 \f
 451
 452 ################################################################
 453
 454 ## ------------------------------------------ ##
 455 ## Variables reset by &initialize_per_input.  ##
 456 ## ------------------------------------------ ##
 457
 458 # Basename and relative dir of the input file.
 459 my $am_file_name;
 460 my $am_relative_dir;
 461
 462 # Same but wrt Makefile.in.
 463 my $in_file_name;
 464 my $relative_dir;
 465
 466 # Greatest timestamp of the output's dependencies (excluding
 467 # configure's dependencies).
 468 my $output_deps_greatest_timestamp;
 469
 470 # These two variables are used when generating each Makefile.in.
 471 # They hold the Makefile.in until it is ready to be printed.
 472 my $output_rules;
 473 my $output_vars;
 474 my $output_trailer;
 475 my $output_all;
 476 my $output_header;
 477
 478 # This is the conditional stack, updated on if/else/endif, and
 479 # used to build Condition objects.
 480 my @cond_stack;
 481
 482 # This holds the set of included files.
 483 my @include_stack;
 484
 485 # This holds a list of directories which we must create at `dist'
 486 # time.  This is used in some strange scenarios involving weird
 487 # AC_OUTPUT commands.
 488 my %dist_dirs;
 489
 490 # List of dependencies for the obvious targets.
 491 my @all;
 492 my @check;
 493 my @check_tests;
 494
 495 # Keys in this hash table are files to delete.  The associated
 496 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 497 my %clean_files;
 498
 499 # Keys in this hash table are object files or other files in
 500 # subdirectories which need to be removed.  This only holds files
 501 # which are created by compilations.  The value in the hash indicates
 502 # when the file should be removed.
 503 my %compile_clean_files;
 504
 505 # Keys in this hash table are directories where we expect to build a
 506 # libtool object.  We use this information to decide what directories
 507 # to delete.
 508 my %libtool_clean_directories;
 509
 510 # Value of `$(SOURCES)', used by tags.am.
 511 my @sources;
 512 # Sources which go in the distribution.
 513 my @dist_sources;
 514
 515 # This hash maps object file names onto their corresponding source
 516 # file names.  This is used to ensure that each object is created
 517 # by a single source file.
 518 my %object_map;
 519
 520 # This hash maps object file names onto an integer value representing
 521 # whether this object has been built via ordinary compilation or
 522 # libtool compilation (the COMPILE_* constants).
 523 my %object_compilation_map;
 524
 525
 526 # This keeps track of the directories for which we've already
 527 # created dirstamp code.  Keys are directories, values are stamp files.
 528 # Several keys can share the same stamp files if they are equivalent
 529 # (as are `.//foo' and `foo').
 530 my %directory_map;
 531
 532 # All .P files.
 533 my %dep_files;
 534
 535 # This is a list of all targets to run during "make dist".
 536 my @dist_targets;
 537
 538 # Keys in this hash are the basenames of files which must depend on
 539 # ansi2knr.  Values are either the empty string, or the directory in
 540 # which the ANSI source file appears; the directory must have a
 541 # trailing `/'.
 542 my %de_ansi_files;
 543
 544 # This is the name of the redirect `all' target to use.
 545 my $all_target;
 546
 547 # This keeps track of which extensions we've seen (that we care
 548 # about).
 549 my %extension_seen;
 550
 551 # This is random scratch space for the language finish functions.
 552 # Don't randomly overwrite it; examine other uses of keys first.
 553 my %language_scratch;
 554
 555 # We keep track of which objects need special (per-executable)
 556 # handling on a per-language basis.
 557 my %lang_specific_files;
 558
 559 # This is set when `handle_dist' has finished.  Once this happens,
 560 # we should no longer push on dist_common.
 561 my $handle_dist_run;
 562
 563 # Used to store a set of linkers needed to generate the sources currently
 564 # under consideration.
 565 my %linkers_used;
 566
 567 # True if we need `LINK' defined.  This is a hack.
 568 my $need_link;
 569
 570 # Was get_object_extension run?
 571 # FIXME: This is a hack. a better switch should be found.
 572 my $get_object_extension_was_run;
 573
 574 # Record each file processed by make_paragraphs.
 575 my %transformed_files;
 576
 577 # Cache each file processed by make_paragraphs.
 578 # (This is different from %transformed_files because
 579 # %transformed_files is reset for each file while %am_file_cache
 580 # it global to the run.)
 581 my %am_file_cache;
 582
 583 ################################################################
 584
 585 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 586 # ------------------------------------
 587 # This is called by Automake::Variable::define() when SUFFIXES
 588 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 589 # The work here needs to be performed as a side-effect of the
 590 # macro_define() call because SUFFIXES definitions impact
 591 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 592 # the input am file.
 593 sub var_SUFFIXES_trigger ($$)
 594 {
 595     my ($type, $value) = @_;
 596     accept_extensions (split (' ', $value));
 597 }
 598 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 599
 600 ################################################################
 601
 602 ## --------------------------------- ##
 603 ## Forward subroutine declarations.  ##
 604 ## --------------------------------- ##
 605 sub register_language (%);
 606 sub file_contents_internal ($$$%);
 607 sub define_files_variable ($\@$$);
 608
 609
 610 # &initialize_per_input ()
 611 # ------------------------
 612 # (Re)-Initialize per-Makefile.am variables.
 613 sub initialize_per_input ()
 614 {
 615     reset_local_duplicates ();
 616
 617     $am_file_name = '';
 618     $am_relative_dir = '';
 619
 620     $in_file_name = '';
 621     $relative_dir = '';
 622
 623     $output_deps_greatest_timestamp = 0;
 624
 625     $output_rules = '';
 626     $output_vars = '';
 627     $output_trailer = '';
 628     $output_all = '';
 629     $output_header = '';
 630
 631     Automake::Options::reset;
 632     Automake::Variable::reset;
 633     Automake::Rule::reset;
 634
 635     @cond_stack = ();
 636
 637     @include_stack = ();
 638
 639     %dist_dirs = ();
 640
 641     @all = ();
 642     @check = ();
 643     @check_tests = ();
 644
 645     %clean_files = ();
 646
 647     @sources = ();
 648     @dist_sources = ();
 649
 650     %object_map = ();
 651     %object_compilation_map = ();
 652
 653     %directory_map = ();
 654
 655     %dep_files = ();
 656
 657     @dist_targets = ();
 658
 659     %de_ansi_files = ();
 660
 661     $all_target = '';
 662
 663     %extension_seen = ();
 664
 665     %language_scratch = ();
 666
 667     %lang_specific_files = ();
 668
 669     $handle_dist_run = 0;
 670
 671     $need_link = 0;
 672
 673     $get_object_extension_was_run = 0;
 674
 675     %compile_clean_files = ();
 676
 677     # We always include `.'.  This isn't strictly correct.
 678     %libtool_clean_directories = ('.' => 1);
 679
 680     %transformed_files = ();
 681 }
 682
 683
 684 ################################################################
 685
 686 # Initialize our list of languages that are internally supported.
 687
 688 # C.
 689 register_language ('name' => 'c',
 690                    'Name' => 'C',
 691                    'config_vars' => ['CC'],
 692                    'ansi' => 1,
 693                    'autodep' => '',
 694                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 695                    'compiler' => 'COMPILE',
 696                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 697                    'lder' => 'CCLD',
 698                    'ld' => '$(CC)',
 699                    'linker' => 'LINK',
 700                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 701                    'compile_flag' => '-c',
 702                    'libtool_tag' => 'CC',
 703                    'extensions' => ['.c'],
 704                    '_finish' => \&lang_c_finish);
 705
 706 # C++.
 707 register_language ('name' => 'cxx',
 708                    'Name' => 'C++',
 709                    'config_vars' => ['CXX'],
 710                    'linker' => 'CXXLINK',
 711                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 712                    'autodep' => 'CXX',
 713                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 714                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 715                    'compiler' => 'CXXCOMPILE',
 716                    'compile_flag' => '-c',
 717                    'output_flag' => '-o',
 718                    'libtool_tag' => 'CXX',
 719                    'lder' => 'CXXLD',
 720                    'ld' => '$(CXX)',
 721                    'pure' => 1,
 722                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 723
 724 # Objective C.
 725 register_language ('name' => 'objc',
 726                    'Name' => 'Objective C',
 727                    'config_vars' => ['OBJC'],
 728                    'linker' => 'OBJCLINK',,
 729                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 730                    'autodep' => 'OBJC',
 731                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 732                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 733                    'compiler' => 'OBJCCOMPILE',
 734                    'compile_flag' => '-c',
 735                    'output_flag' => '-o',
 736                    'lder' => 'OBJCLD',
 737                    'ld' => '$(OBJC)',
 738                    'pure' => 1,
 739                    'extensions' => ['.m']);
 740
 741 # Headers.
 742 register_language ('name' => 'header',
 743                    'Name' => 'Header',
 744                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 745                                     '.hpp', '.inc'],
 746                    # No output.
 747                    'output_extensions' => sub { return () },
 748                    # Nothing to do.
 749                    '_finish' => sub { });
 750
 751 # Yacc (C & C++).
 752 register_language ('name' => 'yacc',
 753                    'Name' => 'Yacc',
 754                    'config_vars' => ['YACC'],
 755                    'flags' => ['YFLAGS'],
 756                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 757                    'compiler' => 'YACCCOMPILE',
 758                    'extensions' => ['.y'],
 759                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 760                                                 return ($ext,) },
 761                    'rule_file' => 'yacc',
 762                    '_finish' => \&lang_yacc_finish,
 763                    '_target_hook' => \&lang_yacc_target_hook,
 764                    'nodist_specific' => 1);
 765 register_language ('name' => 'yaccxx',
 766                    'Name' => 'Yacc (C++)',
 767                    'config_vars' => ['YACC'],
 768                    'rule_file' => 'yacc',
 769                    'flags' => ['YFLAGS'],
 770                    'compiler' => 'YACCCOMPILE',
 771                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 772                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 773                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 774                                                 return ($ext,) },
 775                    '_finish' => \&lang_yacc_finish,
 776                    '_target_hook' => \&lang_yacc_target_hook,
 777                    'nodist_specific' => 1);
 778
 779 # Lex (C & C++).
 780 register_language ('name' => 'lex',
 781                    'Name' => 'Lex',
 782                    'config_vars' => ['LEX'],
 783                    'rule_file' => 'lex',
 784                    'flags' => ['LFLAGS'],
 785                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 786                    'compiler' => 'LEXCOMPILE',
 787                    'extensions' => ['.l'],
 788                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 789                                                 return ($ext,) },
 790                    '_finish' => \&lang_lex_finish,
 791                    '_target_hook' => \&lang_lex_target_hook,
 792                    'nodist_specific' => 1);
 793 register_language ('name' => 'lexxx',
 794                    'Name' => 'Lex (C++)',
 795                    'config_vars' => ['LEX'],
 796                    'rule_file' => 'lex',
 797                    'flags' => ['LFLAGS'],
 798                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 799                    'compiler' => 'LEXCOMPILE',
 800                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 801                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 802                                                 return ($ext,) },
 803                    '_finish' => \&lang_lex_finish,
 804                    '_target_hook' => \&lang_lex_target_hook,
 805                    'nodist_specific' => 1);
 806
 807 # Assembler.
 808 register_language ('name' => 'asm',
 809                    'Name' => 'Assembler',
 810                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 811
 812                    'flags' => ['CCASFLAGS'],
 813                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 814                    # or anything else required.  They can also set CCAS.
 815                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 816                    'compiler' => 'CCASCOMPILE',
 817                    'compile_flag' => '-c',
 818                    'extensions' => ['.s'],
 819
 820                    # With assembly we still use the C linker.
 821                    '_finish' => \&lang_c_finish);
 822
 823 # Preprocessed Assembler.
 824 register_language ('name' => 'cppasm',
 825                    'Name' => 'Preprocessed Assembler',
 826                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 827
 828                    'autodep' => 'CCAS',
 829                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 830                    # Users can set AM_ASFLAGS to include DEFS, INCLUDES,
 831                    # or anything else required.  They can also set CCAS.
 832                    'compile' => '$(CCAS) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 833                    'compiler' => 'CPPASCOMPILE',
 834                    'compile_flag' => '-c',
 835                    'extensions' => ['.S'],
 836
 837                    # With assembly we still use the C linker.
 838                    '_finish' => \&lang_c_finish);
 839
 840 # Fortran 77
 841 register_language ('name' => 'f77',
 842                    'Name' => 'Fortran 77',
 843                    'linker' => 'F77LINK',
 844                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 845                    'flags' => ['FFLAGS'],
 846                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 847                    'compiler' => 'F77COMPILE',
 848                    'compile_flag' => '-c',
 849                    'output_flag' => '-o',
 850                    'libtool_tag' => 'F77',
 851                    'lder' => 'F77LD',
 852                    'ld' => '$(F77)',
 853                    'pure' => 1,
 854                    'extensions' => ['.f', '.for']);
 855
 856 # Fortran
 857 register_language ('name' => 'fc',
 858                    'Name' => 'Fortran',
 859                    'linker' => 'FCLINK',
 860                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 861                    'flags' => ['FCFLAGS'],
 862                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 863                    'compiler' => 'FCCOMPILE',
 864                    'compile_flag' => '-c',
 865                    'output_flag' => '-o',
 866                    'lder' => 'FCLD',
 867                    'ld' => '$(FC)',
 868                    'pure' => 1,
 869                    'extensions' => ['.f90', '.f95']);
 870
 871 # Preprocessed Fortran
 872 register_language ('name' => 'ppfc',
 873                    'Name' => 'Preprocessed Fortran',
 874                    'config_vars' => ['FC'],
 875                    'linker' => 'FCLINK',
 876                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 877                    'lder' => 'FCLD',
 878                    'ld' => '$(FC)',
 879                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 880                    'compiler' => 'PPFCCOMPILE',
 881                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 882                    'compile_flag' => '-c',
 883                    'output_flag' => '-o',
 884                    'libtool_tag' => 'FC',
 885                    'pure' => 1,
 886                    'extensions' => ['.F90','.F95']);
 887
 888 # Preprocessed Fortran 77
 889 #
 890 # The current support for preprocessing Fortran 77 just involves
 891 # passing `$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 892 # $(CPPFLAGS)' as additional flags to the Fortran 77 compiler, since
 893 # this is how GNU Make does it; see the `GNU Make Manual, Edition 0.51
 894 # for `make' Version 3.76 Beta' (specifically, from info file
 895 # `(make)Catalogue of Rules').
 896 #
 897 # A better approach would be to write an Autoconf test
 898 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 899 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 900 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 901 # preprocessing capabilities, and then fall back on cpp (if cpp were
 902 # available).
 903 register_language ('name' => 'ppf77',
 904                    'Name' => 'Preprocessed Fortran 77',
 905                    'config_vars' => ['F77'],
 906                    'linker' => 'F77LINK',
 907                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 908                    'lder' => 'F77LD',
 909                    'ld' => '$(F77)',
 910                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 911                    'compiler' => 'PPF77COMPILE',
 912                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 913                    'compile_flag' => '-c',
 914                    'output_flag' => '-o',
 915                    'libtool_tag' => 'F77',
 916                    'pure' => 1,
 917                    'extensions' => ['.F']);
 918
 919 # Ratfor.
 920 register_language ('name' => 'ratfor',
 921                    'Name' => 'Ratfor',
 922                    'config_vars' => ['F77'],
 923                    'linker' => 'F77LINK',
 924                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 925                    'lder' => 'F77LD',
 926                    'ld' => '$(F77)',
 927                    'flags' => ['RFLAGS', 'FFLAGS'],
 928                    # FIXME also FFLAGS.
 929                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
 930                    'compiler' => 'RCOMPILE',
 931                    'compile_flag' => '-c',
 932                    'output_flag' => '-o',
 933                    'libtool_tag' => 'F77',
 934                    'pure' => 1,
 935                    'extensions' => ['.r']);
 936
 937 # Java via gcj.
 938 register_language ('name' => 'java',
 939                    'Name' => 'Java',
 940                    'config_vars' => ['GCJ'],
 941                    'linker' => 'GCJLINK',
 942                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 943                    'autodep' => 'GCJ',
 944                    'flags' => ['GCJFLAGS'],
 945                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
 946                    'compiler' => 'GCJCOMPILE',
 947                    'compile_flag' => '-c',
 948                    'output_flag' => '-o',
 949                    'libtool_tag' => 'GCJ',
 950                    'lder' => 'GCJLD',
 951                    'ld' => '$(GCJ)',
 952                    'pure' => 1,
 953                    'extensions' => ['.java', '.class', '.zip', '.jar']);
 954
 955 ################################################################
 956
 957 # Error reporting functions.
 958
 959 # err_am ($MESSAGE, [%OPTIONS])
 960 # -----------------------------
 961 # Uncategorized errors about the current Makefile.am.
 962 sub err_am ($;%)
 963 {
 964   msg_am ('error', @_);
 965 }
 966
 967 # err_ac ($MESSAGE, [%OPTIONS])
 968 # -----------------------------
 969 # Uncategorized errors about configure.ac.
 970 sub err_ac ($;%)
 971 {
 972   msg_ac ('error', @_);
 973 }
 974
 975 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
 976 # ---------------------------------------
 977 # Messages about about the current Makefile.am.
 978 sub msg_am ($$;%)
 979 {
 980   my ($channel, $msg, %opts) = @_;
 981   msg $channel, "${am_file}.am", $msg, %opts;
 982 }
 983
 984 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
 985 # ---------------------------------------
 986 # Messages about about configure.ac.
 987 sub msg_ac ($$;%)
 988 {
 989   my ($channel, $msg, %opts) = @_;
 990   msg $channel, $configure_ac, $msg, %opts;
 991 }
 992
 993 ################################################################
 994
 995 # subst ($TEXT)
 996 # -------------
 997 # Return a configure-style substitution using the indicated text.
 998 # We do this to avoid having the substitutions directly in automake.in;
 999 # when we do that they are sometimes removed and this causes confusion
1000 # and bugs.
1001 sub subst ($)
1002 {
1003     my ($text) = @_;
1004     return '@' . $text . '@';
1005 }
1006
1007 ################################################################
1008
1009
1010 # $BACKPATH
1011 # &backname ($REL-DIR)
1012 # --------------------
1013 # If I `cd $REL-DIR', then to come back, I should `cd $BACKPATH'.
1014 # For instance `src/foo' => `../..'.
1015 # Works with non strictly increasing paths, i.e., `src/../lib' => `..'.
1016 sub backname ($)
1017 {
1018     my ($file) = @_;
1019     my @res;
1020     foreach (split (/\//, $file))
1021     {
1022         next if $_ eq '.' || $_ eq '';
1023         if ($_ eq '..')
1024         {
1025             pop @res;
1026         }
1027         else
1028         {
1029             push (@res, '..');
1030         }
1031     }
1032     return join ('/', @res) || '.';
1033 }
1034
1035 ################################################################
1036
1037
1038 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1039 sub handle_options
1040 {
1041   my $var = var ('AUTOMAKE_OPTIONS');
1042   if ($var)
1043     {
1044       # FIXME: We should disallow conditional definitions of AUTOMAKE_OPTIONS.
1045       if (process_option_list ($var->rdef (TRUE)->location,
1046                                $var->value_as_list_recursive (cond_filter =>
1047                                                               TRUE)))
1048         {
1049           return 1;
1050         }
1051     }
1052
1053   if ($strictness == GNITS)
1054     {
1055       set_option ('readme-alpha', INTERNAL);
1056       set_option ('std-options', INTERNAL);
1057       set_option ('check-news', INTERNAL);
1058     }
1059
1060   return 0;
1061 }
1062
1063 # shadow_unconditionally ($varname, $where)
1064 # -----------------------------------------
1065 # Return a $(variable) that contains all possible values
1066 # $varname can take.
1067 # If the VAR wasn't defined conditionally, return $(VAR).
1068 # Otherwise we create a am__VAR_DIST variable which contains
1069 # all possible values, and return $(am__VAR_DIST).
1070 sub shadow_unconditionally ($$)
1071 {
1072   my ($varname, $where) = @_;
1073   my $var = var $varname;
1074   if ($var->has_conditional_contents)
1075     {
1076       $varname = "am__${varname}_DIST";
1077       my @files = uniq ($var->value_as_list_recursive);
1078       define_pretty_variable ($varname, TRUE, $where, @files);
1079     }
1080   return "\$($varname)"
1081 }
1082
1083 # get_object_extension ($EXTENSION)
1084 # ---------------------------------
1085 # Prefix $EXTENSION with $U if ansi2knr is in use.
1086 sub get_object_extension ($)
1087 {
1088     my ($extension) = @_;
1089
1090     # Check for automatic de-ANSI-fication.
1091     $extension = '$U' . $extension
1092       if option 'ansi2knr';
1093
1094     $get_object_extension_was_run = 1;
1095
1096     return $extension;
1097 }
1098
1099 # check_user_variables (@LIST)
1100 # ----------------------------
1101 # Make sure each variable VAR in @LIST do not exist, suggest using AM_VAR
1102 # otherwise.
1103 sub check_user_variables (@)
1104 {
1105   my @dont_override = @_;
1106   foreach my $flag (@dont_override)
1107     {
1108       my $var = var $flag;
1109       if ($var)
1110         {
1111           for my $cond ($var->conditions->conds)
1112             {
1113               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1114                 {
1115                   msg_cond_var ('gnu', $cond, $flag,
1116                                 "`$flag' is a user variable, "
1117                                 . "you should not override it;\n"
1118                                 . "use `AM_$flag' instead.");
1119                 }
1120             }
1121         }
1122     }
1123 }
1124
1125 # Call finish function for each language that was used.
1126 sub handle_languages
1127 {
1128     if (! option 'no-dependencies')
1129     {
1130         # Include auto-dep code.  Don't include it if DEP_FILES would
1131         # be empty.
1132         if (&saw_sources_p (0) && keys %dep_files)
1133         {
1134             # Set location of depcomp.
1135             &define_variable ('depcomp',
1136                               "\$(SHELL) $am_config_aux_dir/depcomp",
1137                               INTERNAL);
1138             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1139
1140             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1141
1142             my @deplist = sort keys %dep_files;
1143             # Generate each `include' individually.  Irix 6 make will
1144             # not properly include several files resulting from a
1145             # variable expansion; generating many separate includes
1146             # seems safest.
1147             $output_rules .= "\n";
1148             foreach my $iter (@deplist)
1149             {
1150                 $output_rules .= (subst ('AMDEP_TRUE')
1151                                   . subst ('am__include')
1152                                   . ' '
1153                                   . subst ('am__quote')
1154                                   . $iter
1155                                   . subst ('am__quote')
1156                                   . "\n");
1157             }
1158
1159             # Compute the set of directories to remove in distclean-depend.
1160             my @depdirs = uniq (map { dirname ($_) } @deplist);
1161             $output_rules .= &file_contents ('depend',
1162                                              new Automake::Location,
1163                                              DEPDIRS => "@depdirs");
1164         }
1165     }
1166     else
1167     {
1168         &define_variable ('depcomp', '', INTERNAL);
1169         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1170     }
1171
1172     my %done;
1173
1174     # Is the c linker needed?
1175     my $needs_c = 0;
1176     foreach my $ext (sort keys %extension_seen)
1177     {
1178         next unless $extension_map{$ext};
1179
1180         my $lang = $languages{$extension_map{$ext}};
1181
1182         my $rule_file = $lang->rule_file || 'depend2';
1183
1184         # Get information on $LANG.
1185         my $pfx = $lang->autodep;
1186         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1187
1188         my ($AMDEP, $FASTDEP) =
1189           (option 'no-dependencies' || $lang->autodep eq 'no')
1190           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1191
1192         my %transform = ('EXT'     => $ext,
1193                          'PFX'     => $pfx,
1194                          'FPFX'    => $fpfx,
1195                          'AMDEP'   => $AMDEP,
1196                          'FASTDEP' => $FASTDEP,
1197                          '-c'      => $lang->compile_flag || '',
1198                          'MORE-THAN-ONE'
1199                                    => (count_files_for_language ($lang->name) > 1),
1200                          # These are not used, but they need to be defined
1201                          # so &transform do not complain.
1202                          SUBDIROBJ     => 0,
1203                          'DERIVED-EXT' => 'BUG',
1204                          DIST_SOURCE   => 1,
1205                         );
1206
1207         # Generate the appropriate rules for this extension.
1208         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1209             || defined $lang->compile)
1210         {
1211             # Some C compilers don't support -c -o.  Use it only if really
1212             # needed.
1213             my $output_flag = $lang->output_flag || '';
1214             $output_flag = '-o'
1215               if (! $output_flag
1216                   && $lang->name eq 'c'
1217                   && option 'subdir-objects');
1218
1219             # Compute a possible derived extension.
1220             # This is not used by depend2.am.
1221             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1222
1223             # When we output an inference rule like `.c.o:' we
1224             # have two cases to consider: either subdir-objects
1225             # is used, or it is not.
1226             #
1227             # In the latter case the rule is used to build objects
1228             # in the current directory, and dependencies always
1229             # go into `./$(DEPDIR)/'.  We can hard-code this value.
1230             #
1231             # In the former case the rule can be used to build
1232             # objects in sub-directories too.  Dependencies should
1233             # go into the appropriate sub-directories, e.g.,
1234             # `sub/$(DEPDIR)/'.  The value of this directory
1235             # need the be computed on-the-fly.
1236             #
1237             # DEPBASE holds the name of this directory, plus the
1238             # basename part of the object file (extensions Po, TPo,
1239             # Plo, TPlo will be added later as appropriate).  It is
1240             # either hardcoded, or a shell variable (`$depbase') that
1241             # will be computed by the rule.
1242             my $depbase =
1243               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1244             $output_rules .=
1245               file_contents ($rule_file,
1246                              new Automake::Location,
1247                              %transform,
1248                              GENERIC   => 1,
1249
1250                              'DERIVED-EXT' => $der_ext,
1251
1252                              DEPBASE   => $depbase,
1253                              BASE      => '$*',
1254                              SOURCE    => '$<',
1255                              OBJ       => '$@',
1256                              OBJOBJ    => '$@',
1257                              LTOBJ     => '$@',
1258
1259                              COMPILE   => '$(' . $lang->compiler . ')',
1260                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1261                              -o        => $output_flag,
1262                              SUBDIROBJ => !! option 'subdir-objects');
1263         }
1264
1265         # Now include code for each specially handled object with this
1266         # language.
1267         my %seen_files = ();
1268         foreach my $file (@{$lang_specific_files{$lang->name}})
1269         {
1270             my ($derived, $source, $obj, $myext, %file_transform) = @$file;
1271
1272             # We might see a given object twice, for instance if it is
1273             # used under different conditions.
1274             next if defined $seen_files{$obj};
1275             $seen_files{$obj} = 1;
1276
1277             prog_error ("found " . $lang->name .
1278                         " in handle_languages, but compiler not defined")
1279               unless defined $lang->compile;
1280
1281             my $obj_compile = $lang->compile;
1282
1283             # Rewrite each occurrence of `AM_$flag' in the compile
1284             # rule into `${derived}_$flag' if it exists.
1285             for my $flag (@{$lang->flags})
1286               {
1287                 my $val = "${derived}_$flag";
1288                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1289                   if set_seen ($val);
1290               }
1291
1292             my $libtool_tag = '';
1293             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1294               {
1295                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1296               }
1297
1298             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1299             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1300
1301             my $obj_ltcompile =
1302               "\$(LIBTOOL) $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1303               . "--mode=compile $obj_compile";
1304
1305             # We _need_ `-o' for per object rules.
1306             my $output_flag = $lang->output_flag || '-o';
1307
1308             my $depbase = dirname ($obj);
1309             $depbase = ''
1310                 if $depbase eq '.';
1311             $depbase .= '/'
1312                 unless $depbase eq '';
1313             $depbase .= '$(DEPDIR)/' . basename ($obj);
1314
1315             # Support for deansified files in subdirectories is ugly
1316             # enough to deserve an explanation.
1317             #
1318             # A Note about normal ansi2knr processing first.  On
1319             #
1320             #   AUTOMAKE_OPTIONS = ansi2knr
1321             #   bin_PROGRAMS = foo
1322             #   foo_SOURCES = foo.c
1323             #
1324             # we generate rules similar to:
1325             #
1326             #   foo: foo$U.o; link ...
1327             #   foo$U.o: foo$U.c; compile ...
1328             #   foo_.c: foo.c; ansi2knr ...
1329             #
1330             # this is fairly compact, and will call ansi2knr depending
1331             # on the value of $U (`' or `_').
1332             #
1333             # It's harder with subdir sources. On
1334             #
1335             #   AUTOMAKE_OPTIONS = ansi2knr
1336             #   bin_PROGRAMS = foo
1337             #   foo_SOURCES = sub/foo.c
1338             #
1339             # we have to create foo_.c in the current directory.
1340             # (Unless the user asks 'subdir-objects'.)  This is important
1341             # in case the same file (`foo.c') is compiled from other
1342             # directories with different cpp options: foo_.c would
1343             # be preprocessed for only one set of options if it were
1344             # put in the subdirectory.
1345             #
1346             # Because foo$U.o must be built from either foo_.c or
1347             # sub/foo.c we can't be as concise as in the first example.
1348             # Instead we output
1349             #
1350             #   foo: foo$U.o; link ...
1351             #   foo_.o: foo_.c; compile ...
1352             #   foo.o: sub/foo.c; compile ...
1353             #   foo_.c: foo.c; ansi2knr ...
1354             #
1355             # This is why we'll now transform $rule_file twice
1356             # if we detect this case.
1357             # A first time we output the compile rule with `$U'
1358             # replaced by `_' and the source directory removed,
1359             # and another time we simply remove `$U'.
1360             #
1361             # Note that at this point $source (as computed by
1362             # &handle_single_transform) is `sub/foo$U.c'.
1363             # This can be confusing: it can be used as-is when
1364             # subdir-objects is set, otherwise you have to know
1365             # it really means `foo_.c' or `sub/foo.c'.
1366             my $objdir = dirname ($obj);
1367             my $srcdir = dirname ($source);
1368             if ($lang->ansi && $obj =~ /\$U/)
1369               {
1370                 prog_error "`$obj' contains \$U, but `$source' doesn't."
1371                   if $source !~ /\$U/;
1372
1373                 (my $source_ = $source) =~ s/\$U/_/g;
1374                 # Output an additional rule if _.c and .c are not in
1375                 # the same directory.  (_.c is always in $objdir.)
1376                 if ($objdir ne $srcdir)
1377                   {
1378                     (my $obj_ = $obj) =~ s/\$U/_/g;
1379                     (my $depbase_ = $depbase) =~ s/\$U/_/g;
1380                     $source_ = basename ($source_);
1381
1382                     $output_rules .=
1383                       file_contents ($rule_file,
1384                                      new Automake::Location,
1385                                      %transform,
1386                                      GENERIC   => 0,
1387
1388                                      DEPBASE   => $depbase_,
1389                                      BASE      => $obj_,
1390                                      SOURCE    => $source_,
1391                                      OBJ       => "$obj_$myext",
1392                                      OBJOBJ    => "$obj_.obj",
1393                                      LTOBJ     => "$obj_.lo",
1394
1395                                      COMPILE   => $obj_compile,
1396                                      LTCOMPILE => $obj_ltcompile,
1397                                      -o        => $output_flag,
1398                                      %file_transform);
1399                     $obj =~ s/\$U//g;
1400                     $depbase =~ s/\$U//g;
1401                     $source =~ s/\$U//g;
1402                   }
1403               }
1404
1405             $output_rules .=
1406               file_contents ($rule_file,
1407                              new Automake::Location,
1408                              %transform,
1409                              GENERIC   => 0,
1410
1411                              DEPBASE   => $depbase,
1412                              BASE      => $obj,
1413                              SOURCE    => $source,
1414                              # Use $myext and not `.o' here, in case
1415                              # we are actually building a new source
1416                              # file -- e.g. via yacc.
1417                              OBJ       => "$obj$myext",
1418                              OBJOBJ    => "$obj.obj",
1419                              LTOBJ     => "$obj.lo",
1420
1421                              COMPILE   => $obj_compile,
1422                              LTCOMPILE => $obj_ltcompile,
1423                              -o        => $output_flag,
1424                              %file_transform);
1425         }
1426
1427         # The rest of the loop is done once per language.
1428         next if defined $done{$lang};
1429         $done{$lang} = 1;
1430
1431         # Load the language dependent Makefile chunks.
1432         my %lang = map { uc ($_) => 0 } keys %languages;
1433         $lang{uc ($lang->name)} = 1;
1434         $output_rules .= file_contents ('lang-compile',
1435                                         new Automake::Location,
1436                                         %transform, %lang);
1437
1438         # If the source to a program consists entirely of code from a
1439         # `pure' language, for instance C++ or Fortran 77, then we
1440         # don't need the C compiler code.  However if we run into
1441         # something unusual then we do generate the C code.  There are
1442         # probably corner cases here that do not work properly.
1443         # People linking Java code to Fortran code deserve pain.
1444         $needs_c ||= ! $lang->pure;
1445
1446         define_compiler_variable ($lang)
1447           if ($lang->compile);
1448
1449         define_linker_variable ($lang)
1450           if ($lang->link);
1451
1452         require_variables ("$am_file.am", $lang->Name . " source seen",
1453                            TRUE, @{$lang->config_vars});
1454
1455         # Call the finisher.
1456         $lang->finish;
1457
1458         # Flags listed in `->flags' are user variables (per GNU Standards),
1459         # they should not be overridden in the Makefile...
1460         my @dont_override = @{$lang->flags};
1461         # ... and so is LDFLAGS.
1462         push @dont_override, 'LDFLAGS' if $lang->link;
1463
1464         check_user_variables @dont_override;
1465     }
1466
1467     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1468     # suffix rule was learned), don't bother with the C stuff.  But if
1469     # anything else creeps in, then use it.
1470     $needs_c = 1
1471       if $need_link || suffix_rules_count > 1;
1472
1473     if ($needs_c)
1474       {
1475         &define_compiler_variable ($languages{'c'})
1476           unless defined $done{$languages{'c'}};
1477         define_linker_variable ($languages{'c'});
1478       }
1479 }
1480
1481 # Check to make sure a source defined in LIBOBJS is not explicitly
1482 # mentioned.  This is a separate function (as opposed to being inlined
1483 # in handle_source_transform) because it isn't always appropriate to
1484 # do this check.
1485 sub check_libobjs_sources
1486 {
1487   my ($one_file, $unxformed) = @_;
1488
1489   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1490                       'dist_EXTRA_', 'nodist_EXTRA_')
1491     {
1492       my @files;
1493       my $varname = $prefix . $one_file . '_SOURCES';
1494       my $var = var ($varname);
1495       if ($var)
1496         {
1497           @files = $var->value_as_list_recursive;
1498         }
1499       elsif ($prefix eq '')
1500         {
1501           @files = ($unxformed . '.c');
1502         }
1503       else
1504         {
1505           next;
1506         }
1507
1508       foreach my $file (@files)
1509         {
1510           err_var ($prefix . $one_file . '_SOURCES',
1511                    "automatically discovered file `$file' should not" .
1512                    " be explicitly mentioned")
1513             if defined $libsources{$file};
1514         }
1515     }
1516 }
1517
1518
1519 # @OBJECTS
1520 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1521 # -----------------------------------------------------------------------------
1522 # Does much of the actual work for handle_source_transform.
1523 # Arguments are:
1524 #   $VAR is the name of the variable that the source filenames come from
1525 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1526 #   $DERIVED is the name of resulting executable or library
1527 #   $OBJ is the object extension (e.g., `$U.lo')
1528 #   $FILE the source file to transform
1529 #   %TRANSFORM contains extras arguments to pass to file_contents
1530 #     when producing explicit rules
1531 # Result is a list of the names of objects
1532 # %linkers_used will be updated with any linkers needed
1533 sub handle_single_transform ($$$$$%)
1534 {
1535     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1536     my @files = ($_file);
1537     my @result = ();
1538     my $nonansi_obj = $obj;
1539     $nonansi_obj =~ s/\$U//g;
1540
1541     # Turn sources into objects.  We use a while loop like this
1542     # because we might add to @files in the loop.
1543     while (scalar @files > 0)
1544     {
1545         $_ = shift @files;
1546
1547         # Configure substitutions in _SOURCES variables are errors.
1548         if (/^\@.*\@$/)
1549         {
1550           my $parent_msg = '';
1551           $parent_msg = "\nand is referred to from `$topparent'"
1552             if $topparent ne $var->name;
1553           err_var ($var,
1554                    "`" . $var->name . "' includes configure substitution `$_'"
1555                    . $parent_msg . ";\nconfigure " .
1556                    "substitutions are not allowed in _SOURCES variables");
1557           next;
1558         }
1559
1560         # If the source file is in a subdirectory then the `.o' is put
1561         # into the current directory, unless the subdir-objects option
1562         # is in effect.
1563
1564         # Split file name into base and extension.
1565         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1566         my $full = $_;
1567         my $directory = $1 || '';
1568         my $base = $2;
1569         my $extension = $3;
1570
1571         # We must generate a rule for the object if it requires its own flags.
1572         my $renamed = 0;
1573         my ($linker, $object);
1574
1575         # This records whether we've seen a derived source file (e.g.
1576         # yacc output).
1577         my $derived_source = 0;
1578
1579         # This holds the `aggregate context' of the file we are
1580         # currently examining.  If the file is compiled with
1581         # per-object flags, then it will be the name of the object.
1582         # Otherwise it will be `AM'.  This is used by the target hook
1583         # language function.
1584         my $aggregate = 'AM';
1585
1586         $extension = &derive_suffix ($extension, $nonansi_obj);
1587         my $lang;
1588         if ($extension_map{$extension} &&
1589             ($lang = $languages{$extension_map{$extension}}))
1590         {
1591             # Found the language, so see what it says.
1592             &saw_extension ($extension);
1593
1594             # Do we have per-executable flags for this executable?
1595             my $have_per_exec_flags = 0;
1596             my @peflags = @{$lang->flags};
1597             push @peflags, 'LIBTOOLFLAGS' if $nonansi_obj eq '.lo';
1598             foreach my $flag (@peflags)
1599               {
1600                 if (set_seen ("${derived}_$flag"))
1601                   {
1602                     $have_per_exec_flags = 1;
1603                     last;
1604                   }
1605               }
1606
1607             # Note: computed subr call.  The language rewrite function
1608             # should return one of the LANG_* constants.  It could
1609             # also return a list whose first value is such a constant
1610             # and whose second value is a new source extension which
1611             # should be applied.  This means this particular language
1612             # generates another source file which we must then process
1613             # further.
1614             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1615             my ($r, $source_extension)
1616                 = &$subr ($directory, $base, $extension,
1617                           $nonansi_obj, $have_per_exec_flags, $var);
1618             # Skip this entry if we were asked not to process it.
1619             next if $r == LANG_IGNORE;
1620
1621             # Now extract linker and other info.
1622             $linker = $lang->linker;
1623
1624             my $this_obj_ext;
1625             if (defined $source_extension)
1626             {
1627                 $this_obj_ext = $source_extension;
1628                 $derived_source = 1;
1629             }
1630             elsif ($lang->ansi)
1631             {
1632                 $this_obj_ext = $obj;
1633             }
1634             else
1635             {
1636                 $this_obj_ext = $nonansi_obj;
1637             }
1638             $object = $base . $this_obj_ext;
1639
1640             if ($have_per_exec_flags)
1641             {
1642                 # We have a per-executable flag in effect for this
1643                 # object.  In this case we rewrite the object's
1644                 # name to ensure it is unique.
1645
1646                 # We choose the name `DERIVED_OBJECT' to ensure
1647                 # (1) uniqueness, and (2) continuity between
1648                 # invocations.  However, this will result in a
1649                 # name that is too long for losing systems, in
1650                 # some situations.  So we provide _SHORTNAME to
1651                 # override.
1652
1653                 my $dname = $derived;
1654                 my $var = var ($derived . '_SHORTNAME');
1655                 if ($var)
1656                 {
1657                     # FIXME: should use the same Condition as
1658                     # the _SOURCES variable.  But this is really
1659                     # silly overkill -- nobody should have
1660                     # conditional shortnames.
1661                     $dname = $var->variable_value;
1662                 }
1663                 $object = $dname . '-' . $object;
1664
1665                 prog_error ($lang->name . " flags defined without compiler")
1666                   if ! defined $lang->compile;
1667
1668                 $renamed = 1;
1669             }
1670
1671             # If rewrite said it was ok, put the object into a
1672             # subdir.
1673             if ($r == LANG_SUBDIR && $directory ne '')
1674             {
1675                 $object = $directory . '/' . $object;
1676             }
1677
1678             # If the object file has been renamed (because per-target
1679             # flags are used) we cannot compile the file with an
1680             # inference rule: we need an explicit rule.
1681             #
1682             # If the source is in a subdirectory and the object is in
1683             # the current directory, we also need an explicit rule.
1684             #
1685             # If both source and object files are in a subdirectory
1686             # (this happens when the subdir-objects option is used),
1687             # then the inference will work.
1688             #
1689             # The latter case deserves a historical note.  When the
1690             # subdir-objects option was added on 1999-04-11 it was
1691             # thought that inferences rules would work for
1692             # subdirectory objects too.  Later, on 1999-11-22,
1693             # automake was changed to output explicit rules even for
1694             # subdir-objects.  Nobody remembers why, but this occured
1695             # soon after the merge of the user-dep-gen-branch so it
1696             # might be related.  In late 2003 people complained about
1697             # the size of the generated Makefile.ins (libgcj, with
1698             # 2200+ subdir objects was reported to have a 9MB
1699             # Makefile), so we now rely on inference rules again.
1700             # Maybe we'll run across the same issue as in the past,
1701             # but at least this time we can document it.  However since
1702             # dependency tracking has evolved it is possible that
1703             # our old problem no longer exists.
1704             # Using inference rules for subdir-objects has been tested
1705             # with GNU make, Solaris make, Ultrix make, BSD make,
1706             # HP-UX make, and OSF1 make successfully.
1707             if ($renamed
1708                 || ($directory ne '' && ! option 'subdir-objects')
1709                 # We must also use specific rules for a nodist_ source
1710                 # if its language requests it.
1711                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1712             {
1713                 my $obj_sans_ext = substr ($object, 0,
1714                                            - length ($this_obj_ext));
1715                 my $full_ansi = $full;
1716                 if ($lang->ansi && option 'ansi2knr')
1717                   {
1718                     $full_ansi =~ s/$KNOWN_EXTENSIONS_PATTERN$/\$U$&/;
1719                     $obj_sans_ext .= '$U';
1720                   }
1721
1722                 my @specifics = ($full_ansi, $obj_sans_ext,
1723                                  # Only use $this_obj_ext in the derived
1724                                  # source case because in the other case we
1725                                  # *don't* want $(OBJEXT) to appear here.
1726                                  ($derived_source ? $this_obj_ext : '.o'));
1727
1728                 # If we renamed the object then we want to use the
1729                 # per-executable flag name.  But if this is simply a
1730                 # subdir build then we still want to use the AM_ flag
1731                 # name.
1732                 if ($renamed)
1733                   {
1734                     unshift @specifics, $derived;
1735                     $aggregate = $derived;
1736                   }
1737                 else
1738                   {
1739                     unshift @specifics, 'AM';
1740                   }
1741
1742                 # Each item on this list is a reference to a list consisting
1743                 # of four values followed by additional transform flags for
1744                 # file_contents.   The four values are the derived flag prefix
1745                 # (e.g. for `foo_CFLAGS', it is `foo'), the name of the
1746                 # source file, the base name of the output file, and
1747                 # the extension for the object file.
1748                 push (@{$lang_specific_files{$lang->name}},
1749                       [@specifics, %transform]);
1750             }
1751         }
1752         elsif ($extension eq $nonansi_obj)
1753         {
1754             # This is probably the result of a direct suffix rule.
1755             # In this case we just accept the rewrite.
1756             $object = "$base$extension";
1757             $linker = '';
1758         }
1759         else
1760         {
1761             # No error message here.  Used to have one, but it was
1762             # very unpopular.
1763             # FIXME: we could potentially do more processing here,
1764             # perhaps treating the new extension as though it were a
1765             # new source extension (as above).  This would require
1766             # more restructuring than is appropriate right now.
1767             next;
1768         }
1769
1770         err_am "object `$object' created by `$full' and `$object_map{$object}'"
1771           if (defined $object_map{$object}
1772               && $object_map{$object} ne $full);
1773
1774         my $comp_val = (($object =~ /\.lo$/)
1775                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1776         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1777         if (defined $object_compilation_map{$comp_obj}
1778             && $object_compilation_map{$comp_obj} != 0
1779             # Only see the error once.
1780             && ($object_compilation_map{$comp_obj}
1781                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1782             && $object_compilation_map{$comp_obj} != $comp_val)
1783           {
1784             err_am "object `$comp_obj' created both with libtool and without";
1785           }
1786         $object_compilation_map{$comp_obj} |= $comp_val;
1787
1788         if (defined $lang)
1789         {
1790             # Let the language do some special magic if required.
1791             $lang->target_hook ($aggregate, $object, $full, %transform);
1792         }
1793
1794         if ($derived_source)
1795           {
1796             prog_error ($lang->name . " has automatic dependency tracking")
1797               if $lang->autodep ne 'no';
1798             # Make sure this new source file is handled next.  That will
1799             # make it appear to be at the right place in the list.
1800             unshift (@files, $object);
1801             # Distribute derived sources unless the source they are
1802             # derived from is not.
1803             &push_dist_common ($object)
1804               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1805             next;
1806           }
1807
1808         $linkers_used{$linker} = 1;
1809
1810         push (@result, $object);
1811
1812         if (! defined $object_map{$object})
1813         {
1814             my @dep_list = ();
1815             $object_map{$object} = $full;
1816
1817             # If resulting object is in subdir, we need to make
1818             # sure the subdir exists at build time.
1819             if ($object =~ /\//)
1820             {
1821                 # FIXME: check that $DIRECTORY is somewhere in the
1822                 # project
1823
1824                 # For Java, the way we're handling it right now, a
1825                 # `..' component doesn't make sense.
1826                 if ($lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1827                   {
1828                     err_am "`$full' should not contain a `..' component";
1829                   }
1830
1831                 # Make sure object is removed by `make mostlyclean'.
1832                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1833                 # If we have a libtool object then we also must remove
1834                 # the ordinary .o.
1835                 if ($object =~ /\.lo$/)
1836                 {
1837                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1838                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1839
1840                     # Remove any libtool object in this directory.
1841                     $libtool_clean_directories{$directory} = 1;
1842                 }
1843
1844                 push (@dep_list, require_build_directory ($directory));
1845
1846                 # If we're generating dependencies, we also want
1847                 # to make sure that the appropriate subdir of the
1848                 # .deps directory is created.
1849                 push (@dep_list,
1850                       require_build_directory ($directory . '/$(DEPDIR)'))
1851                   unless option 'no-dependencies';
1852             }
1853
1854             &pretty_print_rule ($object . ':', "\t", @dep_list)
1855                 if scalar @dep_list > 0;
1856         }
1857
1858         # Transform .o or $o file into .P file (for automatic
1859         # dependency code).
1860         if ($lang && $lang->autodep ne 'no')
1861         {
1862             my $depfile = $object;
1863             $depfile =~ s/\.([^.]*)$/.P$1/;
1864             $depfile =~ s/\$\(OBJEXT\)$/o/;
1865             $dep_files{dirname ($depfile) . '/$(DEPDIR)/'
1866                          . basename ($depfile)} = 1;
1867         }
1868     }
1869
1870     return @result;
1871 }
1872
1873
1874 # $LINKER
1875 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
1876 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
1877 # ---------------------------------------------------------------------------
1878 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
1879 #
1880 # Arguments are:
1881 #   $VAR is the name of the _SOURCES variable
1882 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
1883 #     it will be generated and returned).
1884 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
1885 #     work done to determine the linker will be).
1886 #   $ONE_FILE is the canonical (transformed) name of object to build
1887 #   $OBJ is the object extension (i.e. either `.o' or `.lo').
1888 #   $TOPPARENT is the _SOURCES variable being processed.
1889 #   $WHERE context into which this definition is done
1890 #   %TRANSFORM extra arguments to pass to file_contents when producing
1891 #     rules
1892 #
1893 # Result is a pair ($LINKER, $OBJVAR):
1894 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
1895 sub define_objects_from_sources ($$$$$$$%)
1896 {
1897   my ($var, $objvar, $nodefine, $one_file,
1898       $obj, $topparent, $where, %transform) = @_;
1899
1900   my $needlinker = "";
1901
1902   transform_variable_recursively
1903     ($var, $objvar, 'am__objects', $nodefine, $where,
1904      # The transform code to run on each filename.
1905      sub {
1906        my ($subvar, $val, $cond, $full_cond) = @_;
1907        my @trans = handle_single_transform ($subvar, $topparent,
1908                                             $one_file, $obj, $val,
1909                                             %transform);
1910        $needlinker = "true" if @trans;
1911        return @trans;
1912      });
1913
1914   return $needlinker;
1915 }
1916
1917
1918 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
1919 # -----------------------------------------------------------------------------
1920 # Handle SOURCE->OBJECT transform for one program or library.
1921 # Arguments are:
1922 #   canonical (transformed) name of target to build
1923 #   actual target of object to build
1924 #   object extension (i.e., either `.o' or `$o')
1925 #   location of the source variable
1926 #   extra arguments to pass to file_contents when producing rules
1927 # Return the name of the linker variable that must be used.
1928 # Empty return means just use `LINK'.
1929 sub handle_source_transform ($$$$%)
1930 {
1931     # one_file is canonical name.  unxformed is given name.  obj is
1932     # object extension.
1933     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
1934
1935     my $linker = '';
1936
1937     # No point in continuing if _OBJECTS is defined.
1938     return if reject_var ($one_file . '_OBJECTS',
1939                           $one_file . '_OBJECTS should not be defined');
1940
1941     my %used_pfx = ();
1942     my $needlinker;
1943     %linkers_used = ();
1944     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1945                         'dist_EXTRA_', 'nodist_EXTRA_')
1946     {
1947         my $varname = $prefix . $one_file . "_SOURCES";
1948         my $var = var $varname;
1949         next unless $var;
1950
1951         # We are going to define _OBJECTS variables using the prefix.
1952         # Then we glom them all together.  So we can't use the null
1953         # prefix here as we need it later.
1954         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
1955
1956         # Keep track of which prefixes we saw.
1957         $used_pfx{$xpfx} = 1
1958           unless $prefix =~ /EXTRA_/;
1959
1960         push @sources, "\$($varname)";
1961         push @dist_sources, shadow_unconditionally ($varname, $where)
1962           unless (option ('no-dist') || $prefix =~ /^nodist_/);
1963
1964         $needlinker |=
1965             define_objects_from_sources ($varname,
1966                                          $xpfx . $one_file . '_OBJECTS',
1967                                          $prefix =~ /EXTRA_/,
1968                                          $one_file, $obj, $varname, $where,
1969                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
1970                                          %transform);
1971     }
1972     if ($needlinker)
1973     {
1974         $linker ||= &resolve_linker (%linkers_used);
1975     }
1976
1977     my @keys = sort keys %used_pfx;
1978     if (scalar @keys == 0)
1979     {
1980         # The default source for libfoo.la is libfoo.c, but for
1981         # backward compatibility we first look at libfoo_la.c
1982         my $old_default_source = "$one_file.c";
1983         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,.c,;
1984         if ($old_default_source ne $default_source
1985             && (rule $old_default_source
1986                 || rule '$(srcdir)/' . $old_default_source
1987                 || rule '${srcdir}/' . $old_default_source
1988                 || -f $old_default_source))
1989           {
1990             my $loc = $where->clone;
1991             $loc->pop_context;
1992             msg ('obsolete', $loc,
1993                  "the default source for `$unxformed' has been changed "
1994                  . "to `$default_source'.\n(Using `$old_default_source' for "
1995                  . "backward compatibility.)");
1996             $default_source = $old_default_source;
1997           }
1998         # If a rule exists to build this source with a $(srcdir)
1999         # prefix, use that prefix in our variables too.  This is for
2000         # the sake of BSD Make.
2001         if (rule '$(srcdir)/' . $default_source
2002             || rule '${srcdir}/' . $default_source)
2003           {
2004             $default_source = '$(srcdir)/' . $default_source;
2005           }
2006
2007         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2008         push (@sources, $default_source);
2009         push (@dist_sources, $default_source);
2010
2011         %linkers_used = ();
2012         my (@result) =
2013           handle_single_transform ($one_file . '_SOURCES',
2014                                    $one_file . '_SOURCES',
2015                                    $one_file, $obj,
2016                                    $default_source, %transform);
2017         $linker ||= &resolve_linker (%linkers_used);
2018         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2019     }
2020     else
2021     {
2022         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2023         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2024     }
2025
2026     # If we want to use `LINK' we must make sure it is defined.
2027     if ($linker eq '')
2028     {
2029         $need_link = 1;
2030     }
2031
2032     return $linker;
2033 }
2034
2035
2036 # handle_lib_objects ($XNAME, $VAR)
2037 # ---------------------------------
2038 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2039 # Also, generate _DEPENDENCIES variable if appropriate.
2040 # Arguments are:
2041 #   transformed name of object being built, or empty string if no object
2042 #   name of _LDADD/_LIBADD-type variable to examine
2043 # Returns 1 if LIBOBJS seen, 0 otherwise.
2044 sub handle_lib_objects
2045 {
2046   my ($xname, $varname) = @_;
2047
2048   my $var = var ($varname);
2049   prog_error "handle_lib_objects: `$varname' undefined"
2050     unless $var;
2051   prog_error "handle_lib_objects: unexpected variable name `$varname'"
2052     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2053   my $prefix = $1 || 'AM_';
2054
2055   my $seen_libobjs = 0;
2056   my $flagvar = 0;
2057
2058   transform_variable_recursively
2059     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2060      ! $xname, INTERNAL,
2061      # Transformation function, run on each filename.
2062      sub {
2063        my ($subvar, $val, $cond, $full_cond) = @_;
2064
2065        if ($val =~ /^-/)
2066          {
2067            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2068            if ($val !~ /^-[lL]/ &&
2069                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2070                # for Libtool libraries or programs.  (Actually we are a bit
2071                # laxest here since this code also applies to non-libtool
2072                # libraries or programs, for which -dlopen and -dlopreopen
2073                # are pure non-sence.  Diagnosting this doesn't seems very
2074                # important: the developer will quickly get complaints from
2075                # the linker.)
2076                $val !~ /^-dl(?:pre)?open$/ &&
2077                # Only get this error once.
2078                ! $flagvar)
2079              {
2080                $flagvar = 1;
2081                # FIXME: should display a stack of nested variables
2082                # as context when $var != $subvar.
2083                err_var ($var, "linker flags such as `$val' belong in "
2084                         . "`${prefix}LDFLAGS");
2085              }
2086            return ();
2087          }
2088        elsif ($val !~ /^\@.*\@$/)
2089          {
2090            # Assume we have a file of some sort, and output it into the
2091            # dependency variable.  Autoconf substitutions are not output;
2092            # rarely is a new dependency substituted into e.g. foo_LDADD
2093            # -- but bad things (e.g. -lX11) are routinely substituted.
2094            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2095            # and handled specially below.
2096            return $val;
2097          }
2098        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2099          {
2100            handle_LIBOBJS ($subvar, $cond, $1);
2101            $seen_libobjs = 1;
2102            return $val;
2103          }
2104        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2105          {
2106            handle_ALLOCA ($subvar, $cond, $1);
2107            return $val;
2108          }
2109        else
2110          {
2111            return ();
2112          }
2113      });
2114
2115   return $seen_libobjs;
2116 }
2117
2118 # handle_LIBOBJS_or_ALLOCA ($VAR)
2119 # -------------------------------
2120 # Definitions common to LIBOBJS and ALLOCA.
2121 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2122 sub handle_LIBOBJS_or_ALLOCA ($)
2123 {
2124   my ($var) = @_;
2125
2126   my $dir = $config_libobj_dir ? "$config_libobj_dir/" : '';
2127
2128   # If LIBOBJS files must be built in another directory we have
2129   # to define LIBOBJDIR and ensure the files get cleaned.
2130   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2131   # is achieved by `rm -f *.($OBJEXT)' in compile.am.
2132   if ($config_libobj_dir
2133       && $relative_dir ne $config_libobj_dir)
2134     {
2135       if (option 'subdir-objects')
2136         {
2137           define_variable ('LIBOBJDIR', "\$(top_builddir)/$dir", INTERNAL);
2138           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2139           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2140           # be created by libtool as a side-effect of creating LTLIBOBJS).
2141           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2142
2143         }
2144       else
2145         {
2146           error ("`\$($var)' cannot be used outside `$dir' if"
2147                  . " `subdir-objects' is not set");
2148         }
2149     }
2150
2151   return $dir;
2152 }
2153
2154 sub handle_LIBOBJS ($$$)
2155 {
2156   my ($var, $cond, $lt) = @_;
2157   $lt ||= '';
2158   my $myobjext = ($1 ? 'l' : '') . 'o';
2159
2160   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2161     if ! keys %libsources;
2162
2163   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2164
2165   foreach my $iter (keys %libsources)
2166     {
2167       if ($iter =~ /\.[cly]$/)
2168         {
2169           &saw_extension ($&);
2170           &saw_extension ('.c');
2171         }
2172
2173       if ($iter =~ /\.h$/)
2174         {
2175           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2176         }
2177       elsif ($iter ne 'alloca.c')
2178         {
2179           my $rewrite = $iter;
2180           $rewrite =~ s/\.c$/.P$myobjext/;
2181           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2182           $rewrite = "^" . quotemeta ($iter) . "\$";
2183           # Only require the file if it is not a built source.
2184           my $bs = var ('BUILT_SOURCES');
2185           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2186             {
2187               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2188             }
2189         }
2190     }
2191 }
2192
2193 sub handle_ALLOCA ($$$)
2194 {
2195   my ($var, $cond, $lt) = @_;
2196   my $myobjext = ($lt ? 'l' : '') . 'o';
2197   $lt ||= '';
2198   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2199
2200   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2201   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2202   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2203   &saw_extension ('.c');
2204 }
2205
2206 # Canonicalize the input parameter
2207 sub canonicalize
2208 {
2209     my ($string) = @_;
2210     $string =~ tr/A-Za-z0-9_\@/_/c;
2211     return $string;
2212 }
2213
2214 # Canonicalize a name, and check to make sure the non-canonical name
2215 # is never used.  Returns canonical name.  Arguments are name and a
2216 # list of suffixes to check for.
2217 sub check_canonical_spelling
2218 {
2219   my ($name, @suffixes) = @_;
2220
2221   my $xname = &canonicalize ($name);
2222   if ($xname ne $name)
2223     {
2224       foreach my $xt (@suffixes)
2225         {
2226           reject_var ("$name$xt", "use `$xname$xt', not `$name$xt'");
2227         }
2228     }
2229
2230   return $xname;
2231 }
2232
2233
2234 # handle_compile ()
2235 # -----------------
2236 # Set up the compile suite.
2237 sub handle_compile ()
2238 {
2239     return
2240       unless $get_object_extension_was_run;
2241
2242     # Boilerplate.
2243     my $default_includes = '';
2244     if (! option 'nostdinc')
2245       {
2246         $default_includes = ' -I. -I$(srcdir)';
2247
2248         my $var = var 'CONFIG_HEADER';
2249         if ($var)
2250           {
2251             foreach my $hdr (split (' ', $var->variable_value))
2252               {
2253                 $default_includes .= ' -I' . dirname ($hdr);
2254               }
2255           }
2256       }
2257
2258     my (@mostly_rms, @dist_rms);
2259     foreach my $item (sort keys %compile_clean_files)
2260     {
2261         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2262         {
2263             push (@mostly_rms, "\t-rm -f $item");
2264         }
2265         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2266         {
2267             push (@dist_rms, "\t-rm -f $item");
2268         }
2269         else
2270         {
2271           prog_error 'invalid entry in %compile_clean_files';
2272         }
2273     }
2274
2275     my ($coms, $vars, $rules) =
2276       &file_contents_internal (1, "$libdir/am/compile.am",
2277                                new Automake::Location,
2278                                ('DEFAULT_INCLUDES' => $default_includes,
2279                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2280                                 'DISTRMS' => join ("\n", @dist_rms)));
2281     $output_vars .= $vars;
2282     $output_rules .= "$coms$rules";
2283
2284     # Check for automatic de-ANSI-fication.
2285     if (option 'ansi2knr')
2286       {
2287         my ($ansi2knr_filename, $ansi2knr_where) = @{option 'ansi2knr'};
2288         my $ansi2knr_dir = '';
2289
2290         require_variables ($ansi2knr_where, "option `ansi2knr' is used",
2291                            TRUE, "ANSI2KNR", "U");
2292
2293         # topdir is where ansi2knr should be.
2294         if ($ansi2knr_filename eq 'ansi2knr')
2295           {
2296             # Only require ansi2knr files if they should appear in
2297             # this directory.
2298             require_file ($ansi2knr_where, FOREIGN,
2299                           'ansi2knr.c', 'ansi2knr.1');
2300
2301             # ansi2knr needs to be built before subdirs, so unshift it.
2302             unshift (@all, '$(ANSI2KNR)');
2303           }
2304         else
2305           {
2306             $ansi2knr_dir = dirname ($ansi2knr_filename);
2307           }
2308
2309         $output_rules .= &file_contents ('ansi2knr',
2310                                          new Automake::Location,
2311                                          'ANSI2KNR-DIR' => $ansi2knr_dir);
2312
2313     }
2314 }
2315
2316 # handle_libtool ()
2317 # -----------------
2318 # Handle libtool rules.
2319 sub handle_libtool
2320 {
2321   return unless var ('LIBTOOL');
2322
2323   # Libtool requires some files, but only at top level.
2324   # (Starting with Libtool 2.0 we do not have to bother.  These
2325   # requirements are done with AC_REQUIRE_AUX_FILE.)
2326   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2327     if $relative_dir eq '.' && ! $libtool_new_api;
2328
2329   my @libtool_rms;
2330   foreach my $item (sort keys %libtool_clean_directories)
2331     {
2332       my $dir = ($item eq '.') ? '' : "$item/";
2333       # .libs is for Unix, _libs for DOS.
2334       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2335     }
2336
2337   check_user_variables 'LIBTOOLFLAGS';
2338
2339   # Output the libtool compilation rules.
2340   $output_rules .= &file_contents ('libtool',
2341                                    new Automake::Location,
2342                                    LTRMS => join ("\n", @libtool_rms));
2343 }
2344
2345 # handle_programs ()
2346 # ------------------
2347 # Handle C programs.
2348 sub handle_programs
2349 {
2350   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2351                                   'bin', 'sbin', 'libexec', 'pkglib',
2352                                   'noinst', 'check');
2353   return if ! @proglist;
2354
2355   my $seen_global_libobjs =
2356     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2357
2358   foreach my $pair (@proglist)
2359     {
2360       my ($where, $one_file) = @$pair;
2361
2362       my $seen_libobjs = 0;
2363       my $obj = get_object_extension '.$(OBJEXT)';
2364
2365       # Strip any $(EXEEXT) suffix the user might have added, or this
2366       # will confuse &handle_source_transform and &check_canonical_spelling.
2367       # We'll add $(EXEEXT) back later anyway.
2368       $one_file =~ s/\$\(EXEEXT\)$//;
2369
2370       # Canonicalize names and check for misspellings.
2371       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2372                                              '_SOURCES', '_OBJECTS',
2373                                              '_DEPENDENCIES');
2374
2375       $where->push_context ("while processing program `$one_file'");
2376       $where->set (INTERNAL->get);
2377
2378       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2379                                              NONLIBTOOL => 1, LIBTOOL => 0);
2380
2381       if (var ($xname . "_LDADD"))
2382         {
2383           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2384         }
2385       else
2386         {
2387           # User didn't define prog_LDADD override.  So do it.
2388           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2389
2390           # This does a bit too much work.  But we need it to
2391           # generate _DEPENDENCIES when appropriate.
2392           if (var ('LDADD'))
2393             {
2394               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2395             }
2396         }
2397
2398       reject_var ($xname . '_LIBADD',
2399                   "use `${xname}_LDADD', not `${xname}_LIBADD'");
2400
2401       set_seen ($xname . '_DEPENDENCIES');
2402       set_seen ($xname . '_LDFLAGS');
2403
2404       # Determine program to use for link.
2405       my $xlink = &define_per_target_linker_variable ($linker, $xname);
2406
2407       # If the resulting program lies into a subdirectory,
2408       # make sure this directory will exist.
2409       my $dirstamp = require_build_directory_maybe ($one_file);
2410
2411       $output_rules .= &file_contents ('program',
2412                                        $where,
2413                                        PROGRAM  => $one_file,
2414                                        XPROGRAM => $xname,
2415                                        XLINK    => $xlink,
2416                                        DIRSTAMP => $dirstamp,
2417                                        EXEEXT   => '$(EXEEXT)');
2418
2419       if ($seen_libobjs || $seen_global_libobjs)
2420         {
2421           if (var ($xname . '_LDADD'))
2422             {
2423               &check_libobjs_sources ($xname, $xname . '_LDADD');
2424             }
2425           elsif (var ('LDADD'))
2426             {
2427               &check_libobjs_sources ($xname, 'LDADD');
2428             }
2429         }
2430     }
2431 }
2432
2433
2434 # handle_libraries ()
2435 # -------------------
2436 # Handle libraries.
2437 sub handle_libraries
2438 {
2439   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2440                                  'lib', 'pkglib', 'noinst', 'check');
2441   return if ! @liblist;
2442
2443   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2444                                     'noinst', 'check');
2445
2446   if (@prefix)
2447     {
2448       my $var = rvar ($prefix[0] . '_LIBRARIES');
2449       $var->requires_variables ('library used', 'RANLIB');
2450     }
2451
2452   &define_variable ('AR', 'ar', INTERNAL);
2453   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2454
2455   foreach my $pair (@liblist)
2456     {
2457       my ($where, $onelib) = @$pair;
2458
2459       my $seen_libobjs = 0;
2460       # Check that the library fits the standard naming convention.
2461       my $bn = basename ($onelib);
2462       if ($bn !~ /^lib.*\.a$/)
2463         {
2464           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2465           my $suggestion = dirname ($onelib) . "/$bn";
2466           $suggestion =~ s|^\./||g;
2467           msg ('error-gnu/warn', $where,
2468                "`$onelib' is not a standard library name\n"
2469                . "did you mean `$suggestion'?")
2470         }
2471
2472       $where->push_context ("while processing library `$onelib'");
2473       $where->set (INTERNAL->get);
2474
2475       my $obj = get_object_extension '.$(OBJEXT)';
2476
2477       # Canonicalize names and check for misspellings.
2478       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2479                                             '_OBJECTS', '_DEPENDENCIES',
2480                                             '_AR');
2481
2482       if (! var ($xlib . '_AR'))
2483         {
2484           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2485         }
2486
2487       # Generate support for conditional object inclusion in
2488       # libraries.
2489       if (var ($xlib . '_LIBADD'))
2490         {
2491           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2492             {
2493               $seen_libobjs = 1;
2494             }
2495         }
2496       else
2497         {
2498           &define_variable ($xlib . "_LIBADD", '', $where);
2499         }
2500
2501       reject_var ($xlib . '_LDADD',
2502                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2503
2504       # Make sure we at look at this.
2505       set_seen ($xlib . '_DEPENDENCIES');
2506
2507       &handle_source_transform ($xlib, $onelib, $obj, $where,
2508                                 NONLIBTOOL => 1, LIBTOOL => 0);
2509
2510       # If the resulting library lies into a subdirectory,
2511       # make sure this directory will exist.
2512       my $dirstamp = require_build_directory_maybe ($onelib);
2513
2514       $output_rules .= &file_contents ('library',
2515                                        $where,
2516                                        LIBRARY  => $onelib,
2517                                        XLIBRARY => $xlib,
2518                                        DIRSTAMP => $dirstamp);
2519
2520       if ($seen_libobjs)
2521         {
2522           if (var ($xlib . '_LIBADD'))
2523             {
2524               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2525             }
2526         }
2527     }
2528 }
2529
2530
2531 # handle_ltlibraries ()
2532 # ---------------------
2533 # Handle shared libraries.
2534 sub handle_ltlibraries
2535 {
2536   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2537                                  'noinst', 'lib', 'pkglib', 'check');
2538   return if ! @liblist;
2539
2540   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2541                                     'noinst', 'check');
2542
2543   if (@prefix)
2544     {
2545       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2546       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2547     }
2548
2549   my %instdirs = ();
2550   my %instconds = ();
2551   my %liblocations = ();        # Location (in Makefile.am) of each library.
2552
2553   foreach my $key (@prefix)
2554     {
2555       # Get the installation directory of each library.
2556       (my $dir = $key) =~ s/^nobase_//;
2557       my $var = rvar ($key . '_LTLIBRARIES');
2558
2559       # We reject libraries which are installed in several places
2560       # in the same condition, because we can only specify one
2561       # `-rpath' option.
2562       $var->traverse_recursively
2563         (sub
2564          {
2565            my ($var, $val, $cond, $full_cond) = @_;
2566            my $hcond = $full_cond->human;
2567            my $where = $var->rdef ($cond)->location;
2568            # A library cannot be installed in different directory
2569            # in overlapping conditions.
2570            if (exists $instconds{$val})
2571              {
2572                my ($msg, $acond) =
2573                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2574
2575                if ($msg)
2576                  {
2577                    error ($where, $msg, partial => 1);
2578
2579                    my $dirtxt = "installed in `$dir'";
2580                    $dirtxt = "built for `$dir'"
2581                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2582                    my $dircond =
2583                      $full_cond->true ? "" : " in condition $hcond";
2584
2585                    error ($where, "`$val' should be $dirtxt$dircond ...",
2586                           partial => 1);
2587
2588                    my $hacond = $acond->human;
2589                    my $adir = $instdirs{$val}{$acond};
2590                    my $adirtxt = "installed in `$adir'";
2591                    $adirtxt = "built for `$adir'"
2592                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2593                          || $adir eq 'check');
2594                    my $adircond = $acond->true ? "" : " in condition $hacond";
2595
2596                    my $onlyone = ($dir ne $adir) ?
2597                      ("\nLibtool libraries can be built for only one "
2598                       . "destination.") : "";
2599
2600                    error ($liblocations{$val}{$acond},
2601                           "... and should also be $adirtxt$adircond.$onlyone");
2602                    return;
2603                  }
2604              }
2605            else
2606              {
2607                $instconds{$val} = new Automake::DisjConditions;
2608              }
2609            $instdirs{$val}{$full_cond} = $dir;
2610            $liblocations{$val}{$full_cond} = $where;
2611            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2612          },
2613          sub
2614          {
2615            return ();
2616          },
2617          skip_ac_subst => 1);
2618     }
2619
2620   foreach my $pair (@liblist)
2621     {
2622       my ($where, $onelib) = @$pair;
2623
2624       my $seen_libobjs = 0;
2625       my $obj = get_object_extension '.lo';
2626
2627       # Canonicalize names and check for misspellings.
2628       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2629                                             '_SOURCES', '_OBJECTS',
2630                                             '_DEPENDENCIES');
2631
2632       # Check that the library fits the standard naming convention.
2633       my $libname_rx = '^lib.*\.la';
2634       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2635       my $ldvar2 = var ('LDFLAGS');
2636       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2637           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2638         {
2639           # Relax name checking for libtool modules.
2640           $libname_rx = '\.la';
2641         }
2642
2643       my $bn = basename ($onelib);
2644       if ($bn !~ /$libname_rx$/)
2645         {
2646           my $type = 'library';
2647           if ($libname_rx eq '\.la')
2648             {
2649               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2650               $type = 'module';
2651             }
2652           else
2653             {
2654               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2655             }
2656           my $suggestion = dirname ($onelib) . "/$bn";
2657           $suggestion =~ s|^\./||g;
2658           msg ('error-gnu/warn', $where,
2659                "`$onelib' is not a standard libtool $type name\n"
2660                . "did you mean `$suggestion'?")
2661         }
2662
2663       $where->push_context ("while processing Libtool library `$onelib'");
2664       $where->set (INTERNAL->get);
2665
2666       # Make sure we look at these.
2667       set_seen ($xlib . '_LDFLAGS');
2668       set_seen ($xlib . '_DEPENDENCIES');
2669
2670       # Generate support for conditional object inclusion in
2671       # libraries.
2672       if (var ($xlib . '_LIBADD'))
2673         {
2674           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2675             {
2676               $seen_libobjs = 1;
2677             }
2678         }
2679       else
2680         {
2681           &define_variable ($xlib . "_LIBADD", '', $where);
2682         }
2683
2684       reject_var ("${xlib}_LDADD",
2685                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2686
2687
2688       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2689                                              NONLIBTOOL => 0, LIBTOOL => 1);
2690
2691       # Determine program to use for link.
2692       my $xlink = &define_per_target_linker_variable ($linker, $xlib);
2693
2694       my $rpathvar = "am_${xlib}_rpath";
2695       my $rpath = "\$($rpathvar)";
2696       foreach my $rcond ($instconds{$onelib}->conds)
2697         {
2698           my $val;
2699           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2700               || $instdirs{$onelib}{$rcond} eq 'noinst'
2701               || $instdirs{$onelib}{$rcond} eq 'check')
2702             {
2703               # It's an EXTRA_ library, so we can't specify -rpath,
2704               # because we don't know where the library will end up.
2705               # The user probably knows, but generally speaking automake
2706               # doesn't -- and in fact configure could decide
2707               # dynamically between two different locations.
2708               $val = '';
2709             }
2710           else
2711             {
2712               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2713             }
2714           if ($rcond->true)
2715             {
2716               # If $rcond is true there is only one condition and
2717               # there is no point defining an helper variable.
2718               $rpath = $val;
2719             }
2720           else
2721             {
2722               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2723             }
2724         }
2725
2726       # If the resulting library lies into a subdirectory,
2727       # make sure this directory will exist.
2728       my $dirstamp = require_build_directory_maybe ($onelib);
2729
2730       # Remember to cleanup .libs/ in this directory.
2731       my $dirname = dirname $onelib;
2732       $libtool_clean_directories{$dirname} = 1;
2733
2734       $output_rules .= &file_contents ('ltlibrary',
2735                                        $where,
2736                                        LTLIBRARY  => $onelib,
2737                                        XLTLIBRARY => $xlib,
2738                                        RPATH      => $rpath,
2739                                        XLINK      => $xlink,
2740                                        DIRSTAMP   => $dirstamp);
2741       if ($seen_libobjs)
2742         {
2743           if (var ($xlib . '_LIBADD'))
2744             {
2745               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2746             }
2747         }
2748     }
2749 }
2750
2751 # See if any _SOURCES variable were misspelled.
2752 sub check_typos ()
2753 {
2754   # It is ok if the user sets this particular variable.
2755   set_seen 'AM_LDFLAGS';
2756
2757   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2758     {
2759       foreach my $var (variables $primary)
2760         {
2761           my $varname = $var->name;
2762           # A configure variable is always legitimate.
2763           next if exists $configure_vars{$varname};
2764
2765           for my $cond ($var->conditions->conds)
2766             {
2767               $varname =~ /^(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2768               msg_var ('syntax', $var, "variable `$varname' is defined but no"
2769                        . " program or\nlibrary has `$1' as canonic name"
2770                        . " (possible typo)")
2771                 unless $var->rdef ($cond)->seen;
2772             }
2773         }
2774     }
2775 }
2776
2777
2778 # Handle scripts.
2779 sub handle_scripts
2780 {
2781     # NOTE we no longer automatically clean SCRIPTS, because it is
2782     # useful to sometimes distribute scripts verbatim.  This happens
2783     # e.g. in Automake itself.
2784     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2785                      'bin', 'sbin', 'libexec', 'pkgdata',
2786                      'noinst', 'check');
2787 }
2788
2789
2790
2791
2792 ## ------------------------ ##
2793 ## Handling Texinfo files.  ##
2794 ## ------------------------ ##
2795
2796 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2797 # &scan_texinfo_file ($FILENAME)
2798 # ------------------------------
2799 # $OUTFILE     - name of the info file produced by $FILENAME.
2800 # $VFILE       - name of the version.texi file used (undef if none).
2801 # @CLEAN_FILES - list of byproducts (indexes etc.)
2802 sub scan_texinfo_file ($)
2803 {
2804   my ($filename) = @_;
2805
2806   # Some of the following extensions are always created, no matter
2807   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2808   # are only created when they are used.  We used to scan $FILENAME
2809   # for their use, but that is not enough: they could be used in
2810   # included files.  We can't scan included files because we don't
2811   # know the include path.  Therefore we always erase these files, no
2812   # matter whether they are used or not.
2813   #
2814   # (tmp is only created if an @macro is used and a certain e-TeX
2815   # feature is not available.)
2816   my %clean_suffixes =
2817     map { $_ => 1 } (qw(aux log toc tmp
2818                         cp cps
2819                         fn fns
2820                         ky kys
2821                         vr vrs
2822                         tp tps
2823                         pg pgs)); # grep 'new.*index' texinfo.tex
2824
2825   my $texi = new Automake::XFile "< $filename";
2826   verb "reading $filename";
2827
2828   my ($outfile, $vfile);
2829   while ($_ = $texi->getline)
2830     {
2831       if (/^\@setfilename +(\S+)/)
2832         {
2833           # Honor only the first @setfilename.  (It's possible to have
2834           # more occurrences later if the manual shows examples of how
2835           # to use @setfilename...)
2836           next if $outfile;
2837
2838           $outfile = $1;
2839           if ($outfile =~ /\.(.+)$/ && $1 ne 'info')
2840             {
2841               error ("$filename:$.",
2842                      "output `$outfile' has unrecognized extension");
2843               return;
2844             }
2845         }
2846       # A "version.texi" file is actually any file whose name matches
2847       # "vers*.texi".
2848       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
2849         {
2850           $vfile = $1;
2851         }
2852
2853       # Try to find new or unused indexes.
2854
2855       # Creating a new category of index.
2856       elsif (/^\@def(code)?index (\w+)/)
2857         {
2858           $clean_suffixes{$2} = 1;
2859           $clean_suffixes{"$2s"} = 1;
2860         }
2861
2862       # Merging an index into an another.
2863       elsif (/^\@syn(code)?index (\w+) (\w+)/)
2864         {
2865           delete $clean_suffixes{"$2s"};
2866           $clean_suffixes{"$3s"} = 1;
2867         }
2868
2869     }
2870
2871   if (! $outfile)
2872     {
2873       err_am "`$filename' missing \@setfilename";
2874       return;
2875     }
2876
2877   my $infobase = basename ($filename);
2878   $infobase =~ s/\.te?xi(nfo)?$//;
2879   return ($outfile, $vfile,
2880           map { "$infobase.$_" } (sort keys %clean_suffixes));
2881 }
2882
2883
2884 # ($DIRSTAMP, @CLEAN_FILES)
2885 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
2886 # ------------------------------------------------------------------
2887 # SOURCE - the source Texinfo file
2888 # DEST - the destination Info file
2889 # INSRC - wether DEST should be built in the source tree
2890 # DEPENDENCIES - known dependencies
2891 sub output_texinfo_build_rules ($$$@)
2892 {
2893   my ($source, $dest, $insrc, @deps) = @_;
2894
2895   # Split `a.texi' into `a' and `.texi'.
2896   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
2897   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
2898
2899   $ssfx ||= "";
2900   $dsfx ||= "";
2901
2902   # We can output two kinds of rules: the "generic" rules use Make
2903   # suffix rules and are appropriate when $source and $dest do not lie
2904   # in a sub-directory; the "specific" rules are needed in the other
2905   # case.
2906   #
2907   # The former are output only once (this is not really apparent here,
2908   # but just remember that some logic deeper in Automake will not
2909   # output the same rule twice); while the later need to be output for
2910   # each Texinfo source.
2911   my $generic;
2912   my $makeinfoflags;
2913   my $sdir = dirname $source;
2914   if ($sdir eq '.' && dirname ($dest) eq '.')
2915     {
2916       $generic = 1;
2917       $makeinfoflags = '-I $(srcdir)';
2918     }
2919   else
2920     {
2921       $generic = 0;
2922       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
2923     }
2924
2925   # A directory can contain two kinds of info files: some built in the
2926   # source tree, and some built in the build tree.  The rules are
2927   # different in each case.  However we cannot output two different
2928   # set of generic rules.  Because in-source builds are more usual, we
2929   # use generic rules in this case and fall back to "specific" rules
2930   # for build-dir builds.  (It should not be a problem to invert this
2931   # if needed.)
2932   $generic = 0 unless $insrc;
2933
2934   # We cannot use a suffix rule to build info files with an empty
2935   # extension.  Otherwise we would output a single suffix inference
2936   # rule, with separate dependencies, as in
2937   #
2938   #    .texi:
2939   #             $(MAKEINFO) ...
2940   #    foo.info: foo.texi
2941   #
2942   # which confuse Solaris make.  (See the Autoconf manual for
2943   # details.)  Therefore we use a specific rule in this case.  This
2944   # applies to info files only (dvi and pdf files always have an
2945   # extension).
2946   my $generic_info = ($generic && $dsfx) ? 1 : 0;
2947
2948   # If the resulting file lie into a subdirectory,
2949   # make sure this directory will exist.
2950   my $dirstamp = require_build_directory_maybe ($dest);
2951
2952   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
2953
2954   $output_rules .= file_contents ('texibuild',
2955                                   new Automake::Location,
2956                                   DEPS             => "@deps",
2957                                   DEST_PREFIX      => $dpfx,
2958                                   DEST_INFO_PREFIX => $dipfx,
2959                                   DEST_SUFFIX      => $dsfx,
2960                                   DIRSTAMP         => $dirstamp,
2961                                   GENERIC          => $generic,
2962                                   GENERIC_INFO     => $generic_info,
2963                                   INSRC            => $insrc,
2964                                   MAKEINFOFLAGS    => $makeinfoflags,
2965                                   SOURCE           => ($generic
2966                                                        ? '$<' : $source),
2967                                   SOURCE_INFO      => ($generic_info
2968                                                        ? '$<' : $source),
2969                                   SOURCE_REAL      => $source,
2970                                   SOURCE_SUFFIX    => $ssfx,
2971                                   );
2972   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
2973 }
2974
2975
2976 # $TEXICLEANS
2977 # handle_texinfo_helper ($info_texinfos)
2978 # --------------------------------------
2979 # Handle all Texinfo source; helper for handle_texinfo.
2980 sub handle_texinfo_helper ($)
2981 {
2982   my ($info_texinfos) = @_;
2983   my (@infobase, @info_deps_list, @texi_deps);
2984   my %versions;
2985   my $done = 0;
2986   my @texi_cleans;
2987
2988   # Build a regex matching user-cleaned files.
2989   my $d = var 'DISTCLEANFILES';
2990   my $c = var 'CLEANFILES';
2991   my @f = ();
2992   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
2993   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
2994   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
2995   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
2996
2997   foreach my $texi
2998       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
2999     {
3000       my $infobase = $texi;
3001       $infobase =~ s/\.(txi|texinfo|texi)$//;
3002
3003       if ($infobase eq $texi)
3004         {
3005           # FIXME: report line number.
3006           err_am "texinfo file `$texi' has unrecognized extension";
3007           next;
3008         }
3009
3010       push @infobase, $infobase;
3011
3012       # If 'version.texi' is referenced by input file, then include
3013       # automatic versioning capability.
3014       my ($out_file, $vtexi, @clean_files) =
3015         scan_texinfo_file ("$relative_dir/$texi")
3016         or next;
3017       push (@texi_cleans, @clean_files);
3018
3019       # If the Texinfo source is in a subdirectory, create the
3020       # resulting info in this subdirectory.  If it is in the current
3021       # directory, try hard to not prefix "./" because it breaks the
3022       # generic rules.
3023       my $outdir = dirname ($texi) . '/';
3024       $outdir = "" if $outdir eq './';
3025       $out_file =  $outdir . $out_file;
3026
3027       # Until Automake 1.6.3, .info files were built in the
3028       # source tree.  This was an obstacle to the support of
3029       # non-distributed .info files, and non-distributed .texi
3030       # files.
3031       #
3032       # * Non-distributed .texi files is important in some packages
3033       #   where .texi files are built at make time, probably using
3034       #   other binaries built in the package itself, maybe using
3035       #   tools or information found on the build host.  Because
3036       #   these files are not distributed they are always rebuilt
3037       #   at make time; they should therefore not lie in the source
3038       #   directory.  One plan was to support this using
3039       #   nodist_info_TEXINFOS or something similar.  (Doing this
3040       #   requires some sanity checks.  For instance Automake should
3041       #   not allow:
3042       #      dist_info_TEXINFO = foo.texi
3043       #      nodist_foo_TEXINFO = included.texi
3044       #   because a distributed file should never depend on a
3045       #   non-distributed file.)
3046       #
3047       # * If .texi files are not distributed, then .info files should
3048       #   not be distributed either.  There are also cases where one
3049       #   want to distribute .texi files, but do not want to
3050       #   distribute the .info files.  For instance the Texinfo package
3051       #   distributes the tool used to build these files; it would
3052       #   be a waste of space to distribute them.  It's not clear
3053       #   which syntax we should use to indicate that .info files should
3054       #   not be distributed.  Akim Demaille suggested that eventually
3055       #   we switch to a new syntax:
3056       #   |  Maybe we should take some inspiration from what's already
3057       #   |  done in the rest of Automake.  Maybe there is too much
3058       #   |  syntactic sugar here, and you want
3059       #   |     nodist_INFO = bar.info
3060       #   |     dist_bar_info_SOURCES = bar.texi
3061       #   |     bar_texi_DEPENDENCIES = foo.texi
3062       #   |  with a bit of magic to have bar.info represent the whole
3063       #   |  bar*info set.  That's a lot more verbose that the current
3064       #   |  situation, but it is # not new, hence the user has less
3065       #   |  to learn.
3066       #   |
3067       #   |  But there is still too much room for meaningless specs:
3068       #   |     nodist_INFO = bar.info
3069       #   |     dist_bar_info_SOURCES = bar.texi
3070       #   |     dist_PS = bar.ps something-written-by-hand.ps
3071       #   |     nodist_bar_ps_SOURCES = bar.texi
3072       #   |     bar_texi_DEPENDENCIES = foo.texi
3073       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3074       #
3075       # Back to the point, it should be clear that in order to support
3076       # non-distributed .info files, we need to build them in the
3077       # build tree, not in the source tree (non-distributed .texi
3078       # files are less of a problem, because we do not output build
3079       # rules for them).  In Automake 1.7 .info build rules have been
3080       # largely cleaned up so that .info files get always build in the
3081       # build tree, even when distributed.  The idea was that
3082       #   (1) if during a VPATH build the .info file was found to be
3083       #       absent or out-of-date (in the source tree or in the
3084       #       build tree), Make would rebuild it in the build tree.
3085       #       If an up-to-date source-tree of the .info file existed,
3086       #       make would not rebuild it in the build tree.
3087       #   (2) having two copies of .info files, one in the source tree
3088       #       and one (newer) in the build tree is not a problem
3089       #       because `make dist' always pick files in the build tree
3090       #       first.
3091       # However it turned out the be a bad idea for several reasons:
3092       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3093       #     like GNU Make on point (1) above.  These implementations
3094       #     of Make would always rebuild .info files in the build
3095       #     tree, even if such files were up to date in the source
3096       #     tree.  Consequently, it was impossible to perform a VPATH
3097       #     build of a package containing Texinfo files using these
3098       #     Make implementations.
3099       #     (Refer to the Autoconf Manual, section "Limitation of
3100       #     Make", paragraph "VPATH", item "target lookup", for
3101       #     an account of the differences between these
3102       #     implementations.)
3103       #   * The GNU Coding Standards require these files to be built
3104       #     in the source-tree (when they are distributed, that is).
3105       #   * Keeping a fresher copy of distributed files in the
3106       #     build tree can be annoying during development because
3107       #     - if the files is kept under CVS, you really want it
3108       #       to be updated in the source tree
3109       #     - it is confusing that `make distclean' does not erase
3110       #       all files in the build tree.
3111       #
3112       # Consequently, starting with Automake 1.8, .info files are
3113       # built in the source tree again.  Because we still plan to
3114       # support non-distributed .info files at some point, we
3115       # have a single variable ($INSRC) that controls whether
3116       # the current .info file must be built in the source tree
3117       # or in the build tree.  Actually this variable is switched
3118       # off for .info files that appear to be cleaned; this is
3119       # for backward compatibility with package such as Texinfo,
3120       # which do things like
3121       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3122       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3123       #   # Do not create info files for distribution.
3124       #   dist-info:
3125       # in order not to distribute .info files.
3126       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3127
3128       my $soutdir = '$(srcdir)/' . $outdir;
3129       $outdir = $soutdir if $insrc;
3130
3131       # If user specified file_TEXINFOS, then use that as explicit
3132       # dependency list.
3133       @texi_deps = ();
3134       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3135
3136       my $canonical = canonicalize ($infobase);
3137       if (var ($canonical . "_TEXINFOS"))
3138         {
3139           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3140           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3141         }
3142
3143       my ($dirstamp, @cfiles) =
3144         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3145       push (@texi_cleans, @cfiles);
3146
3147       push (@info_deps_list, $out_file);
3148
3149       # If a vers*.texi file is needed, emit the rule.
3150       if ($vtexi)
3151         {
3152           err_am ("`$vtexi', included in `$texi', "
3153                   . "also included in `$versions{$vtexi}'")
3154             if defined $versions{$vtexi};
3155           $versions{$vtexi} = $texi;
3156
3157           # We number the stamp-vti files.  This is doable since the
3158           # actual names don't matter much.  We only number starting
3159           # with the second one, so that the common case looks nice.
3160           my $vti = ($done ? $done : 'vti');
3161           ++$done;
3162
3163           # This is ugly, but it is our historical practice.
3164           if ($config_aux_dir_set_in_configure_ac)
3165             {
3166               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3167                                             'mdate-sh');
3168             }
3169           else
3170             {
3171               require_file_with_macro (TRUE, 'info_TEXINFOS',
3172                                        FOREIGN, 'mdate-sh');
3173             }
3174
3175           my $conf_dir;
3176           if ($config_aux_dir_set_in_configure_ac)
3177             {
3178               $conf_dir = "$am_config_aux_dir/";
3179             }
3180           else
3181             {
3182               $conf_dir = '$(srcdir)/';
3183             }
3184           $output_rules .= file_contents ('texi-vers',
3185                                           new Automake::Location,
3186                                           TEXI     => $texi,
3187                                           VTI      => $vti,
3188                                           STAMPVTI => "${soutdir}stamp-$vti",
3189                                           VTEXI    => "$soutdir$vtexi",
3190                                           MDDIR    => $conf_dir,
3191                                           DIRSTAMP => $dirstamp);
3192         }
3193     }
3194
3195   # Handle location of texinfo.tex.
3196   my $need_texi_file = 0;
3197   my $texinfodir;
3198   if (var ('TEXINFO_TEX'))
3199     {
3200       # The user defined TEXINFO_TEX so assume he knows what he is
3201       # doing.
3202       $texinfodir = ('$(srcdir)/'
3203                      . dirname (variable_value ('TEXINFO_TEX')));
3204     }
3205   elsif (option 'cygnus')
3206     {
3207       $texinfodir = '$(top_srcdir)/../texinfo';
3208       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3209     }
3210   elsif ($config_aux_dir_set_in_configure_ac)
3211     {
3212       $texinfodir = $am_config_aux_dir;
3213       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3214       $need_texi_file = 2; # so that we require_conf_file later
3215     }
3216   else
3217     {
3218       $texinfodir = '$(srcdir)';
3219       $need_texi_file = 1;
3220     }
3221   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3222
3223   push (@dist_targets, 'dist-info');
3224
3225   if (! option 'no-installinfo')
3226     {
3227       # Make sure documentation is made and installed first.  Use
3228       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3229       # get run twice during "make all".
3230       unshift (@all, '$(INFO_DEPS)');
3231     }
3232
3233   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3234   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3235   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3236   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3237
3238   # This next isn't strictly needed now -- the places that look here
3239   # could easily be changed to look in info_TEXINFOS.  But this is
3240   # probably better, in case noinst_TEXINFOS is ever supported.
3241   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3242
3243   # Do some error checking.  Note that this file is not required
3244   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3245   # up above.
3246   if ($need_texi_file && ! option 'no-texinfo.tex')
3247     {
3248       if ($need_texi_file > 1)
3249         {
3250           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3251                                         'texinfo.tex');
3252         }
3253       else
3254         {
3255           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3256                                    'texinfo.tex');
3257         }
3258     }
3259
3260   return makefile_wrap ("", "\t  ", @texi_cleans);
3261 }
3262
3263
3264 # handle_texinfo ()
3265 # -----------------
3266 # Handle all Texinfo source.
3267 sub handle_texinfo ()
3268 {
3269   reject_var 'TEXINFOS', "`TEXINFOS' is an anachronism; use `info_TEXINFOS'";
3270   # FIXME: I think this is an obsolete future feature name.
3271   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3272
3273   my $info_texinfos = var ('info_TEXINFOS');
3274   my $texiclean = "";
3275   if ($info_texinfos)
3276     {
3277       $texiclean = handle_texinfo_helper ($info_texinfos);
3278     }
3279   $output_rules .=  file_contents ('texinfos',
3280                                    new Automake::Location,
3281                                    TEXICLEAN     => $texiclean,
3282                                    'LOCAL-TEXIS' => !!$info_texinfos);
3283 }
3284
3285
3286 # Handle any man pages.
3287 sub handle_man_pages
3288 {
3289   reject_var 'MANS', "`MANS' is an anachronism; use `man_MANS'";
3290
3291   # Find all the sections in use.  We do this by first looking for
3292   # "standard" sections, and then looking for any additional
3293   # sections used in man_MANS.
3294   my (%sections, %vlist);
3295   # We handle nodist_ for uniformity.  man pages aren't distributed
3296   # by default so it isn't actually very important.
3297   foreach my $pfx ('', 'dist_', 'nodist_')
3298     {
3299       # Add more sections as needed.
3300       foreach my $section ('0'..'9', 'n', 'l')
3301         {
3302           my $varname = $pfx . 'man' . $section . '_MANS';
3303           if (var ($varname))
3304             {
3305               $sections{$section} = 1;
3306               $varname = '$(' . $varname . ')';
3307               $vlist{$varname} = 1;
3308
3309               &push_dist_common ($varname)
3310                 if $pfx eq 'dist_';
3311             }
3312         }
3313
3314       my $varname = $pfx . 'man_MANS';
3315       my $var = var ($varname);
3316       if ($var)
3317         {
3318           foreach ($var->value_as_list_recursive)
3319             {
3320               # A page like `foo.1c' goes into man1dir.
3321               if (/\.([0-9a-z])([a-z]*)$/)
3322                 {
3323                   $sections{$1} = 1;
3324                 }
3325             }
3326
3327           $varname = '$(' . $varname . ')';
3328           $vlist{$varname} = 1;
3329           &push_dist_common ($varname)
3330             if $pfx eq 'dist_';
3331         }
3332     }
3333
3334   return unless %sections;
3335
3336   # Now for each section, generate an install and uninstall rule.
3337   # Sort sections so output is deterministic.
3338   foreach my $section (sort keys %sections)
3339     {
3340       $output_rules .= &file_contents ('mans',
3341                                        new Automake::Location,
3342                                        SECTION => $section);
3343     }
3344
3345   my @mans = sort keys %vlist;
3346   $output_vars .= file_contents ('mans-vars',
3347                                  new Automake::Location,
3348                                  MANS => "@mans");
3349
3350   push (@all, '$(MANS)')
3351     unless option 'no-installman';
3352 }
3353
3354 # Handle DATA variables.
3355 sub handle_data
3356 {
3357     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3358                      'data', 'dataroot', 'dvi', 'html', 'pdf', 'ps',
3359                      'sysconf', 'sharedstate', 'localstate',
3360                      'pkgdata', 'lisp', 'noinst', 'check');
3361 }
3362
3363 # Handle TAGS.
3364 sub handle_tags
3365 {
3366     my @tag_deps = ();
3367     my @ctag_deps = ();
3368     if (var ('SUBDIRS'))
3369     {
3370         $output_rules .= ("tags-recursive:\n"
3371                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3372                           # Never fail here if a subdir fails; it
3373                           # isn't important.
3374                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3375                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3376                           . "\tdone\n");
3377         push (@tag_deps, 'tags-recursive');
3378         &depend ('.PHONY', 'tags-recursive');
3379
3380         $output_rules .= ("ctags-recursive:\n"
3381                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3382                           # Never fail here if a subdir fails; it
3383                           # isn't important.
3384                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3385                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3386                           . "\tdone\n");
3387         push (@ctag_deps, 'ctags-recursive');
3388         &depend ('.PHONY', 'ctags-recursive');
3389     }
3390
3391     if (&saw_sources_p (1)
3392         || var ('ETAGS_ARGS')
3393         || @tag_deps)
3394     {
3395         my @config;
3396         foreach my $spec (@config_headers)
3397         {
3398             my ($out, @ins) = split_config_file_spec ($spec);
3399             foreach my $in (@ins)
3400               {
3401                 # If the config header source is in this directory,
3402                 # require it.
3403                 push @config, basename ($in)
3404                   if $relative_dir eq dirname ($in);
3405               }
3406         }
3407         $output_rules .= &file_contents ('tags',
3408                                          new Automake::Location,
3409                                          CONFIG    => "@config",
3410                                          TAGSDIRS  => "@tag_deps",
3411                                          CTAGSDIRS => "@ctag_deps");
3412
3413         set_seen 'TAGS_DEPENDENCIES';
3414     }
3415     elsif (reject_var ('TAGS_DEPENDENCIES',
3416                        "doesn't make sense to define `TAGS_DEPENDENCIES'"
3417                        . "without\nsources or `ETAGS_ARGS'"))
3418     {
3419     }
3420     else
3421     {
3422         # Every Makefile must define some sort of TAGS rule.
3423         # Otherwise, it would be possible for a top-level "make TAGS"
3424         # to fail because some subdirectory failed.
3425         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3426         # Ditto ctags.
3427         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3428     }
3429 }
3430
3431 # Handle multilib support.
3432 sub handle_multilib
3433 {
3434   if ($seen_multilib && $relative_dir eq '.')
3435     {
3436       $output_rules .= &file_contents ('multilib', new Automake::Location);
3437       push (@all, 'all-multi');
3438     }
3439 }
3440
3441
3442 # user_phony_rule ($NAME)
3443 # -----------------------
3444 # Return false if rule $NAME does not exist.  Otherwise,
3445 # declare it as phony, complete its definition (in case it is
3446 # conditional), and return its Automake::Rule instance.
3447 sub user_phony_rule ($)
3448 {
3449   my ($name) = @_;
3450   my $rule = rule $name;
3451   if ($rule)
3452     {
3453       depend ('.PHONY', $name);
3454       # Define $NAME in all condition where it is not already defined,
3455       # so that it is always OK to depend on $NAME.
3456       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3457         {
3458           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3459                                   $c, INTERNAL);
3460           $output_rules .= $c->subst_string . "$name:\n";
3461         }
3462     }
3463   return $rule;
3464 }
3465
3466
3467 # $BOOLEAN
3468 # &for_dist_common ($A, $B)
3469 # -------------------------
3470 # Subroutine for &handle_dist: sort files to dist.
3471 #
3472 # We put README first because it then becomes easier to make a
3473 # Usenet-compliant shar file (in these, README must be first).
3474 #
3475 # FIXME: do more ordering of files here.
3476 sub for_dist_common
3477 {
3478     return 0
3479         if $a eq $b;
3480     return -1
3481         if $a eq 'README';
3482     return 1
3483         if $b eq 'README';
3484     return $a cmp $b;
3485 }
3486
3487
3488 # handle_dist
3489 # -----------
3490 # Handle 'dist' target.
3491 sub handle_dist ()
3492 {
3493   # Substutions for distdit.am
3494   my %transform;
3495
3496   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3497   # no-dist setting: target like `distclean' or `maintainer-clean' use it.
3498   my $subdirs = var ('SUBDIRS');
3499   if ($subdirs)
3500     {
3501       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3502       # to all possible directories, and use it.  If DIST_SUBDIRS is
3503       # defined, just use it.
3504
3505       # Note that we check DIST_SUBDIRS first on purpose, so that
3506       # we don't call has_conditional_contents for now reason.
3507       # (In the past one project used so many conditional subdirectories
3508       # that calling has_conditional_contents on SUBDIRS caused
3509       # automake to grow to 150Mb -- this should not happen with
3510       # the current implementation of has_conditional_contents,
3511       # but it's more efficient to avoid the call anyway.)
3512       if (var ('DIST_SUBDIRS'))
3513         {
3514         }
3515       elsif ($subdirs->has_conditional_contents)
3516         {
3517           define_pretty_variable
3518             ('DIST_SUBDIRS', TRUE, INTERNAL,
3519              uniq ($subdirs->value_as_list_recursive));
3520         }
3521       else
3522         {
3523           # We always define this because that is what `distclean'
3524           # wants.
3525           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3526                                   '$(SUBDIRS)');
3527         }
3528     }
3529
3530   # The remaining definitions are only required when a dist target is used.
3531   return if option 'no-dist';
3532
3533   # At least one of the archive formats must be enabled.
3534   if ($relative_dir eq '.')
3535     {
3536       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3537       $archive_defined ||=
3538         grep { option "dist-$_" } ('shar', 'zip', 'tarZ', 'bzip2');
3539       error (option 'no-dist-gzip',
3540              "no-dist-gzip specified but no dist-* specified, "
3541              . "at least one archive format must be enabled")
3542         unless $archive_defined;
3543     }
3544
3545   # Look for common files that should be included in distribution.
3546   # If the aux dir is set, and it does not have a Makefile.am, then
3547   # we check for these files there as well.
3548   my $check_aux = 0;
3549   if ($relative_dir eq '.'
3550       && $config_aux_dir_set_in_configure_ac)
3551     {
3552       if (! &is_make_dir ($config_aux_dir))
3553         {
3554           $check_aux = 1;
3555         }
3556     }
3557   foreach my $cfile (@common_files)
3558     {
3559       if (dir_has_case_matching_file ($relative_dir, $cfile)
3560           # The file might be absent, but if it can be built it's ok.
3561           || rule $cfile)
3562         {
3563           &push_dist_common ($cfile);
3564         }
3565
3566       # Don't use `elsif' here because a file might meaningfully
3567       # appear in both directories.
3568       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3569         {
3570           &push_dist_common ("$config_aux_dir/$cfile")
3571         }
3572     }
3573
3574   # We might copy elements from $configure_dist_common to
3575   # %dist_common if we think we need to.  If the file appears in our
3576   # directory, we would have discovered it already, so we don't
3577   # check that.  But if the file is in a subdir without a Makefile,
3578   # we want to distribute it here if we are doing `.'.  Ugly!
3579   if ($relative_dir eq '.')
3580     {
3581       foreach my $file (split (' ' , $configure_dist_common))
3582         {
3583           push_dist_common ($file)
3584             unless is_make_dir (dirname ($file));
3585         }
3586     }
3587
3588   # Files to distributed.  Don't use ->value_as_list_recursive
3589   # as it recursively expands `$(dist_pkgdata_DATA)' etc.
3590   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3591   @dist_common = uniq (sort for_dist_common (@dist_common));
3592   variable_delete 'DIST_COMMON';
3593   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3594
3595   # Now that we've processed DIST_COMMON, disallow further attempts
3596   # to set it.
3597   $handle_dist_run = 1;
3598
3599   # Scan EXTRA_DIST to see if we need to distribute anything from a
3600   # subdir.  If so, add it to the list.  I didn't want to do this
3601   # originally, but there were so many requests that I finally
3602   # relented.
3603   my $extra_dist = var ('EXTRA_DIST');
3604   if ($extra_dist)
3605     {
3606       # FIXME: This should be fixed to work with conditions.  That
3607       # will require only making the entries in %dist_dirs under the
3608       # appropriate condition.  This is meaningful if the nature of
3609       # the distribution should depend upon the configure options
3610       # used.
3611       foreach ($extra_dist->value_as_list_recursive (skip_ac_subst => 1))
3612         {
3613           next unless s,/+[^/]+$,,;
3614           $dist_dirs{$_} = 1
3615             unless $_ eq '.';
3616         }
3617     }
3618
3619   # We have to check DIST_COMMON for extra directories in case the
3620   # user put a source used in AC_OUTPUT into a subdir.
3621   my $topsrcdir = backname ($relative_dir);
3622   foreach (rvar ('DIST_COMMON')->value_as_list_recursive (skip_ac_subst => 1))
3623     {
3624       s/\$\(top_srcdir\)/$topsrcdir/;
3625       s/\$\(srcdir\)/./;
3626       # Strip any leading `./'.
3627       s,^(:?\./+)*,,;
3628       next unless s,/+[^/]+$,,;
3629       $dist_dirs{$_} = 1
3630         unless $_ eq '.';
3631     }
3632
3633   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3634   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3635
3636   # Prepend $(distdir) to each directory given.
3637   my %rewritten = map { '$(distdir)/' . "$_" => 1 } keys %dist_dirs;
3638   $transform{'DISTDIRS'} = join (' ', sort keys %rewritten);
3639
3640   # If the target `dist-hook' exists, make sure it is run.  This
3641   # allows users to do random weird things to the distribution
3642   # before it is packaged up.
3643   push (@dist_targets, 'dist-hook')
3644     if user_phony_rule 'dist-hook';
3645   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3646
3647   my $flm = option ('filename-length-max');
3648   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3649
3650   $output_rules .= &file_contents ('distdir',
3651                                    new Automake::Location,
3652                                    %transform,
3653                                    FILENAME_FILTER => $filename_filter);
3654 }
3655
3656
3657 # check_directory ($NAME, $WHERE)
3658 # -------------------------------
3659 # Ensure $NAME is a directory, and that it uses sane name.
3660 # Use $WHERE as a location in the diagnostic, if any.
3661 sub check_directory ($$)
3662 {
3663   my ($dir, $where) = @_;
3664
3665   error $where, "required directory $relative_dir/$dir does not exist"
3666     unless -d "$relative_dir/$dir";
3667
3668   # If an `obj/' directory exists, BSD make will enter it before
3669   # reading `Makefile'.  Hence the `Makefile' in the current directory
3670   # will not be read.
3671   #
3672   #  % cat Makefile
3673   #  all:
3674   #          echo Hello
3675   #  % cat obj/Makefile
3676   #  all:
3677   #          echo World
3678   #  % make      # GNU make
3679   #  echo Hello
3680   #  Hello
3681   #  % pmake     # BSD make
3682   #  echo World
3683   #  World
3684   msg ('portability', $where,
3685        "naming a subdirectory `obj' causes troubles with BSD make")
3686     if $dir eq 'obj';
3687
3688   # `aux' is probably the most important of the following forbidden name,
3689   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3690   msg ('portability', $where,
3691        "name `$dir' is reserved on W32 and DOS platforms")
3692     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3693 }
3694
3695 # check_directories_in_var ($VARIABLE)
3696 # ------------------------------------
3697 # Recursively check all items in variables $VARIABLE as directories
3698 sub check_directories_in_var ($)
3699 {
3700   my ($var) = @_;
3701   $var->traverse_recursively
3702     (sub
3703      {
3704        my ($var, $val, $cond, $full_cond) = @_;
3705        check_directory ($val, $var->rdef ($cond)->location);
3706        return ();
3707      },
3708      undef,
3709      skip_ac_subst => 1);
3710 }
3711
3712 # &handle_subdirs ()
3713 # ------------------
3714 # Handle subdirectories.
3715 sub handle_subdirs ()
3716 {
3717   my $subdirs = var ('SUBDIRS');
3718   return
3719     unless $subdirs;
3720
3721   check_directories_in_var $subdirs;
3722
3723   my $dsubdirs = var ('DIST_SUBDIRS');
3724   check_directories_in_var $dsubdirs
3725     if $dsubdirs;
3726
3727   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3728   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3729 }
3730
3731
3732 # ($REGEN, @DEPENDENCIES)
3733 # &scan_aclocal_m4
3734 # ----------------
3735 # If aclocal.m4 creation is automated, return the list of its dependencies.
3736 sub scan_aclocal_m4 ()
3737 {
3738   my $regen_aclocal = 0;
3739
3740   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3741   set_seen 'CONFIGURE_DEPENDENCIES';
3742
3743   if (-f 'aclocal.m4')
3744     {
3745       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3746
3747       my $aclocal = new Automake::XFile "< aclocal.m4";
3748       my $line = $aclocal->getline;
3749       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3750     }
3751
3752   my @ac_deps = ();
3753
3754   if (set_seen ('ACLOCAL_M4_SOURCES'))
3755     {
3756       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3757       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3758                "`ACLOCAL_M4_SOURCES' is obsolete.\n"
3759                . "It should be safe to simply remove it.");
3760     }
3761
3762   # Note that it might be possible that aclocal.m4 doesn't exist but
3763   # should be auto-generated.  This case probably isn't very
3764   # important.
3765
3766   return ($regen_aclocal, @ac_deps);
3767 }
3768
3769
3770 # Helper function for substitute_ac_subst_variables.
3771 sub substitute_ac_subst_variables_worker($)
3772 {
3773   my ($token) = @_;
3774   return "\@$token\@" if var $token;
3775   return "\${$token\}";
3776 }
3777
3778 # substitute_ac_subst_variables ($TEXT)
3779 # -------------------------------------
3780 # Replace any occurence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
3781 # variable.
3782 sub substitute_ac_subst_variables ($)
3783 {
3784   my ($text) = @_;
3785   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
3786   return $text;
3787 }
3788
3789 # @DEPENDENCIES
3790 # &prepend_srcdir (@INPUTS)
3791 # -------------------------
3792 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
3793 # if an input file has a directory part the same as the current
3794 # directory, then the directory part is simply replaced by $(srcdir).
3795 # But if the directory part is different, then $(top_srcdir) is
3796 # prepended.
3797 sub prepend_srcdir (@)
3798 {
3799   my (@inputs) = @_;
3800   my @newinputs;
3801
3802   foreach my $single (@inputs)
3803     {
3804       if (dirname ($single) eq $relative_dir)
3805         {
3806           push (@newinputs, '$(srcdir)/' . basename ($single));
3807         }
3808       else
3809         {
3810           push (@newinputs, '$(top_srcdir)/' . $single);
3811         }
3812     }
3813   return @newinputs;
3814 }
3815
3816 # @DEPENDENCIES
3817 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
3818 # ---------------------------------------------------
3819 # Compute a list of dependencies appropriate for the rebuild
3820 # rule of
3821 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
3822 # Also distribute $INPUTs which are not build by another AC_CONFIG_FILES.
3823 sub rewrite_inputs_into_dependencies ($@)
3824 {
3825   my ($file, @inputs) = @_;
3826   my @res = ();
3827
3828   for my $i (@inputs)
3829     {
3830       # We cannot create dependencies on shell variables.
3831       next if (substitute_ac_subst_variables $i) =~ /\$/;
3832
3833       if (exists $ac_config_files_location{$i})
3834         {
3835           my $di = dirname $i;
3836           if ($di eq $relative_dir)
3837             {
3838               $i = basename $i;
3839             }
3840           # In the top-level Makefile we do not use $(top_builddir), because
3841           # we are already there, and since the targets are built without
3842           # a $(top_builddir), it helps BSD Make to match them with
3843           # dependencies.
3844           elsif ($relative_dir ne '.')
3845             {
3846               $i = '$(top_builddir)/' . $i;
3847             }
3848         }
3849       else
3850         {
3851           msg ('error', $ac_config_files_location{$file},
3852                "required file `$i' not found")
3853             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
3854           ($i) = prepend_srcdir ($i);
3855           push_dist_common ($i);
3856         }
3857       push @res, $i;
3858     }
3859   return @res;
3860 }
3861
3862
3863
3864 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
3865 # ------------------------------------------------------------------
3866 # Handle remaking and configure stuff.
3867 # We need the name of the input file, to do proper remaking rules.
3868 sub handle_configure ($$$@)
3869 {
3870   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
3871
3872   prog_error 'empty @inputs'
3873     unless @inputs;
3874
3875   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
3876                                                             $makefile_in);
3877   my $rel_makefile = basename $makefile;
3878
3879   my $colon_infile = ':' . join (':', @inputs);
3880   $colon_infile = '' if $colon_infile eq ":$makefile.in";
3881   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
3882   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
3883   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
3884                           @configure_deps, @aclocal_m4_deps,
3885                           '$(top_srcdir)/' . $configure_ac);
3886   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
3887   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
3888   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
3889                           @configuredeps);
3890
3891   $output_rules .= file_contents
3892     ('configure',
3893      new Automake::Location,
3894      MAKEFILE              => $rel_makefile,
3895      'MAKEFILE-DEPS'       => "@rewritten",
3896      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
3897      'MAKEFILE-IN'         => $rel_makefile_in,
3898      'MAKEFILE-IN-DEPS'    => "@include_stack",
3899      'MAKEFILE-AM'         => $rel_makefile_am,
3900      STRICTNESS            => global_option 'cygnus'
3901                                 ? 'cygnus' : $strictness_name,
3902      'USE-DEPS'            => global_option 'no-dependencies'
3903                                 ? ' --ignore-deps' : '',
3904      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
3905      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4);
3906
3907   if ($relative_dir eq '.')
3908     {
3909       &push_dist_common ('acconfig.h')
3910         if -f 'acconfig.h';
3911     }
3912
3913   # If we have a configure header, require it.
3914   my $hdr_index = 0;
3915   my @distclean_config;
3916   foreach my $spec (@config_headers)
3917     {
3918       $hdr_index += 1;
3919       # $CONFIG_H_PATH: config.h from top level.
3920       my ($config_h_path, @ins) = split_config_file_spec ($spec);
3921       my $config_h_dir = dirname ($config_h_path);
3922
3923       # If the header is in the current directory we want to build
3924       # the header here.  Otherwise, if we're at the topmost
3925       # directory and the header's directory doesn't have a
3926       # Makefile, then we also want to build the header.
3927       if ($relative_dir eq $config_h_dir
3928           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
3929         {
3930           my ($cn_sans_dir, $stamp_dir);
3931           if ($relative_dir eq $config_h_dir)
3932             {
3933               $cn_sans_dir = basename ($config_h_path);
3934               $stamp_dir = '';
3935             }
3936           else
3937             {
3938               $cn_sans_dir = $config_h_path;
3939               if ($config_h_dir eq '.')
3940                 {
3941                   $stamp_dir = '';
3942                 }
3943               else
3944                 {
3945                   $stamp_dir = $config_h_dir . '/';
3946                 }
3947             }
3948
3949           # This will also distribute all inputs.
3950           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
3951
3952           # Cannot define rebuild rules for filenames with shell variables.
3953           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
3954
3955           # Header defined in this directory.
3956           my @files;
3957           if (-f $config_h_path . '.top')
3958             {
3959               push (@files, "$cn_sans_dir.top");
3960             }
3961           if (-f $config_h_path . '.bot')
3962             {
3963               push (@files, "$cn_sans_dir.bot");
3964             }
3965
3966           push_dist_common (@files);
3967
3968           # For now, acconfig.h can only appear in the top srcdir.
3969           if (-f 'acconfig.h')
3970             {
3971               push (@files, '$(top_srcdir)/acconfig.h');
3972             }
3973
3974           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
3975           $output_rules .=
3976             file_contents ('remake-hdr',
3977                            new Automake::Location,
3978                            FILES            => "@files",
3979                            CONFIG_H         => $cn_sans_dir,
3980                            CONFIG_HIN       => $ins[0],
3981                            CONFIG_H_DEPS    => "@ins",
3982                            CONFIG_H_PATH    => $config_h_path,
3983                            STAMP            => "$stamp");
3984
3985           push @distclean_config, $cn_sans_dir, $stamp;
3986         }
3987     }
3988
3989   $output_rules .= file_contents ('clean-hdr',
3990                                   new Automake::Location,
3991                                   FILES => "@distclean_config")
3992     if @distclean_config;
3993
3994   # Distribute and define mkinstalldirs only if it is already present
3995   # in the package, for backward compatibility (some people may still
3996   # use $(mkinstalldirs)).
3997   my $mkidpath = "$config_aux_dir/mkinstalldirs";
3998   if (-f $mkidpath)
3999     {
4000       # Use require_file so that any existing script gets updated
4001       # by --force-missing.
4002       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4003       define_variable ('mkinstalldirs',
4004                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4005     }
4006   else
4007     {
4008       # Use $(install_sh), not $(mkdir_p) because the latter requires
4009       # at least one argument, and $(mkinstalldirs) used to work
4010       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4011       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4012     }
4013
4014   reject_var ('CONFIG_HEADER',
4015               "`CONFIG_HEADER' is an anachronism; now determined "
4016               . "automatically\nfrom `$configure_ac'");
4017
4018   my @config_h;
4019   foreach my $spec (@config_headers)
4020     {
4021       my ($out, @ins) = split_config_file_spec ($spec);
4022       # Generate CONFIG_HEADER define.
4023       if ($relative_dir eq dirname ($out))
4024         {
4025           push @config_h, basename ($out);
4026         }
4027       else
4028         {
4029           push @config_h, "\$(top_builddir)/$out";
4030         }
4031     }
4032   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4033     if @config_h;
4034
4035   # Now look for other files in this directory which must be remade
4036   # by config.status, and generate rules for them.
4037   my @actual_other_files = ();
4038   foreach my $lfile (@other_input_files)
4039     {
4040       my $file;
4041       my @inputs;
4042       if ($lfile =~ /^([^:]*):(.*)$/)
4043         {
4044           # This is the ":" syntax of AC_OUTPUT.
4045           $file = $1;
4046           @inputs = split (':', $2);
4047         }
4048       else
4049         {
4050           # Normal usage.
4051           $file = $lfile;
4052           @inputs = $file . '.in';
4053         }
4054
4055       # Automake files should not be stored in here, but in %MAKE_LIST.
4056       prog_error ("$lfile in \@other_input_files\n"
4057                   . "\@other_input_files = (@other_input_files)")
4058         if -f $file . '.am';
4059
4060       my $local = basename ($file);
4061
4062       # Make sure the dist directory for each input file is created.
4063       # We only have to do this at the topmost level though.  This
4064       # is a bit ugly but it easier than spreading out the logic,
4065       # especially in cases like AC_OUTPUT(foo/out:bar/in), where
4066       # there is no Makefile in bar/.
4067       if ($relative_dir eq '.')
4068         {
4069           foreach (@inputs)
4070             {
4071               $dist_dirs{dirname ($_)} = 1;
4072             }
4073         }
4074
4075       # We skip files that aren't in this directory.  However, if
4076       # the file's directory does not have a Makefile, and we are
4077       # currently doing `.', then we create a rule to rebuild the
4078       # file in the subdir.
4079       my $fd = dirname ($file);
4080       if ($fd ne $relative_dir)
4081         {
4082           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4083             {
4084               $local = $file;
4085             }
4086           else
4087             {
4088               next;
4089             }
4090         }
4091
4092       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4093
4094       # Cannot output rules for shell variables.
4095       next if (substitute_ac_subst_variables $local) =~ /\$/;
4096
4097       $output_rules .= ($local . ': '
4098                         . '$(top_builddir)/config.status '
4099                         . "@rewritten_inputs\n"
4100                         . "\t"
4101                         . 'cd $(top_builddir) && '
4102                         . '$(SHELL) ./config.status '
4103                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4104                         . '$@'
4105                         . "\n");
4106       push (@actual_other_files, $local);
4107     }
4108
4109   # For links we should clean destinations and distribute sources.
4110   foreach my $spec (@config_links)
4111     {
4112       my ($link, $file) = split /:/, $spec;
4113       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4114       # the DEST:SRC form.
4115       next unless $file;
4116       my $where = $ac_config_files_location{$link};
4117
4118       # Skip destinations that contain shell variables.
4119       if ((substitute_ac_subst_variables $link) !~ /\$/)
4120         {
4121           # We skip links that aren't in this directory.  However, if
4122           # the link's directory does not have a Makefile, and we are
4123           # currently doing `.', then we add the link to CONFIG_CLEAN_FILES
4124           # in `.'s Makefile.in.
4125           my $local = basename ($link);
4126           my $fd = dirname ($link);
4127           if ($fd ne $relative_dir)
4128             {
4129               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4130                 {
4131                   $local = $link;
4132                 }
4133               else
4134                 {
4135                   $local = undef;
4136                 }
4137             }
4138           push @actual_other_files, $local if $local;
4139         }
4140
4141       # Do not process sources that contain shell variables.
4142       if ((substitute_ac_subst_variables $file) !~ /\$/)
4143         {
4144           my $fd = dirname ($file);
4145
4146           # Make sure the dist directory for each input file is created.
4147           # We only have to do this at the topmost level though.
4148           if ($relative_dir eq '.')
4149             {
4150               $dist_dirs{$fd} = 1;
4151             }
4152
4153           # We distribute files that are in this directory.
4154           # At the top-level (`.') we also distribute files whose
4155           # directory does not have a Makefile.
4156           if (($fd eq $relative_dir)
4157               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4158             {
4159               # The following will distribute $file as a side-effect when
4160               # it is appropriate (i.e., when $file is not already an output).
4161               # We do not need the result, just the side-effect.
4162               rewrite_inputs_into_dependencies ($link, $file);
4163             }
4164         }
4165     }
4166
4167   # These files get removed by "make distclean".
4168   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4169                           @actual_other_files);
4170 }
4171
4172 # Handle C headers.
4173 sub handle_headers
4174 {
4175     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4176                              'oldinclude', 'pkginclude',
4177                              'noinst', 'check');
4178     foreach (@r)
4179     {
4180       next unless $_->[1] =~ /\..*$/;
4181       &saw_extension ($&);
4182     }
4183 }
4184
4185 sub handle_gettext
4186 {
4187   return if ! $seen_gettext || $relative_dir ne '.';
4188
4189   my $subdirs = var 'SUBDIRS';
4190
4191   if (! $subdirs)
4192     {
4193       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4194       return;
4195     }
4196
4197   # Perform some sanity checks to help users get the right setup.
4198   # We disable these tests when po/ doesn't exist in order not to disallow
4199   # unusual gettext setups.
4200   #
4201   # Bruno Haible:
4202   # | The idea is:
4203   # |
4204   # |  1) If a package doesn't have a directory po/ at top level, it
4205   # |     will likely have multiple po/ directories in subpackages.
4206   # |
4207   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4208   # |     is used without 'external'. It is also useful to warn for the
4209   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4210   # |     warnings apply only to the usual layout of packages, therefore
4211   # |     they should both be disabled if no po/ directory is found at
4212   # |     top level.
4213
4214   if (-d 'po')
4215     {
4216       my @subdirs = $subdirs->value_as_list_recursive;
4217
4218       msg_var ('syntax', $subdirs,
4219                "AM_GNU_GETTEXT used but `po' not in SUBDIRS")
4220         if ! grep ($_ eq 'po', @subdirs);
4221
4222       # intl/ is not required when AM_GNU_GETTEXT is called with
4223       # the `external' option.
4224       msg_var ('syntax', $subdirs,
4225                "AM_GNU_GETTEXT used but `intl' not in SUBDIRS")
4226         if (! $seen_gettext_external
4227             && ! grep ($_ eq 'intl', @subdirs));
4228
4229       # intl/ should not be used with AM_GNU_GETTEXT([external])
4230       msg_var ('syntax', $subdirs,
4231                "`intl' should not be in SUBDIRS when "
4232                . "AM_GNU_GETTEXT([external]) is used")
4233         if ($seen_gettext_external && grep ($_ eq 'intl', @subdirs));
4234     }
4235
4236   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4237 }
4238
4239 # Handle footer elements.
4240 sub handle_footer
4241 {
4242     reject_rule ('.SUFFIXES',
4243                  "use variable `SUFFIXES', not target `.SUFFIXES'");
4244
4245     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4246     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4247     # anything else, by sticking it right after the default: target.
4248     $output_header .= ".SUFFIXES:\n";
4249     my $suffixes = var 'SUFFIXES';
4250     my @suffixes = Automake::Rule::suffixes;
4251     if (@suffixes || $suffixes)
4252     {
4253         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4254         # the output remains consistent.  However, $(SUFFIXES) is
4255         # always at the start of the list, unsorted.  This is done
4256         # because make will choose rules depending on the ordering of
4257         # suffixes, and this lets the user have some control.  Push
4258         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4259         # do not like variable substitutions on the .SUFFIXES line.
4260         my @user_suffixes = ($suffixes
4261                              ? $suffixes->value_as_list_recursive : ());
4262
4263         my %suffixes = map { $_ => 1 } @suffixes;
4264         delete @suffixes{@user_suffixes};
4265
4266         $output_header .= (".SUFFIXES: "
4267                            . join (' ', @user_suffixes, sort keys %suffixes)
4268                            . "\n");
4269     }
4270
4271     $output_trailer .= file_contents ('footer', new Automake::Location);
4272 }
4273
4274
4275 # Generate `make install' rules.
4276 sub handle_install ()
4277 {
4278   $output_rules .= &file_contents
4279     ('install',
4280      new Automake::Location,
4281      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4282                              ? (" \$(BUILT_SOURCES)\n"
4283                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4284                              : ''),
4285      'installdirs-local' => (user_phony_rule 'installdirs-local'
4286                              ? ' installdirs-local' : ''),
4287      am__installdirs => variable_value ('am__installdirs') || '');
4288 }
4289
4290
4291 # Deal with all and all-am.
4292 sub handle_all ($)
4293 {
4294     my ($makefile) = @_;
4295
4296     # Output `all-am'.
4297
4298     # Put this at the beginning for the sake of non-GNU makes.  This
4299     # is still wrong if these makes can run parallel jobs.  But it is
4300     # right enough.
4301     unshift (@all, basename ($makefile));
4302
4303     foreach my $spec (@config_headers)
4304       {
4305         my ($out, @ins) = split_config_file_spec ($spec);
4306         push (@all, basename ($out))
4307           if dirname ($out) eq $relative_dir;
4308       }
4309
4310     # Install `all' hooks.
4311     push (@all, "all-local")
4312       if user_phony_rule "all-local";
4313
4314     &pretty_print_rule ("all-am:", "\t\t", @all);
4315     &depend ('.PHONY', 'all-am', 'all');
4316
4317
4318     # Output `all'.
4319
4320     my @local_headers = ();
4321     push @local_headers, '$(BUILT_SOURCES)'
4322       if var ('BUILT_SOURCES');
4323     foreach my $spec (@config_headers)
4324       {
4325         my ($out, @ins) = split_config_file_spec ($spec);
4326         push @local_headers, basename ($out)
4327           if dirname ($out) eq $relative_dir;
4328       }
4329
4330     if (@local_headers)
4331       {
4332         # We need to make sure config.h is built before we recurse.
4333         # We also want to make sure that built sources are built
4334         # before any ordinary `all' targets are run.  We can't do this
4335         # by changing the order of dependencies to the "all" because
4336         # that breaks when using parallel makes.  Instead we handle
4337         # things explicitly.
4338         $output_all .= ("all: @local_headers"
4339                         . "\n\t"
4340                         . '$(MAKE) $(AM_MAKEFLAGS) '
4341                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4342                         . "\n\n");
4343       }
4344     else
4345       {
4346         $output_all .= "all: " . (var ('SUBDIRS')
4347                                   ? 'all-recursive' : 'all-am') . "\n\n";
4348       }
4349 }
4350
4351
4352 # &do_check_merge_target ()
4353 # -------------------------
4354 # Handle check merge target specially.
4355 sub do_check_merge_target ()
4356 {
4357   # Include user-defined local form of target.
4358   push @check_tests, 'check-local'
4359     if user_phony_rule 'check-local';
4360
4361   # In --cygnus mode, check doesn't depend on all.
4362   if (option 'cygnus')
4363     {
4364       # Just run the local check rules.
4365       pretty_print_rule ('check-am:', "\t\t", @check);
4366     }
4367   else
4368     {
4369       # The check target must depend on the local equivalent of
4370       # `all', to ensure all the primary targets are built.  Then it
4371       # must build the local check rules.
4372       $output_rules .= "check-am: all-am\n";
4373       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4374                          @check)
4375         if @check;
4376     }
4377   pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4378                      @check_tests)
4379     if @check_tests;
4380
4381   depend '.PHONY', 'check', 'check-am';
4382   # Handle recursion.  We have to honor BUILT_SOURCES like for `all:'.
4383   $output_rules .= ("check: "
4384                     . (var ('BUILT_SOURCES')
4385                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4386                        : '')
4387                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4388                     . "\n");
4389 }
4390
4391 # handle_clean ($MAKEFILE)
4392 # ------------------------
4393 # Handle all 'clean' targets.
4394 sub handle_clean ($)
4395 {
4396   my ($makefile) = @_;
4397
4398   # Clean the files listed in user variables if they exist.
4399   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4400     if var ('MOSTLYCLEANFILES');
4401   $clean_files{'$(CLEANFILES)'} = CLEAN
4402     if var ('CLEANFILES');
4403   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4404     if var ('DISTCLEANFILES');
4405   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4406     if var ('MAINTAINERCLEANFILES');
4407
4408   # Built sources are automatically removed by maintainer-clean.
4409   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4410     if var ('BUILT_SOURCES');
4411
4412   # Compute a list of "rm"s to run for each target.
4413   my %rms = (MOSTLY_CLEAN, [],
4414              CLEAN, [],
4415              DIST_CLEAN, [],
4416              MAINTAINER_CLEAN, []);
4417
4418   foreach my $file (keys %clean_files)
4419     {
4420       my $when = $clean_files{$file};
4421       prog_error 'invalid entry in %clean_files'
4422         unless exists $rms{$when};
4423
4424       my $rm = "rm -f $file";
4425       # If file is a variable, make sure when don't call `rm -f' without args.
4426       $rm ="test -z \"$file\" || $rm"
4427         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4428
4429       push @{$rms{$when}}, "\t-$rm\n";
4430     }
4431
4432   $output_rules .= &file_contents
4433     ('clean',
4434      new Automake::Location,
4435      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4436      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4437      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4438      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4439      MAKEFILE             => basename $makefile,
4440      );
4441 }
4442
4443
4444 # &target_cmp ($A, $B)
4445 # --------------------
4446 # Subroutine for &handle_factored_dependencies to let `.PHONY' and
4447 # other `.TARGETS' be last.
4448 sub target_cmp
4449 {
4450   return 0 if $a eq $b;
4451
4452   my $a1 = substr ($a, 0, 1);
4453   my $b1 = substr ($b, 0, 1);
4454   if ($a1 ne $b1)
4455     {
4456       return -1 if $b1 eq '.';
4457       return 1 if $a1 eq '.';
4458     }
4459   return $a cmp $b;
4460 }
4461
4462
4463 # &handle_factored_dependencies ()
4464 # --------------------------------
4465 # Handle everything related to gathered targets.
4466 sub handle_factored_dependencies
4467 {
4468   # Reject bad hooks.
4469   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4470                      'uninstall-exec-local', 'uninstall-exec-hook',
4471                      'uninstall-dvi-local',
4472                      'uninstall-html-local',
4473                      'uninstall-info-local',
4474                      'uninstall-pdf-local',
4475                      'uninstall-ps-local')
4476     {
4477       my $x = $utarg;
4478       $x =~ s/-.*-/-/;
4479       reject_rule ($utarg, "use `$x', not `$utarg'");
4480     }
4481
4482   reject_rule ('install-local',
4483                "use `install-data-local' or `install-exec-local', "
4484                . "not `install-local'");
4485
4486   reject_rule ('install-hook',
4487                "use `install-data-hook' or `install-exec-hook', "
4488                . "not `install-hook'");
4489
4490   # Install the -local hooks.
4491   foreach (keys %dependencies)
4492     {
4493       # Hooks are installed on the -am targets.
4494       s/-am$// or next;
4495       depend ("$_-am", "$_-local")
4496         if user_phony_rule "$_-local";
4497     }
4498
4499   # Install the -hook hooks.
4500   # FIXME: Why not be as liberal as we are with -local hooks?
4501   foreach ('install-exec', 'install-data', 'uninstall')
4502     {
4503       if (user_phony_rule "$_-hook")
4504         {
4505           $actions{"$_-am"} .=
4506             ("\t\@\$(NORMAL_INSTALL)\n"
4507              . "\t" . '$(MAKE) $(AM_MAKEFLAGS) ' . "$_-hook\n");
4508           depend ('.MAKE', "$_-am");
4509         }
4510     }
4511
4512   # All the required targets are phony.
4513   depend ('.PHONY', keys %required_targets);
4514
4515   # Actually output gathered targets.
4516   foreach (sort target_cmp keys %dependencies)
4517     {
4518       # If there is nothing about this guy, skip it.
4519       next
4520         unless (@{$dependencies{$_}}
4521                 || $actions{$_}
4522                 || $required_targets{$_});
4523
4524       # Define gathered targets in undefined conditions.
4525       # FIXME: Right now we must handle .PHONY as an exception,
4526       # because people write things like
4527       #    .PHONY: myphonytarget
4528       # to append dependencies.  This would not work if Automake
4529       # refrained from defining its own .PHONY target as it does
4530       # with other overridden targets.
4531       # Likewise for `.MAKE'.
4532       my @undefined_conds = (TRUE,);
4533       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4534         {
4535           @undefined_conds =
4536             Automake::Rule::define ($_, 'internal',
4537                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4538         }
4539       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4540       foreach my $cond (@undefined_conds)
4541         {
4542           my $condstr = $cond->subst_string;
4543           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4544           $output_rules .= $actions{$_} if defined $actions{$_};
4545           $output_rules .= "\n";
4546         }
4547     }
4548 }
4549
4550
4551 # &handle_tests_dejagnu ()
4552 # ------------------------
4553 sub handle_tests_dejagnu
4554 {
4555     push (@check_tests, 'check-DEJAGNU');
4556     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4557 }
4558
4559
4560 # Handle TESTS variable and other checks.
4561 sub handle_tests
4562 {
4563   if (option 'dejagnu')
4564     {
4565       &handle_tests_dejagnu;
4566     }
4567   else
4568     {
4569       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4570         {
4571           reject_var ($c, "`$c' defined but `dejagnu' not in "
4572                       . "`AUTOMAKE_OPTIONS'");
4573         }
4574     }
4575
4576   if (var ('TESTS'))
4577     {
4578       push (@check_tests, 'check-TESTS');
4579       $output_rules .= &file_contents ('check', new Automake::Location);
4580     }
4581 }
4582
4583 # Handle Emacs Lisp.
4584 sub handle_emacs_lisp
4585 {
4586   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4587                                  'lisp', 'noinst');
4588
4589   return if ! @elfiles;
4590
4591   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4592                           map { $_->[1] } @elfiles);
4593   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
4594                           '$(am__ELFILES:.el=.elc)');
4595   # This one can be overridden by users.
4596   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
4597
4598   push @all, '$(ELCFILES)';
4599
4600   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
4601                      'EMACS', 'lispdir');
4602   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
4603   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
4604 }
4605
4606 # Handle Python
4607 sub handle_python
4608 {
4609   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
4610                                  'noinst');
4611   return if ! @pyfiles;
4612
4613   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
4614   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
4615   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
4616 }
4617
4618 # Handle Java.
4619 sub handle_java
4620 {
4621     my @sourcelist = &am_install_var ('-candist',
4622                                       'java', 'JAVA',
4623                                       'java', 'noinst', 'check');
4624     return if ! @sourcelist;
4625
4626     my @prefix = am_primary_prefixes ('JAVA', 1,
4627                                       'java', 'noinst', 'check');
4628
4629     my $dir;
4630     foreach my $curs (@prefix)
4631       {
4632         next
4633           if $curs eq 'EXTRA';
4634
4635         err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
4636           if defined $dir;
4637         $dir = $curs;
4638       }
4639
4640
4641     push (@all, 'class' . $dir . '.stamp');
4642 }
4643
4644
4645 # Handle some of the minor options.
4646 sub handle_minor_options
4647 {
4648   if (option 'readme-alpha')
4649     {
4650       if ($relative_dir eq '.')
4651         {
4652           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
4653             {
4654               msg ('error-gnits', $package_version_location,
4655                    "version `$package_version' doesn't follow " .
4656                    "Gnits standards");
4657             }
4658           if (defined $1 && -f 'README-alpha')
4659             {
4660               # This means we have an alpha release.  See
4661               # GNITS_VERSION_PATTERN for details.
4662               push_dist_common ('README-alpha');
4663             }
4664         }
4665     }
4666 }
4667
4668 ################################################################
4669
4670 # ($OUTPUT, @INPUTS)
4671 # &split_config_file_spec ($SPEC)
4672 # -------------------------------
4673 # Decode the Autoconf syntax for config files (files, headers, links
4674 # etc.).
4675 sub split_config_file_spec ($)
4676 {
4677   my ($spec) = @_;
4678   my ($output, @inputs) = split (/:/, $spec);
4679
4680   push @inputs, "$output.in"
4681     unless @inputs;
4682
4683   return ($output, @inputs);
4684 }
4685
4686 # $input
4687 # locate_am (@POSSIBLE_SOURCES)
4688 # -----------------------------
4689 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
4690 # This functions returns the first *.in file for which a *.am exists.
4691 # It returns undef otherwise.
4692 sub locate_am (@)
4693 {
4694   my (@rest) = @_;
4695   my $input;
4696   foreach my $file (@rest)
4697     {
4698       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
4699         {
4700           $input = $file;
4701           last;
4702         }
4703     }
4704   return $input;
4705 }
4706
4707 my %make_list;
4708
4709 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
4710 # ---------------------------------------------------
4711 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
4712 # (or AC_OUTPUT).
4713 sub scan_autoconf_config_files ($$)
4714 {
4715   my ($where, $config_files) = @_;
4716
4717   # Look at potential Makefile.am's.
4718   foreach (split ' ', $config_files)
4719     {
4720       # Must skip empty string for Perl 4.
4721       next if $_ eq "\\" || $_ eq '';
4722
4723       # Handle $local:$input syntax.
4724       my ($local, @rest) = split (/:/);
4725       @rest = ("$local.in",) unless @rest;
4726       my $input = locate_am @rest;
4727       if ($input)
4728         {
4729           # We have a file that automake should generate.
4730           $make_list{$input} = join (':', ($local, @rest));
4731         }
4732       else
4733         {
4734           # We have a file that automake should cause to be
4735           # rebuilt, but shouldn't generate itself.
4736           push (@other_input_files, $_);
4737         }
4738       $ac_config_files_location{$local} = $where;
4739     }
4740 }
4741
4742
4743 # &scan_autoconf_traces ($FILENAME)
4744 # ---------------------------------
4745 sub scan_autoconf_traces ($)
4746 {
4747   my ($filename) = @_;
4748
4749   # Macros to trace, with their minimal number of arguments.
4750   #
4751   # IMPORTANT: If you add a macro here, you should also add this macro
4752   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
4753   my %traced = (
4754                 AC_CANONICAL_BUILD => 0,
4755                 AC_CANONICAL_HOST => 0,
4756                 AC_CANONICAL_TARGET => 0,
4757                 AC_CONFIG_AUX_DIR => 1,
4758                 AC_CONFIG_FILES => 1,
4759                 AC_CONFIG_HEADERS => 1,
4760                 AC_CONFIG_LIBOBJ_DIR => 1,
4761                 AC_CONFIG_LINKS => 1,
4762                 AC_INIT => 0,
4763                 AC_LIBSOURCE => 1,
4764                 AC_REQUIRE_AUX_FILE => 1,
4765                 AC_SUBST_TRACE => 1,
4766                 AM_AUTOMAKE_VERSION => 1,
4767                 AM_CONDITIONAL => 2,
4768                 AM_ENABLE_MULTILIB => 0,
4769                 AM_GNU_GETTEXT => 0,
4770                 AM_INIT_AUTOMAKE => 0,
4771                 AM_MAINTAINER_MODE => 0,
4772                 AM_PROG_CC_C_O => 0,
4773                 LT_SUPPORTED_TAG => 1,
4774                 _LT_AC_TAGCONFIG => 0,
4775                 m4_include => 1,
4776                 m4_sinclude => 1,
4777                 sinclude => 1,
4778               );
4779
4780   my $traces = ($ENV{AUTOCONF} || 'autoconf') . " ";
4781
4782   # Use a separator unlikely to be used, not `:', the default, which
4783   # has a precise meaning for AC_CONFIG_FILES and so on.
4784   $traces .= join (' ',
4785                    map { "--trace=$_" . ':\$f:\$l::\$n::\${::}%' }
4786                    (keys %traced));
4787
4788   my $tracefh = new Automake::XFile ("$traces $filename |");
4789   verb "reading $traces";
4790
4791   while ($_ = $tracefh->getline)
4792     {
4793       chomp;
4794       my ($here, @args) = split (/::/);
4795       my $where = new Automake::Location $here;
4796       my $macro = $args[0];
4797
4798       prog_error ("unrequested trace `$macro'")
4799         unless exists $traced{$macro};
4800
4801       # Skip and diagnose malformed calls.
4802       if ($#args < $traced{$macro})
4803         {
4804           msg ('syntax', $where, "not enough arguments for $macro");
4805           next;
4806         }
4807
4808       # Alphabetical ordering please.
4809       if ($macro eq 'AC_CANONICAL_BUILD')
4810         {
4811           if ($seen_canonical <= AC_CANONICAL_BUILD)
4812             {
4813               $seen_canonical = AC_CANONICAL_BUILD;
4814               $canonical_location = $where;
4815             }
4816         }
4817       elsif ($macro eq 'AC_CANONICAL_HOST')
4818         {
4819           if ($seen_canonical <= AC_CANONICAL_HOST)
4820             {
4821               $seen_canonical = AC_CANONICAL_HOST;
4822               $canonical_location = $where;
4823             }
4824         }
4825       elsif ($macro eq 'AC_CANONICAL_TARGET')
4826         {
4827           $seen_canonical = AC_CANONICAL_TARGET;
4828           $canonical_location = $where;
4829         }
4830       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
4831         {
4832           if ($seen_init_automake)
4833             {
4834               error ($where, "AC_CONFIG_AUX_DIR must be called before "
4835                      . "AM_INIT_AUTOMAKE...", partial => 1);
4836               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
4837             }
4838           $config_aux_dir = $args[1];
4839           $config_aux_dir_set_in_configure_ac = 1;
4840           $relative_dir = '.';
4841           check_directory ($config_aux_dir, $where);
4842         }
4843       elsif ($macro eq 'AC_CONFIG_FILES')
4844         {
4845           # Look at potential Makefile.am's.
4846           scan_autoconf_config_files ($where, $args[1]);
4847         }
4848       elsif ($macro eq 'AC_CONFIG_HEADERS')
4849         {
4850           foreach my $spec (split (' ', $args[1]))
4851             {
4852               my ($dest, @src) = split (':', $spec);
4853               $ac_config_files_location{$dest} = $where;
4854               push @config_headers, $spec;
4855             }
4856         }
4857       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
4858         {
4859           $config_libobj_dir = $args[1];
4860           $relative_dir = '.';
4861           check_directory ($config_libobj_dir, $where);
4862         }
4863       elsif ($macro eq 'AC_CONFIG_LINKS')
4864         {
4865           foreach my $spec (split (' ', $args[1]))
4866             {
4867               my ($dest, $src) = split (':', $spec);
4868               $ac_config_files_location{$dest} = $where;
4869               push @config_links, $spec;
4870             }
4871         }
4872       elsif ($macro eq 'AC_INIT')
4873         {
4874           if (defined $args[2])
4875             {
4876               $package_version = $args[2];
4877               $package_version_location = $where;
4878             }
4879         }
4880       elsif ($macro eq 'AC_LIBSOURCE')
4881         {
4882           $libsources{$args[1]} = $here;
4883         }
4884       elsif ($macro eq 'AC_SUBST_TRACE')
4885         {
4886           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
4887           # AC_SUBST(5), then too bad.
4888           $configure_vars{$args[1]} = $where
4889             if $args[1] =~ /^\w+$/;
4890         }
4891       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
4892         {
4893           error ($where,
4894                  "version mismatch.  This is Automake $VERSION,\n" .
4895                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
4896                  "comes from Automake $args[1].  You should recreate\n" .
4897                  "aclocal.m4 with aclocal and run automake again.\n",
4898                  # $? = 63 is used to indicate version mismatch to missing.
4899                  exit_code => 63)
4900             if $VERSION ne $args[1];
4901
4902           $seen_automake_version = 1;
4903         }
4904       elsif ($macro eq 'AM_CONDITIONAL')
4905         {
4906           $configure_cond{$args[1]} = $where;
4907         }
4908       elsif ($macro eq 'AM_ENABLE_MULTILIB')
4909         {
4910           $seen_multilib = $where;
4911         }
4912       elsif ($macro eq 'AM_GNU_GETTEXT')
4913         {
4914           $seen_gettext = $where;
4915           $ac_gettext_location = $where;
4916           $seen_gettext_external = grep ($_ eq 'external', @args);
4917         }
4918       elsif ($macro eq 'AM_INIT_AUTOMAKE')
4919         {
4920           $seen_init_automake = $where;
4921           if (defined $args[2])
4922             {
4923               $package_version = $args[2];
4924               $package_version_location = $where;
4925             }
4926           elsif (defined $args[1])
4927             {
4928               exit $exit_code
4929                 if (process_global_option_list ($where,
4930                                                 split (' ', $args[1])));
4931             }
4932         }
4933       elsif ($macro eq 'AM_MAINTAINER_MODE')
4934         {
4935           $seen_maint_mode = $where;
4936         }
4937       elsif ($macro eq 'AM_PROG_CC_C_O')
4938         {
4939           $seen_cc_c_o = $where;
4940         }
4941       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
4942         {
4943           # Only remember the first time a file is required.
4944           $required_aux_file{$args[1]} = $where
4945             unless exists $required_aux_file{$args[1]};
4946         }
4947       elsif ($macro eq 'm4_include'
4948              || $macro eq 'm4_sinclude'
4949              || $macro eq 'sinclude')
4950         {
4951           # Skip missing `sinclude'd files.
4952           next if $macro ne 'm4_include' && ! -f $args[1];
4953
4954           # Some modified versions of Autoconf don't use
4955           # forzen files.  Consequently it's possible that we see all
4956           # m4_include's performed during Autoconf's startup.
4957           # Obviously we don't want to distribute Autoconf's files
4958           # so we skip absolute filenames here.
4959           push @configure_deps, '$(top_srcdir)/' . $args[1]
4960             unless $here =~ m,^(?:\w:)?[\\/],;
4961           # Keep track of the greatest timestamp.
4962           if (-e $args[1])
4963             {
4964               my $mtime = mtime $args[1];
4965               $configure_deps_greatest_timestamp = $mtime
4966                 if $mtime > $configure_deps_greatest_timestamp;
4967             }
4968         }
4969       elsif ($macro eq 'LT_SUPPORTED_TAG')
4970         {
4971           $libtool_tags{$args[1]} = 1;
4972           $libtool_new_api = 1;
4973         }
4974       elsif ($macro eq '_LT_AC_TAGCONFIG')
4975         {
4976           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
4977           # We use it to detect whether tags are supported.  Our
4978           # prefered interface is LT_SUPPORTED_TAG, but it was
4979           # introduced in Libtool 1.6.
4980           if (0 == keys %libtool_tags)
4981             {
4982               # Hardcode the tags supported by Libtool 1.5.
4983               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
4984             }
4985         }
4986     }
4987
4988   $tracefh->close;
4989 }
4990
4991
4992 # &scan_autoconf_files ()
4993 # -----------------------
4994 # Check whether we use `configure.ac' or `configure.in'.
4995 # Scan it (and possibly `aclocal.m4') for interesting things.
4996 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
4997 sub scan_autoconf_files ()
4998 {
4999   # Reinitialize libsources here.  This isn't really necessary,
5000   # since we currently assume there is only one configure.ac.  But
5001   # that won't always be the case.
5002   %libsources = ();
5003
5004   # Keep track of the youngest configure dependency.
5005   $configure_deps_greatest_timestamp = mtime $configure_ac;
5006   if (-e 'aclocal.m4')
5007     {
5008       my $mtime = mtime 'aclocal.m4';
5009       $configure_deps_greatest_timestamp = $mtime
5010         if $mtime > $configure_deps_greatest_timestamp;
5011     }
5012
5013   scan_autoconf_traces ($configure_ac);
5014
5015   @configure_input_files = sort keys %make_list;
5016   # Set input and output files if not specified by user.
5017   if (! @input_files)
5018     {
5019       @input_files = @configure_input_files;
5020       %output_files = %make_list;
5021     }
5022
5023
5024   if (! $seen_init_automake)
5025     {
5026       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5027               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5028               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5029               . "and that aclocal.m4 was recently regenerated "
5030               . "(using aclocal).");
5031     }
5032   else
5033     {
5034       if (! $seen_automake_version)
5035         {
5036           if (-f 'aclocal.m4')
5037             {
5038               error ($seen_init_automake,
5039                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5040                      "an\nold Automake version.  You should recreate " .
5041                      "aclocal.m4\nwith aclocal and run automake again.\n",
5042                      # $? = 63 is used to indicate version mismatch to missing.
5043                      exit_code => 63);
5044             }
5045           else
5046             {
5047               error ($seen_init_automake,
5048                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5049                      "found,\nprobably because aclocal.m4 is missing...\n" .
5050                      "You should run aclocal to create this file, then\n" .
5051                      "run automake again.\n");
5052             }
5053         }
5054     }
5055
5056   locate_aux_dir ();
5057
5058   # Reorder @input_files so that the Makefile that distributes aux
5059   # files is processed last.  This is important because each directory
5060   # can require auxiliary scripts and we should wait until they have
5061   # been installed before distributing them.
5062
5063   # The Makefile.in that distribute the aux files is the one in
5064   # $config_aux_dir or the top-level Makefile.
5065   my $auxdirdist = is_make_dir ($config_aux_dir) ? $config_aux_dir : '.';
5066   my @new_input_files = ();
5067   while (@input_files)
5068     {
5069       my $in = pop @input_files;
5070       my @ins = split (/:/, $output_files{$in});
5071       if (dirname ($ins[0]) eq $auxdirdist)
5072         {
5073           push @new_input_files, $in;
5074           $automake_will_process_aux_dir = 1;
5075         }
5076       else
5077         {
5078           unshift @new_input_files, $in;
5079         }
5080     }
5081   @input_files = @new_input_files;
5082
5083   # If neither the auxdir/Makefile nor the ./Makefile are generated
5084   # by Automake, we won't distribute the aux files anyway.  Assume
5085   # the user know what (s)he does, and pretend we will distribute
5086   # them to disable the error in require_file_internal.
5087   $automake_will_process_aux_dir = 1 if ! is_make_dir ($auxdirdist);
5088
5089   # Look for some files we need.  Always check for these.  This
5090   # check must be done for every run, even those where we are only
5091   # looking at a subdir Makefile.  We must set relative_dir for
5092   # maybe_push_required_file to work.
5093   $relative_dir = '.';
5094   foreach my $file (keys %required_aux_file)
5095     {
5096       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5097     }
5098   err_am "`install.sh' is an anachronism; use `install-sh' instead"
5099     if -f $config_aux_dir . '/install.sh';
5100
5101   # Preserve dist_common for later.
5102   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5103
5104 }
5105
5106 ################################################################
5107
5108 # Set up for Cygnus mode.
5109 sub check_cygnus
5110 {
5111   my $cygnus = option 'cygnus';
5112   return unless $cygnus;
5113
5114   set_strictness ('foreign');
5115   set_option ('no-installinfo', $cygnus);
5116   set_option ('no-dependencies', $cygnus);
5117   set_option ('no-dist', $cygnus);
5118
5119   err_ac "`AM_MAINTAINER_MODE' required when --cygnus specified"
5120     if !$seen_maint_mode;
5121 }
5122
5123 # Do any extra checking for GNU standards.
5124 sub check_gnu_standards
5125 {
5126   if ($relative_dir eq '.')
5127     {
5128       # In top level (or only) directory.
5129       require_file ("$am_file.am", GNU,
5130                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5131
5132       # Accept one of these three licenses; default to COPYING.
5133       # Make sure we do not overwrite an existing license.
5134       my $license;
5135       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5136         {
5137           if (-f $_)
5138             {
5139               $license = $_;
5140               last;
5141             }
5142         }
5143       require_file ("$am_file.am", GNU, 'COPYING')
5144         unless $license;
5145     }
5146
5147   for my $opt ('no-installman', 'no-installinfo')
5148     {
5149       msg ('error-gnu', option $opt,
5150            "option `$opt' disallowed by GNU standards")
5151         if option $opt;
5152     }
5153 }
5154
5155 # Do any extra checking for GNITS standards.
5156 sub check_gnits_standards
5157 {
5158   if ($relative_dir eq '.')
5159     {
5160       # In top level (or only) directory.
5161       require_file ("$am_file.am", GNITS, 'THANKS');
5162     }
5163 }
5164
5165 ################################################################
5166 #
5167 # Functions to handle files of each language.
5168
5169 # Each `lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5170 # simple formula: Return value is LANG_SUBDIR if the resulting object
5171 # file should be in a subdir if the source file is, LANG_PROCESS if
5172 # file is to be dealt with, LANG_IGNORE otherwise.
5173
5174 # Much of the actual processing is handled in
5175 # handle_single_transform.  These functions exist so that
5176 # auxiliary information can be recorded for a later cleanup pass.
5177 # Note that the calls to these functions are computed, so don't bother
5178 # searching for their precise names in the source.
5179
5180 # This is just a convenience function that can be used to determine
5181 # when a subdir object should be used.
5182 sub lang_sub_obj
5183 {
5184     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5185 }
5186
5187 # Rewrite a single C source file.
5188 sub lang_c_rewrite
5189 {
5190   my ($directory, $base, $ext, $nonansi_obj, $have_per_exec_flags, $var) = @_;
5191
5192   if (option 'ansi2knr' && $base =~ /_$/)
5193     {
5194       # FIXME: include line number in error.
5195       err_am "C source file `$base.c' would be deleted by ansi2knr rules";
5196     }
5197
5198   my $r = LANG_PROCESS;
5199   if (option 'subdir-objects')
5200     {
5201       $r = LANG_SUBDIR;
5202       if ($directory && $directory ne '.')
5203         {
5204           $base = $directory . '/' . $base;
5205
5206           # libtool is always able to put the object at the proper place,
5207           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5208           err_var ($var, "compiling `$base.c' in subdir requires "
5209                    . "`AM_PROG_CC_C_O' in `$configure_ac'",
5210                    uniq_scope => US_GLOBAL,
5211                    uniq_part => 'AM_PROG_CC_C_O subdir')
5212             unless $seen_cc_c_o || $nonansi_obj eq '.lo';
5213         }
5214
5215       # In this case we already have the directory information, so
5216       # don't add it again.
5217       $de_ansi_files{$base} = '';
5218     }
5219   else
5220     {
5221       $de_ansi_files{$base} = (($directory eq '.' || $directory eq '')
5222                                ? ''
5223                                : "$directory/");
5224     }
5225
5226   if (! $seen_cc_c_o
5227       && $have_per_exec_flags
5228       && ! option 'subdir-objects'
5229       && $nonansi_obj ne '.lo')
5230     {
5231       err_var ($var, "compiling `$base.c' with per-target flags requires "
5232                . "`AM_PROG_CC_C_O' in `$configure_ac'",
5233                uniq_scope => US_GLOBAL,
5234                uniq_part => 'AM_PROG_CC_C_O per-target')
5235     }
5236
5237     return $r;
5238 }
5239
5240 # Rewrite a single C++ source file.
5241 sub lang_cxx_rewrite
5242 {
5243     return &lang_sub_obj;
5244 }
5245
5246 # Rewrite a single header file.
5247 sub lang_header_rewrite
5248 {
5249     # Header files are simply ignored.
5250     return LANG_IGNORE;
5251 }
5252
5253 # Rewrite a single yacc file.
5254 sub lang_yacc_rewrite
5255 {
5256     my ($directory, $base, $ext) = @_;
5257
5258     my $r = &lang_sub_obj;
5259     (my $newext = $ext) =~ tr/y/c/;
5260     return ($r, $newext);
5261 }
5262
5263 # Rewrite a single yacc++ file.
5264 sub lang_yaccxx_rewrite
5265 {
5266     my ($directory, $base, $ext) = @_;
5267
5268     my $r = &lang_sub_obj;
5269     (my $newext = $ext) =~ tr/y/c/;
5270     return ($r, $newext);
5271 }
5272
5273 # Rewrite a single lex file.
5274 sub lang_lex_rewrite
5275 {
5276     my ($directory, $base, $ext) = @_;
5277
5278     my $r = &lang_sub_obj;
5279     (my $newext = $ext) =~ tr/l/c/;
5280     return ($r, $newext);
5281 }
5282
5283 # Rewrite a single lex++ file.
5284 sub lang_lexxx_rewrite
5285 {
5286     my ($directory, $base, $ext) = @_;
5287
5288     my $r = &lang_sub_obj;
5289     (my $newext = $ext) =~ tr/l/c/;
5290     return ($r, $newext);
5291 }
5292
5293 # Rewrite a single assembly file.
5294 sub lang_asm_rewrite
5295 {
5296     return &lang_sub_obj;
5297 }
5298
5299 # Rewrite a single preprocessed assembly file.
5300 sub lang_cppasm_rewrite
5301 {
5302     return &lang_sub_obj;
5303 }
5304
5305 # Rewrite a single Fortran 77 file.
5306 sub lang_f77_rewrite
5307 {
5308     return LANG_PROCESS;
5309 }
5310
5311 # Rewrite a single Fortran file.
5312 sub lang_fc_rewrite
5313 {
5314     return LANG_PROCESS;
5315 }
5316
5317 # Rewrite a single preprocessed Fortran file.
5318 sub lang_ppfc_rewrite
5319 {
5320     return LANG_PROCESS;
5321 }
5322
5323 # Rewrite a single preprocessed Fortran 77 file.
5324 sub lang_ppf77_rewrite
5325 {
5326     return LANG_PROCESS;
5327 }
5328
5329 # Rewrite a single ratfor file.
5330 sub lang_ratfor_rewrite
5331 {
5332     return LANG_PROCESS;
5333 }
5334
5335 # Rewrite a single Objective C file.
5336 sub lang_objc_rewrite
5337 {
5338     return &lang_sub_obj;
5339 }
5340
5341 # Rewrite a single Java file.
5342 sub lang_java_rewrite
5343 {
5344     return LANG_SUBDIR;
5345 }
5346
5347 # The lang_X_finish functions are called after all source file
5348 # processing is done.  Each should handle defining rules for the
5349 # language, etc.  A finish function is only called if a source file of
5350 # the appropriate type has been seen.
5351
5352 sub lang_c_finish
5353 {
5354     # Push all libobjs files onto de_ansi_files.  We actually only
5355     # push files which exist in the current directory, and which are
5356     # genuine source files.
5357     foreach my $file (keys %libsources)
5358     {
5359         if ($file =~ /^(.*)\.[cly]$/ && -f "$relative_dir/$file")
5360         {
5361             $de_ansi_files{$1} = ''
5362         }
5363     }
5364
5365     if (option 'ansi2knr' && keys %de_ansi_files)
5366     {
5367         # Make all _.c files depend on their corresponding .c files.
5368         my @objects;
5369         foreach my $base (sort keys %de_ansi_files)
5370         {
5371             # Each _.c file must depend on ansi2knr; otherwise it
5372             # might be used in a parallel build before it is built.
5373             # We need to support files in the srcdir and in the build
5374             # dir (because these files might be auto-generated.  But
5375             # we can't use $< -- some makes only define $< during a
5376             # suffix rule.
5377             my $ansfile = $de_ansi_files{$base} . $base . '.c';
5378             $output_rules .= ($base . "_.c: $ansfile \$(ANSI2KNR)\n\t"
5379                               . '$(CPP) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) '
5380                               . '`if test -f $(srcdir)/' . $ansfile
5381                               . '; then echo $(srcdir)/' . $ansfile
5382                               . '; else echo ' . $ansfile . '; fi` '
5383                               . "| sed 's/^# \\([0-9]\\)/#line \\1/' "
5384                               . '| $(ANSI2KNR) > $@'
5385                               # If ansi2knr fails then we shouldn't
5386                               # create the _.c file
5387                               . " || rm -f \$\@\n");
5388             push (@objects, $base . '_.$(OBJEXT)');
5389             push (@objects, $base . '_.lo')
5390               if var ('LIBTOOL');
5391
5392             # Explicitly clean the _.c files if they are in a
5393             # subdirectory. (In the current directory they get erased
5394             # by a `rm -f *_.c' rule.)
5395             $clean_files{$base . '_.c'} = MOSTLY_CLEAN
5396               if dirname ($base) ne '.';
5397         }
5398
5399         # Make all _.o (and _.lo) files depend on ansi2knr.
5400         # Use a sneaky little hack to make it print nicely.
5401         &pretty_print_rule ('', '', @objects, ':', '$(ANSI2KNR)');
5402     }
5403 }
5404
5405 # This is a yacc helper which is called whenever we have decided to
5406 # compile a yacc file.
5407 sub lang_yacc_target_hook
5408 {
5409     my ($self, $aggregate, $output, $input, %transform) = @_;
5410
5411     my $flag = $aggregate . "_YFLAGS";
5412     my $flagvar = var $flag;
5413     my $YFLAGSvar = var 'YFLAGS';
5414     if (($flagvar && $flagvar->variable_value =~ /$DASH_D_PATTERN/o)
5415         || ($YFLAGSvar && $YFLAGSvar->variable_value =~ /$DASH_D_PATTERN/o))
5416     {
5417         (my $output_base = $output) =~ s/$KNOWN_EXTENSIONS_PATTERN$//;
5418         my $header = $output_base . '.h';
5419
5420         # Found a `-d' that applies to the compilation of this file.
5421         # Add a dependency for the generated header file, and arrange
5422         # for that file to be included in the distribution.
5423         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5424                                                   RULE_AUTOMAKE, TRUE,
5425                                                   INTERNAL))
5426           {
5427             my $condstr = $cond->subst_string;
5428             $output_rules .= ("$condstr${header}: $output\n"
5429                               # Recover from removal of $header
5430                               . "$condstr\t\@if test ! -f \$@; then \\\n"
5431                               . "$condstr\t  rm -f $output; \\\n"
5432                               . "$condstr\t  \$(MAKE) $output; \\\n"
5433                               . "$condstr\telse :; fi\n");
5434           }
5435         # Distribute the generated file, unless its .y source was
5436         # listed in a nodist_ variable.  (&handle_source_transform
5437         # will set DIST_SOURCE.)
5438         &push_dist_common ($header)
5439           if $transform{'DIST_SOURCE'};
5440
5441         # If the files are built in the build directory, then we want
5442         # to remove them with `make clean'.  If they are in srcdir
5443         # they shouldn't be touched.  However, we can't determine this
5444         # statically, and the GNU rules say that yacc/lex output files
5445         # should be removed by maintainer-clean.  So that's what we
5446         # do.
5447         $clean_files{$header} = MAINTAINER_CLEAN;
5448     }
5449     # Erase $OUTPUT on `make maintainer-clean' (by GNU standards).
5450     # See the comment above for $HEADER.
5451     $clean_files{$output} = MAINTAINER_CLEAN;
5452 }
5453
5454 # This is a lex helper which is called whenever we have decided to
5455 # compile a lex file.
5456 sub lang_lex_target_hook
5457 {
5458     my ($self, $aggregate, $output, $input) = @_;
5459     # If the files are built in the build directory, then we want to
5460     # remove them with `make clean'.  If they are in srcdir they
5461     # shouldn't be touched.  However, we can't determine this
5462     # statically, and the GNU rules say that yacc/lex output files
5463     # should be removed by maintainer-clean.  So that's what we do.
5464     $clean_files{$output} = MAINTAINER_CLEAN;
5465 }
5466
5467 # This is a helper for both lex and yacc.
5468 sub yacc_lex_finish_helper
5469 {
5470   return if defined $language_scratch{'lex-yacc-done'};
5471   $language_scratch{'lex-yacc-done'} = 1;
5472
5473   # If there is more than one distinct yacc (resp lex) source file
5474   # in a given directory, then the `ylwrap' program is required to
5475   # allow parallel builds to work correctly.  FIXME: for now, no
5476   # line number.
5477   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
5478   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
5479 }
5480
5481 sub lang_yacc_finish
5482 {
5483   return if defined $language_scratch{'yacc-done'};
5484   $language_scratch{'yacc-done'} = 1;
5485
5486   reject_var 'YACCFLAGS', "`YACCFLAGS' obsolete; use `YFLAGS' instead";
5487
5488   &yacc_lex_finish_helper
5489     if count_files_for_language ('yacc') > 1;
5490 }
5491
5492
5493 sub lang_lex_finish
5494 {
5495   return if defined $language_scratch{'lex-done'};
5496   $language_scratch{'lex-done'} = 1;
5497
5498   &yacc_lex_finish_helper
5499     if count_files_for_language ('lex') > 1;
5500 }
5501
5502
5503 # Given a hash table of linker names, pick the name that has the most
5504 # precedence.  This is lame, but something has to have global
5505 # knowledge in order to eliminate the conflict.  Add more linkers as
5506 # required.
5507 sub resolve_linker
5508 {
5509     my (%linkers) = @_;
5510
5511     foreach my $l (qw(GCJLINK CXXLINK F77LINK FCLINK OBJCLINK))
5512     {
5513         return $l if defined $linkers{$l};
5514     }
5515     return 'LINK';
5516 }
5517
5518 # Called to indicate that an extension was used.
5519 sub saw_extension
5520 {
5521     my ($ext) = @_;
5522     if (! defined $extension_seen{$ext})
5523     {
5524         $extension_seen{$ext} = 1;
5525     }
5526     else
5527     {
5528         ++$extension_seen{$ext};
5529     }
5530 }
5531
5532 # Return the number of files seen for a given language.  Knows about
5533 # special cases we care about.  FIXME: this is hideous.  We need
5534 # something that involves real language objects.  For instance yacc
5535 # and yaccxx could both derive from a common yacc class which would
5536 # know about the strange ylwrap requirement.  (Or better yet we could
5537 # just not support legacy yacc!)
5538 sub count_files_for_language
5539 {
5540     my ($name) = @_;
5541
5542     my @names;
5543     if ($name eq 'yacc' || $name eq 'yaccxx')
5544     {
5545         @names = ('yacc', 'yaccxx');
5546     }
5547     elsif ($name eq 'lex' || $name eq 'lexxx')
5548     {
5549         @names = ('lex', 'lexxx');
5550     }
5551     else
5552     {
5553         @names = ($name);
5554     }
5555
5556     my $r = 0;
5557     foreach $name (@names)
5558     {
5559         my $lang = $languages{$name};
5560         foreach my $ext (@{$lang->extensions})
5561         {
5562             $r += $extension_seen{$ext}
5563                 if defined $extension_seen{$ext};
5564         }
5565     }
5566
5567     return $r
5568 }
5569
5570 # Called to ask whether source files have been seen . If HEADERS is 1,
5571 # headers can be included.
5572 sub saw_sources_p
5573 {
5574     my ($headers) = @_;
5575
5576     # count all the sources
5577     my $count = 0;
5578     foreach my $val (values %extension_seen)
5579     {
5580         $count += $val;
5581     }
5582
5583     if (!$headers)
5584     {
5585         $count -= count_files_for_language ('header');
5586     }
5587
5588     return $count > 0;
5589 }
5590
5591
5592 # register_language (%ATTRIBUTE)
5593 # ------------------------------
5594 # Register a single language.
5595 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
5596 sub register_language (%)
5597 {
5598   my (%option) = @_;
5599
5600   # Set the defaults.
5601   $option{'ansi'} = 0
5602     unless defined $option{'ansi'};
5603   $option{'autodep'} = 'no'
5604     unless defined $option{'autodep'};
5605   $option{'linker'} = ''
5606     unless defined $option{'linker'};
5607   $option{'flags'} = []
5608     unless defined $option{'flags'};
5609   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
5610     unless defined $option{'output_extensions'};
5611   $option{'nodist_specific'} = 0
5612     unless defined $option{'nodist_specific'};
5613
5614   my $lang = new Language (%option);
5615
5616   # Fill indexes.
5617   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
5618   $languages{$lang->name} = $lang;
5619   my $link = $lang->linker;
5620   if ($link)
5621     {
5622       if (exists $link_languages{$link})
5623         {
5624           prog_error ("`$link' has different definitions in "
5625                       . $lang->name . " and " . $link_languages{$link}->name)
5626             if $lang->link ne $link_languages{$link}->link;
5627         }
5628       else
5629         {
5630           $link_languages{$link} = $lang;
5631         }
5632     }
5633
5634   # Update the pattern of known extensions.
5635   accept_extensions (@{$lang->extensions});
5636
5637   # Upate the $suffix_rule map.
5638   foreach my $suffix (@{$lang->extensions})
5639     {
5640       foreach my $dest (&{$lang->output_extensions} ($suffix))
5641         {
5642           register_suffix_rule (INTERNAL, $suffix, $dest);
5643         }
5644     }
5645 }
5646
5647 # derive_suffix ($EXT, $OBJ)
5648 # --------------------------
5649 # This function is used to find a path from a user-specified suffix $EXT
5650 # to $OBJ or to some other suffix we recognize internally, e.g. `cc'.
5651 sub derive_suffix ($$)
5652 {
5653   my ($source_ext, $obj) = @_;
5654
5655   while (! $extension_map{$source_ext}
5656          && $source_ext ne $obj
5657          && exists $suffix_rules->{$source_ext}
5658          && exists $suffix_rules->{$source_ext}{$obj})
5659     {
5660       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
5661     }
5662
5663   return $source_ext;
5664 }
5665
5666
5667 ################################################################
5668
5669 # Pretty-print something and append to output_rules.
5670 sub pretty_print_rule
5671 {
5672     $output_rules .= &makefile_wrap (@_);
5673 }
5674
5675
5676 ################################################################
5677
5678
5679 ## -------------------------------- ##
5680 ## Handling the conditional stack.  ##
5681 ## -------------------------------- ##
5682
5683
5684 # $STRING
5685 # make_conditional_string ($NEGATE, $COND)
5686 # ----------------------------------------
5687 sub make_conditional_string ($$)
5688 {
5689   my ($negate, $cond) = @_;
5690   $cond = "${cond}_TRUE"
5691     unless $cond =~ /^TRUE|FALSE$/;
5692   $cond = Automake::Condition::conditional_negate ($cond)
5693     if $negate;
5694   return $cond;
5695 }
5696
5697
5698 # $COND
5699 # cond_stack_if ($NEGATE, $COND, $WHERE)
5700 # --------------------------------------
5701 sub cond_stack_if ($$$)
5702 {
5703   my ($negate, $cond, $where) = @_;
5704
5705   error $where, "$cond does not appear in AM_CONDITIONAL"
5706     if ! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/;
5707
5708   push (@cond_stack, make_conditional_string ($negate, $cond));
5709
5710   return new Automake::Condition (@cond_stack);
5711 }
5712
5713
5714 # $COND
5715 # cond_stack_else ($NEGATE, $COND, $WHERE)
5716 # ----------------------------------------
5717 sub cond_stack_else ($$$)
5718 {
5719   my ($negate, $cond, $where) = @_;
5720
5721   if (! @cond_stack)
5722     {
5723       error $where, "else without if";
5724       return FALSE;
5725     }
5726
5727   $cond_stack[$#cond_stack] =
5728     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
5729
5730   # If $COND is given, check against it.
5731   if (defined $cond)
5732     {
5733       $cond = make_conditional_string ($negate, $cond);
5734
5735       error ($where, "else reminder ($negate$cond) incompatible with "
5736              . "current conditional: $cond_stack[$#cond_stack]")
5737         if $cond_stack[$#cond_stack] ne $cond;
5738     }
5739
5740   return new Automake::Condition (@cond_stack);
5741 }
5742
5743
5744 # $COND
5745 # cond_stack_endif ($NEGATE, $COND, $WHERE)
5746 # -----------------------------------------
5747 sub cond_stack_endif ($$$)
5748 {
5749   my ($negate, $cond, $where) = @_;
5750   my $old_cond;
5751
5752   if (! @cond_stack)
5753     {
5754       error $where, "endif without if";
5755       return TRUE;
5756     }
5757
5758   # If $COND is given, check against it.
5759   if (defined $cond)
5760     {
5761       $cond = make_conditional_string ($negate, $cond);
5762
5763       error ($where, "endif reminder ($negate$cond) incompatible with "
5764              . "current conditional: $cond_stack[$#cond_stack]")
5765         if $cond_stack[$#cond_stack] ne $cond;
5766     }
5767
5768   pop @cond_stack;
5769
5770   return new Automake::Condition (@cond_stack);
5771 }
5772
5773
5774
5775
5776
5777 ## ------------------------ ##
5778 ## Handling the variables.  ##
5779 ## ------------------------ ##
5780
5781
5782 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
5783 # -----------------------------------------------------
5784 # Like define_variable, but the value is a list, and the variable may
5785 # be defined conditionally.  The second argument is the Condition
5786 # under which the value should be defined; this should be the empty
5787 # string to define the variable unconditionally.  The third argument
5788 # is a list holding the values to use for the variable.  The value is
5789 # pretty printed in the output file.
5790 sub define_pretty_variable ($$$@)
5791 {
5792     my ($var, $cond, $where, @value) = @_;
5793
5794     if (! vardef ($var, $cond))
5795     {
5796         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
5797                                     '', $where, VAR_PRETTY);
5798         rvar ($var)->rdef ($cond)->set_seen;
5799     }
5800 }
5801
5802
5803 # define_variable ($VAR, $VALUE, $WHERE)
5804 # --------------------------------------
5805 # Define a new Automake Makefile variable VAR to VALUE, but only if
5806 # not already defined.
5807 sub define_variable ($$$)
5808 {
5809     my ($var, $value, $where) = @_;
5810     define_pretty_variable ($var, TRUE, $where, $value);
5811 }
5812
5813
5814 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
5815 # -----------------------------------------------------------
5816 # Define the $VAR which content is the list of file names composed of
5817 # a @BASENAME and the $EXTENSION.
5818 sub define_files_variable ($\@$$)
5819 {
5820   my ($var, $basename, $extension, $where) = @_;
5821   define_variable ($var,
5822                    join (' ', map { "$_.$extension" } @$basename),
5823                    $where);
5824 }
5825
5826
5827 # Like define_variable, but define a variable to be the configure
5828 # substitution by the same name.
5829 sub define_configure_variable ($)
5830 {
5831   my ($var) = @_;
5832
5833   my $pretty = VAR_ASIS;
5834   my $owner = VAR_CONFIGURE;
5835
5836   # Do not output the ANSI2KNR configure variable -- we AC_SUBST
5837   # it in protos.m4, but later redefine it elsewhere.  This is
5838   # pretty hacky.  We also don't output AMDEPBACKSLASH: it might
5839   # be subst'd by `\', which certainly would not be appreciated by
5840   # Make.
5841   if ($var eq 'ANSI2KNR' || $var eq 'AMDEPBACKSLASH')
5842     {
5843       $pretty = VAR_SILENT;
5844       $owner = VAR_AUTOMAKE;
5845     }
5846
5847   Automake::Variable::define ($var, $owner, '', TRUE, subst $var,
5848                               '', $configure_vars{$var}, $pretty);
5849 }
5850
5851
5852 # define_compiler_variable ($LANG)
5853 # --------------------------------
5854 # Define a compiler variable.  We also handle defining the `LT'
5855 # version of the command when using libtool.
5856 sub define_compiler_variable ($)
5857 {
5858     my ($lang) = @_;
5859
5860     my ($var, $value) = ($lang->compiler, $lang->compile);
5861     my $libtool_tag = '';
5862     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5863       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5864     &define_variable ($var, $value, INTERNAL);
5865     &define_variable ("LT$var",
5866                       "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) "
5867                       . "\$(LIBTOOLFLAGS) --mode=compile $value",
5868                       INTERNAL)
5869       if var ('LIBTOOL');
5870 }
5871
5872
5873 # define_linker_variable ($LANG)
5874 # ------------------------------
5875 # Define linker variables.
5876 sub define_linker_variable ($)
5877 {
5878     my ($lang) = @_;
5879
5880     my $libtool_tag = '';
5881     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5882       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5883     # CCLD = $(CC).
5884     &define_variable ($lang->lder, $lang->ld, INTERNAL);
5885     # CCLINK = $(CCLD) blah blah...
5886     &define_variable ($lang->linker,
5887                       ((var ('LIBTOOL') ?
5888                         "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) "
5889                         . "\$(LIBTOOLFLAGS) --mode=link " : '')
5890                        . $lang->link),
5891                       INTERNAL);
5892 }
5893
5894 sub define_per_target_linker_variable ($$)
5895 {
5896   my ($linker, $target) = @_;
5897
5898   # If the user wrote a custom link command, we don't define ours.
5899   return "${target}_LINK"
5900     if set_seen "${target}_LINK";
5901
5902   my $xlink = $linker ? $linker : 'LINK';
5903
5904   my $lang = $link_languages{$xlink};
5905   prog_error "Unknown language for linker variable `$xlink'"
5906     unless $lang;
5907
5908   my $link_command = $lang->link;
5909   if (var 'LIBTOOL')
5910     {
5911       my $libtool_tag = '';
5912       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5913         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5914
5915       $link_command =
5916         "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
5917         . "--mode=link " . $link_command;
5918     }
5919
5920   # Rewrite each occurrence of `AM_$flag' in the link
5921   # command into `${derived}_$flag' if it exists.
5922   my $orig_command = $link_command;
5923   my @flags = (@{$lang->flags}, 'LDFLAGS');
5924   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
5925   for my $flag (@flags)
5926     {
5927       my $val = "${target}_$flag";
5928       $link_command =~ s/\(AM_$flag\)/\($val\)/
5929         if set_seen ($val);
5930     }
5931
5932   # If the computed command is the same as the generic command, use
5933   # the command linker variable.
5934   return $lang->linker
5935     if $link_command eq $orig_command;
5936
5937   &define_variable ("${target}_LINK", $link_command, INTERNAL);
5938   return "${target}_LINK";
5939 }
5940
5941 ################################################################
5942
5943 # &check_trailing_slash ($WHERE, $LINE)
5944 # --------------------------------------
5945 # Return 1 iff $LINE ends with a slash.
5946 # Might modify $LINE.
5947 sub check_trailing_slash ($\$)
5948 {
5949   my ($where, $line) = @_;
5950
5951   # Ignore `##' lines.
5952   return 0 if $$line =~ /$IGNORE_PATTERN/o;
5953
5954   # Catch and fix a common error.
5955   msg "syntax", $where, "whitespace following trailing backslash"
5956     if $$line =~ s/\\\s+\n$/\\\n/;
5957
5958   return $$line =~ /\\$/;
5959 }
5960
5961
5962 # &read_am_file ($AMFILE, $WHERE)
5963 # -------------------------------
5964 # Read Makefile.am and set up %contents.  Simultaneously copy lines
5965 # from Makefile.am into $output_trailer, or define variables as
5966 # appropriate.  NOTE we put rules in the trailer section.  We want
5967 # user rules to come after our generated stuff.
5968 sub read_am_file ($$)
5969 {
5970     my ($amfile, $where) = @_;
5971
5972     my $am_file = new Automake::XFile ("< $amfile");
5973     verb "reading $amfile";
5974
5975     # Keep track of the youngest output dependency.
5976     my $mtime = mtime $amfile;
5977     $output_deps_greatest_timestamp = $mtime
5978       if $mtime > $output_deps_greatest_timestamp;
5979
5980     my $spacing = '';
5981     my $comment = '';
5982     my $blank = 0;
5983     my $saw_bk = 0;
5984     my $var_look = VAR_ASIS;
5985
5986     use constant IN_VAR_DEF => 0;
5987     use constant IN_RULE_DEF => 1;
5988     use constant IN_COMMENT => 2;
5989     my $prev_state = IN_RULE_DEF;
5990
5991     while ($_ = $am_file->getline)
5992     {
5993         $where->set ("$amfile:$.");
5994         if (/$IGNORE_PATTERN/o)
5995         {
5996             # Merely delete comments beginning with two hashes.
5997         }
5998         elsif (/$WHITE_PATTERN/o)
5999         {
6000             error $where, "blank line following trailing backslash"
6001               if $saw_bk;
6002             # Stick a single white line before the incoming macro or rule.
6003             $spacing = "\n";
6004             $blank = 1;
6005             # Flush all comments seen so far.
6006             if ($comment ne '')
6007             {
6008                 $output_vars .= $comment;
6009                 $comment = '';
6010             }
6011         }
6012         elsif (/$COMMENT_PATTERN/o)
6013         {
6014             # Stick comments before the incoming macro or rule.  Make
6015             # sure a blank line precedes the first block of comments.
6016             $spacing = "\n" unless $blank;
6017             $blank = 1;
6018             $comment .= $spacing . $_;
6019             $spacing = '';
6020             $prev_state = IN_COMMENT;
6021         }
6022         else
6023         {
6024             last;
6025         }
6026         $saw_bk = check_trailing_slash ($where, $_);
6027     }
6028
6029     # We save the conditional stack on entry, and then check to make
6030     # sure it is the same on exit.  This lets us conditionally include
6031     # other files.
6032     my @saved_cond_stack = @cond_stack;
6033     my $cond = new Automake::Condition (@cond_stack);
6034
6035     my $last_var_name = '';
6036     my $last_var_type = '';
6037     my $last_var_value = '';
6038     my $last_where;
6039     # FIXME: shouldn't use $_ in this loop; it is too big.
6040     while ($_)
6041     {
6042         $where->set ("$amfile:$.");
6043
6044         # Make sure the line is \n-terminated.
6045         chomp;
6046         $_ .= "\n";
6047
6048         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6049         # used by users.  @MAINT@ is an anachronism now.
6050         $_ =~ s/\@MAINT\@//g
6051             unless $seen_maint_mode;
6052
6053         my $new_saw_bk = check_trailing_slash ($where, $_);
6054
6055         if (/$IGNORE_PATTERN/o)
6056         {
6057             # Merely delete comments beginning with two hashes.
6058
6059             # Keep any backslash from the previous line.
6060             $new_saw_bk = $saw_bk;
6061         }
6062         elsif (/$WHITE_PATTERN/o)
6063         {
6064             # Stick a single white line before the incoming macro or rule.
6065             $spacing = "\n";
6066             error $where, "blank line following trailing backslash"
6067               if $saw_bk;
6068         }
6069         elsif (/$COMMENT_PATTERN/o)
6070         {
6071             error $where, "comment following trailing backslash"
6072               if $saw_bk && $comment eq '';
6073
6074             # Stick comments before the incoming macro or rule.
6075             $comment .= $spacing . $_;
6076             $spacing = '';
6077             $prev_state = IN_COMMENT;
6078         }
6079         elsif ($saw_bk)
6080         {
6081             if ($prev_state == IN_RULE_DEF)
6082             {
6083               my $cond = new Automake::Condition @cond_stack;
6084               $output_trailer .= $cond->subst_string;
6085               $output_trailer .= $_;
6086             }
6087             elsif ($prev_state == IN_COMMENT)
6088             {
6089                 # If the line doesn't start with a `#', add it.
6090                 # We do this because a continued comment like
6091                 #   # A = foo \
6092                 #         bar \
6093                 #         baz
6094                 # is not portable.  BSD make doesn't honor
6095                 # escaped newlines in comments.
6096                 s/^#?/#/;
6097                 $comment .= $spacing . $_;
6098             }
6099             else # $prev_state == IN_VAR_DEF
6100             {
6101               $last_var_value .= ' '
6102                 unless $last_var_value =~ /\s$/;
6103               $last_var_value .= $_;
6104
6105               if (!/\\$/)
6106                 {
6107                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6108                                               $last_var_type, $cond,
6109                                               $last_var_value, $comment,
6110                                               $last_where, VAR_ASIS)
6111                     if $cond != FALSE;
6112                   $comment = $spacing = '';
6113                 }
6114             }
6115         }
6116
6117         elsif (/$IF_PATTERN/o)
6118           {
6119             $cond = cond_stack_if ($1, $2, $where);
6120           }
6121         elsif (/$ELSE_PATTERN/o)
6122           {
6123             $cond = cond_stack_else ($1, $2, $where);
6124           }
6125         elsif (/$ENDIF_PATTERN/o)
6126           {
6127             $cond = cond_stack_endif ($1, $2, $where);
6128           }
6129
6130         elsif (/$RULE_PATTERN/o)
6131         {
6132             # Found a rule.
6133             $prev_state = IN_RULE_DEF;
6134
6135             # For now we have to output all definitions of user rules
6136             # and can't diagnose duplicates (see the comment in
6137             # rule_define). So we go on and ignore the return value.
6138             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6139
6140             check_variable_expansions ($_, $where);
6141
6142             $output_trailer .= $comment . $spacing;
6143             my $cond = new Automake::Condition @cond_stack;
6144             $output_trailer .= $cond->subst_string;
6145             $output_trailer .= $_;
6146             $comment = $spacing = '';
6147         }
6148         elsif (/$ASSIGNMENT_PATTERN/o)
6149         {
6150             # Found a macro definition.
6151             $prev_state = IN_VAR_DEF;
6152             $last_var_name = $1;
6153             $last_var_type = $2;
6154             $last_var_value = $3;
6155             $last_where = $where->clone;
6156             if ($3 ne '' && substr ($3, -1) eq "\\")
6157               {
6158                 # We preserve the `\' because otherwise the long lines
6159                 # that are generated will be truncated by broken
6160                 # `sed's.
6161                 $last_var_value = $3 . "\n";
6162               }
6163             # Normally we try to output variable definitions in the
6164             # same format they were input.  However, POSIX compliant
6165             # systems are not required to support lines longer than
6166             # 2048 bytes (most notably, some sed implementation are
6167             # limited to 4000 bytes, and sed is used by config.status
6168             # to rewrite Makefile.in into Makefile).  Moreover nobody
6169             # would really write such long lines by hand since it is
6170             # hardly maintainable.  So if a line is longer that 1000
6171             # bytes (an arbitrary limit), assume it has been
6172             # automatically generated by some tools, and flatten the
6173             # variable definition.  Otherwise, keep the variable as it
6174             # as been input.
6175             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6176
6177             if (!/\\$/)
6178               {
6179                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6180                                             $last_var_type, $cond,
6181                                             $last_var_value, $comment,
6182                                             $last_where, $var_look)
6183                   if $cond != FALSE;
6184                 $comment = $spacing = '';
6185                 $var_look = VAR_ASIS;
6186               }
6187         }
6188         elsif (/$INCLUDE_PATTERN/o)
6189         {
6190             my $path = $1;
6191
6192             if ($path =~ s/^\$\(top_srcdir\)\///)
6193               {
6194                 push (@include_stack, "\$\(top_srcdir\)/$path");
6195                 # Distribute any included file.
6196
6197                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6198                 # otherwise OSF make will implicitly copy the included
6199                 # file in the build tree during `make distdir' to satisfy
6200                 # the dependency.
6201                 # (subdircond2.test and subdircond3.test will fail.)
6202                 push_dist_common ("\$\(top_srcdir\)/$path");
6203               }
6204             else
6205               {
6206                 $path =~ s/\$\(srcdir\)\///;
6207                 push (@include_stack, "\$\(srcdir\)/$path");
6208                 # Always use the $(srcdir) prefix in DIST_COMMON,
6209                 # otherwise OSF make will implicitly copy the included
6210                 # file in the build tree during `make distdir' to satisfy
6211                 # the dependency.
6212                 # (subdircond2.test and subdircond3.test will fail.)
6213                 push_dist_common ("\$\(srcdir\)/$path");
6214                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6215               }
6216             $where->push_context ("`$path' included from here");
6217             &read_am_file ($path, $where);
6218             $where->pop_context;
6219         }
6220         else
6221         {
6222             # This isn't an error; it is probably a continued rule.
6223             # In fact, this is what we assume.
6224             $prev_state = IN_RULE_DEF;
6225             check_variable_expansions ($_, $where);
6226             $output_trailer .= $comment . $spacing;
6227             my $cond = new Automake::Condition @cond_stack;
6228             $output_trailer .= $cond->subst_string;
6229             $output_trailer .= $_;
6230             $comment = $spacing = '';
6231             error $where, "`#' comment at start of rule is unportable"
6232               if $_ =~ /^\t\s*\#/;
6233         }
6234
6235         $saw_bk = $new_saw_bk;
6236         $_ = $am_file->getline;
6237     }
6238
6239     $output_trailer .= $comment;
6240
6241     error ($where, "trailing backslash on last line")
6242       if $saw_bk;
6243
6244     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6245                     : "too many conditionals closed in include file"))
6246       if "@saved_cond_stack" ne "@cond_stack";
6247 }
6248
6249
6250 # define_standard_variables ()
6251 # ----------------------------
6252 # A helper for read_main_am_file which initializes configure variables
6253 # and variables from header-vars.am.
6254 sub define_standard_variables
6255 {
6256   my $saved_output_vars = $output_vars;
6257   my ($comments, undef, $rules) =
6258     file_contents_internal (1, "$libdir/am/header-vars.am",
6259                             new Automake::Location);
6260
6261   foreach my $var (sort keys %configure_vars)
6262     {
6263       &define_configure_variable ($var);
6264     }
6265
6266   $output_vars .= $comments . $rules;
6267 }
6268
6269 # Read main am file.
6270 sub read_main_am_file
6271 {
6272     my ($amfile) = @_;
6273
6274     # This supports the strange variable tricks we are about to play.
6275     prog_error (macros_dump () . "variable defined before read_main_am_file")
6276       if (scalar (variables) > 0);
6277
6278     # Generate copyright header for generated Makefile.in.
6279     # We do discard the output of predefined variables, handled below.
6280     $output_vars = ("# $in_file_name generated by automake "
6281                    . $VERSION . " from $am_file_name.\n");
6282     $output_vars .= '# ' . subst ('configure_input') . "\n";
6283     $output_vars .= $gen_copyright;
6284
6285     # We want to predefine as many variables as possible.  This lets
6286     # the user set them with `+=' in Makefile.am.
6287     &define_standard_variables;
6288
6289     # Read user file, which might override some of our values.
6290     &read_am_file ($amfile, new Automake::Location);
6291 }
6292
6293
6294
6295 ################################################################
6296
6297 # $FLATTENED
6298 # &flatten ($STRING)
6299 # ------------------
6300 # Flatten the $STRING and return the result.
6301 sub flatten
6302 {
6303   $_ = shift;
6304
6305   s/\\\n//somg;
6306   s/\s+/ /g;
6307   s/^ //;
6308   s/ $//;
6309
6310   return $_;
6311 }
6312
6313 # transform($TOKEN, \%PAIRS)
6314 # ==========================
6315 # If ($TOKEN, $VAL) is in %PAIRS:
6316 #   - replaces %$TOKEN% with $VAL,
6317 #   - enables/disables ?$TOKEN? and ?!$TOKEN?,
6318 #   - replaces %?$TOKEN% with TRUE or FALSE.
6319 sub transform($$)
6320 {
6321   my ($token, $transform) = @_;
6322
6323   if (substr ($token, 0, 1) eq '%')
6324     {
6325       my $cond = (substr ($token, 1, 1) eq '?') ? 1 : 0;
6326       $token = substr ($token, 1 + $cond, -1);
6327       my $val = $transform->{$token};
6328       prog_error "Unknown %token% `$token'" unless defined $val;
6329       if ($cond)
6330         {
6331           return $val ? 'TRUE' : 'FALSE';
6332         }
6333       else
6334         {
6335           return $val;
6336         }
6337     }
6338   # Now $token is '?xxx?' or '?!xxx?'.
6339   my $neg = (substr ($token, 1, 1) eq '!') ? 1 : 0;
6340   $token = substr ($token, 1 + $neg, -1);
6341   my $val = $transform->{$token};
6342   prog_error "Unknown ?token? `$token' (neg = $neg)" unless defined $val;
6343   return (!!$val == $neg) ? '##%' : '';
6344 }
6345
6346 # @PARAGRAPHS
6347 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6348 # ------------------------------------------
6349 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6350 # paragraphs.
6351 sub make_paragraphs ($%)
6352 {
6353   my ($file, %transform) = @_;
6354
6355   # Complete %transform with global options.
6356   # Note that %transform goes last, so it overrides global options.
6357   %transform = ('CYGNUS'      => !! option 'cygnus',
6358                  'MAINTAINER-MODE'
6359                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6360
6361                  'BZIP2'       => !! option 'dist-bzip2',
6362                  'COMPRESS'    => !! option 'dist-tarZ',
6363                  'GZIP'        =>  ! option 'no-dist-gzip',
6364                  'SHAR'        => !! option 'dist-shar',
6365                  'ZIP'         => !! option 'dist-zip',
6366
6367                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6368                  'INSTALL-MAN'  =>  ! option 'no-installman',
6369                  'CK-NEWS'      => !! option 'check-news',
6370
6371                  'SUBDIRS'      => !! var ('SUBDIRS'),
6372                  'TOPDIR_P'     => $relative_dir eq '.',
6373
6374                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6375                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6376                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6377
6378                  'LIBTOOL'      => !! var ('LIBTOOL'),
6379                  'NONLIBTOOL'   => 1,
6380                  'FIRST'        => ! $transformed_files{$file},
6381                 %transform);
6382
6383   $transformed_files{$file} = 1;
6384   $_ = $am_file_cache{$file};
6385
6386   if (! defined $_)
6387     {
6388       verb "reading $file";
6389       # Swallow the whole file.
6390       my $fc_file = new Automake::XFile "< $file";
6391       my $saved_dollar_slash = $/;
6392       undef $/;
6393       $_ = $fc_file->getline;
6394       $/ = $saved_dollar_slash;
6395       $fc_file->close;
6396
6397       # Remove ##-comments.
6398       # Besides we don't need more than two consecutive new-lines.
6399       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6400
6401       $am_file_cache{$file} = $_;
6402     }
6403
6404   # Substitute Automake template tokens.
6405   s/(?:%\??[\w\-]+%|\?!?[\w\-]+\?)/transform($&, \%transform)/ge;
6406   # transform() may have added some ##%-comments to strip.
6407   # (we use `##%' instead of `##' so we can distinguish ##%##%##% from
6408   # ####### and do not remove the latter.)
6409   s/^[ \t]*(?:##%)+.*\n//gm;
6410
6411   # Split at unescaped new lines.
6412   my @lines = split (/(?<!\\)\n/, $_);
6413   my @res;
6414
6415   while (defined ($_ = shift @lines))
6416     {
6417       my $paragraph = $_;
6418       # If we are a rule, eat as long as we start with a tab.
6419       if (/$RULE_PATTERN/smo)
6420         {
6421           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
6422             {
6423               $paragraph .= "\n$_";
6424             }
6425           unshift (@lines, $_);
6426         }
6427
6428       # If we are a comments, eat as much comments as you can.
6429       elsif (/$COMMENT_PATTERN/smo)
6430         {
6431           while (defined ($_ = shift @lines)
6432                  && $_ =~ /$COMMENT_PATTERN/smo)
6433             {
6434               $paragraph .= "\n$_";
6435             }
6436           unshift (@lines, $_);
6437         }
6438
6439       push @res, $paragraph;
6440     }
6441
6442   return @res;
6443 }
6444
6445
6446
6447 # ($COMMENT, $VARIABLES, $RULES)
6448 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
6449 # -------------------------------------------------------------
6450 # Return contents of a file from $libdir/am, automatically skipping
6451 # macros or rules which are already known. $IS_AM iff the caller is
6452 # reading an Automake file (as opposed to the user's Makefile.am).
6453 sub file_contents_internal ($$$%)
6454 {
6455     my ($is_am, $file, $where, %transform) = @_;
6456
6457     $where->set ($file);
6458
6459     my $result_vars = '';
6460     my $result_rules = '';
6461     my $comment = '';
6462     my $spacing = '';
6463
6464     # The following flags are used to track rules spanning across
6465     # multiple paragraphs.
6466     my $is_rule = 0;            # 1 if we are processing a rule.
6467     my $discard_rule = 0;       # 1 if the current rule should not be output.
6468
6469     # We save the conditional stack on entry, and then check to make
6470     # sure it is the same on exit.  This lets us conditionally include
6471     # other files.
6472     my @saved_cond_stack = @cond_stack;
6473     my $cond = new Automake::Condition (@cond_stack);
6474
6475     foreach (make_paragraphs ($file, %transform))
6476     {
6477         # FIXME: no line number available.
6478         $where->set ($file);
6479
6480         # Sanity checks.
6481         error $where, "blank line following trailing backslash:\n$_"
6482           if /\\$/;
6483         error $where, "comment following trailing backslash:\n$_"
6484           if /\\#/;
6485
6486         if (/^$/)
6487         {
6488             $is_rule = 0;
6489             # Stick empty line before the incoming macro or rule.
6490             $spacing = "\n";
6491         }
6492         elsif (/$COMMENT_PATTERN/mso)
6493         {
6494             $is_rule = 0;
6495             # Stick comments before the incoming macro or rule.
6496             $comment = "$_\n";
6497         }
6498
6499         # Handle inclusion of other files.
6500         elsif (/$INCLUDE_PATTERN/o)
6501         {
6502             if ($cond != FALSE)
6503               {
6504                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
6505                 $where->push_context ("`$file' included from here");
6506                 # N-ary `.=' fails.
6507                 my ($com, $vars, $rules)
6508                   = file_contents_internal ($is_am, $file, $where, %transform);
6509                 $where->pop_context;
6510                 $comment .= $com;
6511                 $result_vars .= $vars;
6512                 $result_rules .= $rules;
6513               }
6514         }
6515
6516         # Handling the conditionals.
6517         elsif (/$IF_PATTERN/o)
6518           {
6519             $cond = cond_stack_if ($1, $2, $file);
6520           }
6521         elsif (/$ELSE_PATTERN/o)
6522           {
6523             $cond = cond_stack_else ($1, $2, $file);
6524           }
6525         elsif (/$ENDIF_PATTERN/o)
6526           {
6527             $cond = cond_stack_endif ($1, $2, $file);
6528           }
6529
6530         # Handling rules.
6531         elsif (/$RULE_PATTERN/mso)
6532         {
6533           $is_rule = 1;
6534           $discard_rule = 0;
6535           # Separate relationship from optional actions: the first
6536           # `new-line tab" not preceded by backslash (continuation
6537           # line).
6538           my $paragraph = $_;
6539           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
6540           my ($relationship, $actions) = ($1, $2 || '');
6541
6542           # Separate targets from dependencies: the first colon.
6543           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
6544           my ($targets, $dependencies) = ($1, $2);
6545           # Remove the escaped new lines.
6546           # I don't know why, but I have to use a tmp $flat_deps.
6547           my $flat_deps = &flatten ($dependencies);
6548           my @deps = split (' ', $flat_deps);
6549
6550           foreach (split (' ' , $targets))
6551             {
6552               # FIXME: 1. We are not robust to people defining several targets
6553               # at once, only some of them being in %dependencies.  The
6554               # actions from the targets in %dependencies are usually generated
6555               # from the content of %actions, but if some targets in $targets
6556               # are not in %dependencies the ELSE branch will output
6557               # a rule for all $targets (i.e. the targets which are both
6558               # in %dependencies and $targets will have two rules).
6559
6560               # FIXME: 2. The logic here is not able to output a
6561               # multi-paragraph rule several time (e.g. for each condition
6562               # it is defined for) because it only knows the first paragraph.
6563
6564               # FIXME: 3. We are not robust to people defining a subset
6565               # of a previously defined "multiple-target" rule.  E.g.
6566               # `foo:' after `foo bar:'.
6567
6568               # Output only if not in FALSE.
6569               if (defined $dependencies{$_} && $cond != FALSE)
6570                 {
6571                   &depend ($_, @deps);
6572                   if ($actions{$_})
6573                     {
6574                       $actions{$_} .= "\n$actions" if $actions;
6575                     }
6576                   else
6577                     {
6578                       $actions{$_} = $actions;
6579                     }
6580                 }
6581               else
6582                 {
6583                   # Free-lance dependency.  Output the rule for all the
6584                   # targets instead of one by one.
6585                   my @undefined_conds =
6586                     Automake::Rule::define ($targets, $file,
6587                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
6588                                             $cond, $where);
6589                   for my $undefined_cond (@undefined_conds)
6590                     {
6591                       my $condparagraph = $paragraph;
6592                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
6593                       $result_rules .= "$spacing$comment$condparagraph\n";
6594                     }
6595                   if (scalar @undefined_conds == 0)
6596                     {
6597                       # Remember to discard next paragraphs
6598                       # if they belong to this rule.
6599                       # (but see also FIXME: #2 above.)
6600                       $discard_rule = 1;
6601                     }
6602                   $comment = $spacing = '';
6603                   last;
6604                 }
6605             }
6606         }
6607
6608         elsif (/$ASSIGNMENT_PATTERN/mso)
6609         {
6610             my ($var, $type, $val) = ($1, $2, $3);
6611             error $where, "variable `$var' with trailing backslash"
6612               if /\\$/;
6613
6614             $is_rule = 0;
6615
6616             Automake::Variable::define ($var,
6617                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
6618                                         $type, $cond, $val, $comment, $where,
6619                                         VAR_ASIS)
6620               if $cond != FALSE;
6621
6622             $comment = $spacing = '';
6623         }
6624         else
6625         {
6626             # This isn't an error; it is probably some tokens which
6627             # configure is supposed to replace, such as `@SET-MAKE@',
6628             # or some part of a rule cut by an if/endif.
6629             if (! $cond->false && ! ($is_rule && $discard_rule))
6630               {
6631                 s/^/$cond->subst_string/gme;
6632                 $result_rules .= "$spacing$comment$_\n";
6633               }
6634             $comment = $spacing = '';
6635         }
6636     }
6637
6638     error ($where, @cond_stack ?
6639            "unterminated conditionals: @cond_stack" :
6640            "too many conditionals closed in include file")
6641       if "@saved_cond_stack" ne "@cond_stack";
6642
6643     return ($comment, $result_vars, $result_rules);
6644 }
6645
6646
6647 # $CONTENTS
6648 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
6649 # ------------------------------------------------
6650 # Return contents of a file from $libdir/am, automatically skipping
6651 # macros or rules which are already known.
6652 sub file_contents ($$%)
6653 {
6654     my ($basename, $where, %transform) = @_;
6655     my ($comments, $variables, $rules) =
6656       file_contents_internal (1, "$libdir/am/$basename.am", $where,
6657                               %transform);
6658     return "$comments$variables$rules";
6659 }
6660
6661
6662 # &append_exeext ($MACRO)
6663 # -----------------------
6664 # Macro is an Automake magic macro which primary is PROGRAMS, e.g.
6665 # bin_PROGRAMS.  Make sure these programs have $(EXEEXT) appended.
6666 sub append_exeext ($)
6667 {
6668   my ($macro) = @_;
6669
6670   prog_error "append_exeext ($macro)"
6671     unless $macro =~ /_PROGRAMS$/;
6672
6673   transform_variable_recursively
6674     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
6675      sub {
6676        my ($subvar, $val, $cond, $full_cond) = @_;
6677        # Append $(EXEEXT) unless the user did it already, or it's a
6678        # @substitution@.
6679        $val .= '$(EXEEXT)' unless $val =~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/;
6680        return $val;
6681      });
6682 }
6683
6684
6685 # @PREFIX
6686 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
6687 # -----------------------------------------------------
6688 # Find all variable prefixes that are used for install directories.  A
6689 # prefix `zar' qualifies iff:
6690 #
6691 # * `zardir' is a variable.
6692 # * `zar_PRIMARY' is a variable.
6693 #
6694 # As a side effect, it looks for misspellings.  It is an error to have
6695 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
6696 # "bin_PROGRAMS".  However, unusual prefixes are allowed if a variable
6697 # of the same name (with "dir" appended) exists.  For instance, if the
6698 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
6699 # This is to provide a little extra flexibility in those cases which
6700 # need it.
6701 sub am_primary_prefixes ($$@)
6702 {
6703   my ($primary, $can_dist, @prefixes) = @_;
6704
6705   local $_;
6706   my %valid = map { $_ => 0 } @prefixes;
6707   $valid{'EXTRA'} = 0;
6708   foreach my $var (variables $primary)
6709     {
6710       # Automake is allowed to define variables that look like primaries
6711       # but which aren't.  E.g. INSTALL_sh_DATA.
6712       # Autoconf can also define variables like INSTALL_DATA, so
6713       # ignore all configure variables (at least those which are not
6714       # redefined in Makefile.am).
6715       # FIXME: We should make sure that these variables are not
6716       # conditionally defined (or else adjust the condition below).
6717       my $def = $var->def (TRUE);
6718       next if $def && $def->owner != VAR_MAKEFILE;
6719
6720       my $varname = $var->name;
6721
6722       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
6723         {
6724           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
6725           if ($dist ne '' && ! $can_dist)
6726             {
6727               err_var ($var,
6728                        "invalid variable `$varname': `dist' is forbidden");
6729             }
6730           # Standard directories must be explicitly allowed.
6731           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
6732             {
6733               err_var ($var,
6734                        "`${X}dir' is not a legitimate directory " .
6735                        "for `$primary'");
6736             }
6737           # A not explicitly valid directory is allowed if Xdir is defined.
6738           elsif (! defined $valid{$X} &&
6739                  $var->requires_variables ("`$varname' is used", "${X}dir"))
6740             {
6741               # Nothing to do.  Any error message has been output
6742               # by $var->requires_variables.
6743             }
6744           else
6745             {
6746               # Ensure all extended prefixes are actually used.
6747               $valid{"$base$dist$X"} = 1;
6748             }
6749         }
6750       else
6751         {
6752           prog_error "unexpected variable name: $varname";
6753         }
6754     }
6755
6756   # Return only those which are actually defined.
6757   return sort grep { var ($_ . '_' . $primary) } keys %valid;
6758 }
6759
6760
6761 # Handle `where_HOW' variable magic.  Does all lookups, generates
6762 # install code, and possibly generates code to define the primary
6763 # variable.  The first argument is the name of the .am file to munge,
6764 # the second argument is the primary variable (e.g. HEADERS), and all
6765 # subsequent arguments are possible installation locations.
6766 #
6767 # Returns list of [$location, $value] pairs, where
6768 # $value's are the values in all where_HOW variable, and $location
6769 # there associated location (the place here their parent variables were
6770 # defined).
6771 #
6772 # FIXME: this should be rewritten to be cleaner.  It should be broken
6773 # up into multiple functions.
6774 #
6775 # Usage is: am_install_var (OPTION..., file, HOW, where...)
6776 sub am_install_var
6777 {
6778   my (@args) = @_;
6779
6780   my $do_require = 1;
6781   my $can_dist = 0;
6782   my $default_dist = 0;
6783   while (@args)
6784     {
6785       if ($args[0] eq '-noextra')
6786         {
6787           $do_require = 0;
6788         }
6789       elsif ($args[0] eq '-candist')
6790         {
6791           $can_dist = 1;
6792         }
6793       elsif ($args[0] eq '-defaultdist')
6794         {
6795           $default_dist = 1;
6796           $can_dist = 1;
6797         }
6798       elsif ($args[0] !~ /^-/)
6799         {
6800           last;
6801         }
6802       shift (@args);
6803     }
6804
6805   my ($file, $primary, @prefix) = @args;
6806
6807   # Now that configure substitutions are allowed in where_HOW
6808   # variables, it is an error to actually define the primary.  We
6809   # allow `JAVA', as it is customarily used to mean the Java
6810   # interpreter.  This is but one of several Java hacks.  Similarly,
6811   # `PYTHON' is customarily used to mean the Python interpreter.
6812   reject_var $primary, "`$primary' is an anachronism"
6813     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
6814
6815   # Get the prefixes which are valid and actually used.
6816   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
6817
6818   # If a primary includes a configure substitution, then the EXTRA_
6819   # form is required.  Otherwise we can't properly do our job.
6820   my $require_extra;
6821
6822   my @used = ();
6823   my @result = ();
6824
6825   foreach my $X (@prefix)
6826     {
6827       my $nodir_name = $X;
6828       my $one_name = $X . '_' . $primary;
6829       my $one_var = var $one_name;
6830
6831       my $strip_subdir = 1;
6832       # If subdir prefix should be preserved, do so.
6833       if ($nodir_name =~ /^nobase_/)
6834         {
6835           $strip_subdir = 0;
6836           $nodir_name =~ s/^nobase_//;
6837         }
6838
6839       # If files should be distributed, do so.
6840       my $dist_p = 0;
6841       if ($can_dist)
6842         {
6843           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
6844                      || (! $default_dist && $nodir_name =~ /^dist_/));
6845           $nodir_name =~ s/^(dist|nodist)_//;
6846         }
6847
6848
6849       # Use the location of the currently processed variable.
6850       # We are not processing a particular condition, so pick the first
6851       # available.
6852       my $tmpcond = $one_var->conditions->one_cond;
6853       my $where = $one_var->rdef ($tmpcond)->location->clone;
6854
6855       # Append actual contents of where_PRIMARY variable to
6856       # @result, skipping @substitutions@.
6857       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
6858         {
6859           my ($loc, $value) = @$locvals;
6860           # Skip configure substitutions.
6861           if ($value =~ /^\@.*\@$/)
6862             {
6863               if ($nodir_name eq 'EXTRA')
6864                 {
6865                   error ($where,
6866                          "`$one_name' contains configure substitution, "
6867                          . "but shouldn't");
6868                 }
6869               # Check here to make sure variables defined in
6870               # configure.ac do not imply that EXTRA_PRIMARY
6871               # must be defined.
6872               elsif (! defined $configure_vars{$one_name})
6873                 {
6874                   $require_extra = $one_name
6875                     if $do_require;
6876                 }
6877             }
6878           else
6879             {
6880               push (@result, $locvals);
6881             }
6882         }
6883       # A blatant hack: we rewrite each _PROGRAMS primary to include
6884       # EXEEXT.
6885       append_exeext ($one_name)
6886         if $primary eq 'PROGRAMS';
6887       # "EXTRA" shouldn't be used when generating clean targets,
6888       # all, or install targets.  We used to warn if EXTRA_FOO was
6889       # defined uselessly, but this was annoying.
6890       next
6891         if $nodir_name eq 'EXTRA';
6892
6893       if ($nodir_name eq 'check')
6894         {
6895           push (@check, '$(' . $one_name . ')');
6896         }
6897       else
6898         {
6899           push (@used, '$(' . $one_name . ')');
6900         }
6901
6902       # Is this to be installed?
6903       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
6904
6905       # If so, with install-exec? (or install-data?).
6906       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
6907
6908       my $check_options_p = $install_p && !! option 'std-options';
6909
6910       # Use the location of the currently processed variable as context.
6911       $where->push_context ("while processing `$one_name'");
6912
6913       # The variable containing all file to distribute.
6914       my $distvar = "\$($one_name)";
6915       $distvar = shadow_unconditionally ($one_name, $where)
6916         if ($dist_p && $one_var->has_conditional_contents);
6917
6918       # Singular form of $PRIMARY.
6919       (my $one_primary = $primary) =~ s/S$//;
6920       $output_rules .= &file_contents ($file, $where,
6921                                        PRIMARY     => $primary,
6922                                        ONE_PRIMARY => $one_primary,
6923                                        DIR         => $X,
6924                                        NDIR        => $nodir_name,
6925                                        BASE        => $strip_subdir,
6926
6927                                        EXEC      => $exec_p,
6928                                        INSTALL   => $install_p,
6929                                        DIST      => $dist_p,
6930                                        DISTVAR   => $distvar,
6931                                        'CK-OPTS' => $check_options_p);
6932     }
6933
6934   # The JAVA variable is used as the name of the Java interpreter.
6935   # The PYTHON variable is used as the name of the Python interpreter.
6936   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
6937     {
6938       # Define it.
6939       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
6940       $output_vars .= "\n";
6941     }
6942
6943   err_var ($require_extra,
6944            "`$require_extra' contains configure substitution,\n"
6945            . "but `EXTRA_$primary' not defined")
6946     if ($require_extra && ! var ('EXTRA_' . $primary));
6947
6948   # Push here because PRIMARY might be configure time determined.
6949   push (@all, '$(' . $primary . ')')
6950     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
6951
6952   # Make the result unique.  This lets the user use conditionals in
6953   # a natural way, but still lets us program lazily -- we don't have
6954   # to worry about handling a particular object more than once.
6955   # We will keep only one location per object.
6956   my %result = ();
6957   for my $pair (@result)
6958     {
6959       my ($loc, $val) = @$pair;
6960       $result{$val} = $loc;
6961     }
6962   my @l = sort keys %result;
6963   return map { [$result{$_}->clone, $_] } @l;
6964 }
6965
6966
6967 ################################################################
6968
6969 # Each key in this hash is the name of a directory holding a
6970 # Makefile.in.  These variables are local to `is_make_dir'.
6971 my %make_dirs = ();
6972 my $make_dirs_set = 0;
6973
6974 sub is_make_dir
6975 {
6976     my ($dir) = @_;
6977     if (! $make_dirs_set)
6978     {
6979         foreach my $iter (@configure_input_files)
6980         {
6981             $make_dirs{dirname ($iter)} = 1;
6982         }
6983         # We also want to notice Makefile.in's.
6984         foreach my $iter (@other_input_files)
6985         {
6986             if ($iter =~ /Makefile\.in$/)
6987             {
6988                 $make_dirs{dirname ($iter)} = 1;
6989             }
6990         }
6991         $make_dirs_set = 1;
6992     }
6993     return defined $make_dirs{$dir};
6994 }
6995
6996 ################################################################
6997
6998 # Find the aux dir.  This should match the algorithm used by
6999 # ./configure. (See the Autoconf documentation for for
7000 # AC_CONFIG_AUX_DIR.)
7001 sub locate_aux_dir ()
7002 {
7003   if (! $config_aux_dir_set_in_configure_ac)
7004     {
7005       # The default auxiliary directory is the first
7006       # of ., .., or ../.. that contains install-sh.
7007       # Assume . if install-sh doesn't exist yet.
7008       for my $dir (qw (. .. ../..))
7009         {
7010           if (-f "$dir/install-sh")
7011             {
7012               $config_aux_dir = $dir;
7013               last;
7014             }
7015         }
7016       $config_aux_dir = '.' unless $config_aux_dir;
7017     }
7018   # Avoid unsightly '/.'s.
7019   $am_config_aux_dir =
7020     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7021   $am_config_aux_dir =~ s,/*$,,;
7022 }
7023
7024
7025 # &maybe_push_required_file ($DIR, $FILE, $FULLFILE)
7026 # --------------------------------------------------
7027 # See if we want to push this file onto dist_common.  This function
7028 # encodes the rules for deciding when to do so.
7029 sub maybe_push_required_file
7030 {
7031   my ($dir, $file, $fullfile) = @_;
7032
7033   if ($dir eq $relative_dir)
7034     {
7035       push_dist_common ($file);
7036       return 1;
7037     }
7038   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7039     {
7040       # If we are doing the topmost directory, and the file is in a
7041       # subdir which does not have a Makefile, then we distribute it
7042       # here.
7043
7044       # If a required file is above the source tree, it is important
7045       # to prefix it with `$(srcdir)' so that no VPATH search is
7046       # performed.  Otherwise problems occur with Make implementations
7047       # that rewrite and simplify rules whose dependencies are found in a
7048       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7049       #
7050       #   % cat Makefile
7051       #   VPATH = sub
7052       #   distdir: ../a
7053       #           echo ../a
7054       #   % ls
7055       #   Makefile a
7056       #   % make
7057       #   echo a
7058       #   a
7059       #
7060       # Dependency `../a' was found in `sub/../a', but this make
7061       # implementation simplified it as `a'.  (Note that the sub/
7062       # directory does not even exist.)
7063       #
7064       # This kind of VPATH rewriting seems hard to cancel.  The
7065       # distdir.am hack against VPATH rewriting works only when no
7066       # simplification is done, i.e., for dependencies which are in
7067       # subdirectories, not in enclosing directories.  Hence, in
7068       # the latter case we use a full path to make sure no VPATH
7069       # search occurs.
7070       $fullfile = '$(srcdir)/' . $fullfile
7071         if $dir =~ m,^\.\.(?:$|/),;
7072
7073       push_dist_common ($fullfile);
7074       return 1;
7075     }
7076   return 0;
7077 }
7078
7079
7080 # If a file name appears as a key in this hash, then it has already
7081 # been checked for.  This allows us not to report the same error more
7082 # than once.
7083 my %required_file_not_found = ();
7084
7085 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, @FILES)
7086 # --------------------------------------------------------------
7087 # Verify that the file must exist in $DIRECTORY, or install it.
7088 # $MYSTRICT is the strictness level at which this file becomes required.
7089 sub require_file_internal ($$$@)
7090 {
7091   my ($where, $mystrict, $dir, @files) = @_;
7092
7093   foreach my $file (@files)
7094     {
7095       my $fullfile = "$dir/$file";
7096       my $found_it = 0;
7097       my $dangling_sym = 0;
7098
7099       if (-l $fullfile && ! -f $fullfile)
7100         {
7101           $dangling_sym = 1;
7102         }
7103       elsif (dir_has_case_matching_file ($dir, $file))
7104         {
7105           $found_it = 1;
7106           maybe_push_required_file ($dir, $file, $fullfile);
7107         }
7108
7109       # `--force-missing' only has an effect if `--add-missing' is
7110       # specified.
7111       if ($found_it && (! $add_missing || ! $force_missing))
7112         {
7113           next;
7114         }
7115       else
7116         {
7117           # If we've already looked for it, we're done.  You might
7118           # wonder why we don't do this before searching for the
7119           # file.  If we do that, then something like
7120           # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7121           # DIST_COMMON.
7122           if (! $found_it)
7123             {
7124               next if defined $required_file_not_found{$fullfile};
7125               $required_file_not_found{$fullfile} = 1;
7126             }
7127
7128           if ($strictness >= $mystrict)
7129             {
7130               if ($dangling_sym && $add_missing)
7131                 {
7132                   unlink ($fullfile);
7133                 }
7134
7135               my $trailer = '';
7136               my $suppress = 0;
7137
7138               # Only install missing files according to our desired
7139               # strictness level.
7140               my $message = "required file `$fullfile' not found";
7141               if ($add_missing)
7142                 {
7143                   if (-f ("$libdir/$file"))
7144                     {
7145                       $suppress = 1;
7146
7147                       # Install the missing file.  Symlink if we
7148                       # can, copy if we must.  Note: delete the file
7149                       # first, in case it is a dangling symlink.
7150                       $message = "installing `$fullfile'";
7151                       # Windows Perl will hang if we try to delete a
7152                       # file that doesn't exist.
7153                       unlink ($fullfile) if -f $fullfile;
7154                       if ($symlink_exists && ! $copy_missing)
7155                         {
7156                           if (! symlink ("$libdir/$file", $fullfile))
7157                             {
7158                               $suppress = 0;
7159                               $trailer = "; error while making link: $!";
7160                             }
7161                         }
7162                       elsif (system ('cp', "$libdir/$file", $fullfile))
7163                         {
7164                           $suppress = 0;
7165                           $trailer = "\n    error while copying";
7166                         }
7167                       reset_dir_cache ($dir);
7168                     }
7169
7170                   if (! maybe_push_required_file (dirname ($fullfile),
7171                                                   $file, $fullfile))
7172                     {
7173                       if (! $found_it && ! $automake_will_process_aux_dir)
7174                         {
7175                           # We have added the file but could not push it
7176                           # into DIST_COMMON, probably because this is
7177                           # an auxiliary file and we are not processing
7178                           # the top level Makefile.  Furthermore Automake
7179                           # hasn't been asked to create the Makefile.in
7180                           # that distribute the aux dir files.
7181                           error ($where, 'Please make a full run of automake'
7182                                  . " so $fullfile gets distributed.");
7183                         }
7184                     }
7185                 }
7186
7187               # If --force-missing was specified, and we have
7188               # actually found the file, then do nothing.
7189               next
7190                 if $found_it && $force_missing;
7191
7192               # If we couldn' install the file, but it is a target in
7193               # the Makefile, don't print anything.  This allows files
7194               # like README, AUTHORS, or THANKS to be generated.
7195               next
7196                 if !$suppress && rule $file;
7197
7198               msg ($suppress ? 'note' : 'error', $where, "$message$trailer");
7199             }
7200         }
7201     }
7202 }
7203
7204 # &require_file ($WHERE, $MYSTRICT, @FILES)
7205 # -----------------------------------------
7206 sub require_file ($$@)
7207 {
7208     my ($where, $mystrict, @files) = @_;
7209     require_file_internal ($where, $mystrict, $relative_dir, @files);
7210 }
7211
7212 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7213 # -----------------------------------------------------------
7214 sub require_file_with_macro ($$$@)
7215 {
7216     my ($cond, $macro, $mystrict, @files) = @_;
7217     $macro = rvar ($macro) unless ref $macro;
7218     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7219 }
7220
7221 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7222 # ----------------------------------------------------------------
7223 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7224 # must be in that directory.  Otherwise expect it in the current directory.
7225 sub require_libsource_with_macro ($$$@)
7226 {
7227     my ($cond, $macro, $mystrict, @files) = @_;
7228     $macro = rvar ($macro) unless ref $macro;
7229     if ($config_libobj_dir)
7230       {
7231         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7232                                $config_libobj_dir, @files);
7233       }
7234     else
7235       {
7236         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7237       }
7238 }
7239
7240 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7241 # ----------------------------------------------
7242 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7243 sub require_conf_file ($$@)
7244 {
7245     my ($where, $mystrict, @files) = @_;
7246     require_file_internal ($where, $mystrict, $config_aux_dir, @files);
7247 }
7248
7249
7250 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7251 # ----------------------------------------------------------------
7252 sub require_conf_file_with_macro ($$$@)
7253 {
7254     my ($cond, $macro, $mystrict, @files) = @_;
7255     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7256                        $mystrict, @files);
7257 }
7258
7259 ################################################################
7260
7261 # &require_build_directory ($DIRECTORY)
7262 # ------------------------------------
7263 # Emit rules to create $DIRECTORY if needed, and return
7264 # the file that any target requiring this directory should be made
7265 # dependent upon.
7266 # We don't want to emit the rule twice, and want to reuse it
7267 # for directories with equivalent names (e.g., `foo/bar' and `./foo//bar').
7268 sub require_build_directory ($)
7269 {
7270   my $directory = shift;
7271
7272   return $directory_map{$directory} if exists $directory_map{$directory};
7273
7274   my $cdir = File::Spec->canonpath ($directory);
7275
7276   if (exists $directory_map{$cdir})
7277     {
7278       my $stamp = $directory_map{$cdir};
7279       $directory_map{$directory} = $stamp;
7280       return $stamp;
7281     }
7282
7283   my $dirstamp = "$cdir/\$(am__dirstamp)";
7284
7285   $directory_map{$directory} = $dirstamp;
7286   $directory_map{$cdir} = $dirstamp;
7287
7288   # Set a variable for the dirstamp basename.
7289   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7290                           '$(am__leading_dot)dirstamp');
7291
7292   # Directory must be removed by `make distclean'.
7293   $clean_files{$dirstamp} = DIST_CLEAN;
7294
7295   $output_rules .= ("$dirstamp:\n"
7296                     . "\t\@\$(mkdir_p) $directory\n"
7297                     . "\t\@: > $dirstamp\n");
7298
7299   return $dirstamp;
7300 }
7301
7302 # &require_build_directory_maybe ($FILE)
7303 # --------------------------------------
7304 # If $FILE lies in a subdirectory, emit a rule to create this
7305 # directory and return the file that $FILE should be made
7306 # dependent upon.  Otherwise, just return the empty string.
7307 sub require_build_directory_maybe ($)
7308 {
7309     my $file = shift;
7310     my $directory = dirname ($file);
7311
7312     if ($directory ne '.')
7313     {
7314         return require_build_directory ($directory);
7315     }
7316     else
7317     {
7318         return '';
7319     }
7320 }
7321
7322 ################################################################
7323
7324 # Push a list of files onto dist_common.
7325 sub push_dist_common
7326 {
7327   prog_error "push_dist_common run after handle_dist"
7328     if $handle_dist_run;
7329   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
7330                               '', INTERNAL, VAR_PRETTY);
7331 }
7332
7333
7334 ################################################################
7335
7336 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
7337 # ----------------------------------------------
7338 # Generate a Makefile.in given the name of the corresponding Makefile and
7339 # the name of the file output by config.status.
7340 sub generate_makefile ($$)
7341 {
7342   my ($makefile_am, $makefile_in) = @_;
7343
7344   # Reset all the Makefile.am related variables.
7345   initialize_per_input;
7346
7347   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
7348   # warnings for this file.  So hold any warning issued before
7349   # we have processed AUTOMAKE_OPTIONS.
7350   buffer_messages ('warning');
7351
7352   # Name of input file ("Makefile.am") and output file
7353   # ("Makefile.in").  These have no directory components.
7354   $am_file_name = basename ($makefile_am);
7355   $in_file_name = basename ($makefile_in);
7356
7357   # $OUTPUT is encoded.  If it contains a ":" then the first element
7358   # is the real output file, and all remaining elements are input
7359   # files.  We don't scan or otherwise deal with these input files,
7360   # other than to mark them as dependencies.  See
7361   # &scan_autoconf_files for details.
7362   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
7363
7364   $relative_dir = dirname ($makefile);
7365   $am_relative_dir = dirname ($makefile_am);
7366
7367   read_main_am_file ($makefile_am);
7368   if (handle_options)
7369     {
7370       # Process buffered warnings.
7371       flush_messages;
7372       # Fatal error.  Just return, so we can continue with next file.
7373       return;
7374     }
7375   # Process buffered warnings.
7376   flush_messages;
7377
7378   # There are a few install-related variables that you should not define.
7379   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
7380     {
7381       my $v = var $var;
7382       if ($v)
7383         {
7384           my $def = $v->def (TRUE);
7385           prog_error "$var not defined in condition TRUE"
7386             unless $def;
7387           reject_var $var, "`$var' should not be defined"
7388             if $def->owner != VAR_AUTOMAKE;
7389         }
7390     }
7391
7392   # Catch some obsolete variables.
7393   msg_var ('obsolete', 'INCLUDES',
7394            "`INCLUDES' is the old name for `AM_CPPFLAGS' (or `*_CPPFLAGS')")
7395     if var ('INCLUDES');
7396
7397   # Must do this after reading .am file.
7398   define_variable ('subdir', $relative_dir, INTERNAL);
7399
7400   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
7401   # recursive rules are enabled.
7402   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
7403     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
7404
7405   # Check first, because we might modify some state.
7406   check_cygnus;
7407   check_gnu_standards;
7408   check_gnits_standards;
7409
7410   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
7411   handle_gettext;
7412   handle_libraries;
7413   handle_ltlibraries;
7414   handle_programs;
7415   handle_scripts;
7416
7417   # These must be run after all the sources are scanned.  They
7418   # use variables defined by &handle_libraries, &handle_ltlibraries,
7419   # or &handle_programs.
7420   handle_compile;
7421   handle_languages;
7422   handle_libtool;
7423
7424   # Variables used by distdir.am and tags.am.
7425   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
7426   if (! option 'no-dist')
7427     {
7428       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
7429     }
7430
7431   handle_multilib;
7432   handle_texinfo;
7433   handle_emacs_lisp;
7434   handle_python;
7435   handle_java;
7436   handle_man_pages;
7437   handle_data;
7438   handle_headers;
7439   handle_subdirs;
7440   handle_tags;
7441   handle_minor_options;
7442   handle_tests;
7443
7444   # This must come after most other rules.
7445   handle_dist;
7446
7447   handle_footer;
7448   do_check_merge_target;
7449   handle_all ($makefile);
7450
7451   # FIXME: Gross!
7452   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
7453     {
7454       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
7455     }
7456
7457   handle_install;
7458   handle_clean ($makefile);
7459   handle_factored_dependencies;
7460
7461   # Comes last, because all the above procedures may have
7462   # defined or overridden variables.
7463   $output_vars .= output_variables;
7464
7465   check_typos;
7466
7467   my ($out_file) = $output_directory . '/' . $makefile_in;
7468
7469   if ($exit_code != 0)
7470     {
7471       verb "not writing $out_file because of earlier errors";
7472       return;
7473     }
7474
7475   if (! -d ($output_directory . '/' . $am_relative_dir))
7476     {
7477       mkdir ($output_directory . '/' . $am_relative_dir, 0755);
7478     }
7479
7480   # We make sure that `all:' is the first target.
7481   my $output =
7482     "$output_vars$output_all$output_header$output_rules$output_trailer";
7483
7484   # Decide whether we must update the output file or not.
7485   # We have to update in the following situations.
7486   #  * $force_generation is set.
7487   #  * any of the output dependencies is younger than the output
7488   #  * the contents of the output is different (this can happen
7489   #    if the project has been populated with a file listed in
7490   #    @common_files since the last run).
7491   # Output's dependencies are split in two sets:
7492   #  * dependencies which are also configure dependencies
7493   #    These do not change between each Makefile.am
7494   #  * other dependencies, specific to the Makefile.am being processed
7495   #    (such as the Makefile.am itself, or any Makefile fragment
7496   #    it includes).
7497   my $timestamp = mtime $out_file;
7498   if (! $force_generation
7499       && $configure_deps_greatest_timestamp < $timestamp
7500       && $output_deps_greatest_timestamp < $timestamp
7501       && $output eq contents ($out_file))
7502     {
7503       verb "$out_file unchanged";
7504       # No need to update.
7505       return;
7506     }
7507
7508   if (-e $out_file)
7509     {
7510       unlink ($out_file)
7511         or fatal "cannot remove $out_file: $!\n";
7512     }
7513
7514   my $gm_file = new Automake::XFile "> $out_file";
7515   verb "creating $out_file";
7516   print $gm_file $output;
7517 }
7518
7519 ################################################################
7520
7521
7522
7523
7524 ################################################################
7525
7526 # Print usage information.
7527 sub usage ()
7528 {
7529     print "Usage: $0 [OPTION] ... [Makefile]...
7530
7531 Generate Makefile.in for configure from Makefile.am.
7532
7533 Operation modes:
7534       --help               print this help, then exit
7535       --version            print version number, then exit
7536   -v, --verbose            verbosely list files processed
7537       --no-force           only update Makefile.in's that are out of date
7538   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
7539
7540 Dependency tracking:
7541   -i, --ignore-deps      disable dependency tracking code
7542       --include-deps     enable dependency tracking code
7543
7544 Flavors:
7545       --cygnus           assume program is part of Cygnus-style tree
7546       --foreign          set strictness to foreign
7547       --gnits            set strictness to gnits
7548       --gnu              set strictness to gnu
7549
7550 Library files:
7551   -a, --add-missing      add missing standard files to package
7552       --libdir=DIR       directory storing library files
7553   -c, --copy             with -a, copy missing files (default is symlink)
7554   -f, --force-missing    force update of standard files
7555
7556 ";
7557     Automake::ChannelDefs::usage;
7558
7559     my ($last, @lcomm);
7560     $last = '';
7561     foreach my $iter (sort ((@common_files, @common_sometimes)))
7562     {
7563         push (@lcomm, $iter) unless $iter eq $last;
7564         $last = $iter;
7565     }
7566
7567     my @four;
7568     print "\nFiles which are automatically distributed, if found:\n";
7569     format USAGE_FORMAT =
7570   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
7571   $four[0],           $four[1],           $four[2],           $four[3]
7572 .
7573     $~ = "USAGE_FORMAT";
7574
7575     my $cols = 4;
7576     my $rows = int(@lcomm / $cols);
7577     my $rest = @lcomm % $cols;
7578
7579     if ($rest)
7580     {
7581         $rows++;
7582     }
7583     else
7584     {
7585         $rest = $cols;
7586     }
7587
7588     for (my $y = 0; $y < $rows; $y++)
7589     {
7590         @four = ("", "", "", "");
7591         for (my $x = 0; $x < $cols; $x++)
7592         {
7593             last if $y + 1 == $rows && $x == $rest;
7594
7595             my $idx = (($x > $rest)
7596                        ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
7597                        : ($rows * $x));
7598
7599             $idx += $y;
7600             $four[$x] = $lcomm[$idx];
7601         }
7602         write;
7603     }
7604
7605     print "\nReport bugs to <bug-automake\@gnu.org>.\n";
7606
7607     # --help always returns 0 per GNU standards.
7608     exit 0;
7609 }
7610
7611
7612 # &version ()
7613 # -----------
7614 # Print version information
7615 sub version ()
7616 {
7617   print <<EOF;
7618 automake (GNU $PACKAGE) $VERSION
7619 Written by Tom Tromey <tromey\@redhat.com>
7620        and Alexandre Duret-Lutz <adl\@gnu.org>.
7621
7622 Copyright 2005 Free Software Foundation, Inc.
7623 This is free software; see the source for copying conditions.  There is NO
7624 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
7625 EOF
7626   # --version always returns 0 per GNU standards.
7627   exit 0;
7628 }
7629
7630 ################################################################
7631
7632 # Parse command line.
7633 sub parse_arguments ()
7634 {
7635   # Start off as gnu.
7636   set_strictness ('gnu');
7637
7638   my $cli_where = new Automake::Location;
7639   my %cli_options =
7640     (
7641      'libdir=s'         => \$libdir,
7642      'gnu'              => sub { set_strictness ('gnu'); },
7643      'gnits'            => sub { set_strictness ('gnits'); },
7644      'cygnus'           => sub { set_global_option ('cygnus', $cli_where); },
7645      'foreign'          => sub { set_strictness ('foreign'); },
7646      'include-deps'     => sub { unset_global_option ('no-dependencies'); },
7647      'i|ignore-deps'    => sub { set_global_option ('no-dependencies',
7648                                                     $cli_where); },
7649      'no-force'         => sub { $force_generation = 0; },
7650      'f|force-missing'  => \$force_missing,
7651      'o|output-dir=s'   => \$output_directory,
7652      'a|add-missing'    => \$add_missing,
7653      'c|copy'           => \$copy_missing,
7654      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
7655      'W|warnings=s'     => \&parse_warnings,
7656      # These long options (--Werror and --Wno-error) for backward
7657      # compatibility.  Use -Werror and -Wno-error today.
7658      'Werror'           => sub { parse_warnings 'W', 'error'; },
7659      'Wno-error'        => sub { parse_warnings 'W', 'no-error'; },
7660      );
7661   use Getopt::Long;
7662   Getopt::Long::config ("bundling", "pass_through");
7663
7664   # See if --version or --help is used.  We want to process these before
7665   # anything else because the GNU Coding Standards require us to
7666   # `exit 0' after processing these options, and we can't guarantee this
7667   # if we treat other options first.  (Handling other options first
7668   # could produce error diagnostics, and in this condition it is
7669   # confusing if Automake does `exit 0'.)
7670   my %cli_options_1st_pass =
7671     (
7672      'version' => \&version,
7673      'help'    => \&usage,
7674      # Recognize all other options (and their arguments) but do nothing.
7675      map { $_ => sub {} } (keys %cli_options)
7676      );
7677   my @ARGV_backup = @ARGV;
7678   Getopt::Long::GetOptions %cli_options_1st_pass
7679     or exit 1;
7680   @ARGV = @ARGV_backup;
7681
7682   # Now *really* process the options.  This time we know that --help
7683   # and --version are not present, but we specify them nonetheless so
7684   # that ambiguous abbreviation are diagnosed.
7685   Getopt::Long::GetOptions %cli_options, 'version' => sub {}, 'help' => sub {}
7686     or exit 1;
7687
7688   if (defined $output_directory)
7689     {
7690       msg 'obsolete', "`--output-dir' is deprecated\n";
7691     }
7692   else
7693     {
7694       # In the next release we'll remove this entirely.
7695       $output_directory = '.';
7696     }
7697
7698   return unless @ARGV;
7699
7700   if ($ARGV[0] =~ /^-./)
7701     {
7702       my %argopts;
7703       for my $k (keys %cli_options)
7704         {
7705           if ($k =~ /(.*)=s$/)
7706             {
7707               map { $argopts{(length ($_) == 1)
7708                              ? "-$_" : "--$_" } = 1; } (split (/\|/, $1));
7709             }
7710         }
7711       if ($ARGV[0] eq '--')
7712         {
7713           shift @ARGV;
7714         }
7715       elsif (exists $argopts{$ARGV[0]})
7716         {
7717           fatal ("option `$ARGV[0]' requires an argument\n"
7718                  . "Try `$0 --help' for more information.");
7719         }
7720       else
7721         {
7722           fatal ("unrecognized option `$ARGV[0]'.\n"
7723                  . "Try `$0 --help' for more information.");
7724         }
7725     }
7726
7727   my $errspec = 0;
7728   foreach my $arg (@ARGV)
7729     {
7730       fatal ("empty argument\nTry `$0 --help' for more information.")
7731         if ($arg eq '');
7732
7733       # Handle $local:$input syntax.
7734       my ($local, @rest) = split (/:/, $arg);
7735       @rest = ("$local.in",) unless @rest;
7736       my $input = locate_am @rest;
7737       if ($input)
7738         {
7739           push @input_files, $input;
7740           $output_files{$input} = join (':', ($local, @rest));
7741         }
7742       else
7743         {
7744           error "no Automake input file found for `$arg'";
7745           $errspec = 1;
7746         }
7747     }
7748   fatal "no input file found among supplied arguments"
7749     if $errspec && ! @input_files;
7750 }
7751
7752 ################################################################
7753
7754 # Parse the WARNINGS environment variable.
7755 parse_WARNINGS;
7756
7757 # Parse command line.
7758 parse_arguments;
7759
7760 $configure_ac = require_configure_ac;
7761
7762 # Do configure.ac scan only once.
7763 scan_autoconf_files;
7764
7765 if (! @input_files)
7766   {
7767     my $msg = '';
7768     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
7769       if -f 'Makefile.am';
7770     fatal ("no `Makefile.am' found for any configure output$msg");
7771   }
7772
7773 # Now do all the work on each file.
7774 foreach my $file (@input_files)
7775   {
7776     ($am_file = $file) =~ s/\.in$//;
7777     if (! -f ($am_file . '.am'))
7778       {
7779         error "`$am_file.am' does not exist";
7780       }
7781     else
7782       {
7783         # Any warning setting now local to this Makefile.am.
7784         dup_channel_setup;
7785
7786         generate_makefile ($am_file . '.am', $file);
7787
7788         # Back out any warning setting.
7789         drop_channel_setup;
7790       }
7791   }
7792
7793 exit $exit_code;
7794
7795
7796 ### Setup "GNU" style for perl-mode and cperl-mode.
7797 ## Local Variables:
7798 ## perl-indent-level: 2
7799 ## perl-continued-statement-offset: 2
7800 ## perl-continued-brace-offset: 0
7801 ## perl-brace-offset: 0
7802 ## perl-brace-imaginary-offset: 0
7803 ## perl-label-offset: -2
7804 ## cperl-indent-level: 2
7805 ## cperl-brace-offset: 0
7806 ## cperl-continued-brace-offset: 0
7807 ## cperl-label-offset: -2
7808 ## cperl-extra-newline-before-brace: t
7809 ## cperl-merge-trailing-else: nil
7810 ## cperl-continued-statement-offset: 2
7811 ## End: