arch/powerpc/kernel/idle_book3s.S

   1 /*
   2  *  This file contains idle entry/exit functions for POWER7,
   3  *  POWER8 and POWER9 CPUs.
   4  *
   5  *  This program is free software; you can redistribute it and/or
   6  *  modify it under the terms of the GNU General Public License
   7  *  as published by the Free Software Foundation; either version
   8  *  2 of the License, or (at your option) any later version.
   9  */
  10
  11 #include <linux/threads.h>
  12 #include <asm/processor.h>
  13 #include <asm/page.h>
  14 #include <asm/cputable.h>
  15 #include <asm/thread_info.h>
  16 #include <asm/ppc_asm.h>
  17 #include <asm/asm-offsets.h>
  18 #include <asm/ppc-opcode.h>
  19 #include <asm/hw_irq.h>
  20 #include <asm/kvm_book3s_asm.h>
  21 #include <asm/opal.h>
  22 #include <asm/cpuidle.h>
  23 #include <asm/exception-64s.h>
  24 #include <asm/book3s/64/mmu-hash.h>
  25 #include <asm/mmu.h>
  26
  27 #undef DEBUG
  28
  29 /*
  30  * Use unused space in the interrupt stack to save and restore
  31  * registers for winkle support.
  32  */
  33 #define _SDR1   GPR3
  34 #define _PTCR   GPR3
  35 #define _RPR    GPR4
  36 #define _SPURR  GPR5
  37 #define _PURR   GPR6
  38 #define _TSCR   GPR7
  39 #define _DSCR   GPR8
  40 #define _AMOR   GPR9
  41 #define _WORT   GPR10
  42 #define _WORC   GPR11
  43 #define _LPCR   GPR12
  44
  45 #define PSSCR_EC_ESL_MASK_SHIFTED          (PSSCR_EC | PSSCR_ESL) >> 16
  46
  47         .text
  48
  49 /*
  50  * Used by threads before entering deep idle states. Saves SPRs
  51  * in interrupt stack frame
  52  */
  53 save_sprs_to_stack:
  54         /*
  55          * Note all register i.e per-core, per-subcore or per-thread is saved
  56          * here since any thread in the core might wake up first
  57          */
  58 BEGIN_FTR_SECTION
  59         /*
  60          * Note - SDR1 is dropped in Power ISA v3. Hence not restoring
  61          * SDR1 here
  62          */
  63         mfspr   r3,SPRN_PTCR
  64         std     r3,_PTCR(r1)
  65         mfspr   r3,SPRN_LPCR
  66         std     r3,_LPCR(r1)
  67 FTR_SECTION_ELSE
  68         mfspr   r3,SPRN_SDR1
  69         std     r3,_SDR1(r1)
  70 ALT_FTR_SECTION_END_IFSET(CPU_FTR_ARCH_300)
  71         mfspr   r3,SPRN_RPR
  72         std     r3,_RPR(r1)
  73         mfspr   r3,SPRN_SPURR
  74         std     r3,_SPURR(r1)
  75         mfspr   r3,SPRN_PURR
  76         std     r3,_PURR(r1)
  77         mfspr   r3,SPRN_TSCR
  78         std     r3,_TSCR(r1)
  79         mfspr   r3,SPRN_DSCR
  80         std     r3,_DSCR(r1)
  81         mfspr   r3,SPRN_AMOR
  82         std     r3,_AMOR(r1)
  83         mfspr   r3,SPRN_WORT
  84         std     r3,_WORT(r1)
  85         mfspr   r3,SPRN_WORC
  86         std     r3,_WORC(r1)
  87
  88         blr
  89
  90 /*
  91  * Used by threads when the lock bit of core_idle_state is set.
  92  * Threads will spin in HMT_LOW until the lock bit is cleared.
  93  * r14 - pointer to core_idle_state
  94  * r15 - used to load contents of core_idle_state
  95  * r9  - used as a temporary variable
  96  */
  97
  98 core_idle_lock_held:
  99         HMT_LOW
 100 3:      lwz     r15,0(r14)
 101         andis.  r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 102         bne     3b
 103         HMT_MEDIUM
 104         lwarx   r15,0,r14
 105         andis.  r9,r15,PNV_CORE_IDLE_LOCK_BIT@h
 106         bne-    core_idle_lock_held
 107         blr
 108
 109 /*
 110  * Pass requested state in r3:
 111  *      r3 - PNV_THREAD_NAP/SLEEP/WINKLE in POWER8
 112  *         - Requested PSSCR value in POWER9
 113  *
 114  * Address of idle handler to branch to in realmode in r4
 115  */
 116 pnv_powersave_common:
 117         /* Use r3 to pass state nap/sleep/winkle */
 118         /* NAP is a state loss, we create a regs frame on the
 119          * stack, fill it up with the state we care about and
 120          * stick a pointer to it in PACAR1. We really only
 121          * need to save PC, some CR bits and the NV GPRs,
 122          * but for now an interrupt frame will do.
 123          */
 124         mtctr   r4
 125
 126         mflr    r0
 127         std     r0,16(r1)
 128         stdu    r1,-INT_FRAME_SIZE(r1)
 129         std     r0,_LINK(r1)
 130         std     r0,_NIP(r1)
 131
 132         /* We haven't lost state ... yet */
 133         li      r0,0
 134         stb     r0,PACA_NAPSTATELOST(r13)
 135
 136         /* Continue saving state */
 137         SAVE_GPR(2, r1)
 138         SAVE_NVGPRS(r1)
 139         mfcr    r5
 140         std     r5,_CCR(r1)
 141         std     r1,PACAR1(r13)
 142
 143         /*
 144          * Go to real mode to do the nap, as required by the architecture.
 145          * Also, we need to be in real mode before setting hwthread_state,
 146          * because as soon as we do that, another thread can switch
 147          * the MMU context to the guest.
 148          */
 149         LOAD_REG_IMMEDIATE(r7, MSR_IDLE)
 150         mtmsrd  r7,0
 151         bctr
 152
 153         .globl pnv_enter_arch207_idle_mode
 154 pnv_enter_arch207_idle_mode:
 155 #ifdef CONFIG_KVM_BOOK3S_HV_POSSIBLE
 156         /* Tell KVM we're entering idle */
 157         li      r4,KVM_HWTHREAD_IN_IDLE
 158         /******************************************************/
 159         /*  N O T E   W E L L    ! ! !    N O T E   W E L L   */
 160         /* The following store to HSTATE_HWTHREAD_STATE(r13)  */
 161         /* MUST occur in real mode, i.e. with the MMU off,    */
 162         /* and the MMU must stay off until we clear this flag */
 163         /* and test HSTATE_HWTHREAD_REQ(r13) in               */
 164         /* pnv_powersave_wakeup in this file.                 */
 165         /* The reason is that another thread can switch the   */
 166         /* MMU to a guest context whenever this flag is set   */
 167         /* to KVM_HWTHREAD_IN_IDLE, and if the MMU was on,    */
 168         /* that would potentially cause this thread to start  */
 169         /* executing instructions from guest memory in        */
 170         /* hypervisor mode, leading to a host crash or data   */
 171         /* corruption, or worse.                              */
 172         /******************************************************/
 173         stb     r4,HSTATE_HWTHREAD_STATE(r13)
 174 #endif
 175         stb     r3,PACA_THREAD_IDLE_STATE(r13)
 176         cmpwi   cr3,r3,PNV_THREAD_SLEEP
 177         bge     cr3,2f
 178         IDLE_STATE_ENTER_SEQ_NORET(PPC_NAP)
 179         /* No return */
 180 2:
 181         /* Sleep or winkle */
 182         lbz     r7,PACA_THREAD_MASK(r13)
 183         ld      r14,PACA_CORE_IDLE_STATE_PTR(r13)
 184         li      r5,0
 185         beq     cr3,3f
 186         lis     r5,PNV_CORE_IDLE_WINKLE_COUNT@h
 187 3:
 188 lwarx_loop1:
 189         lwarx   r15,0,r14
 190
 191         andis.  r9,r15,PNV_CORE_IDLE_LOCK_BIT@h
 192         bnel-   core_idle_lock_held
 193
 194         add     r15,r15,r5                      /* Add if winkle */
 195         andc    r15,r15,r7                      /* Clear thread bit */
 196
 197         andi.   r9,r15,PNV_CORE_IDLE_THREAD_BITS
 198
 199 /*
 200  * If cr0 = 0, then current thread is the last thread of the core entering
 201  * sleep. Last thread needs to execute the hardware bug workaround code if
 202  * required by the platform.
 203  * Make the workaround call unconditionally here. The below branch call is
 204  * patched out when the idle states are discovered if the platform does not
 205  * require it.
 206  */
 207 .global pnv_fastsleep_workaround_at_entry
 208 pnv_fastsleep_workaround_at_entry:
 209         beq     fastsleep_workaround_at_entry
 210
 211         stwcx.  r15,0,r14
 212         bne-    lwarx_loop1
 213         isync
 214
 215 common_enter: /* common code for all the threads entering sleep or winkle */
 216         bgt     cr3,enter_winkle
 217         IDLE_STATE_ENTER_SEQ_NORET(PPC_SLEEP)
 218
 219 fastsleep_workaround_at_entry:
 220         oris    r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 221         stwcx.  r15,0,r14
 222         bne-    lwarx_loop1
 223         isync
 224
 225         /* Fast sleep workaround */
 226         li      r3,1
 227         li      r4,1
 228         bl      opal_config_cpu_idle_state
 229
 230         /* Unlock */
 231         xoris   r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 232         lwsync
 233         stw     r15,0(r14)
 234         b       common_enter
 235
 236 enter_winkle:
 237         bl      save_sprs_to_stack
 238
 239         IDLE_STATE_ENTER_SEQ_NORET(PPC_WINKLE)
 240
 241 /*
 242  * r3 - PSSCR value corresponding to the requested stop state.
 243  */
 244 power_enter_stop:
 245 #ifdef CONFIG_KVM_BOOK3S_HV_POSSIBLE
 246         /* Tell KVM we're entering idle */
 247         li      r4,KVM_HWTHREAD_IN_IDLE
 248         /* DO THIS IN REAL MODE!  See comment above. */
 249         stb     r4,HSTATE_HWTHREAD_STATE(r13)
 250 #endif
 251 /*
 252  * Check if we are executing the lite variant with ESL=EC=0
 253  */
 254         andis.   r4,r3,PSSCR_EC_ESL_MASK_SHIFTED
 255         clrldi   r3,r3,60 /* r3 = Bits[60:63] = Requested Level (RL) */
 256         bne      .Lhandle_esl_ec_set
 257         IDLE_STATE_ENTER_SEQ(PPC_STOP)
 258         li      r3,0  /* Since we didn't lose state, return 0 */
 259         b       pnv_wakeup_noloss
 260
 261 .Lhandle_esl_ec_set:
 262 /*
 263  * Check if the requested state is a deep idle state.
 264  */
 265         LOAD_REG_ADDRBASE(r5,pnv_first_deep_stop_state)
 266         ld      r4,ADDROFF(pnv_first_deep_stop_state)(r5)
 267         cmpd    r3,r4
 268         bge     .Lhandle_deep_stop
 269         IDLE_STATE_ENTER_SEQ_NORET(PPC_STOP)
 270 .Lhandle_deep_stop:
 271 /*
 272  * Entering deep idle state.
 273  * Clear thread bit in PACA_CORE_IDLE_STATE, save SPRs to
 274  * stack and enter stop
 275  */
 276         lbz     r7,PACA_THREAD_MASK(r13)
 277         ld      r14,PACA_CORE_IDLE_STATE_PTR(r13)
 278
 279 lwarx_loop_stop:
 280         lwarx   r15,0,r14
 281         andis.  r9,r15,PNV_CORE_IDLE_LOCK_BIT@h
 282         bnel-   core_idle_lock_held
 283         andc    r15,r15,r7                      /* Clear thread bit */
 284
 285         stwcx.  r15,0,r14
 286         bne-    lwarx_loop_stop
 287         isync
 288
 289         bl      save_sprs_to_stack
 290
 291         IDLE_STATE_ENTER_SEQ_NORET(PPC_STOP)
 292
 293 /*
 294  * Entered with MSR[EE]=0 and no soft-masked interrupts pending.
 295  * r3 contains desired idle state (PNV_THREAD_NAP/SLEEP/WINKLE).
 296  */
 297 _GLOBAL(power7_idle_insn)
 298         /* Now check if user or arch enabled NAP mode */
 299         LOAD_REG_ADDR(r4, pnv_enter_arch207_idle_mode)
 300         b       pnv_powersave_common
 301
 302 #define CHECK_HMI_INTERRUPT                                             \
 303 BEGIN_FTR_SECTION_NESTED(66);                                           \
 304         rlwinm  r0,r12,45-31,0xf;  /* extract wake reason field (P8) */ \
 305 FTR_SECTION_ELSE_NESTED(66);                                            \
 306         rlwinm  r0,r12,45-31,0xe;  /* P7 wake reason field is 3 bits */ \
 307 ALT_FTR_SECTION_END_NESTED_IFSET(CPU_FTR_ARCH_207S, 66);                \
 308         cmpwi   r0,0xa;                 /* Hypervisor maintenance ? */  \
 309         bne     20f;                                                    \
 310         /* Invoke opal call to handle hmi */                            \
 311         ld      r2,PACATOC(r13);                                        \
 312         ld      r1,PACAR1(r13);                                         \
 313         std     r3,ORIG_GPR3(r1);       /* Save original r3 */          \
 314         li      r3,0;                   /* NULL argument */             \
 315         bl      hmi_exception_realmode;                                 \
 316         nop;                                                            \
 317         ld      r3,ORIG_GPR3(r1);       /* Restore original r3 */       \
 318 20:     nop;
 319
 320 /*
 321  * Entered with MSR[EE]=0 and no soft-masked interrupts pending.
 322  * r3 contains desired PSSCR register value.
 323  */
 324 _GLOBAL(power9_idle_stop)
 325         std     r3, PACA_REQ_PSSCR(r13)
 326         mtspr   SPRN_PSSCR,r3
 327         LOAD_REG_ADDR(r4,power_enter_stop)
 328         b       pnv_powersave_common
 329         /* No return */
 330
 331 /*
 332  * On waking up from stop 0,1,2 with ESL=1 on POWER9 DD1,
 333  * HSPRG0 will be set to the HSPRG0 value of one of the
 334  * threads in this core. Thus the value we have in r13
 335  * may not be this thread's paca pointer.
 336  *
 337  * Fortunately, the TIR remains invariant. Since this thread's
 338  * paca pointer is recorded in all its sibling's paca, we can
 339  * correctly recover this thread's paca pointer if we
 340  * know the index of this thread in the core.
 341  *
 342  * This index can be obtained from the TIR.
 343  *
 344  * i.e, thread's position in the core = TIR.
 345  * If this value is i, then this thread's paca is
 346  * paca->thread_sibling_pacas[i].
 347  */
 348 power9_dd1_recover_paca:
 349         mfspr   r4, SPRN_TIR
 350         /*
 351          * Since each entry in thread_sibling_pacas is 8 bytes
 352          * we need to left-shift by 3 bits. Thus r4 = i * 8
 353          */
 354         sldi    r4, r4, 3
 355         /* Get &paca->thread_sibling_pacas[0] in r5 */
 356         ld      r5, PACA_SIBLING_PACA_PTRS(r13)
 357         /* Load paca->thread_sibling_pacas[i] into r13 */
 358         ldx     r13, r4, r5
 359         SET_PACA(r13)
 360         /*
 361          * Indicate that we have lost NVGPR state
 362          * which needs to be restored from the stack.
 363          */
 364         li      r3, 1
 365         stb     r3,PACA_NAPSTATELOST(r13)
 366         blr
 367
 368 /*
 369  * Called from machine check handler for powersave wakeups.
 370  * Low level machine check processing has already been done. Now just
 371  * go through the wake up path to get everything in order.
 372  *
 373  * r3 - The original SRR1 value.
 374  * Original SRR[01] have been clobbered.
 375  * MSR_RI is clear.
 376  */
 377 .global pnv_powersave_wakeup_mce
 378 pnv_powersave_wakeup_mce:
 379         /* Set cr3 for pnv_powersave_wakeup */
 380         rlwinm  r11,r3,47-31,30,31
 381         cmpwi   cr3,r11,2
 382
 383         /*
 384          * Now put the original SRR1 with SRR1_WAKEMCE_RESVD as the wake
 385          * reason into r12, which allows reuse of the system reset wakeup
 386          * code without being mistaken for another type of wakeup.
 387          */
 388         oris    r12,r3,SRR1_WAKEMCE_RESVD@h
 389
 390         b       pnv_powersave_wakeup
 391
 392 /*
 393  * Called from reset vector for powersave wakeups.
 394  * cr3 - set to gt if waking up with partial/complete hypervisor state loss
 395  * r12 - SRR1
 396  */
 397 .global pnv_powersave_wakeup
 398 pnv_powersave_wakeup:
 399         ld      r2, PACATOC(r13)
 400
 401 BEGIN_FTR_SECTION
 402 BEGIN_FTR_SECTION_NESTED(70)
 403         bl      power9_dd1_recover_paca
 404 END_FTR_SECTION_NESTED_IFSET(CPU_FTR_POWER9_DD1, 70)
 405         bl      pnv_restore_hyp_resource_arch300
 406 FTR_SECTION_ELSE
 407         bl      pnv_restore_hyp_resource_arch207
 408 ALT_FTR_SECTION_END_IFSET(CPU_FTR_ARCH_300)
 409
 410         li      r0,PNV_THREAD_RUNNING
 411         stb     r0,PACA_THREAD_IDLE_STATE(r13)  /* Clear thread state */
 412
 413         mr      r3,r12
 414
 415 #ifdef CONFIG_KVM_BOOK3S_HV_POSSIBLE
 416         li      r0,KVM_HWTHREAD_IN_KERNEL
 417         stb     r0,HSTATE_HWTHREAD_STATE(r13)
 418         /* Order setting hwthread_state vs. testing hwthread_req */
 419         sync
 420         lbz     r0,HSTATE_HWTHREAD_REQ(r13)
 421         cmpwi   r0,0
 422         beq     1f
 423         b       kvm_start_guest
 424 1:
 425 #endif
 426
 427         /* Return SRR1 from power7_nap() */
 428         blt     cr3,pnv_wakeup_noloss
 429         b       pnv_wakeup_loss
 430
 431 /*
 432  * Check whether we have woken up with hypervisor state loss.
 433  * If yes, restore hypervisor state and return back to link.
 434  *
 435  * cr3 - set to gt if waking up with partial/complete hypervisor state loss
 436  */
 437 pnv_restore_hyp_resource_arch300:
 438         /*
 439          * POWER ISA 3. Use PSSCR to determine if we
 440          * are waking up from deep idle state
 441          */
 442         LOAD_REG_ADDRBASE(r5,pnv_first_deep_stop_state)
 443         ld      r4,ADDROFF(pnv_first_deep_stop_state)(r5)
 444
 445 BEGIN_FTR_SECTION_NESTED(71)
 446         /*
 447          * Assume that we are waking up from the state
 448          * same as the Requested Level (RL) in the PSSCR
 449          * which are Bits 60-63
 450          */
 451         ld      r5,PACA_REQ_PSSCR(r13)
 452         rldicl  r5,r5,0,60
 453 FTR_SECTION_ELSE_NESTED(71)
 454         /*
 455          * 0-3 bits correspond to Power-Saving Level Status
 456          * which indicates the idle state we are waking up from
 457          */
 458         mfspr   r5, SPRN_PSSCR
 459         rldicl  r5,r5,4,60
 460 ALT_FTR_SECTION_END_NESTED_IFSET(CPU_FTR_POWER9_DD1, 71)
 461         cmpd    cr4,r5,r4
 462         bge     cr4,pnv_wakeup_tb_loss /* returns to caller */
 463
 464         blr     /* Waking up without hypervisor state loss. */
 465
 466 /* Same calling convention as arch300 */
 467 pnv_restore_hyp_resource_arch207:
 468         /*
 469          * POWER ISA 2.07 or less.
 470          * Check if we slept with sleep or winkle.
 471          */
 472         lbz     r4,PACA_THREAD_IDLE_STATE(r13)
 473         cmpwi   cr2,r4,PNV_THREAD_NAP
 474         bgt     cr2,pnv_wakeup_tb_loss  /* Either sleep or Winkle */
 475
 476         /*
 477          * We fall through here if PACA_THREAD_IDLE_STATE shows we are waking
 478          * up from nap. At this stage CR3 shouldn't contains 'gt' since that
 479          * indicates we are waking with hypervisor state loss from nap.
 480          */
 481         bgt     cr3,.
 482
 483         blr     /* Waking up without hypervisor state loss */
 484
 485 /*
 486  * Called if waking up from idle state which can cause either partial or
 487  * complete hyp state loss.
 488  * In POWER8, called if waking up from fastsleep or winkle
 489  * In POWER9, called if waking up from stop state >= pnv_first_deep_stop_state
 490  *
 491  * r13 - PACA
 492  * cr3 - gt if waking up with partial/complete hypervisor state loss
 493  *
 494  * If ISA300:
 495  * cr4 - gt or eq if waking up from complete hypervisor state loss.
 496  *
 497  * If ISA207:
 498  * r4 - PACA_THREAD_IDLE_STATE
 499  */
 500 pnv_wakeup_tb_loss:
 501         ld      r1,PACAR1(r13)
 502         /*
 503          * Before entering any idle state, the NVGPRs are saved in the stack.
 504          * If there was a state loss, or PACA_NAPSTATELOST was set, then the
 505          * NVGPRs are restored. If we are here, it is likely that state is lost,
 506          * but not guaranteed -- neither ISA207 nor ISA300 tests to reach
 507          * here are the same as the test to restore NVGPRS:
 508          * PACA_THREAD_IDLE_STATE test for ISA207, PSSCR test for ISA300,
 509          * and SRR1 test for restoring NVGPRs.
 510          *
 511          * We are about to clobber NVGPRs now, so set NAPSTATELOST to
 512          * guarantee they will always be restored. This might be tightened
 513          * with careful reading of specs (particularly for ISA300) but this
 514          * is already a slow wakeup path and it's simpler to be safe.
 515          */
 516         li      r0,1
 517         stb     r0,PACA_NAPSTATELOST(r13)
 518
 519         /*
 520          *
 521          * Save SRR1 and LR in NVGPRs as they might be clobbered in
 522          * opal_call() (called in CHECK_HMI_INTERRUPT). SRR1 is required
 523          * to determine the wakeup reason if we branch to kvm_start_guest. LR
 524          * is required to return back to reset vector after hypervisor state
 525          * restore is complete.
 526          */
 527         mr      r19,r12
 528         mr      r18,r4
 529         mflr    r17
 530 BEGIN_FTR_SECTION
 531         CHECK_HMI_INTERRUPT
 532 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
 533
 534         ld      r14,PACA_CORE_IDLE_STATE_PTR(r13)
 535         lbz     r7,PACA_THREAD_MASK(r13)
 536
 537         /*
 538          * Take the core lock to synchronize against other threads.
 539          *
 540          * Lock bit is set in one of the 2 cases-
 541          * a. In the sleep/winkle enter path, the last thread is executing
 542          * fastsleep workaround code.
 543          * b. In the wake up path, another thread is executing fastsleep
 544          * workaround undo code or resyncing timebase or restoring context
 545          * In either case loop until the lock bit is cleared.
 546          */
 547 1:
 548         lwarx   r15,0,r14
 549         andis.  r9,r15,PNV_CORE_IDLE_LOCK_BIT@h
 550         bnel-   core_idle_lock_held
 551         oris    r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 552         stwcx.  r15,0,r14
 553         bne-    1b
 554         isync
 555
 556         andi.   r9,r15,PNV_CORE_IDLE_THREAD_BITS
 557         cmpwi   cr2,r9,0
 558
 559         /*
 560          * At this stage
 561          * cr2 - eq if first thread to wakeup in core
 562          * cr3-  gt if waking up with partial/complete hypervisor state loss
 563          * ISA300:
 564          * cr4 - gt or eq if waking up from complete hypervisor state loss.
 565          */
 566
 567 BEGIN_FTR_SECTION
 568         /*
 569          * Were we in winkle?
 570          * If yes, check if all threads were in winkle, decrement our
 571          * winkle count, set all thread winkle bits if all were in winkle.
 572          * Check if our thread has a winkle bit set, and set cr4 accordingly
 573          * (to match ISA300, above). Pseudo-code for core idle state
 574          * transitions for ISA207 is as follows (everything happens atomically
 575          * due to store conditional and/or lock bit):
 576          *
 577          * nap_idle() { }
 578          * nap_wake() { }
 579          *
 580          * sleep_idle()
 581          * {
 582          *      core_idle_state &= ~thread_in_core
 583          * }
 584          *
 585          * sleep_wake()
 586          * {
 587          *     bool first_in_core, first_in_subcore;
 588          *
 589          *     first_in_core = (core_idle_state & IDLE_THREAD_BITS) == 0;
 590          *     first_in_subcore = (core_idle_state & SUBCORE_SIBLING_MASK) == 0;
 591          *
 592          *     core_idle_state |= thread_in_core;
 593          * }
 594          *
 595          * winkle_idle()
 596          * {
 597          *      core_idle_state &= ~thread_in_core;
 598          *      core_idle_state += 1 << WINKLE_COUNT_SHIFT;
 599          * }
 600          *
 601          * winkle_wake()
 602          * {
 603          *     bool first_in_core, first_in_subcore, winkle_state_lost;
 604          *
 605          *     first_in_core = (core_idle_state & IDLE_THREAD_BITS) == 0;
 606          *     first_in_subcore = (core_idle_state & SUBCORE_SIBLING_MASK) == 0;
 607          *
 608          *     core_idle_state |= thread_in_core;
 609          *
 610          *     if ((core_idle_state & WINKLE_MASK) == (8 << WINKLE_COUNT_SIHFT))
 611          *         core_idle_state |= THREAD_WINKLE_BITS;
 612          *     core_idle_state -= 1 << WINKLE_COUNT_SHIFT;
 613          *
 614          *     winkle_state_lost = core_idle_state &
 615          *                              (thread_in_core << WINKLE_THREAD_SHIFT);
 616          *     core_idle_state &= ~(thread_in_core << WINKLE_THREAD_SHIFT);
 617          * }
 618          *
 619          */
 620         cmpwi   r18,PNV_THREAD_WINKLE
 621         bne     2f
 622         andis.  r9,r15,PNV_CORE_IDLE_WINKLE_COUNT_ALL_BIT@h
 623         subis   r15,r15,PNV_CORE_IDLE_WINKLE_COUNT@h
 624         beq     2f
 625         ori     r15,r15,PNV_CORE_IDLE_THREAD_WINKLE_BITS /* all were winkle */
 626 2:
 627         /* Shift thread bit to winkle mask, then test if this thread is set,
 628          * and remove it from the winkle bits */
 629         slwi    r8,r7,8
 630         and     r8,r8,r15
 631         andc    r15,r15,r8
 632         cmpwi   cr4,r8,1 /* cr4 will be gt if our bit is set, lt if not */
 633
 634         lbz     r4,PACA_SUBCORE_SIBLING_MASK(r13)
 635         and     r4,r4,r15
 636         cmpwi   r4,0    /* Check if first in subcore */
 637
 638         or      r15,r15,r7              /* Set thread bit */
 639         beq     first_thread_in_subcore
 640 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
 641
 642         or      r15,r15,r7              /* Set thread bit */
 643         beq     cr2,first_thread_in_core
 644
 645         /* Not first thread in core or subcore to wake up */
 646         b       clear_lock
 647
 648 first_thread_in_subcore:
 649         /*
 650          * If waking up from sleep, subcore state is not lost. Hence
 651          * skip subcore state restore
 652          */
 653         blt     cr4,subcore_state_restored
 654
 655         /* Restore per-subcore state */
 656         ld      r4,_SDR1(r1)
 657         mtspr   SPRN_SDR1,r4
 658
 659         ld      r4,_RPR(r1)
 660         mtspr   SPRN_RPR,r4
 661         ld      r4,_AMOR(r1)
 662         mtspr   SPRN_AMOR,r4
 663
 664 subcore_state_restored:
 665         /*
 666          * Check if the thread is also the first thread in the core. If not,
 667          * skip to clear_lock.
 668          */
 669         bne     cr2,clear_lock
 670
 671 first_thread_in_core:
 672
 673         /*
 674          * First thread in the core waking up from any state which can cause
 675          * partial or complete hypervisor state loss. It needs to
 676          * call the fastsleep workaround code if the platform requires it.
 677          * Call it unconditionally here. The below branch instruction will
 678          * be patched out if the platform does not have fastsleep or does not
 679          * require the workaround. Patching will be performed during the
 680          * discovery of idle-states.
 681          */
 682 .global pnv_fastsleep_workaround_at_exit
 683 pnv_fastsleep_workaround_at_exit:
 684         b       fastsleep_workaround_at_exit
 685
 686 timebase_resync:
 687         /*
 688          * Use cr3 which indicates that we are waking up with atleast partial
 689          * hypervisor state loss to determine if TIMEBASE RESYNC is needed.
 690          */
 691         ble     cr3,.Ltb_resynced
 692         /* Time base re-sync */
 693         bl      opal_resync_timebase;
 694         /*
 695          * If waking up from sleep (POWER8), per core state
 696          * is not lost, skip to clear_lock.
 697          */
 698 .Ltb_resynced:
 699         blt     cr4,clear_lock
 700
 701         /*
 702          * First thread in the core to wake up and its waking up with
 703          * complete hypervisor state loss. Restore per core hypervisor
 704          * state.
 705          */
 706 BEGIN_FTR_SECTION
 707         ld      r4,_PTCR(r1)
 708         mtspr   SPRN_PTCR,r4
 709         ld      r4,_RPR(r1)
 710         mtspr   SPRN_RPR,r4
 711 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
 712
 713         ld      r4,_TSCR(r1)
 714         mtspr   SPRN_TSCR,r4
 715         ld      r4,_WORC(r1)
 716         mtspr   SPRN_WORC,r4
 717
 718 clear_lock:
 719         xoris   r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 720         lwsync
 721         stw     r15,0(r14)
 722
 723 common_exit:
 724         /*
 725          * Common to all threads.
 726          *
 727          * If waking up from sleep, hypervisor state is not lost. Hence
 728          * skip hypervisor state restore.
 729          */
 730         blt     cr4,hypervisor_state_restored
 731
 732         /* Waking up from winkle */
 733
 734 BEGIN_MMU_FTR_SECTION
 735         b       no_segments
 736 END_MMU_FTR_SECTION_IFSET(MMU_FTR_TYPE_RADIX)
 737         /* Restore SLB  from PACA */
 738         ld      r8,PACA_SLBSHADOWPTR(r13)
 739
 740         .rept   SLB_NUM_BOLTED
 741         li      r3, SLBSHADOW_SAVEAREA
 742         LDX_BE  r5, r8, r3
 743         addi    r3, r3, 8
 744         LDX_BE  r6, r8, r3
 745         andis.  r7,r5,SLB_ESID_V@h
 746         beq     1f
 747         slbmte  r6,r5
 748 1:      addi    r8,r8,16
 749         .endr
 750 no_segments:
 751
 752         /* Restore per thread state */
 753
 754         ld      r4,_SPURR(r1)
 755         mtspr   SPRN_SPURR,r4
 756         ld      r4,_PURR(r1)
 757         mtspr   SPRN_PURR,r4
 758         ld      r4,_DSCR(r1)
 759         mtspr   SPRN_DSCR,r4
 760         ld      r4,_WORT(r1)
 761         mtspr   SPRN_WORT,r4
 762
 763         /* Call cur_cpu_spec->cpu_restore() */
 764         LOAD_REG_ADDR(r4, cur_cpu_spec)
 765         ld      r4,0(r4)
 766         ld      r12,CPU_SPEC_RESTORE(r4)
 767 #ifdef PPC64_ELF_ABI_v1
 768         ld      r12,0(r12)
 769 #endif
 770         mtctr   r12
 771         bctrl
 772
 773 BEGIN_FTR_SECTION
 774         ld      r4,_LPCR(r1)
 775         mtspr   SPRN_LPCR,r4
 776 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
 777 hypervisor_state_restored:
 778
 779         mr      r12,r19
 780         mtlr    r17
 781         blr             /* return to pnv_powersave_wakeup */
 782
 783 fastsleep_workaround_at_exit:
 784         li      r3,1
 785         li      r4,0
 786         bl      opal_config_cpu_idle_state
 787         b       timebase_resync
 788
 789 /*
 790  * R3 here contains the value that will be returned to the caller
 791  * of power7_nap.
 792  * R12 contains SRR1 for CHECK_HMI_INTERRUPT.
 793  */
 794 .global pnv_wakeup_loss
 795 pnv_wakeup_loss:
 796         ld      r1,PACAR1(r13)
 797 BEGIN_FTR_SECTION
 798         CHECK_HMI_INTERRUPT
 799 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
 800         REST_NVGPRS(r1)
 801         REST_GPR(2, r1)
 802         ld      r4,PACAKMSR(r13)
 803         ld      r5,_LINK(r1)
 804         ld      r6,_CCR(r1)
 805         addi    r1,r1,INT_FRAME_SIZE
 806         mtlr    r5
 807         mtcr    r6
 808         mtmsrd  r4
 809         blr
 810
 811 /*
 812  * R3 here contains the value that will be returned to the caller
 813  * of power7_nap.
 814  * R12 contains SRR1 for CHECK_HMI_INTERRUPT.
 815  */
 816 pnv_wakeup_noloss:
 817         lbz     r0,PACA_NAPSTATELOST(r13)
 818         cmpwi   r0,0
 819         bne     pnv_wakeup_loss
 820         ld      r1,PACAR1(r13)
 821 BEGIN_FTR_SECTION
 822         CHECK_HMI_INTERRUPT
 823 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
 824         ld      r4,PACAKMSR(r13)
 825         ld      r5,_NIP(r1)
 826         ld      r6,_CCR(r1)
 827         addi    r1,r1,INT_FRAME_SIZE
 828         mtlr    r5
 829         mtcr    r6
 830         mtmsrd  r4
 831         blr