arch/x86/boot/compressed/head_64.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24         .code32
  25         .text
  26
  27 #include <linux/init.h>
  28 #include <linux/linkage.h>
  29 #include <asm/segment.h>
  30 #include <asm/boot.h>
  31 #include <asm/msr.h>
  32 #include <asm/processor-flags.h>
  33 #include <asm/asm-offsets.h>
  34
  35         __HEAD
  36         .code32
  37 ENTRY(startup_32)
  38         /*
  39          * 32bit entry is 0 and it is ABI so immutable!
  40          * If we come here directly from a bootloader,
  41          * kernel(text+data+bss+brk) ramdisk, zero_page, command line
  42          * all need to be under the 4G limit.
  43          */
  44         cld
  45         /*
  46          * Test KEEP_SEGMENTS flag to see if the bootloader is asking
  47          * us to not reload segments
  48          */
  49         testb $(1<<6), BP_loadflags(%esi)
  50         jnz 1f
  51
  52         cli
  53         movl    $(__BOOT_DS), %eax
  54         movl    %eax, %ds
  55         movl    %eax, %es
  56         movl    %eax, %ss
  57 1:
  58
  59 /*
  60  * Calculate the delta between where we were compiled to run
  61  * at and where we were actually loaded at.  This can only be done
  62  * with a short local call on x86.  Nothing  else will tell us what
  63  * address we are running at.  The reserved chunk of the real-mode
  64  * data at 0x1e4 (defined as a scratch field) are used as the stack
  65  * for this calculation. Only 4 bytes are needed.
  66  */
  67         leal    (BP_scratch+4)(%esi), %esp
  68         call    1f
  69 1:      popl    %ebp
  70         subl    $1b, %ebp
  71
  72 /* setup a stack and make sure cpu supports long mode. */
  73         movl    $boot_stack_end, %eax
  74         addl    %ebp, %eax
  75         movl    %eax, %esp
  76
  77         call    verify_cpu
  78         testl   %eax, %eax
  79         jnz     no_longmode
  80
  81 /*
  82  * Compute the delta between where we were compiled to run at
  83  * and where the code will actually run at.
  84  *
  85  * %ebp contains the address we are loaded at by the boot loader and %ebx
  86  * contains the address where we should move the kernel image temporarily
  87  * for safe in-place decompression.
  88  */
  89
  90 #ifdef CONFIG_RELOCATABLE
  91         movl    %ebp, %ebx
  92         movl    BP_kernel_alignment(%esi), %eax
  93         decl    %eax
  94         addl    %eax, %ebx
  95         notl    %eax
  96         andl    %eax, %ebx
  97         cmpl    $LOAD_PHYSICAL_ADDR, %ebx
  98         jge     1f
  99 #endif
 100         movl    $LOAD_PHYSICAL_ADDR, %ebx
 101 1:
 102
 103         /* Target address to relocate to for decompression */
 104         addl    $z_extract_offset, %ebx
 105
 106 /*
 107  * Prepare for entering 64 bit mode
 108  */
 109
 110         /* Load new GDT with the 64bit segments using 32bit descriptor */
 111         leal    gdt(%ebp), %eax
 112         movl    %eax, gdt+2(%ebp)
 113         lgdt    gdt(%ebp)
 114
 115         /* Enable PAE mode */
 116         movl    $(X86_CR4_PAE), %eax
 117         movl    %eax, %cr4
 118
 119  /*
 120   * Build early 4G boot pagetable
 121   */
 122         /* Initialize Page tables to 0 */
 123         leal    pgtable(%ebx), %edi
 124         xorl    %eax, %eax
 125         movl    $((4096*6)/4), %ecx
 126         rep     stosl
 127
 128         /* Build Level 4 */
 129         leal    pgtable + 0(%ebx), %edi
 130         leal    0x1007 (%edi), %eax
 131         movl    %eax, 0(%edi)
 132
 133         /* Build Level 3 */
 134         leal    pgtable + 0x1000(%ebx), %edi
 135         leal    0x1007(%edi), %eax
 136         movl    $4, %ecx
 137 1:      movl    %eax, 0x00(%edi)
 138         addl    $0x00001000, %eax
 139         addl    $8, %edi
 140         decl    %ecx
 141         jnz     1b
 142
 143         /* Build Level 2 */
 144         leal    pgtable + 0x2000(%ebx), %edi
 145         movl    $0x00000183, %eax
 146         movl    $2048, %ecx
 147 1:      movl    %eax, 0(%edi)
 148         addl    $0x00200000, %eax
 149         addl    $8, %edi
 150         decl    %ecx
 151         jnz     1b
 152
 153         /* Enable the boot page tables */
 154         leal    pgtable(%ebx), %eax
 155         movl    %eax, %cr3
 156
 157         /* Enable Long mode in EFER (Extended Feature Enable Register) */
 158         movl    $MSR_EFER, %ecx
 159         rdmsr
 160         btsl    $_EFER_LME, %eax
 161         wrmsr
 162
 163         /* After gdt is loaded */
 164         xorl    %eax, %eax
 165         lldt    %ax
 166         movl    $0x20, %eax
 167         ltr     %ax
 168
 169         /*
 170          * Setup for the jump to 64bit mode
 171          *
 172          * When the jump is performend we will be in long mode but
 173          * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
 174          * (and in turn EFER.LMA = 1).  To jump into 64bit mode we use
 175          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
 176          * We place all of the values on our mini stack so lret can
 177          * used to perform that far jump.
 178          */
 179         pushl   $__KERNEL_CS
 180         leal    startup_64(%ebp), %eax
 181         pushl   %eax
 182
 183         /* Enter paged protected Mode, activating Long Mode */
 184         movl    $(X86_CR0_PG | X86_CR0_PE), %eax /* Enable Paging and Protected mode */
 185         movl    %eax, %cr0
 186
 187         /* Jump from 32bit compatibility mode into 64bit mode. */
 188         lret
 189 ENDPROC(startup_32)
 190
 191         .code64
 192         .org 0x200
 193 ENTRY(startup_64)
 194         /*
 195          * 64bit entry is 0x200 and it is ABI so immutable!
 196          * We come here either from startup_32 or directly from a
 197          * 64bit bootloader.
 198          * If we come here from a bootloader, kernel(text+data+bss+brk),
 199          * ramdisk, zero_page, command line could be above 4G.
 200          * We depend on an identity mapped page table being provided
 201          * that maps our entire kernel(text+data+bss+brk), zero page
 202          * and command line.
 203          */
 204 #ifdef CONFIG_EFI_STUB
 205         /*
 206          * The entry point for the PE/COFF executable is efi_pe_entry, so
 207          * only legacy boot loaders will execute this jmp.
 208          */
 209         jmp     preferred_addr
 210
 211 ENTRY(efi_pe_entry)
 212         mov     %rcx, %rdi
 213         mov     %rdx, %rsi
 214         pushq   %rdi
 215         pushq   %rsi
 216         call    make_boot_params
 217         cmpq    $0,%rax
 218         je      1f
 219         mov     %rax, %rdx
 220         leaq    startup_32(%rip), %rax
 221         movl    %eax, BP_code32_start(%rdx)
 222         popq    %rsi
 223         popq    %rdi
 224
 225 ENTRY(efi_stub_entry)
 226         call    efi_main
 227         movq    %rax,%rsi
 228         cmpq    $0,%rax
 229         jne     2f
 230 1:
 231         /* EFI init failed, so hang. */
 232         hlt
 233         jmp     1b
 234 2:
 235         movl    BP_code32_start(%esi), %eax
 236         leaq    preferred_addr(%rax), %rax
 237         jmp     *%rax
 238
 239 preferred_addr:
 240 #endif
 241
 242         /* Setup data segments. */
 243         xorl    %eax, %eax
 244         movl    %eax, %ds
 245         movl    %eax, %es
 246         movl    %eax, %ss
 247         movl    %eax, %fs
 248         movl    %eax, %gs
 249
 250         /*
 251          * Compute the decompressed kernel start address.  It is where
 252          * we were loaded at aligned to a 2M boundary. %rbp contains the
 253          * decompressed kernel start address.
 254          *
 255          * If it is a relocatable kernel then decompress and run the kernel
 256          * from load address aligned to 2MB addr, otherwise decompress and
 257          * run the kernel from LOAD_PHYSICAL_ADDR
 258          *
 259          * We cannot rely on the calculation done in 32-bit mode, since we
 260          * may have been invoked via the 64-bit entry point.
 261          */
 262
 263         /* Start with the delta to where the kernel will run at. */
 264 #ifdef CONFIG_RELOCATABLE
 265         leaq    startup_32(%rip) /* - $startup_32 */, %rbp
 266         movl    BP_kernel_alignment(%rsi), %eax
 267         decl    %eax
 268         addq    %rax, %rbp
 269         notq    %rax
 270         andq    %rax, %rbp
 271         cmpq    $LOAD_PHYSICAL_ADDR, %rbp
 272         jge     1f
 273 #endif
 274         movq    $LOAD_PHYSICAL_ADDR, %rbp
 275 1:
 276
 277         /* Target address to relocate to for decompression */
 278         leaq    z_extract_offset(%rbp), %rbx
 279
 280         /* Set up the stack */
 281         leaq    boot_stack_end(%rbx), %rsp
 282
 283         /* Zero EFLAGS */
 284         pushq   $0
 285         popfq
 286
 287 /*
 288  * Copy the compressed kernel to the end of our buffer
 289  * where decompression in place becomes safe.
 290  */
 291         pushq   %rsi
 292         leaq    (_bss-8)(%rip), %rsi
 293         leaq    (_bss-8)(%rbx), %rdi
 294         movq    $_bss /* - $startup_32 */, %rcx
 295         shrq    $3, %rcx
 296         std
 297         rep     movsq
 298         cld
 299         popq    %rsi
 300
 301 /*
 302  * Jump to the relocated address.
 303  */
 304         leaq    relocated(%rbx), %rax
 305         jmp     *%rax
 306
 307         .text
 308 relocated:
 309
 310 /*
 311  * Clear BSS (stack is currently empty)
 312  */
 313         xorl    %eax, %eax
 314         leaq    _bss(%rip), %rdi
 315         leaq    _ebss(%rip), %rcx
 316         subq    %rdi, %rcx
 317         shrq    $3, %rcx
 318         rep     stosq
 319
 320 /*
 321  * Adjust our own GOT
 322  */
 323         leaq    _got(%rip), %rdx
 324         leaq    _egot(%rip), %rcx
 325 1:
 326         cmpq    %rcx, %rdx
 327         jae     2f
 328         addq    %rbx, (%rdx)
 329         addq    $8, %rdx
 330         jmp     1b
 331 2:
 332
 333 /*
 334  * Do the decompression, and jump to the new kernel..
 335  */
 336         pushq   %rsi                    /* Save the real mode argument */
 337         movq    %rsi, %rdi              /* real mode address */
 338         leaq    boot_heap(%rip), %rsi   /* malloc area for uncompression */
 339         leaq    input_data(%rip), %rdx  /* input_data */
 340         movl    $z_input_len, %ecx      /* input_len */
 341         movq    %rbp, %r8               /* output target address */
 342         movq    $z_output_len, %r9      /* decompressed length */
 343         call    decompress_kernel       /* returns kernel location in %rax */
 344         popq    %rsi
 345
 346 /*
 347  * Jump to the decompressed kernel.
 348  */
 349         jmp     *%rax
 350
 351         .code32
 352 no_longmode:
 353         /* This isn't an x86-64 CPU so hang */
 354 1:
 355         hlt
 356         jmp     1b
 357
 358 #include "../../kernel/verify_cpu.S"
 359
 360         .data
 361 gdt:
 362         .word   gdt_end - gdt
 363         .long   gdt
 364         .word   0
 365         .quad   0x0000000000000000      /* NULL descriptor */
 366         .quad   0x00af9a000000ffff      /* __KERNEL_CS */
 367         .quad   0x00cf92000000ffff      /* __KERNEL_DS */
 368         .quad   0x0080890000000000      /* TS descriptor */
 369         .quad   0x0000000000000000      /* TS continued */
 370 gdt_end:
 371
 372 /*
 373  * Stack and heap for uncompression
 374  */
 375         .bss
 376         .balign 4
 377 boot_heap:
 378         .fill BOOT_HEAP_SIZE, 1, 0
 379 boot_stack:
 380         .fill BOOT_STACK_SIZE, 1, 0
 381 boot_stack_end:
 382
 383 /*
 384  * Space for page tables (not in .bss so not zeroed)
 385  */
 386         .section ".pgtable","a",@nobits
 387         .balign 4096
 388 pgtable:
 389         .fill 6*4096, 1, 0