arch/arm/lib/crt0.S

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  *  crt0 - C-runtime startup Code for ARM U-Boot
   4  *
   5  *  Copyright (c) 2012  Albert ARIBAUD <albert.u.boot@aribaud.net>
   6  */
   7
   8 #include <config.h>
   9 #include <asm-offsets.h>
  10 #include <linux/linkage.h>
  11 #include <asm/assembler.h>
  12 #include <system-constants.h>
  13
  14 /*
  15  * This file handles the target-independent stages of the U-Boot
  16  * start-up where a C runtime environment is needed. Its entry point
  17  * is _main and is branched into from the target's start.S file.
  18  *
  19  * _main execution sequence is:
  20  *
  21  * 1. Set up initial environment for calling board_init_f().
  22  *    This environment only provides a stack and a place to store
  23  *    the GD ('global data') structure, both located in some readily
  24  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
  25  *    global data, initialized or not (BSS), are UNAVAILABLE; only
  26  *    CONSTANT initialized data are available. GD should be zeroed
  27  *    before board_init_f() is called.
  28  *
  29  * 2. Call board_init_f(). This function prepares the hardware for
  30  *    execution from system RAM (DRAM, DDR...) As system RAM may not
  31  *    be available yet, , board_init_f() must use the current GD to
  32  *    store any data which must be passed on to later stages. These
  33  *    data include the relocation destination, the future stack, and
  34  *    the future GD location.
  35  *
  36  * 3. Set up intermediate environment where the stack and GD are the
  37  *    ones allocated by board_init_f() in system RAM, but BSS and
  38  *    initialized non-const data are still not available.
  39  *
  40  * 4a.For U-Boot proper (not SPL), call relocate_code(). This function
  41  *    relocates U-Boot from its current location into the relocation
  42  *    destination computed by board_init_f().
  43  *
  44  * 4b.For SPL, board_init_f() just returns (to crt0). There is no
  45  *    code relocation in SPL.
  46  *
  47  * 5. Set up final environment for calling board_init_r(). This
  48  *    environment has BSS (initialized to 0), initialized non-const
  49  *    data (initialized to their intended value), and stack in system
  50  *    RAM (for SPL moving the stack and GD into RAM is optional - see
  51  *    CONFIG_SPL_STACK_R). GD has retained values set by board_init_f().
  52  *
  53  * 6. For U-Boot proper (not SPL), some CPUs have some work left to do
  54  *    at this point regarding memory, so call c_runtime_cpu_setup.
  55  *
  56  * 7. Branch to board_init_r().
  57  *
  58  * For more information see 'Board Initialisation Flow in README.
  59  */
  60
  61 /*
  62  * Macro for clearing BSS during SPL execution. Usually called during the
  63  * relocation process for most boards before entering board_init_r(), but
  64  * can also be done early before entering board_init_f() on plaforms that
  65  * can afford it due to sufficient memory being available early.
  66  */
  67
  68 .macro CLEAR_BSS
  69         ldr     r0, =__bss_start        /* this is auto-relocated! */
  70
  71 #ifdef CONFIG_USE_ARCH_MEMSET
  72         ldr     r3, =__bss_end          /* this is auto-relocated! */
  73         mov     r1, #0x00000000         /* prepare zero to clear BSS */
  74
  75         subs    r2, r3, r0              /* r2 = memset len */
  76         bl      memset
  77 #else
  78         ldr     r1, =__bss_end          /* this is auto-relocated! */
  79         mov     r2, #0x00000000         /* prepare zero to clear BSS */
  80
  81 clbss_l:cmp     r0, r1                  /* while not at end of BSS */
  82         strlo   r2, [r0]                /* clear 32-bit BSS word */
  83         addlo   r0, r0, #4              /* move to next */
  84         blo     clbss_l
  85 #endif
  86 .endm
  87
  88 /*
  89  * entry point of crt0 sequence
  90  */
  91
  92 ENTRY(_main)
  93
  94 /* Call arch_very_early_init before initializing C runtime environment. */
  95 #if CONFIG_IS_ENABLED(ARCH_VERY_EARLY_INIT)
  96         bl      arch_very_early_init
  97 #endif
  98
  99 /*
 100  * Set up initial C runtime environment and call board_init_f(0).
 101  */
 102
 103 #if defined(CONFIG_TPL_BUILD) && defined(CONFIG_TPL_NEEDS_SEPARATE_STACK)
 104         ldr     r0, =(CONFIG_TPL_STACK)
 105 #elif defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
 106         ldr     r0, =(CONFIG_SPL_STACK)
 107 #else
 108         ldr     r0, =(SYS_INIT_SP_ADDR)
 109 #endif
 110         bic     r0, r0, #7      /* 8-byte alignment for ABI compliance */
 111         mov     sp, r0
 112         bl      board_init_f_alloc_reserve
 113         mov     sp, r0
 114         /* set up gd here, outside any C code */
 115         mov     r9, r0
 116         bl      board_init_f_init_reserve
 117
 118 #if defined(CONFIG_DEBUG_UART) && CONFIG_IS_ENABLED(SERIAL)
 119         bl      debug_uart_init
 120 #endif
 121
 122 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_EARLY_BSS)
 123         CLEAR_BSS
 124 #endif
 125
 126         mov     r0, #0
 127         bl      board_init_f
 128
 129 #if ! defined(CONFIG_SPL_BUILD)
 130
 131 /*
 132  * Set up intermediate environment (new sp and gd) and call
 133  * relocate_code(addr_moni). Trick here is that we'll return
 134  * 'here' but relocated.
 135  */
 136
 137         ldr     r0, [r9, #GD_START_ADDR_SP]     /* sp = gd->start_addr_sp */
 138         bic     r0, r0, #7      /* 8-byte alignment for ABI compliance */
 139         mov     sp, r0
 140         ldr     r9, [r9, #GD_NEW_GD]            /* r9 <- gd->new_gd */
 141
 142         adr     lr, here
 143 #if defined(CONFIG_POSITION_INDEPENDENT)
 144         adr     r0, _main
 145         ldr     r1, _start_ofs
 146         add     r0, r1
 147         ldr     r1, =CONFIG_SYS_TEXT_BASE
 148         sub     r1, r0
 149         add     lr, r1
 150 #endif
 151         ldr     r0, [r9, #GD_RELOC_OFF]         /* r0 = gd->reloc_off */
 152         add     lr, lr, r0
 153 #if defined(CONFIG_CPU_V7M)
 154         orr     lr, #1                          /* As required by Thumb-only */
 155 #endif
 156         ldr     r0, [r9, #GD_RELOCADDR]         /* r0 = gd->relocaddr */
 157         b       relocate_code
 158 here:
 159 /*
 160  * now relocate vectors
 161  */
 162
 163         bl      relocate_vectors
 164
 165 /* Set up final (full) environment */
 166
 167         bl      c_runtime_cpu_setup     /* we still call old routine here */
 168 #endif
 169 #if !defined(CONFIG_SPL_BUILD) || CONFIG_IS_ENABLED(FRAMEWORK)
 170
 171 #if !defined(CONFIG_SPL_BUILD) || !defined(CONFIG_SPL_EARLY_BSS)
 172         CLEAR_BSS
 173 #endif
 174
 175 # ifdef CONFIG_SPL_BUILD
 176         /* Use a DRAM stack for the rest of SPL, if requested */
 177         bl      spl_relocate_stack_gd
 178         cmp     r0, #0
 179         movne   sp, r0
 180         movne   r9, r0
 181 # endif
 182
 183 #if ! defined(CONFIG_SPL_BUILD)
 184         bl coloured_LED_init
 185         bl red_led_on
 186 #endif
 187         /* call board_init_r(gd_t *id, ulong dest_addr) */
 188         mov     r0, r9                  /* gd_t */
 189         ldr     r1, [r9, #GD_RELOCADDR] /* dest_addr */
 190         /* call board_init_r */
 191 #if CONFIG_IS_ENABLED(SYS_THUMB_BUILD)
 192         ldr     lr, =board_init_r       /* this is auto-relocated! */
 193         bx      lr
 194 #else
 195         ldr     pc, =board_init_r       /* this is auto-relocated! */
 196 #endif
 197         /* we should not return here. */
 198 #endif
 199
 200 ENDPROC(_main)
 201
 202 _start_ofs:
 203         .word   _start - _main