arch/arm/kernel/entry-armv.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  *  linux/arch/arm/kernel/entry-armv.S
   4  *
   5  *  Copyright (C) 1996,1997,1998 Russell King.
   6  *  ARM700 fix by Matthew Godbolt (linux-user@willothewisp.demon.co.uk)
   7  *  nommu support by Hyok S. Choi (hyok.choi@samsung.com)
   8  *
   9  *  Low-level vector interface routines
  10  *
  11  *  Note:  there is a StrongARM bug in the STMIA rn, {regs}^ instruction
  12  *  that causes it to save wrong values...  Be aware!
  13  */
  14
  15 #include <linux/init.h>
  16
  17 #include <asm/assembler.h>
  18 #include <asm/memory.h>
  19 #include <asm/glue-df.h>
  20 #include <asm/glue-pf.h>
  21 #include <asm/vfpmacros.h>
  22 #include <asm/thread_notify.h>
  23 #include <asm/unwind.h>
  24 #include <asm/unistd.h>
  25 #include <asm/tls.h>
  26 #include <asm/system_info.h>
  27 #include <asm/uaccess-asm.h>
  28
  29 #include "entry-header.S"
  30 #include <asm/probes.h>
  31
  32 /*
  33  * Interrupt handling.
  34  */
  35         .macro  irq_handler, from_user:req
  36         mov     r1, sp
  37         ldr_this_cpu r2, irq_stack_ptr, r2, r3
  38         .if     \from_user == 0
  39         @
  40         @ If we took the interrupt while running in the kernel, we may already
  41         @ be using the IRQ stack, so revert to the original value in that case.
  42         @
  43         subs    r3, r2, r1              @ SP above bottom of IRQ stack?
  44         rsbscs  r3, r3, #THREAD_SIZE    @ ... and below the top?
  45 #ifdef CONFIG_VMAP_STACK
  46         ldr_va  r3, high_memory, cc     @ End of the linear region
  47         cmpcc   r3, r1                  @ Stack pointer was below it?
  48 #endif
  49         bcc     0f                      @ If not, switch to the IRQ stack
  50         mov     r0, r1
  51         bl      generic_handle_arch_irq
  52         b       1f
  53 0:
  54         .endif
  55
  56         mov_l   r0, generic_handle_arch_irq
  57         bl      call_with_stack
  58 1:
  59         .endm
  60
  61         .macro  pabt_helper
  62         @ PABORT handler takes pt_regs in r2, fault address in r4 and psr in r5
  63 #ifdef MULTI_PABORT
  64         ldr_va  ip, processor, offset=PROCESSOR_PABT_FUNC
  65         bl_r    ip
  66 #else
  67         bl      CPU_PABORT_HANDLER
  68 #endif
  69         .endm
  70
  71         .macro  dabt_helper
  72
  73         @
  74         @ Call the processor-specific abort handler:
  75         @
  76         @  r2 - pt_regs
  77         @  r4 - aborted context pc
  78         @  r5 - aborted context psr
  79         @
  80         @ The abort handler must return the aborted address in r0, and
  81         @ the fault status register in r1.  r9 must be preserved.
  82         @
  83 #ifdef MULTI_DABORT
  84         ldr_va  ip, processor, offset=PROCESSOR_DABT_FUNC
  85         bl_r    ip
  86 #else
  87         bl      CPU_DABORT_HANDLER
  88 #endif
  89         .endm
  90
  91         .section        .entry.text,"ax",%progbits
  92
  93 /*
  94  * Invalid mode handlers
  95  */
  96         .macro  inv_entry, reason
  97         sub     sp, sp, #PT_REGS_SIZE
  98  ARM(   stmib   sp, {r1 - lr}           )
  99  THUMB( stmia   sp, {r0 - r12}          )
 100  THUMB( str     sp, [sp, #S_SP]         )
 101  THUMB( str     lr, [sp, #S_LR]         )
 102         mov     r1, #\reason
 103         .endm
 104
 105 __pabt_invalid:
 106         inv_entry BAD_PREFETCH
 107         b       common_invalid
 108 ENDPROC(__pabt_invalid)
 109
 110 __dabt_invalid:
 111         inv_entry BAD_DATA
 112         b       common_invalid
 113 ENDPROC(__dabt_invalid)
 114
 115 __irq_invalid:
 116         inv_entry BAD_IRQ
 117         b       common_invalid
 118 ENDPROC(__irq_invalid)
 119
 120 __und_invalid:
 121         inv_entry BAD_UNDEFINSTR
 122
 123         @
 124         @ XXX fall through to common_invalid
 125         @
 126
 127 @
 128 @ common_invalid - generic code for failed exception (re-entrant version of handlers)
 129 @
 130 common_invalid:
 131         zero_fp
 132
 133         ldmia   r0, {r4 - r6}
 134         add     r0, sp, #S_PC           @ here for interlock avoidance
 135         mov     r7, #-1                 @  ""   ""    ""        ""
 136         str     r4, [sp]                @ save preserved r0
 137         stmia   r0, {r5 - r7}           @ lr_<exception>,
 138                                         @ cpsr_<exception>, "old_r0"
 139
 140         mov     r0, sp
 141         b       bad_mode
 142 ENDPROC(__und_invalid)
 143
 144 /*
 145  * SVC mode handlers
 146  */
 147
 148 #if defined(CONFIG_AEABI) && (__LINUX_ARM_ARCH__ >= 5)
 149 #define SPFIX(code...) code
 150 #else
 151 #define SPFIX(code...)
 152 #endif
 153
 154         .macro  svc_entry, stack_hole=0, trace=1, uaccess=1, overflow_check=1
 155  UNWIND(.fnstart                )
 156         sub     sp, sp, #(SVC_REGS_SIZE + \stack_hole)
 157  THUMB( add     sp, r1          )       @ get SP in a GPR without
 158  THUMB( sub     r1, sp, r1      )       @ using a temp register
 159
 160         .if     \overflow_check
 161  UNWIND(.save   {r0 - pc}       )
 162         do_overflow_check (SVC_REGS_SIZE + \stack_hole)
 163         .endif
 164
 165 #ifdef CONFIG_THUMB2_KERNEL
 166         tst     r1, #4                  @ test stack pointer alignment
 167         sub     r1, sp, r1              @ restore original R1
 168         sub     sp, r1                  @ restore original SP
 169 #else
 170  SPFIX( tst     sp, #4          )
 171 #endif
 172  SPFIX( subne   sp, sp, #4      )
 173
 174  ARM(   stmib   sp, {r1 - r12}  )
 175  THUMB( stmia   sp, {r0 - r12}  )       @ No STMIB in Thumb-2
 176
 177         ldmia   r0, {r3 - r5}
 178         add     r7, sp, #S_SP           @ here for interlock avoidance
 179         mov     r6, #-1                 @  ""  ""      ""       ""
 180         add     r2, sp, #(SVC_REGS_SIZE + \stack_hole)
 181  SPFIX( addne   r2, r2, #4      )
 182         str     r3, [sp]                @ save the "real" r0 copied
 183                                         @ from the exception stack
 184
 185         mov     r3, lr
 186
 187         @
 188         @ We are now ready to fill in the remaining blanks on the stack:
 189         @
 190         @  r2 - sp_svc
 191         @  r3 - lr_svc
 192         @  r4 - lr_<exception>, already fixed up for correct return/restart
 193         @  r5 - spsr_<exception>
 194         @  r6 - orig_r0 (see pt_regs definition in ptrace.h)
 195         @
 196         stmia   r7, {r2 - r6}
 197
 198         get_thread_info tsk
 199         uaccess_entry tsk, r0, r1, r2, \uaccess
 200
 201         .if \trace
 202 #ifdef CONFIG_TRACE_IRQFLAGS
 203         bl      trace_hardirqs_off
 204 #endif
 205         .endif
 206         .endm
 207
 208         .align  5
 209 __dabt_svc:
 210         svc_entry uaccess=0
 211         mov     r2, sp
 212         dabt_helper
 213  THUMB( ldr     r5, [sp, #S_PSR]        )       @ potentially updated CPSR
 214         svc_exit r5                             @ return from exception
 215  UNWIND(.fnend          )
 216 ENDPROC(__dabt_svc)
 217
 218         .align  5
 219 __irq_svc:
 220         svc_entry
 221         irq_handler from_user=0
 222
 223 #ifdef CONFIG_PREEMPTION
 224         ldr     r8, [tsk, #TI_PREEMPT]          @ get preempt count
 225         ldr     r0, [tsk, #TI_FLAGS]            @ get flags
 226         teq     r8, #0                          @ if preempt count != 0
 227         movne   r0, #0                          @ force flags to 0
 228         tst     r0, #_TIF_NEED_RESCHED
 229         blne    svc_preempt
 230 #endif
 231
 232         svc_exit r5, irq = 1                    @ return from exception
 233  UNWIND(.fnend          )
 234 ENDPROC(__irq_svc)
 235
 236         .ltorg
 237
 238 #ifdef CONFIG_PREEMPTION
 239 svc_preempt:
 240         mov     r8, lr
 241 1:      bl      preempt_schedule_irq            @ irq en/disable is done inside
 242         ldr     r0, [tsk, #TI_FLAGS]            @ get new tasks TI_FLAGS
 243         tst     r0, #_TIF_NEED_RESCHED
 244         reteq   r8                              @ go again
 245         b       1b
 246 #endif
 247
 248 __und_fault:
 249         @ Correct the PC such that it is pointing at the instruction
 250         @ which caused the fault.  If the faulting instruction was ARM
 251         @ the PC will be pointing at the next instruction, and have to
 252         @ subtract 4.  Otherwise, it is Thumb, and the PC will be
 253         @ pointing at the second half of the Thumb instruction.  We
 254         @ have to subtract 2.
 255         ldr     r2, [r0, #S_PC]
 256         sub     r2, r2, r1
 257         str     r2, [r0, #S_PC]
 258         b       do_undefinstr
 259 ENDPROC(__und_fault)
 260
 261         .align  5
 262 __und_svc:
 263 #ifdef CONFIG_KPROBES
 264         @ If a kprobe is about to simulate a "stmdb sp..." instruction,
 265         @ it obviously needs free stack space which then will belong to
 266         @ the saved context.
 267         svc_entry MAX_STACK_SIZE
 268 #else
 269         svc_entry
 270 #endif
 271
 272         mov     r1, #4                          @ PC correction to apply
 273  THUMB( tst     r5, #PSR_T_BIT          )       @ exception taken in Thumb mode?
 274  THUMB( movne   r1, #2                  )       @ if so, fix up PC correction
 275         mov     r0, sp                          @ struct pt_regs *regs
 276         bl      __und_fault
 277
 278 __und_svc_finish:
 279         get_thread_info tsk
 280         ldr     r5, [sp, #S_PSR]                @ Get SVC cpsr
 281         svc_exit r5                             @ return from exception
 282  UNWIND(.fnend          )
 283 ENDPROC(__und_svc)
 284
 285         .align  5
 286 __pabt_svc:
 287         svc_entry
 288         mov     r2, sp                          @ regs
 289         pabt_helper
 290         svc_exit r5                             @ return from exception
 291  UNWIND(.fnend          )
 292 ENDPROC(__pabt_svc)
 293
 294         .align  5
 295 __fiq_svc:
 296         svc_entry trace=0
 297         mov     r0, sp                          @ struct pt_regs *regs
 298         bl      handle_fiq_as_nmi
 299         svc_exit_via_fiq
 300  UNWIND(.fnend          )
 301 ENDPROC(__fiq_svc)
 302
 303 /*
 304  * Abort mode handlers
 305  */
 306
 307 @
 308 @ Taking a FIQ in abort mode is similar to taking a FIQ in SVC mode
 309 @ and reuses the same macros. However in abort mode we must also
 310 @ save/restore lr_abt and spsr_abt to make nested aborts safe.
 311 @
 312         .align 5
 313 __fiq_abt:
 314         svc_entry trace=0
 315
 316  ARM(   msr     cpsr_c, #ABT_MODE | PSR_I_BIT | PSR_F_BIT )
 317  THUMB( mov     r0, #ABT_MODE | PSR_I_BIT | PSR_F_BIT )
 318  THUMB( msr     cpsr_c, r0 )
 319         mov     r1, lr          @ Save lr_abt
 320         mrs     r2, spsr        @ Save spsr_abt, abort is now safe
 321  ARM(   msr     cpsr_c, #SVC_MODE | PSR_I_BIT | PSR_F_BIT )
 322  THUMB( mov     r0, #SVC_MODE | PSR_I_BIT | PSR_F_BIT )
 323  THUMB( msr     cpsr_c, r0 )
 324         stmfd   sp!, {r1 - r2}
 325
 326         add     r0, sp, #8                      @ struct pt_regs *regs
 327         bl      handle_fiq_as_nmi
 328
 329         ldmfd   sp!, {r1 - r2}
 330  ARM(   msr     cpsr_c, #ABT_MODE | PSR_I_BIT | PSR_F_BIT )
 331  THUMB( mov     r0, #ABT_MODE | PSR_I_BIT | PSR_F_BIT )
 332  THUMB( msr     cpsr_c, r0 )
 333         mov     lr, r1          @ Restore lr_abt, abort is unsafe
 334         msr     spsr_cxsf, r2   @ Restore spsr_abt
 335  ARM(   msr     cpsr_c, #SVC_MODE | PSR_I_BIT | PSR_F_BIT )
 336  THUMB( mov     r0, #SVC_MODE | PSR_I_BIT | PSR_F_BIT )
 337  THUMB( msr     cpsr_c, r0 )
 338
 339         svc_exit_via_fiq
 340  UNWIND(.fnend          )
 341 ENDPROC(__fiq_abt)
 342
 343 /*
 344  * User mode handlers
 345  *
 346  * EABI note: sp_svc is always 64-bit aligned here, so should PT_REGS_SIZE
 347  */
 348
 349 #if defined(CONFIG_AEABI) && (__LINUX_ARM_ARCH__ >= 5) && (PT_REGS_SIZE & 7)
 350 #error "sizeof(struct pt_regs) must be a multiple of 8"
 351 #endif
 352
 353         .macro  usr_entry, trace=1, uaccess=1
 354  UNWIND(.fnstart        )
 355  UNWIND(.cantunwind     )       @ don't unwind the user space
 356         sub     sp, sp, #PT_REGS_SIZE
 357  ARM(   stmib   sp, {r1 - r12}  )
 358  THUMB( stmia   sp, {r0 - r12}  )
 359
 360  ATRAP( mrc     p15, 0, r7, c1, c0, 0)
 361  ATRAP( ldr_va  r8, cr_alignment)
 362
 363         ldmia   r0, {r3 - r5}
 364         add     r0, sp, #S_PC           @ here for interlock avoidance
 365         mov     r6, #-1                 @  ""  ""     ""        ""
 366
 367         str     r3, [sp]                @ save the "real" r0 copied
 368                                         @ from the exception stack
 369
 370         @
 371         @ We are now ready to fill in the remaining blanks on the stack:
 372         @
 373         @  r4 - lr_<exception>, already fixed up for correct return/restart
 374         @  r5 - spsr_<exception>
 375         @  r6 - orig_r0 (see pt_regs definition in ptrace.h)
 376         @
 377         @ Also, separately save sp_usr and lr_usr
 378         @
 379         stmia   r0, {r4 - r6}
 380  ARM(   stmdb   r0, {sp, lr}^                   )
 381  THUMB( store_user_sp_lr r0, r1, S_SP - S_PC    )
 382
 383         .if \uaccess
 384         uaccess_disable ip
 385         .endif
 386
 387         @ Enable the alignment trap while in kernel mode
 388  ATRAP( teq     r8, r7)
 389  ATRAP( mcrne   p15, 0, r8, c1, c0, 0)
 390
 391         reload_current r7, r8
 392
 393         @
 394         @ Clear FP to mark the first stack frame
 395         @
 396         zero_fp
 397
 398         .if     \trace
 399 #ifdef CONFIG_TRACE_IRQFLAGS
 400         bl      trace_hardirqs_off
 401 #endif
 402         ct_user_exit save = 0
 403         .endif
 404         .endm
 405
 406         .macro  kuser_cmpxchg_check
 407 #if !defined(CONFIG_CPU_32v6K) && defined(CONFIG_KUSER_HELPERS)
 408 #ifndef CONFIG_MMU
 409 #warning "NPTL on non MMU needs fixing"
 410 #else
 411         @ Make sure our user space atomic helper is restarted
 412         @ if it was interrupted in a critical region.  Here we
 413         @ perform a quick test inline since it should be false
 414         @ 99.9999% of the time.  The rest is done out of line.
 415         ldr     r0, =TASK_SIZE
 416         cmp     r4, r0
 417         blhs    kuser_cmpxchg64_fixup
 418 #endif
 419 #endif
 420         .endm
 421
 422         .align  5
 423 __dabt_usr:
 424         usr_entry uaccess=0
 425         kuser_cmpxchg_check
 426         mov     r2, sp
 427         dabt_helper
 428         b       ret_from_exception
 429  UNWIND(.fnend          )
 430 ENDPROC(__dabt_usr)
 431
 432         .align  5
 433 __irq_usr:
 434         usr_entry
 435         kuser_cmpxchg_check
 436         irq_handler from_user=1
 437         get_thread_info tsk
 438         mov     why, #0
 439         b       ret_to_user_from_irq
 440  UNWIND(.fnend          )
 441 ENDPROC(__irq_usr)
 442
 443         .ltorg
 444
 445         .align  5
 446 __und_usr:
 447         usr_entry uaccess=0
 448
 449         mov     r2, r4
 450         mov     r3, r5
 451
 452         @ r2 = regs->ARM_pc, which is either 2 or 4 bytes ahead of the
 453         @      faulting instruction depending on Thumb mode.
 454         @ r3 = regs->ARM_cpsr
 455         @
 456         @ The emulation code returns using r9 if it has emulated the
 457         @ instruction, or the more conventional lr if we are to treat
 458         @ this as a real undefined instruction
 459         @
 460         badr    r9, ret_from_exception
 461
 462         @ IRQs must be enabled before attempting to read the instruction from
 463         @ user space since that could cause a page/translation fault if the
 464         @ page table was modified by another CPU.
 465         enable_irq
 466
 467         tst     r3, #PSR_T_BIT                  @ Thumb mode?
 468         bne     __und_usr_thumb
 469         sub     r4, r2, #4                      @ ARM instr at LR - 4
 470 1:      ldrt    r0, [r4]
 471  ARM_BE8(rev    r0, r0)                         @ little endian instruction
 472
 473         uaccess_disable ip
 474
 475         @ r0 = 32-bit ARM instruction which caused the exception
 476         @ r2 = PC value for the following instruction (:= regs->ARM_pc)
 477         @ r4 = PC value for the faulting instruction
 478         @ lr = 32-bit undefined instruction function
 479         badr    lr, __und_usr_fault_32
 480         b       call_fpe
 481
 482 __und_usr_thumb:
 483         @ Thumb instruction
 484         sub     r4, r2, #2                      @ First half of thumb instr at LR - 2
 485 #if CONFIG_ARM_THUMB && __LINUX_ARM_ARCH__ >= 6 && CONFIG_CPU_V7
 486 /*
 487  * Thumb-2 instruction handling.  Note that because pre-v6 and >= v6 platforms
 488  * can never be supported in a single kernel, this code is not applicable at
 489  * all when __LINUX_ARM_ARCH__ < 6.  This allows simplifying assumptions to be
 490  * made about .arch directives.
 491  */
 492 #if __LINUX_ARM_ARCH__ < 7
 493 /* If the target CPU may not be Thumb-2-capable, a run-time check is needed: */
 494         ldr_va  r5, cpu_architecture
 495         cmp     r5, #CPU_ARCH_ARMv7
 496         blo     __und_usr_fault_16              @ 16bit undefined instruction
 497 /*
 498  * The following code won't get run unless the running CPU really is v7, so
 499  * coding round the lack of ldrht on older arches is pointless.  Temporarily
 500  * override the assembler target arch with the minimum required instead:
 501  */
 502         .arch   armv6t2
 503 #endif
 504 2:      ldrht   r5, [r4]
 505 ARM_BE8(rev16   r5, r5)                         @ little endian instruction
 506         cmp     r5, #0xe800                     @ 32bit instruction if xx != 0
 507         blo     __und_usr_fault_16_pan          @ 16bit undefined instruction
 508 3:      ldrht   r0, [r2]
 509 ARM_BE8(rev16   r0, r0)                         @ little endian instruction
 510         uaccess_disable ip
 511         add     r2, r2, #2                      @ r2 is PC + 2, make it PC + 4
 512         str     r2, [sp, #S_PC]                 @ it's a 2x16bit instr, update
 513         orr     r0, r0, r5, lsl #16
 514         badr    lr, __und_usr_fault_32
 515         @ r0 = the two 16-bit Thumb instructions which caused the exception
 516         @ r2 = PC value for the following Thumb instruction (:= regs->ARM_pc)
 517         @ r4 = PC value for the first 16-bit Thumb instruction
 518         @ lr = 32bit undefined instruction function
 519
 520 #if __LINUX_ARM_ARCH__ < 7
 521 /* If the target arch was overridden, change it back: */
 522 #ifdef CONFIG_CPU_32v6K
 523         .arch   armv6k
 524 #else
 525         .arch   armv6
 526 #endif
 527 #endif /* __LINUX_ARM_ARCH__ < 7 */
 528 #else /* !(CONFIG_ARM_THUMB && __LINUX_ARM_ARCH__ >= 6 && CONFIG_CPU_V7) */
 529         b       __und_usr_fault_16
 530 #endif
 531  UNWIND(.fnend)
 532 ENDPROC(__und_usr)
 533
 534 /*
 535  * The out of line fixup for the ldrt instructions above.
 536  */
 537         .pushsection .text.fixup, "ax"
 538         .align  2
 539 4:      str     r4, [sp, #S_PC]                 @ retry current instruction
 540         ret     r9
 541         .popsection
 542         .pushsection __ex_table,"a"
 543         .long   1b, 4b
 544 #if CONFIG_ARM_THUMB && __LINUX_ARM_ARCH__ >= 6 && CONFIG_CPU_V7
 545         .long   2b, 4b
 546         .long   3b, 4b
 547 #endif
 548         .popsection
 549
 550 /*
 551  * Check whether the instruction is a co-processor instruction.
 552  * If yes, we need to call the relevant co-processor handler.
 553  *
 554  * Note that we don't do a full check here for the co-processor
 555  * instructions; all instructions with bit 27 set are well
 556  * defined.  The only instructions that should fault are the
 557  * co-processor instructions.  However, we have to watch out
 558  * for the ARM6/ARM7 SWI bug.
 559  *
 560  * NEON is a special case that has to be handled here. Not all
 561  * NEON instructions are co-processor instructions, so we have
 562  * to make a special case of checking for them. Plus, there's
 563  * five groups of them, so we have a table of mask/opcode pairs
 564  * to check against, and if any match then we branch off into the
 565  * NEON handler code.
 566  *
 567  * Emulators may wish to make use of the following registers:
 568  *  r0  = instruction opcode (32-bit ARM or two 16-bit Thumb)
 569  *  r2  = PC value to resume execution after successful emulation
 570  *  r9  = normal "successful" return address
 571  *  r10 = this threads thread_info structure
 572  *  lr  = unrecognised instruction return address
 573  * IRQs enabled, FIQs enabled.
 574  */
 575         @
 576         @ Fall-through from Thumb-2 __und_usr
 577         @
 578 #ifdef CONFIG_NEON
 579         get_thread_info r10                     @ get current thread
 580         adr     r6, .LCneon_thumb_opcodes
 581         b       2f
 582 #endif
 583 call_fpe:
 584         get_thread_info r10                     @ get current thread
 585 #ifdef CONFIG_NEON
 586         adr     r6, .LCneon_arm_opcodes
 587 2:      ldr     r5, [r6], #4                    @ mask value
 588         ldr     r7, [r6], #4                    @ opcode bits matching in mask
 589         cmp     r5, #0                          @ end mask?
 590         beq     1f
 591         and     r8, r0, r5
 592         cmp     r8, r7                          @ NEON instruction?
 593         bne     2b
 594         b       do_vfp                          @ let VFP handler handle this
 595 1:
 596 #endif
 597         tst     r0, #0x08000000                 @ only CDP/CPRT/LDC/STC have bit 27
 598         tstne   r0, #0x04000000                 @ bit 26 set on both ARM and Thumb-2
 599         reteq   lr
 600         and     r8, r0, #0x00000f00             @ mask out CP number
 601 #ifdef CONFIG_IWMMXT
 602         @ Test if we need to give access to iWMMXt coprocessors
 603         ldr     r5, [r10, #TI_FLAGS]
 604         rsbs    r7, r8, #(1 << 8)               @ CP 0 or 1 only
 605         movscs  r7, r5, lsr #(TIF_USING_IWMMXT + 1)
 606         bcs     iwmmxt_task_enable
 607 #endif
 608  ARM(   add     pc, pc, r8, lsr #6      )
 609  THUMB( lsr     r8, r8, #6              )
 610  THUMB( add     pc, r8                  )
 611         nop
 612
 613         ret.w   lr                              @ CP#0
 614         W(b)    do_fpe                          @ CP#1 (FPE)
 615         W(b)    do_fpe                          @ CP#2 (FPE)
 616         ret.w   lr                              @ CP#3
 617         ret.w   lr                              @ CP#4
 618         ret.w   lr                              @ CP#5
 619         ret.w   lr                              @ CP#6
 620         ret.w   lr                              @ CP#7
 621         ret.w   lr                              @ CP#8
 622         ret.w   lr                              @ CP#9
 623 #ifdef CONFIG_VFP
 624         W(b)    do_vfp                          @ CP#10 (VFP)
 625         W(b)    do_vfp                          @ CP#11 (VFP)
 626 #else
 627         ret.w   lr                              @ CP#10 (VFP)
 628         ret.w   lr                              @ CP#11 (VFP)
 629 #endif
 630         ret.w   lr                              @ CP#12
 631         ret.w   lr                              @ CP#13
 632         ret.w   lr                              @ CP#14 (Debug)
 633         ret.w   lr                              @ CP#15 (Control)
 634
 635 #ifdef CONFIG_NEON
 636         .align  6
 637
 638 .LCneon_arm_opcodes:
 639         .word   0xfe000000                      @ mask
 640         .word   0xf2000000                      @ opcode
 641
 642         .word   0xff100000                      @ mask
 643         .word   0xf4000000                      @ opcode
 644
 645         .word   0x00000000                      @ mask
 646         .word   0x00000000                      @ opcode
 647
 648 .LCneon_thumb_opcodes:
 649         .word   0xef000000                      @ mask
 650         .word   0xef000000                      @ opcode
 651
 652         .word   0xff100000                      @ mask
 653         .word   0xf9000000                      @ opcode
 654
 655         .word   0x00000000                      @ mask
 656         .word   0x00000000                      @ opcode
 657 #endif
 658
 659 do_fpe:
 660         add     r10, r10, #TI_FPSTATE           @ r10 = workspace
 661         ldr_va  pc, fp_enter, tmp=r4            @ Call FP module USR entry point
 662
 663 /*
 664  * The FP module is called with these registers set:
 665  *  r0  = instruction
 666  *  r2  = PC+4
 667  *  r9  = normal "successful" return address
 668  *  r10 = FP workspace
 669  *  lr  = unrecognised FP instruction return address
 670  */
 671
 672         .pushsection .data
 673         .align  2
 674 ENTRY(fp_enter)
 675         .word   no_fp
 676         .popsection
 677
 678 ENTRY(no_fp)
 679         ret     lr
 680 ENDPROC(no_fp)
 681
 682 __und_usr_fault_32:
 683         mov     r1, #4
 684         b       1f
 685 __und_usr_fault_16_pan:
 686         uaccess_disable ip
 687 __und_usr_fault_16:
 688         mov     r1, #2
 689 1:      mov     r0, sp
 690         badr    lr, ret_from_exception
 691         b       __und_fault
 692 ENDPROC(__und_usr_fault_32)
 693 ENDPROC(__und_usr_fault_16)
 694
 695         .align  5
 696 __pabt_usr:
 697         usr_entry
 698         mov     r2, sp                          @ regs
 699         pabt_helper
 700  UNWIND(.fnend          )
 701         /* fall through */
 702 /*
 703  * This is the return code to user mode for abort handlers
 704  */
 705 ENTRY(ret_from_exception)
 706  UNWIND(.fnstart        )
 707  UNWIND(.cantunwind     )
 708         get_thread_info tsk
 709         mov     why, #0
 710         b       ret_to_user
 711  UNWIND(.fnend          )
 712 ENDPROC(__pabt_usr)
 713 ENDPROC(ret_from_exception)
 714
 715         .align  5
 716 __fiq_usr:
 717         usr_entry trace=0
 718         kuser_cmpxchg_check
 719         mov     r0, sp                          @ struct pt_regs *regs
 720         bl      handle_fiq_as_nmi
 721         get_thread_info tsk
 722         restore_user_regs fast = 0, offset = 0
 723  UNWIND(.fnend          )
 724 ENDPROC(__fiq_usr)
 725
 726 /*
 727  * Register switch for ARMv3 and ARMv4 processors
 728  * r0 = previous task_struct, r1 = previous thread_info, r2 = next thread_info
 729  * previous and next are guaranteed not to be the same.
 730  */
 731 ENTRY(__switch_to)
 732  UNWIND(.fnstart        )
 733  UNWIND(.cantunwind     )
 734         add     ip, r1, #TI_CPU_SAVE
 735  ARM(   stmia   ip!, {r4 - sl, fp, sp, lr} )    @ Store most regs on stack
 736  THUMB( stmia   ip!, {r4 - sl, fp}         )    @ Store most regs on stack
 737  THUMB( str     sp, [ip], #4               )
 738  THUMB( str     lr, [ip], #4               )
 739         ldr     r4, [r2, #TI_TP_VALUE]
 740         ldr     r5, [r2, #TI_TP_VALUE + 4]
 741 #ifdef CONFIG_CPU_USE_DOMAINS
 742         mrc     p15, 0, r6, c3, c0, 0           @ Get domain register
 743         str     r6, [r1, #TI_CPU_DOMAIN]        @ Save old domain register
 744         ldr     r6, [r2, #TI_CPU_DOMAIN]
 745 #endif
 746         switch_tls r1, r4, r5, r3, r7
 747 #if defined(CONFIG_STACKPROTECTOR) && !defined(CONFIG_SMP) && \
 748     !defined(CONFIG_STACKPROTECTOR_PER_TASK)
 749         ldr     r8, =__stack_chk_guard
 750         .if (TSK_STACK_CANARY > IMM12_MASK)
 751         add     r9, r2, #TSK_STACK_CANARY & ~IMM12_MASK
 752         ldr     r9, [r9, #TSK_STACK_CANARY & IMM12_MASK]
 753         .else
 754         ldr     r9, [r2, #TSK_STACK_CANARY & IMM12_MASK]
 755         .endif
 756 #endif
 757         mov     r7, r2                          @ Preserve 'next'
 758 #ifdef CONFIG_CPU_USE_DOMAINS
 759         mcr     p15, 0, r6, c3, c0, 0           @ Set domain register
 760 #endif
 761         mov     r5, r0
 762         add     r4, r2, #TI_CPU_SAVE
 763         ldr     r0, =thread_notify_head
 764         mov     r1, #THREAD_NOTIFY_SWITCH
 765         bl      atomic_notifier_call_chain
 766 #if defined(CONFIG_STACKPROTECTOR) && !defined(CONFIG_SMP) && \
 767     !defined(CONFIG_STACKPROTECTOR_PER_TASK)
 768         str     r9, [r8]
 769 #endif
 770         mov     r0, r5
 771 #if !defined(CONFIG_THUMB2_KERNEL) && !defined(CONFIG_VMAP_STACK)
 772         set_current r7, r8
 773         ldmia   r4, {r4 - sl, fp, sp, pc}       @ Load all regs saved previously
 774 #else
 775         mov     r1, r7
 776         ldmia   r4, {r4 - sl, fp, ip, lr}       @ Load all regs saved previously
 777 #ifdef CONFIG_VMAP_STACK
 778         @
 779         @ Do a dummy read from the new stack while running from the old one so
 780         @ that we can rely on do_translation_fault() to fix up any stale PMD
 781         @ entries covering the vmalloc region.
 782         @
 783         ldr     r2, [ip]
 784 #endif
 785
 786         @ When CONFIG_THREAD_INFO_IN_TASK=n, the update of SP itself is what
 787         @ effectuates the task switch, as that is what causes the observable
 788         @ values of current and current_thread_info to change. When
 789         @ CONFIG_THREAD_INFO_IN_TASK=y, setting current (and therefore
 790         @ current_thread_info) is done explicitly, and the update of SP just
 791         @ switches us to another stack, with few other side effects. In order
 792         @ to prevent this distinction from causing any inconsistencies, let's
 793         @ keep the 'set_current' call as close as we can to the update of SP.
 794         set_current r1, r2
 795         mov     sp, ip
 796         ret     lr
 797 #endif
 798  UNWIND(.fnend          )
 799 ENDPROC(__switch_to)
 800
 801 #ifdef CONFIG_VMAP_STACK
 802         .text
 803         .align  2
 804 __bad_stack:
 805         @
 806         @ We've just detected an overflow. We need to load the address of this
 807         @ CPU's overflow stack into the stack pointer register. We have only one
 808         @ scratch register so let's use a sequence of ADDs including one
 809         @ involving the PC, and decorate them with PC-relative group
 810         @ relocations. As these are ARM only, switch to ARM mode first.
 811         @
 812         @ We enter here with IP clobbered and its value stashed on the mode
 813         @ stack.
 814         @
 815 THUMB(  bx      pc              )
 816 THUMB(  nop                     )
 817 THUMB(  .arm                    )
 818         ldr_this_cpu_armv6 ip, overflow_stack_ptr
 819
 820         str     sp, [ip, #-4]!                  @ Preserve original SP value
 821         mov     sp, ip                          @ Switch to overflow stack
 822         pop     {ip}                            @ Original SP in IP
 823
 824 #if defined(CONFIG_UNWINDER_FRAME_POINTER) && defined(CONFIG_CC_IS_GCC)
 825         mov     ip, ip                          @ mov expected by unwinder
 826         push    {fp, ip, lr, pc}                @ GCC flavor frame record
 827 #else
 828         str     ip, [sp, #-8]!                  @ store original SP
 829         push    {fpreg, lr}                     @ Clang flavor frame record
 830 #endif
 831 UNWIND( ldr     ip, [r0, #4]    )               @ load exception LR
 832 UNWIND( str     ip, [sp, #12]   )               @ store in the frame record
 833         ldr     ip, [r0, #12]                   @ reload IP
 834
 835         @ Store the original GPRs to the new stack.
 836         svc_entry uaccess=0, overflow_check=0
 837
 838 UNWIND( .save   {sp, pc}        )
 839 UNWIND( .save   {fpreg, lr}     )
 840 UNWIND( .setfp  fpreg, sp       )
 841
 842         ldr     fpreg, [sp, #S_SP]              @ Add our frame record
 843                                                 @ to the linked list
 844 #if defined(CONFIG_UNWINDER_FRAME_POINTER) && defined(CONFIG_CC_IS_GCC)
 845         ldr     r1, [fp, #4]                    @ reload SP at entry
 846         add     fp, fp, #12
 847 #else
 848         ldr     r1, [fpreg, #8]
 849 #endif
 850         str     r1, [sp, #S_SP]                 @ store in pt_regs
 851
 852         @ Stash the regs for handle_bad_stack
 853         mov     r0, sp
 854
 855         @ Time to die
 856         bl      handle_bad_stack
 857         nop
 858 UNWIND( .fnend                  )
 859 ENDPROC(__bad_stack)
 860 #endif
 861
 862         __INIT
 863
 864 /*
 865  * User helpers.
 866  *
 867  * Each segment is 32-byte aligned and will be moved to the top of the high
 868  * vector page.  New segments (if ever needed) must be added in front of
 869  * existing ones.  This mechanism should be used only for things that are
 870  * really small and justified, and not be abused freely.
 871  *
 872  * See Documentation/arm/kernel_user_helpers.rst for formal definitions.
 873  */
 874  THUMB( .arm    )
 875
 876         .macro  usr_ret, reg
 877 #ifdef CONFIG_ARM_THUMB
 878         bx      \reg
 879 #else
 880         ret     \reg
 881 #endif
 882         .endm
 883
 884         .macro  kuser_pad, sym, size
 885         .if     (. - \sym) & 3
 886         .rept   4 - (. - \sym) & 3
 887         .byte   0
 888         .endr
 889         .endif
 890         .rept   (\size - (. - \sym)) / 4
 891         .word   0xe7fddef1
 892         .endr
 893         .endm
 894
 895 #ifdef CONFIG_KUSER_HELPERS
 896         .align  5
 897         .globl  __kuser_helper_start
 898 __kuser_helper_start:
 899
 900 /*
 901  * Due to the length of some sequences, __kuser_cmpxchg64 spans 2 regular
 902  * kuser "slots", therefore 0xffff0f80 is not used as a valid entry point.
 903  */
 904
 905 __kuser_cmpxchg64:                              @ 0xffff0f60
 906
 907 #if defined(CONFIG_CPU_32v6K)
 908
 909         stmfd   sp!, {r4, r5, r6, r7}
 910         ldrd    r4, r5, [r0]                    @ load old val
 911         ldrd    r6, r7, [r1]                    @ load new val
 912         smp_dmb arm
 913 1:      ldrexd  r0, r1, [r2]                    @ load current val
 914         eors    r3, r0, r4                      @ compare with oldval (1)
 915         eorseq  r3, r1, r5                      @ compare with oldval (2)
 916         strexdeq r3, r6, r7, [r2]               @ store newval if eq
 917         teqeq   r3, #1                          @ success?
 918         beq     1b                              @ if no then retry
 919         smp_dmb arm
 920         rsbs    r0, r3, #0                      @ set returned val and C flag
 921         ldmfd   sp!, {r4, r5, r6, r7}
 922         usr_ret lr
 923
 924 #elif !defined(CONFIG_SMP)
 925
 926 #ifdef CONFIG_MMU
 927
 928         /*
 929          * The only thing that can break atomicity in this cmpxchg64
 930          * implementation is either an IRQ or a data abort exception
 931          * causing another process/thread to be scheduled in the middle of
 932          * the critical sequence.  The same strategy as for cmpxchg is used.
 933          */
 934         stmfd   sp!, {r4, r5, r6, lr}
 935         ldmia   r0, {r4, r5}                    @ load old val
 936         ldmia   r1, {r6, lr}                    @ load new val
 937 1:      ldmia   r2, {r0, r1}                    @ load current val
 938         eors    r3, r0, r4                      @ compare with oldval (1)
 939         eorseq  r3, r1, r5                      @ compare with oldval (2)
 940 2:      stmiaeq r2, {r6, lr}                    @ store newval if eq
 941         rsbs    r0, r3, #0                      @ set return val and C flag
 942         ldmfd   sp!, {r4, r5, r6, pc}
 943
 944         .text
 945 kuser_cmpxchg64_fixup:
 946         @ Called from kuser_cmpxchg_fixup.
 947         @ r4 = address of interrupted insn (must be preserved).
 948         @ sp = saved regs. r7 and r8 are clobbered.
 949         @ 1b = first critical insn, 2b = last critical insn.
 950         @ If r4 >= 1b and r4 <= 2b then saved pc_usr is set to 1b.
 951         mov     r7, #0xffff0fff
 952         sub     r7, r7, #(0xffff0fff - (0xffff0f60 + (1b - __kuser_cmpxchg64)))
 953         subs    r8, r4, r7
 954         rsbscs  r8, r8, #(2b - 1b)
 955         strcs   r7, [sp, #S_PC]
 956 #if __LINUX_ARM_ARCH__ < 6
 957         bcc     kuser_cmpxchg32_fixup
 958 #endif
 959         ret     lr
 960         .previous
 961
 962 #else
 963 #warning "NPTL on non MMU needs fixing"
 964         mov     r0, #-1
 965         adds    r0, r0, #0
 966         usr_ret lr
 967 #endif
 968
 969 #else
 970 #error "incoherent kernel configuration"
 971 #endif
 972
 973         kuser_pad __kuser_cmpxchg64, 64
 974
 975 __kuser_memory_barrier:                         @ 0xffff0fa0
 976         smp_dmb arm
 977         usr_ret lr
 978
 979         kuser_pad __kuser_memory_barrier, 32
 980
 981 __kuser_cmpxchg:                                @ 0xffff0fc0
 982
 983 #if __LINUX_ARM_ARCH__ < 6
 984
 985 #ifdef CONFIG_MMU
 986
 987         /*
 988          * The only thing that can break atomicity in this cmpxchg
 989          * implementation is either an IRQ or a data abort exception
 990          * causing another process/thread to be scheduled in the middle
 991          * of the critical sequence.  To prevent this, code is added to
 992          * the IRQ and data abort exception handlers to set the pc back
 993          * to the beginning of the critical section if it is found to be
 994          * within that critical section (see kuser_cmpxchg_fixup).
 995          */
 996 1:      ldr     r3, [r2]                        @ load current val
 997         subs    r3, r3, r0                      @ compare with oldval
 998 2:      streq   r1, [r2]                        @ store newval if eq
 999         rsbs    r0, r3, #0                      @ set return val and C flag
1000         usr_ret lr
1001
1002         .text
1003 kuser_cmpxchg32_fixup:
1004         @ Called from kuser_cmpxchg_check macro.
1005         @ r4 = address of interrupted insn (must be preserved).
1006         @ sp = saved regs. r7 and r8 are clobbered.
1007         @ 1b = first critical insn, 2b = last critical insn.
1008         @ If r4 >= 1b and r4 <= 2b then saved pc_usr is set to 1b.
1009         mov     r7, #0xffff0fff
1010         sub     r7, r7, #(0xffff0fff - (0xffff0fc0 + (1b - __kuser_cmpxchg)))
1011         subs    r8, r4, r7
1012         rsbscs  r8, r8, #(2b - 1b)
1013         strcs   r7, [sp, #S_PC]
1014         ret     lr
1015         .previous
1016
1017 #else
1018 #warning "NPTL on non MMU needs fixing"
1019         mov     r0, #-1
1020         adds    r0, r0, #0
1021         usr_ret lr
1022 #endif
1023
1024 #else
1025
1026         smp_dmb arm
1027 1:      ldrex   r3, [r2]
1028         subs    r3, r3, r0
1029         strexeq r3, r1, [r2]
1030         teqeq   r3, #1
1031         beq     1b
1032         rsbs    r0, r3, #0
1033         /* beware -- each __kuser slot must be 8 instructions max */
1034         ALT_SMP(b       __kuser_memory_barrier)
1035         ALT_UP(usr_ret  lr)
1036
1037 #endif
1038
1039         kuser_pad __kuser_cmpxchg, 32
1040
1041 __kuser_get_tls:                                @ 0xffff0fe0
1042         ldr     r0, [pc, #(16 - 8)]     @ read TLS, set in kuser_get_tls_init
1043         usr_ret lr
1044         mrc     p15, 0, r0, c13, c0, 3  @ 0xffff0fe8 hardware TLS code
1045         kuser_pad __kuser_get_tls, 16
1046         .rep    3
1047         .word   0                       @ 0xffff0ff0 software TLS value, then
1048         .endr                           @ pad up to __kuser_helper_version
1049
1050 __kuser_helper_version:                         @ 0xffff0ffc
1051         .word   ((__kuser_helper_end - __kuser_helper_start) >> 5)
1052
1053         .globl  __kuser_helper_end
1054 __kuser_helper_end:
1055
1056 #endif
1057
1058  THUMB( .thumb  )
1059
1060 /*
1061  * Vector stubs.
1062  *
1063  * This code is copied to 0xffff1000 so we can use branches in the
1064  * vectors, rather than ldr's.  Note that this code must not exceed
1065  * a page size.
1066  *
1067  * Common stub entry macro:
1068  *   Enter in IRQ mode, spsr = SVC/USR CPSR, lr = SVC/USR PC
1069  *
1070  * SP points to a minimal amount of processor-private memory, the address
1071  * of which is copied into r0 for the mode specific abort handler.
1072  */
1073         .macro  vector_stub, name, mode, correction=0
1074         .align  5
1075 #ifdef CONFIG_HARDEN_BRANCH_HISTORY
1076 vector_bhb_bpiall_\name:
1077         mcr     p15, 0, r0, c7, c5, 6   @ BPIALL
1078         @ isb not needed due to "movs pc, lr" in the vector stub
1079         @ which gives a "context synchronisation".
1080 #endif
1081
1082 vector_\name:
1083         .if \correction
1084         sub     lr, lr, #\correction
1085         .endif
1086
1087         @ Save r0, lr_<exception> (parent PC)
1088         stmia   sp, {r0, lr}            @ save r0, lr
1089
1090         @ Save spsr_<exception> (parent CPSR)
1091 .Lvec_\name:
1092         mrs     lr, spsr
1093         str     lr, [sp, #8]            @ save spsr
1094
1095         @
1096         @ Prepare for SVC32 mode.  IRQs remain disabled.
1097         @
1098         mrs     r0, cpsr
1099         eor     r0, r0, #(\mode ^ SVC_MODE | PSR_ISETSTATE)
1100         msr     spsr_cxsf, r0
1101
1102         @
1103         @ the branch table must immediately follow this code
1104         @
1105         and     lr, lr, #0x0f
1106  THUMB( adr     r0, 1f                  )
1107  THUMB( ldr     lr, [r0, lr, lsl #2]    )
1108         mov     r0, sp
1109  ARM(   ldr     lr, [pc, lr, lsl #2]    )
1110         movs    pc, lr                  @ branch to handler in SVC mode
1111 ENDPROC(vector_\name)
1112
1113 #ifdef CONFIG_HARDEN_BRANCH_HISTORY
1114         .subsection 1
1115         .align 5
1116 vector_bhb_loop8_\name:
1117         .if \correction
1118         sub     lr, lr, #\correction
1119         .endif
1120
1121         @ Save r0, lr_<exception> (parent PC)
1122         stmia   sp, {r0, lr}
1123
1124         @ bhb workaround
1125         mov     r0, #8
1126 3:      W(b)    . + 4
1127         subs    r0, r0, #1
1128         bne     3b
1129         dsb     nsh
1130         @ isb not needed due to "movs pc, lr" in the vector stub
1131         @ which gives a "context synchronisation".
1132         b       .Lvec_\name
1133 ENDPROC(vector_bhb_loop8_\name)
1134         .previous
1135 #endif
1136
1137         .align  2
1138         @ handler addresses follow this label
1139 1:
1140         .endm
1141
1142         .section .stubs, "ax", %progbits
1143         @ These need to remain at the start of the section so that
1144         @ they are in range of the 'SWI' entries in the vector tables
1145         @ located 4k down.
1146 .L__vector_swi:
1147         .word   vector_swi
1148 #ifdef CONFIG_HARDEN_BRANCH_HISTORY
1149 .L__vector_bhb_loop8_swi:
1150         .word   vector_bhb_loop8_swi
1151 .L__vector_bhb_bpiall_swi:
1152         .word   vector_bhb_bpiall_swi
1153 #endif
1154
1155 vector_rst:
1156  ARM(   swi     SYS_ERROR0      )
1157  THUMB( svc     #0              )
1158  THUMB( nop                     )
1159         b       vector_und
1160
1161 /*
1162  * Interrupt dispatcher
1163  */
1164         vector_stub     irq, IRQ_MODE, 4
1165
1166         .long   __irq_usr                       @  0  (USR_26 / USR_32)
1167         .long   __irq_invalid                   @  1  (FIQ_26 / FIQ_32)
1168         .long   __irq_invalid                   @  2  (IRQ_26 / IRQ_32)
1169         .long   __irq_svc                       @  3  (SVC_26 / SVC_32)
1170         .long   __irq_invalid                   @  4
1171         .long   __irq_invalid                   @  5
1172         .long   __irq_invalid                   @  6
1173         .long   __irq_invalid                   @  7
1174         .long   __irq_invalid                   @  8
1175         .long   __irq_invalid                   @  9
1176         .long   __irq_invalid                   @  a
1177         .long   __irq_invalid                   @  b
1178         .long   __irq_invalid                   @  c
1179         .long   __irq_invalid                   @  d
1180         .long   __irq_invalid                   @  e
1181         .long   __irq_invalid                   @  f
1182
1183 /*
1184  * Data abort dispatcher
1185  * Enter in ABT mode, spsr = USR CPSR, lr = USR PC
1186  */
1187         vector_stub     dabt, ABT_MODE, 8
1188
1189         .long   __dabt_usr                      @  0  (USR_26 / USR_32)
1190         .long   __dabt_invalid                  @  1  (FIQ_26 / FIQ_32)
1191         .long   __dabt_invalid                  @  2  (IRQ_26 / IRQ_32)
1192         .long   __dabt_svc                      @  3  (SVC_26 / SVC_32)
1193         .long   __dabt_invalid                  @  4
1194         .long   __dabt_invalid                  @  5
1195         .long   __dabt_invalid                  @  6
1196         .long   __dabt_invalid                  @  7
1197         .long   __dabt_invalid                  @  8
1198         .long   __dabt_invalid                  @  9
1199         .long   __dabt_invalid                  @  a
1200         .long   __dabt_invalid                  @  b
1201         .long   __dabt_invalid                  @  c
1202         .long   __dabt_invalid                  @  d
1203         .long   __dabt_invalid                  @  e
1204         .long   __dabt_invalid                  @  f
1205
1206 /*
1207  * Prefetch abort dispatcher
1208  * Enter in ABT mode, spsr = USR CPSR, lr = USR PC
1209  */
1210         vector_stub     pabt, ABT_MODE, 4
1211
1212         .long   __pabt_usr                      @  0 (USR_26 / USR_32)
1213         .long   __pabt_invalid                  @  1 (FIQ_26 / FIQ_32)
1214         .long   __pabt_invalid                  @  2 (IRQ_26 / IRQ_32)
1215         .long   __pabt_svc                      @  3 (SVC_26 / SVC_32)
1216         .long   __pabt_invalid                  @  4
1217         .long   __pabt_invalid                  @  5
1218         .long   __pabt_invalid                  @  6
1219         .long   __pabt_invalid                  @  7
1220         .long   __pabt_invalid                  @  8
1221         .long   __pabt_invalid                  @  9
1222         .long   __pabt_invalid                  @  a
1223         .long   __pabt_invalid                  @  b
1224         .long   __pabt_invalid                  @  c
1225         .long   __pabt_invalid                  @  d
1226         .long   __pabt_invalid                  @  e
1227         .long   __pabt_invalid                  @  f
1228
1229 /*
1230  * Undef instr entry dispatcher
1231  * Enter in UND mode, spsr = SVC/USR CPSR, lr = SVC/USR PC
1232  */
1233         vector_stub     und, UND_MODE
1234
1235         .long   __und_usr                       @  0 (USR_26 / USR_32)
1236         .long   __und_invalid                   @  1 (FIQ_26 / FIQ_32)
1237         .long   __und_invalid                   @  2 (IRQ_26 / IRQ_32)
1238         .long   __und_svc                       @  3 (SVC_26 / SVC_32)
1239         .long   __und_invalid                   @  4
1240         .long   __und_invalid                   @  5
1241         .long   __und_invalid                   @  6
1242         .long   __und_invalid                   @  7
1243         .long   __und_invalid                   @  8
1244         .long   __und_invalid                   @  9
1245         .long   __und_invalid                   @  a
1246         .long   __und_invalid                   @  b
1247         .long   __und_invalid                   @  c
1248         .long   __und_invalid                   @  d
1249         .long   __und_invalid                   @  e
1250         .long   __und_invalid                   @  f
1251
1252         .align  5
1253
1254 /*=============================================================================
1255  * Address exception handler
1256  *-----------------------------------------------------------------------------
1257  * These aren't too critical.
1258  * (they're not supposed to happen, and won't happen in 32-bit data mode).
1259  */
1260
1261 vector_addrexcptn:
1262         b       vector_addrexcptn
1263
1264 /*=============================================================================
1265  * FIQ "NMI" handler
1266  *-----------------------------------------------------------------------------
1267  * Handle a FIQ using the SVC stack allowing FIQ act like NMI on x86
1268  * systems. This must be the last vector stub, so lets place it in its own
1269  * subsection.
1270  */
1271         .subsection 2
1272         vector_stub     fiq, FIQ_MODE, 4
1273
1274         .long   __fiq_usr                       @  0  (USR_26 / USR_32)
1275         .long   __fiq_svc                       @  1  (FIQ_26 / FIQ_32)
1276         .long   __fiq_svc                       @  2  (IRQ_26 / IRQ_32)
1277         .long   __fiq_svc                       @  3  (SVC_26 / SVC_32)
1278         .long   __fiq_svc                       @  4
1279         .long   __fiq_svc                       @  5
1280         .long   __fiq_svc                       @  6
1281         .long   __fiq_abt                       @  7
1282         .long   __fiq_svc                       @  8
1283         .long   __fiq_svc                       @  9
1284         .long   __fiq_svc                       @  a
1285         .long   __fiq_svc                       @  b
1286         .long   __fiq_svc                       @  c
1287         .long   __fiq_svc                       @  d
1288         .long   __fiq_svc                       @  e
1289         .long   __fiq_svc                       @  f
1290
1291         .globl  vector_fiq
1292
1293         .section .vectors, "ax", %progbits
1294         W(b)    vector_rst
1295         W(b)    vector_und
1296 ARM(    .reloc  ., R_ARM_LDR_PC_G0, .L__vector_swi              )
1297 THUMB(  .reloc  ., R_ARM_THM_PC12, .L__vector_swi               )
1298         W(ldr)  pc, .
1299         W(b)    vector_pabt
1300         W(b)    vector_dabt
1301         W(b)    vector_addrexcptn
1302         W(b)    vector_irq
1303         W(b)    vector_fiq
1304
1305 #ifdef CONFIG_HARDEN_BRANCH_HISTORY
1306         .section .vectors.bhb.loop8, "ax", %progbits
1307         W(b)    vector_rst
1308         W(b)    vector_bhb_loop8_und
1309 ARM(    .reloc  ., R_ARM_LDR_PC_G0, .L__vector_bhb_loop8_swi    )
1310 THUMB(  .reloc  ., R_ARM_THM_PC12, .L__vector_bhb_loop8_swi     )
1311         W(ldr)  pc, .
1312         W(b)    vector_bhb_loop8_pabt
1313         W(b)    vector_bhb_loop8_dabt
1314         W(b)    vector_addrexcptn
1315         W(b)    vector_bhb_loop8_irq
1316         W(b)    vector_bhb_loop8_fiq
1317
1318         .section .vectors.bhb.bpiall, "ax", %progbits
1319         W(b)    vector_rst
1320         W(b)    vector_bhb_bpiall_und
1321 ARM(    .reloc  ., R_ARM_LDR_PC_G0, .L__vector_bhb_bpiall_swi   )
1322 THUMB(  .reloc  ., R_ARM_THM_PC12, .L__vector_bhb_bpiall_swi    )
1323         W(ldr)  pc, .
1324         W(b)    vector_bhb_bpiall_pabt
1325         W(b)    vector_bhb_bpiall_dabt
1326         W(b)    vector_addrexcptn
1327         W(b)    vector_bhb_bpiall_irq
1328         W(b)    vector_bhb_bpiall_fiq
1329 #endif
1330
1331         .data
1332         .align  2
1333
1334         .globl  cr_alignment
1335 cr_alignment:
1336         .space  4