atk/meson.build

   1 atk_sources = [
   2   'atkaction.c',
   3   'atkcomponent.c',
   4   'atkdocument.c',
   5   'atkeditabletext.c',
   6   'atkgobjectaccessible.c',
   7   'atkhyperlink.c',
   8   'atkhyperlinkimpl.c',
   9   'atkhypertext.c',
  10   'atkimage.c',
  11   'atknoopobject.c',
  12   'atknoopobjectfactory.c',
  13   'atkobject.c',
  14   'atkobjectfactory.c',
  15   'atkplug.c',
  16   'atkprivate.c',
  17   'atkrange.c',
  18   'atkregistry.c',
  19   'atkrelation.c',
  20   'atkrelationset.c',
  21   'atkselection.c',
  22   'atksocket.c',
  23   'atkstate.c',
  24   'atkstateset.c',
  25   'atkstreamablecontent.c',
  26   'atktable.c',
  27   'atktablecell.c',
  28   'atktext.c',
  29   'atkutil.c',
  30   'atkmisc.c',
  31   'atkvalue.c',
  32   'atkversion.c',
  33   'atkwindow.c',
  34 ]
  35
  36 atk_headers = [
  37   'atk.h',
  38   'atkaction.h',
  39   'atkcomponent.h',
  40   'atkdocument.h',
  41   'atkeditabletext.h',
  42   'atkgobjectaccessible.h',
  43   'atkhyperlink.h',
  44   'atkhyperlinkimpl.h',
  45   'atkhypertext.h',
  46   'atknoopobject.h',
  47   'atknoopobjectfactory.h',
  48   'atkobject.h',
  49   'atkobjectfactory.h',
  50   'atkplug.h',
  51   'atkimage.h',
  52   'atkrange.h',
  53   'atkregistry.h',
  54   'atkrelation.h',
  55   'atkrelationtype.h',
  56   'atkrelationset.h',
  57   'atkselection.h',
  58   'atksocket.h',
  59   'atkstate.h',
  60   'atkstateset.h',
  61   'atkstreamablecontent.h',
  62   'atktable.h',
  63   'atktablecell.h',
  64   'atktext.h',
  65   'atkutil.h',
  66   'atkmisc.h',
  67   'atkvalue.h',
  68   'atkwindow.h',
  69 ]
  70
  71 install_headers(atk_headers, subdir: atk_api_path)
  72
  73 # Features header
  74 atk_version_conf = configuration_data()
  75 atk_version_conf.set('ATK_MAJOR_VERSION', atk_major_version)
  76 atk_version_conf.set('ATK_MINOR_VERSION', atk_minor_version)
  77 atk_version_conf.set('ATK_MICRO_VERSION', atk_micro_version)
  78 atk_version_conf.set('ATK_BINARY_AGE', atk_binary_age)
  79 atk_version_conf.set('ATK_INTERFACE_AGE', atk_interface_age)
  80 atk_version_conf.set('LT_CURRENT_MINUS_AGE', '0')
  81 atk_version_conf.set('ATK_VERSION', meson.project_version())
  82
  83 atk_version_h = configure_file(input: 'atkversion.h.in',
  84                output: 'atkversion.h',
  85                configuration: atk_version_conf,
  86                install: true,
  87                install_dir: join_paths(atk_includedir, atk_api_path))
  88
  89 # Marshallers
  90 atk_marshals = gnome.genmarshal('atkmarshal',
  91                                 sources: 'atkmarshal.list',
  92                                 prefix: 'atk_marshal')
  93 atk_marshal_h = atk_marshals[1]
  94
  95 # Enumerations for GType
  96 atk_enums = gnome.mkenums('atk-enum-types',
  97                           sources: atk_headers,
  98                           c_template: 'atk-enum-types.c.template',
  99                           h_template: 'atk-enum-types.h.template',
 100                           install_dir: join_paths(atk_includedir, atk_api_path),
 101                           install_header: true)
 102 atk_enum_h = atk_enums[1]
 103
 104 atk_cflags = [
 105   '-DG_LOG_DOMAIN="Atk"',
 106   '-DG_LOG_USE_STRUCTURED=1',
 107   '-DGLIB_DISABLE_DEPRECATION_WARNINGS',
 108   '-DATK_DISABLE_DEPRECATION_WARNINGS',
 109   '-DATK_COMPILATION',
 110   '-DATK_LOCALEDIR="@0@"'.format(join_paths(atk_datadir, 'locale')),
 111 ]
 112
 113 if host_system == 'windows'
 114   atk_win_rc = configure_file(
 115     input: 'atk.rc.in',
 116     output: 'atk.rc',
 117     configuration: atk_version_conf,
 118   )
 119   atk_win_res = import('windows').compile_resources(atk_win_rc)
 120   atk_sources += atk_win_res
 121 endif
 122
 123 atk_inc = include_directories('.')
 124
 125 libatk = shared_library('atk-@0@'.format(atk_api_version),
 126                         sources: atk_sources + atk_enums + atk_marshals,
 127                         soversion: atk_soversion,
 128                         version: atk_libversion,
 129                         install: true,
 130                         dependencies: gobject_dep,
 131                         include_directories: [ root_inc, atk_inc ],
 132                         c_args: common_cflags + atk_cflags,
 133                         link_args: common_ldflags)
 134
 135 libatk_dep = declare_dependency(link_with: libatk,
 136                                 include_directories: atk_inc,
 137                                 dependencies: gobject_dep,
 138                                 sources: atk_enum_h)
 139
 140 disable_introspection = get_option('disable_introspection')
 141
 142 if not meson.is_cross_build() and not disable_introspection
 143   gnome.generate_gir(libatk,
 144                      sources: atk_sources + atk_headers + [ atk_enum_h ] + [ atk_version_h ],
 145                      namespace: 'Atk',
 146                      nsversion: atk_api_version,
 147                      identifier_prefix: 'Atk',
 148                      symbol_prefix: 'atk',
 149                      export_packages: 'atk',
 150                      includes: [ 'GObject-2.0' ],
 151                      install: true,
 152                      extra_args: [
 153                        '--quiet',
 154                        '--c-include=atk/atk.h',
 155                        '-DATK_COMPILATION',
 156                      ])
 157 endif