aclocal.m4

   1 dnl Local macros
   2
   3 changequote()
   4 define(RIGHT_BRACKET, ])
   5 changequote([, ])
   6
   7 dnl AC_PROG_PERL([MIN-VERSION])
   8 AC_DEFUN(AC_PROG_PERL,
   9 [# find perl binary
  10 AC_MSG_CHECKING([for perl])
  11 AC_CACHE_VAL(ac_cv_prog_PERL,
  12 [ifelse([$1],,,[echo "configure:__oline__: ...version $1 required" >&AC_FD_CC
  13   ])# allow user to override
  14   if test -n "$PERL"; then
  15     ac_try="$PERL"
  16   else
  17     ac_try="perl perl5"
  18   fi
  19
  20   for ac_prog in $ac_try; do
  21     echo "configure:__oline__: trying $ac_prog" >&AC_FD_CC
  22     if ($ac_prog -e 'printf "found version %g\n",$RIGHT_BRACKET dnl
  23 ifelse([$1],,,[;exit($RIGHT_BRACKET<$1)])') 1>&AC_FD_CC 2>&1; then
  24       ac_cv_prog_PERL=$ac_prog
  25       break
  26     fi
  27   done])dnl
  28 PERL="$ac_cv_prog_PERL"
  29 if test -n "$PERL"; then
  30   AC_MSG_RESULT($PERL)
  31 else
  32   AC_MSG_RESULT(no)
  33 fi
  34 AC_SUBST(PERL)dnl
  35 ])dnl
  36
  37 dnl Check for perl module
  38 dnl AC_PERL_MODULE(MODULE, [MIN-VERSION])
  39 AC_DEFUN(AC_PERL_MODULE,
  40 [# check module exists
  41 AC_MSG_CHECKING([for module $1])
  42 define([AC_CV_NAME], translit([ac_cv_module_$1], [:], [_]))dnl
  43 AC_CACHE_VAL(AC_CV_NAME,
  44 [ifelse([$2],,,[echo "configure:__oline__: ...version $2 required" >&AC_FD_CC
  45   ])if ($PERL -m$1[]ifelse([$2],,,[=$2]) -e 1) 1>&AC_FD_CC 2>&1; then
  46     AC_CV_NAME=yes
  47   else
  48     AC_CV_NAME=no
  49   fi
  50 ])dnl
  51 AC_MSG_RESULT([$]AC_CV_NAME)
  52 ])dnl