arch/arm/kernel/entry-common.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  *  linux/arch/arm/kernel/entry-common.S
   4  *
   5  *  Copyright (C) 2000 Russell King
   6  */
   7
   8 #include <asm/assembler.h>
   9 #include <asm/unistd.h>
  10 #include <asm/ftrace.h>
  11 #include <asm/unwind.h>
  12 #include <asm/memory.h>
  13 #ifdef CONFIG_AEABI
  14 #include <asm/unistd-oabi.h>
  15 #endif
  16
  17         .equ    NR_syscalls, __NR_syscalls
  18
  19 #ifdef CONFIG_NEED_RET_TO_USER
  20 #include <mach/entry-macro.S>
  21 #else
  22         .macro  arch_ret_to_user, tmp1, tmp2
  23         .endm
  24 #endif
  25
  26 #include "entry-header.S"
  27
  28 saved_psr       .req    r8
  29 #if defined(CONFIG_TRACE_IRQFLAGS) || defined(CONFIG_CONTEXT_TRACKING)
  30 saved_pc        .req    r9
  31 #define TRACE(x...) x
  32 #else
  33 saved_pc        .req    lr
  34 #define TRACE(x...)
  35 #endif
  36
  37         .section .entry.text,"ax",%progbits
  38         .align  5
  39 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING) || \
  40         IS_ENABLED(CONFIG_DEBUG_RSEQ))
  41 /*
  42  * This is the fast syscall return path.  We do as little as possible here,
  43  * such as avoiding writing r0 to the stack.  We only use this path if we
  44  * have tracing, context tracking and rseq debug disabled - the overheads
  45  * from those features make this path too inefficient.
  46  */
  47 ret_fast_syscall:
  48 __ret_fast_syscall:
  49  UNWIND(.fnstart        )
  50  UNWIND(.cantunwind     )
  51         disable_irq_notrace                     @ disable interrupts
  52         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  53         ldr     r1, =TASK_SIZE
  54         cmp     r2, r1
  55         blne    addr_limit_check_failed
  56         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  57         movs    r1, r1, lsl #16
  58         bne     fast_work_pending
  59
  60
  61         /* perform architecture specific actions before user return */
  62         arch_ret_to_user r1, lr
  63
  64         restore_user_regs fast = 1, offset = S_OFF
  65  UNWIND(.fnend          )
  66 ENDPROC(ret_fast_syscall)
  67
  68         /* Ok, we need to do extra processing, enter the slow path. */
  69 fast_work_pending:
  70         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  71         /* fall through to work_pending */
  72 #else
  73 /*
  74  * The "replacement" ret_fast_syscall for when tracing, context tracking,
  75  * or rseq debug is enabled.  As we will need to call out to some C functions,
  76  * we save r0 first to avoid needing to save registers around each C function
  77  * call.
  78  */
  79 ret_fast_syscall:
  80 __ret_fast_syscall:
  81  UNWIND(.fnstart        )
  82  UNWIND(.cantunwind     )
  83         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  84 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
  85         /* do_rseq_syscall needs interrupts enabled. */
  86         mov     r0, sp                          @ 'regs'
  87         bl      do_rseq_syscall
  88 #endif
  89         disable_irq_notrace                     @ disable interrupts
  90         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  91         ldr     r1, =TASK_SIZE
  92         cmp     r2, r1
  93         blne    addr_limit_check_failed
  94         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  95         movs    r1, r1, lsl #16
  96         beq     no_work_pending
  97  UNWIND(.fnend          )
  98 ENDPROC(ret_fast_syscall)
  99
 100         /* Slower path - fall through to work_pending */
 101 #endif
 102
 103         tst     r1, #_TIF_SYSCALL_WORK
 104         bne     __sys_trace_return_nosave
 105 slow_work_pending:
 106         mov     r0, sp                          @ 'regs'
 107         mov     r2, why                         @ 'syscall'
 108         bl      do_work_pending
 109         cmp     r0, #0
 110         beq     no_work_pending
 111         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
 112         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
 113         b       local_restart                   @ ... and off we go
 114 ENDPROC(ret_fast_syscall)
 115
 116 /*
 117  * "slow" syscall return path.  "why" tells us if this was a real syscall.
 118  * IRQs may be enabled here, so always disable them.  Note that we use the
 119  * "notrace" version to avoid calling into the tracing code unnecessarily.
 120  * do_work_pending() will update this state if necessary.
 121  */
 122 ENTRY(ret_to_user)
 123 ret_slow_syscall:
 124 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
 125         /* do_rseq_syscall needs interrupts enabled. */
 126         enable_irq_notrace                      @ enable interrupts
 127         mov     r0, sp                          @ 'regs'
 128         bl      do_rseq_syscall
 129 #endif
 130         disable_irq_notrace                     @ disable interrupts
 131 ENTRY(ret_to_user_from_irq)
 132         ldr     r2, [tsk, #TI_ADDR_LIMIT]
 133         ldr     r1, =TASK_SIZE
 134         cmp     r2, r1
 135         blne    addr_limit_check_failed
 136         ldr     r1, [tsk, #TI_FLAGS]
 137         movs    r1, r1, lsl #16
 138         bne     slow_work_pending
 139 no_work_pending:
 140         asm_trace_hardirqs_on save = 0
 141
 142         /* perform architecture specific actions before user return */
 143         arch_ret_to_user r1, lr
 144         ct_user_enter save = 0
 145
 146         restore_user_regs fast = 0, offset = 0
 147 ENDPROC(ret_to_user_from_irq)
 148 ENDPROC(ret_to_user)
 149
 150 /*
 151  * This is how we return from a fork.
 152  */
 153 ENTRY(ret_from_fork)
 154         bl      schedule_tail
 155         cmp     r5, #0
 156         movne   r0, r4
 157         badrne  lr, 1f
 158         retne   r5
 159 1:      get_thread_info tsk
 160         b       ret_slow_syscall
 161 ENDPROC(ret_from_fork)
 162
 163 /*=============================================================================
 164  * SWI handler
 165  *-----------------------------------------------------------------------------
 166  */
 167
 168         .align  5
 169 ENTRY(vector_swi)
 170 #ifdef CONFIG_CPU_V7M
 171         v7m_exception_entry
 172 #else
 173         sub     sp, sp, #PT_REGS_SIZE
 174         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 175  ARM(   add     r8, sp, #S_PC           )
 176  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 177  THUMB( mov     r8, sp                  )
 178  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 179         mrs     saved_psr, spsr                 @ called from non-FIQ mode, so ok.
 180  TRACE( mov     saved_pc, lr            )
 181         str     saved_pc, [sp, #S_PC]           @ Save calling PC
 182         str     saved_psr, [sp, #S_PSR]         @ Save CPSR
 183         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 184 #endif
 185         zero_fp
 186         alignment_trap r10, ip, __cr_alignment
 187         asm_trace_hardirqs_on save=0
 188         enable_irq_notrace
 189         ct_user_exit save=0
 190
 191         /*
 192          * Get the system call number.
 193          */
 194
 195 #if defined(CONFIG_OABI_COMPAT)
 196
 197         /*
 198          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 199          * value to determine if it is an EABI or an old ABI call.
 200          */
 201 #ifdef CONFIG_ARM_THUMB
 202         tst     saved_psr, #PSR_T_BIT
 203         movne   r10, #0                         @ no thumb OABI emulation
 204  USER(  ldreq   r10, [saved_pc, #-4]    )       @ get SWI instruction
 205 #else
 206  USER(  ldr     r10, [saved_pc, #-4]    )       @ get SWI instruction
 207 #endif
 208  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 209
 210 #elif defined(CONFIG_AEABI)
 211
 212         /*
 213          * Pure EABI user space always put syscall number into scno (r7).
 214          */
 215 #elif defined(CONFIG_ARM_THUMB)
 216         /* Legacy ABI only, possibly thumb mode. */
 217         tst     saved_psr, #PSR_T_BIT           @ this is SPSR from save_user_regs
 218         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 219  USER(  ldreq   scno, [saved_pc, #-4]   )
 220
 221 #else
 222         /* Legacy ABI only. */
 223  USER(  ldr     scno, [saved_pc, #-4]   )       @ get SWI instruction
 224 #endif
 225
 226         /* saved_psr and saved_pc are now dead */
 227
 228         uaccess_disable tbl
 229         get_thread_info tsk
 230
 231         adr     tbl, sys_call_table             @ load syscall table pointer
 232
 233 #if defined(CONFIG_OABI_COMPAT)
 234         /*
 235          * If the swi argument is zero, this is an EABI call and we do nothing.
 236          *
 237          * If this is an old ABI call, get the syscall number into scno and
 238          * get the old ABI syscall table address.
 239          */
 240         bics    r10, r10, #0xff000000
 241         strne   r10, [tsk, #TI_ABI_SYSCALL]
 242         streq   scno, [tsk, #TI_ABI_SYSCALL]
 243         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 244         ldrne   tbl, =sys_oabi_call_table
 245 #elif !defined(CONFIG_AEABI)
 246         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 247         str     scno, [tsk, #TI_ABI_SYSCALL]
 248         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 249 #else
 250         str     scno, [tsk, #TI_ABI_SYSCALL]
 251 #endif
 252         /*
 253          * Reload the registers that may have been corrupted on entry to
 254          * the syscall assembly (by tracing or context tracking.)
 255          */
 256  TRACE( ldmia   sp, {r0 - r3}           )
 257
 258 local_restart:
 259         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 260         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 261
 262         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 263         bne     __sys_trace
 264
 265         invoke_syscall tbl, scno, r10, __ret_fast_syscall
 266
 267         add     r1, sp, #S_OFF
 268 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 269         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 270         bcs     arm_syscall
 271         mov     why, #0                         @ no longer a real syscall
 272         b       sys_ni_syscall                  @ not private func
 273
 274 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 275         /*
 276          * We failed to handle a fault trying to access the page
 277          * containing the swi instruction, but we're not really in a
 278          * position to return -EFAULT. Instead, return back to the
 279          * instruction and re-enter the user fault handling path trying
 280          * to page it in. This will likely result in sending SEGV to the
 281          * current task.
 282          */
 283 9001:
 284         sub     lr, saved_pc, #4
 285         str     lr, [sp, #S_PC]
 286         get_thread_info tsk
 287         b       ret_fast_syscall
 288 #endif
 289 ENDPROC(vector_swi)
 290
 291         /*
 292          * This is the really slow path.  We're going to be doing
 293          * context switches, and waiting for our parent to respond.
 294          */
 295 __sys_trace:
 296         add     r0, sp, #S_OFF
 297         bl      syscall_trace_enter
 298         mov     scno, r0
 299         invoke_syscall tbl, scno, r10, __sys_trace_return, reload=1
 300         cmp     scno, #-1                       @ skip the syscall?
 301         bne     2b
 302         add     sp, sp, #S_OFF                  @ restore stack
 303
 304 __sys_trace_return_nosave:
 305         enable_irq_notrace
 306         mov     r0, sp
 307         bl      syscall_trace_exit
 308         b       ret_slow_syscall
 309
 310 __sys_trace_return:
 311         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 312         mov     r0, sp
 313         bl      syscall_trace_exit
 314         b       ret_slow_syscall
 315
 316         .align  5
 317 #ifdef CONFIG_ALIGNMENT_TRAP
 318         .type   __cr_alignment, #object
 319 __cr_alignment:
 320         .word   cr_alignment
 321 #endif
 322         .ltorg
 323
 324         .macro  syscall_table_start, sym
 325         .equ    __sys_nr, 0
 326         .type   \sym, #object
 327 ENTRY(\sym)
 328         .endm
 329
 330         .macro  syscall, nr, func
 331         .ifgt   __sys_nr - \nr
 332         .error  "Duplicated/unorded system call entry"
 333         .endif
 334         .rept   \nr - __sys_nr
 335         .long   sys_ni_syscall
 336         .endr
 337         .long   \func
 338         .equ    __sys_nr, \nr + 1
 339         .endm
 340
 341         .macro  syscall_table_end, sym
 342         .ifgt   __sys_nr - __NR_syscalls
 343         .error  "System call table too big"
 344         .endif
 345         .rept   __NR_syscalls - __sys_nr
 346         .long   sys_ni_syscall
 347         .endr
 348         .size   \sym, . - \sym
 349         .endm
 350
 351 #define __SYSCALL_WITH_COMPAT(nr, native, compat)       __SYSCALL(nr, native)
 352 #define __SYSCALL(nr, func) syscall nr, func
 353
 354 /*
 355  * This is the syscall table declaration for native ABI syscalls.
 356  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 357  */
 358         syscall_table_start sys_call_table
 359 #ifdef CONFIG_AEABI
 360 #include <calls-eabi.S>
 361 #else
 362 #include <calls-oabi.S>
 363 #endif
 364         syscall_table_end sys_call_table
 365
 366 /*============================================================================
 367  * Special system call wrappers
 368  */
 369 @ r0 = syscall number
 370 @ r8 = syscall table
 371 sys_syscall:
 372                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 373                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 374                 cmpne   scno, #NR_syscalls      @ check range
 375 #ifdef CONFIG_CPU_SPECTRE
 376                 movhs   scno, #0
 377                 csdb
 378 #endif
 379                 stmialo sp, {r5, r6}            @ shuffle args
 380                 movlo   r0, r1
 381                 movlo   r1, r2
 382                 movlo   r2, r3
 383                 movlo   r3, r4
 384                 ldrlo   pc, [tbl, scno, lsl #2]
 385                 b       sys_ni_syscall
 386 ENDPROC(sys_syscall)
 387
 388 sys_sigreturn_wrapper:
 389                 add     r0, sp, #S_OFF
 390                 mov     why, #0         @ prevent syscall restart handling
 391                 b       sys_sigreturn
 392 ENDPROC(sys_sigreturn_wrapper)
 393
 394 sys_rt_sigreturn_wrapper:
 395                 add     r0, sp, #S_OFF
 396                 mov     why, #0         @ prevent syscall restart handling
 397                 b       sys_rt_sigreturn
 398 ENDPROC(sys_rt_sigreturn_wrapper)
 399
 400 sys_statfs64_wrapper:
 401                 teq     r1, #88
 402                 moveq   r1, #84
 403                 b       sys_statfs64
 404 ENDPROC(sys_statfs64_wrapper)
 405
 406 sys_fstatfs64_wrapper:
 407                 teq     r1, #88
 408                 moveq   r1, #84
 409                 b       sys_fstatfs64
 410 ENDPROC(sys_fstatfs64_wrapper)
 411
 412 /*
 413  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 414  * offset, we return EINVAL.
 415  */
 416 sys_mmap2:
 417                 str     r5, [sp, #4]
 418                 b       sys_mmap_pgoff
 419 ENDPROC(sys_mmap2)
 420
 421 #ifdef CONFIG_OABI_COMPAT
 422
 423 /*
 424  * These are syscalls with argument register differences
 425  */
 426
 427 sys_oabi_pread64:
 428                 stmia   sp, {r3, r4}
 429                 b       sys_pread64
 430 ENDPROC(sys_oabi_pread64)
 431
 432 sys_oabi_pwrite64:
 433                 stmia   sp, {r3, r4}
 434                 b       sys_pwrite64
 435 ENDPROC(sys_oabi_pwrite64)
 436
 437 sys_oabi_truncate64:
 438                 mov     r3, r2
 439                 mov     r2, r1
 440                 b       sys_truncate64
 441 ENDPROC(sys_oabi_truncate64)
 442
 443 sys_oabi_ftruncate64:
 444                 mov     r3, r2
 445                 mov     r2, r1
 446                 b       sys_ftruncate64
 447 ENDPROC(sys_oabi_ftruncate64)
 448
 449 sys_oabi_readahead:
 450                 str     r3, [sp]
 451                 mov     r3, r2
 452                 mov     r2, r1
 453                 b       sys_readahead
 454 ENDPROC(sys_oabi_readahead)
 455
 456 /*
 457  * Let's declare a second syscall table for old ABI binaries
 458  * using the compatibility syscall entries.
 459  */
 460         syscall_table_start sys_oabi_call_table
 461 #undef __SYSCALL_WITH_COMPAT
 462 #define __SYSCALL_WITH_COMPAT(nr, native, compat)       __SYSCALL(nr, compat)
 463 #include <calls-oabi.S>
 464         syscall_table_end sys_oabi_call_table
 465
 466 #endif
 467