arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58
  59 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  60 #include <linux/elf-em.h>
  61 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  62 #define __AUDIT_ARCH_64BIT 0x80000000
  63 #define __AUDIT_ARCH_LE    0x40000000
  64
  65         .code64
  66         .section .entry.text, "ax"
  67
  68 #ifdef CONFIG_FUNCTION_TRACER
  69 #ifdef CONFIG_DYNAMIC_FTRACE
  70 ENTRY(mcount)
  71         retq
  72 END(mcount)
  73
  74 ENTRY(ftrace_caller)
  75         cmpl $0, function_trace_stop
  76         jne  ftrace_stub
  77
  78         MCOUNT_SAVE_FRAME
  79
  80         movq 0x38(%rsp), %rdi
  81         movq 8(%rbp), %rsi
  82         subq $MCOUNT_INSN_SIZE, %rdi
  83
  84 GLOBAL(ftrace_call)
  85         call ftrace_stub
  86
  87         MCOUNT_RESTORE_FRAME
  88
  89 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  90 GLOBAL(ftrace_graph_call)
  91         jmp ftrace_stub
  92 #endif
  93
  94 GLOBAL(ftrace_stub)
  95         retq
  96 END(ftrace_caller)
  97
  98 #else /* ! CONFIG_DYNAMIC_FTRACE */
  99 ENTRY(mcount)
 100         cmpl $0, function_trace_stop
 101         jne  ftrace_stub
 102
 103         cmpq $ftrace_stub, ftrace_trace_function
 104         jnz trace
 105
 106 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 107         cmpq $ftrace_stub, ftrace_graph_return
 108         jnz ftrace_graph_caller
 109
 110         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 111         jnz ftrace_graph_caller
 112 #endif
 113
 114 GLOBAL(ftrace_stub)
 115         retq
 116
 117 trace:
 118         MCOUNT_SAVE_FRAME
 119
 120         movq 0x38(%rsp), %rdi
 121         movq 8(%rbp), %rsi
 122         subq $MCOUNT_INSN_SIZE, %rdi
 123
 124         call   *ftrace_trace_function
 125
 126         MCOUNT_RESTORE_FRAME
 127
 128         jmp ftrace_stub
 129 END(mcount)
 130 #endif /* CONFIG_DYNAMIC_FTRACE */
 131 #endif /* CONFIG_FUNCTION_TRACER */
 132
 133 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 134 ENTRY(ftrace_graph_caller)
 135         cmpl $0, function_trace_stop
 136         jne ftrace_stub
 137
 138         MCOUNT_SAVE_FRAME
 139
 140         leaq 8(%rbp), %rdi
 141         movq 0x38(%rsp), %rsi
 142         movq (%rbp), %rdx
 143         subq $MCOUNT_INSN_SIZE, %rsi
 144
 145         call    prepare_ftrace_return
 146
 147         MCOUNT_RESTORE_FRAME
 148
 149         retq
 150 END(ftrace_graph_caller)
 151
 152 GLOBAL(return_to_handler)
 153         subq  $24, %rsp
 154
 155         /* Save the return values */
 156         movq %rax, (%rsp)
 157         movq %rdx, 8(%rsp)
 158         movq %rbp, %rdi
 159
 160         call ftrace_return_to_handler
 161
 162         movq %rax, %rdi
 163         movq 8(%rsp), %rdx
 164         movq (%rsp), %rax
 165         addq $24, %rsp
 166         jmp *%rdi
 167 #endif
 168
 169
 170 #ifndef CONFIG_PREEMPT
 171 #define retint_kernel retint_restore_args
 172 #endif
 173
 174 #ifdef CONFIG_PARAVIRT
 175 ENTRY(native_usergs_sysret64)
 176         swapgs
 177         sysretq
 178 ENDPROC(native_usergs_sysret64)
 179 #endif /* CONFIG_PARAVIRT */
 180
 181
 182 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 183 #ifdef CONFIG_TRACE_IRQFLAGS
 184         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 185         jnc  1f
 186         TRACE_IRQS_ON
 187 1:
 188 #endif
 189 .endm
 190
 191 /*
 192  * C code is not supposed to know about undefined top of stack. Every time
 193  * a C function with an pt_regs argument is called from the SYSCALL based
 194  * fast path FIXUP_TOP_OF_STACK is needed.
 195  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 196  * manipulation.
 197  */
 198
 199         /* %rsp:at FRAMEEND */
 200         .macro FIXUP_TOP_OF_STACK tmp offset=0
 201         movq PER_CPU_VAR(old_rsp),\tmp
 202         movq \tmp,RSP+\offset(%rsp)
 203         movq $__USER_DS,SS+\offset(%rsp)
 204         movq $__USER_CS,CS+\offset(%rsp)
 205         movq $-1,RCX+\offset(%rsp)
 206         movq R11+\offset(%rsp),\tmp  /* get eflags */
 207         movq \tmp,EFLAGS+\offset(%rsp)
 208         .endm
 209
 210         .macro RESTORE_TOP_OF_STACK tmp offset=0
 211         movq RSP+\offset(%rsp),\tmp
 212         movq \tmp,PER_CPU_VAR(old_rsp)
 213         movq EFLAGS+\offset(%rsp),\tmp
 214         movq \tmp,R11+\offset(%rsp)
 215         .endm
 216
 217         .macro FAKE_STACK_FRAME child_rip
 218         /* push in order ss, rsp, eflags, cs, rip */
 219         xorl %eax, %eax
 220         pushq_cfi $__KERNEL_DS /* ss */
 221         /*CFI_REL_OFFSET        ss,0*/
 222         pushq_cfi %rax /* rsp */
 223         CFI_REL_OFFSET  rsp,0
 224         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 225         /*CFI_REL_OFFSET        rflags,0*/
 226         pushq_cfi $__KERNEL_CS /* cs */
 227         /*CFI_REL_OFFSET        cs,0*/
 228         pushq_cfi \child_rip /* rip */
 229         CFI_REL_OFFSET  rip,0
 230         pushq_cfi %rax /* orig rax */
 231         .endm
 232
 233         .macro UNFAKE_STACK_FRAME
 234         addq $8*6, %rsp
 235         CFI_ADJUST_CFA_OFFSET   -(6*8)
 236         .endm
 237
 238 /*
 239  * initial frame state for interrupts (and exceptions without error code)
 240  */
 241         .macro EMPTY_FRAME start=1 offset=0
 242         .if \start
 243         CFI_STARTPROC simple
 244         CFI_SIGNAL_FRAME
 245         CFI_DEF_CFA rsp,8+\offset
 246         .else
 247         CFI_DEF_CFA_OFFSET 8+\offset
 248         .endif
 249         .endm
 250
 251 /*
 252  * initial frame state for interrupts (and exceptions without error code)
 253  */
 254         .macro INTR_FRAME start=1 offset=0
 255         EMPTY_FRAME \start, SS+8+\offset-RIP
 256         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 257         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 258         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 259         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 260         CFI_REL_OFFSET rip, RIP+\offset-RIP
 261         .endm
 262
 263 /*
 264  * initial frame state for exceptions with error code (and interrupts
 265  * with vector already pushed)
 266  */
 267         .macro XCPT_FRAME start=1 offset=0
 268         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 269         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 270         .endm
 271
 272 /*
 273  * frame that enables calling into C.
 274  */
 275         .macro PARTIAL_FRAME start=1 offset=0
 276         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 277         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 286         .endm
 287
 288 /*
 289  * frame that enables passing a complete pt_regs to a C function.
 290  */
 291         .macro DEFAULT_FRAME start=1 offset=0
 292         PARTIAL_FRAME \start, R11+\offset-R15
 293         CFI_REL_OFFSET rbx, RBX+\offset
 294         CFI_REL_OFFSET rbp, RBP+\offset
 295         CFI_REL_OFFSET r12, R12+\offset
 296         CFI_REL_OFFSET r13, R13+\offset
 297         CFI_REL_OFFSET r14, R14+\offset
 298         CFI_REL_OFFSET r15, R15+\offset
 299         .endm
 300
 301 /* save partial stack frame */
 302         .macro SAVE_ARGS_IRQ
 303         cld
 304         /* start from rbp in pt_regs and jump over */
 305         movq_cfi rdi, RDI-RBP
 306         movq_cfi rsi, RSI-RBP
 307         movq_cfi rdx, RDX-RBP
 308         movq_cfi rcx, RCX-RBP
 309         movq_cfi rax, RAX-RBP
 310         movq_cfi  r8,  R8-RBP
 311         movq_cfi  r9,  R9-RBP
 312         movq_cfi r10, R10-RBP
 313         movq_cfi r11, R11-RBP
 314
 315         /* Save rbp so that we can unwind from get_irq_regs() */
 316         movq_cfi rbp, 0
 317
 318         /* Save previous stack value */
 319         movq %rsp, %rsi
 320
 321         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 322         testl $3, CS(%rdi)
 323         je 1f
 324         SWAPGS
 325         /*
 326          * irq_count is used to check if a CPU is already on an interrupt stack
 327          * or not. While this is essentially redundant with preempt_count it is
 328          * a little cheaper to use a separate counter in the PDA (short of
 329          * moving irq_enter into assembly, which would be too much work)
 330          */
 331 1:      incl PER_CPU_VAR(irq_count)
 332         jne 2f
 333         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 334         CFI_DEF_CFA_REGISTER    rsi
 335
 336 2:      /* Store previous stack value */
 337         pushq %rsi
 338         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 339                         0x77 /* DW_OP_breg7 */, 0, \
 340                         0x06 /* DW_OP_deref */, \
 341                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 342                         0x22 /* DW_OP_plus */
 343         /* We entered an interrupt context - irqs are off: */
 344         TRACE_IRQS_OFF
 345         .endm
 346
 347 ENTRY(save_rest)
 348         PARTIAL_FRAME 1 REST_SKIP+8
 349         movq 5*8+16(%rsp), %r11 /* save return address */
 350         movq_cfi rbx, RBX+16
 351         movq_cfi rbp, RBP+16
 352         movq_cfi r12, R12+16
 353         movq_cfi r13, R13+16
 354         movq_cfi r14, R14+16
 355         movq_cfi r15, R15+16
 356         movq %r11, 8(%rsp)      /* return address */
 357         FIXUP_TOP_OF_STACK %r11, 16
 358         ret
 359         CFI_ENDPROC
 360 END(save_rest)
 361
 362 /* save complete stack frame */
 363         .pushsection .kprobes.text, "ax"
 364 ENTRY(save_paranoid)
 365         XCPT_FRAME 1 RDI+8
 366         cld
 367         movq_cfi rdi, RDI+8
 368         movq_cfi rsi, RSI+8
 369         movq_cfi rdx, RDX+8
 370         movq_cfi rcx, RCX+8
 371         movq_cfi rax, RAX+8
 372         movq_cfi r8, R8+8
 373         movq_cfi r9, R9+8
 374         movq_cfi r10, R10+8
 375         movq_cfi r11, R11+8
 376         movq_cfi rbx, RBX+8
 377         movq_cfi rbp, RBP+8
 378         movq_cfi r12, R12+8
 379         movq_cfi r13, R13+8
 380         movq_cfi r14, R14+8
 381         movq_cfi r15, R15+8
 382         movl $1,%ebx
 383         movl $MSR_GS_BASE,%ecx
 384         rdmsr
 385         testl %edx,%edx
 386         js 1f   /* negative -> in kernel */
 387         SWAPGS
 388         xorl %ebx,%ebx
 389 1:      ret
 390         CFI_ENDPROC
 391 END(save_paranoid)
 392         .popsection
 393
 394 /*
 395  * A newly forked process directly context switches into this address.
 396  *
 397  * rdi: prev task we switched from
 398  */
 399 ENTRY(ret_from_fork)
 400         DEFAULT_FRAME
 401
 402         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 403
 404         pushq_cfi kernel_eflags(%rip)
 405         popfq_cfi                               # reset kernel eflags
 406
 407         call schedule_tail                      # rdi: 'prev' task parameter
 408
 409         GET_THREAD_INFO(%rcx)
 410
 411         RESTORE_REST
 412
 413         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 414         jz   retint_restore_args
 415
 416         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 417         jnz  int_ret_from_sys_call
 418
 419         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 420         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 421
 422         CFI_ENDPROC
 423 END(ret_from_fork)
 424
 425 /*
 426  * System call entry. Up to 6 arguments in registers are supported.
 427  *
 428  * SYSCALL does not save anything on the stack and does not change the
 429  * stack pointer.
 430  */
 431
 432 /*
 433  * Register setup:
 434  * rax  system call number
 435  * rdi  arg0
 436  * rcx  return address for syscall/sysret, C arg3
 437  * rsi  arg1
 438  * rdx  arg2
 439  * r10  arg3    (--> moved to rcx for C)
 440  * r8   arg4
 441  * r9   arg5
 442  * r11  eflags for syscall/sysret, temporary for C
 443  * r12-r15,rbp,rbx saved by C code, not touched.
 444  *
 445  * Interrupts are off on entry.
 446  * Only called from user space.
 447  *
 448  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 449  *      and report it properly in ps. Unfortunately we haven't.
 450  *
 451  * When user can change the frames always force IRET. That is because
 452  * it deals with uncanonical addresses better. SYSRET has trouble
 453  * with them due to bugs in both AMD and Intel CPUs.
 454  */
 455
 456 ENTRY(system_call)
 457         CFI_STARTPROC   simple
 458         CFI_SIGNAL_FRAME
 459         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 460         CFI_REGISTER    rip,rcx
 461         /*CFI_REGISTER  rflags,r11*/
 462         SWAPGS_UNSAFE_STACK
 463         /*
 464          * A hypervisor implementation might want to use a label
 465          * after the swapgs, so that it can do the swapgs
 466          * for the guest and jump here on syscall.
 467          */
 468 ENTRY(system_call_after_swapgs)
 469
 470         movq    %rsp,PER_CPU_VAR(old_rsp)
 471         movq    PER_CPU_VAR(kernel_stack),%rsp
 472         /*
 473          * No need to follow this irqs off/on section - it's straight
 474          * and short:
 475          */
 476         ENABLE_INTERRUPTS(CLBR_NONE)
 477         SAVE_ARGS 8,0
 478         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 479         movq  %rcx,RIP-ARGOFFSET(%rsp)
 480         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 481         GET_THREAD_INFO(%rcx)
 482         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 483         jnz tracesys
 484 system_call_fastpath:
 485         cmpq $__NR_syscall_max,%rax
 486         ja badsys
 487         movq %r10,%rcx
 488         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 489         movq %rax,RAX-ARGOFFSET(%rsp)
 490 /*
 491  * Syscall return path ending with SYSRET (fast path)
 492  * Has incomplete stack frame and undefined top of stack.
 493  */
 494 ret_from_sys_call:
 495         movl $_TIF_ALLWORK_MASK,%edi
 496         /* edi: flagmask */
 497 sysret_check:
 498         LOCKDEP_SYS_EXIT
 499         GET_THREAD_INFO(%rcx)
 500         DISABLE_INTERRUPTS(CLBR_NONE)
 501         TRACE_IRQS_OFF
 502         movl TI_flags(%rcx),%edx
 503         andl %edi,%edx
 504         jnz  sysret_careful
 505         CFI_REMEMBER_STATE
 506         /*
 507          * sysretq will re-enable interrupts:
 508          */
 509         TRACE_IRQS_ON
 510         movq RIP-ARGOFFSET(%rsp),%rcx
 511         CFI_REGISTER    rip,rcx
 512         RESTORE_ARGS 1,-ARG_SKIP,0
 513         /*CFI_REGISTER  rflags,r11*/
 514         movq    PER_CPU_VAR(old_rsp), %rsp
 515         USERGS_SYSRET64
 516
 517         CFI_RESTORE_STATE
 518         /* Handle reschedules */
 519         /* edx: work, edi: workmask */
 520 sysret_careful:
 521         bt $TIF_NEED_RESCHED,%edx
 522         jnc sysret_signal
 523         TRACE_IRQS_ON
 524         ENABLE_INTERRUPTS(CLBR_NONE)
 525         pushq_cfi %rdi
 526         call schedule
 527         popq_cfi %rdi
 528         jmp sysret_check
 529
 530         /* Handle a signal */
 531 sysret_signal:
 532         TRACE_IRQS_ON
 533         ENABLE_INTERRUPTS(CLBR_NONE)
 534 #ifdef CONFIG_AUDITSYSCALL
 535         bt $TIF_SYSCALL_AUDIT,%edx
 536         jc sysret_audit
 537 #endif
 538         /*
 539          * We have a signal, or exit tracing or single-step.
 540          * These all wind up with the iret return path anyway,
 541          * so just join that path right now.
 542          */
 543         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 544         jmp int_check_syscall_exit_work
 545
 546 badsys:
 547         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 548         jmp ret_from_sys_call
 549
 550 #ifdef CONFIG_AUDITSYSCALL
 551         /*
 552          * Fast path for syscall audit without full syscall trace.
 553          * We just call audit_syscall_entry() directly, and then
 554          * jump back to the normal fast path.
 555          */
 556 auditsys:
 557         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 558         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 559         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 560         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 561         movq %rax,%rsi                  /* 2nd arg: syscall number */
 562         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 563         call audit_syscall_entry
 564         LOAD_ARGS 0             /* reload call-clobbered registers */
 565         jmp system_call_fastpath
 566
 567         /*
 568          * Return fast path for syscall audit.  Call audit_syscall_exit()
 569          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 570          * masked off.
 571          */
 572 sysret_audit:
 573         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 574         cmpq $0,%rsi            /* is it < 0? */
 575         setl %al                /* 1 if so, 0 if not */
 576         movzbl %al,%edi         /* zero-extend that into %edi */
 577         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 578         call audit_syscall_exit
 579         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 580         jmp sysret_check
 581 #endif  /* CONFIG_AUDITSYSCALL */
 582
 583         /* Do syscall tracing */
 584 tracesys:
 585 #ifdef CONFIG_AUDITSYSCALL
 586         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 587         jz auditsys
 588 #endif
 589         SAVE_REST
 590         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 591         FIXUP_TOP_OF_STACK %rdi
 592         movq %rsp,%rdi
 593         call syscall_trace_enter
 594         /*
 595          * Reload arg registers from stack in case ptrace changed them.
 596          * We don't reload %rax because syscall_trace_enter() returned
 597          * the value it wants us to use in the table lookup.
 598          */
 599         LOAD_ARGS ARGOFFSET, 1
 600         RESTORE_REST
 601         cmpq $__NR_syscall_max,%rax
 602         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 603         movq %r10,%rcx  /* fixup for C */
 604         call *sys_call_table(,%rax,8)
 605         movq %rax,RAX-ARGOFFSET(%rsp)
 606         /* Use IRET because user could have changed frame */
 607
 608 /*
 609  * Syscall return path ending with IRET.
 610  * Has correct top of stack, but partial stack frame.
 611  */
 612 GLOBAL(int_ret_from_sys_call)
 613         DISABLE_INTERRUPTS(CLBR_NONE)
 614         TRACE_IRQS_OFF
 615         movl $_TIF_ALLWORK_MASK,%edi
 616         /* edi: mask to check */
 617 GLOBAL(int_with_check)
 618         LOCKDEP_SYS_EXIT_IRQ
 619         GET_THREAD_INFO(%rcx)
 620         movl TI_flags(%rcx),%edx
 621         andl %edi,%edx
 622         jnz   int_careful
 623         andl    $~TS_COMPAT,TI_status(%rcx)
 624         jmp   retint_swapgs
 625
 626         /* Either reschedule or signal or syscall exit tracking needed. */
 627         /* First do a reschedule test. */
 628         /* edx: work, edi: workmask */
 629 int_careful:
 630         bt $TIF_NEED_RESCHED,%edx
 631         jnc  int_very_careful
 632         TRACE_IRQS_ON
 633         ENABLE_INTERRUPTS(CLBR_NONE)
 634         pushq_cfi %rdi
 635         call schedule
 636         popq_cfi %rdi
 637         DISABLE_INTERRUPTS(CLBR_NONE)
 638         TRACE_IRQS_OFF
 639         jmp int_with_check
 640
 641         /* handle signals and tracing -- both require a full stack frame */
 642 int_very_careful:
 643         TRACE_IRQS_ON
 644         ENABLE_INTERRUPTS(CLBR_NONE)
 645 int_check_syscall_exit_work:
 646         SAVE_REST
 647         /* Check for syscall exit trace */
 648         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 649         jz int_signal
 650         pushq_cfi %rdi
 651         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 652         call syscall_trace_leave
 653         popq_cfi %rdi
 654         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 655         jmp int_restore_rest
 656
 657 int_signal:
 658         testl $_TIF_DO_NOTIFY_MASK,%edx
 659         jz 1f
 660         movq %rsp,%rdi          # &ptregs -> arg1
 661         xorl %esi,%esi          # oldset -> arg2
 662         call do_notify_resume
 663 1:      movl $_TIF_WORK_MASK,%edi
 664 int_restore_rest:
 665         RESTORE_REST
 666         DISABLE_INTERRUPTS(CLBR_NONE)
 667         TRACE_IRQS_OFF
 668         jmp int_with_check
 669         CFI_ENDPROC
 670 END(system_call)
 671
 672 /*
 673  * Certain special system calls that need to save a complete full stack frame.
 674  */
 675         .macro PTREGSCALL label,func,arg
 676 ENTRY(\label)
 677         PARTIAL_FRAME 1 8               /* offset 8: return address */
 678         subq $REST_SKIP, %rsp
 679         CFI_ADJUST_CFA_OFFSET REST_SKIP
 680         call save_rest
 681         DEFAULT_FRAME 0 8               /* offset 8: return address */
 682         leaq 8(%rsp), \arg      /* pt_regs pointer */
 683         call \func
 684         jmp ptregscall_common
 685         CFI_ENDPROC
 686 END(\label)
 687         .endm
 688
 689         PTREGSCALL stub_clone, sys_clone, %r8
 690         PTREGSCALL stub_fork, sys_fork, %rdi
 691         PTREGSCALL stub_vfork, sys_vfork, %rdi
 692         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 693         PTREGSCALL stub_iopl, sys_iopl, %rsi
 694
 695 ENTRY(ptregscall_common)
 696         DEFAULT_FRAME 1 8       /* offset 8: return address */
 697         RESTORE_TOP_OF_STACK %r11, 8
 698         movq_cfi_restore R15+8, r15
 699         movq_cfi_restore R14+8, r14
 700         movq_cfi_restore R13+8, r13
 701         movq_cfi_restore R12+8, r12
 702         movq_cfi_restore RBP+8, rbp
 703         movq_cfi_restore RBX+8, rbx
 704         ret $REST_SKIP          /* pop extended registers */
 705         CFI_ENDPROC
 706 END(ptregscall_common)
 707
 708 ENTRY(stub_execve)
 709         CFI_STARTPROC
 710         addq $8, %rsp
 711         PARTIAL_FRAME 0
 712         SAVE_REST
 713         FIXUP_TOP_OF_STACK %r11
 714         movq %rsp, %rcx
 715         call sys_execve
 716         RESTORE_TOP_OF_STACK %r11
 717         movq %rax,RAX(%rsp)
 718         RESTORE_REST
 719         jmp int_ret_from_sys_call
 720         CFI_ENDPROC
 721 END(stub_execve)
 722
 723 /*
 724  * sigreturn is special because it needs to restore all registers on return.
 725  * This cannot be done with SYSRET, so use the IRET return path instead.
 726  */
 727 ENTRY(stub_rt_sigreturn)
 728         CFI_STARTPROC
 729         addq $8, %rsp
 730         PARTIAL_FRAME 0
 731         SAVE_REST
 732         movq %rsp,%rdi
 733         FIXUP_TOP_OF_STACK %r11
 734         call sys_rt_sigreturn
 735         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 736         RESTORE_REST
 737         jmp int_ret_from_sys_call
 738         CFI_ENDPROC
 739 END(stub_rt_sigreturn)
 740
 741 /*
 742  * Build the entry stubs and pointer table with some assembler magic.
 743  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 744  * single cache line on all modern x86 implementations.
 745  */
 746         .section .init.rodata,"a"
 747 ENTRY(interrupt)
 748         .section .entry.text
 749         .p2align 5
 750         .p2align CONFIG_X86_L1_CACHE_SHIFT
 751 ENTRY(irq_entries_start)
 752         INTR_FRAME
 753 vector=FIRST_EXTERNAL_VECTOR
 754 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 755         .balign 32
 756   .rept 7
 757     .if vector < NR_VECTORS
 758       .if vector <> FIRST_EXTERNAL_VECTOR
 759         CFI_ADJUST_CFA_OFFSET -8
 760       .endif
 761 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 762       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 763         jmp 2f
 764       .endif
 765       .previous
 766         .quad 1b
 767       .section .entry.text
 768 vector=vector+1
 769     .endif
 770   .endr
 771 2:      jmp common_interrupt
 772 .endr
 773         CFI_ENDPROC
 774 END(irq_entries_start)
 775
 776 .previous
 777 END(interrupt)
 778 .previous
 779
 780 /*
 781  * Interrupt entry/exit.
 782  *
 783  * Interrupt entry points save only callee clobbered registers in fast path.
 784  *
 785  * Entry runs with interrupts off.
 786  */
 787
 788 /* 0(%rsp): ~(interrupt number) */
 789         .macro interrupt func
 790         /* reserve pt_regs for scratch regs and rbp */
 791         subq $ORIG_RAX-RBP, %rsp
 792         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 793         SAVE_ARGS_IRQ
 794         call \func
 795         .endm
 796
 797 /*
 798  * Interrupt entry/exit should be protected against kprobes
 799  */
 800         .pushsection .kprobes.text, "ax"
 801         /*
 802          * The interrupt stubs push (~vector+0x80) onto the stack and
 803          * then jump to common_interrupt.
 804          */
 805         .p2align CONFIG_X86_L1_CACHE_SHIFT
 806 common_interrupt:
 807         XCPT_FRAME
 808         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 809         interrupt do_IRQ
 810         /* 0(%rsp): old_rsp-ARGOFFSET */
 811 ret_from_intr:
 812         DISABLE_INTERRUPTS(CLBR_NONE)
 813         TRACE_IRQS_OFF
 814         decl PER_CPU_VAR(irq_count)
 815
 816         /* Restore saved previous stack */
 817         popq %rsi
 818         CFI_DEF_CFA_REGISTER    rsi
 819         leaq ARGOFFSET-RBP(%rsi), %rsp
 820         CFI_DEF_CFA_REGISTER    rsp
 821         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 822
 823 exit_intr:
 824         GET_THREAD_INFO(%rcx)
 825         testl $3,CS-ARGOFFSET(%rsp)
 826         je retint_kernel
 827
 828         /* Interrupt came from user space */
 829         /*
 830          * Has a correct top of stack, but a partial stack frame
 831          * %rcx: thread info. Interrupts off.
 832          */
 833 retint_with_reschedule:
 834         movl $_TIF_WORK_MASK,%edi
 835 retint_check:
 836         LOCKDEP_SYS_EXIT_IRQ
 837         movl TI_flags(%rcx),%edx
 838         andl %edi,%edx
 839         CFI_REMEMBER_STATE
 840         jnz  retint_careful
 841
 842 retint_swapgs:          /* return to user-space */
 843         /*
 844          * The iretq could re-enable interrupts:
 845          */
 846         DISABLE_INTERRUPTS(CLBR_ANY)
 847         TRACE_IRQS_IRETQ
 848         SWAPGS
 849         jmp restore_args
 850
 851 retint_restore_args:    /* return to kernel space */
 852         DISABLE_INTERRUPTS(CLBR_ANY)
 853         /*
 854          * The iretq could re-enable interrupts:
 855          */
 856         TRACE_IRQS_IRETQ
 857 restore_args:
 858         RESTORE_ARGS 1,8,1
 859
 860 irq_return:
 861         INTERRUPT_RETURN
 862
 863         .section __ex_table, "a"
 864         .quad irq_return, bad_iret
 865         .previous
 866
 867 #ifdef CONFIG_PARAVIRT
 868 ENTRY(native_iret)
 869         iretq
 870
 871         .section __ex_table,"a"
 872         .quad native_iret, bad_iret
 873         .previous
 874 #endif
 875
 876         .section .fixup,"ax"
 877 bad_iret:
 878         /*
 879          * The iret traps when the %cs or %ss being restored is bogus.
 880          * We've lost the original trap vector and error code.
 881          * #GPF is the most likely one to get for an invalid selector.
 882          * So pretend we completed the iret and took the #GPF in user mode.
 883          *
 884          * We are now running with the kernel GS after exception recovery.
 885          * But error_entry expects us to have user GS to match the user %cs,
 886          * so swap back.
 887          */
 888         pushq $0
 889
 890         SWAPGS
 891         jmp general_protection
 892
 893         .previous
 894
 895         /* edi: workmask, edx: work */
 896 retint_careful:
 897         CFI_RESTORE_STATE
 898         bt    $TIF_NEED_RESCHED,%edx
 899         jnc   retint_signal
 900         TRACE_IRQS_ON
 901         ENABLE_INTERRUPTS(CLBR_NONE)
 902         pushq_cfi %rdi
 903         call  schedule
 904         popq_cfi %rdi
 905         GET_THREAD_INFO(%rcx)
 906         DISABLE_INTERRUPTS(CLBR_NONE)
 907         TRACE_IRQS_OFF
 908         jmp retint_check
 909
 910 retint_signal:
 911         testl $_TIF_DO_NOTIFY_MASK,%edx
 912         jz    retint_swapgs
 913         TRACE_IRQS_ON
 914         ENABLE_INTERRUPTS(CLBR_NONE)
 915         SAVE_REST
 916         movq $-1,ORIG_RAX(%rsp)
 917         xorl %esi,%esi          # oldset
 918         movq %rsp,%rdi          # &pt_regs
 919         call do_notify_resume
 920         RESTORE_REST
 921         DISABLE_INTERRUPTS(CLBR_NONE)
 922         TRACE_IRQS_OFF
 923         GET_THREAD_INFO(%rcx)
 924         jmp retint_with_reschedule
 925
 926 #ifdef CONFIG_PREEMPT
 927         /* Returning to kernel space. Check if we need preemption */
 928         /* rcx:  threadinfo. interrupts off. */
 929 ENTRY(retint_kernel)
 930         cmpl $0,TI_preempt_count(%rcx)
 931         jnz  retint_restore_args
 932         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 933         jnc  retint_restore_args
 934         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 935         jnc  retint_restore_args
 936         call preempt_schedule_irq
 937         jmp exit_intr
 938 #endif
 939
 940         CFI_ENDPROC
 941 END(common_interrupt)
 942 /*
 943  * End of kprobes section
 944  */
 945        .popsection
 946
 947 /*
 948  * APIC interrupts.
 949  */
 950 .macro apicinterrupt num sym do_sym
 951 ENTRY(\sym)
 952         INTR_FRAME
 953         pushq_cfi $~(\num)
 954 .Lcommon_\sym:
 955         interrupt \do_sym
 956         jmp ret_from_intr
 957         CFI_ENDPROC
 958 END(\sym)
 959 .endm
 960
 961 #ifdef CONFIG_SMP
 962 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 963         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 964 apicinterrupt REBOOT_VECTOR \
 965         reboot_interrupt smp_reboot_interrupt
 966 #endif
 967
 968 #ifdef CONFIG_X86_UV
 969 apicinterrupt UV_BAU_MESSAGE \
 970         uv_bau_message_intr1 uv_bau_message_interrupt
 971 #endif
 972 apicinterrupt LOCAL_TIMER_VECTOR \
 973         apic_timer_interrupt smp_apic_timer_interrupt
 974 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 975         x86_platform_ipi smp_x86_platform_ipi
 976
 977 #ifdef CONFIG_SMP
 978         ALIGN
 979         INTR_FRAME
 980 .irp idx,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
 981         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 982 .if NUM_INVALIDATE_TLB_VECTORS > \idx
 983 ENTRY(invalidate_interrupt\idx)
 984         pushq_cfi $~(INVALIDATE_TLB_VECTOR_START+\idx)
 985         jmp .Lcommon_invalidate_interrupt0
 986         CFI_ADJUST_CFA_OFFSET -8
 987 END(invalidate_interrupt\idx)
 988 .endif
 989 .endr
 990         CFI_ENDPROC
 991 apicinterrupt INVALIDATE_TLB_VECTOR_START, \
 992         invalidate_interrupt0, smp_invalidate_interrupt
 993 #endif
 994
 995 apicinterrupt THRESHOLD_APIC_VECTOR \
 996         threshold_interrupt smp_threshold_interrupt
 997 apicinterrupt THERMAL_APIC_VECTOR \
 998         thermal_interrupt smp_thermal_interrupt
 999
