arch/m68k/coldfire/entry.S

   1 /*
   2  *  entry.S  -- interrupt and exception processing for ColdFire
   3  *
   4  *  Copyright (C) 1999-2007, Greg Ungerer (gerg@snapgear.com)
   5  *  Copyright (C) 1998  D. Jeff Dionne <jeff@lineo.ca>,
   6  *                      Kenneth Albanowski <kjahds@kjahds.com>,
   7  *  Copyright (C) 2000  Lineo Inc. (www.lineo.com)
   8  *  Copyright (C) 2004-2006  Macq Electronique SA. (www.macqel.com)
   9  *
  10  * Based on:
  11  *
  12  *  linux/arch/m68k/kernel/entry.S
  13  *
  14  *  Copyright (C) 1991, 1992  Linus Torvalds
  15  *
  16  * This file is subject to the terms and conditions of the GNU General Public
  17  * License.  See the file README.legal in the main directory of this archive
  18  * for more details.
  19  *
  20  * Linux/m68k support by Hamish Macdonald
  21  *
  22  * 68060 fixes by Jesper Skov
  23  * ColdFire support by Greg Ungerer (gerg@snapgear.com)
  24  * 5307 fixes by David W. Miller
  25  * linux 2.4 support David McCullough <davidm@snapgear.com>
  26  * Bug, speed and maintainability fixes by Philippe De Muyter <phdm@macqel.be>
  27  */
  28
  29 #include <linux/linkage.h>
  30 #include <asm/unistd.h>
  31 #include <asm/thread_info.h>
  32 #include <asm/errno.h>
  33 #include <asm/setup.h>
  34 #include <asm/asm-offsets.h>
  35 #include <asm/entry.h>
  36
  37 #ifdef CONFIG_COLDFIRE_SW_A7
  38 /*
  39  *      Define software copies of the supervisor and user stack pointers.
  40  */
  41 .bss
  42 sw_ksp:
  43 .long   0
  44 sw_usp:
  45 .long   0
  46 #endif /* CONFIG_COLDFIRE_SW_A7 */
  47
  48 .text
  49
  50 .globl system_call
  51 .globl resume
  52 .globl ret_from_exception
  53 .globl sys_call_table
  54 .globl inthandler
  55
  56 enosys:
  57         mov.l   #sys_ni_syscall,%d3
  58         bra     1f
  59
  60 ENTRY(system_call)
  61         SAVE_ALL_SYS
  62         move    #0x2000,%sr             /* enable intrs again */
  63         GET_CURRENT(%d2)
  64
  65         cmpl    #NR_syscalls,%d0
  66         jcc     enosys
  67         lea     sys_call_table,%a0
  68         lsll    #2,%d0                  /* movel %a0@(%d0:l:4),%d3 */
  69         movel   %a0@(%d0),%d3
  70         jeq     enosys
  71
  72 1:
  73         movel   %sp,%d2                 /* get thread_info pointer */
  74         andl    #-THREAD_SIZE,%d2       /* at start of kernel stack */
  75         movel   %d2,%a0
  76         movel   %a0@,%a1                /* save top of frame */
  77         movel   %sp,%a1@(TASK_THREAD+THREAD_ESP0)
  78         btst    #(TIF_SYSCALL_TRACE%8),%a0@(TINFO_FLAGS+(31-TIF_SYSCALL_TRACE)/8)
  79         bnes    1f
  80
  81         movel   %d3,%a0
  82         jbsr    %a0@
  83         movel   %d0,%sp@(PT_OFF_D0)     /* save the return value */
  84         jra     ret_from_exception
  85 1:
  86         movel   #-ENOSYS,%d2            /* strace needs -ENOSYS in PT_OFF_D0 */
  87         movel   %d2,PT_OFF_D0(%sp)      /* on syscall entry */
  88         subql   #4,%sp
  89         SAVE_SWITCH_STACK
  90         jbsr    syscall_trace_enter
  91         RESTORE_SWITCH_STACK
  92         addql   #4,%sp
  93         movel   %d3,%a0
  94         jbsr    %a0@
  95         movel   %d0,%sp@(PT_OFF_D0)             /* save the return value */
  96         subql   #4,%sp                  /* dummy return address */
  97         SAVE_SWITCH_STACK
  98         jbsr    syscall_trace_leave
  99         RESTORE_SWITCH_STACK
 100         addql   #4,%sp
 101
 102 ret_from_exception:
 103         move    #0x2700,%sr             /* disable intrs */
 104         btst    #5,%sp@(PT_OFF_SR)      /* check if returning to kernel */
 105         jeq     Luser_return            /* if so, skip resched, signals */
 106
 107 #ifdef CONFIG_PREEMPTION
 108         movel   %sp,%d1                 /* get thread_info pointer */
 109         andl    #-THREAD_SIZE,%d1       /* at base of kernel stack */
 110         movel   %d1,%a0
 111         movel   %a0@(TINFO_FLAGS),%d1   /* get thread_info->flags */
 112         andl    #(1<<TIF_NEED_RESCHED),%d1
 113         jeq     Lkernel_return
 114
 115         movel   %a0@(TINFO_PREEMPT),%d1
 116         cmpl    #0,%d1
 117         jne     Lkernel_return
 118
 119         pea     Lkernel_return
 120         jmp     preempt_schedule_irq    /* preempt the kernel */
 121 #endif
 122
 123 Lkernel_return:
 124         moveml  %sp@,%d1-%d5/%a0-%a2
 125         lea     %sp@(32),%sp            /* space for 8 regs */
 126         movel   %sp@+,%d0
 127         addql   #4,%sp                  /* orig d0 */
 128         addl    %sp@+,%sp               /* stk adj */
 129         rte
 130
 131 Luser_return:
 132         movel   %sp,%d1                 /* get thread_info pointer */
 133         andl    #-THREAD_SIZE,%d1       /* at base of kernel stack */
 134         movel   %d1,%a0
 135         moveb   %a0@(TINFO_FLAGS+3),%d1 /* thread_info->flags (low 8 bits) */
 136         jne     Lwork_to_do             /* still work to do */
 137
 138 Lreturn:
 139         RESTORE_USER
 140
 141 Lwork_to_do:
 142         movel   %a0@(TINFO_FLAGS),%d1   /* get thread_info->flags */
 143         move    #0x2000,%sr             /* enable intrs again */
 144         btst    #TIF_NEED_RESCHED,%d1
 145         jne     reschedule
 146
 147 Lsignal_return:
 148         subql   #4,%sp                  /* dummy return address */
 149         SAVE_SWITCH_STACK
 150         pea     %sp@(SWITCH_STACK_SIZE)
 151         jsr     do_notify_resume
 152         addql   #4,%sp
 153         RESTORE_SWITCH_STACK
 154         addql   #4,%sp
 155         jmp     Luser_return
 156
 157 /*
 158  * This is the generic interrupt handler (for all hardware interrupt
 159  * sources). Calls up to high level code to do all the work.
 160  */
 161 ENTRY(inthandler)
 162         SAVE_ALL_INT
 163         GET_CURRENT(%d2)
 164
 165         movew   %sp@(PT_OFF_FORMATVEC),%d0 /* put exception # in d0 */
 166         andl    #0x03fc,%d0             /* mask out vector only */
 167
 168         movel   %sp,%sp@-               /* push regs arg */
 169         lsrl    #2,%d0                  /* calculate real vector # */
 170         movel   %d0,%sp@-               /* push vector number */
 171         jbsr    do_IRQ                  /* call high level irq handler */
 172         lea     %sp@(8),%sp             /* pop args off stack */
 173
 174         bra     ret_from_exception
 175
 176 /*
 177  * Beware - when entering resume, prev (the current task) is
 178  * in a0, next (the new task) is in a1, so don't change these
 179  * registers until their contents are no longer needed.
 180  */
 181 ENTRY(resume)
 182         movew   %sr,%d1                          /* save current status */
 183         movew   %d1,%a0@(TASK_THREAD+THREAD_SR)
 184         movel   %a0,%d1                          /* get prev thread in d1 */
 185         SAVE_SWITCH_STACK
 186         movel   %sp,%a0@(TASK_THREAD+THREAD_KSP) /* save kernel stack pointer */
 187         RDUSP                                    /* movel %usp,%a3 */
 188         movel   %a3,%a0@(TASK_THREAD+THREAD_USP) /* save thread user stack */
 189 #ifdef CONFIG_MMU
 190         movel   %a1,%a2                          /* set new current */
 191 #endif
 192         movel   %a1@(TASK_THREAD+THREAD_USP),%a3 /* restore thread user stack */
 193         WRUSP                                    /* movel %a3,%usp */
 194         movel   %a1@(TASK_THREAD+THREAD_KSP),%sp /* restore new kernel stack */
 195         movew   %a1@(TASK_THREAD+THREAD_SR),%d7  /* restore new status */
 196         movew   %d7,%sr
 197         RESTORE_SWITCH_STACK
 198         rts
 199