arch/arm64/kernel/entry.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * Low-level exception handling code
   4  *
   5  * Copyright (C) 2012 ARM Ltd.
   6  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   7  *              Will Deacon <will.deacon@arm.com>
   8  */
   9
  10 #include <linux/arm-smccc.h>
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13
  14 #include <asm/alternative.h>
  15 #include <asm/assembler.h>
  16 #include <asm/asm-offsets.h>
  17 #include <asm/cpufeature.h>
  18 #include <asm/errno.h>
  19 #include <asm/esr.h>
  20 #include <asm/irq.h>
  21 #include <asm/memory.h>
  22 #include <asm/mmu.h>
  23 #include <asm/processor.h>
  24 #include <asm/ptrace.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/asm-uaccess.h>
  27 #include <asm/unistd.h>
  28
  29 /*
  30  * Context tracking subsystem.  Used to instrument transitions
  31  * between user and kernel mode.
  32  */
  33         .macro ct_user_exit_irqoff
  34 #ifdef CONFIG_CONTEXT_TRACKING
  35         bl      enter_from_user_mode
  36 #endif
  37         .endm
  38
  39         .macro ct_user_enter
  40 #ifdef CONFIG_CONTEXT_TRACKING
  41         bl      context_tracking_user_enter
  42 #endif
  43         .endm
  44
  45         .macro  clear_gp_regs
  46         .irp    n,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29
  47         mov     x\n, xzr
  48         .endr
  49         .endm
  50
  51 /*
  52  * Bad Abort numbers
  53  *-----------------
  54  */
  55 #define BAD_SYNC        0
  56 #define BAD_IRQ         1
  57 #define BAD_FIQ         2
  58 #define BAD_ERROR       3
  59
  60         .macro kernel_ventry, el, label, regsize = 64
  61         .align 7
  62 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
  63 alternative_if ARM64_UNMAP_KERNEL_AT_EL0
  64         .if     \el == 0
  65         .if     \regsize == 64
  66         mrs     x30, tpidrro_el0
  67         msr     tpidrro_el0, xzr
  68         .else
  69         mov     x30, xzr
  70         .endif
  71         .endif
  72 alternative_else_nop_endif
  73 #endif
  74
  75         sub     sp, sp, #S_FRAME_SIZE
  76 #ifdef CONFIG_VMAP_STACK
  77         /*
  78          * Test whether the SP has overflowed, without corrupting a GPR.
  79          * Task and IRQ stacks are aligned to (1 << THREAD_SHIFT).
  80          */
  81         add     sp, sp, x0                      // sp' = sp + x0
  82         sub     x0, sp, x0                      // x0' = sp' - x0 = (sp + x0) - x0 = sp
  83         tbnz    x0, #THREAD_SHIFT, 0f
  84         sub     x0, sp, x0                      // x0'' = sp' - x0' = (sp + x0) - sp = x0
  85         sub     sp, sp, x0                      // sp'' = sp' - x0 = (sp + x0) - x0 = sp
  86         b       el\()\el\()_\label
  87
  88 0:
  89         /*
  90          * Either we've just detected an overflow, or we've taken an exception
  91          * while on the overflow stack. Either way, we won't return to
  92          * userspace, and can clobber EL0 registers to free up GPRs.
  93          */
  94
  95         /* Stash the original SP (minus S_FRAME_SIZE) in tpidr_el0. */
  96         msr     tpidr_el0, x0
  97
  98         /* Recover the original x0 value and stash it in tpidrro_el0 */
  99         sub     x0, sp, x0
 100         msr     tpidrro_el0, x0
 101
 102         /* Switch to the overflow stack */
 103         adr_this_cpu sp, overflow_stack + OVERFLOW_STACK_SIZE, x0
 104
 105         /*
 106          * Check whether we were already on the overflow stack. This may happen
 107          * after panic() re-enables interrupts.
 108          */
 109         mrs     x0, tpidr_el0                   // sp of interrupted context
 110         sub     x0, sp, x0                      // delta with top of overflow stack
 111         tst     x0, #~(OVERFLOW_STACK_SIZE - 1) // within range?
 112         b.ne    __bad_stack                     // no? -> bad stack pointer
 113
 114         /* We were already on the overflow stack. Restore sp/x0 and carry on. */
 115         sub     sp, sp, x0
 116         mrs     x0, tpidrro_el0
 117 #endif
 118         b       el\()\el\()_\label
 119         .endm
 120
 121         .macro tramp_alias, dst, sym
 122         mov_q   \dst, TRAMP_VALIAS
 123         add     \dst, \dst, #(\sym - .entry.tramp.text)
 124         .endm
 125
 126         // This macro corrupts x0-x3. It is the caller's duty
 127         // to save/restore them if required.
 128         .macro  apply_ssbd, state, tmp1, tmp2
 129 #ifdef CONFIG_ARM64_SSBD
 130 alternative_cb  arm64_enable_wa2_handling
 131         b       .L__asm_ssbd_skip\@
 132 alternative_cb_end
 133         ldr_this_cpu    \tmp2, arm64_ssbd_callback_required, \tmp1
 134         cbz     \tmp2,  .L__asm_ssbd_skip\@
 135         ldr     \tmp2, [tsk, #TSK_TI_FLAGS]
 136         tbnz    \tmp2, #TIF_SSBD, .L__asm_ssbd_skip\@
 137         mov     w0, #ARM_SMCCC_ARCH_WORKAROUND_2
 138         mov     w1, #\state
 139 alternative_cb  arm64_update_smccc_conduit
 140         nop                                     // Patched to SMC/HVC #0
 141 alternative_cb_end
 142 .L__asm_ssbd_skip\@:
 143 #endif
 144         .endm
 145
 146         .macro  kernel_entry, el, regsize = 64
 147         .if     \regsize == 32
 148         mov     w0, w0                          // zero upper 32 bits of x0
 149         .endif
 150         stp     x0, x1, [sp, #16 * 0]
 151         stp     x2, x3, [sp, #16 * 1]
 152         stp     x4, x5, [sp, #16 * 2]
 153         stp     x6, x7, [sp, #16 * 3]
 154         stp     x8, x9, [sp, #16 * 4]
 155         stp     x10, x11, [sp, #16 * 5]
 156         stp     x12, x13, [sp, #16 * 6]
 157         stp     x14, x15, [sp, #16 * 7]
 158         stp     x16, x17, [sp, #16 * 8]
 159         stp     x18, x19, [sp, #16 * 9]
 160         stp     x20, x21, [sp, #16 * 10]
 161         stp     x22, x23, [sp, #16 * 11]
 162         stp     x24, x25, [sp, #16 * 12]
 163         stp     x26, x27, [sp, #16 * 13]
 164         stp     x28, x29, [sp, #16 * 14]
 165
 166         .if     \el == 0
 167         clear_gp_regs
 168         mrs     x21, sp_el0
 169         ldr_this_cpu    tsk, __entry_task, x20  // Ensure MDSCR_EL1.SS is clear,
 170         ldr     x19, [tsk, #TSK_TI_FLAGS]       // since we can unmask debug
 171         disable_step_tsk x19, x20               // exceptions when scheduling.
 172
 173         apply_ssbd 1, x22, x23
 174
 175         .else
 176         add     x21, sp, #S_FRAME_SIZE
 177         get_current_task tsk
 178         /* Save the task's original addr_limit and set USER_DS */
 179         ldr     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 180         str     x20, [sp, #S_ORIG_ADDR_LIMIT]
 181         mov     x20, #USER_DS
 182         str     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 183         /* No need to reset PSTATE.UAO, hardware's already set it to 0 for us */
 184         .endif /* \el == 0 */
 185         mrs     x22, elr_el1
 186         mrs     x23, spsr_el1
 187         stp     lr, x21, [sp, #S_LR]
 188
 189         /*
 190          * In order to be able to dump the contents of struct pt_regs at the
 191          * time the exception was taken (in case we attempt to walk the call
 192          * stack later), chain it together with the stack frames.
 193          */
 194         .if \el == 0
 195         stp     xzr, xzr, [sp, #S_STACKFRAME]
 196         .else
 197         stp     x29, x22, [sp, #S_STACKFRAME]
 198         .endif
 199         add     x29, sp, #S_STACKFRAME
 200
 201 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 202         /*
 203          * Set the TTBR0 PAN bit in SPSR. When the exception is taken from
 204          * EL0, there is no need to check the state of TTBR0_EL1 since
 205          * accesses are always enabled.
 206          * Note that the meaning of this bit differs from the ARMv8.1 PAN
 207          * feature as all TTBR0_EL1 accesses are disabled, not just those to
 208          * user mappings.
 209          */
 210 alternative_if ARM64_HAS_PAN
 211         b       1f                              // skip TTBR0 PAN
 212 alternative_else_nop_endif
 213
 214         .if     \el != 0
 215         mrs     x21, ttbr0_el1
 216         tst     x21, #TTBR_ASID_MASK            // Check for the reserved ASID
 217         orr     x23, x23, #PSR_PAN_BIT          // Set the emulated PAN in the saved SPSR
 218         b.eq    1f                              // TTBR0 access already disabled
 219         and     x23, x23, #~PSR_PAN_BIT         // Clear the emulated PAN in the saved SPSR
 220         .endif
 221
 222         __uaccess_ttbr0_disable x21
 223 1:
 224 #endif
 225
 226         stp     x22, x23, [sp, #S_PC]
 227
 228         /* Not in a syscall by default (el0_svc overwrites for real syscall) */
 229         .if     \el == 0
 230         mov     w21, #NO_SYSCALL
 231         str     w21, [sp, #S_SYSCALLNO]
 232         .endif
 233
 234         /*
 235          * Set sp_el0 to current thread_info.
 236          */
 237         .if     \el == 0
 238         msr     sp_el0, tsk
 239         .endif
 240
 241         /* Save pmr */
 242 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 243         mrs_s   x20, SYS_ICC_PMR_EL1
 244         str     x20, [sp, #S_PMR_SAVE]
 245 alternative_else_nop_endif
 246
 247         /*
 248          * Registers that may be useful after this macro is invoked:
 249          *
 250          * x20 - ICC_PMR_EL1
 251          * x21 - aborted SP
 252          * x22 - aborted PC
 253          * x23 - aborted PSTATE
 254         */
 255         .endm
 256
 257         .macro  kernel_exit, el
 258         .if     \el != 0
 259         disable_daif
 260
 261         /* Restore the task's original addr_limit. */
 262         ldr     x20, [sp, #S_ORIG_ADDR_LIMIT]
 263         str     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 264
 265         /* No need to restore UAO, it will be restored from SPSR_EL1 */
 266         .endif
 267
 268         /* Restore pmr */
 269 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 270         ldr     x20, [sp, #S_PMR_SAVE]
 271         msr_s   SYS_ICC_PMR_EL1, x20
 272         /* Ensure priority change is seen by redistributor */
 273         dsb     sy
 274 alternative_else_nop_endif
 275
 276         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 277         .if     \el == 0
 278         ct_user_enter
 279         .endif
 280
 281 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 282         /*
 283          * Restore access to TTBR0_EL1. If returning to EL0, no need for SPSR
 284          * PAN bit checking.
 285          */
 286 alternative_if ARM64_HAS_PAN
 287         b       2f                              // skip TTBR0 PAN
 288 alternative_else_nop_endif
 289
 290         .if     \el != 0
 291         tbnz    x22, #22, 1f                    // Skip re-enabling TTBR0 access if the PSR_PAN_BIT is set
 292         .endif
 293
 294         __uaccess_ttbr0_enable x0, x1
 295
 296         .if     \el == 0
 297         /*
 298          * Enable errata workarounds only if returning to user. The only
 299          * workaround currently required for TTBR0_EL1 changes are for the
 300          * Cavium erratum 27456 (broadcast TLBI instructions may cause I-cache
 301          * corruption).
 302          */
 303         bl      post_ttbr_update_workaround
 304         .endif
 305 1:
 306         .if     \el != 0
 307         and     x22, x22, #~PSR_PAN_BIT         // ARMv8.0 CPUs do not understand this bit
 308         .endif
 309 2:
 310 #endif
 311
 312         .if     \el == 0
 313         ldr     x23, [sp, #S_SP]                // load return stack pointer
 314         msr     sp_el0, x23
 315         tst     x22, #PSR_MODE32_BIT            // native task?
 316         b.eq    3f
 317
 318 #ifdef CONFIG_ARM64_ERRATUM_845719
 319 alternative_if ARM64_WORKAROUND_845719
 320 #ifdef CONFIG_PID_IN_CONTEXTIDR
 321         mrs     x29, contextidr_el1
 322         msr     contextidr_el1, x29
 323 #else
 324         msr contextidr_el1, xzr
 325 #endif
 326 alternative_else_nop_endif
 327 #endif
 328 3:
 329 #ifdef CONFIG_ARM64_ERRATUM_1418040
 330 alternative_if_not ARM64_WORKAROUND_1418040
 331         b       4f
 332 alternative_else_nop_endif
 333         /*
 334          * if (x22.mode32 == cntkctl_el1.el0vcten)
 335          *     cntkctl_el1.el0vcten = ~cntkctl_el1.el0vcten
 336          */
 337         mrs     x1, cntkctl_el1
 338         eon     x0, x1, x22, lsr #3
 339         tbz     x0, #1, 4f
 340         eor     x1, x1, #2      // ARCH_TIMER_USR_VCT_ACCESS_EN
 341         msr     cntkctl_el1, x1
 342 4:
 343 #endif
 344         apply_ssbd 0, x0, x1
 345         .endif
 346
 347         msr     elr_el1, x21                    // set up the return data
 348         msr     spsr_el1, x22
 349         ldp     x0, x1, [sp, #16 * 0]
 350         ldp     x2, x3, [sp, #16 * 1]
 351         ldp     x4, x5, [sp, #16 * 2]
 352         ldp     x6, x7, [sp, #16 * 3]
 353         ldp     x8, x9, [sp, #16 * 4]
 354         ldp     x10, x11, [sp, #16 * 5]
 355         ldp     x12, x13, [sp, #16 * 6]
 356         ldp     x14, x15, [sp, #16 * 7]
 357         ldp     x16, x17, [sp, #16 * 8]
 358         ldp     x18, x19, [sp, #16 * 9]
 359         ldp     x20, x21, [sp, #16 * 10]
 360         ldp     x22, x23, [sp, #16 * 11]
 361         ldp     x24, x25, [sp, #16 * 12]
 362         ldp     x26, x27, [sp, #16 * 13]
 363         ldp     x28, x29, [sp, #16 * 14]
 364         ldr     lr, [sp, #S_LR]
 365         add     sp, sp, #S_FRAME_SIZE           // restore sp
 366
 367         .if     \el == 0
 368 alternative_insn eret, nop, ARM64_UNMAP_KERNEL_AT_EL0
 369 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 370         bne     5f
 371         msr     far_el1, x30
 372         tramp_alias     x30, tramp_exit_native
 373         br      x30
 374 5:
 375         tramp_alias     x30, tramp_exit_compat
 376         br      x30
 377 #endif
 378         .else
 379         eret
 380         .endif
 381         sb
 382         .endm
 383
 384         .macro  irq_stack_entry
 385         mov     x19, sp                 // preserve the original sp
 386
 387         /*
 388          * Compare sp with the base of the task stack.
 389          * If the top ~(THREAD_SIZE - 1) bits match, we are on a task stack,
 390          * and should switch to the irq stack.
 391          */
 392         ldr     x25, [tsk, TSK_STACK]
 393         eor     x25, x25, x19
 394         and     x25, x25, #~(THREAD_SIZE - 1)
 395         cbnz    x25, 9998f
 396
 397         ldr_this_cpu x25, irq_stack_ptr, x26
 398         mov     x26, #IRQ_STACK_SIZE
 399         add     x26, x25, x26
 400
 401         /* switch to the irq stack */
 402         mov     sp, x26
 403 9998:
 404         .endm
 405
 406         /*
 407          * x19 should be preserved between irq_stack_entry and
 408          * irq_stack_exit.
 409          */
 410         .macro  irq_stack_exit
 411         mov     sp, x19
 412         .endm
 413
 414 /* GPRs used by entry code */
 415 tsk     .req    x28             // current thread_info
 416
 417 /*
 418  * Interrupt handling.
 419  */
 420         .macro  irq_handler
 421         ldr_l   x1, handle_arch_irq
 422         mov     x0, sp
 423         irq_stack_entry
 424         blr     x1
 425         irq_stack_exit
 426         .endm
 427
 428 #ifdef CONFIG_ARM64_PSEUDO_NMI
 429         /*
 430          * Set res to 0 if irqs were unmasked in interrupted context.
 431          * Otherwise set res to non-0 value.
 432          */
 433         .macro  test_irqs_unmasked res:req, pmr:req
 434 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 435         sub     \res, \pmr, #GIC_PRIO_IRQON
 436 alternative_else
 437         mov     \res, xzr
 438 alternative_endif
 439         .endm
 440 #endif
 441
 442         .macro  gic_prio_kentry_setup, tmp:req
 443 #ifdef CONFIG_ARM64_PSEUDO_NMI
 444         alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 445         mov     \tmp, #(GIC_PRIO_PSR_I_SET | GIC_PRIO_IRQON)
 446         msr_s   SYS_ICC_PMR_EL1, \tmp
 447         alternative_else_nop_endif
 448 #endif
 449         .endm
 450
 451         .macro  gic_prio_irq_setup, pmr:req, tmp:req
 452 #ifdef CONFIG_ARM64_PSEUDO_NMI
 453         alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 454         orr     \tmp, \pmr, #GIC_PRIO_PSR_I_SET
 455         msr_s   SYS_ICC_PMR_EL1, \tmp
 456         alternative_else_nop_endif
 457 #endif
 458         .endm
 459
 460         .text
 461
 462 /*
 463  * Exception vectors.
 464  */
 465         .pushsection ".entry.text", "ax"
 466
 467         .align  11
 468 ENTRY(vectors)
 469         kernel_ventry   1, sync_invalid                 // Synchronous EL1t
 470         kernel_ventry   1, irq_invalid                  // IRQ EL1t
 471         kernel_ventry   1, fiq_invalid                  // FIQ EL1t
 472         kernel_ventry   1, error_invalid                // Error EL1t
 473
 474         kernel_ventry   1, sync                         // Synchronous EL1h
 475         kernel_ventry   1, irq                          // IRQ EL1h
 476         kernel_ventry   1, fiq_invalid                  // FIQ EL1h
 477         kernel_ventry   1, error                        // Error EL1h
 478
 479         kernel_ventry   0, sync                         // Synchronous 64-bit EL0
 480         kernel_ventry   0, irq                          // IRQ 64-bit EL0
 481         kernel_ventry   0, fiq_invalid                  // FIQ 64-bit EL0
 482         kernel_ventry   0, error                        // Error 64-bit EL0
 483
 484 #ifdef CONFIG_COMPAT
 485         kernel_ventry   0, sync_compat, 32              // Synchronous 32-bit EL0
 486         kernel_ventry   0, irq_compat, 32               // IRQ 32-bit EL0
 487         kernel_ventry   0, fiq_invalid_compat, 32       // FIQ 32-bit EL0
 488         kernel_ventry   0, error_compat, 32             // Error 32-bit EL0
 489 #else
 490         kernel_ventry   0, sync_invalid, 32             // Synchronous 32-bit EL0
 491         kernel_ventry   0, irq_invalid, 32              // IRQ 32-bit EL0
 492         kernel_ventry   0, fiq_invalid, 32              // FIQ 32-bit EL0
 493         kernel_ventry   0, error_invalid, 32            // Error 32-bit EL0
 494 #endif
 495 END(vectors)
 496
 497 #ifdef CONFIG_VMAP_STACK
 498         /*
 499          * We detected an overflow in kernel_ventry, which switched to the
 500          * overflow stack. Stash the exception regs, and head to our overflow
 501          * handler.
 502          */
 503 __bad_stack:
 504         /* Restore the original x0 value */
 505         mrs     x0, tpidrro_el0
 506
 507         /*
 508          * Store the original GPRs to the new stack. The orginal SP (minus
 509          * S_FRAME_SIZE) was stashed in tpidr_el0 by kernel_ventry.
 510          */
 511         sub     sp, sp, #S_FRAME_SIZE
 512         kernel_entry 1
 513         mrs     x0, tpidr_el0
 514         add     x0, x0, #S_FRAME_SIZE
 515         str     x0, [sp, #S_SP]
 516
 517         /* Stash the regs for handle_bad_stack */
 518         mov     x0, sp
 519
 520         /* Time to die */
 521         bl      handle_bad_stack
 522         ASM_BUG()
 523 #endif /* CONFIG_VMAP_STACK */
 524
 525 /*
 526  * Invalid mode handlers
 527  */
 528         .macro  inv_entry, el, reason, regsize = 64
 529         kernel_entry \el, \regsize
 530         mov     x0, sp
 531         mov     x1, #\reason
 532         mrs     x2, esr_el1
 533         bl      bad_mode
 534         ASM_BUG()
 535         .endm
 536
 537 el0_sync_invalid:
 538         inv_entry 0, BAD_SYNC
 539 ENDPROC(el0_sync_invalid)
 540
 541 el0_irq_invalid:
 542         inv_entry 0, BAD_IRQ
 543 ENDPROC(el0_irq_invalid)
 544
 545 el0_fiq_invalid:
 546         inv_entry 0, BAD_FIQ
 547 ENDPROC(el0_fiq_invalid)
 548
 549 el0_error_invalid:
 550         inv_entry 0, BAD_ERROR
 551 ENDPROC(el0_error_invalid)
 552
 553 #ifdef CONFIG_COMPAT
 554 el0_fiq_invalid_compat:
 555         inv_entry 0, BAD_FIQ, 32
 556 ENDPROC(el0_fiq_invalid_compat)
 557 #endif
 558
 559 el1_sync_invalid:
 560         inv_entry 1, BAD_SYNC
 561 ENDPROC(el1_sync_invalid)
 562
 563 el1_irq_invalid:
 564         inv_entry 1, BAD_IRQ
 565 ENDPROC(el1_irq_invalid)
 566
 567 el1_fiq_invalid:
 568         inv_entry 1, BAD_FIQ
 569 ENDPROC(el1_fiq_invalid)
 570
 571 el1_error_invalid:
 572         inv_entry 1, BAD_ERROR
 573 ENDPROC(el1_error_invalid)
 574
 575 /*
 576  * EL1 mode handlers.
 577  */
 578         .align  6
 579 el1_sync:
 580         kernel_entry 1
 581         mov     x0, sp
 582         bl      el1_sync_handler
 583         kernel_exit 1
 584 ENDPROC(el1_sync)
 585
 586         .align  6
 587 el1_irq:
 588         kernel_entry 1
 589         gic_prio_irq_setup pmr=x20, tmp=x1
 590         enable_da_f
 591
 592 #ifdef CONFIG_ARM64_PSEUDO_NMI
 593         test_irqs_unmasked      res=x0, pmr=x20
 594         cbz     x0, 1f
 595         bl      asm_nmi_enter
 596 1:
 597 #endif
 598
 599 #ifdef CONFIG_TRACE_IRQFLAGS
 600         bl      trace_hardirqs_off
 601 #endif
 602
 603         irq_handler
 604
 605 #ifdef CONFIG_PREEMPT
 606         ldr     x24, [tsk, #TSK_TI_PREEMPT]     // get preempt count
 607 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 608         /*
 609          * DA_F were cleared at start of handling. If anything is set in DAIF,
 610          * we come back from an NMI, so skip preemption
 611          */
 612         mrs     x0, daif
 613         orr     x24, x24, x0
 614 alternative_else_nop_endif
 615         cbnz    x24, 1f                         // preempt count != 0 || NMI return path
 616         bl      arm64_preempt_schedule_irq      // irq en/disable is done inside
 617 1:
 618 #endif
 619
 620 #ifdef CONFIG_ARM64_PSEUDO_NMI
 621         /*
 622          * When using IRQ priority masking, we can get spurious interrupts while
 623          * PMR is set to GIC_PRIO_IRQOFF. An NMI might also have occurred in a
 624          * section with interrupts disabled. Skip tracing in those cases.
 625          */
 626         test_irqs_unmasked      res=x0, pmr=x20
 627         cbz     x0, 1f
 628         bl      asm_nmi_exit
 629 1:
 630 #endif
 631
 632 #ifdef CONFIG_TRACE_IRQFLAGS
 633 #ifdef CONFIG_ARM64_PSEUDO_NMI
 634         test_irqs_unmasked      res=x0, pmr=x20
 635         cbnz    x0, 1f
 636 #endif
 637         bl      trace_hardirqs_on
 638 1:
 639 #endif
 640
 641         kernel_exit 1
 642 ENDPROC(el1_irq)
 643
 644 /*
 645  * EL0 mode handlers.
 646  */
 647         .align  6
 648 el0_sync:
 649         kernel_entry 0
 650         mov     x0, sp
 651         bl      el0_sync_handler
 652         b       ret_to_user
 653
 654 #ifdef CONFIG_COMPAT
 655         .align  6
 656 el0_sync_compat:
 657         kernel_entry 0, 32
 658         mov     x0, sp
 659         bl      el0_sync_compat_handler
 660         b       ret_to_user
 661 ENDPROC(el0_sync)
 662
 663         .align  6
 664 el0_irq_compat:
 665         kernel_entry 0, 32
 666         b       el0_irq_naked
 667
 668 el0_error_compat:
 669         kernel_entry 0, 32
 670         b       el0_error_naked
 671 #endif
 672
 673         .align  6
 674 el0_irq:
 675         kernel_entry 0
 676 el0_irq_naked:
 677         gic_prio_irq_setup pmr=x20, tmp=x0
 678         ct_user_exit_irqoff
 679         enable_da_f
 680
 681 #ifdef CONFIG_TRACE_IRQFLAGS
 682         bl      trace_hardirqs_off
 683 #endif
 684
 685 #ifdef CONFIG_HARDEN_BRANCH_PREDICTOR
 686         tbz     x22, #55, 1f
 687         bl      do_el0_irq_bp_hardening
 688 1:
 689 #endif
 690         irq_handler
 691
 692 #ifdef CONFIG_TRACE_IRQFLAGS
 693         bl      trace_hardirqs_on
 694 #endif
 695         b       ret_to_user
 696 ENDPROC(el0_irq)
 697
 698 el1_error:
 699         kernel_entry 1
 700         mrs     x1, esr_el1
 701         gic_prio_kentry_setup tmp=x2
 702         enable_dbg
 703         mov     x0, sp
 704         bl      do_serror
 705         kernel_exit 1
 706 ENDPROC(el1_error)
 707
 708 el0_error:
 709         kernel_entry 0
 710 el0_error_naked:
 711         mrs     x25, esr_el1
 712         gic_prio_kentry_setup tmp=x2
 713         ct_user_exit_irqoff
 714         enable_dbg
 715         mov     x0, sp
 716         mov     x1, x25
 717         bl      do_serror
 718         enable_da_f
 719         b       ret_to_user
 720 ENDPROC(el0_error)
 721
 722 /*
 723  * Ok, we need to do extra processing, enter the slow path.
 724  */
 725 work_pending:
 726         mov     x0, sp                          // 'regs'
 727         bl      do_notify_resume
 728 #ifdef CONFIG_TRACE_IRQFLAGS
 729         bl      trace_hardirqs_on               // enabled while in userspace
 730 #endif
 731         ldr     x1, [tsk, #TSK_TI_FLAGS]        // re-check for single-step
 732         b       finish_ret_to_user
 733 /*
 734  * "slow" syscall return path.
 735  */
 736 ret_to_user:
 737         disable_daif
 738         gic_prio_kentry_setup tmp=x3
 739         ldr     x1, [tsk, #TSK_TI_FLAGS]
 740         and     x2, x1, #_TIF_WORK_MASK
 741         cbnz    x2, work_pending
 742 finish_ret_to_user:
 743         enable_step_tsk x1, x2
 744 #ifdef CONFIG_GCC_PLUGIN_STACKLEAK
 745         bl      stackleak_erase
 746 #endif
 747         kernel_exit 0
 748 ENDPROC(ret_to_user)
 749
 750         .popsection                             // .entry.text
 751
 752 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 753 /*
 754  * Exception vectors trampoline.
 755  */
 756         .pushsection ".entry.tramp.text", "ax"
 757
 758         .macro tramp_map_kernel, tmp
 759         mrs     \tmp, ttbr1_el1
 760         add     \tmp, \tmp, #(PAGE_SIZE + RESERVED_TTBR0_SIZE)
 761         bic     \tmp, \tmp, #USER_ASID_FLAG
 762         msr     ttbr1_el1, \tmp
 763 #ifdef CONFIG_QCOM_FALKOR_ERRATUM_1003
 764 alternative_if ARM64_WORKAROUND_QCOM_FALKOR_E1003
 765         /* ASID already in \tmp[63:48] */
 766         movk    \tmp, #:abs_g2_nc:(TRAMP_VALIAS >> 12)
 767         movk    \tmp, #:abs_g1_nc:(TRAMP_VALIAS >> 12)
 768         /* 2MB boundary containing the vectors, so we nobble the walk cache */
 769         movk    \tmp, #:abs_g0_nc:((TRAMP_VALIAS & ~(SZ_2M - 1)) >> 12)
 770         isb
 771         tlbi    vae1, \tmp
 772         dsb     nsh
 773 alternative_else_nop_endif
 774 #endif /* CONFIG_QCOM_FALKOR_ERRATUM_1003 */
 775         .endm
 776
 777         .macro tramp_unmap_kernel, tmp
 778         mrs     \tmp, ttbr1_el1
 779         sub     \tmp, \tmp, #(PAGE_SIZE + RESERVED_TTBR0_SIZE)
 780         orr     \tmp, \tmp, #USER_ASID_FLAG
 781         msr     ttbr1_el1, \tmp
 782         /*
 783          * We avoid running the post_ttbr_update_workaround here because
 784          * it's only needed by Cavium ThunderX, which requires KPTI to be
 785          * disabled.
 786          */
 787         .endm
 788
 789         .macro tramp_ventry, regsize = 64
 790         .align  7
 791 1:
 792         .if     \regsize == 64
 793         msr     tpidrro_el0, x30        // Restored in kernel_ventry
 794         .endif
 795         /*
 796          * Defend against branch aliasing attacks by pushing a dummy
 797          * entry onto the return stack and using a RET instruction to
 798          * enter the full-fat kernel vectors.
 799          */
 800         bl      2f
 801         b       .
 802 2:
 803         tramp_map_kernel        x30
 804 #ifdef CONFIG_RANDOMIZE_BASE
 805         adr     x30, tramp_vectors + PAGE_SIZE
 806 alternative_insn isb, nop, ARM64_WORKAROUND_QCOM_FALKOR_E1003
 807         ldr     x30, [x30]
 808 #else
 809         ldr     x30, =vectors
 810 #endif
 811 alternative_if_not ARM64_WORKAROUND_CAVIUM_TX2_219_PRFM
 812         prfm    plil1strm, [x30, #(1b - tramp_vectors)]
 813 alternative_else_nop_endif
 814         msr     vbar_el1, x30
 815         add     x30, x30, #(1b - tramp_vectors)
 816         isb
 817         ret
 818         .endm
 819
 820         .macro tramp_exit, regsize = 64
 821         adr     x30, tramp_vectors
 822         msr     vbar_el1, x30
 823         tramp_unmap_kernel      x30
 824         .if     \regsize == 64
 825         mrs     x30, far_el1
 826         .endif
 827         eret
 828         sb
 829         .endm
 830
 831         .align  11
 832 ENTRY(tramp_vectors)
 833         .space  0x400
 834
 835         tramp_ventry
 836         tramp_ventry
 837         tramp_ventry
 838         tramp_ventry
 839
 840         tramp_ventry    32
 841         tramp_ventry    32
 842         tramp_ventry    32
 843         tramp_ventry    32
 844 END(tramp_vectors)
 845
 846 ENTRY(tramp_exit_native)
 847         tramp_exit
 848 END(tramp_exit_native)
 849
 850 ENTRY(tramp_exit_compat)
 851         tramp_exit      32
 852 END(tramp_exit_compat)
 853
 854         .ltorg
 855         .popsection                             // .entry.tramp.text
 856 #ifdef CONFIG_RANDOMIZE_BASE
 857         .pushsection ".rodata", "a"
 858         .align PAGE_SHIFT
 859         .globl  __entry_tramp_data_start
 860 __entry_tramp_data_start:
 861         .quad   vectors
 862         .popsection                             // .rodata
 863 #endif /* CONFIG_RANDOMIZE_BASE */
 864 #endif /* CONFIG_UNMAP_KERNEL_AT_EL0 */
 865
 866 /*
 867  * Register switch for AArch64. The callee-saved registers need to be saved
 868  * and restored. On entry:
 869  *   x0 = previous task_struct (must be preserved across the switch)
 870  *   x1 = next task_struct
 871  * Previous and next are guaranteed not to be the same.
 872  *
 873  */
 874 ENTRY(cpu_switch_to)
 875         mov     x10, #THREAD_CPU_CONTEXT
 876         add     x8, x0, x10
 877         mov     x9, sp
 878         stp     x19, x20, [x8], #16             // store callee-saved registers
 879         stp     x21, x22, [x8], #16
 880         stp     x23, x24, [x8], #16
 881         stp     x25, x26, [x8], #16
 882         stp     x27, x28, [x8], #16
 883         stp     x29, x9, [x8], #16
 884         str     lr, [x8]
 885         add     x8, x1, x10
 886         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 887         ldp     x21, x22, [x8], #16
 888         ldp     x23, x24, [x8], #16
 889         ldp     x25, x26, [x8], #16
 890         ldp     x27, x28, [x8], #16
 891         ldp     x29, x9, [x8], #16
 892         ldr     lr, [x8]
 893         mov     sp, x9
 894         msr     sp_el0, x1
 895         ret
 896 ENDPROC(cpu_switch_to)
 897 NOKPROBE(cpu_switch_to)
 898
 899 /*
 900  * This is how we return from a fork.
 901  */
 902 ENTRY(ret_from_fork)
 903         bl      schedule_tail
 904         cbz     x19, 1f                         // not a kernel thread
 905         mov     x0, x20
 906         blr     x19
 907 1:      get_current_task tsk
 908         b       ret_to_user
 909 ENDPROC(ret_from_fork)
 910 NOKPROBE(ret_from_fork)
 911
 912 #ifdef CONFIG_ARM_SDE_INTERFACE
 913
 914 #include <asm/sdei.h>
 915 #include <uapi/linux/arm_sdei.h>
 916
 917 .macro sdei_handler_exit exit_mode
 918         /* On success, this call never returns... */
 919         cmp     \exit_mode, #SDEI_EXIT_SMC
 920         b.ne    99f
 921         smc     #0
 922         b       .
 923 99:     hvc     #0
 924         b       .
 925 .endm
 926
 927 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 928 /*
 929  * The regular SDEI entry point may have been unmapped along with the rest of
 930  * the kernel. This trampoline restores the kernel mapping to make the x1 memory
 931  * argument accessible.
 932  *
 933  * This clobbers x4, __sdei_handler() will restore this from firmware's
 934  * copy.
 935  */
 936 .ltorg
 937 .pushsection ".entry.tramp.text", "ax"
 938 ENTRY(__sdei_asm_entry_trampoline)
 939         mrs     x4, ttbr1_el1
 940         tbz     x4, #USER_ASID_BIT, 1f
 941
 942         tramp_map_kernel tmp=x4
 943         isb
 944         mov     x4, xzr
 945
 946         /*
 947          * Use reg->interrupted_regs.addr_limit to remember whether to unmap
 948          * the kernel on exit.
 949          */
 950 1:      str     x4, [x1, #(SDEI_EVENT_INTREGS + S_ORIG_ADDR_LIMIT)]
 951
 952 #ifdef CONFIG_RANDOMIZE_BASE
 953         adr     x4, tramp_vectors + PAGE_SIZE
 954         add     x4, x4, #:lo12:__sdei_asm_trampoline_next_handler
 955         ldr     x4, [x4]
 956 #else
 957         ldr     x4, =__sdei_asm_handler
 958 #endif
 959         br      x4
 960 ENDPROC(__sdei_asm_entry_trampoline)
 961 NOKPROBE(__sdei_asm_entry_trampoline)
 962
 963 /*
 964  * Make the exit call and restore the original ttbr1_el1
 965  *
 966  * x0 & x1: setup for the exit API call
 967  * x2: exit_mode
 968  * x4: struct sdei_registered_event argument from registration time.
 969  */
 970 ENTRY(__sdei_asm_exit_trampoline)
 971         ldr     x4, [x4, #(SDEI_EVENT_INTREGS + S_ORIG_ADDR_LIMIT)]
 972         cbnz    x4, 1f
 973
 974         tramp_unmap_kernel      tmp=x4
 975
 976 1:      sdei_handler_exit exit_mode=x2
 977 ENDPROC(__sdei_asm_exit_trampoline)
 978 NOKPROBE(__sdei_asm_exit_trampoline)
 979         .ltorg
 980 .popsection             // .entry.tramp.text
 981 #ifdef CONFIG_RANDOMIZE_BASE
 982 .pushsection ".rodata", "a"
 983 __sdei_asm_trampoline_next_handler:
 984         .quad   __sdei_asm_handler
 985 .popsection             // .rodata
 986 #endif /* CONFIG_RANDOMIZE_BASE */
 987 #endif /* CONFIG_UNMAP_KERNEL_AT_EL0 */
 988
 989 /*
 990  * Software Delegated Exception entry point.
 991  *
 992  * x0: Event number
 993  * x1: struct sdei_registered_event argument from registration time.
 994  * x2: interrupted PC
 995  * x3: interrupted PSTATE
 996  * x4: maybe clobbered by the trampoline
 997  *
 998  * Firmware has preserved x0->x17 for us, we must save/restore the rest to
 999  * follow SMC-CC. We save (or retrieve) all the registers as the handler may
1000  * want them.
1001  */
1002 ENTRY(__sdei_asm_handler)
1003         stp     x2, x3, [x1, #SDEI_EVENT_INTREGS + S_PC]
1004         stp     x4, x5, [x1, #SDEI_EVENT_INTREGS + 16 * 2]
1005         stp     x6, x7, [x1, #SDEI_EVENT_INTREGS + 16 * 3]
1006         stp     x8, x9, [x1, #SDEI_EVENT_INTREGS + 16 * 4]
1007         stp     x10, x11, [x1, #SDEI_EVENT_INTREGS + 16 * 5]
1008         stp     x12, x13, [x1, #SDEI_EVENT_INTREGS + 16 * 6]
1009         stp     x14, x15, [x1, #SDEI_EVENT_INTREGS + 16 * 7]
1010         stp     x16, x17, [x1, #SDEI_EVENT_INTREGS + 16 * 8]
1011         stp     x18, x19, [x1, #SDEI_EVENT_INTREGS + 16 * 9]
1012         stp     x20, x21, [x1, #SDEI_EVENT_INTREGS + 16 * 10]
1013         stp     x22, x23, [x1, #SDEI_EVENT_INTREGS + 16 * 11]
1014         stp     x24, x25, [x1, #SDEI_EVENT_INTREGS + 16 * 12]
1015         stp     x26, x27, [x1, #SDEI_EVENT_INTREGS + 16 * 13]
1016         stp     x28, x29, [x1, #SDEI_EVENT_INTREGS + 16 * 14]
1017         mov     x4, sp
1018         stp     lr, x4, [x1, #SDEI_EVENT_INTREGS + S_LR]
1019
1020         mov     x19, x1
1021
1022 #ifdef CONFIG_VMAP_STACK
1023         /*
1024          * entry.S may have been using sp as a scratch register, find whether
1025          * this is a normal or critical event and switch to the appropriate
1026          * stack for this CPU.
1027          */
1028         ldrb    w4, [x19, #SDEI_EVENT_PRIORITY]
1029         cbnz    w4, 1f
1030         ldr_this_cpu dst=x5, sym=sdei_stack_normal_ptr, tmp=x6
1031         b       2f
1032 1:      ldr_this_cpu dst=x5, sym=sdei_stack_critical_ptr, tmp=x6
1033 2:      mov     x6, #SDEI_STACK_SIZE
1034         add     x5, x5, x6
1035         mov     sp, x5
1036 #endif
1037
1038         /*
1039          * We may have interrupted userspace, or a guest, or exit-from or
1040          * return-to either of these. We can't trust sp_el0, restore it.
1041          */
1042         mrs     x28, sp_el0
1043         ldr_this_cpu    dst=x0, sym=__entry_task, tmp=x1
1044         msr     sp_el0, x0
1045
1046         /* If we interrupted the kernel point to the previous stack/frame. */
1047         and     x0, x3, #0xc
1048         mrs     x1, CurrentEL
1049         cmp     x0, x1
1050         csel    x29, x29, xzr, eq       // fp, or zero
1051         csel    x4, x2, xzr, eq         // elr, or zero
1052
1053         stp     x29, x4, [sp, #-16]!
1054         mov     x29, sp
1055
1056         add     x0, x19, #SDEI_EVENT_INTREGS
1057         mov     x1, x19
1058         bl      __sdei_handler
1059
1060         msr     sp_el0, x28
1061         /* restore regs >x17 that we clobbered */
1062         mov     x4, x19         // keep x4 for __sdei_asm_exit_trampoline
1063         ldp     x28, x29, [x4, #SDEI_EVENT_INTREGS + 16 * 14]
1064         ldp     x18, x19, [x4, #SDEI_EVENT_INTREGS + 16 * 9]
1065         ldp     lr, x1, [x4, #SDEI_EVENT_INTREGS + S_LR]
1066         mov     sp, x1
1067
1068         mov     x1, x0                  // address to complete_and_resume
1069         /* x0 = (x0 <= 1) ? EVENT_COMPLETE:EVENT_COMPLETE_AND_RESUME */
1070         cmp     x0, #1
1071         mov_q   x2, SDEI_1_0_FN_SDEI_EVENT_COMPLETE
1072         mov_q   x3, SDEI_1_0_FN_SDEI_EVENT_COMPLETE_AND_RESUME
1073         csel    x0, x2, x3, ls
1074
1075         ldr_l   x2, sdei_exit_mode
1076
1077 alternative_if_not ARM64_UNMAP_KERNEL_AT_EL0
1078         sdei_handler_exit exit_mode=x2
1079 alternative_else_nop_endif
1080
1081 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
1082         tramp_alias     dst=x5, sym=__sdei_asm_exit_trampoline
1083         br      x5
1084 #endif
1085 ENDPROC(__sdei_asm_handler)
1086 NOKPROBE(__sdei_asm_handler)
1087 #endif /* CONFIG_ARM_SDE_INTERFACE */