arch/arm/cpu/armv7/start.S

   1 /*
   2  * armboot - Startup Code for OMAP3530/ARM Cortex CPU-core
   3  *
   4  * Copyright (c) 2004   Texas Instruments <r-woodruff2@ti.com>
   5  *
   6  * Copyright (c) 2001   Marius Gröger <mag@sysgo.de>
   7  * Copyright (c) 2002   Alex Züpke <azu@sysgo.de>
   8  * Copyright (c) 2002   Gary Jennejohn <garyj@denx.de>
   9  * Copyright (c) 2003   Richard Woodruff <r-woodruff2@ti.com>
  10  * Copyright (c) 2003   Kshitij <kshitij@ti.com>
  11  * Copyright (c) 2006-2008 Syed Mohammed Khasim <x0khasim@ti.com>
  12  *
  13  * See file CREDITS for list of people who contributed to this
  14  * project.
  15  *
  16  * This program is free software; you can redistribute it and/or
  17  * modify it under the terms of the GNU General Public License as
  18  * published by the Free Software Foundation; either version 2 of
  19  * the License, or (at your option) any later version.
  20  *
  21  * This program is distributed in the hope that it will be useful,
  22  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  23  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24  * GNU General Public License for more details.
  25  *
  26  * You should have received a copy of the GNU General Public License
  27  * along with this program; if not, write to the Free Software
  28  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  29  * MA 02111-1307 USA
  30  */
  31
  32 #include <asm-offsets.h>
  33 #include <config.h>
  34 #include <version.h>
  35 #include <asm/system.h>
  36 #include <linux/linkage.h>
  37
  38 .globl _start
  39 _start: b       reset
  40         ldr     pc, _undefined_instruction
  41         ldr     pc, _software_interrupt
  42         ldr     pc, _prefetch_abort
  43         ldr     pc, _data_abort
  44         ldr     pc, _not_used
  45         ldr     pc, _irq
  46         ldr     pc, _fiq
  47 #ifdef CONFIG_SPL_BUILD
  48 _undefined_instruction: .word _undefined_instruction
  49 _software_interrupt:    .word _software_interrupt
  50 _prefetch_abort:        .word _prefetch_abort
  51 _data_abort:            .word _data_abort
  52 _not_used:              .word _not_used
  53 _irq:                   .word _irq
  54 _fiq:                   .word _fiq
  55 _pad:                   .word 0x12345678 /* now 16*4=64 */
  56 #else
  57 _undefined_instruction: .word undefined_instruction
  58 _software_interrupt:    .word software_interrupt
  59 _prefetch_abort:        .word prefetch_abort
  60 _data_abort:            .word data_abort
  61 _not_used:              .word not_used
  62 _irq:                   .word irq
  63 _fiq:                   .word fiq
  64 _pad:                   .word 0x12345678 /* now 16*4=64 */
  65 #endif  /* CONFIG_SPL_BUILD */
  66
  67 .global _end_vect
  68 _end_vect:
  69
  70         .balignl 16,0xdeadbeef
  71 /*************************************************************************
  72  *
  73  * Startup Code (reset vector)
  74  *
  75  * do important init only if we don't start from memory!
  76  * setup Memory and board specific bits prior to relocation.
  77  * relocate armboot to ram
  78  * setup stack
  79  *
  80  *************************************************************************/
  81
  82 .globl _TEXT_BASE
  83 _TEXT_BASE:
  84         .word   CONFIG_SYS_TEXT_BASE
  85
  86 /*
  87  * These are defined in the board-specific linker script.
  88  */
  89 .globl _bss_start_ofs
  90 _bss_start_ofs:
  91         .word __bss_start - _start
  92
  93 .global _image_copy_end_ofs
  94 _image_copy_end_ofs:
  95         .word   __image_copy_end - _start
  96
  97 .globl _bss_end_ofs
  98 _bss_end_ofs:
  99         .word __bss_end__ - _start
 100
 101 .globl _end_ofs
 102 _end_ofs:
 103         .word _end - _start
 104
 105 #ifdef CONFIG_USE_IRQ
 106 /* IRQ stack memory (calculated at run-time) */
 107 .globl IRQ_STACK_START
 108 IRQ_STACK_START:
 109         .word   0x0badc0de
 110
 111 /* IRQ stack memory (calculated at run-time) */
 112 .globl FIQ_STACK_START
 113 FIQ_STACK_START:
 114         .word 0x0badc0de
 115 #endif
 116
 117 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 118 .globl IRQ_STACK_START_IN
 119 IRQ_STACK_START_IN:
 120         .word   0x0badc0de
 121
 122 /*
 123  * the actual reset code
 124  */
 125
 126 reset:
 127         bl      save_boot_params
 128         /*
 129          * set the cpu to SVC32 mode
 130          */
 131         mrs     r0, cpsr
 132         bic     r0, r0, #0x1f
 133         orr     r0, r0, #0xd3
 134         msr     cpsr,r0
 135
 136 #if !defined(CONFIG_TEGRA2)
 137 /*
 138  * Setup vector:
 139  * (OMAP4 spl TEXT_BASE is not 32 byte aligned.
 140  * Continue to use ROM code vector only in OMAP4 spl)
 141  */
 142 #if !(defined(CONFIG_OMAP44XX) && defined(CONFIG_SPL_BUILD))
 143         /* Set V=0 in CP15 SCTRL register - for VBAR to point to vector */
 144         mrc     p15, 0, r0, c1, c0, 0   @ Read CP15 SCTRL Register
 145         bic     r0, #CR_V               @ V = 0
 146         mcr     p15, 0, r0, c1, c0, 0   @ Write CP15 SCTRL Register
 147
 148         /* Set vector address in CP15 VBAR register */
 149         ldr     r0, =_start
 150         mcr     p15, 0, r0, c12, c0, 0  @Set VBAR
 151 #endif
 152 #endif  /* !Tegra2 */
 153
 154         /* the mask ROM code should have PLL and others stable */
 155 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 156         bl      cpu_init_cp15
 157         bl      cpu_init_crit
 158 #endif
 159
 160 /* Set stackpointer in internal RAM to call board_init_f */
 161 call_board_init_f:
 162         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 163         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
 164         ldr     r0,=0x00000000
 165         bl      board_init_f
 166
 167 /*------------------------------------------------------------------------------*/
 168
 169 /*
 170  * void relocate_code (addr_sp, gd, addr_moni)
 171  *
 172  * This "function" does not return, instead it continues in RAM
 173  * after relocating the monitor code.
 174  *
 175  */
 176 ENTRY(relocate_code)
 177         mov     r4, r0  /* save addr_sp */
 178         mov     r5, r1  /* save addr of gd */
 179         mov     r6, r2  /* save addr of destination */
 180
 181         /* Set up the stack                                                 */
 182 stack_setup:
 183         mov     sp, r4
 184
 185         adr     r0, _start
 186         cmp     r0, r6
 187         moveq   r9, #0          /* no relocation. relocation offset(r9) = 0 */
 188         beq     clear_bss               /* skip relocation */
 189         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 190         ldr     r3, _image_copy_end_ofs
 191         add     r2, r0, r3              /* r2 <- source end address         */
 192
 193 copy_loop:
 194         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 195         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 196         cmp     r0, r2                  /* until source end address [r2]    */
 197         blo     copy_loop
 198
 199 #ifndef CONFIG_SPL_BUILD
 200         /*
 201          * fix .rel.dyn relocations
 202          */
 203         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 204         sub     r9, r6, r0              /* r9 <- relocation offset */
 205         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 206         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 207         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 208         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 209         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 210         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 211 fixloop:
 212         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 213         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 214         ldr     r1, [r2, #4]
 215         and     r7, r1, #0xff
 216         cmp     r7, #23                 /* relative fixup? */
 217         beq     fixrel
 218         cmp     r7, #2                  /* absolute fixup? */
 219         beq     fixabs
 220         /* ignore unknown type of fixup */
 221         b       fixnext
 222 fixabs:
 223         /* absolute fix: set location to (offset) symbol value */
 224         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 225         add     r1, r10, r1             /* r1 <- address of symbol in table */
 226         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 227         add     r1, r1, r9              /* r1 <- relocated sym addr */
 228         b       fixnext
 229 fixrel:
 230         /* relative fix: increase location by offset */
 231         ldr     r1, [r0]
 232         add     r1, r1, r9
 233 fixnext:
 234         str     r1, [r0]
 235         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 236         cmp     r2, r3
 237         blo     fixloop
 238         b       clear_bss
 239 _rel_dyn_start_ofs:
 240         .word __rel_dyn_start - _start
 241 _rel_dyn_end_ofs:
 242         .word __rel_dyn_end - _start
 243 _dynsym_start_ofs:
 244         .word __dynsym_start - _start
 245
 246 #endif  /* #ifndef CONFIG_SPL_BUILD */
 247
 248 clear_bss:
 249 #ifdef CONFIG_SPL_BUILD
 250         /* No relocation for SPL */
 251         ldr     r0, =__bss_start
 252         ldr     r1, =__bss_end__
 253 #else
 254         ldr     r0, _bss_start_ofs
 255         ldr     r1, _bss_end_ofs
 256         mov     r4, r6                  /* reloc addr */
 257         add     r0, r0, r4
 258         add     r1, r1, r4
 259 #endif
 260         mov     r2, #0x00000000         /* clear                            */
 261
 262 clbss_l:cmp     r0, r1                  /* clear loop... */
 263         bhs     clbss_e                 /* if reached end of bss, exit */
 264         str     r2, [r0]
 265         add     r0, r0, #4
 266         b       clbss_l
 267 clbss_e:
 268
 269 /*
 270  * We are done. Do not return, instead branch to second part of board
 271  * initialization, now running from RAM.
 272  */
 273 jump_2_ram:
 274 /*
 275  * If I-cache is enabled invalidate it
 276  */
 277 #ifndef CONFIG_SYS_ICACHE_OFF
 278         mcr     p15, 0, r0, c7, c5, 0   @ invalidate icache
 279         mcr     p15, 0, r0, c7, c10, 4  @ DSB
 280         mcr     p15, 0, r0, c7, c5, 4   @ ISB
 281 #endif
 282 /*
 283  * Move vector table
 284  */
 285 #if !defined(CONFIG_TEGRA2)
 286 #if !(defined(CONFIG_OMAP44XX) && defined(CONFIG_SPL_BUILD))
 287         /* Set vector address in CP15 VBAR register */
 288         ldr     r0, =_start
 289         add     r0, r0, r9
 290         mcr     p15, 0, r0, c12, c0, 0  @Set VBAR
 291 #endif
 292 #endif /* !Tegra2 */
 293
 294         ldr     r0, _board_init_r_ofs
 295         adr     r1, _start
 296         add     lr, r0, r1
 297         add     lr, lr, r9
 298         /* setup parameters for board_init_r */
 299         mov     r0, r5          /* gd_t */
 300         mov     r1, r6          /* dest_addr */
 301         /* jump to it ... */
 302         mov     pc, lr
 303
 304 _board_init_r_ofs:
 305         .word board_init_r - _start
 306 ENDPROC(relocate_code)
 307
 308 /*************************************************************************
 309  *
 310  * cpu_init_cp15
 311  *
 312  * Setup CP15 registers (cache, MMU, TLBs). The I-cache is turned on unless
 313  * CONFIG_SYS_ICACHE_OFF is defined.
 314  *
 315  *************************************************************************/
 316 ENTRY(cpu_init_cp15)
 317         /*
 318          * Invalidate L1 I/D
 319          */
 320         mov     r0, #0                  @ set up for MCR
 321         mcr     p15, 0, r0, c8, c7, 0   @ invalidate TLBs
 322         mcr     p15, 0, r0, c7, c5, 0   @ invalidate icache
 323         mcr     p15, 0, r0, c7, c5, 6   @ invalidate BP array
 324         mcr     p15, 0, r0, c7, c10, 4  @ DSB
 325         mcr     p15, 0, r0, c7, c5, 4   @ ISB
 326
 327         /*
 328          * disable MMU stuff and caches
 329          */
 330         mrc     p15, 0, r0, c1, c0, 0
 331         bic     r0, r0, #0x00002000     @ clear bits 13 (--V-)
 332         bic     r0, r0, #0x00000007     @ clear bits 2:0 (-CAM)
 333         orr     r0, r0, #0x00000002     @ set bit 1 (--A-) Align
 334         orr     r0, r0, #0x00000800     @ set bit 11 (Z---) BTB
 335 #ifdef CONFIG_SYS_ICACHE_OFF
 336         bic     r0, r0, #0x00001000     @ clear bit 12 (I) I-cache
 337 #else
 338         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-cache
 339 #endif
 340         mcr     p15, 0, r0, c1, c0, 0
 341         mov     pc, lr                  @ back to my caller
 342 ENDPROC(cpu_init_cp15)
 343
 344 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 345 /*************************************************************************
 346  *
 347  * CPU_init_critical registers
 348  *
 349  * setup important registers
 350  * setup memory timing
 351  *
 352  *************************************************************************/
 353 ENTRY(cpu_init_crit)
 354         /*
 355          * Jump to board specific initialization...
 356          * The Mask ROM will have already initialized
 357          * basic memory. Go here to bump up clock rate and handle
 358          * wake up conditions.
 359          */
 360         mov     ip, lr                  @ persevere link reg across call
 361         bl      lowlevel_init           @ go setup pll,mux,memory
 362         mov     lr, ip                  @ restore link
 363         mov     pc, lr                  @ back to my caller
 364 ENDPROC(cpu_init_crit)
 365 #endif
 366
 367 #ifndef CONFIG_SPL_BUILD
 368 /*
 369  *************************************************************************
 370  *
 371  * Interrupt handling
 372  *
 373  *************************************************************************
 374  */
 375 @
 376 @ IRQ stack frame.
 377 @
 378 #define S_FRAME_SIZE    72
 379
 380 #define S_OLD_R0        68
 381 #define S_PSR           64
 382 #define S_PC            60
 383 #define S_LR            56
 384 #define S_SP            52
 385
 386 #define S_IP            48
 387 #define S_FP            44
 388 #define S_R10           40
 389 #define S_R9            36
 390 #define S_R8            32
 391 #define S_R7            28
 392 #define S_R6            24
 393 #define S_R5            20
 394 #define S_R4            16
 395 #define S_R3            12
 396 #define S_R2            8
 397 #define S_R1            4
 398 #define S_R0            0
 399
 400 #define MODE_SVC 0x13
 401 #define I_BIT    0x80
 402
 403 /*
 404  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 405  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 406  */
 407
 408         .macro  bad_save_user_regs
 409         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current
 410                                                 @ user stack
 411         stmia   sp, {r0 - r12}                  @ Save user registers (now in
 412                                                 @ svc mode) r0-r12
 413         ldr     r2, IRQ_STACK_START_IN          @ set base 2 words into abort
 414                                                 @ stack
 415         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc
 416                                                 @ and cpsr (into parm regs)
 417         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 418
 419         add     r5, sp, #S_SP
 420         mov     r1, lr
 421         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 422         mov     r0, sp                          @ save current stack into r0
 423                                                 @ (param register)
 424         .endm
 425
 426         .macro  irq_save_user_regs
 427         sub     sp, sp, #S_FRAME_SIZE
 428         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 429         add     r8, sp, #S_PC                   @ !! R8 NEEDS to be saved !!
 430                                                 @ a reserved stack spot would
 431                                                 @ be good.
 432         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 433         str     lr, [r8, #0]                    @ Save calling PC
 434         mrs     r6, spsr
 435         str     r6, [r8, #4]                    @ Save CPSR
 436         str     r0, [r8, #8]                    @ Save OLD_R0
 437         mov     r0, sp
 438         .endm
 439
 440         .macro  irq_restore_user_regs
 441         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 442         mov     r0, r0
 443         ldr     lr, [sp, #S_PC]                 @ Get PC
 444         add     sp, sp, #S_FRAME_SIZE
 445         subs    pc, lr, #4                      @ return & move spsr_svc into
 446                                                 @ cpsr
 447         .endm
 448
 449         .macro get_bad_stack
 450         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack (enter
 451                                                 @ in banked mode)
 452
 453         str     lr, [r13]                       @ save caller lr in position 0
 454                                                 @ of saved stack
 455         mrs     lr, spsr                        @ get the spsr
 456         str     lr, [r13, #4]                   @ save spsr in position 1 of
 457                                                 @ saved stack
 458
 459         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 460         @ msr   spsr_c, r13
 461         msr     spsr, r13                       @ switch modes, make sure
 462                                                 @ moves will execute
 463         mov     lr, pc                          @ capture return pc
 464         movs    pc, lr                          @ jump to next instruction &
 465                                                 @ switch modes.
 466         .endm
 467
 468         .macro get_bad_stack_swi
 469         sub     r13, r13, #4                    @ space on current stack for
 470                                                 @ scratch reg.
 471         str     r0, [r13]                       @ save R0's value.
 472         ldr     r0, IRQ_STACK_START_IN          @ get data regions start
 473                                                 @ spots for abort stack
 474         str     lr, [r0]                        @ save caller lr in position 0
 475                                                 @ of saved stack
 476         mrs     r0, spsr                        @ get the spsr
 477         str     lr, [r0, #4]                    @ save spsr in position 1 of
 478                                                 @ saved stack
 479         ldr     r0, [r13]                       @ restore r0
 480         add     r13, r13, #4                    @ pop stack entry
 481         .endm
 482
 483         .macro get_irq_stack                    @ setup IRQ stack
 484         ldr     sp, IRQ_STACK_START
 485         .endm
 486
 487         .macro get_fiq_stack                    @ setup FIQ stack
 488         ldr     sp, FIQ_STACK_START
 489         .endm
 490
 491 /*
 492  * exception handlers
 493  */
 494         .align  5
 495 undefined_instruction:
 496         get_bad_stack
 497         bad_save_user_regs
 498         bl      do_undefined_instruction
 499
 500         .align  5
 501 software_interrupt:
 502         get_bad_stack_swi
 503         bad_save_user_regs
 504         bl      do_software_interrupt
 505
 506         .align  5
 507 prefetch_abort:
 508         get_bad_stack
 509         bad_save_user_regs
 510         bl      do_prefetch_abort
 511
 512         .align  5
 513 data_abort:
 514         get_bad_stack
 515         bad_save_user_regs
 516         bl      do_data_abort
 517
 518         .align  5
 519 not_used:
 520         get_bad_stack
 521         bad_save_user_regs
 522         bl      do_not_used
 523
 524 #ifdef CONFIG_USE_IRQ
 525
 526         .align  5
 527 irq:
 528         get_irq_stack
 529         irq_save_user_regs
 530         bl      do_irq
 531         irq_restore_user_regs
 532
 533         .align  5
 534 fiq:
 535         get_fiq_stack
 536         /* someone ought to write a more effective fiq_save_user_regs */
 537         irq_save_user_regs
 538         bl      do_fiq
 539         irq_restore_user_regs
 540
 541 #else
 542
 543         .align  5
 544 irq:
 545         get_bad_stack
 546         bad_save_user_regs
 547         bl      do_irq
 548
 549         .align  5
 550 fiq:
 551         get_bad_stack
 552         bad_save_user_regs
 553         bl      do_fiq
 554
 555 #endif /* CONFIG_USE_IRQ */
 556 #endif /* CONFIG_SPL_BUILD */