Tests/RunCMake/FileAPI/codemodel-v2.cmake

   1 enable_language(C)
   2
   3 include("${CMAKE_CURRENT_LIST_DIR}/include_test.cmake")
   4
   5 add_library(c_lib empty.c)
   6 add_executable(c_exe empty.c)
   7 target_link_libraries(c_exe PRIVATE c_lib)
   8
   9 add_library(c_shared_lib SHARED empty.c)
  10 add_executable(c_shared_exe empty.c)
  11 target_link_libraries(c_shared_exe PRIVATE c_shared_lib)
  12
  13 add_library(c_static_lib STATIC empty.c)
  14 add_executable(c_static_exe empty.c)
  15 target_link_libraries(c_static_exe PRIVATE c_static_lib)
  16
  17 add_subdirectory(cxx)
  18 add_subdirectory(alias)
  19 add_subdirectory(object)
  20 add_subdirectory(imported)
  21 add_subdirectory(interface)
  22 add_subdirectory(custom)
  23 add_subdirectory("${CMAKE_CURRENT_SOURCE_DIR}/../FileAPIExternalSource" "${CMAKE_CURRENT_BINARY_DIR}/../FileAPIExternalBuild")
  24 add_subdirectory(dir)
  25 add_subdirectory(fileset)
  26
  27 set_property(TARGET c_shared_lib PROPERTY LIBRARY_OUTPUT_DIRECTORY lib)
  28 set_property(TARGET c_shared_lib PROPERTY RUNTIME_OUTPUT_DIRECTORY lib)
  29
  30 include(CheckIPOSupported)
  31 check_ipo_supported(RESULT _ipo LANGUAGES C)
  32 if(_ipo)
  33   set_property(TARGET c_shared_lib PROPERTY INTERPROCEDURAL_OPTIMIZATION ON)
  34   set_property(TARGET c_shared_exe PROPERTY INTERPROCEDURAL_OPTIMIZATION ON)
  35   set_property(TARGET c_static_lib PROPERTY INTERPROCEDURAL_OPTIMIZATION ON)
  36   file(WRITE "${CMAKE_BINARY_DIR}/ipo_enabled.txt" "")
  37 endif()
  38
  39 install(TARGETS cxx_exe COMPONENT Tools EXPORT FooTargets)
  40
  41 set_target_properties(c_shared_lib PROPERTIES VERSION 1.2.3 SOVERSION 1)
  42 install(TARGETS c_shared_lib cxx_shared_lib
  43   ARCHIVE DESTINATION lib
  44   RUNTIME DESTINATION lib
  45   LIBRARY DESTINATION lib NAMELINK_SKIP
  46   )
  47 install(TARGETS c_shared_lib cxx_shared_lib LIBRARY NAMELINK_ONLY)
  48
  49 install(FILES empty.h TYPE INCLUDE RENAME empty-renamed.h OPTIONAL)
  50 install(FILES codemodel-v2.cmake empty.h DESTINATION include)
  51 install(DIRECTORY . dir cxx/ OPTIONAL DESTINATION dir1)
  52 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}" "${CMAKE_CURRENT_SOURCE_DIR}/dir" "${CMAKE_CURRENT_SOURCE_DIR}/cxx/" DESTINATION dir2)
  53 install(EXPORT FooTargets DESTINATION lib/cmake/foo)
  54 install(SCRIPT InstallScript.cmake)
  55 install(CODE "message(foo)" ALL_COMPONENTS)