Tests/CheckSwift.cmake

   1 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Ninja")
   2   set(CMAKE_Swift_COMPILER "")
   3   return()
   4 endif()
   5
   6 if(NOT DEFINED CMAKE_Swift_COMPILER)
   7   set(_desc "Looking for a Swift compiler")
   8   message(STATUS ${_desc})
   9
  10   file(REMOVE_RECURSE ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/CheckSwift)
  11
  12   file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/CheckSwift/CMakeLists.txt"
  13   "cmake_minimum_required(VERSION 3.14)
  14 project(CheckSwift Swift)
  15 file(WRITE \"\${CMAKE_CURRENT_BINARY_DIR}/result.cmake\"
  16   \"set(CMAKE_Swift_COMPILER \\\"\${CMAKE_Swift_COMPILER}\\\")\\n\"
  17   \"set(CMAKE_Swift_COMPILER_VERSION \\\"\${CMAKE_Swift_COMPILER_VERSION}\\\")\\n\"
  18   \"set(CMAKE_Swift_FLAGS \\\"\${CMAKE_Swift_FLAGS}\\\")\\n\")
  19 ")
  20
  21   if(CMAKE_GENERATOR_INSTANCE)
  22     set(_D_CMAKE_GENERATOR_INSTANCE "-DCMAKE_GENERATOR_INSTANCE:INTERNAL=${CMAKE_GENERATOR_INSTANCE}")
  23   else()
  24     set(_D_CMAKE_GENERATOR_INSTANCE "")
  25   endif()
  26
  27   execute_process(WORKING_DIRECTORY
  28                     ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/CheckSwift
  29                   COMMAND
  30                     ${CMAKE_COMMAND} . -G ${CMAKE_GENERATOR}
  31                                        -A "${CMAKE_GENERATOR_PLATFORM}"
  32                                        -T "${CMAKE_GENERATOR_TOOLSET}"
  33                                        ${_D_CMAKE_GENERATOR_INSTANCE}
  34                   TIMEOUT
  35                     60
  36                   OUTPUT_VARIABLE
  37                     output
  38                   ERROR_VARIABLE
  39                     output
  40                   RESULT_VARIABLE
  41                     result)
  42
  43   include(${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/CheckSwift/result.cmake
  44     OPTIONAL)
  45   if(CMAKE_Swift_COMPILER AND "${result}" STREQUAL "0")
  46     file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
  47       "${_desc} passed with the following output:\n"
  48       "${output}\n")
  49   else()
  50     file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
  51       "${_desc} failed with the following output:\n"
  52       "${output}\n")
  53   endif()
  54
  55   message(STATUS "${_desc} - ${CMAKE_Swift_COMPILER}")
  56
  57   set(CMAKE_Swift_COMPILER "${CMAKE_Swift_COMPILER}" CACHE FILEPATH "Swift compiler")
  58   set(CMAKE_Swift_COMPILER_VERSION "${CMAKE_Swift_COMPILER_VERSION}" CACHE FILEPATH "Swift compiler version")
  59   set(CMAKE_Swift_FLAGS "${CMAKE_Swift_FLAGS}" CACHE STRING "Swift flags")
  60
  61   mark_as_advanced(CMAKE_Swift_COMPILER)
  62   mark_as_advanced(CMAKE_Swift_FLAGS)
  63 endif()