atk-adaptor/meson.build

   1 subdir('adaptors')
   2
   3 atk_bridge_sources = [
   4   'accessible-leasing.c',
   5   'accessible-cache.c',
   6   'accessible-register.c',
   7   'accessible-stateset.c',
   8   'introspection.c',
   9   'bridge.c',
  10   'object.c',
  11   'event.c',
  12   'spi-dbus.c',
  13 ]
  14
  15 install_headers([ 'atk-bridge.h' ], subdir: join_paths(meson.project_name(), '2.0'))
  16
  17 libatk_bridge = library('atk-bridge-2.0', atk_bridge_sources,
  18                         include_directories: root_inc,
  19                         dependencies: [
  20                           libatk_bridge_adaptors_dep,
  21                           libdroute_dep,
  22                           libdbus_dep,
  23                           gmodule_dep,
  24                           gobject_dep,
  25                           atk_dep,
  26                           atspi_dep,
  27                         ],
  28                         c_args: p2p_cflags,
  29                         version: atk_bridge_libversion,
  30                         soversion: atk_bridge_soversion,
  31                         install: true)
  32
  33 libatk_bridge_dep = declare_dependency(link_with: libatk_bridge,
  34                                        include_directories: [
  35                                          root_inc,
  36                                          include_directories('.')
  37                                        ])
  38
  39 atk_bridge_module = shared_module('atk-bridge', 'gtk-2.0/module.c',
  40                                   include_directories: root_inc,
  41                                   dependencies: [
  42                                     libatk_bridge_dep,
  43                                     libdbus_dep,
  44                                     atk_dep,
  45                                     atspi_dep,
  46                                     gmodule_dep,
  47                                   ],
  48                                   c_args: p2p_cflags,
  49                                   install: true,
  50                                   install_dir: join_paths(get_option('libdir'), 'gtk-2.0', 'modules'))
  51
  52 pkgconfig = import('pkgconfig')
  53 pkgconfig.generate(
  54   name: 'atk-bridge-2.0',
  55   description: 'ATK/D-Bus Bridge',
  56   version: meson.project_version(),
  57   libraries: libatk_bridge,
  58   requires_private: ['gobject-2.0', 'atspi-2'],
  59   filebase: 'atk-bridge-2.0',
  60   subdirs: 'at-spi2-atk/2.0',
  61   install_dir: join_paths(get_option('libdir'), 'pkgconfig'),
  62 )