SRC/slansb.f

   1 *> \brief \b SLANSB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric band matrix.
   2 *
   3 *  =========== DOCUMENTATION ===========
   4 *
   5 * Online html documentation available at
   6 *            http://www.netlib.org/lapack/explore-html/
   7 *
   8 *> \htmlonly
   9 *> Download SLANSB + dependencies
  10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slansb.f">
  11 *> [TGZ]</a>
  12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slansb.f">
  13 *> [ZIP]</a>
  14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slansb.f">
  15 *> [TXT]</a>
  16 *> \endhtmlonly
  17 *
  18 *  Definition:
  19 *  ===========
  20 *
  21 *       REAL             FUNCTION SLANSB( NORM, UPLO, N, K, AB, LDAB,
  22 *                        WORK )
  23 *
  24 *       .. Scalar Arguments ..
  25 *       CHARACTER          NORM, UPLO
  26 *       INTEGER            K, LDAB, N
  27 *       ..
  28 *       .. Array Arguments ..
  29 *       REAL               AB( LDAB, * ), WORK( * )
  30 *       ..
  31 *
  32 *
  33 *> \par Purpose:
  34 *  =============
  35 *>
  36 *> \verbatim
  37 *>
  38 *> SLANSB  returns the value of the one norm,  or the Frobenius norm, or
  39 *> the  infinity norm,  or the element of  largest absolute value  of an
  40 *> n by n symmetric band matrix A,  with k super-diagonals.
  41 *> \endverbatim
  42 *>
  43 *> \return SLANSB
  44 *> \verbatim
  45 *>
  46 *>    SLANSB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
  47 *>             (
  48 *>             ( norm1(A),         NORM = '1', 'O' or 'o'
  49 *>             (
  50 *>             ( normI(A),         NORM = 'I' or 'i'
  51 *>             (
  52 *>             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
  53 *>
  54 *> where  norm1  denotes the  one norm of a matrix (maximum column sum),
  55 *> normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
  56 *> normF  denotes the  Frobenius norm of a matrix (square root of sum of
  57 *> squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
  58 *> \endverbatim
  59 *
  60 *  Arguments:
  61 *  ==========
  62 *
  63 *> \param[in] NORM
  64 *> \verbatim
  65 *>          NORM is CHARACTER*1
  66 *>          Specifies the value to be returned in SLANSB as described
  67 *>          above.
  68 *> \endverbatim
  69 *>
  70 *> \param[in] UPLO
  71 *> \verbatim
  72 *>          UPLO is CHARACTER*1
  73 *>          Specifies whether the upper or lower triangular part of the
  74 *>          band matrix A is supplied.
  75 *>          = 'U':  Upper triangular part is supplied
  76 *>          = 'L':  Lower triangular part is supplied
  77 *> \endverbatim
  78 *>
  79 *> \param[in] N
  80 *> \verbatim
  81 *>          N is INTEGER
  82 *>          The order of the matrix A.  N >= 0.  When N = 0, SLANSB is
  83 *>          set to zero.
  84 *> \endverbatim
  85 *>
  86 *> \param[in] K
  87 *> \verbatim
  88 *>          K is INTEGER
  89 *>          The number of super-diagonals or sub-diagonals of the
  90 *>          band matrix A.  K >= 0.
  91 *> \endverbatim
  92 *>
  93 *> \param[in] AB
  94 *> \verbatim
  95 *>          AB is REAL array, dimension (LDAB,N)
  96 *>          The upper or lower triangle of the symmetric band matrix A,
  97 *>          stored in the first K+1 rows of AB.  The j-th column of A is
  98 *>          stored in the j-th column of the array AB as follows:
  99 *>          if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
 100 *>          if UPLO = 'L', AB(1+i-j,j)   = A(i,j) for j<=i<=min(n,j+k).
 101 *> \endverbatim
 102 *>
 103 *> \param[in] LDAB
 104 *> \verbatim
 105 *>          LDAB is INTEGER
 106 *>          The leading dimension of the array AB.  LDAB >= K+1.
 107 *> \endverbatim
 108 *>
 109 *> \param[out] WORK
 110 *> \verbatim
 111 *>          WORK is REAL array, dimension (MAX(1,LWORK)),
 112 *>          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
 113 *>          WORK is not referenced.
 114 *> \endverbatim
 115 *
 116 *  Authors:
 117 *  ========
 118 *
 119 *> \author Univ. of Tennessee
 120 *> \author Univ. of California Berkeley
 121 *> \author Univ. of Colorado Denver
 122 *> \author NAG Ltd.
 123 *
 124 *> \date September 2012
 125 *
 126 *> \ingroup realOTHERauxiliary
 127 *
 128 *  =====================================================================
 129       REAL             FUNCTION SLANSB( NORM, UPLO, N, K, AB, LDAB,
 130      $                 WORK )
 131 *
 132 *  -- LAPACK auxiliary routine (version 3.4.2) --
 133 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 134 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 135 *     September 2012
 136 *
 137 *     .. Scalar Arguments ..
 138       CHARACTER          NORM, UPLO
 139       INTEGER            K, LDAB, N
 140 *     ..
 141 *     .. Array Arguments ..
 142       REAL               AB( LDAB, * ), WORK( * )
 143 *     ..
 144 *
 145 * =====================================================================
 146 *
 147 *     .. Parameters ..
 148       REAL               ONE, ZERO
 149       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
 150 *     ..
 151 *     .. Local Scalars ..
 152       INTEGER            I, J, L
 153       REAL               ABSA, SCALE, SUM, VALUE
 154 *     ..
 155 *     .. External Subroutines ..
 156       EXTERNAL           SLASSQ
 157 *     ..
 158 *     .. External Functions ..
 159       LOGICAL            LSAME, SISNAN
 160       EXTERNAL           LSAME, SISNAN
 161 *     ..
 162 *     .. Intrinsic Functions ..
 163       INTRINSIC          ABS, MAX, MIN, SQRT
 164 *     ..
 165 *     .. Executable Statements ..
 166 *
 167       IF( N.EQ.0 ) THEN
 168          VALUE = ZERO
 169       ELSE IF( LSAME( NORM, 'M' ) ) THEN
 170 *
 171 *        Find max(abs(A(i,j))).
 172 *
 173          VALUE = ZERO
 174          IF( LSAME( UPLO, 'U' ) ) THEN
 175             DO 20 J = 1, N
 176                DO 10 I = MAX( K+2-J, 1 ), K + 1
 177                   SUM = ABS( AB( I, J ) )
 178                   IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
 179    10          CONTINUE
 180    20       CONTINUE
 181          ELSE
 182             DO 40 J = 1, N
 183                DO 30 I = 1, MIN( N+1-J, K+1 )
 184                   SUM = ABS( AB( I, J ) )
 185                   IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
 186    30          CONTINUE
 187    40       CONTINUE
 188          END IF
 189       ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
 190      $         ( NORM.EQ.'1' ) ) THEN
 191 *
 192 *        Find normI(A) ( = norm1(A), since A is symmetric).
 193 *
 194          VALUE = ZERO
 195          IF( LSAME( UPLO, 'U' ) ) THEN
 196             DO 60 J = 1, N
 197                SUM = ZERO
 198                L = K + 1 - J
 199                DO 50 I = MAX( 1, J-K ), J - 1
 200                   ABSA = ABS( AB( L+I, J ) )
 201                   SUM = SUM + ABSA
 202                   WORK( I ) = WORK( I ) + ABSA
 203    50          CONTINUE
 204                WORK( J ) = SUM + ABS( AB( K+1, J ) )
 205    60       CONTINUE
 206             DO 70 I = 1, N
 207                SUM = WORK( I )
 208                IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
 209    70       CONTINUE
 210          ELSE
 211             DO 80 I = 1, N
 212                WORK( I ) = ZERO
 213    80       CONTINUE
 214             DO 100 J = 1, N
 215                SUM = WORK( J ) + ABS( AB( 1, J ) )
 216                L = 1 - J
 217                DO 90 I = J + 1, MIN( N, J+K )
 218                   ABSA = ABS( AB( L+I, J ) )
 219                   SUM = SUM + ABSA
 220                   WORK( I ) = WORK( I ) + ABSA
 221    90          CONTINUE
 222                IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
 223   100       CONTINUE
 224          END IF
 225       ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
 226 *
 227 *        Find normF(A).
 228 *
 229          SCALE = ZERO
 230          SUM = ONE
 231          IF( K.GT.0 ) THEN
 232             IF( LSAME( UPLO, 'U' ) ) THEN
 233                DO 110 J = 2, N
 234                   CALL SLASSQ( MIN( J-1, K ), AB( MAX( K+2-J, 1 ), J ),
 235      $                         1, SCALE, SUM )
 236   110          CONTINUE
 237                L = K + 1
 238             ELSE
 239                DO 120 J = 1, N - 1
 240                   CALL SLASSQ( MIN( N-J, K ), AB( 2, J ), 1, SCALE,
 241      $                         SUM )
 242   120          CONTINUE
 243                L = 1
 244             END IF
 245             SUM = 2*SUM
 246          ELSE
 247             L = 1
 248          END IF
 249          CALL SLASSQ( N, AB( L, 1 ), LDAB, SCALE, SUM )
 250          VALUE = SCALE*SQRT( SUM )
 251       END IF
 252 *
 253       SLANSB = VALUE
 254       RETURN
 255 *
 256 *     End of SLANSB
 257 *
 258       END