aclocal.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # aclocal - create aclocal.m4 by scanning configure.ac
   9
  10 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005
  11 #           Free Software Foundation, Inc.
  12
  13 # This program is free software; you can redistribute it and/or modify
  14 # it under the terms of the GNU General Public License as published by
  15 # the Free Software Foundation; either version 2, or (at your option)
  16 # any later version.
  17
  18 # This program is distributed in the hope that it will be useful,
  19 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 # GNU General Public License for more details.
  22
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301, USA.
  27
  28 # Written by Tom Tromey <tromey@redhat.com>, and
  29 # Alexandre Duret-Lutz <adl@gnu.org>.
  30
  31 BEGIN
  32 {
  33   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  34   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  35 }
  36
  37 use strict;
  38
  39 use Automake::Config;
  40 use Automake::General;
  41 use Automake::Configure_ac;
  42 use Automake::Channels;
  43 use Automake::ChannelDefs;
  44 use Automake::XFile;
  45 use Automake::FileUtils;
  46 use File::Basename;
  47 use File::stat;
  48 use Cwd;
  49
  50 # Some globals.
  51
  52 # Include paths for searching macros.  We search macros in this order:
  53 # user-supplied directories first, then the directory containing the
  54 # automake macros, and finally the system-wide directories for
  55 # third-party macro.  @user_includes can be augmented with -I.
  56 # @system_includes can be augmented with the `dirlist' file.  Also
  57 # --acdir will reset both @automake_includes and @system_includes.
  58 my @user_includes = ();
  59 my @automake_includes = ("@datadir@/aclocal-$APIVERSION");
  60 my @system_includes = ('@datadir@/aclocal');
  61
  62 # Whether we should copy M4 file in $user_includes[0].
  63 my $install = 0;
  64
  65 # --diff
  66 my @diff_command;
  67
  68 # --dry-run
  69 my $dry_run = 0;
  70
  71 # configure.ac or configure.in.
  72 my $configure_ac;
  73
  74 # Output file name.
  75 my $output_file = 'aclocal.m4';
  76
  77 # Option --force.
  78 my $force_output = 0;
  79
  80 # Modification time of the youngest dependency.
  81 my $greatest_mtime = 0;
  82
  83 # Which macros have been seen.
  84 my %macro_seen = ();
  85
  86 # Remember the order into which we scanned the files.
  87 # It's important to output the contents of aclocal.m4 in the opposite order.
  88 # (Definitions in first files we have scanned should override those from
  89 # later files.  So they must appear last in the output.)
  90 my @file_order = ();
  91
  92 # Map macro names to file names.
  93 my %map = ();
  94
  95 # Ditto, but records the last definition of each macro as returned by --trace.
  96 my %map_traced_defs = ();
  97
  98 # Map basenames to macro names.
  99 my %invmap = ();
 100
 101 # Map file names to file contents.
 102 my %file_contents = ();
 103
 104 # Map file names to file types.
 105 my %file_type = ();
 106 use constant FT_USER => 1;
 107 use constant FT_AUTOMAKE => 2;
 108 use constant FT_SYSTEM => 3;
 109
 110 # Map file names to included files (transitively closed).
 111 my %file_includes = ();
 112
 113 # Files which have already been added.
 114 my %file_added = ();
 115
 116 # Files that have already been scanned.
 117 my %scanned_configure_dep = ();
 118
 119 # Serial numbers, for files that have one.
 120 # The key is the basename of the file,
 121 # the value is the serial number represented as a list.
 122 my %serial = ();
 123
 124 # Matches a macro definition.
 125 #   AC_DEFUN([macroname], ...)
 126 # or
 127 #   AC_DEFUN(macroname, ...)
 128 # When macroname is `['-quoted , we accept any character in the name,
 129 # except `]'.  Otherwise macroname stops on the first `]', `,', `)',
 130 # or `\n' encountered.
 131 my $ac_defun_rx =
 132   "(?:AU_ALIAS|A[CU]_DEFUN|AC_DEFUN_ONCE)\\((?:\\[([^]]+)\\]|([^],)\n]+))";
 133
 134 # Matches an AC_REQUIRE line.
 135 my $ac_require_rx = "AC_REQUIRE\\((?:\\[([^]]+)\\]|([^],)\n]+))\\)";
 136
 137 # Matches an m4_include line
 138 my $m4_include_rx = "(?:m4_)?(s?)include\\((?:\\[([^]]+)\\]|([^],)\n]+))\\)";
 139
 140 # Match a serial number
 141 my $serial_line_rx = '^#\s*serial\s+(\S*)';
 142 my $serial_number_rx = '^\d+(?:\.\d+)*$';
 143 \f
 144 ################################################################
 145
 146 # Check macros in acinclude.m4.  If one is not used, warn.
 147 sub check_acinclude ()
 148 {
 149   foreach my $key (keys %map)
 150     {
 151       # FIXME: should print line number of acinclude.m4.
 152       msg ('syntax', "warning: macro `$key' defined in "
 153            . "acinclude.m4 but never used")
 154         if $map{$key} eq 'acinclude.m4' && ! exists $macro_seen{$key};
 155     }
 156 }
 157
 158 sub reset_maps ()
 159 {
 160   $greatest_mtime = 0;
 161   %macro_seen = ();
 162   @file_order = ();
 163   %map = ();
 164   %map_traced_defs = ();
 165   %file_contents = ();
 166   %file_type = ();
 167   %file_includes = ();
 168   %file_added = ();
 169   %scanned_configure_dep = ();
 170   %invmap = ();
 171   %serial = ();
 172   undef &search;
 173 }
 174
 175 # install_file ($SRC, $DEST)
 176 sub install_file ($$)
 177 {
 178   my ($src, $dest) = @_;
 179   my $diff_dest = $dest;
 180
 181   if ($force_output
 182       || !exists $file_contents{$dest}
 183       || $file_contents{$src} ne $file_contents{$dest})
 184     {
 185       if (-e $dest)
 186         {
 187           msg 'note', "overwriting `$dest' with `$src'";
 188         }
 189       else
 190         {
 191           msg 'note', "installing `$dest' from `$src'";
 192           $diff_dest = '/dev/null';
 193         }
 194
 195       if (@diff_command)
 196         {
 197           my @cmd = (@diff_command, $diff_dest, $src);
 198           $! = 0;
 199           verb "running: @cmd";
 200           my $res = system (@cmd);
 201           Automake::FileUtils::handle_exec_errors "@cmd", 1
 202             if $res;
 203         }
 204       elsif (!$dry_run)
 205         {
 206           xsystem ('cp', $src, $dest);
 207         }
 208     }
 209 }
 210
 211 # Compare two lists of numbers.
 212 sub list_compare (\@\@)
 213 {
 214   my @l = @{$_[0]};
 215   my @r = @{$_[1]};
 216   while (1)
 217     {
 218       if (0 == @l)
 219         {
 220           return (0 == @r) ? 0 : -1;
 221         }
 222       elsif (0 == @r)
 223         {
 224           return 1;
 225         }
 226       elsif ($l[0] < $r[0])
 227         {
 228           return -1;
 229         }
 230       elsif ($l[0] > $r[0])
 231         {
 232           return 1;
 233         }
 234       shift @l;
 235       shift @r;
 236     }
 237 }
 238
 239 ################################################################
 240
 241 # scan_m4_dirs($TYPE, @DIRS)
 242 # --------------------------
 243 # Scan all M4 files installed in @DIRS for new macro definitions.
 244 # Register each file as of type $TYPE (one of the FT_* constants).
 245 sub scan_m4_dirs ($@)
 246 {
 247   my ($type, @dirlist) = @_;
 248
 249   foreach my $m4dir (@dirlist)
 250     {
 251       if (! opendir (DIR, $m4dir))
 252         {
 253           fatal "couldn't open directory `$m4dir': $!";
 254         }
 255
 256       # We reverse the directory contents so that foo2.m4 gets
 257       # used in preference to foo1.m4.
 258       foreach my $file (reverse sort grep (! /^\./, readdir (DIR)))
 259         {
 260           # Only examine .m4 files.
 261           next unless $file =~ /\.m4$/;
 262
 263           # Skip some files when running out of srcdir.
 264           next if $file eq 'aclocal.m4';
 265
 266           my $fullfile = File::Spec->canonpath ("$m4dir/$file");
 267             &scan_file ($type, $fullfile, 'aclocal');
 268         }
 269       closedir (DIR);
 270     }
 271 }
 272
 273 # Scan all the installed m4 files and construct a map.
 274 sub scan_m4_files ()
 275 {
 276   # First, scan configure.ac.  It may contain macro definitions,
 277   # or may include other files that define macros.
 278   &scan_file (FT_USER, $configure_ac, 'aclocal');
 279
 280   # Then, scan acinclude.m4 if it exists.
 281   if (-f 'acinclude.m4')
 282     {
 283       &scan_file (FT_USER, 'acinclude.m4', 'aclocal');
 284     }
 285
 286   # Finally, scan all files in our search paths.
 287   scan_m4_dirs (FT_USER, @user_includes);
 288   scan_m4_dirs (FT_AUTOMAKE, @automake_includes);
 289   scan_m4_dirs (FT_SYSTEM, @system_includes);
 290
 291   # Construct a new function that does the searching.  We use a
 292   # function (instead of just evaluating $search in the loop) so that
 293   # "die" is correctly and easily propagated if run.
 294   my $search = "sub search {\nmy \$found = 0;\n";
 295   foreach my $key (reverse sort keys %map)
 296     {
 297       $search .= ('if (/\b\Q' . $key . '\E(?!\w)/) { & add_macro ("' . $key
 298                   . '"); $found = 1; }' . "\n");
 299     }
 300   $search .= "return \$found;\n};\n";
 301   eval $search;
 302   prog_error "$@\n search is $search" if $@;
 303 }
 304
 305 ################################################################
 306
 307 # Add a macro to the output.
 308 sub add_macro ($)
 309 {
 310   my ($macro) = @_;
 311
 312   # Ignore unknown required macros.  Either they are not really
 313   # needed (e.g., a conditional AC_REQUIRE), in which case aclocal
 314   # should be quiet, or they are needed and Autoconf itself will
 315   # complain when we trace for macro usage later.
 316   return unless defined $map{$macro};
 317
 318   verb "saw macro $macro";
 319   $macro_seen{$macro} = 1;
 320   &add_file ($map{$macro});
 321 }
 322
 323 # scan_configure_dep ($file)
 324 # --------------------------
 325 # Scan a configure dependency (configure.ac, or separate m4 files)
 326 # for uses of known macros and AC_REQUIREs of possibly unknown macros.
 327 # Recursively scan m4_included files.
 328 sub scan_configure_dep ($)
 329 {
 330   my ($file) = @_;
 331   # Do not scan a file twice.
 332   return ()
 333     if exists $scanned_configure_dep{$file};
 334   $scanned_configure_dep{$file} = 1;
 335
 336   my $mtime = mtime $file;
 337   $greatest_mtime = $mtime if $greatest_mtime < $mtime;
 338
 339   my $contents = exists $file_contents{$file} ?
 340     $file_contents{$file} : contents $file;
 341
 342   my $line = 0;
 343   my @rlist = ();
 344   my @ilist = ();
 345   foreach (split ("\n", $contents))
 346     {
 347       ++$line;
 348       # Remove comments from current line.
 349       s/\bdnl\b.*$//;
 350       s/\#.*$//;
 351
 352       while (/$m4_include_rx/go)
 353         {
 354           my $ifile = $2 || $3;
 355           # Skip missing `sinclude'd files.
 356           next if $1 eq 's' && ! -f $ifile;
 357           push @ilist, $ifile;
 358         }
 359
 360       while (/$ac_require_rx/go)
 361         {
 362           push (@rlist, $1 || $2);
 363         }
 364
 365       # The search function is constructed dynamically by
 366       # scan_m4_files.  The last parenthetical match makes sure we
 367       # don't match things that look like macro assignments or
 368       # AC_SUBSTs.
 369       if (! &search && /(^|\s+)(AM_[A-Z0-9_]+)($|[^\]\)=A-Z0-9_])/)
 370         {
 371           # Macro not found, but AM_ prefix found.
 372           # Make this just a warning, because we do not know whether
 373           # the macro is actually used (it could be called conditionally).
 374           msg ('unsupported', "$file:$line",
 375                "warning: macro `$2' not found in library");
 376         }
 377     }
 378
 379   add_macro ($_) foreach (@rlist);
 380   &scan_configure_dep ($_) foreach @ilist;
 381 }
 382
 383 # add_file ($FILE)
 384 # ----------------
 385 # Add $FILE to output.
 386 sub add_file ($)
 387 {
 388   my ($file) = @_;
 389
 390   # Only add a file once.
 391   return if ($file_added{$file});
 392   $file_added{$file} = 1;
 393
 394   scan_configure_dep $file;
 395 }
 396
 397 # Point to the documentation for underquoted AC_DEFUN only once.
 398 my $underquoted_manual_once = 0;
 399
 400 # scan_file ($TYPE, $FILE, $WHERE)
 401 # --------------------------------
 402 # Scan a single M4 file ($FILE), and all files it includes.
 403 # Return the list of included files.
 404 # $TYPE is one of FT_USER, FT_AUTOMAKE, or FT_SYSTEM, depending
 405 # on where the file comes from.
 406 # $WHERE is the location to use in the diagnostic if the file
 407 # does not exist.
 408 sub scan_file ($$$)
 409 {
 410   my ($type, $file, $where) = @_;
 411   my $basename = basename $file;
 412
 413   # Do not scan the same file twice.
 414   return @{$file_includes{$file}} if exists $file_includes{$file};
 415   # Prevent potential infinite recursion (if two files include each other).
 416   return () if exists $file_contents{$file};
 417
 418   unshift @file_order, $file;
 419
 420   $file_type{$file} = $type;
 421
 422   fatal "$where: file `$file' does not exist" if ! -e $file;
 423
 424   my $fh = new Automake::XFile $file;
 425   my $contents = '';
 426   my @inc_files = ();
 427   my %inc_lines = ();
 428
 429   my $defun_seen = 0;
 430   my $serial_seen = 0;
 431   my $serial_older = 0;
 432
 433   while ($_ = $fh->getline)
 434     {
 435       # Ignore `##' lines.
 436       next if /^##/;
 437
 438       $contents .= $_;
 439       my $line = $_;
 440
 441       if ($line =~ /$serial_line_rx/go)
 442         {
 443           my $number = $1;
 444           if ($number !~ /$serial_number_rx/go)
 445             {
 446               msg ('syntax', "$file:$.",
 447                    "warning: ill-formed serial number `$number', "
 448                    . "expecting a version string with only digits and dots");
 449             }
 450           elsif ($defun_seen)
 451             {
 452               # aclocal removes all definitions from M4 file with the
 453               # same basename if a greater serial number is found.
 454               # Encountering a serial after some macros will undefine
 455               # these macros...
 456               msg ('syntax', "$file:$.",
 457                    'the serial number must appear before any macro definition');
 458             }
 459           # We really care about serials only for non-automake macros
 460           # and when --install is used.  But the above diagnostics are
 461           # made regardless of this, because not using --install is
 462           # not a reason not the fix macro files.
 463           elsif ($install && $type != FT_AUTOMAKE)
 464             {
 465               $serial_seen = 1;
 466               my @new = split (/\./, $number);
 467
 468               verb "$file:$.: serial $number";
 469
 470               if (!exists $serial{$basename}
 471                   || list_compare (@new, @{$serial{$basename}}) > 0)
 472                 {
 473                   # Delete any definition we knew from the old macro.
 474                   foreach my $def (@{$invmap{$basename}})
 475                     {
 476                       verb "$file:$.: ignoring previous definition of $def";
 477                       delete $map{$def};
 478                     }
 479                   $invmap{$basename} = [];
 480                   $serial{$basename} = \@new;
 481                 }
 482               else
 483                 {
 484                   $serial_older = 1;
 485                 }
 486             }
 487         }
 488
 489       while ($line =~ /$ac_defun_rx/go)
 490         {
 491           $defun_seen = 1;
 492           if (! defined $1)
 493             {
 494               msg ('syntax', "$file:$.", "warning: underquoted definition of $2"
 495                    . "\n  run info '(automake)Extending aclocal'\n"
 496                    . "  or see http://sources.redhat.com/automake/"
 497                    . "automake.html#Extending-aclocal")
 498                 unless $underquoted_manual_once;
 499               $underquoted_manual_once = 1;
 500             }
 501
 502           # If this macro does not have a serial and we have already
 503           # seen a macro with the same basename earlier, we should
 504           # ignore the macro (don't exit immediately so we can still
 505           # diagnose later #serial numbers and underquoted macros).
 506           $serial_older ||= ($type != FT_AUTOMAKE
 507                              && !$serial_seen && exists $serial{$basename});
 508
 509           my $macro = $1 || $2;
 510           if (!$serial_older && !defined $map{$macro})
 511             {
 512               verb "found macro $macro in $file: $.";
 513               $map{$macro} = $file;
 514               push @{$invmap{$basename}}, $macro;
 515             }
 516           else
 517             {
 518               # Note: we used to give an error here if we saw a
 519               # duplicated macro.  However, this turns out to be
 520               # extremely unpopular.  It causes actual problems which
 521               # are hard to work around, especially when you must
 522               # mix-and-match tool versions.
 523               verb "ignoring macro $macro in $file: $.";
 524             }
 525         }
 526
 527       while ($line =~ /$m4_include_rx/go)
 528         {
 529           my $ifile = $2 || $3;
 530           # Skip missing `sinclude'd files.
 531           next if $1 eq 's' && ! -f $ifile;
 532           push (@inc_files, $ifile);
 533           $inc_lines{$ifile} = $.;
 534         }
 535     }
 536
 537   # Ignore any file that has an old serial (or no serial if we know
 538   # another one with a serial).
 539   return ()
 540     if ($serial_older ||
 541         ($type != FT_AUTOMAKE && !$serial_seen && exists $serial{$basename}));
 542
 543   $file_contents{$file} = $contents;
 544
 545   # For some reason I don't understand, it does not work
 546   # to do `map { scan_file ($_, ...) } @inc_files' below.
 547   # With Perl 5.8.2 it undefines @inc_files.
 548   my @copy = @inc_files;
 549   my @all_inc_files = (@inc_files,
 550                        map { scan_file ($type, $_,
 551                                         "$file:$inc_lines{$_}") } @copy);
 552   $file_includes{$file} = \@all_inc_files;
 553   return @all_inc_files;
 554 }
 555
 556 # strip_redundant_includes (%FILES)
 557 # ---------------------------------
 558 # Each key in %FILES is a file that must be present in the output.
 559 # However some of these files might already include other files in %FILES,
 560 # so there is no point in including them another time.
 561 # This removes items of %FILES which are already included by another file.
 562 sub strip_redundant_includes (%)
 563 {
 564   my %files = @_;
 565
 566   # Always include acinclude.m4, even if it does not appear to be used.
 567   $files{'acinclude.m4'} = 1 if -f 'acinclude.m4';
 568   # File included by $configure_ac are redundant.
 569   $files{$configure_ac} = 1;
 570
 571   # Files at the end of @file_order should override those at the beginning,
 572   # so it is important to preserve these trailing files.  We can remove
 573   # a file A if it is going to be output before a file B that includes
 574   # file A, not the converse.
 575   foreach my $file (reverse @file_order)
 576     {
 577       next unless exists $files{$file};
 578       foreach my $ifile (@{$file_includes{$file}})
 579         {
 580           next unless exists $files{$ifile};
 581           delete $files{$ifile};
 582           verb "$ifile is already included by $file";
 583         }
 584     }
 585
 586   # configure.ac is implicitly included.
 587   delete $files{$configure_ac};
 588
 589   return %files;
 590 }
 591
 592 sub trace_used_macros ()
 593 {
 594   my %files = map { $map{$_} => 1 } keys %macro_seen;
 595   %files = strip_redundant_includes %files;
 596
 597   my $traces = ($ENV{AUTOM4TE} || 'autom4te');
 598   $traces .= " --language Autoconf-without-aclocal-m4 ";
 599   # All candidate files.
 600   $traces .= join (' ', grep { exists $files{$_} } @file_order) . " ";
 601   # All candidate macros.
 602   $traces .= join (' ',
 603                    (map { "--trace='$_:\$f::\$n::\$1'" } ('AC_DEFUN',
 604                                                           'AC_DEFUN_ONCE',
 605                                                           'AU_DEFUN')),
 606                    # Do not trace $1 for all other macros as we do
 607                    # not need it and it might contains harmful
 608                    # characters (like newlines).
 609                    (map { "--trace='$_:\$f::\$n'" } (keys %macro_seen)));
 610
 611   verb "running $traces $configure_ac";
 612
 613   my $tracefh = new Automake::XFile ("$traces $configure_ac |");
 614
 615   my %traced = ();
 616
 617   while ($_ = $tracefh->getline)
 618     {
 619       chomp;
 620       my ($file, $macro, $arg1) = split (/::/);
 621
 622       $traced{$macro} = 1 if exists $macro_seen{$macro};
 623
 624       $map_traced_defs{$arg1} = $file
 625         if ($macro eq 'AC_DEFUN'
 626             || $macro eq 'AC_DEFUN_ONCE'
 627             || $macro eq 'AU_DEFUN');
 628     }
 629
 630   $tracefh->close;
 631
 632   return %traced;
 633 }
 634
 635 sub scan_configure ()
 636 {
 637   # Make sure we include acinclude.m4 if it exists.
 638   if (-f 'acinclude.m4')
 639     {
 640       add_file ('acinclude.m4');
 641     }
 642   scan_configure_dep ($configure_ac);
 643 }
 644
 645 ################################################################
 646
 647 # Write output.
 648 # Return 0 iff some files were installed locally.
 649 sub write_aclocal ($@)
 650 {
 651   my ($output_file, @macros) = @_;
 652   my $output = '';
 653
 654   my %files = ();
 655   # Get the list of files containing definitions for the macros used.
 656   # (Filter out unused macro definitions with $map_traced_defs.  This
 657   # can happen when an Autoconf macro is conditionally defined:
 658   # aclocal sees the potential definition, but this definition is
 659   # actually never processed and the Autoconf implementation is used
 660   # instead.)
 661   for my $m (@macros)
 662     {
 663       $files{$map{$m}} = 1
 664         if (exists $map_traced_defs{$m}
 665             && $map{$m} eq $map_traced_defs{$m});
 666     }
 667   # Do not explicitly include a file that is already indirectly included.
 668   %files = strip_redundant_includes %files;
 669
 670   my $installed = 0;
 671
 672   for my $file (grep { exists $files{$_} } @file_order)
 673     {
 674       # Check the time stamp of this file, and of all files it includes.
 675       for my $ifile ($file, @{$file_includes{$file}})
 676         {
 677           my $mtime = mtime $ifile;
 678           $greatest_mtime = $mtime if $greatest_mtime < $mtime;
 679         }
 680
 681       # If the file to add looks like outside the project, copy it
 682       # to the output.  The regex catches filenames starting with
 683       # things like `/', `\', or `c:\'.
 684       if ($file_type{$file} != FT_USER
 685           || $file =~ m,^(?:\w:)?[\\/],)
 686         {
 687           if (!$install || $file_type{$file} != FT_SYSTEM)
 688             {
 689               # Copy the file into aclocal.m4.
 690               $output .= $file_contents{$file} . "\n";
 691             }
 692           else
 693             {
 694               # Install the file (and any file it includes).
 695               my $dest;
 696               for my $ifile (@{$file_includes{$file}}, $file)
 697                 {
 698                   $dest = "$user_includes[0]/" . basename $ifile;
 699                   verb "installing $ifile to $dest";
 700                   install_file ($ifile, $dest);
 701                 }
 702               $installed = 1;
 703             }
 704         }
 705       else
 706         {
 707           # Otherwise, simply include the file.
 708           $output .= "m4_include([$file])\n";
 709         }
 710     }
 711
 712   if ($installed)
 713     {
 714       verb "running aclocal anew, because some files were installed locally";
 715       return 0;
 716     }
 717
 718   # Nothing to output?!
 719   # FIXME: Shouldn't we diagnose this?
 720   return 1 if ! length ($output);
 721
 722   # We used to print `# $output_file generated automatically etc.'  But
 723   # this creates spurious differences when using autoreconf.  Autoreconf
 724   # creates aclocal.m4t and then rename it to aclocal.m4, but the
 725   # rebuild rules generated by Automake create aclocal.m4 directly --
 726   # this would gives two ways to get the same file, with a different
 727   # name in the header.
 728   $output = "# generated automatically by aclocal $VERSION -*- Autoconf -*-
 729
 730 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
 731 # 2005  Free Software Foundation, Inc.
 732 # This file is free software; the Free Software Foundation
 733 # gives unlimited permission to copy and/or distribute it,
 734 # with or without modifications, as long as this notice is preserved.
 735
 736 # This program is distributed in the hope that it will be useful,
 737 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 738 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 739 # PARTICULAR PURPOSE.
 740
 741 $output";
 742
 743   # We try not to update $output_file unless necessary, because
 744   # doing so invalidate Autom4te's cache and therefore slows down
 745   # tools called after aclocal.
 746   #
 747   # We need to overwrite $output_file in the following situations.
 748   #   * The --force option is in use.
 749   #   * One of the dependencies is younger.
 750   #     (Not updating $output_file in this situation would cause
 751   #     make to call aclocal in loop.)
 752   #   * The contents of the current file are different from what
 753   #     we have computed.
 754   if (!$force_output
 755       && $greatest_mtime < mtime ($output_file)
 756       && $output eq contents ($output_file))
 757     {
 758       verb "$output_file unchanged";
 759       return 1;
 760     }
 761
 762   verb "writing $output_file";
 763
 764   if (!$dry_run)
 765     {
 766       my $out = new Automake::XFile "> $output_file";
 767       print $out $output;
 768     }
 769   return 1;
 770 }
 771
 772 ################################################################
 773
 774 # Print usage and exit.
 775 sub usage ($)
 776 {
 777   my ($status) = @_;
 778
 779   print "Usage: aclocal [OPTIONS] ...
 780
 781 Generate `aclocal.m4' by scanning `configure.ac' or `configure.in'
 782
 783 Options:
 784       --acdir=DIR           directory holding config files (for debugging)
 785       --diff[=COMMAND]      run COMMAND [diff -u] on M4 files that would be
 786                               changed (implies --install and --dry-run)
 787       --dry-run             pretend to, but do not actually update any file
 788       --force               always update output file
 789       --help                print this help, then exit
 790   -I DIR                    add directory to search list for .m4 files
 791       --install             copy third-party files to the first -I directory
 792       --output=FILE         put output in FILE (default aclocal.m4)
 793       --print-ac-dir        print name of directory holding m4 files, then exit
 794       --verbose             don't be silent
 795       --version             print version number, then exit
 796   -W, --warnings=CATEGORY   report the warnings falling in CATEGORY
 797
 798 Warning categories include:
 799   `syntax'        dubious syntactic constructs (default)
 800   `unsupported'   unknown macros (default)
 801   `all'           all the warnings (default)
 802   `no-CATEGORY'   turn off warnings in CATEGORY
 803   `none'          turn off all the warnings
 804   `error'         treat warnings as errors
 805
 806 Report bugs to <bug-automake\@gnu.org>.\n";
 807
 808   exit $status;
 809 }
 810
 811 # Print version and exit.
 812 sub version()
 813 {
 814   print <<EOF;
 815 aclocal (GNU $PACKAGE) $VERSION
 816 Written by Tom Tromey <tromey\@redhat.com>
 817        and Alexandre Duret-Lutz <adl\@gnu.org>.
 818
 819 Copyright (C) 2005 Free Software Foundation, Inc.
 820 This is free software; see the source for copying conditions.  There is NO
 821 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 822 EOF
 823   exit 0;
 824 }
 825
 826 # Parse command line.
 827 sub parse_arguments ()
 828 {
 829   my $print_and_exit = 0;
 830   my $diff_command;
 831
 832   my %cli_options =
 833     (
 834      'acdir=s'          => sub # Setting --acdir overrides both the
 835                              { # automake (versioned) directory and the
 836                                # public (unversioned) system directory.
 837                                @automake_includes = ();
 838                                @system_includes = ($_[1])
 839                              },
 840      'diff:s'           => \$diff_command,
 841      'dry-run'          => \$dry_run,
 842      'force'            => \$force_output,
 843      'I=s'              => \@user_includes,
 844      'install'          => \$install,
 845      'output=s'         => \$output_file,
 846      'print-ac-dir'     => \$print_and_exit,
 847      'verbose'          => sub { setup_channel 'verb', silent => 0; },
 848      'W|warnings=s'     => \&parse_warnings,
 849      );
 850   use Getopt::Long;
 851   Getopt::Long::config ("bundling", "pass_through");
 852
 853   # See if --version or --help is used.  We want to process these before
 854   # anything else because the GNU Coding Standards require us to
 855   # `exit 0' after processing these options, and we can't guarantee this
 856   # if we treat other options first.  (Handling other options first
 857   # could produce error diagnostics, and in this condition it is
 858   # confusing if aclocal does `exit 0'.)
 859   my %cli_options_1st_pass =
 860     (
 861      'version' => \&version,
 862      'help'    => sub { usage(0); },
 863      # Recognize all other options (and their arguments) but do nothing.
 864      map { $_ => sub {} } (keys %cli_options)
 865      );
 866   my @ARGV_backup = @ARGV;
 867   Getopt::Long::GetOptions %cli_options_1st_pass
 868     or exit 1;
 869   @ARGV = @ARGV_backup;
 870
 871   # Now *really* process the options.  This time we know that --help
 872   # and --version are not present, but we specify them nonetheless so
 873   # that ambiguous abbreviation are diagnosed.
 874   Getopt::Long::GetOptions %cli_options, 'version' => sub {}, 'help' => sub {}
 875     or exit 1;
 876
 877   if (@ARGV)
 878     {
 879       my %argopts;
 880       for my $k (keys %cli_options)
 881         {
 882           if ($k =~ /(.*)=s$/)
 883             {
 884               map { $argopts{(length ($_) == 1)
 885                              ? "-$_" : "--$_" } = 1; } (split (/\|/, $1));
 886             }
 887         }
 888       if (exists $argopts{$ARGV[0]})
 889         {
 890           fatal ("option `$ARGV[0]' requires an argument\n"
 891                  . "Try `$0 --help' for more information.");
 892         }
 893       else
 894         {
 895           fatal ("unrecognized option `$ARGV[0]'\n"
 896                  . "Try `$0 --help' for more information.");
 897         }
 898     }
 899
 900   if ($print_and_exit)
 901     {
 902       print "@system_includes\n";
 903       exit 0;
 904     }
 905
 906   if (defined $diff_command)
 907     {
 908       $diff_command = 'diff -u' if $diff_command eq '';
 909       @diff_command = split (' ', $diff_command);
 910       $install = 1;
 911       $dry_run = 1;
 912     }
 913
 914   if ($install && !@user_includes)
 915     {
 916       fatal ("--install should copy macros in the directory indicated by the"
 917              . "\nfirst -I option, but no -I was supplied.");
 918     }
 919
 920   if (! -d $system_includes[0])
 921     {
 922       # By default $(datadir)/aclocal doesn't exist.  We don't want to
 923       # get an error in the case where we are searching the default
 924       # directory and it hasn't been created.  (We know
 925       # @system_includes has its default value if @automake_includes
 926       # is not empty, because --acdir is the only way to change this.)
 927       @system_includes = () if @automake_includes;
 928     }
 929   else
 930     {
 931       # Finally, adds any directory listed in the `dirlist' file.
 932       if (open (DIRLIST, "$system_includes[0]/dirlist"))
 933         {
 934           while (<DIRLIST>)
 935             {
 936               # Ignore '#' lines.
 937               next if /^#/;
 938               # strip off newlines and end-of-line comments
 939               s/\s*\#.*$//;
 940               chomp;
 941               push (@system_includes, $_) if -d $_;
 942             }
 943           close (DIRLIST);
 944         }
 945     }
 946 }
 947
 948 ################################################################
 949
 950 parse_WARNINGS;             # Parse the WARNINGS environment variable.
 951 parse_arguments;
 952 $configure_ac = require_configure_ac;
 953
 954 # We may have to rerun aclocal if some file have been installed, but
 955 # it should not happen more than once.  The reason we must run again
 956 # is that once the file has been moved from /usr/share/aclocal/ to the
 957 # local m4/ directory it appears at a new place in the search path,
 958 # hence it should be output at a different position in aclocal.m4.  If
 959 # we did not rerun aclocal, the next run of aclocal would produce a
 960 # different aclocal.m4.
 961 my $loop = 0;
 962 while (1)
 963   {
 964     ++$loop;
 965     prog_error "Too many loops." if $loop > 2;
 966
 967     reset_maps;
 968     scan_m4_files;
 969     scan_configure;
 970     last if $exit_code;
 971     my %macro_traced = trace_used_macros;
 972     last if write_aclocal ($output_file, keys %macro_traced);
 973     last if $dry_run;
 974   }
 975 check_acinclude;
 976
 977 exit $exit_code;
 978
 979 ### Setup "GNU" style for perl-mode and cperl-mode.
 980 ## Local Variables:
 981 ## perl-indent-level: 2
 982 ## perl-continued-statement-offset: 2
 983 ## perl-continued-brace-offset: 0
 984 ## perl-brace-offset: 0
 985 ## perl-brace-imaginary-offset: 0
 986 ## perl-label-offset: -2
 987 ## cperl-indent-level: 2
 988 ## cperl-brace-offset: 0
 989 ## cperl-continued-brace-offset: 0
 990 ## cperl-label-offset: -2
 991 ## cperl-extra-newline-before-brace: t
 992 ## cperl-merge-trailing-else: nil
 993 ## cperl-continued-statement-offset: 2
 994 ## End: