arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <linux/err.h>
  60
  61 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  62 #include <linux/elf-em.h>
  63 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  64 #define __AUDIT_ARCH_64BIT 0x80000000
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67         .code64
  68         .section .entry.text, "ax"
  69
  70 #ifdef CONFIG_FUNCTION_TRACER
  71 #ifdef CONFIG_DYNAMIC_FTRACE
  72 ENTRY(mcount)
  73         retq
  74 END(mcount)
  75
  76 ENTRY(ftrace_caller)
  77         cmpl $0, function_trace_stop
  78         jne  ftrace_stub
  79
  80         MCOUNT_SAVE_FRAME
  81
  82         leaq function_trace_op, %rdx
  83         movq 0x38(%rsp), %rdi
  84         movq 8(%rbp), %rsi
  85         subq $MCOUNT_INSN_SIZE, %rdi
  86
  87 GLOBAL(ftrace_call)
  88         call ftrace_stub
  89
  90         MCOUNT_RESTORE_FRAME
  91
  92 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  93 GLOBAL(ftrace_graph_call)
  94         jmp ftrace_stub
  95 #endif
  96
  97 GLOBAL(ftrace_stub)
  98         retq
  99 END(ftrace_caller)
 100
 101 #else /* ! CONFIG_DYNAMIC_FTRACE */
 102 ENTRY(mcount)
 103         cmpl $0, function_trace_stop
 104         jne  ftrace_stub
 105
 106         cmpq $ftrace_stub, ftrace_trace_function
 107         jnz trace
 108
 109 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 110         cmpq $ftrace_stub, ftrace_graph_return
 111         jnz ftrace_graph_caller
 112
 113         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 114         jnz ftrace_graph_caller
 115 #endif
 116
 117 GLOBAL(ftrace_stub)
 118         retq
 119
 120 trace:
 121         MCOUNT_SAVE_FRAME
 122
 123         movq 0x38(%rsp), %rdi
 124         movq 8(%rbp), %rsi
 125         subq $MCOUNT_INSN_SIZE, %rdi
 126
 127         call   *ftrace_trace_function
 128
 129         MCOUNT_RESTORE_FRAME
 130
 131         jmp ftrace_stub
 132 END(mcount)
 133 #endif /* CONFIG_DYNAMIC_FTRACE */
 134 #endif /* CONFIG_FUNCTION_TRACER */
 135
 136 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 137 ENTRY(ftrace_graph_caller)
 138         cmpl $0, function_trace_stop
 139         jne ftrace_stub
 140
 141         MCOUNT_SAVE_FRAME
 142
 143         leaq 8(%rbp), %rdi
 144         movq 0x38(%rsp), %rsi
 145         movq (%rbp), %rdx
 146         subq $MCOUNT_INSN_SIZE, %rsi
 147
 148         call    prepare_ftrace_return
 149
 150         MCOUNT_RESTORE_FRAME
 151
 152         retq
 153 END(ftrace_graph_caller)
 154
 155 GLOBAL(return_to_handler)
 156         subq  $24, %rsp
 157
 158         /* Save the return values */
 159         movq %rax, (%rsp)
 160         movq %rdx, 8(%rsp)
 161         movq %rbp, %rdi
 162
 163         call ftrace_return_to_handler
 164
 165         movq %rax, %rdi
 166         movq 8(%rsp), %rdx
 167         movq (%rsp), %rax
 168         addq $24, %rsp
 169         jmp *%rdi
 170 #endif
 171
 172
 173 #ifndef CONFIG_PREEMPT
 174 #define retint_kernel retint_restore_args
 175 #endif
 176
 177 #ifdef CONFIG_PARAVIRT
 178 ENTRY(native_usergs_sysret64)
 179         swapgs
 180         sysretq
 181 ENDPROC(native_usergs_sysret64)
 182 #endif /* CONFIG_PARAVIRT */
 183
 184
 185 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 186 #ifdef CONFIG_TRACE_IRQFLAGS
 187         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 188         jnc  1f
 189         TRACE_IRQS_ON
 190 1:
 191 #endif
 192 .endm
 193
 194 /*
 195  * When dynamic function tracer is enabled it will add a breakpoint
 196  * to all locations that it is about to modify, sync CPUs, update
 197  * all the code, sync CPUs, then remove the breakpoints. In this time
 198  * if lockdep is enabled, it might jump back into the debug handler
 199  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 200  *
 201  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 202  * make sure the stack pointer does not get reset back to the top
 203  * of the debug stack, and instead just reuses the current stack.
 204  */
 205 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 206
 207 .macro TRACE_IRQS_OFF_DEBUG
 208         call debug_stack_set_zero
 209         TRACE_IRQS_OFF
 210         call debug_stack_reset
 211 .endm
 212
 213 .macro TRACE_IRQS_ON_DEBUG
 214         call debug_stack_set_zero
 215         TRACE_IRQS_ON
 216         call debug_stack_reset
 217 .endm
 218
 219 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 220         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 221         jnc  1f
 222         TRACE_IRQS_ON_DEBUG
 223 1:
 224 .endm
 225
 226 #else
 227 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 228 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 229 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 230 #endif
 231
 232 /*
 233  * C code is not supposed to know about undefined top of stack. Every time
 234  * a C function with an pt_regs argument is called from the SYSCALL based
 235  * fast path FIXUP_TOP_OF_STACK is needed.
 236  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 237  * manipulation.
 238  */
 239
 240         /* %rsp:at FRAMEEND */
 241         .macro FIXUP_TOP_OF_STACK tmp offset=0
 242         movq PER_CPU_VAR(old_rsp),\tmp
 243         movq \tmp,RSP+\offset(%rsp)
 244         movq $__USER_DS,SS+\offset(%rsp)
 245         movq $__USER_CS,CS+\offset(%rsp)
 246         movq $-1,RCX+\offset(%rsp)
 247         movq R11+\offset(%rsp),\tmp  /* get eflags */
 248         movq \tmp,EFLAGS+\offset(%rsp)
 249         .endm
 250
 251         .macro RESTORE_TOP_OF_STACK tmp offset=0
 252         movq RSP+\offset(%rsp),\tmp
 253         movq \tmp,PER_CPU_VAR(old_rsp)
 254         movq EFLAGS+\offset(%rsp),\tmp
 255         movq \tmp,R11+\offset(%rsp)
 256         .endm
 257
 258         .macro FAKE_STACK_FRAME child_rip
 259         /* push in order ss, rsp, eflags, cs, rip */
 260         xorl %eax, %eax
 261         pushq_cfi $__KERNEL_DS /* ss */
 262         /*CFI_REL_OFFSET        ss,0*/
 263         pushq_cfi %rax /* rsp */
 264         CFI_REL_OFFSET  rsp,0
 265         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
 266         /*CFI_REL_OFFSET        rflags,0*/
 267         pushq_cfi $__KERNEL_CS /* cs */
 268         /*CFI_REL_OFFSET        cs,0*/
 269         pushq_cfi \child_rip /* rip */
 270         CFI_REL_OFFSET  rip,0
 271         pushq_cfi %rax /* orig rax */
 272         .endm
 273
 274         .macro UNFAKE_STACK_FRAME
 275         addq $8*6, %rsp
 276         CFI_ADJUST_CFA_OFFSET   -(6*8)
 277         .endm
 278
 279 /*
 280  * initial frame state for interrupts (and exceptions without error code)
 281  */
 282         .macro EMPTY_FRAME start=1 offset=0
 283         .if \start
 284         CFI_STARTPROC simple
 285         CFI_SIGNAL_FRAME
 286         CFI_DEF_CFA rsp,8+\offset
 287         .else
 288         CFI_DEF_CFA_OFFSET 8+\offset
 289         .endif
 290         .endm
 291
 292 /*
 293  * initial frame state for interrupts (and exceptions without error code)
 294  */
 295         .macro INTR_FRAME start=1 offset=0
 296         EMPTY_FRAME \start, SS+8+\offset-RIP
 297         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 298         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 299         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 300         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 301         CFI_REL_OFFSET rip, RIP+\offset-RIP
 302         .endm
 303
 304 /*
 305  * initial frame state for exceptions with error code (and interrupts
 306  * with vector already pushed)
 307  */
 308         .macro XCPT_FRAME start=1 offset=0
 309         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 310         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 311         .endm
 312
 313 /*
 314  * frame that enables calling into C.
 315  */
 316         .macro PARTIAL_FRAME start=1 offset=0
 317         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 318         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 319         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 320         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 321         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 322         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 323         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 324         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 325         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 326         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 327         .endm
 328
 329 /*
 330  * frame that enables passing a complete pt_regs to a C function.
 331  */
 332         .macro DEFAULT_FRAME start=1 offset=0
 333         PARTIAL_FRAME \start, R11+\offset-R15
 334         CFI_REL_OFFSET rbx, RBX+\offset
 335         CFI_REL_OFFSET rbp, RBP+\offset
 336         CFI_REL_OFFSET r12, R12+\offset
 337         CFI_REL_OFFSET r13, R13+\offset
 338         CFI_REL_OFFSET r14, R14+\offset
 339         CFI_REL_OFFSET r15, R15+\offset
 340         .endm
 341
 342 /* save partial stack frame */
 343         .macro SAVE_ARGS_IRQ
 344         cld
 345         /* start from rbp in pt_regs and jump over */
 346         movq_cfi rdi, RDI-RBP
 347         movq_cfi rsi, RSI-RBP
 348         movq_cfi rdx, RDX-RBP
 349         movq_cfi rcx, RCX-RBP
 350         movq_cfi rax, RAX-RBP
 351         movq_cfi  r8,  R8-RBP
 352         movq_cfi  r9,  R9-RBP
 353         movq_cfi r10, R10-RBP
 354         movq_cfi r11, R11-RBP
 355
 356         /* Save rbp so that we can unwind from get_irq_regs() */
 357         movq_cfi rbp, 0
 358
 359         /* Save previous stack value */
 360         movq %rsp, %rsi
 361
 362         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 363         testl $3, CS-RBP(%rsi)
 364         je 1f
 365         SWAPGS
 366         /*
 367          * irq_count is used to check if a CPU is already on an interrupt stack
 368          * or not. While this is essentially redundant with preempt_count it is
 369          * a little cheaper to use a separate counter in the PDA (short of
 370          * moving irq_enter into assembly, which would be too much work)
 371          */
 372 1:      incl PER_CPU_VAR(irq_count)
 373         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 374         CFI_DEF_CFA_REGISTER    rsi
 375
 376         /* Store previous stack value */
 377         pushq %rsi
 378         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 379                         0x77 /* DW_OP_breg7 */, 0, \
 380                         0x06 /* DW_OP_deref */, \
 381                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 382                         0x22 /* DW_OP_plus */
 383         /* We entered an interrupt context - irqs are off: */
 384         TRACE_IRQS_OFF
 385         .endm
 386
 387 ENTRY(save_rest)
 388         PARTIAL_FRAME 1 REST_SKIP+8
 389         movq 5*8+16(%rsp), %r11 /* save return address */
 390         movq_cfi rbx, RBX+16
 391         movq_cfi rbp, RBP+16
 392         movq_cfi r12, R12+16
 393         movq_cfi r13, R13+16
 394         movq_cfi r14, R14+16
 395         movq_cfi r15, R15+16
 396         movq %r11, 8(%rsp)      /* return address */
 397         FIXUP_TOP_OF_STACK %r11, 16
 398         ret
 399         CFI_ENDPROC
 400 END(save_rest)
 401
 402 /* save complete stack frame */
 403         .pushsection .kprobes.text, "ax"
 404 ENTRY(save_paranoid)
 405         XCPT_FRAME 1 RDI+8
 406         cld
 407         movq_cfi rdi, RDI+8
 408         movq_cfi rsi, RSI+8
 409         movq_cfi rdx, RDX+8
 410         movq_cfi rcx, RCX+8
 411         movq_cfi rax, RAX+8
 412         movq_cfi r8, R8+8
 413         movq_cfi r9, R9+8
 414         movq_cfi r10, R10+8
 415         movq_cfi r11, R11+8
 416         movq_cfi rbx, RBX+8
 417         movq_cfi rbp, RBP+8
 418         movq_cfi r12, R12+8
 419         movq_cfi r13, R13+8
 420         movq_cfi r14, R14+8
 421         movq_cfi r15, R15+8
 422         movl $1,%ebx
 423         movl $MSR_GS_BASE,%ecx
 424         rdmsr
 425         testl %edx,%edx
 426         js 1f   /* negative -> in kernel */
 427         SWAPGS
 428         xorl %ebx,%ebx
 429 1:      ret
 430         CFI_ENDPROC
 431 END(save_paranoid)
 432         .popsection
 433
 434 /*
 435  * A newly forked process directly context switches into this address.
 436  *
 437  * rdi: prev task we switched from
 438  */
 439 ENTRY(ret_from_fork)
 440         DEFAULT_FRAME
 441
 442         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 443
 444         pushq_cfi kernel_eflags(%rip)
 445         popfq_cfi                               # reset kernel eflags
 446
 447         call schedule_tail                      # rdi: 'prev' task parameter
 448
 449         GET_THREAD_INFO(%rcx)
 450
 451         RESTORE_REST
 452
 453         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 454         jz   retint_restore_args
 455
 456         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 457         jnz  int_ret_from_sys_call
 458
 459         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 460         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 461
 462         CFI_ENDPROC
 463 END(ret_from_fork)
 464
 465 /*
 466  * System call entry. Up to 6 arguments in registers are supported.
 467  *
 468  * SYSCALL does not save anything on the stack and does not change the
 469  * stack pointer.
 470  */
 471
 472 /*
 473  * Register setup:
 474  * rax  system call number
 475  * rdi  arg0
 476  * rcx  return address for syscall/sysret, C arg3
 477  * rsi  arg1
 478  * rdx  arg2
 479  * r10  arg3    (--> moved to rcx for C)
 480  * r8   arg4
 481  * r9   arg5
 482  * r11  eflags for syscall/sysret, temporary for C
 483  * r12-r15,rbp,rbx saved by C code, not touched.
 484  *
 485  * Interrupts are off on entry.
 486  * Only called from user space.
 487  *
 488  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 489  *      and report it properly in ps. Unfortunately we haven't.
 490  *
 491  * When user can change the frames always force IRET. That is because
 492  * it deals with uncanonical addresses better. SYSRET has trouble
 493  * with them due to bugs in both AMD and Intel CPUs.
 494  */
 495
 496 ENTRY(system_call)
 497         CFI_STARTPROC   simple
 498         CFI_SIGNAL_FRAME
 499         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 500         CFI_REGISTER    rip,rcx
 501         /*CFI_REGISTER  rflags,r11*/
 502         SWAPGS_UNSAFE_STACK
 503         /*
 504          * A hypervisor implementation might want to use a label
 505          * after the swapgs, so that it can do the swapgs
 506          * for the guest and jump here on syscall.
 507          */
 508 GLOBAL(system_call_after_swapgs)
 509
 510         movq    %rsp,PER_CPU_VAR(old_rsp)
 511         movq    PER_CPU_VAR(kernel_stack),%rsp
 512         /*
 513          * No need to follow this irqs off/on section - it's straight
 514          * and short:
 515          */
 516         ENABLE_INTERRUPTS(CLBR_NONE)
 517         SAVE_ARGS 8,0
 518         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 519         movq  %rcx,RIP-ARGOFFSET(%rsp)
 520         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 521         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 522         jnz tracesys
 523 system_call_fastpath:
 524 #if __SYSCALL_MASK == ~0
 525         cmpq $__NR_syscall_max,%rax
 526 #else
 527         andl $__SYSCALL_MASK,%eax
 528         cmpl $__NR_syscall_max,%eax
 529 #endif
 530         ja badsys
 531         movq %r10,%rcx
 532         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 533         movq %rax,RAX-ARGOFFSET(%rsp)
 534 /*
 535  * Syscall return path ending with SYSRET (fast path)
 536  * Has incomplete stack frame and undefined top of stack.
 537  */
 538 ret_from_sys_call:
 539         movl $_TIF_ALLWORK_MASK,%edi
 540         /* edi: flagmask */
 541 sysret_check:
 542         LOCKDEP_SYS_EXIT
 543         DISABLE_INTERRUPTS(CLBR_NONE)
 544         TRACE_IRQS_OFF
 545         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 546         andl %edi,%edx
 547         jnz  sysret_careful
 548         CFI_REMEMBER_STATE
 549         /*
 550          * sysretq will re-enable interrupts:
 551          */
 552         TRACE_IRQS_ON
 553         movq RIP-ARGOFFSET(%rsp),%rcx
 554         CFI_REGISTER    rip,rcx
 555         RESTORE_ARGS 1,-ARG_SKIP,0
 556         /*CFI_REGISTER  rflags,r11*/
 557         movq    PER_CPU_VAR(old_rsp), %rsp
 558         USERGS_SYSRET64
 559
 560         CFI_RESTORE_STATE
 561         /* Handle reschedules */
 562         /* edx: work, edi: workmask */
 563 sysret_careful:
 564         bt $TIF_NEED_RESCHED,%edx
 565         jnc sysret_signal
 566         TRACE_IRQS_ON
 567         ENABLE_INTERRUPTS(CLBR_NONE)
 568         pushq_cfi %rdi
 569         call schedule
 570         popq_cfi %rdi
 571         jmp sysret_check
 572
 573         /* Handle a signal */
 574 sysret_signal:
 575         TRACE_IRQS_ON
 576         ENABLE_INTERRUPTS(CLBR_NONE)
 577 #ifdef CONFIG_AUDITSYSCALL
 578         bt $TIF_SYSCALL_AUDIT,%edx
 579         jc sysret_audit
 580 #endif
 581         /*
 582          * We have a signal, or exit tracing or single-step.
 583          * These all wind up with the iret return path anyway,
 584          * so just join that path right now.
 585          */
 586         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 587         jmp int_check_syscall_exit_work
 588
 589 badsys:
 590         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 591         jmp ret_from_sys_call
 592
 593 #ifdef CONFIG_AUDITSYSCALL
 594         /*
 595          * Fast path for syscall audit without full syscall trace.
 596          * We just call __audit_syscall_entry() directly, and then
 597          * jump back to the normal fast path.
 598          */
 599 auditsys:
 600         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 601         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 602         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 603         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 604         movq %rax,%rsi                  /* 2nd arg: syscall number */
 605         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 606         call __audit_syscall_entry
 607         LOAD_ARGS 0             /* reload call-clobbered registers */
 608         jmp system_call_fastpath
 609
 610         /*
 611          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 612          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 613          * masked off.
 614          */
 615 sysret_audit:
 616         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 617         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 618         setbe %al               /* 1 if so, 0 if not */
 619         movzbl %al,%edi         /* zero-extend that into %edi */
 620         call __audit_syscall_exit
 621         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 622         jmp sysret_check
 623 #endif  /* CONFIG_AUDITSYSCALL */
 624
 625         /* Do syscall tracing */
 626 tracesys:
 627 #ifdef CONFIG_AUDITSYSCALL
 628         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 629         jz auditsys
 630 #endif
 631         SAVE_REST
 632         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 633         FIXUP_TOP_OF_STACK %rdi
 634         movq %rsp,%rdi
 635         call syscall_trace_enter
 636         /*
 637          * Reload arg registers from stack in case ptrace changed them.
 638          * We don't reload %rax because syscall_trace_enter() returned
 639          * the value it wants us to use in the table lookup.
 640          */
 641         LOAD_ARGS ARGOFFSET, 1
 642         RESTORE_REST
 643 #if __SYSCALL_MASK == ~0
 644         cmpq $__NR_syscall_max,%rax
 645 #else
 646         andl $__SYSCALL_MASK,%eax
 647         cmpl $__NR_syscall_max,%eax
 648 #endif
 649         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 650         movq %r10,%rcx  /* fixup for C */
 651         call *sys_call_table(,%rax,8)
 652         movq %rax,RAX-ARGOFFSET(%rsp)
 653         /* Use IRET because user could have changed frame */
 654
 655 /*
 656  * Syscall return path ending with IRET.
 657  * Has correct top of stack, but partial stack frame.
 658  */
 659 GLOBAL(int_ret_from_sys_call)
 660         DISABLE_INTERRUPTS(CLBR_NONE)
 661         TRACE_IRQS_OFF
 662         movl $_TIF_ALLWORK_MASK,%edi
 663         /* edi: mask to check */
 664 GLOBAL(int_with_check)
 665         LOCKDEP_SYS_EXIT_IRQ
 666         GET_THREAD_INFO(%rcx)
 667         movl TI_flags(%rcx),%edx
 668         andl %edi,%edx
 669         jnz   int_careful
 670         andl    $~TS_COMPAT,TI_status(%rcx)
 671         jmp   retint_swapgs
 672
 673         /* Either reschedule or signal or syscall exit tracking needed. */
 674         /* First do a reschedule test. */
 675         /* edx: work, edi: workmask */
 676 int_careful:
 677         bt $TIF_NEED_RESCHED,%edx
 678         jnc  int_very_careful
 679         TRACE_IRQS_ON
 680         ENABLE_INTERRUPTS(CLBR_NONE)
 681         pushq_cfi %rdi
 682         call schedule
 683         popq_cfi %rdi
 684         DISABLE_INTERRUPTS(CLBR_NONE)
 685         TRACE_IRQS_OFF
 686         jmp int_with_check
 687
 688         /* handle signals and tracing -- both require a full stack frame */
 689 int_very_careful:
 690         TRACE_IRQS_ON
 691         ENABLE_INTERRUPTS(CLBR_NONE)
 692 int_check_syscall_exit_work:
 693         SAVE_REST
 694         /* Check for syscall exit trace */
 695         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 696         jz int_signal
 697         pushq_cfi %rdi
 698         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 699         call syscall_trace_leave
 700         popq_cfi %rdi
 701         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 702         jmp int_restore_rest
 703
 704 int_signal:
 705         testl $_TIF_DO_NOTIFY_MASK,%edx
 706         jz 1f
 707         movq %rsp,%rdi          # &ptregs -> arg1
 708         xorl %esi,%esi          # oldset -> arg2
 709         call do_notify_resume
 710 1:      movl $_TIF_WORK_MASK,%edi
 711 int_restore_rest:
 712         RESTORE_REST
 713         DISABLE_INTERRUPTS(CLBR_NONE)
 714         TRACE_IRQS_OFF
 715         jmp int_with_check
 716         CFI_ENDPROC
 717 END(system_call)
 718
 719 /*
 720  * Certain special system calls that need to save a complete full stack frame.
 721  */
 722         .macro PTREGSCALL label,func,arg
 723 ENTRY(\label)
 724         PARTIAL_FRAME 1 8               /* offset 8: return address */
 725         subq $REST_SKIP, %rsp
 726         CFI_ADJUST_CFA_OFFSET REST_SKIP
 727         call save_rest
 728         DEFAULT_FRAME 0 8               /* offset 8: return address */
 729         leaq 8(%rsp), \arg      /* pt_regs pointer */
 730         call \func
 731         jmp ptregscall_common
 732         CFI_ENDPROC
 733 END(\label)
 734         .endm
 735
 736         PTREGSCALL stub_clone, sys_clone, %r8
 737         PTREGSCALL stub_fork, sys_fork, %rdi
 738         PTREGSCALL stub_vfork, sys_vfork, %rdi
 739         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 740         PTREGSCALL stub_iopl, sys_iopl, %rsi
 741
 742 ENTRY(ptregscall_common)
 743         DEFAULT_FRAME 1 8       /* offset 8: return address */
 744         RESTORE_TOP_OF_STACK %r11, 8
 745         movq_cfi_restore R15+8, r15
 746         movq_cfi_restore R14+8, r14
 747         movq_cfi_restore R13+8, r13
 748         movq_cfi_restore R12+8, r12
 749         movq_cfi_restore RBP+8, rbp
 750         movq_cfi_restore RBX+8, rbx
 751         ret $REST_SKIP          /* pop extended registers */
 752         CFI_ENDPROC
 753 END(ptregscall_common)
 754
 755 ENTRY(stub_execve)
 756         CFI_STARTPROC
 757         addq $8, %rsp
 758         PARTIAL_FRAME 0
 759         SAVE_REST
 760         FIXUP_TOP_OF_STACK %r11
 761         movq %rsp, %rcx
 762         call sys_execve
 763         RESTORE_TOP_OF_STACK %r11
 764         movq %rax,RAX(%rsp)
 765         RESTORE_REST
 766         jmp int_ret_from_sys_call
 767         CFI_ENDPROC
 768 END(stub_execve)
 769
 770 /*
 771  * sigreturn is special because it needs to restore all registers on return.
 772  * This cannot be done with SYSRET, so use the IRET return path instead.
 773  */
 774 ENTRY(stub_rt_sigreturn)
 775         CFI_STARTPROC
 776         addq $8, %rsp
 777         PARTIAL_FRAME 0
 778         SAVE_REST
 779         movq %rsp,%rdi
 780         FIXUP_TOP_OF_STACK %r11
 781         call sys_rt_sigreturn
 782         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 783         RESTORE_REST
 784         jmp int_ret_from_sys_call
 785         CFI_ENDPROC
 786 END(stub_rt_sigreturn)
 787
 788 #ifdef CONFIG_X86_X32_ABI
 789         PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
 790
 791 ENTRY(stub_x32_rt_sigreturn)
 792         CFI_STARTPROC
 793         addq $8, %rsp
 794         PARTIAL_FRAME 0
 795         SAVE_REST
 796         movq %rsp,%rdi
 797         FIXUP_TOP_OF_STACK %r11
 798         call sys32_x32_rt_sigreturn
 799         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 800         RESTORE_REST
 801         jmp int_ret_from_sys_call
 802         CFI_ENDPROC
 803 END(stub_x32_rt_sigreturn)
 804
 805 ENTRY(stub_x32_execve)
 806         CFI_STARTPROC
 807         addq $8, %rsp
 808         PARTIAL_FRAME 0
 809         SAVE_REST
 810         FIXUP_TOP_OF_STACK %r11
 811         movq %rsp, %rcx
 812         call sys32_execve
 813         RESTORE_TOP_OF_STACK %r11
 814         movq %rax,RAX(%rsp)
 815         RESTORE_REST
 816         jmp int_ret_from_sys_call
 817         CFI_ENDPROC
 818 END(stub_x32_execve)
 819
 820 #endif
 821
 822 /*
 823  * Build the entry stubs and pointer table with some assembler magic.
 824  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 825  * single cache line on all modern x86 implementations.
 826  */
 827         .section .init.rodata,"a"
 828 ENTRY(interrupt)
 829         .section .entry.text
 830         .p2align 5
 831         .p2align CONFIG_X86_L1_CACHE_SHIFT
 832 ENTRY(irq_entries_start)
 833         INTR_FRAME
 834 vector=FIRST_EXTERNAL_VECTOR
 835 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 836         .balign 32
 837   .rept 7
 838     .if vector < NR_VECTORS
 839       .if vector <> FIRST_EXTERNAL_VECTOR
 840         CFI_ADJUST_CFA_OFFSET -8
 841       .endif
 842 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 843       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 844         jmp 2f
 845       .endif
 846       .previous
 847         .quad 1b
 848       .section .entry.text
 849 vector=vector+1
 850     .endif
 851   .endr
 852 2:      jmp common_interrupt
 853 .endr
 854         CFI_ENDPROC
 855 END(irq_entries_start)
 856
 857 .previous
 858 END(interrupt)
 859 .previous
 860
 861 /*
 862  * Interrupt entry/exit.
 863  *
 864  * Interrupt entry points save only callee clobbered registers in fast path.
 865  *
 866  * Entry runs with interrupts off.
 867  */
 868
 869 /* 0(%rsp): ~(interrupt number) */
 870         .macro interrupt func
 871         /* reserve pt_regs for scratch regs and rbp */
 872         subq $ORIG_RAX-RBP, %rsp
 873         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 874         SAVE_ARGS_IRQ
 875         call \func
 876         .endm
 877
 878 /*
 879  * Interrupt entry/exit should be protected against kprobes
 880  */
 881         .pushsection .kprobes.text, "ax"
 882         /*
 883          * The interrupt stubs push (~vector+0x80) onto the stack and
 884          * then jump to common_interrupt.
 885          */
 886         .p2align CONFIG_X86_L1_CACHE_SHIFT
 887 common_interrupt:
 888         XCPT_FRAME
 889         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 890         interrupt do_IRQ
 891         /* 0(%rsp): old_rsp-ARGOFFSET */
 892 ret_from_intr:
 893         DISABLE_INTERRUPTS(CLBR_NONE)
 894         TRACE_IRQS_OFF
 895         decl PER_CPU_VAR(irq_count)
 896
 897         /* Restore saved previous stack */
 898         popq %rsi
 899         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
 900         leaq ARGOFFSET-RBP(%rsi), %rsp
 901         CFI_DEF_CFA_REGISTER    rsp
 902         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 903
 904 exit_intr:
 905         GET_THREAD_INFO(%rcx)
 906         testl $3,CS-ARGOFFSET(%rsp)
 907         je retint_kernel
 908
 909         /* Interrupt came from user space */
 910         /*
 911          * Has a correct top of stack, but a partial stack frame
 912          * %rcx: thread info. Interrupts off.
 913          */
 914 retint_with_reschedule:
 915         movl $_TIF_WORK_MASK,%edi
 916 retint_check:
 917         LOCKDEP_SYS_EXIT_IRQ
 918         movl TI_flags(%rcx),%edx
 919         andl %edi,%edx
 920         CFI_REMEMBER_STATE
 921         jnz  retint_careful
 922
 923 retint_swapgs:          /* return to user-space */
 924         /*
 925          * The iretq could re-enable interrupts:
 926          */
 927         DISABLE_INTERRUPTS(CLBR_ANY)
 928         TRACE_IRQS_IRETQ
 929         SWAPGS
 930         jmp restore_args
 931
 932 retint_restore_args:    /* return to kernel space */
 933         DISABLE_INTERRUPTS(CLBR_ANY)
 934         /*
 935          * The iretq could re-enable interrupts:
 936          */
 937         TRACE_IRQS_IRETQ
 938 restore_args:
 939         RESTORE_ARGS 1,8,1
 940
 941 irq_return:
 942         INTERRUPT_RETURN
 943         _ASM_EXTABLE(irq_return, bad_iret)
 944
 945 #ifdef CONFIG_PARAVIRT
 946 ENTRY(native_iret)
 947         iretq
 948         _ASM_EXTABLE(native_iret, bad_iret)
 949 #endif
 950
 951         .section .fixup,"ax"
 952 bad_iret:
 953         /*
 954          * The iret traps when the %cs or %ss being restored is bogus.
 955          * We've lost the original trap vector and error code.
 956          * #GPF is the most likely one to get for an invalid selector.
 957          * So pretend we completed the iret and took the #GPF in user mode.
 958          *
 959          * We are now running with the kernel GS after exception recovery.
 960          * But error_entry expects us to have user GS to match the user %cs,
 961          * so swap back.
 962          */
 963         pushq $0
 964
 965         SWAPGS
 966         jmp general_protection
 967
 968         .previous
 969
 970         /* edi: workmask, edx: work */
 971 retint_careful:
 972         CFI_RESTORE_STATE
 973         bt    $TIF_NEED_RESCHED,%edx
 974         jnc   retint_signal
 975         TRACE_IRQS_ON
 976         ENABLE_INTERRUPTS(CLBR_NONE)
 977         pushq_cfi %rdi
 978         call  schedule
 979         popq_cfi %rdi
 980         GET_THREAD_INFO(%rcx)
 981         DISABLE_INTERRUPTS(CLBR_NONE)
 982         TRACE_IRQS_OFF
 983         jmp retint_check
 984
 985 retint_signal:
 986         testl $_TIF_DO_NOTIFY_MASK,%edx
 987         jz    retint_swapgs
 988         TRACE_IRQS_ON
 989         ENABLE_INTERRUPTS(CLBR_NONE)
 990         SAVE_REST
 991         movq $-1,ORIG_RAX(%rsp)
 992         xorl %esi,%esi          # oldset
 993         movq %rsp,%rdi          # &pt_regs
 994         call do_notify_resume
 995         RESTORE_REST
 996         DISABLE_INTERRUPTS(CLBR_NONE)
 997         TRACE_IRQS_OFF
 998         GET_THREAD_INFO(%rcx)
 999         jmp retint_with_reschedule
