arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/unistd.h>
  12 #include <asm/ftrace.h>
  13 #include <asm/unwind.h>
  14
  15 #ifdef CONFIG_NEED_RET_TO_USER
  16 #include <mach/entry-macro.S>
  17 #else
  18         .macro  arch_ret_to_user, tmp1, tmp2
  19         .endm
  20 #endif
  21
  22 #include "entry-header.S"
  23
  24
  25         .align  5
  26 /*
  27  * This is the fast syscall return path.  We do as little as
  28  * possible here, and this includes saving r0 back into the SVC
  29  * stack.
  30  */
  31 ret_fast_syscall:
  32  UNWIND(.fnstart        )
  33  UNWIND(.cantunwind     )
  34         disable_irq                             @ disable interrupts
  35         ldr     r1, [tsk, #TI_FLAGS]
  36         tst     r1, #_TIF_WORK_MASK
  37         bne     fast_work_pending
  38 #if defined(CONFIG_IRQSOFF_TRACER)
  39         asm_trace_hardirqs_on
  40 #endif
  41
  42         /* perform architecture specific actions before user return */
  43         arch_ret_to_user r1, lr
  44         ct_user_enter
  45
  46         restore_user_regs fast = 1, offset = S_OFF
  47  UNWIND(.fnend          )
  48
  49 /*
  50  * Ok, we need to do extra processing, enter the slow path.
  51  */
  52 fast_work_pending:
  53         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  54 work_pending:
  55         mov     r0, sp                          @ 'regs'
  56         mov     r2, why                         @ 'syscall'
  57         bl      do_work_pending
  58         cmp     r0, #0
  59         beq     no_work_pending
  60         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
  61         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
  62         b       local_restart                   @ ... and off we go
  63
  64 /*
  65  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  66  */
  67 ENTRY(ret_to_user)
  68 ret_slow_syscall:
  69         disable_irq                             @ disable interrupts
  70 ENTRY(ret_to_user_from_irq)
  71         ldr     r1, [tsk, #TI_FLAGS]
  72         tst     r1, #_TIF_WORK_MASK
  73         bne     work_pending
  74 no_work_pending:
  75 #if defined(CONFIG_IRQSOFF_TRACER)
  76         asm_trace_hardirqs_on
  77 #endif
  78         /* perform architecture specific actions before user return */
  79         arch_ret_to_user r1, lr
  80         ct_user_enter save = 0
  81
  82         restore_user_regs fast = 0, offset = 0
  83 ENDPROC(ret_to_user_from_irq)
  84 ENDPROC(ret_to_user)
  85
  86 /*
  87  * This is how we return from a fork.
  88  */
  89 ENTRY(ret_from_fork)
  90         bl      schedule_tail
  91         cmp     r5, #0
  92         movne   r0, r4
  93         adrne   lr, BSYM(1f)
  94         movne   pc, r5
  95 1:      get_thread_info tsk
  96         b       ret_slow_syscall
  97 ENDPROC(ret_from_fork)
  98
  99         .equ NR_syscalls,0
 100 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
 101 #include "calls.S"
 102
 103 /*
 104  * Ensure that the system call table is equal to __NR_syscalls,
 105  * which is the value the rest of the system sees
 106  */
 107 .ifne NR_syscalls - __NR_syscalls
 108 .error "__NR_syscalls is not equal to the size of the syscall table"
 109 .endif
 110
 111 #undef CALL
 112 #define CALL(x) .long x
 113
 114 #ifdef CONFIG_FUNCTION_TRACER
 115 /*
 116  * When compiling with -pg, gcc inserts a call to the mcount routine at the
 117  * start of every function.  In mcount, apart from the function's address (in
 118  * lr), we need to get hold of the function's caller's address.
 119  *
 120  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
 121  *
 122  *      bl      mcount
 123  *
 124  * These versions have the limitation that in order for the mcount routine to
 125  * be able to determine the function's caller's address, an APCS-style frame
 126  * pointer (which is set up with something like the code below) is required.
 127  *
 128  *      mov     ip, sp
 129  *      push    {fp, ip, lr, pc}
 130  *      sub     fp, ip, #4
 131  *
 132  * With EABI, these frame pointers are not available unless -mapcs-frame is
 133  * specified, and if building as Thumb-2, not even then.
 134  *
 135  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
 136  * with call sites like:
 137  *
 138  *      push    {lr}
 139  *      bl      __gnu_mcount_nc
 140  *
 141  * With these compilers, frame pointers are not necessary.
 142  *
 143  * mcount can be thought of as a function called in the middle of a subroutine
 144  * call.  As such, it needs to be transparent for both the caller and the
 145  * callee: the original lr needs to be restored when leaving mcount, and no
 146  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
 147  * clobber the ip register.  This is OK because the ARM calling convention
 148  * allows it to be clobbered in subroutines and doesn't use it to hold
 149  * parameters.)
 150  *
 151  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
 152  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
 153  * arch/arm/kernel/ftrace.c).
 154  */
 155
 156 #ifndef CONFIG_OLD_MCOUNT
 157 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
 158 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
 159 #endif
 160 #endif
 161
 162 .macro mcount_adjust_addr rd, rn
 163         bic     \rd, \rn, #1            @ clear the Thumb bit if present
 164         sub     \rd, \rd, #MCOUNT_INSN_SIZE
 165 .endm
 166
 167 .macro __mcount suffix
 168         mcount_enter
 169         ldr     r0, =ftrace_trace_function
 170         ldr     r2, [r0]
 171         adr     r0, .Lftrace_stub
 172         cmp     r0, r2
 173         bne     1f
 174
 175 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 176         ldr     r1, =ftrace_graph_return
 177         ldr     r2, [r1]
 178         cmp     r0, r2
 179         bne     ftrace_graph_caller\suffix
 180
 181         ldr     r1, =ftrace_graph_entry
 182         ldr     r2, [r1]
 183         ldr     r0, =ftrace_graph_entry_stub
 184         cmp     r0, r2
 185         bne     ftrace_graph_caller\suffix
 186 #endif
 187
 188         mcount_exit
 189
 190 1:      mcount_get_lr   r1                      @ lr of instrumented func
 191         mcount_adjust_addr      r0, lr          @ instrumented function
 192         adr     lr, BSYM(2f)
 193         mov     pc, r2
 194 2:      mcount_exit
 195 .endm
 196
 197 .macro __ftrace_caller suffix
 198         mcount_enter
 199
 200         mcount_get_lr   r1                      @ lr of instrumented func
 201         mcount_adjust_addr      r0, lr          @ instrumented function
 202
 203         .globl ftrace_call\suffix
 204 ftrace_call\suffix:
 205         bl      ftrace_stub
 206
 207 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 208         .globl ftrace_graph_call\suffix
 209 ftrace_graph_call\suffix:
 210         mov     r0, r0
 211 #endif
 212
 213         mcount_exit
 214 .endm
 215
 216 .macro __ftrace_graph_caller
 217         sub     r0, fp, #4              @ &lr of instrumented routine (&parent)
 218 #ifdef CONFIG_DYNAMIC_FTRACE
 219         @ called from __ftrace_caller, saved in mcount_enter
 220         ldr     r1, [sp, #16]           @ instrumented routine (func)
 221         mcount_adjust_addr      r1, r1
 222 #else
 223         @ called from __mcount, untouched in lr
 224         mcount_adjust_addr      r1, lr  @ instrumented routine (func)
 225 #endif
 226         mov     r2, fp                  @ frame pointer
 227         bl      prepare_ftrace_return
 228         mcount_exit
 229 .endm
 230
 231 #ifdef CONFIG_OLD_MCOUNT
 232 /*
 233  * mcount
 234  */
 235
 236 .macro mcount_enter
 237         stmdb   sp!, {r0-r3, lr}
 238 .endm
 239
 240 .macro mcount_get_lr reg
 241         ldr     \reg, [fp, #-4]
 242 .endm
 243
 244 .macro mcount_exit
 245         ldr     lr, [fp, #-4]
 246         ldmia   sp!, {r0-r3, pc}
 247 .endm
 248
 249 ENTRY(mcount)
 250 #ifdef CONFIG_DYNAMIC_FTRACE
 251         stmdb   sp!, {lr}
 252         ldr     lr, [fp, #-4]
 253         ldmia   sp!, {pc}
 254 #else
 255         __mcount _old
 256 #endif
 257 ENDPROC(mcount)
 258
 259 #ifdef CONFIG_DYNAMIC_FTRACE
 260 ENTRY(ftrace_caller_old)
 261         __ftrace_caller _old
 262 ENDPROC(ftrace_caller_old)
 263 #endif
 264
 265 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 266 ENTRY(ftrace_graph_caller_old)
 267         __ftrace_graph_caller
 268 ENDPROC(ftrace_graph_caller_old)
 269 #endif
 270
 271 .purgem mcount_enter
 272 .purgem mcount_get_lr
 273 .purgem mcount_exit
 274 #endif
 275
 276 /*
 277  * __gnu_mcount_nc
 278  */
 279
 280 .macro mcount_enter
 281         stmdb   sp!, {r0-r3, lr}
 282 .endm
 283
 284 .macro mcount_get_lr reg
 285         ldr     \reg, [sp, #20]
 286 .endm
 287
 288 .macro mcount_exit
 289         ldmia   sp!, {r0-r3, ip, lr}
 290         mov     pc, ip
 291 .endm
 292
 293 ENTRY(__gnu_mcount_nc)
 294 #ifdef CONFIG_DYNAMIC_FTRACE
 295         mov     ip, lr
 296         ldmia   sp!, {lr}
 297         mov     pc, ip
 298 #else
 299         __mcount
 300 #endif
 301 ENDPROC(__gnu_mcount_nc)
 302
 303 #ifdef CONFIG_DYNAMIC_FTRACE
 304 ENTRY(ftrace_caller)
 305         __ftrace_caller
 306 ENDPROC(ftrace_caller)
 307 #endif
 308
 309 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 310 ENTRY(ftrace_graph_caller)
 311         __ftrace_graph_caller
 312 ENDPROC(ftrace_graph_caller)
 313 #endif
 314
 315 .purgem mcount_enter
 316 .purgem mcount_get_lr
 317 .purgem mcount_exit
 318
 319 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 320         .globl return_to_handler
 321 return_to_handler:
 322         stmdb   sp!, {r0-r3}
 323         mov     r0, fp                  @ frame pointer
 324         bl      ftrace_return_to_handler
 325         mov     lr, r0                  @ r0 has real ret addr
 326         ldmia   sp!, {r0-r3}
 327         mov     pc, lr
 328 #endif
 329
 330 ENTRY(ftrace_stub)
 331 .Lftrace_stub:
 332         mov     pc, lr
 333 ENDPROC(ftrace_stub)
 334
 335 #endif /* CONFIG_FUNCTION_TRACER */
 336
 337 /*=============================================================================
 338  * SWI handler
 339  *-----------------------------------------------------------------------------
 340  */
 341
 342         .align  5
 343 ENTRY(vector_swi)
 344         sub     sp, sp, #S_FRAME_SIZE
 345         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 346  ARM(   add     r8, sp, #S_PC           )
 347  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 348  THUMB( mov     r8, sp                  )
 349  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 350         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 351         str     lr, [sp, #S_PC]                 @ Save calling PC
 352         str     r8, [sp, #S_PSR]                @ Save CPSR
 353         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 354         zero_fp
 355
 356         /*
 357          * Get the system call number.
 358          */
 359
 360 #if defined(CONFIG_OABI_COMPAT)
 361
 362         /*
 363          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 364          * value to determine if it is an EABI or an old ABI call.
 365          */
 366 #ifdef CONFIG_ARM_THUMB
 367         tst     r8, #PSR_T_BIT
 368         movne   r10, #0                         @ no thumb OABI emulation
 369         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 370 #else
 371         ldr     r10, [lr, #-4]                  @ get SWI instruction
 372 #endif
 373 #ifdef CONFIG_CPU_ENDIAN_BE8
 374         rev     r10, r10                        @ little endian instruction
 375 #endif
 376
 377 #elif defined(CONFIG_AEABI)
 378
 379         /*
 380          * Pure EABI user space always put syscall number into scno (r7).
 381          */
 382 #elif defined(CONFIG_ARM_THUMB)
 383         /* Legacy ABI only, possibly thumb mode. */
 384         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 385         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 386         ldreq   scno, [lr, #-4]
 387
 388 #else
 389         /* Legacy ABI only. */
 390         ldr     scno, [lr, #-4]                 @ get SWI instruction
 391 #endif
 392
 393 #ifdef CONFIG_ALIGNMENT_TRAP
 394         ldr     ip, __cr_alignment
 395         ldr     ip, [ip]
 396         mcr     p15, 0, ip, c1, c0              @ update control register
 397 #endif
 398         enable_irq
 399         ct_user_exit
 400
 401         get_thread_info tsk
 402         adr     tbl, sys_call_table             @ load syscall table pointer
 403
 404 #if defined(CONFIG_OABI_COMPAT)
 405         /*
 406          * If the swi argument is zero, this is an EABI call and we do nothing.
 407          *
 408          * If this is an old ABI call, get the syscall number into scno and
 409          * get the old ABI syscall table address.
 410          */
 411         bics    r10, r10, #0xff000000
 412         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 413         ldrne   tbl, =sys_oabi_call_table
 414 #elif !defined(CONFIG_AEABI)
 415         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 416         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 417 #endif
 418
 419 local_restart:
 420         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 421         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 422
 423         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 424         bne     __sys_trace
 425
 426         cmp     scno, #NR_syscalls              @ check upper syscall limit
 427         adr     lr, BSYM(ret_fast_syscall)      @ return address
 428         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 429
 430         add     r1, sp, #S_OFF
 431 2:      mov     why, #0                         @ no longer a real syscall
 432         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 433         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 434         bcs     arm_syscall
 435         b       sys_ni_syscall                  @ not private func
 436 ENDPROC(vector_swi)
 437
 438         /*
 439          * This is the really slow path.  We're going to be doing
 440          * context switches, and waiting for our parent to respond.
 441          */
 442 __sys_trace:
 443         mov     r1, scno
 444         add     r0, sp, #S_OFF
 445         bl      syscall_trace_enter
 446
 447         adr     lr, BSYM(__sys_trace_return)    @ return address
 448         mov     scno, r0                        @ syscall number (possibly new)
 449         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 450         cmp     scno, #NR_syscalls              @ check upper syscall limit
 451         ldmccia r1, {r0 - r6}                   @ have to reload r0 - r6
 452         stmccia sp, {r4, r5}                    @ and update the stack args
 453         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 454         cmp     scno, #-1                       @ skip the syscall?
 455         bne     2b
 456         add     sp, sp, #S_OFF                  @ restore stack
 457         b       ret_slow_syscall
 458
 459 __sys_trace_return:
 460         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 461         mov     r0, sp
 462         bl      syscall_trace_exit
 463         b       ret_slow_syscall
 464
 465         .align  5
 466 #ifdef CONFIG_ALIGNMENT_TRAP
 467         .type   __cr_alignment, #object
 468 __cr_alignment:
 469         .word   cr_alignment
 470 #endif
 471         .ltorg
 472
 473 /*
 474  * This is the syscall table declaration for native ABI syscalls.
 475  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 476  */
 477 #define ABI(native, compat) native
 478 #ifdef CONFIG_AEABI
 479 #define OBSOLETE(syscall) sys_ni_syscall
 480 #else
 481 #define OBSOLETE(syscall) syscall
 482 #endif
 483
 484         .type   sys_call_table, #object
 485 ENTRY(sys_call_table)
 486 #include "calls.S"
 487 #undef ABI
 488 #undef OBSOLETE
 489
 490 /*============================================================================
 491  * Special system call wrappers
 492  */
 493 @ r0 = syscall number
 494 @ r8 = syscall table
 495 sys_syscall:
 496                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 497                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 498                 cmpne   scno, #NR_syscalls      @ check range
 499                 stmloia sp, {r5, r6}            @ shuffle args
 500                 movlo   r0, r1
 501                 movlo   r1, r2
 502                 movlo   r2, r3
 503                 movlo   r3, r4
 504                 ldrlo   pc, [tbl, scno, lsl #2]
 505                 b       sys_ni_syscall
 506 ENDPROC(sys_syscall)
 507
 508 sys_sigreturn_wrapper:
 509                 add     r0, sp, #S_OFF
 510                 mov     why, #0         @ prevent syscall restart handling
 511                 b       sys_sigreturn
 512 ENDPROC(sys_sigreturn_wrapper)
 513
 514 sys_rt_sigreturn_wrapper:
 515                 add     r0, sp, #S_OFF
 516                 mov     why, #0         @ prevent syscall restart handling
 517                 b       sys_rt_sigreturn
 518 ENDPROC(sys_rt_sigreturn_wrapper)
 519
 520 sys_statfs64_wrapper:
 521                 teq     r1, #88
 522                 moveq   r1, #84
 523                 b       sys_statfs64
 524 ENDPROC(sys_statfs64_wrapper)
 525
 526 sys_fstatfs64_wrapper:
 527                 teq     r1, #88
 528                 moveq   r1, #84
 529                 b       sys_fstatfs64
 530 ENDPROC(sys_fstatfs64_wrapper)
 531
 532 /*
 533  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 534  * offset, we return EINVAL.
 535  */
 536 sys_mmap2:
 537 #if PAGE_SHIFT > 12
 538                 tst     r5, #PGOFF_MASK
 539                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 540                 streq   r5, [sp, #4]
 541                 beq     sys_mmap_pgoff
 542                 mov     r0, #-EINVAL
 543                 mov     pc, lr
 544 #else
 545                 str     r5, [sp, #4]
 546                 b       sys_mmap_pgoff
 547 #endif
 548 ENDPROC(sys_mmap2)
 549
 550 #ifdef CONFIG_OABI_COMPAT
 551
 552 /*
 553  * These are syscalls with argument register differences
 554  */
 555
 556 sys_oabi_pread64:
 557                 stmia   sp, {r3, r4}
 558                 b       sys_pread64
 559 ENDPROC(sys_oabi_pread64)
 560
 561 sys_oabi_pwrite64:
 562                 stmia   sp, {r3, r4}
 563                 b       sys_pwrite64
 564 ENDPROC(sys_oabi_pwrite64)
 565
 566 sys_oabi_truncate64:
 567                 mov     r3, r2
 568                 mov     r2, r1
 569                 b       sys_truncate64
 570 ENDPROC(sys_oabi_truncate64)
 571
 572 sys_oabi_ftruncate64:
 573                 mov     r3, r2
 574                 mov     r2, r1
 575                 b       sys_ftruncate64
 576 ENDPROC(sys_oabi_ftruncate64)
 577
 578 sys_oabi_readahead:
 579                 str     r3, [sp]
 580                 mov     r3, r2
 581                 mov     r2, r1
 582                 b       sys_readahead
 583 ENDPROC(sys_oabi_readahead)
 584
 585 /*
 586  * Let's declare a second syscall table for old ABI binaries
 587  * using the compatibility syscall entries.
 588  */
 589 #define ABI(native, compat) compat
 590 #define OBSOLETE(syscall) syscall
 591
 592         .type   sys_oabi_call_table, #object
 593 ENTRY(sys_oabi_call_table)
 594 #include "calls.S"
 595 #undef ABI
 596 #undef OBSOLETE
 597
 598 #endif
 599