SRC/sstevr.f

   1 *> \brief <b> SSTEVR computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices</b>
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download SSTEVR + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sstevr.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sstevr.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sstevr.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE SSTEVR( JOBZ, RANGE, N, D, E, VL, VU, IL, IU, ABSTOL,
  22 *                          M, W, Z, LDZ, ISUPPZ, WORK, LWORK, IWORK,
  23 *                          LIWORK, INFO )
  24 *
  25 *       .. Scalar Arguments ..
  26 *       CHARACTER          JOBZ, RANGE
  27 *       INTEGER            IL, INFO, IU, LDZ, LIWORK, LWORK, M, N
  28 *       REAL               ABSTOL, VL, VU
  29 *       ..
  30 *       .. Array Arguments ..
  31 *       INTEGER            ISUPPZ( * ), IWORK( * )
  32 *       REAL               D( * ), E( * ), W( * ), WORK( * ), Z( LDZ, * )
  33 *       ..
  34 *
  35 *
  36 *> \par Purpose:
  37 *  =============
  38 *>
  39 *> \verbatim
  40 *>
  41 *> SSTEVR computes selected eigenvalues and, optionally, eigenvectors
  42 *> of a real symmetric tridiagonal matrix T.  Eigenvalues and
  43 *> eigenvectors can be selected by specifying either a range of values
  44 *> or a range of indices for the desired eigenvalues.
  45 *>
  46 *> Whenever possible, SSTEVR calls SSTEMR to compute the
  47 *> eigenspectrum using Relatively Robust Representations.  SSTEMR
  48 *> computes eigenvalues by the dqds algorithm, while orthogonal
  49 *> eigenvectors are computed from various "good" L D L^T representations
  50 *> (also known as Relatively Robust Representations). Gram-Schmidt
  51 *> orthogonalization is avoided as far as possible. More specifically,
  52 *> the various steps of the algorithm are as follows. For the i-th
  53 *> unreduced block of T,
  54 *>    (a) Compute T - sigma_i = L_i D_i L_i^T, such that L_i D_i L_i^T
  55 *>         is a relatively robust representation,
  56 *>    (b) Compute the eigenvalues, lambda_j, of L_i D_i L_i^T to high
  57 *>        relative accuracy by the dqds algorithm,
  58 *>    (c) If there is a cluster of close eigenvalues, "choose" sigma_i
  59 *>        close to the cluster, and go to step (a),
  60 *>    (d) Given the approximate eigenvalue lambda_j of L_i D_i L_i^T,
  61 *>        compute the corresponding eigenvector by forming a
  62 *>        rank-revealing twisted factorization.
  63 *> The desired accuracy of the output can be specified by the input
  64 *> parameter ABSTOL.
  65 *>
  66 *> For more details, see "A new O(n^2) algorithm for the symmetric
  67 *> tridiagonal eigenvalue/eigenvector problem", by Inderjit Dhillon,
  68 *> Computer Science Division Technical Report No. UCB//CSD-97-971,
  69 *> UC Berkeley, May 1997.
  70 *>
  71 *>
  72 *> Note 1 : SSTEVR calls SSTEMR when the full spectrum is requested
  73 *> on machines which conform to the ieee-754 floating point standard.
  74 *> SSTEVR calls SSTEBZ and SSTEIN on non-ieee machines and
  75 *> when partial spectrum requests are made.
  76 *>
  77 *> Normal execution of SSTEMR may create NaNs and infinities and
  78 *> hence may abort due to a floating point exception in environments
  79 *> which do not handle NaNs and infinities in the ieee standard default
  80 *> manner.
  81 *> \endverbatim
  82 *
  83 *  Arguments:
  84 *  ==========
  85 *
  86 *> \param[in] JOBZ
  87 *> \verbatim
  88 *>          JOBZ is CHARACTER*1
  89 *>          = 'N':  Compute eigenvalues only;
  90 *>          = 'V':  Compute eigenvalues and eigenvectors.
  91 *> \endverbatim
  92 *>
  93 *> \param[in] RANGE
  94 *> \verbatim
  95 *>          RANGE is CHARACTER*1
  96 *>          = 'A': all eigenvalues will be found.
  97 *>          = 'V': all eigenvalues in the half-open interval (VL,VU]
  98 *>                 will be found.
  99 *>          = 'I': the IL-th through IU-th eigenvalues will be found.
 100 *>          For RANGE = 'V' or 'I' and IU - IL < N - 1, SSTEBZ and
 101 *>          SSTEIN are called
 102 *> \endverbatim
 103 *>
 104 *> \param[in] N
 105 *> \verbatim
 106 *>          N is INTEGER
 107 *>          The order of the matrix.  N >= 0.
 108 *> \endverbatim
 109 *>
 110 *> \param[in,out] D
 111 *> \verbatim
 112 *>          D is REAL array, dimension (N)
 113 *>          On entry, the n diagonal elements of the tridiagonal matrix
 114 *>          A.
 115 *>          On exit, D may be multiplied by a constant factor chosen
 116 *>          to avoid over/underflow in computing the eigenvalues.
 117 *> \endverbatim
 118 *>
 119 *> \param[in,out] E
 120 *> \verbatim
 121 *>          E is REAL array, dimension (max(1,N-1))
 122 *>          On entry, the (n-1) subdiagonal elements of the tridiagonal
 123 *>          matrix A in elements 1 to N-1 of E.
 124 *>          On exit, E may be multiplied by a constant factor chosen
 125 *>          to avoid over/underflow in computing the eigenvalues.
 126 *> \endverbatim
 127 *>
 128 *> \param[in] VL
 129 *> \verbatim
 130 *>          VL is REAL
 131 *>          If RANGE='V', the lower bound of the interval to
 132 *>          be searched for eigenvalues. VL < VU.
 133 *>          Not referenced if RANGE = 'A' or 'I'.
 134 *> \endverbatim
 135 *>
 136 *> \param[in] VU
 137 *> \verbatim
 138 *>          VU is REAL
 139 *>          If RANGE='V', the upper bound of the interval to
 140 *>          be searched for eigenvalues. VL < VU.
 141 *>          Not referenced if RANGE = 'A' or 'I'.
 142 *> \endverbatim
 143 *>
 144 *> \param[in] IL
 145 *> \verbatim
 146 *>          IL is INTEGER
 147 *>          If RANGE='I', the index of the
 148 *>          smallest eigenvalue to be returned.
 149 *>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
 150 *>          Not referenced if RANGE = 'A' or 'V'.
 151 *> \endverbatim
 152 *>
 153 *> \param[in] IU
 154 *> \verbatim
 155 *>          IU is INTEGER
 156 *>          If RANGE='I', the index of the
 157 *>          largest eigenvalue to be returned.
 158 *>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
 159 *>          Not referenced if RANGE = 'A' or 'V'.
 160 *> \endverbatim
 161 *>
 162 *> \param[in] ABSTOL
 163 *> \verbatim
 164 *>          ABSTOL is REAL
 165 *>          The absolute error tolerance for the eigenvalues.
 166 *>          An approximate eigenvalue is accepted as converged
 167 *>          when it is determined to lie in an interval [a,b]
 168 *>          of width less than or equal to
 169 *>
 170 *>                  ABSTOL + EPS *   max( |a|,|b| ) ,
 171 *>
 172 *>          where EPS is the machine precision.  If ABSTOL is less than
 173 *>          or equal to zero, then  EPS*|T|  will be used in its place,
 174 *>          where |T| is the 1-norm of the tridiagonal matrix obtained
 175 *>          by reducing A to tridiagonal form.
 176 *>
 177 *>          See "Computing Small Singular Values of Bidiagonal Matrices
 178 *>          with Guaranteed High Relative Accuracy," by Demmel and
 179 *>          Kahan, LAPACK Working Note #3.
 180 *>
 181 *>          If high relative accuracy is important, set ABSTOL to
 182 *>          SLAMCH( 'Safe minimum' ).  Doing so will guarantee that
 183 *>          eigenvalues are computed to high relative accuracy when
 184 *>          possible in future releases.  The current code does not
 185 *>          make any guarantees about high relative accuracy, but
 186 *>          future releases will. See J. Barlow and J. Demmel,
 187 *>          "Computing Accurate Eigensystems of Scaled Diagonally
 188 *>          Dominant Matrices", LAPACK Working Note #7, for a discussion
 189 *>          of which matrices define their eigenvalues to high relative
 190 *>          accuracy.
 191 *> \endverbatim
 192 *>
 193 *> \param[out] M
 194 *> \verbatim
 195 *>          M is INTEGER
 196 *>          The total number of eigenvalues found.  0 <= M <= N.
 197 *>          If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
 198 *> \endverbatim
 199 *>
 200 *> \param[out] W
 201 *> \verbatim
 202 *>          W is REAL array, dimension (N)
 203 *>          The first M elements contain the selected eigenvalues in
 204 *>          ascending order.
 205 *> \endverbatim
 206 *>
 207 *> \param[out] Z
 208 *> \verbatim
 209 *>          Z is REAL array, dimension (LDZ, max(1,M) )
 210 *>          If JOBZ = 'V', then if INFO = 0, the first M columns of Z
 211 *>          contain the orthonormal eigenvectors of the matrix A
 212 *>          corresponding to the selected eigenvalues, with the i-th
 213 *>          column of Z holding the eigenvector associated with W(i).
 214 *>          Note: the user must ensure that at least max(1,M) columns are
 215 *>          supplied in the array Z; if RANGE = 'V', the exact value of M
 216 *>          is not known in advance and an upper bound must be used.
 217 *> \endverbatim
 218 *>
 219 *> \param[in] LDZ
 220 *> \verbatim
 221 *>          LDZ is INTEGER
 222 *>          The leading dimension of the array Z.  LDZ >= 1, and if
 223 *>          JOBZ = 'V', LDZ >= max(1,N).
 224 *> \endverbatim
 225 *>
 226 *> \param[out] ISUPPZ
 227 *> \verbatim
 228 *>          ISUPPZ is INTEGER array, dimension ( 2*max(1,M) )
 229 *>          The support of the eigenvectors in Z, i.e., the indices
 230 *>          indicating the nonzero elements in Z. The i-th eigenvector
 231 *>          is nonzero only in elements ISUPPZ( 2*i-1 ) through
 232 *>          ISUPPZ( 2*i ).
 233 *>          Implemented only for RANGE = 'A' or 'I' and IU - IL = N - 1
 234 *> \endverbatim
 235 *>
 236 *> \param[out] WORK
 237 *> \verbatim
 238 *>          WORK is REAL array, dimension (MAX(1,LWORK))
 239 *>          On exit, if INFO = 0, WORK(1) returns the optimal (and
 240 *>          minimal) LWORK.
 241 *> \endverbatim
 242 *>
 243 *> \param[in] LWORK
 244 *> \verbatim
 245 *>          LWORK is INTEGER
 246 *>          The dimension of the array WORK.  LWORK >= 20*N.
 247 *>
 248 *>          If LWORK = -1, then a workspace query is assumed; the routine
 249 *>          only calculates the optimal sizes of the WORK and IWORK
 250 *>          arrays, returns these values as the first entries of the WORK
 251 *>          and IWORK arrays, and no error message related to LWORK or
 252 *>          LIWORK is issued by XERBLA.
 253 *> \endverbatim
 254 *>
 255 *> \param[out] IWORK
 256 *> \verbatim
 257 *>          IWORK is INTEGER array, dimension (MAX(1,LIWORK))
 258 *>          On exit, if INFO = 0, IWORK(1) returns the optimal (and
 259 *>          minimal) LIWORK.
 260 *> \endverbatim
 261 *>
 262 *> \param[in] LIWORK
 263 *> \verbatim
 264 *>          LIWORK is INTEGER
 265 *>          The dimension of the array IWORK.  LIWORK >= 10*N.
 266 *>
 267 *>          If LIWORK = -1, then a workspace query is assumed; the
 268 *>          routine only calculates the optimal sizes of the WORK and
 269 *>          IWORK arrays, returns these values as the first entries of
 270 *>          the WORK and IWORK arrays, and no error message related to
 271 *>          LWORK or LIWORK is issued by XERBLA.
 272 *> \endverbatim
 273 *>
 274 *> \param[out] INFO
 275 *> \verbatim
 276 *>          INFO is INTEGER
 277 *>          = 0:  successful exit
 278 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 279 *>          > 0:  Internal error
 280 *> \endverbatim
 281 *
 282 *  Authors:
 283 *  ========
 284 *
 285 *> \author Univ. of Tennessee
 286 *> \author Univ. of California Berkeley
 287 *> \author Univ. of Colorado Denver
 288 *> \author NAG Ltd.
 289 *
 290 *> \date June 2016
 291 *
 292 *> \ingroup realOTHEReigen
 293 *
 294 *> \par Contributors:
 295 *  ==================
 296 *>
 297 *>     Inderjit Dhillon, IBM Almaden, USA \n
 298 *>     Osni Marques, LBNL/NERSC, USA \n
 299 *>     Ken Stanley, Computer Science Division, University of
 300 *>       California at Berkeley, USA \n
 301 *>     Jason Riedy, Computer Science Division, University of
 302 *>       California at Berkeley, USA \n
 303 *>
 304 *  =====================================================================
 305       SUBROUTINE SSTEVR( JOBZ, RANGE, N, D, E, VL, VU, IL, IU, ABSTOL,
 306      $                   M, W, Z, LDZ, ISUPPZ, WORK, LWORK, IWORK,
 307      $                   LIWORK, INFO )
 308 *
 309 *  -- LAPACK driver routine (version 3.6.1) --
 310 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 311 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 312 *     June 2016
 313 *
 314 *     .. Scalar Arguments ..
 315       CHARACTER          JOBZ, RANGE
 316       INTEGER            IL, INFO, IU, LDZ, LIWORK, LWORK, M, N
 317       REAL               ABSTOL, VL, VU
 318 *     ..
 319 *     .. Array Arguments ..
 320       INTEGER            ISUPPZ( * ), IWORK( * )
 321       REAL               D( * ), E( * ), W( * ), WORK( * ), Z( LDZ, * )
 322 *     ..
 323 *
 324 *  =====================================================================
 325 *
 326 *     .. Parameters ..
 327       REAL               ZERO, ONE, TWO
 328       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0, TWO = 2.0E+0 )
 329 *     ..
 330 *     .. Local Scalars ..
 331       LOGICAL            ALLEIG, INDEIG, TEST, LQUERY, VALEIG, WANTZ,
 332      $                   TRYRAC
 333       CHARACTER          ORDER
 334       INTEGER            I, IEEEOK, IMAX, INDIBL, INDIFL, INDISP,
 335      $                   INDIWO, ISCALE, J, JJ, LIWMIN, LWMIN, NSPLIT
 336       REAL               BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA, SMLNUM,
 337      $                   TMP1, TNRM, VLL, VUU
 338 *     ..
 339 *     .. External Functions ..
 340       LOGICAL            LSAME
 341       INTEGER            ILAENV
 342       REAL               SLAMCH, SLANST
 343       EXTERNAL           LSAME, ILAENV, SLAMCH, SLANST
 344 *     ..
 345 *     .. External Subroutines ..
 346       EXTERNAL           SCOPY, SSCAL, SSTEBZ, SSTEMR, SSTEIN, SSTERF,
 347      $                   SSWAP, XERBLA
 348 *     ..
 349 *     .. Intrinsic Functions ..
 350       INTRINSIC          MAX, MIN, SQRT
 351 *     ..
 352 *     .. Executable Statements ..
 353 *
 354 *
 355 *     Test the input parameters.
 356 *
 357       IEEEOK = ILAENV( 10, 'SSTEVR', 'N', 1, 2, 3, 4 )
 358 *
 359       WANTZ = LSAME( JOBZ, 'V' )
 360       ALLEIG = LSAME( RANGE, 'A' )
 361       VALEIG = LSAME( RANGE, 'V' )
 362       INDEIG = LSAME( RANGE, 'I' )
 363 *
 364       LQUERY = ( ( LWORK.EQ.-1 ) .OR. ( LIWORK.EQ.-1 ) )
 365       LWMIN = MAX( 1, 20*N )
 366       LIWMIN = MAX(1, 10*N )
 367 *
 368 *
 369       INFO = 0
 370       IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
 371          INFO = -1
 372       ELSE IF( .NOT.( ALLEIG .OR. VALEIG .OR. INDEIG ) ) THEN
 373          INFO = -2
 374       ELSE IF( N.LT.0 ) THEN
 375          INFO = -3
 376       ELSE
 377          IF( VALEIG ) THEN
 378             IF( N.GT.0 .AND. VU.LE.VL )
 379      $         INFO = -7
 380          ELSE IF( INDEIG ) THEN
 381             IF( IL.LT.1 .OR. IL.GT.MAX( 1, N ) ) THEN
 382                INFO = -8
 383             ELSE IF( IU.LT.MIN( N, IL ) .OR. IU.GT.N ) THEN
 384                INFO = -9
 385             END IF
 386          END IF
 387       END IF
 388       IF( INFO.EQ.0 ) THEN
 389          IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
 390             INFO = -14
 391          END IF
 392       END IF
 393 *
 394       IF( INFO.EQ.0 ) THEN
 395          WORK( 1 ) = LWMIN
 396          IWORK( 1 ) = LIWMIN
 397 *
 398          IF( LWORK.LT.LWMIN .AND. .NOT.LQUERY ) THEN
 399             INFO = -17
 400          ELSE IF( LIWORK.LT.LIWMIN .AND. .NOT.LQUERY ) THEN
 401             INFO = -19
 402          END IF
 403       END IF
 404 *
 405       IF( INFO.NE.0 ) THEN
 406          CALL XERBLA( 'SSTEVR', -INFO )
 407          RETURN
 408       ELSE IF( LQUERY ) THEN
 409          RETURN
 410       END IF
 411 *
 412 *     Quick return if possible
 413 *
 414       M = 0
 415       IF( N.EQ.0 )
 416      $   RETURN
 417 *
 418       IF( N.EQ.1 ) THEN
 419          IF( ALLEIG .OR. INDEIG ) THEN
 420             M = 1
 421             W( 1 ) = D( 1 )
 422          ELSE
 423             IF( VL.LT.D( 1 ) .AND. VU.GE.D( 1 ) ) THEN
 424                M = 1
 425                W( 1 ) = D( 1 )
 426             END IF
 427          END IF
 428          IF( WANTZ )
 429      $      Z( 1, 1 ) = ONE
 430          RETURN
 431       END IF
 432 *
 433 *     Get machine constants.
 434 *
 435       SAFMIN = SLAMCH( 'Safe minimum' )
 436       EPS = SLAMCH( 'Precision' )
 437       SMLNUM = SAFMIN / EPS
 438       BIGNUM = ONE / SMLNUM
 439       RMIN = SQRT( SMLNUM )
 440       RMAX = MIN( SQRT( BIGNUM ), ONE / SQRT( SQRT( SAFMIN ) ) )
 441 *
 442 *
 443 *     Scale matrix to allowable range, if necessary.
 444 *
 445       ISCALE = 0
 446       IF( VALEIG ) THEN
 447          VLL = VL
 448          VUU = VU
 449       END IF
 450 *
 451       TNRM = SLANST( 'M', N, D, E )
 452       IF( TNRM.GT.ZERO .AND. TNRM.LT.RMIN ) THEN
 453          ISCALE = 1
 454          SIGMA = RMIN / TNRM
 455       ELSE IF( TNRM.GT.RMAX ) THEN
 456          ISCALE = 1
 457          SIGMA = RMAX / TNRM
 458       END IF
 459       IF( ISCALE.EQ.1 ) THEN
 460          CALL SSCAL( N, SIGMA, D, 1 )
 461          CALL SSCAL( N-1, SIGMA, E( 1 ), 1 )
 462          IF( VALEIG ) THEN
 463             VLL = VL*SIGMA
 464             VUU = VU*SIGMA
 465          END IF
 466       END IF
 467
 468 *     Initialize indices into workspaces.  Note: These indices are used only
 469 *     if SSTERF or SSTEMR fail.
 470
 471 *     IWORK(INDIBL:INDIBL+M-1) corresponds to IBLOCK in SSTEBZ and
 472 *     stores the block indices of each of the M<=N eigenvalues.
 473       INDIBL = 1
 474 *     IWORK(INDISP:INDISP+NSPLIT-1) corresponds to ISPLIT in SSTEBZ and
 475 *     stores the starting and finishing indices of each block.
 476       INDISP = INDIBL + N
 477 *     IWORK(INDIFL:INDIFL+N-1) stores the indices of eigenvectors
 478 *     that corresponding to eigenvectors that fail to converge in
 479 *     SSTEIN.  This information is discarded; if any fail, the driver
 480 *     returns INFO > 0.
 481       INDIFL = INDISP + N
 482 *     INDIWO is the offset of the remaining integer workspace.
 483       INDIWO = INDISP + N
 484 *
 485 *     If all eigenvalues are desired, then
 486 *     call SSTERF or SSTEMR.  If this fails for some eigenvalue, then
 487 *     try SSTEBZ.
 488 *
 489 *
 490       TEST = .FALSE.
 491       IF( INDEIG ) THEN
 492          IF( IL.EQ.1 .AND. IU.EQ.N ) THEN
 493             TEST = .TRUE.
 494          END IF
 495       END IF
 496       IF( ( ALLEIG .OR. TEST ) .AND. IEEEOK.EQ.1 ) THEN
 497          CALL SCOPY( N-1, E( 1 ), 1, WORK( 1 ), 1 )
 498          IF( .NOT.WANTZ ) THEN
 499             CALL SCOPY( N, D, 1, W, 1 )
 500             CALL SSTERF( N, W, WORK, INFO )
 501          ELSE
 502             CALL SCOPY( N, D, 1, WORK( N+1 ), 1 )
 503             IF (ABSTOL .LE. TWO*N*EPS) THEN
 504                TRYRAC = .TRUE.
 505             ELSE
 506                TRYRAC = .FALSE.
 507             END IF
 508             CALL SSTEMR( JOBZ, 'A', N, WORK( N+1 ), WORK, VL, VU, IL,
 509      $                   IU, M, W, Z, LDZ, N, ISUPPZ, TRYRAC,
 510      $                   WORK( 2*N+1 ), LWORK-2*N, IWORK, LIWORK, INFO )
 511 *
 512          END IF
 513          IF( INFO.EQ.0 ) THEN
 514             M = N
 515             GO TO 10
 516          END IF
 517          INFO = 0
 518       END IF
 519 *
 520 *     Otherwise, call SSTEBZ and, if eigenvectors are desired, SSTEIN.
 521 *
 522       IF( WANTZ ) THEN
 523          ORDER = 'B'
 524       ELSE
 525          ORDER = 'E'
 526       END IF
 527
 528       CALL SSTEBZ( RANGE, ORDER, N, VLL, VUU, IL, IU, ABSTOL, D, E, M,
 529      $             NSPLIT, W, IWORK( INDIBL ), IWORK( INDISP ), WORK,
 530      $             IWORK( INDIWO ), INFO )
 531 *
 532       IF( WANTZ ) THEN
 533          CALL SSTEIN( N, D, E, M, W, IWORK( INDIBL ), IWORK( INDISP ),
 534      $                Z, LDZ, WORK, IWORK( INDIWO ), IWORK( INDIFL ),
 535      $                INFO )
 536       END IF
 537 *
 538 *     If matrix was scaled, then rescale eigenvalues appropriately.
 539 *
 540    10 CONTINUE
 541       IF( ISCALE.EQ.1 ) THEN
 542          IF( INFO.EQ.0 ) THEN
 543             IMAX = M
 544          ELSE
 545             IMAX = INFO - 1
 546          END IF
 547          CALL SSCAL( IMAX, ONE / SIGMA, W, 1 )
 548       END IF
 549 *
 550 *     If eigenvalues are not in order, then sort them, along with
 551 *     eigenvectors.
 552 *
 553       IF( WANTZ ) THEN
 554          DO 30 J = 1, M - 1
 555             I = 0
 556             TMP1 = W( J )
 557             DO 20 JJ = J + 1, M
 558                IF( W( JJ ).LT.TMP1 ) THEN
 559                   I = JJ
 560                   TMP1 = W( JJ )
 561                END IF
 562    20       CONTINUE
 563 *
 564             IF( I.NE.0 ) THEN
 565                W( I ) = W( J )
 566                W( J ) = TMP1
 567                CALL SSWAP( N, Z( 1, I ), 1, Z( 1, J ), 1 )
 568             END IF
 569    30    CONTINUE
 570       END IF
 571 *
 572 *      Causes problems with tests 19 & 20:
 573 *      IF (wantz .and. INDEIG ) Z( 1,1) = Z(1,1) / 1.002 + .002
 574 *
 575 *
 576       WORK( 1 ) = LWMIN
 577       IWORK( 1 ) = LIWMIN
 578       RETURN
 579 *
 580 *     End of SSTEVR
 581 *
 582       END