Tests/RunCMake/CMakePresetsWorkflow/RunCMakeTest.cmake

   1 include(RunCMake)
   2
   3 # Presets do not support legacy VS generator name architecture suffix.
   4 if(RunCMake_GENERATOR MATCHES "^(Visual Studio [0-9]+ [0-9]+) ")
   5   set(RunCMake_GENERATOR "${CMAKE_MATCH_1}")
   6 endif()
   7
   8 function(run_cmake_workflow_presets name)
   9   set(RunCMake_TEST_SOURCE_DIR "${RunCMake_BINARY_DIR}/${name}")
  10   set(RunCMake_TEST_BINARY_DIR "${RunCMake_TEST_SOURCE_DIR}/build")
  11   set(RunCMake_TEST_COMMAND_WORKING_DIRECTORY "${RunCMake_TEST_SOURCE_DIR}")
  12
  13   if(NOT RunCMake_TEST_NO_CLEAN)
  14     file(REMOVE_RECURSE "${RunCMake_TEST_SOURCE_DIR}")
  15     file(MAKE_DIRECTORY "${RunCMake_TEST_SOURCE_DIR}")
  16   endif()
  17
  18   set(RunCMake_TEST_NO_CLEAN TRUE)
  19
  20   set(CASE_NAME "${name}")
  21   set(CASE_SOURCE_DIR "${RunCMake_SOURCE_DIR}")
  22   configure_file("${RunCMake_SOURCE_DIR}/CMakeLists.txt.in" "${RunCMake_TEST_SOURCE_DIR}/CMakeLists.txt" @ONLY)
  23
  24   if(NOT CMakePresets_FILE)
  25     set(CMakePresets_FILE "${RunCMake_SOURCE_DIR}/${name}.json.in")
  26   endif()
  27   if(EXISTS "${CMakePresets_FILE}")
  28     configure_file("${CMakePresets_FILE}" "${RunCMake_TEST_SOURCE_DIR}/CMakePresets.json" @ONLY)
  29   endif()
  30
  31   if(NOT CMakeUserPresets_FILE)
  32     set(CMakeUserPresets_FILE "${RunCMake_SOURCE_DIR}/${name}User.json.in")
  33   endif()
  34   if(EXISTS "${CMakeUserPresets_FILE}")
  35     configure_file("${CMakeUserPresets_FILE}" "${RunCMake_TEST_SOURCE_DIR}/CMakeUserPresets.json" @ONLY)
  36   endif()
  37
  38   foreach(ASSET ${CMakePresets_ASSETS})
  39     configure_file("${RunCMake_SOURCE_DIR}/${ASSET}.in" "${RunCMake_TEST_SOURCE_DIR}/${ASSET}" @ONLY)
  40   endforeach()
  41
  42   if(EXISTS "${RunCMake_SOURCE_DIR}/${name}-check.cmake")
  43     set(RunCMake-check-file "${name}-check.cmake")
  44   else()
  45     set(RunCMake-check-file "check.cmake")
  46   endif()
  47
  48   if(eq)
  49     set(eq 0 PARENT_SCOPE)
  50     set(preset_arg "--preset=${name}")
  51   else()
  52     set(eq 1 PARENT_SCOPE)
  53     set(preset_arg "--preset" "${name}")
  54   endif()
  55   run_cmake_command("${name}" "${CMAKE_COMMAND}" "--workflow" ${preset_arg} ${ARGN})
  56 endfunction()
  57
  58 set(CMakePresets_SCHEMA_EXPECTED_RESULT 1)
  59 run_cmake_workflow_presets(UnsupportedVersion)
  60 set(CMakePresets_SCHEMA_EXPECTED_RESULT 0)
  61 run_cmake_workflow_presets(NoWorkflowSteps)
  62 run_cmake_workflow_presets(FirstStepNotConfigure)
  63 run_cmake_workflow_presets(SecondStepConfigure)
  64 run_cmake_workflow_presets(NonexistentStep)
  65 run_cmake_workflow_presets(UnreachableStep)
  66 run_cmake_workflow_presets(WorkflowStepHidden)
  67 run_cmake_workflow_presets(WorkflowStepDisabled)
  68 run_cmake_workflow_presets(WorkflowStepInvalidMacro)
  69 run_cmake_workflow_presets(ConfigureStepMismatch)
  70
  71 set(CMakePresets_FILE "${RunCMake_SOURCE_DIR}/Good.json.in")
  72 set(CMakeUserPresets_FILE "${RunCMake_SOURCE_DIR}/GoodUser.json.in")
  73 set(CMakePresets_ASSETS cpack_staging.cmake)
  74 run_cmake_workflow_presets(Good)
  75 run_cmake_workflow_presets(GoodUser)
  76 run_cmake_workflow_presets(BadExitCode)
  77 unset(CMakePresets_FILE)
  78 unset(CMakeUserPresets_FILE)
  79 unset(CMakePresets_ASSETS)
  80
  81 run_cmake_workflow_presets(ListPresets --list-presets)
  82 run_cmake_workflow_presets(InvalidOption -DINVALID_OPTION)
  83
  84 set(RunCMake_TEST_NO_CLEAN TRUE)
  85 file(REMOVE_RECURSE "${RunCMake_BINARY_DIR}/Fresh")
  86 file(MAKE_DIRECTORY "${RunCMake_BINARY_DIR}/Fresh/build")
  87 file(WRITE "${RunCMake_BINARY_DIR}/Fresh/build/CMakeCache.txt" "FRESH_CONFIGURE:BOOL=OFF\n")
  88 run_cmake_workflow_presets(Fresh --fresh)
  89 unset(RunCMake_TEST_NO_CLEAN)