TESTING/LIN/slqt01.f

   1 *> \brief \b SLQT01
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *  Definition:
   9 *  ===========
  10 *
  11 *       SUBROUTINE SLQT01( M, N, A, AF, Q, L, LDA, TAU, WORK, LWORK,
  12 *                          RWORK, RESULT )
  13 *
  14 *       .. Scalar Arguments ..
  15 *       INTEGER            LDA, LWORK, M, N
  16 *       ..
  17 *       .. Array Arguments ..
  18 *       REAL               A( LDA, * ), AF( LDA, * ), L( LDA, * ),
  19 *      $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
  20 *      $                   WORK( LWORK )
  21 *       ..
  22 *
  23 *
  24 *> \par Purpose:
  25 *  =============
  26 *>
  27 *> \verbatim
  28 *>
  29 *> SLQT01 tests SGELQF, which computes the LQ factorization of an m-by-n
  30 *> matrix A, and partially tests SORGLQ which forms the n-by-n
  31 *> orthogonal matrix Q.
  32 *>
  33 *> SLQT01 compares L with A*Q', and checks that Q is orthogonal.
  34 *> \endverbatim
  35 *
  36 *  Arguments:
  37 *  ==========
  38 *
  39 *> \param[in] M
  40 *> \verbatim
  41 *>          M is INTEGER
  42 *>          The number of rows of the matrix A.  M >= 0.
  43 *> \endverbatim
  44 *>
  45 *> \param[in] N
  46 *> \verbatim
  47 *>          N is INTEGER
  48 *>          The number of columns of the matrix A.  N >= 0.
  49 *> \endverbatim
  50 *>
  51 *> \param[in] A
  52 *> \verbatim
  53 *>          A is REAL array, dimension (LDA,N)
  54 *>          The m-by-n matrix A.
  55 *> \endverbatim
  56 *>
  57 *> \param[out] AF
  58 *> \verbatim
  59 *>          AF is REAL array, dimension (LDA,N)
  60 *>          Details of the LQ factorization of A, as returned by SGELQF.
  61 *>          See SGELQF for further details.
  62 *> \endverbatim
  63 *>
  64 *> \param[out] Q
  65 *> \verbatim
  66 *>          Q is REAL array, dimension (LDA,N)
  67 *>          The n-by-n orthogonal matrix Q.
  68 *> \endverbatim
  69 *>
  70 *> \param[out] L
  71 *> \verbatim
  72 *>          L is REAL array, dimension (LDA,max(M,N))
  73 *> \endverbatim
  74 *>
  75 *> \param[in] LDA
  76 *> \verbatim
  77 *>          LDA is INTEGER
  78 *>          The leading dimension of the arrays A, AF, Q and L.
  79 *>          LDA >= max(M,N).
  80 *> \endverbatim
  81 *>
  82 *> \param[out] TAU
  83 *> \verbatim
  84 *>          TAU is REAL array, dimension (min(M,N))
  85 *>          The scalar factors of the elementary reflectors, as returned
  86 *>          by SGELQF.
  87 *> \endverbatim
  88 *>
  89 *> \param[out] WORK
  90 *> \verbatim
  91 *>          WORK is REAL array, dimension (LWORK)
  92 *> \endverbatim
  93 *>
  94 *> \param[in] LWORK
  95 *> \verbatim
  96 *>          LWORK is INTEGER
  97 *>          The dimension of the array WORK.
  98 *> \endverbatim
  99 *>
 100 *> \param[out] RWORK
 101 *> \verbatim
 102 *>          RWORK is REAL array, dimension (max(M,N))
 103 *> \endverbatim
 104 *>
 105 *> \param[out] RESULT
 106 *> \verbatim
 107 *>          RESULT is REAL array, dimension (2)
 108 *>          The test ratios:
 109 *>          RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS )
 110 *>          RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
 111 *> \endverbatim
 112 *
 113 *  Authors:
 114 *  ========
 115 *
 116 *> \author Univ. of Tennessee
 117 *> \author Univ. of California Berkeley
 118 *> \author Univ. of Colorado Denver
 119 *> \author NAG Ltd.
 120 *
 121 *> \date November 2011
 122 *
 123 *> \ingroup single_lin
 124 *
 125 *  =====================================================================
 126       SUBROUTINE SLQT01( M, N, A, AF, Q, L, LDA, TAU, WORK, LWORK,
 127      $                   RWORK, RESULT )
 128 *
 129 *  -- LAPACK test routine (version 3.4.0) --
 130 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 131 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 132 *     November 2011
 133 *
 134 *     .. Scalar Arguments ..
 135       INTEGER            LDA, LWORK, M, N
 136 *     ..
 137 *     .. Array Arguments ..
 138       REAL               A( LDA, * ), AF( LDA, * ), L( LDA, * ),
 139      $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
 140      $                   WORK( LWORK )
 141 *     ..
 142 *
 143 *  =====================================================================
 144 *
 145 *     .. Parameters ..
 146       REAL               ZERO, ONE
 147       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0 )
 148       REAL               ROGUE
 149       PARAMETER          ( ROGUE = -1.0E+10 )
 150 *     ..
 151 *     .. Local Scalars ..
 152       INTEGER            INFO, MINMN
 153       REAL               ANORM, EPS, RESID
 154 *     ..
 155 *     .. External Functions ..
 156       REAL               SLAMCH, SLANGE, SLANSY
 157       EXTERNAL           SLAMCH, SLANGE, SLANSY
 158 *     ..
 159 *     .. External Subroutines ..
 160       EXTERNAL           SGELQF, SGEMM, SLACPY, SLASET, SORGLQ, SSYRK
 161 *     ..
 162 *     .. Intrinsic Functions ..
 163       INTRINSIC          MAX, MIN, REAL
 164 *     ..
 165 *     .. Scalars in Common ..
 166       CHARACTER*32       SRNAMT
 167 *     ..
 168 *     .. Common blocks ..
 169       COMMON             / SRNAMC / SRNAMT
 170 *     ..
 171 *     .. Executable Statements ..
 172 *
 173       MINMN = MIN( M, N )
 174       EPS = SLAMCH( 'Epsilon' )
 175 *
 176 *     Copy the matrix A to the array AF.
 177 *
 178       CALL SLACPY( 'Full', M, N, A, LDA, AF, LDA )
 179 *
 180 *     Factorize the matrix A in the array AF.
 181 *
 182       SRNAMT = 'SGELQF'
 183       CALL SGELQF( M, N, AF, LDA, TAU, WORK, LWORK, INFO )
 184 *
 185 *     Copy details of Q
 186 *
 187       CALL SLASET( 'Full', N, N, ROGUE, ROGUE, Q, LDA )
 188       IF( N.GT.1 )
 189      $   CALL SLACPY( 'Upper', M, N-1, AF( 1, 2 ), LDA, Q( 1, 2 ), LDA )
 190 *
 191 *     Generate the n-by-n matrix Q
 192 *
 193       SRNAMT = 'SORGLQ'
 194       CALL SORGLQ( N, N, MINMN, Q, LDA, TAU, WORK, LWORK, INFO )
 195 *
 196 *     Copy L
 197 *
 198       CALL SLASET( 'Full', M, N, ZERO, ZERO, L, LDA )
 199       CALL SLACPY( 'Lower', M, N, AF, LDA, L, LDA )
 200 *
 201 *     Compute L - A*Q'
 202 *
 203       CALL SGEMM( 'No transpose', 'Transpose', M, N, N, -ONE, A, LDA, Q,
 204      $            LDA, ONE, L, LDA )
 205 *
 206 *     Compute norm( L - Q'*A ) / ( N * norm(A) * EPS ) .
 207 *
 208       ANORM = SLANGE( '1', M, N, A, LDA, RWORK )
 209       RESID = SLANGE( '1', M, N, L, LDA, RWORK )
 210       IF( ANORM.GT.ZERO ) THEN
 211          RESULT( 1 ) = ( ( RESID / REAL( MAX( 1, N ) ) ) / ANORM ) / EPS
 212       ELSE
 213          RESULT( 1 ) = ZERO
 214       END IF
 215 *
 216 *     Compute I - Q*Q'
 217 *
 218       CALL SLASET( 'Full', N, N, ZERO, ONE, L, LDA )
 219       CALL SSYRK( 'Upper', 'No transpose', N, N, -ONE, Q, LDA, ONE, L,
 220      $            LDA )
 221 *
 222 *     Compute norm( I - Q*Q' ) / ( N * EPS ) .
 223 *
 224       RESID = SLANSY( '1', 'Upper', N, L, LDA, RWORK )
 225 *
 226       RESULT( 2 ) = ( RESID / REAL( MAX( 1, N ) ) ) / EPS
 227 *
 228       RETURN
 229 *
 230 *     End of SLQT01
 231 *
 232       END