arch/arm/cpu/armv7/omap-common/lowlevel_init.S

   1 /*
   2  * Board specific setup info
   3  *
   4  * (C) Copyright 2010
   5  * Texas Instruments, <www.ti.com>
   6  *
   7  * Author :
   8  *      Aneesh V        <aneesh@ti.com>
   9  *
  10  * See file CREDITS for list of people who contributed to this
  11  * project.
  12  *
  13  * This program is free software; you can redistribute it and/or
  14  * modify it under the terms of the GNU General Public License as
  15  * published by the Free Software Foundation; either version 2 of
  16  * the License, or (at your option) any later version.
  17  *
  18  * This program is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  21  * GNU General Public License for more details.
  22  *
  23  * You should have received a copy of the GNU General Public License
  24  * along with this program; if not, write to the Free Software
  25  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  26  * MA 02111-1307 USA
  27  */
  28
  29 #include <asm/arch/omap.h>
  30
  31 .global save_boot_params
  32 save_boot_params:
  33         /*
  34          * See if the rom code passed pointer is valid:
  35          * It is not valid if it is not in non-secure SRAM
  36          * This may happen if you are booting with the help of
  37          * debugger
  38          */
  39         ldr     r2, =NON_SECURE_SRAM_START
  40         cmp     r2, r0
  41         bgt     1f
  42         ldr     r2, =NON_SECURE_SRAM_END
  43         cmp     r2, r0
  44         blt     1f
  45
  46         /*
  47          * store the boot params passed from rom code or saved
  48          * and passed by SPL
  49          */
  50         cmp     r0, #0
  51         beq     1f
  52         ldr     r1, =boot_params
  53         str     r0, [r1]
  54 #ifdef CONFIG_SPL_BUILD
  55         /* Store the boot device in omap_boot_device */
  56         ldrb    r2, [r0, #BOOT_DEVICE_OFFSET]   @ r1 <- value of boot device
  57         and     r2, #BOOT_DEVICE_MASK
  58         ldr     r3, =boot_params
  59         strb    r2, [r3, #BOOT_DEVICE_OFFSET]   @ omap_boot_device <- r1
  60
  61         /* boot mode is passed only for devices that can raw/fat mode */
  62         cmp     r2, #2
  63         blt     2f
  64         cmp     r2, #7
  65         bgt     2f
  66         /* Store the boot mode (raw/FAT) in omap_boot_mode */
  67         ldr     r2, [r0, #DEV_DESC_PTR_OFFSET]  @ get the device descriptor ptr
  68         ldr     r2, [r2, #DEV_DATA_PTR_OFFSET]  @ get the pDeviceData ptr
  69         ldr     r2, [r2, #BOOT_MODE_OFFSET]     @ get the boot mode
  70         ldr     r3, =omap_bootmode
  71         str     r2, [r3]
  72 #endif
  73 2:
  74         ldrb    r2, [r0, #CH_FLAGS_OFFSET]
  75         ldr     r3, =boot_params
  76         strb    r2, [r3, #CH_FLAGS_OFFSET]
  77 1:
  78         bx      lr
  79
  80
  81 .globl lowlevel_init
  82 lowlevel_init:
  83         /*
  84          * Setup a temporary stack
  85          */
  86         ldr     sp, =LOW_LEVEL_SRAM_STACK
  87
  88         /*
  89          * Save the old lr(passed in ip) and the current lr to stack
  90          */
  91         push    {ip, lr}
  92
  93         /*
  94          * go setup pll, mux, memory
  95          */
  96         bl      s_init
  97         pop     {ip, pc}
  98
  99 .globl set_pl310_ctrl_reg
 100 set_pl310_ctrl_reg:
 101         PUSH    {r4-r11, lr}    @ save registers - ROM code may pollute
 102                                 @ our registers
 103         LDR     r12, =0x102     @ Set PL310 control register - value in R0
 104         .word   0xe1600070      @ SMC #0 - hand assembled because -march=armv5
 105                                 @ call ROM Code API to set control register
 106         POP     {r4-r11, pc}