arch/s390/kernel/entry64.S

   1 /*
   2  *    S390 low-level entry points.
   3  *
   4  *    Copyright IBM Corp. 1999, 2012
   5  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   6  *               Hartmut Penner (hp@de.ibm.com),
   7  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   8  *               Heiko Carstens <heiko.carstens@de.ibm.com>
   9  */
  10
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/cache.h>
  14 #include <asm/errno.h>
  15 #include <asm/ptrace.h>
  16 #include <asm/thread_info.h>
  17 #include <asm/asm-offsets.h>
  18 #include <asm/unistd.h>
  19 #include <asm/page.h>
  20 #include <asm/sigp.h>
  21
  22 __PT_R0      =  __PT_GPRS
  23 __PT_R1      =  __PT_GPRS + 8
  24 __PT_R2      =  __PT_GPRS + 16
  25 __PT_R3      =  __PT_GPRS + 24
  26 __PT_R4      =  __PT_GPRS + 32
  27 __PT_R5      =  __PT_GPRS + 40
  28 __PT_R6      =  __PT_GPRS + 48
  29 __PT_R7      =  __PT_GPRS + 56
  30 __PT_R8      =  __PT_GPRS + 64
  31 __PT_R9      =  __PT_GPRS + 72
  32 __PT_R10     =  __PT_GPRS + 80
  33 __PT_R11     =  __PT_GPRS + 88
  34 __PT_R12     =  __PT_GPRS + 96
  35 __PT_R13     =  __PT_GPRS + 104
  36 __PT_R14     =  __PT_GPRS + 112
  37 __PT_R15     =  __PT_GPRS + 120
  38
  39 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  40 STACK_SIZE  = 1 << STACK_SHIFT
  41
  42 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  43                  _TIF_MCCK_PENDING | _TIF_PER_TRAP )
  44 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  45                  _TIF_MCCK_PENDING)
  46 _TIF_TRACE    = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
  47                  _TIF_SYSCALL_TRACEPOINT)
  48 _TIF_EXIT_SIE = (_TIF_SIGPENDING | _TIF_NEED_RESCHED | _TIF_MCCK_PENDING)
  49
  50 #define BASED(name) name-system_call(%r13)
  51
  52         .macro  TRACE_IRQS_ON
  53 #ifdef CONFIG_TRACE_IRQFLAGS
  54         basr    %r2,%r0
  55         brasl   %r14,trace_hardirqs_on_caller
  56 #endif
  57         .endm
  58
  59         .macro  TRACE_IRQS_OFF
  60 #ifdef CONFIG_TRACE_IRQFLAGS
  61         basr    %r2,%r0
  62         brasl   %r14,trace_hardirqs_off_caller
  63 #endif
  64         .endm
  65
  66         .macro  LOCKDEP_SYS_EXIT
  67 #ifdef CONFIG_LOCKDEP
  68         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
  69         jz      .+10
  70         brasl   %r14,lockdep_sys_exit
  71 #endif
  72         .endm
  73
  74         .macro SPP newpp
  75 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
  76         tm      __LC_MACHINE_FLAGS+6,0x20       # MACHINE_FLAG_SPP
  77         jz      .+8
  78         .insn   s,0xb2800000,\newpp
  79 #endif
  80         .endm
  81
  82         .macro  HANDLE_SIE_INTERCEPT scratch
  83 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
  84         tmhh    %r8,0x0001              # interrupting from user ?
  85         jnz     .+42
  86         lgr     \scratch,%r9
  87         slg     \scratch,BASED(.Lsie_loop)
  88         clg     \scratch,BASED(.Lsie_length)
  89         jhe     .+22
  90         lg      %r9,BASED(.Lsie_loop)
  91         SPP     BASED(.Lhost_id)        # set host id
  92 #endif
  93         .endm
  94
  95         .macro  CHECK_STACK stacksize,savearea
  96 #ifdef CONFIG_CHECK_STACK
  97         tml     %r15,\stacksize - CONFIG_STACK_GUARD
  98         lghi    %r14,\savearea
  99         jz      stack_overflow
 100 #endif
 101         .endm
 102
 103         .macro  SWITCH_ASYNC savearea,stack,shift
 104         tmhh    %r8,0x0001              # interrupting from user ?
 105         jnz     1f
 106         lgr     %r14,%r9
 107         slg     %r14,BASED(.Lcritical_start)
 108         clg     %r14,BASED(.Lcritical_length)
 109         jhe     0f
 110         lghi    %r11,\savearea          # inside critical section, do cleanup
 111         brasl   %r14,cleanup_critical
 112         tmhh    %r8,0x0001              # retest problem state after cleanup
 113         jnz     1f
 114 0:      lg      %r14,\stack             # are we already on the target stack?
 115         slgr    %r14,%r15
 116         srag    %r14,%r14,\shift
 117         jnz     1f
 118         CHECK_STACK 1<<\shift,\savearea
 119         j       2f
 120 1:      lg      %r15,\stack             # load target stack
 121 2:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 122         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 123         .endm
 124
 125         .macro UPDATE_VTIME scratch,enter_timer
 126         lg      \scratch,__LC_EXIT_TIMER
 127         slg     \scratch,\enter_timer
 128         alg     \scratch,__LC_USER_TIMER
 129         stg     \scratch,__LC_USER_TIMER
 130         lg      \scratch,__LC_LAST_UPDATE_TIMER
 131         slg     \scratch,__LC_EXIT_TIMER
 132         alg     \scratch,__LC_SYSTEM_TIMER
 133         stg     \scratch,__LC_SYSTEM_TIMER
 134         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
 135         .endm
 136
 137         .macro  LAST_BREAK scratch
 138         srag    \scratch,%r10,23
 139         jz      .+10
 140         stg     %r10,__TI_last_break(%r12)
 141         .endm
 142
 143         .macro REENABLE_IRQS
 144         stg     %r8,__LC_RETURN_PSW
 145         ni      __LC_RETURN_PSW,0xbf
 146         ssm     __LC_RETURN_PSW
 147         .endm
 148
 149         .macro STCK savearea
 150 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
 151         .insn   s,0xb27c0000,\savearea          # store clock fast
 152 #else
 153         .insn   s,0xb2050000,\savearea          # store clock
 154 #endif
 155         .endm
 156
 157         .section .kprobes.text, "ax"
 158
 159 /*
 160  * Scheduler resume function, called by switch_to
 161  *  gpr2 = (task_struct *) prev
 162  *  gpr3 = (task_struct *) next
 163  * Returns:
 164  *  gpr2 = prev
 165  */
 166 ENTRY(__switch_to)
 167         stmg    %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
 168         stg     %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
 169         lg      %r4,__THREAD_info(%r2)          # get thread_info of prev
 170         lg      %r5,__THREAD_info(%r3)          # get thread_info of next
 171         lgr     %r15,%r5
 172         aghi    %r15,STACK_SIZE                 # end of kernel stack of next
 173         stg     %r3,__LC_CURRENT                # store task struct of next
 174         stg     %r5,__LC_THREAD_INFO            # store thread info of next
 175         stg     %r15,__LC_KERNEL_STACK          # store end of kernel stack
 176         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
 177         mvc     __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
 178         lg      %r15,__THREAD_ksp(%r3)          # load kernel stack of next
 179         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
 180         jz      0f
 181         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 182         oi      __TI_flags+7(%r5),_TIF_MCCK_PENDING     # set it in next
 183 0:      lmg     %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
 184         br      %r14
 185
 186 __critical_start:
 187 /*
 188  * SVC interrupt handler routine. System calls are synchronous events and
 189  * are executed with interrupts enabled.
 190  */
 191
 192 ENTRY(system_call)
 193         stpt    __LC_SYNC_ENTER_TIMER
 194 sysc_stmg:
 195         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 196         lg      %r10,__LC_LAST_BREAK
 197         lg      %r12,__LC_THREAD_INFO
 198         larl    %r13,system_call
 199 sysc_per:
 200         lg      %r15,__LC_KERNEL_STACK
 201         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 202         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
 203 sysc_vtime:
 204         UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
 205         LAST_BREAK %r13
 206         stmg    %r0,%r7,__PT_R0(%r11)
 207         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 208         mvc     __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
 209         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
 210 sysc_do_svc:
 211         oi      __TI_flags+7(%r12),_TIF_SYSCALL
 212         llgh    %r8,__PT_INT_CODE+2(%r11)
 213         slag    %r8,%r8,2                       # shift and test for svc 0
 214         jnz     sysc_nr_ok
 215         # svc 0: system call number in %r1
 216         llgfr   %r1,%r1                         # clear high word in r1
 217         cghi    %r1,NR_syscalls
 218         jnl     sysc_nr_ok
 219         sth     %r1,__PT_INT_CODE+2(%r11)
 220         slag    %r8,%r1,2
 221 sysc_nr_ok:
 222         larl    %r10,sys_call_table             # 64 bit system call table
 223 #ifdef CONFIG_COMPAT
 224         tm      __TI_flags+5(%r12),(_TIF_31BIT>>16)
 225         jno     sysc_noemu
 226         larl    %r10,sys_call_table_emu         # 31 bit system call table
 227 sysc_noemu:
 228 #endif
 229         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 230         stg     %r2,__PT_ORIG_GPR2(%r11)
 231         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 232         lgf     %r9,0(%r8,%r10)                 # get system call add.
 233         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
 234         jnz     sysc_tracesys
 235         basr    %r14,%r9                        # call sys_xxxx
 236         stg     %r2,__PT_R2(%r11)               # store return value
 237
 238 sysc_return:
 239         LOCKDEP_SYS_EXIT
 240 sysc_tif:
 241         tm      __PT_PSW+1(%r11),0x01           # returning to user ?
 242         jno     sysc_restore
 243         tm      __TI_flags+7(%r12),_TIF_WORK_SVC
 244         jnz     sysc_work                       # check for work
 245         ni      __TI_flags+7(%r12),255-_TIF_SYSCALL
 246 sysc_restore:
 247         lg      %r14,__LC_VDSO_PER_CPU
 248         lmg     %r0,%r10,__PT_R0(%r11)
 249         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 250         stpt    __LC_EXIT_TIMER
 251         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 252         lmg     %r11,%r15,__PT_R11(%r11)
 253         lpswe   __LC_RETURN_PSW
 254 sysc_done:
 255
 256 #
 257 # One of the work bits is on. Find out which one.
 258 #
 259 sysc_work:
 260         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 261         jo      sysc_mcck_pending
 262         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 263         jo      sysc_reschedule
 264         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 265         jo      sysc_sigpending
 266         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 267         jo      sysc_notify_resume
 268         tm      __TI_flags+7(%r12),_TIF_PER_TRAP
 269         jo      sysc_singlestep
 270         j       sysc_return             # beware of critical section cleanup
 271
 272 #
 273 # _TIF_NEED_RESCHED is set, call schedule
 274 #
 275 sysc_reschedule:
 276         larl    %r14,sysc_return
 277         jg      schedule
 278
 279 #
 280 # _TIF_MCCK_PENDING is set, call handler
 281 #
 282 sysc_mcck_pending:
 283         larl    %r14,sysc_return
 284         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 285
 286 #
 287 # _TIF_SIGPENDING is set, call do_signal
 288 #
 289 sysc_sigpending:
 290         ni      __TI_flags+7(%r12),255-_TIF_PER_TRAP # clear TIF_PER_TRAP
 291         lgr     %r2,%r11                # pass pointer to pt_regs
 292         brasl   %r14,do_signal
 293         tm      __TI_flags+7(%r12),_TIF_SYSCALL
 294         jno     sysc_return
 295         lmg     %r2,%r7,__PT_R2(%r11)   # load svc arguments
 296         lghi    %r8,0                   # svc 0 returns -ENOSYS
 297         lh      %r1,__PT_INT_CODE+2(%r11)       # load new svc number
 298         cghi    %r1,NR_syscalls
 299         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
 300         slag    %r8,%r1,2
 301         j       sysc_nr_ok              # restart svc
 302
 303 #
 304 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 305 #
 306 sysc_notify_resume:
 307         lgr     %r2,%r11                # pass pointer to pt_regs
 308         larl    %r14,sysc_return
 309         jg      do_notify_resume
 310
 311 #
 312 # _TIF_PER_TRAP is set, call do_per_trap
 313 #
 314 sysc_singlestep:
 315         ni      __TI_flags+7(%r12),255-(_TIF_SYSCALL | _TIF_PER_TRAP)
 316         lgr     %r2,%r11                # pass pointer to pt_regs
 317         larl    %r14,sysc_return
 318         jg      do_per_trap
 319
 320 #
 321 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 322 # and after the system call
 323 #
 324 sysc_tracesys:
 325         lgr     %r2,%r11                # pass pointer to pt_regs
 326         la      %r3,0
 327         llgh    %r0,__PT_INT_CODE+2(%r11)
 328         stg     %r0,__PT_R2(%r11)
 329         brasl   %r14,do_syscall_trace_enter
 330         lghi    %r0,NR_syscalls
 331         clgr    %r0,%r2
 332         jnh     sysc_tracenogo
 333         sllg    %r8,%r2,2
 334         lgf     %r9,0(%r8,%r10)
 335 sysc_tracego:
 336         lmg     %r3,%r7,__PT_R3(%r11)
 337         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 338         lg      %r2,__PT_ORIG_GPR2(%r11)
 339         basr    %r14,%r9                # call sys_xxx
 340         stg     %r2,__PT_R2(%r11)       # store return value
 341 sysc_tracenogo:
 342         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
 343         jz      sysc_return
 344         lgr     %r2,%r11                # pass pointer to pt_regs
 345         larl    %r14,sysc_return
 346         jg      do_syscall_trace_exit
 347
 348 #
 349 # a new process exits the kernel with ret_from_fork
 350 #
 351 ENTRY(ret_from_fork)
 352         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 353         lg      %r12,__LC_THREAD_INFO
 354         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
 355         jo      0f
 356         stg     %r15,__PT_R15(%r11)     # store stack pointer for new kthread
 357 0:      brasl   %r14,schedule_tail
 358         TRACE_IRQS_ON
 359         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 360         j       sysc_tracenogo
 361
 362 #
 363 # kernel_execve function needs to deal with pt_regs that is not
 364 # at the usual place
 365 #
 366 ENTRY(kernel_execve)
 367         stmg    %r12,%r15,96(%r15)
 368         lgr     %r14,%r15
 369         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 370         stg     %r14,__SF_BACKCHAIN(%r15)
 371         la      %r12,STACK_FRAME_OVERHEAD(%r15)
 372         xc      0(__PT_SIZE,%r12),0(%r12)
 373         lgr     %r5,%r12
 374         brasl   %r14,do_execve
 375         ltgfr   %r2,%r2
 376         je      0f
 377         aghi    %r15,(STACK_FRAME_OVERHEAD + __PT_SIZE)
 378         lmg     %r12,%r15,96(%r15)
 379         br      %r14
 380         # execve succeeded.
 381 0:      ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 382         lg      %r15,__LC_KERNEL_STACK  # load ksp
 383         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 384         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 385         mvc     0(__PT_SIZE,%r11),0(%r12)       # copy pt_regs
 386         lg      %r12,__LC_THREAD_INFO
 387         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 388         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 389         brasl   %r14,execve_tail
 390         j       sysc_return
 391
 392 /*
 393  * Program check handler routine
 394  */
 395
 396 ENTRY(pgm_check_handler)
 397         stpt    __LC_SYNC_ENTER_TIMER
 398         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 399         lg      %r10,__LC_LAST_BREAK
 400         lg      %r12,__LC_THREAD_INFO
 401         larl    %r13,system_call
 402         lmg     %r8,%r9,__LC_PGM_OLD_PSW
 403         HANDLE_SIE_INTERCEPT %r14
 404         tmhh    %r8,0x0001              # test problem state bit
 405         jnz     1f                      # -> fault in user space
 406         tmhh    %r8,0x4000              # PER bit set in old PSW ?
 407         jnz     0f                      # -> enabled, can't be a double fault
 408         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 409         jnz     pgm_svcper              # -> single stepped svc
 410 0:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
 411         j       2f
 412 1:      UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
 413         LAST_BREAK %r14
 414         lg      %r15,__LC_KERNEL_STACK
 415         lg      %r14,__TI_task(%r12)
 416         lghi    %r13,__LC_PGM_TDB
 417         tm      __LC_PGM_ILC+2,0x02     # check for transaction abort
 418         jz      2f
 419         mvc     __THREAD_trap_tdb(256,%r14),0(%r13)
 420 2:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 421         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 422         stmg    %r0,%r7,__PT_R0(%r11)
 423         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 424         stmg    %r8,%r9,__PT_PSW(%r11)
 425         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
 426         mvc     __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
 427         stg     %r10,__PT_ARGS(%r11)
 428         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 429         jz      0f
 430         tmhh    %r8,0x0001              # kernel per event ?
 431         jz      pgm_kprobe
 432         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
 433         mvc     __THREAD_per_address(8,%r14),__LC_PER_ADDRESS
 434         mvc     __THREAD_per_cause(2,%r14),__LC_PER_CAUSE
 435         mvc     __THREAD_per_paid(1,%r14),__LC_PER_PAID
 436 0:      REENABLE_IRQS
 437         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 438         larl    %r1,pgm_check_table
 439         llgh    %r10,__PT_INT_CODE+2(%r11)
 440         nill    %r10,0x007f
 441         sll     %r10,3
 442         je      sysc_return
 443         lg      %r1,0(%r10,%r1)         # load address of handler routine
 444         lgr     %r2,%r11                # pass pointer to pt_regs
 445         basr    %r14,%r1                # branch to interrupt-handler
 446         j       sysc_return
 447
 448 #
 449 # PER event in supervisor state, must be kprobes
 450 #
 451 pgm_kprobe:
 452         REENABLE_IRQS
 453         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 454         lgr     %r2,%r11                # pass pointer to pt_regs
 455         brasl   %r14,do_per_trap
 456         j       sysc_return
 457
 458 #
 459 # single stepped system call
 460 #
 461 pgm_svcper:
 462         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
 463         mvc     __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
 464         larl    %r14,sysc_per
 465         stg     %r14,__LC_RETURN_PSW+8
 466         lpswe   __LC_RETURN_PSW         # branch to sysc_per and enable irqs
 467
 468 /*
 469  * IO interrupt handler routine
 470  */
 471 ENTRY(io_int_handler)
 472         STCK    __LC_INT_CLOCK
 473         stpt    __LC_ASYNC_ENTER_TIMER
 474         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 475         lg      %r10,__LC_LAST_BREAK
 476         lg      %r12,__LC_THREAD_INFO
 477         larl    %r13,system_call
 478         lmg     %r8,%r9,__LC_IO_OLD_PSW
 479         HANDLE_SIE_INTERCEPT %r14
 480         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 481         tmhh    %r8,0x0001              # interrupting from user?
 482         jz      io_skip
 483         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
 484         LAST_BREAK %r14
 485 io_skip:
 486         stmg    %r0,%r7,__PT_R0(%r11)
 487         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 488         stmg    %r8,%r9,__PT_PSW(%r11)
 489         TRACE_IRQS_OFF
 490         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 491         lgr     %r2,%r11                # pass pointer to pt_regs
 492         brasl   %r14,do_IRQ
 493 io_return:
 494         LOCKDEP_SYS_EXIT
 495         TRACE_IRQS_ON
 496 io_tif:
 497         tm      __TI_flags+7(%r12),_TIF_WORK_INT
 498         jnz     io_work                 # there is work to do (signals etc.)
 499 io_restore:
 500         lg      %r14,__LC_VDSO_PER_CPU
 501         lmg     %r0,%r10,__PT_R0(%r11)
 502         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 503         stpt    __LC_EXIT_TIMER
 504         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 505         lmg     %r11,%r15,__PT_R11(%r11)
 506         lpswe   __LC_RETURN_PSW
 507 io_done:
 508
 509 #
 510 # There is work todo, find out in which context we have been interrupted:
 511 # 1) if we return to user space we can do all _TIF_WORK_INT work
 512 # 2) if we return to kernel code and kvm is enabled check if we need to
 513 #    modify the psw to leave SIE
 514 # 3) if we return to kernel code and preemptive scheduling is enabled check
 515 #    the preemption counter and if it is zero call preempt_schedule_irq
 516 # Before any work can be done, a switch to the kernel stack is required.
 517 #
 518 io_work:
 519         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 520         jo      io_work_user            # yes -> do resched & signal
 521 #ifdef CONFIG_PREEMPT
 522         # check for preemptive scheduling
 523         icm     %r0,15,__TI_precount(%r12)
 524         jnz     io_restore              # preemption is disabled
 525         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 526         jno     io_restore
 527         # switch to kernel stack
 528         lg      %r1,__PT_R15(%r11)
 529         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 530         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 531         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 532         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 533         lgr     %r15,%r1
 534         # TRACE_IRQS_ON already done at io_return, call
 535         # TRACE_IRQS_OFF to keep things symmetrical
 536         TRACE_IRQS_OFF
 537         brasl   %r14,preempt_schedule_irq
 538         j       io_return
 539 #else
 540         j       io_restore
 541 #endif
 542
 543 #
 544 # Need to do work before returning to userspace, switch to kernel stack
 545 #
 546 io_work_user:
 547         lg      %r1,__LC_KERNEL_STACK
 548         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 549         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 550         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 551         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 552         lgr     %r15,%r1
 553
 554 #
 555 # One of the work bits is on. Find out which one.
 556 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 557 #              and _TIF_MCCK_PENDING
 558 #
 559 io_work_tif:
 560         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 561         jo      io_mcck_pending
 562         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 563         jo      io_reschedule
 564         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 565         jo      io_sigpending
 566         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 567         jo      io_notify_resume
 568         j       io_return               # beware of critical section cleanup
 569
 570 #
 571 # _TIF_MCCK_PENDING is set, call handler
 572 #
 573 io_mcck_pending:
 574         # TRACE_IRQS_ON already done at io_return
 575         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
 576         TRACE_IRQS_OFF
 577         j       io_return
 578
 579 #
 580 # _TIF_NEED_RESCHED is set, call schedule
 581 #
 582 io_reschedule:
 583         # TRACE_IRQS_ON already done at io_return
 584         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 585         brasl   %r14,schedule           # call scheduler
 586         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 587         TRACE_IRQS_OFF
 588         j       io_return
 589
 590 #
 591 # _TIF_SIGPENDING or is set, call do_signal
 592 #
 593 io_sigpending:
 594         # TRACE_IRQS_ON already done at io_return
 595         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 596         lgr     %r2,%r11                # pass pointer to pt_regs
 597         brasl   %r14,do_signal
 598         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 599         TRACE_IRQS_OFF
 600         j       io_return
 601
 602 #
 603 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
 604 #
 605 io_notify_resume:
 606         # TRACE_IRQS_ON already done at io_return
 607         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 608         lgr     %r2,%r11                # pass pointer to pt_regs
 609         brasl   %r14,do_notify_resume
 610         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 611         TRACE_IRQS_OFF
 612         j       io_return
 613
 614 /*
 615  * External interrupt handler routine
 616  */
 617 ENTRY(ext_int_handler)
 618         STCK    __LC_INT_CLOCK
 619         stpt    __LC_ASYNC_ENTER_TIMER
 620         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 621         lg      %r10,__LC_LAST_BREAK
 622         lg      %r12,__LC_THREAD_INFO
 623         larl    %r13,system_call
 624         lmg     %r8,%r9,__LC_EXT_OLD_PSW
 625         HANDLE_SIE_INTERCEPT %r14
 626         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 627         tmhh    %r8,0x0001              # interrupting from user ?
 628         jz      ext_skip
 629         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
 630         LAST_BREAK %r14
 631 ext_skip:
 632         stmg    %r0,%r7,__PT_R0(%r11)
 633         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 634         stmg    %r8,%r9,__PT_PSW(%r11)
 635         TRACE_IRQS_OFF
 636         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 637         lghi    %r1,4096
 638         lgr     %r2,%r11                # pass pointer to pt_regs
 639         llgf    %r3,__LC_EXT_CPU_ADDR   # get cpu address + interruption code
 640         llgf    %r4,__LC_EXT_PARAMS     # get external parameter
 641         lg      %r5,__LC_EXT_PARAMS2-4096(%r1)  # get 64 bit external parameter
 642         brasl   %r14,do_extint
 643         j       io_return
 644
 645 /*
 646  * Load idle PSW. The second "half" of this function is in cleanup_idle.
 647  */
 648 ENTRY(psw_idle)
 649         stg     %r3,__SF_EMPTY(%r15)
 650         larl    %r1,psw_idle_lpsw+4
 651         stg     %r1,__SF_EMPTY+8(%r15)
 652         STCK    __CLOCK_IDLE_ENTER(%r2)
 653         stpt    __TIMER_IDLE_ENTER(%r2)
 654 psw_idle_lpsw:
 655         lpswe   __SF_EMPTY(%r15)
 656         br      %r14
 657 psw_idle_end:
 658
 659 __critical_end:
 660
 661 /*
 662  * Machine check handler routines
 663  */
 664 ENTRY(mcck_int_handler)
 665         STCK    __LC_MCCK_CLOCK
 666         la      %r1,4095                # revalidate r1
 667         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 668         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 669         lg      %r10,__LC_LAST_BREAK
 670         lg      %r12,__LC_THREAD_INFO
 671         larl    %r13,system_call
 672         lmg     %r8,%r9,__LC_MCK_OLD_PSW
 673         HANDLE_SIE_INTERCEPT %r14
 674         tm      __LC_MCCK_CODE,0x80     # system damage?
 675         jo      mcck_panic              # yes -> rest of mcck code invalid
 676         lghi    %r14,__LC_CPU_TIMER_SAVE_AREA
 677         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 678         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 679         jo      3f
 680         la      %r14,__LC_SYNC_ENTER_TIMER
 681         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 682         jl      0f
 683         la      %r14,__LC_ASYNC_ENTER_TIMER
 684 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 685         jl      1f
 686         la      %r14,__LC_EXIT_TIMER
 687 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 688         jl      2f
 689         la      %r14,__LC_LAST_UPDATE_TIMER
 690 2:      spt     0(%r14)
 691         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 692 3:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 693         jno     mcck_panic              # no -> skip cleanup critical
 694         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
 695         tm      %r8,0x0001              # interrupting from user ?
 696         jz      mcck_skip
 697         UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
 698         LAST_BREAK %r14
 699 mcck_skip:
 700         lghi    %r14,__LC_GPREGS_SAVE_AREA
 701         mvc     __PT_R0(128,%r11),0(%r14)
 702         stmg    %r8,%r9,__PT_PSW(%r11)
 703         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 704         lgr     %r2,%r11                # pass pointer to pt_regs
 705         brasl   %r14,s390_do_machine_check
 706         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 707         jno     mcck_return
 708         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 709         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 710         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 711         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 712         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 713         lgr     %r15,%r1
 714         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
 715         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 716         jno     mcck_return
 717         TRACE_IRQS_OFF
 718         brasl   %r14,s390_handle_mcck
 719         TRACE_IRQS_ON
 720 mcck_return:
 721         lg      %r14,__LC_VDSO_PER_CPU
 722         lmg     %r0,%r10,__PT_R0(%r11)
 723         mvc     __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
 724         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 725         jno     0f
 726         stpt    __LC_EXIT_TIMER
 727         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 728 0:      lmg     %r11,%r15,__PT_R11(%r11)
 729         lpswe   __LC_RETURN_MCCK_PSW
 730
 731 mcck_panic:
 732         lg      %r14,__LC_PANIC_STACK
 733         slgr    %r14,%r15
 734         srag    %r14,%r14,PAGE_SHIFT
 735         jz      0f
 736         lg      %r15,__LC_PANIC_STACK
 737 0:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 738         j       mcck_skip
 739
 740 #
 741 # PSW restart interrupt handler
 742 #
 743 ENTRY(restart_int_handler)
 744         stg     %r15,__LC_SAVE_AREA_RESTART
 745         lg      %r15,__LC_RESTART_STACK
 746         aghi    %r15,-__PT_SIZE                 # create pt_regs on stack
 747         xc      0(__PT_SIZE,%r15),0(%r15)
 748         stmg    %r0,%r14,__PT_R0(%r15)
 749         mvc     __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
 750         mvc     __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
 751         aghi    %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
 752         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
 753         lg      %r1,__LC_RESTART_FN             # load fn, parm & source cpu
 754         lg      %r2,__LC_RESTART_DATA
 755         lg      %r3,__LC_RESTART_SOURCE
 756         ltgr    %r3,%r3                         # test source cpu address
 757         jm      1f                              # negative -> skip source stop
 758 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
 759         brc     10,0b                           # wait for status stored
 760 1:      basr    %r14,%r1                        # call function
 761         stap    __SF_EMPTY(%r15)                # store cpu address
 762         llgh    %r3,__SF_EMPTY(%r15)
 763 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
 764         brc     2,2b
 765 3:      j       3b
 766
 767         .section .kprobes.text, "ax"
 768
 769 #ifdef CONFIG_CHECK_STACK
 770 /*
 771  * The synchronous or the asynchronous stack overflowed. We are dead.
 772  * No need to properly save the registers, we are going to panic anyway.
 773  * Setup a pt_regs so that show_trace can provide a good call trace.
 774  */
 775 stack_overflow:
 776         lg      %r11,__LC_PANIC_STACK   # change to panic stack
 777         aghi    %r11,-__PT_SIZE         # create pt_regs
 778         stmg    %r0,%r7,__PT_R0(%r11)
 779         stmg    %r8,%r9,__PT_PSW(%r11)
 780         mvc     __PT_R8(64,%r11),0(%r14)
 781         stg     %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
 782         lgr     %r15,%r11
 783         aghi    %r15,-STACK_FRAME_OVERHEAD
 784         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 785         lgr     %r2,%r11                # pass pointer to pt_regs
 786         jg      kernel_stack_overflow
 787 #endif
 788
 789         .align  8
 790 cleanup_table:
 791         .quad   system_call
 792         .quad   sysc_do_svc
 793         .quad   sysc_tif
 794         .quad   sysc_restore
 795         .quad   sysc_done
 796         .quad   io_tif
 797         .quad   io_restore
 798         .quad   io_done
 799         .quad   psw_idle
 800         .quad   psw_idle_end
 801
 802 cleanup_critical:
 803         clg     %r9,BASED(cleanup_table)        # system_call
 804         jl      0f
 805         clg     %r9,BASED(cleanup_table+8)      # sysc_do_svc
 806         jl      cleanup_system_call
 807         clg     %r9,BASED(cleanup_table+16)     # sysc_tif
 808         jl      0f
 809         clg     %r9,BASED(cleanup_table+24)     # sysc_restore
 810         jl      cleanup_sysc_tif
 811         clg     %r9,BASED(cleanup_table+32)     # sysc_done
 812         jl      cleanup_sysc_restore
 813         clg     %r9,BASED(cleanup_table+40)     # io_tif
 814         jl      0f
 815         clg     %r9,BASED(cleanup_table+48)     # io_restore
 816         jl      cleanup_io_tif
 817         clg     %r9,BASED(cleanup_table+56)     # io_done
 818         jl      cleanup_io_restore
 819         clg     %r9,BASED(cleanup_table+64)     # psw_idle
 820         jl      0f
 821         clg     %r9,BASED(cleanup_table+72)     # psw_idle_end
 822         jl      cleanup_idle
 823 0:      br      %r14
 824
 825
 826 cleanup_system_call:
 827         # check if stpt has been executed
 828         clg     %r9,BASED(cleanup_system_call_insn)
 829         jh      0f
 830         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 831         cghi    %r11,__LC_SAVE_AREA_ASYNC
 832         je      0f
 833         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
 834 0:      # check if stmg has been executed
 835         clg     %r9,BASED(cleanup_system_call_insn+8)
 836         jh      0f
 837         mvc     __LC_SAVE_AREA_SYNC(64),0(%r11)
 838 0:      # check if base register setup + TIF bit load has been done
 839         clg     %r9,BASED(cleanup_system_call_insn+16)
 840         jhe     0f
 841         # set up saved registers r10 and r12
 842         stg     %r10,16(%r11)           # r10 last break
 843         stg     %r12,32(%r11)           # r12 thread-info pointer
 844 0:      # check if the user time update has been done
 845         clg     %r9,BASED(cleanup_system_call_insn+24)
 846         jh      0f
 847         lg      %r15,__LC_EXIT_TIMER
 848         slg     %r15,__LC_SYNC_ENTER_TIMER
 849         alg     %r15,__LC_USER_TIMER
 850         stg     %r15,__LC_USER_TIMER
 851 0:      # check if the system time update has been done
 852         clg     %r9,BASED(cleanup_system_call_insn+32)
 853         jh      0f
 854         lg      %r15,__LC_LAST_UPDATE_TIMER
 855         slg     %r15,__LC_EXIT_TIMER
 856         alg     %r15,__LC_SYSTEM_TIMER
 857         stg     %r15,__LC_SYSTEM_TIMER
 858 0:      # update accounting time stamp
 859         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 860         # do LAST_BREAK
 861         lg      %r9,16(%r11)
 862         srag    %r9,%r9,23
 863         jz      0f
 864         mvc     __TI_last_break(8,%r12),16(%r11)
 865 0:      # set up saved register r11
 866         lg      %r15,__LC_KERNEL_STACK
 867         aghi    %r15,-__PT_SIZE
 868         stg     %r15,24(%r11)           # r11 pt_regs pointer
 869         # fill pt_regs
 870         mvc     __PT_R8(64,%r15),__LC_SAVE_AREA_SYNC
 871         stmg    %r0,%r7,__PT_R0(%r15)
 872         mvc     __PT_PSW(16,%r15),__LC_SVC_OLD_PSW
 873         mvc     __PT_INT_CODE(4,%r15),__LC_SVC_ILC
 874         # setup saved register r15
 875         aghi    %r15,-STACK_FRAME_OVERHEAD
 876         stg     %r15,56(%r11)           # r15 stack pointer
 877         # set new psw address and exit
 878         larl    %r9,sysc_do_svc
 879         br      %r14
 880 cleanup_system_call_insn:
 881         .quad   system_call
 882         .quad   sysc_stmg
 883         .quad   sysc_per
 884         .quad   sysc_vtime+18
 885         .quad   sysc_vtime+42
 886
 887 cleanup_sysc_tif:
 888         larl    %r9,sysc_tif
 889         br      %r14
 890
 891 cleanup_sysc_restore:
 892         clg     %r9,BASED(cleanup_sysc_restore_insn)
 893         je      0f
 894         lg      %r9,24(%r11)            # get saved pointer to pt_regs
 895         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
 896         mvc     0(64,%r11),__PT_R8(%r9)
 897         lmg     %r0,%r7,__PT_R0(%r9)
 898 0:      lmg     %r8,%r9,__LC_RETURN_PSW
 899         br      %r14
 900 cleanup_sysc_restore_insn:
 901         .quad   sysc_done - 4
 902
 903 cleanup_io_tif:
 904         larl    %r9,io_tif
 905         br      %r14
 906
 907 cleanup_io_restore:
 908         clg     %r9,BASED(cleanup_io_restore_insn)
 909         je      0f
 910         lg      %r9,24(%r11)            # get saved r11 pointer to pt_regs
 911         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
 912         mvc     0(64,%r11),__PT_R8(%r9)
 913         lmg     %r0,%r7,__PT_R0(%r9)
 914 0:      lmg     %r8,%r9,__LC_RETURN_PSW
 915         br      %r14
 916 cleanup_io_restore_insn:
 917         .quad   io_done - 4
 918
 919 cleanup_idle:
 920         # copy interrupt clock & cpu timer
 921         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
 922         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
 923         cghi    %r11,__LC_SAVE_AREA_ASYNC
 924         je      0f
 925         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
 926         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
 927 0:      # check if stck & stpt have been executed
 928         clg     %r9,BASED(cleanup_idle_insn)
 929         jhe     1f
 930         mvc     __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
 931         mvc     __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
 932 1:      # account system time going idle
 933         lg      %r9,__LC_STEAL_TIMER
 934         alg     %r9,__CLOCK_IDLE_ENTER(%r2)
 935         slg     %r9,__LC_LAST_UPDATE_CLOCK
 936         stg     %r9,__LC_STEAL_TIMER
 937         mvc     __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
 938         lg      %r9,__LC_SYSTEM_TIMER
 939         alg     %r9,__LC_LAST_UPDATE_TIMER
 940         slg     %r9,__TIMER_IDLE_ENTER(%r2)
 941         stg     %r9,__LC_SYSTEM_TIMER
 942         mvc     __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
 943         # prepare return psw
 944         nihh    %r8,0xfffd              # clear wait state bit
 945         lg      %r9,48(%r11)            # return from psw_idle
 946         br      %r14
 947 cleanup_idle_insn:
 948         .quad   psw_idle_lpsw
 949
 950 /*
 951  * Integer constants
 952  */
 953         .align  8
 954 .Lcritical_start:
 955         .quad   __critical_start
 956 .Lcritical_length:
 957         .quad   __critical_end - __critical_start
 958
 959
 960 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
 961 /*
 962  * sie64a calling convention:
 963  * %r2 pointer to sie control block
 964  * %r3 guest register save area
 965  */
 966 ENTRY(sie64a)
 967         stmg    %r6,%r14,__SF_GPRS(%r15)        # save kernel registers
 968         stg     %r2,__SF_EMPTY(%r15)            # save control block pointer
 969         stg     %r3,__SF_EMPTY+8(%r15)          # save guest register save area
 970         xc      __SF_EMPTY+16(8,%r15),__SF_EMPTY+16(%r15) # host id == 0
 971         lmg     %r0,%r13,0(%r3)                 # load guest gprs 0-13
 972 sie_loop:
 973         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
 974         tm      __TI_flags+7(%r14),_TIF_EXIT_SIE
 975         jnz     sie_exit
 976         lg      %r14,__LC_GMAP                  # get gmap pointer
 977         ltgr    %r14,%r14
 978         jz      sie_gmap
 979         lctlg   %c1,%c1,__GMAP_ASCE(%r14)       # load primary asce
 980 sie_gmap:
 981         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
 982         SPP     __SF_EMPTY(%r15)                # set guest id
 983         sie     0(%r14)
 984 sie_done:
 985         SPP     __SF_EMPTY+16(%r15)             # set host id
 986         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
 987 sie_exit:
 988         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 989         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
 990         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
 991         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
 992         lghi    %r2,0
 993         br      %r14
 994 sie_fault:
 995         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 996         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
 997         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
 998         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
 999         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
1000         lghi    %r2,-EFAULT
1001         br      %r14
1002
1003         .align  8
1004 .Lsie_loop:
1005         .quad   sie_loop
1006 .Lsie_length:
1007         .quad   sie_done - sie_loop
1008 .Lhost_id:
1009         .quad   0
1010
1011         .section __ex_table,"a"
1012         .quad   sie_loop,sie_fault
1013         .previous
1014 #endif
1015
1016                 .section .rodata, "a"
1017 #define SYSCALL(esa,esame,emu)  .long esame
1018         .globl  sys_call_table
1019 sys_call_table:
1020 #include "syscalls.S"
1021 #undef SYSCALL
1022
1023 #ifdef CONFIG_COMPAT
1024
1025 #define SYSCALL(esa,esame,emu)  .long emu
1026 sys_call_table_emu:
1027 #include "syscalls.S"
1028 #undef SYSCALL
1029 #endif