SRC/zlahef_aa.f

   1 *> \brief \b ZLAHEF_AA
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download ZLAHEF_AA + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlahef_aa.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlahef_aa.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlahef_aa.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE ZLAHEF_AA( UPLO, J1, M, NB, A, LDA, IPIV,
  22 *                             H, LDH, WORK )
  23 *
  24 *       .. Scalar Arguments ..
  25 *       CHARACTER    UPLO
  26 *       INTEGER      J1, M, NB, LDA, LDH
  27 *       ..
  28 *       .. Array Arguments ..
  29 *       INTEGER      IPIV( * )
  30 *       COMPLEX*16   A( LDA, * ), H( LDH, * ), WORK( * )
  31 *       ..
  32 *
  33 *
  34 *> \par Purpose:
  35 *  =============
  36 *>
  37 *> \verbatim
  38 *>
  39 *> DLAHEF_AA factorizes a panel of a complex hermitian matrix A using
  40 *> the Aasen's algorithm. The panel consists of a set of NB rows of A
  41 *> when UPLO is U, or a set of NB columns when UPLO is L.
  42 *>
  43 *> In order to factorize the panel, the Aasen's algorithm requires the
  44 *> last row, or column, of the previous panel. The first row, or column,
  45 *> of A is set to be the first row, or column, of an identity matrix,
  46 *> which is used to factorize the first panel.
  47 *>
  48 *> The resulting J-th row of U, or J-th column of L, is stored in the
  49 *> (J-1)-th row, or column, of A (without the unit diagonals), while
  50 *> the diagonal and subdiagonal of A are overwritten by those of T.
  51 *>
  52 *> \endverbatim
  53 *
  54 *  Arguments:
  55 *  ==========
  56 *
  57 *> \param[in] UPLO
  58 *> \verbatim
  59 *>          UPLO is CHARACTER*1
  60 *>          = 'U':  Upper triangle of A is stored;
  61 *>          = 'L':  Lower triangle of A is stored.
  62 *> \endverbatim
  63 *>
  64 *> \param[in] J1
  65 *> \verbatim
  66 *>          J1 is INTEGER
  67 *>          The location of the first row, or column, of the panel
  68 *>          within the submatrix of A, passed to this routine, e.g.,
  69 *>          when called by ZHETRF_AA, for the first panel, J1 is 1,
  70 *>          while for the remaining panels, J1 is 2.
  71 *> \endverbatim
  72 *>
  73 *> \param[in] M
  74 *> \verbatim
  75 *>          M is INTEGER
  76 *>          The dimension of the submatrix. M >= 0.
  77 *> \endverbatim
  78 *>
  79 *> \param[in] NB
  80 *> \verbatim
  81 *>          NB is INTEGER
  82 *>          The dimension of the panel to be facotorized.
  83 *> \endverbatim
  84 *>
  85 *> \param[in,out] A
  86 *> \verbatim
  87 *>          A is COMPLEX*16 array, dimension (LDA,M) for
  88 *>          the first panel, while dimension (LDA,M+1) for the
  89 *>          remaining panels.
  90 *>
  91 *>          On entry, A contains the last row, or column, of
  92 *>          the previous panel, and the trailing submatrix of A
  93 *>          to be factorized, except for the first panel, only
  94 *>          the panel is passed.
  95 *>
  96 *>          On exit, the leading panel is factorized.
  97 *> \endverbatim
  98 *>
  99 *> \param[in] LDA
 100 *> \verbatim
 101 *>          LDA is INTEGER
 102 *>          The leading dimension of the array A.  LDA >= max(1,N).
 103 *> \endverbatim
 104 *>
 105 *> \param[out] IPIV
 106 *> \verbatim
 107 *>          IPIV is INTEGER array, dimension (N)
 108 *>          Details of the row and column interchanges,
 109 *>          the row and column k were interchanged with the row and
 110 *>          column IPIV(k).
 111 *> \endverbatim
 112 *>
 113 *> \param[in,out] H
 114 *> \verbatim
 115 *>          H is COMPLEX*16 workspace, dimension (LDH,NB).
 116 *>
 117 *> \endverbatim
 118 *>
 119 *> \param[in] LDH
 120 *> \verbatim
 121 *>          LDH is INTEGER
 122 *>          The leading dimension of the workspace H. LDH >= max(1,M).
 123 *> \endverbatim
 124 *>
 125 *> \param[out] WORK
 126 *> \verbatim
 127 *>          WORK is COMPLEX*16 workspace, dimension (M).
 128 *> \endverbatim
 129 *>
 130 *
 131 *  Authors:
 132 *  ========
 133 *
 134 *> \author Univ. of Tennessee
 135 *> \author Univ. of California Berkeley
 136 *> \author Univ. of Colorado Denver
 137 *> \author NAG Ltd.
 138 *
 139 *> \date December 2016
 140 *
 141 *> \ingroup complex16HEcomputational
 142 *
 143 *  =====================================================================
 144       SUBROUTINE ZLAHEF_AA( UPLO, J1, M, NB, A, LDA, IPIV,
 145      $                      H, LDH, WORK )
 146 *
 147 *  -- LAPACK computational routine (version 3.7.0) --
 148 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 149 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 150 *     December 2016
 151 *
 152       IMPLICIT NONE
 153 *
 154 *     .. Scalar Arguments ..
 155       CHARACTER    UPLO
 156       INTEGER      M, NB, J1, LDA, LDH
 157 *     ..
 158 *     .. Array Arguments ..
 159       INTEGER      IPIV( * )
 160       COMPLEX*16   A( LDA, * ), H( LDH, * ), WORK( * )
 161 *     ..
 162 *
 163 *  =====================================================================
 164 *     .. Parameters ..
 165       COMPLEX*16   ZERO, ONE
 166       PARAMETER    ( ZERO = (0.0D+0, 0.0D+0), ONE = (1.0D+0, 0.0D+0) )
 167 *
 168 *     .. Local Scalars ..
 169       INTEGER      J, K, K1, I1, I2
 170       COMPLEX*16   PIV, ALPHA
 171 *     ..
 172 *     .. External Functions ..
 173       LOGICAL      LSAME
 174       INTEGER      IZAMAX, ILAENV
 175       EXTERNAL     LSAME, ILAENV, IZAMAX
 176 *     ..
 177 *     .. External Subroutines ..
 178       EXTERNAL     XERBLA
 179 *     ..
 180 *     .. Intrinsic Functions ..
 181       INTRINSIC    DBLE, DCONJG, MAX
 182 *     ..
 183 *     .. Executable Statements ..
 184 *
 185       J = 1
 186 *
 187 *     K1 is the first column of the panel to be factorized
 188 *     i.e.,  K1 is 2 for the first block column, and 1 for the rest of the blocks
 189 *
 190       K1 = (2-J1)+1
 191 *
 192       IF( LSAME( UPLO, 'U' ) ) THEN
 193 *
 194 *        .....................................................
 195 *        Factorize A as U**T*D*U using the upper triangle of A
 196 *        .....................................................
 197 *
 198  10      CONTINUE
 199          IF ( J.GT.MIN(M, NB) )
 200      $      GO TO 20
 201 *
 202 *        K is the column to be factorized
 203 *         when being called from ZHETRF_AA,
 204 *         > for the first block column, J1 is 1, hence J1+J-1 is J,
 205 *         > for the rest of the columns, J1 is 2, and J1+J-1 is J+1,
 206 *
 207          K = J1+J-1
 208 *
 209 *        H(J:N, J) := A(J, J:N) - H(J:N, 1:(J-1)) * L(J1:(J-1), J),
 210 *         where H(J:N, J) has been initialized to be A(J, J:N)
 211 *
 212          IF( K.GT.2 ) THEN
 213 *
 214 *        K is the column to be factorized
 215 *         > for the first block column, K is J, skipping the first two
 216 *           columns
 217 *         > for the rest of the columns, K is J+1, skipping only the
 218 *           first column
 219 *
 220             CALL ZLACGV( J-K1, A( 1, J ), 1 )
 221             CALL ZGEMV( 'No transpose', M-J+1, J-K1,
 222      $                 -ONE, H( J, K1 ), LDH,
 223      $                       A( 1, J ), 1,
 224      $                  ONE, H( J, J ), 1 )
 225             CALL ZLACGV( J-K1, A( 1, J ), 1 )
 226          END IF
 227 *
 228 *        Copy H(i:n, i) into WORK
 229 *
 230          CALL ZCOPY( M-J+1, H( J, J ), 1, WORK( 1 ), 1 )
 231 *
 232          IF( J.GT.K1 ) THEN
 233 *
 234 *           Compute WORK := WORK - L(J-1, J:N) * T(J-1,J),
 235 *            where A(J-1, J) stores T(J-1, J) and A(J-2, J:N) stores U(J-1, J:N)
 236 *
 237             ALPHA = -DCONJG( A( K-1, J ) )
 238             CALL ZAXPY( M-J+1, ALPHA, A( K-2, J ), LDA, WORK( 1 ), 1 )
 239          END IF
 240 *
 241 *        Set A(J, J) = T(J, J)
 242 *
 243          A( K, J ) = DBLE( WORK( 1 ) )
 244 *
 245          IF( J.LT.M ) THEN
 246 *
 247 *           Compute WORK(2:N) = T(J, J) L(J, (J+1):N)
 248 *            where A(J, J) stores T(J, J) and A(J-1, (J+1):N) stores U(J, (J+1):N)
 249 *
 250             IF( K.GT.1 ) THEN
 251                ALPHA = -A( K, J )
 252                CALL ZAXPY( M-J, ALPHA, A( K-1, J+1 ), LDA,
 253      $                                 WORK( 2 ), 1 )
 254             ENDIF
 255 *
 256 *           Find max(|WORK(2:n)|)
 257 *
 258             I2 = IZAMAX( M-J, WORK( 2 ), 1 ) + 1
 259             PIV = WORK( I2 )
 260 *
 261 *           Apply hermitian pivot
 262 *
 263             IF( (I2.NE.2) .AND. (PIV.NE.0) ) THEN
 264 *
 265 *              Swap WORK(I1) and WORK(I2)
 266 *
 267                I1 = 2
 268                WORK( I2 ) = WORK( I1 )
 269                WORK( I1 ) = PIV
 270 *
 271 *              Swap A(I1, I1+1:N) with A(I1+1:N, I2)
 272 *
 273                I1 = I1+J-1
 274                I2 = I2+J-1
 275                CALL ZSWAP( I2-I1-1, A( J1+I1-1, I1+1 ), LDA,
 276      $                              A( J1+I1, I2 ), 1 )
 277                CALL ZLACGV( I2-I1, A( J1+I1-1, I1+1 ), LDA )
 278                CALL ZLACGV( I2-I1-1, A( J1+I1, I2 ), 1 )
 279 *
 280 *              Swap A(I1, I2+1:N) with A(I2, I2+1:N)
 281 *
 282                CALL ZSWAP( M-I2, A( J1+I1-1, I2+1 ), LDA,
 283      $                           A( J1+I2-1, I2+1 ), LDA )
 284 *
 285 *              Swap A(I1, I1) with A(I2,I2)
 286 *
 287                PIV = A( I1+J1-1, I1 )
 288                A( J1+I1-1, I1 ) = A( J1+I2-1, I2 )
 289                A( J1+I2-1, I2 ) = PIV
 290 *
 291 *              Swap H(I1, 1:J1) with H(I2, 1:J1)
 292 *
 293                CALL ZSWAP( I1-1, H( I1, 1 ), LDH, H( I2, 1 ), LDH )
 294                IPIV( I1 ) = I2
 295 *
 296                IF( I1.GT.(K1-1) ) THEN
 297 *
 298 *                 Swap L(1:I1-1, I1) with L(1:I1-1, I2),
 299 *                  skipping the first column
 300 *
 301                   CALL ZSWAP( I1-K1+1, A( 1, I1 ), 1,
 302      $                                 A( 1, I2 ), 1 )
 303                END IF
 304             ELSE
 305                IPIV( J+1 ) = J+1
 306             ENDIF
 307 *
 308 *           Set A(J, J+1) = T(J, J+1)
 309 *
 310             A( K, J+1 ) = WORK( 2 )
 311 *
 312             IF( J.LT.NB ) THEN
 313 *
 314 *              Copy A(J+1:N, J+1) into H(J:N, J),
 315 *
 316                CALL ZCOPY( M-J, A( K+1, J+1 ), LDA,
 317      $                          H( J+1, J+1 ), 1 )
 318             END IF
 319 *
 320 *           Compute L(J+2, J+1) = WORK( 3:N ) / T(J, J+1),
 321 *            where A(J, J+1) = T(J, J+1) and A(J+2:N, J) = L(J+2:N, J+1)
 322 *
 323             IF( A( K, J+1 ).NE.ZERO ) THEN
 324                ALPHA = ONE / A( K, J+1 )
 325                CALL ZCOPY( M-J-1, WORK( 3 ), 1, A( K, J+2 ), LDA )
 326                CALL ZSCAL( M-J-1, ALPHA, A( K, J+2 ), LDA )
 327             ELSE
 328                CALL ZLASET( 'Full', 1, M-J-1, ZERO, ZERO,
 329      $                      A( K, J+2 ), LDA)
 330             END IF
 331          END IF
 332          J = J + 1
 333          GO TO 10
 334  20      CONTINUE
 335 *
 336       ELSE
 337 *
 338 *        .....................................................
 339 *        Factorize A as L*D*L**T using the lower triangle of A
 340 *        .....................................................
 341 *
 342  30      CONTINUE
 343          IF( J.GT.MIN( M, NB ) )
 344      $      GO TO 40
 345 *
 346 *        K is the column to be factorized
 347 *         when being called from ZHETRF_AA,
 348 *         > for the first block column, J1 is 1, hence J1+J-1 is J,
 349 *         > for the rest of the columns, J1 is 2, and J1+J-1 is J+1,
 350 *
 351          K = J1+J-1
 352 *
 353 *        H(J:N, J) := A(J:N, J) - H(J:N, 1:(J-1)) * L(J, J1:(J-1))^T,
 354 *         where H(J:N, J) has been initialized to be A(J:N, J)
 355 *
 356          IF( K.GT.2 ) THEN
 357 *
 358 *        K is the column to be factorized
 359 *         > for the first block column, K is J, skipping the first two
 360 *           columns
 361 *         > for the rest of the columns, K is J+1, skipping only the
 362 *           first column
 363 *
 364             CALL ZLACGV( J-K1, A( J, 1 ), LDA )
 365             CALL ZGEMV( 'No transpose', M-J+1, J-K1,
 366      $                 -ONE, H( J, K1 ), LDH,
 367      $                       A( J, 1 ), LDA,
 368      $                  ONE, H( J, J ), 1 )
 369             CALL ZLACGV( J-K1, A( J, 1 ), LDA )
 370          END IF
 371 *
 372 *        Copy H(J:N, J) into WORK
 373 *
 374          CALL ZCOPY( M-J+1, H( J, J ), 1, WORK( 1 ), 1 )
 375 *
 376          IF( J.GT.K1 ) THEN
 377 *
 378 *           Compute WORK := WORK - L(J:N, J-1) * T(J-1,J),
 379 *            where A(J-1, J) = T(J-1, J) and A(J, J-2) = L(J, J-1)
 380 *
 381             ALPHA = -DCONJG( A( J, K-1 ) )
 382             CALL ZAXPY( M-J+1, ALPHA, A( J, K-2 ), 1, WORK( 1 ), 1 )
 383          END IF
 384 *
 385 *        Set A(J, J) = T(J, J)
 386 *
 387          A( J, K ) = DBLE( WORK( 1 ) )
 388 *
 389          IF( J.LT.M ) THEN
 390 *
 391 *           Compute WORK(2:N) = T(J, J) L((J+1):N, J)
 392 *            where A(J, J) = T(J, J) and A((J+1):N, J-1) = L((J+1):N, J)
 393 *
 394             IF( K.GT.1 ) THEN
 395                ALPHA = -A( J, K )
 396                CALL ZAXPY( M-J, ALPHA, A( J+1, K-1 ), 1,
 397      $                                 WORK( 2 ), 1 )
 398             ENDIF
 399 *
 400 *           Find max(|WORK(2:n)|)
 401 *
 402             I2 = IZAMAX( M-J, WORK( 2 ), 1 ) + 1
 403             PIV = WORK( I2 )
 404 *
 405 *           Apply hermitian pivot
 406 *
 407             IF( (I2.NE.2) .AND. (PIV.NE.0) ) THEN
 408 *
 409 *              Swap WORK(I1) and WORK(I2)
 410 *
 411                I1 = 2
 412                WORK( I2 ) = WORK( I1 )
 413                WORK( I1 ) = PIV
 414 *
 415 *              Swap A(I1+1:N, I1) with A(I2, I1+1:N)
 416 *
 417                I1 = I1+J-1
 418                I2 = I2+J-1
 419                CALL ZSWAP( I2-I1-1, A( I1+1, J1+I1-1 ), 1,
 420      $                              A( I2, J1+I1 ), LDA )
 421                CALL ZLACGV( I2-I1, A( I1+1, J1+I1-1 ), 1 )
 422                CALL ZLACGV( I2-I1-1, A( I2, J1+I1 ), LDA )
 423 *
 424 *              Swap A(I2+1:N, I1) with A(I2+1:N, I2)
 425 *
 426                CALL ZSWAP( M-I2, A( I2+1, J1+I1-1 ), 1,
 427      $                           A( I2+1, J1+I2-1 ), 1 )
 428 *
 429 *              Swap A(I1, I1) with A(I2, I2)
 430 *
 431                PIV = A( I1, J1+I1-1 )
 432                A( I1, J1+I1-1 ) = A( I2, J1+I2-1 )
 433                A( I2, J1+I2-1 ) = PIV
 434 *
 435 *              Swap H(I1, I1:J1) with H(I2, I2:J1)
 436 *
 437                CALL ZSWAP( I1-1, H( I1, 1 ), LDH, H( I2, 1 ), LDH )
 438                IPIV( I1 ) = I2
 439 *
 440                IF( I1.GT.(K1-1) ) THEN
 441 *
 442 *                 Swap L(1:I1-1, I1) with L(1:I1-1, I2),
 443 *                  skipping the first column
 444 *
 445                   CALL ZSWAP( I1-K1+1, A( I1, 1 ), LDA,
 446      $                                 A( I2, 1 ), LDA )
 447                END IF
 448             ELSE
 449                IPIV( J+1 ) = J+1
 450             ENDIF
 451 *
 452 *           Set A(J+1, J) = T(J+1, J)
 453 *
 454             A( J+1, K ) = WORK( 2 )
 455 *
 456             IF( J.LT.NB ) THEN
 457 *
 458 *              Copy A(J+1:N, J+1) into H(J+1:N, J),
 459 *
 460                CALL ZCOPY( M-J, A( J+1, K+1 ), 1,
 461      $                          H( J+1, J+1 ), 1 )
 462             END IF
 463 *
 464 *           Compute L(J+2, J+1) = WORK( 3:N ) / T(J, J+1),
 465 *            where A(J, J+1) = T(J, J+1) and A(J+2:N, J) = L(J+2:N, J+1)
 466 *
 467             IF( A( J+1, K ).NE.ZERO ) THEN
 468                ALPHA = ONE / A( J+1, K )
 469                CALL ZCOPY( M-J-1, WORK( 3 ), 1, A( J+2, K ), 1 )
 470                CALL ZSCAL( M-J-1, ALPHA, A( J+2, K ), 1 )
 471             ELSE
 472                CALL ZLASET( 'Full', M-J-1, 1, ZERO, ZERO,
 473      $                      A( J+2, K ), LDA )
 474             END IF
 475          END IF
 476          J = J + 1
 477          GO TO 30
 478  40      CONTINUE
 479       END IF
 480       RETURN
 481 *
 482 *     End of ZLAHEF_AA
 483 *
 484       END