SRC/sormrz.f

   1 *> \brief \b SORMRZ
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download SORMRZ + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sormrz.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sormrz.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sormrz.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       SUBROUTINE SORMRZ( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
  22 *                          WORK, LWORK, INFO )
  23 *
  24 *       .. Scalar Arguments ..
  25 *       CHARACTER          SIDE, TRANS
  26 *       INTEGER            INFO, K, L, LDA, LDC, LWORK, M, N
  27 *       ..
  28 *       .. Array Arguments ..
  29 *       REAL               A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
  30 *       ..
  31 *
  32 *
  33 *> \par Purpose:
  34 *  =============
  35 *>
  36 *> \verbatim
  37 *>
  38 *> SORMRZ overwrites the general real M-by-N matrix C with
  39 *>
  40 *>                 SIDE = 'L'     SIDE = 'R'
  41 *> TRANS = 'N':      Q * C          C * Q
  42 *> TRANS = 'T':      Q**T * C       C * Q**T
  43 *>
  44 *> where Q is a real orthogonal matrix defined as the product of k
  45 *> elementary reflectors
  46 *>
  47 *>       Q = H(1) H(2) . . . H(k)
  48 *>
  49 *> as returned by STZRZF. Q is of order M if SIDE = 'L' and of order N
  50 *> if SIDE = 'R'.
  51 *> \endverbatim
  52 *
  53 *  Arguments:
  54 *  ==========
  55 *
  56 *> \param[in] SIDE
  57 *> \verbatim
  58 *>          SIDE is CHARACTER*1
  59 *>          = 'L': apply Q or Q**T from the Left;
  60 *>          = 'R': apply Q or Q**T from the Right.
  61 *> \endverbatim
  62 *>
  63 *> \param[in] TRANS
  64 *> \verbatim
  65 *>          TRANS is CHARACTER*1
  66 *>          = 'N':  No transpose, apply Q;
  67 *>          = 'T':  Transpose, apply Q**T.
  68 *> \endverbatim
  69 *>
  70 *> \param[in] M
  71 *> \verbatim
  72 *>          M is INTEGER
  73 *>          The number of rows of the matrix C. M >= 0.
  74 *> \endverbatim
  75 *>
  76 *> \param[in] N
  77 *> \verbatim
  78 *>          N is INTEGER
  79 *>          The number of columns of the matrix C. N >= 0.
  80 *> \endverbatim
  81 *>
  82 *> \param[in] K
  83 *> \verbatim
  84 *>          K is INTEGER
  85 *>          The number of elementary reflectors whose product defines
  86 *>          the matrix Q.
  87 *>          If SIDE = 'L', M >= K >= 0;
  88 *>          if SIDE = 'R', N >= K >= 0.
  89 *> \endverbatim
  90 *>
  91 *> \param[in] L
  92 *> \verbatim
  93 *>          L is INTEGER
  94 *>          The number of columns of the matrix A containing
  95 *>          the meaningful part of the Householder reflectors.
  96 *>          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
  97 *> \endverbatim
  98 *>
  99 *> \param[in] A
 100 *> \verbatim
 101 *>          A is REAL array, dimension
 102 *>                               (LDA,M) if SIDE = 'L',
 103 *>                               (LDA,N) if SIDE = 'R'
 104 *>          The i-th row must contain the vector which defines the
 105 *>          elementary reflector H(i), for i = 1,2,...,k, as returned by
 106 *>          STZRZF in the last k rows of its array argument A.
 107 *>          A is modified by the routine but restored on exit.
 108 *> \endverbatim
 109 *>
 110 *> \param[in] LDA
 111 *> \verbatim
 112 *>          LDA is INTEGER
 113 *>          The leading dimension of the array A. LDA >= max(1,K).
 114 *> \endverbatim
 115 *>
 116 *> \param[in] TAU
 117 *> \verbatim
 118 *>          TAU is REAL array, dimension (K)
 119 *>          TAU(i) must contain the scalar factor of the elementary
 120 *>          reflector H(i), as returned by STZRZF.
 121 *> \endverbatim
 122 *>
 123 *> \param[in,out] C
 124 *> \verbatim
 125 *>          C is REAL array, dimension (LDC,N)
 126 *>          On entry, the M-by-N matrix C.
 127 *>          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
 128 *> \endverbatim
 129 *>
 130 *> \param[in] LDC
 131 *> \verbatim
 132 *>          LDC is INTEGER
 133 *>          The leading dimension of the array C. LDC >= max(1,M).
 134 *> \endverbatim
 135 *>
 136 *> \param[out] WORK
 137 *> \verbatim
 138 *>          WORK is REAL array, dimension (MAX(1,LWORK))
 139 *>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
 140 *> \endverbatim
 141 *>
 142 *> \param[in] LWORK
 143 *> \verbatim
 144 *>          LWORK is INTEGER
 145 *>          The dimension of the array WORK.
 146 *>          If SIDE = 'L', LWORK >= max(1,N);
 147 *>          if SIDE = 'R', LWORK >= max(1,M).
 148 *>          For good performance, LWORK should generally be larger.
 149 *>
 150 *>          If LWORK = -1, then a workspace query is assumed; the routine
 151 *>          only calculates the optimal size of the WORK array, returns
 152 *>          this value as the first entry of the WORK array, and no error
 153 *>          message related to LWORK is issued by XERBLA.
 154 *> \endverbatim
 155 *>
 156 *> \param[out] INFO
 157 *> \verbatim
 158 *>          INFO is INTEGER
 159 *>          = 0:  successful exit
 160 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
 161 *> \endverbatim
 162 *
 163 *  Authors:
 164 *  ========
 165 *
 166 *> \author Univ. of Tennessee
 167 *> \author Univ. of California Berkeley
 168 *> \author Univ. of Colorado Denver
 169 *> \author NAG Ltd.
 170 *
 171 *> \date November 2015
 172 *
 173 *> \ingroup realOTHERcomputational
 174 *
 175 *> \par Contributors:
 176 *  ==================
 177 *>
 178 *>    A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
 179 *
 180 *> \par Further Details:
 181 *  =====================
 182 *>
 183 *> \verbatim
 184 *> \endverbatim
 185 *>
 186 *  =====================================================================
 187       SUBROUTINE SORMRZ( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
 188      $                   WORK, LWORK, INFO )
 189 *
 190 *  -- LAPACK computational routine (version 3.6.0) --
 191 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 192 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 193 *     November 2015
 194 *
 195 *     .. Scalar Arguments ..
 196       CHARACTER          SIDE, TRANS
 197       INTEGER            INFO, K, L, LDA, LDC, LWORK, M, N
 198 *     ..
 199 *     .. Array Arguments ..
 200       REAL               A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
 201 *     ..
 202 *
 203 *  =====================================================================
 204 *
 205 *     .. Parameters ..
 206       INTEGER            NBMAX, LDT, TSIZE
 207       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1,
 208      $                     TSIZE = LDT*NBMAX )
 209 *     ..
 210 *     .. Local Scalars ..
 211       LOGICAL            LEFT, LQUERY, NOTRAN
 212       CHARACTER          TRANST
 213       INTEGER            I, I1, I2, I3, IB, IC, IINFO, IWT, JA, JC,
 214      $                   LDWORK, LWKOPT, MI, NB, NBMIN, NI, NQ, NW
 215 *     ..
 216 *     .. External Functions ..
 217       LOGICAL            LSAME
 218       INTEGER            ILAENV
 219       EXTERNAL           LSAME, ILAENV
 220 *     ..
 221 *     .. External Subroutines ..
 222       EXTERNAL           SLARZB, SLARZT, SORMR3, XERBLA
 223 *     ..
 224 *     .. Intrinsic Functions ..
 225       INTRINSIC          MAX, MIN
 226 *     ..
 227 *     .. Executable Statements ..
 228 *
 229 *     Test the input arguments
 230 *
 231       INFO = 0
 232       LEFT = LSAME( SIDE, 'L' )
 233       NOTRAN = LSAME( TRANS, 'N' )
 234       LQUERY = ( LWORK.EQ.-1 )
 235 *
 236 *     NQ is the order of Q and NW is the minimum dimension of WORK
 237 *
 238       IF( LEFT ) THEN
 239          NQ = M
 240          NW = MAX( 1, N )
 241       ELSE
 242          NQ = N
 243          NW = MAX( 1, M )
 244       END IF
 245       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
 246          INFO = -1
 247       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
 248          INFO = -2
 249       ELSE IF( M.LT.0 ) THEN
 250          INFO = -3
 251       ELSE IF( N.LT.0 ) THEN
 252          INFO = -4
 253       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
 254          INFO = -5
 255       ELSE IF( L.LT.0 .OR. ( LEFT .AND. ( L.GT.M ) ) .OR.
 256      $         ( .NOT.LEFT .AND. ( L.GT.N ) ) ) THEN
 257          INFO = -6
 258       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
 259          INFO = -8
 260       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
 261          INFO = -11
 262       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
 263          INFO = -13
 264       END IF
 265 *
 266       IF( INFO.EQ.0 ) THEN
 267 *
 268 *        Compute the workspace requirements
 269 *
 270          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
 271             LWKOPT = 1
 272          ELSE
 273             NB = MIN( NBMAX, ILAENV( 1, 'SORMRQ', SIDE // TRANS, M, N,
 274      $                               K, -1 ) )
 275             LWKOPT = NW*NB + TSIZE
 276          END IF
 277          WORK( 1 ) = LWKOPT
 278       END IF
 279 *
 280       IF( INFO.NE.0 ) THEN
 281          CALL XERBLA( 'SORMRZ', -INFO )
 282          RETURN
 283       ELSE IF( LQUERY ) THEN
 284          RETURN
 285       END IF
 286 *
 287 *     Quick return if possible
 288 *
 289       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
 290          RETURN
 291       END IF
 292 *
 293       NBMIN = 2
 294       LDWORK = NW
 295       IF( NB.GT.1 .AND. NB.LT.K ) THEN
 296          IF( LWORK.LT.NW*NB+TSIZE ) THEN
 297             NB = (LWORK-TSIZE) / LDWORK
 298             NBMIN = MAX( 2, ILAENV( 2, 'SORMRQ', SIDE // TRANS, M, N, K,
 299      $              -1 ) )
 300          END IF
 301       END IF
 302 *
 303       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
 304 *
 305 *        Use unblocked code
 306 *
 307          CALL SORMR3( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
 308      $                WORK, IINFO )
 309       ELSE
 310 *
 311 *        Use blocked code
 312 *
 313          IWT = 1 + NW*NB
 314          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
 315      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
 316             I1 = 1
 317             I2 = K
 318             I3 = NB
 319          ELSE
 320             I1 = ( ( K-1 ) / NB )*NB + 1
 321             I2 = 1
 322             I3 = -NB
 323          END IF
 324 *
 325          IF( LEFT ) THEN
 326             NI = N
 327             JC = 1
 328             JA = M - L + 1
 329          ELSE
 330             MI = M
 331             IC = 1
 332             JA = N - L + 1
 333          END IF
 334 *
 335          IF( NOTRAN ) THEN
 336             TRANST = 'T'
 337          ELSE
 338             TRANST = 'N'
 339          END IF
 340 *
 341          DO 10 I = I1, I2, I3
 342             IB = MIN( NB, K-I+1 )
 343 *
 344 *           Form the triangular factor of the block reflector
 345 *           H = H(i+ib-1) . . . H(i+1) H(i)
 346 *
 347             CALL SLARZT( 'Backward', 'Rowwise', L, IB, A( I, JA ), LDA,
 348      $                   TAU( I ), WORK( IWT ), LDT )
 349 *
 350             IF( LEFT ) THEN
 351 *
 352 *              H or H**T is applied to C(i:m,1:n)
 353 *
 354                MI = M - I + 1
 355                IC = I
 356             ELSE
 357 *
 358 *              H or H**T is applied to C(1:m,i:n)
 359 *
 360                NI = N - I + 1
 361                JC = I
 362             END IF
 363 *
 364 *           Apply H or H**T
 365 *
 366             CALL SLARZB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
 367      $                   IB, L, A( I, JA ), LDA, WORK( IWT ), LDT,
 368      $                   C( IC, JC ), LDC, WORK, LDWORK )
 369    10    CONTINUE
 370 *
 371       END IF
 372 *
 373       WORK( 1 ) = LWKOPT
 374 *
 375       RETURN
 376 *
 377 *     End of SORMRZ
 378 *
 379       END