Tools/Scripts/report-include-statistics

   1 #!/usr/bin/perl -w
   2
   3 # Copyright (C) 2005, 2006 Apple Computer, Inc.  All rights reserved.
   4 #
   5 # Redistribution and use in source and binary forms, with or without
   6 # modification, are permitted provided that the following conditions
   7 # are met:
   8 #
   9 # 1.  Redistributions of source code must retain the above copyright
  10 #     notice, this list of conditions and the following disclaimer.
  11 # 2.  Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in the
  13 #     documentation and/or other materials provided with the distribution.
  14 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
  15 #     its contributors may be used to endorse or promote products derived
  16 #     from this software without specific prior written permission.
  17 #
  18 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
  19 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  21 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
  22 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  23 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  24 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  25 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  26 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  27 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28
  29 # "report-include-statistics" script for WebKit Open Source Project
  30
  31 use strict;
  32 use File::Find;
  33
  34 find(\&wanted, @ARGV ? @ARGV : ".");
  35
  36 my %paths;
  37 my %sources;
  38 my %includes;
  39
  40 sub wanted
  41 {
  42     my $file = $_;
  43
  44     if ($file eq "icu") {
  45         $File::Find::prune = 1;
  46         return;
  47     }
  48
  49     if ($file !~ /^\./ && $file =~ /\.(h|cpp|c|mm|m)$/) {
  50         $paths{$file} = $File::Find::name;
  51         $sources{$file} = $File::Find::name if $file !~ /\.h/;
  52         open FILE, $file or die;
  53         while (<FILE>) {
  54             if (m-^\s*#\s*(include|import)\s+["<]((\S+/)*)(\S+)[">]-) {
  55                 my $include = ($2 eq "sys/" ? $2 : "") . $4;
  56                 $includes{$file}{$include}++;
  57             }
  58         }
  59         close FILE;
  60     }
  61 }
  62
  63 my %totalIncludes;
  64
  65 sub fillOut
  66 {
  67     my ($file) = @_;
  68
  69     return if defined $totalIncludes{$file};
  70
  71     for my $include (keys %{ $includes{$file} }) {
  72         $totalIncludes{$file}{$include} = 1;
  73         fillOut($include);
  74         for my $i (keys %{ $totalIncludes{$include} }) {
  75             $totalIncludes{$file}{$i} = 1;
  76         }
  77     }
  78 }
  79
  80 my %inclusionCounts;
  81 for my $file (keys %includes) {
  82     $inclusionCounts{$file} = 0;
  83     fillOut($file);
  84 }
  85
  86 for my $file (keys %sources) {
  87     for my $include (keys %{ $totalIncludes{$file} }) {
  88         $inclusionCounts{$include}++;
  89     }
  90 }
  91
  92 for my $file (sort mostincludedcmp keys %includes) {
  93     next if !$paths{$file};
  94     my $count = $inclusionCounts{$file};
  95     my $numIncludes = keys %{ $includes{$file} };
  96     my $numTotalIncludes = keys %{ $totalIncludes{$file} };
  97     print "$file is included $count times, includes $numIncludes files directly, $numTotalIncludes files total.\n"
  98 }
  99
 100 # Sort most-included files first.
 101 sub mostincludedcmp($$)
 102 {
 103     my ($filea, $fileb) = @_;
 104
 105     my $counta = $inclusionCounts{$filea} || 0;
 106     my $countb = $inclusionCounts{$fileb} || 0;
 107     return $countb <=> $counta if $counta != $countb;
 108
 109     my $ta = keys %{ $totalIncludes{$filea} };
 110     my $tb = keys %{ $totalIncludes{$fileb} };
 111     return $ta <=> $tb if $ta != $tb;
 112
 113     return $filea cmp $fileb;
 114 }