1000
1001 #ifdef CONFIG_PREEMPT
1002         /* Returning to kernel space. Check if we need preemption */
1003         /* rcx:  threadinfo. interrupts off. */
1004 ENTRY(retint_kernel)
1005         cmpl $0,TI_preempt_count(%rcx)
1006         jnz  retint_restore_args
1007         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1008         jnc  retint_restore_args
1009         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1010         jnc  retint_restore_args
1011         call preempt_schedule_irq
1012         jmp exit_intr
1013 #endif
1014
1015         CFI_ENDPROC
1016 END(common_interrupt)
1017 /*
1018  * End of kprobes section
1019  */
1020        .popsection
1021
1022 /*
1023  * APIC interrupts.
1024  */
1025 .macro apicinterrupt num sym do_sym
1026 ENTRY(\sym)
1027         INTR_FRAME
1028         pushq_cfi $~(\num)
1029 .Lcommon_\sym:
1030         interrupt \do_sym
1031         jmp ret_from_intr
1032         CFI_ENDPROC
1033 END(\sym)
1034 .endm
1035
1036 #ifdef CONFIG_SMP
1037 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1038         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1039 apicinterrupt REBOOT_VECTOR \
1040         reboot_interrupt smp_reboot_interrupt
1041 #endif
1042
1043 #ifdef CONFIG_X86_UV
1044 apicinterrupt UV_BAU_MESSAGE \
1045         uv_bau_message_intr1 uv_bau_message_interrupt
1046 #endif
1047 apicinterrupt LOCAL_TIMER_VECTOR \
1048         apic_timer_interrupt smp_apic_timer_interrupt
1049 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1050         x86_platform_ipi smp_x86_platform_ipi
1051
1052 #ifdef CONFIG_SMP
1053         ALIGN
1054         INTR_FRAME
1055 .irp idx,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
1056         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
1057 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1058 ENTRY(invalidate_interrupt\idx)
1059         pushq_cfi $~(INVALIDATE_TLB_VECTOR_START+\idx)
1060         jmp .Lcommon_invalidate_interrupt0
1061         CFI_ADJUST_CFA_OFFSET -8
1062 END(invalidate_interrupt\idx)
1063 .endif
1064 .endr
1065         CFI_ENDPROC
1066 apicinterrupt INVALIDATE_TLB_VECTOR_START, \
1067         invalidate_interrupt0, smp_invalidate_interrupt
1068 #endif
1069
1070 apicinterrupt THRESHOLD_APIC_VECTOR \
1071         threshold_interrupt smp_threshold_interrupt
1072 apicinterrupt THERMAL_APIC_VECTOR \
1073         thermal_interrupt smp_thermal_interrupt
1074
1075 #ifdef CONFIG_SMP
1076 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1077         call_function_single_interrupt smp_call_function_single_interrupt
1078 apicinterrupt CALL_FUNCTION_VECTOR \
1079         call_function_interrupt smp_call_function_interrupt
1080 apicinterrupt RESCHEDULE_VECTOR \
1081         reschedule_interrupt smp_reschedule_interrupt
1082 #endif
1083
1084 apicinterrupt ERROR_APIC_VECTOR \
1085         error_interrupt smp_error_interrupt
1086 apicinterrupt SPURIOUS_APIC_VECTOR \
1087         spurious_interrupt smp_spurious_interrupt
1088
1089 #ifdef CONFIG_IRQ_WORK
1090 apicinterrupt IRQ_WORK_VECTOR \
1091         irq_work_interrupt smp_irq_work_interrupt
1092 #endif
1093
1094 /*
1095  * Exception entry points.
1096  */
1097 .macro zeroentry sym do_sym
1098 ENTRY(\sym)
1099         INTR_FRAME
1100         PARAVIRT_ADJUST_EXCEPTION_FRAME
1101         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1102         subq $ORIG_RAX-R15, %rsp
1103         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1104         call error_entry
1105         DEFAULT_FRAME 0
1106         movq %rsp,%rdi          /* pt_regs pointer */
1107         xorl %esi,%esi          /* no error code */
1108         call \do_sym
1109         jmp error_exit          /* %ebx: no swapgs flag */
1110         CFI_ENDPROC
1111 END(\sym)
1112 .endm
1113
1114 .macro paranoidzeroentry sym do_sym
1115 ENTRY(\sym)
1116         INTR_FRAME
1117         PARAVIRT_ADJUST_EXCEPTION_FRAME
1118         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1119         subq $ORIG_RAX-R15, %rsp
1120         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1121         call save_paranoid
1122         TRACE_IRQS_OFF
1123         movq %rsp,%rdi          /* pt_regs pointer */
1124         xorl %esi,%esi          /* no error code */
1125         call \do_sym
1126         jmp paranoid_exit       /* %ebx: no swapgs flag */
1127         CFI_ENDPROC
1128 END(\sym)
1129 .endm
1130
1131 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1132 .macro paranoidzeroentry_ist sym do_sym ist
1133 ENTRY(\sym)
1134         INTR_FRAME
1135         PARAVIRT_ADJUST_EXCEPTION_FRAME
1136         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1137         subq $ORIG_RAX-R15, %rsp
1138         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1139         call save_paranoid
1140         TRACE_IRQS_OFF_DEBUG
1141         movq %rsp,%rdi          /* pt_regs pointer */
1142         xorl %esi,%esi          /* no error code */
1143         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1144         call \do_sym
1145         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1146         jmp paranoid_exit       /* %ebx: no swapgs flag */
1147         CFI_ENDPROC
1148 END(\sym)
1149 .endm
1150
1151 .macro errorentry sym do_sym
1152 ENTRY(\sym)
1153         XCPT_FRAME
1154         PARAVIRT_ADJUST_EXCEPTION_FRAME
1155         subq $ORIG_RAX-R15, %rsp
1156         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1157         call error_entry
1158         DEFAULT_FRAME 0
1159         movq %rsp,%rdi                  /* pt_regs pointer */
1160         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1161         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1162         call \do_sym
1163         jmp error_exit                  /* %ebx: no swapgs flag */
1164         CFI_ENDPROC
1165 END(\sym)
1166 .endm
1167
1168         /* error code is on the stack already */
1169 .macro paranoiderrorentry sym do_sym
1170 ENTRY(\sym)
1171         XCPT_FRAME
1172         PARAVIRT_ADJUST_EXCEPTION_FRAME
1173         subq $ORIG_RAX-R15, %rsp
1174         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1175         call save_paranoid
1176         DEFAULT_FRAME 0
1177         TRACE_IRQS_OFF
1178         movq %rsp,%rdi                  /* pt_regs pointer */
1179         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1180         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1181         call \do_sym
1182         jmp paranoid_exit               /* %ebx: no swapgs flag */
1183         CFI_ENDPROC
1184 END(\sym)
1185 .endm
1186
1187 zeroentry divide_error do_divide_error
1188 zeroentry overflow do_overflow
1189 zeroentry bounds do_bounds
1190 zeroentry invalid_op do_invalid_op
1191 zeroentry device_not_available do_device_not_available
1192 paranoiderrorentry double_fault do_double_fault
1193 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1194 errorentry invalid_TSS do_invalid_TSS
1195 errorentry segment_not_present do_segment_not_present
1196 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1197 zeroentry coprocessor_error do_coprocessor_error
1198 errorentry alignment_check do_alignment_check
1199 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1200
1201
1202         /* Reload gs selector with exception handling */
1203         /* edi:  new selector */
1204 ENTRY(native_load_gs_index)
1205         CFI_STARTPROC
1206         pushfq_cfi
1207         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1208         SWAPGS
1209 gs_change:
1210         movl %edi,%gs
1211 2:      mfence          /* workaround */
1212         SWAPGS
1213         popfq_cfi
1214         ret
1215         CFI_ENDPROC
1216 END(native_load_gs_index)
1217
1218         _ASM_EXTABLE(gs_change,bad_gs)
1219         .section .fixup,"ax"
1220         /* running with kernelgs */
1221 bad_gs:
1222         SWAPGS                  /* switch back to user gs */
1223         xorl %eax,%eax
1224         movl %eax,%gs
1225         jmp  2b
1226         .previous
1227
1228 ENTRY(kernel_thread_helper)
1229         pushq $0                # fake return address
1230         CFI_STARTPROC
1231         /*
1232          * Here we are in the child and the registers are set as they were
1233          * at kernel_thread() invocation in the parent.
1234          */
1235         call *%rsi
1236         # exit
1237         mov %eax, %edi
1238         call do_exit
1239         ud2                     # padding for call trace
1240         CFI_ENDPROC
1241 END(kernel_thread_helper)
1242
1243 /*
1244  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1245  *
1246  * C extern interface:
1247  *       extern long execve(const char *name, char **argv, char **envp)
1248  *
1249  * asm input arguments:
1250  *      rdi: name, rsi: argv, rdx: envp
1251  *
1252  * We want to fallback into:
1253  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1254  *
1255  * do_sys_execve asm fallback arguments:
1256  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1257  */
1258 ENTRY(kernel_execve)
1259         CFI_STARTPROC
1260         FAKE_STACK_FRAME $0
1261         SAVE_ALL
1262         movq %rsp,%rcx
1263         call sys_execve
1264         movq %rax, RAX(%rsp)
1265         RESTORE_REST
1266         testq %rax,%rax
1267         je int_ret_from_sys_call
1268         RESTORE_ARGS
1269         UNFAKE_STACK_FRAME
1270         ret
1271         CFI_ENDPROC
1272 END(kernel_execve)
1273
1274 /* Call softirq on interrupt stack. Interrupts are off. */
1275 ENTRY(call_softirq)
1276         CFI_STARTPROC
1277         pushq_cfi %rbp
1278         CFI_REL_OFFSET rbp,0
1279         mov  %rsp,%rbp
1280         CFI_DEF_CFA_REGISTER rbp
1281         incl PER_CPU_VAR(irq_count)
1282         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1283         push  %rbp                      # backlink for old unwinder
1284         call __do_softirq
1285         leaveq
1286         CFI_RESTORE             rbp
1287         CFI_DEF_CFA_REGISTER    rsp
1288         CFI_ADJUST_CFA_OFFSET   -8
1289         decl PER_CPU_VAR(irq_count)
1290         ret
1291         CFI_ENDPROC
1292 END(call_softirq)
1293
1294 #ifdef CONFIG_XEN
1295 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1296
1297 /*
1298  * A note on the "critical region" in our callback handler.
1299  * We want to avoid stacking callback handlers due to events occurring
1300  * during handling of the last event. To do this, we keep events disabled
1301  * until we've done all processing. HOWEVER, we must enable events before
1302  * popping the stack frame (can't be done atomically) and so it would still
1303  * be possible to get enough handler activations to overflow the stack.
1304  * Although unlikely, bugs of that kind are hard to track down, so we'd
1305  * like to avoid the possibility.
1306  * So, on entry to the handler we detect whether we interrupted an
1307  * existing activation in its critical region -- if so, we pop the current
1308  * activation and restart the handler using the previous one.
1309  */
1310 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1311         CFI_STARTPROC
1312 /*
1313  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1314  * see the correct pointer to the pt_regs
1315  */
1316         movq %rdi, %rsp            # we don't return, adjust the stack frame
1317         CFI_ENDPROC
1318         DEFAULT_FRAME
1319 11:     incl PER_CPU_VAR(irq_count)
1320         movq %rsp,%rbp
1321         CFI_DEF_CFA_REGISTER rbp
1322         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1323         pushq %rbp                      # backlink for old unwinder
1324         call xen_evtchn_do_upcall
1325         popq %rsp
1326         CFI_DEF_CFA_REGISTER rsp
1327         decl PER_CPU_VAR(irq_count)
1328         jmp  error_exit
1329         CFI_ENDPROC
1330 END(xen_do_hypervisor_callback)
1331
1332 /*
1333  * Hypervisor uses this for application faults while it executes.
1334  * We get here for two reasons:
1335  *  1. Fault while reloading DS, ES, FS or GS
1336  *  2. Fault while executing IRET
1337  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1338  * registers that could be reloaded and zeroed the others.
1339  * Category 2 we fix up by killing the current process. We cannot use the
1340  * normal Linux return path in this case because if we use the IRET hypercall
1341  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1342  * We distinguish between categories by comparing each saved segment register
1343  * with its current contents: any discrepancy means we in category 1.
1344  */
1345 ENTRY(xen_failsafe_callback)
1346         INTR_FRAME 1 (6*8)
1347         /*CFI_REL_OFFSET gs,GS*/
1348         /*CFI_REL_OFFSET fs,FS*/
1349         /*CFI_REL_OFFSET es,ES*/
1350         /*CFI_REL_OFFSET ds,DS*/
1351         CFI_REL_OFFSET r11,8
1352         CFI_REL_OFFSET rcx,0
1353         movw %ds,%cx
1354         cmpw %cx,0x10(%rsp)
1355         CFI_REMEMBER_STATE
1356         jne 1f
1357         movw %es,%cx
1358         cmpw %cx,0x18(%rsp)
1359         jne 1f
1360         movw %fs,%cx
1361         cmpw %cx,0x20(%rsp)
1362         jne 1f
1363         movw %gs,%cx
1364         cmpw %cx,0x28(%rsp)
1365         jne 1f
1366         /* All segments match their saved values => Category 2 (Bad IRET). */
1367         movq (%rsp),%rcx
1368         CFI_RESTORE rcx
1369         movq 8(%rsp),%r11
1370         CFI_RESTORE r11
1371         addq $0x30,%rsp
1372         CFI_ADJUST_CFA_OFFSET -0x30
1373         pushq_cfi $0    /* RIP */
1374         pushq_cfi %r11
1375         pushq_cfi %rcx
1376         jmp general_protection
1377         CFI_RESTORE_STATE
1378 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1379         movq (%rsp),%rcx
1380         CFI_RESTORE rcx
1381         movq 8(%rsp),%r11
1382         CFI_RESTORE r11
1383         addq $0x30,%rsp
1384         CFI_ADJUST_CFA_OFFSET -0x30
1385         pushq_cfi $0
1386         SAVE_ALL
1387         jmp error_exit
1388         CFI_ENDPROC
1389 END(xen_failsafe_callback)
1390
1391 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1392         xen_hvm_callback_vector xen_evtchn_do_upcall
1393
1394 #endif /* CONFIG_XEN */
1395
1396 /*
1397  * Some functions should be protected against kprobes
1398  */
1399         .pushsection .kprobes.text, "ax"
1400
1401 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1402 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1403 paranoiderrorentry stack_segment do_stack_segment
1404 #ifdef CONFIG_XEN
1405 zeroentry xen_debug do_debug
1406 zeroentry xen_int3 do_int3
1407 errorentry xen_stack_segment do_stack_segment
1408 #endif
1409 errorentry general_protection do_general_protection
1410 errorentry page_fault do_page_fault
1411 #ifdef CONFIG_KVM_GUEST
1412 errorentry async_page_fault do_async_page_fault
1413 #endif
1414 #ifdef CONFIG_X86_MCE
1415 paranoidzeroentry machine_check *machine_check_vector(%rip)
1416 #endif
1417
1418         /*
1419          * "Paranoid" exit path from exception stack.
1420          * Paranoid because this is used by NMIs and cannot take
1421          * any kernel state for granted.
1422          * We don't do kernel preemption checks here, because only
1423          * NMI should be common and it does not enable IRQs and
1424          * cannot get reschedule ticks.
1425          *
1426          * "trace" is 0 for the NMI handler only, because irq-tracing
1427          * is fundamentally NMI-unsafe. (we cannot change the soft and
1428          * hard flags at once, atomically)
1429          */
1430
1431         /* ebx: no swapgs flag */
1432 ENTRY(paranoid_exit)
1433         DEFAULT_FRAME
1434         DISABLE_INTERRUPTS(CLBR_NONE)
1435         TRACE_IRQS_OFF_DEBUG
1436         testl %ebx,%ebx                         /* swapgs needed? */
1437         jnz paranoid_restore
1438         testl $3,CS(%rsp)
1439         jnz   paranoid_userspace
1440 paranoid_swapgs:
1441         TRACE_IRQS_IRETQ 0
1442         SWAPGS_UNSAFE_STACK
1443         RESTORE_ALL 8
1444         jmp irq_return
1445 paranoid_restore:
1446         TRACE_IRQS_IRETQ_DEBUG 0
1447         RESTORE_ALL 8
1448         jmp irq_return
1449 paranoid_userspace:
1450         GET_THREAD_INFO(%rcx)
1451         movl TI_flags(%rcx),%ebx
1452         andl $_TIF_WORK_MASK,%ebx
1453         jz paranoid_swapgs
1454         movq %rsp,%rdi                  /* &pt_regs */
1455         call sync_regs
1456         movq %rax,%rsp                  /* switch stack for scheduling */
1457         testl $_TIF_NEED_RESCHED,%ebx
1458         jnz paranoid_schedule
1459         movl %ebx,%edx                  /* arg3: thread flags */
1460         TRACE_IRQS_ON
1461         ENABLE_INTERRUPTS(CLBR_NONE)
1462         xorl %esi,%esi                  /* arg2: oldset */
1463         movq %rsp,%rdi                  /* arg1: &pt_regs */
1464         call do_notify_resume
1465         DISABLE_INTERRUPTS(CLBR_NONE)
1466         TRACE_IRQS_OFF
1467         jmp paranoid_userspace
1468 paranoid_schedule:
1469         TRACE_IRQS_ON
1470         ENABLE_INTERRUPTS(CLBR_ANY)
1471         call schedule
1472         DISABLE_INTERRUPTS(CLBR_ANY)
1473         TRACE_IRQS_OFF
1474         jmp paranoid_userspace
1475         CFI_ENDPROC
1476 END(paranoid_exit)
1477
1478 /*
1479  * Exception entry point. This expects an error code/orig_rax on the stack.
1480  * returns in "no swapgs flag" in %ebx.
1481  */
1482 ENTRY(error_entry)
1483         XCPT_FRAME
1484         CFI_ADJUST_CFA_OFFSET 15*8
1485         /* oldrax contains error code */
1486         cld
1487         movq_cfi rdi, RDI+8
1488         movq_cfi rsi, RSI+8
1489         movq_cfi rdx, RDX+8
1490         movq_cfi rcx, RCX+8
1491         movq_cfi rax, RAX+8
1492         movq_cfi  r8,  R8+8
1493         movq_cfi  r9,  R9+8
1494         movq_cfi r10, R10+8
1495         movq_cfi r11, R11+8
1496         movq_cfi rbx, RBX+8
1497         movq_cfi rbp, RBP+8
1498         movq_cfi r12, R12+8
1499         movq_cfi r13, R13+8
1500         movq_cfi r14, R14+8
1501         movq_cfi r15, R15+8
1502         xorl %ebx,%ebx
1503         testl $3,CS+8(%rsp)
1504         je error_kernelspace
1505 error_swapgs:
1506         SWAPGS
1507 error_sti:
1508         TRACE_IRQS_OFF
1509         ret
1510
1511 /*
1512  * There are two places in the kernel that can potentially fault with
1513  * usergs. Handle them here. The exception handlers after iret run with
1514  * kernel gs again, so don't set the user space flag. B stepping K8s
1515  * sometimes report an truncated RIP for IRET exceptions returning to
1516  * compat mode. Check for these here too.
1517  */
1518 error_kernelspace:
1519         incl %ebx
1520         leaq irq_return(%rip),%rcx
1521         cmpq %rcx,RIP+8(%rsp)
1522         je error_swapgs
1523         movl %ecx,%eax  /* zero extend */
1524         cmpq %rax,RIP+8(%rsp)
1525         je bstep_iret
1526         cmpq $gs_change,RIP+8(%rsp)
1527         je error_swapgs
1528         jmp error_sti
1529
1530 bstep_iret:
1531         /* Fix truncated RIP */
1532         movq %rcx,RIP+8(%rsp)
1533         jmp error_swapgs
1534         CFI_ENDPROC
1535 END(error_entry)
1536
1537
1538 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1539 ENTRY(error_exit)
1540         DEFAULT_FRAME
1541         movl %ebx,%eax
1542         RESTORE_REST
1543         DISABLE_INTERRUPTS(CLBR_NONE)
1544         TRACE_IRQS_OFF
1545         GET_THREAD_INFO(%rcx)
1546         testl %eax,%eax
1547         jne retint_kernel
1548         LOCKDEP_SYS_EXIT_IRQ
1549         movl TI_flags(%rcx),%edx
1550         movl $_TIF_WORK_MASK,%edi
1551         andl %edi,%edx
1552         jnz retint_careful
1553         jmp retint_swapgs
1554         CFI_ENDPROC
1555 END(error_exit)
1556
1557 /*
1558  * Test if a given stack is an NMI stack or not.
1559  */
1560         .macro test_in_nmi reg stack nmi_ret normal_ret
1561         cmpq %\reg, \stack
1562         ja \normal_ret
1563         subq $EXCEPTION_STKSZ, %\reg
1564         cmpq %\reg, \stack
1565         jb \normal_ret
1566         jmp \nmi_ret
1567         .endm
1568
1569         /* runs on exception stack */
1570 ENTRY(nmi)
1571         INTR_FRAME
1572         PARAVIRT_ADJUST_EXCEPTION_FRAME
1573         /*
1574          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1575          * the iretq it performs will take us out of NMI context.
1576          * This means that we can have nested NMIs where the next
1577          * NMI is using the top of the stack of the previous NMI. We
1578          * can't let it execute because the nested NMI will corrupt the
1579          * stack of the previous NMI. NMI handlers are not re-entrant
1580          * anyway.
1581          *
1582          * To handle this case we do the following:
1583          *  Check the a special location on the stack that contains
1584          *  a variable that is set when NMIs are executing.
1585          *  The interrupted task's stack is also checked to see if it
1586          *  is an NMI stack.
1587          *  If the variable is not set and the stack is not the NMI
1588          *  stack then:
1589          *    o Set the special variable on the stack
1590          *    o Copy the interrupt frame into a "saved" location on the stack
1591          *    o Copy the interrupt frame into a "copy" location on the stack
1592          *    o Continue processing the NMI
1593          *  If the variable is set or the previous stack is the NMI stack:
1594          *    o Modify the "copy" location to jump to the repeate_nmi
1595          *    o return back to the first NMI
1596          *
1597          * Now on exit of the first NMI, we first clear the stack variable
1598          * The NMI stack will tell any nested NMIs at that point that it is
1599          * nested. Then we pop the stack normally with iret, and if there was
1600          * a nested NMI that updated the copy interrupt stack frame, a
1601          * jump will be made to the repeat_nmi code that will handle the second
1602          * NMI.
1603          */
1604
1605         /* Use %rdx as out temp variable throughout */
1606         pushq_cfi %rdx
1607         CFI_REL_OFFSET rdx, 0
1608
1609         /*
1610          * If %cs was not the kernel segment, then the NMI triggered in user
1611          * space, which means it is definitely not nested.
1612          */
1613         cmpl $__KERNEL_CS, 16(%rsp)
1614         jne first_nmi
1615
1616         /*
1617          * Check the special variable on the stack to see if NMIs are
1618          * executing.
1619          */
1620         cmpl $1, -8(%rsp)
1621         je nested_nmi
1622
1623         /*
1624          * Now test if the previous stack was an NMI stack.
1625          * We need the double check. We check the NMI stack to satisfy the
1626          * race when the first NMI clears the variable before returning.
1627          * We check the variable because the first NMI could be in a
1628          * breakpoint routine using a breakpoint stack.
1629          */
1630         lea 6*8(%rsp), %rdx
1631         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1632         CFI_REMEMBER_STATE
1633
1634 nested_nmi:
1635         /*
1636          * Do nothing if we interrupted the fixup in repeat_nmi.
1637          * It's about to repeat the NMI handler, so we are fine
1638          * with ignoring this one.
1639          */
1640         movq $repeat_nmi, %rdx
1641         cmpq 8(%rsp), %rdx
1642         ja 1f
1643         movq $end_repeat_nmi, %rdx
1644         cmpq 8(%rsp), %rdx
1645         ja nested_nmi_out
1646
1647 1:
1648         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1649         leaq -6*8(%rsp), %rdx
1650         movq %rdx, %rsp
1651         CFI_ADJUST_CFA_OFFSET 6*8
1652         pushq_cfi $__KERNEL_DS
1653         pushq_cfi %rdx
1654         pushfq_cfi
1655         pushq_cfi $__KERNEL_CS
1656         pushq_cfi $repeat_nmi
1657
1658         /* Put stack back */
1659         addq $(11*8), %rsp
1660         CFI_ADJUST_CFA_OFFSET -11*8
1661
1662 nested_nmi_out:
1663         popq_cfi %rdx
1664         CFI_RESTORE rdx
1665
1666         /* No need to check faults here */
1667         INTERRUPT_RETURN
1668
1669         CFI_RESTORE_STATE
1670 first_nmi:
1671         /*
1672          * Because nested NMIs will use the pushed location that we
1673          * stored in rdx, we must keep that space available.
1674          * Here's what our stack frame will look like:
1675          * +-------------------------+
1676          * | original SS             |
1677          * | original Return RSP     |
1678          * | original RFLAGS         |
1679          * | original CS             |
1680          * | original RIP            |
1681          * +-------------------------+
1682          * | temp storage for rdx    |
1683          * +-------------------------+
1684          * | NMI executing variable  |
1685          * +-------------------------+
1686          * | Saved SS                |
1687          * | Saved Return RSP        |
1688          * | Saved RFLAGS            |
1689          * | Saved CS                |
1690          * | Saved RIP               |
1691          * +-------------------------+
1692          * | copied SS               |
1693          * | copied Return RSP       |
1694          * | copied RFLAGS           |
1695          * | copied CS               |
1696          * | copied RIP              |
1697          * +-------------------------+
1698          * | pt_regs                 |
1699          * +-------------------------+
1700          *
1701          * The saved stack frame is used to fix up the copied stack frame
1702          * that a nested NMI may change to make the interrupted NMI iret jump
1703          * to the repeat_nmi. The original stack frame and the temp storage
1704          * is also used by nested NMIs and can not be trusted on exit.
1705          */
1706         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1707         movq (%rsp), %rdx
1708         CFI_RESTORE rdx
1709
1710         /* Set the NMI executing variable on the stack. */
1711         pushq_cfi $1
1712
1713         /* Copy the stack frame to the Saved frame */
1714         .rept 5
1715         pushq_cfi 6*8(%rsp)
1716         .endr
1717         CFI_DEF_CFA_OFFSET SS+8-RIP
1718
1719         /* Everything up to here is safe from nested NMIs */
1720
1721         /*
1722          * If there was a nested NMI, the first NMI's iret will return
1723          * here. But NMIs are still enabled and we can take another
1724          * nested NMI. The nested NMI checks the interrupted RIP to see
1725          * if it is between repeat_nmi and end_repeat_nmi, and if so
1726          * it will just return, as we are about to repeat an NMI anyway.
1727          * This makes it safe to copy to the stack frame that a nested
1728          * NMI will update.
1729          */
1730 repeat_nmi:
1731         /*
1732          * Update the stack variable to say we are still in NMI (the update
1733          * is benign for the non-repeat case, where 1 was pushed just above
1734          * to this very stack slot).
1735          */
1736         movq $1, 5*8(%rsp)
1737
1738         /* Make another copy, this one may be modified by nested NMIs */
1739         .rept 5
1740         pushq_cfi 4*8(%rsp)
1741         .endr
1742         CFI_DEF_CFA_OFFSET SS+8-RIP
1743 end_repeat_nmi:
1744
1745         /*
1746          * Everything below this point can be preempted by a nested
1747          * NMI if the first NMI took an exception and reset our iret stack
1748          * so that we repeat another NMI.
1749          */
1750         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1751         subq $ORIG_RAX-R15, %rsp
1752         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1753         /*
1754          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1755          * as we should not be calling schedule in NMI context.
1756          * Even with normal interrupts enabled. An NMI should not be
1757          * setting NEED_RESCHED or anything that normal interrupts and
1758          * exceptions might do.
1759          */
1760         call save_paranoid
1761         DEFAULT_FRAME 0
1762         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1763         movq %rsp,%rdi
1764         movq $-1,%rsi
1765         call do_nmi
1766         testl %ebx,%ebx                         /* swapgs needed? */
1767         jnz nmi_restore
1768 nmi_swapgs:
1769         SWAPGS_UNSAFE_STACK
1770 nmi_restore:
1771         RESTORE_ALL 8
1772         /* Clear the NMI executing stack variable */
1773         movq $0, 10*8(%rsp)
1774         jmp irq_return
1775         CFI_ENDPROC
1776 END(nmi)
1777
1778 ENTRY(ignore_sysret)
1779         CFI_STARTPROC
1780         mov $-ENOSYS,%eax
1781         sysret
1782         CFI_ENDPROC
1783 END(ignore_sysret)
1784
1785 /*
1786  * End of kprobes section
1787  */
1788         .popsection