Tests/Assembler/CMakeLists.txt

   1 cmake_minimum_required (VERSION 3.8)
   2 if(POLICY CMP0129)
   3   cmake_policy(SET CMP0129 NEW)
   4 endif()
   5 project(Assembler C)
   6 message("CTEST_FULL_OUTPUT ")
   7 set(CMAKE_VERBOSE_MAKEFILE 1)
   8
   9 set(SRCS)
  10
  11 # (at least) the following toolchains can process assembler files directly
  12 # and also generate assembler files from C:
  13 if("${CMAKE_GENERATOR}" MATCHES "Makefile|Xcode|Ninja" AND
  14     NOT CMAKE_OSX_ARCHITECTURES MATCHES ";")
  15   if((CMAKE_C_COMPILER_ID MATCHES "^(GNU|LCC|Clang|AppleClang|HP|SunPro|XL)$") OR (CMAKE_C_COMPILER_ID MATCHES "Intel"  AND  UNIX)
  16      AND NOT (CMAKE_C_COMPILER_ID STREQUAL "Clang" AND "x${CMAKE_C_COMPILER_FRONTEND_VARIANT}" STREQUAL "xMSVC"))
  17     set(C_FLAGS "${CMAKE_C_FLAGS}")
  18     separate_arguments(C_FLAGS)
  19     if(CMAKE_OSX_SYSROOT AND CMAKE_C_SYSROOT_FLAG AND NOT ";${C_FLAGS};" MATCHES ";${CMAKE_C_SYSROOT_FLAG};")
  20       list(APPEND C_FLAGS ${CMAKE_C_SYSROOT_FLAG} ${CMAKE_OSX_SYSROOT})
  21     endif()
  22     if(CMAKE_OSX_ARCHITECTURES)
  23       list(APPEND C_FLAGS -arch ${CMAKE_OSX_ARCHITECTURES})
  24     elseif("${CMAKE_SYSTEM_NAME};${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "Darwin;arm64")
  25       list(APPEND C_FLAGS -arch arm64)
  26     endif()
  27     # Clang on OS X, and perhaps other compilers, do not support -g
  28     # for both generating and assembling, so drop it from generating.
  29     list(REMOVE_ITEM C_FLAGS -g)
  30     set(SRCS main.s)
  31     add_custom_command(
  32       OUTPUT main.s
  33       COMMAND ${CMAKE_C_COMPILER} ${C_FLAGS}
  34         "$<$<CONFIG:Debug>:${CMAKE_C_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDebugDLL}>"
  35         "$<$<NOT:$<CONFIG:Debug>>:${CMAKE_C_COMPILE_OPTIONS_MSVC_RUNTIME_LIBRARY_MultiThreadedDLL}>"
  36         -S ${CMAKE_CURRENT_SOURCE_DIR}/main.c -o main.s
  37       COMMAND_EXPAND_LISTS
  38       DEPENDS main.c
  39       VERBATIM
  40       )
  41   endif()
  42 endif()
  43
  44
  45 if(SRCS)
  46   set(CMAKE_ASM_FLAGS "${CMAKE_C_FLAGS}")
  47   enable_language(ASM OPTIONAL)
  48 else()
  49   message(STATUS "No assembler enabled, using C")
  50   set(SRCS main.c)
  51 endif()
  52
  53 add_executable(HelloAsm ${SRCS})