Tests/RunCMake/CMakePresetsPackage/RunCMakeTest.cmake

   1 include(RunCMake)
   2
   3 # Presets do not support legacy VS generator name architecture suffix.
   4 if(RunCMake_GENERATOR MATCHES "^(Visual Studio [0-9]+ [0-9]+) ")
   5   set(RunCMake_GENERATOR "${CMAKE_MATCH_1}")
   6 endif()
   7
   8 function(run_cmake_package_presets name CMakePresetsPackage_CONFIGURE_PRESETS CMakePresetsPackage_BUILD_PRESETS CMakePresetsPackage_PACKAGE_PRESETS)
   9   set(RunCMake_TEST_SOURCE_DIR "${RunCMake_BINARY_DIR}/${name}")
  10   set(RunCMake_TEST_BINARY_DIR "${RunCMake_TEST_SOURCE_DIR}/build")
  11   set(RunCMake_TEST_COMMAND_WORKING_DIRECTORY "${RunCMake_TEST_SOURCE_DIR}")
  12
  13   set(RunCMake_TEST_NO_CLEAN TRUE)
  14
  15   file(REMOVE_RECURSE "${RunCMake_TEST_SOURCE_DIR}")
  16   file(MAKE_DIRECTORY "${RunCMake_TEST_BINARY_DIR}")
  17
  18   set(CASE_NAME "${name}")
  19   set(CASE_SOURCE_DIR "${RunCMake_SOURCE_DIR}")
  20   configure_file("${RunCMake_SOURCE_DIR}/CMakeLists.txt.in" "${RunCMake_TEST_SOURCE_DIR}/CMakeLists.txt" @ONLY)
  21
  22   if(NOT CMakePresetsPackage_FILE)
  23     set(CMakePresetsPackage_FILE "${RunCMake_SOURCE_DIR}/${name}.json.in")
  24   endif()
  25   if(EXISTS "${CMakePresetsPackage_FILE}")
  26     configure_file("${CMakePresetsPackage_FILE}" "${RunCMake_TEST_SOURCE_DIR}/CMakePresets.json" @ONLY)
  27   endif()
  28
  29   if(NOT CMakeUserPresets_FILE)
  30     set(CMakeUserPresets_FILE "${RunCMake_SOURCE_DIR}/${name}User.json.in")
  31   endif()
  32   if(EXISTS "${CMakeUserPresets_FILE}")
  33     configure_file("${CMakeUserPresets_FILE}" "${RunCMake_TEST_SOURCE_DIR}/CMakeUserPresets.json" @ONLY)
  34   endif()
  35
  36   foreach(ASSET ${CMakePresetsPackage_ASSETS})
  37     configure_file("${RunCMake_SOURCE_DIR}/${ASSET}" "${RunCMake_TEST_SOURCE_DIR}" COPYONLY)
  38   endforeach()
  39
  40   if (NOT CMakePresetsPackage_NO_CONFIGURE)
  41     foreach(CONFIGURE_PRESET ${CMakePresetsPackage_CONFIGURE_PRESETS})
  42       run_cmake_command("${name}-configure-${CONFIGURE_PRESET}"
  43         "${CMAKE_COMMAND}" "--preset" "${CONFIGURE_PRESET}")
  44     endforeach()
  45   endif()
  46
  47   if (NOT CMakePresetsPackage_NO_BUILD)
  48     foreach(BUILD_PRESET ${CMakePresetsPackage_BUILD_PRESETS})
  49       run_cmake_command("${name}-build-${BUILD_PRESET}"
  50         "${CMAKE_COMMAND}" "--build" "--preset" "${BUILD_PRESET}")
  51     endforeach()
  52   endif()
  53
  54   set(eq 0)
  55   foreach(PACKAGE_PRESET ${CMakePresetsPackage_PACKAGE_PRESETS})
  56     file(REMOVE_RECURSE "${RunCMake_TEST_BINARY_DIR}/default/_CPack_Packages")
  57
  58     if (EXISTS "${RunCMake_SOURCE_DIR}/${name}-package-${PACKAGE_PRESET}-check.cmake")
  59       set(RunCMake-check-file "${name}-package-${PACKAGE_PRESET}-check.cmake")
  60     else()
  61       set(RunCMake-check-file "check.cmake")
  62     endif()
  63
  64     if(eq)
  65       run_cmake_command(${name}-package-${PACKAGE_PRESET}
  66         ${CMAKE_CPACK_COMMAND} "--preset=${PACKAGE_PRESET}" ${ARGN})
  67       set(eq 0)
  68     else()
  69       run_cmake_command(${name}-package-${PACKAGE_PRESET}
  70         ${CMAKE_CPACK_COMMAND} "--preset" "${PACKAGE_PRESET}" ${ARGN})
  71       set(eq 1)
  72     endif()
  73   endforeach()
  74 endfunction()
  75
  76 function(check_cpack_packages generators contents)
  77   include("${RunCMake_TEST_BINARY_DIR}/default/CPackConfig.cmake")
  78
  79   set(cpack_dir "${RunCMake_TEST_BINARY_DIR}/default/_CPack_Packages/${CPACK_TOPLEVEL_TAG}")
  80   file(GLOB dirs RELATIVE "${cpack_dir}" "${cpack_dir}/*")
  81   if(NOT dirs STREQUAL generators)
  82     string(APPEND RunCMake_TEST_FAILED "Expected CPack generators: ${generators}\nActual CPack generators: ${dirs}\n")
  83   endif()
  84
  85   if(contents)
  86     foreach(dir IN LISTS dirs)
  87       set(env_file "${cpack_dir}/${dir}/${CPACK_PACKAGE_FILE_NAME}/env.txt")
  88       file(READ "${env_file}" actual_contents)
  89       if(NOT contents STREQUAL actual_contents)
  90         string(REPLACE "\n" "\n  " contents_formatted "${contents}")
  91         string(REPLACE "\n" "\n  " actual_contents_formatted "${actual_contents}")
  92         string(APPEND RunCMake_TEST_FAILED "Expected contents of ${env_file}:\n  ${contents_formatted}\nActual contents:\n  ${actual_contents_formatted}\n")
  93       endif()
  94     endforeach()
  95   endif()
  96
  97   set(RunCMake_TEST_FAILED ${RunCMake_TEST_FAILED} PARENT_SCOPE)
  98 endfunction()
  99
 100 run_cmake_package_presets(UnsupportedVersion "x" "" "")
 101 run_cmake_package_presets(Good "default" "build-default-debug" "no-environment;with-environment;generators;configurations;variables;config-file;debug;verbose;package-name;package-version;package-directory;vendor-name")
 102 run_cmake_package_presets(ListPresets "default" "" "x" "--list-presets")