arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <linux/err.h>
  46 #include <asm/thread_info.h>
  47 #include <asm/irqflags.h>
  48 #include <asm/errno.h>
  49 #include <asm/segment.h>
  50 #include <asm/smp.h>
  51 #include <asm/page_types.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57 #include <asm/cpufeature.h>
  58 #include <asm/alternative-asm.h>
  59 #include <asm/asm.h>
  60 #include <asm/smap.h>
  61
  62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  63 #include <linux/elf-em.h>
  64 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67 #ifndef CONFIG_AUDITSYSCALL
  68 #define sysenter_audit  syscall_trace_entry
  69 #define sysexit_audit   syscall_exit_work
  70 #endif
  71
  72         .section .entry.text, "ax"
  73
  74 /*
  75  * We use macros for low-level operations which need to be overridden
  76  * for paravirtualization.  The following will never clobber any registers:
  77  *   INTERRUPT_RETURN (aka. "iret")
  78  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  79  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  80  *
  81  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  82  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  83  * Allowing a register to be clobbered can shrink the paravirt replacement
  84  * enough to patch inline, increasing performance.
  85  */
  86
  87 #ifdef CONFIG_PREEMPT
  88 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  89 #else
  90 #define preempt_stop(clobbers)
  91 #define resume_kernel           restore_all
  92 #endif
  93
  94 .macro TRACE_IRQS_IRET
  95 #ifdef CONFIG_TRACE_IRQFLAGS
  96         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  97         jz 1f
  98         TRACE_IRQS_ON
  99 1:
 100 #endif
 101 .endm
 102
 103 /*
 104  * User gs save/restore
 105  *
 106  * %gs is used for userland TLS and kernel only uses it for stack
 107  * canary which is required to be at %gs:20 by gcc.  Read the comment
 108  * at the top of stackprotector.h for more info.
 109  *
 110  * Local labels 98 and 99 are used.
 111  */
 112 #ifdef CONFIG_X86_32_LAZY_GS
 113
 114  /* unfortunately push/pop can't be no-op */
 115 .macro PUSH_GS
 116         pushl_cfi $0
 117 .endm
 118 .macro POP_GS pop=0
 119         addl $(4 + \pop), %esp
 120         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 121 .endm
 122 .macro POP_GS_EX
 123 .endm
 124
 125  /* all the rest are no-op */
 126 .macro PTGS_TO_GS
 127 .endm
 128 .macro PTGS_TO_GS_EX
 129 .endm
 130 .macro GS_TO_REG reg
 131 .endm
 132 .macro REG_TO_PTGS reg
 133 .endm
 134 .macro SET_KERNEL_GS reg
 135 .endm
 136
 137 #else   /* CONFIG_X86_32_LAZY_GS */
 138
 139 .macro PUSH_GS
 140         pushl_cfi %gs
 141         /*CFI_REL_OFFSET gs, 0*/
 142 .endm
 143
 144 .macro POP_GS pop=0
 145 98:     popl_cfi %gs
 146         /*CFI_RESTORE gs*/
 147   .if \pop <> 0
 148         add $\pop, %esp
 149         CFI_ADJUST_CFA_OFFSET -\pop
 150   .endif
 151 .endm
 152 .macro POP_GS_EX
 153 .pushsection .fixup, "ax"
 154 99:     movl $0, (%esp)
 155         jmp 98b
 156 .popsection
 157         _ASM_EXTABLE(98b,99b)
 158 .endm
 159
 160 .macro PTGS_TO_GS
 161 98:     mov PT_GS(%esp), %gs
 162 .endm
 163 .macro PTGS_TO_GS_EX
 164 .pushsection .fixup, "ax"
 165 99:     movl $0, PT_GS(%esp)
 166         jmp 98b
 167 .popsection
 168         _ASM_EXTABLE(98b,99b)
 169 .endm
 170
 171 .macro GS_TO_REG reg
 172         movl %gs, \reg
 173         /*CFI_REGISTER gs, \reg*/
 174 .endm
 175 .macro REG_TO_PTGS reg
 176         movl \reg, PT_GS(%esp)
 177         /*CFI_REL_OFFSET gs, PT_GS*/
 178 .endm
 179 .macro SET_KERNEL_GS reg
 180         movl $(__KERNEL_STACK_CANARY), \reg
 181         movl \reg, %gs
 182 .endm
 183
 184 #endif  /* CONFIG_X86_32_LAZY_GS */
 185
 186 .macro SAVE_ALL
 187         cld
 188         PUSH_GS
 189         pushl_cfi %fs
 190         /*CFI_REL_OFFSET fs, 0;*/
 191         pushl_cfi %es
 192         /*CFI_REL_OFFSET es, 0;*/
 193         pushl_cfi %ds
 194         /*CFI_REL_OFFSET ds, 0;*/
 195         pushl_cfi %eax
 196         CFI_REL_OFFSET eax, 0
 197         pushl_cfi %ebp
 198         CFI_REL_OFFSET ebp, 0
 199         pushl_cfi %edi
 200         CFI_REL_OFFSET edi, 0
 201         pushl_cfi %esi
 202         CFI_REL_OFFSET esi, 0
 203         pushl_cfi %edx
 204         CFI_REL_OFFSET edx, 0
 205         pushl_cfi %ecx
 206         CFI_REL_OFFSET ecx, 0
 207         pushl_cfi %ebx
 208         CFI_REL_OFFSET ebx, 0
 209         movl $(__USER_DS), %edx
 210         movl %edx, %ds
 211         movl %edx, %es
 212         movl $(__KERNEL_PERCPU), %edx
 213         movl %edx, %fs
 214         SET_KERNEL_GS %edx
 215 .endm
 216
 217 .macro RESTORE_INT_REGS
 218         popl_cfi %ebx
 219         CFI_RESTORE ebx
 220         popl_cfi %ecx
 221         CFI_RESTORE ecx
 222         popl_cfi %edx
 223         CFI_RESTORE edx
 224         popl_cfi %esi
 225         CFI_RESTORE esi
 226         popl_cfi %edi
 227         CFI_RESTORE edi
 228         popl_cfi %ebp
 229         CFI_RESTORE ebp
 230         popl_cfi %eax
 231         CFI_RESTORE eax
 232 .endm
 233
 234 .macro RESTORE_REGS pop=0
 235         RESTORE_INT_REGS
 236 1:      popl_cfi %ds
 237         /*CFI_RESTORE ds;*/
 238 2:      popl_cfi %es
 239         /*CFI_RESTORE es;*/
 240 3:      popl_cfi %fs
 241         /*CFI_RESTORE fs;*/
 242         POP_GS \pop
 243 .pushsection .fixup, "ax"
 244 4:      movl $0, (%esp)
 245         jmp 1b
 246 5:      movl $0, (%esp)
 247         jmp 2b
 248 6:      movl $0, (%esp)
 249         jmp 3b
 250 .popsection
 251         _ASM_EXTABLE(1b,4b)
 252         _ASM_EXTABLE(2b,5b)
 253         _ASM_EXTABLE(3b,6b)
 254         POP_GS_EX
 255 .endm
 256
 257 .macro RING0_INT_FRAME
 258         CFI_STARTPROC simple
 259         CFI_SIGNAL_FRAME
 260         CFI_DEF_CFA esp, 3*4
 261         /*CFI_OFFSET cs, -2*4;*/
 262         CFI_OFFSET eip, -3*4
 263 .endm
 264
 265 .macro RING0_EC_FRAME
 266         CFI_STARTPROC simple
 267         CFI_SIGNAL_FRAME
 268         CFI_DEF_CFA esp, 4*4
 269         /*CFI_OFFSET cs, -2*4;*/
 270         CFI_OFFSET eip, -3*4
 271 .endm
 272
 273 .macro RING0_PTREGS_FRAME
 274         CFI_STARTPROC simple
 275         CFI_SIGNAL_FRAME
 276         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 277         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 278         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 279         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 280         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 281         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 282         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 283         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 284         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 285         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 286         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 287         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 288 .endm
 289
 290 ENTRY(ret_from_fork)
 291         CFI_STARTPROC
 292         pushl_cfi %eax
 293         call schedule_tail
 294         GET_THREAD_INFO(%ebp)
 295         popl_cfi %eax
 296         pushl_cfi $0x0202               # Reset kernel eflags
 297         popfl_cfi
 298         jmp syscall_exit
 299         CFI_ENDPROC
 300 END(ret_from_fork)
 301
 302 ENTRY(ret_from_kernel_thread)
 303         CFI_STARTPROC
 304         pushl_cfi %eax
 305         call schedule_tail
 306         GET_THREAD_INFO(%ebp)
 307         popl_cfi %eax
 308         pushl_cfi $0x0202               # Reset kernel eflags
 309         popfl_cfi
 310         movl PT_EBP(%esp),%eax
 311         call *PT_EBX(%esp)
 312         movl $0,PT_EAX(%esp)
 313         jmp syscall_exit
 314         CFI_ENDPROC
 315 ENDPROC(ret_from_kernel_thread)
 316
 317 /*
 318  * Interrupt exit functions should be protected against kprobes
 319  */
 320         .pushsection .kprobes.text, "ax"
 321 /*
 322  * Return to user mode is not as complex as all this looks,
 323  * but we want the default path for a system call return to
 324  * go as quickly as possible which is why some of this is
 325  * less clear than it otherwise should be.
 326  */
 327
 328         # userspace resumption stub bypassing syscall exit tracing
 329         ALIGN
 330         RING0_PTREGS_FRAME
 331 ret_from_exception:
 332         preempt_stop(CLBR_ANY)
 333 ret_from_intr:
 334         GET_THREAD_INFO(%ebp)
 335 #ifdef CONFIG_VM86
 336         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 337         movb PT_CS(%esp), %al
 338         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 339 #else
 340         /*
 341          * We can be coming here from child spawned by kernel_thread().
 342          */
 343         movl PT_CS(%esp), %eax
 344         andl $SEGMENT_RPL_MASK, %eax
 345 #endif
 346         cmpl $USER_RPL, %eax
 347         jb resume_kernel                # not returning to v8086 or userspace
 348
 349 ENTRY(resume_userspace)
 350         LOCKDEP_SYS_EXIT
 351         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 352                                         # setting need_resched or sigpending
 353                                         # between sampling and the iret
 354         TRACE_IRQS_OFF
 355         movl TI_flags(%ebp), %ecx
 356         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 357                                         # int/exception return?
 358         jne work_pending
 359         jmp restore_all
 360 END(ret_from_exception)
 361
 362 #ifdef CONFIG_PREEMPT
 363 ENTRY(resume_kernel)
 364         DISABLE_INTERRUPTS(CLBR_ANY)
 365 need_resched:
 366         cmpl $0,PER_CPU_VAR(__preempt_count)
 367         jnz restore_all
 368         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 369         jz restore_all
 370         call preempt_schedule_irq
 371         jmp need_resched
 372 END(resume_kernel)
 373 #endif
 374         CFI_ENDPROC
 375 /*
 376  * End of kprobes section
 377  */
 378         .popsection
 379
 380 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 381    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 382
 383         # sysenter call handler stub
 384 ENTRY(ia32_sysenter_target)
 385         CFI_STARTPROC simple
 386         CFI_SIGNAL_FRAME
 387         CFI_DEF_CFA esp, 0
 388         CFI_REGISTER esp, ebp
 389         movl TSS_sysenter_sp0(%esp),%esp
 390 sysenter_past_esp:
 391         /*
 392          * Interrupts are disabled here, but we can't trace it until
 393          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 394          * we immediately enable interrupts at that point anyway.
 395          */
 396         pushl_cfi $__USER_DS
 397         /*CFI_REL_OFFSET ss, 0*/
 398         pushl_cfi %ebp
 399         CFI_REL_OFFSET esp, 0
 400         pushfl_cfi
 401         orl $X86_EFLAGS_IF, (%esp)
 402         pushl_cfi $__USER_CS
 403         /*CFI_REL_OFFSET cs, 0*/
 404         /*
 405          * Push current_thread_info()->sysenter_return to the stack.
 406          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 407          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 408          */
 409         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 410         CFI_REL_OFFSET eip, 0
 411
 412         pushl_cfi %eax
 413         SAVE_ALL
 414         ENABLE_INTERRUPTS(CLBR_NONE)
 415
 416 /*
 417  * Load the potential sixth argument from user stack.
 418  * Careful about security.
 419  */
 420         cmpl $__PAGE_OFFSET-3,%ebp
 421         jae syscall_fault
 422         ASM_STAC
 423 1:      movl (%ebp),%ebp
 424         ASM_CLAC
 425         movl %ebp,PT_EBP(%esp)
 426         _ASM_EXTABLE(1b,syscall_fault)
 427
 428         GET_THREAD_INFO(%ebp)
 429
 430         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 431         jnz sysenter_audit
 432 sysenter_do_call:
 433         cmpl $(NR_syscalls), %eax
 434         jae sysenter_badsys
 435         call *sys_call_table(,%eax,4)
 436 sysenter_after_call:
 437         movl %eax,PT_EAX(%esp)
 438         LOCKDEP_SYS_EXIT
 439         DISABLE_INTERRUPTS(CLBR_ANY)
 440         TRACE_IRQS_OFF
 441         movl TI_flags(%ebp), %ecx
 442         testl $_TIF_ALLWORK_MASK, %ecx
 443         jne sysexit_audit
 444 sysenter_exit:
 445 /* if something modifies registers it must also disable sysexit */
 446         movl PT_EIP(%esp), %edx
 447         movl PT_OLDESP(%esp), %ecx
 448         xorl %ebp,%ebp
 449         TRACE_IRQS_ON
 450 1:      mov  PT_FS(%esp), %fs
 451         PTGS_TO_GS
 452         ENABLE_INTERRUPTS_SYSEXIT
 453
 454 #ifdef CONFIG_AUDITSYSCALL
 455 sysenter_audit:
 456         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 457         jnz syscall_trace_entry
 458         addl $4,%esp
 459         CFI_ADJUST_CFA_OFFSET -4
 460         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 461         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 462         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 463         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 464         movl %eax,%edx                  /* 2nd arg: syscall number */
 465         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 466         call __audit_syscall_entry
 467         pushl_cfi %ebx
 468         movl PT_EAX(%esp),%eax          /* reload syscall number */
 469         jmp sysenter_do_call
 470
 471 sysexit_audit:
 472         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 473         jne syscall_exit_work
 474         TRACE_IRQS_ON
 475         ENABLE_INTERRUPTS(CLBR_ANY)
 476         movl %eax,%edx          /* second arg, syscall return value */
 477         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 478         setbe %al               /* 1 if so, 0 if not */
 479         movzbl %al,%eax         /* zero-extend that */
 480         call __audit_syscall_exit
 481         DISABLE_INTERRUPTS(CLBR_ANY)
 482         TRACE_IRQS_OFF
 483         movl TI_flags(%ebp), %ecx
 484         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 485         jne syscall_exit_work
 486         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 487         jmp sysenter_exit
 488 #endif
 489
 490         CFI_ENDPROC
 491 .pushsection .fixup,"ax"
 492 2:      movl $0,PT_FS(%esp)
 493         jmp 1b
 494 .popsection
 495         _ASM_EXTABLE(1b,2b)
 496         PTGS_TO_GS_EX
 497 ENDPROC(ia32_sysenter_target)
 498
 499 /*
 500  * syscall stub including irq exit should be protected against kprobes
 501  */
 502         .pushsection .kprobes.text, "ax"
 503         # system call handler stub
 504 ENTRY(system_call)
 505         RING0_INT_FRAME                 # can't unwind into user space anyway
 506         ASM_CLAC
 507         pushl_cfi %eax                  # save orig_eax
 508         SAVE_ALL
 509         GET_THREAD_INFO(%ebp)
 510                                         # system call tracing in operation / emulation
 511         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 512         jnz syscall_trace_entry
 513         cmpl $(NR_syscalls), %eax
 514         jae syscall_badsys
 515 syscall_call:
 516         call *sys_call_table(,%eax,4)
 517 syscall_after_call:
 518         movl %eax,PT_EAX(%esp)          # store the return value
 519 syscall_exit:
 520         LOCKDEP_SYS_EXIT
 521         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 522                                         # setting need_resched or sigpending
 523                                         # between sampling and the iret
 524         TRACE_IRQS_OFF
 525         movl TI_flags(%ebp), %ecx
 526         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 527         jne syscall_exit_work
 528
 529 restore_all:
 530         TRACE_IRQS_IRET
 531 restore_all_notrace:
 532         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 533         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 534         # are returning to the kernel.
 535         # See comments in process.c:copy_thread() for details.
 536         movb PT_OLDSS(%esp), %ah
 537         movb PT_CS(%esp), %al
 538         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 539         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 540         CFI_REMEMBER_STATE
 541         je ldt_ss                       # returning to user-space with LDT SS
 542 restore_nocheck:
 543         RESTORE_REGS 4                  # skip orig_eax/error_code
 544 irq_return:
 545         INTERRUPT_RETURN
 546 .section .fixup,"ax"
 547 ENTRY(iret_exc)
 548         pushl $0                        # no error code
 549         pushl $do_iret_error
 550         jmp error_code
 551 .previous
 552         _ASM_EXTABLE(irq_return,iret_exc)
 553
 554         CFI_RESTORE_STATE
 555 ldt_ss:
 556 #ifdef CONFIG_PARAVIRT
 557         /*
 558          * The kernel can't run on a non-flat stack if paravirt mode
 559          * is active.  Rather than try to fixup the high bits of
 560          * ESP, bypass this code entirely.  This may break DOSemu
 561          * and/or Wine support in a paravirt VM, although the option
 562          * is still available to implement the setting of the high
 563          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 564          */
 565         cmpl $0, pv_info+PARAVIRT_enabled
 566         jne restore_nocheck
 567 #endif
 568
 569 /*
 570  * Setup and switch to ESPFIX stack
 571  *
 572  * We're returning to userspace with a 16 bit stack. The CPU will not
 573  * restore the high word of ESP for us on executing iret... This is an
 574  * "official" bug of all the x86-compatible CPUs, which we can work
 575  * around to make dosemu and wine happy. We do this by preloading the
 576  * high word of ESP with the high word of the userspace ESP while
 577  * compensating for the offset by changing to the ESPFIX segment with
 578  * a base address that matches for the difference.
 579  */
 580 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 581         mov %esp, %edx                  /* load kernel esp */
 582         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 583         mov %dx, %ax                    /* eax: new kernel esp */
 584         sub %eax, %edx                  /* offset (low word is 0) */
 585         shr $16, %edx
 586         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 587         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 588         pushl_cfi $__ESPFIX_SS
 589         pushl_cfi %eax                  /* new kernel esp */
 590         /* Disable interrupts, but do not irqtrace this section: we
 591          * will soon execute iret and the tracer was already set to
 592          * the irqstate after the iret */
 593         DISABLE_INTERRUPTS(CLBR_EAX)
 594         lss (%esp), %esp                /* switch to espfix segment */
 595         CFI_ADJUST_CFA_OFFSET -8
 596         jmp restore_nocheck
 597         CFI_ENDPROC
 598 ENDPROC(system_call)
 599
 600         # perform work that needs to be done immediately before resumption
 601         ALIGN
 602         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 603 work_pending:
 604         testb $_TIF_NEED_RESCHED, %cl
 605         jz work_notifysig
 606 work_resched:
 607         call schedule
 608         LOCKDEP_SYS_EXIT
 609         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 610                                         # setting need_resched or sigpending
 611                                         # between sampling and the iret
 612         TRACE_IRQS_OFF
 613         movl TI_flags(%ebp), %ecx
 614         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 615                                         # than syscall tracing?
 616         jz restore_all
 617         testb $_TIF_NEED_RESCHED, %cl
 618         jnz work_resched
 619
 620 work_notifysig:                         # deal with pending signals and
 621                                         # notify-resume requests
 622 #ifdef CONFIG_VM86
 623         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 624         movl %esp, %eax
 625         jne work_notifysig_v86          # returning to kernel-space or
 626                                         # vm86-space
 627 1:
 628 #else
 629         movl %esp, %eax
 630 #endif
 631         TRACE_IRQS_ON
 632         ENABLE_INTERRUPTS(CLBR_NONE)
 633         movb PT_CS(%esp), %bl
 634         andb $SEGMENT_RPL_MASK, %bl
 635         cmpb $USER_RPL, %bl
 636         jb resume_kernel
 637         xorl %edx, %edx
 638         call do_notify_resume
 639         jmp resume_userspace
 640
 641 #ifdef CONFIG_VM86
 642         ALIGN
 643 work_notifysig_v86:
 644         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 645         call save_v86_state             # %eax contains pt_regs pointer
 646         popl_cfi %ecx
 647         movl %eax, %esp
 648         jmp 1b
 649 #endif
 650 END(work_pending)
 651
 652         # perform syscall exit tracing
 653         ALIGN
 654 syscall_trace_entry:
 655         movl $-ENOSYS,PT_EAX(%esp)
 656         movl %esp, %eax
 657         call syscall_trace_enter
 658         /* What it returned is what we'll actually use.  */
 659         cmpl $(NR_syscalls), %eax
 660         jnae syscall_call
 661         jmp syscall_exit
 662 END(syscall_trace_entry)
 663
 664         # perform syscall exit tracing
 665         ALIGN
 666 syscall_exit_work:
 667         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 668         jz work_pending
 669         TRACE_IRQS_ON
 670         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 671                                         # schedule() instead
 672         movl %esp, %eax
 673         call syscall_trace_leave
 674         jmp resume_userspace
 675 END(syscall_exit_work)
 676         CFI_ENDPROC
 677
 678         RING0_INT_FRAME                 # can't unwind into user space anyway
 679 syscall_fault:
 680         ASM_CLAC
 681         GET_THREAD_INFO(%ebp)
 682         movl $-EFAULT,PT_EAX(%esp)
 683         jmp resume_userspace
 684 END(syscall_fault)
 685
 686 syscall_badsys:
 687         movl $-ENOSYS,%eax
 688         jmp syscall_after_call
 689 END(syscall_badsys)
 690
 691 sysenter_badsys:
 692         movl $-ENOSYS,%eax
 693         jmp sysenter_after_call
 694 END(syscall_badsys)
 695         CFI_ENDPROC
 696 /*
 697  * End of kprobes section
 698  */
 699         .popsection
 700
 701 .macro FIXUP_ESPFIX_STACK
 702 /*
 703  * Switch back for ESPFIX stack to the normal zerobased stack
 704  *
 705  * We can't call C functions using the ESPFIX stack. This code reads
 706  * the high word of the segment base from the GDT and swiches to the
 707  * normal stack and adjusts ESP with the matching offset.
 708  */
 709         /* fixup the stack */
 710         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 711         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 712         shl $16, %eax
 713         addl %esp, %eax                 /* the adjusted stack pointer */
 714         pushl_cfi $__KERNEL_DS
 715         pushl_cfi %eax
 716         lss (%esp), %esp                /* switch to the normal stack segment */
 717         CFI_ADJUST_CFA_OFFSET -8
 718 .endm
 719 .macro UNWIND_ESPFIX_STACK
 720         movl %ss, %eax
 721         /* see if on espfix stack */
 722         cmpw $__ESPFIX_SS, %ax
 723         jne 27f
 724         movl $__KERNEL_DS, %eax
 725         movl %eax, %ds
 726         movl %eax, %es
 727         /* switch to normal stack */
 728         FIXUP_ESPFIX_STACK
 729 27:
 730 .endm
 731
 732 /*
 733  * Build the entry stubs and pointer table with some assembler magic.
 734  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 735  * single cache line on all modern x86 implementations.
 736  */
 737 .section .init.rodata,"a"
 738 ENTRY(interrupt)
 739 .section .entry.text, "ax"
 740         .p2align 5
 741         .p2align CONFIG_X86_L1_CACHE_SHIFT
 742 ENTRY(irq_entries_start)
 743         RING0_INT_FRAME
 744 vector=FIRST_EXTERNAL_VECTOR
 745 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 746         .balign 32
 747   .rept 7
 748     .if vector < NR_VECTORS
 749       .if vector <> FIRST_EXTERNAL_VECTOR
 750         CFI_ADJUST_CFA_OFFSET -4
 751       .endif
 752 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 753       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 754         jmp 2f
 755       .endif
 756       .previous
 757         .long 1b
 758       .section .entry.text, "ax"
 759 vector=vector+1
 760     .endif
 761   .endr
 762 2:      jmp common_interrupt
 763 .endr
 764 END(irq_entries_start)
 765
 766 .previous
 767 END(interrupt)
 768 .previous
 769
 770 /*
 771  * the CPU automatically disables interrupts when executing an IRQ vector,
 772  * so IRQ-flags tracing has to follow that:
 773  */
 774         .p2align CONFIG_X86_L1_CACHE_SHIFT
 775 common_interrupt:
 776         ASM_CLAC
 777         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 778         SAVE_ALL
 779         TRACE_IRQS_OFF
 780         movl %esp,%eax
 781         call do_IRQ
 782         jmp ret_from_intr
 783 ENDPROC(common_interrupt)
 784         CFI_ENDPROC
 785
 786 /*
 787  *  Irq entries should be protected against kprobes
 788  */
 789         .pushsection .kprobes.text, "ax"
 790 #define BUILD_INTERRUPT3(name, nr, fn)  \
 791 ENTRY(name)                             \
 792         RING0_INT_FRAME;                \
 793         ASM_CLAC;                       \
 794         pushl_cfi $~(nr);               \
 795         SAVE_ALL;                       \
 796         TRACE_IRQS_OFF                  \
 797         movl %esp,%eax;                 \
 798         call fn;                        \
 799         jmp ret_from_intr;              \
 800         CFI_ENDPROC;                    \
 801 ENDPROC(name)
 802
 803
 804 #ifdef CONFIG_TRACING
 805 #define TRACE_BUILD_INTERRUPT(name, nr)         \
 806         BUILD_INTERRUPT3(trace_##name, nr, smp_trace_##name)
 807 #else
 808 #define TRACE_BUILD_INTERRUPT(name, nr)
 809 #endif
 810
 811 #define BUILD_INTERRUPT(name, nr) \
 812         BUILD_INTERRUPT3(name, nr, smp_##name); \
 813         TRACE_BUILD_INTERRUPT(name, nr)
 814
 815 /* The include is where all of the SMP etc. interrupts come from */
 816 #include <asm/entry_arch.h>
 817
 818 ENTRY(coprocessor_error)
 819         RING0_INT_FRAME
 820         ASM_CLAC
 821         pushl_cfi $0
 822         pushl_cfi $do_coprocessor_error
 823         jmp error_code
 824         CFI_ENDPROC
 825 END(coprocessor_error)
 826
 827 ENTRY(simd_coprocessor_error)
 828         RING0_INT_FRAME
 829         ASM_CLAC
 830         pushl_cfi $0
 831 #ifdef CONFIG_X86_INVD_BUG
 832         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 833 661:    pushl_cfi $do_general_protection
 834 662:
 835 .section .altinstructions,"a"
 836         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 837 .previous
 838 .section .altinstr_replacement,"ax"
 839 663:    pushl $do_simd_coprocessor_error
 840 664:
 841 .previous
 842 #else
 843         pushl_cfi $do_simd_coprocessor_error
 844 #endif
 845         jmp error_code
 846         CFI_ENDPROC
 847 END(simd_coprocessor_error)
 848
 849 ENTRY(device_not_available)
 850         RING0_INT_FRAME
 851         ASM_CLAC
 852         pushl_cfi $-1                   # mark this as an int
 853         pushl_cfi $do_device_not_available
 854         jmp error_code
 855         CFI_ENDPROC
 856 END(device_not_available)
 857
 858 #ifdef CONFIG_PARAVIRT
 859 ENTRY(native_iret)
 860         iret
 861         _ASM_EXTABLE(native_iret, iret_exc)
 862 END(native_iret)
 863
 864 ENTRY(native_irq_enable_sysexit)
 865         sti
 866         sysexit
 867 END(native_irq_enable_sysexit)
 868 #endif
 869
 870 ENTRY(overflow)
 871         RING0_INT_FRAME
 872         ASM_CLAC
 873         pushl_cfi $0
 874         pushl_cfi $do_overflow
 875         jmp error_code
 876         CFI_ENDPROC
 877 END(overflow)
 878
 879 ENTRY(bounds)
 880         RING0_INT_FRAME
 881         ASM_CLAC
 882         pushl_cfi $0
 883         pushl_cfi $do_bounds
 884         jmp error_code
 885         CFI_ENDPROC
 886 END(bounds)
 887
 888 ENTRY(invalid_op)
 889         RING0_INT_FRAME
 890         ASM_CLAC
 891         pushl_cfi $0
 892         pushl_cfi $do_invalid_op
 893         jmp error_code
 894         CFI_ENDPROC
 895 END(invalid_op)
 896
 897 ENTRY(coprocessor_segment_overrun)
 898         RING0_INT_FRAME
 899         ASM_CLAC
 900         pushl_cfi $0
 901         pushl_cfi $do_coprocessor_segment_overrun
 902         jmp error_code
 903         CFI_ENDPROC
 904 END(coprocessor_segment_overrun)
 905
 906 ENTRY(invalid_TSS)
 907         RING0_EC_FRAME
 908         ASM_CLAC
 909         pushl_cfi $do_invalid_TSS
 910         jmp error_code
 911         CFI_ENDPROC
 912 END(invalid_TSS)
 913
 914 ENTRY(segment_not_present)
 915         RING0_EC_FRAME
 916         ASM_CLAC
 917         pushl_cfi $do_segment_not_present
 918         jmp error_code
 919         CFI_ENDPROC
 920 END(segment_not_present)
 921
 922 ENTRY(stack_segment)
 923         RING0_EC_FRAME
 924         ASM_CLAC
 925         pushl_cfi $do_stack_segment
 926         jmp error_code
 927         CFI_ENDPROC
 928 END(stack_segment)
 929
 930 ENTRY(alignment_check)
 931         RING0_EC_FRAME
 932         ASM_CLAC
 933         pushl_cfi $do_alignment_check
 934         jmp error_code
 935         CFI_ENDPROC
 936 END(alignment_check)
 937
 938 ENTRY(divide_error)
 939         RING0_INT_FRAME
 940         ASM_CLAC
 941         pushl_cfi $0                    # no error code
 942         pushl_cfi $do_divide_error
 943         jmp error_code
 944         CFI_ENDPROC
 945 END(divide_error)
 946
 947 #ifdef CONFIG_X86_MCE
 948 ENTRY(machine_check)
 949         RING0_INT_FRAME
 950         ASM_CLAC
 951         pushl_cfi $0
 952         pushl_cfi machine_check_vector
 953         jmp error_code
 954         CFI_ENDPROC
 955 END(machine_check)
 956 #endif
 957
 958 ENTRY(spurious_interrupt_bug)
 959         RING0_INT_FRAME
 960         ASM_CLAC
 961         pushl_cfi $0
 962         pushl_cfi $do_spurious_interrupt_bug
 963         jmp error_code
 964         CFI_ENDPROC
 965 END(spurious_interrupt_bug)
 966 /*
 967  * End of kprobes section
 968  */
 969         .popsection
 970
 971 #ifdef CONFIG_XEN
 972 /* Xen doesn't set %esp to be precisely what the normal sysenter
 973    entrypoint expects, so fix it up before using the normal path. */
 974 ENTRY(xen_sysenter_target)
 975         RING0_INT_FRAME
 976         addl $5*4, %esp         /* remove xen-provided frame */
 977         CFI_ADJUST_CFA_OFFSET -5*4
 978         jmp sysenter_past_esp
 979         CFI_ENDPROC
 980
 981 ENTRY(xen_hypervisor_callback)
 982         CFI_STARTPROC
 983         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
 984         SAVE_ALL
 985         TRACE_IRQS_OFF
 986
 987         /* Check to see if we got the event in the critical
 988            region in xen_iret_direct, after we've reenabled
 989            events and checked for pending events.  This simulates
 990            iret instruction's behaviour where it delivers a
 991            pending interrupt when enabling interrupts. */
 992         movl PT_EIP(%esp),%eax
 993         cmpl $xen_iret_start_crit,%eax
 994         jb   1f
 995         cmpl $xen_iret_end_crit,%eax
 996         jae  1f
 997
 998         jmp  xen_iret_crit_fixup
 999
1000 ENTRY(xen_do_upcall)
1001 1:      mov %esp, %eax
1002         call xen_evtchn_do_upcall
1003         jmp  ret_from_intr
1004         CFI_ENDPROC
1005 ENDPROC(xen_hypervisor_callback)
1006
1007 # Hypervisor uses this for application faults while it executes.
1008 # We get here for two reasons:
1009 #  1. Fault while reloading DS, ES, FS or GS
1010 #  2. Fault while executing IRET
1011 # Category 1 we fix up by reattempting the load, and zeroing the segment
1012 # register if the load fails.
1013 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1014 # normal Linux return path in this case because if we use the IRET hypercall
1015 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1016 # We distinguish between categories by maintaining a status value in EAX.
1017 ENTRY(xen_failsafe_callback)
1018         CFI_STARTPROC
1019         pushl_cfi %eax
1020         movl $1,%eax
1021 1:      mov 4(%esp),%ds
1022 2:      mov 8(%esp),%es
1023 3:      mov 12(%esp),%fs
1024 4:      mov 16(%esp),%gs
1025         /* EAX == 0 => Category 1 (Bad segment)
1026            EAX != 0 => Category 2 (Bad IRET) */
1027         testl %eax,%eax
1028         popl_cfi %eax
1029         lea 16(%esp),%esp
1030         CFI_ADJUST_CFA_OFFSET -16
1031         jz 5f
1032         jmp iret_exc
1033 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1034         SAVE_ALL
1035         jmp ret_from_exception
1036         CFI_ENDPROC
1037
1038 .section .fixup,"ax"
1039 6:      xorl %eax,%eax
1040         movl %eax,4(%esp)
1041         jmp 1b
1042 7:      xorl %eax,%eax
1043         movl %eax,8(%esp)
1044         jmp 2b
1045 8:      xorl %eax,%eax
1046         movl %eax,12(%esp)
1047         jmp 3b
1048 9:      xorl %eax,%eax
1049         movl %eax,16(%esp)
1050         jmp 4b
1051 .previous
1052         _ASM_EXTABLE(1b,6b)
1053         _ASM_EXTABLE(2b,7b)
1054         _ASM_EXTABLE(3b,8b)
1055         _ASM_EXTABLE(4b,9b)
1056 ENDPROC(xen_failsafe_callback)
1057
1058 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1059                 xen_evtchn_do_upcall)
1060
1061 #endif  /* CONFIG_XEN */
1062
1063 #if IS_ENABLED(CONFIG_HYPERV)
1064
1065 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1066         hyperv_vector_handler)
1067
1068 #endif /* CONFIG_HYPERV */
1069
1070 #ifdef CONFIG_FUNCTION_TRACER
1071 #ifdef CONFIG_DYNAMIC_FTRACE
1072
1073 ENTRY(mcount)
1074         ret
1075 END(mcount)
1076
1077 ENTRY(ftrace_caller)
1078         cmpl $0, function_trace_stop
1079         jne  ftrace_stub
1080
1081         pushl %eax
1082         pushl %ecx
1083         pushl %edx
1084         pushl $0        /* Pass NULL as regs pointer */
1085         movl 4*4(%esp), %eax
1086         movl 0x4(%ebp), %edx
1087         movl function_trace_op, %ecx
1088         subl $MCOUNT_INSN_SIZE, %eax
1089
1090 .globl ftrace_call
1091 ftrace_call:
1092         call ftrace_stub
1093
1094         addl $4,%esp    /* skip NULL pointer */
1095         popl %edx
1096         popl %ecx
1097         popl %eax
1098 ftrace_ret:
1099 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1100 .globl ftrace_graph_call
1101 ftrace_graph_call:
1102         jmp ftrace_stub
1103 #endif
1104
1105 .globl ftrace_stub
1106 ftrace_stub:
1107         ret
1108 END(ftrace_caller)
1109
1110 ENTRY(ftrace_regs_caller)
1111         pushf   /* push flags before compare (in cs location) */
1112         cmpl $0, function_trace_stop
1113         jne ftrace_restore_flags
1114
1115         /*
1116          * i386 does not save SS and ESP when coming from kernel.
1117          * Instead, to get sp, &regs->sp is used (see ptrace.h).
1118          * Unfortunately, that means eflags must be at the same location
1119          * as the current return ip is. We move the return ip into the
1120          * ip location, and move flags into the return ip location.
1121          */
1122         pushl 4(%esp)   /* save return ip into ip slot */
1123
1124         pushl $0        /* Load 0 into orig_ax */
1125         pushl %gs
1126         pushl %fs
1127         pushl %es
1128         pushl %ds
1129         pushl %eax
1130         pushl %ebp
1131         pushl %edi
1132         pushl %esi
1133         pushl %edx
1134         pushl %ecx
1135         pushl %ebx
1136
1137         movl 13*4(%esp), %eax   /* Get the saved flags */
1138         movl %eax, 14*4(%esp)   /* Move saved flags into regs->flags location */
1139                                 /* clobbering return ip */
1140         movl $__KERNEL_CS,13*4(%esp)
1141
1142         movl 12*4(%esp), %eax   /* Load ip (1st parameter) */
1143         subl $MCOUNT_INSN_SIZE, %eax    /* Adjust ip */
1144         movl 0x4(%ebp), %edx    /* Load parent ip (2nd parameter) */
1145         movl function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1146         pushl %esp              /* Save pt_regs as 4th parameter */
1147
1148 GLOBAL(ftrace_regs_call)
1149         call ftrace_stub
1150
1151         addl $4, %esp           /* Skip pt_regs */
1152         movl 14*4(%esp), %eax   /* Move flags back into cs */
1153         movl %eax, 13*4(%esp)   /* Needed to keep addl from modifying flags */
1154         movl 12*4(%esp), %eax   /* Get return ip from regs->ip */
1155         movl %eax, 14*4(%esp)   /* Put return ip back for ret */
1156
1157         popl %ebx
1158         popl %ecx
1159         popl %edx
1160         popl %esi
1161         popl %edi
1162         popl %ebp
1163         popl %eax
1164         popl %ds
1165         popl %es
1166         popl %fs
1167         popl %gs
1168         addl $8, %esp           /* Skip orig_ax and ip */
1169         popf                    /* Pop flags at end (no addl to corrupt flags) */
1170         jmp ftrace_ret
1171
1172 ftrace_restore_flags:
1173         popf
1174         jmp  ftrace_stub
1175 #else /* ! CONFIG_DYNAMIC_FTRACE */
1176
1177 ENTRY(mcount)
1178         cmpl $__PAGE_OFFSET, %esp
1179         jb ftrace_stub          /* Paging not enabled yet? */
1180
1181         cmpl $0, function_trace_stop
1182         jne  ftrace_stub
1183
1184         cmpl $ftrace_stub, ftrace_trace_function
1185         jnz trace
1186 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1187         cmpl $ftrace_stub, ftrace_graph_return
1188         jnz ftrace_graph_caller
1189
1190         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1191         jnz ftrace_graph_caller
1192 #endif
1193 .globl ftrace_stub
1194 ftrace_stub:
1195         ret
1196
1197         /* taken from glibc */
1198 trace:
1199         pushl %eax
1200         pushl %ecx
1201         pushl %edx
1202         movl 0xc(%esp), %eax
1203         movl 0x4(%ebp), %edx
1204         subl $MCOUNT_INSN_SIZE, %eax
1205
1206         call *ftrace_trace_function
1207
1208         popl %edx
1209         popl %ecx
1210         popl %eax
1211         jmp ftrace_stub
1212 END(mcount)
1213 #endif /* CONFIG_DYNAMIC_FTRACE */
1214 #endif /* CONFIG_FUNCTION_TRACER */
1215
1216 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1217 ENTRY(ftrace_graph_caller)
1218         pushl %eax
1219         pushl %ecx
1220         pushl %edx
1221         movl 0xc(%esp), %edx
1222         lea 0x4(%ebp), %eax
1223         movl (%ebp), %ecx
1224         subl $MCOUNT_INSN_SIZE, %edx
1225         call prepare_ftrace_return
1226         popl %edx
1227         popl %ecx
1228         popl %eax
1229         ret
1230 END(ftrace_graph_caller)
1231
1232 .globl return_to_handler
1233 return_to_handler:
1234         pushl %eax
1235         pushl %edx
1236         movl %ebp, %eax
1237         call ftrace_return_to_handler
1238         movl %eax, %ecx
1239         popl %edx
1240         popl %eax
1241         jmp *%ecx
1242 #endif
1243
1244 /*
1245  * Some functions should be protected against kprobes
1246  */
1247         .pushsection .kprobes.text, "ax"
1248
1249 #ifdef CONFIG_TRACING
1250 ENTRY(trace_page_fault)
1251         RING0_EC_FRAME
1252         ASM_CLAC
1253         pushl_cfi $trace_do_page_fault
1254         jmp error_code
1255         CFI_ENDPROC
1256 END(trace_page_fault)
1257 #endif
1258
1259 ENTRY(page_fault)
1260         RING0_EC_FRAME
1261         ASM_CLAC
1262         pushl_cfi $do_page_fault
1263         ALIGN
1264 error_code:
1265         /* the function address is in %gs's slot on the stack */
1266         pushl_cfi %fs
1267         /*CFI_REL_OFFSET fs, 0*/
1268         pushl_cfi %es
1269         /*CFI_REL_OFFSET es, 0*/
1270         pushl_cfi %ds
1271         /*CFI_REL_OFFSET ds, 0*/
1272         pushl_cfi %eax
1273         CFI_REL_OFFSET eax, 0
1274         pushl_cfi %ebp
1275         CFI_REL_OFFSET ebp, 0
1276         pushl_cfi %edi
1277         CFI_REL_OFFSET edi, 0
1278         pushl_cfi %esi
1279         CFI_REL_OFFSET esi, 0
1280         pushl_cfi %edx
1281         CFI_REL_OFFSET edx, 0
1282         pushl_cfi %ecx
1283         CFI_REL_OFFSET ecx, 0
1284         pushl_cfi %ebx
1285         CFI_REL_OFFSET ebx, 0
1286         cld
1287         movl $(__KERNEL_PERCPU), %ecx
1288         movl %ecx, %fs
1289         UNWIND_ESPFIX_STACK
1290         GS_TO_REG %ecx
1291         movl PT_GS(%esp), %edi          # get the function address
1292         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1293         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1294         REG_TO_PTGS %ecx
1295         SET_KERNEL_GS %ecx
1296         movl $(__USER_DS), %ecx
1297         movl %ecx, %ds
1298         movl %ecx, %es
1299         TRACE_IRQS_OFF
1300         movl %esp,%eax                  # pt_regs pointer
1301         call *%edi
1302         jmp ret_from_exception
1303         CFI_ENDPROC
1304 END(page_fault)
1305
1306 /*
1307  * Debug traps and NMI can happen at the one SYSENTER instruction
1308  * that sets up the real kernel stack. Check here, since we can't
1309  * allow the wrong stack to be used.
1310  *
1311  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1312  * already pushed 3 words if it hits on the sysenter instruction:
1313  * eflags, cs and eip.
1314  *
1315  * We just load the right stack, and push the three (known) values
1316  * by hand onto the new stack - while updating the return eip past
1317  * the instruction that would have done it for sysenter.
1318  */
1319 .macro FIX_STACK offset ok label
1320         cmpw $__KERNEL_CS, 4(%esp)
1321         jne \ok
1322 \label:
1323         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1324         CFI_DEF_CFA esp, 0
1325         CFI_UNDEFINED eip
1326         pushfl_cfi
1327         pushl_cfi $__KERNEL_CS
1328         pushl_cfi $sysenter_past_esp
1329         CFI_REL_OFFSET eip, 0
1330 .endm
1331
1332 ENTRY(debug)
1333         RING0_INT_FRAME
1334         ASM_CLAC
1335         cmpl $ia32_sysenter_target,(%esp)
1336         jne debug_stack_correct
1337         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1338 debug_stack_correct:
1339         pushl_cfi $-1                   # mark this as an int
1340         SAVE_ALL
1341         TRACE_IRQS_OFF
1342         xorl %edx,%edx                  # error code 0
1343         movl %esp,%eax                  # pt_regs pointer
1344         call do_debug
1345         jmp ret_from_exception
1346         CFI_ENDPROC
1347 END(debug)
1348
1349 /*
1350  * NMI is doubly nasty. It can happen _while_ we're handling
1351  * a debug fault, and the debug fault hasn't yet been able to
1352  * clear up the stack. So we first check whether we got  an
1353  * NMI on the sysenter entry path, but after that we need to
1354  * check whether we got an NMI on the debug path where the debug
1355  * fault happened on the sysenter path.
1356  */
1357 ENTRY(nmi)
1358         RING0_INT_FRAME
1359         ASM_CLAC
1360         pushl_cfi %eax
1361         movl %ss, %eax
1362         cmpw $__ESPFIX_SS, %ax
1363         popl_cfi %eax
1364         je nmi_espfix_stack
1365         cmpl $ia32_sysenter_target,(%esp)
1366         je nmi_stack_fixup
1367         pushl_cfi %eax
1368         movl %esp,%eax
1369         /* Do not access memory above the end of our stack page,
1370          * it might not exist.
1371          */
1372         andl $(THREAD_SIZE-1),%eax
1373         cmpl $(THREAD_SIZE-20),%eax
1374         popl_cfi %eax
1375         jae nmi_stack_correct
1376         cmpl $ia32_sysenter_target,12(%esp)
1377         je nmi_debug_stack_check
1378 nmi_stack_correct:
1379         /* We have a RING0_INT_FRAME here */
1380         pushl_cfi %eax
1381         SAVE_ALL
1382         xorl %edx,%edx          # zero error code
1383         movl %esp,%eax          # pt_regs pointer
1384         call do_nmi
1385         jmp restore_all_notrace
1386         CFI_ENDPROC
1387
1388 nmi_stack_fixup:
1389         RING0_INT_FRAME
1390         FIX_STACK 12, nmi_stack_correct, 1
1391         jmp nmi_stack_correct
1392
1393 nmi_debug_stack_check:
1394         /* We have a RING0_INT_FRAME here */
1395         cmpw $__KERNEL_CS,16(%esp)
1396         jne nmi_stack_correct
1397         cmpl $debug,(%esp)
1398         jb nmi_stack_correct
1399         cmpl $debug_esp_fix_insn,(%esp)
1400         ja nmi_stack_correct
1401         FIX_STACK 24, nmi_stack_correct, 1
1402         jmp nmi_stack_correct
1403
1404 nmi_espfix_stack:
1405         /* We have a RING0_INT_FRAME here.
1406          *
1407          * create the pointer to lss back
1408          */
1409         pushl_cfi %ss
1410         pushl_cfi %esp
1411         addl $4, (%esp)
1412         /* copy the iret frame of 12 bytes */
1413         .rept 3
1414         pushl_cfi 16(%esp)
1415         .endr
1416         pushl_cfi %eax
1417         SAVE_ALL
1418         FIXUP_ESPFIX_STACK              # %eax == %esp
1419         xorl %edx,%edx                  # zero error code
1420         call do_nmi
1421         RESTORE_REGS
1422         lss 12+4(%esp), %esp            # back to espfix stack
1423         CFI_ADJUST_CFA_OFFSET -24
1424         jmp irq_return
1425         CFI_ENDPROC
1426 END(nmi)
1427
1428 ENTRY(int3)
1429         RING0_INT_FRAME
1430         ASM_CLAC
1431         pushl_cfi $-1                   # mark this as an int
1432         SAVE_ALL
1433         TRACE_IRQS_OFF
1434         xorl %edx,%edx          # zero error code
1435         movl %esp,%eax          # pt_regs pointer
1436         call do_int3
1437         jmp ret_from_exception
1438         CFI_ENDPROC
1439 END(int3)
1440
1441 ENTRY(general_protection)
1442         RING0_EC_FRAME
1443         pushl_cfi $do_general_protection
1444         jmp error_code
1445         CFI_ENDPROC
1446 END(general_protection)
1447
1448 #ifdef CONFIG_KVM_GUEST
1449 ENTRY(async_page_fault)
1450         RING0_EC_FRAME
1451         ASM_CLAC
1452         pushl_cfi $do_async_page_fault
1453         jmp error_code
1454         CFI_ENDPROC
1455 END(async_page_fault)
1456 #endif
1457
1458 /*
1459  * End of kprobes section
1460  */
1461         .popsection