arch/arc/lib/start.S

   1 /*
   2  * Copyright (C) 2013-2014 Synopsys, Inc. All rights reserved.
   3  *
   4  * SPDX-License-Identifier:     GPL-2.0+
   5  */
   6
   7 #include <asm-offsets.h>
   8 #include <config.h>
   9 #include <linux/linkage.h>
  10 #include <asm/arcregs.h>
  11
  12 ENTRY(_start)
  13         /* Setup interrupt vector base that matches "__text_start" */
  14         sr      __ivt_start, [ARC_AUX_INTR_VEC_BASE]
  15
  16         ; Disable/enable I-cache according to configuration
  17         lr      r5, [ARC_BCR_IC_BUILD]
  18         breq    r5, 0, 1f               ; I$ doesn't exist
  19         lr      r5, [ARC_AUX_IC_CTRL]
  20 #ifndef CONFIG_SYS_ICACHE_OFF
  21         bclr    r5, r5, 0               ; 0 - Enable, 1 is Disable
  22 #else
  23         bset    r5, r5, 0               ; I$ exists, but is not used
  24 #endif
  25         sr      r5, [ARC_AUX_IC_CTRL]
  26
  27         mov     r5, 1
  28         sr      r5, [ARC_AUX_IC_IVIC]
  29         ; As per ARC HS databook (see chapter 5.3.3.2)
  30         ; it is required to add 3 NOPs after each write to IC_IVIC.
  31         nop
  32         nop
  33         nop
  34
  35 1:
  36         ; Disable/enable D-cache according to configuration
  37         lr      r5, [ARC_BCR_DC_BUILD]
  38         breq    r5, 0, 1f               ; D$ doesn't exist
  39         lr      r5, [ARC_AUX_DC_CTRL]
  40         bclr    r5, r5, 6               ; Invalidate (discard w/o wback)
  41 #ifndef CONFIG_SYS_DCACHE_OFF
  42         bclr    r5, r5, 0               ; Enable (+Inv)
  43 #else
  44         bset    r5, r5, 0               ; Disable (+Inv)
  45 #endif
  46         sr      r5, [ARC_AUX_DC_CTRL]
  47
  48         mov     r5, 1
  49         sr      r5, [ARC_AUX_DC_IVDC]
  50
  51
  52 1:
  53 #ifdef CONFIG_ISA_ARCV2
  54         ; Disable System-Level Cache (SLC)
  55         lr      r5, [ARC_BCR_SLC]
  56         breq    r5, 0, 1f               ; SLC doesn't exist
  57         lr      r5, [ARC_AUX_SLC_CTRL]
  58         bclr    r5, r5, 6               ; Invalidate (discard w/o wback)
  59         bclr    r5, r5, 0               ; Enable (+Inv)
  60         sr      r5, [ARC_AUX_SLC_CTRL]
  61
  62 1:
  63 #endif
  64
  65         /* Establish C runtime stack and frame */
  66         mov     %sp, CONFIG_SYS_INIT_SP_ADDR
  67         mov     %fp, %sp
  68
  69         /* Allocate reserved area from current top of stack */
  70         mov     %r0, %sp
  71         bl      board_init_f_alloc_reserve
  72         /* Set stack below reserved area, adjust frame pointer accordingly */
  73         mov     %sp, %r0
  74         mov     %fp, %sp
  75
  76         /* Initialize reserved area - note: r0 already contains address */
  77         bl      board_init_f_init_reserve
  78
  79         /* Zero the one and only argument of "board_init_f" */
  80         mov_s   %r0, 0
  81         j       board_init_f
  82 ENDPROC(_start)
  83
  84 /*
  85  * void board_init_f_r_trampoline(stack-pointer address)
  86  *
  87  * This "function" does not return, instead it continues in RAM
  88  * after relocating the monitor code.
  89  *
  90  * r0 = new stack-pointer
  91  */
  92 ENTRY(board_init_f_r_trampoline)
  93         /* Set up the stack- and frame-pointers */
  94         mov     %sp, %r0
  95         mov     %fp, %sp
  96
  97         /* Update position of intterupt vector table */
  98         lr      %r0, [ARC_AUX_INTR_VEC_BASE]
  99         ld      %r1, [%r25, GD_RELOC_OFF]
 100         add     %r0, %r0, %r1
 101         sr      %r0, [ARC_AUX_INTR_VEC_BASE]
 102
 103         /* Re-enter U-Boot by calling board_init_f_r */
 104         j       board_init_f_r
 105 ENDPROC(board_init_f_r_trampoline)