arch/arm/mach-shmobile/headsmp.S

   1 /*
   2  * SMP support for R-Mobile / SH-Mobile
   3  *
   4  * Copyright (C) 2010  Magnus Damm
   5  * Copyright (C) 2010  Takashi Yoshii
   6  *
   7  * Based on vexpress, Copyright (c) 2003 ARM Limited, All Rights Reserved
   8  *
   9  * This program is free software; you can redistribute it and/or modify
  10  * it under the terms of the GNU General Public License version 2 as
  11  * published by the Free Software Foundation.
  12  */
  13 #include <linux/init.h>
  14 #include <linux/linkage.h>
  15 #include <linux/threads.h>
  16 #include <asm/memory.h>
  17
  18 #ifdef CONFIG_SMP
  19 ENTRY(shmobile_invalidate_start)
  20         bl      v7_invalidate_l1
  21         b       secondary_startup
  22 ENDPROC(shmobile_invalidate_start)
  23 #endif
  24
  25 /*
  26  * Reset vector for secondary CPUs.
  27  * This will be mapped at address 0 by SBAR register.
  28  * We need _long_ jump to the physical address.
  29  */
  30         .arm
  31         .align  12
  32 ENTRY(shmobile_boot_vector)
  33         ldr     r0, 2f
  34         ldr     r1, 1f
  35         bx      r1
  36
  37 ENDPROC(shmobile_boot_vector)
  38
  39         .align  2
  40         .globl  shmobile_boot_fn
  41 shmobile_boot_fn:
  42 1:      .space  4
  43         .globl  shmobile_boot_arg
  44 shmobile_boot_arg:
  45 2:      .space  4
  46         .globl  shmobile_boot_size
  47 shmobile_boot_size:
  48         .long   . - shmobile_boot_vector
  49
  50 /*
  51  * Per-CPU SMP boot function/argument selection code based on MPIDR
  52  */
  53
  54 ENTRY(shmobile_smp_boot)
  55                                                 @ r0 = MPIDR_HWID_BITMASK
  56         mrc     p15, 0, r1, c0, c0, 5           @ r1 = MPIDR
  57         and     r0, r1, r0                      @ r0 = cpu_logical_map() value
  58         mov     r1, #0                          @ r1 = CPU index
  59         adr     r5, 1f                          @ array of per-cpu mpidr values
  60         adr     r6, 2f                          @ array of per-cpu functions
  61         adr     r7, 3f                          @ array of per-cpu arguments
  62
  63 shmobile_smp_boot_find_mpidr:
  64         ldr     r8, [r5, r1, lsl #2]
  65         cmp     r8, r0
  66         bne     shmobile_smp_boot_next
  67
  68         ldr     r9, [r6, r1, lsl #2]
  69         cmp     r9, #0
  70         bne     shmobile_smp_boot_found
  71
  72 shmobile_smp_boot_next:
  73         add     r1, r1, #1
  74         cmp     r1, #NR_CPUS
  75         blo     shmobile_smp_boot_find_mpidr
  76
  77         b       shmobile_smp_sleep
  78
  79 shmobile_smp_boot_found:
  80         ldr     r0, [r7, r1, lsl #2]
  81         mov     pc, r9
  82 ENDPROC(shmobile_smp_boot)
  83
  84 ENTRY(shmobile_smp_sleep)
  85         wfi
  86         b       shmobile_smp_boot
  87 ENDPROC(shmobile_smp_sleep)
  88
  89         .globl  shmobile_smp_mpidr
  90 shmobile_smp_mpidr:
  91 1:      .space  NR_CPUS * 4
  92         .globl  shmobile_smp_fn
  93 shmobile_smp_fn:
  94 2:      .space  NR_CPUS * 4
  95         .globl  shmobile_smp_arg
  96 shmobile_smp_arg:
  97 3:      .space  NR_CPUS * 4