arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <linux/err.h>
  60
  61 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  62 #include <linux/elf-em.h>
  63 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  64 #define __AUDIT_ARCH_64BIT 0x80000000
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67         .code64
  68         .section .entry.text, "ax"
  69
  70 #ifdef CONFIG_FUNCTION_TRACER
  71 #ifdef CONFIG_DYNAMIC_FTRACE
  72 ENTRY(mcount)
  73         retq
  74 END(mcount)
  75
  76 /* skip is set if stack has been adjusted */
  77 .macro ftrace_caller_setup skip=0
  78         MCOUNT_SAVE_FRAME \skip
  79
  80         /* Load the ftrace_ops into the 3rd parameter */
  81         leaq function_trace_op, %rdx
  82
  83         /* Load ip into the first parameter */
  84         movq RIP(%rsp), %rdi
  85         subq $MCOUNT_INSN_SIZE, %rdi
  86         /* Load the parent_ip into the second parameter */
  87         movq 8(%rbp), %rsi
  88 .endm
  89
  90 ENTRY(ftrace_caller)
  91         /* Check if tracing was disabled (quick check) */
  92         cmpl $0, function_trace_stop
  93         jne  ftrace_stub
  94
  95         ftrace_caller_setup
  96         /* regs go into 4th parameter (but make it NULL) */
  97         movq $0, %rcx
  98
  99 GLOBAL(ftrace_call)
 100         call ftrace_stub
 101
 102         MCOUNT_RESTORE_FRAME
 103 ftrace_return:
 104
 105 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 106 GLOBAL(ftrace_graph_call)
 107         jmp ftrace_stub
 108 #endif
 109
 110 GLOBAL(ftrace_stub)
 111         retq
 112 END(ftrace_caller)
 113
 114 ENTRY(ftrace_regs_caller)
 115         /* Save the current flags before compare (in SS location)*/
 116         pushfq
 117
 118         /* Check if tracing was disabled (quick check) */
 119         cmpl $0, function_trace_stop
 120         jne  ftrace_restore_flags
 121
 122         /* skip=8 to skip flags saved in SS */
 123         ftrace_caller_setup 8
 124
 125         /* Save the rest of pt_regs */
 126         movq %r15, R15(%rsp)
 127         movq %r14, R14(%rsp)
 128         movq %r13, R13(%rsp)
 129         movq %r12, R12(%rsp)
 130         movq %r11, R11(%rsp)
 131         movq %r10, R10(%rsp)
 132         movq %rbp, RBP(%rsp)
 133         movq %rbx, RBX(%rsp)
 134         /* Copy saved flags */
 135         movq SS(%rsp), %rcx
 136         movq %rcx, EFLAGS(%rsp)
 137         /* Kernel segments */
 138         movq $__KERNEL_DS, %rcx
 139         movq %rcx, SS(%rsp)
 140         movq $__KERNEL_CS, %rcx
 141         movq %rcx, CS(%rsp)
 142         /* Stack - skipping return address */
 143         leaq SS+16(%rsp), %rcx
 144         movq %rcx, RSP(%rsp)
 145
 146         /* regs go into 4th parameter */
 147         leaq (%rsp), %rcx
 148
 149 GLOBAL(ftrace_regs_call)
 150         call ftrace_stub
 151
 152         /* Copy flags back to SS, to restore them */
 153         movq EFLAGS(%rsp), %rax
 154         movq %rax, SS(%rsp)
 155
 156         /* restore the rest of pt_regs */
 157         movq R15(%rsp), %r15
 158         movq R14(%rsp), %r14
 159         movq R13(%rsp), %r13
 160         movq R12(%rsp), %r12
 161         movq R10(%rsp), %r10
 162         movq RBP(%rsp), %rbp
 163         movq RBX(%rsp), %rbx
 164
 165         /* skip=8 to skip flags saved in SS */
 166         MCOUNT_RESTORE_FRAME 8
 167
 168         /* Restore flags */
 169         popfq
 170
 171         jmp ftrace_return
 172 ftrace_restore_flags:
 173         popfq
 174         jmp  ftrace_stub
 175
 176 END(ftrace_regs_caller)
 177
 178
 179 #else /* ! CONFIG_DYNAMIC_FTRACE */
 180 ENTRY(mcount)
 181         cmpl $0, function_trace_stop
 182         jne  ftrace_stub
 183
 184         cmpq $ftrace_stub, ftrace_trace_function
 185         jnz trace
 186
 187 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 188         cmpq $ftrace_stub, ftrace_graph_return
 189         jnz ftrace_graph_caller
 190
 191         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 192         jnz ftrace_graph_caller
 193 #endif
 194
 195 GLOBAL(ftrace_stub)
 196         retq
 197
 198 trace:
 199         MCOUNT_SAVE_FRAME
 200
 201         movq RIP(%rsp), %rdi
 202         movq 8(%rbp), %rsi
 203         subq $MCOUNT_INSN_SIZE, %rdi
 204
 205         call   *ftrace_trace_function
 206
 207         MCOUNT_RESTORE_FRAME
 208
 209         jmp ftrace_stub
 210 END(mcount)
 211 #endif /* CONFIG_DYNAMIC_FTRACE */
 212 #endif /* CONFIG_FUNCTION_TRACER */
 213
 214 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 215 ENTRY(ftrace_graph_caller)
 216         cmpl $0, function_trace_stop
 217         jne ftrace_stub
 218
 219         MCOUNT_SAVE_FRAME
 220
 221         leaq 8(%rbp), %rdi
 222         movq RIP(%rsp), %rsi
 223         movq (%rbp), %rdx
 224         subq $MCOUNT_INSN_SIZE, %rsi
 225
 226         call    prepare_ftrace_return
 227
 228         MCOUNT_RESTORE_FRAME
 229
 230         retq
 231 END(ftrace_graph_caller)
 232
 233 GLOBAL(return_to_handler)
 234         subq  $24, %rsp
 235
 236         /* Save the return values */
 237         movq %rax, (%rsp)
 238         movq %rdx, 8(%rsp)
 239         movq %rbp, %rdi
 240
 241         call ftrace_return_to_handler
 242
 243         movq %rax, %rdi
 244         movq 8(%rsp), %rdx
 245         movq (%rsp), %rax
 246         addq $24, %rsp
 247         jmp *%rdi
 248 #endif
 249
 250
 251 #ifndef CONFIG_PREEMPT
 252 #define retint_kernel retint_restore_args
 253 #endif
 254
 255 #ifdef CONFIG_PARAVIRT
 256 ENTRY(native_usergs_sysret64)
 257         swapgs
 258         sysretq
 259 ENDPROC(native_usergs_sysret64)
 260 #endif /* CONFIG_PARAVIRT */
 261
 262
 263 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 264 #ifdef CONFIG_TRACE_IRQFLAGS
 265         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 266         jnc  1f
 267         TRACE_IRQS_ON
 268 1:
 269 #endif
 270 .endm
 271
 272 /*
 273  * When dynamic function tracer is enabled it will add a breakpoint
 274  * to all locations that it is about to modify, sync CPUs, update
 275  * all the code, sync CPUs, then remove the breakpoints. In this time
 276  * if lockdep is enabled, it might jump back into the debug handler
 277  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 278  *
 279  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 280  * make sure the stack pointer does not get reset back to the top
 281  * of the debug stack, and instead just reuses the current stack.
 282  */
 283 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 284
 285 .macro TRACE_IRQS_OFF_DEBUG
 286         call debug_stack_set_zero
 287         TRACE_IRQS_OFF
 288         call debug_stack_reset
 289 .endm
 290
 291 .macro TRACE_IRQS_ON_DEBUG
 292         call debug_stack_set_zero
 293         TRACE_IRQS_ON
 294         call debug_stack_reset
 295 .endm
 296
 297 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 298         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 299         jnc  1f
 300         TRACE_IRQS_ON_DEBUG
 301 1:
 302 .endm
 303
 304 #else
 305 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 306 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 307 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 308 #endif
 309
 310 /*
 311  * C code is not supposed to know about undefined top of stack. Every time
 312  * a C function with an pt_regs argument is called from the SYSCALL based
 313  * fast path FIXUP_TOP_OF_STACK is needed.
 314  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 315  * manipulation.
 316  */
 317
 318         /* %rsp:at FRAMEEND */
 319         .macro FIXUP_TOP_OF_STACK tmp offset=0
 320         movq PER_CPU_VAR(old_rsp),\tmp
 321         movq \tmp,RSP+\offset(%rsp)
 322         movq $__USER_DS,SS+\offset(%rsp)
 323         movq $__USER_CS,CS+\offset(%rsp)
 324         movq $-1,RCX+\offset(%rsp)
 325         movq R11+\offset(%rsp),\tmp  /* get eflags */
 326         movq \tmp,EFLAGS+\offset(%rsp)
 327         .endm
 328
 329         .macro RESTORE_TOP_OF_STACK tmp offset=0
 330         movq RSP+\offset(%rsp),\tmp
 331         movq \tmp,PER_CPU_VAR(old_rsp)
 332         movq EFLAGS+\offset(%rsp),\tmp
 333         movq \tmp,R11+\offset(%rsp)
 334         .endm
 335
 336         .macro FAKE_STACK_FRAME child_rip
 337         /* push in order ss, rsp, eflags, cs, rip */
 338         xorl %eax, %eax
 339         pushq_cfi $__KERNEL_DS /* ss */
 340         /*CFI_REL_OFFSET        ss,0*/
 341         pushq_cfi %rax /* rsp */
 342         CFI_REL_OFFSET  rsp,0
 343         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
 344         /*CFI_REL_OFFSET        rflags,0*/
 345         pushq_cfi $__KERNEL_CS /* cs */
 346         /*CFI_REL_OFFSET        cs,0*/
 347         pushq_cfi \child_rip /* rip */
 348         CFI_REL_OFFSET  rip,0
 349         pushq_cfi %rax /* orig rax */
 350         .endm
 351
 352         .macro UNFAKE_STACK_FRAME
 353         addq $8*6, %rsp
 354         CFI_ADJUST_CFA_OFFSET   -(6*8)
 355         .endm
 356
 357 /*
 358  * initial frame state for interrupts (and exceptions without error code)
 359  */
 360         .macro EMPTY_FRAME start=1 offset=0
 361         .if \start
 362         CFI_STARTPROC simple
 363         CFI_SIGNAL_FRAME
 364         CFI_DEF_CFA rsp,8+\offset
 365         .else
 366         CFI_DEF_CFA_OFFSET 8+\offset
 367         .endif
 368         .endm
 369
 370 /*
 371  * initial frame state for interrupts (and exceptions without error code)
 372  */
 373         .macro INTR_FRAME start=1 offset=0
 374         EMPTY_FRAME \start, SS+8+\offset-RIP
 375         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 376         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 377         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 378         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 379         CFI_REL_OFFSET rip, RIP+\offset-RIP
 380         .endm
 381
 382 /*
 383  * initial frame state for exceptions with error code (and interrupts
 384  * with vector already pushed)
 385  */
 386         .macro XCPT_FRAME start=1 offset=0
 387         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 388         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 389         .endm
 390
 391 /*
 392  * frame that enables calling into C.
 393  */
 394         .macro PARTIAL_FRAME start=1 offset=0
 395         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 396         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 397         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 398         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 399         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 400         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 401         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 402         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 403         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 404         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 405         .endm
 406
 407 /*
 408  * frame that enables passing a complete pt_regs to a C function.
 409  */
 410         .macro DEFAULT_FRAME start=1 offset=0
 411         PARTIAL_FRAME \start, R11+\offset-R15
 412         CFI_REL_OFFSET rbx, RBX+\offset
 413         CFI_REL_OFFSET rbp, RBP+\offset
 414         CFI_REL_OFFSET r12, R12+\offset
 415         CFI_REL_OFFSET r13, R13+\offset
 416         CFI_REL_OFFSET r14, R14+\offset
 417         CFI_REL_OFFSET r15, R15+\offset
 418         .endm
 419
 420 /* save partial stack frame */
 421         .macro SAVE_ARGS_IRQ
 422         cld
 423         /* start from rbp in pt_regs and jump over */
 424         movq_cfi rdi, RDI-RBP
 425         movq_cfi rsi, RSI-RBP
 426         movq_cfi rdx, RDX-RBP
 427         movq_cfi rcx, RCX-RBP
 428         movq_cfi rax, RAX-RBP
 429         movq_cfi  r8,  R8-RBP
 430         movq_cfi  r9,  R9-RBP
 431         movq_cfi r10, R10-RBP
 432         movq_cfi r11, R11-RBP
 433
 434         /* Save rbp so that we can unwind from get_irq_regs() */
 435         movq_cfi rbp, 0
 436
 437         /* Save previous stack value */
 438         movq %rsp, %rsi
 439
 440         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 441         testl $3, CS-RBP(%rsi)
 442         je 1f
 443         SWAPGS
 444         /*
 445          * irq_count is used to check if a CPU is already on an interrupt stack
 446          * or not. While this is essentially redundant with preempt_count it is
 447          * a little cheaper to use a separate counter in the PDA (short of
 448          * moving irq_enter into assembly, which would be too much work)
 449          */
 450 1:      incl PER_CPU_VAR(irq_count)
 451         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 452         CFI_DEF_CFA_REGISTER    rsi
 453
 454         /* Store previous stack value */
 455         pushq %rsi
 456         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 457                         0x77 /* DW_OP_breg7 */, 0, \
 458                         0x06 /* DW_OP_deref */, \
 459                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 460                         0x22 /* DW_OP_plus */
 461         /* We entered an interrupt context - irqs are off: */
 462         TRACE_IRQS_OFF
 463         .endm
 464
 465 ENTRY(save_rest)
 466         PARTIAL_FRAME 1 REST_SKIP+8
 467         movq 5*8+16(%rsp), %r11 /* save return address */
 468         movq_cfi rbx, RBX+16
 469         movq_cfi rbp, RBP+16
 470         movq_cfi r12, R12+16
 471         movq_cfi r13, R13+16
 472         movq_cfi r14, R14+16
 473         movq_cfi r15, R15+16
 474         movq %r11, 8(%rsp)      /* return address */
 475         FIXUP_TOP_OF_STACK %r11, 16
 476         ret
 477         CFI_ENDPROC
 478 END(save_rest)
 479
 480 /* save complete stack frame */
 481         .pushsection .kprobes.text, "ax"
 482 ENTRY(save_paranoid)
 483         XCPT_FRAME 1 RDI+8
 484         cld
 485         movq_cfi rdi, RDI+8
 486         movq_cfi rsi, RSI+8
 487         movq_cfi rdx, RDX+8
 488         movq_cfi rcx, RCX+8
 489         movq_cfi rax, RAX+8
 490         movq_cfi r8, R8+8
 491         movq_cfi r9, R9+8
 492         movq_cfi r10, R10+8
 493         movq_cfi r11, R11+8
 494         movq_cfi rbx, RBX+8
 495         movq_cfi rbp, RBP+8
 496         movq_cfi r12, R12+8
 497         movq_cfi r13, R13+8
 498         movq_cfi r14, R14+8
 499         movq_cfi r15, R15+8
 500         movl $1,%ebx
 501         movl $MSR_GS_BASE,%ecx
 502         rdmsr
 503         testl %edx,%edx
 504         js 1f   /* negative -> in kernel */
 505         SWAPGS
 506         xorl %ebx,%ebx
 507 1:      ret
 508         CFI_ENDPROC
 509 END(save_paranoid)
 510         .popsection
 511
 512 /*
 513  * A newly forked process directly context switches into this address.
 514  *
 515  * rdi: prev task we switched from
 516  */
 517 ENTRY(ret_from_fork)
 518         DEFAULT_FRAME
 519
 520         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 521
 522         pushq_cfi kernel_eflags(%rip)
 523         popfq_cfi                               # reset kernel eflags
 524
 525         call schedule_tail                      # rdi: 'prev' task parameter
 526
 527         GET_THREAD_INFO(%rcx)
 528
 529         RESTORE_REST
 530
 531         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 532         jz   retint_restore_args
 533
 534         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 535         jnz  int_ret_from_sys_call
 536
 537         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 538         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 539
 540         CFI_ENDPROC
 541 END(ret_from_fork)
 542
 543 /*
 544  * System call entry. Up to 6 arguments in registers are supported.
 545  *
 546  * SYSCALL does not save anything on the stack and does not change the
 547  * stack pointer.
 548  */
 549
 550 /*
 551  * Register setup:
 552  * rax  system call number
 553  * rdi  arg0
 554  * rcx  return address for syscall/sysret, C arg3
 555  * rsi  arg1
 556  * rdx  arg2
 557  * r10  arg3    (--> moved to rcx for C)
 558  * r8   arg4
 559  * r9   arg5
 560  * r11  eflags for syscall/sysret, temporary for C
 561  * r12-r15,rbp,rbx saved by C code, not touched.
 562  *
 563  * Interrupts are off on entry.
 564  * Only called from user space.
 565  *
 566  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 567  *      and report it properly in ps. Unfortunately we haven't.
 568  *
 569  * When user can change the frames always force IRET. That is because
 570  * it deals with uncanonical addresses better. SYSRET has trouble
 571  * with them due to bugs in both AMD and Intel CPUs.
 572  */
 573
 574 ENTRY(system_call)
 575         CFI_STARTPROC   simple
 576         CFI_SIGNAL_FRAME
 577         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 578         CFI_REGISTER    rip,rcx
 579         /*CFI_REGISTER  rflags,r11*/
 580         SWAPGS_UNSAFE_STACK
 581         /*
 582          * A hypervisor implementation might want to use a label
 583          * after the swapgs, so that it can do the swapgs
 584          * for the guest and jump here on syscall.
 585          */
 586 GLOBAL(system_call_after_swapgs)
 587
 588         movq    %rsp,PER_CPU_VAR(old_rsp)
 589         movq    PER_CPU_VAR(kernel_stack),%rsp
 590         /*
 591          * No need to follow this irqs off/on section - it's straight
 592          * and short:
 593          */
 594         ENABLE_INTERRUPTS(CLBR_NONE)
 595         SAVE_ARGS 8,0
 596         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 597         movq  %rcx,RIP-ARGOFFSET(%rsp)
 598         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 599         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 600         jnz tracesys
 601 system_call_fastpath:
 602 #if __SYSCALL_MASK == ~0
 603         cmpq $__NR_syscall_max,%rax
 604 #else
 605         andl $__SYSCALL_MASK,%eax
 606         cmpl $__NR_syscall_max,%eax
 607 #endif
 608         ja badsys
 609         movq %r10,%rcx
 610         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 611         movq %rax,RAX-ARGOFFSET(%rsp)
 612 /*
 613  * Syscall return path ending with SYSRET (fast path)
 614  * Has incomplete stack frame and undefined top of stack.
 615  */
 616 ret_from_sys_call:
 617         movl $_TIF_ALLWORK_MASK,%edi
 618         /* edi: flagmask */
 619 sysret_check:
 620         LOCKDEP_SYS_EXIT
 621         DISABLE_INTERRUPTS(CLBR_NONE)
 622         TRACE_IRQS_OFF
 623         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 624         andl %edi,%edx
 625         jnz  sysret_careful
 626         CFI_REMEMBER_STATE
 627         /*
 628          * sysretq will re-enable interrupts:
 629          */
 630         TRACE_IRQS_ON
 631         movq RIP-ARGOFFSET(%rsp),%rcx
 632         CFI_REGISTER    rip,rcx
 633         RESTORE_ARGS 1,-ARG_SKIP,0
 634         /*CFI_REGISTER  rflags,r11*/
 635         movq    PER_CPU_VAR(old_rsp), %rsp
 636         USERGS_SYSRET64
 637
 638         CFI_RESTORE_STATE
 639         /* Handle reschedules */
 640         /* edx: work, edi: workmask */
 641 sysret_careful:
 642         bt $TIF_NEED_RESCHED,%edx
 643         jnc sysret_signal
 644         TRACE_IRQS_ON
 645         ENABLE_INTERRUPTS(CLBR_NONE)
 646         pushq_cfi %rdi
 647         call schedule
 648         popq_cfi %rdi
 649         jmp sysret_check
 650
 651         /* Handle a signal */
 652 sysret_signal:
 653         TRACE_IRQS_ON
 654         ENABLE_INTERRUPTS(CLBR_NONE)
 655 #ifdef CONFIG_AUDITSYSCALL
 656         bt $TIF_SYSCALL_AUDIT,%edx
 657         jc sysret_audit
 658 #endif
 659         /*
 660          * We have a signal, or exit tracing or single-step.
 661          * These all wind up with the iret return path anyway,
 662          * so just join that path right now.
 663          */
 664         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 665         jmp int_check_syscall_exit_work
 666
 667 badsys:
 668         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 669         jmp ret_from_sys_call
 670
 671 #ifdef CONFIG_AUDITSYSCALL
 672         /*
 673          * Fast path for syscall audit without full syscall trace.
 674          * We just call __audit_syscall_entry() directly, and then
 675          * jump back to the normal fast path.
 676          */
 677 auditsys:
 678         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 679         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 680         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 681         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 682         movq %rax,%rsi                  /* 2nd arg: syscall number */
 683         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 684         call __audit_syscall_entry
 685         LOAD_ARGS 0             /* reload call-clobbered registers */
 686         jmp system_call_fastpath
 687
 688         /*
 689          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 690          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 691          * masked off.
 692          */
 693 sysret_audit:
 694         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 695         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 696         setbe %al               /* 1 if so, 0 if not */
 697         movzbl %al,%edi         /* zero-extend that into %edi */
 698         call __audit_syscall_exit
 699         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 700         jmp sysret_check
 701 #endif  /* CONFIG_AUDITSYSCALL */
 702
 703         /* Do syscall tracing */
 704 tracesys:
 705 #ifdef CONFIG_AUDITSYSCALL
 706         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 707         jz auditsys
 708 #endif
 709         SAVE_REST
 710         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 711         FIXUP_TOP_OF_STACK %rdi
 712         movq %rsp,%rdi
 713         call syscall_trace_enter
 714         /*
 715          * Reload arg registers from stack in case ptrace changed them.
 716          * We don't reload %rax because syscall_trace_enter() returned
 717          * the value it wants us to use in the table lookup.
 718          */
 719         LOAD_ARGS ARGOFFSET, 1
 720         RESTORE_REST
 721 #if __SYSCALL_MASK == ~0
 722         cmpq $__NR_syscall_max,%rax
 723 #else
 724         andl $__SYSCALL_MASK,%eax
 725         cmpl $__NR_syscall_max,%eax
 726 #endif
 727         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 728         movq %r10,%rcx  /* fixup for C */
 729         call *sys_call_table(,%rax,8)
 730         movq %rax,RAX-ARGOFFSET(%rsp)
 731         /* Use IRET because user could have changed frame */
 732
 733 /*
 734  * Syscall return path ending with IRET.
 735  * Has correct top of stack, but partial stack frame.
 736  */
 737 GLOBAL(int_ret_from_sys_call)
 738         DISABLE_INTERRUPTS(CLBR_NONE)
 739         TRACE_IRQS_OFF
 740         movl $_TIF_ALLWORK_MASK,%edi
 741         /* edi: mask to check */
 742 GLOBAL(int_with_check)
 743         LOCKDEP_SYS_EXIT_IRQ
 744         GET_THREAD_INFO(%rcx)
 745         movl TI_flags(%rcx),%edx
 746         andl %edi,%edx
 747         jnz   int_careful
 748         andl    $~TS_COMPAT,TI_status(%rcx)
 749         jmp   retint_swapgs
 750
 751         /* Either reschedule or signal or syscall exit tracking needed. */
 752         /* First do a reschedule test. */
 753         /* edx: work, edi: workmask */
 754 int_careful:
 755         bt $TIF_NEED_RESCHED,%edx
 756         jnc  int_very_careful
 757         TRACE_IRQS_ON
 758         ENABLE_INTERRUPTS(CLBR_NONE)
 759         pushq_cfi %rdi
 760         call schedule
 761         popq_cfi %rdi
 762         DISABLE_INTERRUPTS(CLBR_NONE)
 763         TRACE_IRQS_OFF
 764         jmp int_with_check
 765
 766         /* handle signals and tracing -- both require a full stack frame */
 767 int_very_careful:
 768         TRACE_IRQS_ON
 769         ENABLE_INTERRUPTS(CLBR_NONE)
 770 int_check_syscall_exit_work:
 771         SAVE_REST
 772         /* Check for syscall exit trace */
 773         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 774         jz int_signal
 775         pushq_cfi %rdi
 776         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 777         call syscall_trace_leave
 778         popq_cfi %rdi
 779         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 780         jmp int_restore_rest
 781
 782 int_signal:
 783         testl $_TIF_DO_NOTIFY_MASK,%edx
 784         jz 1f
 785         movq %rsp,%rdi          # &ptregs -> arg1
 786         xorl %esi,%esi          # oldset -> arg2
 787         call do_notify_resume
 788 1:      movl $_TIF_WORK_MASK,%edi
 789 int_restore_rest:
 790         RESTORE_REST
 791         DISABLE_INTERRUPTS(CLBR_NONE)
 792         TRACE_IRQS_OFF
 793         jmp int_with_check
 794         CFI_ENDPROC
 795 END(system_call)
 796
 797 /*
 798  * Certain special system calls that need to save a complete full stack frame.
 799  */
 800         .macro PTREGSCALL label,func,arg
 801 ENTRY(\label)
 802         PARTIAL_FRAME 1 8               /* offset 8: return address */
 803         subq $REST_SKIP, %rsp
 804         CFI_ADJUST_CFA_OFFSET REST_SKIP
 805         call save_rest
 806         DEFAULT_FRAME 0 8               /* offset 8: return address */
 807         leaq 8(%rsp), \arg      /* pt_regs pointer */
 808         call \func
 809         jmp ptregscall_common
 810         CFI_ENDPROC
 811 END(\label)
 812         .endm
 813
 814         PTREGSCALL stub_clone, sys_clone, %r8
 815         PTREGSCALL stub_fork, sys_fork, %rdi
 816         PTREGSCALL stub_vfork, sys_vfork, %rdi
 817         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 818         PTREGSCALL stub_iopl, sys_iopl, %rsi
 819
 820 ENTRY(ptregscall_common)
 821         DEFAULT_FRAME 1 8       /* offset 8: return address */
 822         RESTORE_TOP_OF_STACK %r11, 8
 823         movq_cfi_restore R15+8, r15
 824         movq_cfi_restore R14+8, r14
 825         movq_cfi_restore R13+8, r13
 826         movq_cfi_restore R12+8, r12
 827         movq_cfi_restore RBP+8, rbp
 828         movq_cfi_restore RBX+8, rbx
 829         ret $REST_SKIP          /* pop extended registers */
 830         CFI_ENDPROC
 831 END(ptregscall_common)
 832
 833 ENTRY(stub_execve)
 834         CFI_STARTPROC
 835         addq $8, %rsp
 836         PARTIAL_FRAME 0
 837         SAVE_REST
 838         FIXUP_TOP_OF_STACK %r11
 839         movq %rsp, %rcx
 840         call sys_execve
 841         RESTORE_TOP_OF_STACK %r11
 842         movq %rax,RAX(%rsp)
 843         RESTORE_REST
 844         jmp int_ret_from_sys_call
 845         CFI_ENDPROC
 846 END(stub_execve)
 847
 848 /*
 849  * sigreturn is special because it needs to restore all registers on return.
 850  * This cannot be done with SYSRET, so use the IRET return path instead.
 851  */
 852 ENTRY(stub_rt_sigreturn)
 853         CFI_STARTPROC
 854         addq $8, %rsp
 855         PARTIAL_FRAME 0
 856         SAVE_REST
 857         movq %rsp,%rdi
 858         FIXUP_TOP_OF_STACK %r11
 859         call sys_rt_sigreturn
 860         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 861         RESTORE_REST
 862         jmp int_ret_from_sys_call
 863         CFI_ENDPROC
 864 END(stub_rt_sigreturn)
 865
 866 #ifdef CONFIG_X86_X32_ABI
 867         PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
 868
 869 ENTRY(stub_x32_rt_sigreturn)
 870         CFI_STARTPROC
 871         addq $8, %rsp
 872         PARTIAL_FRAME 0
 873         SAVE_REST
 874         movq %rsp,%rdi
 875         FIXUP_TOP_OF_STACK %r11
 876         call sys32_x32_rt_sigreturn
 877         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 878         RESTORE_REST
 879         jmp int_ret_from_sys_call
 880         CFI_ENDPROC
 881 END(stub_x32_rt_sigreturn)
 882
 883 ENTRY(stub_x32_execve)
 884         CFI_STARTPROC
 885         addq $8, %rsp
 886         PARTIAL_FRAME 0
 887         SAVE_REST
 888         FIXUP_TOP_OF_STACK %r11
 889         movq %rsp, %rcx
 890         call sys32_execve
 891         RESTORE_TOP_OF_STACK %r11
 892         movq %rax,RAX(%rsp)
 893         RESTORE_REST
 894         jmp int_ret_from_sys_call
 895         CFI_ENDPROC
 896 END(stub_x32_execve)
 897
 898 #endif
 899
 900 /*
 901  * Build the entry stubs and pointer table with some assembler magic.
 902  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 903  * single cache line on all modern x86 implementations.
 904  */
 905         .section .init.rodata,"a"
 906 ENTRY(interrupt)
 907         .section .entry.text
 908         .p2align 5
 909         .p2align CONFIG_X86_L1_CACHE_SHIFT
 910 ENTRY(irq_entries_start)
 911         INTR_FRAME
 912 vector=FIRST_EXTERNAL_VECTOR
 913 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 914         .balign 32
 915   .rept 7
 916     .if vector < NR_VECTORS
 917       .if vector <> FIRST_EXTERNAL_VECTOR
 918         CFI_ADJUST_CFA_OFFSET -8
 919       .endif
 920 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 921       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 922         jmp 2f
 923       .endif
 924       .previous
 925         .quad 1b
 926       .section .entry.text
 927 vector=vector+1
 928     .endif
 929   .endr
 930 2:      jmp common_interrupt
 931 .endr
 932         CFI_ENDPROC
 933 END(irq_entries_start)
 934
 935 .previous
 936 END(interrupt)
 937 .previous
 938
 939 /*
 940  * Interrupt entry/exit.
 941  *
 942  * Interrupt entry points save only callee clobbered registers in fast path.
 943  *
 944  * Entry runs with interrupts off.
 945  */
 946
 947 /* 0(%rsp): ~(interrupt number) */
 948         .macro interrupt func
 949         /* reserve pt_regs for scratch regs and rbp */
 950         subq $ORIG_RAX-RBP, %rsp
 951         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 952         SAVE_ARGS_IRQ
 953         call \func
 954         .endm
 955
 956 /*
 957  * Interrupt entry/exit should be protected against kprobes
 958  */
 959         .pushsection .kprobes.text, "ax"
 960         /*
 961          * The interrupt stubs push (~vector+0x80) onto the stack and
 962          * then jump to common_interrupt.
 963          */
 964         .p2align CONFIG_X86_L1_CACHE_SHIFT
 965 common_interrupt:
 966         XCPT_FRAME
 967         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 968         interrupt do_IRQ
 969         /* 0(%rsp): old_rsp-ARGOFFSET */
 970 ret_from_intr:
 971         DISABLE_INTERRUPTS(CLBR_NONE)
 972         TRACE_IRQS_OFF
 973         decl PER_CPU_VAR(irq_count)
 974
 975         /* Restore saved previous stack */
 976         popq %rsi
 977         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
 978         leaq ARGOFFSET-RBP(%rsi), %rsp
 979         CFI_DEF_CFA_REGISTER    rsp
 980         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 981
 982 exit_intr:
 983         GET_THREAD_INFO(%rcx)
 984         testl $3,CS-ARGOFFSET(%rsp)
 985         je retint_kernel
 986
 987         /* Interrupt came from user space */
 988         /*
 989          * Has a correct top of stack, but a partial stack frame
 990          * %rcx: thread info. Interrupts off.
 991          */
 992 retint_with_reschedule:
 993         movl $_TIF_WORK_MASK,%edi
 994 retint_check:
 995         LOCKDEP_SYS_EXIT_IRQ
 996         movl TI_flags(%rcx),%edx
 997         andl %edi,%edx
 998         CFI_REMEMBER_STATE
 999         jnz  retint_careful
