Tests/RunCMake/File_Generate/RunCMakeTest.cmake

   1 include(RunCMake)
   2
   3 run_cmake(CMP0070-NEW)
   4 run_cmake(CMP0070-OLD)
   5 run_cmake(CMP0070-WARN)
   6
   7 run_cmake(SourceProperty)
   8 run_cmake(SourceProperty-CMP0070-NEW)
   9 run_cmake(SourceProperty-CMP0070-OLD)
  10
  11 run_cmake(CommandConflict)
  12 if(RunCMake_GENERATOR_IS_MULTI_CONFIG)
  13   run_cmake(OutputConflict)
  14 endif()
  15 run_cmake(EmptyCondition1)
  16 run_cmake(EmptyCondition2)
  17 run_cmake(BadCondition)
  18 run_cmake(DebugEvaluate)
  19 run_cmake(GenerateSource)
  20 run_cmake(OutputNameMatchesSources)
  21 run_cmake(OutputNameMatchesObjects)
  22 run_cmake(OutputNameMatchesOtherSources)
  23 file(READ "${RunCMake_BINARY_DIR}/OutputNameMatchesOtherSources-build/1somefile.cpp" file_contents)
  24 if (NOT file_contents MATCHES "generated.cpp.rule")
  25   message(SEND_ERROR "Rule file not in target sources! ${file_contents}")
  26 endif()
  27
  28 run_cmake(COMPILE_LANGUAGE-genex)
  29 foreach(l CXX C)
  30   file(READ "${RunCMake_BINARY_DIR}/COMPILE_LANGUAGE-genex-build/opts-${l}.txt" l_defs)
  31   if (NOT l_defs STREQUAL "LANG_IS_${l}\n")
  32     message(FATAL_ERROR "File content does not match: ${l_defs}")
  33   endif()
  34 endforeach()
  35
  36 run_cmake(Target)
  37 file(READ "${RunCMake_BINARY_DIR}/Target-build/sub1/output.txt" sub_1)
  38 file(READ "${RunCMake_BINARY_DIR}/Target-build/sub2/output.txt" sub_2)
  39 if(NOT sub_1 MATCHES "first" OR NOT sub_2 MATCHES "second")
  40   message(SEND_ERROR "Wrong target used by TARGET argument! ${sub_1} ${sub_2}")
  41 endif()
  42
  43 set(timeformat "%Y%j%H%M%S")
  44
  45 file(REMOVE "${RunCMake_BINARY_DIR}/WriteIfDifferent-build/output_file.txt")
  46 set(RunCMake_TEST_OPTIONS "-DTEST_FILE=WriteIfDifferent.cmake")
  47 set(RunCMake_TEST_BINARY_DIR "${RunCMake_BINARY_DIR}/WriteIfDifferent-build")
  48 run_cmake(WriteIfDifferent-prepare)
  49 unset(RunCMake_TEST_OPTIONS)
  50 unset(RunCMake_TEST_BINARY_DIR)
  51 file(TIMESTAMP "${RunCMake_BINARY_DIR}/WriteIfDifferent-build/output_file.txt" timestamp ${timeformat})
  52 if(NOT timestamp)
  53   message(SEND_ERROR "Could not get timestamp for \"${RunCMake_BINARY_DIR}/WriteIfDifferent-build/output_file.txt\"")
  54 endif()
  55
  56 execute_process(COMMAND ${CMAKE_COMMAND} -E sleep 1)
  57
  58 set(RunCMake_TEST_NO_CLEAN ON)
  59 run_cmake(WriteIfDifferent)
  60 file(TIMESTAMP "${RunCMake_BINARY_DIR}/WriteIfDifferent-build/output_file.txt" timestamp_after ${timeformat})
  61 if(NOT timestamp_after)
  62   message(SEND_ERROR "Could not get timestamp for \"${RunCMake_BINARY_DIR}/WriteIfDifferent-build/output_file.txt\"")
  63 endif()
  64 unset(RunCMake_TEST_NO_CLEAN)
  65
  66 if (NOT timestamp_after STREQUAL timestamp)
  67   message(SEND_ERROR "WriteIfDifferent changed output file.")
  68 endif()
  69
  70 if (UNIX AND EXISTS /bin/sh)
  71   set(RunCMake_TEST_NO_CLEAN ON)
  72   run_cmake(CarryPermissions)
  73   execute_process(
  74     COMMAND "${RunCMake_BINARY_DIR}/CarryPermissions-build/output_script.sh"
  75     OUTPUT_VARIABLE script_output
  76     RESULT_VARIABLE script_result
  77     ERROR_VARIABLE script_error
  78     OUTPUT_STRIP_TRAILING_WHITESPACE
  79   )
  80   if (script_result)
  81     message(SEND_ERROR "Generated script did not execute correctly: [${script_result}]\n${script_output}\n====\n${script_error}")
  82   endif()
  83   if (NOT script_output STREQUAL SUCCESS)
  84     message(SEND_ERROR "Generated script did not execute correctly:\n${script_output}\n====\n${script_error}")
  85   endif()
  86   unset(RunCMake_TEST_NO_CLEAN)
  87 endif()
  88
  89 if (RunCMake_GENERATOR MATCHES Makefiles)
  90   file(MAKE_DIRECTORY "${RunCMake_BINARY_DIR}/ReRunCMake-build/")
  91   file(WRITE "${RunCMake_BINARY_DIR}/ReRunCMake-build/input_file.txt" "InitialContent\n")
  92
  93   set(RunCMake_TEST_NO_CLEAN ON)
  94   run_cmake(ReRunCMake)
  95   unset(RunCMake_TEST_NO_CLEAN)
  96   file(TIMESTAMP "${RunCMake_BINARY_DIR}/ReRunCMake-build/output_file.txt" timestamp ${timeformat})
  97   if(NOT timestamp)
  98     message(SEND_ERROR "Could not get timestamp for \"${RunCMake_BINARY_DIR}/ReRunCMake-build/output_file.txt\"")
  99   endif()
 100
 101   execute_process(COMMAND ${CMAKE_COMMAND} -E sleep 1)
 102
 103   file(WRITE "${RunCMake_BINARY_DIR}/ReRunCMake-build/input_file.txt" "ChangedContent\n")
 104   execute_process(COMMAND ${CMAKE_COMMAND} --build "${RunCMake_BINARY_DIR}/ReRunCMake-build/")
 105   file(READ "${RunCMake_BINARY_DIR}/ReRunCMake-build/output_file.txt" out_content)
 106
 107   if(NOT out_content STREQUAL "ChangedContent\n")
 108     message(SEND_ERROR "File did not change: \"${RunCMake_BINARY_DIR}/ReRunCMake-build/output_file.txt\"")
 109   endif()
 110
 111
 112   file(REMOVE "${RunCMake_BINARY_DIR}/ReRunCMake-build/output_file.txt")
 113   execute_process(COMMAND ${CMAKE_COMMAND} --build "${RunCMake_BINARY_DIR}/ReRunCMake-build/")
 114
 115   if (NOT EXISTS "${RunCMake_BINARY_DIR}/ReRunCMake-build/output_file.txt")
 116     message(SEND_ERROR "File did not re-generate: \"${RunCMake_BINARY_DIR}/ReRunCMake-build/output_file.txt\"")
 117   endif()
 118 endif()
 119
 120 set(RunCMake_TEST_BINARY_DIR ${RunCMake_BINARY_DIR}/AdjacentInOut-build)
 121 run_cmake(AdjacentInOut)
 122 set(RunCMake_TEST_NO_CLEAN 1)
 123 run_cmake_command(AdjacentInOut-nowork ${CMAKE_COMMAND} --build .)
 124 unset(RunCMake_TEST_BINARY_DIR)
 125 unset(RunCMake_TEST_NO_CLEAN)
 126
 127 run_cmake(SourcePermissions1)
 128 run_cmake(SourcePermissions2)
 129 run_cmake(SourcePermissions3)
 130 run_cmake(SourcePermissions4)
 131 run_cmake(SourcePermissions5)
 132
 133 function(run_cmake_and_verify_after_build case)
 134   set(RunCMake_TEST_BINARY_DIR "${RunCMake_BINARY_DIR}/${case}-build")
 135   file(REMOVE_RECURSE "${RunCMake_TEST_BINARY_DIR}")
 136   file(MAKE_DIRECTORY "${RunCMake_TEST_BINARY_DIR}")
 137   set(RunCMake_TEST_NO_CLEAN 1)
 138   if(RunCMake_GENERATOR_IS_MULTI_CONFIG)
 139     set(RunCMake_TEST_OPTIONS -DCMAKE_CONFIGURATION_TYPES=Debug)
 140   else()
 141     set(RunCMake_TEST_OPTIONS -DCMAKE_BUILD_TYPE=Debug)
 142   endif()
 143   run_cmake(${case})
 144   run_cmake_command("${case}-build" ${CMAKE_COMMAND} --build .)
 145   unset(RunCMake_TEST_NO_CLEAN)
 146   unset(RunCMake_TEST_BINARY_DIR)
 147 endfunction()
 148
 149 run_cmake_and_verify_after_build(NoSourcePermissions)
 150 run_cmake_and_verify_after_build(UseSourcePermissions)
 151 run_cmake_and_verify_after_build(CustomFilePermissions)
 152
 153 run_cmake(NewLineStyle-NoArg)
 154 run_cmake(NewLineStyle-InvalidArg)
 155 run_cmake_and_verify_after_build(NewLineStyle-Default)
 156 run_cmake_and_verify_after_build(NewLineStyle-Unix)
 157 run_cmake_and_verify_after_build(NewLineStyle-Win32)