arch/x86/cpu/start16.S

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  *  U-Boot - x86 Startup Code
   4  *
   5  * (C) Copyright 2008-2011
   6  * Graeme Russ, <graeme.russ@gmail.com>
   7  *
   8  * (C) Copyright 2002,2003
   9  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
  10  */
  11
  12 #include <asm/processor-flags.h>
  13
  14 #define BOOT_SEG        0xffff0000      /* linear segment of boot code */
  15
  16 .section .start16, "ax"
  17 .code16
  18 .globl start16
  19 start16:
  20         /* Save BIST */
  21         movl    %eax, %ecx
  22
  23         xorl    %eax, %eax
  24         movl    %eax, %cr3      /* Invalidate TLB */
  25
  26         /* Turn off cache (this might require a 486-class CPU) */
  27         movl    %cr0, %eax
  28         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  29         movl    %eax, %cr0
  30         wbinvd
  31
  32         /* load the temporary Global Descriptor Table */
  33 data32 cs       lidt    idt_ptr
  34 data32 cs       lgdt    gdt_ptr
  35
  36         /* Now, we enter protected mode */
  37         movl    %cr0, %eax
  38         orl     $X86_CR0_PE, %eax
  39         movl    %eax, %cr0
  40
  41         /* Flush the prefetch queue */
  42         jmp     ff
  43 ff:
  44
  45         /* Finally restore BIST and jump to the 32-bit initialization code */
  46         movl    %ecx, %eax
  47 data32 cs       ljmp    *code32start
  48
  49         /* 48-bit far pointer */
  50 code32start:
  51         .long   _start          /* offset */
  52         .word   0x10            /* segment */
  53
  54 idt_ptr:
  55         .word   0               /* limit */
  56         .long   0               /* base */
  57
  58         /*
  59          * The following Global Descriptor Table is just enough to get us into
  60          * 'Flat Protected Mode' - It will be discarded as soon as the final
  61          * GDT is setup in a safe location in RAM
  62          */
  63 gdt_ptr:
  64         .word   0x1f            /* limit (31 bytes = 4 GDT entries - 1) */
  65         .long   BOOT_SEG + gdt_rom      /* base */
  66
  67         /* Some CPUs are picky about GDT alignment... */
  68         .align  16
  69 .globl gdt_rom
  70 gdt_rom:
  71         /*
  72          * The GDT table ...
  73          *
  74          *       Selector       Type
  75          *       0x00           NULL
  76          *       0x08           Unused
  77          *       0x10           32bit code
  78          *       0x18           32bit data/stack
  79          */
  80         /* The NULL Desciptor - Mandatory */
  81         .word   0x0000          /* limit_low */
  82         .word   0x0000          /* base_low */
  83         .byte   0x00            /* base_middle */
  84         .byte   0x00            /* access */
  85         .byte   0x00            /* flags + limit_high */
  86         .byte   0x00            /* base_high */
  87
  88         /* Unused Desciptor - (matches Linux) */
  89         .word   0x0000          /* limit_low */
  90         .word   0x0000          /* base_low */
  91         .byte   0x00            /* base_middle */
  92         .byte   0x00            /* access */
  93         .byte   0x00            /* flags + limit_high */
  94         .byte   0x00            /* base_high */
  95
  96         /*
  97          * The Code Segment Descriptor:
  98          * - Base   = 0x00000000
  99          * - Size   = 4GB
 100          * - Access = Present, Ring 0, Exec (Code), Readable
 101          * - Flags  = 4kB Granularity, 32-bit
 102          */
 103         .word   0xffff          /* limit_low */
 104         .word   0x0000          /* base_low */
 105         .byte   0x00            /* base_middle */
 106         .byte   0x9b            /* access */
 107         .byte   0xcf            /* flags + limit_high */
 108         .byte   0x00            /* base_high */
 109
 110         /*
 111          * The Data Segment Descriptor:
 112          * - Base   = 0x00000000
 113          * - Size   = 4GB
 114          * - Access = Present, Ring 0, Non-Exec (Data), Writable
 115          * - Flags  = 4kB Granularity, 32-bit
 116          */
 117         .word   0xffff          /* limit_low */
 118         .word   0x0000          /* base_low */
 119         .byte   0x00            /* base_middle */
 120         .byte   0x93            /* access */
 121         .byte   0xcf            /* flags + limit_high */
 122         .byte   0x00            /* base_high */