Tests/RunCMake/target_link_libraries-LINK_LIBRARY/RunCMakeTest.cmake

   1
   2 include(RunCMake)
   3
   4 cmake_policy(SET CMP0054 NEW)
   5
   6 macro(run_cmake_target test subtest target)
   7   set(RunCMake_TEST_BINARY_DIR ${RunCMake_BINARY_DIR}/${test}-build)
   8   set(RunCMake_TEST_NO_CLEAN 1)
   9   run_cmake_command(${test}-${subtest} ${CMAKE_COMMAND} --build . --target ${target} --config Release --verbose ${ARGN})
  10
  11   unset(RunCMake_TEST_BINARY_DIR)
  12   unset(RunCMake_TEST_NO_CLEAN)
  13 endmacro()
  14
  15 # Some environments are excluded because they are not able to honor verbose mode
  16 if ((RunCMake_GENERATOR MATCHES "Makefiles|Ninja|Xcode"
  17     OR (RunCMake_GENERATOR MATCHES "Visual Studio" AND MSVC_VERSION GREATER_EQUAL "1600"))
  18     AND NOT CMAKE_C_COMPILER_ID STREQUAL "Intel")
  19
  20   set(RunCMake_TEST_OUTPUT_MERGE TRUE)
  21   if (NOT RunCMake_GENERATOR_IS_MULTI_CONFIG)
  22     set(RunCMake_TEST_OPTIONS -DCMAKE_BUILD_TYPE=Release)
  23   endif()
  24
  25   if (CMAKE_SYSTEM_NAME STREQUAL "Windows"
  26       OR CMAKE_SYSTEM_NAME STREQUAL "CYGWIN"
  27       OR CMAKE_SYSTEM_NAME STREQUAL "MSYS")
  28     set(LINK_SHARED_LIBRARY_PREFIX ${CMAKE_IMPORT_LIBRARY_PREFIX})
  29     set(LINK_SHARED_LIBRARY_SUFFIX ${CMAKE_IMPORT_LIBRARY_SUFFIX})
  30   else()
  31     set(LINK_SHARED_LIBRARY_PREFIX ${CMAKE_SHARED_LIBRARY_PREFIX})
  32     set(LINK_SHARED_LIBRARY_SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX})
  33   endif()
  34   if (MINGW OR MSYS OR CYGWIN)
  35     set(LINK_EXTERN_LIBRARY_SUFFIX "")
  36   else()
  37     set(LINK_EXTERN_LIBRARY_SUFFIX "${CMAKE_IMPORT_LIBRARY_SUFFIX}")
  38   endif()
  39
  40   run_cmake(LINK_LIBRARY)
  41
  42   run_cmake_target(LINK_LIBRARY simple1 LinkLibrary_simple1)
  43   run_cmake_target(LINK_LIBRARY simple2 LinkLibrary_simple2)
  44   run_cmake_target(LINK_LIBRARY group1 LinkLibrary_group1)
  45   run_cmake_target(LINK_LIBRARY group2 LinkLibrary_group2)
  46   run_cmake_target(LINK_LIBRARY nested-feature1 LinkLibrary_nested_feature1)
  47   run_cmake_target(LINK_LIBRARY nested-feature2 LinkLibrary_nested_feature2)
  48   run_cmake_target(LINK_LIBRARY link-items1 LinkLibrary_link_items1)
  49   run_cmake_target(LINK_LIBRARY link-items2 LinkLibrary_link_items2)
  50   run_cmake_target(LINK_LIBRARY link-items3 LinkLibrary_link_items3)
  51   run_cmake_target(LINK_LIBRARY link-items4 LinkLibrary_link_items4)
  52   run_cmake_target(LINK_LIBRARY mix-features1 LinkLibrary_mix_features1)
  53   run_cmake_target(LINK_LIBRARY mix-features2 LinkLibrary_mix_features2)
  54   run_cmake_target(LINK_LIBRARY mix-features3 LinkLibrary_mix_features3)
  55
  56   # testing target property LINK_LIBRARY_OVERRIDE
  57   run_cmake_target(LINK_LIBRARY override-features1 LinkLibrary_override_features1)
  58   run_cmake_target(LINK_LIBRARY override-features2 LinkLibrary_override_features2)
  59   run_cmake_target(LINK_LIBRARY override-with-DEFAULT LinkLibrary_override_with_default)
  60   # testing target property LINK_LIBRARY_OVERRIDE_<LIBRARY>
  61   run_cmake_target(LINK_LIBRARY override-features3 LinkLibrary_override_features3)
  62   run_cmake_target(LINK_LIBRARY override-features4 LinkLibrary_override_features4)
  63
  64   run_cmake(imported-target)
  65
  66   # tests using features as described in the documentation
  67   if(CMAKE_C_COMPILER_ID STREQUAL "AppleClang"
  68       OR (CMAKE_C_COMPILER_ID STREQUAL "MSVC" AND MSVC_VERSION GREATER "1900")
  69       OR (CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_SYSTEM_NAME STREQUAL "Linux"))
  70     run_cmake(load_archive)
  71     run_cmake_target(load_archive link-exe main)
  72   endif()
  73   if(CMAKE_C_COMPILER_ID STREQUAL "AppleClang")
  74     run_cmake(weak_library)
  75     run_cmake_target(weak_library link-exe main)
  76   endif()
  77
  78   unset(RunCMake_TEST_OPTIONS)
  79   unset(RunCMake_TEST_OUTPUT_MERGE)
  80
  81 endif()
  82
  83 # Apple framework features
  84 if(APPLE AND (CMAKE_C_COMPILER_ID STREQUAL "GNU" OR CMAKE_C_COMPILER_ID MATCHES "Clang"))
  85   run_cmake(apple_framework)
  86   run_cmake_target(apple_framework framework main-framework)
  87   run_cmake_target(apple_framework reexport_framework main-reexport_framework)
  88   run_cmake_target(apple_framework weak_framework main-weak_framework)
  89
  90   run_cmake_target(apple_framework target-framework main-target-framework)
  91   run_cmake_target(apple_framework target-reexport_framework main-target-reexport_framework)
  92   run_cmake_target(apple_framework target-weak_framework main-target-weak_framework)
  93
  94   if(RunCMake_GENERATOR_IS_MULTI_CONFIG AND (NOT XCODE OR XCODE_VERSION GREATER_EQUAL 13))
  95     run_cmake_target(apple_framework target-framework-postfix main-target-framework-postfix)
  96     run_cmake_target(apple_framework target-reexport_framework-postfix main-target-reexport_framework-postfix)
  97     run_cmake_target(apple_framework target-weak_framework-postfix main-target-weak_framework-postfix)
  98   endif()
  99 endif()
 100
 101 if (CMAKE_C_COMPILER_ID STREQUAL "AppleClang" AND CMAKE_C_COMPILER_VERSION GREATER_EQUAL "12")
 102   run_cmake_target(apple_framework needed_framework main-needed_framework)
 103
 104   run_cmake_target(apple_framework target-needed_framework main-target-needed_framework)
 105
 106   if(RunCMake_GENERATOR_IS_MULTI_CONFIG AND (NOT XCODE OR XCODE_VERSION GREATER_EQUAL 13))
 107     run_cmake_target(apple_framework target-needed_framework-postfix main-target-needed_framework-postfix)
 108   endif()
 109 endif()
 110
 111 # Apple library features
 112 if(APPLE AND (CMAKE_C_COMPILER_ID STREQUAL "GNU" OR CMAKE_C_COMPILER_ID MATCHES "Clang"))
 113   run_cmake(apple_library_external)
 114   run_cmake_target(apple_library_external build external)
 115   run_cmake_with_options(apple_library "-DRunCMake_BINARY_DIR=${RunCMake_BINARY_DIR}")
 116   run_cmake_target(apple_library reexport_library main-reexport_library)
 117   run_cmake_target(apple_library weak_library main-weak_library)
 118 endif()
 119
 120 if (CMAKE_C_COMPILER_ID STREQUAL "AppleClang" AND CMAKE_C_COMPILER_VERSION GREATER_EQUAL "12")
 121   run_cmake_target(apple_library needed_library main-needed_library)
 122 endif()
 123
 124 # WHOLE_ARCHIVE feature
 125 if ((CMAKE_SYSTEM_NAME STREQUAL "Windows" AND
 126       ((DEFINED MSVC_VERSION AND MSVC_VERSION GREATER "1900") OR (CMAKE_C_COMPILER_ID MATCHES "GNU|Clang" AND NOT CMAKE_C_SIMULATE_ID STREQUAL "MSVC")))
 127     OR (CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND
 128       (NOT CMAKE_C_COMPILER_ID STREQUAL "SunPro" OR CMAKE_C_COMPILER_VERSION GREATER "5.9"))
 129     OR CMAKE_SYSTEM_NAME MATCHES "Darwin|iOS|tvOS|watchOS|Linux|BSD|MSYS|CYGWIN")
 130   run_cmake(feature-WHOLE_ARCHIVE)
 131   run_cmake_target(feature-WHOLE_ARCHIVE link-exe main)
 132 endif()