arch/riscv/cpu/start.S

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * Startup Code for RISC-V Core
   4  *
   5  * Copyright (c) 2017 Microsemi Corporation.
   6  * Copyright (c) 2017 Padmarao Begari <Padmarao.Begari@microsemi.com>
   7  *
   8  * Copyright (C) 2017 Andes Technology Corporation
   9  * Rick Chen, Andes Technology Corporation <rick@andestech.com>
  10  */
  11
  12 #include <asm-offsets.h>
  13 #include <config.h>
  14 #include <common.h>
  15 #include <elf.h>
  16 #include <asm/encoding.h>
  17 #include <generated/asm-offsets.h>
  18
  19 #ifdef CONFIG_32BIT
  20 #define LREG                    lw
  21 #define SREG                    sw
  22 #define REGBYTES                4
  23 #define RELOC_TYPE              R_RISCV_32
  24 #define SYM_INDEX               0x8
  25 #define SYM_SIZE                0x10
  26 #else
  27 #define LREG                    ld
  28 #define SREG                    sd
  29 #define REGBYTES                8
  30 #define RELOC_TYPE              R_RISCV_64
  31 #define SYM_INDEX               0x20
  32 #define SYM_SIZE                0x18
  33 #endif
  34
  35 .section .data
  36 secondary_harts_relocation_error:
  37         .ascii "Relocation of secondary harts has failed, error %d\n"
  38
  39 .section .text
  40 .globl _start
  41 _start:
  42 #if CONFIG_IS_ENABLED(RISCV_MMODE)
  43         csrr    a0, CSR_MHARTID
  44 #endif
  45
  46         /* save hart id and dtb pointer */
  47         mv      tp, a0
  48         mv      s1, a1
  49
  50         la      t0, trap_entry
  51         csrw    MODE_PREFIX(tvec), t0
  52
  53         /* mask all interrupts */
  54         csrw    MODE_PREFIX(ie), zero
  55
  56 #if CONFIG_IS_ENABLED(SMP)
  57         /* check if hart is within range */
  58         /* tp: hart id */
  59         li      t0, CONFIG_NR_CPUS
  60         bge     tp, t0, hart_out_of_bounds_loop
  61
  62         /* set xSIE bit to receive IPIs */
  63 #if CONFIG_IS_ENABLED(RISCV_MMODE)
  64         li      t0, MIE_MSIE
  65 #else
  66         li      t0, SIE_SSIE
  67 #endif
  68         /* Clear any pending IPIs */
  69         csrc    MODE_PREFIX(ip), t0
  70         csrs    MODE_PREFIX(ie), t0
  71 #endif
  72
  73 /*
  74  * Set stackpointer in internal/ex RAM to call board_init_f
  75  */
  76 call_board_init_f:
  77         li      t0, -16
  78 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
  79         li      t1, CONFIG_SPL_STACK
  80 #else
  81         li      t1, CONFIG_SYS_INIT_SP_ADDR
  82 #endif
  83         and     sp, t1, t0              /* force 16 byte alignment */
  84
  85 call_board_init_f_0:
  86         mv      a0, sp
  87         jal     board_init_f_alloc_reserve
  88
  89         /*
  90          * Set global data pointer here for all harts, uninitialized at this
  91          * point.
  92          */
  93         mv      gp, a0
  94
  95         /* setup stack */
  96 #if CONFIG_IS_ENABLED(SMP)
  97         /* tp: hart id */
  98         slli    t0, tp, CONFIG_STACK_SIZE_SHIFT
  99         sub     sp, a0, t0
 100 #else
 101         mv      sp, a0
 102 #endif
 103
 104 #ifndef CONFIG_XIP
 105         /*
 106          * Pick hart to initialize global data and run U-Boot. The other harts
 107          * wait for initialization to complete.
 108          */
 109         la      t0, hart_lottery
 110         li      s2, 1
 111         amoswap.w s2, t1, 0(t0)
 112         bnez    s2, wait_for_gd_init
 113 #else
 114         bnez    tp, secondary_hart_loop
 115 #endif
 116
 117 #ifdef CONFIG_OF_PRIOR_STAGE
 118         la      t0, prior_stage_fdt_address
 119         SREG    s1, 0(t0)
 120 #endif
 121
 122         jal     board_init_f_init_reserve
 123
 124         SREG    s1, GD_FIRMWARE_FDT_ADDR(gp)
 125         /* save the boot hart id to global_data */
 126         SREG    tp, GD_BOOT_HART(gp)
 127
 128 #ifndef CONFIG_XIP
 129         la      t0, available_harts_lock
 130         fence   rw, w
 131         amoswap.w zero, zero, 0(t0)
 132
 133 wait_for_gd_init:
 134         la      t0, available_harts_lock
 135         li      t1, 1
 136 1:      amoswap.w t1, t1, 0(t0)
 137         fence   r, rw
 138         bnez    t1, 1b
 139
 140         /* register available harts in the available_harts mask */
 141         li      t1, 1
 142         sll     t1, t1, tp
 143         LREG    t2, GD_AVAILABLE_HARTS(gp)
 144         or      t2, t2, t1
 145         SREG    t2, GD_AVAILABLE_HARTS(gp)
 146
 147         fence   rw, w
 148         amoswap.w zero, zero, 0(t0)
 149
 150         /*
 151          * Continue on hart lottery winner, others branch to
 152          * secondary_hart_loop.
 153          */
 154         bnez    s2, secondary_hart_loop
 155 #endif
 156
 157         /* Enable cache */
 158         jal     icache_enable
 159         jal     dcache_enable
 160
 161 #ifdef CONFIG_DEBUG_UART
 162         jal     debug_uart_init
 163 #endif
 164
 165         mv      a0, zero                /* a0 <-- boot_flags = 0 */
 166         la      t5, board_init_f
 167         jalr    t5                      /* jump to board_init_f() */
 168
 169 #ifdef CONFIG_SPL_BUILD
 170 spl_clear_bss:
 171         la      t0, __bss_start
 172         la      t1, __bss_end
 173         beq     t0, t1, spl_stack_gd_setup
 174
 175 spl_clear_bss_loop:
 176         SREG    zero, 0(t0)
 177         addi    t0, t0, REGBYTES
 178         blt     t0, t1, spl_clear_bss_loop
 179
 180 spl_stack_gd_setup:
 181         jal     spl_relocate_stack_gd
 182
 183         /* skip setup if we did not relocate */
 184         beqz    a0, spl_call_board_init_r
 185         mv      s0, a0
 186
 187         /* setup stack on main hart */
 188 #if CONFIG_IS_ENABLED(SMP)
 189         /* tp: hart id */
 190         slli    t0, tp, CONFIG_STACK_SIZE_SHIFT
 191         sub     sp, s0, t0
 192 #else
 193         mv      sp, s0
 194 #endif
 195
 196         /* set new stack and global data pointer on secondary harts */
 197 spl_secondary_hart_stack_gd_setup:
 198         la      a0, secondary_hart_relocate
 199         mv      a1, s0
 200         mv      a2, s0
 201         mv      a3, zero
 202         jal     smp_call_function
 203
 204         /* hang if relocation of secondary harts has failed */
 205         beqz    a0, 1f
 206         mv      a1, a0
 207         la      a0, secondary_harts_relocation_error
 208         jal     printf
 209         jal     hang
 210
 211         /* set new global data pointer on main hart */
 212 1:      mv      gp, s0
 213
 214 spl_call_board_init_r:
 215         mv      a0, zero
 216         mv      a1, zero
 217         jal     board_init_r
 218 #endif
 219
 220 /*
 221  * void relocate_code(addr_sp, gd, addr_moni)
 222  *
 223  * This "function" does not return, instead it continues in RAM
 224  * after relocating the monitor code.
 225  *
 226  */
 227 .globl relocate_code
 228 relocate_code:
 229         mv      s2, a0                  /* save addr_sp */
 230         mv      s3, a1                  /* save addr of gd */
 231         mv      s4, a2                  /* save addr of destination */
 232
 233 /*
 234  *Set up the stack
 235  */
 236 stack_setup:
 237 #if CONFIG_IS_ENABLED(SMP)
 238         /* tp: hart id */
 239         slli    t0, tp, CONFIG_STACK_SIZE_SHIFT
 240         sub     sp, s2, t0
 241 #else
 242         mv      sp, s2
 243 #endif
 244
 245         la      t0, _start
 246         sub     t6, s4, t0              /* t6 <- relocation offset */
 247         beq     t0, s4, clear_bss       /* skip relocation */
 248
 249         mv      t1, s4                  /* t1 <- scratch for copy_loop */
 250         la      t3, __bss_start
 251         sub     t3, t3, t0              /* t3 <- __bss_start_ofs */
 252         add     t2, t0, t3              /* t2 <- source end address */
 253
 254 copy_loop:
 255         LREG    t5, 0(t0)
 256         addi    t0, t0, REGBYTES
 257         SREG    t5, 0(t1)
 258         addi    t1, t1, REGBYTES
 259         blt     t0, t2, copy_loop
 260
 261 /*
 262  * Update dynamic relocations after board_init_f
 263  */
 264 fix_rela_dyn:
 265         la      t1, __rel_dyn_start
 266         la      t2, __rel_dyn_end
 267         beq     t1, t2, clear_bss
 268         add     t1, t1, t6              /* t1 <- rela_dyn_start in RAM */
 269         add     t2, t2, t6              /* t2 <- rela_dyn_end in RAM */
 270
 271 /*
 272  * skip first reserved entry: address, type, addend
 273  */
 274         j       10f
 275
 276 6:
 277         LREG    t5, -(REGBYTES*2)(t1)   /* t5 <-- relocation info:type */
 278         li      t3, R_RISCV_RELATIVE    /* reloc type R_RISCV_RELATIVE */
 279         bne     t5, t3, 8f              /* skip non-RISCV_RELOC entries */
 280         LREG    t3, -(REGBYTES*3)(t1)
 281         LREG    t5, -(REGBYTES)(t1)     /* t5 <-- addend */
 282         add     t5, t5, t6              /* t5 <-- location to fix up in RAM */
 283         add     t3, t3, t6              /* t3 <-- location to fix up in RAM */
 284         SREG    t5, 0(t3)
 285         j       10f
 286
 287 8:
 288         la      t4, __dyn_sym_start
 289         add     t4, t4, t6
 290
 291 9:
 292         LREG    t5, -(REGBYTES*2)(t1)   /* t5 <-- relocation info:type */
 293         srli    t0, t5, SYM_INDEX       /* t0 <--- sym table index */
 294         andi    t5, t5, 0xFF            /* t5 <--- relocation type */
 295         li      t3, RELOC_TYPE
 296         bne     t5, t3, 10f             /* skip non-addned entries */
 297
 298         LREG    t3, -(REGBYTES*3)(t1)
 299         li      t5, SYM_SIZE
 300         mul     t0, t0, t5
 301         add     s5, t4, t0
 302         LREG    t0, -(REGBYTES)(t1)     /* t0 <-- addend */
 303         LREG    t5, REGBYTES(s5)
 304         add     t5, t5, t0
 305         add     t5, t5, t6              /* t5 <-- location to fix up in RAM */
 306         add     t3, t3, t6              /* t3 <-- location to fix up in RAM */
 307         SREG    t5, 0(t3)
 308 10:
 309         addi    t1, t1, (REGBYTES*3)
 310         ble     t1, t2, 6b
 311
 312 /*
 313  * trap update
 314 */
 315         la      t0, trap_entry
 316         add     t0, t0, t6
 317         csrw    MODE_PREFIX(tvec), t0
 318
 319 clear_bss:
 320         la      t0, __bss_start         /* t0 <- rel __bss_start in FLASH */
 321         add     t0, t0, t6              /* t0 <- rel __bss_start in RAM */
 322         la      t1, __bss_end           /* t1 <- rel __bss_end in FLASH */
 323         add     t1, t1, t6              /* t1 <- rel __bss_end in RAM */
 324         beq     t0, t1, relocate_secondary_harts
 325
 326 clbss_l:
 327         SREG    zero, 0(t0)             /* clear loop... */
 328         addi    t0, t0, REGBYTES
 329         blt     t0, t1, clbss_l
 330
 331 relocate_secondary_harts:
 332 #if CONFIG_IS_ENABLED(SMP)
 333         /* send relocation IPI */
 334         la      t0, secondary_hart_relocate
 335         add     a0, t0, t6
 336
 337         /* store relocation offset */
 338         mv      s5, t6
 339
 340         mv      a1, s2
 341         mv      a2, s3
 342         mv      a3, zero
 343         jal     smp_call_function
 344
 345         /* hang if relocation of secondary harts has failed */
 346         beqz    a0, 1f
 347         mv      a1, a0
 348         la      a0, secondary_harts_relocation_error
 349         jal     printf
 350         jal     hang
 351
 352         /* restore relocation offset */
 353 1:      mv      t6, s5
 354 #endif
 355
 356 /*
 357  * We are done. Do not return, instead branch to second part of board
 358  * initialization, now running from RAM.
 359  */
 360 call_board_init_r:
 361         jal     invalidate_icache_all
 362         jal     flush_dcache_all
 363         la      t0, board_init_r        /* offset of board_init_r() */
 364         add     t4, t0, t6              /* real address of board_init_r() */
 365 /*
 366  * setup parameters for board_init_r
 367  */
 368         mv      a0, s3                  /* gd_t */
 369         mv      a1, s4                  /* dest_addr */
 370
 371 /*
 372  * jump to it ...
 373  */
 374         jr      t4                      /* jump to board_init_r() */
 375
 376 #if CONFIG_IS_ENABLED(SMP)
 377 hart_out_of_bounds_loop:
 378         /* Harts in this loop are out of bounds, increase CONFIG_NR_CPUS. */
 379         wfi
 380         j       hart_out_of_bounds_loop
 381
 382 /* SMP relocation entry */
 383 secondary_hart_relocate:
 384         /* a1: new sp */
 385         /* a2: new gd */
 386         /* tp: hart id */
 387
 388         /* setup stack */
 389         slli    t0, tp, CONFIG_STACK_SIZE_SHIFT
 390         sub     sp, a1, t0
 391
 392         /* update global data pointer */
 393         mv      gp, a2
 394 #endif
 395
 396 secondary_hart_loop:
 397         wfi
 398
 399 #if CONFIG_IS_ENABLED(SMP)
 400         csrr    t0, MODE_PREFIX(ip)
 401 #if CONFIG_IS_ENABLED(RISCV_MMODE)
 402         andi    t0, t0, MIE_MSIE
 403 #else
 404         andi    t0, t0, SIE_SSIE
 405 #endif
 406         beqz    t0, secondary_hart_loop
 407
 408         mv      a0, tp
 409         jal     handle_ipi
 410 #endif
 411
 412         j       secondary_hart_loop