1000
1001 retint_swapgs:          /* return to user-space */
1002         /*
1003          * The iretq could re-enable interrupts:
1004          */
1005         DISABLE_INTERRUPTS(CLBR_ANY)
1006         TRACE_IRQS_IRETQ
1007         SWAPGS
1008         jmp restore_args
1009
1010 retint_restore_args:    /* return to kernel space */
1011         DISABLE_INTERRUPTS(CLBR_ANY)
1012         /*
1013          * The iretq could re-enable interrupts:
1014          */
1015         TRACE_IRQS_IRETQ
1016 restore_args:
1017         RESTORE_ARGS 1,8,1
1018
1019 irq_return:
1020         INTERRUPT_RETURN
1021         _ASM_EXTABLE(irq_return, bad_iret)
1022
1023 #ifdef CONFIG_PARAVIRT
1024 ENTRY(native_iret)
1025         iretq
1026         _ASM_EXTABLE(native_iret, bad_iret)
1027 #endif
1028
1029         .section .fixup,"ax"
1030 bad_iret:
1031         /*
1032          * The iret traps when the %cs or %ss being restored is bogus.
1033          * We've lost the original trap vector and error code.
1034          * #GPF is the most likely one to get for an invalid selector.
1035          * So pretend we completed the iret and took the #GPF in user mode.
1036          *
1037          * We are now running with the kernel GS after exception recovery.
1038          * But error_entry expects us to have user GS to match the user %cs,
1039          * so swap back.
1040          */
1041         pushq $0
1042
1043         SWAPGS
1044         jmp general_protection
1045
1046         .previous
1047
1048         /* edi: workmask, edx: work */
1049 retint_careful:
1050         CFI_RESTORE_STATE
1051         bt    $TIF_NEED_RESCHED,%edx
1052         jnc   retint_signal
1053         TRACE_IRQS_ON
1054         ENABLE_INTERRUPTS(CLBR_NONE)
1055         pushq_cfi %rdi
1056         call  schedule
1057         popq_cfi %rdi
1058         GET_THREAD_INFO(%rcx)
1059         DISABLE_INTERRUPTS(CLBR_NONE)
1060         TRACE_IRQS_OFF
1061         jmp retint_check
1062
1063 retint_signal:
1064         testl $_TIF_DO_NOTIFY_MASK,%edx
1065         jz    retint_swapgs
1066         TRACE_IRQS_ON
1067         ENABLE_INTERRUPTS(CLBR_NONE)
1068         SAVE_REST
1069         movq $-1,ORIG_RAX(%rsp)
1070         xorl %esi,%esi          # oldset
1071         movq %rsp,%rdi          # &pt_regs
1072         call do_notify_resume
1073         RESTORE_REST
1074         DISABLE_INTERRUPTS(CLBR_NONE)
1075         TRACE_IRQS_OFF
1076         GET_THREAD_INFO(%rcx)
1077         jmp retint_with_reschedule
1078
1079 #ifdef CONFIG_PREEMPT
1080         /* Returning to kernel space. Check if we need preemption */
1081         /* rcx:  threadinfo. interrupts off. */
1082 ENTRY(retint_kernel)
1083         cmpl $0,TI_preempt_count(%rcx)
1084         jnz  retint_restore_args
1085         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1086         jnc  retint_restore_args
1087         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1088         jnc  retint_restore_args
1089         call preempt_schedule_irq
1090         jmp exit_intr
1091 #endif
1092
1093         CFI_ENDPROC
1094 END(common_interrupt)
1095 /*
1096  * End of kprobes section
1097  */
1098        .popsection
1099
1100 /*
1101  * APIC interrupts.
1102  */
1103 .macro apicinterrupt num sym do_sym
1104 ENTRY(\sym)
1105         INTR_FRAME
1106         pushq_cfi $~(\num)
1107 .Lcommon_\sym:
1108         interrupt \do_sym
1109         jmp ret_from_intr
1110         CFI_ENDPROC
1111 END(\sym)
1112 .endm
1113
1114 #ifdef CONFIG_SMP
1115 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1116         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1117 apicinterrupt REBOOT_VECTOR \
1118         reboot_interrupt smp_reboot_interrupt
1119 #endif
1120
1121 #ifdef CONFIG_X86_UV
1122 apicinterrupt UV_BAU_MESSAGE \
1123         uv_bau_message_intr1 uv_bau_message_interrupt
1124 #endif
1125 apicinterrupt LOCAL_TIMER_VECTOR \
1126         apic_timer_interrupt smp_apic_timer_interrupt
1127 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1128         x86_platform_ipi smp_x86_platform_ipi
1129
1130 #ifdef CONFIG_SMP
1131         ALIGN
1132         INTR_FRAME
1133 .irp idx,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
1134         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
1135 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1136 ENTRY(invalidate_interrupt\idx)
1137         pushq_cfi $~(INVALIDATE_TLB_VECTOR_START+\idx)
1138         jmp .Lcommon_invalidate_interrupt0
1139         CFI_ADJUST_CFA_OFFSET -8
1140 END(invalidate_interrupt\idx)
1141 .endif
1142 .endr
1143         CFI_ENDPROC
1144 apicinterrupt INVALIDATE_TLB_VECTOR_START, \
1145         invalidate_interrupt0, smp_invalidate_interrupt
1146 #endif
1147
1148 apicinterrupt THRESHOLD_APIC_VECTOR \
1149         threshold_interrupt smp_threshold_interrupt
1150 apicinterrupt THERMAL_APIC_VECTOR \
1151         thermal_interrupt smp_thermal_interrupt
1152
1153 #ifdef CONFIG_SMP
1154 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1155         call_function_single_interrupt smp_call_function_single_interrupt
1156 apicinterrupt CALL_FUNCTION_VECTOR \
1157         call_function_interrupt smp_call_function_interrupt
1158 apicinterrupt RESCHEDULE_VECTOR \
1159         reschedule_interrupt smp_reschedule_interrupt
1160 #endif
1161
1162 apicinterrupt ERROR_APIC_VECTOR \
1163         error_interrupt smp_error_interrupt
1164 apicinterrupt SPURIOUS_APIC_VECTOR \
1165         spurious_interrupt smp_spurious_interrupt
1166
1167 #ifdef CONFIG_IRQ_WORK
1168 apicinterrupt IRQ_WORK_VECTOR \
1169         irq_work_interrupt smp_irq_work_interrupt
1170 #endif
1171
1172 /*
1173  * Exception entry points.
1174  */
1175 .macro zeroentry sym do_sym
1176 ENTRY(\sym)
1177         INTR_FRAME
1178         PARAVIRT_ADJUST_EXCEPTION_FRAME
1179         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1180         subq $ORIG_RAX-R15, %rsp
1181         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1182         call error_entry
1183         DEFAULT_FRAME 0
1184         movq %rsp,%rdi          /* pt_regs pointer */
1185         xorl %esi,%esi          /* no error code */
1186         call \do_sym
1187         jmp error_exit          /* %ebx: no swapgs flag */
1188         CFI_ENDPROC
1189 END(\sym)
1190 .endm
1191
1192 .macro paranoidzeroentry sym do_sym
1193 ENTRY(\sym)
1194         INTR_FRAME
1195         PARAVIRT_ADJUST_EXCEPTION_FRAME
1196         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1197         subq $ORIG_RAX-R15, %rsp
1198         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1199         call save_paranoid
1200         TRACE_IRQS_OFF
1201         movq %rsp,%rdi          /* pt_regs pointer */
1202         xorl %esi,%esi          /* no error code */
1203         call \do_sym
1204         jmp paranoid_exit       /* %ebx: no swapgs flag */
1205         CFI_ENDPROC
1206 END(\sym)
1207 .endm
1208
1209 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1210 .macro paranoidzeroentry_ist sym do_sym ist
1211 ENTRY(\sym)
1212         INTR_FRAME
1213         PARAVIRT_ADJUST_EXCEPTION_FRAME
1214         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1215         subq $ORIG_RAX-R15, %rsp
1216         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1217         call save_paranoid
1218         TRACE_IRQS_OFF_DEBUG
1219         movq %rsp,%rdi          /* pt_regs pointer */
1220         xorl %esi,%esi          /* no error code */
1221         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1222         call \do_sym
1223         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1224         jmp paranoid_exit       /* %ebx: no swapgs flag */
1225         CFI_ENDPROC
1226 END(\sym)
1227 .endm
1228
1229 .macro errorentry sym do_sym
1230 ENTRY(\sym)
1231         XCPT_FRAME
1232         PARAVIRT_ADJUST_EXCEPTION_FRAME
1233         subq $ORIG_RAX-R15, %rsp
1234         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1235         call error_entry
1236         DEFAULT_FRAME 0
1237         movq %rsp,%rdi                  /* pt_regs pointer */
1238         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1239         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1240         call \do_sym
1241         jmp error_exit                  /* %ebx: no swapgs flag */
1242         CFI_ENDPROC
1243 END(\sym)
1244 .endm
1245
1246         /* error code is on the stack already */
1247 .macro paranoiderrorentry sym do_sym
1248 ENTRY(\sym)
1249         XCPT_FRAME
1250         PARAVIRT_ADJUST_EXCEPTION_FRAME
1251         subq $ORIG_RAX-R15, %rsp
1252         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1253         call save_paranoid
1254         DEFAULT_FRAME 0
1255         TRACE_IRQS_OFF
1256         movq %rsp,%rdi                  /* pt_regs pointer */
1257         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1258         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1259         call \do_sym
1260         jmp paranoid_exit               /* %ebx: no swapgs flag */
1261         CFI_ENDPROC
1262 END(\sym)
1263 .endm
1264
1265 zeroentry divide_error do_divide_error
1266 zeroentry overflow do_overflow
1267 zeroentry bounds do_bounds
1268 zeroentry invalid_op do_invalid_op
1269 zeroentry device_not_available do_device_not_available
1270 paranoiderrorentry double_fault do_double_fault
1271 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1272 errorentry invalid_TSS do_invalid_TSS
1273 errorentry segment_not_present do_segment_not_present
1274 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1275 zeroentry coprocessor_error do_coprocessor_error
1276 errorentry alignment_check do_alignment_check
1277 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1278
1279
1280         /* Reload gs selector with exception handling */
1281         /* edi:  new selector */
1282 ENTRY(native_load_gs_index)
1283         CFI_STARTPROC
1284         pushfq_cfi
1285         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1286         SWAPGS
1287 gs_change:
1288         movl %edi,%gs
1289 2:      mfence          /* workaround */
1290         SWAPGS
1291         popfq_cfi
1292         ret
1293         CFI_ENDPROC
1294 END(native_load_gs_index)
1295
1296         _ASM_EXTABLE(gs_change,bad_gs)
1297         .section .fixup,"ax"
1298         /* running with kernelgs */
1299 bad_gs:
1300         SWAPGS                  /* switch back to user gs */
1301         xorl %eax,%eax
1302         movl %eax,%gs
1303         jmp  2b
1304         .previous
1305
1306 ENTRY(kernel_thread_helper)
1307         pushq $0                # fake return address
1308         CFI_STARTPROC
1309         /*
1310          * Here we are in the child and the registers are set as they were
1311          * at kernel_thread() invocation in the parent.
1312          */
1313         call *%rsi
1314         # exit
1315         mov %eax, %edi
1316         call do_exit
1317         ud2                     # padding for call trace
1318         CFI_ENDPROC
1319 END(kernel_thread_helper)
1320
1321 /*
1322  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1323  *
1324  * C extern interface:
1325  *       extern long execve(const char *name, char **argv, char **envp)
1326  *
1327  * asm input arguments:
1328  *      rdi: name, rsi: argv, rdx: envp
1329  *
1330  * We want to fallback into:
1331  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1332  *
1333  * do_sys_execve asm fallback arguments:
1334  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1335  */
1336 ENTRY(kernel_execve)
1337         CFI_STARTPROC
1338         FAKE_STACK_FRAME $0
1339         SAVE_ALL
1340         movq %rsp,%rcx
1341         call sys_execve
1342         movq %rax, RAX(%rsp)
1343         RESTORE_REST
1344         testq %rax,%rax
1345         je int_ret_from_sys_call
1346         RESTORE_ARGS
1347         UNFAKE_STACK_FRAME
1348         ret
1349         CFI_ENDPROC
1350 END(kernel_execve)
1351
1352 /* Call softirq on interrupt stack. Interrupts are off. */
1353 ENTRY(call_softirq)
1354         CFI_STARTPROC
1355         pushq_cfi %rbp
1356         CFI_REL_OFFSET rbp,0
1357         mov  %rsp,%rbp
1358         CFI_DEF_CFA_REGISTER rbp
1359         incl PER_CPU_VAR(irq_count)
1360         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1361         push  %rbp                      # backlink for old unwinder
1362         call __do_softirq
1363         leaveq
1364         CFI_RESTORE             rbp
1365         CFI_DEF_CFA_REGISTER    rsp
1366         CFI_ADJUST_CFA_OFFSET   -8
1367         decl PER_CPU_VAR(irq_count)
1368         ret
1369         CFI_ENDPROC
1370 END(call_softirq)
1371
1372 #ifdef CONFIG_XEN
1373 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1374
1375 /*
1376  * A note on the "critical region" in our callback handler.
1377  * We want to avoid stacking callback handlers due to events occurring
1378  * during handling of the last event. To do this, we keep events disabled
1379  * until we've done all processing. HOWEVER, we must enable events before
1380  * popping the stack frame (can't be done atomically) and so it would still
1381  * be possible to get enough handler activations to overflow the stack.
1382  * Although unlikely, bugs of that kind are hard to track down, so we'd
1383  * like to avoid the possibility.
1384  * So, on entry to the handler we detect whether we interrupted an
1385  * existing activation in its critical region -- if so, we pop the current
1386  * activation and restart the handler using the previous one.
1387  */
1388 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1389         CFI_STARTPROC
1390 /*
1391  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1392  * see the correct pointer to the pt_regs
1393  */
1394         movq %rdi, %rsp            # we don't return, adjust the stack frame
1395         CFI_ENDPROC
1396         DEFAULT_FRAME
1397 11:     incl PER_CPU_VAR(irq_count)
1398         movq %rsp,%rbp
1399         CFI_DEF_CFA_REGISTER rbp
1400         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1401         pushq %rbp                      # backlink for old unwinder
1402         call xen_evtchn_do_upcall
1403         popq %rsp
1404         CFI_DEF_CFA_REGISTER rsp
1405         decl PER_CPU_VAR(irq_count)
1406         jmp  error_exit
1407         CFI_ENDPROC
1408 END(xen_do_hypervisor_callback)
1409
1410 /*
1411  * Hypervisor uses this for application faults while it executes.
1412  * We get here for two reasons:
1413  *  1. Fault while reloading DS, ES, FS or GS
1414  *  2. Fault while executing IRET
1415  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1416  * registers that could be reloaded and zeroed the others.
1417  * Category 2 we fix up by killing the current process. We cannot use the
1418  * normal Linux return path in this case because if we use the IRET hypercall
1419  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1420  * We distinguish between categories by comparing each saved segment register
1421  * with its current contents: any discrepancy means we in category 1.
1422  */
1423 ENTRY(xen_failsafe_callback)
1424         INTR_FRAME 1 (6*8)
1425         /*CFI_REL_OFFSET gs,GS*/
1426         /*CFI_REL_OFFSET fs,FS*/
1427         /*CFI_REL_OFFSET es,ES*/
1428         /*CFI_REL_OFFSET ds,DS*/
1429         CFI_REL_OFFSET r11,8
1430         CFI_REL_OFFSET rcx,0
1431         movw %ds,%cx
1432         cmpw %cx,0x10(%rsp)
1433         CFI_REMEMBER_STATE
1434         jne 1f
1435         movw %es,%cx
1436         cmpw %cx,0x18(%rsp)
1437         jne 1f
1438         movw %fs,%cx
1439         cmpw %cx,0x20(%rsp)
1440         jne 1f
1441         movw %gs,%cx
1442         cmpw %cx,0x28(%rsp)
1443         jne 1f
1444         /* All segments match their saved values => Category 2 (Bad IRET). */
1445         movq (%rsp),%rcx
1446         CFI_RESTORE rcx
1447         movq 8(%rsp),%r11
1448         CFI_RESTORE r11
1449         addq $0x30,%rsp
1450         CFI_ADJUST_CFA_OFFSET -0x30
1451         pushq_cfi $0    /* RIP */
1452         pushq_cfi %r11
1453         pushq_cfi %rcx
1454         jmp general_protection
1455         CFI_RESTORE_STATE
1456 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1457         movq (%rsp),%rcx
1458         CFI_RESTORE rcx
1459         movq 8(%rsp),%r11
1460         CFI_RESTORE r11
1461         addq $0x30,%rsp
1462         CFI_ADJUST_CFA_OFFSET -0x30
1463         pushq_cfi $0
1464         SAVE_ALL
1465         jmp error_exit
1466         CFI_ENDPROC
1467 END(xen_failsafe_callback)
1468
1469 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1470         xen_hvm_callback_vector xen_evtchn_do_upcall
1471
1472 #endif /* CONFIG_XEN */
1473
1474 /*
1475  * Some functions should be protected against kprobes
1476  */
1477         .pushsection .kprobes.text, "ax"
1478
1479 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1480 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1481 paranoiderrorentry stack_segment do_stack_segment
1482 #ifdef CONFIG_XEN
1483 zeroentry xen_debug do_debug
1484 zeroentry xen_int3 do_int3
1485 errorentry xen_stack_segment do_stack_segment
1486 #endif
1487 errorentry general_protection do_general_protection
1488 errorentry page_fault do_page_fault
1489 #ifdef CONFIG_KVM_GUEST
1490 errorentry async_page_fault do_async_page_fault
1491 #endif
1492 #ifdef CONFIG_X86_MCE
1493 paranoidzeroentry machine_check *machine_check_vector(%rip)
1494 #endif
1495
1496         /*
1497          * "Paranoid" exit path from exception stack.
1498          * Paranoid because this is used by NMIs and cannot take
1499          * any kernel state for granted.
1500          * We don't do kernel preemption checks here, because only
1501          * NMI should be common and it does not enable IRQs and
1502          * cannot get reschedule ticks.
1503          *
1504          * "trace" is 0 for the NMI handler only, because irq-tracing
1505          * is fundamentally NMI-unsafe. (we cannot change the soft and
1506          * hard flags at once, atomically)
1507          */
1508
1509         /* ebx: no swapgs flag */
1510 ENTRY(paranoid_exit)
1511         DEFAULT_FRAME
1512         DISABLE_INTERRUPTS(CLBR_NONE)
1513         TRACE_IRQS_OFF_DEBUG
1514         testl %ebx,%ebx                         /* swapgs needed? */
1515         jnz paranoid_restore
1516         testl $3,CS(%rsp)
1517         jnz   paranoid_userspace
1518 paranoid_swapgs:
1519         TRACE_IRQS_IRETQ 0
1520         SWAPGS_UNSAFE_STACK
1521         RESTORE_ALL 8
1522         jmp irq_return
1523 paranoid_restore:
1524         TRACE_IRQS_IRETQ_DEBUG 0
1525         RESTORE_ALL 8
1526         jmp irq_return
1527 paranoid_userspace:
1528         GET_THREAD_INFO(%rcx)
1529         movl TI_flags(%rcx),%ebx
1530         andl $_TIF_WORK_MASK,%ebx
1531         jz paranoid_swapgs
1532         movq %rsp,%rdi                  /* &pt_regs */
1533         call sync_regs
1534         movq %rax,%rsp                  /* switch stack for scheduling */
1535         testl $_TIF_NEED_RESCHED,%ebx
1536         jnz paranoid_schedule
1537         movl %ebx,%edx                  /* arg3: thread flags */
1538         TRACE_IRQS_ON
1539         ENABLE_INTERRUPTS(CLBR_NONE)
1540         xorl %esi,%esi                  /* arg2: oldset */
1541         movq %rsp,%rdi                  /* arg1: &pt_regs */
1542         call do_notify_resume
1543         DISABLE_INTERRUPTS(CLBR_NONE)
1544         TRACE_IRQS_OFF
1545         jmp paranoid_userspace
1546 paranoid_schedule:
1547         TRACE_IRQS_ON
1548         ENABLE_INTERRUPTS(CLBR_ANY)
1549         call schedule
1550         DISABLE_INTERRUPTS(CLBR_ANY)
1551         TRACE_IRQS_OFF
1552         jmp paranoid_userspace
1553         CFI_ENDPROC
1554 END(paranoid_exit)
1555
1556 /*
1557  * Exception entry point. This expects an error code/orig_rax on the stack.
1558  * returns in "no swapgs flag" in %ebx.
1559  */
1560 ENTRY(error_entry)
1561         XCPT_FRAME
1562         CFI_ADJUST_CFA_OFFSET 15*8
1563         /* oldrax contains error code */
1564         cld
1565         movq_cfi rdi, RDI+8
1566         movq_cfi rsi, RSI+8
1567         movq_cfi rdx, RDX+8
1568         movq_cfi rcx, RCX+8
1569         movq_cfi rax, RAX+8
1570         movq_cfi  r8,  R8+8
1571         movq_cfi  r9,  R9+8
1572         movq_cfi r10, R10+8
1573         movq_cfi r11, R11+8
1574         movq_cfi rbx, RBX+8
1575         movq_cfi rbp, RBP+8
1576         movq_cfi r12, R12+8
1577         movq_cfi r13, R13+8
1578         movq_cfi r14, R14+8
1579         movq_cfi r15, R15+8
1580         xorl %ebx,%ebx
1581         testl $3,CS+8(%rsp)
1582         je error_kernelspace
1583 error_swapgs:
1584         SWAPGS
1585 error_sti:
1586         TRACE_IRQS_OFF
1587         ret
1588
1589 /*
1590  * There are two places in the kernel that can potentially fault with
1591  * usergs. Handle them here. The exception handlers after iret run with
1592  * kernel gs again, so don't set the user space flag. B stepping K8s
1593  * sometimes report an truncated RIP for IRET exceptions returning to
1594  * compat mode. Check for these here too.
1595  */
1596 error_kernelspace:
1597         incl %ebx
1598         leaq irq_return(%rip),%rcx
1599         cmpq %rcx,RIP+8(%rsp)
1600         je error_swapgs
1601         movl %ecx,%eax  /* zero extend */
1602         cmpq %rax,RIP+8(%rsp)
1603         je bstep_iret
1604         cmpq $gs_change,RIP+8(%rsp)
1605         je error_swapgs
1606         jmp error_sti
1607
1608 bstep_iret:
1609         /* Fix truncated RIP */
1610         movq %rcx,RIP+8(%rsp)
1611         jmp error_swapgs
1612         CFI_ENDPROC
1613 END(error_entry)
1614
1615
1616 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1617 ENTRY(error_exit)
1618         DEFAULT_FRAME
1619         movl %ebx,%eax
1620         RESTORE_REST
1621         DISABLE_INTERRUPTS(CLBR_NONE)
1622         TRACE_IRQS_OFF
1623         GET_THREAD_INFO(%rcx)
1624         testl %eax,%eax
1625         jne retint_kernel
1626         LOCKDEP_SYS_EXIT_IRQ
1627         movl TI_flags(%rcx),%edx
1628         movl $_TIF_WORK_MASK,%edi
1629         andl %edi,%edx
1630         jnz retint_careful
1631         jmp retint_swapgs
1632         CFI_ENDPROC
1633 END(error_exit)
1634
1635 /*
1636  * Test if a given stack is an NMI stack or not.
1637  */
1638         .macro test_in_nmi reg stack nmi_ret normal_ret
1639         cmpq %\reg, \stack
1640         ja \normal_ret
1641         subq $EXCEPTION_STKSZ, %\reg
1642         cmpq %\reg, \stack
1643         jb \normal_ret
1644         jmp \nmi_ret
1645         .endm
1646
1647         /* runs on exception stack */
1648 ENTRY(nmi)
1649         INTR_FRAME
1650         PARAVIRT_ADJUST_EXCEPTION_FRAME
1651         /*
1652          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1653          * the iretq it performs will take us out of NMI context.
1654          * This means that we can have nested NMIs where the next
1655          * NMI is using the top of the stack of the previous NMI. We
1656          * can't let it execute because the nested NMI will corrupt the
1657          * stack of the previous NMI. NMI handlers are not re-entrant
1658          * anyway.
1659          *
1660          * To handle this case we do the following:
1661          *  Check the a special location on the stack that contains
1662          *  a variable that is set when NMIs are executing.
1663          *  The interrupted task's stack is also checked to see if it
1664          *  is an NMI stack.
1665          *  If the variable is not set and the stack is not the NMI
1666          *  stack then:
1667          *    o Set the special variable on the stack
1668          *    o Copy the interrupt frame into a "saved" location on the stack
1669          *    o Copy the interrupt frame into a "copy" location on the stack
1670          *    o Continue processing the NMI
1671          *  If the variable is set or the previous stack is the NMI stack:
1672          *    o Modify the "copy" location to jump to the repeate_nmi
1673          *    o return back to the first NMI
1674          *
1675          * Now on exit of the first NMI, we first clear the stack variable
1676          * The NMI stack will tell any nested NMIs at that point that it is
1677          * nested. Then we pop the stack normally with iret, and if there was
1678          * a nested NMI that updated the copy interrupt stack frame, a
1679          * jump will be made to the repeat_nmi code that will handle the second
1680          * NMI.
1681          */
1682
1683         /* Use %rdx as out temp variable throughout */
1684         pushq_cfi %rdx
1685         CFI_REL_OFFSET rdx, 0
1686
1687         /*
1688          * If %cs was not the kernel segment, then the NMI triggered in user
1689          * space, which means it is definitely not nested.
1690          */
1691         cmpl $__KERNEL_CS, 16(%rsp)
1692         jne first_nmi
1693
1694         /*
1695          * Check the special variable on the stack to see if NMIs are
1696          * executing.
1697          */
1698         cmpl $1, -8(%rsp)
1699         je nested_nmi
1700
1701         /*
1702          * Now test if the previous stack was an NMI stack.
1703          * We need the double check. We check the NMI stack to satisfy the
1704          * race when the first NMI clears the variable before returning.
1705          * We check the variable because the first NMI could be in a
1706          * breakpoint routine using a breakpoint stack.
1707          */
1708         lea 6*8(%rsp), %rdx
1709         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1710         CFI_REMEMBER_STATE
1711
1712 nested_nmi:
1713         /*
1714          * Do nothing if we interrupted the fixup in repeat_nmi.
1715          * It's about to repeat the NMI handler, so we are fine
1716          * with ignoring this one.
1717          */
1718         movq $repeat_nmi, %rdx
1719         cmpq 8(%rsp), %rdx
1720         ja 1f
1721         movq $end_repeat_nmi, %rdx
1722         cmpq 8(%rsp), %rdx
1723         ja nested_nmi_out
1724
1725 1:
1726         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1727         leaq -6*8(%rsp), %rdx
1728         movq %rdx, %rsp
1729         CFI_ADJUST_CFA_OFFSET 6*8
1730         pushq_cfi $__KERNEL_DS
1731         pushq_cfi %rdx
1732         pushfq_cfi
1733         pushq_cfi $__KERNEL_CS
1734         pushq_cfi $repeat_nmi
1735
1736         /* Put stack back */
1737         addq $(11*8), %rsp
1738         CFI_ADJUST_CFA_OFFSET -11*8
1739
1740 nested_nmi_out:
1741         popq_cfi %rdx
1742         CFI_RESTORE rdx
1743
1744         /* No need to check faults here */
1745         INTERRUPT_RETURN
1746
1747         CFI_RESTORE_STATE
1748 first_nmi:
1749         /*
1750          * Because nested NMIs will use the pushed location that we
1751          * stored in rdx, we must keep that space available.
1752          * Here's what our stack frame will look like:
1753          * +-------------------------+
1754          * | original SS             |
1755          * | original Return RSP     |
1756          * | original RFLAGS         |
1757          * | original CS             |
1758          * | original RIP            |
1759          * +-------------------------+
1760          * | temp storage for rdx    |
1761          * +-------------------------+
1762          * | NMI executing variable  |
1763          * +-------------------------+
1764          * | Saved SS                |
1765          * | Saved Return RSP        |
1766          * | Saved RFLAGS            |
1767          * | Saved CS                |
1768          * | Saved RIP               |
1769          * +-------------------------+
1770          * | copied SS               |
1771          * | copied Return RSP       |
1772          * | copied RFLAGS           |
1773          * | copied CS               |
1774          * | copied RIP              |
1775          * +-------------------------+
1776          * | pt_regs                 |
1777          * +-------------------------+
1778          *
1779          * The saved stack frame is used to fix up the copied stack frame
1780          * that a nested NMI may change to make the interrupted NMI iret jump
1781          * to the repeat_nmi. The original stack frame and the temp storage
1782          * is also used by nested NMIs and can not be trusted on exit.
1783          */
1784         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1785         movq (%rsp), %rdx
1786         CFI_RESTORE rdx
1787
1788         /* Set the NMI executing variable on the stack. */
1789         pushq_cfi $1
1790
1791         /* Copy the stack frame to the Saved frame */
1792         .rept 5
1793         pushq_cfi 6*8(%rsp)
1794         .endr
1795         CFI_DEF_CFA_OFFSET SS+8-RIP
1796
1797         /* Everything up to here is safe from nested NMIs */
1798
1799         /*
1800          * If there was a nested NMI, the first NMI's iret will return
1801          * here. But NMIs are still enabled and we can take another
1802          * nested NMI. The nested NMI checks the interrupted RIP to see
1803          * if it is between repeat_nmi and end_repeat_nmi, and if so
1804          * it will just return, as we are about to repeat an NMI anyway.
1805          * This makes it safe to copy to the stack frame that a nested
1806          * NMI will update.
1807          */
1808 repeat_nmi:
1809         /*
1810          * Update the stack variable to say we are still in NMI (the update
1811          * is benign for the non-repeat case, where 1 was pushed just above
1812          * to this very stack slot).
1813          */
1814         movq $1, 5*8(%rsp)
1815
1816         /* Make another copy, this one may be modified by nested NMIs */
1817         .rept 5
1818         pushq_cfi 4*8(%rsp)
1819         .endr
1820         CFI_DEF_CFA_OFFSET SS+8-RIP
1821 end_repeat_nmi:
1822
1823         /*
1824          * Everything below this point can be preempted by a nested
1825          * NMI if the first NMI took an exception and reset our iret stack
1826          * so that we repeat another NMI.
1827          */
1828         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1829         subq $ORIG_RAX-R15, %rsp
1830         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1831         /*
1832          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1833          * as we should not be calling schedule in NMI context.
1834          * Even with normal interrupts enabled. An NMI should not be
1835          * setting NEED_RESCHED or anything that normal interrupts and
1836          * exceptions might do.
1837          */
1838         call save_paranoid
1839         DEFAULT_FRAME 0
1840         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1841         movq %rsp,%rdi
1842         movq $-1,%rsi
1843         call do_nmi
1844         testl %ebx,%ebx                         /* swapgs needed? */
1845         jnz nmi_restore
1846 nmi_swapgs:
1847         SWAPGS_UNSAFE_STACK
1848 nmi_restore:
1849         RESTORE_ALL 8
1850         /* Clear the NMI executing stack variable */
1851         movq $0, 10*8(%rsp)
1852         jmp irq_return
1853         CFI_ENDPROC
1854 END(nmi)
1855
1856 ENTRY(ignore_sysret)
1857         CFI_STARTPROC
1858         mov $-ENOSYS,%eax
1859         sysret
1860         CFI_ENDPROC
1861 END(ignore_sysret)
1862
1863 /*
1864  * End of kprobes section
1865  */
1866         .popsection