automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
  10 # Free Software Foundation, Inc.
  11
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2, or (at your option)
  15 # any later version.
  16
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  25 # 02111-1307, USA.
  26
  27 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  28 # Perl reimplementation by Tom Tromey <tromey@redhat.com>.
  29
  30 package Language;
  31
  32 BEGIN
  33 {
  34   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  35   unshift @INC, (split ':', $perllibdir);
  36
  37   # Override SHELL.  This is required on DJGPP so that system() uses
  38   # bash, not COMMAND.COM which doesn't quote arguments properly.
  39   # Other systems aren't expected to use $SHELL when Automake
  40   # runs, but it should be safe to drop the `if DJGPP' guard if
  41   # it turns up other systems need the same thing.  After all,
  42   # if SHELL is used, ./configure's SHELL is always better than
  43   # the user's SHELL (which may be something like tcsh).
  44   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJGPP'};
  45 }
  46
  47 use Automake::Struct;
  48 struct (# Short name of the language (c, f77...).
  49         'name' => "\$",
  50         # Nice name of the language (C, Fortran 77...).
  51         'Name' => "\$",
  52
  53         # List of configure variables which must be defined.
  54         'config_vars' => '@',
  55
  56         'ansi'    => "\$",
  57         # `pure' is `1' or `'.  A `pure' language is one where, if
  58         # all the files in a directory are of that language, then we
  59         # do not require the C compiler or any code to call it.
  60         'pure'   => "\$",
  61
  62         'autodep' => "\$",
  63
  64         # Name of the compiling variable (COMPILE).
  65         'compiler'  => "\$",
  66         # Content of the compiling variable.
  67         'compile'  => "\$",
  68         # Flag to require compilation without linking (-c).
  69         'compile_flag' => "\$",
  70         'extensions' => '@',
  71         # A subroutine to compute a list of possible extensions of
  72         # the product given the input extensions.
  73         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  74         'output_extensions' => "\$",
  75         # A list of flag variables used in 'compile'.
  76         # (defaults to [])
  77         'flags' => "@",
  78
  79         # The file to use when generating rules for this language.
  80         # The default is 'depend2'.
  81         'rule_file' => "\$",
  82
  83         # Name of the linking variable (LINK).
  84         'linker' => "\$",
  85         # Content of the linking variable.
  86         'link' => "\$",
  87
  88         # Name of the linker variable (LD).
  89         'lder' => "\$",
  90         # Content of the linker variable ($(CC)).
  91         'ld' => "\$",
  92
  93         # Flag to specify the output file (-o).
  94         'output_flag' => "\$",
  95         '_finish' => "\$",
  96
  97         # This is a subroutine which is called whenever we finally
  98         # determine the context in which a source file will be
  99         # compiled.
 100         '_target_hook' => "\$");
 101
 102
 103 sub finish ($)
 104 {
 105   my ($self) = @_;
 106   if (defined $self->_finish)
 107     {
 108       &{$self->_finish} ();
 109     }
 110 }
 111
 112 sub target_hook ($$$$)
 113 {
 114     my ($self) = @_;
 115     if (defined $self->_target_hook)
 116     {
 117         &{$self->_target_hook} (@_);
 118     }
 119 }
 120
 121 package Automake;
 122
 123 use strict;
 124 use Automake::Config;
 125 use Automake::General;
 126 use Automake::XFile;
 127 use Automake::Channels;
 128 use Automake::ChannelDefs;
 129 use Automake::Configure_ac;
 130 use Automake::FileUtils;
 131 use Automake::Location;
 132 use Automake::Condition qw/TRUE FALSE/;
 133 use Automake::DisjConditions;
 134 use Automake::Options;
 135 use Automake::Version;
 136 use Automake::Variable;
 137 use Automake::VarDef;
 138 use Automake::Rule;
 139 use Automake::RuleDef;
 140 use Automake::Wrap 'makefile_wrap';
 141 use File::Basename;
 142 use Carp;
 143
 144 ## ----------- ##
 145 ## Constants.  ##
 146 ## ----------- ##
 147
 148 # Some regular expressions.  One reason to put them here is that it
 149 # makes indentation work better in Emacs.
 150
 151 # Writing singled-quoted-$-terminated regexes is a pain because
 152 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 153 # by a closing quote.  Letting perl-mode think the quote is not closed
 154 # leads to all sort of misindentations.  On the other hand, defining
 155 # regexes as double-quoted strings is far less readable.  So usually
 156 # we will write:
 157 #
 158 #  $REGEX = '^regex_value' . "\$";
 159
 160 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 161 my $WHITE_PATTERN = '^\s*' . "\$";
 162 my $COMMENT_PATTERN = '^#';
 163 my $TARGET_PATTERN='[$a-zA-Z_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 164 # A rule has three parts: a list of targets, a list of dependencies,
 165 # and optionally actions.
 166 my $RULE_PATTERN =
 167   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 168
 169 # Only recognize leading spaces, not leading tabs.  If we recognize
 170 # leading tabs here then we need to make the reader smarter, because
 171 # otherwise it will think rules like `foo=bar; \' are errors.
 172 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 173 # This pattern recognizes a Gnits version id and sets $1 if the
 174 # release is an alpha release.  We also allow a suffix which can be
 175 # used to extend the version number with a "fork" identifier.
 176 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 177
 178 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 179 my $ELSE_PATTERN =
 180   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 181 my $ENDIF_PATTERN =
 182   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 183 my $PATH_PATTERN = '(\w|[/.-])+';
 184 # This will pass through anything not of the prescribed form.
 185 my $INCLUDE_PATTERN = ('^include\s+'
 186                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 187                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 188                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 189
 190 # Match `-d' as a command-line argument in a string.
 191 my $DASH_D_PATTERN = "(^|\\s)-d(\\s|\$)";
 192 # Directories installed during 'install-exec' phase.
 193 my $EXEC_DIR_PATTERN =
 194   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 195
 196 # Values for AC_CANONICAL_*
 197 use constant AC_CANONICAL_HOST   => 1;
 198 use constant AC_CANONICAL_SYSTEM => 2;
 199
 200 # Values indicating when something should be cleaned.
 201 use constant MOSTLY_CLEAN     => 0;
 202 use constant CLEAN            => 1;
 203 use constant DIST_CLEAN       => 2;
 204 use constant MAINTAINER_CLEAN => 3;
 205
 206 # Libtool files.
 207 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 208 # ltconfig appears here for compatibility with old versions of libtool.
 209 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 210
 211 # Commonly found files we look for and automatically include in
 212 # DISTFILES.
 213 my @common_files =
 214     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 215         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 216         ansi2knr.1 ansi2knr.c compile config.guess config.rpath config.sub
 217         configure configure.ac configure.in depcomp elisp-comp
 218         install-sh libversion.in mdate-sh missing mkinstalldirs
 219         py-compile texinfo.tex ylwrap),
 220      @libtool_files, @libtool_sometimes);
 221
 222 # Commonly used files we auto-include, but only sometimes.
 223 my @common_sometimes =
 224     qw(aclocal.m4 acconfig.h config.h.top config.h.bot stamp-vti);
 225
 226 # Standard directories from the GNU Coding Standards, and additional
 227 # pkg* directories from Automake.  Stored in a hash for fast member check.
 228 my %standard_prefix =
 229     map { $_ => 1 } (qw(bin data exec include info lib libexec lisp
 230                         localstate man man1 man2 man3 man4 man5 man6
 231                         man7 man8 man9 oldinclude pkgdatadir
 232                         pkgincludedir pkglibdir sbin sharedstate
 233                         sysconf));
 234
 235 # Copyright on generated Makefile.ins.
 236 my $gen_copyright = "\
 237 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
 238 # Free Software Foundation, Inc.
 239 # This Makefile.in is free software; the Free Software Foundation
 240 # gives unlimited permission to copy and/or distribute it,
 241 # with or without modifications, as long as this notice is preserved.
 242
 243 # This program is distributed in the hope that it will be useful,
 244 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 245 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 246 # PARTICULAR PURPOSE.
 247 ";
 248
 249 # These constants are returned by lang_*_rewrite functions.
 250 # LANG_SUBDIR means that the resulting object file should be in a
 251 # subdir if the source file is.  In this case the file name cannot
 252 # have `..' components.
 253 use constant LANG_IGNORE  => 0;
 254 use constant LANG_PROCESS => 1;
 255 use constant LANG_SUBDIR  => 2;
 256
 257 # These are used when keeping track of whether an object can be built
 258 # by two different paths.
 259 use constant COMPILE_LIBTOOL  => 1;
 260 use constant COMPILE_ORDINARY => 2;
 261
 262 # We can't always associate a location to a variable or a rule,
 263 # when its defined by Automake.  We use INTERNAL in this case.
 264 use constant INTERNAL => new Automake::Location;
 265 \f
 266
 267 ## ---------------------------------- ##
 268 ## Variables related to the options.  ##
 269 ## ---------------------------------- ##
 270
 271 # TRUE if we should always generate Makefile.in.
 272 my $force_generation = 1;
 273
 274 # From the Perl manual.
 275 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 276
 277 # TRUE if missing standard files should be installed.
 278 my $add_missing = 0;
 279
 280 # TRUE if we should copy missing files; otherwise symlink if possible.
 281 my $copy_missing = 0;
 282
 283 # TRUE if we should always update files that we know about.
 284 my $force_missing = 0;
 285
 286
 287 ## ---------------------------------------- ##
 288 ## Variables filled during files scanning.  ##
 289 ## ---------------------------------------- ##
 290
 291 # Name of the configure.ac file.
 292 my $configure_ac = require_configure_ac;
 293
 294 # Files found by scanning configure.ac for LIBOBJS.
 295 my %libsources = ();
 296
 297 # Names used in AC_CONFIG_HEADER call.
 298 my @config_headers = ();
 299 # Where AC_CONFIG_HEADER appears.
 300 my $config_header_location;
 301
 302 # Names used in AC_CONFIG_LINKS call.
 303 my @config_links = ();
 304
 305 # Directory where output files go.  Actually, output files are
 306 # relative to this directory.
 307 my $output_directory;
 308
 309 # List of Makefile.am's to process, and their corresponding outputs.
 310 my @input_files = ();
 311 my %output_files = ();
 312
 313 # Complete list of Makefile.am's that exist.
 314 my @configure_input_files = ();
 315
 316 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 317 # and their outputs.
 318 my @other_input_files = ();
 319 # Where the last AC_CONFIG_FILES/AC_OUTPUT appears.
 320 my $ac_config_files_location;
 321
 322 # List of directories to search for configure-required files.  This
 323 # can be set by AC_CONFIG_AUX_DIR.
 324 my @config_aux_path = qw(. .. ../..);
 325 my $config_aux_dir = '';
 326 my $config_aux_dir_set_in_configure_in = 0;
 327
 328 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 329 my $seen_gettext = 0;
 330 # Whether AM_GNU_GETTEXT([external]) is used.
 331 my $seen_gettext_external = 0;
 332 # Where AM_GNU_GETTEXT appears.
 333 my $ac_gettext_location;
 334
 335 # TRUE if we've seen AC_CANONICAL_(HOST|SYSTEM).
 336 my $seen_canonical = 0;
 337 my $canonical_location;
 338
 339 # Where AM_MAINTAINER_MODE appears.
 340 my $seen_maint_mode;
 341
 342 # Actual version we've seen.
 343 my $package_version = '';
 344
 345 # Where version is defined.
 346 my $package_version_location;
 347
 348 # TRUE if we've seen AC_ENABLE_MULTILIB.
 349 my $seen_multilib = 0;
 350
 351 # TRUE if we've seen AM_PROG_CC_C_O
 352 my $seen_cc_c_o = 0;
 353
 354 # Where AM_INIT_AUTOMAKE is called;
 355 my $seen_init_automake = 0;
 356
 357 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 358 my $seen_automake_version = 0;
 359
 360 # Hash table of discovered configure substitutions.  Keys are names,
 361 # values are `FILE:LINE' strings which are used by error message
 362 # generation.
 363 my %configure_vars = ();
 364
 365 # Files included by $configure_ac.
 366 my @configure_deps = ();
 367
 368 # Greatest timestamp of configure's dependencies.
 369 my $configure_deps_greatest_timestamp = 0;
 370
 371 # Hash table of AM_CONDITIONAL variables seen in configure.
 372 my %configure_cond = ();
 373
 374 # This maps extensions onto language names.
 375 my %extension_map = ();
 376
 377 # List of the DIST_COMMON files we discovered while reading
 378 # configure.in
 379 my $configure_dist_common = '';
 380
 381 # This maps languages names onto objects.
 382 my %languages = ();
 383
 384 # List of targets we must always output.
 385 # FIXME: Complete, and remove falsely required targets.
 386 my %required_targets =
 387   (
 388    'all'          => 1,
 389    'dvi'          => 1,
 390    'pdf'          => 1,
 391    'ps'           => 1,
 392    'info'         => 1,
 393    'install-info' => 1,
 394    'install'      => 1,
 395    'install-data' => 1,
 396    'install-exec' => 1,
 397    'uninstall'    => 1,
 398
 399    # FIXME: Not required, temporary hacks.
 400    # Well, actually they are sort of required: the -recursive
 401    # targets will run them anyway...
 402    'dvi-am'          => 1,
 403    'pdf-am'          => 1,
 404    'ps-am'           => 1,
 405    'info-am'         => 1,
 406    'install-data-am' => 1,
 407    'install-exec-am' => 1,
 408    'installcheck-am' => 1,
 409    'uninstall-am' => 1,
 410
 411    'install-man' => 1,
 412   );
 413
 414 # This is set to 1 when Automake needs to be run again.
 415 # (For instance, this happens when an auxiliary file such as
 416 # depcomp is added after the toplevel Makefile.in -- which
 417 # should distribute depcomp -- has been generated.)
 418 my $automake_needs_to_reprocess_all_files = 0;
 419
 420 # If a file name appears as a key in this hash, then it has already
 421 # been checked for.  This variable is local to the "require file"
 422 # functions.
 423 my %require_file_found = ();
 424
 425 # The name of the Makefile currently being processed.
 426 my $am_file = 'BUG';
 427 \f
 428
 429 ################################################################
 430
 431 ## ------------------------------------------ ##
 432 ## Variables reset by &initialize_per_input.  ##
 433 ## ------------------------------------------ ##
 434
 435 # Basename and relative dir of the input file.
 436 my $am_file_name;
 437 my $am_relative_dir;
 438
 439 # Same but wrt Makefile.in.
 440 my $in_file_name;
 441 my $relative_dir;
 442
 443 # Greatest timestamp of the output's dependencies (excluding
 444 # configure's dependencies).
 445 my $output_deps_greatest_timestamp;
 446
 447 # These two variables are used when generating each Makefile.in.
 448 # They hold the Makefile.in until it is ready to be printed.
 449 my $output_rules;
 450 my $output_vars;
 451 my $output_trailer;
 452 my $output_all;
 453 my $output_header;
 454
 455 # This is the conditional stack, updated on if/else/endif, and
 456 # used to build Condition objects.
 457 my @cond_stack;
 458
 459 # This holds the set of included files.
 460 my @include_stack;
 461
 462 # This holds a list of directories which we must create at `dist'
 463 # time.  This is used in some strange scenarios involving weird
 464 # AC_OUTPUT commands.
 465 my %dist_dirs;
 466
 467 # List of dependencies for the obvious targets.
 468 my @all;
 469 my @check;
 470 my @check_tests;
 471
 472 # Keys in this hash table are files to delete.  The associated
 473 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 474 my %clean_files;
 475
 476 # Keys in this hash table are object files or other files in
 477 # subdirectories which need to be removed.  This only holds files
 478 # which are created by compilations.  The value in the hash indicates
 479 # when the file should be removed.
 480 my %compile_clean_files;
 481
 482 # Keys in this hash table are directories where we expect to build a
 483 # libtool object.  We use this information to decide what directories
 484 # to delete.
 485 my %libtool_clean_directories;
 486
 487 # Value of `$(SOURCES)', used by tags.am.
 488 my @sources;
 489 # Sources which go in the distribution.
 490 my @dist_sources;
 491
 492 # This hash maps object file names onto their corresponding source
 493 # file names.  This is used to ensure that each object is created
 494 # by a single source file.
 495 my %object_map;
 496
 497 # This hash maps object file names onto an integer value representing
 498 # whether this object has been built via ordinary compilation or
 499 # libtool compilation (the COMPILE_* constants).
 500 my %object_compilation_map;
 501
 502
 503 # This keeps track of the directories for which we've already
 504 # created dirstamp code.
 505 my %directory_map;
 506
 507 # All .P files.
 508 my %dep_files;
 509
 510 # This is a list of all targets to run during "make dist".
 511 my @dist_targets;
 512
 513 # Keys in this hash are the basenames of files which must depend on
 514 # ansi2knr.  Values are either the empty string, or the directory in
 515 # which the ANSI source file appears; the directory must have a
 516 # trailing `/'.
 517 my %de_ansi_files;
 518
 519 # This is the name of the redirect `all' target to use.
 520 my $all_target;
 521
 522 # This keeps track of which extensions we've seen (that we care
 523 # about).
 524 my %extension_seen;
 525
 526 # This is random scratch space for the language finish functions.
 527 # Don't randomly overwrite it; examine other uses of keys first.
 528 my %language_scratch;
 529
 530 # We keep track of which objects need special (per-executable)
 531 # handling on a per-language basis.
 532 my %lang_specific_files;
 533
 534 # This is set when `handle_dist' has finished.  Once this happens,
 535 # we should no longer push on dist_common.
 536 my $handle_dist_run;
 537
 538 # Used to store a set of linkers needed to generate the sources currently
 539 # under consideration.
 540 my %linkers_used;
 541
 542 # True if we need `LINK' defined.  This is a hack.
 543 my $need_link;
 544
 545 # Was get_object_extension run?
 546 # FIXME: This is a hack. a better switch should be found.
 547 my $get_object_extension_was_run;
 548
 549 ################################################################
 550
 551 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 552 # ------------------------------------
 553 # This is called by Automake::Variable::define() when SUFFIXES
 554 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 555 # The work here needs to be performed as a side-effect of the
 556 # macro_define() call because SUFFIXES definitions impact
 557 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 558 # the input am file.
 559 sub var_SUFFIXES_trigger ($$)
 560 {
 561     my ($type, $value) = @_;
 562     accept_extensions (split (' ', $value));
 563 }
 564 Automake::Variable::hook ('SUFFIXES', &var_SUFFIXES_trigger);
 565
 566 ################################################################
 567
 568 ## --------------------------------- ##
 569 ## Forward subroutine declarations.  ##
 570 ## --------------------------------- ##
 571 sub register_language (%);
 572 sub file_contents_internal ($$$%);
 573 sub define_files_variable ($\@$$);
 574
 575
 576 # &initialize_per_input ()
 577 # ------------------------
 578 # (Re)-Initialize per-Makefile.am variables.
 579 sub initialize_per_input ()
 580 {
 581     reset_local_duplicates ();
 582
 583     $am_file_name = '';
 584     $am_relative_dir = '';
 585
 586     $in_file_name = '';
 587     $relative_dir = '';
 588
 589     $output_deps_greatest_timestamp = 0;
 590
 591     $output_rules = '';
 592     $output_vars = '';
 593     $output_trailer = '';
 594     $output_all = '';
 595     $output_header = '';
 596
 597     Automake::Options::reset;
 598     Automake::Variable::reset;
 599     Automake::Rule::reset;
 600
 601     @cond_stack = ();
 602
 603     @include_stack = ();
 604
 605     %dist_dirs = ();
 606
 607     @all = ();
 608     @check = ();
 609     @check_tests = ();
 610
 611     %clean_files = ();
 612
 613     @sources = ();
 614     @dist_sources = ();
 615
 616     %object_map = ();
 617     %object_compilation_map = ();
 618
 619     %directory_map = ();
 620
 621     %dep_files = ();
 622
 623     @dist_targets = ();
 624
 625     %de_ansi_files = ();
 626
 627     $all_target = '';
 628
 629     %extension_seen = ();
 630
 631     %language_scratch = ();
 632
 633     %lang_specific_files = ();
 634
 635     $handle_dist_run = 0;
 636
 637     $need_link = 0;
 638
 639     $get_object_extension_was_run = 0;
 640
 641     %compile_clean_files = ();
 642
 643     # We always include `.'.  This isn't strictly correct.
 644     %libtool_clean_directories = ('.' => 1);
 645 }
 646
 647
 648 ################################################################
 649
 650 # Initialize our list of languages that are internally supported.
 651
 652 # C.
 653 register_language ('name' => 'c',
 654                    'Name' => 'C',
 655                    'config_vars' => ['CC'],
 656                    'ansi' => 1,
 657                    'autodep' => '',
 658                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 659                    'compiler' => 'COMPILE',
 660                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 661                    'lder' => 'CCLD',
 662                    'ld' => '$(CC)',
 663                    'linker' => 'LINK',
 664                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 665                    'compile_flag' => '-c',
 666                    'extensions' => ['.c'],
 667                    '_finish' => \&lang_c_finish);
 668
 669 # C++.
 670 register_language ('name' => 'cxx',
 671                    'Name' => 'C++',
 672                    'config_vars' => ['CXX'],
 673                    'linker' => 'CXXLINK',
 674                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 675                    'autodep' => 'CXX',
 676                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 677                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 678                    'compiler' => 'CXXCOMPILE',
 679                    'compile_flag' => '-c',
 680                    'output_flag' => '-o',
 681                    'lder' => 'CXXLD',
 682                    'ld' => '$(CXX)',
 683                    'pure' => 1,
 684                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 685
 686 # Objective C.
 687 register_language ('name' => 'objc',
 688                    'Name' => 'Objective C',
 689                    'config_vars' => ['OBJC'],
 690                    'linker' => 'OBJCLINK',,
 691                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 692                    'autodep' => 'OBJC',
 693                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 694                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 695                    'compiler' => 'OBJCCOMPILE',
 696                    'compile_flag' => '-c',
 697                    'output_flag' => '-o',
 698                    'lder' => 'OBJCLD',
 699                    'ld' => '$(OBJC)',
 700                    'pure' => 1,
 701                    'extensions' => ['.m']);
 702
 703 # Headers.
 704 register_language ('name' => 'header',
 705                    'Name' => 'Header',
 706                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 707                                     '.hpp', '.inc'],
 708                    # No output.
 709                    'output_extensions' => sub { return () },
 710                    # Nothing to do.
 711                    '_finish' => sub { });
 712
 713 # Yacc (C & C++).
 714 register_language ('name' => 'yacc',
 715                    'Name' => 'Yacc',
 716                    'config_vars' => ['YACC'],
 717                    'flags' => ['YFLAGS'],
 718                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 719                    'compiler' => 'YACCCOMPILE',
 720                    'extensions' => ['.y'],
 721                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 722                                                 return ($ext,) },
 723                    'rule_file' => 'yacc',
 724                    '_finish' => \&lang_yacc_finish,
 725                    '_target_hook' => \&lang_yacc_target_hook);
 726 register_language ('name' => 'yaccxx',
 727                    'Name' => 'Yacc (C++)',
 728                    'config_vars' => ['YACC'],
 729                    'rule_file' => 'yacc',
 730                    'flags' => ['YFLAGS'],
 731                    'compiler' => 'YACCCOMPILE',
 732                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 733                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 734                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 735                                                 return ($ext,) },
 736                    '_finish' => \&lang_yacc_finish,
 737                    '_target_hook' => \&lang_yacc_target_hook);
 738
 739 # Lex (C & C++).
 740 register_language ('name' => 'lex',
 741                    'Name' => 'Lex',
 742                    'config_vars' => ['LEX'],
 743                    'rule_file' => 'lex',
 744                    'flags' => ['LFLAGS'],
 745                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 746                    'compiler' => 'LEXCOMPILE',
 747                    'extensions' => ['.l'],
 748                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 749                                                 return ($ext,) },
 750                    '_finish' => \&lang_lex_finish,
 751                    '_target_hook' => \&lang_lex_target_hook);
 752 register_language ('name' => 'lexxx',
 753                    'Name' => 'Lex (C++)',
 754                    'config_vars' => ['LEX'],
 755                    'rule_file' => 'lex',
 756                    'flags' => ['LFLAGS'],
 757                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 758                    'compiler' => 'LEXCOMPILE',
 759                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 760                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 761                                                 return ($ext,) },
 762                    '_finish' => \&lang_lex_finish,
 763                    '_target_hook' => \&lang_lex_target_hook);
 764
 765 # Assembler.
 766 register_language ('name' => 'asm',
 767                    'Name' => 'Assembler',
 768                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 769
 770                    'flags' => ['CCASFLAGS'],
 771                    # Users can set AM_ASFLAGS to includes DEFS, INCLUDES,
 772                    # or anything else required.  They can also set AS.
 773                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 774                    'compiler' => 'CCASCOMPILE',
 775                    'compile_flag' => '-c',
 776                    'extensions' => ['.s', '.S'],
 777
 778                    # With assembly we still use the C linker.
 779                    '_finish' => \&lang_c_finish);
 780
 781 # Fortran 77
 782 register_language ('name' => 'f77',
 783                    'Name' => 'Fortran 77',
 784                    'linker' => 'F77LINK',
 785                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 786                    'flags' => ['FFLAGS'],
 787                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 788                    'compiler' => 'F77COMPILE',
 789                    'compile_flag' => '-c',
 790                    'output_flag' => '-o',
 791                    'lder' => 'F77LD',
 792                    'ld' => '$(F77)',
 793                    'pure' => 1,
 794                    'extensions' => ['.f', '.for', '.f90']);
 795
 796 # Preprocessed Fortran 77
 797 #
 798 # The current support for preprocessing Fortran 77 just involves
 799 # passing `$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 800 # $(CPPFLAGS)' as additional flags to the Fortran 77 compiler, since
 801 # this is how GNU Make does it; see the `GNU Make Manual, Edition 0.51
 802 # for `make' Version 3.76 Beta' (specifically, from info file
 803 # `(make)Catalogue of Rules').
 804 #
 805 # A better approach would be to write an Autoconf test
 806 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 807 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 808 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 809 # preprocessing capabilities, and then fall back on cpp (if cpp were
 810 # available).
 811 register_language ('name' => 'ppf77',
 812                    'Name' => 'Preprocessed Fortran 77',
 813                    'config_vars' => ['F77'],
 814                    'linker' => 'F77LINK',
 815                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 816                    'lder' => 'F77LD',
 817                    'ld' => '$(F77)',
 818                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 819                    'compiler' => 'PPF77COMPILE',
 820                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 821                    'compile_flag' => '-c',
 822                    'output_flag' => '-o',
 823                    'pure' => 1,
 824                    'extensions' => ['.F']);
 825
 826 # Ratfor.
 827 register_language ('name' => 'ratfor',
 828                    'Name' => 'Ratfor',
 829                    'config_vars' => ['F77'],
 830                    'linker' => 'F77LINK',
 831                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 832                    'lder' => 'F77LD',
 833                    'ld' => '$(F77)',
 834                    'flags' => ['RFLAGS', 'FFLAGS'],
 835                    # FIXME also FFLAGS.
 836                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
 837                    'compiler' => 'RCOMPILE',
 838                    'compile_flag' => '-c',
 839                    'output_flag' => '-o',
 840                    'pure' => 1,
 841                    'extensions' => ['.r']);
 842
 843 # Java via gcj.
 844 register_language ('name' => 'java',
 845                    'Name' => 'Java',
 846                    'config_vars' => ['GCJ'],
 847                    'linker' => 'GCJLINK',
 848                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 849                    'autodep' => 'GCJ',
 850                    'flags' => ['GCJFLAGS'],
 851                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
 852                    'compiler' => 'GCJCOMPILE',
 853                    'compile_flag' => '-c',
 854                    'output_flag' => '-o',
 855                    'lder' => 'GCJLD',
 856                    'ld' => '$(GCJ)',
 857                    'pure' => 1,
 858                    'extensions' => ['.java', '.class', '.zip', '.jar']);
 859
 860 ################################################################
 861
 862 # Error reporting functions.
 863
 864 # err_am ($MESSAGE, [%OPTIONS])
 865 # -----------------------------
 866 # Uncategorized errors about the current Makefile.am.
 867 sub err_am ($;%)
 868 {
 869   msg_am ('error', @_);
 870 }
 871
 872 # err_ac ($MESSAGE, [%OPTIONS])
 873 # -----------------------------
 874 # Uncategorized errors about configure.ac.
 875 sub err_ac ($;%)
 876 {
 877   msg_ac ('error', @_);
 878 }
 879
 880 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
 881 # ---------------------------------------
 882 # Messages about about the current Makefile.am.
 883 sub msg_am ($$;%)
 884 {
 885   my ($channel, $msg, %opts) = @_;
 886   msg $channel, "${am_file}.am", $msg, %opts;
 887 }
 888
 889 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
 890 # ---------------------------------------
 891 # Messages about about configure.ac.
 892 sub msg_ac ($$;%)
 893 {
 894   my ($channel, $msg, %opts) = @_;
 895   msg $channel, $configure_ac, $msg, %opts;
 896 }
 897
 898 ################################################################
 899
 900 # subst ($TEXT)
 901 # -------------
 902 # Return a configure-style substitution using the indicated text.
 903 # We do this to avoid having the substitutions directly in automake.in;
 904 # when we do that they are sometimes removed and this causes confusion
 905 # and bugs.
 906 sub subst ($)
 907 {
 908     my ($text) = @_;
 909     return '@' . $text . '@';
 910 }
 911
 912 ################################################################
 913
 914
 915 # $BACKPATH
 916 # &backname ($REL-DIR)
 917 # --------------------
 918 # If I `cd $REL-DIR', then to come back, I should `cd $BACKPATH'.
 919 # For instance `src/foo' => `../..'.
 920 # Works with non strictly increasing paths, i.e., `src/../lib' => `..'.
 921 sub backname ($)
 922 {
 923     my ($file) = @_;
 924     my @res;
 925     foreach (split (/\//, $file))
 926     {
 927         next if $_ eq '.' || $_ eq '';
 928         if ($_ eq '..')
 929         {
 930             pop @res;
 931         }
 932         else
 933         {
 934             push (@res, '..');
 935         }
 936     }
 937     return join ('/', @res) || '.';
 938 }
 939
 940 ################################################################
 941
 942
 943 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
 944 sub handle_options
 945 {
 946   my $var = var ('AUTOMAKE_OPTIONS');
 947   if ($var)
 948     {
 949       # FIXME: We should disallow conditional definitions of AUTOMAKE_OPTIONS.
 950       if (process_option_list ($var->rdef (TRUE)->location,
 951                                $var->value_as_list_recursive (TRUE)))
 952         {
 953           return 1;
 954         }
 955     }
 956
 957   if ($strictness == GNITS)
 958     {
 959       set_option ('readme-alpha', INTERNAL);
 960       set_option ('std-options', INTERNAL);
 961       set_option ('check-news', INTERNAL);
 962     }
 963
 964   return 0;
 965 }
 966
 967
 968 # get_object_extension ($OUT)
 969 # ---------------------------
 970 # Return object extension.  Just once, put some code into the output.
 971 # OUT is the name of the output file
 972 sub get_object_extension
 973 {
 974     my ($out) = @_;
 975
 976     # Maybe require libtool library object files.
 977     my $extension = '.$(OBJEXT)';
 978     $extension = '.lo' if ($out =~ /\.la$/);
 979
 980     # Check for automatic de-ANSI-fication.
 981     $extension = '$U' . $extension
 982       if option 'ansi2knr';
 983
 984     $get_object_extension_was_run = 1;
 985
 986     return $extension;
 987 }
 988
 989
 990 # Call finish function for each language that was used.
 991 sub handle_languages
 992 {
 993     if (! option 'no-dependencies')
 994     {
 995         # Include auto-dep code.  Don't include it if DEP_FILES would
 996         # be empty.
 997         if (&saw_sources_p (0) && keys %dep_files)
 998         {
 999             # Set location of depcomp.
1000             &define_variable ('depcomp', "\$(SHELL) $config_aux_dir/depcomp",
1001                               INTERNAL);
1002             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1003
1004             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1005
1006             my @deplist = sort keys %dep_files;
1007
1008             # We define this as a conditional variable because BSD
1009             # make can't handle backslashes for continuing comments on
1010             # the following line.
1011             define_pretty_variable ('DEP_FILES',
1012                                     new Automake::Condition ('AMDEP_TRUE'),
1013                                     INTERNAL, @deplist);
1014
1015             # Generate each `include' individually.  Irix 6 make will
1016             # not properly include several files resulting from a
1017             # variable expansion; generating many separate includes
1018             # seems safest.
1019             $output_rules .= "\n";
1020             foreach my $iter (@deplist)
1021             {
1022                 $output_rules .= (subst ('AMDEP_TRUE')
1023                                   . subst ('am__include')
1024                                   . ' '
1025                                   . subst ('am__quote')
1026                                   . $iter
1027                                   . subst ('am__quote')
1028                                   . "\n");
1029             }
1030
1031             # Compute the set of directories to remove in distclean-depend.
1032             my @depdirs = uniq (map { dirname ($_) } @deplist);
1033             $output_rules .= &file_contents ('depend',
1034                                              new Automake::Location,
1035                                              DEPDIRS => "@depdirs");
1036         }
1037     }
1038     else
1039     {
1040         &define_variable ('depcomp', '', INTERNAL);
1041         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1042     }
1043
1044     my %done;
1045
1046     # Is the c linker needed?
1047     my $needs_c = 0;
1048     foreach my $ext (sort keys %extension_seen)
1049     {
1050         next unless $extension_map{$ext};
1051
1052         my $lang = $languages{$extension_map{$ext}};
1053
1054         my $rule_file = $lang->rule_file || 'depend2';
1055
1056         # Get information on $LANG.
1057         my $pfx = $lang->autodep;
1058         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1059
1060         my ($AMDEP, $FASTDEP) =
1061           (option 'no-dependencies' || $lang->autodep eq 'no')
1062           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1063
1064         my %transform = ('EXT'     => $ext,
1065                          'PFX'     => $pfx,
1066                          'FPFX'    => $fpfx,
1067                          'AMDEP'   => $AMDEP,
1068                          'FASTDEP' => $FASTDEP,
1069                          '-c'      => $lang->compile_flag || '',
1070                          'MORE-THAN-ONE'
1071                                    => (count_files_for_language ($lang->name) > 1));
1072
1073         # Generate the appropriate rules for this extension.
1074         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1075             || defined $lang->compile)
1076         {
1077             # Some C compilers don't support -c -o.  Use it only if really
1078             # needed.
1079             my $output_flag = $lang->output_flag || '';
1080             $output_flag = '-o'
1081               if (! $output_flag
1082                   && $lang->name eq 'c'
1083                   && option 'subdir-objects');
1084
1085             # Compute a possible derived extension.
1086             # This is not used by depend2.am.
1087             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1088
1089             $output_rules .=
1090               file_contents ($rule_file,
1091                              new Automake::Location,
1092                              %transform,
1093                              GENERIC   => 1,
1094
1095                              'DERIVED-EXT' => $der_ext,
1096
1097                              # In this situation we know that the
1098                              # object is in this directory, so
1099                              # $(DEPDIR) is the correct location for
1100                              # dependencies.
1101                              DEPBASE   => '$(DEPDIR)/$*',
1102                              BASE      => '$*',
1103                              SOURCE    => '$<',
1104                              OBJ       => '$@',
1105                              OBJOBJ    => '$@',
1106                              LTOBJ     => '$@',
1107
1108                              COMPILE   => '$(' . $lang->compiler . ')',
1109                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1110                              -o        => $output_flag);
1111         }
1112
1113         # Now include code for each specially handled object with this
1114         # language.
1115         my %seen_files = ();
1116         foreach my $file (@{$lang_specific_files{$lang->name}})
1117         {
1118             my ($derived, $source, $obj, $myext) = split (' ', $file);
1119
1120             # We might see a given object twice, for instance if it is
1121             # used under different conditions.
1122             next if defined $seen_files{$obj};
1123             $seen_files{$obj} = 1;
1124
1125             prog_error ("found " . $lang->name .
1126                         " in handle_languages, but compiler not defined")
1127               unless defined $lang->compile;
1128
1129             my $obj_compile = $lang->compile;
1130
1131             # Rewrite each occurrence of `AM_$flag' in the compile
1132             # rule into `${derived}_$flag' if it exists.
1133             for my $flag (@{$lang->flags})
1134               {
1135                 my $val = "${derived}_$flag";
1136                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1137                   if set_seen ($val);
1138               }
1139
1140             my $obj_ltcompile = '$(LIBTOOL) --mode=compile ' . $obj_compile;
1141
1142             # We _need_ `-o' for per object rules.
1143             my $output_flag = $lang->output_flag || '-o';
1144
1145             my $depbase = dirname ($obj);
1146             $depbase = ''
1147                 if $depbase eq '.';
1148             $depbase .= '/'
1149                 unless $depbase eq '';
1150             $depbase .= '$(DEPDIR)/' . basename ($obj);
1151
1152             # Support for deansified files in subdirectories is ugly
1153             # enough to deserve an explanation.
1154             #
1155             # A Note about normal ansi2knr processing first.  On
1156             #
1157             #   AUTOMAKE_OPTIONS = ansi2knr
1158             #   bin_PROGRAMS = foo
1159             #   foo_SOURCES = foo.c
1160             #
1161             # we generate rules similar to:
1162             #
1163             #   foo: foo$U.o; link ...
1164             #   foo$U.o: foo$U.c; compile ...
1165             #   foo_.c: foo.c; ansi2knr ...
1166             #
1167             # this is fairly compact, and will call ansi2knr depending
1168             # on the value of $U (`' or `_').
1169             #
1170             # It's harder with subdir sources. On
1171             #
1172             #   AUTOMAKE_OPTIONS = ansi2knr
1173             #   bin_PROGRAMS = foo
1174             #   foo_SOURCES = sub/foo.c
1175             #
1176             # we have to create foo_.c in the current directory.
1177             # (Unless the user asks 'subdir-objects'.)  This is important
1178             # in case the same file (`foo.c') is compiled from other
1179             # directories with different cpp options: foo_.c would
1180             # be preprocessed for only one set of options if it were
1181             # put in the subdirectory.
1182             #
1183             # Because foo$U.o must be built from either foo_.c or
1184             # sub/foo.c we can't be as concise as in the first example.
1185             # Instead we output
1186             #
1187             #   foo: foo$U.o; link ...
1188             #   foo_.o: foo_.c; compile ...
1189             #   foo.o: sub/foo.c; compile ...
1190             #   foo_.c: foo.c; ansi2knr ...
1191             #
1192             # This is why we'll now transform $rule_file twice
1193             # if we detect this case.
1194             # A first time we output the compile rule with `$U'
1195             # replaced by `_' and the source directory removed,
1196             # and another time we simply remove `$U'.
1197             #
1198             # Note that at this point $source (as computed by
1199             # &handle_single_transform_list) is `sub/foo$U.c'.
1200             # This can be confusing: it can be used as-is when
1201             # subdir-objects is set, otherwise you have to know
1202             # it really means `foo_.c' or `sub/foo.c'.
1203             my $objdir = dirname ($obj);
1204             my $srcdir = dirname ($source);
1205             if ($lang->ansi && $obj =~ /\$U/)
1206               {
1207                 prog_error "`$obj' contains \$U, but `$source' doesn't."
1208                   if $source !~ /\$U/;
1209
1210                 (my $source_ = $source) =~ s/\$U/_/g;
1211                 # Explicitly clean the _.c files if they are in
1212                 # a subdirectory. (In the current directory they get
1213                 # erased by a `rm -f *_.c' rule.)
1214                 $clean_files{$source_} = MOSTLY_CLEAN
1215                   if $objdir ne '.';
1216                 # Output an additional rule if _.c and .c are not in
1217                 # the same directory.  (_.c is always in $objdir.)
1218                 if ($objdir ne $srcdir)
1219                   {
1220                     (my $obj_ = $obj) =~ s/\$U/_/g;
1221                     (my $depbase_ = $depbase) =~ s/\$U/_/g;
1222                     $source_ = basename ($source_);
1223
1224                     $output_rules .=
1225                       file_contents ($rule_file,
1226                                      new Automake::Location,
1227                                      %transform,
1228                                      GENERIC   => 0,
1229
1230                                      DEPBASE   => $depbase_,
1231                                      BASE      => $obj_,
1232                                      SOURCE    => $source_,
1233                                      OBJ       => "$obj_$myext",
1234                                      OBJOBJ    => "$obj_.obj",
1235                                      LTOBJ     => "$obj_.lo",
1236
1237                                      COMPILE   => $obj_compile,
1238                                      LTCOMPILE => $obj_ltcompile,
1239                                      -o        => $output_flag);
1240                     $obj =~ s/\$U//g;
1241                     $depbase =~ s/\$U//g;
1242                     $source =~ s/\$U//g;
1243                   }
1244               }
1245
1246             $output_rules .=
1247               file_contents ($rule_file,
1248                              new Automake::Location,
1249                              %transform,
1250                              GENERIC   => 0,
1251
1252                              DEPBASE   => $depbase,
1253                              BASE      => $obj,
1254                              SOURCE    => $source,
1255                              # Use $myext and not `.o' here, in case
1256                              # we are actually building a new source
1257                              # file -- e.g. via yacc.
1258                              OBJ       => "$obj$myext",
1259                              OBJOBJ    => "$obj.obj",
1260                              LTOBJ     => "$obj.lo",
1261
1262                              COMPILE   => $obj_compile,
1263                              LTCOMPILE => $obj_ltcompile,
1264                              -o        => $output_flag);
1265         }
1266
1267         # The rest of the loop is done once per language.
1268         next if defined $done{$lang};
1269         $done{$lang} = 1;
1270
1271         # Load the language dependent Makefile chunks.
1272         my %lang = map { uc ($_) => 0 } keys %languages;
1273         $lang{uc ($lang->name)} = 1;
1274         $output_rules .= file_contents ('lang-compile',
1275                                         new Automake::Location,
1276                                         %transform, %lang);
1277
1278         # If the source to a program consists entirely of code from a
1279         # `pure' language, for instance C++ for Fortran 77, then we
1280         # don't need the C compiler code.  However if we run into
1281         # something unusual then we do generate the C code.  There are
1282         # probably corner cases here that do not work properly.
1283         # People linking Java code to Fortran code deserve pain.
1284         $needs_c ||= ! $lang->pure;
1285
1286         define_compiler_variable ($lang)
1287           if ($lang->compile);
1288
1289         define_linker_variable ($lang)
1290           if ($lang->link);
1291
1292         require_variables ("$am_file.am", $lang->Name . " source seen",
1293                            TRUE, @{$lang->config_vars});
1294
1295         # Call the finisher.
1296         $lang->finish;
1297
1298         # Flags listed in `->flags' are user variables (per GNU Standards),
1299         # they should not be overridden in the Makefile...
1300         my @dont_override = @{$lang->flags};
1301         # ... and so is LDFLAGS.
1302         push @dont_override, 'LDFLAGS' if $lang->link;
1303
1304         foreach my $flag (@dont_override)
1305           {
1306             my $var = var $flag;
1307             if ($var)
1308               {
1309                 for my $cond ($var->conditions->conds)
1310                   {
1311                     if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1312                       {
1313                         msg_cond_var ('gnu', $cond, $flag,
1314                                       "`$flag' is a user variable, "
1315                                       . "you should not override it;\n"
1316                                       . "use `AM_$flag' instead.");
1317                       }
1318                   }
1319               }
1320           }
1321     }
1322
1323     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1324     # suffix rule was learned), don't bother with the C stuff.  But if
1325     # anything else creeps in, then use it.
1326     $needs_c = 1
1327       if $need_link || suffix_rules_count > 1;
1328
1329     if ($needs_c)
1330       {
1331         &define_compiler_variable ($languages{'c'})
1332           unless defined $done{$languages{'c'}};
1333         define_linker_variable ($languages{'c'});
1334       }
1335 }
1336
1337 # Check to make sure a source defined in LIBOBJS is not explicitly
1338 # mentioned.  This is a separate function (as opposed to being inlined
1339 # in handle_source_transform) because it isn't always appropriate to
1340 # do this check.
1341 sub check_libobjs_sources
1342 {
1343   my ($one_file, $unxformed) = @_;
1344
1345   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1346                       'dist_EXTRA_', 'nodist_EXTRA_')
1347     {
1348       my @files;
1349       my $varname = $prefix . $one_file . '_SOURCES';
1350       my $var = var ($varname);
1351       if ($var)
1352         {
1353           @files = $var->value_as_list_recursive ('all');
1354         }
1355       elsif ($prefix eq '')
1356         {
1357           @files = ($unxformed . '.c');
1358         }
1359       else
1360         {
1361           next;
1362         }
1363
1364       foreach my $file (@files)
1365         {
1366           err_var ($prefix . $one_file . '_SOURCES',
1367                    "automatically discovered file `$file' should not" .
1368                    " be explicitly mentioned")
1369             if defined $libsources{$file};
1370         }
1371     }
1372 }
1373
1374
1375 # @OBJECTS
1376 # handle_single_transform_list ($VAR, $TOPPARENT, $DERIVED, $OBJ, @FILES)
1377 # -----------------------------------------------------------------------
1378 # Does much of the actual work for handle_source_transform.
1379 # Arguments are:
1380 #   $VAR is the name of the variable that the source filenames come from
1381 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1382 #   $DERIVED is the name of resulting executable or library
1383 #   $OBJ is the object extension (e.g., `$U.lo')
1384 #   @FILES is the list of source files to transform
1385 # Result is a list of the names of objects
1386 # %linkers_used will be updated with any linkers needed
1387 sub handle_single_transform_list ($$$$@)
1388 {
1389     my ($var, $topparent, $derived, $obj, @files) = @_;
1390     my @result = ();
1391     my $nonansi_obj = $obj;
1392     $nonansi_obj =~ s/\$U//g;
1393
1394     # Turn sources into objects.  We use a while loop like this
1395     # because we might add to @files in the loop.
1396     while (scalar @files > 0)
1397     {
1398         $_ = shift @files;
1399
1400         # Configure substitutions in _SOURCES variables are errors.
1401         if (/^\@.*\@$/)
1402         {
1403           my $parent_msg = '';
1404           $parent_msg = "\nand is referred to from `$topparent'"
1405             if $topparent ne $var->name;
1406           err_var ($var,
1407                    "`" . $var->name . "' includes configure substitution `$_'"
1408                    . $parent_msg . ";\nconfigure " .
1409                    "substitutions are not allowed in _SOURCES variables");
1410           next;
1411         }
1412
1413         # If the source file is in a subdirectory then the `.o' is put
1414         # into the current directory, unless the subdir-objects option
1415         # is in effect.
1416
1417         # Split file name into base and extension.
1418         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1419         my $full = $_;
1420         my $directory = $1 || '';
1421         my $base = $2;
1422         my $extension = $3;
1423
1424         # We must generate a rule for the object if it requires its own flags.
1425         my $renamed = 0;
1426         my ($linker, $object);
1427
1428         # This records whether we've seen a derived source file (e.g.
1429         # yacc output).
1430         my $derived_source = 0;
1431
1432         # This holds the `aggregate context' of the file we are
1433         # currently examining.  If the file is compiled with
1434         # per-object flags, then it will be the name of the object.
1435         # Otherwise it will be `AM'.  This is used by the target hook
1436         # language function.
1437         my $aggregate = 'AM';
1438
1439         $extension = &derive_suffix ($extension, $nonansi_obj);
1440         my $lang;
1441         if ($extension_map{$extension} &&
1442             ($lang = $languages{$extension_map{$extension}}))
1443         {
1444             # Found the language, so see what it says.
1445             &saw_extension ($extension);
1446
1447             # Note: computed subr call.  The language rewrite function
1448             # should return one of the LANG_* constants.  It could
1449             # also return a list whose first value is such a constant
1450             # and whose second value is a new source extension which
1451             # should be applied.  This means this particular language
1452             # generates another source file which we must then process
1453             # further.
1454             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1455             my ($r, $source_extension)
1456                 = &$subr ($directory, $base, $extension);
1457             # Skip this entry if we were asked not to process it.
1458             next if $r == LANG_IGNORE;
1459
1460             # Now extract linker and other info.
1461             $linker = $lang->linker;
1462
1463             my $this_obj_ext;
1464             if (defined $source_extension)
1465             {
1466                 $this_obj_ext = $source_extension;
1467                 $derived_source = 1;
1468             }
1469             elsif ($lang->ansi)
1470             {
1471                 $this_obj_ext = $obj;
1472             }
1473             else
1474             {
1475                 $this_obj_ext = $nonansi_obj;
1476             }
1477             $object = $base . $this_obj_ext;
1478
1479             # Do we have per-executable flags for this executable?
1480             my $have_per_exec_flags = 0;
1481             foreach my $flag (@{$lang->flags})
1482               {
1483                 if (set_seen ("${derived}_$flag"))
1484                   {
1485                     $have_per_exec_flags = 1;
1486                     last;
1487                   }
1488               }
1489
1490             if ($have_per_exec_flags)
1491             {
1492                 # We have a per-executable flag in effect for this
1493                 # object.  In this case we rewrite the object's
1494                 # name to ensure it is unique.  We also require
1495                 # the `compile' program to deal with compilers
1496                 # where `-c -o' does not work.
1497
1498                 # We choose the name `DERIVED_OBJECT' to ensure
1499                 # (1) uniqueness, and (2) continuity between
1500                 # invocations.  However, this will result in a
1501                 # name that is too long for losing systems, in
1502                 # some situations.  So we provide _SHORTNAME to
1503                 # override.
1504
1505                 my $dname = $derived;
1506                 my $var = var ($derived . '_SHORTNAME');
1507                 if ($var)
1508                 {
1509                     # FIXME: should use the same Condition as
1510                     # the _SOURCES variable.  But this is really
1511                     # silly overkill -- nobody should have
1512                     # conditional shortnames.
1513                     $dname = $var->variable_value;
1514                 }
1515                 $object = $dname . '-' . $object;
1516
1517                 require_conf_file ("$am_file.am", FOREIGN, 'compile')
1518                     if $lang->name eq 'c';
1519
1520                 prog_error ($lang->name . " flags defined without compiler")
1521                   if ! defined $lang->compile;
1522
1523                 $renamed = 1;
1524             }
1525
1526             # If rewrite said it was ok, put the object into a
1527             # subdir.
1528             if ($r == LANG_SUBDIR && $directory ne '')
1529             {
1530                 $object = $directory . '/' . $object;
1531             }
1532
1533             # If doing dependency tracking, then we can't print
1534             # the rule.  If we have a subdir object, we need to
1535             # generate an explicit rule.  Actually, in any case
1536             # where the object is not in `.' we need a special
1537             # rule.  The per-object rules in this case are
1538             # generated later, by handle_languages.
1539             if ($renamed || $directory ne '')
1540             {
1541                 my $obj_sans_ext = substr ($object, 0,
1542                                            - length ($this_obj_ext));
1543                 my $full_ansi = $full;
1544                 if ($lang->ansi && option 'ansi2knr')
1545                   {
1546                     $full_ansi =~ s/$KNOWN_EXTENSIONS_PATTERN$/\$U$&/;
1547                     $obj_sans_ext .= '$U';
1548                   }
1549
1550                 my $val = ("$full_ansi $obj_sans_ext "
1551                            # Only use $this_obj_ext in the derived
1552                            # source case because in the other case we
1553                            # *don't* want $(OBJEXT) to appear here.
1554                            . ($derived_source ? $this_obj_ext : '.o'));
1555
1556                 # If we renamed the object then we want to use the
1557                 # per-executable flag name.  But if this is simply a
1558                 # subdir build then we still want to use the AM_ flag
1559                 # name.
1560                 if ($renamed)
1561                 {
1562                     $val = "$derived $val";
1563                     $aggregate = $derived;
1564                 }
1565                 else
1566                 {
1567                     $val = "AM $val";
1568                 }
1569
1570                 # Each item on this list is a string consisting of
1571                 # four space-separated values: the derived flag prefix
1572                 # (e.g. for `foo_CFLAGS', it is `foo'), the name of the
1573                 # source file, the base name of the output file, and
1574                 # the extension for the object file.
1575                 push (@{$lang_specific_files{$lang->name}}, $val);
1576             }
1577         }
1578         elsif ($extension eq $nonansi_obj)
1579         {
1580             # This is probably the result of a direct suffix rule.
1581             # In this case we just accept the rewrite.
1582             $object = "$base$extension";
1583             $linker = '';
1584         }
1585         else
1586         {
1587             # No error message here.  Used to have one, but it was
1588             # very unpopular.
1589             # FIXME: we could potentially do more processing here,
1590             # perhaps treating the new extension as though it were a
1591             # new source extension (as above).  This would require
1592             # more restructuring than is appropriate right now.
1593             next;
1594         }
1595
1596         err_am "object `$object' created by `$full' and `$object_map{$object}'"
1597           if (defined $object_map{$object}
1598               && $object_map{$object} ne $full);
1599
1600         my $comp_val = (($object =~ /\.lo$/)
1601                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1602         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1603         if (defined $object_compilation_map{$comp_obj}
1604             && $object_compilation_map{$comp_obj} != 0
1605             # Only see the error once.
1606             && ($object_compilation_map{$comp_obj}
1607                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1608             && $object_compilation_map{$comp_obj} != $comp_val)
1609           {
1610             err_am "object `$comp_obj' created both with libtool and without";
1611           }
1612         $object_compilation_map{$comp_obj} |= $comp_val;
1613
1614         if (defined $lang)
1615         {
1616             # Let the language do some special magic if required.
1617             $lang->target_hook ($aggregate, $object, $full);
1618         }
1619
1620         if ($derived_source)
1621           {
1622             prog_error ($lang->name . " has automatic dependency tracking")
1623               if $lang->autodep ne 'no';
1624             # Make sure this new source file is handled next.  That will
1625             # make it appear to be at the right place in the list.
1626             unshift (@files, $object);
1627             # Distribute derived sources unless the source they are
1628             # derived from is not.
1629             &push_dist_common ($object)
1630               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1631             next;
1632           }
1633
1634         $linkers_used{$linker} = 1;
1635
1636         push (@result, $object);
1637
1638         if (! defined $object_map{$object})
1639         {
1640             my @dep_list = ();
1641             $object_map{$object} = $full;
1642
1643             # If resulting object is in subdir, we need to make
1644             # sure the subdir exists at build time.
1645             if ($object =~ /\//)
1646             {
1647                 # FIXME: check that $DIRECTORY is somewhere in the
1648                 # project
1649
1650                 # For Java, the way we're handling it right now, a
1651                 # `..' component doesn't make sense.
1652                 if ($lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1653                   {
1654                     err_am "`$full' should not contain a `..' component";
1655                   }
1656
1657                 # Make sure object is removed by `make mostlyclean'.
1658                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1659                 # If we have a libtool object then we also must remove
1660                 # the ordinary .o.
1661                 if ($object =~ /\.lo$/)
1662                 {
1663                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1664                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1665
1666                     # Remove any libtool object in this directory.
1667                     $libtool_clean_directories{$directory} = 1;
1668                 }
1669
1670                 push (@dep_list, require_build_directory ($directory));
1671
1672                 # If we're generating dependencies, we also want
1673                 # to make sure that the appropriate subdir of the
1674                 # .deps directory is created.
1675                 push (@dep_list,
1676                       require_build_directory ($directory . '/$(DEPDIR)'))
1677                   unless option 'no-dependencies';
1678             }
1679
1680             &pretty_print_rule ($object . ':', "\t", @dep_list)
1681                 if scalar @dep_list > 0;
1682         }
1683
1684         # Transform .o or $o file into .P file (for automatic
1685         # dependency code).
1686         if ($lang && $lang->autodep ne 'no')
1687         {
1688             my $depfile = $object;
1689             $depfile =~ s/\.([^.]*)$/.P$1/;
1690             $depfile =~ s/\$\(OBJEXT\)$/o/;
1691             $dep_files{dirname ($depfile) . '/$(DEPDIR)/'
1692                            . basename ($depfile)} = 1;
1693         }
1694     }
1695
1696     return @result;
1697 }
1698
1699
1700 # $LINKER
1701 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
1702 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE)
1703 # ---------------------------------------------------------------------
1704 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
1705 #
1706 # Arguments are:
1707 #   $VAR is the name of the _SOURCES variable
1708 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
1709 #     it will be generated and returned).
1710 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
1711 #     work done to determine the linker will be).
1712 #   $ONE_FILE is the canonical (transformed) name of object to build
1713 #   $OBJ is the object extension (i.e. either `.o' or `.lo').
1714 #   $TOPPARENT is the _SOURCES variable being processed.
1715 #   $WHERE context into which this definition is done
1716 #
1717 # Result is a pair ($LINKER, $OBJVAR):
1718 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
1719 sub define_objects_from_sources ($$$$$$$)
1720 {
1721   my ($var, $objvar, $nodefine, $one_file, $obj, $topparent, $where) = @_;
1722
1723   my $needlinker = "";
1724
1725   transform_variable_recursively
1726     ($var, $objvar, 'am__objects', $nodefine, $where,
1727      # The transform code to run on each filename.
1728      sub {
1729        my ($subvar, $val, $cond, $full_cond) = @_;
1730        my @trans = &handle_single_transform_list ($subvar, $topparent,
1731                                                   $one_file, $obj, $val);
1732        $needlinker = "true" if @trans;
1733        return @trans;
1734      });
1735
1736   return $needlinker;
1737 }
1738
1739
1740 # Handle SOURCE->OBJECT transform for one program or library.
1741 # Arguments are:
1742 #   canonical (transformed) name of object to build
1743 #   actual name of object to build
1744 #   object extension (i.e. either `.o' or `$o'.
1745 # Return result is name of linker variable that must be used.
1746 # Empty return means just use `LINK'.
1747 sub handle_source_transform
1748 {
1749     # one_file is canonical name.  unxformed is given name.  obj is
1750     # object extension.
1751     my ($one_file, $unxformed, $obj, $where) = @_;
1752
1753     my ($linker) = '';
1754
1755     # No point in continuing if _OBJECTS is defined.
1756     return if reject_var ($one_file . '_OBJECTS',
1757                           $one_file . '_OBJECTS should not be defined');
1758
1759     my %used_pfx = ();
1760     my $needlinker;
1761     %linkers_used = ();
1762     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1763                         'dist_EXTRA_', 'nodist_EXTRA_')
1764     {
1765         my $varname = $prefix . $one_file . "_SOURCES";
1766         my $var = var $varname;
1767         next unless $var;
1768
1769         # We are going to define _OBJECTS variables using the prefix.
1770         # Then we glom them all together.  So we can't use the null
1771         # prefix here as we need it later.
1772         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
1773
1774         # Keep track of which prefixes we saw.
1775         $used_pfx{$xpfx} = 1
1776           unless $prefix =~ /EXTRA_/;
1777
1778         push @sources, "\$($varname)";
1779         if ($prefix !~ /^nodist_/)
1780           {
1781             # If the VAR wasn't defined conditionally, we add
1782             # it to DIST_SOURCES as is.  Otherwise we create a
1783             # am__VAR_DIST variable which contains all possible values,
1784             # and add this variable to DIST_SOURCES.
1785             my $distvar = $varname;
1786             if ($var->has_conditional_contents)
1787               {
1788                 $distvar = "am__${varname}_DIST";
1789                 my @files =
1790                   uniq ($var->value_as_list_recursive ('all'));
1791                 define_pretty_variable ($distvar, TRUE, $where, @files);
1792               }
1793             push @dist_sources, "\$($distvar)"
1794           }
1795
1796         $needlinker |=
1797             define_objects_from_sources ($varname,
1798                                          $xpfx . $one_file . '_OBJECTS',
1799                                          $prefix =~ /EXTRA_/,
1800                                          $one_file, $obj, $varname, $where);
1801     }
1802     if ($needlinker)
1803     {
1804         $linker ||= &resolve_linker (%linkers_used);
1805     }
1806
1807     my @keys = sort keys %used_pfx;
1808     if (scalar @keys == 0)
1809     {
1810         &define_variable ($one_file . "_SOURCES", $unxformed . ".c", $where);
1811         push (@sources, $unxformed . '.c');
1812         push (@dist_sources, $unxformed . '.c');
1813
1814         %linkers_used = ();
1815         my (@result) =
1816           &handle_single_transform_list ($one_file . '_SOURCES',
1817                                          $one_file . '_SOURCES',
1818                                          $one_file, $obj,
1819                                          "$unxformed.c");
1820         $linker ||= &resolve_linker (%linkers_used);
1821         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
1822     }
1823     else
1824     {
1825         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
1826         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
1827     }
1828
1829     # If we want to use `LINK' we must make sure it is defined.
1830     if ($linker eq '')
1831     {
1832         $need_link = 1;
1833     }
1834
1835     return $linker;
1836 }
1837
1838
1839 # handle_lib_objects ($XNAME, $VAR)
1840 # ---------------------------------
1841 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
1842 # Also, generate _DEPENDENCIES variable if appropriate.
1843 # Arguments are:
1844 #   transformed name of object being built, or empty string if no object
1845 #   name of _LDADD/_LIBADD-type variable to examine
1846 # Returns 1 if LIBOBJS seen, 0 otherwise.
1847 sub handle_lib_objects
1848 {
1849   my ($xname, $varname) = @_;
1850
1851   my $var = var ($varname);
1852   prog_error "handle_lib_objects: `$varname' undefined"
1853     unless $var;
1854   prog_error "handle_lib_objects: unexpected variable name `$varname'"
1855     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
1856   my $prefix = $1 || 'AM_';
1857
1858   my $seen_libobjs = 0;
1859   my $flagvar = 0;
1860
1861   transform_variable_recursively
1862     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
1863      ! $xname, INTERNAL,
1864      # Transformation function, run on each filename.
1865      sub {
1866        my ($subvar, $val, $cond, $full_cond) = @_;
1867
1868        if ($val =~ /^-/)
1869          {
1870            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
1871            if ($val !~ /^-[lL]/ &&
1872                # Skip -dlopen and -dlpreopen; these are explicitly allowed
1873                # for Libtool libraries or programs.  (Actually we are a bit
1874                # laxest here since this code also applies to non-libtool
1875                # libraries or programs, for which -dlopen and -dlopreopen
1876                # are pure non-sence.  Diagnosting this doesn't seems very
1877                # important: the developer will quickly get complaints from
1878                # the linker.)
1879                $val !~ /^-dl(?:pre)?open$/ &&
1880                # Only get this error once.
1881                ! $flagvar)
1882              {
1883                $flagvar = 1;
1884                # FIXME: should display a stack of nested variables
1885                # as context when $var != $subvar.
1886                err_var ($var, "linker flags such as `$val' belong in "
1887                         . "`${prefix}LDFLAGS");
1888              }
1889            return ();
1890          }
1891        elsif ($val !~ /^\@.*\@$/)
1892          {
1893            # Assume we have a file of some sort, and output it into the
1894            # dependency variable.  Autoconf substitutions are not output;
1895            # rarely is a new dependency substituted into e.g. foo_LDADD
1896            # -- but bad things (e.g. -lX11) are routinely substituted.
1897            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
1898            # and handled specially below.
1899            return $val;
1900          }
1901        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
1902          {
1903            handle_LIBOBJS ($subvar, $full_cond, $1);
1904            $seen_libobjs = 1;
1905            return $val;
1906          }
1907        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
1908          {
1909            handle_ALLOCA ($subvar, $full_cond, $1);
1910            return $val;
1911          }
1912        else
1913          {
1914            return ();
1915          }
1916      });
1917
1918   return $seen_libobjs;
1919 }
1920
1921 sub handle_LIBOBJS ($$$)
1922 {
1923   my ($var, $cond, $lt) = @_;
1924   $lt ||= '';
1925   my $myobjext = ($1 ? 'l' : '') . 'o';
1926
1927   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
1928     if ! keys %libsources;
1929
1930   foreach my $iter (keys %libsources)
1931     {
1932       if ($iter =~ /\.[cly]$/)
1933         {
1934           &saw_extension ($&);
1935           &saw_extension ('.c');
1936         }
1937
1938       if ($iter =~ /\.h$/)
1939         {
1940           require_file_with_macro ($cond, $var, FOREIGN, $iter);
1941         }
1942       elsif ($iter ne 'alloca.c')
1943         {
1944           my $rewrite = $iter;
1945           $rewrite =~ s/\.c$/.P$myobjext/;
1946           $dep_files{'$(DEPDIR)/' . $rewrite} = 1;
1947           $rewrite = "^" . quotemeta ($iter) . "\$";
1948           # Only require the file if it is not a built source.
1949           my $bs = var ('BUILT_SOURCES');
1950           if (! $bs
1951               || ! grep (/$rewrite/, $bs->value_as_list_recursive ('all')))
1952             {
1953               require_file_with_macro ($cond, $var, FOREIGN, $iter);
1954             }
1955         }
1956     }
1957 }
1958
1959 sub handle_ALLOCA ($$$)
1960 {
1961   my ($var, $cond, $lt) = @_;
1962   my $myobjext = ($lt ? 'l' : '') . 'o';
1963   $lt ||= '';
1964   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
1965   $dep_files{'$(DEPDIR)/alloca.P' . $myobjext} = 1;
1966   require_file_with_macro ($cond, $var, FOREIGN, 'alloca.c');
1967   &saw_extension ('c');
1968 }
1969
1970 # Canonicalize the input parameter
1971 sub canonicalize
1972 {
1973     my ($string) = @_;
1974     $string =~ tr/A-Za-z0-9_\@/_/c;
1975     return $string;
1976 }
1977
1978 # Canonicalize a name, and check to make sure the non-canonical name
1979 # is never used.  Returns canonical name.  Arguments are name and a
1980 # list of suffixes to check for.
1981 sub check_canonical_spelling
1982 {
1983   my ($name, @suffixes) = @_;
1984
1985   my $xname = &canonicalize ($name);
1986   if ($xname ne $name)
1987     {
1988       foreach my $xt (@suffixes)
1989         {
1990           reject_var ("$name$xt", "use `$xname$xt', not `$name$xt'");
1991         }
1992     }
1993
1994   return $xname;
1995 }
1996
1997
1998 # handle_compile ()
1999 # -----------------
2000 # Set up the compile suite.
2001 sub handle_compile ()
2002 {
2003     return
2004       unless $get_object_extension_was_run;
2005
2006     # Boilerplate.
2007     my $default_includes = '';
2008     if (! option 'nostdinc')
2009       {
2010         $default_includes = ' -I. -I$(srcdir)';
2011
2012         my $var = var 'CONFIG_HEADER';
2013         if ($var)
2014           {
2015             foreach my $hdr (split (' ', $var->variable_value))
2016               {
2017                 $default_includes .= ' -I' . dirname ($hdr);
2018               }
2019           }
2020       }
2021
2022     my (@mostly_rms, @dist_rms);
2023     foreach my $item (sort keys %compile_clean_files)
2024     {
2025         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2026         {
2027             push (@mostly_rms, "\t-rm -f $item");
2028         }
2029         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2030         {
2031             push (@dist_rms, "\t-rm -f $item");
2032         }
2033         else
2034         {
2035           prog_error 'invalid entry in %compile_clean_files';
2036         }
2037     }
2038
2039     my ($coms, $vars, $rules) =
2040       &file_contents_internal (1, "$libdir/am/compile.am",
2041                                new Automake::Location,
2042                                ('DEFAULT_INCLUDES' => $default_includes,
2043                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2044                                 'DISTRMS' => join ("\n", @dist_rms)));
2045     $output_vars .= $vars;
2046     $output_rules .= "$coms$rules";
2047
2048     # Check for automatic de-ANSI-fication.
2049     if (option 'ansi2knr')
2050       {
2051         my ($ansi2knr_filename, $ansi2knr_where) = @{option 'ansi2knr'};
2052         my $ansi2knr_dir = '';
2053
2054         require_variables ($ansi2knr_where, "option `ansi2knr' is used",
2055                            TRUE, "ANSI2KNR", "U");
2056
2057         # topdir is where ansi2knr should be.
2058         if ($ansi2knr_filename eq 'ansi2knr')
2059           {
2060             # Only require ansi2knr files if they should appear in
2061             # this directory.
2062             require_file ($ansi2knr_where, FOREIGN,
2063                           'ansi2knr.c', 'ansi2knr.1');
2064
2065             # ansi2knr needs to be built before subdirs, so unshift it.
2066             unshift (@all, '$(ANSI2KNR)');
2067           }
2068         else
2069           {
2070             $ansi2knr_dir = dirname ($ansi2knr_filename);
2071           }
2072
2073         $output_rules .= &file_contents ('ansi2knr',
2074                                          new Automake::Location,
2075                                          'ANSI2KNR-DIR' => $ansi2knr_dir);
2076
2077     }
2078 }
2079
2080 # handle_libtool ()
2081 # -----------------
2082 # Handle libtool rules.
2083 sub handle_libtool
2084 {
2085   return unless var ('LIBTOOL');
2086
2087   # Libtool requires some files, but only at top level.
2088   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2089     if $relative_dir eq '.';
2090
2091   my @libtool_rms;
2092   foreach my $item (sort keys %libtool_clean_directories)
2093     {
2094       my $dir = ($item eq '.') ? '' : "$item/";
2095       # .libs is for Unix, _libs for DOS.
2096       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2097     }
2098
2099   # Output the libtool compilation rules.
2100   $output_rules .= &file_contents ('libtool',
2101                                    new Automake::Location,
2102                                    LTRMS => join ("\n", @libtool_rms));
2103 }
2104
2105 # handle_programs ()
2106 # ------------------
2107 # Handle C programs.
2108 sub handle_programs
2109 {
2110   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2111                                   'bin', 'sbin', 'libexec', 'pkglib',
2112                                   'noinst', 'check');
2113   return if ! @proglist;
2114
2115   my $seen_global_libobjs =
2116     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2117
2118   foreach my $pair (@proglist)
2119     {
2120       my ($where, $one_file) = @$pair;
2121
2122       my $seen_libobjs = 0;
2123       my $obj = &get_object_extension ($one_file);
2124
2125       # Strip any $(EXEEXT) suffix the user might have added, or this
2126       # will confuse &handle_source_transform and &check_canonical_spelling.
2127       # We'll add $(EXEEXT) back later anyway.
2128       $one_file =~ s/\$\(EXEEXT\)$//;
2129
2130       # Canonicalize names and check for misspellings.
2131       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2132                                              '_SOURCES', '_OBJECTS',
2133                                              '_DEPENDENCIES');
2134
2135       $where->push_context ("while processing program `$one_file'");
2136       $where->set (INTERNAL->get);
2137
2138       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where);
2139
2140       if (var ($xname . "_LDADD"))
2141         {
2142           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2143         }
2144       else
2145         {
2146           # User didn't define prog_LDADD override.  So do it.
2147           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2148
2149           # This does a bit too much work.  But we need it to
2150           # generate _DEPENDENCIES when appropriate.
2151           if (var ('LDADD'))
2152             {
2153               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2154             }
2155         }
2156
2157       reject_var ($xname . '_LIBADD',
2158                   "use `${xname}_LDADD', not `${xname}_LIBADD'");
2159
2160       set_seen ($xname . '_DEPENDENCIES');
2161       set_seen ($xname . '_LDFLAGS');
2162
2163       # Determine program to use for link.
2164       my $xlink;
2165       if (var ($xname . '_LINK'))
2166         {
2167           $xlink = $xname . '_LINK';
2168         }
2169       else
2170         {
2171           $xlink = $linker ? $linker : 'LINK';
2172         }
2173
2174       # If the resulting program lies into a subdirectory,
2175       # make sure this directory will exist.
2176       my $dirstamp = require_build_directory_maybe ($one_file);
2177
2178       $output_rules .= &file_contents ('program',
2179                                        $where,
2180                                        PROGRAM  => $one_file,
2181                                        XPROGRAM => $xname,
2182                                        XLINK    => $xlink,
2183                                        DIRSTAMP => $dirstamp,
2184                                        EXEEXT   => '$(EXEEXT)');
2185
2186       if ($seen_libobjs || $seen_global_libobjs)
2187         {
2188           if (var ($xname . '_LDADD'))
2189             {
2190               &check_libobjs_sources ($xname, $xname . '_LDADD');
2191             }
2192           elsif (var ('LDADD'))
2193             {
2194               &check_libobjs_sources ($xname, 'LDADD');
2195             }
2196         }
2197     }
2198 }
2199
2200
2201 # handle_libraries ()
2202 # -------------------
2203 # Handle libraries.
2204 sub handle_libraries
2205 {
2206   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2207                                  'lib', 'pkglib', 'noinst', 'check');
2208   return if ! @liblist;
2209
2210   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2211                                     'noinst', 'check');
2212
2213   if (@prefix)
2214     {
2215       my $var = rvar ($prefix[0] . '_LIBRARIES');
2216       $var->requires_variables ('library used', 'RANLIB');
2217     }
2218
2219   foreach my $pair (@liblist)
2220     {
2221       my ($where, $onelib) = @$pair;
2222
2223       my $seen_libobjs = 0;
2224       # Check that the library fits the standard naming convention.
2225       if (basename ($onelib) !~ /^lib.*\.a/)
2226         {
2227           error $where, "`$onelib' is not a standard library name";
2228         }
2229
2230       $where->push_context ("while processing library `$onelib'");
2231       $where->set (INTERNAL->get);
2232
2233       my $obj = &get_object_extension ($onelib);
2234
2235       # Canonicalize names and check for misspellings.
2236       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2237                                             '_OBJECTS', '_DEPENDENCIES',
2238                                             '_AR');
2239
2240       if (! var ($xlib . '_AR'))
2241         {
2242           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2243         }
2244
2245       # Generate support for conditional object inclusion in
2246       # libraries.
2247       if (var ($xlib . '_LIBADD'))
2248         {
2249           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2250             {
2251               $seen_libobjs = 1;
2252             }
2253         }
2254       else
2255         {
2256           &define_variable ($xlib . "_LIBADD", '', $where);
2257         }
2258
2259       reject_var ($xlib . '_LDADD',
2260                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2261
2262       # Make sure we at look at this.
2263       set_seen ($xlib . '_DEPENDENCIES');
2264
2265       &handle_source_transform ($xlib, $onelib, $obj, $where);
2266
2267       # If the resulting library lies into a subdirectory,
2268       # make sure this directory will exist.
2269       my $dirstamp = require_build_directory_maybe ($onelib);
2270
2271       $output_rules .= &file_contents ('library',
2272                                        $where,
2273                                        LIBRARY  => $onelib,
2274                                        XLIBRARY => $xlib,
2275                                        DIRSTAMP => $dirstamp);
2276
2277       if ($seen_libobjs)
2278         {
2279           if (var ($xlib . '_LIBADD'))
2280             {
2281               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2282             }
2283         }
2284     }
2285 }
2286
2287
2288 # handle_ltlibraries ()
2289 # ---------------------
2290 # Handle shared libraries.
2291 sub handle_ltlibraries
2292 {
2293   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2294                                  'noinst', 'lib', 'pkglib', 'check');
2295   return if ! @liblist;
2296
2297   my %instdirs;
2298   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2299                                     'noinst', 'check');
2300
2301   if (@prefix)
2302     {
2303       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2304       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2305     }
2306
2307   my %liblocations = ();        # Location (in Makefile.am) of each library.
2308
2309   foreach my $key (@prefix)
2310     {
2311       # Get the installation directory of each library.
2312       (my $dir = $key) =~ s/^nobase_//;
2313       my $var = rvar ($key . '_LTLIBRARIES');
2314       for my $pair ($var->loc_and_value_as_list_recursive ('all'))
2315         {
2316           my ($where, $lib) = @$pair;
2317           # We reject libraries which are installed in several places,
2318           # because we don't handle this in the rules (think `-rpath').
2319           #
2320           # However, we allow the same library to be listed many times
2321           # for the same directory.  This is for users who need setups
2322           # like
2323           #   if COND1
2324           #     lib_LTLIBRARIES = libfoo.la
2325           #   endif
2326           #   if COND2
2327           #     lib_LTLIBRARIES = libfoo.la
2328           #   endif
2329           #
2330           # Actually this will also allow
2331           #   lib_LTLIBRARIES = libfoo.la libfoo.la
2332           # Diagnosing this case doesn't seem worth the plain (we'd
2333           # have to fill $instdirs on a per-condition basis, check
2334           # implied conditions, etc.)
2335           if (defined $instdirs{$lib} && $instdirs{$lib} ne $dir)
2336             {
2337               error ($where, "`$lib' is already going to be installed in "
2338                      . "`$instdirs{$lib}'", partial => 1);
2339               error ($liblocations{$lib}, "`$lib' previously declared here");
2340             }
2341           else
2342             {
2343               $instdirs{$lib} = $dir;
2344               $liblocations{$lib} = $where->clone;
2345             }
2346         }
2347     }
2348
2349   foreach my $pair (@liblist)
2350     {
2351       my ($where, $onelib) = @$pair;
2352
2353       my $seen_libobjs = 0;
2354       my $obj = &get_object_extension ($onelib);
2355
2356       # Canonicalize names and check for misspellings.
2357       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2358                                             '_SOURCES', '_OBJECTS',
2359                                             '_DEPENDENCIES');
2360
2361       # Check that the library fits the standard naming convention.
2362       my $libname_rx = "^lib.*\.la";
2363       my $ldvar = var ("${xlib}_LDFLAGS") || var ('LDFLAGS');
2364       if ($ldvar && grep (/-module/, $ldvar->value_as_list_recursive ('all')))
2365         {
2366           # Relax name checking for libtool modules.
2367           $libname_rx = "\.la";
2368         }
2369       if (basename ($onelib) !~ /$libname_rx$/)
2370         {
2371           msg ('error-gnu/warn', $where,
2372                "`$onelib' is not a standard libtool library name");
2373         }
2374
2375       $where->push_context ("while processing Libtool library `$onelib'");
2376       $where->set (INTERNAL->get);
2377
2378       # Make sure we at look at these.
2379       set_seen ($xlib . '_LDFLAGS');
2380       set_seen ($xlib . '_DEPENDENCIES');
2381
2382       # Generate support for conditional object inclusion in
2383       # libraries.
2384       if (var ($xlib . '_LIBADD'))
2385         {
2386           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2387             {
2388               $seen_libobjs = 1;
2389             }
2390         }
2391       else
2392         {
2393           &define_variable ($xlib . "_LIBADD", '', $where);
2394         }
2395
2396       reject_var ("${xlib}_LDADD",
2397                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2398
2399
2400       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where);
2401
2402       # Determine program to use for link.
2403       my $xlink;
2404       if (var ($xlib . '_LINK'))
2405         {
2406           $xlink = $xlib . '_LINK';
2407         }
2408       else
2409         {
2410           $xlink = $linker ? $linker : 'LINK';
2411         }
2412
2413       my $rpath;
2414       if ($instdirs{$onelib} eq 'EXTRA'
2415           || $instdirs{$onelib} eq 'noinst'
2416           || $instdirs{$onelib} eq 'check')
2417         {
2418           # It's an EXTRA_ library, so we can't specify -rpath,
2419           # because we don't know where the library will end up.
2420           # The user probably knows, but generally speaking automake
2421           # doesn't -- and in fact configure could decide
2422           # dynamically between two different locations.
2423           $rpath = '';
2424         }
2425       else
2426         {
2427           $rpath = ('-rpath $(' . $instdirs{$onelib} . 'dir)');
2428         }
2429
2430       # If the resulting library lies into a subdirectory,
2431       # make sure this directory will exist.
2432       my $dirstamp = require_build_directory_maybe ($onelib);
2433
2434       # Remember to cleanup .libs/ in this directory.
2435       my $dirname = dirname $onelib;
2436       $libtool_clean_directories{$dirname} = 1;
2437
2438       $output_rules .= &file_contents ('ltlibrary',
2439                                        $where,
2440                                        LTLIBRARY  => $onelib,
2441                                        XLTLIBRARY => $xlib,
2442                                        RPATH      => $rpath,
2443                                        XLINK      => $xlink,
2444                                        DIRSTAMP   => $dirstamp);
2445       if ($seen_libobjs)
2446         {
2447           if (var ($xlib . '_LIBADD'))
2448             {
2449               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2450             }
2451         }
2452     }
2453 }
2454
2455 # See if any _SOURCES variable were misspelled.
2456 sub check_typos ()
2457 {
2458   # It is ok if the user sets this particular variable.
2459   set_seen 'AM_LDFLAGS';
2460
2461   foreach my $var (variables)
2462     {
2463       my $varname = $var->name;
2464       # A configure variable is always legitimate.
2465       next if exists $configure_vars{$varname};
2466
2467       my $check = 0;
2468       foreach my $primary ('_SOURCES', '_LIBADD', '_LDADD', '_LDFLAGS',
2469                            '_DEPENDENCIES')
2470         {
2471           if ($varname =~ /$primary$/)
2472             {
2473               $check = 1;
2474               last;
2475             }
2476         }
2477       next unless $check;
2478
2479       for my $cond ($var->conditions->conds)
2480         {
2481           msg_var 'syntax', $var, "unused variable: `$varname'"
2482             unless $var->rdef ($cond)->seen;
2483         }
2484     }
2485 }
2486
2487
2488 # Handle scripts.
2489 sub handle_scripts
2490 {
2491     # NOTE we no longer automatically clean SCRIPTS, because it is
2492     # useful to sometimes distribute scripts verbatim.  This happens
2493     # e.g. in Automake itself.
2494     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2495                      'bin', 'sbin', 'libexec', 'pkgdata',
2496                      'noinst', 'check');
2497 }
2498
2499
2500
2501
2502 ## ------------------------ ##
2503 ## Handling Texinfo files.  ##
2504 ## ------------------------ ##
2505
2506 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2507 # &scan_texinfo_file ($FILENAME)
2508 # ------------------------------
2509 # $OUTFILE     - name of the info file produced by $FILENAME.
2510 # $VFILE       - name of the version.texi file used (undef if none).
2511 # @CLEAN_FILES - list of byproducts (indexes etc.)
2512 sub scan_texinfo_file ($)
2513 {
2514   my ($filename) = @_;
2515
2516   # Some of the following extensions are always created, no matter
2517   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2518   # are only created when they are used.  We used to scan $FILENAME
2519   # for their use, but that is not enough: they could be used in
2520   # included files.  We can't scan included files because we don't
2521   # know the include path.  Therefore we always erase these files, no
2522   # matter whether they are used or not.
2523   #
2524   # (tmp is only created if an @macro is used and a certain e-TeX
2525   # feature is not available.)
2526   my %clean_suffixes =
2527     map { $_ => 1 } (qw(aux log toc tmp
2528                         cp cps
2529                         fn fns
2530                         ky kys
2531                         vr vrs
2532                         tp tps
2533                         pg pgs)); # grep 'new.*index' texinfo.tex
2534
2535   my $texi = new Automake::XFile "< $filename";
2536   verb "reading $filename";
2537
2538   my ($outfile, $vfile);
2539   while ($_ = $texi->getline)
2540     {
2541       if (/^\@setfilename +(\S+)/)
2542         {
2543           # Honor only the first @setfilename.  (It's possible to have
2544           # more occurrences later if the manual shows examples of how
2545           # to use @setfilename...)
2546           next if $outfile;
2547
2548           $outfile = $1;
2549           if ($outfile =~ /\.(.+)$/ && $1 ne 'info')
2550             {
2551               error ("$filename:$.",
2552                      "output `$outfile' has unrecognized extension");
2553               return;
2554             }
2555         }
2556       # A "version.texi" file is actually any file whose name matches
2557       # "vers*.texi".
2558       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
2559         {
2560           $vfile = $1;
2561         }
2562
2563       # Try to find new or unused indexes.
2564
2565       # Creating a new category of index.
2566       elsif (/^\@def(code)?index (\w+)/)
2567         {
2568           $clean_suffixes{$2} = 1;
2569           $clean_suffixes{"$2s"} = 1;
2570         }
2571
2572       # Merging an index into an another.
2573       elsif (/^\@syn(code)?index (\w+) (\w+)/)
2574         {
2575           delete $clean_suffixes{"$2s"};
2576           $clean_suffixes{"$3s"} = 1;
2577         }
2578
2579     }
2580
2581   if ($outfile eq '')
2582     {
2583       err_am "`$filename' missing \@setfilename";
2584       return;
2585     }
2586
2587   my $infobase = basename ($filename);
2588   $infobase =~ s/\.te?xi(nfo)?$//;
2589   return ($outfile, $vfile,
2590           map { "$infobase.$_" } (sort keys %clean_suffixes));
2591 }
2592
2593
2594 # ($DIRSTAMP, @CLEAN_FILES)
2595 # output_texinfo_build_rules ($SOURCE, $DEST, @DEPENDENCIES)
2596 # ----------------------------------------------------------
2597 # SOURCE - the source Texinfo file
2598 # DEST - the destination Info file
2599 # DEPENDENCIES - known dependencies
2600 sub output_texinfo_build_rules ($$@)
2601 {
2602   my ($source, $dest, @deps) = @_;
2603
2604   # Split `a.texi' into `a' and `.texi'.
2605   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
2606   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
2607
2608   $ssfx ||= "";
2609   $dsfx ||= "";
2610
2611   # We can output two kinds of rules: the "generic" rules use Make
2612   # suffix rules and are appropriate when $source and $dest lie in
2613   # the current directory; the "specific" rules are needed in the other
2614   # case.
2615   #
2616   # The former are output only once (this is not really apparent here,
2617   # but just remember that some logic deeper in Automake will not
2618   # output the same rule twice); while the later need to be output for
2619   # each Texinfo source.
2620   my $generic;
2621   my $makeinfoflags;
2622   my $sdir = dirname $source;
2623   if ($sdir eq '.' && dirname ($dest) eq '.')
2624     {
2625       $generic = 1;
2626       $makeinfoflags = '-I $(srcdir)';
2627     }
2628   else
2629     {
2630       $generic = 0;
2631       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
2632     }
2633
2634   # We cannot use a suffix rule to build info files with an empty
2635   # extension.  Otherwise we would output a single suffix inference
2636   # rule, with separate dependencies, as in
2637   #
2638   #    .texi:
2639   #             $(MAKEINFO) ...
2640   #    foo.info: foo.texi
2641   #
2642   # which confuse Solaris make.  (See the Autoconf manual for
2643   # details.)  Therefore we use a specific rule in this case.  This
2644   # applies to info files only (dvi and pdf files always have an
2645   # extension).
2646   my $generic_info = ($generic && $dsfx) ? 1 : 0;
2647
2648   # If the resulting file lie into a subdirectory,
2649   # make sure this directory will exist.
2650   my $dirstamp = require_build_directory_maybe ($dest);
2651
2652   $output_rules .= file_contents ('texibuild',
2653                                   new Automake::Location,
2654                                   GENERIC       => $generic,
2655                                   GENERIC_INFO  => $generic_info,
2656                                   SOURCE_SUFFIX => $ssfx,
2657                                   SOURCE => ($generic ? '$<' : $source),
2658                                   SOURCE_INFO   => ($generic_info ?
2659                                                     '$<' : $source),
2660                                   SOURCE_REAL   => $source,
2661                                   DEST_PREFIX   => $dpfx,
2662                                   DEST_SUFFIX   => $dsfx,
2663                                   MAKEINFOFLAGS => $makeinfoflags,
2664                                   DEPS          => "@deps",
2665                                   DIRSTAMP      => $dirstamp);
2666   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
2667 }
2668
2669
2670 # $TEXICLEANS
2671 # handle_texinfo_helper ($info_texinfos)
2672 # --------------------------------------
2673 # Handle all Texinfo source; helper for handle_texinfo.
2674 sub handle_texinfo_helper ($)
2675 {
2676   my ($info_texinfos) = @_;
2677   my (@infobase, @info_deps_list, @texi_deps);
2678   my %versions;
2679   my $done = 0;
2680   my @texi_cleans;
2681
2682   foreach my $texi ($info_texinfos->value_as_list_recursive ('all'))
2683     {
2684       my $infobase = $texi;
2685       $infobase =~ s/\.(txi|texinfo|texi)$//;
2686
2687       if ($infobase eq $texi)
2688         {
2689           # FIXME: report line number.
2690           err_am "texinfo file `$texi' has unrecognized extension";
2691           next;
2692         }
2693
2694       push @infobase, $infobase;
2695
2696       # If 'version.texi' is referenced by input file, then include
2697       # automatic versioning capability.
2698       my ($out_file, $vtexi, @clean_files) =
2699         scan_texinfo_file ("$relative_dir/$texi")
2700         or next;
2701       push (@texi_cleans, @clean_files);
2702
2703       # If the Texinfo source is in a subdirectory, create the
2704       # resulting info in this subdirectory.  If it is in the current
2705       # directory, try hard to not prefix "./" because it breaks the
2706       # generic rules.
2707       my $outdir = dirname ($texi) . '/';
2708       $outdir = "" if $outdir eq './';
2709       $out_file =  $outdir . $out_file;
2710
2711       # If user specified file_TEXINFOS, then use that as explicit
2712       # dependency list.
2713       @texi_deps = ();
2714       push (@texi_deps, "$outdir$vtexi") if $vtexi;
2715
2716       my $canonical = canonicalize ($infobase);
2717       if (var ($canonical . "_TEXINFOS"))
2718         {
2719           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
2720           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
2721         }
2722
2723       my ($dirstamp, @cfiles) =
2724         output_texinfo_build_rules ($texi, $out_file, @texi_deps);
2725       push (@texi_cleans, @cfiles);
2726
2727       push (@info_deps_list, $out_file);
2728
2729       # If a vers*.texi file is needed, emit the rule.
2730       if ($vtexi)
2731         {
2732           err_am ("`$vtexi', included in `$texi', "
2733                   . "also included in `$versions{$vtexi}'")
2734             if defined $versions{$vtexi};
2735           $versions{$vtexi} = $texi;
2736
2737           # We number the stamp-vti files.  This is doable since the
2738           # actual names don't matter much.  We only number starting
2739           # with the second one, so that the common case looks nice.
2740           my $vti = ($done ? $done : 'vti');
2741           ++$done;
2742
2743           # This is ugly, but it is our historical practice.
2744           if ($config_aux_dir_set_in_configure_in)
2745             {
2746               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
2747                                             'mdate-sh');
2748             }
2749           else
2750             {
2751               require_file_with_macro (TRUE, 'info_TEXINFOS',
2752                                        FOREIGN, 'mdate-sh');
2753             }
2754
2755           my $conf_dir;
2756           if ($config_aux_dir_set_in_configure_in)
2757             {
2758               $conf_dir = $config_aux_dir;
2759               $conf_dir .= '/' unless $conf_dir =~ /\/$/;
2760             }
2761           else
2762             {
2763               $conf_dir = '$(srcdir)/';
2764             }
2765           $output_rules .= file_contents ('texi-vers',
2766                                           new Automake::Location,
2767                                           TEXI     => $texi,
2768                                           VTI      => $vti,
2769                                           STAMPVTI => "${outdir}stamp-$vti",
2770                                           VTEXI    => "$outdir$vtexi",
2771                                           MDDIR    => $conf_dir,
2772                                           DIRSTAMP => $dirstamp);
2773         }
2774     }
2775
2776   # Handle location of texinfo.tex.
2777   my $need_texi_file = 0;
2778   my $texinfodir;
2779   if (var ('TEXINFO_TEX'))
2780     {
2781       # The user defined TEXINFO_TEX so assume he knows what he is
2782       # doing.
2783       $texinfodir = ('$(srcdir)/'
2784                      . dirname (variable_value ('TEXINFO_TEX')));
2785     }
2786   elsif (option 'cygnus')
2787     {
2788       $texinfodir = '$(top_srcdir)/../texinfo';
2789       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
2790     }
2791   elsif ($config_aux_dir_set_in_configure_in)
2792     {
2793       $texinfodir = $config_aux_dir;
2794       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
2795       $need_texi_file = 2; # so that we require_conf_file later
2796     }
2797   else
2798     {
2799       $texinfodir = '$(srcdir)';
2800       $need_texi_file = 1;
2801     }
2802   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
2803
2804   push (@dist_targets, 'dist-info');
2805
2806   if (! option 'no-installinfo')
2807     {
2808       # Make sure documentation is made and installed first.  Use
2809       # $(INFO_DEPS), not 'info', because otherwise recursive makes
2810       # get run twice during "make all".
2811       unshift (@all, '$(INFO_DEPS)');
2812     }
2813
2814   define_variable ("INFO_DEPS", "@info_deps_list", INTERNAL);
2815   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
2816   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
2817   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
2818   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
2819
2820   # This next isn't strictly needed now -- the places that look here
2821   # could easily be changed to look in info_TEXINFOS.  But this is
2822   # probably better, in case noinst_TEXINFOS is ever supported.
2823   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
2824
2825   # Do some error checking.  Note that this file is not required
2826   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
2827   # up above.
2828   if ($need_texi_file && ! option 'no-texinfo.tex')
2829     {
2830       if ($need_texi_file > 1)
2831         {
2832           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
2833                                         'texinfo.tex');
2834         }
2835       else
2836         {
2837           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
2838                                    'texinfo.tex');
2839         }
2840     }
2841
2842   return makefile_wrap ("", "\t  ", @texi_cleans);
2843 }
2844
2845
2846 # handle_texinfo ()
2847 # -----------------
2848 # Handle all Texinfo source.
2849 sub handle_texinfo ()
2850 {
2851   reject_var 'TEXINFOS', "`TEXINFOS' is an anachronism; use `info_TEXINFOS'";
2852   # FIXME: I think this is an obsolete future feature name.
2853   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
2854
2855   my $info_texinfos = var ('info_TEXINFOS');
2856   my $texiclean = "";
2857   if ($info_texinfos)
2858     {
2859       $texiclean = handle_texinfo_helper ($info_texinfos);
2860     }
2861   $output_rules .=  file_contents ('texinfos',
2862                                    new Automake::Location,
2863                                    TEXICLEAN     => $texiclean,
2864                                    'LOCAL-TEXIS' => !!$info_texinfos);
2865 }
2866
2867
2868 # Handle any man pages.
2869 sub handle_man_pages
2870 {
2871   reject_var 'MANS', "`MANS' is an anachronism; use `man_MANS'";
2872
2873   # Find all the sections in use.  We do this by first looking for
2874   # "standard" sections, and then looking for any additional
2875   # sections used in man_MANS.
2876   my (%sections, %vlist);
2877   # We handle nodist_ for uniformity.  man pages aren't distributed
2878   # by default so it isn't actually very important.
2879   foreach my $pfx ('', 'dist_', 'nodist_')
2880     {
2881       # Add more sections as needed.
2882       foreach my $section ('0'..'9', 'n', 'l')
2883         {
2884           my $varname = $pfx . 'man' . $section . '_MANS';
2885           if (var ($varname))
2886             {
2887               $sections{$section} = 1;
2888               $varname = '$(' . $varname . ')';
2889               $vlist{$varname} = 1;
2890
2891               &push_dist_common ($varname)
2892                 if $pfx eq 'dist_';
2893             }
2894         }
2895
2896       my $varname = $pfx . 'man_MANS';
2897       my $var = var ($varname);
2898       if ($var)
2899         {
2900           foreach ($var->value_as_list_recursive ('all'))
2901             {
2902               # A page like `foo.1c' goes into man1dir.
2903               if (/\.([0-9a-z])([a-z]*)$/)
2904                 {
2905                   $sections{$1} = 1;
2906                 }
2907             }
2908
2909           $varname = '$(' . $varname . ')';
2910           $vlist{$varname} = 1;
2911           &push_dist_common ($varname)
2912             if $pfx eq 'dist_';
2913         }
2914     }
2915
2916   return unless %sections;
2917
2918   # Now for each section, generate an install and uninstall rule.
2919   # Sort sections so output is deterministic.
2920   foreach my $section (sort keys %sections)
2921     {
2922       $output_rules .= &file_contents ('mans',
2923                                        new Automake::Location,
2924                                        SECTION => $section);
2925     }
2926
2927   my @mans = sort keys %vlist;
2928   $output_vars .= file_contents ('mans-vars',
2929                                  new Automake::Location,
2930                                  MANS => "@mans");
2931
2932   push (@all, '$(MANS)')
2933     unless option 'no-installman';
2934 }
2935
2936 # Handle DATA variables.
2937 sub handle_data
2938 {
2939     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
2940                      'data', 'sysconf', 'sharedstate', 'localstate',
2941                      'pkgdata', 'lisp', 'noinst', 'check');
2942 }
2943
2944 # Handle TAGS.
2945 sub handle_tags
2946 {
2947     my @tag_deps = ();
2948     my @ctag_deps = ();
2949     if (var ('SUBDIRS'))
2950     {
2951         $output_rules .= ("tags-recursive:\n"
2952                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
2953                           # Never fail here if a subdir fails; it
2954                           # isn't important.
2955                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
2956                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
2957                           . "\tdone\n");
2958         push (@tag_deps, 'tags-recursive');
2959         &depend ('.PHONY', 'tags-recursive');
2960
2961         $output_rules .= ("ctags-recursive:\n"
2962                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
2963                           # Never fail here if a subdir fails; it
2964                           # isn't important.
2965                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
2966                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
2967                           . "\tdone\n");
2968         push (@ctag_deps, 'ctags-recursive');
2969         &depend ('.PHONY', 'ctags-recursive');
2970     }
2971
2972     if (&saw_sources_p (1)
2973         || var ('ETAGS_ARGS')
2974         || @tag_deps)
2975     {
2976         my @config;
2977         foreach my $spec (@config_headers)
2978         {
2979             my ($out, @ins) = split_config_file_spec ($spec);
2980             foreach my $in (@ins)
2981               {
2982                 # If the config header source is in this directory,
2983                 # require it.
2984                 push @config, basename ($in)
2985                   if $relative_dir eq dirname ($in);
2986               }
2987         }
2988         $output_rules .= &file_contents ('tags',
2989                                          new Automake::Location,
2990                                          CONFIG    => "@config",
2991                                          TAGSDIRS  => "@tag_deps",
2992                                          CTAGSDIRS => "@ctag_deps");
2993
2994         set_seen 'TAGS_DEPENDENCIES';
2995     }
2996     elsif (reject_var ('TAGS_DEPENDENCIES',
2997                        "doesn't make sense to define `TAGS_DEPENDENCIES'"
2998                        . "without\nsources or `ETAGS_ARGS'"))
2999     {
3000     }
3001     else
3002     {
3003         # Every Makefile must define some sort of TAGS rule.
3004         # Otherwise, it would be possible for a top-level "make TAGS"
3005         # to fail because some subdirectory failed.
3006         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3007         # Ditto ctags.
3008         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3009     }
3010 }
3011
3012 # Handle multilib support.
3013 sub handle_multilib
3014 {
3015   if ($seen_multilib && $relative_dir eq '.')
3016     {
3017       $output_rules .= &file_contents ('multilib', new Automake::Location);
3018       push (@all, 'all-multi');
3019     }
3020 }
3021
3022
3023 # $BOOLEAN
3024 # &for_dist_common ($A, $B)
3025 # -------------------------
3026 # Subroutine for &handle_dist: sort files to dist.
3027 #
3028 # We put README first because it then becomes easier to make a
3029 # Usenet-compliant shar file (in these, README must be first).
3030 #
3031 # FIXME: do more ordering of files here.
3032 sub for_dist_common
3033 {
3034     return 0
3035         if $a eq $b;
3036     return -1
3037         if $a eq 'README';
3038     return 1
3039         if $b eq 'README';
3040     return $a cmp $b;
3041 }
3042
3043
3044 # handle_dist ($MAKEFILE)
3045 # -----------------------
3046 # Handle 'dist' target.
3047 sub handle_dist
3048 {
3049   my ($makefile) = @_;
3050
3051   # `make dist' isn't used in a Cygnus-style tree.
3052   # Omit the rules so that people don't try to use them.
3053   return if option 'cygnus';
3054
3055   # At least one of the archive formats must be enabled.
3056   if ($relative_dir eq '.')
3057     {
3058       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3059       $archive_defined ||=
3060         grep { option "dist-$_" } ('shar', 'zip', 'tarZ', 'bzip2');
3061       error (option 'no-dist-gzip',
3062              "no-dist-gzip specified but no dist-* specified, "
3063              . "at least one archive format must be enabled")
3064         unless $archive_defined;
3065     }
3066
3067   # Look for common files that should be included in distribution.
3068   # If the aux dir is set, and it does not have a Makefile.am, then
3069   # we check for these files there as well.
3070   my $check_aux = 0;
3071   my $auxdir = '';
3072   if ($relative_dir eq '.'
3073       && $config_aux_dir_set_in_configure_in)
3074     {
3075       ($auxdir = $config_aux_dir) =~ s,^\$\(top_srcdir\)/,,;
3076       if (! &is_make_dir ($auxdir))
3077         {
3078           $check_aux = 1;
3079         }
3080     }
3081   foreach my $cfile (@common_files)
3082     {
3083       if (-f ($relative_dir . "/" . $cfile)
3084           # The file might be absent, but if it can be built it's ok.
3085           || rule $cfile)
3086         {
3087           &push_dist_common ($cfile);
3088         }
3089
3090       # Don't use `elsif' here because a file might meaningfully
3091       # appear in both directories.
3092       if ($check_aux && -f ($auxdir . '/' . $cfile))
3093         {
3094           &push_dist_common ($auxdir . '/' . $cfile);
3095         }
3096     }
3097
3098   # We might copy elements from $configure_dist_common to
3099   # %dist_common if we think we need to.  If the file appears in our
3100   # directory, we would have discovered it already, so we don't
3101   # check that.  But if the file is in a subdir without a Makefile,
3102   # we want to distribute it here if we are doing `.'.  Ugly!
3103   if ($relative_dir eq '.')
3104     {
3105       foreach my $file (split (' ' , $configure_dist_common))
3106         {
3107           push_dist_common ($file)
3108             unless is_make_dir (dirname ($file));
3109         }
3110     }
3111
3112   # Files to distributed.  Don't use ->value_as_list_recursive
3113   # as it recursively expands `$(dist_pkgdata_DATA)' etc.
3114   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3115   @dist_common = uniq (sort for_dist_common (@dist_common));
3116   variable_delete 'DIST_COMMON';
3117   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3118
3119   # Now that we've processed DIST_COMMON, disallow further attempts
3120   # to set it.
3121   $handle_dist_run = 1;
3122
3123   # Scan EXTRA_DIST to see if we need to distribute anything from a
3124   # subdir.  If so, add it to the list.  I didn't want to do this
3125   # originally, but there were so many requests that I finally
3126   # relented.
3127   my $extra_dist = var ('EXTRA_DIST');
3128   if ($extra_dist)
3129     {
3130       # FIXME: This should be fixed to work with conditions.  That
3131       # will require only making the entries in %dist_dirs under the
3132       # appropriate condition.  This is meaningful if the nature of
3133       # the distribution should depend upon the configure options
3134       # used.
3135       foreach ($extra_dist->value_as_list_recursive ('all'))
3136         {
3137           next if /^\@.*\@$/;
3138           next unless s,/+[^/]+$,,;
3139           $dist_dirs{$_} = 1
3140             unless $_ eq '.';
3141         }
3142     }
3143
3144   # We have to check DIST_COMMON for extra directories in case the
3145   # user put a source used in AC_OUTPUT into a subdir.
3146   my $topsrcdir = backname ($relative_dir);
3147   foreach (rvar ('DIST_COMMON')->value_as_list_recursive ('all'))
3148     {
3149       next if /^\@.*\@$/;
3150       s/\$\(top_srcdir\)/$topsrcdir/;
3151       s/\$\(srcdir\)/./;
3152       # Strip any leading `./'.
3153       s,^(:?\./+)*,,;
3154       next unless s,/+[^/]+$,,;
3155       $dist_dirs{$_} = 1
3156         unless $_ eq '.';
3157     }
3158
3159   # Rule to check whether a distribution is viable.
3160   my %transform = ('DISTCHECK-HOOK' => !! rule 'distcheck-hook',
3161                    'GETTEXT' => $seen_gettext && !$seen_gettext_external);
3162
3163   # Prepend $(distdir) to each directory given.
3164   my %rewritten = map { '$(distdir)/' . "$_" => 1 } keys %dist_dirs;
3165   $transform{'DISTDIRS'} = join (' ', sort keys %rewritten);
3166
3167   # If we have SUBDIRS, create all dist subdirectories and do
3168   # recursive build.
3169   my $subdirs = var ('SUBDIRS');
3170   if ($subdirs)
3171     {
3172       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3173       # to all possible directories, and use it.  If DIST_SUBDIRS is
3174       # defined, just use it.
3175       my $dist_subdir_name;
3176       # Note that we check DIST_SUBDIRS first on purpose, so that
3177       # we don't call has_conditional_contents for now reason.
3178       # (In the past one project used so many conditional subdirectories
3179       # that calling has_conditional_contents on SUBDIRS caused
3180       # automake to grow to 150Mb -- this should not happen with
3181       # the current implementation of has_conditional_contents,
3182       # but it's more efficient to avoid the call anyway.)
3183       if (var ('DIST_SUBDIRS'))
3184         {
3185           $dist_subdir_name = 'DIST_SUBDIRS';
3186         }
3187       elsif ($subdirs->has_conditional_contents)
3188         {
3189           $dist_subdir_name = 'DIST_SUBDIRS';
3190           define_pretty_variable
3191             ('DIST_SUBDIRS', TRUE, INTERNAL,
3192              uniq ($subdirs->value_as_list_recursive ('all')));
3193         }
3194       else
3195         {
3196           $dist_subdir_name = 'SUBDIRS';
3197           # We always define this because that is what `distclean'
3198           # wants.
3199           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3200                                   '$(SUBDIRS)');
3201         }
3202
3203       $transform{'DIST_SUBDIR_NAME'} = $dist_subdir_name;
3204     }
3205
3206   # If the target `dist-hook' exists, make sure it is run.  This
3207   # allows users to do random weird things to the distribution
3208   # before it is packaged up.
3209   push (@dist_targets, 'dist-hook')
3210     if rule 'dist-hook';
3211   $transform{'DIST-TARGETS'} = join(' ', @dist_targets);
3212
3213   $output_rules .= &file_contents ('distdir',
3214                                    new Automake::Location,
3215                                    %transform);
3216 }
3217
3218
3219 # &handle_subdirs ()
3220 # ------------------
3221 # Handle subdirectories.
3222 sub handle_subdirs ()
3223 {
3224   my $subdirs = var ('SUBDIRS');
3225   return
3226     unless $subdirs;
3227
3228   my @subdirs = $subdirs->value_as_list_recursive ('all');
3229   my @dsubdirs = ();
3230   my $dsubdirs = var ('DIST_SUBDIRS');
3231   @dsubdirs = $dsubdirs->value_as_list_recursive ('all')
3232     if $dsubdirs;
3233
3234   # If an `obj/' directory exists, BSD make will enter it before
3235   # reading `Makefile'.  Hence the `Makefile' in the current directory
3236   # will not be read.
3237   #
3238   #  % cat Makefile
3239   #  all:
3240   #          echo Hello
3241   #  % cat obj/Makefile
3242   #  all:
3243   #          echo World
3244   #  % make      # GNU make
3245   #  echo Hello
3246   #  Hello
3247   #  % pmake     # BSD make
3248   #  echo World
3249   #  World
3250   msg_var ('portability', 'SUBDIRS',
3251            "naming a subdirectory `obj' causes troubles with BSD make")
3252     if grep ($_ eq 'obj', @subdirs);
3253   msg_var ('portability', 'DIST_SUBDIRS',
3254            "naming a subdirectory `obj' causes troubles with BSD make")
3255     if grep ($_ eq 'obj', @dsubdirs);
3256
3257   # Make sure each directory mentioned in SUBDIRS actually exists.
3258   foreach my $dir (@subdirs)
3259     {
3260       # Skip directories substituted by configure.
3261       next if $dir =~ /^\@.*\@$/;
3262
3263       if (! -d $am_relative_dir . '/' . $dir)
3264         {
3265           err_var ('SUBDIRS', "required directory $am_relative_dir/$dir "
3266                    . "does not exist");
3267           next;
3268         }
3269
3270       err_var 'SUBDIRS', "directory should not contain `/'"
3271         if $dir =~ /\//;
3272     }
3273
3274   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3275   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3276 }
3277
3278
3279 # ($REGEN, @DEPENDENCIES)
3280 # &scan_aclocal_m4
3281 # ----------------
3282 # If aclocal.m4 creation is automated, return the list of its dependencies.
3283 sub scan_aclocal_m4 ()
3284 {
3285   my $regen_aclocal = 0;
3286
3287   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3288   set_seen 'CONFIGURE_DEPENDENCIES';
3289
3290   if (-f 'aclocal.m4')
3291     {
3292       &push_dist_common ('aclocal.m4')
3293         if $relative_dir eq '.';
3294       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3295
3296       my $aclocal = new Automake::XFile "< aclocal.m4";
3297       my $line = $aclocal->getline;
3298       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3299     }
3300
3301   my @ac_deps = ();
3302
3303   if (set_seen ('ACLOCAL_M4_SOURCES'))
3304     {
3305       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3306       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3307                "`ACLOCAL_M4_SOURCES' is obsolete.\n"
3308                . "It should be safe to simply remove it.");
3309     }
3310
3311   # Note that it might be possible that aclocal.m4 doesn't exist but
3312   # should be auto-generated.  This case probably isn't very
3313   # important.
3314
3315   return ($regen_aclocal, @ac_deps);
3316 }
3317
3318
3319 # @DEPENDENCY
3320 # &rewrite_inputs_into_dependencies ($ADD_SRCDIR, @INPUTS)
3321 # --------------------------------------------------------
3322 # Rewrite a list of input files into a form suitable to put on a
3323 # dependency list.  The idea is that if an input file has a directory
3324 # part the same as the current directory, then the directory part is
3325 # simply removed.  But if the directory part is different, then
3326 # $(top_srcdir) is prepended.  Among other things, this is used to
3327 # generate the dependency list for the output files generated by
3328 # AC_OUTPUT.  Consider what the dependencies should look like in this
3329 # case:
3330 #   AC_OUTPUT(src/out:src/in1:lib/in2)
3331 # The first argument, ADD_SRCDIR, is 1 if $(top_srcdir) should be added.
3332 # If 0 then files that require this addition will simply be ignored.
3333 sub rewrite_inputs_into_dependencies ($@)
3334 {
3335   my ($add_srcdir, @inputs) = @_;
3336   my @newinputs;
3337
3338   foreach my $single (@inputs)
3339     {
3340       if (dirname ($single) eq $relative_dir)
3341         {
3342           push (@newinputs, basename ($single));
3343         }
3344       else
3345         {
3346           push (@newinputs, ($add_srcdir ? '$(top_srcdir)/' : '') . $single);
3347         }
3348     }
3349   return @newinputs;
3350 }
3351
3352
3353 # &handle_configure ($LOCAL, $INPUT, @SECONDARY_INPUTS)
3354 # -----------------------------------------------------
3355 # Handle remaking and configure stuff.
3356 # We need the name of the input file, to do proper remaking rules.
3357 sub handle_configure ($$@)
3358 {
3359   my ($local, $input, @secondary_inputs) = @_;
3360
3361   my $input_base = basename ($input);
3362   my $local_base = basename ($local);
3363
3364   my $amfile = $input_base . '.am';
3365   # We know we can always add '.in' because it really should be an
3366   # error if the .in was missing originally.
3367   my $infile = '$(srcdir)/' . $input_base . '.in';
3368   my $colon_infile = '';
3369   if ($local ne $input || @secondary_inputs)
3370     {
3371       $colon_infile = ':' . $input . '.in';
3372     }
3373   $colon_infile .= ':' . join (':', @secondary_inputs)
3374     if @secondary_inputs;
3375
3376   my @rewritten = rewrite_inputs_into_dependencies (1, @secondary_inputs);
3377
3378   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
3379
3380
3381   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
3382                           @configure_deps);
3383
3384   $output_rules .= file_contents
3385     ('configure',
3386      new Automake::Location,
3387      MAKEFILE              => $local_base,
3388      'MAKEFILE-DEPS'       => "@rewritten",
3389      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
3390      'MAKEFILE-IN'         => $infile,
3391      'MAKEFILE-IN-DEPS'    => "@include_stack",
3392      'MAKEFILE-AM'         => $amfile,
3393      STRICTNESS            => global_option 'cygnus'
3394                                 ? 'cygnus' : $strictness_name,
3395      'USE-DEPS'            => global_option 'no-dependencies'
3396                                 ? ' --ignore-deps' : '',
3397      'MAKEFILE-AM-SOURCES' =>  "$input$colon_infile",
3398      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
3399      ACLOCAL_M4_DEPS       => "@aclocal_m4_deps");
3400
3401   if ($relative_dir eq '.')
3402     {
3403       &push_dist_common ('acconfig.h')
3404         if -f 'acconfig.h';
3405     }
3406
3407   # If we have a configure header, require it.
3408   my $hdr_index = 0;
3409   my @distclean_config;
3410   foreach my $spec (@config_headers)
3411     {
3412       $hdr_index += 1;
3413       # $CONFIG_H_PATH: config.h from top level.
3414       my ($config_h_path, @ins) = split_config_file_spec ($spec);
3415       my $config_h_dir = dirname ($config_h_path);
3416
3417       # If the header is in the current directory we want to build
3418       # the header here.  Otherwise, if we're at the topmost
3419       # directory and the header's directory doesn't have a
3420       # Makefile, then we also want to build the header.
3421       if ($relative_dir eq $config_h_dir
3422           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
3423         {
3424           my ($cn_sans_dir, $stamp_dir);
3425           if ($relative_dir eq $config_h_dir)
3426             {
3427               $cn_sans_dir = basename ($config_h_path);
3428               $stamp_dir = '';
3429             }
3430           else
3431             {
3432               $cn_sans_dir = $config_h_path;
3433               if ($config_h_dir eq '.')
3434                 {
3435                   $stamp_dir = '';
3436                 }
3437               else
3438                 {
3439                   $stamp_dir = $config_h_dir . '/';
3440                 }
3441             }
3442
3443           # Compute relative path from directory holding output
3444           # header to directory holding input header.  FIXME:
3445           # doesn't handle case where we have multiple inputs.
3446           my $in0_sans_dir;
3447           if (dirname ($ins[0]) eq $relative_dir)
3448             {
3449               $in0_sans_dir = basename ($ins[0]);
3450             }
3451           else
3452             {
3453               $in0_sans_dir = backname ($relative_dir) . '/' . $ins[0];
3454             }
3455
3456           require_file ($config_header_location, FOREIGN, $in0_sans_dir);
3457
3458           # Header defined and in this directory.
3459           my @files;
3460           if (-f $config_h_path . '.top')
3461             {
3462               push (@files, "$cn_sans_dir.top");
3463             }
3464           if (-f $config_h_path . '.bot')
3465             {
3466               push (@files, "$cn_sans_dir.bot");
3467             }
3468
3469           push_dist_common (@files);
3470
3471           # For now, acconfig.h can only appear in the top srcdir.
3472           if (-f 'acconfig.h')
3473             {
3474               push (@files, '$(top_srcdir)/acconfig.h');
3475             }
3476
3477           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
3478           $output_rules .=
3479             file_contents ('remake-hdr',
3480                            new Automake::Location,
3481                            FILES         => "@files",
3482                            CONFIG_H      => $cn_sans_dir,
3483                            CONFIG_HIN    => $in0_sans_dir,
3484                            CONFIG_H_PATH => $config_h_path,
3485                            STAMP         => "$stamp");
3486
3487           push @distclean_config, $cn_sans_dir, $stamp;
3488         }
3489     }
3490
3491   $output_rules .= file_contents ('clean-hdr',
3492                                   new Automake::Location,
3493                                   FILES => "@distclean_config")
3494     if @distclean_config;
3495
3496   # Set location of mkinstalldirs.
3497   define_variable ('mkinstalldirs',
3498                    '$(SHELL) ' . $config_aux_dir . '/mkinstalldirs',
3499                    INTERNAL);
3500
3501   reject_var ('CONFIG_HEADER',
3502               "`CONFIG_HEADER' is an anachronism; now determined "
3503               . "automatically\nfrom `$configure_ac'");
3504
3505   my @config_h;
3506   foreach my $spec (@config_headers)
3507     {
3508       my ($out, @ins) = split_config_file_spec ($spec);
3509       # Generate CONFIG_HEADER define.
3510       if ($relative_dir eq dirname ($out))
3511         {
3512           push @config_h, basename ($out);
3513         }
3514       else
3515         {
3516           push @config_h, "\$(top_builddir)/$out";
3517         }
3518     }
3519   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
3520     if @config_h;
3521
3522   # Now look for other files in this directory which must be remade
3523   # by config.status, and generate rules for them.
3524   my @actual_other_files = ();
3525   foreach my $lfile (@other_input_files)
3526     {
3527       my $file;
3528       my @inputs;
3529       if ($lfile =~ /^([^:]*):(.*)$/)
3530         {
3531           # This is the ":" syntax of AC_OUTPUT.
3532           $file = $1;
3533           @inputs = split (':', $2);
3534         }
3535       else
3536         {
3537           # Normal usage.
3538           $file = $lfile;
3539           @inputs = $file . '.in';
3540         }
3541
3542       # Automake files should not be stored in here, but in %MAKE_LIST.
3543       prog_error "$lfile in \@other_input_files"
3544         if -f $file . '.am';
3545
3546       my $local = basename ($file);
3547
3548       # Make sure the dist directory for each input file is created.
3549       # We only have to do this at the topmost level though.  This
3550       # is a bit ugly but it easier than spreading out the logic,
3551       # especially in cases like AC_OUTPUT(foo/out:bar/in), where
3552       # there is no Makefile in bar/.
3553       if ($relative_dir eq '.')
3554         {
3555           foreach (@inputs)
3556             {
3557               $dist_dirs{dirname ($_)} = 1;
3558             }
3559         }
3560
3561       # We skip files that aren't in this directory.  However, if
3562       # the file's directory does not have a Makefile, and we are
3563       # currently doing `.', then we create a rule to rebuild the
3564       # file in the subdir.
3565       my $fd = dirname ($file);
3566       if ($fd ne $relative_dir)
3567         {
3568           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
3569             {
3570               $local = $file;
3571             }
3572           else
3573             {
3574               next;
3575             }
3576         }
3577
3578       my @rewritten_inputs = rewrite_inputs_into_dependencies (1, @inputs);
3579       $output_rules .= ($local . ': '
3580                         . '$(top_builddir)/config.status '
3581                         . "@rewritten_inputs\n"
3582                         . "\t"
3583                         . 'cd $(top_builddir) && '
3584                         . '$(SHELL) ./config.status '
3585                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
3586                         . '$@'
3587                         . "\n");
3588       push (@actual_other_files, $local);
3589
3590       # Require all input files.
3591       require_file ($ac_config_files_location, FOREIGN,
3592                     rewrite_inputs_into_dependencies (0, @inputs));
3593     }
3594
3595   foreach my $struct (@config_links)
3596     {
3597       my ($spec, $where) = @$struct;
3598       my ($link, $file) = split /:/, $spec;
3599
3600       # We skip links that aren't in this directory.  However, if
3601       # the link's directory does not have a Makefile, and we are
3602       # currently doing `.', then we add the link to CONFIG_CLEAN_FILES
3603       # in `.'s Makefile.in.
3604       my $local = basename ($link);
3605       my $fd = dirname ($link);
3606       if ($fd ne $relative_dir)
3607         {
3608           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
3609             {
3610               $local = $link;
3611             }
3612           else
3613             {
3614               $local = undef;
3615             }
3616         }
3617
3618       push @actual_other_files, $local if $local;
3619
3620       $local = basename ($file);
3621       $fd = dirname ($file);
3622
3623       # Make sure the dist directory for each input file is created.
3624       # We only have to do this at the topmost level though.
3625       if ($relative_dir eq '.')
3626         {
3627           $dist_dirs{$fd} = 1;
3628         }
3629
3630       # We skip files that aren't in this directory.  However, if
3631       # the files's directory does not have a Makefile, and we are
3632       # currently doing `.', then we require the file from `.'.
3633       if ($fd ne $relative_dir)
3634         {
3635           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
3636             {
3637               $local = $file;
3638             }
3639           else
3640             {
3641               next;
3642             }
3643         }
3644
3645       # Require all input files.
3646       require_file ($where, FOREIGN, $local);
3647   }
3648
3649   # These files get removed by "make distclean".
3650   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
3651                           @actual_other_files);
3652 }
3653
3654 # Handle C headers.
3655 sub handle_headers
3656 {
3657     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
3658                              'oldinclude', 'pkginclude',
3659                              'noinst', 'check');
3660     foreach (@r)
3661     {
3662       next unless $_->[1] =~ /\..*$/;
3663       &saw_extension ($&);
3664     }
3665 }
3666
3667 sub handle_gettext
3668 {
3669   return if ! $seen_gettext || $relative_dir ne '.';
3670
3671   my $subdirs = var 'SUBDIRS';
3672
3673   if (! $subdirs)
3674     {
3675       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
3676       return;
3677     }
3678
3679   # Perform some sanity checks to help users get the right setup.
3680   # We disable these tests when po/ doesn't exist in order not to disallow
3681   # unusual gettext setups.
3682   #
3683   # Bruno Haible:
3684   # | The idea is:
3685   # |
3686   # |  1) If a package doesn't have a directory po/ at top level, it
3687   # |     will likely have multiple po/ directories in subpackages.
3688   # |
3689   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
3690   # |     is used without 'external'. It is also useful to warn for the
3691   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
3692   # |     warnings apply only to the usual layout of packages, therefore
3693   # |     they should both be disabled if no po/ directory is found at
3694   # |     top level.
3695
3696   if (-d 'po')
3697     {
3698       my @subdirs = $subdirs->value_as_list_recursive ('all');
3699
3700       msg_var ('syntax', $subdirs,
3701                "AM_GNU_GETTEXT used but `po' not in SUBDIRS")
3702         if ! grep ($_ eq 'po', @subdirs);
3703
3704       # intl/ is not required when AM_GNU_GETTEXT is called with
3705       # the `external' option.
3706       msg_var ('syntax', $subdirs,
3707                "AM_GNU_GETTEXT used but `intl' not in SUBDIRS")
3708         if (! $seen_gettext_external
3709             && ! grep ($_ eq 'intl', @subdirs));
3710
3711       # intl/ should not be used with AM_GNU_GETTEXT([external])
3712       msg_var ('syntax', $subdirs,
3713                "`intl' should not be in SUBDIRS when "
3714                . "AM_GNU_GETTEXT([external]) is used")
3715         if ($seen_gettext_external && grep ($_ eq 'intl', @subdirs));
3716     }
3717
3718   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
3719 }
3720
3721 # Handle footer elements.
3722 sub handle_footer
3723 {
3724     # NOTE don't use define_pretty_variable here, because
3725     # $contents{...} is already defined.
3726     $output_vars .= 'SOURCES = ' . variable_value ('SOURCES') . "\n\n"
3727       if variable_value ('SOURCES');
3728
3729     reject_rule ('.SUFFIXES',
3730                  "use variable `SUFFIXES', not target `.SUFFIXES'");
3731
3732     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
3733     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
3734     # anything else, by sticking it right after the default: target.
3735     $output_header .= ".SUFFIXES:\n";
3736     my $suffixes = var 'SUFFIXES';
3737     my @suffixes = Automake::Rule::suffixes;
3738     if (@suffixes || $suffixes)
3739     {
3740         # Make sure SUFFIXES has unique elements.  Sort them to ensure
3741         # the output remains consistent.  However, $(SUFFIXES) is
3742         # always at the start of the list, unsorted.  This is done
3743         # because make will choose rules depending on the ordering of
3744         # suffixes, and this lets the user have some control.  Push
3745         # actual suffixes, and not $(SUFFIXES).  Some versions of make
3746         # do not like variable substitutions on the .SUFFIXES line.
3747         my @user_suffixes = ($suffixes
3748                              ? $suffixes->value_as_list_recursive ('all')
3749                              : ());
3750
3751         my %suffixes = map { $_ => 1 } @suffixes;
3752         delete @suffixes{@user_suffixes};
3753
3754         $output_header .= (".SUFFIXES: "
3755                            . join (' ', @user_suffixes, sort keys %suffixes)
3756                            . "\n");
3757     }
3758
3759     $output_trailer .= file_contents ('footer', new Automake::Location);
3760 }
3761
3762
3763 # Generate `make install' rules.
3764 sub handle_install ()
3765 {
3766   $output_rules .= &file_contents
3767     ('install',
3768      new Automake::Location,
3769      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
3770                              ? (" \$(BUILT_SOURCES)\n"
3771                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
3772                              : ''),
3773      'installdirs-local' => (rule 'installdirs-local'
3774                              ? ' installdirs-local' : ''),
3775      am__installdirs => variable_value ('am__installdirs') || '');
3776 }
3777
3778
3779 # Deal with all and all-am.
3780 sub handle_all ($)
3781 {
3782     my ($makefile) = @_;
3783
3784     # Output `all-am'.
3785
3786     # Put this at the beginning for the sake of non-GNU makes.  This
3787     # is still wrong if these makes can run parallel jobs.  But it is
3788     # right enough.
3789     unshift (@all, basename ($makefile));
3790
3791     foreach my $spec (@config_headers)
3792       {
3793         my ($out, @ins) = split_config_file_spec ($spec);
3794         push (@all, basename ($out))
3795           if dirname ($out) eq $relative_dir;
3796       }
3797
3798     # Install `all' hooks.
3799     if (rule "all-local")
3800     {
3801       push (@all, "all-local");
3802       &depend ('.PHONY', "all-local");
3803     }
3804
3805     &pretty_print_rule ("all-am:", "\t\t", @all);
3806     &depend ('.PHONY', 'all-am', 'all');
3807
3808
3809     # Output `all'.
3810
3811     my @local_headers = ();
3812     push @local_headers, '$(BUILT_SOURCES)'
3813       if var ('BUILT_SOURCES');
3814     foreach my $spec (@config_headers)
3815       {
3816         my ($out, @ins) = split_config_file_spec ($spec);
3817         push @local_headers, basename ($out)
3818           if dirname ($out) eq $relative_dir;
3819       }
3820
3821     if (@local_headers)
3822       {
3823         # We need to make sure config.h is built before we recurse.
3824         # We also want to make sure that built sources are built
3825         # before any ordinary `all' targets are run.  We can't do this
3826         # by changing the order of dependencies to the "all" because
3827         # that breaks when using parallel makes.  Instead we handle
3828         # things explicitly.
3829         $output_all .= ("all: @local_headers"
3830                         . "\n\t"
3831                         . '$(MAKE) $(AM_MAKEFLAGS) '
3832                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
3833                         . "\n\n");
3834       }
3835     else
3836       {
3837         $output_all .= "all: " . (var ('SUBDIRS')
3838                                   ? 'all-recursive' : 'all-am') . "\n\n";
3839       }
3840 }
3841
3842
3843 # &do_check_merge_target ()
3844 # -------------------------
3845 # Handle check merge target specially.
3846 sub do_check_merge_target ()
3847 {
3848   if (rule 'check-local')
3849     {
3850       # User defined local form of target.  So include it.
3851       push @check_tests, 'check-local';
3852       depend '.PHONY', 'check-local';
3853     }
3854
3855   # In --cygnus mode, check doesn't depend on all.
3856   if (option 'cygnus')
3857     {
3858       # Just run the local check rules.
3859       pretty_print_rule ('check-am:', "\t\t", @check);
3860     }
3861   else
3862     {
3863       # The check target must depend on the local equivalent of
3864       # `all', to ensure all the primary targets are built.  Then it
3865       # must build the local check rules.
3866       $output_rules .= "check-am: all-am\n";
3867       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
3868                          @check)
3869         if @check;
3870     }
3871   pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
3872                      @check_tests)
3873     if @check_tests;
3874
3875   depend '.PHONY', 'check', 'check-am';
3876   # Handle recursion.  We have to honor BUILT_SOURCES like for `all:'.
3877   $output_rules .= ("check: "
3878                     . (var ('BUILT_SOURCES')
3879                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
3880                        : '')
3881                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
3882                     . "\n");
3883 }
3884
3885 # Handle all 'clean' targets.
3886 sub handle_clean
3887 {
3888   # Clean the files listed in user variables if they exist.
3889   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
3890     if var ('MOSTLYCLEANFILES');
3891   $clean_files{'$(CLEANFILES)'} = CLEAN
3892     if var ('CLEANFILES');
3893   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
3894     if var ('DISTCLEANFILES');
3895   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
3896     if var ('MAINTAINERCLEANFILES');
3897
3898   # Built sources are automatically removed by maintainer-clean.
3899   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
3900     if var ('BUILT_SOURCES');
3901
3902   # Compute a list of "rm"s to run for each target.
3903   my %rms = (MOSTLY_CLEAN, [],
3904              CLEAN, [],
3905              DIST_CLEAN, [],
3906              MAINTAINER_CLEAN, []);
3907
3908   foreach my $file (keys %clean_files)
3909     {
3910       my $when = $clean_files{$file};
3911       prog_error 'invalid entry in %clean_files'
3912         unless exists $rms{$when};
3913
3914       my $rm = "rm -f $file";
3915       # If file is a variable, make sure when don't call `rm -f' without args.
3916       $rm ="test -z \"$file\" || $rm"
3917         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
3918
3919       push @{$rms{$when}}, "\t-$rm\n";
3920     }
3921
3922   $output_rules .= &file_contents
3923     ('clean',
3924      new Automake::Location,
3925      MOSTLYCLEAN_RMS      => join ('', @{$rms{&MOSTLY_CLEAN}}),
3926      CLEAN_RMS            => join ('', @{$rms{&CLEAN}}),
3927      DISTCLEAN_RMS        => join ('', @{$rms{&DIST_CLEAN}}),
3928      MAINTAINER_CLEAN_RMS => join ('', @{$rms{&MAINTAINER_CLEAN}}));
3929 }
3930
3931
3932 # &target_cmp ($A, $B)
3933 # --------------------
3934 # Subroutine for &handle_factored_dependencies to let `.PHONY' be last.
3935 sub target_cmp
3936 {
3937     return 0
3938         if $a eq $b;
3939     return -1
3940         if $b eq '.PHONY';
3941     return 1
3942         if $a eq '.PHONY';
3943     return $a cmp $b;
3944 }
3945
3946
3947 # &handle_factored_dependencies ()
3948 # --------------------------------
3949 # Handle everything related to gathered targets.
3950 sub handle_factored_dependencies
3951 {
3952   # Reject bad hooks.
3953   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
3954                      'uninstall-exec-local', 'uninstall-exec-hook')
3955     {
3956       my $x = $utarg;
3957       $x =~ s/(data|exec)-//;
3958       reject_rule ($utarg, "use `$x', not `$utarg'");
3959     }
3960
3961   reject_rule ('install-local',
3962                "use `install-data-local' or `install-exec-local', "
3963                . "not `install-local'");
3964
3965   reject_rule ('install-info-local',
3966                "`install-info-local' target defined but "
3967                . "`no-installinfo' option not in use")
3968     unless option 'no-installinfo';
3969
3970   # Install the -local hooks.
3971   foreach (keys %dependencies)
3972     {
3973       # Hooks are installed on the -am targets.
3974       s/-am$// or next;
3975       if (rule "$_-local")
3976         {
3977           depend ("$_-am", "$_-local");
3978           depend ('.PHONY', "$_-local");
3979         }
3980     }
3981
3982   # Install the -hook hooks.
3983   # FIXME: Why not be as liberal as we are with -local hooks?
3984   foreach ('install-exec', 'install-data', 'uninstall')
3985     {
3986       if (rule ("$_-hook"))
3987         {
3988           $actions{"$_-am"} .=
3989             ("\t\@\$(NORMAL_INSTALL)\n"
3990              . "\t" . '$(MAKE) $(AM_MAKEFLAGS) ' . "$_-hook\n");
3991         }
3992     }
3993
3994   # All the required targets are phony.
3995   depend ('.PHONY', keys %required_targets);
3996
3997   # Actually output gathered targets.
3998   foreach (sort target_cmp keys %dependencies)
3999     {
4000       # If there is nothing about this guy, skip it.
4001       next
4002         unless (@{$dependencies{$_}}
4003                 || $actions{$_}
4004                 || $required_targets{$_});
4005
4006       # Define gathered targets in undefined conditions.
4007       # FIXME: Right now we must handle .PHONY as an exception,
4008       # because people write things like
4009       #    .PHONY: myphonytarget
4010       # to append dependencies.  This would not work if Automake
4011       # refrained from defining its own .PHONY target as it does
4012       # with other overridden targets.
4013       my @undefined_conds = (TRUE,);
4014       if ($_ ne '.PHONY')
4015         {
4016           @undefined_conds =
4017             Automake::Rule::define ($_, 'internal',
4018                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4019         }
4020       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4021       foreach my $cond (@undefined_conds)
4022         {
4023           my $condstr = $cond->subst_string;
4024           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4025           $output_rules .= $actions{$_} if defined $actions{$_};
4026           $output_rules .= "\n";
4027         }
4028     }
4029 }
4030
4031
4032 # &handle_tests_dejagnu ()
4033 # ------------------------
4034 sub handle_tests_dejagnu
4035 {
4036     push (@check_tests, 'check-DEJAGNU');
4037     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4038 }
4039
4040
4041 # Handle TESTS variable and other checks.
4042 sub handle_tests
4043 {
4044   if (option 'dejagnu')
4045     {
4046       &handle_tests_dejagnu;
4047     }
4048   else
4049     {
4050       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4051         {
4052           reject_var ($c, "`$c' defined but `dejagnu' not in "
4053                       . "`AUTOMAKE_OPTIONS'");
4054         }
4055     }
4056
4057   if (var ('TESTS'))
4058     {
4059       push (@check_tests, 'check-TESTS');
4060       $output_rules .= &file_contents ('check', new Automake::Location);
4061     }
4062 }
4063
4064 # Handle Emacs Lisp.
4065 sub handle_emacs_lisp
4066 {
4067   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4068                                  'lisp', 'noinst');
4069
4070   return if ! @elfiles;
4071
4072   # Generate .elc files.
4073   my @elcfiles = map { $_->[1] . 'c' } @elfiles;
4074
4075   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, @elcfiles);
4076   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4077                           map { $_->[1] } @elfiles);
4078
4079   # Do not depend on the build rules if ELCFILES is empty.
4080   # This is necessary because overriding ELCFILES= is a documented
4081   # idiom to disable byte-compilation.
4082   if (variable_value ('ELCFILES'))
4083     {
4084       # It's important that all depends on elc-stamp so that
4085       # all .elc files get recompiled whenever a .el changes.
4086       # It's important that all depends on $(ELCFILES) so that
4087       # we can recover if any of them is deleted.
4088       push (@all, 'elc-stamp', '$(ELCFILES)');
4089     }
4090
4091   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
4092                      'EMACS', 'lispdir');
4093   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
4094   &define_variable ('elisp_comp', $config_aux_dir . '/elisp-comp', INTERNAL);
4095 }
4096
4097 # Handle Python
4098 sub handle_python
4099 {
4100   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
4101                                  'noinst');
4102   return if ! @pyfiles;
4103
4104   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
4105   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
4106   &define_variable ('py_compile', $config_aux_dir . '/py-compile', INTERNAL);
4107 }
4108
4109 # Handle Java.
4110 sub handle_java
4111 {
4112     my @sourcelist = &am_install_var ('-candist',
4113                                       'java', 'JAVA',
4114                                       'java', 'noinst', 'check');
4115     return if ! @sourcelist;
4116
4117     my @prefix = am_primary_prefixes ('JAVA', 1,
4118                                       'java', 'noinst', 'check');
4119
4120     my $dir;
4121     foreach my $curs (@prefix)
4122       {
4123         next
4124           if $curs eq 'EXTRA';
4125
4126         err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
4127           if defined $dir;
4128         $dir = $curs;
4129       }
4130
4131
4132     push (@all, 'class' . $dir . '.stamp');
4133 }
4134
4135
4136 # Handle some of the minor options.
4137 sub handle_minor_options
4138 {
4139   if (option 'readme-alpha')
4140     {
4141       if ($relative_dir eq '.')
4142         {
4143           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
4144             {
4145               msg ('error-gnits', $package_version_location,
4146                    "version `$package_version' doesn't follow " .
4147                    "Gnits standards");
4148             }
4149           if (defined $1 && -f 'README-alpha')
4150             {
4151               # This means we have an alpha release.  See
4152               # GNITS_VERSION_PATTERN for details.
4153               push_dist_common ('README-alpha');
4154             }
4155         }
4156     }
4157 }
4158
4159 ################################################################
4160
4161 # ($OUTPUT, @INPUTS)
4162 # &split_config_file_spec ($SPEC)
4163 # -------------------------------
4164 # Decode the Autoconf syntax for config files (files, headers, links
4165 # etc.).
4166 sub split_config_file_spec ($)
4167 {
4168   my ($spec) = @_;
4169   my ($output, @inputs) = split (/:/, $spec);
4170
4171   push @inputs, "$output.in"
4172     unless @inputs;
4173
4174   return ($output, @inputs);
4175 }
4176
4177
4178 my %make_list;
4179
4180 # &scan_autoconf_config_files ($CONFIG-FILES)
4181 # -------------------------------------------
4182 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
4183 # (or AC_OUTPUT).
4184 sub scan_autoconf_config_files ($)
4185 {
4186   my ($config_files) = @_;
4187   # Look at potential Makefile.am's.
4188   foreach (split ' ', $config_files)
4189     {
4190       # Must skip empty string for Perl 4.
4191       next if $_ eq "\\" || $_ eq '';
4192
4193       # Handle $local:$input syntax.  Note that we ignore
4194       # every input file past the first, though we keep
4195       # those around for later.
4196       my ($local, $input, @rest) = split (/:/);
4197       if (! $input)
4198         {
4199           $input = $local;
4200         }
4201       else
4202         {
4203           # FIXME: should be error if .in is missing.
4204           $input =~ s/\.in$//;
4205         }
4206
4207       if (-f $input . '.am')
4208         {
4209           # We have a file that automake should generate.
4210           $make_list{$input} = join (':', ($local, @rest));
4211         }
4212       else
4213         {
4214           # We have a file that automake should cause to be
4215           # rebuilt, but shouldn't generate itself.
4216           push (@other_input_files, $_);
4217         }
4218     }
4219 }
4220
4221
4222 # &scan_autoconf_traces ($FILENAME)
4223 # ---------------------------------
4224 sub scan_autoconf_traces ($)
4225 {
4226   my ($filename) = @_;
4227
4228   # Macros to trace, with their minimal number of arguments.
4229   my %traced = (
4230                 AC_CANONICAL_HOST => 0,
4231                 AC_CANONICAL_SYSTEM => 0,
4232                 AC_CONFIG_AUX_DIR => 1,
4233                 AC_CONFIG_FILES => 1,
4234                 AC_CONFIG_HEADERS => 1,
4235                 AC_CONFIG_LINKS => 1,
4236                 AC_INIT => 0,
4237                 AC_LIBSOURCE => 1,
4238                 AC_SUBST => 1,
4239                 AM_AUTOMAKE_VERSION => 1,
4240                 AM_CONDITIONAL => 2,
4241                 AM_ENABLE_MULTILIB => 0,
4242                 AM_GNU_GETTEXT => 0,
4243                 AM_INIT_AUTOMAKE => 0,
4244                 AM_MAINTAINER_MODE => 0,
4245                 AM_PROG_CC_C_O => 0,
4246                 m4_include => 1,
4247                 m4_sinclude => 1,
4248               );
4249
4250   my $traces = ($ENV{AUTOCONF} || 'autoconf') . " ";
4251
4252   # Use a separator unlikely to be used, not `:', the default, which
4253   # has a precise meaning for AC_CONFIG_FILES and so on.
4254   $traces .= join (' ',
4255                    map { "--trace=$_" . ':\$f:\$l::\$n::\${::}%' }
4256                    (keys %traced));
4257
4258   my $tracefh = new Automake::XFile ("$traces $filename |");
4259   verb "reading $traces";
4260
4261   while ($_ = $tracefh->getline)
4262     {
4263       chomp;
4264       my ($here, @args) = split /::/;
4265       my $where = new Automake::Location $here;
4266       my $macro = $args[0];
4267
4268       prog_error ("unrequested trace `$macro'")
4269         unless exists $traced{$macro};
4270
4271       # Skip and diagnose malformed calls.
4272       if ($#args < $traced{$macro})
4273         {
4274           msg ('syntax', $where, "not enough arguments for $macro");
4275           next;
4276         }
4277
4278       # Alphabetical ordering please.
4279       if ($macro eq 'AC_CANONICAL_HOST')
4280         {
4281           if (! $seen_canonical)
4282             {
4283               $seen_canonical = AC_CANONICAL_HOST;
4284               $canonical_location = $where;
4285             }
4286         }
4287       elsif ($macro eq 'AC_CANONICAL_SYSTEM')
4288         {
4289           $seen_canonical = AC_CANONICAL_SYSTEM;
4290           $canonical_location = $where;
4291         }
4292       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
4293         {
4294           @config_aux_path = $args[1];
4295           $config_aux_dir_set_in_configure_in = 1;
4296         }
4297       elsif ($macro eq 'AC_CONFIG_FILES')
4298         {
4299           # Look at potential Makefile.am's.
4300           $ac_config_files_location = $where;
4301           &scan_autoconf_config_files ($args[1]);
4302         }
4303       elsif ($macro eq 'AC_CONFIG_HEADERS')
4304         {
4305           $config_header_location = $where;
4306           push @config_headers, split (' ', $args[1]);
4307         }
4308       elsif ($macro eq 'AC_CONFIG_LINKS')
4309         {
4310           push @config_links, map { [$_, $where] } split (' ', $args[1]);
4311         }
4312       elsif ($macro eq 'AC_INIT')
4313         {
4314           if (defined $args[2])
4315             {
4316               $package_version = $args[2];
4317               $package_version_location = $where;
4318             }
4319         }
4320       elsif ($macro eq 'AC_LIBSOURCE')
4321         {
4322           $libsources{$args[1]} = $here;
4323         }
4324       elsif ($macro eq 'AC_SUBST')
4325         {
4326           # Just check for alphanumeric in AC_SUBST.  If you do
4327           # AC_SUBST(5), then too bad.
4328           $configure_vars{$args[1]} = $where
4329             if $args[1] =~ /^\w+$/;
4330         }
4331       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
4332         {
4333           error ($where,
4334                  "version mismatch.  This is Automake $VERSION,\n" .
4335                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
4336                  "comes from Automake $args[1].  You should recreate\n" .
4337                  "aclocal.m4 with aclocal and run automake again.\n")
4338             if $VERSION ne $args[1];
4339
4340           $seen_automake_version = 1;
4341         }
4342       elsif ($macro eq 'AM_CONDITIONAL')
4343         {
4344           $configure_cond{$args[1]} = $where;
4345         }
4346       elsif ($macro eq 'AM_ENABLE_MULTILIB')
4347         {
4348           $seen_multilib = $where;
4349         }
4350       elsif ($macro eq 'AM_GNU_GETTEXT')
4351         {
4352           $seen_gettext = $where;
4353           $ac_gettext_location = $where;
4354           $seen_gettext_external = grep ($_ eq 'external', @args);
4355         }
4356       elsif ($macro eq 'AM_INIT_AUTOMAKE')
4357         {
4358           $seen_init_automake = $where;
4359           if (defined $args[2])
4360             {
4361               $package_version = $args[2];
4362               $package_version_location = $where;
4363             }
4364           elsif (defined $args[1])
4365             {
4366               exit $exit_code
4367                 if (process_global_option_list ($where,
4368                                                 split (' ', $args[1])));
4369             }
4370         }
4371       elsif ($macro eq 'AM_MAINTAINER_MODE')
4372         {
4373           $seen_maint_mode = $where;
4374         }
4375       elsif ($macro eq 'AM_PROG_CC_C_O')
4376         {
4377           $seen_cc_c_o = $where;
4378         }
4379       elsif ($macro eq 'm4_include' || $macro eq 'm4_sinclude')
4380         {
4381           # Some modified versions of Autoconf don't use
4382           # forzen files.  Consequently it's possible that we see all
4383           # m4_include's performed during Autoconf's startup.
4384           # Obviously we don't want to distribute Autoconf's files
4385           # so we skip absolute filenames here.
4386           push @configure_deps, '$(top_srcdir)/' . $args[1]
4387             unless $here =~ m,^(?:\w:)?[\\/],;
4388           # Keep track of the greatest timestamp.
4389           if (-e $args[1])
4390             {
4391               my $mtime = mtime $args[1];
4392               $configure_deps_greatest_timestamp = $mtime
4393                 if $mtime > $configure_deps_greatest_timestamp;
4394             }
4395         }
4396    }
4397 }
4398
4399
4400 # &scan_autoconf_files ()
4401 # -----------------------
4402 # Check whether we use `configure.ac' or `configure.in'.
4403 # Scan it (and possibly `aclocal.m4') for interesting things.
4404 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
4405 sub scan_autoconf_files ()
4406 {
4407   # Reinitialize libsources here.  This isn't really necessary,
4408   # since we currently assume there is only one configure.ac.  But
4409   # that won't always be the case.
4410   %libsources = ();
4411
4412   # Keep track of the youngest configure dependency.
4413   $configure_deps_greatest_timestamp = mtime $configure_ac;
4414   if (-e 'aclocal.m4')
4415     {
4416       my $mtime = mtime 'aclocal.m4';
4417       $configure_deps_greatest_timestamp = $mtime
4418         if $mtime > $configure_deps_greatest_timestamp;
4419     }
4420
4421   scan_autoconf_traces ($configure_ac);
4422
4423   # Set input and output files if not specified by user.
4424   if (! @input_files)
4425     {
4426       @input_files = sort keys %make_list;
4427       %output_files = %make_list;
4428     }
4429
4430   @configure_input_files = sort keys %make_list;
4431
4432   if (! $seen_init_automake)
4433     {
4434       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
4435               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
4436               . "\nthat aclocal.m4 is present in the top-level directory,\n"
4437               . "and that aclocal.m4 was recently regenerated "
4438               . "(using aclocal).");
4439     }
4440   else
4441     {
4442       if (! $seen_automake_version)
4443         {
4444           if (-f 'aclocal.m4')
4445             {
4446               error ($seen_init_automake,
4447                      "your implementation of AM_INIT_AUTOMAKE comes from " .
4448                      "an\nold Automake version.  You should recreate " .
4449                      "aclocal.m4\nwith aclocal and run automake again.\n");
4450             }
4451           else
4452             {
4453               error ($seen_init_automake,
4454                      "no proper implementation of AM_INIT_AUTOMAKE was " .
4455                      "found,\nprobably because aclocal.m4 is missing...\n" .
4456                      "You should run aclocal to create this file, then\n" .
4457                      "run automake again.\n");
4458             }
4459         }
4460     }
4461
4462   # Look for some files we need.  Always check for these.  This
4463   # check must be done for every run, even those where we are only
4464   # looking at a subdir Makefile.  We must set relative_dir so that
4465   # the file-finding machinery works.
4466   # FIXME: Is this broken because it needs dynamic scopes.
4467   # My tests seems to show it's not the case.
4468   $relative_dir = '.';
4469   require_conf_file ($configure_ac, FOREIGN,
4470                      'install-sh', 'mkinstalldirs', 'missing');
4471   err_am "`install.sh' is an anachronism; use `install-sh' instead"
4472     if -f $config_aux_path[0] . '/install.sh';
4473
4474   # Preserve dist_common for later.
4475   $configure_dist_common = variable_value ('DIST_COMMON') || '';
4476 }
4477
4478 ################################################################
4479
4480 # Set up for Cygnus mode.
4481 sub check_cygnus
4482 {
4483   my $cygnus = option 'cygnus';
4484   return unless $cygnus;
4485
4486   set_strictness ('foreign');
4487   set_option ('no-installinfo', $cygnus);
4488   set_option ('no-dependencies', $cygnus);
4489
4490   err_ac "`AM_MAINTAINER_MODE' required when --cygnus specified"
4491     if !$seen_maint_mode;
4492 }
4493
4494 # Do any extra checking for GNU standards.
4495 sub check_gnu_standards
4496 {
4497   if ($relative_dir eq '.')
4498     {
4499       # In top level (or only) directory.
4500
4501       # Accept one of these three licenses; default to COPYING.
4502       my $license = 'COPYING';
4503       foreach (qw /COPYING.LIB COPYING.LESSER/)
4504         {
4505           $license = $_ if -f $_;
4506         }
4507       require_file ("$am_file.am", GNU, $license,
4508                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
4509     }
4510
4511   for my $opt ('no-installman', 'no-installinfo')
4512     {
4513       msg ('error-gnu', option $opt,
4514            "option `$opt' disallowed by GNU standards")
4515         if option $opt;
4516     }
4517 }
4518
4519 # Do any extra checking for GNITS standards.
4520 sub check_gnits_standards
4521 {
4522   if ($relative_dir eq '.')
4523     {
4524       # In top level (or only) directory.
4525       require_file ("$am_file.am", GNITS, 'THANKS');
4526     }
4527 }
4528
4529 ################################################################
4530 #
4531 # Functions to handle files of each language.
4532
4533 # Each `lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
4534 # simple formula: Return value is LANG_SUBDIR if the resulting object
4535 # file should be in a subdir if the source file is, LANG_PROCESS if
4536 # file is to be dealt with, LANG_IGNORE otherwise.
4537
4538 # Much of the actual processing is handled in
4539 # handle_single_transform_list.  These functions exist so that
4540 # auxiliary information can be recorded for a later cleanup pass.
4541 # Note that the calls to these functions are computed, so don't bother
4542 # searching for their precise names in the source.
4543
4544 # This is just a convenience function that can be used to determine
4545 # when a subdir object should be used.
4546 sub lang_sub_obj
4547 {
4548     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
4549 }
4550
4551 # Rewrite a single C source file.
4552 sub lang_c_rewrite
4553 {
4554   my ($directory, $base, $ext) = @_;
4555
4556   if (option 'ansi2knr' && $base =~ /_$/)
4557     {
4558       # FIXME: include line number in error.
4559       err_am "C source file `$base.c' would be deleted by ansi2knr rules";
4560     }
4561
4562   my $r = LANG_PROCESS;
4563   if (option 'subdir-objects')
4564     {
4565       $r = LANG_SUBDIR;
4566       $base = $directory . '/' . $base
4567         unless $directory eq '.' || $directory eq '';
4568
4569       err_am ("C objects in subdir but `AM_PROG_CC_C_O' "
4570               . "not in `$configure_ac'",
4571               uniq_scope => US_GLOBAL)
4572         unless $seen_cc_c_o;
4573
4574       require_conf_file ("$am_file.am", FOREIGN, 'compile');
4575
4576       # In this case we already have the directory information, so
4577       # don't add it again.
4578       $de_ansi_files{$base} = '';
4579     }
4580   else
4581     {
4582       $de_ansi_files{$base} = (($directory eq '.' || $directory eq '')
4583                                ? ''
4584                                : "$directory/");
4585     }
4586
4587     return $r;
4588 }
4589
4590 # Rewrite a single C++ source file.
4591 sub lang_cxx_rewrite
4592 {
4593     return &lang_sub_obj;
4594 }
4595
4596 # Rewrite a single header file.
4597 sub lang_header_rewrite
4598 {
4599     # Header files are simply ignored.
4600     return LANG_IGNORE;
4601 }
4602
4603 # Rewrite a single yacc file.
4604 sub lang_yacc_rewrite
4605 {
4606     my ($directory, $base, $ext) = @_;
4607
4608     my $r = &lang_sub_obj;
4609     (my $newext = $ext) =~ tr/y/c/;
4610     return ($r, $newext);
4611 }
4612
4613 # Rewrite a single yacc++ file.
4614 sub lang_yaccxx_rewrite
4615 {
4616     my ($directory, $base, $ext) = @_;
4617
4618     my $r = &lang_sub_obj;
4619     (my $newext = $ext) =~ tr/y/c/;
4620     return ($r, $newext);
4621 }
4622
4623 # Rewrite a single lex file.
4624 sub lang_lex_rewrite
4625 {
4626     my ($directory, $base, $ext) = @_;
4627
4628     my $r = &lang_sub_obj;
4629     (my $newext = $ext) =~ tr/l/c/;
4630     return ($r, $newext);
4631 }
4632
4633 # Rewrite a single lex++ file.
4634 sub lang_lexxx_rewrite
4635 {
4636     my ($directory, $base, $ext) = @_;
4637
4638     my $r = &lang_sub_obj;
4639     (my $newext = $ext) =~ tr/l/c/;
4640     return ($r, $newext);
4641 }
4642
4643 # Rewrite a single assembly file.
4644 sub lang_asm_rewrite
4645 {
4646     return &lang_sub_obj;
4647 }
4648
4649 # Rewrite a single Fortran 77 file.
4650 sub lang_f77_rewrite
4651 {
4652     return LANG_PROCESS;
4653 }
4654
4655 # Rewrite a single preprocessed Fortran 77 file.
4656 sub lang_ppf77_rewrite
4657 {
4658     return LANG_PROCESS;
4659 }
4660
4661 # Rewrite a single ratfor file.
4662 sub lang_ratfor_rewrite
4663 {
4664     return LANG_PROCESS;
4665 }
4666
4667 # Rewrite a single Objective C file.
4668 sub lang_objc_rewrite
4669 {
4670     return &lang_sub_obj;
4671 }
4672
4673 # Rewrite a single Java file.
4674 sub lang_java_rewrite
4675 {
4676     return LANG_SUBDIR;
4677 }
4678
4679 # The lang_X_finish functions are called after all source file
4680 # processing is done.  Each should handle defining rules for the
4681 # language, etc.  A finish function is only called if a source file of
4682 # the appropriate type has been seen.
4683
4684 sub lang_c_finish
4685 {
4686     # Push all libobjs files onto de_ansi_files.  We actually only
4687     # push files which exist in the current directory, and which are
4688     # genuine source files.
4689     foreach my $file (keys %libsources)
4690     {
4691         if ($file =~ /^(.*)\.[cly]$/ && -f "$relative_dir/$file")
4692         {
4693             $de_ansi_files{$1} = ''
4694         }
4695     }
4696
4697     if (option 'ansi2knr' && keys %de_ansi_files)
4698     {
4699         # Make all _.c files depend on their corresponding .c files.
4700         my @objects;
4701         foreach my $base (sort keys %de_ansi_files)
4702         {
4703             # Each _.c file must depend on ansi2knr; otherwise it
4704             # might be used in a parallel build before it is built.
4705             # We need to support files in the srcdir and in the build
4706             # dir (because these files might be auto-generated.  But
4707             # we can't use $< -- some makes only define $< during a
4708             # suffix rule.
4709             my $ansfile = $de_ansi_files{$base} . $base . '.c';
4710             $output_rules .= ($base . "_.c: $ansfile \$(ANSI2KNR)\n\t"
4711                               . '$(CPP) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) '
4712                               . '`if test -f $(srcdir)/' . $ansfile
4713                               . '; then echo $(srcdir)/' . $ansfile
4714                               . '; else echo ' . $ansfile . '; fi` '
4715                               . "| sed 's/^# \\([0-9]\\)/#line \\1/' "
4716                               . '| $(ANSI2KNR) > $@'
4717                               # If ansi2knr fails then we shouldn't
4718                               # create the _.c file
4719                               . " || rm -f \$\@\n");
4720             push (@objects, $base . '_.$(OBJEXT)');
4721             push (@objects, $base . '_.lo')
4722               if var ('LIBTOOL');
4723         }
4724
4725         # Make all _.o (and _.lo) files depend on ansi2knr.
4726         # Use a sneaky little hack to make it print nicely.
4727         &pretty_print_rule ('', '', @objects, ':', '$(ANSI2KNR)');
4728     }
4729 }
4730
4731 # This is a yacc helper which is called whenever we have decided to
4732 # compile a yacc file.
4733 sub lang_yacc_target_hook
4734 {
4735     my ($self, $aggregate, $output, $input) = @_;
4736
4737     my $flag = $aggregate . "_YFLAGS";
4738     my $flagvar = var $flag;
4739     my $YFLAGSvar = var 'YFLAGS';
4740     if (($flagvar && $flagvar->variable_value =~ /$DASH_D_PATTERN/o)
4741         || ($YFLAGSvar && $YFLAGSvar->variable_value =~ /$DASH_D_PATTERN/o))
4742     {
4743         (my $output_base = $output) =~ s/$KNOWN_EXTENSIONS_PATTERN$//;
4744         my $header = $output_base . '.h';
4745
4746         # Found a `-d' that applies to the compilation of this file.
4747         # Add a dependency for the generated header file, and arrange
4748         # for that file to be included in the distribution.
4749         # FIXME: this fails for `nodist_*_SOURCES'.
4750         $output_rules .= ("${header}: $output\n"
4751                           # Recover from removal of $header
4752                           . "\t\@if test ! -f \$@; then \\\n"
4753                           . "\t  rm -f $output; \\\n"
4754                           . "\t  \$(MAKE) $output; \\\n"
4755                           . "\telse :; fi\n");
4756         &push_dist_common ($header);
4757         # If the files are built in the build directory, then we want
4758         # to remove them with `make clean'.  If they are in srcdir
4759         # they shouldn't be touched.  However, we can't determine this
4760         # statically, and the GNU rules say that yacc/lex output files
4761         # should be removed by maintainer-clean.  So that's what we
4762         # do.
4763         $clean_files{$header} = MAINTAINER_CLEAN;
4764     }
4765     # Erase $OUTPUT on `make maintainer-clean' (by GNU standards).
4766     # See the comment above for $HEADER.
4767     $clean_files{$output} = MAINTAINER_CLEAN;
4768 }
4769
4770 # This is a lex helper which is called whenever we have decided to
4771 # compile a lex file.
4772 sub lang_lex_target_hook
4773 {
4774     my ($self, $aggregate, $output, $input) = @_;
4775     # If the files are built in the build directory, then we want to
4776     # remove them with `make clean'.  If they are in srcdir they
4777     # shouldn't be touched.  However, we can't determine this
4778     # statically, and the GNU rules say that yacc/lex output files
4779     # should be removed by maintainer-clean.  So that's what we do.
4780     $clean_files{$output} = MAINTAINER_CLEAN;
4781 }
4782
4783 # This is a helper for both lex and yacc.
4784 sub yacc_lex_finish_helper
4785 {
4786     return if defined $language_scratch{'lex-yacc-done'};
4787     $language_scratch{'lex-yacc-done'} = 1;
4788
4789     # If there is more than one distinct yacc (resp lex) source file
4790     # in a given directory, then the `ylwrap' program is required to
4791     # allow parallel builds to work correctly.  FIXME: for now, no
4792     # line number.
4793     require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
4794     if ($config_aux_dir_set_in_configure_in)
4795     {
4796         &define_variable ('YLWRAP', $config_aux_dir . "/ylwrap", INTERNAL);
4797     }
4798     else
4799     {
4800         &define_variable ('YLWRAP', '$(top_srcdir)/ylwrap', INTERNAL);
4801     }
4802 }
4803
4804 sub lang_yacc_finish
4805 {
4806   return if defined $language_scratch{'yacc-done'};
4807   $language_scratch{'yacc-done'} = 1;
4808
4809   reject_var 'YACCFLAGS', "`YACCFLAGS' obsolete; use `YFLAGS' instead";
4810
4811   &yacc_lex_finish_helper
4812     if count_files_for_language ('yacc') > 1;
4813 }
4814
4815
4816 sub lang_lex_finish
4817 {
4818   return if defined $language_scratch{'lex-done'};
4819   $language_scratch{'lex-done'} = 1;
4820
4821   &yacc_lex_finish_helper
4822     if count_files_for_language ('lex') > 1;
4823 }
4824
4825
4826 # Given a hash table of linker names, pick the name that has the most
4827 # precedence.  This is lame, but something has to have global
4828 # knowledge in order to eliminate the conflict.  Add more linkers as
4829 # required.
4830 sub resolve_linker
4831 {
4832     my (%linkers) = @_;
4833
4834     foreach my $l (qw(GCJLINK CXXLINK F77LINK OBJCLINK))
4835     {
4836         return $l if defined $linkers{$l};
4837     }
4838     return 'LINK';
4839 }
4840
4841 # Called to indicate that an extension was used.
4842 sub saw_extension
4843 {
4844     my ($ext) = @_;
4845     if (! defined $extension_seen{$ext})
4846     {
4847         $extension_seen{$ext} = 1;
4848     }
4849     else
4850     {
4851         ++$extension_seen{$ext};
4852     }
4853 }
4854
4855 # Return the number of files seen for a given language.  Knows about
4856 # special cases we care about.  FIXME: this is hideous.  We need
4857 # something that involves real language objects.  For instance yacc
4858 # and yaccxx could both derive from a common yacc class which would
4859 # know about the strange ylwrap requirement.  (Or better yet we could
4860 # just not support legacy yacc!)
4861 sub count_files_for_language
4862 {
4863     my ($name) = @_;
4864
4865     my @names;
4866     if ($name eq 'yacc' || $name eq 'yaccxx')
4867     {
4868         @names = ('yacc', 'yaccxx');
4869     }
4870     elsif ($name eq 'lex' || $name eq 'lexxx')
4871     {
4872         @names = ('lex', 'lexxx');
4873     }
4874     else
4875     {
4876         @names = ($name);
4877     }
4878
4879     my $r = 0;
4880     foreach $name (@names)
4881     {
4882         my $lang = $languages{$name};
4883         foreach my $ext (@{$lang->extensions})
4884         {
4885             $r += $extension_seen{$ext}
4886                 if defined $extension_seen{$ext};
4887         }
4888     }
4889
4890     return $r
4891 }
4892
4893 # Called to ask whether source files have been seen . If HEADERS is 1,
4894 # headers can be included.
4895 sub saw_sources_p
4896 {
4897     my ($headers) = @_;
4898
4899     # count all the sources
4900     my $count = 0;
4901     foreach my $val (values %extension_seen)
4902     {
4903         $count += $val;
4904     }
4905
4906     if (!$headers)
4907     {
4908         $count -= count_files_for_language ('header');
4909     }
4910
4911     return $count > 0;
4912 }
4913
4914
4915 # register_language (%ATTRIBUTE)
4916 # ------------------------------
4917 # Register a single language.
4918 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
4919 sub register_language (%)
4920 {
4921   my (%option) = @_;
4922
4923   # Set the defaults.
4924   $option{'ansi'} = 0
4925     unless defined $option{'ansi'};
4926   $option{'autodep'} = 'no'
4927     unless defined $option{'autodep'};
4928   $option{'linker'} = ''
4929     unless defined $option{'linker'};
4930   $option{'flags'} = []
4931     unless defined $option{'flags'};
4932   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
4933     unless defined $option{'output_extensions'};
4934
4935   my $lang = new Language (%option);
4936
4937   # Fill indexes.
4938   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
4939   $languages{$lang->name} = $lang;
4940
4941   # Update the pattern of known extensions.
4942   accept_extensions (@{$lang->extensions});
4943
4944   # Upate the $suffix_rule map.
4945   foreach my $suffix (@{$lang->extensions})
4946     {
4947       foreach my $dest (&{$lang->output_extensions} ($suffix))
4948         {
4949           register_suffix_rule (INTERNAL, $suffix, $dest);
4950         }
4951     }
4952 }
4953
4954 # derive_suffix ($EXT, $OBJ)
4955 # --------------------------
4956 # This function is used to find a path from a user-specified suffix $EXT
4957 # to $OBJ or to some other suffix we recognize internally, e.g. `cc'.
4958 sub derive_suffix ($$)
4959 {
4960   my ($source_ext, $obj) = @_;
4961
4962   while (! $extension_map{$source_ext}
4963          && $source_ext ne $obj
4964          && exists $suffix_rules->{$source_ext}
4965          && exists $suffix_rules->{$source_ext}{$obj})
4966     {
4967       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
4968     }
4969
4970   return $source_ext;
4971 }
4972
4973
4974 ################################################################
4975
4976 # Pretty-print something and append to output_rules.
4977 sub pretty_print_rule
4978 {
4979     $output_rules .= &makefile_wrap (@_);
4980 }
4981
4982
4983 ################################################################
4984
4985
4986 ## -------------------------------- ##
4987 ## Handling the conditional stack.  ##
4988 ## -------------------------------- ##
4989
4990
4991 # $STRING
4992 # make_conditional_string ($NEGATE, $COND)
4993 # ----------------------------------------
4994 sub make_conditional_string ($$)
4995 {
4996   my ($negate, $cond) = @_;
4997   $cond = "${cond}_TRUE"
4998     unless $cond =~ /^TRUE|FALSE$/;
4999   $cond = Automake::Condition::conditional_negate ($cond)
5000     if $negate;
5001   return $cond;
5002 }
5003
5004
5005 # $COND
5006 # cond_stack_if ($NEGATE, $COND, $WHERE)
5007 # --------------------------------------
5008 sub cond_stack_if ($$$)
5009 {
5010   my ($negate, $cond, $where) = @_;
5011
5012   error $where, "$cond does not appear in AM_CONDITIONAL"
5013     if ! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/;
5014
5015   push (@cond_stack, make_conditional_string ($negate, $cond));
5016
5017   return new Automake::Condition (@cond_stack);
5018 }
5019
5020
5021 # $COND
5022 # cond_stack_else ($NEGATE, $COND, $WHERE)
5023 # ----------------------------------------
5024 sub cond_stack_else ($$$)
5025 {
5026   my ($negate, $cond, $where) = @_;
5027
5028   if (! @cond_stack)
5029     {
5030       error $where, "else without if";
5031       return FALSE;
5032     }
5033
5034   $cond_stack[$#cond_stack] =
5035     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
5036
5037   # If $COND is given, check against it.
5038   if (defined $cond)
5039     {
5040       $cond = make_conditional_string ($negate, $cond);
5041
5042       error ($where, "else reminder ($negate$cond) incompatible with "
5043              . "current conditional: $cond_stack[$#cond_stack]")
5044         if $cond_stack[$#cond_stack] ne $cond;
5045     }
5046
5047   return new Automake::Condition (@cond_stack);
5048 }
5049
5050
5051 # $COND
5052 # cond_stack_endif ($NEGATE, $COND, $WHERE)
5053 # -----------------------------------------
5054 sub cond_stack_endif ($$$)
5055 {
5056   my ($negate, $cond, $where) = @_;
5057   my $old_cond;
5058
5059   if (! @cond_stack)
5060     {
5061       error $where, "endif without if";
5062       return TRUE;
5063     }
5064
5065   # If $COND is given, check against it.
5066   if (defined $cond)
5067     {
5068       $cond = make_conditional_string ($negate, $cond);
5069
5070       error ($where, "endif reminder ($negate$cond) incompatible with "
5071              . "current conditional: $cond_stack[$#cond_stack]")
5072         if $cond_stack[$#cond_stack] ne $cond;
5073     }
5074
5075   pop @cond_stack;
5076
5077   return new Automake::Condition (@cond_stack);
5078 }
5079
5080
5081
5082
5083
5084 ## ------------------------ ##
5085 ## Handling the variables.  ##
5086 ## ------------------------ ##
5087
5088
5089 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
5090 # -----------------------------------------------------
5091 # Like define_variable, but the value is a list, and the variable may
5092 # be defined conditionally.  The second argument is the Condition
5093 # under which the value should be defined; this should be the empty
5094 # string to define the variable unconditionally.  The third argument
5095 # is a list holding the values to use for the variable.  The value is
5096 # pretty printed in the output file.
5097 sub define_pretty_variable ($$$@)
5098 {
5099     my ($var, $cond, $where, @value) = @_;
5100
5101     if (! vardef ($var, $cond))
5102     {
5103         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
5104                                     '', $where, VAR_PRETTY);
5105         rvar ($var)->rdef ($cond)->set_seen;
5106     }
5107 }
5108
5109
5110 # define_variable ($VAR, $VALUE, $WHERE)
5111 # --------------------------------------
5112 # Define a new user variable VAR to VALUE, but only if not already defined.
5113 sub define_variable ($$$)
5114 {
5115     my ($var, $value, $where) = @_;
5116     define_pretty_variable ($var, TRUE, $where, $value);
5117 }
5118
5119
5120 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
5121 # -----------------------------------------------------------
5122 # Define the $VAR which content is the list of file names composed of
5123 # a @BASENAME and the $EXTENSION.
5124 sub define_files_variable ($\@$$)
5125 {
5126   my ($var, $basename, $extension, $where) = @_;
5127   define_variable ($var,
5128                    join (' ', map { "$_.$extension" } @$basename),
5129                    $where);
5130 }
5131
5132
5133 # Like define_variable, but define a variable to be the configure
5134 # substitution by the same name.
5135 sub define_configure_variable ($)
5136 {
5137   my ($var) = @_;
5138
5139   my $pretty = VAR_ASIS;
5140   my $owner = VAR_CONFIGURE;
5141
5142   # Do not output the ANSI2KNR configure variable -- we AC_SUBST
5143   # it in protos.m4, but later redefine it elsewhere.  This is
5144   # pretty hacky.  We also don't output AMDEPBACKSLASH: it might
5145   # be subst'd by `\', which certainly would not be appreciated by
5146   # Make.
5147   if ($var eq 'ANSI2KNR' || $var eq 'AMDEPBACKSLASH')
5148     {
5149       $pretty = VAR_SILENT;
5150       $owner = VAR_AUTOMAKE;
5151     }
5152
5153   Automake::Variable::define ($var, $owner, '', TRUE, subst $var,
5154                               '', $configure_vars{$var}, $pretty);
5155 }
5156
5157
5158 # define_compiler_variable ($LANG)
5159 # --------------------------------
5160 # Define a compiler variable.  We also handle defining the `LT'
5161 # version of the command when using libtool.
5162 sub define_compiler_variable ($)
5163 {
5164     my ($lang) = @_;
5165
5166     my ($var, $value) = ($lang->compiler, $lang->compile);
5167     &define_variable ($var, $value, INTERNAL);
5168     &define_variable ("LT$var", "\$(LIBTOOL) --mode=compile $value", INTERNAL)
5169       if var ('LIBTOOL');
5170 }
5171
5172
5173 # define_linker_variable ($LANG)
5174 # ------------------------------
5175 # Define linker variables.
5176 sub define_linker_variable ($)
5177 {
5178     my ($lang) = @_;
5179
5180     my ($var, $value) = ($lang->lder, $lang->ld);
5181     # CCLD = $(CC).
5182     &define_variable ($lang->lder, $lang->ld, INTERNAL);
5183     # CCLINK = $(CCLD) blah blah...
5184     &define_variable ($lang->linker,
5185                       ((var ('LIBTOOL') ? '$(LIBTOOL) --mode=link ' : '')
5186                        . $lang->link),
5187                       INTERNAL);
5188 }
5189
5190 ################################################################
5191
5192 # &check_trailing_slash ($WHERE, $LINE)
5193 # --------------------------------------
5194 # Return 1 iff $LINE ends with a slash.
5195 # Might modify $LINE.
5196 sub check_trailing_slash ($\$)
5197 {
5198   my ($where, $line) = @_;
5199
5200   # Ignore `##' lines.
5201   return 0 if $$line =~ /$IGNORE_PATTERN/o;
5202
5203   # Catch and fix a common error.
5204   msg "syntax", $where, "whitespace following trailing backslash"
5205     if $$line =~ s/\\\s+\n$/\\\n/;
5206
5207   return $$line =~ /\\$/;
5208 }
5209
5210
5211 # &read_am_file ($AMFILE, $WHERE)
5212 # -------------------------------
5213 # Read Makefile.am and set up %contents.  Simultaneously copy lines
5214 # from Makefile.am into $output_trailer, or define variables as
5215 # appropriate.  NOTE we put rules in the trailer section.  We want
5216 # user rules to come after our generated stuff.
5217 sub read_am_file ($$)
5218 {
5219     my ($amfile, $where) = @_;
5220
5221     my $am_file = new Automake::XFile ("< $amfile");
5222     verb "reading $amfile";
5223
5224     # Keep track of the youngest output dependency.
5225     my $mtime = mtime $amfile;
5226     $output_deps_greatest_timestamp = $mtime
5227       if $mtime > $output_deps_greatest_timestamp;
5228
5229     my $spacing = '';
5230     my $comment = '';
5231     my $blank = 0;
5232     my $saw_bk = 0;
5233
5234     use constant IN_VAR_DEF => 0;
5235     use constant IN_RULE_DEF => 1;
5236     use constant IN_COMMENT => 2;
5237     my $prev_state = IN_RULE_DEF;
5238
5239     while ($_ = $am_file->getline)
5240     {
5241         $where->set ("$amfile:$.");
5242         if (/$IGNORE_PATTERN/o)
5243         {
5244             # Merely delete comments beginning with two hashes.
5245         }
5246         elsif (/$WHITE_PATTERN/o)
5247         {
5248             error $where, "blank line following trailing backslash"
5249               if $saw_bk;
5250             # Stick a single white line before the incoming macro or rule.
5251             $spacing = "\n";
5252             $blank = 1;
5253             # Flush all comments seen so far.
5254             if ($comment ne '')
5255             {
5256                 $output_vars .= $comment;
5257                 $comment = '';
5258             }
5259         }
5260         elsif (/$COMMENT_PATTERN/o)
5261         {
5262             # Stick comments before the incoming macro or rule.  Make
5263             # sure a blank line precedes the first block of comments.
5264             $spacing = "\n" unless $blank;
5265             $blank = 1;
5266             $comment .= $spacing . $_;
5267             $spacing = '';
5268             $prev_state = IN_COMMENT;
5269         }
5270         else
5271         {
5272             last;
5273         }
5274         $saw_bk = check_trailing_slash ($where, $_);
5275     }
5276
5277     # We save the conditional stack on entry, and then check to make
5278     # sure it is the same on exit.  This lets us conditionally include
5279     # other files.
5280     my @saved_cond_stack = @cond_stack;
5281     my $cond = new Automake::Condition (@cond_stack);
5282
5283     my $last_var_name = '';
5284     my $last_var_type = '';
5285     my $last_var_value = '';
5286     my $last_where;
5287     # FIXME: shouldn't use $_ in this loop; it is too big.
5288     while ($_)
5289     {
5290         $where->set ("$amfile:$.");
5291
5292         # Make sure the line is \n-terminated.
5293         chomp;
5294         $_ .= "\n";
5295
5296         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
5297         # used by users.  @MAINT@ is an anachronism now.
5298         $_ =~ s/\@MAINT\@//g
5299             unless $seen_maint_mode;
5300
5301         my $new_saw_bk = check_trailing_slash ($where, $_);
5302
5303         if (/$IGNORE_PATTERN/o)
5304         {
5305             # Merely delete comments beginning with two hashes.
5306         }
5307         elsif (/$WHITE_PATTERN/o)
5308         {
5309             # Stick a single white line before the incoming macro or rule.
5310             $spacing = "\n";
5311             error $where, "blank line following trailing backslash"
5312               if $saw_bk;
5313         }
5314         elsif (/$COMMENT_PATTERN/o)
5315         {
5316             # Stick comments before the incoming macro or rule.
5317             $comment .= $spacing . $_;
5318             $spacing = '';
5319             error $where, "comment following trailing backslash"
5320               if $saw_bk && $comment eq '';
5321             $prev_state = IN_COMMENT;
5322         }
5323         elsif ($saw_bk)
5324         {
5325             if ($prev_state == IN_RULE_DEF)
5326             {
5327               my $cond = new Automake::Condition @cond_stack;
5328               $output_trailer .= $cond->subst_string;
5329               $output_trailer .= $_;
5330             }
5331             elsif ($prev_state == IN_COMMENT)
5332             {
5333                 # If the line doesn't start with a `#', add it.
5334                 # We do this because a continued comment like
5335                 #   # A = foo \
5336                 #         bar \
5337                 #         baz
5338                 # is not portable.  BSD make doesn't honor
5339                 # escaped newlines in comments.
5340                 s/^#?/#/;
5341                 $comment .= $spacing . $_;
5342             }
5343             else # $prev_state == IN_VAR_DEF
5344             {
5345               $last_var_value .= ' '
5346                 unless $last_var_value =~ /\s$/;
5347               $last_var_value .= $_;
5348
5349               if (!/\\$/)
5350                 {
5351                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
5352                                               $last_var_type, $cond,
5353                                               $last_var_value, $comment,
5354                                               $last_where, VAR_ASIS)
5355                     if $cond != FALSE;
5356                   $comment = $spacing = '';
5357                 }
5358             }
5359         }
5360
5361         elsif (/$IF_PATTERN/o)
5362           {
5363             $cond = cond_stack_if ($1, $2, $where);
5364           }
5365         elsif (/$ELSE_PATTERN/o)
5366           {
5367             $cond = cond_stack_else ($1, $2, $where);
5368           }
5369         elsif (/$ENDIF_PATTERN/o)
5370           {
5371             $cond = cond_stack_endif ($1, $2, $where);
5372           }
5373
5374         elsif (/$RULE_PATTERN/o)
5375         {
5376             # Found a rule.
5377             $prev_state = IN_RULE_DEF;
5378
5379             # For now we have to output all definitions of user rules
5380             # and can't diagnose duplicates (see the comment in
5381             # rule_define). So we go on and ignore the return value.
5382             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
5383
5384             check_variable_expansions ($_, $where);
5385
5386             $output_trailer .= $comment . $spacing;
5387             my $cond = new Automake::Condition @cond_stack;
5388             $output_trailer .= $cond->subst_string;
5389             $output_trailer .= $_;
5390             $comment = $spacing = '';
5391         }
5392         elsif (/$ASSIGNMENT_PATTERN/o)
5393         {
5394             # Found a macro definition.
5395             $prev_state = IN_VAR_DEF;
5396             $last_var_name = $1;
5397             $last_var_type = $2;
5398             $last_var_value = $3;
5399             $last_where = $where->clone;
5400             if ($3 ne '' && substr ($3, -1) eq "\\")
5401             {
5402                 # We preserve the `\' because otherwise the long lines
5403                 # that are generated will be truncated by broken
5404                 # `sed's.
5405                 $last_var_value = $3 . "\n";
5406             }
5407
5408             if (!/\\$/)
5409               {
5410                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
5411                                             $last_var_type, $cond,
5412                                             $last_var_value, $comment,
5413                                             $last_where, VAR_ASIS)
5414                   if $cond != FALSE;
5415                 $comment = $spacing = '';
5416               }
5417         }
5418         elsif (/$INCLUDE_PATTERN/o)
5419         {
5420             my $path = $1;
5421
5422             if ($path =~ s/^\$\(top_srcdir\)\///)
5423               {
5424                 push (@include_stack, "\$\(top_srcdir\)/$path");
5425                 # Distribute any included file.
5426
5427                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
5428                 # otherwise OSF make will implicitly copy the included
5429                 # file in the build tree during `make distdir' to satisfy
5430                 # the dependency.
5431                 # (subdircond2.test and subdircond3.test will fail.)
5432                 push_dist_common ("\$\(top_srcdir\)/$path");
5433               }
5434             else
5435               {
5436                 $path =~ s/\$\(srcdir\)\///;
5437                 push (@include_stack, "\$\(srcdir\)/$path");
5438                 # Always use the $(srcdir) prefix in DIST_COMMON,
5439                 # otherwise OSF make will implicitly copy the included
5440                 # file in the build tree during `make distdir' to satisfy
5441                 # the dependency.
5442                 # (subdircond2.test and subdircond3.test will fail.)
5443                 push_dist_common ("\$\(srcdir\)/$path");
5444                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
5445               }
5446             $where->push_context ("`$path' included from here");
5447             &read_am_file ($path, $where);
5448             $where->pop_context;
5449         }
5450         else
5451         {
5452             # This isn't an error; it is probably a continued rule.
5453             # In fact, this is what we assume.
5454             $prev_state = IN_RULE_DEF;
5455             check_variable_expansions ($_, $where);
5456             $output_trailer .= $comment . $spacing;
5457             my $cond = new Automake::Condition @cond_stack;
5458             $output_trailer .= $cond->subst_string;
5459             $output_trailer .= $_;
5460             $comment = $spacing = '';
5461             error $where, "`#' comment at start of rule is unportable"
5462               if $_ =~ /^\t\s*\#/;
5463         }
5464
5465         $saw_bk = $new_saw_bk;
5466         $_ = $am_file->getline;
5467     }
5468
5469     $output_trailer .= $comment;
5470
5471     error ($where, "trailing backslash on last line")
5472       if $saw_bk;
5473
5474     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
5475                     : "too many conditionals closed in include file"))
5476       if "@saved_cond_stack" ne "@cond_stack";
5477 }
5478
5479
5480 # define_standard_variables ()
5481 # ----------------------------
5482 # A helper for read_main_am_file which initializes configure variables
5483 # and variables from header-vars.am.
5484 sub define_standard_variables
5485 {
5486   my $saved_output_vars = $output_vars;
5487   my ($comments, undef, $rules) =
5488     file_contents_internal (1, "$libdir/am/header-vars.am",
5489                             new Automake::Location);
5490
5491   foreach my $var (sort keys %configure_vars)
5492     {
5493       &define_configure_variable ($var);
5494     }
5495
5496   $output_vars .= $comments . $rules;
5497 }
5498
5499 # Read main am file.
5500 sub read_main_am_file
5501 {
5502     my ($amfile) = @_;
5503
5504     # This supports the strange variable tricks we are about to play.
5505     prog_error (macros_dump () . "variable defined before read_main_am_file")
5506       if (scalar (variables) > 0);
5507
5508     # Generate copyright header for generated Makefile.in.
5509     # We do discard the output of predefined variables, handled below.
5510     $output_vars = ("# $in_file_name generated by automake "
5511                    . $VERSION . " from $am_file_name.\n");
5512     $output_vars .= '# ' . subst ('configure_input') . "\n";
5513     $output_vars .= $gen_copyright;
5514
5515     # We want to predefine as many variables as possible.  This lets
5516     # the user set them with `+=' in Makefile.am.
5517     &define_standard_variables;
5518
5519     # Read user file, which might override some of our values.
5520     &read_am_file ($amfile, new Automake::Location);
5521 }
5522
5523
5524
5525 ################################################################
5526
5527 # $FLATTENED
5528 # &flatten ($STRING)
5529 # ------------------
5530 # Flatten the $STRING and return the result.
5531 sub flatten
5532 {
5533   $_ = shift;
5534
5535   s/\\\n//somg;
5536   s/\s+/ /g;
5537   s/^ //;
5538   s/ $//;
5539
5540   return $_;
5541 }
5542
5543
5544 # @PARAGRAPHS
5545 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
5546 # ------------------------------------------
5547 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
5548 # paragraphs.
5549 sub make_paragraphs ($%)
5550 {
5551   my ($file, %transform) = @_;
5552
5553   # Complete %transform with global options and make it a Perl
5554   # $command.
5555   my $command =
5556     "s/$IGNORE_PATTERN//gm;"
5557     . transform (%transform,
5558                  'CYGNUS'      => !! option 'cygnus',
5559                  'MAINTAINER-MODE'
5560                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
5561
5562                  'BZIP2'       => !! option 'dist-bzip2',
5563                  'COMPRESS'    => !! option 'dist-tarZ',
5564                  'GZIP'        =>  ! option 'no-dist-gzip',
5565                  'SHAR'        => !! option 'dist-shar',
5566                  'ZIP'         => !! option 'dist-zip',
5567
5568                  'INSTALL-INFO' =>  ! option 'no-installinfo',
5569                  'INSTALL-MAN'  =>  ! option 'no-installman',
5570                  'CK-NEWS'      => !! option 'check-news',
5571
5572                  'SUBDIRS'      => !! var ('SUBDIRS'),
5573                  'TOPDIR'       => backname ($relative_dir),
5574                  'TOPDIR_P'     => $relative_dir eq '.',
5575                  'CONFIGURE-AC' => $configure_ac,
5576
5577                  'BUILD'    => $seen_canonical == AC_CANONICAL_SYSTEM,
5578                  'HOST'     => $seen_canonical,
5579                  'TARGET'   => $seen_canonical == AC_CANONICAL_SYSTEM,
5580
5581                  'LIBTOOL'      => !! var ('LIBTOOL'))
5582     # We don't need more than two consecutive new-lines.
5583     . 's/\n{3,}/\n\n/g';
5584
5585   # Swallow the file and apply the COMMAND.
5586   my $fc_file = new Automake::XFile "< $file";
5587   # Looks stupid?
5588   verb "reading $file";
5589   my $saved_dollar_slash = $/;
5590   undef $/;
5591   $_ = $fc_file->getline;
5592   $/ = $saved_dollar_slash;
5593   eval $command;
5594   $fc_file->close;
5595   my $content = $_;
5596
5597   # Split at unescaped new lines.
5598   my @lines = split (/(?<!\\)\n/, $content);
5599   my @res;
5600
5601   while (defined ($_ = shift @lines))
5602     {
5603       my $paragraph = "$_";
5604       # If we are a rule, eat as long as we start with a tab.
5605       if (/$RULE_PATTERN/smo)
5606         {
5607           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
5608             {
5609               $paragraph .= "\n$_";
5610             }
5611           unshift (@lines, $_);
5612         }
5613
5614       # If we are a comments, eat as much comments as you can.
5615       elsif (/$COMMENT_PATTERN/smo)
5616         {
5617           while (defined ($_ = shift @lines)
5618                  && $_ =~ /$COMMENT_PATTERN/smo)
5619             {
5620               $paragraph .= "\n$_";
5621             }
5622           unshift (@lines, $_);
5623         }
5624
5625       push @res, $paragraph;
5626       $paragraph = '';
5627     }
5628
5629   return @res;
5630 }
5631
5632
5633
5634 # ($COMMENT, $VARIABLES, $RULES)
5635 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
5636 # -------------------------------------------------------------
5637 # Return contents of a file from $libdir/am, automatically skipping
5638 # macros or rules which are already known. $IS_AM iff the caller is
5639 # reading an Automake file (as opposed to the user's Makefile.am).
5640 sub file_contents_internal ($$$%)
5641 {
5642     my ($is_am, $file, $where, %transform) = @_;
5643
5644     $where->set ($file);
5645
5646     my $result_vars = '';
5647     my $result_rules = '';
5648     my $comment = '';
5649     my $spacing = '';
5650
5651     # The following flags are used to track rules spanning across
5652     # multiple paragraphs.
5653     my $is_rule = 0;            # 1 if we are processing a rule.
5654     my $discard_rule = 0;       # 1 if the current rule should not be output.
5655
5656     # We save the conditional stack on entry, and then check to make
5657     # sure it is the same on exit.  This lets us conditionally include
5658     # other files.
5659     my @saved_cond_stack = @cond_stack;
5660     my $cond = new Automake::Condition (@cond_stack);
5661
5662     foreach (make_paragraphs ($file, %transform))
5663     {
5664         # FIXME: no line number available.
5665         $where->set ($file);
5666
5667         # Sanity checks.
5668         error $where, "blank line following trailing backslash:\n$_"
5669           if /\\$/;
5670         error $where, "comment following trailing backslash:\n$_"
5671           if /\\#/;
5672
5673         if (/^$/)
5674         {
5675             $is_rule = 0;
5676             # Stick empty line before the incoming macro or rule.
5677             $spacing = "\n";
5678         }
5679         elsif (/$COMMENT_PATTERN/mso)
5680         {
5681             $is_rule = 0;
5682             # Stick comments before the incoming macro or rule.
5683             $comment = "$_\n";
5684         }
5685
5686         # Handle inclusion of other files.
5687         elsif (/$INCLUDE_PATTERN/o)
5688         {
5689             if ($cond != FALSE)
5690               {
5691                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
5692                 $where->push_context ("`$file' included from here");
5693                 # N-ary `.=' fails.
5694                 my ($com, $vars, $rules)
5695                   = file_contents_internal ($is_am, $file, $where, %transform);
5696                 $where->pop_context;
5697                 $comment .= $com;
5698                 $result_vars .= $vars;
5699                 $result_rules .= $rules;
5700               }
5701         }
5702
5703         # Handling the conditionals.
5704         elsif (/$IF_PATTERN/o)
5705           {
5706             $cond = cond_stack_if ($1, $2, $file);
5707           }
5708         elsif (/$ELSE_PATTERN/o)
5709           {
5710             $cond = cond_stack_else ($1, $2, $file);
5711           }
5712         elsif (/$ENDIF_PATTERN/o)
5713           {
5714             $cond = cond_stack_endif ($1, $2, $file);
5715           }
5716
5717         # Handling rules.
5718         elsif (/$RULE_PATTERN/mso)
5719         {
5720           $is_rule = 1;
5721           $discard_rule = 0;
5722           # Separate relationship from optional actions: the first
5723           # `new-line tab" not preceded by backslash (continuation
5724           # line).
5725           my $paragraph = $_;
5726           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
5727           my ($relationship, $actions) = ($1, $2 || '');
5728
5729           # Separate targets from dependencies: the first colon.
5730           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
5731           my ($targets, $dependencies) = ($1, $2);
5732           # Remove the escaped new lines.
5733           # I don't know why, but I have to use a tmp $flat_deps.
5734           my $flat_deps = &flatten ($dependencies);
5735           my @deps = split (' ', $flat_deps);
5736
5737           foreach (split (' ' , $targets))
5738             {
5739               # FIXME: 1. We are not robust to people defining several targets
5740               # at once, only some of them being in %dependencies.  The
5741               # actions from the targets in %dependencies are usually generated
5742               # from the content of %actions, but if some targets in $targets
5743               # are not in %dependencies the ELSE branch will output
5744               # a rule for all $targets (i.e. the targets which are both
5745               # in %dependencies and $targets will have two rules).
5746
5747               # FIXME: 2. The logic here is not able to output a
5748               # multi-paragraph rule several time (e.g. for each condition
5749               # it is defined for) because it only knows the first paragraph.
5750
5751               # FIXME: 3. We are not robust to people defining a subset
5752               # of a previously defined "multiple-target" rule.  E.g.
5753               # `foo:' after `foo bar:'.
5754
5755               # Output only if not in FALSE.
5756               if (defined $dependencies{$_} && $cond != FALSE)
5757                 {
5758                   &depend ($_, @deps);
5759                   if ($actions{$_})
5760                     {
5761                       $actions{$_} .= "\n$actions" if $actions;
5762                     }
5763                   else
5764                     {
5765                       $actions{$_} = $actions;
5766                     }
5767                 }
5768               else
5769                 {
5770                   # Free-lance dependency.  Output the rule for all the
5771                   # targets instead of one by one.
5772                   my @undefined_conds =
5773                     Automake::Rule::define ($targets, $file,
5774                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
5775                                             $cond, $where);
5776                   for my $undefined_cond (@undefined_conds)
5777                     {
5778                       my $condparagraph = $paragraph;
5779                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
5780                       $result_rules .= "$spacing$comment$condparagraph\n";
5781                     }
5782                   if (scalar @undefined_conds == 0)
5783                     {
5784                       # Remember to discard next paragraphs
5785                       # if they belong to this rule.
5786                       # (but see also FIXME: #2 above.)
5787                       $discard_rule = 1;
5788                     }
5789                   $comment = $spacing = '';
5790                   last;
5791                 }
5792             }
5793         }
5794
5795         elsif (/$ASSIGNMENT_PATTERN/mso)
5796         {
5797             my ($var, $type, $val) = ($1, $2, $3);
5798             error $where, "variable `$var' with trailing backslash"
5799               if /\\$/;
5800
5801             $is_rule = 0;
5802
5803             Automake::Variable::define ($var,
5804                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
5805                                         $type, $cond, $val, $comment, $where,
5806                                         VAR_ASIS)
5807               if $cond != FALSE;
5808
5809             $comment = $spacing = '';
5810         }
5811         else
5812         {
5813             # This isn't an error; it is probably some tokens which
5814             # configure is supposed to replace, such as `@SET-MAKE@',
5815             # or some part of a rule cut by an if/endif.
5816             if (! $cond->false && ! ($is_rule && $discard_rule))
5817               {
5818                 s/^/$cond->subst_string/gme;
5819                 $result_rules .= "$spacing$comment$_\n";
5820               }
5821             $comment = $spacing = '';
5822         }
5823     }
5824
5825     error ($where, @cond_stack ?
5826            "unterminated conditionals: @cond_stack" :
5827            "too many conditionals closed in include file")
5828       if "@saved_cond_stack" ne "@cond_stack";
5829
5830     return ($comment, $result_vars, $result_rules);
5831 }
5832
5833
5834 # $CONTENTS
5835 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
5836 # ------------------------------------------------
5837 # Return contents of a file from $libdir/am, automatically skipping
5838 # macros or rules which are already known.
5839 sub file_contents ($$%)
5840 {
5841     my ($basename, $where, %transform) = @_;
5842     my ($comments, $variables, $rules) =
5843       file_contents_internal (1, "$libdir/am/$basename.am", $where,
5844                               %transform);
5845     return "$comments$variables$rules";
5846 }
5847
5848
5849 # $REGEXP
5850 # &transform (%PAIRS)
5851 # -------------------
5852 # For each ($TOKEN, $VAL) in %PAIRS produce a replacement expression
5853 # suitable for file_contents which:
5854 #   - replaces %$TOKEN% with $VAL,
5855 #   - enables/disables ?$TOKEN? and ?!$TOKEN?,
5856 #   - replaces %?$TOKEN% with TRUE or FALSE.
5857 sub transform (%)
5858 {
5859   my (%pairs) = @_;
5860   my $result = '';
5861
5862   while (my ($token, $val) = each %pairs)
5863     {
5864       $result .= "s/\Q%$token%\E/\Q$val\E/gm;";
5865       if ($val)
5866         {
5867           $result .= "s/\Q?$token?\E//gm;s/^.*\Q?!$token?\E.*\\n//gm;";
5868           $result .= "s/\Q%?$token%\E/TRUE/gm;";
5869         }
5870       else
5871         {
5872           $result .= "s/\Q?!$token?\E//gm;s/^.*\Q?$token?\E.*\\n//gm;";
5873           $result .= "s/\Q%?$token%\E/FALSE/gm;";
5874         }
5875     }
5876
5877   return $result;
5878 }
5879
5880
5881 # &append_exeext ($MACRO)
5882 # -----------------------
5883 # Macro is an Automake magic macro which primary is PROGRAMS, e.g.
5884 # bin_PROGRAMS.  Make sure these programs have $(EXEEXT) appended.
5885 sub append_exeext ($)
5886 {
5887   my ($macro) = @_;
5888
5889   prog_error "append_exeext ($macro)"
5890     unless $macro =~ /_PROGRAMS$/;
5891
5892   transform_variable_recursively
5893     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
5894      sub {
5895        my ($subvar, $val, $cond, $full_cond) = @_;
5896        # Append $(EXEEXT) unless the user did it already.
5897        $val .= '$(EXEEXT)' unless $val =~ /\$\(EXEEXT\)$/;
5898        return $val;
5899      });
5900 }
5901
5902
5903 # @PREFIX
5904 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
5905 # -----------------------------------------------------
5906 # Find all variable prefixes that are used for install directories.  A
5907 # prefix `zar' qualifies iff:
5908 #
5909 # * `zardir' is a variable.
5910 # * `zar_PRIMARY' is a variable.
5911 #
5912 # As a side effect, it looks for misspellings.  It is an error to have
5913 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
5914 # "bin_PROGRAMS".  However, unusual prefixes are allowed if a variable
5915 # of the same name (with "dir" appended) exists.  For instance, if the
5916 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
5917 # This is to provide a little extra flexibility in those cases which
5918 # need it.
5919 sub am_primary_prefixes ($$@)
5920 {
5921   my ($primary, $can_dist, @prefixes) = @_;
5922
5923   local $_;
5924   my %valid = map { $_ => 0 } @prefixes;
5925   $valid{'EXTRA'} = 0;
5926   foreach my $var (variables)
5927     {
5928       # Automake is allowed to define variables that look like primaries
5929       # but which aren't.  E.g. INSTALL_sh_DATA.
5930       # Autoconf can also define variables like INSTALL_DATA, so
5931       # ignore all configure variables (at least those which are not
5932       # redefined in Makefile.am).
5933       # FIXME: We should make sure that these variables are not
5934       # conditionally defined (or else adjust the condition below).
5935       my $def = $var->def (TRUE);
5936       next if $def && $def->owner != VAR_MAKEFILE;
5937
5938       my $varname = $var->name;
5939
5940       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_$primary$/)
5941         {
5942           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
5943           if ($dist ne '' && ! $can_dist)
5944             {
5945               err_var ($var,
5946                        "invalid variable `$varname': `dist' is forbidden");
5947             }
5948           # Standard directories must be explicitly allowed.
5949           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
5950             {
5951               err_var ($var,
5952                        "`${X}dir' is not a legitimate directory " .
5953                        "for `$primary'");
5954             }
5955           # A not explicitly valid directory is allowed if Xdir is defined.
5956           elsif (! defined $valid{$X} &&
5957                  $var->requires_variables ("`$varname' is used", "${X}dir"))
5958             {
5959               # Nothing to do.  Any error message has been output
5960               # by $var->requires_variables.
5961             }
5962           else
5963             {
5964               # Ensure all extended prefixes are actually used.
5965               $valid{"$base$dist$X"} = 1;
5966             }
5967         }
5968     }
5969
5970   # Return only those which are actually defined.
5971   return sort grep { var ($_ . '_' . $primary) } keys %valid;
5972 }
5973
5974
5975 # Handle `where_HOW' variable magic.  Does all lookups, generates
5976 # install code, and possibly generates code to define the primary
5977 # variable.  The first argument is the name of the .am file to munge,
5978 # the second argument is the primary variable (e.g. HEADERS), and all
5979 # subsequent arguments are possible installation locations.
5980 #
5981 # Returns list of [$location, $value] pairs, where
5982 # $value's are the values in all where_HOW variable, and $location
5983 # there associated location (the place here their parent variables were
5984 # defined).
5985 #
5986 # FIXME: this should be rewritten to be cleaner.  It should be broken
5987 # up into multiple functions.
5988 #
5989 # Usage is: am_install_var (OPTION..., file, HOW, where...)
5990 sub am_install_var
5991 {
5992   my (@args) = @_;
5993
5994   my $do_require = 1;
5995   my $can_dist = 0;
5996   my $default_dist = 0;
5997   while (@args)
5998     {
5999       if ($args[0] eq '-noextra')
6000         {
6001           $do_require = 0;
6002         }
6003       elsif ($args[0] eq '-candist')
6004         {
6005           $can_dist = 1;
6006         }
6007       elsif ($args[0] eq '-defaultdist')
6008         {
6009           $default_dist = 1;
6010           $can_dist = 1;
6011         }
6012       elsif ($args[0] !~ /^-/)
6013         {
6014           last;
6015         }
6016       shift (@args);
6017     }
6018
6019   my ($file, $primary, @prefix) = @args;
6020
6021   # Now that configure substitutions are allowed in where_HOW
6022   # variables, it is an error to actually define the primary.  We
6023   # allow `JAVA', as it is customarily used to mean the Java
6024   # interpreter.  This is but one of several Java hacks.  Similarly,
6025   # `PYTHON' is customarily used to mean the Python interpreter.
6026   reject_var $primary, "`$primary' is an anachronism"
6027     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
6028
6029   # Get the prefixes which are valid and actually used.
6030   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
6031
6032   # If a primary includes a configure substitution, then the EXTRA_
6033   # form is required.  Otherwise we can't properly do our job.
6034   my $require_extra;
6035
6036   my @used = ();
6037   my @result = ();
6038
6039   # True if the iteration is the first one.  Used for instance to
6040   # output parts of the associated file only once.
6041   my $first = 1;
6042   foreach my $X (@prefix)
6043     {
6044       my $nodir_name = $X;
6045       my $one_name = $X . '_' . $primary;
6046       my $one_var = var $one_name;
6047
6048       my $strip_subdir = 1;
6049       # If subdir prefix should be preserved, do so.
6050       if ($nodir_name =~ /^nobase_/)
6051         {
6052           $strip_subdir = 0;
6053           $nodir_name =~ s/^nobase_//;
6054         }
6055
6056       # If files should be distributed, do so.
6057       my $dist_p = 0;
6058       if ($can_dist)
6059         {
6060           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
6061                      || (! $default_dist && $nodir_name =~ /^dist_/));
6062           $nodir_name =~ s/^(dist|nodist)_//;
6063         }
6064
6065
6066       # Use the location of the currently processed variable.
6067       # We are not processing a particular condition, so pick the first
6068       # available.
6069       my $tmpcond = $one_var->conditions->one_cond;
6070       my $where = $one_var->rdef ($tmpcond)->location->clone;
6071
6072       # Append actual contents of where_PRIMARY variable to
6073       # @result, skipping @substitutions@.
6074       foreach my $locvals ($one_var->loc_and_value_as_list_recursive ('all'))
6075         {
6076           my ($loc, $value) = @$locvals;
6077           # Skip configure substitutions.
6078           if ($value =~ /^\@.*\@$/)
6079             {
6080               if ($nodir_name eq 'EXTRA')
6081                 {
6082                   error ($where,
6083                          "`$one_name' contains configure substitution, "
6084                          . "but shouldn't");
6085                 }
6086               # Check here to make sure variables defined in
6087               # configure.ac do not imply that EXTRA_PRIMARY
6088               # must be defined.
6089               elsif (! defined $configure_vars{$one_name})
6090                 {
6091                   $require_extra = $one_name
6092                     if $do_require;
6093                 }
6094             }
6095           else
6096             {
6097               push (@result, $locvals);
6098             }
6099         }
6100       # A blatant hack: we rewrite each _PROGRAMS primary to include
6101       # EXEEXT.
6102       append_exeext ($one_name)
6103         if $primary eq 'PROGRAMS';
6104       # "EXTRA" shouldn't be used when generating clean targets,
6105       # all, or install targets.  We used to warn if EXTRA_FOO was
6106       # defined uselessly, but this was annoying.
6107       next
6108         if $nodir_name eq 'EXTRA';
6109
6110       if ($nodir_name eq 'check')
6111         {
6112           push (@check, '$(' . $one_name . ')');
6113         }
6114       else
6115         {
6116           push (@used, '$(' . $one_name . ')');
6117         }
6118
6119       # Is this to be installed?
6120       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
6121
6122       # If so, with install-exec? (or install-data?).
6123       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
6124
6125       my $check_options_p = $install_p && !! option 'std-options';
6126
6127       # Use the location of the currently processed variable as context.
6128       $where->push_context ("while processing `$one_name'");
6129
6130       # Singular form of $PRIMARY.
6131       (my $one_primary = $primary) =~ s/S$//;
6132       $output_rules .= &file_contents ($file, $where,
6133                                          FIRST => $first,
6134
6135                                          PRIMARY     => $primary,
6136                                          ONE_PRIMARY => $one_primary,
6137                                          DIR         => $X,
6138                                          NDIR        => $nodir_name,
6139                                          BASE        => $strip_subdir,
6140
6141                                          EXEC      => $exec_p,
6142                                          INSTALL   => $install_p,
6143                                          DIST      => $dist_p,
6144                                          'CK-OPTS' => $check_options_p);
6145
6146       $first = 0;
6147     }
6148
6149   # The JAVA variable is used as the name of the Java interpreter.
6150   # The PYTHON variable is used as the name of the Python interpreter.
6151   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
6152     {
6153       # Define it.
6154       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
6155       $output_vars .= "\n";
6156     }
6157
6158   err_var ($require_extra,
6159            "`$require_extra' contains configure substitution,\n"
6160            . "but `EXTRA_$primary' not defined")
6161     if ($require_extra && ! var ('EXTRA_' . $primary));
6162
6163   # Push here because PRIMARY might be configure time determined.
6164   push (@all, '$(' . $primary . ')')
6165     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
6166
6167   # Make the result unique.  This lets the user use conditionals in
6168   # a natural way, but still lets us program lazily -- we don't have
6169   # to worry about handling a particular object more than once.
6170   # We will keep only one location per object.
6171   my %result = ();
6172   for my $pair (@result)
6173     {
6174       my ($loc, $val) = @$pair;
6175       $result{$val} = $loc;
6176     }
6177   my @l = sort keys %result;
6178   return map { [$result{$_}->clone, $_] } @l;
6179 }
6180
6181
6182 ################################################################
6183
6184 # Each key in this hash is the name of a directory holding a
6185 # Makefile.in.  These variables are local to `is_make_dir'.
6186 my %make_dirs = ();
6187 my $make_dirs_set = 0;
6188
6189 sub is_make_dir
6190 {
6191     my ($dir) = @_;
6192     if (! $make_dirs_set)
6193     {
6194         foreach my $iter (@configure_input_files)
6195         {
6196             $make_dirs{dirname ($iter)} = 1;
6197         }
6198         # We also want to notice Makefile.in's.
6199         foreach my $iter (@other_input_files)
6200         {
6201             if ($iter =~ /Makefile\.in$/)
6202             {
6203                 $make_dirs{dirname ($iter)} = 1;
6204             }
6205         }
6206         $make_dirs_set = 1;
6207     }
6208     return defined $make_dirs{$dir};
6209 }
6210
6211 ################################################################
6212
6213 # This variable is local to the "require file" set of functions.
6214 my @require_file_paths = ();
6215
6216
6217 # &maybe_push_required_file ($DIR, $FILE, $FULLFILE)
6218 # --------------------------------------------------
6219 # See if we want to push this file onto dist_common.  This function
6220 # encodes the rules for deciding when to do so.
6221 sub maybe_push_required_file
6222 {
6223     my ($dir, $file, $fullfile) = @_;
6224
6225     if ($dir eq $relative_dir)
6226     {
6227         push_dist_common ($file);
6228         return 1;
6229     }
6230     elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
6231     {
6232         # If we are doing the topmost directory, and the file is in a
6233         # subdir which does not have a Makefile, then we distribute it
6234         # here.
6235         push_dist_common ($fullfile);
6236         return 1;
6237     }
6238     return 0;
6239 }
6240
6241
6242 # &require_file_internal ($WHERE, $MYSTRICT, @FILES)
6243 # --------------------------------------------------
6244 # Verify that the file must exist in the current directory.
6245 # $MYSTRICT is the strictness level at which this file becomes required.
6246 #
6247 # Must set require_file_paths before calling this function.
6248 # require_file_paths is set to hold a single directory (the one in
6249 # which the first file was found) before return.
6250 sub require_file_internal ($$@)
6251 {
6252     my ($where, $mystrict, @files) = @_;
6253
6254     foreach my $file (@files)
6255     {
6256         my $fullfile;
6257         my $errdir;
6258         my $errfile;
6259         my $save_dir;
6260
6261         my $found_it = 0;
6262         my $dangling_sym = 0;
6263         foreach my $dir (@require_file_paths)
6264         {
6265             $fullfile = $dir . "/" . $file;
6266             $errdir = $dir unless $errdir;
6267
6268             # Use different name for "error filename".  Otherwise on
6269             # an error the bad file will be reported as e.g.
6270             # `../../install-sh' when using the default
6271             # config_aux_path.
6272             $errfile = $errdir . '/' . $file;
6273
6274             if (-l $fullfile && ! -f $fullfile)
6275             {
6276                 $dangling_sym = 1;
6277                 last;
6278             }
6279             elsif (-f $fullfile)
6280             {
6281                 $found_it = 1;
6282                 maybe_push_required_file ($dir, $file, $fullfile);
6283                 $save_dir = $dir;
6284                 last;
6285             }
6286         }
6287
6288         # `--force-missing' only has an effect if `--add-missing' is
6289         # specified.
6290         if ($found_it && (! $add_missing || ! $force_missing))
6291         {
6292             # Prune the path list.
6293             @require_file_paths = $save_dir;
6294         }
6295         else
6296         {
6297             # If we've already looked for it, we're done.  You might
6298             # wonder why we don't do this before searching for the
6299             # file.  If we do that, then something like
6300             # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
6301             # DIST_COMMON.
6302             if (! $found_it)
6303             {
6304                 next if defined $require_file_found{$fullfile};
6305                 $require_file_found{$fullfile} = 1;
6306             }
6307
6308             if ($strictness >= $mystrict)
6309             {
6310                 if ($dangling_sym && $add_missing)
6311                 {
6312                     unlink ($fullfile);
6313                 }
6314
6315                 my $trailer = '';
6316                 my $suppress = 0;
6317
6318                 # Only install missing files according to our desired
6319                 # strictness level.
6320                 my $message = "required file `$errfile' not found";
6321                 if ($add_missing)
6322                 {
6323                     if (-f ("$libdir/$file"))
6324                     {
6325                         $suppress = 1;
6326
6327                         # Install the missing file.  Symlink if we
6328                         # can, copy if we must.  Note: delete the file
6329                         # first, in case it is a dangling symlink.
6330                         $message = "installing `$errfile'";
6331                         # Windows Perl will hang if we try to delete a
6332                         # file that doesn't exist.
6333                         unlink ($errfile) if -f $errfile;
6334                         if ($symlink_exists && ! $copy_missing)
6335                         {
6336                             if (! symlink ("$libdir/$file", $errfile))
6337                             {
6338                                 $suppress = 0;
6339                                 $trailer = "; error while making link: $!";
6340                             }
6341                         }
6342                         elsif (system ('cp', "$libdir/$file", $errfile))
6343                         {
6344                             $suppress = 0;
6345                             $trailer = "\n    error while copying";
6346                         }
6347                     }
6348
6349                     if (! maybe_push_required_file (dirname ($errfile),
6350                                                     $file, $errfile))
6351                     {
6352                         if (! $found_it)
6353                         {
6354                             # We have added the file but could not push it
6355                             # into DIST_COMMON (probably because this is
6356                             # an auxiliary file and we are not processing
6357                             # the top level Makefile). This is unfortunate,
6358                             # since it means we are using a file which is not
6359                             # distributed!
6360
6361                             # Get Automake to be run again: on the second
6362                             # run the file will be found, and pushed into
6363                             # the toplevel DIST_COMMON automatically.
6364                             $automake_needs_to_reprocess_all_files = 1;
6365                         }
6366                     }
6367
6368                     # Prune the path list.
6369                     @require_file_paths = &dirname ($errfile);
6370                 }
6371
6372                 # If --force-missing was specified, and we have
6373                 # actually found the file, then do nothing.
6374                 next
6375                     if $found_it && $force_missing;
6376
6377                 # If we couldn' install the file, but it is a target in
6378                 # the Makefile, don't print anything.  This allows files
6379                 # like README, AUTHORS, or THANKS to be generated.
6380                 next
6381                   if !$suppress && rule $file;
6382
6383                 msg ($suppress ? 'note' : 'error', $where, "$message$trailer");
6384             }
6385         }
6386     }
6387 }
6388
6389 # &require_file ($WHERE, $MYSTRICT, @FILES)
6390 # -----------------------------------------
6391 sub require_file ($$@)
6392 {
6393     my ($where, $mystrict, @files) = @_;
6394     @require_file_paths = $relative_dir;
6395     require_file_internal ($where, $mystrict, @files);
6396 }
6397
6398 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
6399 # -----------------------------------------------------------
6400 sub require_file_with_macro ($$$@)
6401 {
6402     my ($cond, $macro, $mystrict, @files) = @_;
6403     $macro = rvar ($macro) unless ref $macro;
6404     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
6405 }
6406
6407
6408 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
6409 # ----------------------------------------------
6410 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
6411 sub require_conf_file ($$@)
6412 {
6413     my ($where, $mystrict, @files) = @_;
6414     @require_file_paths = @config_aux_path;
6415     require_file_internal ($where, $mystrict, @files);
6416     my $dir = $require_file_paths[0];
6417     @config_aux_path = @require_file_paths;
6418      # Avoid unsightly '/.'s.
6419     $config_aux_dir = '$(top_srcdir)' . ($dir eq '.' ? "" : "/$dir");
6420 }
6421
6422
6423 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
6424 # ----------------------------------------------------------------
6425 sub require_conf_file_with_macro ($$$@)
6426 {
6427     my ($cond, $macro, $mystrict, @files) = @_;
6428     require_conf_file (rvar ($macro)->rdef ($cond)->location,
6429                        $mystrict, @files);
6430 }
6431
6432 ################################################################
6433
6434 # &require_build_directory ($DIRECTORY)
6435 # ------------------------------------
6436 # Emit rules to create $DIRECTORY if needed, and return
6437 # the file that any target requiring this directory should be made
6438 # dependent upon.
6439 sub require_build_directory ($)
6440 {
6441   my $directory = shift;
6442   my $dirstamp = "$directory/\$(am__dirstamp)";
6443
6444   # Don't emit the rule twice.
6445   if (! defined $directory_map{$directory})
6446     {
6447       $directory_map{$directory} = 1;
6448
6449       # Set a variable for the dirstamp basename.
6450       define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
6451                               '$(am__leading_dot)dirstamp');
6452
6453       # Directory must be removed by `make distclean'.
6454       $clean_files{$dirstamp} = DIST_CLEAN;
6455
6456       $output_rules .= ("$dirstamp:\n"
6457                         . "\t\@\$(mkinstalldirs) $directory\n"
6458                         . "\t\@: > $dirstamp\n");
6459     }
6460
6461   return $dirstamp;
6462 }
6463
6464 # &require_build_directory_maybe ($FILE)
6465 # --------------------------------------
6466 # If $FILE lies in a subdirectory, emit a rule to create this
6467 # directory and return the file that $FILE should be made
6468 # dependent upon.  Otherwise, just return the empty string.
6469 sub require_build_directory_maybe ($)
6470 {
6471     my $file = shift;
6472     my $directory = dirname ($file);
6473
6474     if ($directory ne '.')
6475     {
6476         return require_build_directory ($directory);
6477     }
6478     else
6479     {
6480         return '';
6481     }
6482 }
6483
6484 ################################################################
6485
6486 # Push a list of files onto dist_common.
6487 sub push_dist_common
6488 {
6489   prog_error "push_dist_common run after handle_dist"
6490     if $handle_dist_run;
6491   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
6492                               '', INTERNAL, VAR_PRETTY);
6493 }
6494
6495
6496 ################################################################
6497
6498 # generate_makefile ($OUTPUT, $MAKEFILE)
6499 # --------------------------------------
6500 # Generate a Makefile.in given the name of the corresponding Makefile and
6501 # the name of the file output by config.status.
6502 sub generate_makefile ($$)
6503 {
6504   my ($output, $makefile) = @_;
6505
6506   # Reset all the Makefile.am related variables.
6507   initialize_per_input;
6508
6509   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
6510   # warnings for this file.  So hold any warning issued before
6511   # we have processed AUTOMAKE_OPTIONS.
6512   buffer_messages ('warning');
6513
6514   # Name of input file ("Makefile.am") and output file
6515   # ("Makefile.in").  These have no directory components.
6516   $am_file_name = basename ($makefile) . '.am';
6517   $in_file_name = basename ($makefile) . '.in';
6518
6519   # $OUTPUT is encoded.  If it contains a ":" then the first element
6520   # is the real output file, and all remaining elements are input
6521   # files.  We don't scan or otherwise deal with these input files,
6522   # other than to mark them as dependencies.  See
6523   # &scan_autoconf_files for details.
6524   my (@secondary_inputs);
6525   ($output, @secondary_inputs) = split (/:/, $output);
6526
6527   $relative_dir = dirname ($output);
6528   $am_relative_dir = dirname ($makefile);
6529
6530   read_main_am_file ($makefile . '.am');
6531   if (handle_options)
6532     {
6533       # Process buffered warnings.
6534       flush_messages;
6535       # Fatal error.  Just return, so we can continue with next file.
6536       return;
6537     }
6538   # Process buffered warnings.
6539   flush_messages;
6540
6541   # There are a few install-related variables that you should not define.
6542   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
6543     {
6544       my $v = var $var;
6545       if ($v)
6546         {
6547           my $def = $v->def (TRUE);
6548           prog_error "$var not defined in condition TRUE"
6549             unless $def;
6550           reject_var $var, "`$var' should not be defined"
6551             if $def->owner != VAR_AUTOMAKE;
6552         }
6553     }
6554
6555   # Catch some obsolete variables.
6556   msg_var ('obsolete', 'INCLUDES',
6557            "`INCLUDES' is the old name for `AM_CPPFLAGS'")
6558     if var ('INCLUDES');
6559
6560   # At the toplevel directory, we might need config.guess, config.sub
6561   # or libtool scripts (ltconfig and ltmain.sh).
6562   if ($relative_dir eq '.')
6563     {
6564       # AC_CANONICAL_HOST and AC_CANONICAL_SYSTEM need config.guess and
6565       # config.sub.
6566       require_conf_file ($canonical_location, FOREIGN,
6567                          'config.guess', 'config.sub')
6568         if $seen_canonical;
6569     }
6570
6571   # Must do this after reading .am file.
6572   define_variable ('subdir', $relative_dir, INTERNAL);
6573
6574   # Check first, because we might modify some state.
6575   check_cygnus;
6576   check_gnu_standards;
6577   check_gnits_standards;
6578
6579   handle_configure ($output, $makefile, @secondary_inputs);
6580   handle_gettext;
6581   handle_libraries;
6582   handle_ltlibraries;
6583   handle_programs;
6584   handle_scripts;
6585
6586   # This must run first so that the ANSI2KNR definition is generated
6587   # before it is used by the _.c rules.  We have to do this because
6588   # a variable which is used in a dependency must be defined before
6589   # the target, or else make won't properly see it.
6590   handle_compile;
6591   # This must be run after all the sources are scanned.
6592   handle_languages;
6593
6594   # We have to run this after dealing with all the programs.
6595   handle_libtool;
6596
6597   # Variables used by distdir.am and tags.am.
6598   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
6599   define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
6600
6601   handle_multilib;
6602   handle_texinfo;
6603   handle_emacs_lisp;
6604   handle_python;
6605   handle_java;
6606   handle_man_pages;
6607   handle_data;
6608   handle_headers;
6609   handle_subdirs;
6610   handle_tags;
6611   handle_minor_options;
6612   handle_tests;
6613
6614   # This must come after most other rules.
6615   handle_dist ($makefile);
6616
6617   handle_footer;
6618   do_check_merge_target;
6619   handle_all ($output);
6620
6621   # FIXME: Gross!
6622   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
6623     {
6624       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
6625     }
6626
6627   handle_install;
6628   handle_clean;
6629   handle_factored_dependencies;
6630
6631   # Comes last, because all the above procedures may have
6632   # defined or overridden variables.
6633   $output_vars .= output_variables;
6634
6635   check_typos;
6636
6637   if (! -d ($output_directory . '/' . $am_relative_dir))
6638     {
6639       mkdir ($output_directory . '/' . $am_relative_dir, 0755);
6640     }
6641
6642   my ($out_file) = $output_directory . '/' . $makefile . ".in";
6643
6644   # We make sure that `all:' is the first target.
6645   $output =
6646     "$output_vars$output_all$output_header$output_rules$output_trailer";
6647
6648   # Decide whether we must update the output file or not.
6649   # We have to update in the following situations.
6650   #  * $force_generation is set.
6651   #  * any of the output dependencies is younger than the output
6652   #  * the contents of the output is different (this can happen
6653   #    if the project has been populated with a file listed in
6654   #    @common_files since the last run).
6655   # Output's dependencies are split in two sets:
6656   #  * dependencies which are also configure dependencies
6657   #    These do not change between each Makefile.am
6658   #  * other dependencies, specific to the Makefile.am being processed
6659   #    (such as the Makefile.am itself, or any Makefile fragment
6660   #    it includes).
6661   my $timestamp = mtime $out_file;
6662   if (! $force_generation
6663       && $configure_deps_greatest_timestamp < $timestamp
6664       && $output_deps_greatest_timestamp < $timestamp
6665       && $output eq contents ($out_file))
6666   {
6667       verb "$out_file unchanged";
6668       # No need to update.
6669       return;
6670     }
6671
6672   if (-e $out_file)
6673     {
6674       unlink ($out_file)
6675         or fatal "cannot remove $out_file: $!\n";
6676     }
6677
6678   my $gm_file = new Automake::XFile "> $out_file";
6679   verb "creating $out_file";
6680   print $gm_file $output;
6681 }
6682
6683 ################################################################
6684
6685
6686
6687
6688 ################################################################
6689
6690 # Print usage information.
6691 sub usage ()
6692 {
6693     print "Usage: $0 [OPTION] ... [Makefile]...
6694
6695 Generate Makefile.in for configure from Makefile.am.
6696
6697 Operation modes:
6698       --help               print this help, then exit
6699       --version            print version number, then exit
6700   -v, --verbose            verbosely list files processed
6701       --no-force           only update Makefile.in's that are out of date
6702   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
6703
6704 Dependency tracking:
6705   -i, --ignore-deps      disable dependency tracking code
6706       --include-deps     enable dependency tracking code
6707
6708 Flavors:
6709       --cygnus           assume program is part of Cygnus-style tree
6710       --foreign          set strictness to foreign
6711       --gnits            set strictness to gnits
6712       --gnu              set strictness to gnu
6713
6714 Library files:
6715   -a, --add-missing      add missing standard files to package
6716       --libdir=DIR       directory storing library files
6717   -c, --copy             with -a, copy missing files (default is symlink)
6718   -f, --force-missing    force update of standard files
6719
6720 ";
6721     Automake::ChannelDefs::usage;
6722
6723     my ($last, @lcomm);
6724     $last = '';
6725     foreach my $iter (sort ((@common_files, @common_sometimes)))
6726     {
6727         push (@lcomm, $iter) unless $iter eq $last;
6728         $last = $iter;
6729     }
6730
6731     my @four;
6732     print "\nFiles which are automatically distributed, if found:\n";
6733     format USAGE_FORMAT =
6734   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
6735   $four[0],           $four[1],           $four[2],           $four[3]
6736 .
6737     $~ = "USAGE_FORMAT";
6738
6739     my $cols = 4;
6740     my $rows = int(@lcomm / $cols);
6741     my $rest = @lcomm % $cols;
6742
6743     if ($rest)
6744     {
6745         $rows++;
6746     }
6747     else
6748     {
6749         $rest = $cols;
6750     }
6751
6752     for (my $y = 0; $y < $rows; $y++)
6753     {
6754         @four = ("", "", "", "");
6755         for (my $x = 0; $x < $cols; $x++)
6756         {
6757             last if $y + 1 == $rows && $x == $rest;
6758
6759             my $idx = (($x > $rest)
6760                        ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
6761                        : ($rows * $x));
6762
6763             $idx += $y;
6764             $four[$x] = $lcomm[$idx];
6765         }
6766         write;
6767     }
6768
6769     print "\nReport bugs to <bug-automake\@gnu.org>.\n";
6770
6771     # --help always returns 0 per GNU standards.
6772     exit 0;
6773 }
6774
6775
6776 # &version ()
6777 # -----------
6778 # Print version information
6779 sub version ()
6780 {
6781   print <<EOF;
6782 automake (GNU $PACKAGE) $VERSION
6783 Written by Tom Tromey <tromey\@redhat.com>.
6784
6785 Copyright 2003 Free Software Foundation, Inc.
6786 This is free software; see the source for copying conditions.  There is NO
6787 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
6788 EOF
6789   # --version always returns 0 per GNU standards.
6790   exit 0;
6791 }
6792
6793 ################################################################
6794
6795 # Parse command line.
6796 sub parse_arguments ()
6797 {
6798   # Start off as gnu.
6799   set_strictness ('gnu');
6800
6801   my $cli_where = new Automake::Location;
6802   my %cli_options =
6803     (
6804      'libdir:s'         => \$libdir,
6805      'gnu'              => sub { set_strictness ('gnu'); },
6806      'gnits'            => sub { set_strictness ('gnits'); },
6807      'cygnus'           => sub { set_global_option ('cygnus', $cli_where); },
6808      'foreign'          => sub { set_strictness ('foreign'); },
6809      'include-deps'     => sub { unset_global_option ('no-dependencies'); },
6810      'i|ignore-deps'    => sub { set_global_option ('no-dependencies',
6811                                                     $cli_where); },
6812      'no-force'         => sub { $force_generation = 0; },
6813      'f|force-missing'  => \$force_missing,
6814      'o|output-dir:s'   => \$output_directory,
6815      'a|add-missing'    => \$add_missing,
6816      'c|copy'           => \$copy_missing,
6817      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
6818      'W|warnings:s'     => \&parse_warnings,
6819      # These long options (--Werror and --Wno-error) for backward
6820      # compatibility.  Use -Werror and -Wno-error today.
6821      'Werror'           => sub { parse_warnings 'W', 'error'; },
6822      'Wno-error'        => sub { parse_warnings 'W', 'no-error'; },
6823      );
6824   use Getopt::Long;
6825   Getopt::Long::config ("bundling", "pass_through");
6826
6827   # See if --version or --help is used.  We want to process these before
6828   # anything else because the GNU Coding Standards require us to
6829   # `exit 0' after processing these options, and we can't guarantee this
6830   # if we treat other options first.  (Handling other options first
6831   # could produce error diagnostics, and in this condition it is
6832   # confusing if Automake does `exit 0'.)
6833   my %cli_options_1st_pass =
6834     (
6835      'version' => \&version,
6836      'help'    => \&usage,
6837      # Recognize all other options (and their arguments) but do nothing.
6838      map { $_ => sub {} } (keys %cli_options)
6839      );
6840   my @ARGV_backup = @ARGV;
6841   Getopt::Long::GetOptions %cli_options_1st_pass
6842     or exit 1;
6843   @ARGV = @ARGV_backup;
6844
6845   # Now *really* process the options.  This time we know
6846   # that --help and --version are not present.
6847   Getopt::Long::GetOptions %cli_options
6848     or exit 1;
6849
6850   if (defined $output_directory)
6851     {
6852       msg 'obsolete', "`--output-dir' is deprecated\n";
6853     }
6854   else
6855     {
6856       # In the next release we'll remove this entirely.
6857       $output_directory = '.';
6858     }
6859
6860   foreach my $arg (@ARGV)
6861     {
6862       if ($arg =~ /^-./)
6863         {
6864           fatal ("unrecognized option `$arg'\n"
6865                  . "Try `$0 --help' for more information.");
6866         }
6867
6868       # Handle $local:$input syntax.  Note that we only examine the
6869       # first ":" file to see if it is automake input; the rest are
6870       # just taken verbatim.  We still keep all the files around for
6871       # dependency checking, however.
6872       my ($local, $input, @rest) = split (/:/, $arg);
6873       if (! $input)
6874         {
6875           $input = $local;
6876         }
6877       else
6878         {
6879           # Strip .in; later on .am is tacked on.  That is how the
6880           # automake input file is found.  Maybe not the best way, but
6881           # it is easy to explain.
6882           $input =~ s/\.in$//
6883             or fatal "invalid input file name `$arg'\n.";
6884         }
6885       push (@input_files, $input);
6886       $output_files{$input} = join (':', ($local, @rest));
6887     }
6888 }
6889
6890 ################################################################
6891
6892 # Parse the WARNINGS environment variable.
6893 parse_WARNINGS;
6894
6895 # Parse command line.
6896 parse_arguments;
6897
6898 # Do configure.ac scan only once.
6899 scan_autoconf_files;
6900
6901 fatal "no `Makefile.am' found or specified\n"
6902   if ! @input_files;
6903
6904 my $automake_has_run = 0;
6905
6906 do
6907 {
6908   if ($automake_has_run)
6909     {
6910       verb 'processing Makefiles another time to fix them up.';
6911       prog_error 'running more than two times should never be needed.'
6912         if $automake_has_run >= 2;
6913     }
6914   $automake_needs_to_reprocess_all_files = 0;
6915
6916   # Now do all the work on each file.
6917   foreach my $file (@input_files)
6918     {
6919       $am_file = $file;
6920       if (! -f ($am_file . '.am'))
6921         {
6922           error "`$am_file.am' does not exist";
6923         }
6924       else
6925         {
6926           # Any warning setting now local to this Makefile.am.
6927           dup_channel_setup;
6928
6929           generate_makefile ($output_files{$am_file}, $am_file);
6930
6931           # Back out any warning setting.
6932           drop_channel_setup;
6933         }
6934     }
6935   ++$automake_has_run;
6936 }
6937 while ($automake_needs_to_reprocess_all_files);
6938
6939 exit $exit_code;
6940
6941
6942 ### Setup "GNU" style for perl-mode and cperl-mode.
6943 ## Local Variables:
6944 ## perl-indent-level: 2
6945 ## perl-continued-statement-offset: 2
6946 ## perl-continued-brace-offset: 0
6947 ## perl-brace-offset: 0
6948 ## perl-brace-imaginary-offset: 0
6949 ## perl-label-offset: -2
6950 ## cperl-indent-level: 2
6951 ## cperl-brace-offset: 0
6952 ## cperl-continued-brace-offset: 0
6953 ## cperl-label-offset: -2
6954 ## cperl-extra-newline-before-brace: t
6955 ## cperl-merge-trailing-else: nil
6956 ## cperl-continued-statement-offset: 2
6957 ## End: