arch/powerpc/kvm/book3s_hv_rmhandlers.S

   1 /*
   2  * This program is free software; you can redistribute it and/or modify
   3  * it under the terms of the GNU General Public License, version 2, as
   4  * published by the Free Software Foundation.
   5  *
   6  * This program is distributed in the hope that it will be useful,
   7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9  * GNU General Public License for more details.
  10  *
  11  * Copyright 2011 Paul Mackerras, IBM Corp. <paulus@au1.ibm.com>
  12  *
  13  * Derived from book3s_rmhandlers.S and other files, which are:
  14  *
  15  * Copyright SUSE Linux Products GmbH 2009
  16  *
  17  * Authors: Alexander Graf <agraf@suse.de>
  18  */
  19
  20 #include <asm/ppc_asm.h>
  21 #include <asm/kvm_asm.h>
  22 #include <asm/reg.h>
  23 #include <asm/mmu.h>
  24 #include <asm/page.h>
  25 #include <asm/ptrace.h>
  26 #include <asm/hvcall.h>
  27 #include <asm/asm-offsets.h>
  28 #include <asm/exception-64s.h>
  29 #include <asm/kvm_book3s_asm.h>
  30 #include <asm/mmu-hash64.h>
  31
  32 #ifdef __LITTLE_ENDIAN__
  33 #error Need to fix lppaca and SLB shadow accesses in little endian mode
  34 #endif
  35
  36 /*
  37  * Call kvmppc_hv_entry in real mode.
  38  * Must be called with interrupts hard-disabled.
  39  *
  40  * Input Registers:
  41  *
  42  * LR = return address to continue at after eventually re-enabling MMU
  43  */
  44 _GLOBAL(kvmppc_hv_entry_trampoline)
  45         mflr    r0
  46         std     r0, PPC_LR_STKOFF(r1)
  47         stdu    r1, -112(r1)
  48         mfmsr   r10
  49         LOAD_REG_ADDR(r5, kvmppc_call_hv_entry)
  50         li      r0,MSR_RI
  51         andc    r0,r10,r0
  52         li      r6,MSR_IR | MSR_DR
  53         andc    r6,r10,r6
  54         mtmsrd  r0,1            /* clear RI in MSR */
  55         mtsrr0  r5
  56         mtsrr1  r6
  57         RFI
  58
  59 kvmppc_call_hv_entry:
  60         bl      kvmppc_hv_entry
  61
  62         /* Back from guest - restore host state and return to caller */
  63
  64         /* Restore host DABR and DABRX */
  65         ld      r5,HSTATE_DABR(r13)
  66         li      r6,7
  67         mtspr   SPRN_DABR,r5
  68         mtspr   SPRN_DABRX,r6
  69
  70         /* Restore SPRG3 */
  71         ld      r3,PACA_SPRG3(r13)
  72         mtspr   SPRN_SPRG3,r3
  73
  74         /*
  75          * Reload DEC.  HDEC interrupts were disabled when
  76          * we reloaded the host's LPCR value.
  77          */
  78         ld      r3, HSTATE_DECEXP(r13)
  79         mftb    r4
  80         subf    r4, r4, r3
  81         mtspr   SPRN_DEC, r4
  82
  83         /* Reload the host's PMU registers */
  84         ld      r3, PACALPPACAPTR(r13)  /* is the host using the PMU? */
  85         lbz     r4, LPPACA_PMCINUSE(r3)
  86         cmpwi   r4, 0
  87         beq     23f                     /* skip if not */
  88         lwz     r3, HSTATE_PMC(r13)
  89         lwz     r4, HSTATE_PMC + 4(r13)
  90         lwz     r5, HSTATE_PMC + 8(r13)
  91         lwz     r6, HSTATE_PMC + 12(r13)
  92         lwz     r8, HSTATE_PMC + 16(r13)
  93         lwz     r9, HSTATE_PMC + 20(r13)
  94 BEGIN_FTR_SECTION
  95         lwz     r10, HSTATE_PMC + 24(r13)
  96         lwz     r11, HSTATE_PMC + 28(r13)
  97 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
  98         mtspr   SPRN_PMC1, r3
  99         mtspr   SPRN_PMC2, r4
 100         mtspr   SPRN_PMC3, r5
 101         mtspr   SPRN_PMC4, r6
 102         mtspr   SPRN_PMC5, r8
 103         mtspr   SPRN_PMC6, r9
 104 BEGIN_FTR_SECTION
 105         mtspr   SPRN_PMC7, r10
 106         mtspr   SPRN_PMC8, r11
 107 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
 108         ld      r3, HSTATE_MMCR(r13)
 109         ld      r4, HSTATE_MMCR + 8(r13)
 110         ld      r5, HSTATE_MMCR + 16(r13)
 111         mtspr   SPRN_MMCR1, r4
 112         mtspr   SPRN_MMCRA, r5
 113         mtspr   SPRN_MMCR0, r3
 114         isync
 115 23:
 116
 117         /*
 118          * For external and machine check interrupts, we need
 119          * to call the Linux handler to process the interrupt.
 120          * We do that by jumping to absolute address 0x500 for
 121          * external interrupts, or the machine_check_fwnmi label
 122          * for machine checks (since firmware might have patched
 123          * the vector area at 0x200).  The [h]rfid at the end of the
 124          * handler will return to the book3s_hv_interrupts.S code.
 125          * For other interrupts we do the rfid to get back
 126          * to the book3s_hv_interrupts.S code here.
 127          */
 128         ld      r8, 112+PPC_LR_STKOFF(r1)
 129         addi    r1, r1, 112
 130         ld      r7, HSTATE_HOST_MSR(r13)
 131
 132         cmpwi   cr1, r12, BOOK3S_INTERRUPT_MACHINE_CHECK
 133         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
 134 BEGIN_FTR_SECTION
 135         beq     11f
 136 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
 137
 138         /* RFI into the highmem handler, or branch to interrupt handler */
 139         mfmsr   r6
 140         li      r0, MSR_RI
 141         andc    r6, r6, r0
 142         mtmsrd  r6, 1                   /* Clear RI in MSR */
 143         mtsrr0  r8
 144         mtsrr1  r7
 145         beqa    0x500                   /* external interrupt (PPC970) */
 146         beq     cr1, 13f                /* machine check */
 147         RFI
 148
 149         /* On POWER7, we have external interrupts set to use HSRR0/1 */
 150 11:     mtspr   SPRN_HSRR0, r8
 151         mtspr   SPRN_HSRR1, r7
 152         ba      0x500
 153
 154 13:     b       machine_check_fwnmi
 155
 156 /*
 157  * We come in here when wakened from nap mode on a secondary hw thread.
 158  * Relocation is off and most register values are lost.
 159  * r13 points to the PACA.
 160  */
 161         .globl  kvm_start_guest
 162 kvm_start_guest:
 163         ld      r1,PACAEMERGSP(r13)
 164         subi    r1,r1,STACK_FRAME_OVERHEAD
 165         ld      r2,PACATOC(r13)
 166
 167         li      r0,KVM_HWTHREAD_IN_KVM
 168         stb     r0,HSTATE_HWTHREAD_STATE(r13)
 169
 170         /* NV GPR values from power7_idle() will no longer be valid */
 171         li      r0,1
 172         stb     r0,PACA_NAPSTATELOST(r13)
 173
 174         /* were we napping due to cede? */
 175         lbz     r0,HSTATE_NAPPING(r13)
 176         cmpwi   r0,0
 177         bne     kvm_end_cede
 178
 179         /*
 180          * We weren't napping due to cede, so this must be a secondary
 181          * thread being woken up to run a guest, or being woken up due
 182          * to a stray IPI.  (Or due to some machine check or hypervisor
 183          * maintenance interrupt while the core is in KVM.)
 184          */
 185
 186         /* Check the wake reason in SRR1 to see why we got here */
 187         mfspr   r3,SPRN_SRR1
 188         rlwinm  r3,r3,44-31,0x7         /* extract wake reason field */
 189         cmpwi   r3,4                    /* was it an external interrupt? */
 190         bne     27f                     /* if not */
 191         ld      r5,HSTATE_XICS_PHYS(r13)
 192         li      r7,XICS_XIRR            /* if it was an external interrupt, */
 193         lwzcix  r8,r5,r7                /* get and ack the interrupt */
 194         sync
 195         clrldi. r9,r8,40                /* get interrupt source ID. */
 196         beq     28f                     /* none there? */
 197         cmpwi   r9,XICS_IPI             /* was it an IPI? */
 198         bne     29f
 199         li      r0,0xff
 200         li      r6,XICS_MFRR
 201         stbcix  r0,r5,r6                /* clear IPI */
 202         stwcix  r8,r5,r7                /* EOI the interrupt */
 203         sync                            /* order loading of vcpu after that */
 204
 205         /* get vcpu pointer, NULL if we have no vcpu to run */
 206         ld      r4,HSTATE_KVM_VCPU(r13)
 207         cmpdi   r4,0
 208         /* if we have no vcpu to run, go back to sleep */
 209         beq     kvm_no_guest
 210         b       30f
 211
 212 27:     /* XXX should handle hypervisor maintenance interrupts etc. here */
 213         b       kvm_no_guest
 214 28:     /* SRR1 said external but ICP said nope?? */
 215         b       kvm_no_guest
 216 29:     /* External non-IPI interrupt to offline secondary thread? help?? */
 217         stw     r8,HSTATE_SAVED_XIRR(r13)
 218         b       kvm_no_guest
 219
 220 30:     bl      kvmppc_hv_entry
 221
 222         /* Back from the guest, go back to nap */
 223         /* Clear our vcpu pointer so we don't come back in early */
 224         li      r0, 0
 225         std     r0, HSTATE_KVM_VCPU(r13)
 226         /*
 227          * Make sure we clear HSTATE_KVM_VCPU(r13) before incrementing
 228          * the nap_count, because once the increment to nap_count is
 229          * visible we could be given another vcpu.
 230          */
 231         lwsync
 232         /* Clear any pending IPI - we're an offline thread */
 233         ld      r5, HSTATE_XICS_PHYS(r13)
 234         li      r7, XICS_XIRR
 235         lwzcix  r3, r5, r7              /* ack any pending interrupt */
 236         rlwinm. r0, r3, 0, 0xffffff     /* any pending? */
 237         beq     37f
 238         sync
 239         li      r0, 0xff
 240         li      r6, XICS_MFRR
 241         stbcix  r0, r5, r6              /* clear the IPI */
 242         stwcix  r3, r5, r7              /* EOI it */
 243 37:     sync
 244
 245         /* increment the nap count and then go to nap mode */
 246         ld      r4, HSTATE_KVM_VCORE(r13)
 247         addi    r4, r4, VCORE_NAP_COUNT
 248 51:     lwarx   r3, 0, r4
 249         addi    r3, r3, 1
 250         stwcx.  r3, 0, r4
 251         bne     51b
 252
 253 kvm_no_guest:
 254         li      r0, KVM_HWTHREAD_IN_NAP
 255         stb     r0, HSTATE_HWTHREAD_STATE(r13)
 256         li      r3, LPCR_PECE0
 257         mfspr   r4, SPRN_LPCR
 258         rlwimi  r4, r3, 0, LPCR_PECE0 | LPCR_PECE1
 259         mtspr   SPRN_LPCR, r4
 260         isync
 261         std     r0, HSTATE_SCRATCH0(r13)
 262         ptesync
 263         ld      r0, HSTATE_SCRATCH0(r13)
 264 1:      cmpd    r0, r0
 265         bne     1b
 266         nap
 267         b       .
 268
 269 /******************************************************************************
 270  *                                                                            *
 271  *                               Entry code                                   *
 272  *                                                                            *
 273  *****************************************************************************/
 274
 275 .global kvmppc_hv_entry
 276 kvmppc_hv_entry:
 277
 278         /* Required state:
 279          *
 280          * R4 = vcpu pointer
 281          * MSR = ~IR|DR
 282          * R13 = PACA
 283          * R1 = host R1
 284          * all other volatile GPRS = free
 285          */
 286         mflr    r0
 287         std     r0, PPC_LR_STKOFF(r1)
 288         stdu    r1, -112(r1)
 289
 290         /* Set partition DABR */
 291         /* Do this before re-enabling PMU to avoid P7 DABR corruption bug */
 292         li      r5,3
 293         ld      r6,VCPU_DABR(r4)
 294         mtspr   SPRN_DABRX,r5
 295         mtspr   SPRN_DABR,r6
 296 BEGIN_FTR_SECTION
 297         isync
 298 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
 299
 300         /* Load guest PMU registers */
 301         /* R4 is live here (vcpu pointer) */
 302         li      r3, 1
 303         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
 304         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
 305         isync
 306         lwz     r3, VCPU_PMC(r4)        /* always load up guest PMU registers */
 307         lwz     r5, VCPU_PMC + 4(r4)    /* to prevent information leak */
 308         lwz     r6, VCPU_PMC + 8(r4)
 309         lwz     r7, VCPU_PMC + 12(r4)
 310         lwz     r8, VCPU_PMC + 16(r4)
 311         lwz     r9, VCPU_PMC + 20(r4)
 312 BEGIN_FTR_SECTION
 313         lwz     r10, VCPU_PMC + 24(r4)
 314         lwz     r11, VCPU_PMC + 28(r4)
 315 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
 316         mtspr   SPRN_PMC1, r3
 317         mtspr   SPRN_PMC2, r5
 318         mtspr   SPRN_PMC3, r6
 319         mtspr   SPRN_PMC4, r7
 320         mtspr   SPRN_PMC5, r8
 321         mtspr   SPRN_PMC6, r9
 322 BEGIN_FTR_SECTION
 323         mtspr   SPRN_PMC7, r10
 324         mtspr   SPRN_PMC8, r11
 325 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
 326         ld      r3, VCPU_MMCR(r4)
 327         ld      r5, VCPU_MMCR + 8(r4)
 328         ld      r6, VCPU_MMCR + 16(r4)
 329         ld      r7, VCPU_SIAR(r4)
 330         ld      r8, VCPU_SDAR(r4)
 331         mtspr   SPRN_MMCR1, r5
 332         mtspr   SPRN_MMCRA, r6
 333         mtspr   SPRN_SIAR, r7
 334         mtspr   SPRN_SDAR, r8
 335         mtspr   SPRN_MMCR0, r3
 336         isync
 337
 338         /* Load up FP, VMX and VSX registers */
 339         bl      kvmppc_load_fp
 340
 341         ld      r14, VCPU_GPR(R14)(r4)
 342         ld      r15, VCPU_GPR(R15)(r4)
 343         ld      r16, VCPU_GPR(R16)(r4)
 344         ld      r17, VCPU_GPR(R17)(r4)
 345         ld      r18, VCPU_GPR(R18)(r4)
 346         ld      r19, VCPU_GPR(R19)(r4)
 347         ld      r20, VCPU_GPR(R20)(r4)
 348         ld      r21, VCPU_GPR(R21)(r4)
 349         ld      r22, VCPU_GPR(R22)(r4)
 350         ld      r23, VCPU_GPR(R23)(r4)
 351         ld      r24, VCPU_GPR(R24)(r4)
 352         ld      r25, VCPU_GPR(R25)(r4)
 353         ld      r26, VCPU_GPR(R26)(r4)
 354         ld      r27, VCPU_GPR(R27)(r4)
 355         ld      r28, VCPU_GPR(R28)(r4)
 356         ld      r29, VCPU_GPR(R29)(r4)
 357         ld      r30, VCPU_GPR(R30)(r4)
 358         ld      r31, VCPU_GPR(R31)(r4)
 359
 360 BEGIN_FTR_SECTION
 361         /* Switch DSCR to guest value */
 362         ld      r5, VCPU_DSCR(r4)
 363         mtspr   SPRN_DSCR, r5
 364 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
 365
 366         /*
 367          * Set the decrementer to the guest decrementer.
 368          */
 369         ld      r8,VCPU_DEC_EXPIRES(r4)
 370         mftb    r7
 371         subf    r3,r7,r8
 372         mtspr   SPRN_DEC,r3
 373         stw     r3,VCPU_DEC(r4)
 374
 375         ld      r5, VCPU_SPRG0(r4)
 376         ld      r6, VCPU_SPRG1(r4)
 377         ld      r7, VCPU_SPRG2(r4)
 378         ld      r8, VCPU_SPRG3(r4)
 379         mtspr   SPRN_SPRG0, r5
 380         mtspr   SPRN_SPRG1, r6
 381         mtspr   SPRN_SPRG2, r7
 382         mtspr   SPRN_SPRG3, r8
 383
 384         /* Save R1 in the PACA */
 385         std     r1, HSTATE_HOST_R1(r13)
 386
 387         /* Load up DAR and DSISR */
 388         ld      r5, VCPU_DAR(r4)
 389         lwz     r6, VCPU_DSISR(r4)
 390         mtspr   SPRN_DAR, r5
 391         mtspr   SPRN_DSISR, r6
 392
 393         li      r6, KVM_GUEST_MODE_HOST_HV
 394         stb     r6, HSTATE_IN_GUEST(r13)
 395
 396 BEGIN_FTR_SECTION
 397         /* Restore AMR and UAMOR, set AMOR to all 1s */
 398         ld      r5,VCPU_AMR(r4)
 399         ld      r6,VCPU_UAMOR(r4)
 400         li      r7,-1
 401         mtspr   SPRN_AMR,r5
 402         mtspr   SPRN_UAMOR,r6
 403         mtspr   SPRN_AMOR,r7
 404 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
 405
 406         /* Clear out SLB */
 407         li      r6,0
 408         slbmte  r6,r6
 409         slbia
 410         ptesync
 411
 412 BEGIN_FTR_SECTION
 413         b       30f
 414 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
 415         /*
 416          * POWER7 host -> guest partition switch code.
 417          * We don't have to lock against concurrent tlbies,
 418          * but we do have to coordinate across hardware threads.
 419          */
 420         /* Increment entry count iff exit count is zero. */
 421         ld      r5,HSTATE_KVM_VCORE(r13)
 422         addi    r9,r5,VCORE_ENTRY_EXIT
 423 21:     lwarx   r3,0,r9
 424         cmpwi   r3,0x100                /* any threads starting to exit? */
 425         bge     secondary_too_late      /* if so we're too late to the party */
 426         addi    r3,r3,1
 427         stwcx.  r3,0,r9
 428         bne     21b
 429
 430         /* Primary thread switches to guest partition. */
 431         ld      r9,VCPU_KVM(r4)         /* pointer to struct kvm */
 432         lwz     r6,VCPU_PTID(r4)
 433         cmpwi   r6,0
 434         bne     20f
 435         ld      r6,KVM_SDR1(r9)
 436         lwz     r7,KVM_LPID(r9)
 437         li      r0,LPID_RSVD            /* switch to reserved LPID */
 438         mtspr   SPRN_LPID,r0
 439         ptesync
 440         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
 441         mtspr   SPRN_LPID,r7
 442         isync
 443
 444         /* See if we need to flush the TLB */
 445         lhz     r6,PACAPACAINDEX(r13)   /* test_bit(cpu, need_tlb_flush) */
 446         clrldi  r7,r6,64-6              /* extract bit number (6 bits) */
 447         srdi    r6,r6,6                 /* doubleword number */
 448         sldi    r6,r6,3                 /* address offset */
 449         add     r6,r6,r9
 450         addi    r6,r6,KVM_NEED_FLUSH    /* dword in kvm->arch.need_tlb_flush */
 451         li      r0,1
 452         sld     r0,r0,r7
 453         ld      r7,0(r6)
 454         and.    r7,r7,r0
 455         beq     22f
 456 23:     ldarx   r7,0,r6                 /* if set, clear the bit */
 457         andc    r7,r7,r0
 458         stdcx.  r7,0,r6
 459         bne     23b
 460         li      r6,128                  /* and flush the TLB */
 461         mtctr   r6
 462         li      r7,0x800                /* IS field = 0b10 */
 463         ptesync
 464 28:     tlbiel  r7
 465         addi    r7,r7,0x1000
 466         bdnz    28b
 467         ptesync
 468
 469         /* Add timebase offset onto timebase */
 470 22:     ld      r8,VCORE_TB_OFFSET(r5)
 471         cmpdi   r8,0
 472         beq     37f
 473         mftb    r6              /* current host timebase */
 474         add     r8,r8,r6
 475         mtspr   SPRN_TBU40,r8   /* update upper 40 bits */
 476         mftb    r7              /* check if lower 24 bits overflowed */
 477         clrldi  r6,r6,40
 478         clrldi  r7,r7,40
 479         cmpld   r7,r6
 480         bge     37f
 481         addis   r8,r8,0x100     /* if so, increment upper 40 bits */
 482         mtspr   SPRN_TBU40,r8
 483
 484         /* Load guest PCR value to select appropriate compat mode */
 485 37:     ld      r7, VCORE_PCR(r5)
 486         cmpdi   r7, 0
 487         beq     38f
 488         mtspr   SPRN_PCR, r7
 489 38:
 490         li      r0,1
 491         stb     r0,VCORE_IN_GUEST(r5)   /* signal secondaries to continue */
 492         b       10f
 493
 494         /* Secondary threads wait for primary to have done partition switch */
 495 20:     lbz     r0,VCORE_IN_GUEST(r5)
 496         cmpwi   r0,0
 497         beq     20b
 498
 499         /* Set LPCR and RMOR. */
 500 10:     ld      r8,VCORE_LPCR(r5)
 501         mtspr   SPRN_LPCR,r8
 502         ld      r8,KVM_RMOR(r9)
 503         mtspr   SPRN_RMOR,r8
 504         isync
 505
 506         /* Increment yield count if they have a VPA */
 507         ld      r3, VCPU_VPA(r4)
 508         cmpdi   r3, 0
 509         beq     25f
 510         lwz     r5, LPPACA_YIELDCOUNT(r3)
 511         addi    r5, r5, 1
 512         stw     r5, LPPACA_YIELDCOUNT(r3)
 513         li      r6, 1
 514         stb     r6, VCPU_VPA_DIRTY(r4)
 515 25:
 516         /* Check if HDEC expires soon */
 517         mfspr   r3,SPRN_HDEC
 518         cmpwi   r3,10
 519         li      r12,BOOK3S_INTERRUPT_HV_DECREMENTER
 520         mr      r9,r4
 521         blt     hdec_soon
 522
 523         /* Save purr/spurr */
 524         mfspr   r5,SPRN_PURR
 525         mfspr   r6,SPRN_SPURR
 526         std     r5,HSTATE_PURR(r13)
 527         std     r6,HSTATE_SPURR(r13)
 528         ld      r7,VCPU_PURR(r4)
 529         ld      r8,VCPU_SPURR(r4)
 530         mtspr   SPRN_PURR,r7
 531         mtspr   SPRN_SPURR,r8
 532         b       31f
 533
 534         /*
 535          * PPC970 host -> guest partition switch code.
 536          * We have to lock against concurrent tlbies,
 537          * using native_tlbie_lock to lock against host tlbies
 538          * and kvm->arch.tlbie_lock to lock against guest tlbies.
 539          * We also have to invalidate the TLB since its
 540          * entries aren't tagged with the LPID.
 541          */
 542 30:     ld      r9,VCPU_KVM(r4)         /* pointer to struct kvm */
 543
 544         /* first take native_tlbie_lock */
 545         .section ".toc","aw"
 546 toc_tlbie_lock:
 547         .tc     native_tlbie_lock[TC],native_tlbie_lock
 548         .previous
 549         ld      r3,toc_tlbie_lock@toc(2)
 550 #ifdef __BIG_ENDIAN__
 551         lwz     r8,PACA_LOCK_TOKEN(r13)
 552 #else
 553         lwz     r8,PACAPACAINDEX(r13)
 554 #endif
 555 24:     lwarx   r0,0,r3
 556         cmpwi   r0,0
 557         bne     24b
 558         stwcx.  r8,0,r3
 559         bne     24b
 560         isync
 561
 562         ld      r5,HSTATE_KVM_VCORE(r13)
 563         ld      r7,VCORE_LPCR(r5)       /* use vcore->lpcr to store HID4 */
 564         li      r0,0x18f
 565         rotldi  r0,r0,HID4_LPID5_SH     /* all lpid bits in HID4 = 1 */
 566         or      r0,r7,r0
 567         ptesync
 568         sync
 569         mtspr   SPRN_HID4,r0            /* switch to reserved LPID */
 570         isync
 571         li      r0,0
 572         stw     r0,0(r3)                /* drop native_tlbie_lock */
 573
 574         /* invalidate the whole TLB */
 575         li      r0,256
 576         mtctr   r0
 577         li      r6,0
 578 25:     tlbiel  r6
 579         addi    r6,r6,0x1000
 580         bdnz    25b
 581         ptesync
 582
 583         /* Take the guest's tlbie_lock */
 584         addi    r3,r9,KVM_TLBIE_LOCK
 585 24:     lwarx   r0,0,r3
 586         cmpwi   r0,0
 587         bne     24b
 588         stwcx.  r8,0,r3
 589         bne     24b
 590         isync
 591         ld      r6,KVM_SDR1(r9)
 592         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
 593
 594         /* Set up HID4 with the guest's LPID etc. */
 595         sync
 596         mtspr   SPRN_HID4,r7
 597         isync
 598
 599         /* drop the guest's tlbie_lock */
 600         li      r0,0
 601         stw     r0,0(r3)
 602
 603         /* Check if HDEC expires soon */
 604         mfspr   r3,SPRN_HDEC
 605         cmpwi   r3,10
 606         li      r12,BOOK3S_INTERRUPT_HV_DECREMENTER
 607         mr      r9,r4
 608         blt     hdec_soon
 609
 610         /* Enable HDEC interrupts */
 611         mfspr   r0,SPRN_HID0
 612         li      r3,1
 613         rldimi  r0,r3, HID0_HDICE_SH, 64-HID0_HDICE_SH-1
 614         sync
 615         mtspr   SPRN_HID0,r0
 616         mfspr   r0,SPRN_HID0
 617         mfspr   r0,SPRN_HID0
 618         mfspr   r0,SPRN_HID0
 619         mfspr   r0,SPRN_HID0
 620         mfspr   r0,SPRN_HID0
 621         mfspr   r0,SPRN_HID0
 622
 623         /* Load up guest SLB entries */
 624 31:     lwz     r5,VCPU_SLB_MAX(r4)
 625         cmpwi   r5,0
 626         beq     9f
 627         mtctr   r5
 628         addi    r6,r4,VCPU_SLB
 629 1:      ld      r8,VCPU_SLB_E(r6)
 630         ld      r9,VCPU_SLB_V(r6)
 631         slbmte  r9,r8
 632         addi    r6,r6,VCPU_SLB_SIZE
 633         bdnz    1b
 634 9:
 635
 636         /* Restore state of CTRL run bit; assume 1 on entry */
 637         lwz     r5,VCPU_CTRL(r4)
 638         andi.   r5,r5,1
 639         bne     4f
 640         mfspr   r6,SPRN_CTRLF
 641         clrrdi  r6,r6,1
 642         mtspr   SPRN_CTRLT,r6
 643 4:
 644         ld      r6, VCPU_CTR(r4)
 645         lwz     r7, VCPU_XER(r4)
 646
 647         mtctr   r6
 648         mtxer   r7
 649
 650         ld      r10, VCPU_PC(r4)
 651         ld      r11, VCPU_MSR(r4)
 652 kvmppc_cede_reentry:            /* r4 = vcpu, r13 = paca */
 653         ld      r6, VCPU_SRR0(r4)
 654         ld      r7, VCPU_SRR1(r4)
 655
 656         /* r11 = vcpu->arch.msr & ~MSR_HV */
 657         rldicl  r11, r11, 63 - MSR_HV_LG, 1
 658         rotldi  r11, r11, 1 + MSR_HV_LG
 659         ori     r11, r11, MSR_ME
 660
 661         /* Check if we can deliver an external or decrementer interrupt now */
 662         ld      r0,VCPU_PENDING_EXC(r4)
 663         lis     r8,(1 << BOOK3S_IRQPRIO_EXTERNAL_LEVEL)@h
 664         and     r0,r0,r8
 665         cmpdi   cr1,r0,0
 666         andi.   r0,r11,MSR_EE
 667         beq     cr1,11f
 668 BEGIN_FTR_SECTION
 669         mfspr   r8,SPRN_LPCR
 670         ori     r8,r8,LPCR_MER
 671         mtspr   SPRN_LPCR,r8
 672         isync
 673 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
 674         beq     5f
 675         li      r0,BOOK3S_INTERRUPT_EXTERNAL
 676 12:     mr      r6,r10
 677         mr      r10,r0
 678         mr      r7,r11
 679         li      r11,(MSR_ME << 1) | 1   /* synthesize MSR_SF | MSR_ME */
 680         rotldi  r11,r11,63
 681         b       5f
 682 11:     beq     5f
 683         mfspr   r0,SPRN_DEC
 684         cmpwi   r0,0
 685         li      r0,BOOK3S_INTERRUPT_DECREMENTER
 686         blt     12b
 687
 688         /* Move SRR0 and SRR1 into the respective regs */
 689 5:      mtspr   SPRN_SRR0, r6
 690         mtspr   SPRN_SRR1, r7
 691
 692 fast_guest_return:
 693         li      r0,0
 694         stb     r0,VCPU_CEDED(r4)       /* cancel cede */
 695         mtspr   SPRN_HSRR0,r10
 696         mtspr   SPRN_HSRR1,r11
 697
 698         /* Activate guest mode, so faults get handled by KVM */
 699         li      r9, KVM_GUEST_MODE_GUEST_HV
 700         stb     r9, HSTATE_IN_GUEST(r13)
 701
 702         /* Enter guest */
 703
 704 BEGIN_FTR_SECTION
 705         ld      r5, VCPU_CFAR(r4)
 706         mtspr   SPRN_CFAR, r5
 707 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 708 BEGIN_FTR_SECTION
 709         ld      r0, VCPU_PPR(r4)
 710 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 711
 712         ld      r5, VCPU_LR(r4)
 713         lwz     r6, VCPU_CR(r4)
 714         mtlr    r5
 715         mtcr    r6
 716
 717         ld      r1, VCPU_GPR(R1)(r4)
 718         ld      r2, VCPU_GPR(R2)(r4)
 719         ld      r3, VCPU_GPR(R3)(r4)
 720         ld      r5, VCPU_GPR(R5)(r4)
 721         ld      r6, VCPU_GPR(R6)(r4)
 722         ld      r7, VCPU_GPR(R7)(r4)
 723         ld      r8, VCPU_GPR(R8)(r4)
 724         ld      r9, VCPU_GPR(R9)(r4)
 725         ld      r10, VCPU_GPR(R10)(r4)
 726         ld      r11, VCPU_GPR(R11)(r4)
 727         ld      r12, VCPU_GPR(R12)(r4)
 728         ld      r13, VCPU_GPR(R13)(r4)
 729
 730 BEGIN_FTR_SECTION
 731         mtspr   SPRN_PPR, r0
 732 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 733         ld      r0, VCPU_GPR(R0)(r4)
 734         ld      r4, VCPU_GPR(R4)(r4)
 735
 736         hrfid
 737         b       .
 738
 739 /******************************************************************************
 740  *                                                                            *
 741  *                               Exit code                                    *
 742  *                                                                            *
 743  *****************************************************************************/
 744
 745 /*
 746  * We come here from the first-level interrupt handlers.
 747  */
 748         .globl  kvmppc_interrupt_hv
 749 kvmppc_interrupt_hv:
 750         /*
 751          * Register contents:
 752          * R12          = interrupt vector
 753          * R13          = PACA
 754          * guest CR, R12 saved in shadow VCPU SCRATCH1/0
 755          * guest R13 saved in SPRN_SCRATCH0
 756          */
 757         /* abuse host_r2 as third scratch area; we get r2 from PACATOC(r13) */
 758         std     r9, HSTATE_HOST_R2(r13)
 759
 760         lbz     r9, HSTATE_IN_GUEST(r13)
 761         cmpwi   r9, KVM_GUEST_MODE_HOST_HV
 762         beq     kvmppc_bad_host_intr
 763 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
 764         cmpwi   r9, KVM_GUEST_MODE_GUEST
 765         ld      r9, HSTATE_HOST_R2(r13)
 766         beq     kvmppc_interrupt_pr
 767 #endif
 768         /* We're now back in the host but in guest MMU context */
 769         li      r9, KVM_GUEST_MODE_HOST_HV
 770         stb     r9, HSTATE_IN_GUEST(r13)
 771
 772         ld      r9, HSTATE_KVM_VCPU(r13)
 773
 774         /* Save registers */
 775
 776         std     r0, VCPU_GPR(R0)(r9)
 777         std     r1, VCPU_GPR(R1)(r9)
 778         std     r2, VCPU_GPR(R2)(r9)
 779         std     r3, VCPU_GPR(R3)(r9)
 780         std     r4, VCPU_GPR(R4)(r9)
 781         std     r5, VCPU_GPR(R5)(r9)
 782         std     r6, VCPU_GPR(R6)(r9)
 783         std     r7, VCPU_GPR(R7)(r9)
 784         std     r8, VCPU_GPR(R8)(r9)
 785         ld      r0, HSTATE_HOST_R2(r13)
 786         std     r0, VCPU_GPR(R9)(r9)
 787         std     r10, VCPU_GPR(R10)(r9)
 788         std     r11, VCPU_GPR(R11)(r9)
 789         ld      r3, HSTATE_SCRATCH0(r13)
 790         lwz     r4, HSTATE_SCRATCH1(r13)
 791         std     r3, VCPU_GPR(R12)(r9)
 792         stw     r4, VCPU_CR(r9)
 793 BEGIN_FTR_SECTION
 794         ld      r3, HSTATE_CFAR(r13)
 795         std     r3, VCPU_CFAR(r9)
 796 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 797 BEGIN_FTR_SECTION
 798         ld      r4, HSTATE_PPR(r13)
 799         std     r4, VCPU_PPR(r9)
 800 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 801
 802         /* Restore R1/R2 so we can handle faults */
 803         ld      r1, HSTATE_HOST_R1(r13)
 804         ld      r2, PACATOC(r13)
 805
 806         mfspr   r10, SPRN_SRR0
 807         mfspr   r11, SPRN_SRR1
 808         std     r10, VCPU_SRR0(r9)
 809         std     r11, VCPU_SRR1(r9)
 810         andi.   r0, r12, 2              /* need to read HSRR0/1? */
 811         beq     1f
 812         mfspr   r10, SPRN_HSRR0
 813         mfspr   r11, SPRN_HSRR1
 814         clrrdi  r12, r12, 2
 815 1:      std     r10, VCPU_PC(r9)
 816         std     r11, VCPU_MSR(r9)
 817
 818         GET_SCRATCH0(r3)
 819         mflr    r4
 820         std     r3, VCPU_GPR(R13)(r9)
 821         std     r4, VCPU_LR(r9)
 822
 823         stw     r12,VCPU_TRAP(r9)
 824
 825         /* Save HEIR (HV emulation assist reg) in last_inst
 826            if this is an HEI (HV emulation interrupt, e40) */
 827         li      r3,KVM_INST_FETCH_FAILED
 828 BEGIN_FTR_SECTION
 829         cmpwi   r12,BOOK3S_INTERRUPT_H_EMUL_ASSIST
 830         bne     11f
 831         mfspr   r3,SPRN_HEIR
 832 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
 833 11:     stw     r3,VCPU_LAST_INST(r9)
 834
 835         /* these are volatile across C function calls */
 836         mfctr   r3
 837         mfxer   r4
 838         std     r3, VCPU_CTR(r9)
 839         stw     r4, VCPU_XER(r9)
 840
 841 BEGIN_FTR_SECTION
 842         /* If this is a page table miss then see if it's theirs or ours */
 843         cmpwi   r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
 844         beq     kvmppc_hdsi
 845         cmpwi   r12, BOOK3S_INTERRUPT_H_INST_STORAGE
 846         beq     kvmppc_hisi
 847 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
 848
 849         /* See if this is a leftover HDEC interrupt */
 850         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
 851         bne     2f
 852         mfspr   r3,SPRN_HDEC
 853         cmpwi   r3,0
 854         bge     ignore_hdec
 855 2:
 856         /* See if this is an hcall we can handle in real mode */
 857         cmpwi   r12,BOOK3S_INTERRUPT_SYSCALL
 858         beq     hcall_try_real_mode
 859
 860         /* Only handle external interrupts here on arch 206 and later */
 861 BEGIN_FTR_SECTION
 862         b       ext_interrupt_to_host
 863 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_206)
 864
 865         /* External interrupt ? */
 866         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
 867         bne+    ext_interrupt_to_host
 868
 869         /* External interrupt, first check for host_ipi. If this is
 870          * set, we know the host wants us out so let's do it now
 871          */
 872 do_ext_interrupt:
 873         bl      kvmppc_read_intr
 874         cmpdi   r3, 0
 875         bgt     ext_interrupt_to_host
 876
 877         /* Allright, looks like an IPI for the guest, we need to set MER */
 878         /* Check if any CPU is heading out to the host, if so head out too */
 879         ld      r5, HSTATE_KVM_VCORE(r13)
 880         lwz     r0, VCORE_ENTRY_EXIT(r5)
 881         cmpwi   r0, 0x100
 882         bge     ext_interrupt_to_host
 883
 884         /* See if there is a pending interrupt for the guest */
 885         mfspr   r8, SPRN_LPCR
 886         ld      r0, VCPU_PENDING_EXC(r9)
 887         /* Insert EXTERNAL_LEVEL bit into LPCR at the MER bit position */
 888         rldicl. r0, r0, 64 - BOOK3S_IRQPRIO_EXTERNAL_LEVEL, 63
 889         rldimi  r8, r0, LPCR_MER_SH, 63 - LPCR_MER_SH
 890         beq     2f
 891
 892         /* And if the guest EE is set, we can deliver immediately, else
 893          * we return to the guest with MER set
 894          */
 895         andi.   r0, r11, MSR_EE
 896         beq     2f
 897         mtspr   SPRN_SRR0, r10
 898         mtspr   SPRN_SRR1, r11
 899         li      r10, BOOK3S_INTERRUPT_EXTERNAL
 900         li      r11, (MSR_ME << 1) | 1  /* synthesize MSR_SF | MSR_ME */
 901         rotldi  r11, r11, 63
 902 2:      mr      r4, r9
 903         mtspr   SPRN_LPCR, r8
 904         b       fast_guest_return
 905
 906 ext_interrupt_to_host:
 907
 908 guest_exit_cont:                /* r9 = vcpu, r12 = trap, r13 = paca */
 909         /* Save more register state  */
 910         mfdar   r6
 911         mfdsisr r7
 912         std     r6, VCPU_DAR(r9)
 913         stw     r7, VCPU_DSISR(r9)
 914 BEGIN_FTR_SECTION
 915         /* don't overwrite fault_dar/fault_dsisr if HDSI */
 916         cmpwi   r12,BOOK3S_INTERRUPT_H_DATA_STORAGE
 917         beq     6f
 918 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
 919         std     r6, VCPU_FAULT_DAR(r9)
 920         stw     r7, VCPU_FAULT_DSISR(r9)
 921
 922         /* See if it is a machine check */
 923         cmpwi   r12, BOOK3S_INTERRUPT_MACHINE_CHECK
 924         beq     machine_check_realmode
 925 mc_cont:
 926
 927         /* Save guest CTRL register, set runlatch to 1 */
 928 6:      mfspr   r6,SPRN_CTRLF
 929         stw     r6,VCPU_CTRL(r9)
 930         andi.   r0,r6,1
 931         bne     4f
 932         ori     r6,r6,1
 933         mtspr   SPRN_CTRLT,r6
 934 4:
 935         /* Read the guest SLB and save it away */
 936         lwz     r0,VCPU_SLB_NR(r9)      /* number of entries in SLB */
 937         mtctr   r0
 938         li      r6,0
 939         addi    r7,r9,VCPU_SLB
 940         li      r5,0
 941 1:      slbmfee r8,r6
 942         andis.  r0,r8,SLB_ESID_V@h
 943         beq     2f
 944         add     r8,r8,r6                /* put index in */
 945         slbmfev r3,r6
 946         std     r8,VCPU_SLB_E(r7)
 947         std     r3,VCPU_SLB_V(r7)
 948         addi    r7,r7,VCPU_SLB_SIZE
 949         addi    r5,r5,1
 950 2:      addi    r6,r6,1
 951         bdnz    1b
 952         stw     r5,VCPU_SLB_MAX(r9)
 953
 954         /*
 955          * Save the guest PURR/SPURR
 956          */
 957 BEGIN_FTR_SECTION
 958         mfspr   r5,SPRN_PURR
 959         mfspr   r6,SPRN_SPURR
 960         ld      r7,VCPU_PURR(r9)
 961         ld      r8,VCPU_SPURR(r9)
 962         std     r5,VCPU_PURR(r9)
 963         std     r6,VCPU_SPURR(r9)
 964         subf    r5,r7,r5
 965         subf    r6,r8,r6
 966
 967         /*
 968          * Restore host PURR/SPURR and add guest times
 969          * so that the time in the guest gets accounted.
 970          */
 971         ld      r3,HSTATE_PURR(r13)
 972         ld      r4,HSTATE_SPURR(r13)
 973         add     r3,r3,r5
 974         add     r4,r4,r6
 975         mtspr   SPRN_PURR,r3
 976         mtspr   SPRN_SPURR,r4
 977 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_201)
 978
 979         /* Clear out SLB */
 980         li      r5,0
 981         slbmte  r5,r5
 982         slbia
 983         ptesync
 984
 985 hdec_soon:                      /* r9 = vcpu, r12 = trap, r13 = paca */
 986 BEGIN_FTR_SECTION
 987         b       32f
 988 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
 989         /*
 990          * POWER7 guest -> host partition switch code.
 991          * We don't have to lock against tlbies but we do
 992          * have to coordinate the hardware threads.
 993          */
 994         /* Increment the threads-exiting-guest count in the 0xff00
 995            bits of vcore->entry_exit_count */
 996         ld      r5,HSTATE_KVM_VCORE(r13)
 997         addi    r6,r5,VCORE_ENTRY_EXIT
 998 41:     lwarx   r3,0,r6
 999         addi    r0,r3,0x100
