Tests/MSVCDebugInformationFormat/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.24)
   2 cmake_policy(SET CMP0141 NEW)
   3
   4 # The debug information format flags do not change preprocessor definitions,
   5 # so override our table of flags to artificially add a definition we can check.
   6 set(CMAKE_USER_MAKE_RULES_OVERRIDE_C ${CMAKE_CURRENT_SOURCE_DIR}/override-C.cmake)
   7 set(CMAKE_USER_MAKE_RULES_OVERRIDE_CXX ${CMAKE_CURRENT_SOURCE_DIR}/override-CXX.cmake)
   8 set(CMAKE_USER_MAKE_RULES_OVERRIDE_CUDA ${CMAKE_CURRENT_SOURCE_DIR}/override-CUDA.cmake)
   9 set(CMAKE_USER_MAKE_RULES_OVERRIDE_Fortran ${CMAKE_CURRENT_SOURCE_DIR}/override-Fortran.cmake)
  10
  11 project(MSVCDebugInformationFormat)
  12 if(CMake_TEST_CUDA)
  13   enable_language(CUDA)
  14 endif()
  15 if(CMake_TEST_Fortran)
  16   enable_language(Fortran)
  17 endif()
  18
  19 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
  20
  21 if("${CMAKE_C_COMPILER_ID};${CMAKE_C_SIMULATE_ID};${CMAKE_C_COMPILER_FRONTEND_VARIANT}" STREQUAL "Clang;MSVC;GNU")
  22   set(verify_default VERIFY_Z7)
  23   set(NO_COMPILER_PDB 1)
  24 elseif("${CMAKE_C_COMPILER_ID};${CMAKE_C_SIMULATE_ID};${CMAKE_C_COMPILER_FRONTEND_VARIANT}" STREQUAL "Clang;MSVC;MSVC")
  25   set(verify_default VERIFY_Zi)
  26   set(NO_EDIT_AND_CONTINUE 1)
  27 else()
  28   set(verify_default VERIFY_Zi)
  29 endif()
  30
  31 set(verify_def_Embedded        -DVERIFY_Z7)
  32 set(verify_def_ProgramDatabase -DVERIFY_Zi)
  33 set(verify_def_EditAndContinue -DVERIFY_ZI)
  34
  35 function(verify_combination format lang src)
  36   # Test that try_compile builds with this debug format.
  37   set(CMAKE_MSVC_DEBUG_INFORMATION_FORMAT "${format}")
  38   set(CMAKE_TRY_COMPILE_CONFIGURATION "Debug")
  39   set(CMAKE_TRY_COMPILE_TARGET_TYPE "STATIC_LIBRARY")
  40   try_compile(${format}_COMPILES
  41     ${CMAKE_CURRENT_BINARY_DIR}/try_compile/${format}
  42     ${CMAKE_CURRENT_SOURCE_DIR}/${src}
  43     COMPILE_DEFINITIONS ${verify_def_${format}}
  44     CMAKE_FLAGS -DINCLUDE_DIRECTORIES=${CMAKE_CURRENT_SOURCE_DIR}
  45     OUTPUT_VARIABLE ${format}_OUTPUT
  46     )
  47   if(${format}_COMPILES)
  48     message(STATUS "try_compile ${lang} with ${format} worked")
  49   else()
  50     string(REPLACE "\n" "\n  " ${format}_OUTPUT "  ${${format}_OUTPUT}")
  51     message(SEND_ERROR "try_compile ${lang} with ${format} failed:\n${${format}_OUTPUT}")
  52   endif()
  53
  54   # Test that targets build with this debug format.
  55   set(CMAKE_MSVC_DEBUG_INFORMATION_FORMAT "$<$<BOOL:$<TARGET_PROPERTY:BOOL_TRUE>>:${format}>$<$<BOOL:$<TARGET_PROPERTY:BOOL_FALSE>>:BadContent>")
  56   add_library(${format}-${lang} ${src})
  57   set_property(TARGET ${format}-${lang} PROPERTY BOOL_TRUE TRUE)
  58   target_compile_definitions(${format}-${lang} PRIVATE ${verify_def_${format}})
  59 endfunction()
  60
  61 function(verify lang src)
  62   add_library(default-${lang} ${src})
  63   target_compile_definitions(default-${lang} PRIVATE "$<$<CONFIG:Debug,RelWithDebInfo>:${verify_default}>")
  64
  65   verify_combination(Embedded ${lang} ${src})
  66   if(NOT NO_COMPILER_PDB)
  67     verify_combination(ProgramDatabase ${lang} ${src})
  68     if(NOT NO_EDIT_AND_CONTINUE AND NOT lang MATCHES "^(Fortran)$")
  69       verify_combination(EditAndContinue ${lang} ${src})
  70     endif()
  71   endif()
  72 endfunction()
  73
  74 verify(C verify.c)
  75 verify(CXX verify.cxx)
  76 if(CMake_TEST_CUDA)
  77   verify(CUDA verify.cu)
  78 endif()
  79 if(CMake_TEST_Fortran)
  80   verify(Fortran verify.F90)
  81 endif()