acinclude.m4

   1
   2 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
   3 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
   4 dnl also defines GSTUFF_PKG_ERRORS on error
   5 AC_DEFUN([PKG_CHECK_MODULES], [
   6   succeeded=no
   7
   8   if test -z "$PKG_CONFIG"; then
   9     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  10   fi
  11
  12   if test "$PKG_CONFIG" = "no" ; then
  13      echo "*** The pkg-config script could not be found. Make sure it is"
  14      echo "*** in your path, or set the PKG_CONFIG environment variable"
  15      echo "*** to the full path to pkg-config."
  16      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
  17   else
  18      PKG_CONFIG_MIN_VERSION=0.9.0
  19      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
  20         AC_MSG_CHECKING(for $2)
  21
  22         if $PKG_CONFIG --exists "$2" ; then
  23             AC_MSG_RESULT(yes)
  24             succeeded=yes
  25
  26             AC_MSG_CHECKING($1_CFLAGS)
  27             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
  28             AC_MSG_RESULT($$1_CFLAGS)
  29
  30             AC_MSG_CHECKING($1_LIBS)
  31             $1_LIBS=`$PKG_CONFIG --libs "$2"`
  32             AC_MSG_RESULT($$1_LIBS)
  33         else
  34             $1_CFLAGS=""
  35             $1_LIBS=""
  36             ## If we have a custom action on failure, don't print errors, but
  37             ## do set a variable so people can do so.
  38             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
  39             ifelse([$4], ,echo $$1_PKG_ERRORS,)
  40         fi
  41
  42         AC_SUBST($1_CFLAGS)
  43         AC_SUBST($1_LIBS)
  44      else
  45         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
  46         echo "*** See http://www.freedesktop.org/software/pkgconfig"
  47      fi
  48   fi
  49
  50   if test $succeeded = yes; then
  51      ifelse([$3], , :, [$3])
  52   else
  53      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
  54   fi
  55 ])
  56
  57
  58
  59 dnl a macro to check for ability to create python extensions
  60 dnl  AM_CHECK_PYTHON_HEADERS([ACTION-IF-POSSIBLE], [ACTION-IF-NOT-POSSIBLE])
  61 dnl function also defines PYTHON_INCLUDES
  62 AC_DEFUN([AM_CHECK_PYTHON_HEADERS],
  63 [AC_REQUIRE([AM_PATH_PYTHON])
  64 AC_MSG_CHECKING(for headers required to compile python extensions)
  65 dnl deduce PYTHON_INCLUDES
  66 py_prefix=`$PYTHON -c "import sys; print sys.prefix"`
  67 py_exec_prefix=`$PYTHON -c "import sys; print sys.exec_prefix"`
  68 PYTHON_INCLUDES="-I${py_prefix}/include/python${PYTHON_VERSION}"
  69 if test "$py_prefix" != "$py_exec_prefix"; then
  70   PYTHON_INCLUDES="$PYTHON_INCLUDES -I${py_exec_prefix}/include/python${PYTHON_VERSION}"
  71 fi
  72 AC_SUBST(PYTHON_INCLUDES)
  73 dnl check if the headers exist:
  74 save_CPPFLAGS="$CPPFLAGS"
  75 CPPFLAGS="$CPPFLAGS $PYTHON_INCLUDES"
  76 AC_TRY_CPP([#include <Python.h>],dnl
  77 [AC_MSG_RESULT(found)
  78 $1],dnl
  79 [AC_MSG_RESULT(not found)
  80 $2])
  81 CPPFLAGS="$save_CPPFLAGS"
  82 ])
  83
  84
  85 dnl as-ac-expand.m4 0.2.0                                   -*- autoconf -*-
  86 dnl autostars m4 macro for expanding directories using configure's prefix
  87
  88 dnl (C) 2003, 2004, 2005 Thomas Vander Stichele <thomas at apestaart dot org>
  89
  90 dnl Copying and distribution of this file, with or without modification,
  91 dnl are permitted in any medium without royalty provided the copyright
  92 dnl notice and this notice are preserved.
  93
  94 dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
  95
  96 dnl example:
  97 dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
  98 dnl will set SYSCONFDIR to /usr/local/etc if prefix=/usr/local
  99
 100 AC_DEFUN([AS_AC_EXPAND],
 101 [
 102   EXP_VAR=[$1]
 103   FROM_VAR=[$2]
 104
 105   dnl first expand prefix and exec_prefix if necessary
 106   prefix_save=$prefix
 107   exec_prefix_save=$exec_prefix
 108
 109   dnl if no prefix given, then use /usr/local, the default prefix
 110   if test "x$prefix" = "xNONE"; then
 111     prefix="$ac_default_prefix"
 112   fi
 113   dnl if no exec_prefix given, then use prefix
 114   if test "x$exec_prefix" = "xNONE"; then
 115     exec_prefix=$prefix
 116   fi
 117
 118   full_var="$FROM_VAR"
 119   dnl loop until it doesn't change anymore
 120   while true; do
 121     new_full_var="`eval echo $full_var`"
 122     if test "x$new_full_var" = "x$full_var"; then break; fi
 123     full_var=$new_full_var
 124   done
 125
 126   dnl clean up
 127   full_var=$new_full_var
 128   AC_SUBST([$1], "$full_var")
 129
 130   dnl restore prefix and exec_prefix
 131   prefix=$prefix_save
 132   exec_prefix=$exec_prefix_save
 133 ])