1000 #ifdef CONFIG_SMP
1001 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1002         call_function_single_interrupt smp_call_function_single_interrupt
1003 apicinterrupt CALL_FUNCTION_VECTOR \
1004         call_function_interrupt smp_call_function_interrupt
1005 apicinterrupt RESCHEDULE_VECTOR \
1006         reschedule_interrupt smp_reschedule_interrupt
1007 #endif
1008
1009 apicinterrupt ERROR_APIC_VECTOR \
1010         error_interrupt smp_error_interrupt
1011 apicinterrupt SPURIOUS_APIC_VECTOR \
1012         spurious_interrupt smp_spurious_interrupt
1013
1014 #ifdef CONFIG_IRQ_WORK
1015 apicinterrupt IRQ_WORK_VECTOR \
1016         irq_work_interrupt smp_irq_work_interrupt
1017 #endif
1018
1019 /*
1020  * Exception entry points.
1021  */
1022 .macro zeroentry sym do_sym
1023 ENTRY(\sym)
1024         INTR_FRAME
1025         PARAVIRT_ADJUST_EXCEPTION_FRAME
1026         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1027         subq $ORIG_RAX-R15, %rsp
1028         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1029         call error_entry
1030         DEFAULT_FRAME 0
1031         movq %rsp,%rdi          /* pt_regs pointer */
1032         xorl %esi,%esi          /* no error code */
1033         call \do_sym
1034         jmp error_exit          /* %ebx: no swapgs flag */
1035         CFI_ENDPROC
1036 END(\sym)
1037 .endm
1038
1039 .macro paranoidzeroentry sym do_sym
1040 ENTRY(\sym)
1041         INTR_FRAME
1042         PARAVIRT_ADJUST_EXCEPTION_FRAME
1043         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1044         subq $ORIG_RAX-R15, %rsp
1045         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1046         call save_paranoid
1047         TRACE_IRQS_OFF
1048         movq %rsp,%rdi          /* pt_regs pointer */
1049         xorl %esi,%esi          /* no error code */
1050         call \do_sym
1051         jmp paranoid_exit       /* %ebx: no swapgs flag */
1052         CFI_ENDPROC
1053 END(\sym)
1054 .endm
1055
1056 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1057 .macro paranoidzeroentry_ist sym do_sym ist
1058 ENTRY(\sym)
1059         INTR_FRAME
1060         PARAVIRT_ADJUST_EXCEPTION_FRAME
1061         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1062         subq $ORIG_RAX-R15, %rsp
1063         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1064         call save_paranoid
1065         TRACE_IRQS_OFF
1066         movq %rsp,%rdi          /* pt_regs pointer */
1067         xorl %esi,%esi          /* no error code */
1068         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1069         call \do_sym
1070         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1071         jmp paranoid_exit       /* %ebx: no swapgs flag */
1072         CFI_ENDPROC
1073 END(\sym)
1074 .endm
1075
1076 .macro errorentry sym do_sym
1077 ENTRY(\sym)
1078         XCPT_FRAME
1079         PARAVIRT_ADJUST_EXCEPTION_FRAME
1080         subq $ORIG_RAX-R15, %rsp
1081         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1082         call error_entry
1083         DEFAULT_FRAME 0
1084         movq %rsp,%rdi                  /* pt_regs pointer */
1085         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1086         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1087         call \do_sym
1088         jmp error_exit                  /* %ebx: no swapgs flag */
1089         CFI_ENDPROC
1090 END(\sym)
1091 .endm
1092
1093         /* error code is on the stack already */
1094 .macro paranoiderrorentry sym do_sym
1095 ENTRY(\sym)
1096         XCPT_FRAME
1097         PARAVIRT_ADJUST_EXCEPTION_FRAME
1098         subq $ORIG_RAX-R15, %rsp
1099         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1100         call save_paranoid
1101         DEFAULT_FRAME 0
1102         TRACE_IRQS_OFF
1103         movq %rsp,%rdi                  /* pt_regs pointer */
1104         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1105         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1106         call \do_sym
1107         jmp paranoid_exit               /* %ebx: no swapgs flag */
1108         CFI_ENDPROC
1109 END(\sym)
1110 .endm
1111
1112 zeroentry divide_error do_divide_error
1113 zeroentry overflow do_overflow
1114 zeroentry bounds do_bounds
1115 zeroentry invalid_op do_invalid_op
1116 zeroentry device_not_available do_device_not_available
1117 paranoiderrorentry double_fault do_double_fault
1118 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1119 errorentry invalid_TSS do_invalid_TSS
1120 errorentry segment_not_present do_segment_not_present
1121 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1122 zeroentry coprocessor_error do_coprocessor_error
1123 errorentry alignment_check do_alignment_check
1124 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1125
1126
1127         /* Reload gs selector with exception handling */
1128         /* edi:  new selector */
1129 ENTRY(native_load_gs_index)
1130         CFI_STARTPROC
1131         pushfq_cfi
1132         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1133         SWAPGS
1134 gs_change:
1135         movl %edi,%gs
1136 2:      mfence          /* workaround */
1137         SWAPGS
1138         popfq_cfi
1139         ret
1140         CFI_ENDPROC
1141 END(native_load_gs_index)
1142
1143         .section __ex_table,"a"
1144         .align 8
1145         .quad gs_change,bad_gs
1146         .previous
1147         .section .fixup,"ax"
1148         /* running with kernelgs */
1149 bad_gs:
1150         SWAPGS                  /* switch back to user gs */
1151         xorl %eax,%eax
1152         movl %eax,%gs
1153         jmp  2b
1154         .previous
1155
1156 ENTRY(kernel_thread_helper)
1157         pushq $0                # fake return address
1158         CFI_STARTPROC
1159         /*
1160          * Here we are in the child and the registers are set as they were
1161          * at kernel_thread() invocation in the parent.
1162          */
1163         call *%rsi
1164         # exit
1165         mov %eax, %edi
1166         call do_exit
1167         ud2                     # padding for call trace
1168         CFI_ENDPROC
1169 END(kernel_thread_helper)
1170
1171 /*
1172  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1173  *
1174  * C extern interface:
1175  *       extern long execve(const char *name, char **argv, char **envp)
1176  *
1177  * asm input arguments:
1178  *      rdi: name, rsi: argv, rdx: envp
1179  *
1180  * We want to fallback into:
1181  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1182  *
1183  * do_sys_execve asm fallback arguments:
1184  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1185  */
1186 ENTRY(kernel_execve)
1187         CFI_STARTPROC
1188         FAKE_STACK_FRAME $0
1189         SAVE_ALL
1190         movq %rsp,%rcx
1191         call sys_execve
1192         movq %rax, RAX(%rsp)
1193         RESTORE_REST
1194         testq %rax,%rax
1195         je int_ret_from_sys_call
1196         RESTORE_ARGS
1197         UNFAKE_STACK_FRAME
1198         ret
1199         CFI_ENDPROC
1200 END(kernel_execve)
1201
1202 /* Call softirq on interrupt stack. Interrupts are off. */
1203 ENTRY(call_softirq)
1204         CFI_STARTPROC
1205         pushq_cfi %rbp
1206         CFI_REL_OFFSET rbp,0
1207         mov  %rsp,%rbp
1208         CFI_DEF_CFA_REGISTER rbp
1209         incl PER_CPU_VAR(irq_count)
1210         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1211         push  %rbp                      # backlink for old unwinder
1212         call __do_softirq
1213         leaveq
1214         CFI_RESTORE             rbp
1215         CFI_DEF_CFA_REGISTER    rsp
1216         CFI_ADJUST_CFA_OFFSET   -8
1217         decl PER_CPU_VAR(irq_count)
1218         ret
1219         CFI_ENDPROC
1220 END(call_softirq)
1221
1222 #ifdef CONFIG_XEN
1223 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1224
1225 /*
1226  * A note on the "critical region" in our callback handler.
1227  * We want to avoid stacking callback handlers due to events occurring
1228  * during handling of the last event. To do this, we keep events disabled
1229  * until we've done all processing. HOWEVER, we must enable events before
1230  * popping the stack frame (can't be done atomically) and so it would still
1231  * be possible to get enough handler activations to overflow the stack.
1232  * Although unlikely, bugs of that kind are hard to track down, so we'd
1233  * like to avoid the possibility.
1234  * So, on entry to the handler we detect whether we interrupted an
1235  * existing activation in its critical region -- if so, we pop the current
1236  * activation and restart the handler using the previous one.
1237  */
1238 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1239         CFI_STARTPROC
1240 /*
1241  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1242  * see the correct pointer to the pt_regs
1243  */
1244         movq %rdi, %rsp            # we don't return, adjust the stack frame
1245         CFI_ENDPROC
1246         DEFAULT_FRAME
1247 11:     incl PER_CPU_VAR(irq_count)
1248         movq %rsp,%rbp
1249         CFI_DEF_CFA_REGISTER rbp
1250         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1251         pushq %rbp                      # backlink for old unwinder
1252         call xen_evtchn_do_upcall
1253         popq %rsp
1254         CFI_DEF_CFA_REGISTER rsp
1255         decl PER_CPU_VAR(irq_count)
1256         jmp  error_exit
1257         CFI_ENDPROC
1258 END(xen_do_hypervisor_callback)
1259
1260 /*
1261  * Hypervisor uses this for application faults while it executes.
1262  * We get here for two reasons:
1263  *  1. Fault while reloading DS, ES, FS or GS
1264  *  2. Fault while executing IRET
1265  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1266  * registers that could be reloaded and zeroed the others.
1267  * Category 2 we fix up by killing the current process. We cannot use the
1268  * normal Linux return path in this case because if we use the IRET hypercall
1269  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1270  * We distinguish between categories by comparing each saved segment register
1271  * with its current contents: any discrepancy means we in category 1.
1272  */
1273 ENTRY(xen_failsafe_callback)
1274         INTR_FRAME 1 (6*8)
1275         /*CFI_REL_OFFSET gs,GS*/
1276         /*CFI_REL_OFFSET fs,FS*/
1277         /*CFI_REL_OFFSET es,ES*/
1278         /*CFI_REL_OFFSET ds,DS*/
1279         CFI_REL_OFFSET r11,8
1280         CFI_REL_OFFSET rcx,0
1281         movw %ds,%cx
1282         cmpw %cx,0x10(%rsp)
1283         CFI_REMEMBER_STATE
1284         jne 1f
1285         movw %es,%cx
1286         cmpw %cx,0x18(%rsp)
1287         jne 1f
1288         movw %fs,%cx
1289         cmpw %cx,0x20(%rsp)
1290         jne 1f
1291         movw %gs,%cx
1292         cmpw %cx,0x28(%rsp)
1293         jne 1f
1294         /* All segments match their saved values => Category 2 (Bad IRET). */
1295         movq (%rsp),%rcx
1296         CFI_RESTORE rcx
1297         movq 8(%rsp),%r11
1298         CFI_RESTORE r11
1299         addq $0x30,%rsp
1300         CFI_ADJUST_CFA_OFFSET -0x30
1301         pushq_cfi $0    /* RIP */
1302         pushq_cfi %r11
1303         pushq_cfi %rcx
1304         jmp general_protection
1305         CFI_RESTORE_STATE
1306 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1307         movq (%rsp),%rcx
1308         CFI_RESTORE rcx
1309         movq 8(%rsp),%r11
1310         CFI_RESTORE r11
1311         addq $0x30,%rsp
1312         CFI_ADJUST_CFA_OFFSET -0x30
1313         pushq_cfi $0
1314         SAVE_ALL
1315         jmp error_exit
1316         CFI_ENDPROC
1317 END(xen_failsafe_callback)
1318
1319 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1320         xen_hvm_callback_vector xen_evtchn_do_upcall
1321
1322 #endif /* CONFIG_XEN */
1323
1324 /*
1325  * Some functions should be protected against kprobes
1326  */
1327         .pushsection .kprobes.text, "ax"
1328
1329 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1330 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1331 paranoiderrorentry stack_segment do_stack_segment
1332 #ifdef CONFIG_XEN
1333 zeroentry xen_debug do_debug
1334 zeroentry xen_int3 do_int3
1335 errorentry xen_stack_segment do_stack_segment
1336 #endif
1337 errorentry general_protection do_general_protection
1338 errorentry page_fault do_page_fault
1339 #ifdef CONFIG_KVM_GUEST
1340 errorentry async_page_fault do_async_page_fault
1341 #endif
1342 #ifdef CONFIG_X86_MCE
1343 paranoidzeroentry machine_check *machine_check_vector(%rip)
1344 #endif
1345
1346         /*
1347          * "Paranoid" exit path from exception stack.
1348          * Paranoid because this is used by NMIs and cannot take
1349          * any kernel state for granted.
1350          * We don't do kernel preemption checks here, because only
1351          * NMI should be common and it does not enable IRQs and
1352          * cannot get reschedule ticks.
1353          *
1354          * "trace" is 0 for the NMI handler only, because irq-tracing
1355          * is fundamentally NMI-unsafe. (we cannot change the soft and
1356          * hard flags at once, atomically)
1357          */
1358
1359         /* ebx: no swapgs flag */
1360 ENTRY(paranoid_exit)
1361         DEFAULT_FRAME
1362         DISABLE_INTERRUPTS(CLBR_NONE)
1363         TRACE_IRQS_OFF
1364         testl %ebx,%ebx                         /* swapgs needed? */
1365         jnz paranoid_restore
1366         testl $3,CS(%rsp)
1367         jnz   paranoid_userspace
1368 paranoid_swapgs:
1369         TRACE_IRQS_IRETQ 0
1370         SWAPGS_UNSAFE_STACK
1371         RESTORE_ALL 8
1372         jmp irq_return
1373 paranoid_restore:
1374         TRACE_IRQS_IRETQ 0
1375         RESTORE_ALL 8
1376         jmp irq_return
1377 paranoid_userspace:
1378         GET_THREAD_INFO(%rcx)
1379         movl TI_flags(%rcx),%ebx
1380         andl $_TIF_WORK_MASK,%ebx
1381         jz paranoid_swapgs
1382         movq %rsp,%rdi                  /* &pt_regs */
1383         call sync_regs
1384         movq %rax,%rsp                  /* switch stack for scheduling */
1385         testl $_TIF_NEED_RESCHED,%ebx
1386         jnz paranoid_schedule
1387         movl %ebx,%edx                  /* arg3: thread flags */
1388         TRACE_IRQS_ON
1389         ENABLE_INTERRUPTS(CLBR_NONE)
1390         xorl %esi,%esi                  /* arg2: oldset */
1391         movq %rsp,%rdi                  /* arg1: &pt_regs */
1392         call do_notify_resume
1393         DISABLE_INTERRUPTS(CLBR_NONE)
1394         TRACE_IRQS_OFF
1395         jmp paranoid_userspace
1396 paranoid_schedule:
1397         TRACE_IRQS_ON
1398         ENABLE_INTERRUPTS(CLBR_ANY)
1399         call schedule
1400         DISABLE_INTERRUPTS(CLBR_ANY)
1401         TRACE_IRQS_OFF
1402         jmp paranoid_userspace
1403         CFI_ENDPROC
1404 END(paranoid_exit)
1405
1406 /*
1407  * Exception entry point. This expects an error code/orig_rax on the stack.
1408  * returns in "no swapgs flag" in %ebx.
1409  */
1410 ENTRY(error_entry)
1411         XCPT_FRAME
1412         CFI_ADJUST_CFA_OFFSET 15*8
1413         /* oldrax contains error code */
1414         cld
1415         movq_cfi rdi, RDI+8
1416         movq_cfi rsi, RSI+8
1417         movq_cfi rdx, RDX+8
1418         movq_cfi rcx, RCX+8
1419         movq_cfi rax, RAX+8
1420         movq_cfi  r8,  R8+8
1421         movq_cfi  r9,  R9+8
1422         movq_cfi r10, R10+8
1423         movq_cfi r11, R11+8
1424         movq_cfi rbx, RBX+8
1425         movq_cfi rbp, RBP+8
1426         movq_cfi r12, R12+8
1427         movq_cfi r13, R13+8
1428         movq_cfi r14, R14+8
1429         movq_cfi r15, R15+8
1430         xorl %ebx,%ebx
1431         testl $3,CS+8(%rsp)
1432         je error_kernelspace
1433 error_swapgs:
1434         SWAPGS
1435 error_sti:
1436         TRACE_IRQS_OFF
1437         ret
1438
1439 /*
1440  * There are two places in the kernel that can potentially fault with
1441  * usergs. Handle them here. The exception handlers after iret run with
1442  * kernel gs again, so don't set the user space flag. B stepping K8s
1443  * sometimes report an truncated RIP for IRET exceptions returning to
1444  * compat mode. Check for these here too.
1445  */
1446 error_kernelspace:
1447         incl %ebx
1448         leaq irq_return(%rip),%rcx
1449         cmpq %rcx,RIP+8(%rsp)
1450         je error_swapgs
1451         movl %ecx,%eax  /* zero extend */
1452         cmpq %rax,RIP+8(%rsp)
1453         je bstep_iret
1454         cmpq $gs_change,RIP+8(%rsp)
1455         je error_swapgs
1456         jmp error_sti
1457
1458 bstep_iret:
1459         /* Fix truncated RIP */
1460         movq %rcx,RIP+8(%rsp)
1461         jmp error_swapgs
1462         CFI_ENDPROC
1463 END(error_entry)
1464
1465
1466 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1467 ENTRY(error_exit)
1468         DEFAULT_FRAME
1469         movl %ebx,%eax
1470         RESTORE_REST
1471         DISABLE_INTERRUPTS(CLBR_NONE)
1472         TRACE_IRQS_OFF
1473         GET_THREAD_INFO(%rcx)
1474         testl %eax,%eax
1475         jne retint_kernel
1476         LOCKDEP_SYS_EXIT_IRQ
1477         movl TI_flags(%rcx),%edx
1478         movl $_TIF_WORK_MASK,%edi
1479         andl %edi,%edx
1480         jnz retint_careful
1481         jmp retint_swapgs
1482         CFI_ENDPROC
1483 END(error_exit)
1484
1485
1486         /* runs on exception stack */
1487 ENTRY(nmi)
1488         INTR_FRAME
1489         PARAVIRT_ADJUST_EXCEPTION_FRAME
1490         pushq_cfi $-1
1491         subq $ORIG_RAX-R15, %rsp
1492         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1493         call save_paranoid
1494         DEFAULT_FRAME 0
1495         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1496         movq %rsp,%rdi
1497         movq $-1,%rsi
1498         call do_nmi
1499 #ifdef CONFIG_TRACE_IRQFLAGS
1500         /* paranoidexit; without TRACE_IRQS_OFF */
1501         /* ebx: no swapgs flag */
1502         DISABLE_INTERRUPTS(CLBR_NONE)
1503         testl %ebx,%ebx                         /* swapgs needed? */
1504         jnz nmi_restore
1505         testl $3,CS(%rsp)
1506         jnz nmi_userspace
1507 nmi_swapgs:
1508         SWAPGS_UNSAFE_STACK
1509 nmi_restore:
1510         RESTORE_ALL 8
1511         jmp irq_return
1512 nmi_userspace:
1513         GET_THREAD_INFO(%rcx)
1514         movl TI_flags(%rcx),%ebx
1515         andl $_TIF_WORK_MASK,%ebx
1516         jz nmi_swapgs
1517         movq %rsp,%rdi                  /* &pt_regs */
1518         call sync_regs
1519         movq %rax,%rsp                  /* switch stack for scheduling */
1520         testl $_TIF_NEED_RESCHED,%ebx
1521         jnz nmi_schedule
1522         movl %ebx,%edx                  /* arg3: thread flags */
1523         ENABLE_INTERRUPTS(CLBR_NONE)
1524         xorl %esi,%esi                  /* arg2: oldset */
1525         movq %rsp,%rdi                  /* arg1: &pt_regs */
1526         call do_notify_resume
1527         DISABLE_INTERRUPTS(CLBR_NONE)
1528         jmp nmi_userspace
1529 nmi_schedule:
1530         ENABLE_INTERRUPTS(CLBR_ANY)
1531         call schedule
1532         DISABLE_INTERRUPTS(CLBR_ANY)
1533         jmp nmi_userspace
1534         CFI_ENDPROC
1535 #else
1536         jmp paranoid_exit
1537         CFI_ENDPROC
1538 #endif
1539 END(nmi)
1540
1541 ENTRY(ignore_sysret)
1542         CFI_STARTPROC
1543         mov $-ENOSYS,%eax
1544         sysret
1545         CFI_ENDPROC
1546 END(ignore_sysret)
1547
1548 /*
1549  * End of kprobes section
1550  */
1551         .popsection