arch/microblaze/cpu/start.S

   1 /*
   2  * (C) Copyright 2007 Michal Simek
   3  * (C) Copyright 2004 Atmark Techno, Inc.
   4  *
   5  * Michal  SIMEK <monstr@monstr.eu>
   6  * Yasushi SHOJI <yashi@atmark-techno.com>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 #include <asm-offsets.h>
  28 #include <config.h>
  29
  30         .text
  31         .global _start
  32 _start:
  33         /*
  34          * reserve registers:
  35          * r10: Stores little/big endian offset for vectors
  36          * r2: Stores imm opcode
  37          * r3: Stores brai opcode
  38          */
  39
  40         mts     rmsr, r0        /* disable cache */
  41         addi    r1, r0, CONFIG_SYS_INIT_SP_OFFSET
  42         addi    r1, r1, -4      /* Decrement SP to top of memory */
  43
  44         /* Find-out if u-boot is running on BIG/LITTLE endian platform
  45          * There are some steps which is necessary to keep in mind:
  46          * 1. Setup offset value to r6
  47          * 2. Store word offset value to address 0x0
  48          * 3. Load just byte from address 0x0
  49          * 4a) LITTLE endian - r10 contains 0x2 because it is the smallest
  50          *     value that's why is on address 0x0
  51          * 4b) BIG endian - r10 contains 0x0 because 0x2 offset is on addr 0x3
  52          */
  53         addik   r6, r0, 0x2 /* BIG/LITTLE endian offset */
  54         lwi     r7, r0, 0x28
  55         swi     r6, r0, 0x28 /* used first unused MB vector */
  56         lbui    r10, r0, 0x28 /* used first unused MB vector */
  57         swi     r7, r0, 0x28
  58
  59         /* add opcode instruction for 32bit jump - 2 instruction imm & brai */
  60         addi    r2, r0, 0xb0000000      /* hex b000 opcode imm */
  61         addi    r3, r0, 0xb8080000      /* hew b808 opcode brai */
  62
  63 #ifdef CONFIG_SYS_RESET_ADDRESS
  64         /* reset address */
  65         swi     r2, r0, 0x0     /* reset address - imm opcode */
  66         swi     r3, r0, 0x4     /* reset address - brai opcode */
  67
  68         addik   r6, r0, CONFIG_SYS_RESET_ADDRESS
  69         sw      r6, r1, r0
  70         lhu     r7, r1, r10
  71         rsubi   r8, r10, 0x2
  72         sh      r7, r0, r8
  73         rsubi   r8, r10, 0x6
  74         sh      r6, r0, r8
  75 #endif
  76
  77 #ifdef CONFIG_SYS_USR_EXCEP
  78         /* user_vector_exception */
  79         swi     r2, r0, 0x8     /* user vector exception - imm opcode */
  80         swi     r3, r0, 0xC     /* user vector exception - brai opcode */
  81
  82         addik   r6, r0, _exception_handler
  83         sw      r6, r1, r0
  84         /*
  85          * BIG ENDIAN memory map for user exception
  86          * 0x8: 0xB000XXXX
  87          * 0xC: 0xB808XXXX
  88          *
  89          * then it is necessary to count address for storing the most significant
  90          * 16bits from _exception_handler address and copy it to
  91          * 0xa address. Big endian use offset in r10=0 that's why is it just
  92          * 0xa address. The same is done for the least significant 16 bits
  93          * for 0xe address.
  94          *
  95          * LITTLE ENDIAN memory map for user exception
  96          * 0x8: 0xXXXX00B0
  97          * 0xC: 0xXXXX08B8
  98          *
  99          * Offset is for little endian setup to 0x2. rsubi instruction decrease
 100          * address value to ensure that points to proper place which is
 101          * 0x8 for the most significant 16 bits and
 102          * 0xC for the least significant 16 bits
 103          */
 104         lhu     r7, r1, r10
 105         rsubi   r8, r10, 0xa
 106         sh      r7, r0, r8
 107         rsubi   r8, r10, 0xe
 108         sh      r6, r0, r8
 109 #endif
 110
 111         /* interrupt_handler */
 112         swi     r2, r0, 0x10    /* interrupt - imm opcode */
 113         swi     r3, r0, 0x14    /* interrupt - brai opcode */
 114
 115         addik   r6, r0, _interrupt_handler
 116         sw      r6, r1, r0
 117         lhu     r7, r1, r10
 118         rsubi   r8, r10, 0x12
 119         sh      r7, r0, r8
 120         rsubi   r8, r10, 0x16
 121         sh      r6, r0, r8
 122
 123         /* hardware exception */
 124         swi     r2, r0, 0x20    /* hardware exception - imm opcode */
 125         swi     r3, r0, 0x24    /* hardware exception - brai opcode */
 126
 127         addik   r6, r0, _hw_exception_handler
 128         sw      r6, r1, r0
 129         lhu     r7, r1, r10
 130         rsubi   r8, r10, 0x22
 131         sh      r7, r0, r8
 132         rsubi   r8, r10, 0x26
 133         sh      r6, r0, r8
 134
 135         /* Flush cache before enable cache */
 136         addik   r5, r0, 0
 137         addik   r6, r0, XILINX_DCACHE_BYTE_SIZE
 138 flush:  bralid r15, flush_cache
 139         nop
 140
 141         /* enable instruction and data cache */
 142         mfs     r12, rmsr
 143         ori     r12, r12, 0xa0
 144         mts     rmsr, r12
 145
 146 clear_bss:
 147         /* clear BSS segments */
 148         addi    r5, r0, __bss_start
 149         addi    r4, r0, __bss_end
 150         cmp     r6, r5, r4
 151         beqi    r6, 3f
 152 2:
 153         swi     r0, r5, 0 /* write zero to loc */
 154         addi    r5, r5, 4 /* increment to next loc */
 155         cmp     r6, r5, r4 /* check if we have reach the end */
 156         bnei    r6, 2b
 157 3:      /* jumping to board_init */
 158         brai    board_init_f
 159 1:      bri     1b
 160
 161 /*
 162  * Read 16bit little endian
 163  */
 164         .text
 165         .global in16
 166         .ent    in16
 167         .align  2
 168 in16:   lhu     r3, r0, r5
 169         bslli   r4, r3, 8
 170         bsrli   r3, r3, 8
 171         andi    r4, r4, 0xffff
 172         or      r3, r3, r4
 173         rtsd    r15, 8
 174         sext16  r3, r3
 175         .end    in16
 176
 177 /*
 178  * Write 16bit little endian
 179  * first parameter(r5) - address, second(r6) - short value
 180  */
 181         .text
 182         .global out16
 183         .ent    out16
 184         .align  2
 185 out16:  bslli   r3, r6, 8
 186         bsrli   r6, r6, 8
 187         andi    r3, r3, 0xffff
 188         or      r3, r3, r6
 189         sh      r3, r0, r5
 190         rtsd    r15, 8
 191         or      r0, r0, r0
 192         .end    out16