arch/arm/mm/proc-v7.S

   1 /*
   2  *  linux/arch/arm/mm/proc-v7.S
   3  *
   4  *  Copyright (C) 2001 Deep Blue Solutions Ltd.
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  This is the "shell" of the ARMv7 processor support.
  11  */
  12 #include <linux/init.h>
  13 #include <linux/linkage.h>
  14 #include <asm/assembler.h>
  15 #include <asm/asm-offsets.h>
  16 #include <asm/hwcap.h>
  17 #include <asm/pgtable-hwdef.h>
  18 #include <asm/pgtable.h>
  19
  20 #include "proc-macros.S"
  21
  22 #define TTB_S           (1 << 1)
  23 #define TTB_RGN_NC      (0 << 3)
  24 #define TTB_RGN_OC_WBWA (1 << 3)
  25 #define TTB_RGN_OC_WT   (2 << 3)
  26 #define TTB_RGN_OC_WB   (3 << 3)
  27 #define TTB_NOS         (1 << 5)
  28 #define TTB_IRGN_NC     ((0 << 0) | (0 << 6))
  29 #define TTB_IRGN_WBWA   ((0 << 0) | (1 << 6))
  30 #define TTB_IRGN_WT     ((1 << 0) | (0 << 6))
  31 #define TTB_IRGN_WB     ((1 << 0) | (1 << 6))
  32
  33 /* PTWs cacheable, inner WB not shareable, outer WB not shareable */
  34 #define TTB_FLAGS_UP    TTB_IRGN_WB|TTB_RGN_OC_WB
  35 #define PMD_FLAGS_UP    PMD_SECT_WB
  36
  37 /* PTWs cacheable, inner WBWA shareable, outer WBWA not shareable */
  38 #define TTB_FLAGS_SMP   TTB_IRGN_WBWA|TTB_S|TTB_NOS|TTB_RGN_OC_WBWA
  39 #define PMD_FLAGS_SMP   PMD_SECT_WBWA|PMD_SECT_S
  40
  41 ENTRY(cpu_v7_proc_init)
  42         mov     pc, lr
  43 ENDPROC(cpu_v7_proc_init)
  44
  45 ENTRY(cpu_v7_proc_fin)
  46         mrc     p15, 0, r0, c1, c0, 0           @ ctrl register
  47         bic     r0, r0, #0x1000                 @ ...i............
  48         bic     r0, r0, #0x0006                 @ .............ca.
  49         mcr     p15, 0, r0, c1, c0, 0           @ disable caches
  50         mov     pc, lr
  51 ENDPROC(cpu_v7_proc_fin)
  52
  53 /*
  54  *      cpu_v7_reset(loc)
  55  *
  56  *      Perform a soft reset of the system.  Put the CPU into the
  57  *      same state as it would be if it had been reset, and branch
  58  *      to what would be the reset vector.
  59  *
  60  *      - loc   - location to jump to for soft reset
  61  */
  62         .align  5
  63 ENTRY(cpu_v7_reset)
  64         mov     pc, r0
  65 ENDPROC(cpu_v7_reset)
  66
  67 /*
  68  *      cpu_v7_do_idle()
  69  *
  70  *      Idle the processor (eg, wait for interrupt).
  71  *
  72  *      IRQs are already disabled.
  73  */
  74 ENTRY(cpu_v7_do_idle)
  75         dsb                                     @ WFI may enter a low-power mode
  76         wfi
  77         mov     pc, lr
  78 ENDPROC(cpu_v7_do_idle)
  79
  80 ENTRY(cpu_v7_dcache_clean_area)
  81 #ifndef TLB_CAN_READ_FROM_L1_CACHE
  82         dcache_line_size r2, r3
  83 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
  84         add     r0, r0, r2
  85         subs    r1, r1, r2
  86         bhi     1b
  87         dsb
  88 #endif
  89         mov     pc, lr
  90 ENDPROC(cpu_v7_dcache_clean_area)
  91
  92 /*
  93  *      cpu_v7_switch_mm(pgd_phys, tsk)
  94  *
  95  *      Set the translation table base pointer to be pgd_phys
  96  *
  97  *      - pgd_phys - physical address of new TTB
  98  *
  99  *      It is assumed that:
 100  *      - we are not using split page tables
 101  */
 102 ENTRY(cpu_v7_switch_mm)
 103 #ifdef CONFIG_MMU
 104         mov     r2, #0
 105         ldr     r1, [r1, #MM_CONTEXT_ID]        @ get mm->context.id
 106         ALT_SMP(orr     r0, r0, #TTB_FLAGS_SMP)
 107         ALT_UP(orr      r0, r0, #TTB_FLAGS_UP)
 108 #ifdef CONFIG_ARM_ERRATA_430973
 109         mcr     p15, 0, r2, c7, c5, 6           @ flush BTAC/BTB
 110 #endif
 111         mcr     p15, 0, r2, c13, c0, 1          @ set reserved context ID
 112         isb
 113 1:      mcr     p15, 0, r0, c2, c0, 0           @ set TTB 0
 114         isb
 115         mcr     p15, 0, r1, c13, c0, 1          @ set context ID
 116         isb
 117 #endif
 118         mov     pc, lr
 119 ENDPROC(cpu_v7_switch_mm)
 120
 121 /*
 122  *      cpu_v7_set_pte_ext(ptep, pte)
 123  *
 124  *      Set a level 2 translation table entry.
 125  *
 126  *      - ptep  - pointer to level 2 translation table entry
 127  *                (hardware version is stored at +2048 bytes)
 128  *      - pte   - PTE value to store
 129  *      - ext   - value for extended PTE bits
 130  */
 131 ENTRY(cpu_v7_set_pte_ext)
 132 #ifdef CONFIG_MMU
 133         str     r1, [r0]                        @ linux version
 134
 135         bic     r3, r1, #0x000003f0
 136         bic     r3, r3, #PTE_TYPE_MASK
 137         orr     r3, r3, r2
 138         orr     r3, r3, #PTE_EXT_AP0 | 2
 139
 140         tst     r1, #1 << 4
 141         orrne   r3, r3, #PTE_EXT_TEX(1)
 142
 143         tst     r1, #L_PTE_WRITE
 144         tstne   r1, #L_PTE_DIRTY
 145         orreq   r3, r3, #PTE_EXT_APX
 146
 147         tst     r1, #L_PTE_USER
 148         orrne   r3, r3, #PTE_EXT_AP1
 149         tstne   r3, #PTE_EXT_APX
 150         bicne   r3, r3, #PTE_EXT_APX | PTE_EXT_AP0
 151
 152         tst     r1, #L_PTE_EXEC
 153         orreq   r3, r3, #PTE_EXT_XN
 154
 155         tst     r1, #L_PTE_YOUNG
 156         tstne   r1, #L_PTE_PRESENT
 157         moveq   r3, #0
 158
 159         str     r3, [r0, #2048]!
 160         mcr     p15, 0, r0, c7, c10, 1          @ flush_pte
 161 #endif
 162         mov     pc, lr
 163 ENDPROC(cpu_v7_set_pte_ext)
 164
 165 cpu_v7_name:
 166         .ascii  "ARMv7 Processor"
 167         .align
 168
 169         __CPUINIT
 170
 171 /*
 172  *      __v7_setup
 173  *
 174  *      Initialise TLB, Caches, and MMU state ready to switch the MMU
 175  *      on.  Return in r0 the new CP15 C1 control register setting.
 176  *
 177  *      We automatically detect if we have a Harvard cache, and use the
 178  *      Harvard cache control instructions insead of the unified cache
 179  *      control instructions.
 180  *
 181  *      This should be able to cover all ARMv7 cores.
 182  *
 183  *      It is assumed that:
 184  *      - cache type register is implemented
 185  */
 186 __v7_ca9mp_setup:
 187 #ifdef CONFIG_SMP
 188         ALT_SMP(mrc     p15, 0, r0, c1, c0, 1)
 189         ALT_UP(mov      r0, #(1 << 6))          @ fake it for UP
 190         tst     r0, #(1 << 6)                   @ SMP/nAMP mode enabled?
 191         orreq   r0, r0, #(1 << 6) | (1 << 0)    @ Enable SMP/nAMP mode and
 192         mcreq   p15, 0, r0, c1, c0, 1           @ TLB ops broadcasting
 193 #endif
 194 __v7_setup:
 195         adr     r12, __v7_setup_stack           @ the local stack
 196         stmia   r12, {r0-r5, r7, r9, r11, lr}
 197         bl      v7_flush_dcache_all
 198         ldmia   r12, {r0-r5, r7, r9, r11, lr}
 199
 200         mrc     p15, 0, r0, c0, c0, 0           @ read main ID register
 201         and     r10, r0, #0xff000000            @ ARM?
 202         teq     r10, #0x41000000
 203         bne     3f
 204         and     r5, r0, #0x00f00000             @ variant
 205         and     r6, r0, #0x0000000f             @ revision
 206         orr     r6, r6, r5, lsr #20-4           @ combine variant and revision
 207         ubfx    r0, r0, #4, #12                 @ primary part number
 208
 209         /* Cortex-A8 Errata */
 210         ldr     r10, =0x00000c08                @ Cortex-A8 primary part number
 211         teq     r0, r10
 212         bne     2f
 213 #ifdef CONFIG_ARM_ERRATA_430973
 214         teq     r5, #0x00100000                 @ only present in r1p*
 215         mrceq   p15, 0, r10, c1, c0, 1          @ read aux control register
 216         orreq   r10, r10, #(1 << 6)             @ set IBE to 1
 217         mcreq   p15, 0, r10, c1, c0, 1          @ write aux control register
 218 #endif
 219 #ifdef CONFIG_ARM_ERRATA_458693
 220         teq     r6, #0x20                       @ only present in r2p0
 221         mrceq   p15, 0, r10, c1, c0, 1          @ read aux control register
 222         orreq   r10, r10, #(1 << 5)             @ set L1NEON to 1
 223         orreq   r10, r10, #(1 << 9)             @ set PLDNOP to 1
 224         mcreq   p15, 0, r10, c1, c0, 1          @ write aux control register
 225 #endif
 226 #ifdef CONFIG_ARM_ERRATA_460075
 227         teq     r6, #0x20                       @ only present in r2p0
 228         mrceq   p15, 1, r10, c9, c0, 2          @ read L2 cache aux ctrl register
 229         tsteq   r10, #1 << 22
 230         orreq   r10, r10, #(1 << 22)            @ set the Write Allocate disable bit
 231         mcreq   p15, 1, r10, c9, c0, 2          @ write the L2 cache aux ctrl register
 232 #endif
 233         b       3f
 234
 235         /* Cortex-A9 Errata */
 236 2:      ldr     r10, =0x00000c09                @ Cortex-A9 primary part number
 237         teq     r0, r10
 238         bne     3f
 239 #ifdef CONFIG_ARM_ERRATA_742230
 240         cmp     r6, #0x22                       @ only present up to r2p2
 241         mrcle   p15, 0, r10, c15, c0, 1         @ read diagnostic register
 242         orrle   r10, r10, #1 << 4               @ set bit #4
 243         mcrle   p15, 0, r10, c15, c0, 1         @ write diagnostic register
 244 #endif
 245 #ifdef CONFIG_ARM_ERRATA_742231
 246         teq     r6, #0x20                       @ present in r2p0
 247         teqne   r6, #0x21                       @ present in r2p1
 248         teqne   r6, #0x22                       @ present in r2p2
 249         mrceq   p15, 0, r10, c15, c0, 1         @ read diagnostic register
 250         orreq   r10, r10, #1 << 12              @ set bit #12
 251         orreq   r10, r10, #1 << 22              @ set bit #22
 252         mcreq   p15, 0, r10, c15, c0, 1         @ write diagnostic register
 253 #endif
 254 #ifdef CONFIG_ARM_ERRATA_743622
 255         teq     r6, #0x20                       @ present in r2p0
 256         teqne   r6, #0x21                       @ present in r2p1
 257         teqne   r6, #0x22                       @ present in r2p2
 258         mrceq   p15, 0, r10, c15, c0, 1         @ read diagnostic register
 259         orreq   r10, r10, #1 << 6               @ set bit #6
 260         mcreq   p15, 0, r10, c15, c0, 1         @ write diagnostic register
 261 #endif
 262
 263 3:      mov     r10, #0
 264 #ifdef HARVARD_CACHE
 265         mcr     p15, 0, r10, c7, c5, 0          @ I+BTB cache invalidate
 266 #endif
 267         dsb
 268 #ifdef CONFIG_MMU
 269         mcr     p15, 0, r10, c8, c7, 0          @ invalidate I + D TLBs
 270         mcr     p15, 0, r10, c2, c0, 2          @ TTB control register
 271         ALT_SMP(orr     r4, r4, #TTB_FLAGS_SMP)
 272         ALT_UP(orr      r4, r4, #TTB_FLAGS_UP)
 273         mcr     p15, 0, r4, c2, c0, 1           @ load TTB1
 274         mov     r10, #0x1f                      @ domains 0, 1 = manager
 275         mcr     p15, 0, r10, c3, c0, 0          @ load domain access register
 276         /*
 277          * Memory region attributes with SCTLR.TRE=1
 278          *
 279          *   n = TEX[0],C,B
 280          *   TR = PRRR[2n+1:2n]         - memory type
 281          *   IR = NMRR[2n+1:2n]         - inner cacheable property
 282          *   OR = NMRR[2n+17:2n+16]     - outer cacheable property
 283          *
 284          *                      n       TR      IR      OR
 285          *   UNCACHED           000     00
 286          *   BUFFERABLE         001     10      00      00
 287          *   WRITETHROUGH       010     10      10      10
 288          *   WRITEBACK          011     10      11      11
 289          *   reserved           110
 290          *   WRITEALLOC         111     10      01      01
 291          *   DEV_SHARED         100     01
 292          *   DEV_NONSHARED      100     01
 293          *   DEV_WC             001     10
 294          *   DEV_CACHED         011     10
 295          *
 296          * Other attributes:
 297          *
 298          *   DS0 = PRRR[16] = 0         - device shareable property
 299          *   DS1 = PRRR[17] = 1         - device shareable property
 300          *   NS0 = PRRR[18] = 0         - normal shareable property
 301          *   NS1 = PRRR[19] = 1         - normal shareable property
 302          *   NOS = PRRR[24+n] = 1       - not outer shareable
 303          */
 304         ldr     r5, =0xff0a81a8                 @ PRRR
 305         ldr     r6, =0x40e040e0                 @ NMRR
 306         mcr     p15, 0, r5, c10, c2, 0          @ write PRRR
 307         mcr     p15, 0, r6, c10, c2, 1          @ write NMRR
 308 #endif
 309         adr     r5, v7_crval
 310         ldmia   r5, {r5, r6}
 311 #ifdef CONFIG_CPU_ENDIAN_BE8
 312         orr     r6, r6, #1 << 25                @ big-endian page tables
 313 #endif
 314         mrc     p15, 0, r0, c1, c0, 0           @ read control register
 315         bic     r0, r0, r5                      @ clear bits them
 316         orr     r0, r0, r6                      @ set them
 317  THUMB( orr     r0, r0, #1 << 30        )       @ Thumb exceptions
 318         mov     pc, lr                          @ return to head.S:__ret
 319 ENDPROC(__v7_setup)
 320
 321         /*   AT
 322          *  TFR   EV X F   I D LR    S
 323          * .EEE ..EE PUI. .T.T 4RVI ZWRS BLDP WCAM
 324          * rxxx rrxx xxx0 0101 xxxx xxxx x111 xxxx < forced
 325          *    1    0 110       0011 1100 .111 1101 < we want
 326          */
 327         .type   v7_crval, #object
 328 v7_crval:
 329         crval   clear=0x0120c302, mmuset=0x10c03c7d, ucset=0x00c01c7c
 330
 331 __v7_setup_stack:
 332         .space  4 * 11                          @ 11 registers
 333
 334         __INITDATA
 335
 336         .type   v7_processor_functions, #object
 337 ENTRY(v7_processor_functions)
 338         .word   v7_early_abort
 339         .word   v7_pabort
 340         .word   cpu_v7_proc_init
 341         .word   cpu_v7_proc_fin
 342         .word   cpu_v7_reset
 343         .word   cpu_v7_do_idle
 344         .word   cpu_v7_dcache_clean_area
 345         .word   cpu_v7_switch_mm
 346         .word   cpu_v7_set_pte_ext
 347         .size   v7_processor_functions, . - v7_processor_functions
 348
 349         .section ".rodata"
 350
 351         .type   cpu_arch_name, #object
 352 cpu_arch_name:
 353         .asciz  "armv7"
 354         .size   cpu_arch_name, . - cpu_arch_name
 355
 356         .type   cpu_elf_name, #object
 357 cpu_elf_name:
 358         .asciz  "v7"
 359         .size   cpu_elf_name, . - cpu_elf_name
 360         .align
 361
 362         .section ".proc.info.init", #alloc, #execinstr
 363
 364         .type   __v7_ca9mp_proc_info, #object
 365 __v7_ca9mp_proc_info:
 366         .long   0x410fc090              @ Required ID value
 367         .long   0xff0ffff0              @ Mask for ID
 368         ALT_SMP(.long \
 369                 PMD_TYPE_SECT | \
 370                 PMD_SECT_AP_WRITE | \
 371                 PMD_SECT_AP_READ | \
 372                 PMD_FLAGS_SMP)
 373         ALT_UP(.long \
 374                 PMD_TYPE_SECT | \
 375                 PMD_SECT_AP_WRITE | \
 376                 PMD_SECT_AP_READ | \
 377                 PMD_FLAGS_UP)
 378         .long   PMD_TYPE_SECT | \
 379                 PMD_SECT_XN | \
 380                 PMD_SECT_AP_WRITE | \
 381                 PMD_SECT_AP_READ
 382         b       __v7_ca9mp_setup
 383         .long   cpu_arch_name
 384         .long   cpu_elf_name
 385         .long   HWCAP_SWP|HWCAP_HALF|HWCAP_THUMB|HWCAP_FAST_MULT|HWCAP_EDSP|HWCAP_TLS
 386         .long   cpu_v7_name
 387         .long   v7_processor_functions
 388         .long   v7wbi_tlb_fns
 389         .long   v6_user_fns
 390         .long   v7_cache_fns
 391         .size   __v7_ca9mp_proc_info, . - __v7_ca9mp_proc_info
 392
 393         /*
 394          * Match any ARMv7 processor core.
 395          */
 396         .type   __v7_proc_info, #object
 397 __v7_proc_info:
 398         .long   0x000f0000              @ Required ID value
 399         .long   0x000f0000              @ Mask for ID
 400         ALT_SMP(.long \
 401                 PMD_TYPE_SECT | \
 402                 PMD_SECT_AP_WRITE | \
 403                 PMD_SECT_AP_READ | \
 404                 PMD_FLAGS_SMP)
 405         ALT_UP(.long \
 406                 PMD_TYPE_SECT | \
 407                 PMD_SECT_AP_WRITE | \
 408                 PMD_SECT_AP_READ | \
 409                 PMD_FLAGS_UP)
 410         .long   PMD_TYPE_SECT | \
 411                 PMD_SECT_XN | \
 412                 PMD_SECT_AP_WRITE | \
 413                 PMD_SECT_AP_READ
 414         b       __v7_setup
 415         .long   cpu_arch_name
 416         .long   cpu_elf_name
 417         .long   HWCAP_SWP|HWCAP_HALF|HWCAP_THUMB|HWCAP_FAST_MULT|HWCAP_EDSP|HWCAP_TLS
 418         .long   cpu_v7_name
 419         .long   v7_processor_functions
 420         .long   v7wbi_tlb_fns
 421         .long   v6_user_fns
 422         .long   v7_cache_fns
 423         .size   __v7_proc_info, . - __v7_proc_info