1000         stwcx.  r0,0,r6
1001         bne     41b
1002         isync           /* order stwcx. vs. reading napping_threads */
1003
1004         /*
1005          * At this point we have an interrupt that we have to pass
1006          * up to the kernel or qemu; we can't handle it in real mode.
1007          * Thus we have to do a partition switch, so we have to
1008          * collect the other threads, if we are the first thread
1009          * to take an interrupt.  To do this, we set the HDEC to 0,
1010          * which causes an HDEC interrupt in all threads within 2ns
1011          * because the HDEC register is shared between all 4 threads.
1012          * However, we don't need to bother if this is an HDEC
1013          * interrupt, since the other threads will already be on their
1014          * way here in that case.
1015          */
1016         cmpwi   r3,0x100        /* Are we the first here? */
1017         bge     43f
1018         cmpwi   r3,1            /* Are any other threads in the guest? */
1019         ble     43f
1020         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
1021         beq     40f
1022         li      r0,0
1023         mtspr   SPRN_HDEC,r0
1024 40:
1025         /*
1026          * Send an IPI to any napping threads, since an HDEC interrupt
1027          * doesn't wake CPUs up from nap.
1028          */
1029         lwz     r3,VCORE_NAPPING_THREADS(r5)
1030         lwz     r4,VCPU_PTID(r9)
1031         li      r0,1
1032         sld     r0,r0,r4
1033         andc.   r3,r3,r0                /* no sense IPI'ing ourselves */
1034         beq     43f
1035         /* Order entry/exit update vs. IPIs */
1036         sync
1037         mulli   r4,r4,PACA_SIZE         /* get paca for thread 0 */
1038         subf    r6,r4,r13
1039 42:     andi.   r0,r3,1
1040         beq     44f
1041         ld      r8,HSTATE_XICS_PHYS(r6) /* get thread's XICS reg addr */
1042         li      r0,IPI_PRIORITY
1043         li      r7,XICS_MFRR
1044         stbcix  r0,r7,r8                /* trigger the IPI */
1045 44:     srdi.   r3,r3,1
1046         addi    r6,r6,PACA_SIZE
1047         bne     42b
1048
1049         /* Secondary threads wait for primary to do partition switch */
1050 43:     ld      r4,VCPU_KVM(r9)         /* pointer to struct kvm */
1051         ld      r5,HSTATE_KVM_VCORE(r13)
1052         lwz     r3,VCPU_PTID(r9)
1053         cmpwi   r3,0
1054         beq     15f
1055         HMT_LOW
1056 13:     lbz     r3,VCORE_IN_GUEST(r5)
1057         cmpwi   r3,0
1058         bne     13b
1059         HMT_MEDIUM
1060         b       16f
1061
1062         /* Primary thread waits for all the secondaries to exit guest */
1063 15:     lwz     r3,VCORE_ENTRY_EXIT(r5)
1064         srwi    r0,r3,8
1065         clrldi  r3,r3,56
1066         cmpw    r3,r0
1067         bne     15b
1068         isync
1069
1070         /* Primary thread switches back to host partition */
1071         ld      r6,KVM_HOST_SDR1(r4)
1072         lwz     r7,KVM_HOST_LPID(r4)
1073         li      r8,LPID_RSVD            /* switch to reserved LPID */
1074         mtspr   SPRN_LPID,r8
1075         ptesync
1076         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
1077         mtspr   SPRN_LPID,r7
1078         isync
1079
1080         /* Subtract timebase offset from timebase */
1081         ld      r8,VCORE_TB_OFFSET(r5)
1082         cmpdi   r8,0
1083         beq     17f
1084         mftb    r6                      /* current host timebase */
1085         subf    r8,r8,r6
1086         mtspr   SPRN_TBU40,r8           /* update upper 40 bits */
1087         mftb    r7                      /* check if lower 24 bits overflowed */
1088         clrldi  r6,r6,40
1089         clrldi  r7,r7,40
1090         cmpld   r7,r6
1091         bge     17f
1092         addis   r8,r8,0x100             /* if so, increment upper 40 bits */
1093         mtspr   SPRN_TBU40,r8
1094
1095         /* Reset PCR */
1096 17:     ld      r0, VCORE_PCR(r5)
1097         cmpdi   r0, 0
1098         beq     18f
1099         li      r0, 0
1100         mtspr   SPRN_PCR, r0
1101 18:
1102         /* Signal secondary CPUs to continue */
1103         stb     r0,VCORE_IN_GUEST(r5)
1104         lis     r8,0x7fff               /* MAX_INT@h */
1105         mtspr   SPRN_HDEC,r8
1106
1107 16:     ld      r8,KVM_HOST_LPCR(r4)
1108         mtspr   SPRN_LPCR,r8
1109         isync
1110         b       33f
1111
1112         /*
1113          * PPC970 guest -> host partition switch code.
1114          * We have to lock against concurrent tlbies, and
1115          * we have to flush the whole TLB.
1116          */
1117 32:     ld      r4,VCPU_KVM(r9)         /* pointer to struct kvm */
1118
1119         /* Take the guest's tlbie_lock */
1120 #ifdef __BIG_ENDIAN__
1121         lwz     r8,PACA_LOCK_TOKEN(r13)
1122 #else
1123         lwz     r8,PACAPACAINDEX(r13)
1124 #endif
1125         addi    r3,r4,KVM_TLBIE_LOCK
1126 24:     lwarx   r0,0,r3
1127         cmpwi   r0,0
1128         bne     24b
1129         stwcx.  r8,0,r3
1130         bne     24b
1131         isync
1132
1133         ld      r7,KVM_HOST_LPCR(r4)    /* use kvm->arch.host_lpcr for HID4 */
1134         li      r0,0x18f
1135         rotldi  r0,r0,HID4_LPID5_SH     /* all lpid bits in HID4 = 1 */
1136         or      r0,r7,r0
1137         ptesync
1138         sync
1139         mtspr   SPRN_HID4,r0            /* switch to reserved LPID */
1140         isync
1141         li      r0,0
1142         stw     r0,0(r3)                /* drop guest tlbie_lock */
1143
1144         /* invalidate the whole TLB */
1145         li      r0,256
1146         mtctr   r0
1147         li      r6,0
1148 25:     tlbiel  r6
1149         addi    r6,r6,0x1000
1150         bdnz    25b
1151         ptesync
1152
1153         /* take native_tlbie_lock */
1154         ld      r3,toc_tlbie_lock@toc(2)
1155 24:     lwarx   r0,0,r3
1156         cmpwi   r0,0
1157         bne     24b
1158         stwcx.  r8,0,r3
1159         bne     24b
1160         isync
1161
1162         ld      r6,KVM_HOST_SDR1(r4)
1163         mtspr   SPRN_SDR1,r6            /* switch to host page table */
1164
1165         /* Set up host HID4 value */
1166         sync
1167         mtspr   SPRN_HID4,r7
1168         isync
1169         li      r0,0
1170         stw     r0,0(r3)                /* drop native_tlbie_lock */
1171
1172         lis     r8,0x7fff               /* MAX_INT@h */
1173         mtspr   SPRN_HDEC,r8
1174
1175         /* Disable HDEC interrupts */
1176         mfspr   r0,SPRN_HID0
1177         li      r3,0
1178         rldimi  r0,r3, HID0_HDICE_SH, 64-HID0_HDICE_SH-1
1179         sync
1180         mtspr   SPRN_HID0,r0
1181         mfspr   r0,SPRN_HID0
1182         mfspr   r0,SPRN_HID0
1183         mfspr   r0,SPRN_HID0
1184         mfspr   r0,SPRN_HID0
1185         mfspr   r0,SPRN_HID0
1186         mfspr   r0,SPRN_HID0
1187
1188         /* load host SLB entries */
1189 33:     ld      r8,PACA_SLBSHADOWPTR(r13)
1190
1191         .rept   SLB_NUM_BOLTED
1192         ld      r5,SLBSHADOW_SAVEAREA(r8)
1193         ld      r6,SLBSHADOW_SAVEAREA+8(r8)
1194         andis.  r7,r5,SLB_ESID_V@h
1195         beq     1f
1196         slbmte  r6,r5
1197 1:      addi    r8,r8,16
1198         .endr
1199
1200         /* Save DEC */
1201         mfspr   r5,SPRN_DEC
1202         mftb    r6
1203         extsw   r5,r5
1204         add     r5,r5,r6
1205         std     r5,VCPU_DEC_EXPIRES(r9)
1206
1207         /* Save and reset AMR and UAMOR before turning on the MMU */
1208 BEGIN_FTR_SECTION
1209         mfspr   r5,SPRN_AMR
1210         mfspr   r6,SPRN_UAMOR
1211         std     r5,VCPU_AMR(r9)
1212         std     r6,VCPU_UAMOR(r9)
1213         li      r6,0
1214         mtspr   SPRN_AMR,r6
1215 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
1216
1217         /* Unset guest mode */
1218         li      r0, KVM_GUEST_MODE_NONE
1219         stb     r0, HSTATE_IN_GUEST(r13)
1220
1221         /* Switch DSCR back to host value */
1222 BEGIN_FTR_SECTION
1223         mfspr   r8, SPRN_DSCR
1224         ld      r7, HSTATE_DSCR(r13)
1225         std     r8, VCPU_DSCR(r9)
1226         mtspr   SPRN_DSCR, r7
1227 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
1228
1229         /* Save non-volatile GPRs */
1230         std     r14, VCPU_GPR(R14)(r9)
1231         std     r15, VCPU_GPR(R15)(r9)
1232         std     r16, VCPU_GPR(R16)(r9)
1233         std     r17, VCPU_GPR(R17)(r9)
1234         std     r18, VCPU_GPR(R18)(r9)
1235         std     r19, VCPU_GPR(R19)(r9)
1236         std     r20, VCPU_GPR(R20)(r9)
1237         std     r21, VCPU_GPR(R21)(r9)
1238         std     r22, VCPU_GPR(R22)(r9)
1239         std     r23, VCPU_GPR(R23)(r9)
1240         std     r24, VCPU_GPR(R24)(r9)
1241         std     r25, VCPU_GPR(R25)(r9)
1242         std     r26, VCPU_GPR(R26)(r9)
1243         std     r27, VCPU_GPR(R27)(r9)
1244         std     r28, VCPU_GPR(R28)(r9)
1245         std     r29, VCPU_GPR(R29)(r9)
1246         std     r30, VCPU_GPR(R30)(r9)
1247         std     r31, VCPU_GPR(R31)(r9)
1248
1249         /* Save SPRGs */
1250         mfspr   r3, SPRN_SPRG0
1251         mfspr   r4, SPRN_SPRG1
1252         mfspr   r5, SPRN_SPRG2
1253         mfspr   r6, SPRN_SPRG3
1254         std     r3, VCPU_SPRG0(r9)
1255         std     r4, VCPU_SPRG1(r9)
1256         std     r5, VCPU_SPRG2(r9)
1257         std     r6, VCPU_SPRG3(r9)
1258
1259         /* save FP state */
1260         mr      r3, r9
1261         bl      .kvmppc_save_fp
1262
1263         /* Increment yield count if they have a VPA */
1264         ld      r8, VCPU_VPA(r9)        /* do they have a VPA? */
1265         cmpdi   r8, 0
1266         beq     25f
1267         lwz     r3, LPPACA_YIELDCOUNT(r8)
1268         addi    r3, r3, 1
1269         stw     r3, LPPACA_YIELDCOUNT(r8)
1270         li      r3, 1
1271         stb     r3, VCPU_VPA_DIRTY(r9)
1272 25:
1273         /* Save PMU registers if requested */
1274         /* r8 and cr0.eq are live here */
1275         li      r3, 1
1276         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
1277         mfspr   r4, SPRN_MMCR0          /* save MMCR0 */
1278         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
1279         mfspr   r6, SPRN_MMCRA
1280 BEGIN_FTR_SECTION
1281         /* On P7, clear MMCRA in order to disable SDAR updates */
1282         li      r7, 0
1283         mtspr   SPRN_MMCRA, r7
1284 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
1285         isync
1286         beq     21f                     /* if no VPA, save PMU stuff anyway */
1287         lbz     r7, LPPACA_PMCINUSE(r8)
1288         cmpwi   r7, 0                   /* did they ask for PMU stuff to be saved? */
1289         bne     21f
1290         std     r3, VCPU_MMCR(r9)       /* if not, set saved MMCR0 to FC */
1291         b       22f
1292 21:     mfspr   r5, SPRN_MMCR1
1293         mfspr   r7, SPRN_SIAR
1294         mfspr   r8, SPRN_SDAR
1295         std     r4, VCPU_MMCR(r9)
1296         std     r5, VCPU_MMCR + 8(r9)
1297         std     r6, VCPU_MMCR + 16(r9)
1298         std     r7, VCPU_SIAR(r9)
1299         std     r8, VCPU_SDAR(r9)
1300         mfspr   r3, SPRN_PMC1
1301         mfspr   r4, SPRN_PMC2
1302         mfspr   r5, SPRN_PMC3
1303         mfspr   r6, SPRN_PMC4
1304         mfspr   r7, SPRN_PMC5
1305         mfspr   r8, SPRN_PMC6
1306 BEGIN_FTR_SECTION
1307         mfspr   r10, SPRN_PMC7
1308         mfspr   r11, SPRN_PMC8
1309 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
1310         stw     r3, VCPU_PMC(r9)
1311         stw     r4, VCPU_PMC + 4(r9)
1312         stw     r5, VCPU_PMC + 8(r9)
1313         stw     r6, VCPU_PMC + 12(r9)
1314         stw     r7, VCPU_PMC + 16(r9)
1315         stw     r8, VCPU_PMC + 20(r9)
1316 BEGIN_FTR_SECTION
1317         stw     r10, VCPU_PMC + 24(r9)
1318         stw     r11, VCPU_PMC + 28(r9)
1319 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
1320 22:
1321         ld      r0, 112+PPC_LR_STKOFF(r1)
1322         addi    r1, r1, 112
1323         mtlr    r0
1324         blr
1325 secondary_too_late:
1326         ld      r5,HSTATE_KVM_VCORE(r13)
1327         HMT_LOW
1328 13:     lbz     r3,VCORE_IN_GUEST(r5)
1329         cmpwi   r3,0
1330         bne     13b
1331         HMT_MEDIUM
1332         li      r0, KVM_GUEST_MODE_NONE
1333         stb     r0, HSTATE_IN_GUEST(r13)
1334         ld      r11,PACA_SLBSHADOWPTR(r13)
1335
1336         .rept   SLB_NUM_BOLTED
1337         ld      r5,SLBSHADOW_SAVEAREA(r11)
1338         ld      r6,SLBSHADOW_SAVEAREA+8(r11)
1339         andis.  r7,r5,SLB_ESID_V@h
1340         beq     1f
1341         slbmte  r6,r5
1342 1:      addi    r11,r11,16
1343         .endr
1344         b       22b
1345
1346 /*
1347  * Check whether an HDSI is an HPTE not found fault or something else.
1348  * If it is an HPTE not found fault that is due to the guest accessing
1349  * a page that they have mapped but which we have paged out, then
1350  * we continue on with the guest exit path.  In all other cases,
1351  * reflect the HDSI to the guest as a DSI.
1352  */
1353 kvmppc_hdsi:
1354         mfspr   r4, SPRN_HDAR
1355         mfspr   r6, SPRN_HDSISR
1356         /* HPTE not found fault or protection fault? */
1357         andis.  r0, r6, (DSISR_NOHPTE | DSISR_PROTFAULT)@h
1358         beq     1f                      /* if not, send it to the guest */
1359         andi.   r0, r11, MSR_DR         /* data relocation enabled? */
1360         beq     3f
1361         clrrdi  r0, r4, 28
1362         PPC_SLBFEE_DOT(R5, R0)          /* if so, look up SLB */
1363         bne     1f                      /* if no SLB entry found */
1364 4:      std     r4, VCPU_FAULT_DAR(r9)
1365         stw     r6, VCPU_FAULT_DSISR(r9)
1366
1367         /* Search the hash table. */
1368         mr      r3, r9                  /* vcpu pointer */
1369         li      r7, 1                   /* data fault */
1370         bl      .kvmppc_hpte_hv_fault
1371         ld      r9, HSTATE_KVM_VCPU(r13)
1372         ld      r10, VCPU_PC(r9)
1373         ld      r11, VCPU_MSR(r9)
1374         li      r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
1375         cmpdi   r3, 0                   /* retry the instruction */
1376         beq     6f
1377         cmpdi   r3, -1                  /* handle in kernel mode */
1378         beq     guest_exit_cont
1379         cmpdi   r3, -2                  /* MMIO emulation; need instr word */
1380         beq     2f
1381
1382         /* Synthesize a DSI for the guest */
1383         ld      r4, VCPU_FAULT_DAR(r9)
1384         mr      r6, r3
1385 1:      mtspr   SPRN_DAR, r4
1386         mtspr   SPRN_DSISR, r6
1387         mtspr   SPRN_SRR0, r10
1388         mtspr   SPRN_SRR1, r11
1389         li      r10, BOOK3S_INTERRUPT_DATA_STORAGE
1390         li      r11, (MSR_ME << 1) | 1  /* synthesize MSR_SF | MSR_ME */
1391         rotldi  r11, r11, 63
1392 fast_interrupt_c_return:
1393 6:      ld      r7, VCPU_CTR(r9)
1394         lwz     r8, VCPU_XER(r9)
1395         mtctr   r7
1396         mtxer   r8
1397         mr      r4, r9
1398         b       fast_guest_return
1399
1400 3:      ld      r5, VCPU_KVM(r9)        /* not relocated, use VRMA */
1401         ld      r5, KVM_VRMA_SLB_V(r5)
1402         b       4b
1403
1404         /* If this is for emulated MMIO, load the instruction word */
1405 2:      li      r8, KVM_INST_FETCH_FAILED       /* In case lwz faults */
1406
1407         /* Set guest mode to 'jump over instruction' so if lwz faults
1408          * we'll just continue at the next IP. */
1409         li      r0, KVM_GUEST_MODE_SKIP
1410         stb     r0, HSTATE_IN_GUEST(r13)
1411
1412         /* Do the access with MSR:DR enabled */
1413         mfmsr   r3
1414         ori     r4, r3, MSR_DR          /* Enable paging for data */
1415         mtmsrd  r4
1416         lwz     r8, 0(r10)
1417         mtmsrd  r3
1418
1419         /* Store the result */
1420         stw     r8, VCPU_LAST_INST(r9)
1421
1422         /* Unset guest mode. */
1423         li      r0, KVM_GUEST_MODE_HOST_HV
1424         stb     r0, HSTATE_IN_GUEST(r13)
1425         b       guest_exit_cont
1426
1427 /*
1428  * Similarly for an HISI, reflect it to the guest as an ISI unless
1429  * it is an HPTE not found fault for a page that we have paged out.
1430  */
1431 kvmppc_hisi:
1432         andis.  r0, r11, SRR1_ISI_NOPT@h
1433         beq     1f
1434         andi.   r0, r11, MSR_IR         /* instruction relocation enabled? */
1435         beq     3f
1436         clrrdi  r0, r10, 28
1437         PPC_SLBFEE_DOT(R5, R0)          /* if so, look up SLB */
1438         bne     1f                      /* if no SLB entry found */
1439 4:
1440         /* Search the hash table. */
1441         mr      r3, r9                  /* vcpu pointer */
1442         mr      r4, r10
1443         mr      r6, r11
1444         li      r7, 0                   /* instruction fault */
1445         bl      .kvmppc_hpte_hv_fault
1446         ld      r9, HSTATE_KVM_VCPU(r13)
1447         ld      r10, VCPU_PC(r9)
1448         ld      r11, VCPU_MSR(r9)
1449         li      r12, BOOK3S_INTERRUPT_H_INST_STORAGE
1450         cmpdi   r3, 0                   /* retry the instruction */
1451         beq     fast_interrupt_c_return
1452         cmpdi   r3, -1                  /* handle in kernel mode */
1453         beq     guest_exit_cont
1454
1455         /* Synthesize an ISI for the guest */
1456         mr      r11, r3
1457 1:      mtspr   SPRN_SRR0, r10
1458         mtspr   SPRN_SRR1, r11
1459         li      r10, BOOK3S_INTERRUPT_INST_STORAGE
1460         li      r11, (MSR_ME << 1) | 1  /* synthesize MSR_SF | MSR_ME */
1461         rotldi  r11, r11, 63
1462         b       fast_interrupt_c_return
1463
1464 3:      ld      r6, VCPU_KVM(r9)        /* not relocated, use VRMA */
1465         ld      r5, KVM_VRMA_SLB_V(r6)
1466         b       4b
1467
1468 /*
1469  * Try to handle an hcall in real mode.
1470  * Returns to the guest if we handle it, or continues on up to
1471  * the kernel if we can't (i.e. if we don't have a handler for
1472  * it, or if the handler returns H_TOO_HARD).
1473  */
1474         .globl  hcall_try_real_mode
1475 hcall_try_real_mode:
1476         ld      r3,VCPU_GPR(R3)(r9)
1477         andi.   r0,r11,MSR_PR
1478         bne     guest_exit_cont
1479         clrrdi  r3,r3,2
1480         cmpldi  r3,hcall_real_table_end - hcall_real_table
1481         bge     guest_exit_cont
1482         LOAD_REG_ADDR(r4, hcall_real_table)
1483         lwax    r3,r3,r4
1484         cmpwi   r3,0
1485         beq     guest_exit_cont
1486         add     r3,r3,r4
1487         mtctr   r3
1488         mr      r3,r9           /* get vcpu pointer */
1489         ld      r4,VCPU_GPR(R4)(r9)
1490         bctrl
1491         cmpdi   r3,H_TOO_HARD
1492         beq     hcall_real_fallback
1493         ld      r4,HSTATE_KVM_VCPU(r13)
1494         std     r3,VCPU_GPR(R3)(r4)
1495         ld      r10,VCPU_PC(r4)
1496         ld      r11,VCPU_MSR(r4)
1497         b       fast_guest_return
1498
1499         /* We've attempted a real mode hcall, but it's punted it back
1500          * to userspace.  We need to restore some clobbered volatiles
1501          * before resuming the pass-it-to-qemu path */
1502 hcall_real_fallback:
1503         li      r12,BOOK3S_INTERRUPT_SYSCALL
1504         ld      r9, HSTATE_KVM_VCPU(r13)
1505
1506         b       guest_exit_cont
1507
1508         .globl  hcall_real_table
1509 hcall_real_table:
1510         .long   0               /* 0 - unused */
1511         .long   .kvmppc_h_remove - hcall_real_table
1512         .long   .kvmppc_h_enter - hcall_real_table
1513         .long   .kvmppc_h_read - hcall_real_table
1514         .long   0               /* 0x10 - H_CLEAR_MOD */
1515         .long   0               /* 0x14 - H_CLEAR_REF */
1516         .long   .kvmppc_h_protect - hcall_real_table
1517         .long   0               /* 0x1c - H_GET_TCE */
1518         .long   .kvmppc_h_put_tce - hcall_real_table
1519         .long   0               /* 0x24 - H_SET_SPRG0 */
1520         .long   .kvmppc_h_set_dabr - hcall_real_table
1521         .long   0               /* 0x2c */
1522         .long   0               /* 0x30 */
1523         .long   0               /* 0x34 */
1524         .long   0               /* 0x38 */
1525         .long   0               /* 0x3c */
1526         .long   0               /* 0x40 */
1527         .long   0               /* 0x44 */
1528         .long   0               /* 0x48 */
1529         .long   0               /* 0x4c */
1530         .long   0               /* 0x50 */
1531         .long   0               /* 0x54 */
1532         .long   0               /* 0x58 */
1533         .long   0               /* 0x5c */
1534         .long   0               /* 0x60 */
1535 #ifdef CONFIG_KVM_XICS
1536         .long   .kvmppc_rm_h_eoi - hcall_real_table
1537         .long   .kvmppc_rm_h_cppr - hcall_real_table
1538         .long   .kvmppc_rm_h_ipi - hcall_real_table
1539         .long   0               /* 0x70 - H_IPOLL */
1540         .long   .kvmppc_rm_h_xirr - hcall_real_table
1541 #else
1542         .long   0               /* 0x64 - H_EOI */
1543         .long   0               /* 0x68 - H_CPPR */
1544         .long   0               /* 0x6c - H_IPI */
1545         .long   0               /* 0x70 - H_IPOLL */
1546         .long   0               /* 0x74 - H_XIRR */
1547 #endif
1548         .long   0               /* 0x78 */
1549         .long   0               /* 0x7c */
1550         .long   0               /* 0x80 */
1551         .long   0               /* 0x84 */
1552         .long   0               /* 0x88 */
1553         .long   0               /* 0x8c */
1554         .long   0               /* 0x90 */
1555         .long   0               /* 0x94 */
1556         .long   0               /* 0x98 */
1557         .long   0               /* 0x9c */
1558         .long   0               /* 0xa0 */
1559         .long   0               /* 0xa4 */
1560         .long   0               /* 0xa8 */
1561         .long   0               /* 0xac */
1562         .long   0               /* 0xb0 */
1563         .long   0               /* 0xb4 */
1564         .long   0               /* 0xb8 */
1565         .long   0               /* 0xbc */
1566         .long   0               /* 0xc0 */
1567         .long   0               /* 0xc4 */
1568         .long   0               /* 0xc8 */
1569         .long   0               /* 0xcc */
1570         .long   0               /* 0xd0 */
1571         .long   0               /* 0xd4 */
1572         .long   0               /* 0xd8 */
1573         .long   0               /* 0xdc */
1574         .long   .kvmppc_h_cede - hcall_real_table
1575         .long   0               /* 0xe4 */
1576         .long   0               /* 0xe8 */
1577         .long   0               /* 0xec */
1578         .long   0               /* 0xf0 */
1579         .long   0               /* 0xf4 */
1580         .long   0               /* 0xf8 */
1581         .long   0               /* 0xfc */
1582         .long   0               /* 0x100 */
1583         .long   0               /* 0x104 */
1584         .long   0               /* 0x108 */
1585         .long   0               /* 0x10c */
1586         .long   0               /* 0x110 */
1587         .long   0               /* 0x114 */
1588         .long   0               /* 0x118 */
1589         .long   0               /* 0x11c */
1590         .long   0               /* 0x120 */
1591         .long   .kvmppc_h_bulk_remove - hcall_real_table
1592 hcall_real_table_end:
1593
1594 ignore_hdec:
1595         mr      r4,r9
1596         b       fast_guest_return
1597
1598 _GLOBAL(kvmppc_h_set_dabr)
1599         std     r4,VCPU_DABR(r3)
1600         /* Work around P7 bug where DABR can get corrupted on mtspr */
1601 1:      mtspr   SPRN_DABR,r4
1602         mfspr   r5, SPRN_DABR
1603         cmpd    r4, r5
1604         bne     1b
1605         isync
1606         li      r3,0
1607         blr
1608
1609 _GLOBAL(kvmppc_h_cede)
1610         ori     r11,r11,MSR_EE
1611         std     r11,VCPU_MSR(r3)
1612         li      r0,1
1613         stb     r0,VCPU_CEDED(r3)
1614         sync                    /* order setting ceded vs. testing prodded */
1615         lbz     r5,VCPU_PRODDED(r3)
1616         cmpwi   r5,0
1617         bne     kvm_cede_prodded
1618         li      r0,0            /* set trap to 0 to say hcall is handled */
1619         stw     r0,VCPU_TRAP(r3)
1620         li      r0,H_SUCCESS
1621         std     r0,VCPU_GPR(R3)(r3)
1622 BEGIN_FTR_SECTION
1623         b       kvm_cede_exit   /* just send it up to host on 970 */
1624 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_206)
1625
1626         /*
1627          * Set our bit in the bitmask of napping threads unless all the
1628          * other threads are already napping, in which case we send this
1629          * up to the host.
1630          */
1631         ld      r5,HSTATE_KVM_VCORE(r13)
1632         lwz     r6,VCPU_PTID(r3)
1633         lwz     r8,VCORE_ENTRY_EXIT(r5)
1634         clrldi  r8,r8,56
1635         li      r0,1
1636         sld     r0,r0,r6
1637         addi    r6,r5,VCORE_NAPPING_THREADS
1638 31:     lwarx   r4,0,r6
1639         or      r4,r4,r0
1640         PPC_POPCNTW(R7,R4)
1641         cmpw    r7,r8
1642         bge     kvm_cede_exit
1643         stwcx.  r4,0,r6
1644         bne     31b
1645         /* order napping_threads update vs testing entry_exit_count */
1646         isync
1647         li      r0,1
1648         stb     r0,HSTATE_NAPPING(r13)
1649         mr      r4,r3
1650         lwz     r7,VCORE_ENTRY_EXIT(r5)
1651         cmpwi   r7,0x100
1652         bge     33f             /* another thread already exiting */
1653
1654 /*
1655  * Although not specifically required by the architecture, POWER7
1656  * preserves the following registers in nap mode, even if an SMT mode
1657  * switch occurs: SLB entries, PURR, SPURR, AMOR, UAMOR, AMR, SPRG0-3,
1658  * DAR, DSISR, DABR, DABRX, DSCR, PMCx, MMCRx, SIAR, SDAR.
1659  */
1660         /* Save non-volatile GPRs */
1661         std     r14, VCPU_GPR(R14)(r3)
1662         std     r15, VCPU_GPR(R15)(r3)
1663         std     r16, VCPU_GPR(R16)(r3)
1664         std     r17, VCPU_GPR(R17)(r3)
1665         std     r18, VCPU_GPR(R18)(r3)
1666         std     r19, VCPU_GPR(R19)(r3)
1667         std     r20, VCPU_GPR(R20)(r3)
1668         std     r21, VCPU_GPR(R21)(r3)
1669         std     r22, VCPU_GPR(R22)(r3)
1670         std     r23, VCPU_GPR(R23)(r3)
1671         std     r24, VCPU_GPR(R24)(r3)
1672         std     r25, VCPU_GPR(R25)(r3)
1673         std     r26, VCPU_GPR(R26)(r3)
1674         std     r27, VCPU_GPR(R27)(r3)
1675         std     r28, VCPU_GPR(R28)(r3)
1676         std     r29, VCPU_GPR(R29)(r3)
1677         std     r30, VCPU_GPR(R30)(r3)
1678         std     r31, VCPU_GPR(R31)(r3)
1679
1680         /* save FP state */
1681         bl      .kvmppc_save_fp
1682
1683         /*
1684          * Take a nap until a decrementer or external interrupt occurs,
1685          * with PECE1 (wake on decr) and PECE0 (wake on external) set in LPCR
1686          */
1687         li      r0,1
1688         stb     r0,HSTATE_HWTHREAD_REQ(r13)
1689         mfspr   r5,SPRN_LPCR
1690         ori     r5,r5,LPCR_PECE0 | LPCR_PECE1
1691         mtspr   SPRN_LPCR,r5
1692         isync
1693         li      r0, 0
1694         std     r0, HSTATE_SCRATCH0(r13)
1695         ptesync
1696         ld      r0, HSTATE_SCRATCH0(r13)
1697 1:      cmpd    r0, r0
1698         bne     1b
1699         nap
1700         b       .
1701
1702 kvm_end_cede:
1703         /* get vcpu pointer */
1704         ld      r4, HSTATE_KVM_VCPU(r13)
1705
1706         /* Woken by external or decrementer interrupt */
1707         ld      r1, HSTATE_HOST_R1(r13)
1708
1709         /* load up FP state */
1710         bl      kvmppc_load_fp
1711
1712         /* Load NV GPRS */
1713         ld      r14, VCPU_GPR(R14)(r4)
1714         ld      r15, VCPU_GPR(R15)(r4)
1715         ld      r16, VCPU_GPR(R16)(r4)
1716         ld      r17, VCPU_GPR(R17)(r4)
1717         ld      r18, VCPU_GPR(R18)(r4)
1718         ld      r19, VCPU_GPR(R19)(r4)
1719         ld      r20, VCPU_GPR(R20)(r4)
1720         ld      r21, VCPU_GPR(R21)(r4)
1721         ld      r22, VCPU_GPR(R22)(r4)
1722         ld      r23, VCPU_GPR(R23)(r4)
1723         ld      r24, VCPU_GPR(R24)(r4)
1724         ld      r25, VCPU_GPR(R25)(r4)
1725         ld      r26, VCPU_GPR(R26)(r4)
1726         ld      r27, VCPU_GPR(R27)(r4)
1727         ld      r28, VCPU_GPR(R28)(r4)
1728         ld      r29, VCPU_GPR(R29)(r4)
1729         ld      r30, VCPU_GPR(R30)(r4)
1730         ld      r31, VCPU_GPR(R31)(r4)
1731
1732         /* clear our bit in vcore->napping_threads */
1733 33:     ld      r5,HSTATE_KVM_VCORE(r13)
1734         lwz     r3,VCPU_PTID(r4)
1735         li      r0,1
1736         sld     r0,r0,r3
1737         addi    r6,r5,VCORE_NAPPING_THREADS
1738 32:     lwarx   r7,0,r6
1739         andc    r7,r7,r0
1740         stwcx.  r7,0,r6
1741         bne     32b
1742         li      r0,0
1743         stb     r0,HSTATE_NAPPING(r13)
1744
1745         /* Check the wake reason in SRR1 to see why we got here */
1746         mfspr   r3, SPRN_SRR1
1747         rlwinm  r3, r3, 44-31, 0x7      /* extract wake reason field */
1748         cmpwi   r3, 4                   /* was it an external interrupt? */
1749         li      r12, BOOK3S_INTERRUPT_EXTERNAL
1750         mr      r9, r4
1751         ld      r10, VCPU_PC(r9)
1752         ld      r11, VCPU_MSR(r9)
1753         beq     do_ext_interrupt        /* if so */
1754
1755         /* see if any other thread is already exiting */
1756         lwz     r0,VCORE_ENTRY_EXIT(r5)
1757         cmpwi   r0,0x100
1758         blt     kvmppc_cede_reentry     /* if not go back to guest */
1759
1760         /* some threads are exiting, so go to the guest exit path */
1761         b       hcall_real_fallback
1762
1763         /* cede when already previously prodded case */
1764 kvm_cede_prodded:
1765         li      r0,0
1766         stb     r0,VCPU_PRODDED(r3)
1767         sync                    /* order testing prodded vs. clearing ceded */
1768         stb     r0,VCPU_CEDED(r3)
1769         li      r3,H_SUCCESS
1770         blr
1771
1772         /* we've ceded but we want to give control to the host */
1773 kvm_cede_exit:
1774         b       hcall_real_fallback
1775
1776         /* Try to handle a machine check in real mode */
1777 machine_check_realmode:
1778         mr      r3, r9          /* get vcpu pointer */
1779         bl      .kvmppc_realmode_machine_check
1780         nop
1781         cmpdi   r3, 0           /* continue exiting from guest? */
1782         ld      r9, HSTATE_KVM_VCPU(r13)
1783         li      r12, BOOK3S_INTERRUPT_MACHINE_CHECK
1784         beq     mc_cont
1785         /* If not, deliver a machine check.  SRR0/1 are already set */
1786         li      r10, BOOK3S_INTERRUPT_MACHINE_CHECK
1787         li      r11, (MSR_ME << 1) | 1  /* synthesize MSR_SF | MSR_ME */
1788         rotldi  r11, r11, 63
1789         b       fast_interrupt_c_return
1790
1791 /*
1792  * Determine what sort of external interrupt is pending (if any).
1793  * Returns:
1794  *      0 if no interrupt is pending
1795  *      1 if an interrupt is pending that needs to be handled by the host
1796  *      -1 if there was a guest wakeup IPI (which has now been cleared)
1797  */
1798 kvmppc_read_intr:
1799         /* see if a host IPI is pending */
1800         li      r3, 1
1801         lbz     r0, HSTATE_HOST_IPI(r13)
1802         cmpwi   r0, 0
1803         bne     1f
1804
1805         /* Now read the interrupt from the ICP */
1806         ld      r6, HSTATE_XICS_PHYS(r13)
1807         li      r7, XICS_XIRR
1808         cmpdi   r6, 0
1809         beq-    1f
1810         lwzcix  r0, r6, r7
1811         rlwinm. r3, r0, 0, 0xffffff
1812         sync
1813         beq     1f                      /* if nothing pending in the ICP */
1814
1815         /* We found something in the ICP...
1816          *
1817          * If it's not an IPI, stash it in the PACA and return to
1818          * the host, we don't (yet) handle directing real external
1819          * interrupts directly to the guest
1820          */
1821         cmpwi   r3, XICS_IPI            /* if there is, is it an IPI? */
1822         li      r3, 1
1823         bne     42f
1824
1825         /* It's an IPI, clear the MFRR and EOI it */
1826         li      r3, 0xff
1827         li      r8, XICS_MFRR
1828         stbcix  r3, r6, r8              /* clear the IPI */
1829         stwcix  r0, r6, r7              /* EOI it */
1830         sync
1831
1832         /* We need to re-check host IPI now in case it got set in the
1833          * meantime. If it's clear, we bounce the interrupt to the
1834          * guest
1835          */
1836         lbz     r0, HSTATE_HOST_IPI(r13)
1837         cmpwi   r0, 0
1838         bne-    43f
1839
1840         /* OK, it's an IPI for us */
1841         li      r3, -1
1842 1:      blr
1843
1844 42:     /* It's not an IPI and it's for the host, stash it in the PACA
1845          * before exit, it will be picked up by the host ICP driver
1846          */
1847         stw     r0, HSTATE_SAVED_XIRR(r13)
1848         b       1b
1849
1850 43:     /* We raced with the host, we need to resend that IPI, bummer */
1851         li      r0, IPI_PRIORITY
1852         stbcix  r0, r6, r8              /* set the IPI */
1853         sync
1854         b       1b
1855
1856 /*
1857  * Save away FP, VMX and VSX registers.
1858  * r3 = vcpu pointer
1859  */
1860 _GLOBAL(kvmppc_save_fp)
1861         mfmsr   r5
1862         ori     r8,r5,MSR_FP
1863 #ifdef CONFIG_ALTIVEC
1864 BEGIN_FTR_SECTION
1865         oris    r8,r8,MSR_VEC@h
1866 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1867 #endif
1868 #ifdef CONFIG_VSX
1869 BEGIN_FTR_SECTION
1870         oris    r8,r8,MSR_VSX@h
1871 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1872 #endif
1873         mtmsrd  r8
1874         isync
1875 #ifdef CONFIG_VSX
1876 BEGIN_FTR_SECTION
1877         reg = 0
1878         .rept   32
1879         li      r6,reg*16+VCPU_VSRS
1880         STXVD2X(reg,R6,R3)
1881         reg = reg + 1
1882         .endr
1883 FTR_SECTION_ELSE
1884 #endif
1885         reg = 0
1886         .rept   32
1887         stfd    reg,reg*8+VCPU_FPRS(r3)
1888         reg = reg + 1
1889         .endr
1890 #ifdef CONFIG_VSX
1891 ALT_FTR_SECTION_END_IFSET(CPU_FTR_VSX)
1892 #endif
1893         mffs    fr0
1894         stfd    fr0,VCPU_FPSCR(r3)
1895
1896 #ifdef CONFIG_ALTIVEC
1897 BEGIN_FTR_SECTION
1898         reg = 0
1899         .rept   32
1900         li      r6,reg*16+VCPU_VRS
1901         stvx    reg,r6,r3
1902         reg = reg + 1
1903         .endr
1904         mfvscr  vr0
1905         li      r6,VCPU_VSCR
1906         stvx    vr0,r6,r3
1907 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1908 #endif
1909         mfspr   r6,SPRN_VRSAVE
1910         stw     r6,VCPU_VRSAVE(r3)
1911         mtmsrd  r5
1912         isync
1913         blr
1914
1915 /*
1916  * Load up FP, VMX and VSX registers
1917  * r4 = vcpu pointer
1918  */
1919         .globl  kvmppc_load_fp
1920 kvmppc_load_fp:
1921         mfmsr   r9
1922         ori     r8,r9,MSR_FP
1923 #ifdef CONFIG_ALTIVEC
1924 BEGIN_FTR_SECTION
1925         oris    r8,r8,MSR_VEC@h
1926 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1927 #endif
1928 #ifdef CONFIG_VSX
1929 BEGIN_FTR_SECTION
1930         oris    r8,r8,MSR_VSX@h
1931 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1932 #endif
1933         mtmsrd  r8
1934         isync
1935         lfd     fr0,VCPU_FPSCR(r4)
1936         MTFSF_L(fr0)
1937 #ifdef CONFIG_VSX
1938 BEGIN_FTR_SECTION
1939         reg = 0
1940         .rept   32
1941         li      r7,reg*16+VCPU_VSRS
1942         LXVD2X(reg,R7,R4)
1943         reg = reg + 1
1944         .endr
1945 FTR_SECTION_ELSE
1946 #endif
1947         reg = 0
1948         .rept   32
1949         lfd     reg,reg*8+VCPU_FPRS(r4)
1950         reg = reg + 1
1951         .endr
1952 #ifdef CONFIG_VSX
1953 ALT_FTR_SECTION_END_IFSET(CPU_FTR_VSX)
1954 #endif
1955
1956 #ifdef CONFIG_ALTIVEC
1957 BEGIN_FTR_SECTION
1958         li      r7,VCPU_VSCR
1959         lvx     vr0,r7,r4
1960         mtvscr  vr0
1961         reg = 0
1962         .rept   32
1963         li      r7,reg*16+VCPU_VRS
1964         lvx     reg,r7,r4
1965         reg = reg + 1
1966         .endr
1967 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1968 #endif
1969         lwz     r7,VCPU_VRSAVE(r4)
1970         mtspr   SPRN_VRSAVE,r7
1971         blr
1972
1973 /*
1974  * We come here if we get any exception or interrupt while we are
1975  * executing host real mode code while in guest MMU context.
1976  * For now just spin, but we should do something better.
1977  */
1978 kvmppc_bad_host_intr:
1979         b       .