SRC/ssyevr.f

   1 *> \brief <b> SSYEVR computes the eigenvalues and, optionally, the left and/or right eigenvectors for SY matrices</b>
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download SSYEVR + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ssyevr.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ssyevr.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ssyevr.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE SSYEVR( JOBZ, RANGE, UPLO, N, A, LDA, VL, VU, IL, IU,
  22 *                          ABSTOL, M, W, Z, LDZ, ISUPPZ, WORK, LWORK,
  23 *                          IWORK, LIWORK, INFO )
  24 *
  25 *       .. Scalar Arguments ..
  26 *       CHARACTER          JOBZ, RANGE, UPLO
  27 *       INTEGER            IL, INFO, IU, LDA, LDZ, LIWORK, LWORK, M, N
  28 *       REAL               ABSTOL, VL, VU
  29 *       ..
  30 *       .. Array Arguments ..
  31 *       INTEGER            ISUPPZ( * ), IWORK( * )
  32 *       REAL               A( LDA, * ), W( * ), WORK( * ), Z( LDZ, * )
  33 *       ..
  34 *
  35 *
  36 *> \par Purpose:
  37 *  =============
  38 *>
  39 *> \verbatim
  40 *>
  41 *> SSYEVR computes selected eigenvalues and, optionally, eigenvectors
  42 *> of a real symmetric matrix A.  Eigenvalues and eigenvectors can be
  43 *> selected by specifying either a range of values or a range of
  44 *> indices for the desired eigenvalues.
  45 *>
  46 *> SSYEVR first reduces the matrix A to tridiagonal form T with a call
  47 *> to SSYTRD.  Then, whenever possible, SSYEVR calls SSTEMR to compute
  48 *> the eigenspectrum using Relatively Robust Representations.  SSTEMR
  49 *> computes eigenvalues by the dqds algorithm, while orthogonal
  50 *> eigenvectors are computed from various "good" L D L^T representations
  51 *> (also known as Relatively Robust Representations). Gram-Schmidt
  52 *> orthogonalization is avoided as far as possible. More specifically,
  53 *> the various steps of the algorithm are as follows.
  54 *>
  55 *> For each unreduced block (submatrix) of T,
  56 *>    (a) Compute T - sigma I  = L D L^T, so that L and D
  57 *>        define all the wanted eigenvalues to high relative accuracy.
  58 *>        This means that small relative changes in the entries of D and L
  59 *>        cause only small relative changes in the eigenvalues and
  60 *>        eigenvectors. The standard (unfactored) representation of the
  61 *>        tridiagonal matrix T does not have this property in general.
  62 *>    (b) Compute the eigenvalues to suitable accuracy.
  63 *>        If the eigenvectors are desired, the algorithm attains full
  64 *>        accuracy of the computed eigenvalues only right before
  65 *>        the corresponding vectors have to be computed, see steps c) and d).
  66 *>    (c) For each cluster of close eigenvalues, select a new
  67 *>        shift close to the cluster, find a new factorization, and refine
  68 *>        the shifted eigenvalues to suitable accuracy.
  69 *>    (d) For each eigenvalue with a large enough relative separation compute
  70 *>        the corresponding eigenvector by forming a rank revealing twisted
  71 *>        factorization. Go back to (c) for any clusters that remain.
  72 *>
  73 *> The desired accuracy of the output can be specified by the input
  74 *> parameter ABSTOL.
  75 *>
  76 *> For more details, see SSTEMR's documentation and:
  77 *> - Inderjit S. Dhillon and Beresford N. Parlett: "Multiple representations
  78 *>   to compute orthogonal eigenvectors of symmetric tridiagonal matrices,"
  79 *>   Linear Algebra and its Applications, 387(1), pp. 1-28, August 2004.
  80 *> - Inderjit Dhillon and Beresford Parlett: "Orthogonal Eigenvectors and
  81 *>   Relative Gaps," SIAM Journal on Matrix Analysis and Applications, Vol. 25,
  82 *>   2004.  Also LAPACK Working Note 154.
  83 *> - Inderjit Dhillon: "A new O(n^2) algorithm for the symmetric
  84 *>   tridiagonal eigenvalue/eigenvector problem",
  85 *>   Computer Science Division Technical Report No. UCB/CSD-97-971,
  86 *>   UC Berkeley, May 1997.
  87 *>
  88 *>
  89 *> Note 1 : SSYEVR calls SSTEMR when the full spectrum is requested
  90 *> on machines which conform to the ieee-754 floating point standard.
  91 *> SSYEVR calls SSTEBZ and SSTEIN on non-ieee machines and
  92 *> when partial spectrum requests are made.
  93 *>
  94 *> Normal execution of SSTEMR may create NaNs and infinities and
  95 *> hence may abort due to a floating point exception in environments
  96 *> which do not handle NaNs and infinities in the ieee standard default
  97 *> manner.
  98 *> \endverbatim
  99 *
 100 *  Arguments:
 101 *  ==========
 102 *
 103 *> \param[in] JOBZ
 104 *> \verbatim
 105 *>          JOBZ is CHARACTER*1
 106 *>          = 'N':  Compute eigenvalues only;
 107 *>          = 'V':  Compute eigenvalues and eigenvectors.
 108 *> \endverbatim
 109 *>
 110 *> \param[in] RANGE
 111 *> \verbatim
 112 *>          RANGE is CHARACTER*1
 113 *>          = 'A': all eigenvalues will be found.
 114 *>          = 'V': all eigenvalues in the half-open interval (VL,VU]
 115 *>                 will be found.
 116 *>          = 'I': the IL-th through IU-th eigenvalues will be found.
 117 *>          For RANGE = 'V' or 'I' and IU - IL < N - 1, SSTEBZ and
 118 *>          SSTEIN are called
 119 *> \endverbatim
 120 *>
 121 *> \param[in] UPLO
 122 *> \verbatim
 123 *>          UPLO is CHARACTER*1
 124 *>          = 'U':  Upper triangle of A is stored;
 125 *>          = 'L':  Lower triangle of A is stored.
 126 *> \endverbatim
 127 *>
 128 *> \param[in] N
 129 *> \verbatim
 130 *>          N is INTEGER
 131 *>          The order of the matrix A.  N >= 0.
 132 *> \endverbatim
 133 *>
 134 *> \param[in,out] A
 135 *> \verbatim
 136 *>          A is REAL array, dimension (LDA, N)
 137 *>          On entry, the symmetric matrix A.  If UPLO = 'U', the
 138 *>          leading N-by-N upper triangular part of A contains the
 139 *>          upper triangular part of the matrix A.  If UPLO = 'L',
 140 *>          the leading N-by-N lower triangular part of A contains
 141 *>          the lower triangular part of the matrix A.
 142 *>          On exit, the lower triangle (if UPLO='L') or the upper
 143 *>          triangle (if UPLO='U') of A, including the diagonal, is
 144 *>          destroyed.
 145 *> \endverbatim
 146 *>
 147 *> \param[in] LDA
 148 *> \verbatim
 149 *>          LDA is INTEGER
 150 *>          The leading dimension of the array A.  LDA >= max(1,N).
 151 *> \endverbatim
 152 *>
 153 *> \param[in] VL
 154 *> \verbatim
 155 *>          VL is REAL
 156 *>          If RANGE='V', the lower bound of the interval to
 157 *>          be searched for eigenvalues. VL < VU.
 158 *>          Not referenced if RANGE = 'A' or 'I'.
 159 *> \endverbatim
 160 *>
 161 *> \param[in] VU
 162 *> \verbatim
 163 *>          VU is REAL
 164 *>          If RANGE='V', the upper bound of the interval to
 165 *>          be searched for eigenvalues. VL < VU.
 166 *>          Not referenced if RANGE = 'A' or 'I'.
 167 *> \endverbatim
 168 *>
 169 *> \param[in] IL
 170 *> \verbatim
 171 *>          IL is INTEGER
 172 *>          If RANGE='I', the index of the
 173 *>          smallest eigenvalue to be returned.
 174 *>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
 175 *>          Not referenced if RANGE = 'A' or 'V'.
 176 *> \endverbatim
 177 *>
 178 *> \param[in] IU
 179 *> \verbatim
 180 *>          IU is INTEGER
 181 *>          If RANGE='I', the index of the
 182 *>          largest eigenvalue to be returned.
 183 *>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
 184 *>          Not referenced if RANGE = 'A' or 'V'.
 185 *> \endverbatim
 186 *>
 187 *> \param[in] ABSTOL
 188 *> \verbatim
 189 *>          ABSTOL is REAL
 190 *>          The absolute error tolerance for the eigenvalues.
 191 *>          An approximate eigenvalue is accepted as converged
 192 *>          when it is determined to lie in an interval [a,b]
 193 *>          of width less than or equal to
 194 *>
 195 *>                  ABSTOL + EPS *   max( |a|,|b| ) ,
 196 *>
 197 *>          where EPS is the machine precision.  If ABSTOL is less than
 198 *>          or equal to zero, then  EPS*|T|  will be used in its place,
 199 *>          where |T| is the 1-norm of the tridiagonal matrix obtained
 200 *>          by reducing A to tridiagonal form.
 201 *>
 202 *>          See "Computing Small Singular Values of Bidiagonal Matrices
 203 *>          with Guaranteed High Relative Accuracy," by Demmel and
 204 *>          Kahan, LAPACK Working Note #3.
 205 *>
 206 *>          If high relative accuracy is important, set ABSTOL to
 207 *>          SLAMCH( 'Safe minimum' ).  Doing so will guarantee that
 208 *>          eigenvalues are computed to high relative accuracy when
 209 *>          possible in future releases.  The current code does not
 210 *>          make any guarantees about high relative accuracy, but
 211 *>          future releases will. See J. Barlow and J. Demmel,
 212 *>          "Computing Accurate Eigensystems of Scaled Diagonally
 213 *>          Dominant Matrices", LAPACK Working Note #7, for a discussion
 214 *>          of which matrices define their eigenvalues to high relative
 215 *>          accuracy.
 216 *> \endverbatim
 217 *>
 218 *> \param[out] M
 219 *> \verbatim
 220 *>          M is INTEGER
 221 *>          The total number of eigenvalues found.  0 <= M <= N.
 222 *>          If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
 223 *> \endverbatim
 224 *>
 225 *> \param[out] W
 226 *> \verbatim
 227 *>          W is REAL array, dimension (N)
 228 *>          The first M elements contain the selected eigenvalues in
 229 *>          ascending order.
 230 *> \endverbatim
 231 *>
 232 *> \param[out] Z
 233 *> \verbatim
 234 *>          Z is REAL array, dimension (LDZ, max(1,M))
 235 *>          If JOBZ = 'V', then if INFO = 0, the first M columns of Z
 236 *>          contain the orthonormal eigenvectors of the matrix A
 237 *>          corresponding to the selected eigenvalues, with the i-th
 238 *>          column of Z holding the eigenvector associated with W(i).
 239 *>          If JOBZ = 'N', then Z is not referenced.
 240 *>          Note: the user must ensure that at least max(1,M) columns are
 241 *>          supplied in the array Z; if RANGE = 'V', the exact value of M
 242 *>          is not known in advance and an upper bound must be used.
 243 *>          Supplying N columns is always safe.
 244 *> \endverbatim
 245 *>
 246 *> \param[in] LDZ
 247 *> \verbatim
 248 *>          LDZ is INTEGER
 249 *>          The leading dimension of the array Z.  LDZ >= 1, and if
 250 *>          JOBZ = 'V', LDZ >= max(1,N).
 251 *> \endverbatim
 252 *>
 253 *> \param[out] ISUPPZ
 254 *> \verbatim
 255 *>          ISUPPZ is INTEGER array, dimension ( 2*max(1,M) )
 256 *>          The support of the eigenvectors in Z, i.e., the indices
 257 *>          indicating the nonzero elements in Z. The i-th eigenvector
 258 *>          is nonzero only in elements ISUPPZ( 2*i-1 ) through
 259 *>          ISUPPZ( 2*i ).
 260 *>          Implemented only for RANGE = 'A' or 'I' and IU - IL = N - 1
 261 *> \endverbatim
 262 *>
 263 *> \param[out] WORK
 264 *> \verbatim
 265 *>          WORK is REAL array, dimension (MAX(1,LWORK))
 266 *>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
 267 *> \endverbatim
 268 *>
 269 *> \param[in] LWORK
 270 *> \verbatim
 271 *>          LWORK is INTEGER
 272 *>          The dimension of the array WORK.  LWORK >= max(1,26*N).
 273 *>          For optimal efficiency, LWORK >= (NB+6)*N,
 274 *>          where NB is the max of the blocksize for SSYTRD and SORMTR
 275 *>          returned by ILAENV.
 276 *>
 277 *>          If LWORK = -1, then a workspace query is assumed; the routine
 278 *>          only calculates the optimal sizes of the WORK and IWORK
 279 *>          arrays, returns these values as the first entries of the WORK
 280 *>          and IWORK arrays, and no error message related to LWORK or
 281 *>          LIWORK is issued by XERBLA.
 282 *> \endverbatim
 283 *>
 284 *> \param[out] IWORK
 285 *> \verbatim
 286 *>          IWORK is INTEGER array, dimension (MAX(1,LIWORK))
 287 *>          On exit, if INFO = 0, IWORK(1) returns the optimal LWORK.
 288 *> \endverbatim
 289 *>
 290 *> \param[in] LIWORK
 291 *> \verbatim
 292 *>          LIWORK is INTEGER
 293 *>          The dimension of the array IWORK.  LIWORK >= max(1,10*N).
 294 *>
 295 *>          If LIWORK = -1, then a workspace query is assumed; the
 296 *>          routine only calculates the optimal sizes of the WORK and
 297 *>          IWORK arrays, returns these values as the first entries of
 298 *>          the WORK and IWORK arrays, and no error message related to
 299 *>          LWORK or LIWORK is issued by XERBLA.
 300 *> \endverbatim
 301 *>
 302 *> \param[out] INFO
 303 *> \verbatim
 304 *>          INFO is INTEGER
 305 *>          = 0:  successful exit
 306 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 307 *>          > 0:  Internal error
 308 *> \endverbatim
 309 *
 310 *  Authors:
 311 *  ========
 312 *
 313 *> \author Univ. of Tennessee
 314 *> \author Univ. of California Berkeley
 315 *> \author Univ. of Colorado Denver
 316 *> \author NAG Ltd.
 317 *
 318 *> \date June 2016
 319 *
 320 *> \ingroup realSYeigen
 321 *
 322 *> \par Contributors:
 323 *  ==================
 324 *>
 325 *>     Inderjit Dhillon, IBM Almaden, USA \n
 326 *>     Osni Marques, LBNL/NERSC, USA \n
 327 *>     Ken Stanley, Computer Science Division, University of
 328 *>       California at Berkeley, USA \n
 329 *>     Jason Riedy, Computer Science Division, University of
 330 *>       California at Berkeley, USA \n
 331 *>
 332 *  =====================================================================
 333       SUBROUTINE SSYEVR( JOBZ, RANGE, UPLO, N, A, LDA, VL, VU, IL, IU,
 334      $                   ABSTOL, M, W, Z, LDZ, ISUPPZ, WORK, LWORK,
 335      $                   IWORK, LIWORK, INFO )
 336 *
 337 *  -- LAPACK driver routine (version 3.6.1) --
 338 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 339 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 340 *     June 2016
 341 *
 342 *     .. Scalar Arguments ..
 343       CHARACTER          JOBZ, RANGE, UPLO
 344       INTEGER            IL, INFO, IU, LDA, LDZ, LIWORK, LWORK, M, N
 345       REAL               ABSTOL, VL, VU
 346 *     ..
 347 *     .. Array Arguments ..
 348       INTEGER            ISUPPZ( * ), IWORK( * )
 349       REAL               A( LDA, * ), W( * ), WORK( * ), Z( LDZ, * )
 350 *     ..
 351 *
 352 * =====================================================================
 353 *
 354 *     .. Parameters ..
 355       REAL               ZERO, ONE, TWO
 356       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0, TWO = 2.0E+0 )
 357 *     ..
 358 *     .. Local Scalars ..
 359       LOGICAL            ALLEIG, INDEIG, LOWER, LQUERY, TEST, VALEIG,
 360      $                   WANTZ, TRYRAC
 361       CHARACTER          ORDER
 362       INTEGER            I, IEEEOK, IINFO, IMAX, INDD, INDDD, INDE,
 363      $                   INDEE, INDIBL, INDIFL, INDISP, INDIWO, INDTAU,
 364      $                   INDWK, INDWKN, ISCALE, J, JJ, LIWMIN,
 365      $                   LLWORK, LLWRKN, LWKOPT, LWMIN, NB, NSPLIT
 366       REAL               ABSTLL, ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN,
 367      $                   SIGMA, SMLNUM, TMP1, VLL, VUU
 368 *     ..
 369 *     .. External Functions ..
 370       LOGICAL            LSAME
 371       INTEGER            ILAENV
 372       REAL               SLAMCH, SLANSY
 373       EXTERNAL           LSAME, ILAENV, SLAMCH, SLANSY
 374 *     ..
 375 *     .. External Subroutines ..
 376       EXTERNAL           SCOPY, SORMTR, SSCAL, SSTEBZ, SSTEMR, SSTEIN,
 377      $                   SSTERF, SSWAP, SSYTRD, XERBLA
 378 *     ..
 379 *     .. Intrinsic Functions ..
 380       INTRINSIC          MAX, MIN, SQRT
 381 *     ..
 382 *     .. Executable Statements ..
 383 *
 384 *     Test the input parameters.
 385 *
 386       IEEEOK = ILAENV( 10, 'SSYEVR', 'N', 1, 2, 3, 4 )
 387 *
 388       LOWER = LSAME( UPLO, 'L' )
 389       WANTZ = LSAME( JOBZ, 'V' )
 390       ALLEIG = LSAME( RANGE, 'A' )
 391       VALEIG = LSAME( RANGE, 'V' )
 392       INDEIG = LSAME( RANGE, 'I' )
 393 *
 394       LQUERY = ( ( LWORK.EQ.-1 ) .OR. ( LIWORK.EQ.-1 ) )
 395 *
 396       LWMIN = MAX( 1, 26*N )
 397       LIWMIN = MAX( 1, 10*N )
 398 *
 399       INFO = 0
 400       IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
 401          INFO = -1
 402       ELSE IF( .NOT.( ALLEIG .OR. VALEIG .OR. INDEIG ) ) THEN
 403          INFO = -2
 404       ELSE IF( .NOT.( LOWER .OR. LSAME( UPLO, 'U' ) ) ) THEN
 405          INFO = -3
 406       ELSE IF( N.LT.0 ) THEN
 407          INFO = -4
 408       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
 409          INFO = -6
 410       ELSE
 411          IF( VALEIG ) THEN
 412             IF( N.GT.0 .AND. VU.LE.VL )
 413      $         INFO = -8
 414          ELSE IF( INDEIG ) THEN
 415             IF( IL.LT.1 .OR. IL.GT.MAX( 1, N ) ) THEN
 416                INFO = -9
 417             ELSE IF( IU.LT.MIN( N, IL ) .OR. IU.GT.N ) THEN
 418                INFO = -10
 419             END IF
 420          END IF
 421       END IF
 422       IF( INFO.EQ.0 ) THEN
 423          IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
 424             INFO = -15
 425          END IF
 426       END IF
 427 *
 428       IF( INFO.EQ.0 ) THEN
 429          NB = ILAENV( 1, 'SSYTRD', UPLO, N, -1, -1, -1 )
 430          NB = MAX( NB, ILAENV( 1, 'SORMTR', UPLO, N, -1, -1, -1 ) )
 431          LWKOPT = MAX( ( NB+1 )*N, LWMIN )
 432          WORK( 1 ) = LWKOPT
 433          IWORK( 1 ) = LIWMIN
 434 *
 435          IF( LWORK.LT.LWMIN .AND. .NOT.LQUERY ) THEN
 436             INFO = -18
 437          ELSE IF( LIWORK.LT.LIWMIN .AND. .NOT.LQUERY ) THEN
 438             INFO = -20
 439          END IF
 440       END IF
 441 *
 442       IF( INFO.NE.0 ) THEN
 443          CALL XERBLA( 'SSYEVR', -INFO )
 444          RETURN
 445       ELSE IF( LQUERY ) THEN
 446          RETURN
 447       END IF
 448 *
 449 *     Quick return if possible
 450 *
 451       M = 0
 452       IF( N.EQ.0 ) THEN
 453          WORK( 1 ) = 1
 454          RETURN
 455       END IF
 456 *
 457       IF( N.EQ.1 ) THEN
 458          WORK( 1 ) = 26
 459          IF( ALLEIG .OR. INDEIG ) THEN
 460             M = 1
 461             W( 1 ) = A( 1, 1 )
 462          ELSE
 463             IF( VL.LT.A( 1, 1 ) .AND. VU.GE.A( 1, 1 ) ) THEN
 464                M = 1
 465                W( 1 ) = A( 1, 1 )
 466             END IF
 467          END IF
 468          IF( WANTZ ) THEN
 469             Z( 1, 1 ) = ONE
 470             ISUPPZ( 1 ) = 1
 471             ISUPPZ( 2 ) = 1
 472          END IF
 473          RETURN
 474       END IF
 475 *
 476 *     Get machine constants.
 477 *
 478       SAFMIN = SLAMCH( 'Safe minimum' )
 479       EPS = SLAMCH( 'Precision' )
 480       SMLNUM = SAFMIN / EPS
 481       BIGNUM = ONE / SMLNUM
 482       RMIN = SQRT( SMLNUM )
 483       RMAX = MIN( SQRT( BIGNUM ), ONE / SQRT( SQRT( SAFMIN ) ) )
 484 *
 485 *     Scale matrix to allowable range, if necessary.
 486 *
 487       ISCALE = 0
 488       ABSTLL = ABSTOL
 489       IF (VALEIG) THEN
 490          VLL = VL
 491          VUU = VU
 492       END IF
 493       ANRM = SLANSY( 'M', UPLO, N, A, LDA, WORK )
 494       IF( ANRM.GT.ZERO .AND. ANRM.LT.RMIN ) THEN
 495          ISCALE = 1
 496          SIGMA = RMIN / ANRM
 497       ELSE IF( ANRM.GT.RMAX ) THEN
 498          ISCALE = 1
 499          SIGMA = RMAX / ANRM
 500       END IF
 501       IF( ISCALE.EQ.1 ) THEN
 502          IF( LOWER ) THEN
 503             DO 10 J = 1, N
 504                CALL SSCAL( N-J+1, SIGMA, A( J, J ), 1 )
 505    10       CONTINUE
 506          ELSE
 507             DO 20 J = 1, N
 508                CALL SSCAL( J, SIGMA, A( 1, J ), 1 )
 509    20       CONTINUE
 510          END IF
 511          IF( ABSTOL.GT.0 )
 512      $      ABSTLL = ABSTOL*SIGMA
 513          IF( VALEIG ) THEN
 514             VLL = VL*SIGMA
 515             VUU = VU*SIGMA
 516          END IF
 517       END IF
 518
 519 *     Initialize indices into workspaces.  Note: The IWORK indices are
 520 *     used only if SSTERF or SSTEMR fail.
 521
 522 *     WORK(INDTAU:INDTAU+N-1) stores the scalar factors of the
 523 *     elementary reflectors used in SSYTRD.
 524       INDTAU = 1
 525 *     WORK(INDD:INDD+N-1) stores the tridiagonal's diagonal entries.
 526       INDD = INDTAU + N
 527 *     WORK(INDE:INDE+N-1) stores the off-diagonal entries of the
 528 *     tridiagonal matrix from SSYTRD.
 529       INDE = INDD + N
 530 *     WORK(INDDD:INDDD+N-1) is a copy of the diagonal entries over
 531 *     -written by SSTEMR (the SSTERF path copies the diagonal to W).
 532       INDDD = INDE + N
 533 *     WORK(INDEE:INDEE+N-1) is a copy of the off-diagonal entries over
 534 *     -written while computing the eigenvalues in SSTERF and SSTEMR.
 535       INDEE = INDDD + N
 536 *     INDWK is the starting offset of the left-over workspace, and
 537 *     LLWORK is the remaining workspace size.
 538       INDWK = INDEE + N
 539       LLWORK = LWORK - INDWK + 1
 540
 541 *     IWORK(INDIBL:INDIBL+M-1) corresponds to IBLOCK in SSTEBZ and
 542 *     stores the block indices of each of the M<=N eigenvalues.
 543       INDIBL = 1
 544 *     IWORK(INDISP:INDISP+NSPLIT-1) corresponds to ISPLIT in SSTEBZ and
 545 *     stores the starting and finishing indices of each block.
 546       INDISP = INDIBL + N
 547 *     IWORK(INDIFL:INDIFL+N-1) stores the indices of eigenvectors
 548 *     that corresponding to eigenvectors that fail to converge in
 549 *     SSTEIN.  This information is discarded; if any fail, the driver
 550 *     returns INFO > 0.
 551       INDIFL = INDISP + N
 552 *     INDIWO is the offset of the remaining integer workspace.
 553       INDIWO = INDIFL + N
 554
 555 *
 556 *     Call SSYTRD to reduce symmetric matrix to tridiagonal form.
 557 *
 558       CALL SSYTRD( UPLO, N, A, LDA, WORK( INDD ), WORK( INDE ),
 559      $             WORK( INDTAU ), WORK( INDWK ), LLWORK, IINFO )
 560 *
 561 *     If all eigenvalues are desired
 562 *     then call SSTERF or SSTEMR and SORMTR.
 563 *
 564       TEST = .FALSE.
 565       IF( INDEIG ) THEN
 566          IF( IL.EQ.1 .AND. IU.EQ.N ) THEN
 567             TEST = .TRUE.
 568          END IF
 569       END IF
 570       IF( ( ALLEIG.OR.TEST ) .AND. ( IEEEOK.EQ.1 ) ) THEN
 571          IF( .NOT.WANTZ ) THEN
 572             CALL SCOPY( N, WORK( INDD ), 1, W, 1 )
 573             CALL SCOPY( N-1, WORK( INDE ), 1, WORK( INDEE ), 1 )
 574             CALL SSTERF( N, W, WORK( INDEE ), INFO )
 575          ELSE
 576             CALL SCOPY( N-1, WORK( INDE ), 1, WORK( INDEE ), 1 )
 577             CALL SCOPY( N, WORK( INDD ), 1, WORK( INDDD ), 1 )
 578 *
 579             IF (ABSTOL .LE. TWO*N*EPS) THEN
 580                TRYRAC = .TRUE.
 581             ELSE
 582                TRYRAC = .FALSE.
 583             END IF
 584             CALL SSTEMR( JOBZ, 'A', N, WORK( INDDD ), WORK( INDEE ),
 585      $                   VL, VU, IL, IU, M, W, Z, LDZ, N, ISUPPZ,
 586      $                   TRYRAC, WORK( INDWK ), LWORK, IWORK, LIWORK,
 587      $                   INFO )
 588 *
 589 *
 590 *
 591 *        Apply orthogonal matrix used in reduction to tridiagonal
 592 *        form to eigenvectors returned by SSTEIN.
 593 *
 594             IF( WANTZ .AND. INFO.EQ.0 ) THEN
 595                INDWKN = INDE
 596                LLWRKN = LWORK - INDWKN + 1
 597                CALL SORMTR( 'L', UPLO, 'N', N, M, A, LDA,
 598      $                      WORK( INDTAU ), Z, LDZ, WORK( INDWKN ),
 599      $                      LLWRKN, IINFO )
 600             END IF
 601          END IF
 602 *
 603 *
 604          IF( INFO.EQ.0 ) THEN
 605 *           Everything worked.  Skip SSTEBZ/SSTEIN.  IWORK(:) are
 606 *           undefined.
 607             M = N
 608             GO TO 30
 609          END IF
 610          INFO = 0
 611       END IF
 612 *
 613 *     Otherwise, call SSTEBZ and, if eigenvectors are desired, SSTEIN.
 614 *     Also call SSTEBZ and SSTEIN if SSTEMR fails.
 615 *
 616       IF( WANTZ ) THEN
 617          ORDER = 'B'
 618       ELSE
 619          ORDER = 'E'
 620       END IF
 621
 622       CALL SSTEBZ( RANGE, ORDER, N, VLL, VUU, IL, IU, ABSTLL,
 623      $             WORK( INDD ), WORK( INDE ), M, NSPLIT, W,
 624      $             IWORK( INDIBL ), IWORK( INDISP ), WORK( INDWK ),
 625      $             IWORK( INDIWO ), INFO )
 626 *
 627       IF( WANTZ ) THEN
 628          CALL SSTEIN( N, WORK( INDD ), WORK( INDE ), M, W,
 629      $                IWORK( INDIBL ), IWORK( INDISP ), Z, LDZ,
 630      $                WORK( INDWK ), IWORK( INDIWO ), IWORK( INDIFL ),
 631      $                INFO )
 632 *
 633 *        Apply orthogonal matrix used in reduction to tridiagonal
 634 *        form to eigenvectors returned by SSTEIN.
 635 *
 636          INDWKN = INDE
 637          LLWRKN = LWORK - INDWKN + 1
 638          CALL SORMTR( 'L', UPLO, 'N', N, M, A, LDA, WORK( INDTAU ), Z,
 639      $                LDZ, WORK( INDWKN ), LLWRKN, IINFO )
 640       END IF
 641 *
 642 *     If matrix was scaled, then rescale eigenvalues appropriately.
 643 *
 644 *  Jump here if SSTEMR/SSTEIN succeeded.
 645    30 CONTINUE
 646       IF( ISCALE.EQ.1 ) THEN
 647          IF( INFO.EQ.0 ) THEN
 648             IMAX = M
 649          ELSE
 650             IMAX = INFO - 1
 651          END IF
 652          CALL SSCAL( IMAX, ONE / SIGMA, W, 1 )
 653       END IF
 654 *
 655 *     If eigenvalues are not in order, then sort them, along with
 656 *     eigenvectors.  Note: We do not sort the IFAIL portion of IWORK.
 657 *     It may not be initialized (if SSTEMR/SSTEIN succeeded), and we do
 658 *     not return this detailed information to the user.
 659 *
 660       IF( WANTZ ) THEN
 661          DO 50 J = 1, M - 1
 662             I = 0
 663             TMP1 = W( J )
 664             DO 40 JJ = J + 1, M
 665                IF( W( JJ ).LT.TMP1 ) THEN
 666                   I = JJ
 667                   TMP1 = W( JJ )
 668                END IF
 669    40       CONTINUE
 670 *
 671             IF( I.NE.0 ) THEN
 672                W( I ) = W( J )
 673                W( J ) = TMP1
 674                CALL SSWAP( N, Z( 1, I ), 1, Z( 1, J ), 1 )
 675             END IF
 676    50    CONTINUE
 677       END IF
 678 *
 679 *     Set WORK(1) to optimal workspace size.
 680 *
 681       WORK( 1 ) = LWKOPT
 682       IWORK( 1 ) = LIWMIN
 683 *
 684       RETURN
 685 *
 686 *     End of SSYEVR
 687 *
 688       END