arch/x86/cpu/start.S

   1 /*
   2  *  U-Boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <config.h>
  14 #include <asm/global_data.h>
  15 #include <asm/post.h>
  16 #include <asm/processor.h>
  17 #include <asm/processor-flags.h>
  18 #include <generated/generic-asm-offsets.h>
  19 #include <generated/asm-offsets.h>
  20
  21 .section .text
  22 .code32
  23 .globl _start
  24 .type _start, @function
  25 .globl _x86boot_start
  26 _x86boot_start:
  27         /*
  28          * This is the fail-safe 32-bit bootstrap entry point.
  29          *
  30          * This code is used when booting from another boot loader like
  31          * coreboot or EFI. So we repeat some of the same init found in
  32          * start16.
  33          */
  34         cli
  35         cld
  36
  37         /* Turn off cache (this might require a 486-class CPU) */
  38         movl    %cr0, %eax
  39         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  40         movl    %eax, %cr0
  41         wbinvd
  42
  43         /* Tell 32-bit code it is being entered from an in-RAM copy */
  44         movl    $GD_FLG_WARM_BOOT, %ebx
  45
  46         /*
  47          * Zero the BIST (Built-In Self Test) value since we don't have it.
  48          * It must be 0 or the previous loader would have reported an error.
  49          */
  50         movl    $0, %ebp
  51
  52         jmp     1f
  53
  54         /* Add a way for tools to discover the _start entry point */
  55         .align  4
  56         .long   0x12345678
  57 _start:
  58         /*
  59          * This is the 32-bit cold-reset entry point, coming from start16.
  60          * Set %ebx to GD_FLG_COLD_BOOT to indicate this.
  61          */
  62         movl    $GD_FLG_COLD_BOOT, %ebx
  63
  64         /* Save BIST */
  65         movl    %eax, %ebp
  66 1:
  67
  68         /* Save table pointer */
  69         movl    %ecx, %esi
  70
  71         /* Load the segement registers to match the GDT loaded in start16.S */
  72         movl    $(X86_GDT_ENTRY_32BIT_DS * X86_GDT_ENTRY_SIZE), %eax
  73         movw    %ax, %fs
  74         movw    %ax, %ds
  75         movw    %ax, %gs
  76         movw    %ax, %es
  77         movw    %ax, %ss
  78
  79         /* Clear the interrupt vectors */
  80         lidt    blank_idt_ptr
  81
  82         /*
  83          * Critical early platform init - generally not used, we prefer init
  84          * to happen later when we have a console, in case something goes
  85          * wrong.
  86          */
  87         jmp     early_board_init
  88 .globl early_board_init_ret
  89 early_board_init_ret:
  90         post_code(POST_START)
  91
  92         /* Initialise Cache-As-RAM */
  93         jmp     car_init
  94 .globl car_init_ret
  95 car_init_ret:
  96 #ifndef CONFIG_HAVE_FSP
  97         /*
  98          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  99          * or fully initialised SDRAM - we really don't care which)
 100          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
 101          * and early malloc() area. The MRC requires some space at the top.
 102          *
 103          * Stack grows down from top of CAR. We have:
 104          *
 105          * top-> CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE
 106          *      MRC area
 107          *      global_data with x86 global descriptor table
 108          *      early malloc area
 109          *      stack
 110          * bottom-> CONFIG_SYS_CAR_ADDR
 111          */
 112         movl    $(CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE - 4), %esp
 113 #ifdef CONFIG_DCACHE_RAM_MRC_VAR_SIZE
 114         subl    $CONFIG_DCACHE_RAM_MRC_VAR_SIZE, %esp
 115 #endif
 116 #else
 117         /*
 118          * U-Boot enters here twice. For the first time it comes from
 119          * car_init_done() with esp points to a temporary stack and esi
 120          * set to zero. For the second time it comes from fsp_init_done()
 121          * with esi holding the HOB list address returned by the FSP.
 122          */
 123 #endif
 124         /* Set up global data */
 125         mov     %esp, %eax
 126         call    board_init_f_mem
 127         mov     %eax, %esp
 128
 129 #ifdef CONFIG_DEBUG_UART
 130         call    debug_uart_init
 131 #endif
 132
 133         /* Get address of global_data */
 134         mov     %fs:0, %edx
 135 #ifdef CONFIG_HAVE_FSP
 136         /* Store the HOB list if we have one */
 137         test    %esi, %esi
 138         jz      skip_hob
 139         movl    %esi, GD_HOB_LIST(%edx)
 140
 141         /*
 142          * After fsp_init() returns, the stack has already been switched to a
 143          * place within system memory as defined by CONFIG_FSP_TEMP_RAM_ADDR.
 144          * Enlarge the size of malloc() pool before relocation since we have
 145          * plenty of memory now.
 146          */
 147         subl    $CONFIG_FSP_SYS_MALLOC_F_LEN, %esp
 148         movl    %esp, GD_MALLOC_BASE(%edx)
 149 skip_hob:
 150 #else
 151         /* Store table pointer */
 152         movl    %esi, GD_TABLE(%edx)
 153 #endif
 154         /* Store BIST */
 155         movl    %ebp, GD_BIST(%edx)
 156
 157         /* Set parameter to board_init_f() to boot flags */
 158         post_code(POST_START_DONE)
 159         xorl    %eax, %eax
 160
 161         /* Enter, U-Boot! */
 162         call    board_init_f
 163
 164         /* indicate (lack of) progress */
 165         movw    $0x85, %ax
 166         jmp     die
 167
 168 .globl board_init_f_r_trampoline
 169 .type board_init_f_r_trampoline, @function
 170 board_init_f_r_trampoline:
 171         /*
 172          * SDRAM has been initialised, U-Boot code has been copied into
 173          * RAM, BSS has been cleared and relocation adjustments have been
 174          * made. It is now time to jump into the in-RAM copy of U-Boot
 175          *
 176          * %eax = Address of top of new stack
 177          */
 178
 179         /* Stack grows down from top of SDRAM */
 180         movl    %eax, %esp
 181
 182         /* See if we need to disable CAR */
 183 .weak   car_uninit
 184         movl    $car_uninit, %eax
 185         cmpl    $0, %eax
 186         jz      1f
 187
 188         call    car_uninit
 189 1:
 190         /* Re-enter U-Boot by calling board_init_f_r() */
 191         call    board_init_f_r
 192
 193 die:
 194         hlt
 195         jmp     die
 196         hlt
 197
 198 blank_idt_ptr:
 199         .word   0               /* limit */
 200         .long   0               /* base */
 201
 202         .p2align        2       /* force 4-byte alignment */
 203
 204         /* Add a multiboot header so U-Boot can be loaded by GRUB2 */
 205 multiboot_header:
 206         /* magic */
 207         .long   0x1badb002
 208         /* flags */
 209         .long   (1 << 16)
 210         /* checksum */
 211         .long   -0x1BADB002 - (1 << 16)
 212         /* header addr */
 213         .long   multiboot_header - _x86boot_start + CONFIG_SYS_TEXT_BASE
 214         /* load addr */
 215         .long   CONFIG_SYS_TEXT_BASE
 216         /* load end addr */
 217         .long   0
 218         /* bss end addr */
 219         .long   0
 220         /* entry addr */
 221         .long   CONFIG_SYS_TEXT_BASE